3 perlop - Perl operators and precedence
7 =head2 Operator Precedence and Associativity
9 Operator precedence and associativity work in Perl more or less like
10 they do in mathematics.
12 I<Operator precedence> means some operators are evaluated before
13 others. For example, in C<2 + 4 * 5>, the multiplication has higher
14 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
15 22> and not C<6 * 5 == 30>.
17 I<Operator associativity> defines what happens if a sequence of the
18 same operators is used one after another: whether the evaluator will
19 evaluate the left operations first or the right. For example, in C<8
20 - 4 - 2>, subtraction is left associative so Perl evaluates the
21 expression left to right. C<8 - 4> is evaluated first making the
22 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
24 Perl operators have the following associativity and precedence,
25 listed from highest precedence to lowest. Operators borrowed from
26 C keep the same precedence relationship with each other, even where
27 C's precedence is slightly screwy. (This makes learning Perl easier
28 for C folks.) With very few exceptions, these all operate on scalar
29 values only, not array values.
31 left terms and list operators (leftward)
35 right ! ~ \ and unary + and -
40 nonassoc named unary operators
41 nonassoc < > <= >= lt gt le ge
42 nonassoc == != <=> eq ne cmp
51 nonassoc list operators (rightward)
56 In the following sections, these operators are covered in precedence order.
58 Many operators can be overloaded for objects. See L<overload>.
60 =head2 Terms and List Operators (Leftward)
62 A TERM has the highest precedence in Perl. They include variables,
63 quote and quote-like operators, any expression in parentheses,
64 and any function whose arguments are parenthesized. Actually, there
65 aren't really functions in this sense, just list operators and unary
66 operators behaving as functions because you put parentheses around
67 the arguments. These are all documented in L<perlfunc>.
69 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
70 is followed by a left parenthesis as the next token, the operator and
71 arguments within parentheses are taken to be of highest precedence,
72 just like a normal function call.
74 In the absence of parentheses, the precedence of list operators such as
75 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
76 whether you are looking at the left side or the right side of the operator.
79 @ary = (1, 3, sort 4, 2);
80 print @ary; # prints 1324
82 the commas on the right of the sort are evaluated before the sort,
83 but the commas on the left are evaluated after. In other words,
84 list operators tend to gobble up all arguments that follow, and
85 then act like a simple TERM with regard to the preceding expression.
86 Be careful with parentheses:
88 # These evaluate exit before doing the print:
89 print($foo, exit); # Obviously not what you want.
90 print $foo, exit; # Nor is this.
92 # These do the print before evaluating exit:
93 (print $foo), exit; # This is what you want.
94 print($foo), exit; # Or this.
95 print ($foo), exit; # Or even this.
99 print ($foo & 255) + 1, "\n";
101 probably doesn't do what you expect at first glance. The parentheses
102 enclose the argument list for C<print> which is evaluated (printing
103 the result of C<$foo & 255>). Then one is added to the return value
104 of C<print> (usually 1). The result is something like this:
106 1 + 1, "\n"; # Obviously not what you meant.
108 To do what you meant properly, you must write:
110 print(($foo & 255) + 1, "\n");
112 See L<Named Unary Operators> for more discussion of this.
114 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
115 well as subroutine and method calls, and the anonymous
116 constructors C<[]> and C<{}>.
118 See also L<Quote and Quote-like Operators> toward the end of this section,
119 as well as L<"I/O Operators">.
121 =head2 The Arrow Operator
123 "C<< -> >>" is an infix dereference operator, just as it is in C
124 and C++. If the right side is either a C<[...]>, C<{...}>, or a
125 C<(...)> subscript, then the left side must be either a hard or
126 symbolic reference to an array, a hash, or a subroutine respectively.
127 (Or technically speaking, a location capable of holding a hard
128 reference, if it's an array or hash reference being used for
129 assignment.) See L<perlreftut> and L<perlref>.
131 Otherwise, the right side is a method name or a simple scalar
132 variable containing either the method name or a subroutine reference,
133 and the left side must be either an object (a blessed reference)
134 or a class name (that is, a package name). See L<perlobj>.
136 =head2 Auto-increment and Auto-decrement
138 "++" and "--" work as in C. That is, if placed before a variable,
139 they increment or decrement the variable by one before returning the
140 value, and if placed after, increment or decrement after returning the
144 print $i++; # prints 0
145 print ++$j; # prints 1
147 The auto-increment operator has a little extra builtin magic to it. If
148 you increment a variable that is numeric, or that has ever been used in
149 a numeric context, you get a normal increment. If, however, the
150 variable has been used in only string contexts since it was set, and
151 has a value that is not the empty string and matches the pattern
152 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
153 character within its range, with carry:
155 print ++($foo = '99'); # prints '100'
156 print ++($foo = 'a0'); # prints 'a1'
157 print ++($foo = 'Az'); # prints 'Ba'
158 print ++($foo = 'zz'); # prints 'aaa'
160 C<undef> is always treated as numeric, and in particular is changed
161 to C<0> before incrementing (so that a post-increment of an undef value
162 will return C<0> rather than C<undef>).
164 The auto-decrement operator is not magical.
166 =head2 Exponentiation
168 Binary "**" is the exponentiation operator. It binds even more
169 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
170 implemented using C's pow(3) function, which actually works on doubles
173 =head2 Symbolic Unary Operators
175 Unary "!" performs logical negation, i.e., "not". See also C<not> for a lower
176 precedence version of this.
178 Unary "-" performs arithmetic negation if the operand is numeric. If
179 the operand is an identifier, a string consisting of a minus sign
180 concatenated with the identifier is returned. Otherwise, if the string
181 starts with a plus or minus, a string starting with the opposite sign
182 is returned. One effect of these rules is that C<-bareword> is equivalent
185 Unary "~" performs bitwise negation, i.e., 1's complement. For
186 example, C<0666 & ~027> is 0640. (See also L<Integer Arithmetic> and
187 L<Bitwise String Operators>.) Note that the width of the result is
188 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
189 bits wide on a 64-bit platform, so if you are expecting a certain bit
190 width, remember to use the & operator to mask off the excess bits.
192 Unary "+" has no effect whatsoever, even on strings. It is useful
193 syntactically for separating a function name from a parenthesized expression
194 that would otherwise be interpreted as the complete list of function
195 arguments. (See examples above under L<Terms and List Operators (Leftward)>.)
197 Unary "\" creates a reference to whatever follows it. See L<perlreftut>
198 and L<perlref>. Do not confuse this behavior with the behavior of
199 backslash within a string, although both forms do convey the notion
200 of protecting the next thing from interpolation.
202 =head2 Binding Operators
204 Binary "=~" binds a scalar expression to a pattern match. Certain operations
205 search or modify the string $_ by default. This operator makes that kind
206 of operation work on some other string. The right argument is a search
207 pattern, substitution, or transliteration. The left argument is what is
208 supposed to be searched, substituted, or transliterated instead of the default
209 $_. When used in scalar context, the return value generally indicates the
210 success of the operation. Behavior in list context depends on the particular
211 operator. See L</"Regexp Quote-Like Operators"> for details.
213 If the right argument is an expression rather than a search pattern,
214 substitution, or transliteration, it is interpreted as a search pattern at run
217 Binary "!~" is just like "=~" except the return value is negated in
220 =head2 Multiplicative Operators
222 Binary "*" multiplies two numbers.
224 Binary "/" divides two numbers.
226 Binary "%" computes the modulus of two numbers. Given integer
227 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
228 C<$a> minus the largest multiple of C<$b> that is not greater than
229 C<$a>. If C<$b> is negative, then C<$a % $b> is C<$a> minus the
230 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
231 result will be less than or equal to zero).
232 Note that when C<use integer> is in scope, "%" gives you direct access
233 to the modulus operator as implemented by your C compiler. This
234 operator is not as well defined for negative operands, but it will
237 Binary "x" is the repetition operator. In scalar context or if the left
238 operand is not enclosed in parentheses, it returns a string consisting
239 of the left operand repeated the number of times specified by the right
240 operand. In list context, if the left operand is enclosed in
241 parentheses, it repeats the list.
243 print '-' x 80; # print row of dashes
245 print "\t" x ($tab/8), ' ' x ($tab%8); # tab over
247 @ones = (1) x 80; # a list of 80 1's
248 @ones = (5) x @ones; # set all elements to 5
251 =head2 Additive Operators
253 Binary "+" returns the sum of two numbers.
255 Binary "-" returns the difference of two numbers.
257 Binary "." concatenates two strings.
259 =head2 Shift Operators
261 Binary "<<" returns the value of its left argument shifted left by the
262 number of bits specified by the right argument. Arguments should be
263 integers. (See also L<Integer Arithmetic>.)
265 Binary ">>" returns the value of its left argument shifted right by
266 the number of bits specified by the right argument. Arguments should
267 be integers. (See also L<Integer Arithmetic>.)
269 Note that both "<<" and ">>" in Perl are implemented directly using
270 "<<" and ">>" in C. If C<use integer> (see L<Integer Arithmetic>) is
271 in force then signed C integers are used, else unsigned C integers are
272 used. Either way, the implementation isn't going to generate results
273 larger than the size of the integer type Perl was built with (32 bits
276 The result of overflowing the range of the integers is undefined
277 because it is undefined also in C. In other words, using 32-bit
278 integers, C<< 1 << 32 >> is undefined. Shifting by a negative number
279 of bits is also undefined.
281 =head2 Named Unary Operators
283 The various named unary operators are treated as functions with one
284 argument, with optional parentheses.
286 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
287 is followed by a left parenthesis as the next token, the operator and
288 arguments within parentheses are taken to be of highest precedence,
289 just like a normal function call. For example,
290 because named unary operators are higher precedence than ||:
292 chdir $foo || die; # (chdir $foo) || die
293 chdir($foo) || die; # (chdir $foo) || die
294 chdir ($foo) || die; # (chdir $foo) || die
295 chdir +($foo) || die; # (chdir $foo) || die
297 but, because * is higher precedence than named operators:
299 chdir $foo * 20; # chdir ($foo * 20)
300 chdir($foo) * 20; # (chdir $foo) * 20
301 chdir ($foo) * 20; # (chdir $foo) * 20
302 chdir +($foo) * 20; # chdir ($foo * 20)
304 rand 10 * 20; # rand (10 * 20)
305 rand(10) * 20; # (rand 10) * 20
306 rand (10) * 20; # (rand 10) * 20
307 rand +(10) * 20; # rand (10 * 20)
309 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
310 treated like named unary operators, but they don't follow this functional
311 parenthesis rule. That means, for example, that C<-f($file).".bak"> is
312 equivalent to C<-f "$file.bak">.
314 See also L<"Terms and List Operators (Leftward)">.
316 =head2 Relational Operators
318 Binary "<" returns true if the left argument is numerically less than
321 Binary ">" returns true if the left argument is numerically greater
322 than the right argument.
324 Binary "<=" returns true if the left argument is numerically less than
325 or equal to the right argument.
327 Binary ">=" returns true if the left argument is numerically greater
328 than or equal to the right argument.
330 Binary "lt" returns true if the left argument is stringwise less than
333 Binary "gt" returns true if the left argument is stringwise greater
334 than the right argument.
336 Binary "le" returns true if the left argument is stringwise less than
337 or equal to the right argument.
339 Binary "ge" returns true if the left argument is stringwise greater
340 than or equal to the right argument.
342 =head2 Equality Operators
344 Binary "==" returns true if the left argument is numerically equal to
347 Binary "!=" returns true if the left argument is numerically not equal
348 to the right argument.
350 Binary "<=>" returns -1, 0, or 1 depending on whether the left
351 argument is numerically less than, equal to, or greater than the right
352 argument. If your platform supports NaNs (not-a-numbers) as numeric
353 values, using them with "<=>" returns undef. NaN is not "<", "==", ">",
354 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
355 returns true, as does NaN != anything else. If your platform doesn't
356 support NaNs then NaN is just a string with numeric value 0.
358 perl -le '$a = NaN; print "No NaN support here" if $a == $a'
359 perl -le '$a = NaN; print "NaN support here" if $a != $a'
361 Binary "eq" returns true if the left argument is stringwise equal to
364 Binary "ne" returns true if the left argument is stringwise not equal
365 to the right argument.
367 Binary "cmp" returns -1, 0, or 1 depending on whether the left
368 argument is stringwise less than, equal to, or greater than the right
371 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
372 by the current locale if C<use locale> is in effect. See L<perllocale>.
376 Binary "&" returns its operands ANDed together bit by bit.
377 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
379 Note that "&" has lower priority than relational operators, so for example
380 the brackets are essential in a test like
382 print "Even\n" if ($x & 1) == 0;
384 =head2 Bitwise Or and Exclusive Or
386 Binary "|" returns its operands ORed together bit by bit.
387 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
389 Binary "^" returns its operands XORed together bit by bit.
390 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
392 Note that "|" and "^" have lower priority than relational operators, so
393 for example the brackets are essential in a test like
395 print "false\n" if (8 | 2) != 10;
397 =head2 C-style Logical And
399 Binary "&&" performs a short-circuit logical AND operation. That is,
400 if the left operand is false, the right operand is not even evaluated.
401 Scalar or list context propagates down to the right operand if it
404 =head2 C-style Logical Or
406 Binary "||" performs a short-circuit logical OR operation. That is,
407 if the left operand is true, the right operand is not even evaluated.
408 Scalar or list context propagates down to the right operand if it
411 =head2 C-style Logical Defined-Or
413 Although it has no direct equivalent in C, Perl's C<//> operator is related
414 to its C-style or. In fact, it's exactly the same as C<||>, except that it
415 tests the left hand side's definedness instead of its truth. Thus, C<$a // $b>
416 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
417 rather than the value of C<defined($a)>) and is exactly equivalent to
418 C<defined($a) ? $a : $b>. This is very useful for providing default values
419 for variables. If you actually want to test if at least one of C<$a> and
420 C<$b> is defined, use C<defined($a // $b)>.
422 The C<||>, C<//> and C<&&> operators return the last value evaluated
423 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
424 portable way to find out the home directory might be:
426 $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
427 (getpwuid($<))[7] // die "You're homeless!\n";
429 In particular, this means that you shouldn't use this
430 for selecting between two aggregates for assignment:
432 @a = @b || @c; # this is wrong
433 @a = scalar(@b) || @c; # really meant this
434 @a = @b ? @b : @c; # this works fine, though
436 As more readable alternatives to C<&&>, C<//> and C<||> when used for
437 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
438 The short-circuit behavior is identical. The precedence of "and", "err"
439 and "or" is much lower, however, so that you can safely use them after a
440 list operator without the need for parentheses:
442 unlink "alpha", "beta", "gamma"
443 or gripe(), next LINE;
445 With the C-style operators that would have been written like this:
447 unlink("alpha", "beta", "gamma")
448 || (gripe(), next LINE);
450 Using "or" for assignment is unlikely to do what you want; see below.
452 =head2 Range Operators
454 Binary ".." is the range operator, which is really two different
455 operators depending on the context. In list context, it returns a
456 list of values counting (up by ones) from the left value to the right
457 value. If the left value is greater than the right value then it
458 returns the empty list. The range operator is useful for writing
459 C<foreach (1..10)> loops and for doing slice operations on arrays. In
460 the current implementation, no temporary array is created when the
461 range operator is used as the expression in C<foreach> loops, but older
462 versions of Perl might burn a lot of memory when you write something
465 for (1 .. 1_000_000) {
469 The range operator also works on strings, using the magical auto-increment,
472 In scalar context, ".." returns a boolean value. The operator is
473 bistable, like a flip-flop, and emulates the line-range (comma) operator
474 of B<sed>, B<awk>, and various editors. Each ".." operator maintains its
475 own boolean state. It is false as long as its left operand is false.
476 Once the left operand is true, the range operator stays true until the
477 right operand is true, I<AFTER> which the range operator becomes false
478 again. It doesn't become false till the next time the range operator is
479 evaluated. It can test the right operand and become false on the same
480 evaluation it became true (as in B<awk>), but it still returns true once.
481 If you don't want it to test the right operand till the next
482 evaluation, as in B<sed>, just use three dots ("...") instead of
483 two. In all other regards, "..." behaves just like ".." does.
485 The right operand is not evaluated while the operator is in the
486 "false" state, and the left operand is not evaluated while the
487 operator is in the "true" state. The precedence is a little lower
488 than || and &&. The value returned is either the empty string for
489 false, or a sequence number (beginning with 1) for true. The
490 sequence number is reset for each range encountered. The final
491 sequence number in a range has the string "E0" appended to it, which
492 doesn't affect its numeric value, but gives you something to search
493 for if you want to exclude the endpoint. You can exclude the
494 beginning point by waiting for the sequence number to be greater
497 If either operand of scalar ".." is a constant expression,
498 that operand is considered true if it is equal (C<==>) to the current
499 input line number (the C<$.> variable).
501 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
502 but that is only an issue if you use a floating point expression; when
503 implicitly using C<$.> as described in the previous paragraph, the
504 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
505 is set to a floating point value and you are not reading from a file.
506 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
507 you want in scalar context because each of the operands are evaluated
508 using their integer representation.
512 As a scalar operator:
514 if (101 .. 200) { print; } # print 2nd hundred lines, short for
515 # if ($. == 101 .. $. == 200) ...
516 next line if (1 .. /^$/); # skip header lines, short for
517 # ... if ($. == 1 .. /^$/);
518 s/^/> / if (/^$/ .. eof()); # quote body
520 # parse mail messages
522 $in_header = 1 .. /^$/;
523 $in_body = /^$/ .. eof;
530 close ARGV if eof; # reset $. each file
535 for (101 .. 200) { print; } # print $_ 100 times
536 @foo = @foo[0 .. $#foo]; # an expensive no-op
537 @foo = @foo[$#foo-4 .. $#foo]; # slice last 5 items
539 The range operator (in list context) makes use of the magical
540 auto-increment algorithm if the operands are strings. You
543 @alphabet = ('A' .. 'Z');
545 to get all normal letters of the English alphabet, or
547 $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
549 to get a hexadecimal digit, or
551 @z2 = ('01' .. '31'); print $z2[$mday];
553 to get dates with leading zeros. If the final value specified is not
554 in the sequence that the magical increment would produce, the sequence
555 goes until the next value would be longer than the final value
558 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
559 return two elements in list context.
561 @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
563 =head2 Conditional Operator
565 Ternary "?:" is the conditional operator, just as in C. It works much
566 like an if-then-else. If the argument before the ? is true, the
567 argument before the : is returned, otherwise the argument after the :
568 is returned. For example:
570 printf "I have %d dog%s.\n", $n,
571 ($n == 1) ? '' : "s";
573 Scalar or list context propagates downward into the 2nd
574 or 3rd argument, whichever is selected.
576 $a = $ok ? $b : $c; # get a scalar
577 @a = $ok ? @b : @c; # get an array
578 $a = $ok ? @b : @c; # oops, that's just a count!
580 The operator may be assigned to if both the 2nd and 3rd arguments are
581 legal lvalues (meaning that you can assign to them):
583 ($a_or_b ? $a : $b) = $c;
585 Because this operator produces an assignable result, using assignments
586 without parentheses will get you in trouble. For example, this:
588 $a % 2 ? $a += 10 : $a += 2
592 (($a % 2) ? ($a += 10) : $a) += 2
596 ($a % 2) ? ($a += 10) : ($a += 2)
598 That should probably be written more simply as:
600 $a += ($a % 2) ? 10 : 2;
602 =head2 Assignment Operators
604 "=" is the ordinary assignment operator.
606 Assignment operators work as in C. That is,
614 although without duplicating any side effects that dereferencing the lvalue
615 might trigger, such as from tie(). Other assignment operators work similarly.
616 The following are recognized:
623 Although these are grouped by family, they all have the precedence
626 Unlike in C, the scalar assignment operator produces a valid lvalue.
627 Modifying an assignment is equivalent to doing the assignment and
628 then modifying the variable that was assigned to. This is useful
629 for modifying a copy of something, like this:
631 ($tmp = $global) =~ tr [A-Z] [a-z];
642 Similarly, a list assignment in list context produces the list of
643 lvalues assigned to, and a list assignment in scalar context returns
644 the number of elements produced by the expression on the right hand
645 side of the assignment.
647 =head2 Comma Operator
649 Binary "," is the comma operator. In scalar context it evaluates
650 its left argument, throws that value away, then evaluates its right
651 argument and returns that value. This is just like C's comma operator.
653 In list context, it's just the list argument separator, and inserts
654 both its arguments into the list.
656 The C<< => >> operator is a synonym for the comma, but forces any word
657 to its left to be interpreted as a string (as of 5.001). It is helpful
658 in documenting the correspondence between keys and values in hashes,
659 and other paired elements in lists.
661 =head2 List Operators (Rightward)
663 On the right side of a list operator, it has very low precedence,
664 such that it controls all comma-separated expressions found there.
665 The only operators with lower precedence are the logical operators
666 "and", "or", and "not", which may be used to evaluate calls to list
667 operators without the need for extra parentheses:
669 open HANDLE, "filename"
670 or die "Can't open: $!\n";
672 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
676 Unary "not" returns the logical negation of the expression to its right.
677 It's the equivalent of "!" except for the very low precedence.
681 Binary "and" returns the logical conjunction of the two surrounding
682 expressions. It's equivalent to && except for the very low
683 precedence. This means that it short-circuits: i.e., the right
684 expression is evaluated only if the left expression is true.
686 =head2 Logical or, Defined or, and Exclusive Or
688 Binary "or" returns the logical disjunction of the two surrounding
689 expressions. It's equivalent to || except for the very low precedence.
690 This makes it useful for control flow
692 print FH $data or die "Can't write to FH: $!";
694 This means that it short-circuits: i.e., the right expression is evaluated
695 only if the left expression is false. Due to its precedence, you should
696 probably avoid using this for assignment, only for control flow.
698 $a = $b or $c; # bug: this is wrong
699 ($a = $b) or $c; # really means this
700 $a = $b || $c; # better written this way
702 However, when it's a list-context assignment and you're trying to use
703 "||" for control flow, you probably need "or" so that the assignment
704 takes higher precedence.
706 @info = stat($file) || die; # oops, scalar sense of stat!
707 @info = stat($file) or die; # better, now @info gets its due
709 Then again, you could always use parentheses.
711 Binary "err" is equivalent to C<//>--it's just like binary "or", except it tests
712 its left argument's definedness instead of its truth. There are two ways to
713 remember "err": either because many functions return C<undef> on an B<err>or,
714 or as a sort of correction: C<$a=($b err 'default')>
716 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
717 It cannot short circuit, of course.
719 =head2 C Operators Missing From Perl
721 Here is what C has that Perl doesn't:
727 Address-of operator. (But see the "\" operator for taking a reference.)
731 Dereference-address operator. (Perl's prefix dereferencing
732 operators are typed: $, @, %, and &.)
736 Type-casting operator.
740 =head2 Quote and Quote-like Operators
742 While we usually think of quotes as literal values, in Perl they
743 function as operators, providing various kinds of interpolating and
744 pattern matching capabilities. Perl provides customary quote characters
745 for these behaviors, but also provides a way for you to choose your
746 quote character for any of them. In the following table, a C<{}> represents
747 any pair of delimiters you choose.
749 Customary Generic Meaning Interpolates
754 // m{} Pattern match yes*
756 s{}{} Substitution yes*
757 tr{}{} Transliteration no (but see below)
760 * unless the delimiter is ''.
762 Non-bracketing delimiters use the same character fore and aft, but the four
763 sorts of brackets (round, angle, square, curly) will all nest, which means
772 Note, however, that this does not always work for quoting Perl code:
774 $s = q{ if($a eq "}") ... }; # WRONG
776 is a syntax error. The C<Text::Balanced> module (from CPAN, and
777 starting from Perl 5.8 part of the standard distribution) is able
780 There can be whitespace between the operator and the quoting
781 characters, except when C<#> is being used as the quoting character.
782 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
783 operator C<q> followed by a comment. Its argument will be taken
784 from the next line. This allows you to write:
786 s {foo} # Replace foo
789 The following escape sequences are available in constructs that interpolate
790 and in transliterations.
797 \a alarm (bell) (BEL)
799 \033 octal char (ESC)
801 \x{263a} wide hex char (SMILEY)
802 \c[ control char (ESC)
803 \N{name} named Unicode character
805 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
806 the vertical tab (VT - ASCII 11).
808 The following escape sequences are available in constructs that interpolate
809 but not in transliterations.
811 \l lowercase next char
812 \u uppercase next char
815 \E end case modification
816 \Q quote non-word characters till \E
818 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
819 C<\u> and C<\U> is taken from the current locale. See L<perllocale>.
820 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
821 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
822 C<\U> is as defined by Unicode. For documentation of C<\N{name}>,
825 All systems use the virtual C<"\n"> to represent a line terminator,
826 called a "newline". There is no such thing as an unvarying, physical
827 newline character. It is only an illusion that the operating system,
828 device drivers, C libraries, and Perl all conspire to preserve. Not all
829 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF. For example,
830 on a Mac, these are reversed, and on systems without line terminator,
831 printing C<"\n"> may emit no actual data. In general, use C<"\n"> when
832 you mean a "newline" for your system, but use the literal ASCII when you
833 need an exact character. For example, most networking protocols expect
834 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
835 and although they often accept just C<"\012">, they seldom tolerate just
836 C<"\015">. If you get in the habit of using C<"\n"> for networking,
837 you may be burned some day.
839 For constructs that do interpolate, variables beginning with "C<$>"
840 or "C<@>" are interpolated. Subscripted variables such as C<$a[3]> or
841 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
842 But method calls such as C<< $obj->meth >> are not.
844 Interpolating an array or slice interpolates the elements in order,
845 separated by the value of C<$">, so is equivalent to interpolating
846 C<join $", @array>. "Punctuation" arrays such as C<@+> are only
847 interpolated if the name is enclosed in braces C<@{+}>.
849 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
850 An unescaped C<$> or C<@> interpolates the corresponding variable,
851 while escaping will cause the literal string C<\$> to be inserted.
852 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
854 Patterns are subject to an additional level of interpretation as a
855 regular expression. This is done as a second pass, after variables are
856 interpolated, so that regular expressions may be incorporated into the
857 pattern from the variables. If this is not what you want, use C<\Q> to
858 interpolate a variable literally.
860 Apart from the behavior described above, Perl does not expand
861 multiple levels of interpolation. In particular, contrary to the
862 expectations of shell programmers, back-quotes do I<NOT> interpolate
863 within double quotes, nor do single quotes impede evaluation of
864 variables when used within double quotes.
866 =head2 Regexp Quote-Like Operators
868 Here are the quote-like operators that apply to pattern
869 matching and related activities.
875 This is just like the C</pattern/> search, except that it matches only
876 once between calls to the reset() operator. This is a useful
877 optimization when you want to see only the first occurrence of
878 something in each file of a set of files, for instance. Only C<??>
879 patterns local to the current package are reset.
883 # blank line between header and body
886 reset if eof; # clear ?? status for next file
889 This usage is vaguely deprecated, which means it just might possibly
890 be removed in some distant future version of Perl, perhaps somewhere
891 around the year 2168.
893 =item m/PATTERN/cgimosx
895 =item /PATTERN/cgimosx
897 Searches a string for a pattern match, and in scalar context returns
898 true if it succeeds, false if it fails. If no string is specified
899 via the C<=~> or C<!~> operator, the $_ string is searched. (The
900 string specified with C<=~> need not be an lvalue--it may be the
901 result of an expression evaluation, but remember the C<=~> binds
902 rather tightly.) See also L<perlre>. See L<perllocale> for
903 discussion of additional considerations that apply when C<use locale>
908 c Do not reset search position on a failed match when /g is in effect.
909 g Match globally, i.e., find all occurrences.
910 i Do case-insensitive pattern matching.
911 m Treat string as multiple lines.
912 o Compile pattern only once.
913 s Treat string as single line.
914 x Use extended regular expressions.
916 If "/" is the delimiter then the initial C<m> is optional. With the C<m>
917 you can use any pair of non-alphanumeric, non-whitespace characters
918 as delimiters. This is particularly useful for matching path names
919 that contain "/", to avoid LTS (leaning toothpick syndrome). If "?" is
920 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
921 If "'" is the delimiter, no interpolation is performed on the PATTERN.
923 PATTERN may contain variables, which will be interpolated (and the
924 pattern recompiled) every time the pattern search is evaluated, except
925 for when the delimiter is a single quote. (Note that C<$(>, C<$)>, and
926 C<$|> are not interpolated because they look like end-of-string tests.)
927 If you want such a pattern to be compiled only once, add a C</o> after
928 the trailing delimiter. This avoids expensive run-time recompilations,
929 and is useful when the value you are interpolating won't change over
930 the life of the script. However, mentioning C</o> constitutes a promise
931 that you won't change the variables in the pattern. If you change them,
932 Perl won't even notice. See also L<"qr/STRING/imosx">.
934 If the PATTERN evaluates to the empty string, the last
935 I<successfully> matched regular expression is used instead. In this
936 case, only the C<g> and C<c> flags on the empty pattern is honoured -
937 the other flags are taken from the original pattern. If no match has
938 previously succeeded, this will (silently) act instead as a genuine
939 empty pattern (which will always match).
941 Note that it's possible to confuse Perl into thinking C<//> (the empty
942 regex) is really C<//> (the defined-or operator). Perl is usually pretty
943 good about this, but some pathological cases might trigger this, such as
944 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
945 (C<print $fh(//> or C<print($fh //>?). In all of these examples, Perl
946 will assume you meant defined-or. If you meant the empty regex, just
947 use parentheses or spaces to disambiguate, or even prefix the empty
948 regex with an C<m> (so C<//> becomes C<m//>).
950 If the C</g> option is not used, C<m//> in list context returns a
951 list consisting of the subexpressions matched by the parentheses in the
952 pattern, i.e., (C<$1>, C<$2>, C<$3>...). (Note that here C<$1> etc. are
953 also set, and that this differs from Perl 4's behavior.) When there are
954 no parentheses in the pattern, the return value is the list C<(1)> for
955 success. With or without parentheses, an empty list is returned upon
960 open(TTY, '/dev/tty');
961 <TTY> =~ /^y/i && foo(); # do foo if desired
963 if (/Version: *([0-9.]*)/) { $version = $1; }
965 next if m#^/usr/spool/uucp#;
970 print if /$arg/o; # compile only once
973 if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
975 This last example splits $foo into the first two words and the
976 remainder of the line, and assigns those three fields to $F1, $F2, and
977 $Etc. The conditional is true if any variables were assigned, i.e., if
980 The C</g> modifier specifies global pattern matching--that is,
981 matching as many times as possible within the string. How it behaves
982 depends on the context. In list context, it returns a list of the
983 substrings matched by any capturing parentheses in the regular
984 expression. If there are no parentheses, it returns a list of all
985 the matched strings, as if there were parentheses around the whole
988 In scalar context, each execution of C<m//g> finds the next match,
989 returning true if it matches, and false if there is no further match.
990 The position after the last match can be read or set using the pos()
991 function; see L<perlfunc/pos>. A failed match normally resets the
992 search position to the beginning of the string, but you can avoid that
993 by adding the C</c> modifier (e.g. C<m//gc>). Modifying the target
994 string also resets the search position.
996 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
997 zero-width assertion that matches the exact position where the previous
998 C<m//g>, if any, left off. Without the C</g> modifier, the C<\G> assertion
999 still anchors at pos(), but the match is of course only attempted once.
1000 Using C<\G> without C</g> on a target string that has not previously had a
1001 C</g> match applied to it is the same as using the C<\A> assertion to match
1002 the beginning of the string. Note also that, currently, C<\G> is only
1003 properly supported when anchored at the very beginning of the pattern.
1008 ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1012 while (defined($paragraph = <>)) {
1013 while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1017 print "$sentences\n";
1019 # using m//gc with \G
1023 print $1 while /(o)/gc; print "', pos=", pos, "\n";
1025 print $1 if /\G(q)/gc; print "', pos=", pos, "\n";
1027 print $1 while /(p)/gc; print "', pos=", pos, "\n";
1029 print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1031 The last example should print:
1041 Notice that the final match matched C<q> instead of C<p>, which a match
1042 without the C<\G> anchor would have done. Also note that the final match
1043 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1044 final match did indeed match C<p>, it's a good bet that you're running an
1045 older (pre-5.6.0) Perl.
1047 A useful idiom for C<lex>-like scanners is C</\G.../gc>. You can
1048 combine several regexps like this to process a string part-by-part,
1049 doing different actions depending on which regexp matched. Each
1050 regexp tries to match where the previous one leaves off.
1053 $url = new URI::URL "http://www/"; die if $url eq "xXx";
1057 print(" digits"), redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1058 print(" lowercase"), redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1059 print(" UPPERCASE"), redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1060 print(" Capitalized"), redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1061 print(" MiXeD"), redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1062 print(" alphanumeric"), redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1063 print(" line-noise"), redo LOOP if /\G[^A-Za-z0-9]+/gc;
1064 print ". That's all!\n";
1067 Here is the output (split into several lines):
1069 line-noise lowercase line-noise lowercase UPPERCASE line-noise
1070 UPPERCASE line-noise lowercase line-noise lowercase line-noise
1071 lowercase lowercase line-noise lowercase lowercase line-noise
1072 MiXeD line-noise. That's all!
1078 A single-quoted, literal string. A backslash represents a backslash
1079 unless followed by the delimiter or another backslash, in which case
1080 the delimiter or backslash is interpolated.
1082 $foo = q!I said, "You said, 'She said it.'"!;
1083 $bar = q('This is it.');
1084 $baz = '\n'; # a two-character string
1090 A double-quoted, interpolated string.
1093 (*** The previous line contains the naughty word "$1".\n)
1094 if /\b(tcl|java|python)\b/i; # :-)
1095 $baz = "\n"; # a one-character string
1097 =item qr/STRING/imosx
1099 This operator quotes (and possibly compiles) its I<STRING> as a regular
1100 expression. I<STRING> is interpolated the same way as I<PATTERN>
1101 in C<m/PATTERN/>. If "'" is used as the delimiter, no interpolation
1102 is done. Returns a Perl value which may be used instead of the
1103 corresponding C</STRING/imosx> expression.
1107 $rex = qr/my.STRING/is;
1114 The result may be used as a subpattern in a match:
1117 $string =~ /foo${re}bar/; # can be interpolated in other patterns
1118 $string =~ $re; # or used standalone
1119 $string =~ /$re/; # or this way
1121 Since Perl may compile the pattern at the moment of execution of qr()
1122 operator, using qr() may have speed advantages in some situations,
1123 notably if the result of qr() is used standalone:
1126 my $patterns = shift;
1127 my @compiled = map qr/$_/i, @$patterns;
1130 foreach my $pat (@compiled) {
1131 $success = 1, last if /$pat/;
1137 Precompilation of the pattern into an internal representation at
1138 the moment of qr() avoids a need to recompile the pattern every
1139 time a match C</$pat/> is attempted. (Perl has many other internal
1140 optimizations, but none would be triggered in the above example if
1141 we did not use qr() operator.)
1145 i Do case-insensitive pattern matching.
1146 m Treat string as multiple lines.
1147 o Compile pattern only once.
1148 s Treat string as single line.
1149 x Use extended regular expressions.
1151 See L<perlre> for additional information on valid syntax for STRING, and
1152 for a detailed look at the semantics of regular expressions.
1158 A string which is (possibly) interpolated and then executed as a
1159 system command with C</bin/sh> or its equivalent. Shell wildcards,
1160 pipes, and redirections will be honored. The collected standard
1161 output of the command is returned; standard error is unaffected. In
1162 scalar context, it comes back as a single (potentially multi-line)
1163 string, or undef if the command failed. In list context, returns a
1164 list of lines (however you've defined lines with $/ or
1165 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1167 Because backticks do not affect standard error, use shell file descriptor
1168 syntax (assuming the shell supports this) if you care to address this.
1169 To capture a command's STDERR and STDOUT together:
1171 $output = `cmd 2>&1`;
1173 To capture a command's STDOUT but discard its STDERR:
1175 $output = `cmd 2>/dev/null`;
1177 To capture a command's STDERR but discard its STDOUT (ordering is
1180 $output = `cmd 2>&1 1>/dev/null`;
1182 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1183 but leave its STDOUT to come out the old STDERR:
1185 $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1187 To read both a command's STDOUT and its STDERR separately, it's easiest
1188 to redirect them separately to files, and then read from those files
1189 when the program is done:
1191 system("program args 1>program.stdout 2>program.stderr");
1193 Using single-quote as a delimiter protects the command from Perl's
1194 double-quote interpolation, passing it on to the shell instead:
1196 $perl_info = qx(ps $$); # that's Perl's $$
1197 $shell_info = qx'ps $$'; # that's the new shell's $$
1199 How that string gets evaluated is entirely subject to the command
1200 interpreter on your system. On most platforms, you will have to protect
1201 shell metacharacters if you want them treated literally. This is in
1202 practice difficult to do, as it's unclear how to escape which characters.
1203 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1204 to emulate backticks safely.
1206 On some platforms (notably DOS-like ones), the shell may not be
1207 capable of dealing with multiline commands, so putting newlines in
1208 the string may not get you what you want. You may be able to evaluate
1209 multiple commands in a single line by separating them with the command
1210 separator character, if your shell supports that (e.g. C<;> on many Unix
1211 shells; C<&> on the Windows NT C<cmd> shell).
1213 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1214 output before starting the child process, but this may not be supported
1215 on some platforms (see L<perlport>). To be safe, you may need to set
1216 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1217 C<IO::Handle> on any open handles.
1219 Beware that some command shells may place restrictions on the length
1220 of the command line. You must ensure your strings don't exceed this
1221 limit after any necessary interpolations. See the platform-specific
1222 release notes for more details about your particular environment.
1224 Using this operator can lead to programs that are difficult to port,
1225 because the shell commands called vary between systems, and may in
1226 fact not be present at all. As one example, the C<type> command under
1227 the POSIX shell is very different from the C<type> command under DOS.
1228 That doesn't mean you should go out of your way to avoid backticks
1229 when they're the right way to get something done. Perl was made to be
1230 a glue language, and one of the things it glues together is commands.
1231 Just understand what you're getting yourself into.
1233 See L<"I/O Operators"> for more discussion.
1237 Evaluates to a list of the words extracted out of STRING, using embedded
1238 whitespace as the word delimiters. It can be understood as being roughly
1241 split(' ', q/STRING/);
1243 the differences being that it generates a real list at compile time, and
1244 in scalar context it returns the last element in the list. So
1249 is semantically equivalent to the list:
1253 Some frequently seen examples:
1255 use POSIX qw( setlocale localeconv )
1256 @EXPORT = qw( foo bar baz );
1258 A common mistake is to try to separate the words with comma or to
1259 put comments into a multi-line C<qw>-string. For this reason, the
1260 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1261 produces warnings if the STRING contains the "," or the "#" character.
1263 =item s/PATTERN/REPLACEMENT/egimosx
1265 Searches a string for a pattern, and if found, replaces that pattern
1266 with the replacement text and returns the number of substitutions
1267 made. Otherwise it returns false (specifically, the empty string).
1269 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1270 variable is searched and modified. (The string specified with C<=~> must
1271 be scalar variable, an array element, a hash element, or an assignment
1272 to one of those, i.e., an lvalue.)
1274 If the delimiter chosen is a single quote, no interpolation is
1275 done on either the PATTERN or the REPLACEMENT. Otherwise, if the
1276 PATTERN contains a $ that looks like a variable rather than an
1277 end-of-string test, the variable will be interpolated into the pattern
1278 at run-time. If you want the pattern compiled only once the first time
1279 the variable is interpolated, use the C</o> option. If the pattern
1280 evaluates to the empty string, the last successfully executed regular
1281 expression is used instead. See L<perlre> for further explanation on these.
1282 See L<perllocale> for discussion of additional considerations that apply
1283 when C<use locale> is in effect.
1287 e Evaluate the right side as an expression.
1288 g Replace globally, i.e., all occurrences.
1289 i Do case-insensitive pattern matching.
1290 m Treat string as multiple lines.
1291 o Compile pattern only once.
1292 s Treat string as single line.
1293 x Use extended regular expressions.
1295 Any non-alphanumeric, non-whitespace delimiter may replace the
1296 slashes. If single quotes are used, no interpretation is done on the
1297 replacement string (the C</e> modifier overrides this, however). Unlike
1298 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1299 text is not evaluated as a command. If the
1300 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1301 pair of quotes, which may or may not be bracketing quotes, e.g.,
1302 C<s(foo)(bar)> or C<< s<foo>/bar/ >>. A C</e> will cause the
1303 replacement portion to be treated as a full-fledged Perl expression
1304 and evaluated right then and there. It is, however, syntax checked at
1305 compile-time. A second C<e> modifier will cause the replacement portion
1306 to be C<eval>ed before being run as a Perl expression.
1310 s/\bgreen\b/mauve/g; # don't change wintergreen
1312 $path =~ s|/usr/bin|/usr/local/bin|;
1314 s/Login: $foo/Login: $bar/; # run-time pattern
1316 ($foo = $bar) =~ s/this/that/; # copy first, then change
1318 $count = ($paragraph =~ s/Mister\b/Mr./g); # get change-count
1321 s/\d+/$&*2/e; # yields 'abc246xyz'
1322 s/\d+/sprintf("%5d",$&)/e; # yields 'abc 246xyz'
1323 s/\w/$& x 2/eg; # yields 'aabbcc 224466xxyyzz'
1325 s/%(.)/$percent{$1}/g; # change percent escapes; no /e
1326 s/%(.)/$percent{$1} || $&/ge; # expr now, so /e
1327 s/^=(\w+)/&pod($1)/ge; # use function call
1329 # expand variables in $_, but dynamics only, using
1330 # symbolic dereferencing
1333 # Add one to the value of any numbers in the string
1336 # This will expand any embedded scalar variable
1337 # (including lexicals) in $_ : First $1 is interpolated
1338 # to the variable name, and then evaluated
1341 # Delete (most) C comments.
1343 /\* # Match the opening delimiter.
1344 .*? # Match a minimal number of characters.
1345 \*/ # Match the closing delimiter.
1348 s/^\s*(.*?)\s*$/$1/; # trim white space in $_, expensively
1350 for ($variable) { # trim white space in $variable, cheap
1355 s/([^ ]*) *([^ ]*)/$2 $1/; # reverse 1st two fields
1357 Note the use of $ instead of \ in the last example. Unlike
1358 B<sed>, we use the \<I<digit>> form in only the left hand side.
1359 Anywhere else it's $<I<digit>>.
1361 Occasionally, you can't use just a C</g> to get all the changes
1362 to occur that you might want. Here are two common cases:
1364 # put commas in the right places in an integer
1365 1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1367 # expand tabs to 8-column spacing
1368 1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1370 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1372 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1374 Transliterates all occurrences of the characters found in the search list
1375 with the corresponding character in the replacement list. It returns
1376 the number of characters replaced or deleted. If no string is
1377 specified via the =~ or !~ operator, the $_ string is transliterated. (The
1378 string specified with =~ must be a scalar variable, an array element, a
1379 hash element, or an assignment to one of those, i.e., an lvalue.)
1381 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1382 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1383 For B<sed> devotees, C<y> is provided as a synonym for C<tr>. If the
1384 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1385 its own pair of quotes, which may or may not be bracketing quotes,
1386 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1388 Note that C<tr> does B<not> do regular expression character classes
1389 such as C<\d> or C<[:lower:]>. The <tr> operator is not equivalent to
1390 the tr(1) utility. If you want to map strings between lower/upper
1391 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1392 using the C<s> operator if you need regular expressions.
1394 Note also that the whole range idea is rather unportable between
1395 character sets--and even within character sets they may cause results
1396 you probably didn't expect. A sound principle is to use only ranges
1397 that begin from and end at either alphabets of equal case (a-e, A-E),
1398 or digits (0-4). Anything else is unsafe. If in doubt, spell out the
1399 character sets in full.
1403 c Complement the SEARCHLIST.
1404 d Delete found but unreplaced characters.
1405 s Squash duplicate replaced characters.
1407 If the C</c> modifier is specified, the SEARCHLIST character set
1408 is complemented. If the C</d> modifier is specified, any characters
1409 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1410 (Note that this is slightly more flexible than the behavior of some
1411 B<tr> programs, which delete anything they find in the SEARCHLIST,
1412 period.) If the C</s> modifier is specified, sequences of characters
1413 that were transliterated to the same character are squashed down
1414 to a single instance of the character.
1416 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1417 exactly as specified. Otherwise, if the REPLACEMENTLIST is shorter
1418 than the SEARCHLIST, the final character is replicated till it is long
1419 enough. If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1420 This latter is useful for counting characters in a class or for
1421 squashing character sequences in a class.
1425 $ARGV[1] =~ tr/A-Z/a-z/; # canonicalize to lower case
1427 $cnt = tr/*/*/; # count the stars in $_
1429 $cnt = $sky =~ tr/*/*/; # count the stars in $sky
1431 $cnt = tr/0-9//; # count the digits in $_
1433 tr/a-zA-Z//s; # bookkeeper -> bokeper
1435 ($HOST = $host) =~ tr/a-z/A-Z/;
1437 tr/a-zA-Z/ /cs; # change non-alphas to single space
1440 [\000-\177]; # delete 8th bit
1442 If multiple transliterations are given for a character, only the
1447 will transliterate any A to X.
1449 Because the transliteration table is built at compile time, neither
1450 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1451 interpolation. That means that if you want to use variables, you
1454 eval "tr/$oldlist/$newlist/";
1457 eval "tr/$oldlist/$newlist/, 1" or die $@;
1461 A line-oriented form of quoting is based on the shell "here-document"
1462 syntax. Following a C<< << >> you specify a string to terminate
1463 the quoted material, and all lines following the current line down to
1464 the terminating string are the value of the item. The terminating
1465 string may be either an identifier (a word), or some quoted text. If
1466 quoted, the type of quotes you use determines the treatment of the
1467 text, just as in regular quoting. An unquoted identifier works like
1468 double quotes. There must be no space between the C<< << >> and
1469 the identifier, unless the identifier is quoted. (If you put a space it
1470 will be treated as a null identifier, which is valid, and matches the first
1471 empty line.) The terminating string must appear by itself (unquoted and
1472 with no surrounding whitespace) on the terminating line.
1475 The price is $Price.
1478 print << "EOF"; # same as above
1479 The price is $Price.
1482 print << `EOC`; # execute commands
1487 print <<"foo", <<"bar"; # you can stack them
1493 myfunc(<< "THIS", 23, <<'THAT');
1500 Just don't forget that you have to put a semicolon on the end
1501 to finish the statement, as Perl doesn't know you're not going to
1509 If you want your here-docs to be indented with the
1510 rest of the code, you'll need to remove leading whitespace
1511 from each line manually:
1513 ($quote = <<'FINIS') =~ s/^\s+//gm;
1514 The Road goes ever on and on,
1515 down from the door where it began.
1518 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1519 the quoted material must come on the lines following the final delimiter.
1534 If the terminating identifier is on the last line of the program, you
1535 must be sure there is a newline after it; otherwise, Perl will give the
1536 warning B<Can't find string terminator "END" anywhere before EOF...>.
1538 Additionally, the quoting rules for the identifier are not related to
1539 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
1540 in place of C<''> and C<"">, and the only interpolation is for backslashing
1541 the quoting character:
1543 print << "abc\"def";
1547 Finally, quoted strings cannot span multiple lines. The general rule is
1548 that the identifier must be a string literal. Stick with that, and you
1553 =head2 Gory details of parsing quoted constructs
1555 When presented with something that might have several different
1556 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1557 principle to pick the most probable interpretation. This strategy
1558 is so successful that Perl programmers often do not suspect the
1559 ambivalence of what they write. But from time to time, Perl's
1560 notions differ substantially from what the author honestly meant.
1562 This section hopes to clarify how Perl handles quoted constructs.
1563 Although the most common reason to learn this is to unravel labyrinthine
1564 regular expressions, because the initial steps of parsing are the
1565 same for all quoting operators, they are all discussed together.
1567 The most important Perl parsing rule is the first one discussed
1568 below: when processing a quoted construct, Perl first finds the end
1569 of that construct, then interprets its contents. If you understand
1570 this rule, you may skip the rest of this section on the first
1571 reading. The other rules are likely to contradict the user's
1572 expectations much less frequently than this first one.
1574 Some passes discussed below are performed concurrently, but because
1575 their results are the same, we consider them individually. For different
1576 quoting constructs, Perl performs different numbers of passes, from
1577 one to five, but these passes are always performed in the same order.
1581 =item Finding the end
1583 The first pass is finding the end of the quoted construct, whether
1584 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1585 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1586 terminates C<qq[]> construct, or a C<< > >> which terminates a
1587 fileglob started with C<< < >>.
1589 When searching for single-character non-pairing delimiters, such
1590 as C</>, combinations of C<\\> and C<\/> are skipped. However,
1591 when searching for single-character pairing delimiter like C<[>,
1592 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1593 C<[>, C<]> are skipped as well. When searching for multicharacter
1594 delimiters, nothing is skipped.
1596 For constructs with three-part delimiters (C<s///>, C<y///>, and
1597 C<tr///>), the search is repeated once more.
1599 During this search no attention is paid to the semantics of the construct.
1602 "$hash{"$foo/$bar"}"
1607 bar # NOT a comment, this slash / terminated m//!
1610 do not form legal quoted expressions. The quoted part ends on the
1611 first C<"> and C</>, and the rest happens to be a syntax error.
1612 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1613 the example above is not C<m//x>, but rather C<m//> with no C</x>
1614 modifier. So the embedded C<#> is interpreted as a literal C<#>.
1616 =item Removal of backslashes before delimiters
1618 During the second pass, text between the starting and ending
1619 delimiters is copied to a safe location, and the C<\> is removed
1620 from combinations consisting of C<\> and delimiter--or delimiters,
1621 meaning both starting and ending delimiters will should these differ.
1622 This removal does not happen for multi-character delimiters.
1623 Note that the combination C<\\> is left intact, just as it was.
1625 Starting from this step no information about the delimiters is
1630 The next step is interpolation in the text obtained, which is now
1631 delimiter-independent. There are four different cases.
1635 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1637 No interpolation is performed.
1641 The only interpolation is removal of C<\> from pairs C<\\>.
1643 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1645 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1646 converted to corresponding Perl constructs. Thus, C<"$foo\Qbaz$bar">
1647 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1648 The other combinations are replaced with appropriate expansions.
1650 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1651 is interpolated in the usual way. Something like C<"\Q\\E"> has
1652 no C<\E> inside. instead, it has C<\Q>, C<\\>, and C<E>, so the
1653 result is the same as for C<"\\\\E">. As a general rule, backslashes
1654 between C<\Q> and C<\E> may lead to counterintuitive results. So,
1655 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1656 as C<"\\\t"> (since TAB is not alphanumeric). Note also that:
1661 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1663 Interpolated scalars and arrays are converted internally to the C<join> and
1664 C<.> catenation operations. Thus, C<"$foo XXX '@arr'"> becomes:
1666 $foo . " XXX '" . (join $", @arr) . "'";
1668 All operations above are performed simultaneously, left to right.
1670 Because the result of C<"\Q STRING \E"> has all metacharacters
1671 quoted, there is no way to insert a literal C<$> or C<@> inside a
1672 C<\Q\E> pair. If protected by C<\>, C<$> will be quoted to became
1673 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1676 Note also that the interpolation code needs to make a decision on
1677 where the interpolated scalar ends. For instance, whether
1678 C<< "a $b -> {c}" >> really means:
1680 "a " . $b . " -> {c}";
1686 Most of the time, the longest possible text that does not include
1687 spaces between components and which contains matching braces or
1688 brackets. because the outcome may be determined by voting based
1689 on heuristic estimators, the result is not strictly predictable.
1690 Fortunately, it's usually correct for ambiguous cases.
1692 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
1694 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1695 happens (almost) as with C<qq//> constructs, but the substitution
1696 of C<\> followed by RE-special chars (including C<\>) is not
1697 performed. Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1698 a C<#>-comment in a C<//x>-regular expression, no processing is
1699 performed whatsoever. This is the first step at which the presence
1700 of the C<//x> modifier is relevant.
1702 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1703 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1704 different estimators) to be either an array element or C<$var>
1705 followed by an RE alternative. This is where the notation
1706 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1707 array element C<-9>, not as a regular expression from the variable
1708 C<$arr> followed by a digit, which would be the interpretation of
1709 C</$arr[0-9]/>. Since voting among different estimators may occur,
1710 the result is not predictable.
1712 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1713 the replacement text of C<s///> to correct the incorrigible
1714 I<sed> hackers who haven't picked up the saner idiom yet. A warning
1715 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1716 (that is, the C<$^W> variable) was set.
1718 The lack of processing of C<\\> creates specific restrictions on
1719 the post-processed text. If the delimiter is C</>, one cannot get
1720 the combination C<\/> into the result of this step. C</> will
1721 finish the regular expression, C<\/> will be stripped to C</> on
1722 the previous step, and C<\\/> will be left as is. Because C</> is
1723 equivalent to C<\/> inside a regular expression, this does not
1724 matter unless the delimiter happens to be character special to the
1725 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1726 alphanumeric char, as in:
1730 In the RE above, which is intentionally obfuscated for illustration, the
1731 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1732 RE is the same as for C<m/ ^ a \s* b /mx>. There's more than one
1733 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1734 non-whitespace choices.
1738 This step is the last one for all constructs except regular expressions,
1739 which are processed further.
1741 =item Interpolation of regular expressions
1743 Previous steps were performed during the compilation of Perl code,
1744 but this one happens at run time--although it may be optimized to
1745 be calculated at compile time if appropriate. After preprocessing
1746 described above, and possibly after evaluation if catenation,
1747 joining, casing translation, or metaquoting are involved, the
1748 resulting I<string> is passed to the RE engine for compilation.
1750 Whatever happens in the RE engine might be better discussed in L<perlre>,
1751 but for the sake of continuity, we shall do so here.
1753 This is another step where the presence of the C<//x> modifier is
1754 relevant. The RE engine scans the string from left to right and
1755 converts it to a finite automaton.
1757 Backslashed characters are either replaced with corresponding
1758 literal strings (as with C<\{>), or else they generate special nodes
1759 in the finite automaton (as with C<\b>). Characters special to the
1760 RE engine (such as C<|>) generate corresponding nodes or groups of
1761 nodes. C<(?#...)> comments are ignored. All the rest is either
1762 converted to literal strings to match, or else is ignored (as is
1763 whitespace and C<#>-style comments if C<//x> is present).
1765 Parsing of the bracketed character class construct, C<[...]>, is
1766 rather different than the rule used for the rest of the pattern.
1767 The terminator of this construct is found using the same rules as
1768 for finding the terminator of a C<{}>-delimited construct, the only
1769 exception being that C<]> immediately following C<[> is treated as
1770 though preceded by a backslash. Similarly, the terminator of
1771 C<(?{...})> is found using the same rules as for finding the
1772 terminator of a C<{}>-delimited construct.
1774 It is possible to inspect both the string given to RE engine and the
1775 resulting finite automaton. See the arguments C<debug>/C<debugcolor>
1776 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1777 switch documented in L<perlrun/"Command Switches">.
1779 =item Optimization of regular expressions
1781 This step is listed for completeness only. Since it does not change
1782 semantics, details of this step are not documented and are subject
1783 to change without notice. This step is performed over the finite
1784 automaton that was generated during the previous pass.
1786 It is at this stage that C<split()> silently optimizes C</^/> to
1791 =head2 I/O Operators
1793 There are several I/O operators you should know about.
1795 A string enclosed by backticks (grave accents) first undergoes
1796 double-quote interpolation. It is then interpreted as an external
1797 command, and the output of that command is the value of the
1798 backtick string, like in a shell. In scalar context, a single string
1799 consisting of all output is returned. In list context, a list of
1800 values is returned, one per line of output. (You can set C<$/> to use
1801 a different line terminator.) The command is executed each time the
1802 pseudo-literal is evaluated. The status value of the command is
1803 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
1804 Unlike in B<csh>, no translation is done on the return data--newlines
1805 remain newlines. Unlike in any of the shells, single quotes do not
1806 hide variable names in the command from interpretation. To pass a
1807 literal dollar-sign through to the shell you need to hide it with a
1808 backslash. The generalized form of backticks is C<qx//>. (Because
1809 backticks always undergo shell expansion as well, see L<perlsec> for
1812 In scalar context, evaluating a filehandle in angle brackets yields
1813 the next line from that file (the newline, if any, included), or
1814 C<undef> at end-of-file or on error. When C<$/> is set to C<undef>
1815 (sometimes known as file-slurp mode) and the file is empty, it
1816 returns C<''> the first time, followed by C<undef> subsequently.
1818 Ordinarily you must assign the returned value to a variable, but
1819 there is one situation where an automatic assignment happens. If
1820 and only if the input symbol is the only thing inside the conditional
1821 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1822 the value is automatically assigned to the global variable $_,
1823 destroying whatever was there previously. (This may seem like an
1824 odd thing to you, but you'll use the construct in almost every Perl
1825 script you write.) The $_ variable is not implicitly localized.
1826 You'll have to put a C<local $_;> before the loop if you want that
1829 The following lines are equivalent:
1831 while (defined($_ = <STDIN>)) { print; }
1832 while ($_ = <STDIN>) { print; }
1833 while (<STDIN>) { print; }
1834 for (;<STDIN>;) { print; }
1835 print while defined($_ = <STDIN>);
1836 print while ($_ = <STDIN>);
1837 print while <STDIN>;
1839 This also behaves similarly, but avoids $_ :
1841 while (my $line = <STDIN>) { print $line }
1843 In these loop constructs, the assigned value (whether assignment
1844 is automatic or explicit) is then tested to see whether it is
1845 defined. The defined test avoids problems where line has a string
1846 value that would be treated as false by Perl, for example a "" or
1847 a "0" with no trailing newline. If you really mean for such values
1848 to terminate the loop, they should be tested for explicitly:
1850 while (($_ = <STDIN>) ne '0') { ... }
1851 while (<STDIN>) { last unless $_; ... }
1853 In other boolean contexts, C<< <I<filehandle>> >> without an
1854 explicit C<defined> test or comparison elicit a warning if the
1855 C<use warnings> pragma or the B<-w>
1856 command-line switch (the C<$^W> variable) is in effect.
1858 The filehandles STDIN, STDOUT, and STDERR are predefined. (The
1859 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
1860 in packages, where they would be interpreted as local identifiers
1861 rather than global.) Additional filehandles may be created with
1862 the open() function, amongst others. See L<perlopentut> and
1863 L<perlfunc/open> for details on this.
1865 If a <FILEHANDLE> is used in a context that is looking for
1866 a list, a list comprising all input lines is returned, one line per
1867 list element. It's easy to grow to a rather large data space this
1868 way, so use with care.
1870 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
1871 See L<perlfunc/readline>.
1873 The null filehandle <> is special: it can be used to emulate the
1874 behavior of B<sed> and B<awk>. Input from <> comes either from
1875 standard input, or from each file listed on the command line. Here's
1876 how it works: the first time <> is evaluated, the @ARGV array is
1877 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1878 gives you standard input. The @ARGV array is then processed as a list
1879 of filenames. The loop
1882 ... # code for each line
1885 is equivalent to the following Perl-like pseudo code:
1887 unshift(@ARGV, '-') unless @ARGV;
1888 while ($ARGV = shift) {
1891 ... # code for each line
1895 except that it isn't so cumbersome to say, and will actually work.
1896 It really does shift the @ARGV array and put the current filename
1897 into the $ARGV variable. It also uses filehandle I<ARGV>
1898 internally--<> is just a synonym for <ARGV>, which
1899 is magical. (The pseudo code above doesn't work because it treats
1900 <ARGV> as non-magical.)
1902 You can modify @ARGV before the first <> as long as the array ends up
1903 containing the list of filenames you really want. Line numbers (C<$.>)
1904 continue as though the input were one big happy file. See the example
1905 in L<perlfunc/eof> for how to reset line numbers on each file.
1907 If you want to set @ARGV to your own list of files, go right ahead.
1908 This sets @ARGV to all plain text files if no @ARGV was given:
1910 @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1912 You can even set them to pipe commands. For example, this automatically
1913 filters compressed arguments through B<gzip>:
1915 @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1917 If you want to pass switches into your script, you can use one of the
1918 Getopts modules or put a loop on the front like this:
1920 while ($_ = $ARGV[0], /^-/) {
1923 if (/^-D(.*)/) { $debug = $1 }
1924 if (/^-v/) { $verbose++ }
1925 # ... # other switches
1929 # ... # code for each line
1932 The <> symbol will return C<undef> for end-of-file only once.
1933 If you call it again after this, it will assume you are processing another
1934 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
1936 If what the angle brackets contain is a simple scalar variable (e.g.,
1937 <$foo>), then that variable contains the name of the
1938 filehandle to input from, or its typeglob, or a reference to the
1944 If what's within the angle brackets is neither a filehandle nor a simple
1945 scalar variable containing a filehandle name, typeglob, or typeglob
1946 reference, it is interpreted as a filename pattern to be globbed, and
1947 either a list of filenames or the next filename in the list is returned,
1948 depending on context. This distinction is determined on syntactic
1949 grounds alone. That means C<< <$x> >> is always a readline() from
1950 an indirect handle, but C<< <$hash{key}> >> is always a glob().
1951 That's because $x is a simple scalar variable, but C<$hash{key}> is
1952 not--it's a hash element.
1954 One level of double-quote interpretation is done first, but you can't
1955 say C<< <$foo> >> because that's an indirect filehandle as explained
1956 in the previous paragraph. (In older versions of Perl, programmers
1957 would insert curly brackets to force interpretation as a filename glob:
1958 C<< <${foo}> >>. These days, it's considered cleaner to call the
1959 internal function directly as C<glob($foo)>, which is probably the right
1960 way to have done it in the first place.) For example:
1966 is roughly equivalent to:
1968 open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1974 except that the globbing is actually done internally using the standard
1975 C<File::Glob> extension. Of course, the shortest way to do the above is:
1979 A (file)glob evaluates its (embedded) argument only when it is
1980 starting a new list. All values must be read before it will start
1981 over. In list context, this isn't important because you automatically
1982 get them all anyway. However, in scalar context the operator returns
1983 the next value each time it's called, or C<undef> when the list has
1984 run out. As with filehandle reads, an automatic C<defined> is
1985 generated when the glob occurs in the test part of a C<while>,
1986 because legal glob returns (e.g. a file called F<0>) would otherwise
1987 terminate the loop. Again, C<undef> is returned only once. So if
1988 you're expecting a single value from a glob, it is much better to
1991 ($file) = <blurch*>;
1997 because the latter will alternate between returning a filename and
2000 If you're trying to do variable interpolation, it's definitely better
2001 to use the glob() function, because the older notation can cause people
2002 to become confused with the indirect filehandle notation.
2004 @files = glob("$dir/*.[ch]");
2005 @files = glob($files[$i]);
2007 =head2 Constant Folding
2009 Like C, Perl does a certain amount of expression evaluation at
2010 compile time whenever it determines that all arguments to an
2011 operator are static and have no side effects. In particular, string
2012 concatenation happens at compile time between literals that don't do
2013 variable substitution. Backslash interpolation also happens at
2014 compile time. You can say
2016 'Now is the time for all' . "\n" .
2017 'good men to come to.'
2019 and this all reduces to one string internally. Likewise, if
2022 foreach $file (@filenames) {
2023 if (-s $file > 5 + 100 * 2**16) { }
2026 the compiler will precompute the number which that expression
2027 represents so that the interpreter won't have to.
2029 =head2 Bitwise String Operators
2031 Bitstrings of any size may be manipulated by the bitwise operators
2034 If the operands to a binary bitwise op are strings of different
2035 sizes, B<|> and B<^> ops act as though the shorter operand had
2036 additional zero bits on the right, while the B<&> op acts as though
2037 the longer operand were truncated to the length of the shorter.
2038 The granularity for such extension or truncation is one or more
2041 # ASCII-based examples
2042 print "j p \n" ^ " a h"; # prints "JAPH\n"
2043 print "JA" | " ph\n"; # prints "japh\n"
2044 print "japh\nJunk" & '_____'; # prints "JAPH\n";
2045 print 'p N$' ^ " E<H\n"; # prints "Perl\n";
2047 If you are intending to manipulate bitstrings, be certain that
2048 you're supplying bitstrings: If an operand is a number, that will imply
2049 a B<numeric> bitwise operation. You may explicitly show which type of
2050 operation you intend by using C<""> or C<0+>, as in the examples below.
2052 $foo = 150 | 105 ; # yields 255 (0x96 | 0x69 is 0xFF)
2053 $foo = '150' | 105 ; # yields 255
2054 $foo = 150 | '105'; # yields 255
2055 $foo = '150' | '105'; # yields string '155' (under ASCII)
2057 $baz = 0+$foo & 0+$bar; # both ops explicitly numeric
2058 $biz = "$foo" ^ "$bar"; # both ops explicitly stringy
2060 See L<perlfunc/vec> for information on how to manipulate individual bits
2063 =head2 Integer Arithmetic
2065 By default, Perl assumes that it must do most of its arithmetic in
2066 floating point. But by saying
2070 you may tell the compiler that it's okay to use integer operations
2071 (if it feels like it) from here to the end of the enclosing BLOCK.
2072 An inner BLOCK may countermand this by saying
2076 which lasts until the end of that BLOCK. Note that this doesn't
2077 mean everything is only an integer, merely that Perl may use integer
2078 operations if it is so inclined. For example, even under C<use
2079 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2082 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2083 and ">>") always produce integral results. (But see also
2084 L<Bitwise String Operators>.) However, C<use integer> still has meaning for
2085 them. By default, their results are interpreted as unsigned integers, but
2086 if C<use integer> is in effect, their results are interpreted
2087 as signed integers. For example, C<~0> usually evaluates to a large
2088 integral value. However, C<use integer; ~0> is C<-1> on twos-complement
2091 =head2 Floating-point Arithmetic
2093 While C<use integer> provides integer-only arithmetic, there is no
2094 analogous mechanism to provide automatic rounding or truncation to a
2095 certain number of decimal places. For rounding to a certain number
2096 of digits, sprintf() or printf() is usually the easiest route.
2099 Floating-point numbers are only approximations to what a mathematician
2100 would call real numbers. There are infinitely more reals than floats,
2101 so some corners must be cut. For example:
2103 printf "%.20g\n", 123456789123456789;
2104 # produces 123456789123456784
2106 Testing for exact equality of floating-point equality or inequality is
2107 not a good idea. Here's a (relatively expensive) work-around to compare
2108 whether two floating-point numbers are equal to a particular number of
2109 decimal places. See Knuth, volume II, for a more robust treatment of
2113 my ($X, $Y, $POINTS) = @_;
2115 $tX = sprintf("%.${POINTS}g", $X);
2116 $tY = sprintf("%.${POINTS}g", $Y);
2120 The POSIX module (part of the standard perl distribution) implements
2121 ceil(), floor(), and other mathematical and trigonometric functions.
2122 The Math::Complex module (part of the standard perl distribution)
2123 defines mathematical functions that work on both the reals and the
2124 imaginary numbers. Math::Complex not as efficient as POSIX, but
2125 POSIX can't work with complex numbers.
2127 Rounding in financial applications can have serious implications, and
2128 the rounding method used should be specified precisely. In these
2129 cases, it probably pays not to trust whichever system rounding is
2130 being used by Perl, but to instead implement the rounding function you
2133 =head2 Bigger Numbers
2135 The standard Math::BigInt and Math::BigFloat modules provide
2136 variable-precision arithmetic and overloaded operators, although
2137 they're currently pretty slow. At the cost of some space and
2138 considerable speed, they avoid the normal pitfalls associated with
2139 limited-precision representations.
2142 $x = Math::BigInt->new('123456789123456789');
2145 # prints +15241578780673678515622620750190521
2147 There are several modules that let you calculate with (bound only by
2148 memory and cpu-time) unlimited or fixed precision. There are also
2149 some non-standard modules that provide faster implementations via
2150 external C libraries.
2152 Here is a short, but incomplete summary:
2154 Math::Fraction big, unlimited fractions like 9973 / 12967
2155 Math::String treat string sequences like numbers
2156 Math::FixedPrecision calculate with a fixed precision
2157 Math::Currency for currency calculations
2158 Bit::Vector manipulate bit vectors fast (uses C)
2159 Math::BigIntFast Bit::Vector wrapper for big numbers
2160 Math::Pari provides access to the Pari C library
2161 Math::BigInteger uses an external C library
2162 Math::Cephes uses external Cephes C library (no big numbers)
2163 Math::Cephes::Fraction fractions via the Cephes library
2164 Math::GMP another one using an external C library