3 perlop - Perl operators and precedence
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest. Note that all operators
9 borrowed from C keep the same precedence relationship with each other,
10 even where C's precedence is slightly screwy. (This makes learning
11 Perl easier for C folks.) With very few exceptions, these all
12 operate on scalar values only, not array values.
14 left terms and list operators (leftward)
18 right ! ~ \ and unary + and -
23 nonassoc named unary operators
24 nonassoc < > <= >= lt gt le ge
25 nonassoc == != <=> eq ne cmp
34 nonassoc list operators (rightward)
39 In the following sections, these operators are covered in precedence order.
43 =head2 Terms and List Operators (Leftward)
45 A TERM has the highest precedence in Perl. They includes variables,
46 quote and quote-like operators, any expression in parentheses,
47 and any function whose arguments are parenthesized. Actually, there
48 aren't really functions in this sense, just list operators and unary
49 operators behaving as functions because you put parentheses around
50 the arguments. These are all documented in L<perlfunc>.
52 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
53 is followed by a left parenthesis as the next token, the operator and
54 arguments within parentheses are taken to be of highest precedence,
55 just like a normal function call.
57 In the absence of parentheses, the precedence of list operators such as
58 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
59 whether you are looking at the left side or the right side of the operator.
62 @ary = (1, 3, sort 4, 2);
63 print @ary; # prints 1324
65 the commas on the right of the sort are evaluated before the sort, but
66 the commas on the left are evaluated after. In other words, list
67 operators tend to gobble up all the arguments that follow them, and
68 then act like a simple TERM with regard to the preceding expression.
69 Note that you have to be careful with parentheses:
71 # These evaluate exit before doing the print:
72 print($foo, exit); # Obviously not what you want.
73 print $foo, exit; # Nor is this.
75 # These do the print before evaluating exit:
76 (print $foo), exit; # This is what you want.
77 print($foo), exit; # Or this.
78 print ($foo), exit; # Or even this.
82 print ($foo & 255) + 1, "\n";
84 probably doesn't do what you expect at first glance. See
85 L<Named Unary Operators> for more discussion of this.
87 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
88 well as subroutine and method calls, and the anonymous
89 constructors C<[]> and C<{}>.
91 See also L<Quote and Quote-like Operators> toward the end of this section,
92 as well as L<"I/O Operators">.
94 =head2 The Arrow Operator
96 Just as in C and C++, "C<-E<gt>>" is an infix dereference operator. If the
97 right side is either a C<[...]> or C<{...}> subscript, then the left side
98 must be either a hard or symbolic reference to an array or hash (or
99 a location capable of holding a hard reference, if it's an lvalue (assignable)).
102 Otherwise, the right side is a method name or a simple scalar variable
103 containing the method name, and the left side must either be an object
104 (a blessed reference) or a class name (that is, a package name).
107 =head2 Auto-increment and Auto-decrement
109 "++" and "--" work as in C. That is, if placed before a variable, they
110 increment or decrement the variable before returning the value, and if
111 placed after, increment or decrement the variable after returning the value.
113 The auto-increment operator has a little extra builtin magic to it. If
114 you increment a variable that is numeric, or that has ever been used in
115 a numeric context, you get a normal increment. If, however, the
116 variable has been used in only string contexts since it was set, and
117 has a value that is not null and matches the pattern
118 C</^[a-zA-Z]*[0-9]*$/>, the increment is done as a string, preserving each
119 character within its range, with carry:
121 print ++($foo = '99'); # prints '100'
122 print ++($foo = 'a0'); # prints 'a1'
123 print ++($foo = 'Az'); # prints 'Ba'
124 print ++($foo = 'zz'); # prints 'aaa'
126 The auto-decrement operator is not magical.
128 =head2 Exponentiation
130 Binary "**" is the exponentiation operator. Note that it binds even more
131 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
132 implemented using C's pow(3) function, which actually works on doubles
135 =head2 Symbolic Unary Operators
137 Unary "!" performs logical negation, i.e., "not". See also C<not> for a lower
138 precedence version of this.
140 Unary "-" performs arithmetic negation if the operand is numeric. If
141 the operand is an identifier, a string consisting of a minus sign
142 concatenated with the identifier is returned. Otherwise, if the string
143 starts with a plus or minus, a string starting with the opposite sign
144 is returned. One effect of these rules is that C<-bareword> is equivalent
147 Unary "~" performs bitwise negation, i.e., 1's complement.
148 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
150 Unary "+" has no effect whatsoever, even on strings. It is useful
151 syntactically for separating a function name from a parenthesized expression
152 that would otherwise be interpreted as the complete list of function
153 arguments. (See examples above under L<Terms and List Operators (Leftward)>.)
155 Unary "\" creates a reference to whatever follows it. See L<perlref>.
156 Do not confuse this behavior with the behavior of backslash within a
157 string, although both forms do convey the notion of protecting the next
158 thing from interpretation.
160 =head2 Binding Operators
162 Binary "=~" binds a scalar expression to a pattern match. Certain operations
163 search or modify the string $_ by default. This operator makes that kind
164 of operation work on some other string. The right argument is a search
165 pattern, substitution, or transliteration. The left argument is what is
166 supposed to be searched, substituted, or transliterated instead of the default
167 $_. The return value indicates the success of the operation. (If the
168 right argument is an expression rather than a search pattern,
169 substitution, or transliteration, it is interpreted as a search pattern at run
170 time. This can be is less efficient than an explicit search, because the
171 pattern must be compiled every time the expression is evaluated.
173 Binary "!~" is just like "=~" except the return value is negated in
176 =head2 Multiplicative Operators
178 Binary "*" multiplies two numbers.
180 Binary "/" divides two numbers.
182 Binary "%" computes the modulus of two numbers. Given integer
183 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
184 C<$a> minus the largest multiple of C<$b> that is not greater than
185 C<$a>. If C<$b> is negative, then C<$a % $b> is C<$a> minus the
186 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
187 result will be less than or equal to zero).
189 Binary "x" is the repetition operator. In a scalar context, it
190 returns a string consisting of the left operand repeated the number of
191 times specified by the right operand. In a list context, if the left
192 operand is a list in parentheses, it repeats the list.
194 print '-' x 80; # print row of dashes
196 print "\t" x ($tab/8), ' ' x ($tab%8); # tab over
198 @ones = (1) x 80; # a list of 80 1's
199 @ones = (5) x @ones; # set all elements to 5
202 =head2 Additive Operators
204 Binary "+" returns the sum of two numbers.
206 Binary "-" returns the difference of two numbers.
208 Binary "." concatenates two strings.
210 =head2 Shift Operators
212 Binary "<<" returns the value of its left argument shifted left by the
213 number of bits specified by the right argument. Arguments should be
214 integers. (See also L<Integer Arithmetic>.)
216 Binary ">>" returns the value of its left argument shifted right by
217 the number of bits specified by the right argument. Arguments should
218 be integers. (See also L<Integer Arithmetic>.)
220 =head2 Named Unary Operators
222 The various named unary operators are treated as functions with one
223 argument, with optional parentheses. These include the filetest
224 operators, like C<-f>, C<-M>, etc. See L<perlfunc>.
226 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
227 is followed by a left parenthesis as the next token, the operator and
228 arguments within parentheses are taken to be of highest precedence,
229 just like a normal function call. Examples:
231 chdir $foo || die; # (chdir $foo) || die
232 chdir($foo) || die; # (chdir $foo) || die
233 chdir ($foo) || die; # (chdir $foo) || die
234 chdir +($foo) || die; # (chdir $foo) || die
236 but, because * is higher precedence than ||:
238 chdir $foo * 20; # chdir ($foo * 20)
239 chdir($foo) * 20; # (chdir $foo) * 20
240 chdir ($foo) * 20; # (chdir $foo) * 20
241 chdir +($foo) * 20; # chdir ($foo * 20)
243 rand 10 * 20; # rand (10 * 20)
244 rand(10) * 20; # (rand 10) * 20
245 rand (10) * 20; # (rand 10) * 20
246 rand +(10) * 20; # rand (10 * 20)
248 See also L<"Terms and List Operators (Leftward)">.
250 =head2 Relational Operators
252 Binary "E<lt>" returns true if the left argument is numerically less than
255 Binary "E<gt>" returns true if the left argument is numerically greater
256 than the right argument.
258 Binary "E<lt>=" returns true if the left argument is numerically less than
259 or equal to the right argument.
261 Binary "E<gt>=" returns true if the left argument is numerically greater
262 than or equal to the right argument.
264 Binary "lt" returns true if the left argument is stringwise less than
267 Binary "gt" returns true if the left argument is stringwise greater
268 than the right argument.
270 Binary "le" returns true if the left argument is stringwise less than
271 or equal to the right argument.
273 Binary "ge" returns true if the left argument is stringwise greater
274 than or equal to the right argument.
276 =head2 Equality Operators
278 Binary "==" returns true if the left argument is numerically equal to
281 Binary "!=" returns true if the left argument is numerically not equal
282 to the right argument.
284 Binary "E<lt>=E<gt>" returns -1, 0, or 1 depending on whether the left
285 argument is numerically less than, equal to, or greater than the right
288 Binary "eq" returns true if the left argument is stringwise equal to
291 Binary "ne" returns true if the left argument is stringwise not equal
292 to the right argument.
294 Binary "cmp" returns -1, 0, or 1 depending on whether the left argument is stringwise
295 less than, equal to, or greater than the right argument.
297 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
298 by the current locale if C<use locale> is in effect. See L<perllocale>.
302 Binary "&" returns its operators ANDed together bit by bit.
303 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
305 =head2 Bitwise Or and Exclusive Or
307 Binary "|" returns its operators ORed together bit by bit.
308 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
310 Binary "^" returns its operators XORed together bit by bit.
311 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
313 =head2 C-style Logical And
315 Binary "&&" performs a short-circuit logical AND operation. That is,
316 if the left operand is false, the right operand is not even evaluated.
317 Scalar or list context propagates down to the right operand if it
320 =head2 C-style Logical Or
322 Binary "||" performs a short-circuit logical OR operation. That is,
323 if the left operand is true, the right operand is not even evaluated.
324 Scalar or list context propagates down to the right operand if it
327 The C<||> and C<&&> operators differ from C's in that, rather than returning
328 0 or 1, they return the last value evaluated. Thus, a reasonably portable
329 way to find out the home directory (assuming it's not "0") might be:
331 $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
332 (getpwuid($<))[7] || die "You're homeless!\n";
334 As more readable alternatives to C<&&> and C<||>, Perl provides "and" and
335 "or" operators (see below). The short-circuit behavior is identical. The
336 precedence of "and" and "or" is much lower, however, so that you can
337 safely use them after a list operator without the need for
340 unlink "alpha", "beta", "gamma"
341 or gripe(), next LINE;
343 With the C-style operators that would have been written like this:
345 unlink("alpha", "beta", "gamma")
346 || (gripe(), next LINE);
348 =head2 Range Operator
350 Binary ".." is the range operator, which is really two different
351 operators depending on the context. In a list context, it returns an
352 array of values counting (by ones) from the left value to the right
353 value. This is useful for writing C<for (1..10)> loops and for doing
354 slice operations on arrays. Be aware that under the current implementation,
355 a temporary array is created, so you'll burn a lot of memory if you
356 write something like this:
358 for (1 .. 1_000_000) {
362 In a scalar context, ".." returns a boolean value. The operator is
363 bistable, like a flip-flop, and emulates the line-range (comma) operator
364 of B<sed>, B<awk>, and various editors. Each ".." operator maintains its
365 own boolean state. It is false as long as its left operand is false.
366 Once the left operand is true, the range operator stays true until the
367 right operand is true, I<AFTER> which the range operator becomes false
368 again. (It doesn't become false till the next time the range operator is
369 evaluated. It can test the right operand and become false on the same
370 evaluation it became true (as in B<awk>), but it still returns true once.
371 If you don't want it to test the right operand till the next evaluation
372 (as in B<sed>), use three dots ("...") instead of two.) The right
373 operand is not evaluated while the operator is in the "false" state, and
374 the left operand is not evaluated while the operator is in the "true"
375 state. The precedence is a little lower than || and &&. The value
376 returned is either the null string for false, or a sequence number
377 (beginning with 1) for true. The sequence number is reset for each range
378 encountered. The final sequence number in a range has the string "E0"
379 appended to it, which doesn't affect its numeric value, but gives you
380 something to search for if you want to exclude the endpoint. You can
381 exclude the beginning point by waiting for the sequence number to be
382 greater than 1. If either operand of scalar ".." is a numeric literal,
383 that operand is implicitly compared to the C<$.> variable, the current
384 line number. Examples:
386 As a scalar operator:
388 if (101 .. 200) { print; } # print 2nd hundred lines
389 next line if (1 .. /^$/); # skip header lines
390 s/^/> / if (/^$/ .. eof()); # quote body
394 for (101 .. 200) { print; } # print $_ 100 times
395 @foo = @foo[0 .. $#foo]; # an expensive no-op
396 @foo = @foo[$#foo-4 .. $#foo]; # slice last 5 items
398 The range operator (in a list context) makes use of the magical
399 auto-increment algorithm if the operands are strings. You
402 @alphabet = ('A' .. 'Z');
404 to get all the letters of the alphabet, or
406 $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
408 to get a hexadecimal digit, or
410 @z2 = ('01' .. '31'); print $z2[$mday];
412 to get dates with leading zeros. If the final value specified is not
413 in the sequence that the magical increment would produce, the sequence
414 goes until the next value would be longer than the final value
417 =head2 Conditional Operator
419 Ternary "?:" is the conditional operator, just as in C. It works much
420 like an if-then-else. If the argument before the ? is true, the
421 argument before the : is returned, otherwise the argument after the :
422 is returned. For example:
424 printf "I have %d dog%s.\n", $n,
425 ($n == 1) ? '' : "s";
427 Scalar or list context propagates downward into the 2nd
428 or 3rd argument, whichever is selected.
430 $a = $ok ? $b : $c; # get a scalar
431 @a = $ok ? @b : @c; # get an array
432 $a = $ok ? @b : @c; # oops, that's just a count!
434 The operator may be assigned to if both the 2nd and 3rd arguments are
435 legal lvalues (meaning that you can assign to them):
437 ($a_or_b ? $a : $b) = $c;
439 This is not necessarily guaranteed to contribute to the readability of your program.
441 =head2 Assignment Operators
443 "=" is the ordinary assignment operator.
445 Assignment operators work as in C. That is,
453 although without duplicating any side effects that dereferencing the lvalue
454 might trigger, such as from tie(). Other assignment operators work similarly.
455 The following are recognized:
462 Note that while these are grouped by family, they all have the precedence
465 Unlike in C, the assignment operator produces a valid lvalue. Modifying
466 an assignment is equivalent to doing the assignment and then modifying
467 the variable that was assigned to. This is useful for modifying
468 a copy of something, like this:
470 ($tmp = $global) =~ tr [A-Z] [a-z];
481 =head2 Comma Operator
483 Binary "," is the comma operator. In a scalar context it evaluates
484 its left argument, throws that value away, then evaluates its right
485 argument and returns that value. This is just like C's comma operator.
487 In a list context, it's just the list argument separator, and inserts
488 both its arguments into the list.
490 The =E<gt> digraph is mostly just a synonym for the comma operator. It's useful for
491 documenting arguments that come in pairs. As of release 5.001, it also forces
492 any word to the left of it to be interpreted as a string.
494 =head2 List Operators (Rightward)
496 On the right side of a list operator, it has very low precedence,
497 such that it controls all comma-separated expressions found there.
498 The only operators with lower precedence are the logical operators
499 "and", "or", and "not", which may be used to evaluate calls to list
500 operators without the need for extra parentheses:
502 open HANDLE, "filename"
503 or die "Can't open: $!\n";
505 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
509 Unary "not" returns the logical negation of the expression to its right.
510 It's the equivalent of "!" except for the very low precedence.
514 Binary "and" returns the logical conjunction of the two surrounding
515 expressions. It's equivalent to && except for the very low
516 precedence. This means that it short-circuits: i.e., the right
517 expression is evaluated only if the left expression is true.
519 =head2 Logical or and Exclusive Or
521 Binary "or" returns the logical disjunction of the two surrounding
522 expressions. It's equivalent to || except for the very low
523 precedence. This means that it short-circuits: i.e., the right
524 expression is evaluated only if the left expression is false.
526 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
527 It cannot short circuit, of course.
529 =head2 C Operators Missing From Perl
531 Here is what C has that Perl doesn't:
537 Address-of operator. (But see the "\" operator for taking a reference.)
541 Dereference-address operator. (Perl's prefix dereferencing
542 operators are typed: $, @, %, and &.)
546 Type casting operator.
550 =head2 Quote and Quote-like Operators
552 While we usually think of quotes as literal values, in Perl they
553 function as operators, providing various kinds of interpolating and
554 pattern matching capabilities. Perl provides customary quote characters
555 for these behaviors, but also provides a way for you to choose your
556 quote character for any of them. In the following table, a C<{}> represents
557 any pair of delimiters you choose. Non-bracketing delimiters use
558 the same character fore and aft, but the 4 sorts of brackets
559 (round, angle, square, curly) will all nest.
561 Customary Generic Meaning Interpolates
566 // m{} Pattern match yes
567 s{}{} Substitution yes
568 tr{}{} Transliteration no (but see below)
570 Note that there can be whitespace between the operator and the quoting
571 characters, except when C<#> is being used as the quoting character.
572 C<q#foo#> is parsed as being the string C<foo>, while C<q #foo#> is the
573 operator C<q> followed by a comment. Its argument will be taken from the
574 next line. This allows you to write:
576 s {foo} # Replace foo
579 For constructs that do interpolation, variables beginning with "C<$>"
580 or "C<@>" are interpolated, as are the following sequences. Within
581 a transliteration, the first ten of these sequences may be used.
588 \a alarm (bell) (BEL)
594 \l lowercase next char
595 \u uppercase next char
598 \E end case modification
599 \Q quote regexp metacharacters till \E
601 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
602 and C<\U> is taken from the current locale. See L<perllocale>.
604 Patterns are subject to an additional level of interpretation as a
605 regular expression. This is done as a second pass, after variables are
606 interpolated, so that regular expressions may be incorporated into the
607 pattern from the variables. If this is not what you want, use C<\Q> to
608 interpolate a variable literally.
610 Apart from the above, there are no multiple levels of interpolation. In
611 particular, contrary to the expectations of shell programmers, back-quotes
612 do I<NOT> interpolate within double quotes, nor do single quotes impede
613 evaluation of variables when used within double quotes.
615 =head2 Regexp Quote-Like Operators
617 Here are the quote-like operators that apply to pattern
618 matching and related activities.
624 This is just like the C</pattern/> search, except that it matches only
625 once between calls to the reset() operator. This is a useful
626 optimization when you want to see only the first occurrence of
627 something in each file of a set of files, for instance. Only C<??>
628 patterns local to the current package are reset.
630 This usage is vaguely deprecated, and may be removed in some future
633 =item m/PATTERN/cgimosx
635 =item /PATTERN/cgimosx
637 Searches a string for a pattern match, and in a scalar context returns
638 true (1) or false (''). If no string is specified via the C<=~> or
639 C<!~> operator, the $_ string is searched. (The string specified with
640 C<=~> need not be an lvalue--it may be the result of an expression
641 evaluation, but remember the C<=~> binds rather tightly.) See also
643 See L<perllocale> for discussion of additional considerations which apply
644 when C<use locale> is in effect.
648 c Do not reset search position on a failed match when /g is in effect.
649 g Match globally, i.e., find all occurrences.
650 i Do case-insensitive pattern matching.
651 m Treat string as multiple lines.
652 o Compile pattern only once.
653 s Treat string as single line.
654 x Use extended regular expressions.
656 If "/" is the delimiter then the initial C<m> is optional. With the C<m>
657 you can use any pair of non-alphanumeric, non-whitespace characters as
658 delimiters. This is particularly useful for matching Unix path names
659 that contain "/", to avoid LTS (leaning toothpick syndrome). If "?" is
660 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
662 PATTERN may contain variables, which will be interpolated (and the
663 pattern recompiled) every time the pattern search is evaluated. (Note
664 that C<$)> and C<$|> might not be interpolated because they look like
665 end-of-string tests.) If you want such a pattern to be compiled only
666 once, add a C</o> after the trailing delimiter. This avoids expensive
667 run-time recompilations, and is useful when the value you are
668 interpolating won't change over the life of the script. However, mentioning
669 C</o> constitutes a promise that you won't change the variables in the pattern.
670 If you change them, Perl won't even notice.
672 If the PATTERN evaluates to a null string, the last
673 successfully matched regular expression is used instead.
675 If used in a context that requires a list value, a pattern match returns a
676 list consisting of the subexpressions matched by the parentheses in the
677 pattern, i.e., (C<$1>, $2, $3...). (Note that here $1 etc. are also set, and
678 that this differs from Perl 4's behavior.) If the match fails, a null
679 array is returned. If the match succeeds, but there were no parentheses,
680 a list value of (1) is returned.
684 open(TTY, '/dev/tty');
685 <TTY> =~ /^y/i && foo(); # do foo if desired
687 if (/Version: *([0-9.]*)/) { $version = $1; }
689 next if m#^/usr/spool/uucp#;
694 print if /$arg/o; # compile only once
697 if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
699 This last example splits $foo into the first two words and the
700 remainder of the line, and assigns those three fields to $F1, $F2, and
701 $Etc. The conditional is true if any variables were assigned, i.e., if
704 The C</g> modifier specifies global pattern matching--that is, matching
705 as many times as possible within the string. How it behaves depends on
706 the context. In a list context, it returns a list of all the
707 substrings matched by all the parentheses in the regular expression.
708 If there are no parentheses, it returns a list of all the matched
709 strings, as if there were parentheses around the whole pattern.
711 In a scalar context, C<m//g> iterates through the string, returning TRUE
712 each time it matches, and FALSE when it eventually runs out of matches.
713 (In other words, it remembers where it left off last time and restarts
714 the search at that point. You can actually find the current match
715 position of a string or set it using the pos() function; see
716 L<perlfunc/pos>.) A failed match normally resets the search position to
717 the beginning of the string, but you can avoid that by adding the C</c>
718 modifier (e.g. C<m//gc>). Modifying the target string also resets the
721 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
722 zero-width assertion that matches the exact position where the previous
723 C<m//g>, if any, left off. The C<\G> assertion is not supported without
724 the C</g> modifier; currently, without C</g>, C<\G> behaves just like
725 C<\A>, but that's accidental and may change in the future.
730 ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
733 $/ = ""; $* = 1; # $* deprecated in modern perls
734 while (defined($paragraph = <>)) {
735 while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
739 print "$sentences\n";
741 # using m//gc with \G
745 print $1 while /(o)/gc; print "', pos=", pos, "\n";
747 print $1 if /\G(q)/gc; print "', pos=", pos, "\n";
749 print $1 while /(p)/gc; print "', pos=", pos, "\n";
752 The last example should print:
761 A useful idiom for C<lex>-like scanners is C</\G.../gc>. You can
762 combine several regexps like this to process a string part-by-part,
763 doing different actions depending on which regexp matched. Each
764 regexp tries to match where the previous one leaves off.
767 $url = new URI::URL "http://www/"; die if $url eq "xXx";
771 print(" digits"), redo LOOP if /\G\d+\b[,.;]?\s*/gc;
772 print(" lowercase"), redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
773 print(" UPPERCASE"), redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
774 print(" Capitalized"), redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
775 print(" MiXeD"), redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
776 print(" alphanumeric"), redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
777 print(" line-noise"), redo LOOP if /\G[^A-Za-z0-9]+/gc;
778 print ". That's all!\n";
781 Here is the output (split into several lines):
783 line-noise lowercase line-noise lowercase UPPERCASE line-noise
784 UPPERCASE line-noise lowercase line-noise lowercase line-noise
785 lowercase lowercase line-noise lowercase lowercase line-noise
786 MiXeD line-noise. That's all!
792 A single-quoted, literal string. A backslash represents a backslash
793 unless followed by the delimiter or another backslash, in which case
794 the delimiter or backslash is interpolated.
796 $foo = q!I said, "You said, 'She said it.'"!;
797 $bar = q('This is it.');
798 $baz = '\n'; # a two-character string
804 A double-quoted, interpolated string.
807 (*** The previous line contains the naughty word "$1".\n)
808 if /(tcl|rexx|python)/; # :-)
809 $baz = "\n"; # a one-character string
815 A string which is interpolated and then executed as a system command.
816 The collected standard output of the command is returned. In scalar
817 context, it comes back as a single (potentially multi-line) string.
818 In list context, returns a list of lines (however you've defined lines
819 with $/ or $INPUT_RECORD_SEPARATOR).
823 Note that how the string gets evaluated is entirely subject to the
824 command interpreter on your system. On most platforms, you will have
825 to protect shell metacharacters if you want them treated literally.
826 On some platforms (notably DOS-like ones), the shell may not be
827 capable of dealing with multiline commands, so putting newlines in
828 the string may not get you what you want. You may be able to evaluate
829 multiple commands in a single line by separating them with the command
830 separator character, if your shell supports that (e.g. C<;> on many Unix
831 shells; C<&> on the Windows NT C<cmd> shell).
833 Beware that some command shells may place restrictions on the length
834 of the command line. You must ensure your strings don't exceed this
835 limit after any necessary interpolations. See the platform-specific
836 release notes for more details about your particular environment.
838 Also realize that using this operator frequently leads to unportable
841 See L<"I/O Operators"> for more discussion.
845 Returns a list of the words extracted out of STRING, using embedded
846 whitespace as the word delimiters. It is exactly equivalent to
848 split(' ', q/STRING/);
850 Some frequently seen examples:
852 use POSIX qw( setlocale localeconv )
853 @EXPORT = qw( foo bar baz );
855 A common mistake is to try to separate the words with comma or to put
856 comments into a multi-line qw-string. For this reason the C<-w>
857 switch produce warnings if the STRING contains the "," or the "#"
860 =item s/PATTERN/REPLACEMENT/egimosx
862 Searches a string for a pattern, and if found, replaces that pattern
863 with the replacement text and returns the number of substitutions
864 made. Otherwise it returns false (specifically, the empty string).
866 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
867 variable is searched and modified. (The string specified with C<=~> must
868 be a scalar variable, an array element, a hash element, or an assignment
869 to one of those, i.e., an lvalue.)
871 If the delimiter chosen is single quote, no variable interpolation is
872 done on either the PATTERN or the REPLACEMENT. Otherwise, if the
873 PATTERN contains a $ that looks like a variable rather than an
874 end-of-string test, the variable will be interpolated into the pattern
875 at run-time. If you want the pattern compiled only once the first time
876 the variable is interpolated, use the C</o> option. If the pattern
877 evaluates to a null string, the last successfully executed regular
878 expression is used instead. See L<perlre> for further explanation on these.
879 See L<perllocale> for discussion of additional considerations which apply
880 when C<use locale> is in effect.
884 e Evaluate the right side as an expression.
885 g Replace globally, i.e., all occurrences.
886 i Do case-insensitive pattern matching.
887 m Treat string as multiple lines.
888 o Compile pattern only once.
889 s Treat string as single line.
890 x Use extended regular expressions.
892 Any non-alphanumeric, non-whitespace delimiter may replace the
893 slashes. If single quotes are used, no interpretation is done on the
894 replacement string (the C</e> modifier overrides this, however). Unlike
895 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
896 text is not evaluated as a command. If the
897 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
898 pair of quotes, which may or may not be bracketing quotes, e.g.,
899 C<s(foo)(bar)> or C<sE<lt>fooE<gt>/bar/>. A C</e> will cause the
900 replacement portion to be interpreted as a full-fledged Perl expression
901 and eval()ed right then and there. It is, however, syntax checked at
906 s/\bgreen\b/mauve/g; # don't change wintergreen
908 $path =~ s|/usr/bin|/usr/local/bin|;
910 s/Login: $foo/Login: $bar/; # run-time pattern
912 ($foo = $bar) =~ s/this/that/;
914 $count = ($paragraph =~ s/Mister\b/Mr./g);
917 s/\d+/$&*2/e; # yields 'abc246xyz'
918 s/\d+/sprintf("%5d",$&)/e; # yields 'abc 246xyz'
919 s/\w/$& x 2/eg; # yields 'aabbcc 224466xxyyzz'
921 s/%(.)/$percent{$1}/g; # change percent escapes; no /e
922 s/%(.)/$percent{$1} || $&/ge; # expr now, so /e
923 s/^=(\w+)/&pod($1)/ge; # use function call
925 # /e's can even nest; this will expand
926 # simple embedded variables in $_
931 /\* # Match the opening delimiter.
932 .*? # Match a minimal number of characters.
933 \*/ # Match the closing delimiter.
936 s/^\s*(.*?)\s*$/$1/; # trim white space
938 s/([^ ]*) *([^ ]*)/$2 $1/; # reverse 1st two fields
940 Note the use of $ instead of \ in the last example. Unlike
941 B<sed>, we use the \E<lt>I<digit>E<gt> form in only the left hand side.
942 Anywhere else it's $E<lt>I<digit>E<gt>.
944 Occasionally, you can't use just a C</g> to get all the changes
945 to occur. Here are two common cases:
947 # put commas in the right places in an integer
948 1 while s/(.*\d)(\d\d\d)/$1,$2/g; # perl4
949 1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g; # perl5
951 # expand tabs to 8-column spacing
952 1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
955 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
957 =item y/SEARCHLIST/REPLACEMENTLIST/cds
959 Transliterates all occurrences of the characters found in the search list
960 with the corresponding character in the replacement list. It returns
961 the number of characters replaced or deleted. If no string is
962 specified via the =~ or !~ operator, the $_ string is transliterated. (The
963 string specified with =~ must be a scalar variable, an array element, a
964 hash element, or an assignment to one of those, i.e., an lvalue.)
965 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
966 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
967 For B<sed> devotees, C<y> is provided as a synonym for C<tr>. If the
968 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
969 its own pair of quotes, which may or may not be bracketing quotes,
970 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
974 c Complement the SEARCHLIST.
975 d Delete found but unreplaced characters.
976 s Squash duplicate replaced characters.
978 If the C</c> modifier is specified, the SEARCHLIST character set is
979 complemented. If the C</d> modifier is specified, any characters specified
980 by SEARCHLIST not found in REPLACEMENTLIST are deleted. (Note
981 that this is slightly more flexible than the behavior of some B<tr>
982 programs, which delete anything they find in the SEARCHLIST, period.)
983 If the C</s> modifier is specified, sequences of characters that were
984 transliterated to the same character are squashed down to a single instance of the
987 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
988 exactly as specified. Otherwise, if the REPLACEMENTLIST is shorter
989 than the SEARCHLIST, the final character is replicated till it is long
990 enough. If the REPLACEMENTLIST is null, the SEARCHLIST is replicated.
991 This latter is useful for counting characters in a class or for
992 squashing character sequences in a class.
996 $ARGV[1] =~ tr/A-Z/a-z/; # canonicalize to lower case
998 $cnt = tr/*/*/; # count the stars in $_
1000 $cnt = $sky =~ tr/*/*/; # count the stars in $sky
1002 $cnt = tr/0-9//; # count the digits in $_
1004 tr/a-zA-Z//s; # bookkeeper -> bokeper
1006 ($HOST = $host) =~ tr/a-z/A-Z/;
1008 tr/a-zA-Z/ /cs; # change non-alphas to single space
1011 [\000-\177]; # delete 8th bit
1013 If multiple transliterations are given for a character, only the first one is used:
1017 will transliterate any A to X.
1019 Note that because the transliteration table is built at compile time, neither
1020 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1021 interpolation. That means that if you want to use variables, you must use
1024 eval "tr/$oldlist/$newlist/";
1027 eval "tr/$oldlist/$newlist/, 1" or die $@;
1031 =head2 I/O Operators
1033 There are several I/O operators you should know about.
1034 A string enclosed by backticks (grave accents) first undergoes
1035 variable substitution just like a double quoted string. It is then
1036 interpreted as a command, and the output of that command is the value
1037 of the pseudo-literal, like in a shell. In a scalar context, a single
1038 string consisting of all the output is returned. In a list context,
1039 a list of values is returned, one for each line of output. (You can
1040 set C<$/> to use a different line terminator.) The command is executed
1041 each time the pseudo-literal is evaluated. The status value of the
1042 command is returned in C<$?> (see L<perlvar> for the interpretation
1043 of C<$?>). Unlike in B<csh>, no translation is done on the return
1044 data--newlines remain newlines. Unlike in any of the shells, single
1045 quotes do not hide variable names in the command from interpretation.
1046 To pass a $ through to the shell you need to hide it with a backslash.
1047 The generalized form of backticks is C<qx//>. (Because backticks
1048 always undergo shell expansion as well, see L<perlsec> for
1051 Evaluating a filehandle in angle brackets yields the next line from
1052 that file (newline, if any, included), or C<undef> at end of file.
1053 Ordinarily you must assign that value to a variable, but there is one
1054 situation where an automatic assignment happens. I<If and ONLY if> the
1055 input symbol is the only thing inside the conditional of a C<while> or
1056 C<for(;;)> loop, the value is automatically assigned to the variable
1057 C<$_>. In these loop constructs, the assigned value (whether assignment
1058 is automatic or explcit) is then tested to see if it is defined.
1059 The defined test avoids problems where line has a string value
1060 that would be treated as false by perl e.g. "" or "0" with no trailing
1061 newline. (This may seem like an odd thing to you, but you'll use the
1062 construct in almost every Perl script you write.) Anyway, the following
1063 lines are equivalent to each other:
1065 while (defined($_ = <STDIN>)) { print; }
1066 while ($_ = <STDIN>) { print; }
1067 while (<STDIN>) { print; }
1068 for (;<STDIN>;) { print; }
1069 print while defined($_ = <STDIN>);
1070 print while ($_ = <STDIN>);
1071 print while <STDIN>;
1073 and this also behaves similarly, but avoids the use of $_ :
1075 while (my $line = <STDIN>) { print $line }
1077 If you really mean such values to terminate the loop they should be
1078 tested for explcitly:
1080 while (($_ = <STDIN>) ne '0') { ... }
1081 while (<STDIN>) { last unless $_; ... }
1083 In other boolean contexts C<E<lt>I<filehandle>E<gt>> without explcit C<defined>
1084 test or comparison will solicit a warning if C<-w> is in effect.
1086 The filehandles STDIN, STDOUT, and STDERR are predefined. (The
1087 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except in
1088 packages, where they would be interpreted as local identifiers rather
1089 than global.) Additional filehandles may be created with the open()
1090 function. See L<perlfunc/open()> for details on this.
1092 If a E<lt>FILEHANDLEE<gt> is used in a context that is looking for a list, a
1093 list consisting of all the input lines is returned, one line per list
1094 element. It's easy to make a I<LARGE> data space this way, so use with
1097 The null filehandle E<lt>E<gt> is special and can be used to emulate the
1098 behavior of B<sed> and B<awk>. Input from E<lt>E<gt> comes either from
1099 standard input, or from each file listed on the command line. Here's
1100 how it works: the first time E<lt>E<gt> is evaluated, the @ARGV array is
1101 checked, and if it is null, C<$ARGV[0]> is set to "-", which when opened
1102 gives you standard input. The @ARGV array is then processed as a list
1103 of filenames. The loop
1106 ... # code for each line
1109 is equivalent to the following Perl-like pseudo code:
1111 unshift(@ARGV, '-') unless @ARGV;
1112 while ($ARGV = shift) {
1115 ... # code for each line
1119 except that it isn't so cumbersome to say, and will actually work. It
1120 really does shift array @ARGV and put the current filename into variable
1121 $ARGV. It also uses filehandle I<ARGV> internally--E<lt>E<gt> is just a
1122 synonym for E<lt>ARGVE<gt>, which is magical. (The pseudo code above
1123 doesn't work because it treats E<lt>ARGVE<gt> as non-magical.)
1125 You can modify @ARGV before the first E<lt>E<gt> as long as the array ends up
1126 containing the list of filenames you really want. Line numbers (C<$.>)
1127 continue as if the input were one big happy file. (But see example
1128 under eof() for how to reset line numbers on each file.)
1130 If you want to set @ARGV to your own list of files, go right ahead. If
1131 you want to pass switches into your script, you can use one of the
1132 Getopts modules or put a loop on the front like this:
1134 while ($_ = $ARGV[0], /^-/) {
1137 if (/^-D(.*)/) { $debug = $1 }
1138 if (/^-v/) { $verbose++ }
1139 ... # other switches
1142 ... # code for each line
1145 The E<lt>E<gt> symbol will return C<undef> for end-of-file only once.
1146 If you call it again after this it will assume you are processing another
1147 @ARGV list, and if you haven't set @ARGV, will input from STDIN.
1149 If the string inside the angle brackets is a reference to a scalar
1150 variable (e.g., E<lt>$fooE<gt>), then that variable contains the name of the
1151 filehandle to input from, or a reference to the same. For example:
1156 If the string inside angle brackets is not a filehandle or a scalar
1157 variable containing a filehandle name or reference, then it is interpreted
1158 as a filename pattern to be globbed, and either a list of filenames or the
1159 next filename in the list is returned, depending on context. One level of
1160 $ interpretation is done first, but you can't say C<E<lt>$fooE<gt>>
1161 because that's an indirect filehandle as explained in the previous
1162 paragraph. (In older versions of Perl, programmers would insert curly
1163 brackets to force interpretation as a filename glob: C<E<lt>${foo}E<gt>>.
1164 These days, it's considered cleaner to call the internal function directly
1165 as C<glob($foo)>, which is probably the right way to have done it in the
1166 first place.) Example:
1174 open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1180 In fact, it's currently implemented that way. (Which means it will not
1181 work on filenames with spaces in them unless you have csh(1) on your
1182 machine.) Of course, the shortest way to do the above is:
1186 Because globbing invokes a shell, it's often faster to call readdir() yourself
1187 and do your own grep() on the filenames. Furthermore, due to its current
1188 implementation of using a shell, the glob() routine may get "Arg list too
1189 long" errors (unless you've installed tcsh(1L) as F</bin/csh>).
1191 A glob evaluates its (embedded) argument only when it is starting a new
1192 list. All values must be read before it will start over. In a list
1193 context this isn't important, because you automatically get them all
1194 anyway. In a scalar context, however, the operator returns the next value
1195 each time it is called, or a C<undef> value if you've just run out. As
1196 for filehandles an automatic C<defined> is generated when the glob
1197 occurs in the test part of a C<while> or C<for> - because legal glob returns
1198 (e.g. a file called F<0>) would otherwise terminate the loop.
1199 Again, C<undef> is returned only once. So if you're expecting a single value
1200 from a glob, it is much better to say
1202 ($file) = <blurch*>;
1208 because the latter will alternate between returning a filename and
1211 It you're trying to do variable interpolation, it's definitely better
1212 to use the glob() function, because the older notation can cause people
1213 to become confused with the indirect filehandle notation.
1215 @files = glob("$dir/*.[ch]");
1216 @files = glob($files[$i]);
1218 =head2 Constant Folding
1220 Like C, Perl does a certain amount of expression evaluation at
1221 compile time, whenever it determines that all of the arguments to an
1222 operator are static and have no side effects. In particular, string
1223 concatenation happens at compile time between literals that don't do
1224 variable substitution. Backslash interpretation also happens at
1225 compile time. You can say
1227 'Now is the time for all' . "\n" .
1228 'good men to come to.'
1230 and this all reduces to one string internally. Likewise, if
1233 foreach $file (@filenames) {
1234 if (-s $file > 5 + 100 * 2**16) { ... }
1237 the compiler will precompute the number that
1238 expression represents so that the interpreter
1241 =head2 Bitwise String Operators
1243 Bitstrings of any size may be manipulated by the bitwise operators
1246 If the operands to a binary bitwise op are strings of different sizes,
1247 B<or> and B<xor> ops will act as if the shorter operand had additional
1248 zero bits on the right, while the B<and> op will act as if the longer
1249 operand were truncated to the length of the shorter.
1251 # ASCII-based examples
1252 print "j p \n" ^ " a h"; # prints "JAPH\n"
1253 print "JA" | " ph\n"; # prints "japh\n"
1254 print "japh\nJunk" & '_____'; # prints "JAPH\n";
1255 print 'p N$' ^ " E<H\n"; # prints "Perl\n";
1257 If you are intending to manipulate bitstrings, you should be certain that
1258 you're supplying bitstrings: If an operand is a number, that will imply
1259 a B<numeric> bitwise operation. You may explicitly show which type of
1260 operation you intend by using C<""> or C<0+>, as in the examples below.
1262 $foo = 150 | 105 ; # yields 255 (0x96 | 0x69 is 0xFF)
1263 $foo = '150' | 105 ; # yields 255
1264 $foo = 150 | '105'; # yields 255
1265 $foo = '150' | '105'; # yields string '155' (under ASCII)
1267 $baz = 0+$foo & 0+$bar; # both ops explicitly numeric
1268 $biz = "$foo" ^ "$bar"; # both ops explicitly stringy
1270 =head2 Integer Arithmetic
1272 By default Perl assumes that it must do most of its arithmetic in
1273 floating point. But by saying
1277 you may tell the compiler that it's okay to use integer operations
1278 from here to the end of the enclosing BLOCK. An inner BLOCK may
1279 countermand this by saying
1283 which lasts until the end of that BLOCK.
1285 The bitwise operators ("&", "|", "^", "~", "<<", and ">>") always
1286 produce integral results. (But see also L<Bitwise String Operators>.)
1287 However, C<use integer> still has meaning
1288 for them. By default, their results are interpreted as unsigned
1289 integers. However, if C<use integer> is in effect, their results are
1290 interpreted as signed integers. For example, C<~0> usually evaluates
1291 to a large integral value. However, C<use integer; ~0> is -1.
1293 =head2 Floating-point Arithmetic
1295 While C<use integer> provides integer-only arithmetic, there is no
1296 similar ways to provide rounding or truncation at a certain number of
1297 decimal places. For rounding to a certain number of digits, sprintf()
1298 or printf() is usually the easiest route.
1300 The POSIX module (part of the standard perl distribution) implements
1301 ceil(), floor(), and a number of other mathematical and trigonometric
1302 functions. The Math::Complex module (part of the standard perl
1303 distribution) defines a number of mathematical functions that can also
1304 work on real numbers. Math::Complex not as efficient as POSIX, but
1305 POSIX can't work with complex numbers.
1307 Rounding in financial applications can have serious implications, and
1308 the rounding method used should be specified precisely. In these
1309 cases, it probably pays not to trust whichever system rounding is
1310 being used by Perl, but to instead implement the rounding function you