Fix unnecessary re-linking
[p5sagit/p5-mst-13.2.git] / pod / perlipc.pod
1 =head1 NAME
2
3 perlipc - Perl interprocess communication (signals, fifos, pipes, safe subprocesses, sockets, and semaphores)
4
5 =head1 DESCRIPTION
6
7 The basic IPC facilities of Perl are built out of the good old Unix
8 signals, named pipes, pipe opens, the Berkeley socket routines, and SysV
9 IPC calls.  Each is used in slightly different situations.
10
11 =head1 Signals
12
13 Perl uses a simple signal handling model: the %SIG hash contains names or
14 references of user-installed signal handlers.  These handlers will be called
15 with an argument which is the name of the signal that triggered it.  A
16 signal may be generated intentionally from a particular keyboard sequence like
17 control-C or control-Z, sent to you from another process, or
18 triggered automatically by the kernel when special events transpire, like
19 a child process exiting, your process running out of stack space, or
20 hitting file size limit.
21
22 For example, to trap an interrupt signal, set up a handler like this.
23 Notice how all we do is set a global variable and then raise an
24 exception.  That's because on most systems libraries are not
25 reentrant, so calling any print() functions (or even anything that needs to
26 malloc(3) more memory) could in theory trigger a memory fault
27 and subsequent core dump.
28
29     sub catch_zap {
30         my $signame = shift;
31         $shucks++;
32         die "Somebody sent me a SIG$signame";
33     }
34     $SIG{INT} = 'catch_zap';  # could fail in modules
35     $SIG{INT} = \&catch_zap;  # best strategy
36
37 The names of the signals are the ones listed out by C<kill -l> on your
38 system, or you can retrieve them from the Config module.  Set up an
39 @signame list indexed by number to get the name and a %signo table
40 indexed by name to get the number:
41
42     use Config;
43     defined $Config{sig_name} || die "No sigs?";
44     foreach $name (split(' ', $Config{sig_name})) {
45         $signo{$name} = $i;
46         $signame[$i] = $name;
47         $i++;
48     }
49
50 So to check whether signal 17 and SIGALRM were the same, do just this:
51
52     print "signal #17 = $signame[17]\n";
53     if ($signo{ALRM}) {
54         print "SIGALRM is $signo{ALRM}\n";
55     }
56
57 You may also choose to assign the strings C<'IGNORE'> or C<'DEFAULT'> as
58 the handler, in which case Perl will try to discard the signal or do the
59 default thing.  Some signals can be neither trapped nor ignored, such as
60 the KILL and STOP (but not the TSTP) signals.  One strategy for
61 temporarily ignoring signals is to use a local() statement, which will be
62 automatically restored once your block is exited.  (Remember that local()
63 values are "inherited" by functions called from within that block.)
64
65     sub precious {
66         local $SIG{INT} = 'IGNORE';
67         &more_functions;
68     }
69     sub more_functions {
70         # interrupts still ignored, for now...
71     }
72
73 Sending a signal to a negative process ID means that you send the signal
74 to the entire Unix process-group.  This code send a hang-up signal to all
75 processes in the current process group I<except for> the current process
76 itself:
77
78     {
79         local $SIG{HUP} = 'IGNORE';
80         kill HUP => -$$;
81         # snazzy writing of: kill('HUP', -$$)
82     }
83
84 Another interesting signal to send is signal number zero.  This doesn't
85 actually affect another process, but instead checks whether it's alive
86 or has changed its UID.
87
88     unless (kill 0 => $kid_pid) {
89         warn "something wicked happened to $kid_pid";
90     }
91
92 You might also want to employ anonymous functions for simple signal
93 handlers:
94
95     $SIG{INT} = sub { die "\nOutta here!\n" };
96
97 But that will be problematic for the more complicated handlers that need
98 to reinstall themselves.  Because Perl's signal mechanism is currently
99 based on the signal(3) function from the C library, you may sometimes be so
100 misfortunate as to run on systems where that function is "broken", that
101 is, it behaves in the old unreliable SysV way rather than the newer, more
102 reasonable BSD and POSIX fashion.  So you'll see defensive people writing
103 signal handlers like this:
104
105     sub REAPER {
106         $waitedpid = wait;
107         # loathe sysV: it makes us not only reinstate
108         # the handler, but place it after the wait
109         $SIG{CHLD} = \&REAPER;
110     }
111     $SIG{CHLD} = \&REAPER;
112     # now do something that forks...
113
114 or even the more elaborate:
115
116     use POSIX ":sys_wait_h";
117     sub REAPER {
118         my $child;
119         while ($child = waitpid(-1,WNOHANG)) {
120             $Kid_Status{$child} = $?;
121         }
122         $SIG{CHLD} = \&REAPER;  # still loathe sysV
123     }
124     $SIG{CHLD} = \&REAPER;
125     # do something that forks...
126
127 Signal handling is also used for timeouts in Unix,   While safely
128 protected within an C<eval{}> block, you set a signal handler to trap
129 alarm signals and then schedule to have one delivered to you in some
130 number of seconds.  Then try your blocking operation, clearing the alarm
131 when it's done but not before you've exited your C<eval{}> block.  If it
132 goes off, you'll use die() to jump out of the block, much as you might
133 using longjmp() or throw() in other languages.
134
135 Here's an example:
136
137     eval {
138         local $SIG{ALRM} = sub { die "alarm clock restart" };
139         alarm 10;
140         flock(FH, 2);   # blocking write lock
141         alarm 0;
142     };
143     if ($@ and $@ !~ /alarm clock restart/) { die }
144
145 For more complex signal handling, you might see the standard POSIX
146 module.  Lamentably, this is almost entirely undocumented, but
147 the F<t/lib/posix.t> file from the Perl source distribution has some
148 examples in it.
149
150 =head1 Named Pipes
151
152 A named pipe (often referred to as a FIFO) is an old Unix IPC
153 mechanism for processes communicating on the same machine.  It works
154 just like a regular, connected anonymous pipes, except that the
155 processes rendezvous using a filename and don't have to be related.
156
157 To create a named pipe, use the Unix command mknod(1) or on some
158 systems, mkfifo(1).  These may not be in your normal path.
159
160     # system return val is backwards, so && not ||
161     #
162     $ENV{PATH} .= ":/etc:/usr/etc";
163     if  (      system('mknod',  $path, 'p')
164             && system('mkfifo', $path) )
165     {
166         die "mk{nod,fifo} $path failed;
167     }
168
169
170 A fifo is convenient when you want to connect a process to an unrelated
171 one.  When you open a fifo, the program will block until there's something
172 on the other end.
173
174 For example, let's say you'd like to have your F<.signature> file be a
175 named pipe that has a Perl program on the other end.  Now every time any
176 program (like a mailer, news reader, finger program, etc.) tries to read
177 from that file, the reading program will block and your program will
178 supply the new signature.  We'll use the pipe-checking file test B<-p>
179 to find out whether anyone (or anything) has accidentally removed our fifo.
180
181     chdir; # go home
182     $FIFO = '.signature';
183     $ENV{PATH} .= ":/etc:/usr/games";
184
185     while (1) {
186         unless (-p $FIFO) {
187             unlink $FIFO;
188             system('mknod', $FIFO, 'p')
189                 && die "can't mknod $FIFO: $!";
190         }
191
192         # next line blocks until there's a reader
193         open (FIFO, "> $FIFO") || die "can't write $FIFO: $!";
194         print FIFO "John Smith (smith\@host.org)\n", `fortune -s`;
195         close FIFO;
196         sleep 2;    # to avoid dup signals
197     }
198
199
200 =head1 Using open() for IPC
201
202 Perl's basic open() statement can also be used for unidirectional interprocess
203 communication by either appending or prepending a pipe symbol to the second
204 argument to open().  Here's how to start something up in a child process you
205 intend to write to:
206
207     open(SPOOLER, "| cat -v | lpr -h 2>/dev/null")
208                     || die "can't fork: $!";
209     local $SIG{PIPE} = sub { die "spooler pipe broke" };
210     print SPOOLER "stuff\n";
211     close SPOOLER || die "bad spool: $! $?";
212
213 And here's how to start up a child process you intend to read from:
214
215     open(STATUS, "netstat -an 2>&1 |")
216                     || die "can't fork: $!";
217     while (<STATUS>) {
218         next if /^(tcp|udp)/;
219         print;
220     }
221     close STATUS || die "bad netstat: $! $?";
222
223 If one can be sure that a particular program is a Perl script that is
224 expecting filenames in @ARGV, the clever programmer can write something
225 like this:
226
227     $ program f1 "cmd1|" - f2 "cmd2|" f3 < tmpfile
228
229 and irrespective of which shell it's called from, the Perl program will
230 read from the file F<f1>, the process F<cmd1>, standard input (F<tmpfile>
231 in this case), the F<f2> file, the F<cmd2> command, and finally the F<f3>
232 file.  Pretty nifty, eh?
233
234 You might notice that you could use backticks for much the
235 same effect as opening a pipe for reading:
236
237     print grep { !/^(tcp|udp)/ } `netstat -an 2>&1`;
238     die "bad netstat" if $?;
239
240 While this is true on the surface, it's much more efficient to process the
241 file one line or record at a time because then you don't have to read the
242 whole thing into memory at once. It also gives you finer control of the
243 whole process, letting you to kill off the child process early if you'd
244 like.
245
246 Be careful to check both the open() and the close() return values.  If
247 you're I<writing> to a pipe, you should also trap SIGPIPE.  Otherwise,
248 think of what happens when you start up a pipe to a command that doesn't
249 exist: the open() will in all likelihood succeed (it only reflects the
250 fork()'s success), but then your output will fail--spectacularly.  Perl
251 can't know whether the command worked because your command is actually
252 running in a separate process whose exec() might have failed.  Therefore,
253 while readers of bogus commands return just a quick end of file, writers
254 to bogus command will trigger a signal they'd better be prepared to
255 handle.  Consider:
256
257     open(FH, "|bogus");
258     print FH "bang\n";
259     close FH;
260
261 =head2 Filehandles
262
263 Both the main process and the child process share the same STDIN,
264 STDOUT and STDERR filehandles.  If both processes try to access them
265 at once, strange things can happen.  You may want to close or reopen
266 the filehandles for the child.  You can get around this by opening
267 your pipe with open(), but on some systems this means that the child
268 process cannot outlive the parent.
269
270 =head2 Background Processes
271
272 You can run a command in the background with:
273
274     system("cmd&");
275
276 The command's STDOUT and STDERR (and possibly STDIN, depending on your
277 shell) will be the same as the parent's.  You won't need to catch
278 SIGCHLD because of the double-fork taking place (see below for more
279 details).
280
281 =head2 Complete Dissociation of Child from Parent
282
283 In some cases (starting server processes, for instance) you'll want to
284 complete dissociate the child process from the parent.  The following
285 process is reported to work on most Unixish systems.  Non-Unix users
286 should check their Your_OS::Process module for other solutions.
287
288 =over 4
289
290 =item *
291
292 Open /dev/tty and use the TIOCNOTTY ioctl on it.  See L<tty(4)>
293 for details.
294
295 =item *
296
297 Change directory to /
298
299 =item *
300
301 Reopen STDIN, STDOUT, and STDERR so they're not connected to the old
302 tty.
303
304 =item *
305
306 Background yourself like this:
307
308     fork && exit;
309
310 =back
311
312 =head2 Safe Pipe Opens
313
314 Another interesting approach to IPC is making your single program go
315 multiprocess and communicate between (or even amongst) yourselves.  The
316 open() function will accept a file argument of either C<"-|"> or C<"|-">
317 to do a very interesting thing: it forks a child connected to the
318 filehandle you've opened.  The child is running the same program as the
319 parent.  This is useful for safely opening a file when running under an
320 assumed UID or GID, for example.  If you open a pipe I<to> minus, you can
321 write to the filehandle you opened and your kid will find it in his
322 STDIN.  If you open a pipe I<from> minus, you can read from the filehandle
323 you opened whatever your kid writes to his STDOUT.
324
325     use English;
326     my $sleep_count = 0;
327
328     do {
329         $pid = open(KID_TO_WRITE, "|-");
330         unless (defined $pid) {
331             warn "cannot fork: $!";
332             die "bailing out" if $sleep_count++ > 6;
333             sleep 10;
334         }
335     } until defined $pid;
336
337     if ($pid) {  # parent
338         print KID_TO_WRITE @some_data;
339         close(KID_TO_WRITE) || warn "kid exited $?";
340     } else {     # child
341         ($EUID, $EGID) = ($UID, $GID); # suid progs only
342         open (FILE, "> /safe/file")
343             || die "can't open /safe/file: $!";
344         while (<STDIN>) {
345             print FILE; # child's STDIN is parent's KID
346         }
347         exit;  # don't forget this
348     }
349
350 Another common use for this construct is when you need to execute
351 something without the shell's interference.  With system(), it's
352 straightforward, but you can't use a pipe open or backticks safely.
353 That's because there's no way to stop the shell from getting its hands on
354 your arguments.   Instead, use lower-level control to call exec() directly.
355
356 Here's a safe backtick or pipe open for read:
357
358     # add error processing as above
359     $pid = open(KID_TO_READ, "-|");
360
361     if ($pid) {   # parent
362         while (<KID_TO_READ>) {
363             # do something interesting
364         }
365         close(KID_TO_READ) || warn "kid exited $?";
366
367     } else {      # child
368         ($EUID, $EGID) = ($UID, $GID); # suid only
369         exec($program, @options, @args)
370             || die "can't exec program: $!";
371         # NOTREACHED
372     }
373
374
375 And here's a safe pipe open for writing:
376
377     # add error processing as above
378     $pid = open(KID_TO_WRITE, "|-");
379     $SIG{ALRM} = sub { die "whoops, $program pipe broke" };
380
381     if ($pid) {  # parent
382         for (@data) {
383             print KID_TO_WRITE;
384         }
385         close(KID_TO_WRITE) || warn "kid exited $?";
386
387     } else {     # child
388         ($EUID, $EGID) = ($UID, $GID);
389         exec($program, @options, @args)
390             || die "can't exec program: $!";
391         # NOTREACHED
392     }
393
394 Note that these operations are full Unix forks, which means they may not be
395 correctly implemented on alien systems.  Additionally, these are not true
396 multithreading.  If you'd like to learn more about threading, see the
397 F<modules> file mentioned below in the SEE ALSO section.
398
399 =head2 Bidirectional Communication
400
401 While this works reasonably well for unidirectional communication, what
402 about bidirectional communication?  The obvious thing you'd like to do
403 doesn't actually work:
404
405     open(PROG_FOR_READING_AND_WRITING, "| some program |")
406
407 and if you forget to use the B<-w> flag, then you'll miss out
408 entirely on the diagnostic message:
409
410     Can't do bidirectional pipe at -e line 1.
411
412 If you really want to, you can use the standard open2() library function
413 to catch both ends.  There's also an open3() for tri-directional I/O so you
414 can also catch your child's STDERR, but doing so would then require an
415 awkward select() loop and wouldn't allow you to use normal Perl input
416 operations.
417
418 If you look at its source, you'll see that open2() uses low-level
419 primitives like Unix pipe() and exec() to create all the connections.
420 While it might have been slightly more efficient by using socketpair(), it
421 would have then been even less portable than it already is.  The open2()
422 and open3() functions are  unlikely to work anywhere except on a Unix
423 system or some other one purporting to be POSIX compliant.
424
425 Here's an example of using open2():
426
427     use FileHandle;
428     use IPC::Open2;
429     $pid = open2( \*Reader, \*Writer, "cat -u -n" );
430     Writer->autoflush(); # default here, actually
431     print Writer "stuff\n";
432     $got = <Reader>;
433
434 The problem with this is that Unix buffering is really going to
435 ruin your day.  Even though your C<Writer> filehandle is auto-flushed,
436 and the process on the other end will get your data in a timely manner,
437 you can't usually do anything to force it to give it back to you
438 in a similarly quick fashion.  In this case, we could, because we
439 gave I<cat> a B<-u> flag to make it unbuffered.  But very few Unix
440 commands are designed to operate over pipes, so this seldom works
441 unless you yourself wrote the program on the other end of the
442 double-ended pipe.
443
444 A solution to this is the nonstandard F<Comm.pl> library.  It uses
445 pseudo-ttys to make your program behave more reasonably:
446
447     require 'Comm.pl';
448     $ph = open_proc('cat -n');
449     for (1..10) {
450         print $ph "a line\n";
451         print "got back ", scalar <$ph>;
452     }
453
454 This way you don't have to have control over the source code of the
455 program you're using.  The F<Comm> library also has expect()
456 and interact() functions.  Find the library (and we hope its
457 successor F<IPC::Chat>) at your nearest CPAN archive as detailed
458 in the SEE ALSO section below.
459
460 =head1 Sockets: Client/Server Communication
461
462 While not limited to Unix-derived operating systems (e.g., WinSock on PCs
463 provides socket support, as do some VMS libraries), you may not have
464 sockets on your system, in which case this section probably isn't going to do
465 you much good.  With sockets, you can do both virtual circuits (i.e., TCP
466 streams) and datagrams (i.e., UDP packets).  You may be able to do even more
467 depending on your system.
468
469 The Perl function calls for dealing with sockets have the same names as
470 the corresponding system calls in C, but their arguments tend to differ
471 for two reasons: first, Perl filehandles work differently than C file
472 descriptors.  Second, Perl already knows the length of its strings, so you
473 don't need to pass that information.
474
475 One of the major problems with old socket code in Perl was that it used
476 hard-coded values for some of the constants, which severely hurt
477 portability.  If you ever see code that does anything like explicitly
478 setting C<$AF_INET = 2>, you know you're in for big trouble:  An
479 immeasurably superior approach is to use the C<Socket> module, which more
480 reliably grants access to various constants and functions you'll need.
481
482 If you're not writing a server/client for an existing protocol like
483 NNTP or SMTP, you should give some thought to how your server will
484 know when the client has finished talking, and vice-versa.  Most
485 protocols are based on one-line messages and responses (so one party
486 knows the other has finished when a "\n" is received) or multi-line
487 messages and responses that end with a period on an empty line
488 ("\n.\n" terminates a message/response).
489
490 =head2 Internet TCP Clients and Servers
491
492 Use Internet-domain sockets when you want to do client-server
493 communication that might extend to machines outside of your own system.
494
495 Here's a sample TCP client using Internet-domain sockets:
496
497     #!/usr/bin/perl -w
498     require 5.002;
499     use strict;
500     use Socket;
501     my ($remote,$port, $iaddr, $paddr, $proto, $line);
502
503     $remote  = shift || 'localhost';
504     $port    = shift || 2345;  # random port
505     if ($port =~ /\D/) { $port = getservbyname($port, 'tcp') }
506     die "No port" unless $port;
507     $iaddr   = inet_aton($remote)               || die "no host: $remote";
508     $paddr   = sockaddr_in($port, $iaddr);
509
510     $proto   = getprotobyname('tcp');
511     socket(SOCK, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
512     connect(SOCK, $paddr)    || die "connect: $!";
513     while (defined($line = <SOCK>)) {
514         print $line;
515     }
516
517     close (SOCK)            || die "close: $!";
518     exit;
519
520 And here's a corresponding server to go along with it.  We'll
521 leave the address as INADDR_ANY so that the kernel can choose
522 the appropriate interface on multihomed hosts.  If you want sit
523 on a particular interface (like the external side of a gateway
524 or firewall machine), you should fill this in with your real address
525 instead.
526
527     #!/usr/bin/perl -Tw
528     require 5.002;
529     use strict;
530     BEGIN { $ENV{PATH} = '/usr/ucb:/bin' }
531     use Socket;
532     use Carp;
533
534     sub logmsg { print "$0 $$: @_ at ", scalar localtime, "\n" }
535
536     my $port = shift || 2345;
537     my $proto = getprotobyname('tcp');
538     $port = $1 if $port =~ /(\d+)/; # untaint port number
539
540     socket(Server, PF_INET, SOCK_STREAM, $proto)        || die "socket: $!";
541     setsockopt(Server, SOL_SOCKET, SO_REUSEADDR,
542                                         pack("l", 1))   || die "setsockopt: $!";
543     bind(Server, sockaddr_in($port, INADDR_ANY))        || die "bind: $!";
544     listen(Server,SOMAXCONN)                            || die "listen: $!";
545
546     logmsg "server started on port $port";
547
548     my $paddr;
549
550     $SIG{CHLD} = \&REAPER;
551
552     for ( ; $paddr = accept(Client,Server); close Client) {
553         my($port,$iaddr) = sockaddr_in($paddr);
554         my $name = gethostbyaddr($iaddr,AF_INET);
555
556         logmsg "connection from $name [",
557                 inet_ntoa($iaddr), "]
558                 at port $port";
559
560         print Client "Hello there, $name, it's now ",
561                         scalar localtime, "\n";
562     }
563
564 And here's a multithreaded version.  It's multithreaded in that
565 like most typical servers, it spawns (forks) a slave server to
566 handle the client request so that the master server can quickly
567 go back to service a new client.
568
569     #!/usr/bin/perl -Tw
570     require 5.002;
571     use strict;
572     BEGIN { $ENV{PATH} = '/usr/ucb:/bin' }
573     use Socket;
574     use Carp;
575
576     sub spawn;  # forward declaration
577     sub logmsg { print "$0 $$: @_ at ", scalar localtime, "\n" }
578
579     my $port = shift || 2345;
580     my $proto = getprotobyname('tcp');
581     $port = $1 if $port =~ /(\d+)/; # untaint port number
582
583     socket(Server, PF_INET, SOCK_STREAM, $proto)        || die "socket: $!";
584     setsockopt(Server, SOL_SOCKET, SO_REUSEADDR,
585                                         pack("l", 1))   || die "setsockopt: $!";
586     bind(Server, sockaddr_in($port, INADDR_ANY))        || die "bind: $!";
587     listen(Server,SOMAXCONN)                            || die "listen: $!";
588
589     logmsg "server started on port $port";
590
591     my $waitedpid = 0;
592     my $paddr;
593
594     sub REAPER {
595         $waitedpid = wait;
596         $SIG{CHLD} = \&REAPER;  # loathe sysV
597         logmsg "reaped $waitedpid" . ($? ? " with exit $?" : '');
598     }
599
600     $SIG{CHLD} = \&REAPER;
601
602     for ( $waitedpid = 0;
603           ($paddr = accept(Client,Server)) || $waitedpid;
604           $waitedpid = 0, close Client)
605     {
606         next if $waitedpid and not $paddr;
607         my($port,$iaddr) = sockaddr_in($paddr);
608         my $name = gethostbyaddr($iaddr,AF_INET);
609
610         logmsg "connection from $name [",
611                 inet_ntoa($iaddr), "]
612                 at port $port";
613
614         spawn sub {
615             print "Hello there, $name, it's now ", scalar localtime, "\n";
616             exec '/usr/games/fortune'
617                 or confess "can't exec fortune: $!";
618         };
619
620     }
621
622     sub spawn {
623         my $coderef = shift;
624
625         unless (@_ == 0 && $coderef && ref($coderef) eq 'CODE') {
626             confess "usage: spawn CODEREF";
627         }
628
629         my $pid;
630         if (!defined($pid = fork)) {
631             logmsg "cannot fork: $!";
632             return;
633         } elsif ($pid) {
634             logmsg "begat $pid";
635             return; # I'm the parent
636         }
637         # else I'm the child -- go spawn
638
639         open(STDIN,  "<&Client")   || die "can't dup client to stdin";
640         open(STDOUT, ">&Client")   || die "can't dup client to stdout";
641         ## open(STDERR, ">&STDOUT") || die "can't dup stdout to stderr";
642         exit &$coderef();
643     }
644
645 This server takes the trouble to clone off a child version via fork() for
646 each incoming request.  That way it can handle many requests at once,
647 which you might not always want.  Even if you don't fork(), the listen()
648 will allow that many pending connections.  Forking servers have to be
649 particularly careful about cleaning up their dead children (called
650 "zombies" in Unix parlance), because otherwise you'll quickly fill up your
651 process table.
652
653 We suggest that you use the B<-T> flag to use taint checking (see L<perlsec>)
654 even if we aren't running setuid or setgid.  This is always a good idea
655 for servers and other programs run on behalf of someone else (like CGI
656 scripts), because it lessens the chances that people from the outside will
657 be able to compromise your system.
658
659 Let's look at another TCP client.  This one connects to the TCP "time"
660 service on a number of different machines and shows how far their clocks
661 differ from the system on which it's being run:
662
663     #!/usr/bin/perl  -w
664     require 5.002;
665     use strict;
666     use Socket;
667
668     my $SECS_of_70_YEARS = 2208988800;
669     sub ctime { scalar localtime(shift) }
670
671     my $iaddr = gethostbyname('localhost');
672     my $proto = getprotobyname('tcp');
673     my $port = getservbyname('time', 'tcp');
674     my $paddr = sockaddr_in(0, $iaddr);
675     my($host);
676
677     $| = 1;
678     printf "%-24s %8s %s\n",  "localhost", 0, ctime(time());
679
680     foreach $host (@ARGV) {
681         printf "%-24s ", $host;
682         my $hisiaddr = inet_aton($host)     || die "unknown host";
683         my $hispaddr = sockaddr_in($port, $hisiaddr);
684         socket(SOCKET, PF_INET, SOCK_STREAM, $proto)   || die "socket: $!";
685         connect(SOCKET, $hispaddr)          || die "bind: $!";
686         my $rtime = '    ';
687         read(SOCKET, $rtime, 4);
688         close(SOCKET);
689         my $histime = unpack("N", $rtime) - $SECS_of_70_YEARS ;
690         printf "%8d %s\n", $histime - time, ctime($histime);
691     }
692
693 =head2 Unix-Domain TCP Clients and Servers
694
695 That's fine for Internet-domain clients and servers, but what about local
696 communications?  While you can use the same setup, sometimes you don't
697 want to.  Unix-domain sockets are local to the current host, and are often
698 used internally to implement pipes.  Unlike Internet domain sockets, Unix
699 domain sockets can show up in the file system with an ls(1) listing.
700
701     $ ls -l /dev/log
702     srw-rw-rw-  1 root            0 Oct 31 07:23 /dev/log
703
704 You can test for these with Perl's B<-S> file test:
705
706     unless ( -S '/dev/log' ) {
707         die "something's wicked with the print system";
708     }
709
710 Here's a sample Unix-domain client:
711
712     #!/usr/bin/perl -w
713     require 5.002;
714     use Socket;
715     use strict;
716     my ($rendezvous, $line);
717
718     $rendezvous = shift || '/tmp/catsock';
719     socket(SOCK, PF_UNIX, SOCK_STREAM, 0)       || die "socket: $!";
720     connect(SOCK, sockaddr_un($rendezvous))     || die "connect: $!";
721     while (defined($line = <SOCK>)) {
722         print $line;
723     }
724     exit;
725
726 And here's a corresponding server.
727
728     #!/usr/bin/perl -Tw
729     require 5.002;
730     use strict;
731     use Socket;
732     use Carp;
733
734     BEGIN { $ENV{PATH} = '/usr/ucb:/bin' }
735
736     my $NAME = '/tmp/catsock';
737     my $uaddr = sockaddr_un($NAME);
738     my $proto = getprotobyname('tcp');
739
740     socket(Server,PF_UNIX,SOCK_STREAM,0)        || die "socket: $!";
741     unlink($NAME);
742     bind  (Server, $uaddr)                      || die "bind: $!";
743     listen(Server,SOMAXCONN)                    || die "listen: $!";
744
745     logmsg "server started on $NAME";
746
747     $SIG{CHLD} = \&REAPER;
748
749     for ( $waitedpid = 0;
750           accept(Client,Server) || $waitedpid;
751           $waitedpid = 0, close Client)
752     {
753         next if $waitedpid;
754         logmsg "connection on $NAME";
755         spawn sub {
756             print "Hello there, it's now ", scalar localtime, "\n";
757             exec '/usr/games/fortune' or die "can't exec fortune: $!";
758         };
759     }
760
761 As you see, it's remarkably similar to the Internet domain TCP server, so
762 much so, in fact, that we've omitted several duplicate functions--spawn(),
763 logmsg(), ctime(), and REAPER()--which are exactly the same as in the
764 other server.
765
766 So why would you ever want to use a Unix domain socket instead of a
767 simpler named pipe?  Because a named pipe doesn't give you sessions.  You
768 can't tell one process's data from another's.  With socket programming,
769 you get a separate session for each client: that's why accept() takes two
770 arguments.
771
772 For example, let's say that you have a long running database server daemon
773 that you want folks from the World Wide Web to be able to access, but only
774 if they go through a CGI interface.  You'd have a small, simple CGI
775 program that does whatever checks and logging you feel like, and then acts
776 as a Unix-domain client and connects to your private server.
777
778 =head2 UDP: Message Passing
779
780 Another kind of client-server setup is one that uses not connections, but
781 messages.  UDP communications involve much lower overhead but also provide
782 less reliability, as there are no promises that messages will arrive at
783 all, let alone in order and unmangled.  Still, UDP offers some advantages
784 over TCP, including being able to "broadcast" or "multicast" to a whole
785 bunch of destination hosts at once (usually on your local subnet).  If you
786 find yourself overly concerned about reliability and start building checks
787 into your message system, then you probably should use just TCP to start
788 with.
789
790 Here's a UDP program similar to the sample Internet TCP client given
791 above.  However, instead of checking one host at a time, the UDP version
792 will check many of them asynchronously by simulating a multicast and then
793 using select() to do a timed-out wait for I/O.  To do something similar
794 with TCP, you'd have to use a different socket handle for each host.
795
796     #!/usr/bin/perl -w
797     use strict;
798     require 5.002;
799     use Socket;
800     use Sys::Hostname;
801
802     my ( $count, $hisiaddr, $hispaddr, $histime,
803          $host, $iaddr, $paddr, $port, $proto,
804          $rin, $rout, $rtime, $SECS_of_70_YEARS);
805
806     $SECS_of_70_YEARS      = 2208988800;
807
808     $iaddr = gethostbyname(hostname());
809     $proto = getprotobyname('udp');
810     $port = getservbyname('time', 'udp');
811     $paddr = sockaddr_in(0, $iaddr); # 0 means let kernel pick
812
813     socket(SOCKET, PF_INET, SOCK_DGRAM, $proto)   || die "socket: $!";
814     bind(SOCKET, $paddr)                          || die "bind: $!";
815
816     $| = 1;
817     printf "%-12s %8s %s\n",  "localhost", 0, scalar localtime time;
818     $count = 0;
819     for $host (@ARGV) {
820         $count++;
821         $hisiaddr = inet_aton($host)    || die "unknown host";
822         $hispaddr = sockaddr_in($port, $hisiaddr);
823         defined(send(SOCKET, 0, 0, $hispaddr))    || die "send $host: $!";
824     }
825
826     $rin = '';
827     vec($rin, fileno(SOCKET), 1) = 1;
828
829     # timeout after 10.0 seconds
830     while ($count && select($rout = $rin, undef, undef, 10.0)) {
831         $rtime = '';
832         ($hispaddr = recv(SOCKET, $rtime, 4, 0))        || die "recv: $!";
833         ($port, $hisiaddr) = sockaddr_in($hispaddr);
834         $host = gethostbyaddr($hisiaddr, AF_INET);
835         $histime = unpack("N", $rtime) - $SECS_of_70_YEARS ;
836         printf "%-12s ", $host;
837         printf "%8d %s\n", $histime - time, scalar localtime($histime);
838         $count--;
839     }
840
841 =head1 SysV IPC
842
843 While System V IPC isn't so widely used as sockets, it still has some
844 interesting uses.  You can't, however, effectively use SysV IPC or
845 Berkeley mmap() to have shared memory so as to share a variable amongst
846 several processes.  That's because Perl would reallocate your string when
847 you weren't wanting it to.
848
849
850 Here's a small example showing shared memory usage.
851
852     $IPC_PRIVATE = 0;
853     $IPC_RMID = 0;
854     $size = 2000;
855     $key = shmget($IPC_PRIVATE, $size , 0777 );
856     die unless defined $key;
857
858     $message = "Message #1";
859     shmwrite($key, $message, 0, 60 ) || die "$!";
860     shmread($key,$buff,0,60) || die "$!";
861
862     print $buff,"\n";
863
864     print "deleting $key\n";
865     shmctl($key ,$IPC_RMID, 0) || die "$!";
866
867 Here's an example of a semaphore:
868
869     $IPC_KEY = 1234;
870     $IPC_RMID = 0;
871     $IPC_CREATE = 0001000;
872     $key = semget($IPC_KEY, $nsems , 0666 | $IPC_CREATE );
873     die if !defined($key);
874     print "$key\n";
875
876 Put this code in a separate file to be run in more than one process.
877 Call the file F<take>:
878
879     # create a semaphore
880
881     $IPC_KEY = 1234;
882     $key = semget($IPC_KEY,  0 , 0 );
883     die if !defined($key);
884
885     $semnum = 0;
886     $semflag = 0;
887
888     # 'take' semaphore
889     # wait for semaphore to be zero
890     $semop = 0;
891     $opstring1 = pack("sss", $semnum, $semop, $semflag);
892
893     # Increment the semaphore count
894     $semop = 1;
895     $opstring2 = pack("sss", $semnum, $semop,  $semflag);
896     $opstring = $opstring1 . $opstring2;
897
898     semop($key,$opstring) || die "$!";
899
900 Put this code in a separate file to be run in more than one process.
901 Call this file F<give>:
902
903     # 'give' the semaphore
904     # run this in the original process and you will see
905     # that the second process continues
906
907     $IPC_KEY = 1234;
908     $key = semget($IPC_KEY, 0, 0);
909     die if !defined($key);
910
911     $semnum = 0;
912     $semflag = 0;
913
914     # Decrement the semaphore count
915     $semop = -1;
916     $opstring = pack("sss", $semnum, $semop, $semflag);
917
918     semop($key,$opstring) || die "$!";
919
920 =head1 WARNING
921
922 The SysV IPC code above was written long ago, and it's definitely clunky
923 looking.  It should at the very least be made to C<use strict> and
924 C<require "sys/ipc.ph">.  Better yet, perhaps someone should create an
925 C<IPC::SysV> module the way we have the C<Socket> module for normal
926 client-server communications.
927
928 (... time passes)
929
930 Voila!  Check out the IPC::SysV modules written by Jack Shirazi.  You can
931 find them at a CPAN store near you.
932
933 =head1 NOTES
934
935 If you are running under version 5.000 (dubious) or 5.001, you can still
936 use most of the examples in this document.  You may have to remove the
937 C<use strict> and some of the my() statements for 5.000, and for both
938 you'll have to load in version 1.2 or older of the F<Socket.pm> module, which
939 is included in I<perl5.002>.
940
941 Most of these routines quietly but politely return C<undef> when they fail
942 instead of causing your program to die right then and there due to an
943 uncaught exception.  (Actually, some of the new I<Socket> conversion
944 functions  croak() on bad arguments.)  It is therefore essential
945 that you should check the return values of these functions.  Always begin
946 your socket programs this way for optimal success, and don't forget to add
947 B<-T> taint checking flag to the pound-bang line for servers:
948
949     #!/usr/bin/perl -w
950     require 5.002;
951     use strict;
952     use sigtrap;
953     use Socket;
954
955 =head1 BUGS
956
957 All these routines create system-specific portability problems.  As noted
958 elsewhere, Perl is at the mercy of your C libraries for much of its system
959 behaviour.  It's probably safest to assume broken SysV semantics for
960 signals and to stick with simple TCP and UDP socket operations; e.g., don't
961 try to pass open file descriptors over a local UDP datagram socket if you
962 want your code to stand a chance of being portable.
963
964 Because few vendors provide C libraries that are safely
965 reentrant, the prudent programmer will do little else within
966 a handler beyond die() to raise an exception and longjmp(3) out.
967
968 =head1 AUTHOR
969
970 Tom Christiansen, with occasional vestiges of Larry Wall's original
971 version.
972
973 =head1 SEE ALSO
974
975 Besides the obvious functions in L<perlfunc>, you should also check out
976 the F<modules> file at your nearest CPAN site.  (See L<perlmod> or best
977 yet, the F<Perl FAQ> for a description of what CPAN is and where to get it.)
978 Section 5 of the F<modules> file is devoted to "Networking, Device Control
979 (modems), and Interprocess Communication", and contains numerous unbundled
980 modules numerous networking modules, Chat and Expect operations, CGI
981 programming, DCE, FTP, IPC, NNTP, Proxy, Ptty, RPC, SNMP, SMTP, Telnet,
982 Threads, and ToolTalk--just to name a few.