Re: [perl #2562] wantarray fails in END, INIT, and CHECK blocks
[p5sagit/p5-mst-13.2.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 Changes the working directory to EXPR, if possible. If EXPR is omitted,
607 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
608 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
609 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
610 neither is set, C<chdir> does nothing. It returns true upon success,
611 false otherwise. See the example under C<die>.
612
613 =item chmod LIST
614
615 Changes the permissions of a list of files.  The first element of the
616 list must be the numerical mode, which should probably be an octal
617 number, and which definitely should I<not> be a string of octal digits:
618 C<0644> is okay, C<'0644'> is not.  Returns the number of files
619 successfully changed.  See also L</oct>, if all you have is a string.
620
621     $cnt = chmod 0755, 'foo', 'bar';
622     chmod 0755, @executables;
623     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
624                                              # --w----r-T
625     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
626     $mode = 0644;   chmod $mode, 'foo';      # this is best
627
628 You can also import the symbolic C<S_I*> constants from the Fcntl
629 module:
630
631     use Fcntl ':mode';
632
633     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
634     # This is identical to the chmod 0755 of the above example.
635
636 =item chomp VARIABLE
637
638 =item chomp( LIST )
639
640 =item chomp
641
642 This safer version of L</chop> removes any trailing string
643 that corresponds to the current value of C<$/> (also known as
644 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
645 number of characters removed from all its arguments.  It's often used to
646 remove the newline from the end of an input record when you're worried
647 that the final record may be missing its newline.  When in paragraph
648 mode (C<$/ = "">), it removes all trailing newlines from the string.
649 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
650 a reference to an integer or the like, see L<perlvar>) chomp() won't
651 remove anything.
652 If VARIABLE is omitted, it chomps C<$_>.  Example:
653
654     while (<>) {
655         chomp;  # avoid \n on last field
656         @array = split(/:/);
657         # ...
658     }
659
660 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
661
662 You can actually chomp anything that's an lvalue, including an assignment:
663
664     chomp($cwd = `pwd`);
665     chomp($answer = <STDIN>);
666
667 If you chomp a list, each element is chomped, and the total number of
668 characters removed is returned.
669
670 If the C<encoding> pragma is in scope then the lengths returned are
671 calculated from the length of C<$/> in Unicode characters, which is not
672 always the same as the length of C<$/> in the native encoding.
673
674 Note that parentheses are necessary when you're chomping anything
675 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
676 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
677 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
678 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
679 as C<chomp($a, $b)>.
680
681 =item chop VARIABLE
682
683 =item chop( LIST )
684
685 =item chop
686
687 Chops off the last character of a string and returns the character
688 chopped.  It is much more efficient than C<s/.$//s> because it neither
689 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
690 If VARIABLE is a hash, it chops the hash's values, but not its keys.
691
692 You can actually chop anything that's an lvalue, including an assignment.
693
694 If you chop a list, each element is chopped.  Only the value of the
695 last C<chop> is returned.
696
697 Note that C<chop> returns the last character.  To return all but the last
698 character, use C<substr($string, 0, -1)>.
699
700 See also L</chomp>.
701
702 =item chown LIST
703
704 Changes the owner (and group) of a list of files.  The first two
705 elements of the list must be the I<numeric> uid and gid, in that
706 order.  A value of -1 in either position is interpreted by most
707 systems to leave that value unchanged.  Returns the number of files
708 successfully changed.
709
710     $cnt = chown $uid, $gid, 'foo', 'bar';
711     chown $uid, $gid, @filenames;
712
713 Here's an example that looks up nonnumeric uids in the passwd file:
714
715     print "User: ";
716     chomp($user = <STDIN>);
717     print "Files: ";
718     chomp($pattern = <STDIN>);
719
720     ($login,$pass,$uid,$gid) = getpwnam($user)
721         or die "$user not in passwd file";
722
723     @ary = glob($pattern);      # expand filenames
724     chown $uid, $gid, @ary;
725
726 On most systems, you are not allowed to change the ownership of the
727 file unless you're the superuser, although you should be able to change
728 the group to any of your secondary groups.  On insecure systems, these
729 restrictions may be relaxed, but this is not a portable assumption.
730 On POSIX systems, you can detect this condition this way:
731
732     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
733     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
734
735 =item chr NUMBER
736
737 =item chr
738
739 Returns the character represented by that NUMBER in the character set.
740 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
741 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
742 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
743 backward compatibility reasons (but see L<encoding>).
744
745 If NUMBER is omitted, uses C<$_>.
746
747 For the reverse, use L</ord>.
748
749 Note that under the C<bytes> pragma the NUMBER is masked to
750 the low eight bits.
751
752 See L<perlunicode> and L<encoding> for more about Unicode.
753
754 =item chroot FILENAME
755
756 =item chroot
757
758 This function works like the system call by the same name: it makes the
759 named directory the new root directory for all further pathnames that
760 begin with a C</> by your process and all its children.  (It doesn't
761 change your current working directory, which is unaffected.)  For security
762 reasons, this call is restricted to the superuser.  If FILENAME is
763 omitted, does a C<chroot> to C<$_>.
764
765 =item close FILEHANDLE
766
767 =item close
768
769 Closes the file or pipe associated with the file handle, returning
770 true only if IO buffers are successfully flushed and closes the system
771 file descriptor.  Closes the currently selected filehandle if the
772 argument is omitted.
773
774 You don't have to close FILEHANDLE if you are immediately going to do
775 another C<open> on it, because C<open> will close it for you.  (See
776 C<open>.)  However, an explicit C<close> on an input file resets the line
777 counter (C<$.>), while the implicit close done by C<open> does not.
778
779 If the file handle came from a piped open, C<close> will additionally
780 return false if one of the other system calls involved fails, or if the
781 program exits with non-zero status.  (If the only problem was that the
782 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
783 also waits for the process executing on the pipe to complete, in case you
784 want to look at the output of the pipe afterwards, and
785 implicitly puts the exit status value of that command into C<$?>.
786
787 Prematurely closing the read end of a pipe (i.e. before the process
788 writing to it at the other end has closed it) will result in a
789 SIGPIPE being delivered to the writer.  If the other end can't
790 handle that, be sure to read all the data before closing the pipe.
791
792 Example:
793
794     open(OUTPUT, '|sort >foo')  # pipe to sort
795         or die "Can't start sort: $!";
796     #...                        # print stuff to output
797     close OUTPUT                # wait for sort to finish
798         or warn $! ? "Error closing sort pipe: $!"
799                    : "Exit status $? from sort";
800     open(INPUT, 'foo')          # get sort's results
801         or die "Can't open 'foo' for input: $!";
802
803 FILEHANDLE may be an expression whose value can be used as an indirect
804 filehandle, usually the real filehandle name.
805
806 =item closedir DIRHANDLE
807
808 Closes a directory opened by C<opendir> and returns the success of that
809 system call.
810
811 =item connect SOCKET,NAME
812
813 Attempts to connect to a remote socket, just as the connect system call
814 does.  Returns true if it succeeded, false otherwise.  NAME should be a
815 packed address of the appropriate type for the socket.  See the examples in
816 L<perlipc/"Sockets: Client/Server Communication">.
817
818 =item continue BLOCK
819
820 Actually a flow control statement rather than a function.  If there is a
821 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
822 C<foreach>), it is always executed just before the conditional is about to
823 be evaluated again, just like the third part of a C<for> loop in C.  Thus
824 it can be used to increment a loop variable, even when the loop has been
825 continued via the C<next> statement (which is similar to the C C<continue>
826 statement).
827
828 C<last>, C<next>, or C<redo> may appear within a C<continue>
829 block.  C<last> and C<redo> will behave as if they had been executed within
830 the main block.  So will C<next>, but since it will execute a C<continue>
831 block, it may be more entertaining.
832
833     while (EXPR) {
834         ### redo always comes here
835         do_something;
836     } continue {
837         ### next always comes here
838         do_something_else;
839         # then back the top to re-check EXPR
840     }
841     ### last always comes here
842
843 Omitting the C<continue> section is semantically equivalent to using an
844 empty one, logically enough.  In that case, C<next> goes directly back
845 to check the condition at the top of the loop.
846
847 =item cos EXPR
848
849 =item cos
850
851 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
852 takes cosine of C<$_>.
853
854 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
855 function, or use this relation:
856
857     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
858
859 =item crypt PLAINTEXT,SALT
860
861 Encrypts a string exactly like the crypt(3) function in the C library
862 (assuming that you actually have a version there that has not been
863 extirpated as a potential munition).  This can prove useful for checking
864 the password file for lousy passwords, amongst other things.  Only the
865 guys wearing white hats should do this.
866
867 Note that L<crypt|/crypt> is intended to be a one-way function, much like
868 breaking eggs to make an omelette.  There is no (known) corresponding
869 decrypt function (in other words, the crypt() is a one-way hash
870 function).  As a result, this function isn't all that useful for
871 cryptography.  (For that, see your nearby CPAN mirror.)
872
873 When verifying an existing encrypted string you should use the
874 encrypted text as the salt (like C<crypt($plain, $crypted) eq
875 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
876 and with more exotic implementations.  In other words, do not assume
877 anything about the returned string itself, or how many bytes in
878 the encrypted string matter.
879
880 Traditionally the result is a string of 13 bytes: two first bytes of
881 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
882 the first eight bytes of the encrypted string mattered, but
883 alternative hashing schemes (like MD5), higher level security schemes
884 (like C2), and implementations on non-UNIX platforms may produce
885 different strings.
886
887 When choosing a new salt create a random two character string whose
888 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
889 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
890 characters is just a recommendation; the characters allowed in
891 the salt depend solely on your system's crypt library, and Perl can't
892 restrict what salts C<crypt()> accepts.
893
894 Here's an example that makes sure that whoever runs this program knows
895 their own password:
896
897     $pwd = (getpwuid($<))[1];
898
899     system "stty -echo";
900     print "Password: ";
901     chomp($word = <STDIN>);
902     print "\n";
903     system "stty echo";
904
905     if (crypt($word, $pwd) ne $pwd) {
906         die "Sorry...\n";
907     } else {
908         print "ok\n";
909     }
910
911 Of course, typing in your own password to whoever asks you
912 for it is unwise.
913
914 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
915 of data, not least of all because you can't get the information
916 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
917 on your favorite CPAN mirror for a slew of potentially useful
918 modules.
919
920 If using crypt() on a Unicode string (which I<potentially> has
921 characters with codepoints above 255), Perl tries to make sense
922 of the situation by trying to downgrade (a copy of the string)
923 the string back to an eight-bit byte string before calling crypt()
924 (on that copy).  If that works, good.  If not, crypt() dies with
925 C<Wide character in crypt>.
926
927 =item dbmclose HASH
928
929 [This function has been largely superseded by the C<untie> function.]
930
931 Breaks the binding between a DBM file and a hash.
932
933 =item dbmopen HASH,DBNAME,MASK
934
935 [This function has been largely superseded by the C<tie> function.]
936
937 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
938 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
939 argument is I<not> a filehandle, even though it looks like one).  DBNAME
940 is the name of the database (without the F<.dir> or F<.pag> extension if
941 any).  If the database does not exist, it is created with protection
942 specified by MASK (as modified by the C<umask>).  If your system supports
943 only the older DBM functions, you may perform only one C<dbmopen> in your
944 program.  In older versions of Perl, if your system had neither DBM nor
945 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
946 sdbm(3).
947
948 If you don't have write access to the DBM file, you can only read hash
949 variables, not set them.  If you want to test whether you can write,
950 either use file tests or try setting a dummy hash entry inside an C<eval>,
951 which will trap the error.
952
953 Note that functions such as C<keys> and C<values> may return huge lists
954 when used on large DBM files.  You may prefer to use the C<each>
955 function to iterate over large DBM files.  Example:
956
957     # print out history file offsets
958     dbmopen(%HIST,'/usr/lib/news/history',0666);
959     while (($key,$val) = each %HIST) {
960         print $key, ' = ', unpack('L',$val), "\n";
961     }
962     dbmclose(%HIST);
963
964 See also L<AnyDBM_File> for a more general description of the pros and
965 cons of the various dbm approaches, as well as L<DB_File> for a particularly
966 rich implementation.
967
968 You can control which DBM library you use by loading that library
969 before you call dbmopen():
970
971     use DB_File;
972     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
973         or die "Can't open netscape history file: $!";
974
975 =item defined EXPR
976
977 =item defined
978
979 Returns a Boolean value telling whether EXPR has a value other than
980 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
981 checked.
982
983 Many operations return C<undef> to indicate failure, end of file,
984 system error, uninitialized variable, and other exceptional
985 conditions.  This function allows you to distinguish C<undef> from
986 other values.  (A simple Boolean test will not distinguish among
987 C<undef>, zero, the empty string, and C<"0">, which are all equally
988 false.)  Note that since C<undef> is a valid scalar, its presence
989 doesn't I<necessarily> indicate an exceptional condition: C<pop>
990 returns C<undef> when its argument is an empty array, I<or> when the
991 element to return happens to be C<undef>.
992
993 You may also use C<defined(&func)> to check whether subroutine C<&func>
994 has ever been defined.  The return value is unaffected by any forward
995 declarations of C<&func>.  Note that a subroutine which is not defined
996 may still be callable: its package may have an C<AUTOLOAD> method that
997 makes it spring into existence the first time that it is called -- see
998 L<perlsub>.
999
1000 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1001 used to report whether memory for that aggregate has ever been
1002 allocated.  This behavior may disappear in future versions of Perl.
1003 You should instead use a simple test for size:
1004
1005     if (@an_array) { print "has array elements\n" }
1006     if (%a_hash)   { print "has hash members\n"   }
1007
1008 When used on a hash element, it tells you whether the value is defined,
1009 not whether the key exists in the hash.  Use L</exists> for the latter
1010 purpose.
1011
1012 Examples:
1013
1014     print if defined $switch{'D'};
1015     print "$val\n" while defined($val = pop(@ary));
1016     die "Can't readlink $sym: $!"
1017         unless defined($value = readlink $sym);
1018     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1019     $debugging = 0 unless defined $debugging;
1020
1021 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1022 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1023 defined values.  For example, if you say
1024
1025     "ab" =~ /a(.*)b/;
1026
1027 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1028 matched "nothing".  But it didn't really match nothing--rather, it
1029 matched something that happened to be zero characters long.  This is all
1030 very above-board and honest.  When a function returns an undefined value,
1031 it's an admission that it couldn't give you an honest answer.  So you
1032 should use C<defined> only when you're questioning the integrity of what
1033 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1034 what you want.
1035
1036 See also L</undef>, L</exists>, L</ref>.
1037
1038 =item delete EXPR
1039
1040 Given an expression that specifies a hash element, array element, hash slice,
1041 or array slice, deletes the specified element(s) from the hash or array.
1042 In the case of an array, if the array elements happen to be at the end,
1043 the size of the array will shrink to the highest element that tests
1044 true for exists() (or 0 if no such element exists).
1045
1046 Returns a list with the same number of elements as the number of elements
1047 for which deletion was attempted.  Each element of that list consists of
1048 either the value of the element deleted, or the undefined value.  In scalar
1049 context, this means that you get the value of the last element deleted (or
1050 the undefined value if that element did not exist).
1051
1052     %hash = (foo => 11, bar => 22, baz => 33);
1053     $scalar = delete $hash{foo};             # $scalar is 11
1054     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1055     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1056
1057 Deleting from C<%ENV> modifies the environment.  Deleting from
1058 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1059 from a C<tie>d hash or array may not necessarily return anything.
1060
1061 Deleting an array element effectively returns that position of the array
1062 to its initial, uninitialized state.  Subsequently testing for the same
1063 element with exists() will return false.  Note that deleting array
1064 elements in the middle of an array will not shift the index of the ones
1065 after them down--use splice() for that.  See L</exists>.
1066
1067 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1068
1069     foreach $key (keys %HASH) {
1070         delete $HASH{$key};
1071     }
1072
1073     foreach $index (0 .. $#ARRAY) {
1074         delete $ARRAY[$index];
1075     }
1076
1077 And so do these:
1078
1079     delete @HASH{keys %HASH};
1080
1081     delete @ARRAY[0 .. $#ARRAY];
1082
1083 But both of these are slower than just assigning the empty list
1084 or undefining %HASH or @ARRAY:
1085
1086     %HASH = ();         # completely empty %HASH
1087     undef %HASH;        # forget %HASH ever existed
1088
1089     @ARRAY = ();        # completely empty @ARRAY
1090     undef @ARRAY;       # forget @ARRAY ever existed
1091
1092 Note that the EXPR can be arbitrarily complicated as long as the final
1093 operation is a hash element, array element,  hash slice, or array slice
1094 lookup:
1095
1096     delete $ref->[$x][$y]{$key};
1097     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1098
1099     delete $ref->[$x][$y][$index];
1100     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1101
1102 =item die LIST
1103
1104 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1105 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1106 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1107 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1108 an C<eval(),> the error message is stuffed into C<$@> and the
1109 C<eval> is terminated with the undefined value.  This makes
1110 C<die> the way to raise an exception.
1111
1112 Equivalent examples:
1113
1114     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1115     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1116
1117 If the last element of LIST does not end in a newline, the current
1118 script line number and input line number (if any) are also printed,
1119 and a newline is supplied.  Note that the "input line number" (also
1120 known as "chunk") is subject to whatever notion of "line" happens to
1121 be currently in effect, and is also available as the special variable
1122 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1123
1124 Hint: sometimes appending C<", stopped"> to your message will cause it
1125 to make better sense when the string C<"at foo line 123"> is appended.
1126 Suppose you are running script "canasta".
1127
1128     die "/etc/games is no good";
1129     die "/etc/games is no good, stopped";
1130
1131 produce, respectively
1132
1133     /etc/games is no good at canasta line 123.
1134     /etc/games is no good, stopped at canasta line 123.
1135
1136 See also exit(), warn(), and the Carp module.
1137
1138 If LIST is empty and C<$@> already contains a value (typically from a
1139 previous eval) that value is reused after appending C<"\t...propagated">.
1140 This is useful for propagating exceptions:
1141
1142     eval { ... };
1143     die unless $@ =~ /Expected exception/;
1144
1145 If LIST is empty and C<$@> contains an object reference that has a
1146 C<PROPAGATE> method, that method will be called with additional file
1147 and line number parameters.  The return value replaces the value in
1148 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1149 were called.
1150
1151 If C<$@> is empty then the string C<"Died"> is used.
1152
1153 die() can also be called with a reference argument.  If this happens to be
1154 trapped within an eval(), $@ contains the reference.  This behavior permits
1155 a more elaborate exception handling implementation using objects that
1156 maintain arbitrary state about the nature of the exception.  Such a scheme
1157 is sometimes preferable to matching particular string values of $@ using
1158 regular expressions.  Here's an example:
1159
1160     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1161     if ($@) {
1162         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1163             # handle Some::Module::Exception
1164         }
1165         else {
1166             # handle all other possible exceptions
1167         }
1168     }
1169
1170 Because perl will stringify uncaught exception messages before displaying
1171 them, you may want to overload stringification operations on such custom
1172 exception objects.  See L<overload> for details about that.
1173
1174 You can arrange for a callback to be run just before the C<die>
1175 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1176 handler will be called with the error text and can change the error
1177 message, if it sees fit, by calling C<die> again.  See
1178 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1179 L<"eval BLOCK"> for some examples.  Although this feature was meant
1180 to be run only right before your program was to exit, this is not
1181 currently the case--the C<$SIG{__DIE__}> hook is currently called
1182 even inside eval()ed blocks/strings!  If one wants the hook to do
1183 nothing in such situations, put
1184
1185         die @_ if $^S;
1186
1187 as the first line of the handler (see L<perlvar/$^S>).  Because
1188 this promotes strange action at a distance, this counterintuitive
1189 behavior may be fixed in a future release.
1190
1191 =item do BLOCK
1192
1193 Not really a function.  Returns the value of the last command in the
1194 sequence of commands indicated by BLOCK.  When modified by a loop
1195 modifier, executes the BLOCK once before testing the loop condition.
1196 (On other statements the loop modifiers test the conditional first.)
1197
1198 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1199 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1200 See L<perlsyn> for alternative strategies.
1201
1202 =item do SUBROUTINE(LIST)
1203
1204 A deprecated form of subroutine call.  See L<perlsub>.
1205
1206 =item do EXPR
1207
1208 Uses the value of EXPR as a filename and executes the contents of the
1209 file as a Perl script.  Its primary use is to include subroutines
1210 from a Perl subroutine library.
1211
1212     do 'stat.pl';
1213
1214 is just like
1215
1216     eval `cat stat.pl`;
1217
1218 except that it's more efficient and concise, keeps track of the current
1219 filename for error messages, searches the @INC libraries, and updates
1220 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1221 variables.  It also differs in that code evaluated with C<do FILENAME>
1222 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1223 same, however, in that it does reparse the file every time you call it,
1224 so you probably don't want to do this inside a loop.
1225
1226 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1227 error.  If C<do> can read the file but cannot compile it, it
1228 returns undef and sets an error message in C<$@>.   If the file is
1229 successfully compiled, C<do> returns the value of the last expression
1230 evaluated.
1231
1232 Note that inclusion of library modules is better done with the
1233 C<use> and C<require> operators, which also do automatic error checking
1234 and raise an exception if there's a problem.
1235
1236 You might like to use C<do> to read in a program configuration
1237 file.  Manual error checking can be done this way:
1238
1239     # read in config files: system first, then user
1240     for $file ("/share/prog/defaults.rc",
1241                "$ENV{HOME}/.someprogrc")
1242    {
1243         unless ($return = do $file) {
1244             warn "couldn't parse $file: $@" if $@;
1245             warn "couldn't do $file: $!"    unless defined $return;
1246             warn "couldn't run $file"       unless $return;
1247         }
1248     }
1249
1250 =item dump LABEL
1251
1252 =item dump
1253
1254 This function causes an immediate core dump.  See also the B<-u>
1255 command-line switch in L<perlrun>, which does the same thing.
1256 Primarily this is so that you can use the B<undump> program (not
1257 supplied) to turn your core dump into an executable binary after
1258 having initialized all your variables at the beginning of the
1259 program.  When the new binary is executed it will begin by executing
1260 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1261 Think of it as a goto with an intervening core dump and reincarnation.
1262 If C<LABEL> is omitted, restarts the program from the top.
1263
1264 B<WARNING>: Any files opened at the time of the dump will I<not>
1265 be open any more when the program is reincarnated, with possible
1266 resulting confusion on the part of Perl.
1267
1268 This function is now largely obsolete, partly because it's very
1269 hard to convert a core file into an executable, and because the
1270 real compiler backends for generating portable bytecode and compilable
1271 C code have superseded it.  That's why you should now invoke it as
1272 C<CORE::dump()>, if you don't want to be warned against a possible
1273 typo.
1274
1275 If you're looking to use L<dump> to speed up your program, consider
1276 generating bytecode or native C code as described in L<perlcc>.  If
1277 you're just trying to accelerate a CGI script, consider using the
1278 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1279 You might also consider autoloading or selfloading, which at least
1280 make your program I<appear> to run faster.
1281
1282 =item each HASH
1283
1284 When called in list context, returns a 2-element list consisting of the
1285 key and value for the next element of a hash, so that you can iterate over
1286 it.  When called in scalar context, returns only the key for the next
1287 element in the hash.
1288
1289 Entries are returned in an apparently random order.  The actual random
1290 order is subject to change in future versions of perl, but it is
1291 guaranteed to be in the same order as either the C<keys> or C<values>
1292 function would produce on the same (unmodified) hash.  Since Perl
1293 5.8.1 the ordering is different even between different runs of Perl
1294 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1295
1296 When the hash is entirely read, a null array is returned in list context
1297 (which when assigned produces a false (C<0>) value), and C<undef> in
1298 scalar context.  The next call to C<each> after that will start iterating
1299 again.  There is a single iterator for each hash, shared by all C<each>,
1300 C<keys>, and C<values> function calls in the program; it can be reset by
1301 reading all the elements from the hash, or by evaluating C<keys HASH> or
1302 C<values HASH>.  If you add or delete elements of a hash while you're
1303 iterating over it, you may get entries skipped or duplicated, so
1304 don't.  Exception: It is always safe to delete the item most recently
1305 returned by C<each()>, which means that the following code will work:
1306
1307         while (($key, $value) = each %hash) {
1308           print $key, "\n";
1309           delete $hash{$key};   # This is safe
1310         }
1311
1312 The following prints out your environment like the printenv(1) program,
1313 only in a different order:
1314
1315     while (($key,$value) = each %ENV) {
1316         print "$key=$value\n";
1317     }
1318
1319 See also C<keys>, C<values> and C<sort>.
1320
1321 =item eof FILEHANDLE
1322
1323 =item eof ()
1324
1325 =item eof
1326
1327 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1328 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1329 gives the real filehandle.  (Note that this function actually
1330 reads a character and then C<ungetc>s it, so isn't very useful in an
1331 interactive context.)  Do not read from a terminal file (or call
1332 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1333 as terminals may lose the end-of-file condition if you do.
1334
1335 An C<eof> without an argument uses the last file read.  Using C<eof()>
1336 with empty parentheses is very different.  It refers to the pseudo file
1337 formed from the files listed on the command line and accessed via the
1338 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1339 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1340 used will cause C<@ARGV> to be examined to determine if input is
1341 available.   Similarly, an C<eof()> after C<< <> >> has returned
1342 end-of-file will assume you are processing another C<@ARGV> list,
1343 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1344 see L<perlop/"I/O Operators">.
1345
1346 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1347 detect the end of each file, C<eof()> will only detect the end of the
1348 last file.  Examples:
1349
1350     # reset line numbering on each input file
1351     while (<>) {
1352         next if /^\s*#/;        # skip comments
1353         print "$.\t$_";
1354     } continue {
1355         close ARGV  if eof;     # Not eof()!
1356     }
1357
1358     # insert dashes just before last line of last file
1359     while (<>) {
1360         if (eof()) {            # check for end of last file
1361             print "--------------\n";
1362         }
1363         print;
1364         last if eof();          # needed if we're reading from a terminal
1365     }
1366
1367 Practical hint: you almost never need to use C<eof> in Perl, because the
1368 input operators typically return C<undef> when they run out of data, or if
1369 there was an error.
1370
1371 =item eval EXPR
1372
1373 =item eval BLOCK
1374
1375 In the first form, the return value of EXPR is parsed and executed as if it
1376 were a little Perl program.  The value of the expression (which is itself
1377 determined within scalar context) is first parsed, and if there weren't any
1378 errors, executed in the lexical context of the current Perl program, so
1379 that any variable settings or subroutine and format definitions remain
1380 afterwards.  Note that the value is parsed every time the eval executes.
1381 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1382 delay parsing and subsequent execution of the text of EXPR until run time.
1383
1384 In the second form, the code within the BLOCK is parsed only once--at the
1385 same time the code surrounding the eval itself was parsed--and executed
1386 within the context of the current Perl program.  This form is typically
1387 used to trap exceptions more efficiently than the first (see below), while
1388 also providing the benefit of checking the code within BLOCK at compile
1389 time.
1390
1391 The final semicolon, if any, may be omitted from the value of EXPR or within
1392 the BLOCK.
1393
1394 In both forms, the value returned is the value of the last expression
1395 evaluated inside the mini-program; a return statement may be also used, just
1396 as with subroutines.  The expression providing the return value is evaluated
1397 in void, scalar, or list context, depending on the context of the eval itself.
1398 See L</wantarray> for more on how the evaluation context can be determined.
1399
1400 If there is a syntax error or runtime error, or a C<die> statement is
1401 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1402 error message.  If there was no error, C<$@> is guaranteed to be a null
1403 string.  Beware that using C<eval> neither silences perl from printing
1404 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1405 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1406 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1407 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1408
1409 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1410 determining whether a particular feature (such as C<socket> or C<symlink>)
1411 is implemented.  It is also Perl's exception trapping mechanism, where
1412 the die operator is used to raise exceptions.
1413
1414 If the code to be executed doesn't vary, you may use the eval-BLOCK
1415 form to trap run-time errors without incurring the penalty of
1416 recompiling each time.  The error, if any, is still returned in C<$@>.
1417 Examples:
1418
1419     # make divide-by-zero nonfatal
1420     eval { $answer = $a / $b; }; warn $@ if $@;
1421
1422     # same thing, but less efficient
1423     eval '$answer = $a / $b'; warn $@ if $@;
1424
1425     # a compile-time error
1426     eval { $answer = };                 # WRONG
1427
1428     # a run-time error
1429     eval '$answer =';   # sets $@
1430
1431 Due to the current arguably broken state of C<__DIE__> hooks, when using
1432 the C<eval{}> form as an exception trap in libraries, you may wish not
1433 to trigger any C<__DIE__> hooks that user code may have installed.
1434 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1435 as shown in this example:
1436
1437     # a very private exception trap for divide-by-zero
1438     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1439     warn $@ if $@;
1440
1441 This is especially significant, given that C<__DIE__> hooks can call
1442 C<die> again, which has the effect of changing their error messages:
1443
1444     # __DIE__ hooks may modify error messages
1445     {
1446        local $SIG{'__DIE__'} =
1447               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1448        eval { die "foo lives here" };
1449        print $@ if $@;                # prints "bar lives here"
1450     }
1451
1452 Because this promotes action at a distance, this counterintuitive behavior
1453 may be fixed in a future release.
1454
1455 With an C<eval>, you should be especially careful to remember what's
1456 being looked at when:
1457
1458     eval $x;            # CASE 1
1459     eval "$x";          # CASE 2
1460
1461     eval '$x';          # CASE 3
1462     eval { $x };        # CASE 4
1463
1464     eval "\$$x++";      # CASE 5
1465     $$x++;              # CASE 6
1466
1467 Cases 1 and 2 above behave identically: they run the code contained in
1468 the variable $x.  (Although case 2 has misleading double quotes making
1469 the reader wonder what else might be happening (nothing is).)  Cases 3
1470 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1471 does nothing but return the value of $x.  (Case 4 is preferred for
1472 purely visual reasons, but it also has the advantage of compiling at
1473 compile-time instead of at run-time.)  Case 5 is a place where
1474 normally you I<would> like to use double quotes, except that in this
1475 particular situation, you can just use symbolic references instead, as
1476 in case 6.
1477
1478 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1479 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1480
1481 Note that as a very special case, an C<eval ''> executed within the C<DB>
1482 package doesn't see the usual surrounding lexical scope, but rather the
1483 scope of the first non-DB piece of code that called it. You don't normally
1484 need to worry about this unless you are writing a Perl debugger.
1485
1486 =item exec LIST
1487
1488 =item exec PROGRAM LIST
1489
1490 The C<exec> function executes a system command I<and never returns>--
1491 use C<system> instead of C<exec> if you want it to return.  It fails and
1492 returns false only if the command does not exist I<and> it is executed
1493 directly instead of via your system's command shell (see below).
1494
1495 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1496 warns you if there is a following statement which isn't C<die>, C<warn>,
1497 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1498 I<really> want to follow an C<exec> with some other statement, you
1499 can use one of these styles to avoid the warning:
1500
1501     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1502     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1503
1504 If there is more than one argument in LIST, or if LIST is an array
1505 with more than one value, calls execvp(3) with the arguments in LIST.
1506 If there is only one scalar argument or an array with one element in it,
1507 the argument is checked for shell metacharacters, and if there are any,
1508 the entire argument is passed to the system's command shell for parsing
1509 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1510 If there are no shell metacharacters in the argument, it is split into
1511 words and passed directly to C<execvp>, which is more efficient.
1512 Examples:
1513
1514     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1515     exec "sort $outfile | uniq";
1516
1517 If you don't really want to execute the first argument, but want to lie
1518 to the program you are executing about its own name, you can specify
1519 the program you actually want to run as an "indirect object" (without a
1520 comma) in front of the LIST.  (This always forces interpretation of the
1521 LIST as a multivalued list, even if there is only a single scalar in
1522 the list.)  Example:
1523
1524     $shell = '/bin/csh';
1525     exec $shell '-sh';          # pretend it's a login shell
1526
1527 or, more directly,
1528
1529     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1530
1531 When the arguments get executed via the system shell, results will
1532 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1533 for details.
1534
1535 Using an indirect object with C<exec> or C<system> is also more
1536 secure.  This usage (which also works fine with system()) forces
1537 interpretation of the arguments as a multivalued list, even if the
1538 list had just one argument.  That way you're safe from the shell
1539 expanding wildcards or splitting up words with whitespace in them.
1540
1541     @args = ( "echo surprise" );
1542
1543     exec @args;               # subject to shell escapes
1544                                 # if @args == 1
1545     exec { $args[0] } @args;  # safe even with one-arg list
1546
1547 The first version, the one without the indirect object, ran the I<echo>
1548 program, passing it C<"surprise"> an argument.  The second version
1549 didn't--it tried to run a program literally called I<"echo surprise">,
1550 didn't find it, and set C<$?> to a non-zero value indicating failure.
1551
1552 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1553 output before the exec, but this may not be supported on some platforms
1554 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1555 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1556 open handles in order to avoid lost output.
1557
1558 Note that C<exec> will not call your C<END> blocks, nor will it call
1559 any C<DESTROY> methods in your objects.
1560
1561 =item exists EXPR
1562
1563 Given an expression that specifies a hash element or array element,
1564 returns true if the specified element in the hash or array has ever
1565 been initialized, even if the corresponding value is undefined.  The
1566 element is not autovivified if it doesn't exist.
1567
1568     print "Exists\n"    if exists $hash{$key};
1569     print "Defined\n"   if defined $hash{$key};
1570     print "True\n"      if $hash{$key};
1571
1572     print "Exists\n"    if exists $array[$index];
1573     print "Defined\n"   if defined $array[$index];
1574     print "True\n"      if $array[$index];
1575
1576 A hash or array element can be true only if it's defined, and defined if
1577 it exists, but the reverse doesn't necessarily hold true.
1578
1579 Given an expression that specifies the name of a subroutine,
1580 returns true if the specified subroutine has ever been declared, even
1581 if it is undefined.  Mentioning a subroutine name for exists or defined
1582 does not count as declaring it.  Note that a subroutine which does not
1583 exist may still be callable: its package may have an C<AUTOLOAD>
1584 method that makes it spring into existence the first time that it is
1585 called -- see L<perlsub>.
1586
1587     print "Exists\n"    if exists &subroutine;
1588     print "Defined\n"   if defined &subroutine;
1589
1590 Note that the EXPR can be arbitrarily complicated as long as the final
1591 operation is a hash or array key lookup or subroutine name:
1592
1593     if (exists $ref->{A}->{B}->{$key})  { }
1594     if (exists $hash{A}{B}{$key})       { }
1595
1596     if (exists $ref->{A}->{B}->[$ix])   { }
1597     if (exists $hash{A}{B}[$ix])        { }
1598
1599     if (exists &{$ref->{A}{B}{$key}})   { }
1600
1601 Although the deepest nested array or hash will not spring into existence
1602 just because its existence was tested, any intervening ones will.
1603 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1604 into existence due to the existence test for the $key element above.
1605 This happens anywhere the arrow operator is used, including even:
1606
1607     undef $ref;
1608     if (exists $ref->{"Some key"})      { }
1609     print $ref;             # prints HASH(0x80d3d5c)
1610
1611 This surprising autovivification in what does not at first--or even
1612 second--glance appear to be an lvalue context may be fixed in a future
1613 release.
1614
1615 Use of a subroutine call, rather than a subroutine name, as an argument
1616 to exists() is an error.
1617
1618     exists &sub;        # OK
1619     exists &sub();      # Error
1620
1621 =item exit EXPR
1622
1623 Evaluates EXPR and exits immediately with that value.    Example:
1624
1625     $ans = <STDIN>;
1626     exit 0 if $ans =~ /^[Xx]/;
1627
1628 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1629 universally recognized values for EXPR are C<0> for success and C<1>
1630 for error; other values are subject to interpretation depending on the
1631 environment in which the Perl program is running.  For example, exiting
1632 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1633 the mailer to return the item undelivered, but that's not true everywhere.
1634
1635 Don't use C<exit> to abort a subroutine if there's any chance that
1636 someone might want to trap whatever error happened.  Use C<die> instead,
1637 which can be trapped by an C<eval>.
1638
1639 The exit() function does not always exit immediately.  It calls any
1640 defined C<END> routines first, but these C<END> routines may not
1641 themselves abort the exit.  Likewise any object destructors that need to
1642 be called are called before the real exit.  If this is a problem, you
1643 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1644 See L<perlmod> for details.
1645
1646 =item exp EXPR
1647
1648 =item exp
1649
1650 Returns I<e> (the natural logarithm base) to the power of EXPR.
1651 If EXPR is omitted, gives C<exp($_)>.
1652
1653 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1654
1655 Implements the fcntl(2) function.  You'll probably have to say
1656
1657     use Fcntl;
1658
1659 first to get the correct constant definitions.  Argument processing and
1660 value return works just like C<ioctl> below.
1661 For example:
1662
1663     use Fcntl;
1664     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1665         or die "can't fcntl F_GETFL: $!";
1666
1667 You don't have to check for C<defined> on the return from C<fcntl>.
1668 Like C<ioctl>, it maps a C<0> return from the system call into
1669 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1670 in numeric context.  It is also exempt from the normal B<-w> warnings
1671 on improper numeric conversions.
1672
1673 Note that C<fcntl> will produce a fatal error if used on a machine that
1674 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1675 manpage to learn what functions are available on your system.
1676
1677 Here's an example of setting a filehandle named C<REMOTE> to be
1678 non-blocking at the system level.  You'll have to negotiate C<$|>
1679 on your own, though.
1680
1681     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1682
1683     $flags = fcntl(REMOTE, F_GETFL, 0)
1684                 or die "Can't get flags for the socket: $!\n";
1685
1686     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1687                 or die "Can't set flags for the socket: $!\n";
1688
1689 =item fileno FILEHANDLE
1690
1691 Returns the file descriptor for a filehandle, or undefined if the
1692 filehandle is not open.  This is mainly useful for constructing
1693 bitmaps for C<select> and low-level POSIX tty-handling operations.
1694 If FILEHANDLE is an expression, the value is taken as an indirect
1695 filehandle, generally its name.
1696
1697 You can use this to find out whether two handles refer to the
1698 same underlying descriptor:
1699
1700     if (fileno(THIS) == fileno(THAT)) {
1701         print "THIS and THAT are dups\n";
1702     }
1703
1704 (Filehandles connected to memory objects via new features of C<open> may
1705 return undefined even though they are open.)
1706
1707
1708 =item flock FILEHANDLE,OPERATION
1709
1710 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1711 for success, false on failure.  Produces a fatal error if used on a
1712 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1713 C<flock> is Perl's portable file locking interface, although it locks
1714 only entire files, not records.
1715
1716 Two potentially non-obvious but traditional C<flock> semantics are
1717 that it waits indefinitely until the lock is granted, and that its locks
1718 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1719 fewer guarantees.  This means that files locked with C<flock> may be
1720 modified by programs that do not also use C<flock>.  See L<perlport>,
1721 your port's specific documentation, or your system-specific local manpages
1722 for details.  It's best to assume traditional behavior if you're writing
1723 portable programs.  (But if you're not, you should as always feel perfectly
1724 free to write for your own system's idiosyncrasies (sometimes called
1725 "features").  Slavish adherence to portability concerns shouldn't get
1726 in the way of your getting your job done.)
1727
1728 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1729 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1730 you can use the symbolic names if you import them from the Fcntl module,
1731 either individually, or as a group using the ':flock' tag.  LOCK_SH
1732 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1733 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1734 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1735 waiting for the lock (check the return status to see if you got it).
1736
1737 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1738 before locking or unlocking it.
1739
1740 Note that the emulation built with lockf(3) doesn't provide shared
1741 locks, and it requires that FILEHANDLE be open with write intent.  These
1742 are the semantics that lockf(3) implements.  Most if not all systems
1743 implement lockf(3) in terms of fcntl(2) locking, though, so the
1744 differing semantics shouldn't bite too many people.
1745
1746 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1747 be open with read intent to use LOCK_SH and requires that it be open
1748 with write intent to use LOCK_EX.
1749
1750 Note also that some versions of C<flock> cannot lock things over the
1751 network; you would need to use the more system-specific C<fcntl> for
1752 that.  If you like you can force Perl to ignore your system's flock(2)
1753 function, and so provide its own fcntl(2)-based emulation, by passing
1754 the switch C<-Ud_flock> to the F<Configure> program when you configure
1755 perl.
1756
1757 Here's a mailbox appender for BSD systems.
1758
1759     use Fcntl ':flock'; # import LOCK_* constants
1760
1761     sub lock {
1762         flock(MBOX,LOCK_EX);
1763         # and, in case someone appended
1764         # while we were waiting...
1765         seek(MBOX, 0, 2);
1766     }
1767
1768     sub unlock {
1769         flock(MBOX,LOCK_UN);
1770     }
1771
1772     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1773             or die "Can't open mailbox: $!";
1774
1775     lock();
1776     print MBOX $msg,"\n\n";
1777     unlock();
1778
1779 On systems that support a real flock(), locks are inherited across fork()
1780 calls, whereas those that must resort to the more capricious fcntl()
1781 function lose the locks, making it harder to write servers.
1782
1783 See also L<DB_File> for other flock() examples.
1784
1785 =item fork
1786
1787 Does a fork(2) system call to create a new process running the
1788 same program at the same point.  It returns the child pid to the
1789 parent process, C<0> to the child process, or C<undef> if the fork is
1790 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1791 are shared, while everything else is copied.  On most systems supporting
1792 fork(), great care has gone into making it extremely efficient (for
1793 example, using copy-on-write technology on data pages), making it the
1794 dominant paradigm for multitasking over the last few decades.
1795
1796 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1797 output before forking the child process, but this may not be supported
1798 on some platforms (see L<perlport>).  To be safe, you may need to set
1799 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1800 C<IO::Handle> on any open handles in order to avoid duplicate output.
1801
1802 If you C<fork> without ever waiting on your children, you will
1803 accumulate zombies.  On some systems, you can avoid this by setting
1804 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1805 forking and reaping moribund children.
1806
1807 Note that if your forked child inherits system file descriptors like
1808 STDIN and STDOUT that are actually connected by a pipe or socket, even
1809 if you exit, then the remote server (such as, say, a CGI script or a
1810 backgrounded job launched from a remote shell) won't think you're done.
1811 You should reopen those to F</dev/null> if it's any issue.
1812
1813 =item format
1814
1815 Declare a picture format for use by the C<write> function.  For
1816 example:
1817
1818     format Something =
1819         Test: @<<<<<<<< @||||| @>>>>>
1820               $str,     $%,    '$' . int($num)
1821     .
1822
1823     $str = "widget";
1824     $num = $cost/$quantity;
1825     $~ = 'Something';
1826     write;
1827
1828 See L<perlform> for many details and examples.
1829
1830 =item formline PICTURE,LIST
1831
1832 This is an internal function used by C<format>s, though you may call it,
1833 too.  It formats (see L<perlform>) a list of values according to the
1834 contents of PICTURE, placing the output into the format output
1835 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1836 Eventually, when a C<write> is done, the contents of
1837 C<$^A> are written to some filehandle, but you could also read C<$^A>
1838 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1839 does one C<formline> per line of form, but the C<formline> function itself
1840 doesn't care how many newlines are embedded in the PICTURE.  This means
1841 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1842 You may therefore need to use multiple formlines to implement a single
1843 record format, just like the format compiler.
1844
1845 Be careful if you put double quotes around the picture, because an C<@>
1846 character may be taken to mean the beginning of an array name.
1847 C<formline> always returns true.  See L<perlform> for other examples.
1848
1849 =item getc FILEHANDLE
1850
1851 =item getc
1852
1853 Returns the next character from the input file attached to FILEHANDLE,
1854 or the undefined value at end of file, or if there was an error (in
1855 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1856 STDIN.  This is not particularly efficient.  However, it cannot be
1857 used by itself to fetch single characters without waiting for the user
1858 to hit enter.  For that, try something more like:
1859
1860     if ($BSD_STYLE) {
1861         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1862     }
1863     else {
1864         system "stty", '-icanon', 'eol', "\001";
1865     }
1866
1867     $key = getc(STDIN);
1868
1869     if ($BSD_STYLE) {
1870         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1871     }
1872     else {
1873         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1874     }
1875     print "\n";
1876
1877 Determination of whether $BSD_STYLE should be set
1878 is left as an exercise to the reader.
1879
1880 The C<POSIX::getattr> function can do this more portably on
1881 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1882 module from your nearest CPAN site; details on CPAN can be found on
1883 L<perlmodlib/CPAN>.
1884
1885 =item getlogin
1886
1887 Implements the C library function of the same name, which on most
1888 systems returns the current login from F</etc/utmp>, if any.  If null,
1889 use C<getpwuid>.
1890
1891     $login = getlogin || getpwuid($<) || "Kilroy";
1892
1893 Do not consider C<getlogin> for authentication: it is not as
1894 secure as C<getpwuid>.
1895
1896 =item getpeername SOCKET
1897
1898 Returns the packed sockaddr address of other end of the SOCKET connection.
1899
1900     use Socket;
1901     $hersockaddr    = getpeername(SOCK);
1902     ($port, $iaddr) = sockaddr_in($hersockaddr);
1903     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1904     $herstraddr     = inet_ntoa($iaddr);
1905
1906 =item getpgrp PID
1907
1908 Returns the current process group for the specified PID.  Use
1909 a PID of C<0> to get the current process group for the
1910 current process.  Will raise an exception if used on a machine that
1911 doesn't implement getpgrp(2).  If PID is omitted, returns process
1912 group of current process.  Note that the POSIX version of C<getpgrp>
1913 does not accept a PID argument, so only C<PID==0> is truly portable.
1914
1915 =item getppid
1916
1917 Returns the process id of the parent process.
1918
1919 Note for Linux users: on Linux, the C functions C<getpid()> and
1920 C<getppid()> return different values from different threads. In order to
1921 be portable, this behavior is not reflected by the perl-level function
1922 C<getppid()>, that returns a consistent value across threads. If you want
1923 to call the underlying C<getppid()>, you may use the CPAN module
1924 C<Linux::Pid>.
1925
1926 =item getpriority WHICH,WHO
1927
1928 Returns the current priority for a process, a process group, or a user.
1929 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1930 machine that doesn't implement getpriority(2).
1931
1932 =item getpwnam NAME
1933
1934 =item getgrnam NAME
1935
1936 =item gethostbyname NAME
1937
1938 =item getnetbyname NAME
1939
1940 =item getprotobyname NAME
1941
1942 =item getpwuid UID
1943
1944 =item getgrgid GID
1945
1946 =item getservbyname NAME,PROTO
1947
1948 =item gethostbyaddr ADDR,ADDRTYPE
1949
1950 =item getnetbyaddr ADDR,ADDRTYPE
1951
1952 =item getprotobynumber NUMBER
1953
1954 =item getservbyport PORT,PROTO
1955
1956 =item getpwent
1957
1958 =item getgrent
1959
1960 =item gethostent
1961
1962 =item getnetent
1963
1964 =item getprotoent
1965
1966 =item getservent
1967
1968 =item setpwent
1969
1970 =item setgrent
1971
1972 =item sethostent STAYOPEN
1973
1974 =item setnetent STAYOPEN
1975
1976 =item setprotoent STAYOPEN
1977
1978 =item setservent STAYOPEN
1979
1980 =item endpwent
1981
1982 =item endgrent
1983
1984 =item endhostent
1985
1986 =item endnetent
1987
1988 =item endprotoent
1989
1990 =item endservent
1991
1992 These routines perform the same functions as their counterparts in the
1993 system library.  In list context, the return values from the
1994 various get routines are as follows:
1995
1996     ($name,$passwd,$uid,$gid,
1997        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1998     ($name,$passwd,$gid,$members) = getgr*
1999     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2000     ($name,$aliases,$addrtype,$net) = getnet*
2001     ($name,$aliases,$proto) = getproto*
2002     ($name,$aliases,$port,$proto) = getserv*
2003
2004 (If the entry doesn't exist you get a null list.)
2005
2006 The exact meaning of the $gcos field varies but it usually contains
2007 the real name of the user (as opposed to the login name) and other
2008 information pertaining to the user.  Beware, however, that in many
2009 system users are able to change this information and therefore it
2010 cannot be trusted and therefore the $gcos is tainted (see
2011 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2012 login shell, are also tainted, because of the same reason.
2013
2014 In scalar context, you get the name, unless the function was a
2015 lookup by name, in which case you get the other thing, whatever it is.
2016 (If the entry doesn't exist you get the undefined value.)  For example:
2017
2018     $uid   = getpwnam($name);
2019     $name  = getpwuid($num);
2020     $name  = getpwent();
2021     $gid   = getgrnam($name);
2022     $name  = getgrgid($num);
2023     $name  = getgrent();
2024     #etc.
2025
2026 In I<getpw*()> the fields $quota, $comment, and $expire are special
2027 cases in the sense that in many systems they are unsupported.  If the
2028 $quota is unsupported, it is an empty scalar.  If it is supported, it
2029 usually encodes the disk quota.  If the $comment field is unsupported,
2030 it is an empty scalar.  If it is supported it usually encodes some
2031 administrative comment about the user.  In some systems the $quota
2032 field may be $change or $age, fields that have to do with password
2033 aging.  In some systems the $comment field may be $class.  The $expire
2034 field, if present, encodes the expiration period of the account or the
2035 password.  For the availability and the exact meaning of these fields
2036 in your system, please consult your getpwnam(3) documentation and your
2037 F<pwd.h> file.  You can also find out from within Perl what your
2038 $quota and $comment fields mean and whether you have the $expire field
2039 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2040 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2041 files are only supported if your vendor has implemented them in the
2042 intuitive fashion that calling the regular C library routines gets the
2043 shadow versions if you're running under privilege or if there exists
2044 the shadow(3) functions as found in System V ( this includes Solaris
2045 and Linux.)  Those systems which implement a proprietary shadow password
2046 facility are unlikely to be supported.
2047
2048 The $members value returned by I<getgr*()> is a space separated list of
2049 the login names of the members of the group.
2050
2051 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2052 C, it will be returned to you via C<$?> if the function call fails.  The
2053 C<@addrs> value returned by a successful call is a list of the raw
2054 addresses returned by the corresponding system library call.  In the
2055 Internet domain, each address is four bytes long and you can unpack it
2056 by saying something like:
2057
2058     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2059
2060 The Socket library makes this slightly easier:
2061
2062     use Socket;
2063     $iaddr = inet_aton("127.1"); # or whatever address
2064     $name  = gethostbyaddr($iaddr, AF_INET);
2065
2066     # or going the other way
2067     $straddr = inet_ntoa($iaddr);
2068
2069 If you get tired of remembering which element of the return list
2070 contains which return value, by-name interfaces are provided
2071 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2072 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2073 and C<User::grent>.  These override the normal built-ins, supplying
2074 versions that return objects with the appropriate names
2075 for each field.  For example:
2076
2077    use File::stat;
2078    use User::pwent;
2079    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2080
2081 Even though it looks like they're the same method calls (uid),
2082 they aren't, because a C<File::stat> object is different from
2083 a C<User::pwent> object.
2084
2085 =item getsockname SOCKET
2086
2087 Returns the packed sockaddr address of this end of the SOCKET connection,
2088 in case you don't know the address because you have several different
2089 IPs that the connection might have come in on.
2090
2091     use Socket;
2092     $mysockaddr = getsockname(SOCK);
2093     ($port, $myaddr) = sockaddr_in($mysockaddr);
2094     printf "Connect to %s [%s]\n",
2095        scalar gethostbyaddr($myaddr, AF_INET),
2096        inet_ntoa($myaddr);
2097
2098 =item getsockopt SOCKET,LEVEL,OPTNAME
2099
2100 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2101 Options may exist at multiple protocol levels depending on the socket
2102 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2103 C<Socket> module) will exist. To query options at another level the
2104 protocol number of the appropriate protocol controlling the option
2105 should be supplied. For example, to indicate that an option is to be
2106 interpreted by the TCP protocol, LEVEL should be set to the protocol
2107 number of TCP, which you can get using getprotobyname.
2108
2109 The call returns a packed string representing the requested socket option,
2110 or C<undef> if there is an error (the error reason will be in $!). What
2111 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2112 your system documentation for details. A very common case however is that
2113 the option is an integer, in which case the result will be an packed
2114 integer which you can decode using unpack with the C<i> (or C<I>) format.
2115
2116 An example testing if Nagle's algorithm is turned on on a socket:
2117
2118     use Socket;
2119
2120     defined(my $tcp = getprotobyname("tcp"))
2121         or die "Could not determine the protocol number for tcp";
2122     # my $tcp = Socket::IPPROTO_TCP; # Alternative
2123     my $packed = getsockopt($socket, $tcp, Socket::TCP_NODELAY)
2124         or die "Could not query TCP_NODELAY SOCKEt option: $!";
2125     my $nodelay = unpack("I", $packed);
2126     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2127
2128
2129 =item glob EXPR
2130
2131 =item glob
2132
2133 In list context, returns a (possibly empty) list of filename expansions on
2134 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2135 scalar context, glob iterates through such filename expansions, returning
2136 undef when the list is exhausted. This is the internal function
2137 implementing the C<< <*.c> >> operator, but you can use it directly. If
2138 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2139 more detail in L<perlop/"I/O Operators">.
2140
2141 Beginning with v5.6.0, this operator is implemented using the standard
2142 C<File::Glob> extension.  See L<File::Glob> for details.
2143
2144 =item gmtime EXPR
2145
2146 Converts a time as returned by the time function to an 8-element list
2147 with the time localized for the standard Greenwich time zone.
2148 Typically used as follows:
2149
2150     #  0    1    2     3     4    5     6     7
2151     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2152                                             gmtime(time);
2153
2154 All list elements are numeric, and come straight out of the C `struct
2155 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2156 specified time.  $mday is the day of the month, and $mon is the month
2157 itself, in the range C<0..11> with 0 indicating January and 11
2158 indicating December.  $year is the number of years since 1900.  That
2159 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2160 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2161 the year, in the range C<0..364> (or C<0..365> in leap years.)
2162
2163 Note that the $year element is I<not> simply the last two digits of
2164 the year.  If you assume it is, then you create non-Y2K-compliant
2165 programs--and you wouldn't want to do that, would you?
2166
2167 The proper way to get a complete 4-digit year is simply:
2168
2169         $year += 1900;
2170
2171 And to get the last two digits of the year (e.g., '01' in 2001) do:
2172
2173         $year = sprintf("%02d", $year % 100);
2174
2175 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2176
2177 In scalar context, C<gmtime()> returns the ctime(3) value:
2178
2179     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2180
2181 If you need local time instead of GMT use the L</localtime> builtin. 
2182 See also the C<timegm> function provided by the C<Time::Local> module,
2183 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2184
2185 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2186 instead a Perl builtin.  To get somewhat similar but locale dependent date
2187 strings, see the example in L</localtime>.
2188
2189 =item goto LABEL
2190
2191 =item goto EXPR
2192
2193 =item goto &NAME
2194
2195 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2196 execution there.  It may not be used to go into any construct that
2197 requires initialization, such as a subroutine or a C<foreach> loop.  It
2198 also can't be used to go into a construct that is optimized away,
2199 or to get out of a block or subroutine given to C<sort>.
2200 It can be used to go almost anywhere else within the dynamic scope,
2201 including out of subroutines, but it's usually better to use some other
2202 construct such as C<last> or C<die>.  The author of Perl has never felt the
2203 need to use this form of C<goto> (in Perl, that is--C is another matter).
2204 (The difference being that C does not offer named loops combined with
2205 loop control.  Perl does, and this replaces most structured uses of C<goto>
2206 in other languages.)
2207
2208 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2209 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2210 necessarily recommended if you're optimizing for maintainability:
2211
2212     goto ("FOO", "BAR", "GLARCH")[$i];
2213
2214 The C<goto-&NAME> form is quite different from the other forms of
2215 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2216 doesn't have the stigma associated with other gotos.  Instead, it
2217 exits the current subroutine (losing any changes set by local()) and
2218 immediately calls in its place the named subroutine using the current
2219 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2220 load another subroutine and then pretend that the other subroutine had
2221 been called in the first place (except that any modifications to C<@_>
2222 in the current subroutine are propagated to the other subroutine.)
2223 After the C<goto>, not even C<caller> will be able to tell that this
2224 routine was called first.
2225
2226 NAME needn't be the name of a subroutine; it can be a scalar variable
2227 containing a code reference, or a block which evaluates to a code
2228 reference.
2229
2230 =item grep BLOCK LIST
2231
2232 =item grep EXPR,LIST
2233
2234 This is similar in spirit to, but not the same as, grep(1) and its
2235 relatives.  In particular, it is not limited to using regular expressions.
2236
2237 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2238 C<$_> to each element) and returns the list value consisting of those
2239 elements for which the expression evaluated to true.  In scalar
2240 context, returns the number of times the expression was true.
2241
2242     @foo = grep(!/^#/, @bar);    # weed out comments
2243
2244 or equivalently,
2245
2246     @foo = grep {!/^#/} @bar;    # weed out comments
2247
2248 Note that C<$_> is an alias to the list value, so it can be used to
2249 modify the elements of the LIST.  While this is useful and supported,
2250 it can cause bizarre results if the elements of LIST are not variables.
2251 Similarly, grep returns aliases into the original list, much as a for
2252 loop's index variable aliases the list elements.  That is, modifying an
2253 element of a list returned by grep (for example, in a C<foreach>, C<map>
2254 or another C<grep>) actually modifies the element in the original list.
2255 This is usually something to be avoided when writing clear code.
2256
2257 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2258 been declared with C<my $_>) then, in addition the be locally aliased to
2259 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2260 can't be seen from the outside, avoiding any potential side-effects.
2261
2262 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2263
2264 =item hex EXPR
2265
2266 =item hex
2267
2268 Interprets EXPR as a hex string and returns the corresponding value.
2269 (To convert strings that might start with either 0, 0x, or 0b, see
2270 L</oct>.)  If EXPR is omitted, uses C<$_>.
2271
2272     print hex '0xAf'; # prints '175'
2273     print hex 'aF';   # same
2274
2275 Hex strings may only represent integers.  Strings that would cause
2276 integer overflow trigger a warning.  Leading whitespace is not stripped,
2277 unlike oct().
2278
2279 =item import
2280
2281 There is no builtin C<import> function.  It is just an ordinary
2282 method (subroutine) defined (or inherited) by modules that wish to export
2283 names to another module.  The C<use> function calls the C<import> method
2284 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2285
2286 =item index STR,SUBSTR,POSITION
2287
2288 =item index STR,SUBSTR
2289
2290 The index function searches for one string within another, but without
2291 the wildcard-like behavior of a full regular-expression pattern match.
2292 It returns the position of the first occurrence of SUBSTR in STR at
2293 or after POSITION.  If POSITION is omitted, starts searching from the
2294 beginning of the string.  The return value is based at C<0> (or whatever
2295 you've set the C<$[> variable to--but don't do that).  If the substring
2296 is not found, returns one less than the base, ordinarily C<-1>.
2297
2298 =item int EXPR
2299
2300 =item int
2301
2302 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2303 You should not use this function for rounding: one because it truncates
2304 towards C<0>, and two because machine representations of floating point
2305 numbers can sometimes produce counterintuitive results.  For example,
2306 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2307 because it's really more like -268.99999999999994315658 instead.  Usually,
2308 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2309 functions will serve you better than will int().
2310
2311 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2312
2313 Implements the ioctl(2) function.  You'll probably first have to say
2314
2315     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2316
2317 to get the correct function definitions.  If F<ioctl.ph> doesn't
2318 exist or doesn't have the correct definitions you'll have to roll your
2319 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2320 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2321 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2322 written depending on the FUNCTION--a pointer to the string value of SCALAR
2323 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2324 has no string value but does have a numeric value, that value will be
2325 passed rather than a pointer to the string value.  To guarantee this to be
2326 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2327 functions may be needed to manipulate the values of structures used by
2328 C<ioctl>.
2329
2330 The return value of C<ioctl> (and C<fcntl>) is as follows:
2331
2332         if OS returns:          then Perl returns:
2333             -1                    undefined value
2334              0                  string "0 but true"
2335         anything else               that number
2336
2337 Thus Perl returns true on success and false on failure, yet you can
2338 still easily determine the actual value returned by the operating
2339 system:
2340
2341     $retval = ioctl(...) || -1;
2342     printf "System returned %d\n", $retval;
2343
2344 The special string C<"0 but true"> is exempt from B<-w> complaints
2345 about improper numeric conversions.
2346
2347 =item join EXPR,LIST
2348
2349 Joins the separate strings of LIST into a single string with fields
2350 separated by the value of EXPR, and returns that new string.  Example:
2351
2352     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2353
2354 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2355 first argument.  Compare L</split>.
2356
2357 =item keys HASH
2358
2359 Returns a list consisting of all the keys of the named hash.
2360 (In scalar context, returns the number of keys.)
2361
2362 The keys are returned in an apparently random order.  The actual
2363 random order is subject to change in future versions of perl, but it
2364 is guaranteed to be the same order as either the C<values> or C<each>
2365 function produces (given that the hash has not been modified).  Since
2366 Perl 5.8.1 the ordering is different even between different runs of
2367 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2368 Attacks">).
2369
2370 As a side effect, calling keys() resets the HASH's internal iterator,
2371 see L</each>. (In particular, calling keys() in void context resets
2372 the iterator with no other overhead.)
2373
2374 Here is yet another way to print your environment:
2375
2376     @keys = keys %ENV;
2377     @values = values %ENV;
2378     while (@keys) {
2379         print pop(@keys), '=', pop(@values), "\n";
2380     }
2381
2382 or how about sorted by key:
2383
2384     foreach $key (sort(keys %ENV)) {
2385         print $key, '=', $ENV{$key}, "\n";
2386     }
2387
2388 The returned values are copies of the original keys in the hash, so
2389 modifying them will not affect the original hash.  Compare L</values>.
2390
2391 To sort a hash by value, you'll need to use a C<sort> function.
2392 Here's a descending numeric sort of a hash by its values:
2393
2394     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2395         printf "%4d %s\n", $hash{$key}, $key;
2396     }
2397
2398 As an lvalue C<keys> allows you to increase the number of hash buckets
2399 allocated for the given hash.  This can gain you a measure of efficiency if
2400 you know the hash is going to get big.  (This is similar to pre-extending
2401 an array by assigning a larger number to $#array.)  If you say
2402
2403     keys %hash = 200;
2404
2405 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2406 in fact, since it rounds up to the next power of two.  These
2407 buckets will be retained even if you do C<%hash = ()>, use C<undef
2408 %hash> if you want to free the storage while C<%hash> is still in scope.
2409 You can't shrink the number of buckets allocated for the hash using
2410 C<keys> in this way (but you needn't worry about doing this by accident,
2411 as trying has no effect).
2412
2413 See also C<each>, C<values> and C<sort>.
2414
2415 =item kill SIGNAL, LIST
2416
2417 Sends a signal to a list of processes.  Returns the number of
2418 processes successfully signaled (which is not necessarily the
2419 same as the number actually killed).
2420
2421     $cnt = kill 1, $child1, $child2;
2422     kill 9, @goners;
2423
2424 If SIGNAL is zero, no signal is sent to the process.  This is a
2425 useful way to check that a child process is alive and hasn't changed
2426 its UID.  See L<perlport> for notes on the portability of this
2427 construct.
2428
2429 Unlike in the shell, if SIGNAL is negative, it kills
2430 process groups instead of processes.  (On System V, a negative I<PROCESS>
2431 number will also kill process groups, but that's not portable.)  That
2432 means you usually want to use positive not negative signals.  You may also
2433 use a signal name in quotes.
2434
2435 See L<perlipc/"Signals"> for more details.
2436
2437 =item last LABEL
2438
2439 =item last
2440
2441 The C<last> command is like the C<break> statement in C (as used in
2442 loops); it immediately exits the loop in question.  If the LABEL is
2443 omitted, the command refers to the innermost enclosing loop.  The
2444 C<continue> block, if any, is not executed:
2445
2446     LINE: while (<STDIN>) {
2447         last LINE if /^$/;      # exit when done with header
2448         #...
2449     }
2450
2451 C<last> cannot be used to exit a block which returns a value such as
2452 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2453 a grep() or map() operation.
2454
2455 Note that a block by itself is semantically identical to a loop
2456 that executes once.  Thus C<last> can be used to effect an early
2457 exit out of such a block.
2458
2459 See also L</continue> for an illustration of how C<last>, C<next>, and
2460 C<redo> work.
2461
2462 =item lc EXPR
2463
2464 =item lc
2465
2466 Returns a lowercased version of EXPR.  This is the internal function
2467 implementing the C<\L> escape in double-quoted strings.  Respects
2468 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2469 and L<perlunicode> for more details about locale and Unicode support.
2470
2471 If EXPR is omitted, uses C<$_>.
2472
2473 =item lcfirst EXPR
2474
2475 =item lcfirst
2476
2477 Returns the value of EXPR with the first character lowercased.  This
2478 is the internal function implementing the C<\l> escape in
2479 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2480 locale> in force.  See L<perllocale> and L<perlunicode> for more
2481 details about locale and Unicode support.
2482
2483 If EXPR is omitted, uses C<$_>.
2484
2485 =item length EXPR
2486
2487 =item length
2488
2489 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2490 omitted, returns length of C<$_>.  Note that this cannot be used on
2491 an entire array or hash to find out how many elements these have.
2492 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2493
2494 Note the I<characters>: if the EXPR is in Unicode, you will get the
2495 number of characters, not the number of bytes.  To get the length
2496 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2497
2498 =item link OLDFILE,NEWFILE
2499
2500 Creates a new filename linked to the old filename.  Returns true for
2501 success, false otherwise.
2502
2503 =item listen SOCKET,QUEUESIZE
2504
2505 Does the same thing that the listen system call does.  Returns true if
2506 it succeeded, false otherwise.  See the example in
2507 L<perlipc/"Sockets: Client/Server Communication">.
2508
2509 =item local EXPR
2510
2511 You really probably want to be using C<my> instead, because C<local> isn't
2512 what most people think of as "local".  See
2513 L<perlsub/"Private Variables via my()"> for details.
2514
2515 A local modifies the listed variables to be local to the enclosing
2516 block, file, or eval.  If more than one value is listed, the list must
2517 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2518 for details, including issues with tied arrays and hashes.
2519
2520 =item localtime EXPR
2521
2522 Converts a time as returned by the time function to a 9-element list
2523 with the time analyzed for the local time zone.  Typically used as
2524 follows:
2525
2526     #  0    1    2     3     4    5     6     7     8
2527     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2528                                                 localtime(time);
2529
2530 All list elements are numeric, and come straight out of the C `struct
2531 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2532 specified time.  $mday is the day of the month, and $mon is the month
2533 itself, in the range C<0..11> with 0 indicating January and 11
2534 indicating December.  $year is the number of years since 1900.  That
2535 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2536 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2537 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2538 is true if the specified time occurs during daylight savings time,
2539 false otherwise.
2540
2541 Note that the $year element is I<not> simply the last two digits of
2542 the year.  If you assume it is, then you create non-Y2K-compliant
2543 programs--and you wouldn't want to do that, would you?
2544
2545 The proper way to get a complete 4-digit year is simply:
2546
2547         $year += 1900;
2548
2549 And to get the last two digits of the year (e.g., '01' in 2001) do:
2550
2551         $year = sprintf("%02d", $year % 100);
2552
2553 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2554
2555 In scalar context, C<localtime()> returns the ctime(3) value:
2556
2557     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2558
2559 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2560 instead of local time use the L</gmtime> builtin. See also the
2561 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2562 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2563 and mktime(3) functions.
2564
2565 To get somewhat similar but locale dependent date strings, set up your
2566 locale environment variables appropriately (please see L<perllocale>) and
2567 try for example:
2568
2569     use POSIX qw(strftime);
2570     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2571     # or for GMT formatted appropriately for your locale:
2572     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2573
2574 Note that the C<%a> and C<%b>, the short forms of the day of the week
2575 and the month of the year, may not necessarily be three characters wide.
2576
2577 =item lock THING
2578
2579 This function places an advisory lock on a shared variable, or referenced
2580 object contained in I<THING> until the lock goes out of scope.
2581
2582 lock() is a "weak keyword" : this means that if you've defined a function
2583 by this name (before any calls to it), that function will be called
2584 instead. (However, if you've said C<use threads>, lock() is always a
2585 keyword.) See L<threads>.
2586
2587 =item log EXPR
2588
2589 =item log
2590
2591 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2592 returns log of C<$_>.  To get the log of another base, use basic algebra:
2593 The base-N log of a number is equal to the natural log of that number
2594 divided by the natural log of N.  For example:
2595
2596     sub log10 {
2597         my $n = shift;
2598         return log($n)/log(10);
2599     }
2600
2601 See also L</exp> for the inverse operation.
2602
2603 =item lstat EXPR
2604
2605 =item lstat
2606
2607 Does the same thing as the C<stat> function (including setting the
2608 special C<_> filehandle) but stats a symbolic link instead of the file
2609 the symbolic link points to.  If symbolic links are unimplemented on
2610 your system, a normal C<stat> is done.  For much more detailed
2611 information, please see the documentation for C<stat>.
2612
2613 If EXPR is omitted, stats C<$_>.
2614
2615 =item m//
2616
2617 The match operator.  See L<perlop>.
2618
2619 =item map BLOCK LIST
2620
2621 =item map EXPR,LIST
2622
2623 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2624 C<$_> to each element) and returns the list value composed of the
2625 results of each such evaluation.  In scalar context, returns the
2626 total number of elements so generated.  Evaluates BLOCK or EXPR in
2627 list context, so each element of LIST may produce zero, one, or
2628 more elements in the returned value.
2629
2630     @chars = map(chr, @nums);
2631
2632 translates a list of numbers to the corresponding characters.  And
2633
2634     %hash = map { getkey($_) => $_ } @array;
2635
2636 is just a funny way to write
2637
2638     %hash = ();
2639     foreach $_ (@array) {
2640         $hash{getkey($_)} = $_;
2641     }
2642
2643 Note that C<$_> is an alias to the list value, so it can be used to
2644 modify the elements of the LIST.  While this is useful and supported,
2645 it can cause bizarre results if the elements of LIST are not variables.
2646 Using a regular C<foreach> loop for this purpose would be clearer in
2647 most cases.  See also L</grep> for an array composed of those items of
2648 the original list for which the BLOCK or EXPR evaluates to true.
2649
2650 If C<$_> is lexical in the scope where the C<map> appears (because it has
2651 been declared with C<my $_>) then, in addition the be locally aliased to
2652 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2653 can't be seen from the outside, avoiding any potential side-effects.
2654
2655 C<{> starts both hash references and blocks, so C<map { ...> could be either
2656 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2657 ahead for the closing C<}> it has to take a guess at which its dealing with
2658 based what it finds just after the C<{>. Usually it gets it right, but if it
2659 doesn't it won't realize something is wrong until it gets to the C<}> and
2660 encounters the missing (or unexpected) comma. The syntax error will be
2661 reported close to the C<}> but you'll need to change something near the C<{>
2662 such as using a unary C<+> to give perl some help:
2663
2664     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2665     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2666     %hash = map { ("\L$_", 1) } @array  # this also works
2667     %hash = map {  lc($_), 1  } @array  # as does this.
2668     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2669
2670     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2671
2672 or to force an anon hash constructor use C<+{>
2673
2674    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2675
2676 and you get list of anonymous hashes each with only 1 entry.
2677
2678 =item mkdir FILENAME,MASK
2679
2680 =item mkdir FILENAME
2681
2682 Creates the directory specified by FILENAME, with permissions
2683 specified by MASK (as modified by C<umask>).  If it succeeds it
2684 returns true, otherwise it returns false and sets C<$!> (errno).
2685 If omitted, MASK defaults to 0777.
2686
2687 In general, it is better to create directories with permissive MASK,
2688 and let the user modify that with their C<umask>, than it is to supply
2689 a restrictive MASK and give the user no way to be more permissive.
2690 The exceptions to this rule are when the file or directory should be
2691 kept private (mail files, for instance).  The perlfunc(1) entry on
2692 C<umask> discusses the choice of MASK in more detail.
2693
2694 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2695 number of trailing slashes.  Some operating and filesystems do not get
2696 this right, so Perl automatically removes all trailing slashes to keep
2697 everyone happy.
2698
2699 =item msgctl ID,CMD,ARG
2700
2701 Calls the System V IPC function msgctl(2).  You'll probably have to say
2702
2703     use IPC::SysV;
2704
2705 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2706 then ARG must be a variable which will hold the returned C<msqid_ds>
2707 structure.  Returns like C<ioctl>: the undefined value for error,
2708 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2709 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2710
2711 =item msgget KEY,FLAGS
2712
2713 Calls the System V IPC function msgget(2).  Returns the message queue
2714 id, or the undefined value if there is an error.  See also
2715 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2716
2717 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2718
2719 Calls the System V IPC function msgrcv to receive a message from
2720 message queue ID into variable VAR with a maximum message size of
2721 SIZE.  Note that when a message is received, the message type as a
2722 native long integer will be the first thing in VAR, followed by the
2723 actual message.  This packing may be opened with C<unpack("l! a*")>.
2724 Taints the variable.  Returns true if successful, or false if there is
2725 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2726 C<IPC::SysV::Msg> documentation.
2727
2728 =item msgsnd ID,MSG,FLAGS
2729
2730 Calls the System V IPC function msgsnd to send the message MSG to the
2731 message queue ID.  MSG must begin with the native long integer message
2732 type, and be followed by the length of the actual message, and finally
2733 the message itself.  This kind of packing can be achieved with
2734 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2735 or false if there is an error.  See also C<IPC::SysV>
2736 and C<IPC::SysV::Msg> documentation.
2737
2738 =item my EXPR
2739
2740 =item my TYPE EXPR
2741
2742 =item my EXPR : ATTRS
2743
2744 =item my TYPE EXPR : ATTRS
2745
2746 A C<my> declares the listed variables to be local (lexically) to the
2747 enclosing block, file, or C<eval>.  If more than one value is listed,
2748 the list must be placed in parentheses.
2749
2750 The exact semantics and interface of TYPE and ATTRS are still
2751 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2752 and attributes are handled using the C<attributes> pragma, or starting
2753 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2754 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2755 L<attributes>, and L<Attribute::Handlers>.
2756
2757 =item next LABEL
2758
2759 =item next
2760
2761 The C<next> command is like the C<continue> statement in C; it starts
2762 the next iteration of the loop:
2763
2764     LINE: while (<STDIN>) {
2765         next LINE if /^#/;      # discard comments
2766         #...
2767     }
2768
2769 Note that if there were a C<continue> block on the above, it would get
2770 executed even on discarded lines.  If the LABEL is omitted, the command
2771 refers to the innermost enclosing loop.
2772
2773 C<next> cannot be used to exit a block which returns a value such as
2774 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2775 a grep() or map() operation.
2776
2777 Note that a block by itself is semantically identical to a loop
2778 that executes once.  Thus C<next> will exit such a block early.
2779
2780 See also L</continue> for an illustration of how C<last>, C<next>, and
2781 C<redo> work.
2782
2783 =item no Module VERSION LIST
2784
2785 =item no Module VERSION
2786
2787 =item no Module LIST
2788
2789 =item no Module
2790
2791 See the C<use> function, of which C<no> is the opposite.
2792
2793 =item oct EXPR
2794
2795 =item oct
2796
2797 Interprets EXPR as an octal string and returns the corresponding
2798 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2799 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2800 binary string.  Leading whitespace is ignored in all three cases.)
2801 The following will handle decimal, binary, octal, and hex in the standard
2802 Perl or C notation:
2803
2804     $val = oct($val) if $val =~ /^0/;
2805
2806 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2807 in octal), use sprintf() or printf():
2808
2809     $perms = (stat("filename"))[2] & 07777;
2810     $oct_perms = sprintf "%lo", $perms;
2811
2812 The oct() function is commonly used when a string such as C<644> needs
2813 to be converted into a file mode, for example. (Although perl will
2814 automatically convert strings into numbers as needed, this automatic
2815 conversion assumes base 10.)
2816
2817 =item open FILEHANDLE,EXPR
2818
2819 =item open FILEHANDLE,MODE,EXPR
2820
2821 =item open FILEHANDLE,MODE,EXPR,LIST
2822
2823 =item open FILEHANDLE,MODE,REFERENCE
2824
2825 =item open FILEHANDLE
2826
2827 Opens the file whose filename is given by EXPR, and associates it with
2828 FILEHANDLE.
2829
2830 (The following is a comprehensive reference to open(): for a gentler
2831 introduction you may consider L<perlopentut>.)
2832
2833 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2834 the variable is assigned a reference to a new anonymous filehandle,
2835 otherwise if FILEHANDLE is an expression, its value is used as the name of
2836 the real filehandle wanted.  (This is considered a symbolic reference, so
2837 C<use strict 'refs'> should I<not> be in effect.)
2838
2839 If EXPR is omitted, the scalar variable of the same name as the
2840 FILEHANDLE contains the filename.  (Note that lexical variables--those
2841 declared with C<my>--will not work for this purpose; so if you're
2842 using C<my>, specify EXPR in your call to open.)
2843
2844 If three or more arguments are specified then the mode of opening and
2845 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2846 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2847 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2848 the file is opened for appending, again being created if necessary.
2849
2850 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2851 indicate that you want both read and write access to the file; thus
2852 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2853 '+>' >> mode would clobber the file first.  You can't usually use
2854 either read-write mode for updating textfiles, since they have
2855 variable length records.  See the B<-i> switch in L<perlrun> for a
2856 better approach.  The file is created with permissions of C<0666>
2857 modified by the process' C<umask> value.
2858
2859 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2860 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2861
2862 In the 2-arguments (and 1-argument) form of the call the mode and
2863 filename should be concatenated (in this order), possibly separated by
2864 spaces.  It is possible to omit the mode in these forms if the mode is
2865 C<< '<' >>.
2866
2867 If the filename begins with C<'|'>, the filename is interpreted as a
2868 command to which output is to be piped, and if the filename ends with a
2869 C<'|'>, the filename is interpreted as a command which pipes output to
2870 us.  See L<perlipc/"Using open() for IPC">
2871 for more examples of this.  (You are not allowed to C<open> to a command
2872 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2873 and L<perlipc/"Bidirectional Communication with Another Process">
2874 for alternatives.)
2875
2876 For three or more arguments if MODE is C<'|-'>, the filename is
2877 interpreted as a command to which output is to be piped, and if MODE
2878 is C<'-|'>, the filename is interpreted as a command which pipes
2879 output to us.  In the 2-arguments (and 1-argument) form one should
2880 replace dash (C<'-'>) with the command.
2881 See L<perlipc/"Using open() for IPC"> for more examples of this.
2882 (You are not allowed to C<open> to a command that pipes both in I<and>
2883 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2884 L<perlipc/"Bidirectional Communication"> for alternatives.)
2885
2886 In the three-or-more argument form of pipe opens, if LIST is specified
2887 (extra arguments after the command name) then LIST becomes arguments
2888 to the command invoked if the platform supports it.  The meaning of
2889 C<open> with more than three arguments for non-pipe modes is not yet
2890 specified. Experimental "layers" may give extra LIST arguments
2891 meaning.
2892
2893 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2894 and opening C<< '>-' >> opens STDOUT.
2895
2896 You may use the three-argument form of open to specify IO "layers"
2897 (sometimes also referred to as "disciplines") to be applied to the handle
2898 that affect how the input and output are processed (see L<open> and
2899 L<PerlIO> for more details). For example
2900
2901   open(FH, "<:utf8", "file")
2902
2903 will open the UTF-8 encoded file containing Unicode characters,
2904 see L<perluniintro>. (Note that if layers are specified in the
2905 three-arg form then default layers set by the C<open> pragma are
2906 ignored.)
2907
2908 Open returns nonzero upon success, the undefined value otherwise.  If
2909 the C<open> involved a pipe, the return value happens to be the pid of
2910 the subprocess.
2911
2912 If you're running Perl on a system that distinguishes between text
2913 files and binary files, then you should check out L</binmode> for tips
2914 for dealing with this.  The key distinction between systems that need
2915 C<binmode> and those that don't is their text file formats.  Systems
2916 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2917 character, and which encode that character in C as C<"\n">, do not
2918 need C<binmode>.  The rest need it.
2919
2920 When opening a file, it's usually a bad idea to continue normal execution
2921 if the request failed, so C<open> is frequently used in connection with
2922 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2923 where you want to make a nicely formatted error message (but there are
2924 modules that can help with that problem)) you should always check
2925 the return value from opening a file.  The infrequent exception is when
2926 working with an unopened filehandle is actually what you want to do.
2927
2928 As a special case the 3 arg form with a read/write mode and the third
2929 argument being C<undef>:
2930
2931     open(TMP, "+>", undef) or die ...
2932
2933 opens a filehandle to an anonymous temporary file.  Also using "+<"
2934 works for symmetry, but you really should consider writing something
2935 to the temporary file first.  You will need to seek() to do the
2936 reading.
2937
2938 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2939 changed this (ie Configure -Uuseperlio), you can open file handles to
2940 "in memory" files held in Perl scalars via:
2941
2942     open($fh, '>', \$variable) || ..
2943
2944 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2945 file, you have to close it first:
2946
2947     close STDOUT;
2948     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2949
2950 Examples:
2951
2952     $ARTICLE = 100;
2953     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2954     while (<ARTICLE>) {...
2955
2956     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2957     # if the open fails, output is discarded
2958
2959     open(DBASE, '+<', 'dbase.mine')             # open for update
2960         or die "Can't open 'dbase.mine' for update: $!";
2961
2962     open(DBASE, '+<dbase.mine')                 # ditto
2963         or die "Can't open 'dbase.mine' for update: $!";
2964
2965     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2966         or die "Can't start caesar: $!";
2967
2968     open(ARTICLE, "caesar <$article |")         # ditto
2969         or die "Can't start caesar: $!";
2970
2971     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
2972         or die "Can't start sort: $!";
2973
2974     # in memory files
2975     open(MEMORY,'>', \$var)
2976         or die "Can't open memory file: $!";
2977     print MEMORY "foo!\n";                      # output will end up in $var
2978
2979     # process argument list of files along with any includes
2980
2981     foreach $file (@ARGV) {
2982         process($file, 'fh00');
2983     }
2984
2985     sub process {
2986         my($filename, $input) = @_;
2987         $input++;               # this is a string increment
2988         unless (open($input, $filename)) {
2989             print STDERR "Can't open $filename: $!\n";
2990             return;
2991         }
2992
2993         local $_;
2994         while (<$input>) {              # note use of indirection
2995             if (/^#include "(.*)"/) {
2996                 process($1, $input);
2997                 next;
2998             }
2999             #...                # whatever
3000         }
3001     }
3002
3003 See L<perliol/> for detailed info on PerlIO.
3004
3005 You may also, in the Bourne shell tradition, specify an EXPR beginning
3006 with C<< '>&' >>, in which case the rest of the string is interpreted
3007 as the name of a filehandle (or file descriptor, if numeric) to be
3008 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3009 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3010 The mode you specify should match the mode of the original filehandle.
3011 (Duping a filehandle does not take into account any existing contents
3012 of IO buffers.) If you use the 3 arg form then you can pass either a
3013 number, the name of a filehandle or the normal "reference to a glob".
3014
3015 Here is a script that saves, redirects, and restores C<STDOUT> and
3016 C<STDERR> using various methods:
3017
3018     #!/usr/bin/perl
3019     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3020     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3021
3022     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3023     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3024
3025     select STDERR; $| = 1;      # make unbuffered
3026     select STDOUT; $| = 1;      # make unbuffered
3027
3028     print STDOUT "stdout 1\n";  # this works for
3029     print STDERR "stderr 1\n";  # subprocesses too
3030
3031     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3032     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3033
3034     print STDOUT "stdout 2\n";
3035     print STDERR "stderr 2\n";
3036
3037 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3038 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3039 that file descriptor (and not call L<dup(2)>); this is more
3040 parsimonious of file descriptors.  For example:
3041
3042     # open for input, reusing the fileno of $fd
3043     open(FILEHANDLE, "<&=$fd")
3044
3045 or
3046
3047     open(FILEHANDLE, "<&=", $fd)
3048
3049 or
3050
3051     # open for append, using the fileno of OLDFH
3052     open(FH, ">>&=", OLDFH)
3053
3054 or
3055
3056     open(FH, ">>&=OLDFH")
3057
3058 Being parsimonious on filehandles is also useful (besides being
3059 parsimonious) for example when something is dependent on file
3060 descriptors, like for example locking using flock().  If you do just
3061 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3062 descriptor as B, and therefore flock(A) will not flock(B), and vice
3063 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3064 the same file descriptor.
3065
3066 Note that if you are using Perls older than 5.8.0, Perl will be using
3067 the standard C libraries' fdopen() to implement the "=" functionality.
3068 On many UNIX systems fdopen() fails when file descriptors exceed a
3069 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3070 most often the default.
3071
3072 You can see whether Perl has been compiled with PerlIO or not by
3073 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3074 is C<define>, you have PerlIO, otherwise you don't.
3075
3076 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3077 with 2-arguments (or 1-argument) form of open(), then
3078 there is an implicit fork done, and the return value of open is the pid
3079 of the child within the parent process, and C<0> within the child
3080 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3081 The filehandle behaves normally for the parent, but i/o to that
3082 filehandle is piped from/to the STDOUT/STDIN of the child process.
3083 In the child process the filehandle isn't opened--i/o happens from/to
3084 the new STDOUT or STDIN.  Typically this is used like the normal
3085 piped open when you want to exercise more control over just how the
3086 pipe command gets executed, such as when you are running setuid, and
3087 don't want to have to scan shell commands for metacharacters.
3088 The following triples are more or less equivalent:
3089
3090     open(FOO, "|tr '[a-z]' '[A-Z]'");
3091     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3092     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3093     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3094
3095     open(FOO, "cat -n '$file'|");
3096     open(FOO, '-|', "cat -n '$file'");
3097     open(FOO, '-|') || exec 'cat', '-n', $file;
3098     open(FOO, '-|', "cat", '-n', $file);
3099
3100 The last example in each block shows the pipe as "list form", which is
3101 not yet supported on all platforms.  A good rule of thumb is that if
3102 your platform has true C<fork()> (in other words, if your platform is
3103 UNIX) you can use the list form.
3104
3105 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3106
3107 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3108 output before any operation that may do a fork, but this may not be
3109 supported on some platforms (see L<perlport>).  To be safe, you may need
3110 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3111 of C<IO::Handle> on any open handles.
3112
3113 On systems that support a close-on-exec flag on files, the flag will
3114 be set for the newly opened file descriptor as determined by the value
3115 of $^F.  See L<perlvar/$^F>.
3116
3117 Closing any piped filehandle causes the parent process to wait for the
3118 child to finish, and returns the status value in C<$?>.
3119
3120 The filename passed to 2-argument (or 1-argument) form of open() will
3121 have leading and trailing whitespace deleted, and the normal
3122 redirection characters honored.  This property, known as "magic open",
3123 can often be used to good effect.  A user could specify a filename of
3124 F<"rsh cat file |">, or you could change certain filenames as needed:
3125
3126     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3127     open(FH, $filename) or die "Can't open $filename: $!";
3128
3129 Use 3-argument form to open a file with arbitrary weird characters in it,
3130
3131     open(FOO, '<', $file);
3132
3133 otherwise it's necessary to protect any leading and trailing whitespace:
3134
3135     $file =~ s#^(\s)#./$1#;
3136     open(FOO, "< $file\0");
3137
3138 (this may not work on some bizarre filesystems).  One should
3139 conscientiously choose between the I<magic> and 3-arguments form
3140 of open():
3141
3142     open IN, $ARGV[0];
3143
3144 will allow the user to specify an argument of the form C<"rsh cat file |">,
3145 but will not work on a filename which happens to have a trailing space, while
3146
3147     open IN, '<', $ARGV[0];
3148
3149 will have exactly the opposite restrictions.
3150
3151 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3152 should use the C<sysopen> function, which involves no such magic (but
3153 may use subtly different filemodes than Perl open(), which is mapped
3154 to C fopen()).  This is
3155 another way to protect your filenames from interpretation.  For example:
3156
3157     use IO::Handle;
3158     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3159         or die "sysopen $path: $!";
3160     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3161     print HANDLE "stuff $$\n";
3162     seek(HANDLE, 0, 0);
3163     print "File contains: ", <HANDLE>;
3164
3165 Using the constructor from the C<IO::Handle> package (or one of its
3166 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3167 filehandles that have the scope of whatever variables hold references to
3168 them, and automatically close whenever and however you leave that scope:
3169
3170     use IO::File;
3171     #...
3172     sub read_myfile_munged {
3173         my $ALL = shift;
3174         my $handle = new IO::File;
3175         open($handle, "myfile") or die "myfile: $!";
3176         $first = <$handle>
3177             or return ();     # Automatically closed here.
3178         mung $first or die "mung failed";       # Or here.
3179         return $first, <$handle> if $ALL;       # Or here.
3180         $first;                                 # Or here.
3181     }
3182
3183 See L</seek> for some details about mixing reading and writing.
3184
3185 =item opendir DIRHANDLE,EXPR
3186
3187 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3188 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3189 DIRHANDLE may be an expression whose value can be used as an indirect
3190 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3191 scalar variable (or array or hash element), the variable is assigned a
3192 reference to a new anonymous dirhandle.
3193 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3194
3195 =item ord EXPR
3196
3197 =item ord
3198
3199 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3200 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3201 uses C<$_>.
3202
3203 For the reverse, see L</chr>.
3204 See L<perlunicode> and L<encoding> for more about Unicode.
3205
3206 =item our EXPR
3207
3208 =item our EXPR TYPE
3209
3210 =item our EXPR : ATTRS
3211
3212 =item our TYPE EXPR : ATTRS
3213
3214 An C<our> declares the listed variables to be valid globals within
3215 the enclosing block, file, or C<eval>.  That is, it has the same
3216 scoping rules as a "my" declaration, but does not create a local
3217 variable.  If more than one value is listed, the list must be placed
3218 in parentheses.  The C<our> declaration has no semantic effect unless
3219 "use strict vars" is in effect, in which case it lets you use the
3220 declared global variable without qualifying it with a package name.
3221 (But only within the lexical scope of the C<our> declaration.  In this
3222 it differs from "use vars", which is package scoped.)
3223
3224 An C<our> declaration declares a global variable that will be visible
3225 across its entire lexical scope, even across package boundaries.  The
3226 package in which the variable is entered is determined at the point
3227 of the declaration, not at the point of use.  This means the following
3228 behavior holds:
3229
3230     package Foo;
3231     our $bar;           # declares $Foo::bar for rest of lexical scope
3232     $bar = 20;
3233
3234     package Bar;
3235     print $bar;         # prints 20
3236
3237 Multiple C<our> declarations in the same lexical scope are allowed
3238 if they are in different packages.  If they happened to be in the same
3239 package, Perl will emit warnings if you have asked for them.
3240
3241     use warnings;
3242     package Foo;
3243     our $bar;           # declares $Foo::bar for rest of lexical scope
3244     $bar = 20;
3245
3246     package Bar;
3247     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3248     print $bar;         # prints 30
3249
3250     our $bar;           # emits warning
3251
3252 An C<our> declaration may also have a list of attributes associated
3253 with it.
3254
3255 The exact semantics and interface of TYPE and ATTRS are still
3256 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3257 and attributes are handled using the C<attributes> pragma, or starting
3258 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3259 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3260 L<attributes>, and L<Attribute::Handlers>.
3261
3262 The only currently recognized C<our()> attribute is C<unique> which
3263 indicates that a single copy of the global is to be used by all
3264 interpreters should the program happen to be running in a
3265 multi-interpreter environment. (The default behaviour would be for
3266 each interpreter to have its own copy of the global.)  Examples:
3267
3268     our @EXPORT : unique = qw(foo);
3269     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3270     our $VERSION : unique = "1.00";
3271
3272 Note that this attribute also has the effect of making the global
3273 readonly when the first new interpreter is cloned (for example,
3274 when the first new thread is created).
3275
3276 Multi-interpreter environments can come to being either through the
3277 fork() emulation on Windows platforms, or by embedding perl in a
3278 multi-threaded application.  The C<unique> attribute does nothing in
3279 all other environments.
3280
3281 Warning: the current implementation of this attribute operates on the
3282 typeglob associated with the variable; this means that C<our $x : unique>
3283 also has the effect of C<our @x : unique; our %x : unique>. This may be
3284 subject to change.
3285
3286 =item pack TEMPLATE,LIST
3287
3288 Takes a LIST of values and converts it into a string using the rules
3289 given by the TEMPLATE.  The resulting string is the concatenation of
3290 the converted values.  Typically, each converted value looks
3291 like its machine-level representation.  For example, on 32-bit machines
3292 a converted integer may be represented by a sequence of 4 bytes.
3293
3294 The TEMPLATE is a sequence of characters that give the order and type
3295 of values, as follows:
3296
3297     a   A string with arbitrary binary data, will be null padded.
3298     A   A text (ASCII) string, will be space padded.
3299     Z   A null terminated (ASCIZ) string, will be null padded.
3300
3301     b   A bit string (ascending bit order inside each byte, like vec()).
3302     B   A bit string (descending bit order inside each byte).
3303     h   A hex string (low nybble first).
3304     H   A hex string (high nybble first).
3305
3306     c   A signed char (8-bit) value.
3307     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3308
3309     s   A signed short (16-bit) value.
3310     S   An unsigned short value.
3311
3312     l   A signed long (32-bit) value.
3313     L   An unsigned long value.
3314
3315     q   A signed quad (64-bit) value.
3316     Q   An unsigned quad value.
3317           (Quads are available only if your system supports 64-bit
3318            integer values _and_ if Perl has been compiled to support those.
3319            Causes a fatal error otherwise.)
3320
3321     i   A signed integer value.
3322     I   A unsigned integer value.
3323           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3324            size depends on what a local C compiler calls 'int'.)
3325  
3326     n   An unsigned short (16-bit) in "network" (big-endian) order.
3327     N   An unsigned long (32-bit) in "network" (big-endian) order.
3328     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3329     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3330
3331     j   A Perl internal signed integer value (IV).
3332     J   A Perl internal unsigned integer value (UV).
3333
3334     f   A single-precision float in the native format.
3335     d   A double-precision float in the native format.
3336
3337     F   A Perl internal floating point value (NV) in the native format
3338     D   A long double-precision float in the native format.
3339           (Long doubles are available only if your system supports long
3340            double values _and_ if Perl has been compiled to support those.
3341            Causes a fatal error otherwise.)
3342
3343     p   A pointer to a null-terminated string.
3344     P   A pointer to a structure (fixed-length string).
3345
3346     u   A uuencoded string.
3347     U   A Unicode character number.  Encodes to UTF-8 internally
3348         (or UTF-EBCDIC in EBCDIC platforms).
3349
3350     w   A BER compressed integer.  Its bytes represent an unsigned
3351         integer in base 128, most significant digit first, with as
3352         few digits as possible.  Bit eight (the high bit) is set
3353         on each byte except the last.
3354
3355     x   A null byte.
3356     X   Back up a byte.
3357     @   Null fill to absolute position, counted from the start of
3358         the innermost ()-group.
3359     (   Start of a ()-group.
3360
3361 Some letters in the TEMPLATE may optionally be followed by one or
3362 more of these modifiers (the second column lists the letters for
3363 which the modifier is valid):
3364
3365     !   sSlLiI     Forces native (short, long, int) sizes instead
3366                    of fixed (16-/32-bit) sizes.
3367
3368         xX         Make x and X act as alignment commands.
3369
3370         nNvV       Treat integers as signed instead of unsigned.
3371
3372     >   sSiIlLqQ   Force big-endian byte-order on the type.
3373         jJfFdDpP   (The "big end" touches the construct.)
3374
3375     <   sSiIlLqQ   Force little-endian byte-order on the type.
3376         jJfFdDpP   (The "little end" touches the construct.)
3377
3378 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3379 in which case they force a certain byte-order on all components of
3380 that group, including subgroups.
3381
3382 The following rules apply:
3383
3384 =over 8
3385
3386 =item *
3387
3388 Each letter may optionally be followed by a number giving a repeat
3389 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3390 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3391 many values from the LIST.  A C<*> for the repeat count means to use
3392 however many items are left, except for C<@>, C<x>, C<X>, where it is
3393 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3394 is the same).  A numeric repeat count may optionally be enclosed in
3395 brackets, as in C<pack 'C[80]', @arr>.
3396
3397 One can replace the numeric repeat count by a template enclosed in brackets;
3398 then the packed length of this template in bytes is used as a count.
3399 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3400 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3401 If the template in brackets contains alignment commands (such as C<x![d]>),
3402 its packed length is calculated as if the start of the template has the maximal
3403 possible alignment.
3404
3405 When used with C<Z>, C<*> results in the addition of a trailing null
3406 byte (so the packed result will be one longer than the byte C<length>
3407 of the item).
3408
3409 The repeat count for C<u> is interpreted as the maximal number of bytes
3410 to encode per line of output, with 0 and 1 replaced by 45.
3411
3412 =item *
3413
3414 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3415 string of length count, padding with nulls or spaces as necessary.  When
3416 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3417 after the first null, and C<a> returns data verbatim.  When packing,
3418 C<a>, and C<Z> are equivalent.
3419
3420 If the value-to-pack is too long, it is truncated.  If too long and an
3421 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3422 by a null byte.  Thus C<Z> always packs a trailing null byte under
3423 all circumstances.
3424
3425 =item *
3426
3427 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3428 Each byte of the input field of pack() generates 1 bit of the result.
3429 Each result bit is based on the least-significant bit of the corresponding
3430 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3431 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3432
3433 Starting from the beginning of the input string of pack(), each 8-tuple
3434 of bytes is converted to 1 byte of output.  With format C<b>
3435 the first byte of the 8-tuple determines the least-significant bit of a
3436 byte, and with format C<B> it determines the most-significant bit of
3437 a byte.
3438
3439 If the length of the input string is not exactly divisible by 8, the
3440 remainder is packed as if the input string were padded by null bytes
3441 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3442
3443 If the input string of pack() is longer than needed, extra bytes are ignored.
3444 A C<*> for the repeat count of pack() means to use all the bytes of
3445 the input field.  On unpack()ing the bits are converted to a string
3446 of C<"0">s and C<"1">s.
3447
3448 =item *
3449
3450 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3451 representable as hexadecimal digits, 0-9a-f) long.
3452
3453 Each byte of the input field of pack() generates 4 bits of the result.
3454 For non-alphabetical bytes the result is based on the 4 least-significant
3455 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3456 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3457 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3458 is compatible with the usual hexadecimal digits, so that C<"a"> and
3459 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3460 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3461
3462 Starting from the beginning of the input string of pack(), each pair
3463 of bytes is converted to 1 byte of output.  With format C<h> the
3464 first byte of the pair determines the least-significant nybble of the
3465 output byte, and with format C<H> it determines the most-significant
3466 nybble.
3467
3468 If the length of the input string is not even, it behaves as if padded
3469 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3470 nybbles are ignored.
3471
3472 If the input string of pack() is longer than needed, extra bytes are ignored.
3473 A C<*> for the repeat count of pack() means to use all the bytes of
3474 the input field.  On unpack()ing the bits are converted to a string
3475 of hexadecimal digits.
3476
3477 =item *
3478
3479 The C<p> type packs a pointer to a null-terminated string.  You are
3480 responsible for ensuring the string is not a temporary value (which can
3481 potentially get deallocated before you get around to using the packed result).
3482 The C<P> type packs a pointer to a structure of the size indicated by the
3483 length.  A NULL pointer is created if the corresponding value for C<p> or
3484 C<P> is C<undef>, similarly for unpack().
3485
3486 If your system has a strange pointer size (i.e. a pointer is neither as
3487 big as an int nor as big as a long), it may not be possible to pack or
3488 unpack pointers in big- or little-endian byte order.  Attempting to do
3489 so will result in a fatal error.
3490
3491 =item *
3492
3493 The C</> template character allows packing and unpacking of strings where
3494 the packed structure contains a byte count followed by the string itself.
3495 You write I<length-item>C</>I<string-item>.
3496
3497 The I<length-item> can be any C<pack> template letter, and describes
3498 how the length value is packed.  The ones likely to be of most use are
3499 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3500 SNMP) and C<N> (for Sun XDR).
3501
3502 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3503 C<"Z*">. For C<unpack> the length of the string is obtained from the
3504 I<length-item>, but if you put in the '*' it will be ignored. For all other
3505 codes, C<unpack> applies the length value to the next item, which must not
3506 have a repeat count.
3507
3508     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3509     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3510     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3511
3512 The I<length-item> is not returned explicitly from C<unpack>.
3513
3514 Adding a count to the I<length-item> letter is unlikely to do anything
3515 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3516 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3517 which Perl does not regard as legal in numeric strings.
3518
3519 =item *
3520
3521 The integer types C<s>, C<S>, C<l>, and C<L> may be
3522 followed by a C<!> modifier to signify native shorts or
3523 longs--as you can see from above for example a bare C<l> does mean
3524 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3525 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3526 see whether using C<!> makes any difference by
3527
3528         print length(pack("s")), " ", length(pack("s!")), "\n";
3529         print length(pack("l")), " ", length(pack("l!")), "\n";
3530
3531 C<i!> and C<I!> also work but only because of completeness;
3532 they are identical to C<i> and C<I>.
3533
3534 The actual sizes (in bytes) of native shorts, ints, longs, and long
3535 longs on the platform where Perl was built are also available via
3536 L<Config>:
3537
3538        use Config;
3539        print $Config{shortsize},    "\n";
3540        print $Config{intsize},      "\n";
3541        print $Config{longsize},     "\n";
3542        print $Config{longlongsize}, "\n";
3543
3544 (The C<$Config{longlongsize}> will be undefined if your system does
3545 not support long longs.)
3546
3547 =item *
3548
3549 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3550 are inherently non-portable between processors and operating systems
3551 because they obey the native byteorder and endianness.  For example a
3552 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3553 (arranged in and handled by the CPU registers) into bytes as
3554
3555         0x12 0x34 0x56 0x78     # big-endian
3556         0x78 0x56 0x34 0x12     # little-endian
3557
3558 Basically, the Intel and VAX CPUs are little-endian, while everybody
3559 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3560 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3561 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3562 mode.
3563
3564 The names `big-endian' and `little-endian' are comic references to
3565 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3566 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3567 the egg-eating habits of the Lilliputians.
3568
3569 Some systems may have even weirder byte orders such as
3570
3571         0x56 0x78 0x12 0x34
3572         0x34 0x12 0x78 0x56
3573
3574 You can see your system's preference with
3575
3576         print join(" ", map { sprintf "%#02x", $_ }
3577                             unpack("C*",pack("L",0x12345678))), "\n";
3578
3579 The byteorder on the platform where Perl was built is also available
3580 via L<Config>:
3581
3582         use Config;
3583         print $Config{byteorder}, "\n";
3584
3585 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3586 and C<'87654321'> are big-endian.
3587
3588 If you want portable packed integers you can either use the formats
3589 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3590 modifiers.  These modifiers are only available as of perl 5.9.2.
3591 See also L<perlport>.
3592
3593 =item *
3594
3595 All integer and floating point formats as well as C<p> and C<P> and
3596 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3597 to force big- or little- endian byte-order, respectively.
3598 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3599 signed integers, 64-bit integers and floating point values.  However,
3600 there are some things to keep in mind.
3601
3602 Exchanging signed integers between different platforms only works
3603 if all platforms store them in the same format.  Most platforms store
3604 signed integers in two's complement, so usually this is not an issue.
3605
3606 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3607 formats on big- or little-endian machines.  Otherwise, attempting to
3608 do so will result in a fatal error.
3609
3610 Forcing big- or little-endian byte-order on floating point values for
3611 data exchange can only work if all platforms are using the same
3612 binary representation (e.g. IEEE floating point format).  Even if all
3613 platforms are using IEEE, there may be subtle differences.  Being able
3614 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3615 but also very dangerous if you don't know exactly what you're doing.
3616 It is definetely not a general way to portably store floating point
3617 values.
3618
3619 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3620 all types inside the group that accept the byte-order modifiers,
3621 including all subgroups.  It will silently be ignored for all other
3622 types.  You are not allowed to override the byte-order within a group
3623 that already has a byte-order modifier suffix.
3624
3625 =item *
3626
3627 Real numbers (floats and doubles) are in the native machine format only;
3628 due to the multiplicity of floating formats around, and the lack of a
3629 standard "network" representation, no facility for interchange has been
3630 made.  This means that packed floating point data written on one machine
3631 may not be readable on another - even if both use IEEE floating point
3632 arithmetic (as the endian-ness of the memory representation is not part
3633 of the IEEE spec).  See also L<perlport>.
3634
3635 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3636 modifiers to force big- or little-endian byte-order on floating point values.
3637
3638 Note that Perl uses doubles (or long doubles, if configured) internally for
3639 all numeric calculation, and converting from double into float and thence back
3640 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3641 will not in general equal $foo).
3642
3643 =item *
3644
3645 If the pattern begins with a C<U>, the resulting string will be
3646 treated as UTF-8-encoded Unicode. You can force UTF-8 encoding on in a
3647 string with an initial C<U0>, and the bytes that follow will be
3648 interpreted as Unicode characters. If you don't want this to happen,
3649 you can begin your pattern with C<C0> (or anything else) to force Perl
3650 not to UTF-8 encode your string, and then follow this with a C<U*>
3651 somewhere in your pattern.
3652
3653 =item *
3654
3655 You must yourself do any alignment or padding by inserting for example
3656 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3657 could know where the bytes are going to or coming from.  Therefore
3658 C<pack> (and C<unpack>) handle their output and input as flat
3659 sequences of bytes.
3660
3661 =item *
3662
3663 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3664 take a repeat count, both as postfix, and for unpack() also via the C</>
3665 template character. Within each repetition of a group, positioning with
3666 C<@> starts again at 0. Therefore, the result of
3667
3668     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3669
3670 is the string "\0a\0\0bc".
3671
3672
3673 =item *
3674
3675 C<x> and C<X> accept C<!> modifier.  In this case they act as
3676 alignment commands: they jump forward/back to the closest position
3677 aligned at a multiple of C<count> bytes.  For example, to pack() or
3678 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3679 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3680 aligned on the double's size.
3681
3682 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3683 both result in no-ops.
3684
3685 =item *
3686
3687 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3688 will represent signed 16-/32-bit integers in big-/little-endian order.
3689 This is only portable if all platforms sharing the packed data use the
3690 same binary representation for signed integers (e.g. all platforms are
3691 using two's complement representation).
3692
3693 =item *
3694
3695 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3696 White space may be used to separate pack codes from each other, but
3697 modifiers and a repeat count must follow immediately.
3698
3699 =item *
3700
3701 If TEMPLATE requires more arguments to pack() than actually given, pack()
3702 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3703 to pack() than actually given, extra arguments are ignored.
3704
3705 =back
3706
3707 Examples:
3708
3709     $foo = pack("CCCC",65,66,67,68);
3710     # foo eq "ABCD"
3711     $foo = pack("C4",65,66,67,68);
3712     # same thing
3713     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3714     # same thing with Unicode circled letters
3715
3716     $foo = pack("ccxxcc",65,66,67,68);
3717     # foo eq "AB\0\0CD"
3718
3719     # note: the above examples featuring "C" and "c" are true
3720     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3721     # and UTF-8.  In EBCDIC the first example would be
3722     # $foo = pack("CCCC",193,194,195,196);
3723
3724     $foo = pack("s2",1,2);
3725     # "\1\0\2\0" on little-endian
3726     # "\0\1\0\2" on big-endian
3727
3728     $foo = pack("a4","abcd","x","y","z");
3729     # "abcd"
3730
3731     $foo = pack("aaaa","abcd","x","y","z");
3732     # "axyz"
3733
3734     $foo = pack("a14","abcdefg");
3735     # "abcdefg\0\0\0\0\0\0\0"
3736
3737     $foo = pack("i9pl", gmtime);
3738     # a real struct tm (on my system anyway)
3739
3740     $utmp_template = "Z8 Z8 Z16 L";
3741     $utmp = pack($utmp_template, @utmp1);
3742     # a struct utmp (BSDish)
3743
3744     @utmp2 = unpack($utmp_template, $utmp);
3745     # "@utmp1" eq "@utmp2"
3746
3747     sub bintodec {
3748         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3749     }
3750
3751     $foo = pack('sx2l', 12, 34);
3752     # short 12, two zero bytes padding, long 34
3753     $bar = pack('s@4l', 12, 34);
3754     # short 12, zero fill to position 4, long 34
3755     # $foo eq $bar
3756
3757     $foo = pack('nN', 42, 4711);
3758     # pack big-endian 16- and 32-bit unsigned integers
3759     $foo = pack('S>L>', 42, 4711);
3760     # exactly the same
3761     $foo = pack('s<l<', -42, 4711);
3762     # pack little-endian 16- and 32-bit signed integers
3763     $foo = pack('(sl)<', -42, 4711);
3764     # exactly the same
3765
3766 The same template may generally also be used in unpack().
3767
3768 =item package NAMESPACE
3769
3770 =item package
3771
3772 Declares the compilation unit as being in the given namespace.  The scope
3773 of the package declaration is from the declaration itself through the end
3774 of the enclosing block, file, or eval (the same as the C<my> operator).
3775 All further unqualified dynamic identifiers will be in this namespace.
3776 A package statement affects only dynamic variables--including those
3777 you've used C<local> on--but I<not> lexical variables, which are created
3778 with C<my>.  Typically it would be the first declaration in a file to
3779 be included by the C<require> or C<use> operator.  You can switch into a
3780 package in more than one place; it merely influences which symbol table
3781 is used by the compiler for the rest of that block.  You can refer to
3782 variables and filehandles in other packages by prefixing the identifier
3783 with the package name and a double colon:  C<$Package::Variable>.
3784 If the package name is null, the C<main> package as assumed.  That is,
3785 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3786 still seen in older code).
3787
3788 If NAMESPACE is omitted, then there is no current package, and all
3789 identifiers must be fully qualified or lexicals.  However, you are
3790 strongly advised not to make use of this feature. Its use can cause
3791 unexpected behaviour, even crashing some versions of Perl. It is
3792 deprecated, and will be removed from a future release.
3793
3794 See L<perlmod/"Packages"> for more information about packages, modules,
3795 and classes.  See L<perlsub> for other scoping issues.
3796
3797 =item pipe READHANDLE,WRITEHANDLE
3798
3799 Opens a pair of connected pipes like the corresponding system call.
3800 Note that if you set up a loop of piped processes, deadlock can occur
3801 unless you are very careful.  In addition, note that Perl's pipes use
3802 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3803 after each command, depending on the application.
3804
3805 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3806 for examples of such things.
3807
3808 On systems that support a close-on-exec flag on files, the flag will be set
3809 for the newly opened file descriptors as determined by the value of $^F.
3810 See L<perlvar/$^F>.
3811
3812 =item pop ARRAY
3813
3814 =item pop
3815
3816 Pops and returns the last value of the array, shortening the array by
3817 one element.  Has an effect similar to
3818
3819     $ARRAY[$#ARRAY--]
3820
3821 If there are no elements in the array, returns the undefined value
3822 (although this may happen at other times as well).  If ARRAY is
3823 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3824 array in subroutines, just like C<shift>.
3825
3826 =item pos SCALAR
3827
3828 =item pos
3829
3830 Returns the offset of where the last C<m//g> search left off for the variable
3831 in question (C<$_> is used when the variable is not specified).  Note that
3832 0 is a valid match offset, while C<undef> indicates that the search position
3833 is reset (usually due to match failure, but can also be because no match has
3834 yet been performed on the scalar). C<pos> directly accesses the location used
3835 by the regexp engine to store the offset, so assigning to C<pos> will change
3836 that offset, and so will also influence the C<\G> zero-width assertion in
3837 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3838 the return from C<pos> won't change either in this case.  See L<perlre> and
3839 L<perlop>.
3840
3841 =item print FILEHANDLE LIST
3842
3843 =item print LIST
3844
3845 =item print
3846
3847 Prints a string or a list of strings.  Returns true if successful.
3848 FILEHANDLE may be a scalar variable name, in which case the variable
3849 contains the name of or a reference to the filehandle, thus introducing
3850 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3851 the next token is a term, it may be misinterpreted as an operator
3852 unless you interpose a C<+> or put parentheses around the arguments.)
3853 If FILEHANDLE is omitted, prints by default to standard output (or
3854 to the last selected output channel--see L</select>).  If LIST is
3855 also omitted, prints C<$_> to the currently selected output channel.
3856 To set the default output channel to something other than STDOUT
3857 use the select operation.  The current value of C<$,> (if any) is
3858 printed between each LIST item.  The current value of C<$\> (if
3859 any) is printed after the entire LIST has been printed.  Because
3860 print takes a LIST, anything in the LIST is evaluated in list
3861 context, and any subroutine that you call will have one or more of
3862 its expressions evaluated in list context.  Also be careful not to
3863 follow the print keyword with a left parenthesis unless you want
3864 the corresponding right parenthesis to terminate the arguments to
3865 the print--interpose a C<+> or put parentheses around all the
3866 arguments.
3867
3868 Note that if you're storing FILEHANDLES in an array or other expression,
3869 you will have to use a block returning its value instead:
3870
3871     print { $files[$i] } "stuff\n";
3872     print { $OK ? STDOUT : STDERR } "stuff\n";
3873
3874 =item printf FILEHANDLE FORMAT, LIST
3875
3876 =item printf FORMAT, LIST
3877
3878 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3879 (the output record separator) is not appended.  The first argument
3880 of the list will be interpreted as the C<printf> format. See C<sprintf>
3881 for an explanation of the format argument. If C<use locale> is in effect,
3882 the character used for the decimal point in formatted real numbers is
3883 affected by the LC_NUMERIC locale.  See L<perllocale>.
3884
3885 Don't fall into the trap of using a C<printf> when a simple
3886 C<print> would do.  The C<print> is more efficient and less
3887 error prone.
3888
3889 =item prototype FUNCTION
3890
3891 Returns the prototype of a function as a string (or C<undef> if the
3892 function has no prototype).  FUNCTION is a reference to, or the name of,
3893 the function whose prototype you want to retrieve.
3894
3895 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3896 name for Perl builtin.  If the builtin is not I<overridable> (such as
3897 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3898 C<system>) returns C<undef> because the builtin does not really behave
3899 like a Perl function.  Otherwise, the string describing the equivalent
3900 prototype is returned.
3901
3902 =item push ARRAY,LIST
3903
3904 Treats ARRAY as a stack, and pushes the values of LIST
3905 onto the end of ARRAY.  The length of ARRAY increases by the length of
3906 LIST.  Has the same effect as
3907
3908     for $value (LIST) {
3909         $ARRAY[++$#ARRAY] = $value;
3910     }
3911
3912 but is more efficient.  Returns the new number of elements in the array.
3913
3914 =item q/STRING/
3915
3916 =item qq/STRING/
3917
3918 =item qr/STRING/
3919
3920 =item qx/STRING/
3921
3922 =item qw/STRING/
3923
3924 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3925
3926 =item quotemeta EXPR
3927
3928 =item quotemeta
3929
3930 Returns the value of EXPR with all non-"word"
3931 characters backslashed.  (That is, all characters not matching
3932 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3933 returned string, regardless of any locale settings.)
3934 This is the internal function implementing
3935 the C<\Q> escape in double-quoted strings.
3936
3937 If EXPR is omitted, uses C<$_>.
3938
3939 =item rand EXPR
3940
3941 =item rand
3942
3943 Returns a random fractional number greater than or equal to C<0> and less
3944 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3945 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3946 also special-cased as C<1> - this has not been documented before perl 5.8.0
3947 and is subject to change in future versions of perl.  Automatically calls
3948 C<srand> unless C<srand> has already been called.  See also C<srand>.
3949
3950 Apply C<int()> to the value returned by C<rand()> if you want random
3951 integers instead of random fractional numbers.  For example,
3952
3953     int(rand(10))
3954
3955 returns a random integer between C<0> and C<9>, inclusive.
3956
3957 (Note: If your rand function consistently returns numbers that are too
3958 large or too small, then your version of Perl was probably compiled
3959 with the wrong number of RANDBITS.)
3960
3961 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3962
3963 =item read FILEHANDLE,SCALAR,LENGTH
3964
3965 Attempts to read LENGTH I<characters> of data into variable SCALAR
3966 from the specified FILEHANDLE.  Returns the number of characters
3967 actually read, C<0> at end of file, or undef if there was an error (in
3968 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
3969 so that the last character actually read is the last character of the
3970 scalar after the read.
3971
3972 An OFFSET may be specified to place the read data at some place in the
3973 string other than the beginning.  A negative OFFSET specifies
3974 placement at that many characters counting backwards from the end of
3975 the string.  A positive OFFSET greater than the length of SCALAR
3976 results in the string being padded to the required size with C<"\0">
3977 bytes before the result of the read is appended.
3978
3979 The call is actually implemented in terms of either Perl's or system's
3980 fread() call.  To get a true read(2) system call, see C<sysread>.
3981
3982 Note the I<characters>: depending on the status of the filehandle,
3983 either (8-bit) bytes or characters are read.  By default all
3984 filehandles operate on bytes, but for example if the filehandle has
3985 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3986 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3987 characters, not bytes.  Similarly for the C<:encoding> pragma:
3988 in that case pretty much any characters can be read.
3989
3990 =item readdir DIRHANDLE
3991
3992 Returns the next directory entry for a directory opened by C<opendir>.
3993 If used in list context, returns all the rest of the entries in the
3994 directory.  If there are no more entries, returns an undefined value in
3995 scalar context or a null list in list context.
3996
3997 If you're planning to filetest the return values out of a C<readdir>, you'd
3998 better prepend the directory in question.  Otherwise, because we didn't
3999 C<chdir> there, it would have been testing the wrong file.
4000
4001     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4002     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4003     closedir DIR;
4004
4005 =item readline EXPR
4006
4007 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4008 context, each call reads and returns the next line, until end-of-file is
4009 reached, whereupon the subsequent call returns undef.  In list context,
4010 reads until end-of-file is reached and returns a list of lines.  Note that
4011 the notion of "line" used here is however you may have defined it
4012 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4013
4014 When C<$/> is set to C<undef>, when readline() is in scalar
4015 context (i.e. file slurp mode), and when an empty file is read, it
4016 returns C<''> the first time, followed by C<undef> subsequently.
4017
4018 This is the internal function implementing the C<< <EXPR> >>
4019 operator, but you can use it directly.  The C<< <EXPR> >>
4020 operator is discussed in more detail in L<perlop/"I/O Operators">.
4021
4022     $line = <STDIN>;
4023     $line = readline(*STDIN);           # same thing
4024
4025 If readline encounters an operating system error, C<$!> will be set with the
4026 corresponding error message.  It can be helpful to check C<$!> when you are
4027 reading from filehandles you don't trust, such as a tty or a socket.  The
4028 following example uses the operator form of C<readline>, and takes the necessary
4029 steps to ensure that C<readline> was successful.
4030
4031     for (;;) {
4032         undef $!;
4033         unless (defined( $line = <> )) {
4034             die $! if $!;
4035             last; # reached EOF
4036         }
4037         # ...
4038     }
4039
4040 =item readlink EXPR
4041
4042 =item readlink
4043
4044 Returns the value of a symbolic link, if symbolic links are
4045 implemented.  If not, gives a fatal error.  If there is some system
4046 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4047 omitted, uses C<$_>.
4048
4049 =item readpipe EXPR
4050
4051 EXPR is executed as a system command.
4052 The collected standard output of the command is returned.
4053 In scalar context, it comes back as a single (potentially
4054 multi-line) string.  In list context, returns a list of lines
4055 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4056 This is the internal function implementing the C<qx/EXPR/>
4057 operator, but you can use it directly.  The C<qx/EXPR/>
4058 operator is discussed in more detail in L<perlop/"I/O Operators">.
4059
4060 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4061
4062 Receives a message on a socket.  Attempts to receive LENGTH characters
4063 of data into variable SCALAR from the specified SOCKET filehandle.
4064 SCALAR will be grown or shrunk to the length actually read.  Takes the
4065 same flags as the system call of the same name.  Returns the address
4066 of the sender if SOCKET's protocol supports this; returns an empty
4067 string otherwise.  If there's an error, returns the undefined value.
4068 This call is actually implemented in terms of recvfrom(2) system call.
4069 See L<perlipc/"UDP: Message Passing"> for examples.
4070
4071 Note the I<characters>: depending on the status of the socket, either
4072 (8-bit) bytes or characters are received.  By default all sockets
4073 operate on bytes, but for example if the socket has been changed using
4074 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4075 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4076 characters, not bytes.  Similarly for the C<:encoding> pragma:
4077 in that case pretty much any characters can be read.
4078
4079 =item redo LABEL
4080
4081 =item redo
4082
4083 The C<redo> command restarts the loop block without evaluating the
4084 conditional again.  The C<continue> block, if any, is not executed.  If
4085 the LABEL is omitted, the command refers to the innermost enclosing
4086 loop.  This command is normally used by programs that want to lie to
4087 themselves about what was just input:
4088
4089     # a simpleminded Pascal comment stripper
4090     # (warning: assumes no { or } in strings)
4091     LINE: while (<STDIN>) {
4092         while (s|({.*}.*){.*}|$1 |) {}
4093         s|{.*}| |;
4094         if (s|{.*| |) {
4095             $front = $_;
4096             while (<STDIN>) {
4097                 if (/}/) {      # end of comment?
4098                     s|^|$front\{|;
4099                     redo LINE;
4100                 }
4101             }
4102         }
4103         print;
4104     }
4105
4106 C<redo> cannot be used to retry a block which returns a value such as
4107 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4108 a grep() or map() operation.
4109
4110 Note that a block by itself is semantically identical to a loop
4111 that executes once.  Thus C<redo> inside such a block will effectively
4112 turn it into a looping construct.
4113
4114 See also L</continue> for an illustration of how C<last>, C<next>, and
4115 C<redo> work.
4116
4117 =item ref EXPR
4118
4119 =item ref
4120
4121 Returns a non-empty string if EXPR is a reference, the empty
4122 string otherwise. If EXPR
4123 is not specified, C<$_> will be used.  The value returned depends on the
4124 type of thing the reference is a reference to.
4125 Builtin types include:
4126
4127     SCALAR
4128     ARRAY
4129     HASH
4130     CODE
4131     REF
4132     GLOB
4133     LVALUE
4134
4135 If the referenced object has been blessed into a package, then that package
4136 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4137
4138     if (ref($r) eq "HASH") {
4139         print "r is a reference to a hash.\n";
4140     }
4141     unless (ref($r)) {
4142         print "r is not a reference at all.\n";
4143     }
4144     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4145         print "r is a reference to something that isa hash.\n";
4146     }
4147
4148 See also L<perlref>.
4149
4150 =item rename OLDNAME,NEWNAME
4151
4152 Changes the name of a file; an existing file NEWNAME will be
4153 clobbered.  Returns true for success, false otherwise.
4154
4155 Behavior of this function varies wildly depending on your system
4156 implementation.  For example, it will usually not work across file system
4157 boundaries, even though the system I<mv> command sometimes compensates
4158 for this.  Other restrictions include whether it works on directories,
4159 open files, or pre-existing files.  Check L<perlport> and either the
4160 rename(2) manpage or equivalent system documentation for details.
4161
4162 =item require VERSION
4163
4164 =item require EXPR
4165
4166 =item require
4167
4168 Demands a version of Perl specified by VERSION, or demands some semantics
4169 specified by EXPR or by C<$_> if EXPR is not supplied.
4170
4171 VERSION may be either a numeric argument such as 5.006, which will be
4172 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4173 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4174 VERSION is greater than the version of the current Perl interpreter.
4175 Compare with L</use>, which can do a similar check at compile time.
4176
4177 Specifying VERSION as a literal of the form v5.6.1 should generally be
4178 avoided, because it leads to misleading error messages under earlier
4179 versions of Perl which do not support this syntax.  The equivalent numeric
4180 version should be used instead.
4181
4182     require v5.6.1;     # run time version check
4183     require 5.6.1;      # ditto
4184     require 5.006_001;  # ditto; preferred for backwards compatibility
4185
4186 Otherwise, demands that a library file be included if it hasn't already
4187 been included.  The file is included via the do-FILE mechanism, which is
4188 essentially just a variety of C<eval>.  Has semantics similar to the
4189 following subroutine:
4190
4191     sub require {
4192        my ($filename) = @_;
4193        if (exists $INC{$filename}) {
4194            return 1 if $INC{$filename};
4195            die "Compilation failed in require";
4196        }
4197        my ($realfilename,$result);
4198        ITER: {
4199            foreach $prefix (@INC) {
4200                $realfilename = "$prefix/$filename";
4201                if (-f $realfilename) {
4202                    $INC{$filename} = $realfilename;
4203                    $result = do $realfilename;
4204                    last ITER;
4205                }
4206            }
4207            die "Can't find $filename in \@INC";
4208        }
4209        if ($@) {
4210            $INC{$filename} = undef;
4211            die $@;
4212        } elsif (!$result) {
4213            delete $INC{$filename};
4214            die "$filename did not return true value";
4215        } else {
4216            return $result;
4217        }
4218     }
4219
4220 Note that the file will not be included twice under the same specified
4221 name.
4222
4223 The file must return true as the last statement to indicate
4224 successful execution of any initialization code, so it's customary to
4225 end such a file with C<1;> unless you're sure it'll return true
4226 otherwise.  But it's better just to put the C<1;>, in case you add more
4227 statements.
4228
4229 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4230 replaces "F<::>" with "F</>" in the filename for you,
4231 to make it easy to load standard modules.  This form of loading of
4232 modules does not risk altering your namespace.
4233
4234 In other words, if you try this:
4235
4236         require Foo::Bar;    # a splendid bareword
4237
4238 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4239 directories specified in the C<@INC> array.
4240
4241 But if you try this:
4242
4243         $class = 'Foo::Bar';
4244         require $class;      # $class is not a bareword
4245     #or
4246         require "Foo::Bar";  # not a bareword because of the ""
4247
4248 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4249 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4250
4251         eval "require $class";
4252
4253 Now that you understand how C<require> looks for files in the case of
4254 a bareword argument, there is a little extra functionality going on
4255 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4256 it will first look for a filename with a "F<.pmc>" extension.  A file
4257 with this extension is assumed to be Perl bytecode generated by
4258 L<B::Bytecode|B::Bytecode>.  If this file is found, and it's modification
4259 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4260 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4261
4262 You can also insert hooks into the import facility, by putting directly
4263 Perl code into the @INC array.  There are three forms of hooks: subroutine
4264 references, array references and blessed objects.
4265
4266 Subroutine references are the simplest case.  When the inclusion system
4267 walks through @INC and encounters a subroutine, this subroutine gets
4268 called with two parameters, the first being a reference to itself, and the
4269 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4270 subroutine should return C<undef> or a filehandle, from which the file to
4271 include will be read.  If C<undef> is returned, C<require> will look at
4272 the remaining elements of @INC.
4273
4274 If the hook is an array reference, its first element must be a subroutine
4275 reference.  This subroutine is called as above, but the first parameter is
4276 the array reference.  This enables to pass indirectly some arguments to
4277 the subroutine.
4278
4279 In other words, you can write:
4280
4281     push @INC, \&my_sub;
4282     sub my_sub {
4283         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4284         ...
4285     }
4286
4287 or:
4288
4289     push @INC, [ \&my_sub, $x, $y, ... ];
4290     sub my_sub {
4291         my ($arrayref, $filename) = @_;
4292         # Retrieve $x, $y, ...
4293         my @parameters = @$arrayref[1..$#$arrayref];
4294         ...
4295     }
4296
4297 If the hook is an object, it must provide an INC method, that will be
4298 called as above, the first parameter being the object itself.  (Note that
4299 you must fully qualify the sub's name, as it is always forced into package
4300 C<main>.)  Here is a typical code layout:
4301
4302     # In Foo.pm
4303     package Foo;
4304     sub new { ... }
4305     sub Foo::INC {
4306         my ($self, $filename) = @_;
4307         ...
4308     }
4309
4310     # In the main program
4311     push @INC, new Foo(...);
4312
4313 Note that these hooks are also permitted to set the %INC entry
4314 corresponding to the files they have loaded. See L<perlvar/%INC>.
4315
4316 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4317
4318 =item reset EXPR
4319
4320 =item reset
4321
4322 Generally used in a C<continue> block at the end of a loop to clear
4323 variables and reset C<??> searches so that they work again.  The
4324 expression is interpreted as a list of single characters (hyphens
4325 allowed for ranges).  All variables and arrays beginning with one of
4326 those letters are reset to their pristine state.  If the expression is
4327 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4328 only variables or searches in the current package.  Always returns
4329 1.  Examples:
4330
4331     reset 'X';          # reset all X variables
4332     reset 'a-z';        # reset lower case variables
4333     reset;              # just reset ?one-time? searches
4334
4335 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4336 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4337 variables--lexical variables are unaffected, but they clean themselves
4338 up on scope exit anyway, so you'll probably want to use them instead.
4339 See L</my>.
4340
4341 =item return EXPR
4342
4343 =item return
4344
4345 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4346 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4347 context, depending on how the return value will be used, and the context
4348 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4349 is given, returns an empty list in list context, the undefined value in
4350 scalar context, and (of course) nothing at all in a void context.
4351
4352 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4353 or do FILE will automatically return the value of the last expression
4354 evaluated.)
4355
4356 =item reverse LIST
4357
4358 In list context, returns a list value consisting of the elements
4359 of LIST in the opposite order.  In scalar context, concatenates the
4360 elements of LIST and returns a string value with all characters
4361 in the opposite order.
4362
4363     print reverse <>;           # line tac, last line first
4364
4365     undef $/;                   # for efficiency of <>
4366     print scalar reverse <>;    # character tac, last line tsrif
4367
4368 Used without arguments in scalar context, reverse() reverses C<$_>.
4369
4370 This operator is also handy for inverting a hash, although there are some
4371 caveats.  If a value is duplicated in the original hash, only one of those
4372 can be represented as a key in the inverted hash.  Also, this has to
4373 unwind one hash and build a whole new one, which may take some time
4374 on a large hash, such as from a DBM file.
4375
4376     %by_name = reverse %by_address;     # Invert the hash
4377
4378 =item rewinddir DIRHANDLE
4379
4380 Sets the current position to the beginning of the directory for the
4381 C<readdir> routine on DIRHANDLE.
4382
4383 =item rindex STR,SUBSTR,POSITION
4384
4385 =item rindex STR,SUBSTR
4386
4387 Works just like index() except that it returns the position of the LAST
4388 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4389 last occurrence at or before that position.
4390
4391 =item rmdir FILENAME
4392
4393 =item rmdir
4394
4395 Deletes the directory specified by FILENAME if that directory is
4396 empty.  If it succeeds it returns true, otherwise it returns false and
4397 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4398
4399 =item s///
4400
4401 The substitution operator.  See L<perlop>.
4402
4403 =item scalar EXPR
4404
4405 Forces EXPR to be interpreted in scalar context and returns the value
4406 of EXPR.
4407
4408     @counts = ( scalar @a, scalar @b, scalar @c );
4409
4410 There is no equivalent operator to force an expression to
4411 be interpolated in list context because in practice, this is never
4412 needed.  If you really wanted to do so, however, you could use
4413 the construction C<@{[ (some expression) ]}>, but usually a simple
4414 C<(some expression)> suffices.
4415
4416 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4417 parenthesized list, this behaves as a scalar comma expression, evaluating
4418 all but the last element in void context and returning the final element
4419 evaluated in scalar context.  This is seldom what you want.
4420
4421 The following single statement:
4422
4423         print uc(scalar(&foo,$bar)),$baz;
4424
4425 is the moral equivalent of these two:
4426
4427         &foo;
4428         print(uc($bar),$baz);
4429
4430 See L<perlop> for more details on unary operators and the comma operator.
4431
4432 =item seek FILEHANDLE,POSITION,WHENCE
4433
4434 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4435 FILEHANDLE may be an expression whose value gives the name of the
4436 filehandle.  The values for WHENCE are C<0> to set the new position
4437 I<in bytes> to POSITION, C<1> to set it to the current position plus
4438 POSITION, and C<2> to set it to EOF plus POSITION (typically
4439 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4440 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4441 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4442 otherwise.
4443
4444 Note the I<in bytes>: even if the filehandle has been set to
4445 operate on characters (for example by using the C<:utf8> open
4446 layer), tell() will return byte offsets, not character offsets
4447 (because implementing that would render seek() and tell() rather slow).
4448
4449 If you want to position file for C<sysread> or C<syswrite>, don't use
4450 C<seek>--buffering makes its effect on the file's system position
4451 unpredictable and non-portable.  Use C<sysseek> instead.
4452
4453 Due to the rules and rigors of ANSI C, on some systems you have to do a
4454 seek whenever you switch between reading and writing.  Amongst other
4455 things, this may have the effect of calling stdio's clearerr(3).
4456 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4457
4458     seek(TEST,0,1);
4459
4460 This is also useful for applications emulating C<tail -f>.  Once you hit
4461 EOF on your read, and then sleep for a while, you might have to stick in a
4462 seek() to reset things.  The C<seek> doesn't change the current position,
4463 but it I<does> clear the end-of-file condition on the handle, so that the
4464 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4465
4466 If that doesn't work (some IO implementations are particularly
4467 cantankerous), then you may need something more like this:
4468
4469     for (;;) {
4470         for ($curpos = tell(FILE); $_ = <FILE>;
4471              $curpos = tell(FILE)) {
4472             # search for some stuff and put it into files
4473         }
4474         sleep($for_a_while);
4475         seek(FILE, $curpos, 0);
4476     }
4477
4478 =item seekdir DIRHANDLE,POS
4479
4480 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4481 must be a value returned by C<telldir>.  Has the same caveats about
4482 possible directory compaction as the corresponding system library
4483 routine.
4484
4485 =item select FILEHANDLE
4486
4487 =item select
4488
4489 Returns the currently selected filehandle.  Sets the current default
4490 filehandle for output, if FILEHANDLE is supplied.  This has two
4491 effects: first, a C<write> or a C<print> without a filehandle will
4492 default to this FILEHANDLE.  Second, references to variables related to
4493 output will refer to this output channel.  For example, if you have to
4494 set the top of form format for more than one output channel, you might
4495 do the following:
4496
4497     select(REPORT1);
4498     $^ = 'report1_top';
4499     select(REPORT2);
4500     $^ = 'report2_top';
4501
4502 FILEHANDLE may be an expression whose value gives the name of the
4503 actual filehandle.  Thus:
4504
4505     $oldfh = select(STDERR); $| = 1; select($oldfh);
4506
4507 Some programmers may prefer to think of filehandles as objects with
4508 methods, preferring to write the last example as:
4509
4510     use IO::Handle;
4511     STDERR->autoflush(1);
4512
4513 =item select RBITS,WBITS,EBITS,TIMEOUT
4514
4515 This calls the select(2) system call with the bit masks specified, which
4516 can be constructed using C<fileno> and C<vec>, along these lines:
4517
4518     $rin = $win = $ein = '';
4519     vec($rin,fileno(STDIN),1) = 1;
4520     vec($win,fileno(STDOUT),1) = 1;
4521     $ein = $rin | $win;
4522
4523 If you want to select on many filehandles you might wish to write a
4524 subroutine:
4525
4526     sub fhbits {
4527         my(@fhlist) = split(' ',$_[0]);
4528         my($bits);
4529         for (@fhlist) {
4530             vec($bits,fileno($_),1) = 1;
4531         }
4532         $bits;
4533     }
4534     $rin = fhbits('STDIN TTY SOCK');
4535
4536 The usual idiom is:
4537
4538     ($nfound,$timeleft) =
4539       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4540
4541 or to block until something becomes ready just do this
4542
4543     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4544
4545 Most systems do not bother to return anything useful in $timeleft, so
4546 calling select() in scalar context just returns $nfound.
4547
4548 Any of the bit masks can also be undef.  The timeout, if specified, is
4549 in seconds, which may be fractional.  Note: not all implementations are
4550 capable of returning the $timeleft.  If not, they always return
4551 $timeleft equal to the supplied $timeout.
4552
4553 You can effect a sleep of 250 milliseconds this way:
4554
4555     select(undef, undef, undef, 0.25);
4556
4557 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4558 is implementation-dependent.  See also L<perlport> for notes on the
4559 portability of C<select>.
4560
4561 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4562 or <FH>) with C<select>, except as permitted by POSIX, and even
4563 then only on POSIX systems.  You have to use C<sysread> instead.
4564
4565 =item semctl ID,SEMNUM,CMD,ARG
4566
4567 Calls the System V IPC function C<semctl>.  You'll probably have to say
4568
4569     use IPC::SysV;
4570
4571 first to get the correct constant definitions.  If CMD is IPC_STAT or
4572 GETALL, then ARG must be a variable which will hold the returned
4573 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4574 the undefined value for error, "C<0 but true>" for zero, or the actual
4575 return value otherwise.  The ARG must consist of a vector of native
4576 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4577 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4578 documentation.
4579
4580 =item semget KEY,NSEMS,FLAGS
4581
4582 Calls the System V IPC function semget.  Returns the semaphore id, or
4583 the undefined value if there is an error.  See also
4584 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4585 documentation.
4586
4587 =item semop KEY,OPSTRING
4588
4589 Calls the System V IPC function semop to perform semaphore operations
4590 such as signalling and waiting.  OPSTRING must be a packed array of
4591 semop structures.  Each semop structure can be generated with
4592 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4593 operations is implied by the length of OPSTRING.  Returns true if
4594 successful, or false if there is an error.  As an example, the
4595 following code waits on semaphore $semnum of semaphore id $semid:
4596
4597     $semop = pack("s!3", $semnum, -1, 0);
4598     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4599
4600 To signal the semaphore, replace C<-1> with C<1>.  See also
4601 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4602 documentation.
4603
4604 =item send SOCKET,MSG,FLAGS,TO
4605
4606 =item send SOCKET,MSG,FLAGS
4607
4608 Sends a message on a socket.  Attempts to send the scalar MSG to the
4609 SOCKET filehandle.  Takes the same flags as the system call of the
4610 same name.  On unconnected sockets you must specify a destination to
4611 send TO, in which case it does a C C<sendto>.  Returns the number of
4612 characters sent, or the undefined value if there is an error.  The C
4613 system call sendmsg(2) is currently unimplemented.  See
4614 L<perlipc/"UDP: Message Passing"> for examples.
4615
4616 Note the I<characters>: depending on the status of the socket, either
4617 (8-bit) bytes or characters are sent.  By default all sockets operate
4618 on bytes, but for example if the socket has been changed using
4619 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4620 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4621 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4622 in that case pretty much any characters can be sent.
4623
4624 =item setpgrp PID,PGRP
4625
4626 Sets the current process group for the specified PID, C<0> for the current
4627 process.  Will produce a fatal error if used on a machine that doesn't
4628 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4629 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4630 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4631 C<POSIX::setsid()>.
4632
4633 =item setpriority WHICH,WHO,PRIORITY
4634
4635 Sets the current priority for a process, a process group, or a user.
4636 (See setpriority(2).)  Will produce a fatal error if used on a machine
4637 that doesn't implement setpriority(2).
4638
4639 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4640
4641 Sets the socket option requested.  Returns undefined if there is an
4642 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4643 argument.
4644
4645 =item shift ARRAY
4646
4647 =item shift
4648
4649 Shifts the first value of the array off and returns it, shortening the
4650 array by 1 and moving everything down.  If there are no elements in the
4651 array, returns the undefined value.  If ARRAY is omitted, shifts the
4652 C<@_> array within the lexical scope of subroutines and formats, and the
4653 C<@ARGV> array at file scopes or within the lexical scopes established by
4654 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4655 constructs.
4656
4657 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4658 same thing to the left end of an array that C<pop> and C<push> do to the
4659 right end.
4660
4661 =item shmctl ID,CMD,ARG
4662
4663 Calls the System V IPC function shmctl.  You'll probably have to say
4664
4665     use IPC::SysV;
4666
4667 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4668 then ARG must be a variable which will hold the returned C<shmid_ds>
4669 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4670 true" for zero, or the actual return value otherwise.
4671 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4672
4673 =item shmget KEY,SIZE,FLAGS
4674
4675 Calls the System V IPC function shmget.  Returns the shared memory
4676 segment id, or the undefined value if there is an error.
4677 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4678
4679 =item shmread ID,VAR,POS,SIZE
4680
4681 =item shmwrite ID,STRING,POS,SIZE
4682
4683 Reads or writes the System V shared memory segment ID starting at
4684 position POS for size SIZE by attaching to it, copying in/out, and
4685 detaching from it.  When reading, VAR must be a variable that will
4686 hold the data read.  When writing, if STRING is too long, only SIZE
4687 bytes are used; if STRING is too short, nulls are written to fill out
4688 SIZE bytes.  Return true if successful, or false if there is an error.
4689 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4690 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4691
4692 =item shutdown SOCKET,HOW
4693
4694 Shuts down a socket connection in the manner indicated by HOW, which
4695 has the same interpretation as in the system call of the same name.
4696
4697     shutdown(SOCKET, 0);    # I/we have stopped reading data
4698     shutdown(SOCKET, 1);    # I/we have stopped writing data
4699     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4700
4701 This is useful with sockets when you want to tell the other
4702 side you're done writing but not done reading, or vice versa.
4703 It's also a more insistent form of close because it also
4704 disables the file descriptor in any forked copies in other
4705 processes.
4706
4707 =item sin EXPR
4708
4709 =item sin
4710
4711 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4712 returns sine of C<$_>.
4713
4714 For the inverse sine operation, you may use the C<Math::Trig::asin>
4715 function, or use this relation:
4716
4717     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4718
4719 =item sleep EXPR
4720
4721 =item sleep
4722
4723 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4724 May be interrupted if the process receives a signal such as C<SIGALRM>.
4725 Returns the number of seconds actually slept.  You probably cannot
4726 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4727 using C<alarm>.
4728
4729 On some older systems, it may sleep up to a full second less than what
4730 you requested, depending on how it counts seconds.  Most modern systems
4731 always sleep the full amount.  They may appear to sleep longer than that,
4732 however, because your process might not be scheduled right away in a
4733 busy multitasking system.
4734
4735 For delays of finer granularity than one second, you may use Perl's
4736 C<syscall> interface to access setitimer(2) if your system supports
4737 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4738 and starting from Perl 5.8 part of the standard distribution) may also
4739 help.
4740
4741 See also the POSIX module's C<pause> function.
4742
4743 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4744
4745 Opens a socket of the specified kind and attaches it to filehandle
4746 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4747 the system call of the same name.  You should C<use Socket> first
4748 to get the proper definitions imported.  See the examples in
4749 L<perlipc/"Sockets: Client/Server Communication">.
4750
4751 On systems that support a close-on-exec flag on files, the flag will
4752 be set for the newly opened file descriptor, as determined by the
4753 value of $^F.  See L<perlvar/$^F>.
4754
4755 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4756
4757 Creates an unnamed pair of sockets in the specified domain, of the
4758 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4759 for the system call of the same name.  If unimplemented, yields a fatal
4760 error.  Returns true if successful.
4761
4762 On systems that support a close-on-exec flag on files, the flag will
4763 be set for the newly opened file descriptors, as determined by the value
4764 of $^F.  See L<perlvar/$^F>.
4765
4766 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4767 to C<pipe(Rdr, Wtr)> is essentially:
4768
4769     use Socket;
4770     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4771     shutdown(Rdr, 1);        # no more writing for reader
4772     shutdown(Wtr, 0);        # no more reading for writer
4773
4774 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4775 emulate socketpair using IP sockets to localhost if your system implements
4776 sockets but not socketpair.
4777
4778 =item sort SUBNAME LIST
4779
4780 =item sort BLOCK LIST
4781
4782 =item sort LIST
4783
4784 In list context, this sorts the LIST and returns the sorted list value.
4785 In scalar context, the behaviour of C<sort()> is undefined.
4786
4787 If SUBNAME or BLOCK is omitted, C<sort>s in standard string comparison
4788 order.  If SUBNAME is specified, it gives the name of a subroutine
4789 that returns an integer less than, equal to, or greater than C<0>,
4790 depending on how the elements of the list are to be ordered.  (The C<<
4791 <=> >> and C<cmp> operators are extremely useful in such routines.)
4792 SUBNAME may be a scalar variable name (unsubscripted), in which case
4793 the value provides the name of (or a reference to) the actual
4794 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
4795 an anonymous, in-line sort subroutine.
4796
4797 If the subroutine's prototype is C<($$)>, the elements to be compared
4798 are passed by reference in C<@_>, as for a normal subroutine.  This is
4799 slower than unprototyped subroutines, where the elements to be
4800 compared are passed into the subroutine
4801 as the package global variables $a and $b (see example below).  Note that
4802 in the latter case, it is usually counter-productive to declare $a and
4803 $b as lexicals.
4804
4805 In either case, the subroutine may not be recursive.  The values to be
4806 compared are always passed by reference, so don't modify them.
4807
4808 You also cannot exit out of the sort block or subroutine using any of the
4809 loop control operators described in L<perlsyn> or with C<goto>.
4810
4811 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4812 current collation locale.  See L<perllocale>.
4813
4814 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4815 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4816 preserves the input order of elements that compare equal.  Although
4817 quicksort's run time is O(NlogN) when averaged over all arrays of
4818 length N, the time can be O(N**2), I<quadratic> behavior, for some
4819 inputs.)  In 5.7, the quicksort implementation was replaced with
4820 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4821 But benchmarks indicated that for some inputs, on some platforms,
4822 the original quicksort was faster.  5.8 has a sort pragma for
4823 limited control of the sort.  Its rather blunt control of the
4824 underlying algorithm may not persist into future perls, but the
4825 ability to characterize the input or output in implementation
4826 independent ways quite probably will.  See L<sort>.
4827
4828 Examples:
4829
4830     # sort lexically
4831     @articles = sort @files;
4832
4833     # same thing, but with explicit sort routine
4834     @articles = sort {$a cmp $b} @files;
4835
4836     # now case-insensitively
4837     @articles = sort {uc($a) cmp uc($b)} @files;
4838
4839     # same thing in reversed order
4840     @articles = sort {$b cmp $a} @files;
4841
4842     # sort numerically ascending
4843     @articles = sort {$a <=> $b} @files;
4844
4845     # sort numerically descending
4846     @articles = sort {$b <=> $a} @files;
4847
4848     # this sorts the %age hash by value instead of key
4849     # using an in-line function
4850     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4851
4852     # sort using explicit subroutine name
4853     sub byage {
4854         $age{$a} <=> $age{$b};  # presuming numeric
4855     }
4856     @sortedclass = sort byage @class;
4857
4858     sub backwards { $b cmp $a }
4859     @harry  = qw(dog cat x Cain Abel);
4860     @george = qw(gone chased yz Punished Axed);
4861     print sort @harry;
4862             # prints AbelCaincatdogx
4863     print sort backwards @harry;
4864             # prints xdogcatCainAbel
4865     print sort @george, 'to', @harry;
4866             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4867
4868     # inefficiently sort by descending numeric compare using
4869     # the first integer after the first = sign, or the
4870     # whole record case-insensitively otherwise
4871
4872     @new = sort {
4873         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4874                             ||
4875                     uc($a)  cmp  uc($b)
4876     } @old;
4877
4878     # same thing, but much more efficiently;
4879     # we'll build auxiliary indices instead
4880     # for speed
4881     @nums = @caps = ();
4882     for (@old) {
4883         push @nums, /=(\d+)/;
4884         push @caps, uc($_);
4885     }
4886
4887     @new = @old[ sort {
4888                         $nums[$b] <=> $nums[$a]
4889                                  ||
4890                         $caps[$a] cmp $caps[$b]
4891                        } 0..$#old
4892                ];
4893
4894     # same thing, but without any temps
4895     @new = map { $_->[0] }
4896            sort { $b->[1] <=> $a->[1]
4897                            ||
4898                   $a->[2] cmp $b->[2]
4899            } map { [$_, /=(\d+)/, uc($_)] } @old;
4900
4901     # using a prototype allows you to use any comparison subroutine
4902     # as a sort subroutine (including other package's subroutines)
4903     package other;
4904     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4905
4906     package main;
4907     @new = sort other::backwards @old;
4908
4909     # guarantee stability, regardless of algorithm
4910     use sort 'stable';
4911     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4912
4913     # force use of mergesort (not portable outside Perl 5.8)
4914     use sort '_mergesort';  # note discouraging _
4915     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4916
4917 If you're using strict, you I<must not> declare $a
4918 and $b as lexicals.  They are package globals.  That means
4919 if you're in the C<main> package and type
4920
4921     @articles = sort {$b <=> $a} @files;
4922
4923 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4924 but if you're in the C<FooPack> package, it's the same as typing
4925
4926     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4927
4928 The comparison function is required to behave.  If it returns
4929 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4930 sometimes saying the opposite, for example) the results are not
4931 well-defined.
4932
4933 Because C<< <=> >> returns C<undef> when either operand is C<NaN>
4934 (not-a-number), and because C<sort> will trigger a fatal error unless the
4935 result of a comparison is defined, when sorting with a comparison function
4936 like C<< $a <=> $b >>, be careful about lists that might contain a C<NaN>.
4937 The following example takes advantage of the fact that C<NaN != NaN> to
4938 eliminate any C<NaN>s from the input.
4939
4940     @result = sort { $a <=> $b } grep { $_ == $_ } @input;
4941
4942 =item splice ARRAY,OFFSET,LENGTH,LIST
4943
4944 =item splice ARRAY,OFFSET,LENGTH
4945
4946 =item splice ARRAY,OFFSET
4947
4948 =item splice ARRAY
4949
4950 Removes the elements designated by OFFSET and LENGTH from an array, and
4951 replaces them with the elements of LIST, if any.  In list context,
4952 returns the elements removed from the array.  In scalar context,
4953 returns the last element removed, or C<undef> if no elements are
4954 removed.  The array grows or shrinks as necessary.
4955 If OFFSET is negative then it starts that far from the end of the array.
4956 If LENGTH is omitted, removes everything from OFFSET onward.
4957 If LENGTH is negative, removes the elements from OFFSET onward
4958 except for -LENGTH elements at the end of the array.
4959 If both OFFSET and LENGTH are omitted, removes everything. If OFFSET is
4960 past the end of the array, perl issues a warning, and splices at the
4961 end of the array.
4962
4963 The following equivalences hold (assuming C<< $[ == 0 and $#a >= $i >> )
4964
4965     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4966     pop(@a)             splice(@a,-1)
4967     shift(@a)           splice(@a,0,1)
4968     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4969     $a[$i] = $y         splice(@a,$i,1,$y)
4970
4971 Example, assuming array lengths are passed before arrays:
4972
4973     sub aeq {   # compare two list values
4974         my(@a) = splice(@_,0,shift);
4975         my(@b) = splice(@_,0,shift);
4976         return 0 unless @a == @b;       # same len?
4977         while (@a) {
4978             return 0 if pop(@a) ne pop(@b);
4979         }
4980         return 1;
4981     }
4982     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4983
4984 =item split /PATTERN/,EXPR,LIMIT
4985
4986 =item split /PATTERN/,EXPR
4987
4988 =item split /PATTERN/
4989
4990 =item split
4991
4992 Splits the string EXPR into a list of strings and returns that list.  By
4993 default, empty leading fields are preserved, and empty trailing ones are
4994 deleted.  (If all fields are empty, they are considered to be trailing.)
4995
4996 In scalar context, returns the number of fields found and splits into
4997 the C<@_> array.  Use of split in scalar context is deprecated, however,
4998 because it clobbers your subroutine arguments.
4999
5000 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
5001 splits on whitespace (after skipping any leading whitespace).  Anything
5002 matching PATTERN is taken to be a delimiter separating the fields.  (Note
5003 that the delimiter may be longer than one character.)
5004
5005 If LIMIT is specified and positive, it represents the maximum number
5006 of fields the EXPR will be split into, though the actual number of
5007 fields returned depends on the number of times PATTERN matches within
5008 EXPR.  If LIMIT is unspecified or zero, trailing null fields are
5009 stripped (which potential users of C<pop> would do well to remember).
5010 If LIMIT is negative, it is treated as if an arbitrarily large LIMIT
5011 had been specified.  Note that splitting an EXPR that evaluates to the
5012 empty string always returns the empty list, regardless of the LIMIT
5013 specified.
5014
5015 A pattern matching the null string (not to be confused with
5016 a null pattern C<//>, which is just one member of the set of patterns
5017 matching a null string) will split the value of EXPR into separate
5018 characters at each point it matches that way.  For example:
5019
5020     print join(':', split(/ */, 'hi there'));
5021
5022 produces the output 'h:i:t:h:e:r:e'.
5023
5024 Using the empty pattern C<//> specifically matches the null string, and is
5025 not be confused with the use of C<//> to mean "the last successful pattern
5026 match".
5027
5028 Empty leading (or trailing) fields are produced when there are positive width
5029 matches at the beginning (or end) of the string; a zero-width match at the
5030 beginning (or end) of the string does not produce an empty field.  For
5031 example:
5032
5033    print join(':', split(/(?=\w)/, 'hi there!'));
5034
5035 produces the output 'h:i :t:h:e:r:e!'.
5036
5037 The LIMIT parameter can be used to split a line partially
5038
5039     ($login, $passwd, $remainder) = split(/:/, $_, 3);
5040
5041 When assigning to a list, if LIMIT is omitted, or zero, Perl supplies
5042 a LIMIT one larger than the number of variables in the list, to avoid
5043 unnecessary work.  For the list above LIMIT would have been 4 by
5044 default.  In time critical applications it behooves you not to split
5045 into more fields than you really need.
5046
5047 If the PATTERN contains parentheses, additional list elements are
5048 created from each matching substring in the delimiter.
5049
5050     split(/([,-])/, "1-10,20", 3);
5051
5052 produces the list value
5053
5054     (1, '-', 10, ',', 20)
5055
5056 If you had the entire header of a normal Unix email message in $header,
5057 you could split it up into fields and their values this way:
5058
5059     $header =~ s/\n\s+/ /g;  # fix continuation lines
5060     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
5061
5062 The pattern C</PATTERN/> may be replaced with an expression to specify
5063 patterns that vary at runtime.  (To do runtime compilation only once,
5064 use C</$variable/o>.)
5065
5066 As a special case, specifying a PATTERN of space (S<C<' '>>) will split on
5067 white space just as C<split> with no arguments does.  Thus, S<C<split(' ')>> can
5068 be used to emulate B<awk>'s default behavior, whereas S<C<split(/ /)>>
5069 will give you as many null initial fields as there are leading spaces.
5070 A C<split> on C</\s+/> is like a S<C<split(' ')>> except that any leading
5071 whitespace produces a null first field.  A C<split> with no arguments
5072 really does a S<C<split(' ', $_)>> internally.
5073
5074 A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't
5075 much use otherwise.
5076
5077 Example:
5078
5079     open(PASSWD, '/etc/passwd');
5080     while (<PASSWD>) {
5081         chomp;
5082         ($login, $passwd, $uid, $gid,
5083          $gcos, $home, $shell) = split(/:/);
5084         #...
5085     }
5086
5087 As with regular pattern matching, any capturing parentheses that are not
5088 matched in a C<split()> will be set to C<undef> when returned:
5089
5090     @fields = split /(A)|B/, "1A2B3";
5091     # @fields is (1, 'A', 2, undef, 3)
5092
5093 =item sprintf FORMAT, LIST
5094
5095 Returns a string formatted by the usual C<printf> conventions of the C
5096 library function C<sprintf>.  See below for more details
5097 and see L<sprintf(3)> or L<printf(3)> on your system for an explanation of
5098 the general principles.
5099
5100 For example:
5101
5102         # Format number with up to 8 leading zeroes
5103         $result = sprintf("%08d", $number);
5104
5105         # Round number to 3 digits after decimal point
5106         $rounded = sprintf("%.3f", $number);
5107
5108 Perl does its own C<sprintf> formatting--it emulates the C
5109 function C<sprintf>, but it doesn't use it (except for floating-point
5110 numbers, and even then only the standard modifiers are allowed).  As a
5111 result, any non-standard extensions in your local C<sprintf> are not
5112 available from Perl.
5113
5114 Unlike C<printf>, C<sprintf> does not do what you probably mean when you
5115 pass it an array as your first argument. The array is given scalar context,
5116 and instead of using the 0th element of the array as the format, Perl will
5117 use the count of elements in the array as the format, which is almost never
5118 useful.
5119
5120 Perl's C<sprintf> permits the following universally-known conversions:
5121
5122    %%   a percent sign
5123    %c   a character with the given number
5124    %s   a string
5125    %d   a signed integer, in decimal
5126    %u   an unsigned integer, in decimal
5127    %o   an unsigned integer, in octal
5128    %x   an unsigned integer, in hexadecimal
5129    %e   a floating-point number, in scientific notation
5130    %f   a floating-point number, in fixed decimal notation
5131    %g   a floating-point number, in %e or %f notation
5132
5133 In addition, Perl permits the following widely-supported conversions:
5134
5135    %X   like %x, but using upper-case letters
5136    %E   like %e, but using an upper-case "E"
5137    %G   like %g, but with an upper-case "E" (if applicable)
5138    %b   an unsigned integer, in binary
5139    %p   a pointer (outputs the Perl value's address in hexadecimal)
5140    %n   special: *stores* the number of characters output so far
5141         into the next variable in the parameter list
5142
5143 Finally, for backward (and we do mean "backward") compatibility, Perl
5144 permits these unnecessary but widely-supported conversions:
5145
5146    %i   a synonym for %d
5147    %D   a synonym for %ld
5148    %U   a synonym for %lu
5149    %O   a synonym for %lo
5150    %F   a synonym for %f
5151
5152 Note that the number of exponent digits in the scientific notation produced
5153 by C<%e>, C<%E>, C<%g> and C<%G> for numbers with the modulus of the
5154 exponent less than 100 is system-dependent: it may be three or less
5155 (zero-padded as necessary).  In other words, 1.23 times ten to the
5156 99th may be either "1.23e99" or "1.23e099".
5157
5158 Between the C<%> and the format letter, you may specify a number of
5159 additional attributes controlling the interpretation of the format.
5160 In order, these are:
5161
5162 =over 4
5163
5164 =item format parameter index
5165
5166 An explicit format parameter index, such as C<2$>. By default sprintf
5167 will format the next unused argument in the list, but this allows you
5168 to take the arguments out of order. Eg:
5169
5170   printf '%2$d %1$d', 12, 34;      # prints "34 12"
5171   printf '%3$d %d %1$d', 1, 2, 3;  # prints "3 1 1"
5172
5173 =item flags
5174
5175 one or more of:
5176    space   prefix positive number with a space
5177    +       prefix positive number with a plus sign
5178    -       left-justify within the field
5179    0       use zeros, not spaces, to right-justify
5180    #       prefix non-zero octal with "0", non-zero hex with "0x",
5181            non-zero binary with "0b"
5182
5183 For example:
5184
5185   printf '<% d>', 12;   # prints "< 12>"
5186   printf '<%+d>', 12;   # prints "<+12>"
5187   printf '<%6s>', 12;   # prints "<    12>"
5188   printf '<%-6s>', 12;  # prints "<12    >"
5189   printf '<%06s>', 12;  # prints "<000012>"
5190   printf '<%#x>', 12;   # prints "<0xc>"
5191
5192 =item vector flag
5193
5194 The vector flag C<v>, optionally specifying the join string to use.
5195 This flag tells perl to interpret the supplied string as a vector
5196 of integers, one for each character in the string, separated by
5197 a given string (a dot C<.> by default). This can be useful for
5198 displaying ordinal values of characters in arbitrary strings:
5199
5200   printf "version is v%vd\n", $^V;     # Perl's version
5201
5202 Put an asterisk C<*> before the C<v> to override the string to
5203 use to separate the numbers:
5204
5205   printf "address is %*vX\n", ":", $addr;   # IPv6 address
5206   printf "bits are %0*v8b\n", " ", $bits;   # random bitstring
5207
5208 You can also explicitly specify the argument number to use for
5209 the join string using eg C<*2$v>:
5210
5211   printf '%*4$vX %*4$vX %*4$vX', @addr[1..3], ":";   # 3 IPv6 addresses
5212
5213 =item (minimum) width
5214
5215 Arguments are usually formatted to be only as wide as required to
5216 display the given value. You can override the width by putting
5217 a number here, or get the width from the next argument (with C<*>)
5218 or from a specified argument (with eg C<*2$>):
5219
5220   printf '<%s>', "a";       # prints "<a>"
5221   printf '<%6s>', "a";      # prints "<     a>"
5222   printf '<%*s>', 6, "a";   # prints "<     a>"
5223   printf '<%*2$s>', "a", 6; # prints "<     a>"
5224   printf '<%2s>', "long";   # prints "<long>" (does not truncate)
5225
5226 If a field width obtained through C<*> is negative, it has the same
5227 effect as the C<-> flag: left-justification.
5228
5229 =item precision, or maximum width
5230
5231 You can specify a precision (for numeric conversions) or a maximum
5232 width (for string conversions) by specifying a C<.> followed by a number.
5233 For floating point formats, with the exception of 'g' and 'G', this specifies
5234 the number of decimal places to show (the default being 6), eg:
5235
5236   # these examples are subject to system-specific variation
5237   printf '<%f>', 1;    # prints "<1.000000>"
5238   printf '<%.1f>', 1;  # prints "<1.0>"
5239   printf '<%.0f>', 1;  # prints "<1>"
5240   printf '<%e>', 10;   # prints "<1.000000e+01>"
5241   printf '<%.1e>', 10; # prints "<1.0e+01>"
5242
5243 For 'g' and 'G', this specifies the maximum number of digits to show,
5244 including prior to the decimal point as well as after it, eg:
5245
5246   # these examples are subject to system-specific variation
5247   printf '<%g>', 1;        # prints "<1>"
5248   printf '<%.10g>', 1;     # prints "<1>"
5249   printf '<%g>', 100;      # prints "<100>"
5250   printf '<%.1g>', 100;    # prints "<1e+02>"
5251   printf '<%.2g>', 100.01; # prints "<1e+02>"
5252   printf '<%.5g>', 100.01; # prints "<100.01>"
5253   printf '<%.4g>', 100.01; # prints "<100>"
5254
5255 For integer conversions, specifying a precision implies that the
5256 output of the number itself should be zero-padded to this width:
5257
5258   printf '<%.6x>', 1;      # prints "<000001>"
5259   printf '<%#.6x>', 1;     # prints "<0x000001>"
5260   printf '<%-10.6x>', 1;   # prints "<000001    >"
5261
5262 For string conversions, specifying a precision truncates the string
5263 to fit in the specified width:
5264
5265   printf '<%.5s>', "truncated";   # prints "<trunc>"
5266   printf '<%10.5s>', "truncated"; # prints "<     trunc>"
5267
5268 You can also get the precision from the next argument using C<.*>:
5269
5270   printf '<%.6x>', 1;       # prints "<000001>"
5271   printf '<%.*x>', 6, 1;    # prints "<000001>"
5272
5273 You cannot currently get the precision from a specified number,
5274 but it is intended that this will be possible in the future using
5275 eg C<.*2$>:
5276
5277   printf '<%.*2$x>', 1, 6;   # INVALID, but in future will print "<000001>"
5278
5279 =item size
5280
5281 For numeric conversions, you can specify the size to interpret the
5282 number as using C<l>, C<h>, C<V>, C<q>, C<L>, or C<ll>. For integer
5283 conversions (C<d u o x X b i D U O>), numbers are usually assumed to be
5284 whatever the default integer size is on your platform (usually 32 or 64
5285 bits), but you can override this to use instead one of the standard C types,
5286 as supported by the compiler used to build Perl:
5287
5288    l           interpret integer as C type "long" or "unsigned long"
5289    h           interpret integer as C type "short" or "unsigned short"
5290    q, L or ll  interpret integer as C type "long long", "unsigned long long".
5291                or "quads" (typically 64-bit integers)
5292
5293 The last will produce errors if Perl does not understand "quads" in your
5294 installation. (This requires that either the platform natively supports quads
5295 or Perl was specifically compiled to support quads.) You can find out
5296 whether your Perl supports quads via L<Config>:
5297
5298         use Config;
5299         ($Config{use64bitint} eq 'define' || $Config{longsize} >= 8) &&
5300                 print "quads\n";
5301
5302 For floating point conversions (C<e f g E F G>), numbers are usually assumed
5303 to be the default floating point size on your platform (double or long double),
5304 but you can force 'long double' with C<q>, C<L>, or C<ll> if your
5305 platform supports them. You can find out whether your Perl supports long
5306 doubles via L<Config>:
5307
5308         use Config;
5309         $Config{d_longdbl} eq 'define' && print "long doubles\n";
5310
5311 You can find out whether Perl considers 'long double' to be the default
5312 floating point size to use on your platform via L<Config>:
5313
5314         use Config;
5315         ($Config{uselongdouble} eq 'define') &&
5316                 print "long doubles by default\n";
5317
5318 It can also be the case that long doubles and doubles are the same thing:
5319
5320         use Config;
5321         ($Config{doublesize} == $Config{longdblsize}) &&
5322                 print "doubles are long doubles\n";
5323
5324 The size specifier C<V> has no effect for Perl code, but it is supported
5325 for compatibility with XS code; it means 'use the standard size for
5326 a Perl integer (or floating-point number)', which is already the
5327 default for Perl code.
5328
5329 =item order of arguments
5330
5331 Normally, sprintf takes the next unused argument as the value to
5332 format for each format specification. If the format specification
5333 uses C<*> to require additional arguments, these are consumed from
5334 the argument list in the order in which they appear in the format
5335 specification I<before> the value to format. Where an argument is
5336 specified using an explicit index, this does not affect the normal
5337 order for the arguments (even when the explicitly specified index
5338 would have been the next argument in any case).
5339
5340 So:
5341
5342   printf '<%*.*s>', $a, $b, $c;
5343
5344 would use C<$a> for the width, C<$b> for the precision and C<$c>
5345 as the value to format, while:
5346
5347   print '<%*1$.*s>', $a, $b;
5348
5349 would use C<$a> for the width and the precision, and C<$b> as the
5350 value to format.
5351
5352 Here are some more examples - beware that when using an explicit
5353 index, the C<$> may need to be escaped:
5354
5355   printf "%2\$d %d\n",    12, 34;               # will print "34 12\n"
5356   printf "%2\$d %d %d\n", 12, 34;               # will print "34 12 34\n"
5357   printf "%3\$d %d %d\n", 12, 34, 56;           # will print "56 12 34\n"
5358   printf "%2\$*3\$d %d\n", 12, 34, 3;           # will print " 34 12\n"
5359
5360 =back
5361
5362 If C<use locale> is in effect, the character used for the decimal
5363 point in formatted real numbers is affected by the LC_NUMERIC locale.
5364 See L<perllocale>.
5365
5366 =item sqrt EXPR
5367
5368 =item sqrt
5369
5370 Return the square root of EXPR.  If EXPR is omitted, returns square
5371 root of C<$_>.  Only works on non-negative operands, unless you've
5372 loaded the standard Math::Complex module.
5373
5374     use Math::Complex;
5375     print sqrt(-2);    # prints 1.4142135623731i
5376
5377 =item srand EXPR
5378
5379 =item srand
5380
5381 Sets the random number seed for the C<rand> operator.
5382
5383 The point of the function is to "seed" the C<rand> function so that
5384 C<rand> can produce a different sequence each time you run your
5385 program.
5386
5387 If srand() is not called explicitly, it is called implicitly at the
5388 first use of the C<rand> operator.  However, this was not the case in
5389 versions of Perl before 5.004, so if your script will run under older
5390 Perl versions, it should call C<srand>.
5391
5392 Most programs won't even call srand() at all, except those that
5393 need a cryptographically-strong starting point rather than the
5394 generally acceptable default, which is based on time of day,
5395 process ID, and memory allocation, or the F</dev/urandom> device,
5396 if available.
5397
5398 You can call srand($seed) with the same $seed to reproduce the
5399 I<same> sequence from rand(), but this is usually reserved for
5400 generating predictable results for testing or debugging.
5401 Otherwise, don't call srand() more than once in your program.
5402
5403 Do B<not> call srand() (i.e. without an argument) more than once in
5404 a script.  The internal state of the random number generator should
5405 contain more entropy than can be provided by any seed, so calling
5406 srand() again actually I<loses> randomness.
5407
5408 Most implementations of C<srand> take an integer and will silently
5409 truncate decimal numbers.  This means C<srand(42)> will usually
5410 produce the same results as C<srand(42.1)>.  To be safe, always pass
5411 C<srand> an integer.
5412
5413 In versions of Perl prior to 5.004 the default seed was just the
5414 current C<time>.  This isn't a particularly good seed, so many old
5415 programs supply their own seed value (often C<time ^ $$> or C<time ^
5416 ($$ + ($$ << 15))>), but that isn't necessary any more.
5417
5418 Note that you need something much more random than the default seed for
5419 cryptographic purposes.  Checksumming the compressed output of one or more
5420 rapidly changing operating system status programs is the usual method.  For
5421 example:
5422
5423     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
5424
5425 If you're particularly concerned with this, see the C<Math::TrulyRandom>
5426 module in CPAN.
5427
5428 Frequently called programs (like CGI scripts) that simply use
5429
5430     time ^ $$
5431
5432 for a seed can fall prey to the mathematical property that
5433
5434     a^b == (a+1)^(b+1)
5435
5436 one-third of the time.  So don't do that.
5437
5438 =item stat FILEHANDLE
5439
5440 =item stat EXPR
5441
5442 =item stat
5443
5444 Returns a 13-element list giving the status info for a file, either
5445 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
5446 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
5447 as follows:
5448
5449     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
5450        $atime,$mtime,$ctime,$blksize,$blocks)
5451            = stat($filename);
5452
5453 Not all fields are supported on all filesystem types.  Here are the
5454 meanings of the fields:
5455
5456   0 dev      device number of filesystem
5457   1 ino      inode number
5458   2 mode     file mode  (type and permissions)
5459   3 nlink    number of (hard) links to the file
5460   4 uid      numeric user ID of file's owner
5461   5 gid      numeric group ID of file's owner
5462   6 rdev     the device identifier (special files only)
5463   7 size     total size of file, in bytes
5464   8 atime    last access time in seconds since the epoch
5465   9 mtime    last modify time in seconds since the epoch
5466  10 ctime    inode change time in seconds since the epoch (*)
5467  11 blksize  preferred block size for file system I/O
5468  12 blocks   actual number of blocks allocated
5469
5470 (The epoch was at 00:00 January 1, 1970 GMT.)
5471
5472 (*) Not all fields are supported on all filesystem types. Notably, the
5473 ctime field is non-portable.  In particular, you cannot expect it to be a
5474 "creation time", see L<perlport/"Files and Filesystems"> for details.
5475
5476 If C<stat> is passed the special filehandle consisting of an underline, no
5477 stat is done, but the current contents of the stat structure from the
5478 last C<stat>, C<lstat>, or filetest are returned.  Example:
5479
5480     if (-x $file && (($d) = stat(_)) && $d < 0) {
5481         print "$file is executable NFS file\n";
5482     }
5483
5484 (This works on machines only for which the device number is negative
5485 under NFS.)
5486
5487 Because the mode contains both the file type and its permissions, you
5488 should mask off the file type portion and (s)printf using a C<"%o">
5489 if you want to see the real permissions.
5490
5491     $mode = (stat($filename))[2];
5492     printf "Permissions are %04o\n", $mode & 07777;
5493
5494 In scalar context, C<stat> returns a boolean value indicating success
5495 or failure, and, if successful, sets the information associated with
5496 the special filehandle C<_>.
5497
5498 The File::stat module provides a convenient, by-name access mechanism:
5499
5500     use File::stat;
5501     $sb = stat($filename);
5502     printf "File is %s, size is %s, perm %04o, mtime %s\n",
5503         $filename, $sb->size, $sb->mode & 07777,
5504         scalar localtime $sb->mtime;
5505
5506 You can import symbolic mode constants (C<S_IF*>) and functions
5507 (C<S_IS*>) from the Fcntl module:
5508
5509     use Fcntl ':mode';
5510
5511     $mode = (stat($filename))[2];
5512
5513     $user_rwx      = ($mode & S_IRWXU) >> 6;
5514     $group_read    = ($mode & S_IRGRP) >> 3;
5515     $other_execute =  $mode & S_IXOTH;
5516
5517     printf "Permissions are %04o\n", S_IMODE($mode), "\n";
5518
5519     $is_setuid     =  $mode & S_ISUID;
5520     $is_setgid     =  S_ISDIR($mode);
5521
5522 You could write the last two using the C<-u> and C<-d> operators.
5523 The commonly available C<S_IF*> constants are
5524
5525     # Permissions: read, write, execute, for user, group, others.
5526
5527     S_IRWXU S_IRUSR S_IWUSR S_IXUSR
5528     S_IRWXG S_IRGRP S_IWGRP S_IXGRP
5529     S_IRWXO S_IROTH S_IWOTH S_IXOTH
5530
5531     # Setuid/Setgid/Stickiness/SaveText.
5532     # Note that the exact meaning of these is system dependent.
5533
5534     S_ISUID S_ISGID S_ISVTX S_ISTXT
5535
5536     # File types.  Not necessarily all are available on your system.
5537
5538     S_IFREG S_IFDIR S_IFLNK S_IFBLK S_ISCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT
5539
5540     # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR.
5541
5542     S_IREAD S_IWRITE S_IEXEC
5543
5544 and the C<S_IF*> functions are
5545
5546     S_IMODE($mode)      the part of $mode containing the permission bits
5547                         and the setuid/setgid/sticky bits
5548
5549     S_IFMT($mode)       the part of $mode containing the file type
5550                         which can be bit-anded with e.g. S_IFREG
5551                         or with the following functions
5552
5553     # The operators -f, -d, -l, -b, -c, -p, and -S.
5554
5555     S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode)
5556     S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode)
5557
5558     # No direct -X operator counterpart, but for the first one
5559     # the -g operator is often equivalent.  The ENFMT stands for
5560     # record flocking enforcement, a platform-dependent feature.
5561
5562     S_ISENFMT($mode) S_ISWHT($mode)
5563
5564 See your native chmod(2) and stat(2) documentation for more details
5565 about the C<S_*> constants.  To get status info for a symbolic link
5566 instead of the target file behind the link, use the C<lstat> function.
5567
5568 =item study SCALAR
5569
5570 =item study
5571
5572 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
5573 doing many pattern matches on the string before it is next modified.
5574 This may or may not save time, depending on the nature and number of
5575 patterns you are searching on, and on the distribution of character
5576 frequencies in the string to be searched--you probably want to compare
5577 run times with and without it to see which runs faster.  Those loops
5578 which scan for many short constant strings (including the constant
5579 parts of more complex patterns) will benefit most.  You may have only
5580 one C<study> active at a time--if you study a different scalar the first
5581 is "unstudied".  (The way C<study> works is this: a linked list of every
5582 character in the string to be searched is made, so we know, for
5583 example, where all the C<'k'> characters are.  From each search string,
5584 the rarest character is selected, based on some static frequency tables
5585 constructed from some C programs and English text.  Only those places
5586 that contain this "rarest" character are examined.)
5587
5588 For example, here is a loop that inserts index producing entries
5589 before any line containing a certain pattern:
5590
5591     while (<>) {
5592         study;
5593         print ".IX foo\n"       if /\bfoo\b/;
5594         print ".IX bar\n"       if /\bbar\b/;
5595         print ".IX blurfl\n"    if /\bblurfl\b/;
5596         # ...
5597         print;
5598     }
5599
5600 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<f>
5601 will be looked at, because C<f> is rarer than C<o>.  In general, this is
5602 a big win except in pathological cases.  The only question is whether
5603 it saves you more time than it took to build the linked list in the
5604 first place.
5605
5606 Note that if you have to look for strings that you don't know till
5607 runtime, you can build an entire loop as a string and C<eval> that to
5608 avoid recompiling all your patterns all the time.  Together with
5609 undefining C<$/> to input entire files as one record, this can be very
5610 fast, often faster than specialized programs like fgrep(1).  The following
5611 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
5612 out the names of those files that contain a match:
5613
5614     $search = 'while (<>) { study;';
5615     foreach $word (@words) {
5616         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
5617     }
5618     $search .= "}";
5619     @ARGV = @files;
5620     undef $/;
5621     eval $search;               # this screams
5622     $/ = "\n";          # put back to normal input delimiter
5623     foreach $file (sort keys(%seen)) {
5624         print $file, "\n";
5625     }
5626
5627 =item sub NAME BLOCK
5628
5629 =item sub NAME (PROTO) BLOCK
5630
5631 =item sub NAME : ATTRS BLOCK
5632
5633 =item sub NAME (PROTO) : ATTRS BLOCK
5634
5635 This is subroutine definition, not a real function I<per se>.
5636 Without a BLOCK it's just a forward declaration.  Without a NAME,
5637 it's an anonymous function declaration, and does actually return
5638 a value: the CODE ref of the closure you just created.
5639
5640 See L<perlsub> and L<perlref> for details about subroutines and
5641 references, and L<attributes> and L<Attribute::Handlers> for more
5642 information about attributes.
5643
5644 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
5645
5646 =item substr EXPR,OFFSET,LENGTH
5647
5648 =item substr EXPR,OFFSET
5649
5650 Extracts a substring out of EXPR and returns it.  First character is at
5651 offset C<0>, or whatever you've set C<$[> to (but don't do that).
5652 If OFFSET is negative (or more precisely, less than C<$[>), starts
5653 that far from the end of the string.  If LENGTH is omitted, returns
5654 everything to the end of the string.  If LENGTH is negative, leaves that
5655 many characters off the end of the string.
5656
5657 You can use the substr() function as an lvalue, in which case EXPR
5658 must itself be an lvalue.  If you assign something shorter than LENGTH,
5659 the string will shrink, and if you assign something longer than LENGTH,
5660 the string will grow to accommodate it.  To keep the string the same
5661 length you may need to pad or chop your value using C<sprintf>.
5662
5663 If OFFSET and LENGTH specify a substring that is partly outside the
5664 string, only the part within the string is returned.  If the substring
5665 is beyond either end of the string, substr() returns the undefined
5666 value and produces a warning.  When used as an lvalue, specifying a
5667 substring that is entirely outside the string is a fatal error.
5668 Here's an example showing the behavior for boundary cases:
5669
5670     my $name = 'fred';
5671     substr($name, 4) = 'dy';            # $name is now 'freddy'
5672     my $null = substr $name, 6, 2;      # returns '' (no warning)
5673     my $oops = substr $name, 7;         # returns undef, with warning
5674     substr($name, 7) = 'gap';           # fatal error
5675
5676 An alternative to using substr() as an lvalue is to specify the
5677 replacement string as the 4th argument.  This allows you to replace
5678 parts of the EXPR and return what was there before in one operation,
5679 just as you can with splice().
5680
5681 Note that the lvalue returned by by the 3-arg version of substr() acts as
5682 a 'magic bullet'; each time it is assigned to, it remembers which part
5683 of the original string is being modified; for example:
5684
5685     $x = '1234';
5686     for (substr($x,1,2)) {
5687         $_ = 'a';   print $x,"\n";      # prints 1a4
5688         $_ = 'xyz'; print $x,"\n";      # prints 1xyz4
5689         $x = '56789';
5690         $_ = 'pq';  print $x,"\n";      # prints 5pq9
5691     }
5692
5693
5694 Prior to Perl version 5.9.1, the result of using an lvalue multiple times was
5695 unspecified.
5696
5697 =item symlink OLDFILE,NEWFILE
5698
5699 Creates a new filename symbolically linked to the old filename.
5700 Returns C<1> for success, C<0> otherwise.  On systems that don't support
5701 symbolic links, produces a fatal error at run time.  To check for that,
5702 use eval:
5703
5704     $symlink_exists = eval { symlink("",""); 1 };
5705
5706 =item syscall NUMBER, LIST
5707
5708 Calls the system call specified as the first element of the list,
5709 passing the remaining elements as arguments to the system call.  If
5710 unimplemented, produces a fatal error.  The arguments are interpreted
5711 as follows: if a given argument is numeric, the argument is passed as
5712 an int.  If not, the pointer to the string value is passed.  You are
5713 responsible to make sure a string is pre-extended long enough to
5714 receive any result that might be written into a string.  You can't use a
5715 string literal (or other read-only string) as an argument to C<syscall>
5716 because Perl has to assume that any string pointer might be written
5717 through.  If your
5718 integer arguments are not literals and have never been interpreted in a
5719 numeric context, you may need to add C<0> to them to force them to look
5720 like numbers.  This emulates the C<syswrite> function (or vice versa):
5721
5722     require 'syscall.ph';               # may need to run h2ph
5723     $s = "hi there\n";
5724     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
5725
5726 Note that Perl supports passing of up to only 14 arguments to your system call,
5727 which in practice should usually suffice.
5728
5729 Syscall returns whatever value returned by the system call it calls.
5730 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
5731 Note that some system calls can legitimately return C<-1>.  The proper
5732 way to handle such calls is to assign C<$!=0;> before the call and
5733 check the value of C<$!> if syscall returns C<-1>.
5734
5735 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
5736 number of the read end of the pipe it creates.  There is no way
5737 to retrieve the file number of the other end.  You can avoid this
5738 problem by using C<pipe> instead.
5739
5740 =item sysopen FILEHANDLE,FILENAME,MODE
5741
5742 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
5743
5744 Opens the file whose filename is given by FILENAME, and associates it
5745 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
5746 the name of the real filehandle wanted.  This function calls the
5747 underlying operating system's C<open> function with the parameters
5748 FILENAME, MODE, PERMS.
5749
5750 The possible values and flag bits of the MODE parameter are
5751 system-dependent; they are available via the standard module C<Fcntl>.
5752 See the documentation of your operating system's C<open> to see which
5753 values and flag bits are available.  You may combine several flags
5754 using the C<|>-operator.
5755
5756 Some of the most common values are C<O_RDONLY> for opening the file in
5757 read-only mode, C<O_WRONLY> for opening the file in write-only mode,
5758 and C<O_RDWR> for opening the file in read-write mode.
5759
5760 For historical reasons, some values work on almost every system
5761 supported by perl: zero means read-only, one means write-only, and two
5762 means read/write.  We know that these values do I<not> work under
5763 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
5764 use them in new code.
5765
5766 If the file named by FILENAME does not exist and the C<open> call creates
5767 it (typically because MODE includes the C<O_CREAT> flag), then the value of
5768 PERMS specifies the permissions of the newly created file.  If you omit
5769 the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>.
5770 These permission values need to be in octal, and are modified by your
5771 process's current C<umask>.
5772
5773 In many systems the C<O_EXCL> flag is available for opening files in
5774 exclusive mode.  This is B<not> locking: exclusiveness means here that
5775 if the file already exists, sysopen() fails.  C<O_EXCL> may not work
5776 on network filesystems, and has no effect unless the C<O_CREAT> flag
5777 is set as well.  Setting C<O_CREAT|O_EXCL> prevents the file from
5778 being opened if it is a symbolic link.  It does not protect against
5779 symbolic links in the file's path.
5780
5781 Sometimes you may want to truncate an already-existing file.  This
5782 can be done using the C<O_TRUNC> flag.  The behavior of
5783 C<O_TRUNC> with C<O_RDONLY> is undefined.
5784
5785 You should seldom if ever use C<0644> as argument to C<sysopen>, because
5786 that takes away the user's option to have a more permissive umask.
5787 Better to omit it.  See the perlfunc(1) entry on C<umask> for more
5788 on this.
5789
5790 Note that C<sysopen> depends on the fdopen() C library function.
5791 On many UNIX systems, fdopen() is known to fail when file descriptors
5792 exceed a certain value, typically 255. If you need more file
5793 descriptors than that, consider rebuilding Perl to use the C<sfio>
5794 library, or perhaps using the POSIX::open() function.
5795
5796 See L<perlopentut> for a kinder, gentler explanation of opening files.
5797
5798 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
5799
5800 =item sysread FILEHANDLE,SCALAR,LENGTH
5801
5802 Attempts to read LENGTH bytes of data into variable SCALAR from the
5803 specified FILEHANDLE, using the system call read(2).  It bypasses
5804 buffered IO, so mixing this with other kinds of reads, C<print>,
5805 C<write>, C<seek>, C<tell>, or C<eof> can cause confusion because the
5806 perlio or stdio layers usually buffers data.  Returns the number of
5807 bytes actually read, C<0> at end of file, or undef if there was an
5808 error (in the latter case C<$!> is also set).  SCALAR will be grown or
5809 shrunk so that the last byte actually read is the last byte of the
5810 scalar after the read.
5811
5812 An OFFSET may be specified to place the read data at some place in the
5813 string other than the beginning.  A negative OFFSET specifies
5814 placement at that many characters counting backwards from the end of
5815 the string.  A positive OFFSET greater than the length of SCALAR
5816 results in the string being padded to the required size with C<"\0">
5817 bytes before the result of the read is appended.
5818
5819 There is no syseof() function, which is ok, since eof() doesn't work
5820 very well on device files (like ttys) anyway.  Use sysread() and check
5821 for a return value for 0 to decide whether you're done.
5822
5823 Note that if the filehandle has been marked as C<:utf8> Unicode
5824 characters are read instead of bytes (the LENGTH, OFFSET, and the
5825 return value of sysread() are in Unicode characters).
5826 The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer.
5827 See L</binmode>, L</open>, and the C<open> pragma, L<open>.
5828
5829 =item sysseek FILEHANDLE,POSITION,WHENCE
5830
5831 Sets FILEHANDLE's system position in bytes using the system call
5832 lseek(2).  FILEHANDLE may be an expression whose value gives the name
5833 of the filehandle.  The values for WHENCE are C<0> to set the new
5834 position to POSITION, C<1> to set the it to the current position plus
5835 POSITION, and C<2> to set it to EOF plus POSITION (typically
5836 negative).
5837
5838 Note the I<in bytes>: even if the filehandle has been set to operate
5839 on characters (for example by using the C<:utf8> I/O layer), tell()
5840 will return byte offsets, not character offsets (because implementing
5841 that would render sysseek() very slow).
5842
5843 sysseek() bypasses normal buffered IO, so mixing this with reads (other
5844 than C<sysread>, for example &gt;&lt or read()) C<print>, C<write>,
5845 C<seek>, C<tell>, or C<eof> may cause confusion.
5846
5847 For WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>,
5848 and C<SEEK_END> (start of the file, current position, end of the file)
5849 from the Fcntl module.  Use of the constants is also more portable
5850 than relying on 0, 1, and 2.  For example to define a "systell" function:
5851
5852         use Fcntl 'SEEK_CUR';
5853         sub systell { sysseek($_[0], 0, SEEK_CUR) }
5854
5855 Returns the new position, or the undefined value on failure.  A position
5856 of zero is returned as the string C<"0 but true">; thus C<sysseek> returns
5857 true on success and false on failure, yet you can still easily determine
5858 the new position.
5859
5860 =item system LIST
5861
5862 =item system PROGRAM LIST
5863
5864 Does exactly the same thing as C<exec LIST>, except that a fork is
5865 done first, and the parent process waits for the child process to
5866 complete.  Note that argument processing varies depending on the
5867 number of arguments.  If there is more than one argument in LIST,
5868 or if LIST is an array with more than one value, starts the program
5869 given by the first element of the list with arguments given by the
5870 rest of the list.  If there is only one scalar argument, the argument
5871 is checked for shell metacharacters, and if there are any, the
5872 entire argument is passed to the system's command shell for parsing
5873 (this is C</bin/sh -c> on Unix platforms, but varies on other
5874 platforms).  If there are no shell metacharacters in the argument,
5875 it is split into words and passed directly to C<execvp>, which is
5876 more efficient.
5877
5878 Beginning with v5.6.0, Perl will attempt to flush all files opened for
5879 output before any operation that may do a fork, but this may not be
5880 supported on some platforms (see L<perlport>).  To be safe, you may need
5881 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
5882 of C<IO::Handle> on any open handles.
5883
5884 The return value is the exit status of the program as returned by the
5885 C<wait> call.  To get the actual exit value shift right by eight (see below).
5886 See also L</exec>.  This is I<not> what you want to use to capture
5887 the output from a command, for that you should use merely backticks or
5888 C<qx//>, as described in L<perlop/"`STRING`">.  Return value of -1
5889 indicates a failure to start the program (inspect $! for the reason).
5890
5891 Like C<exec>, C<system> allows you to lie to a program about its name if
5892 you use the C<system PROGRAM LIST> syntax.  Again, see L</exec>.
5893
5894 Since C<SIGINT> and C<SIGQUIT> are ignored during the execution of
5895 C<system>, if you expect your program to terminate on receipt of these
5896 signals you will need to arrange to do so yourself based on the return
5897 value.
5898
5899     @args = ("command", "arg1", "arg2");
5900     system(@args) == 0
5901          or die "system @args failed: $?"
5902
5903 You can check all the failure possibilities by inspecting
5904 C<$?> like this:
5905
5906     if ($? == -1) {
5907         print "failed to execute: $!\n";
5908     }
5909     elsif ($? & 127) {
5910         printf "child died with signal %d, %s coredump\n",
5911             ($? & 127),  ($? & 128) ? 'with' : 'without';
5912     }
5913     else {
5914         printf "child exited with value %d\n", $? >> 8;
5915     }
5916
5917 or more portably by using the W*() calls of the POSIX extension;
5918 see L<perlport> for more information.
5919
5920 When the arguments get executed via the system shell, results
5921 and return codes will be subject to its quirks and capabilities.
5922 See L<perlop/"`STRING`"> and L</exec> for details.
5923
5924 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
5925
5926 =item syswrite FILEHANDLE,SCALAR,LENGTH
5927
5928 =item syswrite FILEHANDLE,SCALAR
5929
5930 Attempts to write LENGTH bytes of data from variable SCALAR to the
5931 specified FILEHANDLE, using the system call write(2).  If LENGTH is
5932 not specified, writes whole SCALAR.  It bypasses buffered IO, so
5933 mixing this with reads (other than C<sysread())>, C<print>, C<write>,
5934 C<seek>, C<tell>, or C<eof> may cause confusion because the perlio and
5935 stdio layers usually buffers data.  Returns the number of bytes
5936 actually written, or C<undef> if there was an error (in this case the
5937 errno variable C<$!> is also set).  If the LENGTH is greater than the
5938 available data in the SCALAR after the OFFSET, only as much data as is
5939 available will be written.
5940
5941 An OFFSET may be specified to write the data from some part of the
5942 string other than the beginning.  A negative OFFSET specifies writing
5943 that many characters counting backwards from the end of the string.
5944 In the case the SCALAR is empty you can use OFFSET but only zero offset.
5945
5946 Note that if the filehandle has been marked as C<:utf8>, Unicode
5947 characters are written instead of bytes (the LENGTH, OFFSET, and the
5948 return value of syswrite() are in UTF-8 encoded Unicode characters).
5949 The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer.
5950 See L</binmode>, L</open>, and the C<open> pragma, L<open>.
5951
5952 =item tell FILEHANDLE
5953
5954 =item tell
5955
5956 Returns the current position I<in bytes> for FILEHANDLE, or -1 on
5957 error.  FILEHANDLE may be an expression whose value gives the name of
5958 the actual filehandle.  If FILEHANDLE is omitted, assumes the file
5959 last read.
5960
5961 Note the I<in bytes>: even if the filehandle has been set to
5962 operate on characters (for example by using the C<:utf8> open
5963 layer), tell() will return byte offsets, not character offsets
5964 (because that would render seek() and tell() rather slow).
5965
5966 The return value of tell() for the standard streams like the STDIN
5967 depends on the operating system: it may return -1 or something else.
5968 tell() on pipes, fifos, and sockets usually returns -1.
5969
5970 There is no C<systell> function.  Use C<sysseek(FH, 0, 1)> for that.
5971
5972 Do not use tell() (or other buffered I/O operations) on a file handle
5973 that has been manipulated by sysread(), syswrite() or sysseek().
5974 Those functions ignore the buffering, while tell() does not.
5975
5976 =item telldir DIRHANDLE
5977
5978 Returns the current position of the C<readdir> routines on DIRHANDLE.
5979 Value may be given to C<seekdir> to access a particular location in a
5980 directory.  Has the same caveats about possible directory compaction as
5981 the corresponding system library routine.
5982
5983 =item tie VARIABLE,CLASSNAME,LIST
5984
5985 This function binds a variable to a package class that will provide the
5986 implementation for the variable.  VARIABLE is the name of the variable
5987 to be enchanted.  CLASSNAME is the name of a class implementing objects
5988 of correct type.  Any additional arguments are passed to the C<new>
5989 method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>,
5990 or C<TIEHASH>).  Typically these are arguments such as might be passed
5991 to the C<dbm_open()> function of C.  The object returned by the C<new>
5992 method is also returned by the C<tie> function, which would be useful
5993 if you want to access other methods in CLASSNAME.
5994
5995 Note that functions such as C<keys> and C<values> may return huge lists
5996 when used on large objects, like DBM files.  You may prefer to use the
5997 C<each> function to iterate over such.  Example:
5998
5999     # print out history file offsets
6000     use NDBM_File;
6001     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
6002     while (($key,$val) = each %HIST) {
6003         print $key, ' = ', unpack('L',$val), "\n";
6004     }
6005     untie(%HIST);
6006
6007 A class implementing a hash should have the following methods:
6008
6009     TIEHASH classname, LIST
6010     FETCH this, key
6011     STORE this, key, value
6012     DELETE this, key
6013     CLEAR this
6014     EXISTS this, key
6015     FIRSTKEY this
6016     NEXTKEY this, lastkey
6017     SCALAR this
6018     DESTROY this
6019     UNTIE this
6020
6021 A class implementing an ordinary array should have the following methods:
6022
6023     TIEARRAY classname, LIST
6024     FETCH this, key
6025     STORE this, key, value
6026     FETCHSIZE this
6027     STORESIZE this, count
6028     CLEAR this
6029     PUSH this, LIST
6030     POP this
6031     SHIFT this
6032     UNSHIFT this, LIST
6033     SPLICE this, offset, length, LIST
6034     EXTEND this, count
6035     DESTROY this
6036     UNTIE this
6037
6038 A class implementing a file handle should have the following methods:
6039
6040     TIEHANDLE classname, LIST
6041     READ this, scalar, length, offset
6042     READLINE this
6043     GETC this
6044     WRITE this, scalar, length, offset
6045     PRINT this, LIST
6046     PRINTF this, format, LIST
6047     BINMODE this
6048     EOF this
6049     FILENO this
6050     SEEK this, position, whence
6051     TELL this
6052     OPEN this, mode, LIST
6053     CLOSE this
6054     DESTROY this
6055     UNTIE this
6056
6057 A class implementing a scalar should have the following methods:
6058
6059     TIESCALAR classname, LIST
6060     FETCH this,
6061     STORE this, value
6062     DESTROY this
6063     UNTIE this
6064
6065 Not all methods indicated above need be implemented.  See L<perltie>,
6066 L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar>, and L<Tie::Handle>.
6067
6068 Unlike C<dbmopen>, the C<tie> function will not use or require a module
6069 for you--you need to do that explicitly yourself.  See L<DB_File>
6070 or the F<Config> module for interesting C<tie> implementations.
6071
6072 For further details see L<perltie>, L<"tied VARIABLE">.
6073
6074 =item tied VARIABLE
6075
6076 Returns a reference to the object underlying VARIABLE (the same value
6077 that was originally returned by the C<tie> call that bound the variable
6078 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
6079 package.
6080
6081 =item time
6082
6083 Returns the number of non-leap seconds since whatever time the system
6084 considers to be the epoch, suitable for feeding to C<gmtime> and
6085 C<localtime>. On most systems the epoch is 00:00:00 UTC, January 1, 1970;
6086 a prominent exception being Mac OS Classic which uses 00:00:00, January 1,
6087 1904 in the current local time zone for its epoch.
6088
6089 For measuring time in better granularity than one second,
6090 you may use either the Time::HiRes module (from CPAN, and starting from
6091 Perl 5.8 part of the standard distribution), or if you have
6092 gettimeofday(2), you may be able to use the C<syscall> interface of Perl.
6093 See L<perlfaq8> for details.
6094
6095 =item times
6096
6097 Returns a four-element list giving the user and system times, in
6098 seconds, for this process and the children of this process.
6099
6100     ($user,$system,$cuser,$csystem) = times;
6101
6102 In scalar context, C<times> returns C<$user>.
6103
6104 =item tr///
6105
6106 The transliteration operator.  Same as C<y///>.  See L<perlop>.
6107
6108 =item truncate FILEHANDLE,LENGTH
6109
6110 =item truncate EXPR,LENGTH
6111
6112 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
6113 specified length.  Produces a fatal error if truncate isn't implemented
6114 on your system.  Returns true if successful, the undefined value
6115 otherwise.
6116
6117 The behavior is undefined if LENGTH is greater than the length of the
6118 file.
6119
6120 =item uc EXPR
6121
6122 =item uc
6123
6124 Returns an uppercased version of EXPR.  This is the internal function
6125 implementing the C<\U> escape in double-quoted strings.  Respects
6126 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
6127 and L<perlunicode> for more details about locale and Unicode support.
6128 It does not attempt to do titlecase mapping on initial letters.  See
6129 C<ucfirst> for that.
6130
6131 If EXPR is omitted, uses C<$_>.
6132
6133 =item ucfirst EXPR
6134
6135 =item ucfirst
6136
6137 Returns the value of EXPR with the first character in uppercase
6138 (titlecase in Unicode).  This is the internal function implementing
6139 the C<\u> escape in double-quoted strings.  Respects current LC_CTYPE
6140 locale if C<use locale> in force.  See L<perllocale> and L<perlunicode>
6141 for more details about locale and Unicode support.
6142
6143 If EXPR is omitted, uses C<$_>.
6144
6145 =item umask EXPR
6146
6147 =item umask
6148
6149 Sets the umask for the process to EXPR and returns the previous value.
6150 If EXPR is omitted, merely returns the current umask.
6151
6152 The Unix permission C<rwxr-x---> is represented as three sets of three
6153 bits, or three octal digits: C<0750> (the leading 0 indicates octal
6154 and isn't one of the digits).  The C<umask> value is such a number
6155 representing disabled permissions bits.  The permission (or "mode")
6156 values you pass C<mkdir> or C<sysopen> are modified by your umask, so
6157 even if you tell C<sysopen> to create a file with permissions C<0777>,
6158 if your umask is C<0022> then the file will actually be created with
6159 permissions C<0755>.  If your C<umask> were C<0027> (group can't
6160 write; others can't read, write, or execute), then passing
6161 C<sysopen> C<0666> would create a file with mode C<0640> (C<0666 &~
6162 027> is C<0640>).
6163
6164 Here's some advice: supply a creation mode of C<0666> for regular
6165 files (in C<sysopen>) and one of C<0777> for directories (in
6166 C<mkdir>) and executable files.  This gives users the freedom of
6167 choice: if they want protected files, they might choose process umasks
6168 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.
6169 Programs should rarely if ever make policy decisions better left to
6170 the user.  The exception to this is when writing files that should be
6171 kept private: mail files, web browser cookies, I<.rhosts> files, and
6172 so on.
6173
6174 If umask(2) is not implemented on your system and you are trying to
6175 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
6176 fatal error at run time.  If umask(2) is not implemented and you are
6177 not trying to restrict access for yourself, returns C<undef>.
6178
6179 Remember that a umask is a number, usually given in octal; it is I<not> a
6180 string of octal digits.  See also L</oct>, if all you have is a string.
6181
6182 =item undef EXPR
6183
6184 =item undef
6185
6186 Undefines the value of EXPR, which must be an lvalue.  Use only on a
6187 scalar value, an array (using C<@>), a hash (using C<%>), a subroutine
6188 (using C<&>), or a typeglob (using C<*>).  (Saying C<undef $hash{$key}>
6189 will probably not do what you expect on most predefined variables or
6190 DBM list values, so don't do that; see L<delete>.)  Always returns the
6191 undefined value.  You can omit the EXPR, in which case nothing is
6192 undefined, but you still get an undefined value that you could, for
6193 instance, return from a subroutine, assign to a variable or pass as a
6194 parameter.  Examples:
6195
6196     undef $foo;
6197     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
6198     undef @ary;
6199     undef %hash;
6200     undef &mysub;
6201     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
6202     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
6203     select undef, undef, undef, 0.25;
6204     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
6205
6206 Note that this is a unary operator, not a list operator.
6207
6208 =item unlink LIST
6209
6210 =item unlink
6211
6212 Deletes a list of files.  Returns the number of files successfully
6213 deleted.
6214
6215     $cnt = unlink 'a', 'b', 'c';
6216     unlink @goners;
6217     unlink <*.bak>;
6218
6219 Note: C<unlink> will not delete directories unless you are superuser and
6220 the B<-U> flag is supplied to Perl.  Even if these conditions are
6221 met, be warned that unlinking a directory can inflict damage on your
6222 filesystem.  Use C<rmdir> instead.
6223
6224 If LIST is omitted, uses C<$_>.
6225
6226 =item unpack TEMPLATE,EXPR
6227
6228 =item unpack TEMPLATE
6229
6230 C<unpack> does the reverse of C<pack>: it takes a string
6231 and expands it out into a list of values.
6232 (In scalar context, it returns merely the first value produced.)
6233
6234 If EXPR is omitted, unpacks the C<$_> string.
6235
6236 The string is broken into chunks described by the TEMPLATE.  Each chunk
6237 is converted separately to a value.  Typically, either the string is a result
6238 of C<pack>, or the bytes of the string represent a C structure of some
6239 kind.
6240
6241 The TEMPLATE has the same format as in the C<pack> function.
6242 Here's a subroutine that does substring:
6243
6244     sub substr {
6245         my($what,$where,$howmuch) = @_;
6246         unpack("x$where a$howmuch", $what);
6247     }
6248
6249 and then there's
6250
6251     sub ordinal { unpack("c",$_[0]); } # same as ord()
6252
6253 In addition to fields allowed in pack(), you may prefix a field with
6254 a %<number> to indicate that
6255 you want a <number>-bit checksum of the items instead of the items
6256 themselves.  Default is a 16-bit checksum.  Checksum is calculated by
6257 summing numeric values of expanded values (for string fields the sum of
6258 C<ord($char)> is taken, for bit fields the sum of zeroes and ones).
6259
6260 For example, the following
6261 computes the same number as the System V sum program:
6262
6263     $checksum = do {
6264         local $/;  # slurp!
6265         unpack("%32C*",<>) % 65535;
6266     };
6267
6268 The following efficiently counts the number of set bits in a bit vector:
6269
6270     $setbits = unpack("%32b*", $selectmask);
6271
6272 The C<p> and C<P> formats should be used with care.  Since Perl
6273 has no way of checking whether the value passed to C<unpack()>
6274 corresponds to a valid memory location, passing a pointer value that's
6275 not known to be valid is likely to have disastrous consequences.
6276
6277 If there are more pack codes or if the repeat count of a field or a group
6278 is larger than what the remainder of the input string allows, the result
6279 is not well defined: in some cases, the repeat count is decreased, or
6280 C<unpack()> will produce null strings or zeroes, or terminate with an
6281 error. If the input string is longer than one described by the TEMPLATE,
6282 the rest is ignored.
6283
6284 See L</pack> for more examples and notes.
6285
6286 =item untie VARIABLE
6287
6288 Breaks the binding between a variable and a package.  (See C<tie>.)
6289 Has no effect if the variable is not tied.
6290
6291 =item unshift ARRAY,LIST
6292
6293 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
6294 depending on how you look at it.  Prepends list to the front of the
6295 array, and returns the new number of elements in the array.
6296
6297     unshift(@ARGV, '-e') unless $ARGV[0] =~ /^-/;
6298
6299 Note the LIST is prepended whole, not one element at a time, so the
6300 prepended elements stay in the same order.  Use C<reverse> to do the
6301 reverse.
6302
6303 =item use Module VERSION LIST
6304
6305 =item use Module VERSION
6306
6307 =item use Module LIST
6308
6309 =item use Module
6310
6311 =item use VERSION
6312
6313 Imports some semantics into the current package from the named module,
6314 generally by aliasing certain subroutine or variable names into your
6315 package.  It is exactly equivalent to
6316
6317     BEGIN { require Module; import Module LIST; }
6318
6319 except that Module I<must> be a bareword.
6320
6321 VERSION may be either a numeric argument such as 5.006, which will be
6322 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
6323 to C<$^V> (aka $PERL_VERSION.  A fatal error is produced if VERSION is
6324 greater than the version of the current Perl interpreter; Perl will not
6325 attempt to parse the rest of the file.  Compare with L</require>, which can
6326 do a similar check at run time.
6327
6328 Specifying VERSION as a literal of the form v5.6.1 should generally be
6329 avoided, because it leads to misleading error messages under earlier
6330 versions of Perl which do not support this syntax.  The equivalent numeric
6331 version should be used instead.
6332
6333     use v5.6.1;         # compile time version check
6334     use 5.6.1;          # ditto
6335     use 5.006_001;      # ditto; preferred for backwards compatibility
6336
6337 This is often useful if you need to check the current Perl version before
6338 C<use>ing library modules that have changed in incompatible ways from
6339 older versions of Perl.  (We try not to do this more than we have to.)
6340
6341 The C<BEGIN> forces the C<require> and C<import> to happen at compile time.  The
6342 C<require> makes sure the module is loaded into memory if it hasn't been
6343 yet.  The C<import> is not a builtin--it's just an ordinary static method
6344 call into the C<Module> package to tell the module to import the list of
6345 features back into the current package.  The module can implement its
6346 C<import> method any way it likes, though most modules just choose to
6347 derive their C<import> method via inheritance from the C<Exporter> class that
6348 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import>
6349 method can be found then the call is skipped, even if there is an AUTOLOAD
6350 method.
6351
6352 If you do not want to call the package's C<import> method (for instance,
6353 to stop your namespace from being altered), explicitly supply the empty list:
6354
6355     use Module ();
6356
6357 That is exactly equivalent to
6358
6359     BEGIN { require Module }
6360
6361 If the VERSION argument is present between Module and LIST, then the
6362 C<use> will call the VERSION method in class Module with the given
6363 version as an argument.  The default VERSION method, inherited from
6364 the UNIVERSAL class, croaks if the given version is larger than the
6365 value of the variable C<$Module::VERSION>.
6366
6367 Again, there is a distinction between omitting LIST (C<import> called
6368 with no arguments) and an explicit empty LIST C<()> (C<import> not
6369 called).  Note that there is no comma after VERSION!
6370
6371 Because this is a wide-open interface, pragmas (compiler directives)
6372 are also implemented this way.  Currently implemented pragmas are:
6373
6374     use constant;
6375     use diagnostics;
6376     use integer;
6377     use sigtrap  qw(SEGV BUS);
6378     use strict   qw(subs vars refs);
6379     use subs     qw(afunc blurfl);
6380     use warnings qw(all);
6381     use sort     qw(stable _quicksort _mergesort);
6382
6383 Some of these pseudo-modules import semantics into the current
6384 block scope (like C<strict> or C<integer>, unlike ordinary modules,
6385 which import symbols into the current package (which are effective
6386 through the end of the file).
6387
6388 There's a corresponding C<no> command that unimports meanings imported
6389 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import>.
6390 It behaves exactly as C<import> does with respect to VERSION, an
6391 omitted LIST, empty LIST, or no unimport method being found.
6392
6393     no integer;
6394     no strict 'refs';
6395     no warnings;
6396
6397 See L<perlmodlib> for a list of standard modules and pragmas.  See L<perlrun>
6398 for the C<-M> and C<-m> command-line options to perl that give C<use>
6399 functionality from the command-line.
6400
6401 =item utime LIST
6402
6403 Changes the access and modification times on each file of a list of
6404 files.  The first two elements of the list must be the NUMERICAL access
6405 and modification times, in that order.  Returns the number of files
6406 successfully changed.  The inode change time of each file is set
6407 to the current time.  For example, this code has the same effect as the
6408 Unix touch(1) command when the files I<already exist> and belong to
6409 the user running the program:
6410
6411     #!/usr/bin/perl
6412     $atime = $mtime = time;
6413     utime $atime, $mtime, @ARGV;
6414
6415 Since perl 5.7.2, if the first two elements of the list are C<undef>, then
6416 the utime(2) function in the C library will be called with a null second
6417 argument. On most systems, this will set the file's access and
6418 modification times to the current time (i.e. equivalent to the example
6419 above) and will even work on other users' files where you have write
6420 permission:
6421
6422     utime undef, undef, @ARGV;
6423
6424 Under NFS this will use the time of the NFS server, not the time of
6425 the local machine.  If there is a time synchronization problem, the
6426 NFS server and local machine will have different times.  The Unix
6427 touch(1) command will in fact normally use this form instead of the
6428 one shown in the first example.
6429
6430 Note that only passing one of the first two elements as C<undef> will
6431 be equivalent of passing it as 0 and will not have the same effect as
6432 described when they are both C<undef>.  This case will also trigger an
6433 uninitialized warning.
6434
6435 =item values HASH
6436
6437 Returns a list consisting of all the values of the named hash.
6438 (In a scalar context, returns the number of values.)
6439
6440 The values are returned in an apparently random order.  The actual
6441 random order is subject to change in future versions of perl, but it
6442 is guaranteed to be the same order as either the C<keys> or C<each>
6443 function would produce on the same (unmodified) hash.  Since Perl
6444 5.8.1 the ordering is different even between different runs of Perl
6445 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
6446
6447 As a side effect, calling values() resets the HASH's internal iterator,
6448 see L</each>. (In particular, calling values() in void context resets
6449 the iterator with no other overhead.)
6450
6451 Note that the values are not copied, which means modifying them will
6452 modify the contents of the hash:
6453
6454     for (values %hash)      { s/foo/bar/g }   # modifies %hash values
6455     for (@hash{keys %hash}) { s/foo/bar/g }   # same
6456
6457 See also C<keys>, C<each>, and C<sort>.
6458
6459 =item vec EXPR,OFFSET,BITS
6460
6461 Treats the string in EXPR as a bit vector made up of elements of
6462 width BITS, and returns the value of the element specified by OFFSET
6463 as an unsigned integer.  BITS therefore specifies the number of bits
6464 that are reserved for each element in the bit vector.  This must
6465 be a power of two from 1 to 32 (or 64, if your platform supports
6466 that).
6467
6468 If BITS is 8, "elements" coincide with bytes of the input string.
6469
6470 If BITS is 16 or more, bytes of the input string are grouped into chunks
6471 of size BITS/8, and each group is converted to a number as with
6472 pack()/unpack() with big-endian formats C<n>/C<N> (and analogously
6473 for BITS==64).  See L<"pack"> for details.
6474
6475 If bits is 4 or less, the string is broken into bytes, then the bits
6476 of each byte are broken into 8/BITS groups.  Bits of a byte are
6477 numbered in a little-endian-ish way, as in C<0x01>, C<0x02>,
6478 C<0x04>, C<0x08>, C<0x10>, C<0x20>, C<0x40>, C<0x80>.  For example,
6479 breaking the single input byte C<chr(0x36)> into two groups gives a list
6480 C<(0x6, 0x3)>; breaking it into 4 groups gives C<(0x2, 0x1, 0x3, 0x0)>.
6481
6482 C<vec> may also be assigned to, in which case parentheses are needed
6483 to give the expression the correct precedence as in
6484
6485     vec($image, $max_x * $x + $y, 8) = 3;
6486
6487 If the selected element is outside the string, the value 0 is returned.
6488 If an element off the end of the string is written to, Perl will first
6489 extend the string with sufficiently many zero bytes.   It is an error
6490 to try to write off the beginning of the string (i.e. negative OFFSET).
6491
6492 The string should not contain any character with the value > 255 (which
6493 can only happen if you're using UTF-8 encoding).  If it does, it will be
6494 treated as something which is not UTF-8 encoded.  When the C<vec> was
6495 assigned to, other parts of your program will also no longer consider the
6496 string to be UTF-8 encoded.  In other words, if you do have such characters
6497 in your string, vec() will operate on the actual byte string, and not the
6498 conceptual character string.
6499
6500 Strings created with C<vec> can also be manipulated with the logical
6501 operators C<|>, C<&>, C<^>, and C<~>.  These operators will assume a bit
6502 vector operation is desired when both operands are strings.
6503 See L<perlop/"Bitwise String Operators">.
6504
6505 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
6506 The comments show the string after each step.  Note that this code works
6507 in the same way on big-endian or little-endian machines.
6508
6509     my $foo = '';
6510     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
6511
6512     # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits
6513     print vec($foo, 0, 8);              # prints 80 == 0x50 == ord('P')
6514
6515     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
6516     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
6517     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
6518     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
6519     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
6520     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
6521                                         # 'r' is "\x72"
6522     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
6523     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
6524     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
6525                                         # 'l' is "\x6c"
6526
6527 To transform a bit vector into a string or list of 0's and 1's, use these:
6528
6529     $bits = unpack("b*", $vector);
6530     @bits = split(//, unpack("b*", $vector));
6531
6532 If you know the exact length in bits, it can be used in place of the C<*>.
6533
6534 Here is an example to illustrate how the bits actually fall in place:
6535
6536     #!/usr/bin/perl -wl
6537
6538     print <<'EOT';
6539                                       0         1         2         3
6540                        unpack("V",$_) 01234567890123456789012345678901
6541     ------------------------------------------------------------------
6542     EOT
6543
6544     for $w (0..3) {
6545         $width = 2**$w;
6546         for ($shift=0; $shift < $width; ++$shift) {
6547             for ($off=0; $off < 32/$width; ++$off) {
6548                 $str = pack("B*", "0"x32);
6549                 $bits = (1<<$shift);
6550                 vec($str, $off, $width) = $bits;
6551                 $res = unpack("b*",$str);
6552                 $val = unpack("V", $str);
6553                 write;
6554             }
6555         }
6556     }
6557
6558     format STDOUT =
6559     vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
6560     $off, $width, $bits, $val, $res
6561     .
6562     __END__
6563
6564 Regardless of the machine architecture on which it is run, the above
6565 example should print the following table:
6566
6567                                       0         1         2         3
6568                        unpack("V",$_) 01234567890123456789012345678901
6569     ------------------------------------------------------------------
6570     vec($_, 0, 1) = 1   ==          1 10000000000000000000000000000000
6571     vec($_, 1, 1) = 1   ==          2 01000000000000000000000000000000
6572     vec($_, 2, 1) = 1   ==          4 00100000000000000000000000000000
6573     vec($_, 3, 1) = 1   ==          8 00010000000000000000000000000000
6574     vec($_, 4, 1) = 1   ==         16 00001000000000000000000000000000
6575     vec($_, 5, 1) = 1   ==         32 00000100000000000000000000000000
6576     vec($_, 6, 1) = 1   ==         64 00000010000000000000000000000000
6577     vec($_, 7, 1) = 1   ==        128 00000001000000000000000000000000
6578     vec($_, 8, 1) = 1   ==        256 00000000100000000000000000000000
6579     vec($_, 9, 1) = 1   ==        512 00000000010000000000000000000000
6580     vec($_,10, 1) = 1   ==       1024 00000000001000000000000000000000
6581     vec($_,11, 1) = 1   ==       2048 00000000000100000000000000000000
6582     vec($_,12, 1) = 1   ==       4096 00000000000010000000000000000000
6583     vec($_,13, 1) = 1   ==       8192 00000000000001000000000000000000
6584     vec($_,14, 1) = 1   ==      16384 00000000000000100000000000000000
6585     vec($_,15, 1) = 1   ==      32768 00000000000000010000000000000000
6586     vec($_,16, 1) = 1   ==      65536 00000000000000001000000000000000
6587     vec($_,17, 1) = 1   ==     131072 00000000000000000100000000000000
6588     vec($_,18, 1) = 1   ==     262144 00000000000000000010000000000000
6589     vec($_,19, 1) = 1   ==     524288 00000000000000000001000000000000
6590     vec($_,20, 1) = 1   ==    1048576 00000000000000000000100000000000
6591     vec($_,21, 1) = 1   ==    2097152 00000000000000000000010000000000
6592     vec($_,22, 1) = 1   ==    4194304 00000000000000000000001000000000
6593     vec($_,23, 1) = 1   ==    8388608 00000000000000000000000100000000
6594     vec($_,24, 1) = 1   ==   16777216 00000000000000000000000010000000
6595     vec($_,25, 1) = 1   ==   33554432 00000000000000000000000001000000
6596     vec($_,26, 1) = 1   ==   67108864 00000000000000000000000000100000
6597     vec($_,27, 1) = 1   ==  134217728 00000000000000000000000000010000
6598     vec($_,28, 1) = 1   ==  268435456 00000000000000000000000000001000
6599     vec($_,29, 1) = 1   ==  536870912 00000000000000000000000000000100
6600     vec($_,30, 1) = 1   == 1073741824 00000000000000000000000000000010
6601     vec($_,31, 1) = 1   == 2147483648 00000000000000000000000000000001
6602     vec($_, 0, 2) = 1   ==          1 10000000000000000000000000000000
6603     vec($_, 1, 2) = 1   ==          4 00100000000000000000000000000000
6604     vec($_, 2, 2) = 1   ==         16 00001000000000000000000000000000
6605     vec($_, 3, 2) = 1   ==         64 00000010000000000000000000000000
6606     vec($_, 4, 2) = 1   ==        256 00000000100000000000000000000000
6607     vec($_, 5, 2) = 1   ==       1024 00000000001000000000000000000000
6608     vec($_, 6, 2) = 1   ==       4096 00000000000010000000000000000000
6609     vec($_, 7, 2) = 1   ==      16384 00000000000000100000000000000000
6610     vec($_, 8, 2) = 1   ==      65536 00000000000000001000000000000000
6611     vec($_, 9, 2) = 1   ==     262144 00000000000000000010000000000000
6612     vec($_,10, 2) = 1   ==    1048576 00000000000000000000100000000000
6613     vec($_,11, 2) = 1   ==    4194304 00000000000000000000001000000000
6614     vec($_,12, 2) = 1   ==   16777216 00000000000000000000000010000000
6615     vec($_,13, 2) = 1   ==   67108864 00000000000000000000000000100000
6616     vec($_,14, 2) = 1   ==  268435456 00000000000000000000000000001000
6617     vec($_,15, 2) = 1   == 1073741824 00000000000000000000000000000010
6618     vec($_, 0, 2) = 2   ==          2 01000000000000000000000000000000
6619     vec($_, 1, 2) = 2   ==          8 00010000000000000000000000000000
6620     vec($_, 2, 2) = 2   ==         32 00000100000000000000000000000000
6621     vec($_, 3, 2) = 2   ==        128 00000001000000000000000000000000
6622     vec($_, 4, 2) = 2   ==        512 00000000010000000000000000000000
6623     vec($_, 5, 2) = 2   ==       2048 00000000000100000000000000000000
6624     vec($_, 6, 2) = 2   ==       8192 00000000000001000000000000000000
6625     vec($_, 7, 2) = 2   ==      32768 00000000000000010000000000000000
6626     vec($_, 8, 2) = 2   ==     131072 00000000000000000100000000000000
6627     vec($_, 9, 2) = 2   ==     524288 00000000000000000001000000000000
6628     vec($_,10, 2) = 2   ==    2097152 00000000000000000000010000000000
6629     vec($_,11, 2) = 2   ==    8388608 00000000000000000000000100000000
6630     vec($_,12, 2) = 2   ==   33554432 00000000000000000000000001000000
6631     vec($_,13, 2) = 2   ==  134217728 00000000000000000000000000010000
6632     vec($_,14, 2) = 2   ==  536870912 00000000000000000000000000000100
6633     vec($_,15, 2) = 2   == 2147483648 00000000000000000000000000000001
6634     vec($_, 0, 4) = 1   ==          1 10000000000000000000000000000000
6635     vec($_, 1, 4) = 1   ==         16 00001000000000000000000000000000
6636     vec($_, 2, 4) = 1   ==        256 00000000100000000000000000000000
6637     vec($_, 3, 4) = 1   ==       4096 00000000000010000000000000000000
6638     vec($_, 4, 4) = 1   ==      65536 00000000000000001000000000000000
6639     vec($_, 5, 4) = 1   ==    1048576 00000000000000000000100000000000
6640     vec($_, 6, 4) = 1   ==   16777216 00000000000000000000000010000000
6641     vec($_, 7, 4) = 1   ==  268435456 00000000000000000000000000001000
6642     vec($_, 0, 4) = 2   ==          2 01000000000000000000000000000000
6643     vec($_, 1, 4) = 2   ==         32 00000100000000000000000000000000
6644     vec($_, 2, 4) = 2   ==        512 00000000010000000000000000000000
6645     vec($_, 3, 4) = 2   ==       8192 00000000000001000000000000000000
6646     vec($_, 4, 4) = 2   ==     131072 00000000000000000100000000000000
6647     vec($_, 5, 4) = 2   ==    2097152 00000000000000000000010000000000
6648     vec($_, 6, 4) = 2   ==   33554432 00000000000000000000000001000000
6649     vec($_, 7, 4) = 2   ==  536870912 00000000000000000000000000000100
6650     vec($_, 0, 4) = 4   ==          4 00100000000000000000000000000000
6651     vec($_, 1, 4) = 4   ==         64 00000010000000000000000000000000
6652     vec($_, 2, 4) = 4   ==       1024 00000000001000000000000000000000
6653     vec($_, 3, 4) = 4   ==      16384 00000000000000100000000000000000
6654     vec($_, 4, 4) = 4   ==     262144 00000000000000000010000000000000
6655     vec($_, 5, 4) = 4   ==    4194304 00000000000000000000001000000000
6656     vec($_, 6, 4) = 4   ==   67108864 00000000000000000000000000100000
6657     vec($_, 7, 4) = 4   == 1073741824 00000000000000000000000000000010
6658     vec($_, 0, 4) = 8   ==          8 00010000000000000000000000000000
6659     vec($_, 1, 4) = 8   ==        128 00000001000000000000000000000000
6660     vec($_, 2, 4) = 8   ==       2048 00000000000100000000000000000000
6661     vec($_, 3, 4) = 8   ==      32768 00000000000000010000000000000000
6662     vec($_, 4, 4) = 8   ==     524288 00000000000000000001000000000000
6663     vec($_, 5, 4) = 8   ==    8388608 00000000000000000000000100000000
6664     vec($_, 6, 4) = 8   ==  134217728 00000000000000000000000000010000
6665     vec($_, 7, 4) = 8   == 2147483648 00000000000000000000000000000001
6666     vec($_, 0, 8) = 1   ==          1 10000000000000000000000000000000
6667     vec($_, 1, 8) = 1   ==        256 00000000100000000000000000000000
6668     vec($_, 2, 8) = 1   ==      65536 00000000000000001000000000000000
6669     vec($_, 3, 8) = 1   ==   16777216 00000000000000000000000010000000
6670     vec($_, 0, 8) = 2   ==          2 01000000000000000000000000000000
6671     vec($_, 1, 8) = 2   ==        512 00000000010000000000000000000000
6672     vec($_, 2, 8) = 2   ==     131072 00000000000000000100000000000000
6673     vec($_, 3, 8) = 2   ==   33554432 00000000000000000000000001000000
6674     vec($_, 0, 8) = 4   ==          4 00100000000000000000000000000000
6675     vec($_, 1, 8) = 4   ==       1024 00000000001000000000000000000000
6676     vec($_, 2, 8) = 4   ==     262144 00000000000000000010000000000000
6677     vec($_, 3, 8) = 4   ==   67108864 00000000000000000000000000100000
6678     vec($_, 0, 8) = 8   ==          8 00010000000000000000000000000000
6679     vec($_, 1, 8) = 8   ==       2048 00000000000100000000000000000000
6680     vec($_, 2, 8) = 8   ==     524288 00000000000000000001000000000000
6681     vec($_, 3, 8) = 8   ==  134217728 00000000000000000000000000010000
6682     vec($_, 0, 8) = 16  ==         16 00001000000000000000000000000000
6683     vec($_, 1, 8) = 16  ==       4096 00000000000010000000000000000000
6684     vec($_, 2, 8) = 16  ==    1048576 00000000000000000000100000000000
6685     vec($_, 3, 8) = 16  ==  268435456 00000000000000000000000000001000
6686     vec($_, 0, 8) = 32  ==         32 00000100000000000000000000000000
6687     vec($_, 1, 8) = 32  ==       8192 00000000000001000000000000000000
6688     vec($_, 2, 8) = 32  ==    2097152 00000000000000000000010000000000
6689     vec($_, 3, 8) = 32  ==  536870912 00000000000000000000000000000100
6690     vec($_, 0, 8) = 64  ==         64 00000010000000000000000000000000
6691     vec($_, 1, 8) = 64  ==      16384 00000000000000100000000000000000
6692     vec($_, 2, 8) = 64  ==    4194304 00000000000000000000001000000000
6693     vec($_, 3, 8) = 64  == 1073741824 00000000000000000000000000000010
6694     vec($_, 0, 8) = 128 ==        128 00000001000000000000000000000000
6695     vec($_, 1, 8) = 128 ==      32768 00000000000000010000000000000000
6696     vec($_, 2, 8) = 128 ==    8388608 00000000000000000000000100000000
6697     vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001
6698
6699 =item wait
6700
6701 Behaves like the wait(2) system call on your system: it waits for a child
6702 process to terminate and returns the pid of the deceased process, or
6703 C<-1> if there are no child processes.  The status is returned in C<$?>.
6704 Note that a return value of C<-1> could mean that child processes are
6705 being automatically reaped, as described in L<perlipc>.
6706
6707 =item waitpid PID,FLAGS
6708
6709 Waits for a particular child process to terminate and returns the pid of
6710 the deceased process, or C<-1> if there is no such child process.  On some
6711 systems, a value of 0 indicates that there are processes still running.
6712 The status is returned in C<$?>.  If you say
6713
6714     use POSIX ":sys_wait_h";
6715     #...
6716     do {
6717         $kid = waitpid(-1, WNOHANG);
6718     } until $kid > 0;
6719
6720 then you can do a non-blocking wait for all pending zombie processes.
6721 Non-blocking wait is available on machines supporting either the
6722 waitpid(2) or wait4(2) system calls.  However, waiting for a particular
6723 pid with FLAGS of C<0> is implemented everywhere.  (Perl emulates the
6724 system call by remembering the status values of processes that have
6725 exited but have not been harvested by the Perl script yet.)
6726
6727 Note that on some systems, a return value of C<-1> could mean that child
6728 processes are being automatically reaped.  See L<perlipc> for details,
6729 and for other examples.
6730
6731 =item wantarray
6732
6733 Returns true if the context of the currently executing subroutine or
6734 C<eval> is looking for a list value.  Returns false if the context is
6735 looking for a scalar.  Returns the undefined value if the context is
6736 looking for no value (void context).
6737
6738     return unless defined wantarray;    # don't bother doing more
6739     my @a = complex_calculation();
6740     return wantarray ? @a : "@a";
6741
6742 C<wantarray()>'s result is unspecified in the top level of a file,
6743 in a C<BEGIN>, C<CHECK>, C<INIT> or C<END> block, or in a C<DESTROY>
6744 method.
6745
6746 This function should have been named wantlist() instead.
6747
6748 =item warn LIST
6749
6750 Produces a message on STDERR just like C<die>, but doesn't exit or throw
6751 an exception.
6752
6753 If LIST is empty and C<$@> already contains a value (typically from a
6754 previous eval) that value is used after appending C<"\t...caught">
6755 to C<$@>.  This is useful for staying almost, but not entirely similar to
6756 C<die>.
6757
6758 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
6759
6760 No message is printed if there is a C<$SIG{__WARN__}> handler
6761 installed.  It is the handler's responsibility to deal with the message
6762 as it sees fit (like, for instance, converting it into a C<die>).  Most
6763 handlers must therefore make arrangements to actually display the
6764 warnings that they are not prepared to deal with, by calling C<warn>
6765 again in the handler.  Note that this is quite safe and will not
6766 produce an endless loop, since C<__WARN__> hooks are not called from
6767 inside one.
6768
6769 You will find this behavior is slightly different from that of
6770 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
6771 instead call C<die> again to change it).
6772
6773 Using a C<__WARN__> handler provides a powerful way to silence all
6774 warnings (even the so-called mandatory ones).  An example:
6775
6776     # wipe out *all* compile-time warnings
6777     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
6778     my $foo = 10;
6779     my $foo = 20;          # no warning about duplicate my $foo,
6780                            # but hey, you asked for it!
6781     # no compile-time or run-time warnings before here
6782     $DOWARN = 1;
6783
6784     # run-time warnings enabled after here
6785     warn "\$foo is alive and $foo!";     # does show up
6786
6787 See L<perlvar> for details on setting C<%SIG> entries, and for more
6788 examples.  See the Carp module for other kinds of warnings using its
6789 carp() and cluck() functions.
6790
6791 =item write FILEHANDLE
6792
6793 =item write EXPR
6794
6795 =item write
6796
6797 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
6798 using the format associated with that file.  By default the format for
6799 a file is the one having the same name as the filehandle, but the
6800 format for the current output channel (see the C<select> function) may be set
6801 explicitly by assigning the name of the format to the C<$~> variable.
6802
6803 Top of form processing is handled automatically:  if there is
6804 insufficient room on the current page for the formatted record, the
6805 page is advanced by writing a form feed, a special top-of-page format
6806 is used to format the new page header, and then the record is written.
6807 By default the top-of-page format is the name of the filehandle with
6808 "_TOP" appended, but it may be dynamically set to the format of your
6809 choice by assigning the name to the C<$^> variable while the filehandle is
6810 selected.  The number of lines remaining on the current page is in
6811 variable C<$->, which can be set to C<0> to force a new page.
6812
6813 If FILEHANDLE is unspecified, output goes to the current default output
6814 channel, which starts out as STDOUT but may be changed by the
6815 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
6816 is evaluated and the resulting string is used to look up the name of
6817 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
6818
6819 Note that write is I<not> the opposite of C<read>.  Unfortunately.
6820
6821 =item y///
6822
6823 The transliteration operator.  Same as C<tr///>.  See L<perlop>.
6824
6825 =back