3 perlfaq7 - General Perl Language Issues ($Revision: 1.18 $, $Date: 2004/11/03 22:54:08 $)
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave. The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
23 They are type specifiers, as detailed in L<perldata>:
25 $ for scalar values (number, string or reference)
27 % for hashes (associative arrays)
28 & for subroutines (aka functions, procedures, methods)
29 * for all types of that symbol name. In version 4 you used them like
30 pointers, but in modern perls you can just use references.
32 There are couple of other symbols that you're likely to encounter that aren't
33 really type specifiers:
35 <> are used for inputting a record from a filehandle.
36 \ takes a reference to something.
38 Note that <FILE> is I<neither> the type specifier for files
39 nor the name of the handle. It is the C<< <> >> operator applied
40 to the handle FILE. It reads one line (well, record--see
41 L<perlvar/$E<sol>>) from the handle FILE in scalar context, or I<all> lines
42 in list context. When performing open, close, or any other operation
43 besides C<< <> >> on files, or even when talking about the handle, do
44 I<not> use the brackets. These are correct: C<eof(FH)>, C<seek(FH, 0,
45 2)> and "copying from STDIN to FILE".
47 =head2 Do I always/never have to quote my strings or use semicolons and commas?
49 Normally, a bareword doesn't need to be quoted, but in most cases
50 probably should be (and must be under C<use strict>). But a hash key
51 consisting of a simple word (that isn't the name of a defined
52 subroutine) and the left-hand operand to the C<< => >> operator both
53 count as though they were quoted:
56 ------------ ---------------
57 $foo{line} $foo{"line"}
58 bar => stuff "bar" => stuff
60 The final semicolon in a block is optional, as is the final comma in a
61 list. Good style (see L<perlstyle>) says to put them in except for
64 if ($whoops) { exit 1 }
71 "There Beren came from mountains cold",
72 "And lost he wandered under leaves",
75 =head2 How do I skip some return values?
77 One way is to treat the return values as a list and index into it:
79 $dir = (getpwnam($user))[7];
81 Another way is to use undef as an element on the left-hand-side:
83 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
85 You can also use a list slice to select only the elements that
88 ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];
90 =head2 How do I temporarily block warnings?
92 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
93 allows fine control of what warning are produced.
94 See L<perllexwarn> for more details.
97 no warnings; # temporarily turn off warnings
98 $a = $b + $c; # I know these might be undef
101 Additionally, you can enable and disable categories of warnings.
102 You turn off the categories you want to ignore and you can still
103 get other categories of warnings. See L<perllexwarn> for the
104 complete details, including the category names and hierarchy.
107 no warnings 'uninitialized';
111 If you have an older version of Perl, the C<$^W> variable (documented
112 in L<perlvar>) controls runtime warnings for a block:
115 local $^W = 0; # temporarily turn off warnings
116 $a = $b + $c; # I know these might be undef
119 Note that like all the punctuation variables, you cannot currently
120 use my() on C<$^W>, only local().
122 =head2 What's an extension?
124 An extension is a way of calling compiled C code from Perl. Reading
125 L<perlxstut> is a good place to learn more about extensions.
127 =head2 Why do Perl operators have different precedence than C operators?
129 Actually, they don't. All C operators that Perl copies have the same
130 precedence in Perl as they do in C. The problem is with operators that C
131 doesn't have, especially functions that give a list context to everything
132 on their right, eg. print, chmod, exec, and so on. Such functions are
133 called "list operators" and appear as such in the precedence table in
136 A common mistake is to write:
138 unlink $file || die "snafu";
140 This gets interpreted as:
142 unlink ($file || die "snafu");
144 To avoid this problem, either put in extra parentheses or use the
145 super low precedence C<or> operator:
147 (unlink $file) || die "snafu";
148 unlink $file or die "snafu";
150 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
151 deliberately have precedence lower than that of list operators for
152 just such situations as the one above.
154 Another operator with surprising precedence is exponentiation. It
155 binds more tightly even than unary minus, making C<-2**2> product a
156 negative not a positive four. It is also right-associating, meaning
157 that C<2**3**2> is two raised to the ninth power, not eight squared.
159 Although it has the same precedence as in C, Perl's C<?:> operator
160 produces an lvalue. This assigns $x to either $a or $b, depending
161 on the trueness of $maybe:
163 ($maybe ? $a : $b) = $x;
165 =head2 How do I declare/create a structure?
167 In general, you don't "declare" a structure. Just use a (probably
168 anonymous) hash reference. See L<perlref> and L<perldsc> for details.
171 $person = {}; # new anonymous hash
172 $person->{AGE} = 24; # set field AGE to 24
173 $person->{NAME} = "Nat"; # set field NAME to "Nat"
175 If you're looking for something a bit more rigorous, try L<perltoot>.
177 =head2 How do I create a module?
179 A module is a package that lives in a file of the same name. For
180 example, the Hello::There module would live in Hello/There.pm. For
181 details, read L<perlmod>. You'll also find L<Exporter> helpful. If
182 you're writing a C or mixed-language module with both C and Perl, then
183 you should study L<perlxstut>.
185 The C<h2xs> program will create stubs for all the important stuff for you:
187 % h2xs -XA -n My::Module
189 The C<-X> switch tells C<h2xs> that you are not using C<XS> extension
190 code. The C<-A> switch tells C<h2xs> that you are not using the
191 AutoLoader, and the C<-n> switch specifies the name of the module.
192 See L<h2xs> for more details.
194 =head2 How do I create a class?
196 See L<perltoot> for an introduction to classes and objects, as well as
197 L<perlobj> and L<perlbot>.
199 =head2 How can I tell if a variable is tainted?
201 You can use the tainted() function of the Scalar::Util module, available
202 from CPAN (or included with Perl since release 5.8.0).
203 See also L<perlsec/"Laundering and Detecting Tainted Data">.
205 =head2 What's a closure?
207 Closures are documented in L<perlref>.
209 I<Closure> is a computer science term with a precise but
210 hard-to-explain meaning. Closures are implemented in Perl as anonymous
211 subroutines with lasting references to lexical variables outside their
212 own scopes. These lexicals magically refer to the variables that were
213 around when the subroutine was defined (deep binding).
215 Closures make sense in any programming language where you can have the
216 return value of a function be itself a function, as you can in Perl.
217 Note that some languages provide anonymous functions but are not
218 capable of providing proper closures: the Python language, for
219 example. For more information on closures, check out any textbook on
220 functional programming. Scheme is a language that not only supports
221 but encourages closures.
223 Here's a classic function-generating function:
225 sub add_function_generator {
226 return sub { shift() + shift() };
229 $add_sub = add_function_generator();
230 $sum = $add_sub->(4,5); # $sum is 9 now.
232 The closure works as a I<function template> with some customization
233 slots left out to be filled later. The anonymous subroutine returned
234 by add_function_generator() isn't technically a closure because it
235 refers to no lexicals outside its own scope.
237 Contrast this with the following make_adder() function, in which the
238 returned anonymous function contains a reference to a lexical variable
239 outside the scope of that function itself. Such a reference requires
240 that Perl return a proper closure, thus locking in for all time the
241 value that the lexical had when the function was created.
244 my $addpiece = shift;
245 return sub { shift() + $addpiece };
248 $f1 = make_adder(20);
249 $f2 = make_adder(555);
251 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
252 C<&$f2($n)> is always 555 plus whatever $n you pass in. The $addpiece
253 in the closure sticks around.
255 Closures are often used for less esoteric purposes. For example, when
256 you want to pass in a bit of code into a function:
259 timeout( 30, sub { $line = <STDIN> } );
261 If the code to execute had been passed in as a string,
262 C<< '$line = <STDIN>' >>, there would have been no way for the
263 hypothetical timeout() function to access the lexical variable
264 $line back in its caller's scope.
266 =head2 What is variable suicide and how can I prevent it?
268 Variable suicide is when you (temporarily or permanently) lose the
269 value of a variable. It is caused by scoping through my() and local()
270 interacting with either closures or aliased foreach() iterator
271 variables and subroutine arguments. It used to be easy to
272 inadvertently lose a variable's value this way, but now it's much
273 harder. Take this code:
277 while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
280 print "Finally $f\n";
282 The $f that has "bar" added to it three times should be a new C<$f>
283 (C<my $f> should create a new local variable each time through the loop).
284 It isn't, however. This was a bug, now fixed in the latest releases
285 (tested against 5.004_05, 5.005_03, and 5.005_56).
287 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
289 With the exception of regexes, you need to pass references to these
290 objects. See L<perlsub/"Pass by Reference"> for this particular
291 question, and L<perlref> for information on references.
293 See ``Passing Regexes'', below, for information on passing regular
298 =item Passing Variables and Functions
300 Regular variables and functions are quite easy to pass: just pass in a
301 reference to an existing or anonymous variable or function:
303 func( \$some_scalar );
305 func( \@some_array );
309 func( { this => 10, that => 20 } );
312 func( sub { $_[0] ** $_[1] } );
314 =item Passing Filehandles
316 As of Perl 5.6, you can represent filehandles with scalar variables
317 which you treat as any other scalar.
319 open my $fh, $filename or die "Cannot open $filename! $!";
323 my $passed_fh = shift;
328 Before Perl 5.6, you had to use the C<*FH> or C<\*FH> notations.
329 These are "typeglobs"--see L<perldata/"Typeglobs and Filehandles">
330 and especially L<perlsub/"Pass by Reference"> for more information.
332 =item Passing Regexes
334 To pass regexes around, you'll need to be using a release of Perl
335 sufficiently recent as to support the C<qr//> construct, pass around
336 strings and use an exception-trapping eval, or else be very, very clever.
338 Here's an example of how to pass in a string to be regex compared
342 my ($val1, $regex) = @_;
343 my $retval = $val1 =~ /$regex/;
346 $match = compare("old McDonald", qr/d.*D/i);
348 Notice how C<qr//> allows flags at the end. That pattern was compiled
349 at compile time, although it was executed later. The nifty C<qr//>
350 notation wasn't introduced until the 5.005 release. Before that, you
351 had to approach this problem much less intuitively. For example, here
352 it is again if you don't have C<qr//>:
355 my ($val1, $regex) = @_;
356 my $retval = eval { $val1 =~ /$regex/ };
361 $match = compare("old McDonald", q/($?i)d.*D/);
363 Make sure you never say something like this:
365 return eval "\$val =~ /$regex/"; # WRONG
367 or someone can sneak shell escapes into the regex due to the double
368 interpolation of the eval and the double-quoted string. For example:
370 $pattern_of_evil = 'danger ${ system("rm -rf * &") } danger';
372 eval "\$string =~ /$pattern_of_evil/";
374 Those preferring to be very, very clever might see the O'Reilly book,
375 I<Mastering Regular Expressions>, by Jeffrey Friedl. Page 273's
376 Build_MatchMany_Function() is particularly interesting. A complete
377 citation of this book is given in L<perlfaq2>.
379 =item Passing Methods
381 To pass an object method into a subroutine, you can do this:
383 call_a_lot(10, $some_obj, "methname")
385 my ($count, $widget, $trick) = @_;
386 for (my $i = 0; $i < $count; $i++) {
391 Or, you can use a closure to bundle up the object, its
392 method call, and arguments:
394 my $whatnot = sub { $some_obj->obfuscate(@args) };
401 You could also investigate the can() method in the UNIVERSAL class
402 (part of the standard perl distribution).
406 =head2 How do I create a static variable?
408 As with most things in Perl, TMTOWTDI. What is a "static variable" in
409 other languages could be either a function-private variable (visible
410 only within a single function, retaining its value between calls to
411 that function), or a file-private variable (visible only to functions
412 within the file it was declared in) in Perl.
414 Here's code to implement a function-private variable:
418 sub prev_counter { return --$counter }
419 sub next_counter { return $counter++ }
422 Now prev_counter() and next_counter() share a private variable $counter
423 that was initialized at compile time.
425 To declare a file-private variable, you'll still use a my(), putting
426 the declaration at the outer scope level at the top of the file.
427 Assume this is in file Pax.pm:
430 my $started = scalar(localtime(time()));
432 sub begun { return $started }
434 When C<use Pax> or C<require Pax> loads this module, the variable will
435 be initialized. It won't get garbage-collected the way most variables
436 going out of scope do, because the begun() function cares about it,
437 but no one else can get it. It is not called $Pax::started because
438 its scope is unrelated to the package. It's scoped to the file. You
439 could conceivably have several packages in that same file all
440 accessing the same private variable, but another file with the same
441 package couldn't get to it.
443 See L<perlsub/"Persistent Private Variables"> for details.
445 =head2 What's the difference between dynamic and lexical (static) scoping? Between local() and my()?
447 C<local($x)> saves away the old value of the global variable C<$x>
448 and assigns a new value for the duration of the subroutine I<which is
449 visible in other functions called from that subroutine>. This is done
450 at run-time, so is called dynamic scoping. local() always affects global
451 variables, also called package variables or dynamic variables.
453 C<my($x)> creates a new variable that is only visible in the current
454 subroutine. This is done at compile-time, so it is called lexical or
455 static scoping. my() always affects private variables, also called
456 lexical variables or (improperly) static(ly scoped) variables.
461 print "var has value $var\n";
465 local $var = 'local'; # new temporary value for the still-global
466 visible(); # variable called $var
470 my $var = 'private'; # new private variable, $var
471 visible(); # (invisible outside of sub scope)
476 visible(); # prints global
477 dynamic(); # prints local
478 lexical(); # prints global
480 Notice how at no point does the value "private" get printed. That's
481 because $var only has that value within the block of the lexical()
482 function, and it is hidden from called subroutine.
484 In summary, local() doesn't make what you think of as private, local
485 variables. It gives a global variable a temporary value. my() is
486 what you're looking for if you want private variables.
488 See L<perlsub/"Private Variables via my()"> and
489 L<perlsub/"Temporary Values via local()"> for excruciating details.
491 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
493 If you know your package, you can just mention it explicitly, as in
494 $Some_Pack::var. Note that the notation $::var is B<not> the dynamic $var
495 in the current package, but rather the one in the "main" package, as
496 though you had written $main::var.
499 local $var = "global";
502 print "lexical is $var\n";
503 print "global is $main::var\n";
505 Alternatively you can use the compiler directive our() to bring a
506 dynamic variable into the current lexical scope.
508 require 5.006; # our() did not exist before 5.6
511 local $var = "global";
514 print "lexical is $var\n";
518 print "global is $var\n";
521 =head2 What's the difference between deep and shallow binding?
523 In deep binding, lexical variables mentioned in anonymous subroutines
524 are the same ones that were in scope when the subroutine was created.
525 In shallow binding, they are whichever variables with the same names
526 happen to be in scope when the subroutine is called. Perl always uses
527 deep binding of lexical variables (i.e., those created with my()).
528 However, dynamic variables (aka global, local, or package variables)
529 are effectively shallowly bound. Consider this just one more reason
530 not to use them. See the answer to L<"What's a closure?">.
532 =head2 Why doesn't "my($foo) = E<lt>FILEE<gt>;" work right?
534 C<my()> and C<local()> give list context to the right hand side
535 of C<=>. The <FH> read operation, like so many of Perl's
536 functions and operators, can tell which context it was called in and
537 behaves appropriately. In general, the scalar() function can help.
538 This function does nothing to the data itself (contrary to popular myth)
539 but rather tells its argument to behave in whatever its scalar fashion is.
540 If that function doesn't have a defined scalar behavior, this of course
541 doesn't help you (such as with sort()).
543 To enforce scalar context in this particular case, however, you need
544 merely omit the parentheses:
546 local($foo) = <FILE>; # WRONG
547 local($foo) = scalar(<FILE>); # ok
548 local $foo = <FILE>; # right
550 You should probably be using lexical variables anyway, although the
551 issue is the same here:
553 my($foo) = <FILE>; # WRONG
554 my $foo = <FILE>; # right
556 =head2 How do I redefine a builtin function, operator, or method?
558 Why do you want to do that? :-)
560 If you want to override a predefined function, such as open(),
561 then you'll have to import the new definition from a different
562 module. See L<perlsub/"Overriding Built-in Functions">. There's
563 also an example in L<perltoot/"Class::Template">.
565 If you want to overload a Perl operator, such as C<+> or C<**>,
566 then you'll want to use the C<use overload> pragma, documented
569 If you're talking about obscuring method calls in parent classes,
570 see L<perltoot/"Overridden Methods">.
572 =head2 What's the difference between calling a function as &foo and foo()?
574 When you call a function as C<&foo>, you allow that function access to
575 your current @_ values, and you bypass prototypes.
576 The function doesn't get an empty @_--it gets yours! While not
577 strictly speaking a bug (it's documented that way in L<perlsub>), it
578 would be hard to consider this a feature in most cases.
580 When you call your function as C<&foo()>, then you I<do> get a new @_,
581 but prototyping is still circumvented.
583 Normally, you want to call a function using C<foo()>. You may only
584 omit the parentheses if the function is already known to the compiler
585 because it already saw the definition (C<use> but not C<require>),
586 or via a forward reference or C<use subs> declaration. Even in this
587 case, you get a clean @_ without any of the old values leaking through
588 where they don't belong.
590 =head2 How do I create a switch or case statement?
592 This is explained in more depth in the L<perlsyn>. Briefly, there's
593 no official case statement, because of the variety of tests possible
594 in Perl (numeric comparison, string comparison, glob comparison,
595 regex matching, overloaded comparisons, ...).
596 Larry couldn't decide how best to do this, so he left it out, even
597 though it's been on the wish list since perl1.
599 Starting from Perl 5.8 to get switch and case one can use the
600 Switch extension and say:
604 after which one has switch and case. It is not as fast as it could be
605 because it's not really part of the language (it's done using source
606 filters) but it is available, and it's very flexible.
608 But if one wants to use pure Perl, the general answer is to write a
611 for ($variable_to_test) {
612 if (/pat1/) { } # do something
613 elsif (/pat2/) { } # do something else
614 elsif (/pat3/) { } # do something else
618 Here's a simple example of a switch based on pattern matching, this
619 time lined up in a way to make it look more like a switch statement.
620 We'll do a multiway conditional based on the type of reference stored
623 SWITCH: for (ref $whatchamacallit) {
625 /^$/ && die "not a reference";
643 warn "can't print function ref";
649 warn "User defined type skipped";
653 See C<perlsyn/"Basic BLOCKs and Switch Statements"> for many other
654 examples in this style.
656 Sometimes you should change the positions of the constant and the variable.
657 For example, let's say you wanted to test which of many answers you were
658 given, but in a case-insensitive way that also allows abbreviations.
659 You can use the following technique if the strings all start with
660 different characters or if you want to arrange the matches so that
661 one takes precedence over another, as C<"SEND"> has precedence over
665 if ("SEND" =~ /^\Q$answer/i) { print "Action is send\n" }
666 elsif ("STOP" =~ /^\Q$answer/i) { print "Action is stop\n" }
667 elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
668 elsif ("LIST" =~ /^\Q$answer/i) { print "Action is list\n" }
669 elsif ("EDIT" =~ /^\Q$answer/i) { print "Action is edit\n" }
671 A totally different approach is to create a hash of function references.
676 "done" => sub { die "See ya!" },
680 print "How are you? ";
681 chomp($string = <STDIN>);
682 if ($commands{$string}) {
683 $commands{$string}->();
685 print "No such command: $string\n";
688 =head2 How can I catch accesses to undefined variables, functions, or methods?
690 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
691 L<perltoot/"AUTOLOAD: Proxy Methods">, lets you capture calls to
692 undefined functions and methods.
694 When it comes to undefined variables that would trigger a warning
695 under C<use warnings>, you can promote the warning to an error.
697 use warnings FATAL => qw(uninitialized);
699 =head2 Why can't a method included in this same file be found?
701 Some possible reasons: your inheritance is getting confused, you've
702 misspelled the method name, or the object is of the wrong type. Check
703 out L<perltoot> for details about any of the above cases. You may
704 also use C<print ref($object)> to find out the class C<$object> was
707 Another possible reason for problems is because you've used the
708 indirect object syntax (eg, C<find Guru "Samy">) on a class name
709 before Perl has seen that such a package exists. It's wisest to make
710 sure your packages are all defined before you start using them, which
711 will be taken care of if you use the C<use> statement instead of
712 C<require>. If not, make sure to use arrow notation (eg.,
713 C<< Guru->find("Samy") >>) instead. Object notation is explained in
716 Make sure to read about creating modules in L<perlmod> and
717 the perils of indirect objects in L<perlobj/"Method Invocation">.
719 =head2 How can I find out my current package?
721 If you're just a random program, you can do this to find
722 out what the currently compiled package is:
724 my $packname = __PACKAGE__;
726 But, if you're a method and you want to print an error message
727 that includes the kind of object you were called on (which is
728 not necessarily the same as the one in which you were compiled):
732 my $class = ref($self) || $self;
733 warn "called me from a $class object";
736 =head2 How can I comment out a large block of perl code?
738 You can use embedded POD to discard it. Enclose the blocks you want
739 to comment out in POD markers, for example C<=for nobody> and C<=cut>
740 (which marks ends of POD blocks).
755 The pod directives cannot go just anywhere. You must put a
756 pod directive where the parser is expecting a new statement,
757 not just in the middle of an expression or some other
758 arbitrary grammar production.
760 See L<perlpod> for more details.
762 =head2 How do I clear a package?
764 Use this code, provided by Mark-Jason Dominus:
769 die "Shouldn't delete main package"
770 if $pack eq "" || $pack eq "main";
771 my $stash = *{$pack . '::'}{HASH};
773 foreach $name (keys %$stash) {
774 my $fullname = $pack . '::' . $name;
775 # Get rid of everything with that name.
784 Or, if you're using a recent release of Perl, you can
785 just use the Symbol::delete_package() function instead.
787 =head2 How can I use a variable as a variable name?
789 Beginners often think they want to have a variable contain the name
794 ++$$varname; # $fred now 24
796 This works I<sometimes>, but it is a very bad idea for two reasons.
798 The first reason is that this technique I<only works on global
799 variables>. That means that if $fred is a lexical variable created
800 with my() in the above example, the code wouldn't work at all: you'd
801 accidentally access the global and skip right over the private lexical
802 altogether. Global variables are bad because they can easily collide
803 accidentally and in general make for non-scalable and confusing code.
805 Symbolic references are forbidden under the C<use strict> pragma.
806 They are not true references and consequently are not reference counted
807 or garbage collected.
809 The other reason why using a variable to hold the name of another
810 variable is a bad idea is that the question often stems from a lack of
811 understanding of Perl data structures, particularly hashes. By using
812 symbolic references, you are just using the package's symbol-table hash
813 (like C<%main::>) instead of a user-defined hash. The solution is to
814 use your own hash or a real reference instead.
816 $USER_VARS{"fred"} = 23;
818 $USER_VARS{$varname}++; # not $$varname++
820 There we're using the %USER_VARS hash instead of symbolic references.
821 Sometimes this comes up in reading strings from the user with variable
822 references and wanting to expand them to the values of your perl
823 program's variables. This is also a bad idea because it conflates the
824 program-addressable namespace and the user-addressable one. Instead of
825 reading a string and expanding it to the actual contents of your program's
828 $str = 'this has a $fred and $barney in it';
829 $str =~ s/(\$\w+)/$1/eeg; # need double eval
831 it would be better to keep a hash around like %USER_VARS and have
832 variable references actually refer to entries in that hash:
834 $str =~ s/\$(\w+)/$USER_VARS{$1}/g; # no /e here at all
836 That's faster, cleaner, and safer than the previous approach. Of course,
837 you don't need to use a dollar sign. You could use your own scheme to
838 make it less confusing, like bracketed percent symbols, etc.
840 $str = 'this has a %fred% and %barney% in it';
841 $str =~ s/%(\w+)%/$USER_VARS{$1}/g; # no /e here at all
843 Another reason that folks sometimes think they want a variable to
844 contain the name of a variable is because they don't know how to build
845 proper data structures using hashes. For example, let's say they
846 wanted two hashes in their program: %fred and %barney, and that they
847 wanted to use another scalar variable to refer to those by name.
850 $$name{WIFE} = "wilma"; # set %fred
853 $$name{WIFE} = "betty"; # set %barney
855 This is still a symbolic reference, and is still saddled with the
856 problems enumerated above. It would be far better to write:
858 $folks{"fred"}{WIFE} = "wilma";
859 $folks{"barney"}{WIFE} = "betty";
861 And just use a multilevel hash to start with.
863 The only times that you absolutely I<must> use symbolic references are
864 when you really must refer to the symbol table. This may be because it's
865 something that can't take a real reference to, such as a format name.
866 Doing so may also be important for method calls, since these always go
867 through the symbol table for resolution.
869 In those cases, you would turn off C<strict 'refs'> temporarily so you
870 can play around with the symbol table. For example:
872 @colors = qw(red blue green yellow orange purple violet);
873 for my $name (@colors) {
874 no strict 'refs'; # renege for the block
875 *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
878 All those functions (red(), blue(), green(), etc.) appear to be separate,
879 but the real code in the closure actually was compiled only once.
881 So, sometimes you might want to use symbolic references to directly
882 manipulate the symbol table. This doesn't matter for formats, handles, and
883 subroutines, because they are always global--you can't use my() on them.
884 For scalars, arrays, and hashes, though--and usually for subroutines--
885 you probably only want to use hard references.
887 =head2 What does "bad interpreter" mean?
889 The "bad interpreter" message comes from the shell, not perl. The
890 actual message may vary depending on your platform, shell, and locale
893 If you see "bad interpreter - no such file or directory", the first
894 line in your perl script (the "shebang" line) does not contain the
895 right path to perl (or any other program capable of running scripts).
896 Sometimes this happens when you move the script from one machine to
897 another and each machine has a different path to perl---/usr/bin/perl
898 versus /usr/local/bin/perl for instance.
900 If you see "bad interpreter: Permission denied", you need to make your
903 In either case, you should still be able to run the scripts with perl
908 If you get a message like "perl: command not found", perl is not in
909 your PATH, which might also mean that the location of perl is not
910 where you expect it so you need to adjust your shebang line.
912 =head1 AUTHOR AND COPYRIGHT
914 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
917 This documentation is free; you can redistribute it and/or modify it
918 under the same terms as Perl itself.
920 Irrespective of its distribution, all code examples in this file
921 are hereby placed into the public domain. You are permitted and
922 encouraged to use this code in your own programs for fun
923 or for profit as you see fit. A simple comment in the code giving
924 credit would be courteous but is not required.