3 perlfaq7 - Perl Language Issues ($Revision: 1.28 $, $Date: 1999/05/23 20:36:18 $)
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave. The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
23 They are type specifiers, as detailed in L<perldata>:
25 $ for scalar values (number, string or reference)
27 % for hashes (associative arrays)
28 & for subroutines (aka functions, procedures, methods)
29 * for all types of that symbol name. In version 4 you used them like
30 pointers, but in modern perls you can just use references.
32 A couple of others that you're likely to encounter that aren't
33 really type specifiers are:
35 <> are used for inputting a record from a filehandle.
36 \ takes a reference to something.
38 Note that <FILE> is I<neither> the type specifier for files
39 nor the name of the handle. It is the C<< <> >> operator applied
40 to the handle FILE. It reads one line (well, record - see
41 L<perlvar/$/>) from the handle FILE in scalar context, or I<all> lines
42 in list context. When performing open, close, or any other operation
43 besides C<< <> >> on files, or even talking about the handle, do
44 I<not> use the brackets. These are correct: C<eof(FH)>, C<seek(FH, 0,
45 2)> and "copying from STDIN to FILE".
47 =head2 Do I always/never have to quote my strings or use semicolons and commas?
49 Normally, a bareword doesn't need to be quoted, but in most cases
50 probably should be (and must be under C<use strict>). But a hash key
51 consisting of a simple word (that isn't the name of a defined
52 subroutine) and the left-hand operand to the C<< => >> operator both
53 count as though they were quoted:
56 ------------ ---------------
57 $foo{line} $foo{"line"}
58 bar => stuff "bar" => stuff
60 The final semicolon in a block is optional, as is the final comma in a
61 list. Good style (see L<perlstyle>) says to put them in except for
64 if ($whoops) { exit 1 }
71 "There Beren came from mountains cold",
72 "And lost he wandered under leaves",
75 =head2 How do I skip some return values?
77 One way is to treat the return values as a list and index into it:
79 $dir = (getpwnam($user))[7];
81 Another way is to use undef as an element on the left-hand-side:
83 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
85 =head2 How do I temporarily block warnings?
87 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
88 allows fine control of what warning are produced.
89 See L<perllexwarn> for more details.
92 no warnings; # temporarily turn off warnings
93 $a = $b + $c; # I know these might be undef
96 If you have an older version of Perl, the C<$^W> variable (documented
97 in L<perlvar>) controls runtime warnings for a block:
100 local $^W = 0; # temporarily turn off warnings
101 $a = $b + $c; # I know these might be undef
104 Note that like all the punctuation variables, you cannot currently
105 use my() on C<$^W>, only local().
107 =head2 What's an extension?
109 A way of calling compiled C code from Perl. Reading L<perlxstut>
110 is a good place to learn more about extensions.
112 =head2 Why do Perl operators have different precedence than C operators?
114 Actually, they don't. All C operators that Perl copies have the same
115 precedence in Perl as they do in C. The problem is with operators that C
116 doesn't have, especially functions that give a list context to everything
117 on their right, eg print, chmod, exec, and so on. Such functions are
118 called "list operators" and appear as such in the precedence table in
121 A common mistake is to write:
123 unlink $file || die "snafu";
125 This gets interpreted as:
127 unlink ($file || die "snafu");
129 To avoid this problem, either put in extra parentheses or use the
130 super low precedence C<or> operator:
132 (unlink $file) || die "snafu";
133 unlink $file or die "snafu";
135 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
136 deliberately have precedence lower than that of list operators for
137 just such situations as the one above.
139 Another operator with surprising precedence is exponentiation. It
140 binds more tightly even than unary minus, making C<-2**2> product a
141 negative not a positive four. It is also right-associating, meaning
142 that C<2**3**2> is two raised to the ninth power, not eight squared.
144 Although it has the same precedence as in C, Perl's C<?:> operator
145 produces an lvalue. This assigns $x to either $a or $b, depending
146 on the trueness of $maybe:
148 ($maybe ? $a : $b) = $x;
150 =head2 How do I declare/create a structure?
152 In general, you don't "declare" a structure. Just use a (probably
153 anonymous) hash reference. See L<perlref> and L<perldsc> for details.
156 $person = {}; # new anonymous hash
157 $person->{AGE} = 24; # set field AGE to 24
158 $person->{NAME} = "Nat"; # set field NAME to "Nat"
160 If you're looking for something a bit more rigorous, try L<perltoot>.
162 =head2 How do I create a module?
164 A module is a package that lives in a file of the same name. For
165 example, the Hello::There module would live in Hello/There.pm. For
166 details, read L<perlmod>. You'll also find L<Exporter> helpful. If
167 you're writing a C or mixed-language module with both C and Perl, then
168 you should study L<perlxstut>.
170 Here's a convenient template you might wish you use when starting your
171 own module. Make sure to change the names appropriately.
173 package Some::Module; # assumes Some/Module.pm
180 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
182 ## set the version for version checking; uncomment to use
185 # if using RCS/CVS, this next line may be preferred,
186 # but beware two-digit versions.
187 $VERSION = do{my@r=q$Revision: 1.28 $=~/\d+/g;sprintf '%d.'.'%02d'x$#r,@r};
190 @EXPORT = qw(&func1 &func2 &func3);
191 %EXPORT_TAGS = ( ); # eg: TAG => [ qw!name1 name2! ],
193 # your exported package globals go here,
194 # as well as any optionally exported functions
195 @EXPORT_OK = qw($Var1 %Hashit);
199 # non-exported package globals go here
203 # initialize package globals, first exported ones
207 # then the others (which are still accessible as $Some::Module::stuff)
211 # all file-scoped lexicals must be created before
212 # the functions below that use them.
214 # file-private lexicals go here
216 my %secret_hash = ();
218 # here's a file-private function as a closure,
219 # callable as &$priv_func; it cannot be prototyped.
220 my $priv_func = sub {
224 # make all your functions, whether exported or not;
225 # remember to put something interesting in the {} stubs
226 sub func1 {} # no prototype
227 sub func2() {} # proto'd void
228 sub func3($$) {} # proto'd to 2 scalars
230 # this one isn't exported, but could be called!
231 sub func4(\%) {} # proto'd to 1 hash ref
233 END { } # module clean-up code here (global destructor)
235 1; # modules must return true
237 The h2xs program will create stubs for all the important stuff for you:
239 % h2xs -XA -n My::Module
241 =head2 How do I create a class?
243 See L<perltoot> for an introduction to classes and objects, as well as
244 L<perlobj> and L<perlbot>.
246 =head2 How can I tell if a variable is tainted?
248 See L<perlsec/"Laundering and Detecting Tainted Data">. Here's an
249 example (which doesn't use any system calls, because the kill()
250 is given no processes to signal):
253 return ! eval { join('',@_), kill 0; 1; };
256 This is not C<-w> clean, however. There is no C<-w> clean way to
257 detect taintedness - take this as a hint that you should untaint
258 all possibly-tainted data.
260 =head2 What's a closure?
262 Closures are documented in L<perlref>.
264 I<Closure> is a computer science term with a precise but
265 hard-to-explain meaning. Closures are implemented in Perl as anonymous
266 subroutines with lasting references to lexical variables outside their
267 own scopes. These lexicals magically refer to the variables that were
268 around when the subroutine was defined (deep binding).
270 Closures make sense in any programming language where you can have the
271 return value of a function be itself a function, as you can in Perl.
272 Note that some languages provide anonymous functions but are not
273 capable of providing proper closures; the Python language, for
274 example. For more information on closures, check out any textbook on
275 functional programming. Scheme is a language that not only supports
276 but encourages closures.
278 Here's a classic function-generating function:
280 sub add_function_generator {
281 return sub { shift + shift };
284 $add_sub = add_function_generator();
285 $sum = $add_sub->(4,5); # $sum is 9 now.
287 The closure works as a I<function template> with some customization
288 slots left out to be filled later. The anonymous subroutine returned
289 by add_function_generator() isn't technically a closure because it
290 refers to no lexicals outside its own scope.
292 Contrast this with the following make_adder() function, in which the
293 returned anonymous function contains a reference to a lexical variable
294 outside the scope of that function itself. Such a reference requires
295 that Perl return a proper closure, thus locking in for all time the
296 value that the lexical had when the function was created.
299 my $addpiece = shift;
300 return sub { shift + $addpiece };
303 $f1 = make_adder(20);
304 $f2 = make_adder(555);
306 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
307 C<&$f2($n)> is always 555 plus whatever $n you pass in. The $addpiece
308 in the closure sticks around.
310 Closures are often used for less esoteric purposes. For example, when
311 you want to pass in a bit of code into a function:
314 timeout( 30, sub { $line = <STDIN> } );
316 If the code to execute had been passed in as a string,
317 C<< '$line = <STDIN>' >>, there would have been no way for the
318 hypothetical timeout() function to access the lexical variable
319 $line back in its caller's scope.
321 =head2 What is variable suicide and how can I prevent it?
323 Variable suicide is when you (temporarily or permanently) lose the
324 value of a variable. It is caused by scoping through my() and local()
325 interacting with either closures or aliased foreach() iterator
326 variables and subroutine arguments. It used to be easy to
327 inadvertently lose a variable's value this way, but now it's much
328 harder. Take this code:
332 while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
335 print "Finally $f\n";
337 The $f that has "bar" added to it three times should be a new C<$f>
338 (C<my $f> should create a new local variable each time through the loop).
339 It isn't, however. This was a bug, now fixed in the latest releases
340 (tested against 5.004_05, 5.005_03, and 5.005_56).
342 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
344 With the exception of regexes, you need to pass references to these
345 objects. See L<perlsub/"Pass by Reference"> for this particular
346 question, and L<perlref> for information on references.
350 =item Passing Variables and Functions
352 Regular variables and functions are quite easy: just pass in a
353 reference to an existing or anonymous variable or function:
355 func( \$some_scalar );
357 func( \@some_array );
361 func( { this => 10, that => 20 } );
364 func( sub { $_[0] ** $_[1] } );
366 =item Passing Filehandles
368 To pass filehandles to subroutines, use the C<*FH> or C<\*FH> notations.
369 These are "typeglobs" - see L<perldata/"Typeglobs and Filehandles">
370 and especially L<perlsub/"Pass by Reference"> for more information.
374 If you're passing around filehandles, you could usually just use the bare
375 typeglob, like *STDOUT, but typeglobs references would be better because
376 they'll still work properly under C<use strict 'refs'>. For example:
381 print $fh "her um well a hmmm\n";
384 $rec = get_rec(\*STDIN);
390 If you're planning on generating new filehandles, you could do this:
395 return open (FH, $path) ? *FH : undef;
397 $fh = openit('< /etc/motd');
400 =item Passing Regexes
402 To pass regexes around, you'll need to be using a release of Perl
403 sufficiently recent as to support the C<qr//> construct, pass around
404 strings and use an exception-trapping eval, or else be very, very clever.
406 Here's an example of how to pass in a string to be regex compared
410 my ($val1, $regex) = @_;
411 my $retval = $val1 =~ /$regex/;
414 $match = compare("old McDonald", qr/d.*D/i);
416 Notice how C<qr//> allows flags at the end. That pattern was compiled
417 at compile time, although it was executed later. The nifty C<qr//>
418 notation wasn't introduced until the 5.005 release. Before that, you
419 had to approach this problem much less intuitively. For example, here
420 it is again if you don't have C<qr//>:
423 my ($val1, $regex) = @_;
424 my $retval = eval { $val1 =~ /$regex/ };
429 $match = compare("old McDonald", q/($?i)d.*D/);
431 Make sure you never say something like this:
433 return eval "\$val =~ /$regex/"; # WRONG
435 or someone can sneak shell escapes into the regex due to the double
436 interpolation of the eval and the double-quoted string. For example:
438 $pattern_of_evil = 'danger ${ system("rm -rf * &") } danger';
440 eval "\$string =~ /$pattern_of_evil/";
442 Those preferring to be very, very clever might see the O'Reilly book,
443 I<Mastering Regular Expressions>, by Jeffrey Friedl. Page 273's
444 Build_MatchMany_Function() is particularly interesting. A complete
445 citation of this book is given in L<perlfaq2>.
447 =item Passing Methods
449 To pass an object method into a subroutine, you can do this:
451 call_a_lot(10, $some_obj, "methname")
453 my ($count, $widget, $trick) = @_;
454 for (my $i = 0; $i < $count; $i++) {
459 Or you can use a closure to bundle up the object and its method call
462 my $whatnot = sub { $some_obj->obfuscate(@args) };
469 You could also investigate the can() method in the UNIVERSAL class
470 (part of the standard perl distribution).
474 =head2 How do I create a static variable?
476 As with most things in Perl, TMTOWTDI. What is a "static variable" in
477 other languages could be either a function-private variable (visible
478 only within a single function, retaining its value between calls to
479 that function), or a file-private variable (visible only to functions
480 within the file it was declared in) in Perl.
482 Here's code to implement a function-private variable:
486 sub prev_counter { return --$counter }
487 sub next_counter { return $counter++ }
490 Now prev_counter() and next_counter() share a private variable $counter
491 that was initialized at compile time.
493 To declare a file-private variable, you'll still use a my(), putting
494 it at the outer scope level at the top of the file. Assume this is in
498 my $started = scalar(localtime(time()));
500 sub begun { return $started }
502 When C<use Pax> or C<require Pax> loads this module, the variable will
503 be initialized. It won't get garbage-collected the way most variables
504 going out of scope do, because the begun() function cares about it,
505 but no one else can get it. It is not called $Pax::started because
506 its scope is unrelated to the package. It's scoped to the file. You
507 could conceivably have several packages in that same file all
508 accessing the same private variable, but another file with the same
509 package couldn't get to it.
511 See L<perlsub/"Persistent Private Variables"> for details.
513 =head2 What's the difference between dynamic and lexical (static) scoping? Between local() and my()?
515 C<local($x)> saves away the old value of the global variable C<$x>,
516 and assigns a new value for the duration of the subroutine, I<which is
517 visible in other functions called from that subroutine>. This is done
518 at run-time, so is called dynamic scoping. local() always affects global
519 variables, also called package variables or dynamic variables.
521 C<my($x)> creates a new variable that is only visible in the current
522 subroutine. This is done at compile-time, so is called lexical or
523 static scoping. my() always affects private variables, also called
524 lexical variables or (improperly) static(ly scoped) variables.
529 print "var has value $var\n";
533 local $var = 'local'; # new temporary value for the still-global
534 visible(); # variable called $var
538 my $var = 'private'; # new private variable, $var
539 visible(); # (invisible outside of sub scope)
544 visible(); # prints global
545 dynamic(); # prints local
546 lexical(); # prints global
548 Notice how at no point does the value "private" get printed. That's
549 because $var only has that value within the block of the lexical()
550 function, and it is hidden from called subroutine.
552 In summary, local() doesn't make what you think of as private, local
553 variables. It gives a global variable a temporary value. my() is
554 what you're looking for if you want private variables.
556 See L<perlsub/"Private Variables via my()"> and L<perlsub/"Temporary
557 Values via local()"> for excruciating details.
559 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
561 You can do this via symbolic references, provided you haven't set
562 C<use strict "refs">. So instead of $var, use C<${'var'}>.
564 local $var = "global";
567 print "lexical is $var\n";
570 print "global is ${'var'}\n";
572 If you know your package, you can just mention it explicitly, as in
573 $Some_Pack::var. Note that the notation $::var is I<not> the dynamic
574 $var in the current package, but rather the one in the C<main>
575 package, as though you had written $main::var. Specifying the package
576 directly makes you hard-code its name, but it executes faster and
577 avoids running afoul of C<use strict "refs">.
579 =head2 What's the difference between deep and shallow binding?
581 In deep binding, lexical variables mentioned in anonymous subroutines
582 are the same ones that were in scope when the subroutine was created.
583 In shallow binding, they are whichever variables with the same names
584 happen to be in scope when the subroutine is called. Perl always uses
585 deep binding of lexical variables (i.e., those created with my()).
586 However, dynamic variables (aka global, local, or package variables)
587 are effectively shallowly bound. Consider this just one more reason
588 not to use them. See the answer to L<"What's a closure?">.
590 =head2 Why doesn't "my($foo) = <FILE>;" work right?
592 C<my()> and C<local()> give list context to the right hand side
593 of C<=>. The <FH> read operation, like so many of Perl's
594 functions and operators, can tell which context it was called in and
595 behaves appropriately. In general, the scalar() function can help.
596 This function does nothing to the data itself (contrary to popular myth)
597 but rather tells its argument to behave in whatever its scalar fashion is.
598 If that function doesn't have a defined scalar behavior, this of course
599 doesn't help you (such as with sort()).
601 To enforce scalar context in this particular case, however, you need
602 merely omit the parentheses:
604 local($foo) = <FILE>; # WRONG
605 local($foo) = scalar(<FILE>); # ok
606 local $foo = <FILE>; # right
608 You should probably be using lexical variables anyway, although the
609 issue is the same here:
611 my($foo) = <FILE>; # WRONG
612 my $foo = <FILE>; # right
614 =head2 How do I redefine a builtin function, operator, or method?
616 Why do you want to do that? :-)
618 If you want to override a predefined function, such as open(),
619 then you'll have to import the new definition from a different
620 module. See L<perlsub/"Overriding Built-in Functions">. There's
621 also an example in L<perltoot/"Class::Template">.
623 If you want to overload a Perl operator, such as C<+> or C<**>,
624 then you'll want to use the C<use overload> pragma, documented
627 If you're talking about obscuring method calls in parent classes,
628 see L<perltoot/"Overridden Methods">.
630 =head2 What's the difference between calling a function as &foo and foo()?
632 When you call a function as C<&foo>, you allow that function access to
633 your current @_ values, and you by-pass prototypes. That means that
634 the function doesn't get an empty @_, it gets yours! While not
635 strictly speaking a bug (it's documented that way in L<perlsub>), it
636 would be hard to consider this a feature in most cases.
638 When you call your function as C<&foo()>, then you I<do> get a new @_,
639 but prototyping is still circumvented.
641 Normally, you want to call a function using C<foo()>. You may only
642 omit the parentheses if the function is already known to the compiler
643 because it already saw the definition (C<use> but not C<require>),
644 or via a forward reference or C<use subs> declaration. Even in this
645 case, you get a clean @_ without any of the old values leaking through
646 where they don't belong.
648 =head2 How do I create a switch or case statement?
650 This is explained in more depth in the L<perlsyn>. Briefly, there's
651 no official case statement, because of the variety of tests possible
652 in Perl (numeric comparison, string comparison, glob comparison,
653 regex matching, overloaded comparisons, ...). Larry couldn't decide
654 how best to do this, so he left it out, even though it's been on the
655 wish list since perl1.
657 The general answer is to write a construct like this:
659 for ($variable_to_test) {
660 if (/pat1/) { } # do something
661 elsif (/pat2/) { } # do something else
662 elsif (/pat3/) { } # do something else
666 Here's a simple example of a switch based on pattern matching, this
667 time lined up in a way to make it look more like a switch statement.
668 We'll do a multi-way conditional based on the type of reference stored
671 SWITCH: for (ref $whatchamacallit) {
673 /^$/ && die "not a reference";
691 warn "can't print function ref";
697 warn "User defined type skipped";
701 See C<perlsyn/"Basic BLOCKs and Switch Statements"> for many other
702 examples in this style.
704 Sometimes you should change the positions of the constant and the variable.
705 For example, let's say you wanted to test which of many answers you were
706 given, but in a case-insensitive way that also allows abbreviations.
707 You can use the following technique if the strings all start with
708 different characters, or if you want to arrange the matches so that
709 one takes precedence over another, as C<"SEND"> has precedence over
713 if ("SEND" =~ /^\Q$answer/i) { print "Action is send\n" }
714 elsif ("STOP" =~ /^\Q$answer/i) { print "Action is stop\n" }
715 elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
716 elsif ("LIST" =~ /^\Q$answer/i) { print "Action is list\n" }
717 elsif ("EDIT" =~ /^\Q$answer/i) { print "Action is edit\n" }
719 A totally different approach is to create a hash of function references.
724 "done" => sub { die "See ya!" },
728 print "How are you? ";
729 chomp($string = <STDIN>);
730 if ($commands{$string}) {
731 $commands{$string}->();
733 print "No such command: $string\n";
736 =head2 How can I catch accesses to undefined variables/functions/methods?
738 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
739 L<perltoot/"AUTOLOAD: Proxy Methods">, lets you capture calls to
740 undefined functions and methods.
742 When it comes to undefined variables that would trigger a warning
743 under C<-w>, you can use a handler to trap the pseudo-signal
744 C<__WARN__> like this:
746 $SIG{__WARN__} = sub {
748 for ( $_[0] ) { # voici un switch statement
750 /Use of uninitialized value/ && do {
751 # promote warning to a fatal
755 # other warning cases to catch could go here;
762 =head2 Why can't a method included in this same file be found?
764 Some possible reasons: your inheritance is getting confused, you've
765 misspelled the method name, or the object is of the wrong type. Check
766 out L<perltoot> for details on these. You may also use C<print
767 ref($object)> to find out the class C<$object> was blessed into.
769 Another possible reason for problems is because you've used the
770 indirect object syntax (eg, C<find Guru "Samy">) on a class name
771 before Perl has seen that such a package exists. It's wisest to make
772 sure your packages are all defined before you start using them, which
773 will be taken care of if you use the C<use> statement instead of
774 C<require>. If not, make sure to use arrow notation (eg,
775 C<< Guru->find("Samy") >>) instead. Object notation is explained in
778 Make sure to read about creating modules in L<perlmod> and
779 the perils of indirect objects in L<perlobj/"WARNING">.
781 =head2 How can I find out my current package?
783 If you're just a random program, you can do this to find
784 out what the currently compiled package is:
786 my $packname = __PACKAGE__;
788 But if you're a method and you want to print an error message
789 that includes the kind of object you were called on (which is
790 not necessarily the same as the one in which you were compiled):
794 my $class = ref($self) || $self;
795 warn "called me from a $class object";
798 =head2 How can I comment out a large block of perl code?
800 Use embedded POD to discard it:
805 This paragraph is commented out
820 This can't go just anywhere. You have to put a pod directive where
821 the parser is expecting a new statement, not just in the middle
822 of an expression or some other arbitrary yacc grammar production.
824 =head2 How do I clear a package?
826 Use this code, provided by Mark-Jason Dominus:
831 die "Shouldn't delete main package"
832 if $pack eq "" || $pack eq "main";
833 my $stash = *{$pack . '::'}{HASH};
835 foreach $name (keys %$stash) {
836 my $fullname = $pack . '::' . $name;
837 # Get rid of everything with that name.
846 Or, if you're using a recent release of Perl, you can
847 just use the Symbol::delete_package() function instead.
849 =head2 How can I use a variable as a variable name?
851 Beginners often think they want to have a variable contain the name
856 ++$$varname; # $fred now 24
858 This works I<sometimes>, but it is a very bad idea for two reasons.
860 The first reason is that they I<only work on global variables>.
861 That means above that if $fred is a lexical variable created with my(),
862 that the code won't work at all: you'll accidentally access the global
863 and skip right over the private lexical altogether. Global variables
864 are bad because they can easily collide accidentally and in general make
865 for non-scalable and confusing code.
867 Symbolic references are forbidden under the C<use strict> pragma.
868 They are not true references and consequently are not reference counted
869 or garbage collected.
871 The other reason why using a variable to hold the name of another
872 variable a bad idea is that the question often stems from a lack of
873 understanding of Perl data structures, particularly hashes. By using
874 symbolic references, you are just using the package's symbol-table hash
875 (like C<%main::>) instead of a user-defined hash. The solution is to
876 use your own hash or a real reference instead.
880 $USER_VARS{$varname}++; # not $$varname++
882 There we're using the %USER_VARS hash instead of symbolic references.
883 Sometimes this comes up in reading strings from the user with variable
884 references and wanting to expand them to the values of your perl
885 program's variables. This is also a bad idea because it conflates the
886 program-addressable namespace and the user-addressable one. Instead of
887 reading a string and expanding it to the actual contents of your program's
890 $str = 'this has a $fred and $barney in it';
891 $str =~ s/(\$\w+)/$1/eeg; # need double eval
893 Instead, it would be better to keep a hash around like %USER_VARS and have
894 variable references actually refer to entries in that hash:
896 $str =~ s/\$(\w+)/$USER_VARS{$1}/g; # no /e here at all
898 That's faster, cleaner, and safer than the previous approach. Of course,
899 you don't need to use a dollar sign. You could use your own scheme to
900 make it less confusing, like bracketed percent symbols, etc.
902 $str = 'this has a %fred% and %barney% in it';
903 $str =~ s/%(\w+)%/$USER_VARS{$1}/g; # no /e here at all
905 Another reason that folks sometimes think they want a variable to contain
906 the name of a variable is because they don't know how to build proper
907 data structures using hashes. For example, let's say they wanted two
908 hashes in their program: %fred and %barney, and to use another scalar
909 variable to refer to those by name.
912 $$name{WIFE} = "wilma"; # set %fred
915 $$name{WIFE} = "betty"; # set %barney
917 This is still a symbolic reference, and is still saddled with the
918 problems enumerated above. It would be far better to write:
920 $folks{"fred"}{WIFE} = "wilma";
921 $folks{"barney"}{WIFE} = "betty";
923 And just use a multilevel hash to start with.
925 The only times that you absolutely I<must> use symbolic references are
926 when you really must refer to the symbol table. This may be because it's
927 something that can't take a real reference to, such as a format name.
928 Doing so may also be important for method calls, since these always go
929 through the symbol table for resolution.
931 In those cases, you would turn off C<strict 'refs'> temporarily so you
932 can play around with the symbol table. For example:
934 @colors = qw(red blue green yellow orange purple violet);
935 for my $name (@colors) {
936 no strict 'refs'; # renege for the block
937 *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
940 All those functions (red(), blue(), green(), etc.) appear to be separate,
941 but the real code in the closure actually was compiled only once.
943 So, sometimes you might want to use symbolic references to directly
944 manipulate the symbol table. This doesn't matter for formats, handles, and
945 subroutines, because they are always global -- you can't use my() on them.
946 But for scalars, arrays, and hashes -- and usually for subroutines --
947 you probably want to use hard references only.
949 =head1 AUTHOR AND COPYRIGHT
951 Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington.
954 When included as part of the Standard Version of Perl, or as part of
955 its complete documentation whether printed or otherwise, this work
956 may be distributed only under the terms of Perl's Artistic License.
957 Any distribution of this file or derivatives thereof I<outside>
958 of that package require that special arrangements be made with
961 Irrespective of its distribution, all code examples in this file
962 are hereby placed into the public domain. You are permitted and
963 encouraged to use this code in your own programs for fun
964 or for profit as you see fit. A simple comment in the code giving
965 credit would be courteous but is not required.