3 perlfaq6 - Regular Expressions ($Revision: 7910 $)
7 This section is surprisingly small because the rest of the FAQ is
8 littered with answers involving regular expressions. For example,
9 decoding a URL and checking whether something is a number are handled
10 with regular expressions, but those answers are found elsewhere in
11 this document (in L<perlfaq9>: "How do I decode or create those %-encodings
12 on the web" and L<perlfaq4>: "How do I determine whether a scalar is
13 a number/whole/integer/float", to be precise).
15 =head2 How can I hope to use regular expressions without creating illegible and unmaintainable code?
16 X<regex, legibility> X<regexp, legibility>
17 X<regular expression, legibility> X</x>
19 Three techniques can make regular expressions maintainable and
24 =item Comments Outside the Regex
26 Describe what you're doing and how you're doing it, using normal Perl
29 # turn the line into the first word, a colon, and the
30 # number of characters on the rest of the line
31 s/^(\w+)(.*)/ lc($1) . ":" . length($2) /meg;
33 =item Comments Inside the Regex
35 The C</x> modifier causes whitespace to be ignored in a regex pattern
36 (except in a character class), and also allows you to use normal
37 comments there, too. As you can imagine, whitespace and comments help
40 C</x> lets you turn this:
42 s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;
46 s{ < # opening angle bracket
47 (?: # Non-backreffing grouping paren
48 [^>'"] * # 0 or more things that are neither > nor ' nor "
50 ".*?" # a section between double quotes (stingy match)
52 '.*?' # a section between single quotes (stingy match)
53 ) + # all occurring one or more times
54 > # closing angle bracket
55 }{}gsx; # replace with nothing, i.e. delete
57 It's still not quite so clear as prose, but it is very useful for
58 describing the meaning of each part of the pattern.
60 =item Different Delimiters
62 While we normally think of patterns as being delimited with C</>
63 characters, they can be delimited by almost any character. L<perlre>
64 describes this. For example, the C<s///> above uses braces as
65 delimiters. Selecting another delimiter can avoid quoting the
66 delimiter within the pattern:
68 s/\/usr\/local/\/usr\/share/g; # bad delimiter choice
69 s#/usr/local#/usr/share#g; # better
73 =head2 I'm having trouble matching over more than one line. What's wrong?
74 X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
76 Either you don't have more than one line in the string you're looking
77 at (probably), or else you aren't using the correct modifier(s) on
78 your pattern (possibly).
80 There are many ways to get multiline data into a string. If you want
81 it to happen automatically while reading input, you'll want to set $/
82 (probably to '' for paragraphs or C<undef> for the whole file) to
83 allow you to read more than one line at a time.
85 Read L<perlre> to help you decide which of C</s> and C</m> (or both)
86 you might want to use: C</s> allows dot to include newline, and C</m>
87 allows caret and dollar to match next to a newline, not just at the
88 end of the string. You do need to make sure that you've actually
89 got a multiline string in there.
91 For example, this program detects duplicate words, even when they span
92 line breaks (but not paragraph ones). For this example, we don't need
93 C</s> because we aren't using dot in a regular expression that we want
94 to cross line boundaries. Neither do we need C</m> because we aren't
95 wanting caret or dollar to match at any point inside the record next
96 to newlines. But it's imperative that $/ be set to something other
97 than the default, or else we won't actually ever have a multiline
100 $/ = ''; # read in more whole paragraph, not just one line
102 while ( /\b([\w'-]+)(\s+\1)+\b/gi ) { # word starts alpha
103 print "Duplicate $1 at paragraph $.\n";
107 Here's code that finds sentences that begin with "From " (which would
108 be mangled by many mailers):
110 $/ = ''; # read in more whole paragraph, not just one line
112 while ( /^From /gm ) { # /m makes ^ match next to \n
113 print "leading from in paragraph $.\n";
117 Here's code that finds everything between START and END in a paragraph:
119 undef $/; # read in whole file, not just one line or paragraph
121 while ( /START(.*?)END/sgm ) { # /s makes . cross line boundaries
126 =head2 How can I pull out lines between two patterns that are themselves on different lines?
129 You can use Perl's somewhat exotic C<..> operator (documented in
132 perl -ne 'print if /START/ .. /END/' file1 file2 ...
134 If you wanted text and not lines, you would use
136 perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...
138 But if you want nested occurrences of C<START> through C<END>, you'll
139 run up against the problem described in the question in this section
140 on matching balanced text.
142 Here's another example of using C<..>:
145 $in_header = 1 .. /^$/;
146 $in_body = /^$/ .. eof;
147 # now choose between them
149 $. = 0 if eof; # fix $.
152 =head2 I put a regular expression into $/ but it didn't work. What's wrong?
153 X<$/, regexes in> X<$INPUT_RECORD_SEPARATOR, regexes in>
156 Up to Perl 5.8.0, $/ has to be a string. This may change in 5.10,
157 but don't get your hopes up. Until then, you can use these examples
158 if you really need to do this.
160 If you have File::Stream, this is easy.
164 my $stream = File::Stream->new(
166 separator => qr/\s*,\s*/,
169 print "$_\n" while <$stream>;
171 If you don't have File::Stream, you have to do a little more work.
173 You can use the four argument form of sysread to continually add to
174 a buffer. After you add to the buffer, you check if you have a
175 complete line (using your regular expression).
178 while( sysread FH, $_, 8192, length ) {
179 while( s/^((?s).*?)your_pattern/ ) {
185 You can do the same thing with foreach and a match using the
186 c flag and the \G anchor, if you do not mind your entire file
187 being in memory at the end.
190 while( sysread FH, $_, 8192, length ) {
191 foreach my $record ( m/\G((?s).*?)your_pattern/gc ) {
194 substr( $_, 0, pos ) = "" if pos;
198 =head2 How do I substitute case insensitively on the LHS while preserving case on the RHS?
199 X<replace, case preserving> X<substitute, case preserving>
200 X<substitution, case preserving> X<s, case preserving>
202 Here's a lovely Perlish solution by Larry Rosler. It exploits
203 properties of bitwise xor on ASCII strings.
205 $_= "this is a TEsT case";
211 { uc $new | (uc $1 ^ $1) .
212 (uc(substr $1, -1) ^ substr $1, -1) x
213 (length($new) - length $1)
218 And here it is as a subroutine, modeled after the above:
220 sub preserve_case($$) {
221 my ($old, $new) = @_;
222 my $mask = uc $old ^ $old;
225 substr($mask, -1) x (length($new) - length($old))
228 $a = "this is a TEsT case";
229 $a =~ s/(test)/preserve_case($1, "success")/egi;
234 this is a SUcCESS case
236 As an alternative, to keep the case of the replacement word if it is
237 longer than the original, you can use this code, by Jeff Pinyan:
240 my ($from, $to) = @_;
241 my ($lf, $lt) = map length, @_;
243 if ($lt < $lf) { $from = substr $from, 0, $lt }
244 else { $from .= substr $to, $lf }
246 return uc $to | ($from ^ uc $from);
249 This changes the sentence to "this is a SUcCess case."
251 Just to show that C programmers can write C in any programming language,
252 if you prefer a more C-like solution, the following script makes the
253 substitution have the same case, letter by letter, as the original.
254 (It also happens to run about 240% slower than the Perlish solution runs.)
255 If the substitution has more characters than the string being substituted,
256 the case of the last character is used for the rest of the substitution.
258 # Original by Nathan Torkington, massaged by Jeffrey Friedl
260 sub preserve_case($$)
262 my ($old, $new) = @_;
263 my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
264 my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
265 my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
267 for ($i = 0; $i < $len; $i++) {
268 if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
270 } elsif (lc $c eq $c) {
271 substr($new, $i, 1) = lc(substr($new, $i, 1));
274 substr($new, $i, 1) = uc(substr($new, $i, 1));
278 # finish up with any remaining new (for when new is longer than old)
279 if ($newlen > $oldlen) {
281 substr($new, $oldlen) = lc(substr($new, $oldlen));
282 } elsif ($state == 2) {
283 substr($new, $oldlen) = uc(substr($new, $oldlen));
289 =head2 How can I make C<\w> match national character sets?
292 Put C<use locale;> in your script. The \w character class is taken
293 from the current locale.
295 See L<perllocale> for details.
297 =head2 How can I match a locale-smart version of C</[a-zA-Z]/>?
300 You can use the POSIX character class syntax C</[[:alpha:]]/>
301 documented in L<perlre>.
303 No matter which locale you are in, the alphabetic characters are
304 the characters in \w without the digits and the underscore.
305 As a regex, that looks like C</[^\W\d_]/>. Its complement,
306 the non-alphabetics, is then everything in \W along with
307 the digits and the underscore, or C</[\W\d_]/>.
309 =head2 How can I quote a variable to use in a regex?
310 X<regex, escaping> X<regexp, escaping> X<regular expression, escaping>
312 The Perl parser will expand $variable and @variable references in
313 regular expressions unless the delimiter is a single quote. Remember,
314 too, that the right-hand side of a C<s///> substitution is considered
315 a double-quoted string (see L<perlop> for more details). Remember
316 also that any regex special characters will be acted on unless you
317 precede the substitution with \Q. Here's an example:
319 $string = "Placido P. Octopus";
322 $string =~ s/$regex/Polyp/;
323 # $string is now "Polypacido P. Octopus"
325 Because C<.> is special in regular expressions, and can match any
326 single character, the regex C<P.> here has matched the <Pl> in the
329 To escape the special meaning of C<.>, we use C<\Q>:
331 $string = "Placido P. Octopus";
334 $string =~ s/\Q$regex/Polyp/;
335 # $string is now "Placido Polyp Octopus"
337 The use of C<\Q> causes the <.> in the regex to be treated as a
338 regular character, so that C<P.> matches a C<P> followed by a dot.
340 =head2 What is C</o> really for?
343 Using a variable in a regular expression match forces a re-evaluation
344 (and perhaps recompilation) each time the regular expression is
345 encountered. The C</o> modifier locks in the regex the first time
346 it's used. This always happens in a constant regular expression, and
347 in fact, the pattern was compiled into the internal format at the same
348 time your entire program was.
350 Use of C</o> is irrelevant unless variable interpolation is used in
351 the pattern, and if so, the regex engine will neither know nor care
352 whether the variables change after the pattern is evaluated the I<very
355 C</o> is often used to gain an extra measure of efficiency by not
356 performing subsequent evaluations when you know it won't matter
357 (because you know the variables won't change), or more rarely, when
358 you don't want the regex to notice if they do.
360 For example, here's a "paragrep" program:
362 $/ = ''; # paragraph mode
368 =head2 How do I use a regular expression to strip C style comments from a file?
370 While this actually can be done, it's much harder than you'd think.
371 For example, this one-liner
373 perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c
375 will work in many but not all cases. You see, it's too simple-minded for
376 certain kinds of C programs, in particular, those with what appear to be
377 comments in quoted strings. For that, you'd need something like this,
378 created by Jeffrey Friedl and later modified by Fred Curtis.
382 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;
385 This could, of course, be more legibly written with the C</x> modifier, adding
386 whitespace and comments. Here it is expanded, courtesy of Fred Curtis.
389 /\* ## Start of /* ... */ comment
390 [^*]*\*+ ## Non-* followed by 1-or-more *'s
393 )* ## 0-or-more things which don't start with /
394 ## but do end with '*'
395 / ## End of /* ... */ comment
397 | ## OR various things which aren't comments:
400 " ## Start of " ... " string
406 " ## End of " ... " string
410 ' ## Start of ' ... ' string
416 ' ## End of ' ... ' string
420 . ## Anything other char
421 [^/"'\\]* ## Chars which doesn't start a comment, string or escape
423 }{defined $2 ? $2 : ""}gxse;
425 A slight modification also removes C++ comments, as long as they are not
426 spread over multiple lines using a continuation character):
428 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|//[^\n]*|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;
430 =head2 Can I use Perl regular expressions to match balanced text?
431 X<regex, matching balanced test> X<regexp, matching balanced test>
432 X<regular expression, matching balanced test>
434 Historically, Perl regular expressions were not capable of matching
435 balanced text. As of more recent versions of perl including 5.6.1
436 experimental features have been added that make it possible to do this.
437 Look at the documentation for the (??{ }) construct in recent perlre manual
438 pages to see an example of matching balanced parentheses. Be sure to take
439 special notice of the warnings present in the manual before making use
442 CPAN contains many modules that can be useful for matching text
443 depending on the context. Damian Conway provides some useful
444 patterns in Regexp::Common. The module Text::Balanced provides a
445 general solution to this problem.
447 One of the common applications of balanced text matching is working
448 with XML and HTML. There are many modules available that support
449 these needs. Two examples are HTML::Parser and XML::Parser. There
452 An elaborate subroutine (for 7-bit ASCII only) to pull out balanced
453 and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>,
454 or C<(> and C<)> can be found in
455 http://www.cpan.org/authors/id/TOMC/scripts/pull_quotes.gz .
457 The C::Scan module from CPAN also contains such subs for internal use,
458 but they are undocumented.
460 =head2 What does it mean that regexes are greedy? How can I get around it?
461 X<greedy> X<greediness>
463 Most people mean that greedy regexes match as much as they can.
464 Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>,
465 C<{}>) that are greedy rather than the whole pattern; Perl prefers local
466 greed and immediate gratification to overall greed. To get non-greedy
467 versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>).
471 $s1 = $s2 = "I am very very cold";
472 $s1 =~ s/ve.*y //; # I am cold
473 $s2 =~ s/ve.*?y //; # I am very cold
475 Notice how the second substitution stopped matching as soon as it
476 encountered "y ". The C<*?> quantifier effectively tells the regular
477 expression engine to find a match as quickly as possible and pass
478 control on to whatever is next in line, like you would if you were
481 =head2 How do I process each word on each line?
484 Use the split function:
487 foreach $word ( split ) {
488 # do something with $word here
492 Note that this isn't really a word in the English sense; it's just
493 chunks of consecutive non-whitespace characters.
495 To work with only alphanumeric sequences (including underscores), you
499 foreach $word (m/(\w+)/g) {
500 # do something with $word here
504 =head2 How can I print out a word-frequency or line-frequency summary?
506 To do this, you have to parse out each word in the input stream. We'll
507 pretend that by word you mean chunk of alphabetics, hyphens, or
508 apostrophes, rather than the non-whitespace chunk idea of a word given
509 in the previous question:
512 while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'"
517 while ( ($word, $count) = each %seen ) {
518 print "$count $word\n";
521 If you wanted to do the same thing for lines, you wouldn't need a
528 while ( ($line, $count) = each %seen ) {
529 print "$count $line";
532 If you want these output in a sorted order, see L<perlfaq4>: "How do I
533 sort a hash (optionally by value instead of key)?".
535 =head2 How can I do approximate matching?
536 X<match, approximate> X<matching, approximate>
538 See the module String::Approx available from CPAN.
540 =head2 How do I efficiently match many regular expressions at once?
541 X<regex, efficiency> X<regexp, efficiency>
542 X<regular expression, efficiency>
544 ( contributed by brian d foy )
546 Avoid asking Perl to compile a regular expression every time
547 you want to match it. In this example, perl must recompile
548 the regular expression for every iteration of the foreach()
549 loop since it has no way to know what $pattern will be.
551 @patterns = qw( foo bar baz );
553 LINE: while( <DATA> )
555 foreach $pattern ( @patterns )
557 if( /\b$pattern\b/i )
565 The qr// operator showed up in perl 5.005. It compiles a
566 regular expression, but doesn't apply it. When you use the
567 pre-compiled version of the regex, perl does less work. In
568 this example, I inserted a map() to turn each pattern into
569 its pre-compiled form. The rest of the script is the same,
572 @patterns = map { qr/\b$_\b/i } qw( foo bar baz );
576 foreach $pattern ( @patterns )
578 print if /\b$pattern\b/i;
583 In some cases, you may be able to make several patterns into
584 a single regular expression. Beware of situations that require
587 $regex = join '|', qw( foo bar baz );
591 print if /\b(?:$regex)\b/i;
594 For more details on regular expression efficiency, see Mastering
595 Regular Expressions by Jeffrey Freidl. He explains how regular
596 expressions engine work and why some patterns are surprisingly
597 inefficient. Once you understand how perl applies regular
598 expressions, you can tune them for individual situations.
600 =head2 Why don't word-boundary searches with C<\b> work for me?
603 (contributed by brian d foy)
605 Ensure that you know what \b really does: it's the boundary between a
606 word character, \w, and something that isn't a word character. That
607 thing that isn't a word character might be \W, but it can also be the
608 start or end of the string.
610 It's not (not!) the boundary between whitespace and non-whitespace,
611 and it's not the stuff between words we use to create sentences.
613 In regex speak, a word boundary (\b) is a "zero width assertion",
614 meaning that it doesn't represent a character in the string, but a
615 condition at a certain position.
617 For the regular expression, /\bPerl\b/, there has to be a word
618 boundary before the "P" and after the "l". As long as something other
619 than a word character precedes the "P" and succeeds the "l", the
620 pattern will match. These strings match /\bPerl\b/.
622 "Perl" # no word char before P or after l
623 "Perl " # same as previous (space is not a word char)
624 "'Perl'" # the ' char is not a word char
625 "Perl's" # no word char before P, non-word char after "l"
627 These strings do not match /\bPerl\b/.
629 "Perl_" # _ is a word char!
630 "Perler" # no word char before P, but one after l
632 You don't have to use \b to match words though. You can look for
633 non-word characters surrounded by word characters. These strings
634 match the pattern /\b'\b/.
636 "don't" # the ' char is surrounded by "n" and "t"
637 "qep'a'" # the ' char is surrounded by "p" and "a"
639 These strings do not match /\b'\b/.
641 "foo'" # there is no word char after non-word '
643 You can also use the complement of \b, \B, to specify that there
644 should not be a word boundary.
646 In the pattern /\Bam\B/, there must be a word character before the "a"
647 and after the "m". These patterns match /\Bam\B/:
649 "llama" # "am" surrounded by word chars
652 These strings do not match /\Bam\B/
654 "Sam" # no word boundary before "a", but one after "m"
655 "I am Sam" # "am" surrounded by non-word chars
658 =head2 Why does using $&, $`, or $' slow my program down?
659 X<$MATCH> X<$&> X<$POSTMATCH> X<$'> X<$PREMATCH> X<$`>
661 (contributed by Anno Siegel)
663 Once Perl sees that you need one of these variables anywhere in the
664 program, it provides them on each and every pattern match. That means
665 that on every pattern match the entire string will be copied, part of it
666 to $`, part to $&, and part to $'. Thus the penalty is most severe with
667 long strings and patterns that match often. Avoid $&, $', and $` if you
668 can, but if you can't, once you've used them at all, use them at will
669 because you've already paid the price. Remember that some algorithms
670 really appreciate them. As of the 5.005 release, the $& variable is no
671 longer "expensive" the way the other two are.
673 Since Perl 5.6.1 the special variables @- and @+ can functionally replace
674 $`, $& and $'. These arrays contain pointers to the beginning and end
675 of each match (see perlvar for the full story), so they give you
676 essentially the same information, but without the risk of excessive
679 =head2 What good is C<\G> in a regular expression?
682 You use the C<\G> anchor to start the next match on the same
683 string where the last match left off. The regular
684 expression engine cannot skip over any characters to find
685 the next match with this anchor, so C<\G> is similar to the
686 beginning of string anchor, C<^>. The C<\G> anchor is typically
687 used with the C<g> flag. It uses the value of pos()
688 as the position to start the next match. As the match
689 operator makes successive matches, it updates pos() with the
690 position of the next character past the last match (or the
691 first character of the next match, depending on how you like
692 to look at it). Each string has its own pos() value.
694 Suppose you want to match all of consective pairs of digits
695 in a string like "1122a44" and stop matching when you
696 encounter non-digits. You want to match C<11> and C<22> but
697 the letter <a> shows up between C<22> and C<44> and you want
698 to stop at C<a>. Simply matching pairs of digits skips over
699 the C<a> and still matches C<44>.
702 my @pairs = m/(\d\d)/g; # qw( 11 22 44 )
704 If you use the \G anchor, you force the match after C<22> to
705 start with the C<a>. The regular expression cannot match
706 there since it does not find a digit, so the next match
707 fails and the match operator returns the pairs it already
711 my @pairs = m/\G(\d\d)/g; # qw( 11 22 )
713 You can also use the C<\G> anchor in scalar context. You
714 still need the C<g> flag.
717 while( m/\G(\d\d)/g )
722 After the match fails at the letter C<a>, perl resets pos()
723 and the next match on the same string starts at the beginning.
726 while( m/\G(\d\d)/g )
731 print "Found $1 after while" if m/(\d\d)/g; # finds "11"
733 You can disable pos() resets on fail with the C<c> flag.
734 Subsequent matches start where the last successful match
735 ended (the value of pos()) even if a match on the same
736 string as failed in the meantime. In this case, the match
737 after the while() loop starts at the C<a> (where the last
738 match stopped), and since it does not use any anchor it can
739 skip over the C<a> to find "44".
742 while( m/\G(\d\d)/gc )
747 print "Found $1 after while" if m/(\d\d)/g; # finds "44"
749 Typically you use the C<\G> anchor with the C<c> flag
750 when you want to try a different match if one fails,
751 such as in a tokenizer. Jeffrey Friedl offers this example
752 which works in 5.004 or later.
757 m/ \G( \d+\b )/gcx && do { print "number: $1\n"; redo; };
758 m/ \G( \w+ )/gcx && do { print "word: $1\n"; redo; };
759 m/ \G( \s+ )/gcx && do { print "space: $1\n"; redo; };
760 m/ \G( [^\w\d]+ )/gcx && do { print "other: $1\n"; redo; };
764 For each line, the PARSER loop first tries to match a series
765 of digits followed by a word boundary. This match has to
766 start at the place the last match left off (or the beginning
767 of the string on the first match). Since C<m/ \G( \d+\b
768 )/gcx> uses the C<c> flag, if the string does not match that
769 regular expression, perl does not reset pos() and the next
770 match starts at the same position to try a different
773 =head2 Are Perl regexes DFAs or NFAs? Are they POSIX compliant?
774 X<DFA> X<NFA> X<POSIX>
776 While it's true that Perl's regular expressions resemble the DFAs
777 (deterministic finite automata) of the egrep(1) program, they are in
778 fact implemented as NFAs (non-deterministic finite automata) to allow
779 backtracking and backreferencing. And they aren't POSIX-style either,
780 because those guarantee worst-case behavior for all cases. (It seems
781 that some people prefer guarantees of consistency, even when what's
782 guaranteed is slowness.) See the book "Mastering Regular Expressions"
783 (from O'Reilly) by Jeffrey Friedl for all the details you could ever
784 hope to know on these matters (a full citation appears in
787 =head2 What's wrong with using grep in a void context?
790 The problem is that grep builds a return list, regardless of the context.
791 This means you're making Perl go to the trouble of building a list that
792 you then just throw away. If the list is large, you waste both time and space.
793 If your intent is to iterate over the list, then use a for loop for this
796 In perls older than 5.8.1, map suffers from this problem as well.
797 But since 5.8.1, this has been fixed, and map is context aware - in void
798 context, no lists are constructed.
800 =head2 How can I match strings with multibyte characters?
801 X<regex, and multibyte characters> X<regexp, and multibyte characters>
802 X<regular expression, and multibyte characters> X<martian> X<encoding, Martian>
804 Starting from Perl 5.6 Perl has had some level of multibyte character
805 support. Perl 5.8 or later is recommended. Supported multibyte
806 character repertoires include Unicode, and legacy encodings
807 through the Encode module. See L<perluniintro>, L<perlunicode>,
810 If you are stuck with older Perls, you can do Unicode with the
811 C<Unicode::String> module, and character conversions using the
812 C<Unicode::Map8> and C<Unicode::Map> modules. If you are using
813 Japanese encodings, you might try using the jperl 5.005_03.
815 Finally, the following set of approaches was offered by Jeffrey
816 Friedl, whose article in issue #5 of The Perl Journal talks about
819 Let's suppose you have some weird Martian encoding where pairs of
820 ASCII uppercase letters encode single Martian letters (i.e. the two
821 bytes "CV" make a single Martian letter, as do the two bytes "SG",
822 "VS", "XX", etc.). Other bytes represent single characters, just like
825 So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the
826 nine characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.
828 Now, say you want to search for the single character C</GX/>. Perl
829 doesn't know about Martian, so it'll find the two bytes "GX" in the "I
830 am CVSGXX!" string, even though that character isn't there: it just
831 looks like it is because "SG" is next to "XX", but there's no real
832 "GX". This is a big problem.
834 Here are a few ways, all painful, to deal with it:
836 # Make sure adjacent "martian" bytes are no longer adjacent.
837 $martian =~ s/([A-Z][A-Z])/ $1 /g;
839 print "found GX!\n" if $martian =~ /GX/;
843 @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
844 # above is conceptually similar to: @chars = $text =~ m/(.)/g;
846 foreach $char (@chars) {
847 print "found GX!\n", last if $char eq 'GX';
852 while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded
853 print "found GX!\n", last if $1 eq 'GX';
856 Here's another, slightly less painful, way to do it from Benjamin
857 Goldberg, who uses a zero-width negative look-behind assertion.
859 print "found GX!\n" if $martian =~ m/
865 This succeeds if the "martian" character GX is in the string, and fails
866 otherwise. If you don't like using (?<!), a zero-width negative
867 look-behind assertion, you can replace (?<![A-Z]) with (?:^|[^A-Z]).
869 It does have the drawback of putting the wrong thing in $-[0] and $+[0],
870 but this usually can be worked around.
872 =head2 How do I match a regular expression that's in a variable?
873 X<regex, in variable> X<eval> X<regex> X<quotemeta> X<\Q, regex>
874 X<\E, regex>, X<qr//>
876 (contributed by brian d foy)
878 We don't have to hard-code patterns into the match operator (or
879 anything else that works with regular expressions). We can put the
880 pattern in a variable for later use.
882 The match operator is a double quote context, so you can interpolate
883 your variable just like a double quoted string. In this case, you
884 read the regular expression as user input and store it in C<$regex>.
885 Once you have the pattern in C<$regex>, you use that variable in the
888 chomp( my $regex = <STDIN> );
890 if( $string =~ m/$regex/ ) { ... }
892 Any regular expression special characters in C<$regex> are still
893 special, and the pattern still has to be valid or Perl will complain.
894 For instance, in this pattern there is an unpaired parenthesis.
896 my $regex = "Unmatched ( paren";
898 "Two parens to bind them all" =~ m/$regex/;
900 When Perl compiles the regular expression, it treats the parenthesis
901 as the start of a memory match. When it doesn't find the closing
902 parenthesis, it complains:
904 Unmatched ( in regex; marked by <-- HERE in m/Unmatched ( <-- HERE paren/ at script line 3.
906 You can get around this in several ways depending on our situation.
907 First, if you don't want any of the characters in the string to be
908 special, you can escape them with C<quotemeta> before you use the string.
910 chomp( my $regex = <STDIN> );
911 $regex = quotemeta( $regex );
913 if( $string =~ m/$regex/ ) { ... }
915 You can also do this directly in the match operator using the C<\Q>
916 and C<\E> sequences. The C<\Q> tells Perl where to start escaping
917 special characters, and the C<\E> tells it where to stop (see L<perlop>
920 chomp( my $regex = <STDIN> );
922 if( $string =~ m/\Q$regex\E/ ) { ... }
924 Alternately, you can use C<qr//>, the regular expression quote operator (see
925 L<perlop> for more details). It quotes and perhaps compiles the pattern,
926 and you can apply regular expression flags to the pattern.
928 chomp( my $input = <STDIN> );
930 my $regex = qr/$input/is;
932 $string =~ m/$regex/ # same as m/$input/is;
934 You might also want to trap any errors by wrapping an C<eval> block
935 around the whole thing.
937 chomp( my $input = <STDIN> );
940 if( $string =~ m/\Q$input\E/ ) { ... }
946 my $regex = eval { qr/$input/is };
947 if( defined $regex ) {
948 $string =~ m/$regex/;
956 Revision: $Revision: 7910 $
958 Date: $Date: 2006-10-07 22:38:54 +0200 (sam, 07 oct 2006) $
960 See L<perlfaq> for source control details and availability.
962 =head1 AUTHOR AND COPYRIGHT
964 Copyright (c) 1997-2006 Tom Christiansen, Nathan Torkington, and
965 other authors as noted. All rights reserved.
967 This documentation is free; you can redistribute it and/or modify it
968 under the same terms as Perl itself.
970 Irrespective of its distribution, all code examples in this file
971 are hereby placed into the public domain. You are permitted and
972 encouraged to use this code in your own programs for fun
973 or for profit as you see fit. A simple comment in the code giving
974 credit would be courteous but is not required.