3 perlfaq6 - Regexps ($Revision: 1.25 $, $Date: 1999/01/08 04:50:47 $)
7 This section is surprisingly small because the rest of the FAQ is
8 littered with answers involving regular expressions. For example,
9 decoding a URL and checking whether something is a number are handled
10 with regular expressions, but those answers are found elsewhere in
11 this document (in the section on Data and the Networking one on
12 networking, to be precise).
14 =head2 How can I hope to use regular expressions without creating illegible and unmaintainable code?
16 Three techniques can make regular expressions maintainable and
21 =item Comments Outside the Regexp
23 Describe what you're doing and how you're doing it, using normal Perl
26 # turn the line into the first word, a colon, and the
27 # number of characters on the rest of the line
28 s/^(\w+)(.*)/ lc($1) . ":" . length($2) /meg;
30 =item Comments Inside the Regexp
32 The C</x> modifier causes whitespace to be ignored in a regexp pattern
33 (except in a character class), and also allows you to use normal
34 comments there, too. As you can imagine, whitespace and comments help
37 C</x> lets you turn this:
39 s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;
43 s{ < # opening angle bracket
44 (?: # Non-backreffing grouping paren
45 [^>'"] * # 0 or more things that are neither > nor ' nor "
47 ".*?" # a section between double quotes (stingy match)
49 '.*?' # a section between single quotes (stingy match)
50 ) + # all occurring one or more times
51 > # closing angle bracket
52 }{}gsx; # replace with nothing, i.e. delete
54 It's still not quite so clear as prose, but it is very useful for
55 describing the meaning of each part of the pattern.
57 =item Different Delimiters
59 While we normally think of patterns as being delimited with C</>
60 characters, they can be delimited by almost any character. L<perlre>
61 describes this. For example, the C<s///> above uses braces as
62 delimiters. Selecting another delimiter can avoid quoting the
63 delimiter within the pattern:
65 s/\/usr\/local/\/usr\/share/g; # bad delimiter choice
66 s#/usr/local#/usr/share#g; # better
70 =head2 I'm having trouble matching over more than one line. What's wrong?
72 Either you don't have more than one line in the string you're looking at
73 (probably), or else you aren't using the correct modifier(s) on your
76 There are many ways to get multiline data into a string. If you want
77 it to happen automatically while reading input, you'll want to set $/
78 (probably to '' for paragraphs or C<undef> for the whole file) to
79 allow you to read more than one line at a time.
81 Read L<perlre> to help you decide which of C</s> and C</m> (or both)
82 you might want to use: C</s> allows dot to include newline, and C</m>
83 allows caret and dollar to match next to a newline, not just at the
84 end of the string. You do need to make sure that you've actually
85 got a multiline string in there.
87 For example, this program detects duplicate words, even when they span
88 line breaks (but not paragraph ones). For this example, we don't need
89 C</s> because we aren't using dot in a regular expression that we want
90 to cross line boundaries. Neither do we need C</m> because we aren't
91 wanting caret or dollar to match at any point inside the record next
92 to newlines. But it's imperative that $/ be set to something other
93 than the default, or else we won't actually ever have a multiline
96 $/ = ''; # read in more whole paragraph, not just one line
98 while ( /\b([\w'-]+)(\s+\1)+\b/gi ) { # word starts alpha
99 print "Duplicate $1 at paragraph $.\n";
103 Here's code that finds sentences that begin with "From " (which would
104 be mangled by many mailers):
106 $/ = ''; # read in more whole paragraph, not just one line
108 while ( /^From /gm ) { # /m makes ^ match next to \n
109 print "leading from in paragraph $.\n";
113 Here's code that finds everything between START and END in a paragraph:
115 undef $/; # read in whole file, not just one line or paragraph
117 while ( /START(.*?)END/sm ) { # /s makes . cross line boundaries
122 =head2 How can I pull out lines between two patterns that are themselves on different lines?
124 You can use Perl's somewhat exotic C<..> operator (documented in
127 perl -ne 'print if /START/ .. /END/' file1 file2 ...
129 If you wanted text and not lines, you would use
131 perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...
133 But if you want nested occurrences of C<START> through C<END>, you'll
134 run up against the problem described in the question in this section
135 on matching balanced text.
137 Here's another example of using C<..>:
140 $in_header = 1 .. /^$/;
141 $in_body = /^$/ .. eof();
142 # now choose between them
144 reset if eof(); # fix $.
147 =head2 I put a regular expression into $/ but it didn't work. What's wrong?
149 $/ must be a string, not a regular expression. Awk has to be better
152 Actually, you could do this if you don't mind reading the whole file
156 @records = split /your_pattern/, <FH>;
158 The Net::Telnet module (available from CPAN) has the capability to
159 wait for a pattern in the input stream, or timeout if it doesn't
160 appear within a certain time.
162 ## Create a file with three lines.
164 print FH "The first line\nThe second line\nThe third line\n";
167 ## Get a read/write filehandle to it.
168 $fh = new FileHandle "+<file";
170 ## Attach it to a "stream" object.
172 $file = new Net::Telnet (-fhopen => $fh);
174 ## Search for the second line and print out the third.
175 $file->waitfor('/second line\n/');
176 print $file->getline;
178 =head2 How do I substitute case insensitively on the LHS, but preserving case on the RHS?
180 It depends on what you mean by "preserving case". The following
181 script makes the substitution have the same case, letter by letter, as
182 the original. If the substitution has more characters than the string
183 being substituted, the case of the last character is used for the rest
186 # Original by Nathan Torkington, massaged by Jeffrey Friedl
188 sub preserve_case($$)
190 my ($old, $new) = @_;
191 my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
192 my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
193 my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
195 for ($i = 0; $i < $len; $i++) {
196 if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
198 } elsif (lc $c eq $c) {
199 substr($new, $i, 1) = lc(substr($new, $i, 1));
202 substr($new, $i, 1) = uc(substr($new, $i, 1));
206 # finish up with any remaining new (for when new is longer than old)
207 if ($newlen > $oldlen) {
209 substr($new, $oldlen) = lc(substr($new, $oldlen));
210 } elsif ($state == 2) {
211 substr($new, $oldlen) = uc(substr($new, $oldlen));
217 $a = "this is a TEsT case";
218 $a =~ s/(test)/preserve_case($1, "success")/gie;
223 this is a SUcCESS case
225 =head2 How can I make C<\w> match national character sets?
229 =head2 How can I match a locale-smart version of C</[a-zA-Z]/>?
231 One alphabetic character would be C</[^\W\d_]/>, no matter what locale
232 you're in. Non-alphabetics would be C</[\W\d_]/> (assuming you don't
233 consider an underscore a letter).
235 =head2 How can I quote a variable to use in a regexp?
237 The Perl parser will expand $variable and @variable references in
238 regular expressions unless the delimiter is a single quote. Remember,
239 too, that the right-hand side of a C<s///> substitution is considered
240 a double-quoted string (see L<perlop> for more details). Remember
241 also that any regexp special characters will be acted on unless you
242 precede the substitution with \Q. Here's an example:
246 $rhs = "sleep no more";
248 $string =~ s/\Q$lhs/$rhs/;
249 # $string is now "to sleep no more"
251 Without the \Q, the regexp would also spuriously match "di".
253 =head2 What is C</o> really for?
255 Using a variable in a regular expression match forces a re-evaluation
256 (and perhaps recompilation) each time through. The C</o> modifier
257 locks in the regexp the first time it's used. This always happens in a
258 constant regular expression, and in fact, the pattern was compiled
259 into the internal format at the same time your entire program was.
261 Use of C</o> is irrelevant unless variable interpolation is used in
262 the pattern, and if so, the regexp engine will neither know nor care
263 whether the variables change after the pattern is evaluated the I<very
266 C</o> is often used to gain an extra measure of efficiency by not
267 performing subsequent evaluations when you know it won't matter
268 (because you know the variables won't change), or more rarely, when
269 you don't want the regexp to notice if they do.
271 For example, here's a "paragrep" program:
273 $/ = ''; # paragraph mode
279 =head2 How do I use a regular expression to strip C style comments from a file?
281 While this actually can be done, it's much harder than you'd think.
282 For example, this one-liner
284 perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c
286 will work in many but not all cases. You see, it's too simple-minded for
287 certain kinds of C programs, in particular, those with what appear to be
288 comments in quoted strings. For that, you'd need something like this,
289 created by Jeffrey Friedl:
293 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|\n+|.[^/"'\\]*)#$2#g;
296 This could, of course, be more legibly written with the C</x> modifier, adding
297 whitespace and comments.
299 =head2 Can I use Perl regular expressions to match balanced text?
301 Although Perl regular expressions are more powerful than "mathematical"
302 regular expressions, because they feature conveniences like backreferences
303 (C<\1> and its ilk), they still aren't powerful enough. You still need
304 to use non-regexp techniques to parse balanced text, such as the text
305 enclosed between matching parentheses or braces, for example.
307 An elaborate subroutine (for 7-bit ASCII only) to pull out balanced
308 and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>,
309 or C<(> and C<)> can be found in
310 http://www.perl.com/CPAN/authors/id/TOMC/scripts/pull_quotes.gz .
312 The C::Scan module from CPAN contains such subs for internal usage,
313 but they are undocumented.
315 =head2 What does it mean that regexps are greedy? How can I get around it?
317 Most people mean that greedy regexps match as much as they can.
318 Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>,
319 C<{}>) that are greedy rather than the whole pattern; Perl prefers local
320 greed and immediate gratification to overall greed. To get non-greedy
321 versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>).
325 $s1 = $s2 = "I am very very cold";
326 $s1 =~ s/ve.*y //; # I am cold
327 $s2 =~ s/ve.*?y //; # I am very cold
329 Notice how the second substitution stopped matching as soon as it
330 encountered "y ". The C<*?> quantifier effectively tells the regular
331 expression engine to find a match as quickly as possible and pass
332 control on to whatever is next in line, like you would if you were
335 =head2 How do I process each word on each line?
337 Use the split function:
340 foreach $word ( split ) {
341 # do something with $word here
345 Note that this isn't really a word in the English sense; it's just
346 chunks of consecutive non-whitespace characters.
348 To work with only alphanumeric sequences, you might consider
351 foreach $word (m/(\w+)/g) {
352 # do something with $word here
356 =head2 How can I print out a word-frequency or line-frequency summary?
358 To do this, you have to parse out each word in the input stream. We'll
359 pretend that by word you mean chunk of alphabetics, hyphens, or
360 apostrophes, rather than the non-whitespace chunk idea of a word given
361 in the previous question:
364 while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'"
368 while ( ($word, $count) = each %seen ) {
369 print "$count $word\n";
372 If you wanted to do the same thing for lines, you wouldn't need a
378 while ( ($line, $count) = each %seen ) {
379 print "$count $line";
382 If you want these output in a sorted order, see the section on Hashes.
384 =head2 How can I do approximate matching?
386 See the module String::Approx available from CPAN.
388 =head2 How do I efficiently match many regular expressions at once?
390 The following is extremely inefficient:
392 # slow but obvious way
393 @popstates = qw(CO ON MI WI MN);
394 while (defined($line = <>)) {
395 for $state (@popstates) {
396 if ($line =~ /\b$state\b/i) {
403 That's because Perl has to recompile all those patterns for each of
404 the lines of the file. As of the 5.005 release, there's a much better
405 approach, one which makes use of the new C<qr//> operator:
407 # use spiffy new qr// operator, with /i flag even
409 @popstates = qw(CO ON MI WI MN);
410 @poppats = map { qr/\b$_\b/i } @popstates;
411 while (defined($line = <>)) {
412 for $patobj (@poppats) {
413 print $line if $line =~ /$patobj/;
417 =head2 Why don't word-boundary searches with C<\b> work for me?
419 Two common misconceptions are that C<\b> is a synonym for C<\s+>, and
420 that it's the edge between whitespace characters and non-whitespace
421 characters. Neither is correct. C<\b> is the place between a C<\w>
422 character and a C<\W> character (that is, C<\b> is the edge of a
423 "word"). It's a zero-width assertion, just like C<^>, C<$>, and all
424 the other anchors, so it doesn't consume any characters. L<perlre>
425 describes the behaviour of all the regexp metacharacters.
427 Here are examples of the incorrect application of C<\b>, with fixes:
429 "two words" =~ /(\w+)\b(\w+)/; # WRONG
430 "two words" =~ /(\w+)\s+(\w+)/; # right
432 " =matchless= text" =~ /\b=(\w+)=\b/; # WRONG
433 " =matchless= text" =~ /=(\w+)=/; # right
435 Although they may not do what you thought they did, C<\b> and C<\B>
436 can still be quite useful. For an example of the correct use of
437 C<\b>, see the example of matching duplicate words over multiple
440 An example of using C<\B> is the pattern C<\Bis\B>. This will find
441 occurrences of "is" on the insides of words only, as in "thistle", but
442 not "this" or "island".
444 =head2 Why does using $&, $`, or $' slow my program down?
446 Because once Perl sees that you need one of these variables anywhere in
447 the program, it has to provide them on each and every pattern match.
448 The same mechanism that handles these provides for the use of $1, $2,
449 etc., so you pay the same price for each regexp that contains capturing
450 parentheses. But if you never use $&, etc., in your script, then regexps
451 I<without> capturing parentheses won't be penalized. So avoid $&, $',
452 and $` if you can, but if you can't, once you've used them at all, use
453 them at will because you've already paid the price. Remember that some
454 algorithms really appreciate them. As of the 5.005 release. the $&
455 variable is no longer "expensive" the way the other two are.
457 =head2 What good is C<\G> in a regular expression?
459 The notation C<\G> is used in a match or substitution in conjunction the
460 C</g> modifier (and ignored if there's no C</g>) to anchor the regular
461 expression to the point just past where the last match occurred, i.e. the
462 pos() point. A failed match resets the position of C<\G> unless the
463 C</c> modifier is in effect.
465 For example, suppose you had a line of text quoted in standard mail
466 and Usenet notation, (that is, with leading C<E<gt>> characters), and
467 you want change each leading C<E<gt>> into a corresponding C<:>. You
468 could do so in this way:
470 s/^(>+)/':' x length($1)/gem;
472 Or, using C<\G>, the much simpler (and faster):
476 A more sophisticated use might involve a tokenizer. The following
477 lex-like example is courtesy of Jeffrey Friedl. It did not work in
478 5.003 due to bugs in that release, but does work in 5.004 or better.
479 (Note the use of C</c>, which prevents a failed match with C</g> from
480 resetting the search position back to the beginning of the string.)
485 m/ \G( \d+\b )/gcx && do { print "number: $1\n"; redo; };
486 m/ \G( \w+ )/gcx && do { print "word: $1\n"; redo; };
487 m/ \G( \s+ )/gcx && do { print "space: $1\n"; redo; };
488 m/ \G( [^\w\d]+ )/gcx && do { print "other: $1\n"; redo; };
492 Of course, that could have been written as
497 if ( /\G( \d+\b )/gcx {
498 print "number: $1\n";
501 if ( /\G( \w+ )/gcx {
505 if ( /\G( \s+ )/gcx {
509 if ( /\G( [^\w\d]+ )/gcx {
516 But then you lose the vertical alignment of the regular expressions.
518 =head2 Are Perl regexps DFAs or NFAs? Are they POSIX compliant?
520 While it's true that Perl's regular expressions resemble the DFAs
521 (deterministic finite automata) of the egrep(1) program, they are in
522 fact implemented as NFAs (non-deterministic finite automata) to allow
523 backtracking and backreferencing. And they aren't POSIX-style either,
524 because those guarantee worst-case behavior for all cases. (It seems
525 that some people prefer guarantees of consistency, even when what's
526 guaranteed is slowness.) See the book "Mastering Regular Expressions"
527 (from O'Reilly) by Jeffrey Friedl for all the details you could ever
528 hope to know on these matters (a full citation appears in
531 =head2 What's wrong with using grep or map in a void context?
533 Both grep and map build a return list, regardless of their context.
534 This means you're making Perl go to the trouble of building up a
535 return list that you then just ignore. That's no way to treat a
536 programming language, you insensitive scoundrel!
538 =head2 How can I match strings with multibyte characters?
540 This is hard, and there's no good way. Perl does not directly support
541 wide characters. It pretends that a byte and a character are
542 synonymous. The following set of approaches was offered by Jeffrey
543 Friedl, whose article in issue #5 of The Perl Journal talks about this
546 Let's suppose you have some weird Martian encoding where pairs of
547 ASCII uppercase letters encode single Martian letters (i.e. the two
548 bytes "CV" make a single Martian letter, as do the two bytes "SG",
549 "VS", "XX", etc.). Other bytes represent single characters, just like
552 So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the
553 nine characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.
555 Now, say you want to search for the single character C</GX/>. Perl
556 doesn't know about Martian, so it'll find the two bytes "GX" in the "I
557 am CVSGXX!" string, even though that character isn't there: it just
558 looks like it is because "SG" is next to "XX", but there's no real
559 "GX". This is a big problem.
561 Here are a few ways, all painful, to deal with it:
563 $martian =~ s/([A-Z][A-Z])/ $1 /g; # Make sure adjacent ``martian'' bytes
564 # are no longer adjacent.
565 print "found GX!\n" if $martian =~ /GX/;
569 @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
570 # above is conceptually similar to: @chars = $text =~ m/(.)/g;
572 foreach $char (@chars) {
573 print "found GX!\n", last if $char eq 'GX';
578 while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded
579 print "found GX!\n", last if $1 eq 'GX';
584 die "sorry, Perl doesn't (yet) have Martian support )-:\n";
586 There are many double- (and multi-) byte encodings commonly used these
587 days. Some versions of these have 1-, 2-, 3-, and 4-byte characters,
590 =head2 How do I match a pattern that is supplied by the user?
592 Well, if it's really a pattern, then just use
594 chomp($pattern = <STDIN>);
595 if ($line =~ /$pattern/) { }
597 Or, since you have no guarantee that your user entered
598 a valid regular expression, trap the exception this way:
600 if (eval { $line =~ /$pattern/ }) { }
602 But if all you really want to search for a string, not a pattern,
603 then you should either use the index() function, which is made for
604 string searching, or if you can't be disabused of using a pattern
605 match on a non-pattern, then be sure to use C<\Q>...C<\E>, documented
610 open (FILE, $input) or die "Couldn't open input $input: $!; aborting";
612 print if /\Q$pattern\E/;
616 =head1 AUTHOR AND COPYRIGHT
618 Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington.
621 When included as part of the Standard Version of Perl, or as part of
622 its complete documentation whether printed or otherwise, this work
623 may be distributed only under the terms of Perl's Artistic License.
624 Any distribution of this file or derivatives thereof I<outside>
625 of that package require that special arrangements be made with
628 Irrespective of its distribution, all code examples in this file
629 are hereby placed into the public domain. You are permitted and
630 encouraged to use this code in your own programs for fun
631 or for profit as you see fit. A simple comment in the code giving
632 credit would be courteous but is not required.