3 perlfaq6 - Regular Expressions ($Revision: 1.27 $, $Date: 2004/11/03 22:52:16 $)
7 This section is surprisingly small because the rest of the FAQ is
8 littered with answers involving regular expressions. For example,
9 decoding a URL and checking whether something is a number are handled
10 with regular expressions, but those answers are found elsewhere in
11 this document (in L<perlfaq9>: ``How do I decode or create those %-encodings
12 on the web'' and L<perlfaq4>: ``How do I determine whether a scalar is
13 a number/whole/integer/float'', to be precise).
15 =head2 How can I hope to use regular expressions without creating illegible and unmaintainable code?
17 Three techniques can make regular expressions maintainable and
22 =item Comments Outside the Regex
24 Describe what you're doing and how you're doing it, using normal Perl
27 # turn the line into the first word, a colon, and the
28 # number of characters on the rest of the line
29 s/^(\w+)(.*)/ lc($1) . ":" . length($2) /meg;
31 =item Comments Inside the Regex
33 The C</x> modifier causes whitespace to be ignored in a regex pattern
34 (except in a character class), and also allows you to use normal
35 comments there, too. As you can imagine, whitespace and comments help
38 C</x> lets you turn this:
40 s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;
44 s{ < # opening angle bracket
45 (?: # Non-backreffing grouping paren
46 [^>'"] * # 0 or more things that are neither > nor ' nor "
48 ".*?" # a section between double quotes (stingy match)
50 '.*?' # a section between single quotes (stingy match)
51 ) + # all occurring one or more times
52 > # closing angle bracket
53 }{}gsx; # replace with nothing, i.e. delete
55 It's still not quite so clear as prose, but it is very useful for
56 describing the meaning of each part of the pattern.
58 =item Different Delimiters
60 While we normally think of patterns as being delimited with C</>
61 characters, they can be delimited by almost any character. L<perlre>
62 describes this. For example, the C<s///> above uses braces as
63 delimiters. Selecting another delimiter can avoid quoting the
64 delimiter within the pattern:
66 s/\/usr\/local/\/usr\/share/g; # bad delimiter choice
67 s#/usr/local#/usr/share#g; # better
71 =head2 I'm having trouble matching over more than one line. What's wrong?
73 Either you don't have more than one line in the string you're looking
74 at (probably), or else you aren't using the correct modifier(s) on
75 your pattern (possibly).
77 There are many ways to get multiline data into a string. If you want
78 it to happen automatically while reading input, you'll want to set $/
79 (probably to '' for paragraphs or C<undef> for the whole file) to
80 allow you to read more than one line at a time.
82 Read L<perlre> to help you decide which of C</s> and C</m> (or both)
83 you might want to use: C</s> allows dot to include newline, and C</m>
84 allows caret and dollar to match next to a newline, not just at the
85 end of the string. You do need to make sure that you've actually
86 got a multiline string in there.
88 For example, this program detects duplicate words, even when they span
89 line breaks (but not paragraph ones). For this example, we don't need
90 C</s> because we aren't using dot in a regular expression that we want
91 to cross line boundaries. Neither do we need C</m> because we aren't
92 wanting caret or dollar to match at any point inside the record next
93 to newlines. But it's imperative that $/ be set to something other
94 than the default, or else we won't actually ever have a multiline
97 $/ = ''; # read in more whole paragraph, not just one line
99 while ( /\b([\w'-]+)(\s+\1)+\b/gi ) { # word starts alpha
100 print "Duplicate $1 at paragraph $.\n";
104 Here's code that finds sentences that begin with "From " (which would
105 be mangled by many mailers):
107 $/ = ''; # read in more whole paragraph, not just one line
109 while ( /^From /gm ) { # /m makes ^ match next to \n
110 print "leading from in paragraph $.\n";
114 Here's code that finds everything between START and END in a paragraph:
116 undef $/; # read in whole file, not just one line or paragraph
118 while ( /START(.*?)END/sgm ) { # /s makes . cross line boundaries
123 =head2 How can I pull out lines between two patterns that are themselves on different lines?
125 You can use Perl's somewhat exotic C<..> operator (documented in
128 perl -ne 'print if /START/ .. /END/' file1 file2 ...
130 If you wanted text and not lines, you would use
132 perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...
134 But if you want nested occurrences of C<START> through C<END>, you'll
135 run up against the problem described in the question in this section
136 on matching balanced text.
138 Here's another example of using C<..>:
141 $in_header = 1 .. /^$/;
142 $in_body = /^$/ .. eof();
143 # now choose between them
145 reset if eof(); # fix $.
148 =head2 I put a regular expression into $/ but it didn't work. What's wrong?
150 Up to Perl 5.8.0, $/ has to be a string. This may change in 5.10,
151 but don't get your hopes up. Until then, you can use these examples
152 if you really need to do this.
154 If you have File::Stream, this is easy.
157 my $stream = File::Stream->new(
159 separator => qr/\s*,\s*/,
162 print "$_\n" while <$stream>;
164 If you don't have File::Stream, you have to do a little more work.
166 You can use the four argument form of sysread to continually add to
167 a buffer. After you add to the buffer, you check if you have a
168 complete line (using your regular expression).
171 while( sysread FH, $_, 8192, length ) {
172 while( s/^((?s).*?)your_pattern/ ) {
178 You can do the same thing with foreach and a match using the
179 c flag and the \G anchor, if you do not mind your entire file
180 being in memory at the end.
183 while( sysread FH, $_, 8192, length ) {
184 foreach my $record ( m/\G((?s).*?)your_pattern/gc ) {
187 substr( $_, 0, pos ) = "" if pos;
191 =head2 How do I substitute case insensitively on the LHS while preserving case on the RHS?
193 Here's a lovely Perlish solution by Larry Rosler. It exploits
194 properties of bitwise xor on ASCII strings.
196 $_= "this is a TEsT case";
202 { uc $new | (uc $1 ^ $1) .
203 (uc(substr $1, -1) ^ substr $1, -1) x
204 (length($new) - length $1)
209 And here it is as a subroutine, modeled after the above:
211 sub preserve_case($$) {
212 my ($old, $new) = @_;
213 my $mask = uc $old ^ $old;
216 substr($mask, -1) x (length($new) - length($old))
219 $a = "this is a TEsT case";
220 $a =~ s/(test)/preserve_case($1, "success")/egi;
225 this is a SUcCESS case
227 As an alternative, to keep the case of the replacement word if it is
228 longer than the original, you can use this code, by Jeff Pinyan:
231 my ($from, $to) = @_;
232 my ($lf, $lt) = map length, @_;
234 if ($lt < $lf) { $from = substr $from, 0, $lt }
235 else { $from .= substr $to, $lf }
237 return uc $to | ($from ^ uc $from);
240 This changes the sentence to "this is a SUcCess case."
242 Just to show that C programmers can write C in any programming language,
243 if you prefer a more C-like solution, the following script makes the
244 substitution have the same case, letter by letter, as the original.
245 (It also happens to run about 240% slower than the Perlish solution runs.)
246 If the substitution has more characters than the string being substituted,
247 the case of the last character is used for the rest of the substitution.
249 # Original by Nathan Torkington, massaged by Jeffrey Friedl
251 sub preserve_case($$)
253 my ($old, $new) = @_;
254 my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
255 my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
256 my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
258 for ($i = 0; $i < $len; $i++) {
259 if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
261 } elsif (lc $c eq $c) {
262 substr($new, $i, 1) = lc(substr($new, $i, 1));
265 substr($new, $i, 1) = uc(substr($new, $i, 1));
269 # finish up with any remaining new (for when new is longer than old)
270 if ($newlen > $oldlen) {
272 substr($new, $oldlen) = lc(substr($new, $oldlen));
273 } elsif ($state == 2) {
274 substr($new, $oldlen) = uc(substr($new, $oldlen));
280 =head2 How can I make C<\w> match national character sets?
282 Put C<use locale;> in your script. The \w character class is taken
283 from the current locale.
285 See L<perllocale> for details.
287 =head2 How can I match a locale-smart version of C</[a-zA-Z]/>?
289 You can use the POSIX character class syntax C</[[:alpha:]]/>
290 documented in L<perlre>.
292 No matter which locale you are in, the alphabetic characters are
293 the characters in \w without the digits and the underscore.
294 As a regex, that looks like C</[^\W\d_]/>. Its complement,
295 the non-alphabetics, is then everything in \W along with
296 the digits and the underscore, or C</[\W\d_]/>.
298 =head2 How can I quote a variable to use in a regex?
300 The Perl parser will expand $variable and @variable references in
301 regular expressions unless the delimiter is a single quote. Remember,
302 too, that the right-hand side of a C<s///> substitution is considered
303 a double-quoted string (see L<perlop> for more details). Remember
304 also that any regex special characters will be acted on unless you
305 precede the substitution with \Q. Here's an example:
307 $string = "Placido P. Octopus";
310 $string =~ s/$regex/Polyp/;
311 # $string is now "Polypacido P. Octopus"
313 Because C<.> is special in regular expressions, and can match any
314 single character, the regex C<P.> here has matched the <Pl> in the
317 To escape the special meaning of C<.>, we use C<\Q>:
319 $string = "Placido P. Octopus";
322 $string =~ s/\Q$regex/Polyp/;
323 # $string is now "Placido Polyp Octopus"
325 The use of C<\Q> causes the <.> in the regex to be treated as a
326 regular character, so that C<P.> matches a C<P> followed by a dot.
328 =head2 What is C</o> really for?
330 Using a variable in a regular expression match forces a re-evaluation
331 (and perhaps recompilation) each time the regular expression is
332 encountered. The C</o> modifier locks in the regex the first time
333 it's used. This always happens in a constant regular expression, and
334 in fact, the pattern was compiled into the internal format at the same
335 time your entire program was.
337 Use of C</o> is irrelevant unless variable interpolation is used in
338 the pattern, and if so, the regex engine will neither know nor care
339 whether the variables change after the pattern is evaluated the I<very
342 C</o> is often used to gain an extra measure of efficiency by not
343 performing subsequent evaluations when you know it won't matter
344 (because you know the variables won't change), or more rarely, when
345 you don't want the regex to notice if they do.
347 For example, here's a "paragrep" program:
349 $/ = ''; # paragraph mode
355 =head2 How do I use a regular expression to strip C style comments from a file?
357 While this actually can be done, it's much harder than you'd think.
358 For example, this one-liner
360 perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c
362 will work in many but not all cases. You see, it's too simple-minded for
363 certain kinds of C programs, in particular, those with what appear to be
364 comments in quoted strings. For that, you'd need something like this,
365 created by Jeffrey Friedl and later modified by Fred Curtis.
369 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;
372 This could, of course, be more legibly written with the C</x> modifier, adding
373 whitespace and comments. Here it is expanded, courtesy of Fred Curtis.
376 /\* ## Start of /* ... */ comment
377 [^*]*\*+ ## Non-* followed by 1-or-more *'s
380 )* ## 0-or-more things which don't start with /
381 ## but do end with '*'
382 / ## End of /* ... */ comment
384 | ## OR various things which aren't comments:
387 " ## Start of " ... " string
393 " ## End of " ... " string
397 ' ## Start of ' ... ' string
403 ' ## End of ' ... ' string
407 . ## Anything other char
408 [^/"'\\]* ## Chars which doesn't start a comment, string or escape
410 }{defined $2 ? $2 : ""}gxse;
412 A slight modification also removes C++ comments:
414 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|//[^\n]*|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#defined $2 ? $2 : ""#gse;
416 =head2 Can I use Perl regular expressions to match balanced text?
418 Historically, Perl regular expressions were not capable of matching
419 balanced text. As of more recent versions of perl including 5.6.1
420 experimental features have been added that make it possible to do this.
421 Look at the documentation for the (??{ }) construct in recent perlre manual
422 pages to see an example of matching balanced parentheses. Be sure to take
423 special notice of the warnings present in the manual before making use
426 CPAN contains many modules that can be useful for matching text
427 depending on the context. Damian Conway provides some useful
428 patterns in Regexp::Common. The module Text::Balanced provides a
429 general solution to this problem.
431 One of the common applications of balanced text matching is working
432 with XML and HTML. There are many modules available that support
433 these needs. Two examples are HTML::Parser and XML::Parser. There
436 An elaborate subroutine (for 7-bit ASCII only) to pull out balanced
437 and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>,
438 or C<(> and C<)> can be found in
439 http://www.cpan.org/authors/id/TOMC/scripts/pull_quotes.gz .
441 The C::Scan module from CPAN also contains such subs for internal use,
442 but they are undocumented.
444 =head2 What does it mean that regexes are greedy? How can I get around it?
446 Most people mean that greedy regexes match as much as they can.
447 Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>,
448 C<{}>) that are greedy rather than the whole pattern; Perl prefers local
449 greed and immediate gratification to overall greed. To get non-greedy
450 versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>).
454 $s1 = $s2 = "I am very very cold";
455 $s1 =~ s/ve.*y //; # I am cold
456 $s2 =~ s/ve.*?y //; # I am very cold
458 Notice how the second substitution stopped matching as soon as it
459 encountered "y ". The C<*?> quantifier effectively tells the regular
460 expression engine to find a match as quickly as possible and pass
461 control on to whatever is next in line, like you would if you were
464 =head2 How do I process each word on each line?
466 Use the split function:
469 foreach $word ( split ) {
470 # do something with $word here
474 Note that this isn't really a word in the English sense; it's just
475 chunks of consecutive non-whitespace characters.
477 To work with only alphanumeric sequences (including underscores), you
481 foreach $word (m/(\w+)/g) {
482 # do something with $word here
486 =head2 How can I print out a word-frequency or line-frequency summary?
488 To do this, you have to parse out each word in the input stream. We'll
489 pretend that by word you mean chunk of alphabetics, hyphens, or
490 apostrophes, rather than the non-whitespace chunk idea of a word given
491 in the previous question:
494 while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'"
498 while ( ($word, $count) = each %seen ) {
499 print "$count $word\n";
502 If you wanted to do the same thing for lines, you wouldn't need a
508 while ( ($line, $count) = each %seen ) {
509 print "$count $line";
512 If you want these output in a sorted order, see L<perlfaq4>: ``How do I
513 sort a hash (optionally by value instead of key)?''.
515 =head2 How can I do approximate matching?
517 See the module String::Approx available from CPAN.
519 =head2 How do I efficiently match many regular expressions at once?
521 The following is extremely inefficient:
523 # slow but obvious way
524 @popstates = qw(CO ON MI WI MN);
525 while (defined($line = <>)) {
526 for $state (@popstates) {
527 if ($line =~ /\b$state\b/i) {
534 That's because Perl has to recompile all those patterns for each of
535 the lines of the file. As of the 5.005 release, there's a much better
536 approach, one which makes use of the new C<qr//> operator:
538 # use spiffy new qr// operator, with /i flag even
540 @popstates = qw(CO ON MI WI MN);
541 @poppats = map { qr/\b$_\b/i } @popstates;
542 while (defined($line = <>)) {
543 for $patobj (@poppats) {
544 print $line if $line =~ /$patobj/;
548 =head2 Why don't word-boundary searches with C<\b> work for me?
550 Two common misconceptions are that C<\b> is a synonym for C<\s+> and
551 that it's the edge between whitespace characters and non-whitespace
552 characters. Neither is correct. C<\b> is the place between a C<\w>
553 character and a C<\W> character (that is, C<\b> is the edge of a
554 "word"). It's a zero-width assertion, just like C<^>, C<$>, and all
555 the other anchors, so it doesn't consume any characters. L<perlre>
556 describes the behavior of all the regex metacharacters.
558 Here are examples of the incorrect application of C<\b>, with fixes:
560 "two words" =~ /(\w+)\b(\w+)/; # WRONG
561 "two words" =~ /(\w+)\s+(\w+)/; # right
563 " =matchless= text" =~ /\b=(\w+)=\b/; # WRONG
564 " =matchless= text" =~ /=(\w+)=/; # right
566 Although they may not do what you thought they did, C<\b> and C<\B>
567 can still be quite useful. For an example of the correct use of
568 C<\b>, see the example of matching duplicate words over multiple
571 An example of using C<\B> is the pattern C<\Bis\B>. This will find
572 occurrences of "is" on the insides of words only, as in "thistle", but
573 not "this" or "island".
575 =head2 Why does using $&, $`, or $' slow my program down?
577 Once Perl sees that you need one of these variables anywhere in
578 the program, it provides them on each and every pattern match.
579 The same mechanism that handles these provides for the use of $1, $2,
580 etc., so you pay the same price for each regex that contains capturing
581 parentheses. If you never use $&, etc., in your script, then regexes
582 I<without> capturing parentheses won't be penalized. So avoid $&, $',
583 and $` if you can, but if you can't, once you've used them at all, use
584 them at will because you've already paid the price. Remember that some
585 algorithms really appreciate them. As of the 5.005 release. the $&
586 variable is no longer "expensive" the way the other two are.
588 =head2 What good is C<\G> in a regular expression?
590 You use the C<\G> anchor to start the next match on the same
591 string where the last match left off. The regular
592 expression engine cannot skip over any characters to find
593 the next match with this anchor, so C<\G> is similar to the
594 beginning of string anchor, C<^>. The C<\G> anchor is typically
595 used with the C<g> flag. It uses the value of pos()
596 as the position to start the next match. As the match
597 operator makes successive matches, it updates pos() with the
598 position of the next character past the last match (or the
599 first character of the next match, depending on how you like
600 to look at it). Each string has its own pos() value.
602 Suppose you want to match all of consective pairs of digits
603 in a string like "1122a44" and stop matching when you
604 encounter non-digits. You want to match C<11> and C<22> but
605 the letter <a> shows up between C<22> and C<44> and you want
606 to stop at C<a>. Simply matching pairs of digits skips over
607 the C<a> and still matches C<44>.
610 my @pairs = m/(\d\d)/g; # qw( 11 22 44 )
612 If you use the \G anchor, you force the match after C<22> to
613 start with the C<a>. The regular expression cannot match
614 there since it does not find a digit, so the next match
615 fails and the match operator returns the pairs it already
619 my @pairs = m/\G(\d\d)/g; # qw( 11 22 )
621 You can also use the C<\G> anchor in scalar context. You
622 still need the C<g> flag.
625 while( m/\G(\d\d)/g )
630 After the match fails at the letter C<a>, perl resets pos()
631 and the next match on the same string starts at the beginning.
634 while( m/\G(\d\d)/g )
639 print "Found $1 after while" if m/(\d\d)/g; # finds "11"
641 You can disable pos() resets on fail with the C<c> flag.
642 Subsequent matches start where the last successful match
643 ended (the value of pos()) even if a match on the same
644 string as failed in the meantime. In this case, the match
645 after the while() loop starts at the C<a> (where the last
646 match stopped), and since it does not use any anchor it can
647 skip over the C<a> to find "44".
650 while( m/\G(\d\d)/gc )
655 print "Found $1 after while" if m/(\d\d)/g; # finds "44"
657 Typically you use the C<\G> anchor with the C<c> flag
658 when you want to try a different match if one fails,
659 such as in a tokenizer. Jeffrey Friedl offers this example
660 which works in 5.004 or later.
665 m/ \G( \d+\b )/gcx && do { print "number: $1\n"; redo; };
666 m/ \G( \w+ )/gcx && do { print "word: $1\n"; redo; };
667 m/ \G( \s+ )/gcx && do { print "space: $1\n"; redo; };
668 m/ \G( [^\w\d]+ )/gcx && do { print "other: $1\n"; redo; };
672 For each line, the PARSER loop first tries to match a series
673 of digits followed by a word boundary. This match has to
674 start at the place the last match left off (or the beginning
675 of the string on the first match). Since C<m/ \G( \d+\b
676 )/gcx> uses the C<c> flag, if the string does not match that
677 regular expression, perl does not reset pos() and the next
678 match starts at the same position to try a different
681 =head2 Are Perl regexes DFAs or NFAs? Are they POSIX compliant?
683 While it's true that Perl's regular expressions resemble the DFAs
684 (deterministic finite automata) of the egrep(1) program, they are in
685 fact implemented as NFAs (non-deterministic finite automata) to allow
686 backtracking and backreferencing. And they aren't POSIX-style either,
687 because those guarantee worst-case behavior for all cases. (It seems
688 that some people prefer guarantees of consistency, even when what's
689 guaranteed is slowness.) See the book "Mastering Regular Expressions"
690 (from O'Reilly) by Jeffrey Friedl for all the details you could ever
691 hope to know on these matters (a full citation appears in
694 =head2 What's wrong with using grep in a void context?
696 The problem is that grep builds a return list, regardless of the context.
697 This means you're making Perl go to the trouble of building a list that
698 you then just throw away. If the list is large, you waste both time and space.
699 If your intent is to iterate over the list, then use a for loop for this
702 In perls older than 5.8.1, map suffers from this problem as well.
703 But since 5.8.1, this has been fixed, and map is context aware - in void
704 context, no lists are constructed.
706 =head2 How can I match strings with multibyte characters?
708 Starting from Perl 5.6 Perl has had some level of multibyte character
709 support. Perl 5.8 or later is recommended. Supported multibyte
710 character repertoires include Unicode, and legacy encodings
711 through the Encode module. See L<perluniintro>, L<perlunicode>,
714 If you are stuck with older Perls, you can do Unicode with the
715 C<Unicode::String> module, and character conversions using the
716 C<Unicode::Map8> and C<Unicode::Map> modules. If you are using
717 Japanese encodings, you might try using the jperl 5.005_03.
719 Finally, the following set of approaches was offered by Jeffrey
720 Friedl, whose article in issue #5 of The Perl Journal talks about
723 Let's suppose you have some weird Martian encoding where pairs of
724 ASCII uppercase letters encode single Martian letters (i.e. the two
725 bytes "CV" make a single Martian letter, as do the two bytes "SG",
726 "VS", "XX", etc.). Other bytes represent single characters, just like
729 So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the
730 nine characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.
732 Now, say you want to search for the single character C</GX/>. Perl
733 doesn't know about Martian, so it'll find the two bytes "GX" in the "I
734 am CVSGXX!" string, even though that character isn't there: it just
735 looks like it is because "SG" is next to "XX", but there's no real
736 "GX". This is a big problem.
738 Here are a few ways, all painful, to deal with it:
740 $martian =~ s/([A-Z][A-Z])/ $1 /g; # Make sure adjacent ``martian''
741 # bytes are no longer adjacent.
742 print "found GX!\n" if $martian =~ /GX/;
746 @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
747 # above is conceptually similar to: @chars = $text =~ m/(.)/g;
749 foreach $char (@chars) {
750 print "found GX!\n", last if $char eq 'GX';
755 while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded
756 print "found GX!\n", last if $1 eq 'GX';
759 Here's another, slightly less painful, way to do it from Benjamin
760 Goldberg, who uses a zero-width negative look-behind assertion.
762 print "found GX!\n" if $martian =~ m/
768 This succeeds if the "martian" character GX is in the string, and fails
769 otherwise. If you don't like using (?<!), a zero-width negative
770 look-behind assertion, you can replace (?<![A-Z]) with (?:^|[^A-Z]).
772 It does have the drawback of putting the wrong thing in $-[0] and $+[0],
773 but this usually can be worked around.
775 =head2 How do I match a pattern that is supplied by the user?
777 Well, if it's really a pattern, then just use
779 chomp($pattern = <STDIN>);
780 if ($line =~ /$pattern/) { }
782 Alternatively, since you have no guarantee that your user entered
783 a valid regular expression, trap the exception this way:
785 if (eval { $line =~ /$pattern/ }) { }
787 If all you really want to search for a string, not a pattern,
788 then you should either use the index() function, which is made for
789 string searching, or if you can't be disabused of using a pattern
790 match on a non-pattern, then be sure to use C<\Q>...C<\E>, documented
795 open (FILE, $input) or die "Couldn't open input $input: $!; aborting";
797 print if /\Q$pattern\E/;
801 =head1 AUTHOR AND COPYRIGHT
803 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
806 This documentation is free; you can redistribute it and/or modify it
807 under the same terms as Perl itself.
809 Irrespective of its distribution, all code examples in this file
810 are hereby placed into the public domain. You are permitted and
811 encouraged to use this code in your own programs for fun
812 or for profit as you see fit. A simple comment in the code giving
813 credit would be courteous but is not required.