3 perlfaq6 - Regexes ($Revision: 1.27 $, $Date: 1999/05/23 16:08:30 $)
7 This section is surprisingly small because the rest of the FAQ is
8 littered with answers involving regular expressions. For example,
9 decoding a URL and checking whether something is a number are handled
10 with regular expressions, but those answers are found elsewhere in
11 this document (in the section on Data and the Networking one on
12 networking, to be precise).
14 =head2 How can I hope to use regular expressions without creating illegible and unmaintainable code?
16 Three techniques can make regular expressions maintainable and
21 =item Comments Outside the Regex
23 Describe what you're doing and how you're doing it, using normal Perl
26 # turn the line into the first word, a colon, and the
27 # number of characters on the rest of the line
28 s/^(\w+)(.*)/ lc($1) . ":" . length($2) /meg;
30 =item Comments Inside the Regex
32 The C</x> modifier causes whitespace to be ignored in a regex pattern
33 (except in a character class), and also allows you to use normal
34 comments there, too. As you can imagine, whitespace and comments help
37 C</x> lets you turn this:
39 s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;
43 s{ < # opening angle bracket
44 (?: # Non-backreffing grouping paren
45 [^>'"] * # 0 or more things that are neither > nor ' nor "
47 ".*?" # a section between double quotes (stingy match)
49 '.*?' # a section between single quotes (stingy match)
50 ) + # all occurring one or more times
51 > # closing angle bracket
52 }{}gsx; # replace with nothing, i.e. delete
54 It's still not quite so clear as prose, but it is very useful for
55 describing the meaning of each part of the pattern.
57 =item Different Delimiters
59 While we normally think of patterns as being delimited with C</>
60 characters, they can be delimited by almost any character. L<perlre>
61 describes this. For example, the C<s///> above uses braces as
62 delimiters. Selecting another delimiter can avoid quoting the
63 delimiter within the pattern:
65 s/\/usr\/local/\/usr\/share/g; # bad delimiter choice
66 s#/usr/local#/usr/share#g; # better
70 =head2 I'm having trouble matching over more than one line. What's wrong?
72 Either you don't have more than one line in the string you're looking at
73 (probably), or else you aren't using the correct modifier(s) on your
76 There are many ways to get multiline data into a string. If you want
77 it to happen automatically while reading input, you'll want to set $/
78 (probably to '' for paragraphs or C<undef> for the whole file) to
79 allow you to read more than one line at a time.
81 Read L<perlre> to help you decide which of C</s> and C</m> (or both)
82 you might want to use: C</s> allows dot to include newline, and C</m>
83 allows caret and dollar to match next to a newline, not just at the
84 end of the string. You do need to make sure that you've actually
85 got a multiline string in there.
87 For example, this program detects duplicate words, even when they span
88 line breaks (but not paragraph ones). For this example, we don't need
89 C</s> because we aren't using dot in a regular expression that we want
90 to cross line boundaries. Neither do we need C</m> because we aren't
91 wanting caret or dollar to match at any point inside the record next
92 to newlines. But it's imperative that $/ be set to something other
93 than the default, or else we won't actually ever have a multiline
96 $/ = ''; # read in more whole paragraph, not just one line
98 while ( /\b([\w'-]+)(\s+\1)+\b/gi ) { # word starts alpha
99 print "Duplicate $1 at paragraph $.\n";
103 Here's code that finds sentences that begin with "From " (which would
104 be mangled by many mailers):
106 $/ = ''; # read in more whole paragraph, not just one line
108 while ( /^From /gm ) { # /m makes ^ match next to \n
109 print "leading from in paragraph $.\n";
113 Here's code that finds everything between START and END in a paragraph:
115 undef $/; # read in whole file, not just one line or paragraph
117 while ( /START(.*?)END/sm ) { # /s makes . cross line boundaries
122 =head2 How can I pull out lines between two patterns that are themselves on different lines?
124 You can use Perl's somewhat exotic C<..> operator (documented in
127 perl -ne 'print if /START/ .. /END/' file1 file2 ...
129 If you wanted text and not lines, you would use
131 perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...
133 But if you want nested occurrences of C<START> through C<END>, you'll
134 run up against the problem described in the question in this section
135 on matching balanced text.
137 Here's another example of using C<..>:
140 $in_header = 1 .. /^$/;
141 $in_body = /^$/ .. eof();
142 # now choose between them
144 reset if eof(); # fix $.
147 =head2 I put a regular expression into $/ but it didn't work. What's wrong?
149 $/ must be a string, not a regular expression. Awk has to be better
152 Actually, you could do this if you don't mind reading the whole file
156 @records = split /your_pattern/, <FH>;
158 The Net::Telnet module (available from CPAN) has the capability to
159 wait for a pattern in the input stream, or timeout if it doesn't
160 appear within a certain time.
162 ## Create a file with three lines.
164 print FH "The first line\nThe second line\nThe third line\n";
167 ## Get a read/write filehandle to it.
168 $fh = new FileHandle "+<file";
170 ## Attach it to a "stream" object.
172 $file = new Net::Telnet (-fhopen => $fh);
174 ## Search for the second line and print out the third.
175 $file->waitfor('/second line\n/');
176 print $file->getline;
178 =head2 How do I substitute case insensitively on the LHS, but preserving case on the RHS?
180 Here's a lovely Perlish solution by Larry Rosler. It exploits
181 properties of bitwise xor on ASCII strings.
183 $_= "this is a TEsT case";
189 { uc $new | (uc $1 ^ $1) .
190 (uc(substr $1, -1) ^ substr $1, -1) x
191 (length($new) - length $1)
196 And here it is as a subroutine, modelled after the above:
198 sub preserve_case($$) {
199 my ($old, $new) = @_;
200 my $mask = uc $old ^ $old;
203 substr($mask, -1) x (length($new) - length($old))
206 $a = "this is a TEsT case";
207 $a =~ s/(test)/preserve_case($1, "success")/egi;
212 this is a SUcCESS case
214 Just to show that C programmers can write C in any programming language,
215 if you prefer a more C-like solution, the following script makes the
216 substitution have the same case, letter by letter, as the original.
217 (It also happens to run about 240% slower than the Perlish solution runs.)
218 If the substitution has more characters than the string being substituted,
219 the case of the last character is used for the rest of the substitution.
221 # Original by Nathan Torkington, massaged by Jeffrey Friedl
223 sub preserve_case($$)
225 my ($old, $new) = @_;
226 my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
227 my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
228 my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
230 for ($i = 0; $i < $len; $i++) {
231 if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
233 } elsif (lc $c eq $c) {
234 substr($new, $i, 1) = lc(substr($new, $i, 1));
237 substr($new, $i, 1) = uc(substr($new, $i, 1));
241 # finish up with any remaining new (for when new is longer than old)
242 if ($newlen > $oldlen) {
244 substr($new, $oldlen) = lc(substr($new, $oldlen));
245 } elsif ($state == 2) {
246 substr($new, $oldlen) = uc(substr($new, $oldlen));
252 =head2 How can I make C<\w> match national character sets?
256 =head2 How can I match a locale-smart version of C</[a-zA-Z]/>?
258 One alphabetic character would be C</[^\W\d_]/>, no matter what locale
259 you're in. Non-alphabetics would be C</[\W\d_]/> (assuming you don't
260 consider an underscore a letter).
262 =head2 How can I quote a variable to use in a regex?
264 The Perl parser will expand $variable and @variable references in
265 regular expressions unless the delimiter is a single quote. Remember,
266 too, that the right-hand side of a C<s///> substitution is considered
267 a double-quoted string (see L<perlop> for more details). Remember
268 also that any regex special characters will be acted on unless you
269 precede the substitution with \Q. Here's an example:
273 $rhs = "sleep, no more";
275 $string =~ s/\Q$lhs/$rhs/;
276 # $string is now "to sleep no more"
278 Without the \Q, the regex would also spuriously match "di".
280 =head2 What is C</o> really for?
282 Using a variable in a regular expression match forces a re-evaluation
283 (and perhaps recompilation) each time through. The C</o> modifier
284 locks in the regex the first time it's used. This always happens in a
285 constant regular expression, and in fact, the pattern was compiled
286 into the internal format at the same time your entire program was.
288 Use of C</o> is irrelevant unless variable interpolation is used in
289 the pattern, and if so, the regex engine will neither know nor care
290 whether the variables change after the pattern is evaluated the I<very
293 C</o> is often used to gain an extra measure of efficiency by not
294 performing subsequent evaluations when you know it won't matter
295 (because you know the variables won't change), or more rarely, when
296 you don't want the regex to notice if they do.
298 For example, here's a "paragrep" program:
300 $/ = ''; # paragraph mode
306 =head2 How do I use a regular expression to strip C style comments from a file?
308 While this actually can be done, it's much harder than you'd think.
309 For example, this one-liner
311 perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c
313 will work in many but not all cases. You see, it's too simple-minded for
314 certain kinds of C programs, in particular, those with what appear to be
315 comments in quoted strings. For that, you'd need something like this,
316 created by Jeffrey Friedl and later modified by Fred Curtis.
320 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs
323 This could, of course, be more legibly written with the C</x> modifier, adding
324 whitespace and comments. Here it is expanded, courtesy of Fred Curtis.
327 /\* ## Start of /* ... */ comment
328 [^*]*\*+ ## Non-* followed by 1-or-more *'s
331 )* ## 0-or-more things which don't start with /
332 ## but do end with '*'
333 / ## End of /* ... */ comment
335 | ## OR various things which aren't comments:
338 " ## Start of " ... " string
344 " ## End of " ... " string
348 ' ## Start of ' ... ' string
354 ' ## End of ' ... ' string
358 . ## Anything other char
359 [^/"'\\]* ## Chars which doesn't start a comment, string or escape
363 A slight modification also removes C++ comments:
365 s#/\*[^*]*\*+([^/*][^*]*\*+)*/|//[^\n]*|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs;
367 =head2 Can I use Perl regular expressions to match balanced text?
369 Although Perl regular expressions are more powerful than "mathematical"
370 regular expressions, because they feature conveniences like backreferences
371 (C<\1> and its ilk), they still aren't powerful enough -- with
372 the possible exception of bizarre and experimental features in the
373 development-track releases of Perl. You still need to use non-regex
374 techniques to parse balanced text, such as the text enclosed between
375 matching parentheses or braces, for example.
377 An elaborate subroutine (for 7-bit ASCII only) to pull out balanced
378 and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>,
379 or C<(> and C<)> can be found in
380 http://www.perl.com/CPAN/authors/id/TOMC/scripts/pull_quotes.gz .
382 The C::Scan module from CPAN contains such subs for internal usage,
383 but they are undocumented.
385 =head2 What does it mean that regexes are greedy? How can I get around it?
387 Most people mean that greedy regexes match as much as they can.
388 Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>,
389 C<{}>) that are greedy rather than the whole pattern; Perl prefers local
390 greed and immediate gratification to overall greed. To get non-greedy
391 versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>).
395 $s1 = $s2 = "I am very very cold";
396 $s1 =~ s/ve.*y //; # I am cold
397 $s2 =~ s/ve.*?y //; # I am very cold
399 Notice how the second substitution stopped matching as soon as it
400 encountered "y ". The C<*?> quantifier effectively tells the regular
401 expression engine to find a match as quickly as possible and pass
402 control on to whatever is next in line, like you would if you were
405 =head2 How do I process each word on each line?
407 Use the split function:
410 foreach $word ( split ) {
411 # do something with $word here
415 Note that this isn't really a word in the English sense; it's just
416 chunks of consecutive non-whitespace characters.
418 To work with only alphanumeric sequences (including underscores), you
422 foreach $word (m/(\w+)/g) {
423 # do something with $word here
427 =head2 How can I print out a word-frequency or line-frequency summary?
429 To do this, you have to parse out each word in the input stream. We'll
430 pretend that by word you mean chunk of alphabetics, hyphens, or
431 apostrophes, rather than the non-whitespace chunk idea of a word given
432 in the previous question:
435 while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'"
439 while ( ($word, $count) = each %seen ) {
440 print "$count $word\n";
443 If you wanted to do the same thing for lines, you wouldn't need a
449 while ( ($line, $count) = each %seen ) {
450 print "$count $line";
453 If you want these output in a sorted order, see the section on Hashes.
455 =head2 How can I do approximate matching?
457 See the module String::Approx available from CPAN.
459 =head2 How do I efficiently match many regular expressions at once?
461 The following is extremely inefficient:
463 # slow but obvious way
464 @popstates = qw(CO ON MI WI MN);
465 while (defined($line = <>)) {
466 for $state (@popstates) {
467 if ($line =~ /\b$state\b/i) {
474 That's because Perl has to recompile all those patterns for each of
475 the lines of the file. As of the 5.005 release, there's a much better
476 approach, one which makes use of the new C<qr//> operator:
478 # use spiffy new qr// operator, with /i flag even
480 @popstates = qw(CO ON MI WI MN);
481 @poppats = map { qr/\b$_\b/i } @popstates;
482 while (defined($line = <>)) {
483 for $patobj (@poppats) {
484 print $line if $line =~ /$patobj/;
488 =head2 Why don't word-boundary searches with C<\b> work for me?
490 Two common misconceptions are that C<\b> is a synonym for C<\s+>, and
491 that it's the edge between whitespace characters and non-whitespace
492 characters. Neither is correct. C<\b> is the place between a C<\w>
493 character and a C<\W> character (that is, C<\b> is the edge of a
494 "word"). It's a zero-width assertion, just like C<^>, C<$>, and all
495 the other anchors, so it doesn't consume any characters. L<perlre>
496 describes the behavior of all the regex metacharacters.
498 Here are examples of the incorrect application of C<\b>, with fixes:
500 "two words" =~ /(\w+)\b(\w+)/; # WRONG
501 "two words" =~ /(\w+)\s+(\w+)/; # right
503 " =matchless= text" =~ /\b=(\w+)=\b/; # WRONG
504 " =matchless= text" =~ /=(\w+)=/; # right
506 Although they may not do what you thought they did, C<\b> and C<\B>
507 can still be quite useful. For an example of the correct use of
508 C<\b>, see the example of matching duplicate words over multiple
511 An example of using C<\B> is the pattern C<\Bis\B>. This will find
512 occurrences of "is" on the insides of words only, as in "thistle", but
513 not "this" or "island".
515 =head2 Why does using $&, $`, or $' slow my program down?
517 Because once Perl sees that you need one of these variables anywhere in
518 the program, it has to provide them on each and every pattern match.
519 The same mechanism that handles these provides for the use of $1, $2,
520 etc., so you pay the same price for each regex that contains capturing
521 parentheses. But if you never use $&, etc., in your script, then regexes
522 I<without> capturing parentheses won't be penalized. So avoid $&, $',
523 and $` if you can, but if you can't, once you've used them at all, use
524 them at will because you've already paid the price. Remember that some
525 algorithms really appreciate them. As of the 5.005 release. the $&
526 variable is no longer "expensive" the way the other two are.
528 =head2 What good is C<\G> in a regular expression?
530 The notation C<\G> is used in a match or substitution in conjunction the
531 C</g> modifier (and ignored if there's no C</g>) to anchor the regular
532 expression to the point just past where the last match occurred, i.e. the
533 pos() point. A failed match resets the position of C<\G> unless the
534 C</c> modifier is in effect.
536 For example, suppose you had a line of text quoted in standard mail
537 and Usenet notation, (that is, with leading C<< > >> characters), and
538 you want change each leading C<< > >> into a corresponding C<:>. You
539 could do so in this way:
541 s/^(>+)/':' x length($1)/gem;
543 Or, using C<\G>, the much simpler (and faster):
547 A more sophisticated use might involve a tokenizer. The following
548 lex-like example is courtesy of Jeffrey Friedl. It did not work in
549 5.003 due to bugs in that release, but does work in 5.004 or better.
550 (Note the use of C</c>, which prevents a failed match with C</g> from
551 resetting the search position back to the beginning of the string.)
556 m/ \G( \d+\b )/gcx && do { print "number: $1\n"; redo; };
557 m/ \G( \w+ )/gcx && do { print "word: $1\n"; redo; };
558 m/ \G( \s+ )/gcx && do { print "space: $1\n"; redo; };
559 m/ \G( [^\w\d]+ )/gcx && do { print "other: $1\n"; redo; };
563 Of course, that could have been written as
568 if ( /\G( \d+\b )/gcx {
569 print "number: $1\n";
572 if ( /\G( \w+ )/gcx {
576 if ( /\G( \s+ )/gcx {
580 if ( /\G( [^\w\d]+ )/gcx {
587 But then you lose the vertical alignment of the regular expressions.
589 =head2 Are Perl regexes DFAs or NFAs? Are they POSIX compliant?
591 While it's true that Perl's regular expressions resemble the DFAs
592 (deterministic finite automata) of the egrep(1) program, they are in
593 fact implemented as NFAs (non-deterministic finite automata) to allow
594 backtracking and backreferencing. And they aren't POSIX-style either,
595 because those guarantee worst-case behavior for all cases. (It seems
596 that some people prefer guarantees of consistency, even when what's
597 guaranteed is slowness.) See the book "Mastering Regular Expressions"
598 (from O'Reilly) by Jeffrey Friedl for all the details you could ever
599 hope to know on these matters (a full citation appears in
602 =head2 What's wrong with using grep or map in a void context?
604 Both grep and map build a return list, regardless of their context.
605 This means you're making Perl go to the trouble of building up a
606 return list that you then just ignore. That's no way to treat a
607 programming language, you insensitive scoundrel!
609 =head2 How can I match strings with multibyte characters?
611 This is hard, and there's no good way. Perl does not directly support
612 wide characters. It pretends that a byte and a character are
613 synonymous. The following set of approaches was offered by Jeffrey
614 Friedl, whose article in issue #5 of The Perl Journal talks about this
617 Let's suppose you have some weird Martian encoding where pairs of
618 ASCII uppercase letters encode single Martian letters (i.e. the two
619 bytes "CV" make a single Martian letter, as do the two bytes "SG",
620 "VS", "XX", etc.). Other bytes represent single characters, just like
623 So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the
624 nine characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.
626 Now, say you want to search for the single character C</GX/>. Perl
627 doesn't know about Martian, so it'll find the two bytes "GX" in the "I
628 am CVSGXX!" string, even though that character isn't there: it just
629 looks like it is because "SG" is next to "XX", but there's no real
630 "GX". This is a big problem.
632 Here are a few ways, all painful, to deal with it:
634 $martian =~ s/([A-Z][A-Z])/ $1 /g; # Make sure adjacent ``martian'' bytes
635 # are no longer adjacent.
636 print "found GX!\n" if $martian =~ /GX/;
640 @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
641 # above is conceptually similar to: @chars = $text =~ m/(.)/g;
643 foreach $char (@chars) {
644 print "found GX!\n", last if $char eq 'GX';
649 while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded
650 print "found GX!\n", last if $1 eq 'GX';
655 die "sorry, Perl doesn't (yet) have Martian support )-:\n";
657 There are many double- (and multi-) byte encodings commonly used these
658 days. Some versions of these have 1-, 2-, 3-, and 4-byte characters,
661 =head2 How do I match a pattern that is supplied by the user?
663 Well, if it's really a pattern, then just use
665 chomp($pattern = <STDIN>);
666 if ($line =~ /$pattern/) { }
668 Or, since you have no guarantee that your user entered
669 a valid regular expression, trap the exception this way:
671 if (eval { $line =~ /$pattern/ }) { }
673 But if all you really want to search for a string, not a pattern,
674 then you should either use the index() function, which is made for
675 string searching, or if you can't be disabused of using a pattern
676 match on a non-pattern, then be sure to use C<\Q>...C<\E>, documented
681 open (FILE, $input) or die "Couldn't open input $input: $!; aborting";
683 print if /\Q$pattern\E/;
687 =head1 AUTHOR AND COPYRIGHT
689 Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington.
692 When included as part of the Standard Version of Perl, or as part of
693 its complete documentation whether printed or otherwise, this work
694 may be distributed only under the terms of Perl's Artistic License.
695 Any distribution of this file or derivatives thereof I<outside>
696 of that package require that special arrangements be made with
699 Irrespective of its distribution, all code examples in this file
700 are hereby placed into the public domain. You are permitted and
701 encouraged to use this code in your own programs for fun
702 or for profit as you see fit. A simple comment in the code giving
703 credit would be courteous but is not required.