pod/perlfaq5.pod

   1 =head1 NAME
   2
   3 perlfaq5 - Files and Formats
   4
   5 =head1 DESCRIPTION
   6
   7 This section deals with I/O and the "f" issues: filehandles, flushing,
   8 formats, and footers.
   9
  10 =head2 How do I flush/unbuffer an output filehandle?  Why must I do this?
  11 X<flush> X<buffer> X<unbuffer> X<autoflush>
  12
  13 (contributed by brian d foy)
  14
  15 You might like to read Mark Jason Dominus's "Suffering From Buffering"
  16 at http://perl.plover.com/FAQs/Buffering.html .
  17
  18 Perl normally buffers output so it doesn't make a system call for every
  19 bit of output. By saving up output, it makes fewer expensive system calls.
  20 For instance, in this little bit of code, you want to print a dot to the
  21 screen for every line you process to watch the progress of your program.
  22 Instead of seeing a dot for every line, Perl buffers the output and you
  23 have a long wait before you see a row of 50 dots all at once:
  24
  25         # long wait, then row of dots all at once
  26         while( <> ) {
  27                 print ".";
  28                 print "\n" unless ++$count % 50;
  29
  30                 #... expensive line processing operations
  31                 }
  32
  33 To get around this, you have to unbuffer the output filehandle, in this
  34 case, C<STDOUT>. You can set the special variable C<$|> to a true value
  35 (mnemonic: making your filehandles "piping hot"):
  36
  37         $|++;
  38
  39         # dot shown immediately
  40         while( <> ) {
  41                 print ".";
  42                 print "\n" unless ++$count % 50;
  43
  44                 #... expensive line processing operations
  45                 }
  46
  47 The C<$|> is one of the per-filehandle special variables, so each
  48 filehandle has its own copy of its value. If you want to merge
  49 standard output and standard error for instance, you have to unbuffer
  50 each (although STDERR might be unbuffered by default):
  51
  52         {
  53         my $previous_default = select(STDOUT);  # save previous default
  54         $|++;                                   # autoflush STDOUT
  55         select(STDERR);
  56         $|++;                                   # autoflush STDERR, to be sure
  57         select($previous_default);              # restore previous default
  58         }
  59
  60         # now should alternate . and +
  61         while( 1 )
  62                 {
  63                 sleep 1;
  64                 print STDOUT ".";
  65                 print STDERR "+";
  66                 print STDOUT "\n" unless ++$count % 25;
  67                 }
  68
  69 Besides the C<$|> special variable, you can use C<binmode> to give
  70 your filehandle a C<:unix> layer, which is unbuffered:
  71
  72         binmode( STDOUT, ":unix" );
  73
  74         while( 1 ) {
  75                 sleep 1;
  76                 print ".";
  77                 print "\n" unless ++$count % 50;
  78                 }
  79
  80 For more information on output layers, see the entries for C<binmode>
  81 and C<open> in L<perlfunc>, and the C<PerlIO> module documentation.
  82
  83 If you are using C<IO::Handle> or one of its subclasses, you can
  84 call the C<autoflush> method to change the settings of the
  85 filehandle:
  86
  87         use IO::Handle;
  88         open my( $io_fh ), ">", "output.txt";
  89         $io_fh->autoflush(1);
  90
  91 The C<IO::Handle> objects also have a C<flush> method. You can flush
  92 the buffer any time you want without auto-buffering
  93
  94         $io_fh->flush;
  95
  96 =head2 How do I change, delete, or insert a line in a file, or append to the beginning of a file?
  97 X<file, editing>
  98
  99 (contributed by brian d foy)
 100
 101 The basic idea of inserting, changing, or deleting a line from a text
 102 file involves reading and printing the file to the point you want to
 103 make the change, making the change, then reading and printing the rest
 104 of the file. Perl doesn't provide random access to lines (especially
 105 since the record input separator, C<$/>, is mutable), although modules
 106 such as C<Tie::File> can fake it.
 107
 108 A Perl program to do these tasks takes the basic form of opening a
 109 file, printing its lines, then closing the file:
 110
 111         open my $in,  '<',  $file      or die "Can't read old file: $!";
 112         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 113
 114         while( <$in> )
 115                 {
 116                 print $out $_;
 117                 }
 118
 119    close $out;
 120
 121 Within that basic form, add the parts that you need to insert, change,
 122 or delete lines.
 123
 124 To prepend lines to the beginning, print those lines before you enter
 125 the loop that prints the existing lines.
 126
 127         open my $in,  '<',  $file      or die "Can't read old file: $!";
 128         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 129
 130         print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC
 131
 132         while( <$in> )
 133                 {
 134                 print $out $_;
 135                 }
 136
 137    close $out;
 138
 139 To change existing lines, insert the code to modify the lines inside
 140 the C<while> loop. In this case, the code finds all lowercased
 141 versions of "perl" and uppercases them. The happens for every line, so
 142 be sure that you're supposed to do that on every line!
 143
 144         open my $in,  '<',  $file      or die "Can't read old file: $!";
 145         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 146
 147         print $out "# Add this line to the top\n";
 148
 149         while( <$in> )
 150                 {
 151                 s/\b(perl)\b/Perl/g;
 152                 print $out $_;
 153                 }
 154
 155    close $out;
 156
 157 To change only a particular line, the input line number, C<$.>, is
 158 useful. First read and print the lines up to the one you  want to
 159 change. Next, read the single line you want to change, change it, and
 160 print it. After that, read the rest of the lines and print those:
 161
 162         while( <$in> )   # print the lines before the change
 163                 {
 164                 print $out $_;
 165                 last if $. == 4; # line number before change
 166                 }
 167
 168         my $line = <$in>;
 169         $line =~ s/\b(perl)\b/Perl/g;
 170         print $out $line;
 171
 172         while( <$in> )   # print the rest of the lines
 173                 {
 174                 print $out $_;
 175                 }
 176
 177 To skip lines, use the looping controls. The C<next> in this example
 178 skips comment lines, and the C<last> stops all processing once it
 179 encounters either C<__END__> or C<__DATA__>.
 180
 181         while( <$in> )
 182                 {
 183                 next if /^\s+#/;             # skip comment lines
 184                 last if /^__(END|DATA)__$/;  # stop at end of code marker
 185                 print $out $_;
 186                 }
 187
 188 Do the same sort of thing to delete a particular line by using C<next>
 189 to skip the lines you don't want to show up in the output. This
 190 example skips every fifth line:
 191
 192         while( <$in> )
 193                 {
 194                 next unless $. % 5;
 195                 print $out $_;
 196                 }
 197
 198 If, for some odd reason, you really want to see the whole file at once
 199 rather than processing line-by-line, you can slurp it in (as long as
 200 you can fit the whole thing in memory!):
 201
 202         open my $in,  '<',  $file      or die "Can't read old file: $!"
 203         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 204
 205         my @lines = do { local $/; <$in> }; # slurp!
 206
 207                 # do your magic here
 208
 209         print $out @lines;
 210
 211 Modules such as C<File::Slurp> and C<Tie::File> can help with that
 212 too. If you can, however, avoid reading the entire file at once. Perl
 213 won't give that memory back to the operating system until the process
 214 finishes.
 215
 216 You can also use Perl one-liners to modify a file in-place. The
 217 following changes all 'Fred' to 'Barney' in F<inFile.txt>, overwriting
 218 the file with the new contents. With the C<-p> switch, Perl wraps a
 219 C<while> loop around the code you specify with C<-e>, and C<-i> turns
 220 on in-place editing. The current line is in C<$_>. With C<-p>, Perl
 221 automatically prints the value of C<$_> at the end of the loop. See
 222 L<perlrun> for more details.
 223
 224         perl -pi -e 's/Fred/Barney/' inFile.txt
 225
 226 To make a backup of C<inFile.txt>, give C<-i> a file extension to add:
 227
 228         perl -pi.bak -e 's/Fred/Barney/' inFile.txt
 229
 230 To change only the fifth line, you can add a test checking C<$.>, the
 231 input line number, then only perform the operation when the test
 232 passes:
 233
 234         perl -pi -e 's/Fred/Barney/ if $. == 5' inFile.txt
 235
 236 To add lines before a certain line, you can add a line (or lines!)
 237 before Perl prints C<$_>:
 238
 239         perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt
 240
 241 You can even add a line to the beginning of a file, since the current
 242 line prints at the end of the loop:
 243
 244         perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt
 245
 246 To insert a line after one already in the file, use the C<-n> switch.
 247 It's just like C<-p> except that it doesn't print C<$_> at the end of
 248 the loop, so you have to do that yourself. In this case, print C<$_>
 249 first, then print the line that you want to add.
 250
 251         perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt
 252
 253 To delete lines, only print the ones that you want.
 254
 255         perl -ni -e 'print unless /d/' inFile.txt
 256
 257                 ... or ...
 258
 259         perl -pi -e 'next unless /d/' inFile.txt
 260
 261 =head2 How do I count the number of lines in a file?
 262 X<file, counting lines> X<lines> X<line>
 263
 264 One fairly efficient way is to count newlines in the file. The
 265 following program uses a feature of tr///, as documented in L<perlop>.
 266 If your text file doesn't end with a newline, then it's not really a
 267 proper text file, so this may report one fewer line than you expect.
 268
 269         $lines = 0;
 270         open(FILE, $filename) or die "Can't open `$filename': $!";
 271         while (sysread FILE, $buffer, 4096) {
 272                 $lines += ($buffer =~ tr/\n//);
 273                 }
 274         close FILE;
 275
 276 This assumes no funny games with newline translations.
 277
 278 =head2 How can I use Perl's C<-i> option from within a program?
 279 X<-i> X<in-place>
 280
 281 C<-i> sets the value of Perl's C<$^I> variable, which in turn affects
 282 the behavior of C<< <> >>; see L<perlrun> for more details.  By
 283 modifying the appropriate variables directly, you can get the same
 284 behavior within a larger program.  For example:
 285
 286         # ...
 287         {
 288         local($^I, @ARGV) = ('.orig', glob("*.c"));
 289         while (<>) {
 290                 if ($. == 1) {
 291                         print "This line should appear at the top of each file\n";
 292                 }
 293                 s/\b(p)earl\b/${1}erl/i;        # Correct typos, preserving case
 294                 print;
 295                 close ARGV if eof;              # Reset $.
 296                 }
 297         }
 298         # $^I and @ARGV return to their old values here
 299
 300 This block modifies all the C<.c> files in the current directory,
 301 leaving a backup of the original data from each file in a new
 302 C<.c.orig> file.
 303
 304 =head2 How can I copy a file?
 305 X<copy> X<file, copy> X<File::Copy>
 306
 307 (contributed by brian d foy)
 308
 309 Use the C<File::Copy> module. It comes with Perl and can do a
 310 true copy across file systems, and it does its magic in
 311 a portable fashion.
 312
 313         use File::Copy;
 314
 315         copy( $original, $new_copy ) or die "Copy failed: $!";
 316
 317 If you can't use C<File::Copy>, you'll have to do the work yourself:
 318 open the original file, open the destination file, then print
 319 to the destination file as you read the original. You also have to
 320 remember to copy the permissions, owner, and group to the new file.
 321
 322 =head2 How do I make a temporary file name?
 323 X<file, temporary>
 324
 325 If you don't need to know the name of the file, you can use C<open()>
 326 with C<undef> in place of the file name.  In Perl 5.8 or later, the
 327 C<open()> function creates an anonymous temporary file:
 328
 329         open my $tmp, '+>', undef or die $!;
 330
 331 Otherwise, you can use the File::Temp module.
 332
 333         use File::Temp qw/ tempfile tempdir /;
 334
 335         $dir = tempdir( CLEANUP => 1 );
 336         ($fh, $filename) = tempfile( DIR => $dir );
 337
 338         # or if you don't need to know the filename
 339
 340         $fh = tempfile( DIR => $dir );
 341
 342 The File::Temp has been a standard module since Perl 5.6.1.  If you
 343 don't have a modern enough Perl installed, use the C<new_tmpfile>
 344 class method from the IO::File module to get a filehandle opened for
 345 reading and writing.  Use it if you don't need to know the file's name:
 346
 347         use IO::File;
 348         $fh = IO::File->new_tmpfile()
 349         or die "Unable to make new temporary file: $!";
 350
 351 If you're committed to creating a temporary file by hand, use the
 352 process ID and/or the current time-value.  If you need to have many
 353 temporary files in one process, use a counter:
 354
 355         BEGIN {
 356         use Fcntl;
 357         my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
 358         my $base_name = sprintf "%s/%d-%d-0000", $temp_dir, $$, time;
 359
 360         sub temp_file {
 361                 local *FH;
 362                 my $count = 0;
 363                 until( defined(fileno(FH)) || $count++ > 100 ) {
 364                         $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
 365                         # O_EXCL is required for security reasons.
 366                         sysopen FH, $base_name, O_WRONLY|O_EXCL|O_CREAT;
 367                         }
 368
 369                 if( defined fileno(FH) ) {
 370                         return (*FH, $base_name);
 371                         }
 372                 else {
 373                         return ();
 374                         }
 375                 }
 376
 377         }
 378
 379 =head2 How can I manipulate fixed-record-length files?
 380 X<fixed-length> X<file, fixed-length records>
 381
 382 The most efficient way is using L<pack()|perlfunc/"pack"> and
 383 L<unpack()|perlfunc/"unpack">.  This is faster than using
 384 L<substr()|perlfunc/"substr"> when taking many, many strings.  It is
 385 slower for just a few.
 386
 387 Here is a sample chunk of code to break up and put back together again
 388 some fixed-format input lines, in this case from the output of a normal,
 389 Berkeley-style ps:
 390
 391         # sample input line:
 392         #   15158 p5  T      0:00 perl /home/tchrist/scripts/now-what
 393         my $PS_T = 'A6 A4 A7 A5 A*';
 394         open my $ps, '-|', 'ps';
 395         print scalar <$ps>;
 396         my @fields = qw( pid tt stat time command );
 397         while (<$ps>) {
 398                 my %process;
 399                 @process{@fields} = unpack($PS_T, $_);
 400         for my $field ( @fields ) {
 401                 print "$field: <$process{$field}>\n";
 402         }
 403         print 'line=', pack($PS_T, @process{@fields} ), "\n";
 404         }
 405
 406 We've used a hash slice in order to easily handle the fields of each row.
 407 Storing the keys in an array means it's easy to operate on them as a
 408 group or loop over them with for. It also avoids polluting the program
 409 with global variables and using symbolic references.
 410
 411 =head2 How can I make a filehandle local to a subroutine?  How do I pass filehandles between subroutines?  How do I make an array of filehandles?
 412 X<filehandle, local> X<filehandle, passing> X<filehandle, reference>
 413
 414 As of perl5.6, open() autovivifies file and directory handles
 415 as references if you pass it an uninitialized scalar variable.
 416 You can then pass these references just like any other scalar,
 417 and use them in the place of named handles.
 418
 419         open my    $fh, $file_name;
 420
 421         open local $fh, $file_name;
 422
 423         print $fh "Hello World!\n";
 424
 425         process_file( $fh );
 426
 427 If you like, you can store these filehandles in an array or a hash.
 428 If you access them directly, they aren't simple scalars and you
 429 need to give C<print> a little help by placing the filehandle
 430 reference in braces. Perl can only figure it out on its own when
 431 the filehandle reference is a simple scalar.
 432
 433         my @fhs = ( $fh1, $fh2, $fh3 );
 434
 435         for( $i = 0; $i <= $#fhs; $i++ ) {
 436                 print {$fhs[$i]} "just another Perl answer, \n";
 437                 }
 438
 439 Before perl5.6, you had to deal with various typeglob idioms
 440 which you may see in older code.
 441
 442         open FILE, "> $filename";
 443         process_typeglob(   *FILE );
 444         process_reference( \*FILE );
 445
 446         sub process_typeglob  { local *FH = shift; print FH  "Typeglob!" }
 447         sub process_reference { local $fh = shift; print $fh "Reference!" }
 448
 449 If you want to create many anonymous handles, you should
 450 check out the Symbol or IO::Handle modules.
 451
 452 =head2 How can I use a filehandle indirectly?
 453 X<filehandle, indirect>
 454
 455 An indirect filehandle is using something other than a symbol
 456 in a place that a filehandle is expected.  Here are ways
 457 to get indirect filehandles:
 458
 459         $fh =   SOME_FH;       # bareword is strict-subs hostile
 460         $fh =  "SOME_FH";      # strict-refs hostile; same package only
 461         $fh =  *SOME_FH;       # typeglob
 462         $fh = \*SOME_FH;       # ref to typeglob (bless-able)
 463         $fh =  *SOME_FH{IO};   # blessed IO::Handle from *SOME_FH typeglob
 464
 465 Or, you can use the C<new> method from one of the IO::* modules to
 466 create an anonymous filehandle, store that in a scalar variable,
 467 and use it as though it were a normal filehandle.
 468
 469         use IO::Handle;                     # 5.004 or higher
 470         $fh = IO::Handle->new();
 471
 472 Then use any of those as you would a normal filehandle.  Anywhere that
 473 Perl is expecting a filehandle, an indirect filehandle may be used
 474 instead. An indirect filehandle is just a scalar variable that contains
 475 a filehandle.  Functions like C<print>, C<open>, C<seek>, or
 476 the C<< <FH> >> diamond operator will accept either a named filehandle
 477 or a scalar variable containing one:
 478
 479         ($ifh, $ofh, $efh) = (*STDIN, *STDOUT, *STDERR);
 480         print $ofh "Type it: ";
 481         $got = <$ifh>
 482         print $efh "What was that: $got";
 483
 484 If you're passing a filehandle to a function, you can write
 485 the function in two ways:
 486
 487         sub accept_fh {
 488                 my $fh = shift;
 489                 print $fh "Sending to indirect filehandle\n";
 490         }
 491
 492 Or it can localize a typeglob and use the filehandle directly:
 493
 494         sub accept_fh {
 495                 local *FH = shift;
 496                 print  FH "Sending to localized filehandle\n";
 497         }
 498
 499 Both styles work with either objects or typeglobs of real filehandles.
 500 (They might also work with strings under some circumstances, but this
 501 is risky.)
 502
 503         accept_fh(*STDOUT);
 504         accept_fh($handle);
 505
 506 In the examples above, we assigned the filehandle to a scalar variable
 507 before using it.  That is because only simple scalar variables, not
 508 expressions or subscripts of hashes or arrays, can be used with
 509 built-ins like C<print>, C<printf>, or the diamond operator.  Using
 510 something other than a simple scalar variable as a filehandle is
 511 illegal and won't even compile:
 512
 513         @fd = (*STDIN, *STDOUT, *STDERR);
 514         print $fd[1] "Type it: ";                           # WRONG
 515         $got = <$fd[0]>                                     # WRONG
 516         print $fd[2] "What was that: $got";                 # WRONG
 517
 518 With C<print> and C<printf>, you get around this by using a block and
 519 an expression where you would place the filehandle:
 520
 521         print  { $fd[1] } "funny stuff\n";
 522         printf { $fd[1] } "Pity the poor %x.\n", 3_735_928_559;
 523         # Pity the poor deadbeef.
 524
 525 That block is a proper block like any other, so you can put more
 526 complicated code there.  This sends the message out to one of two places:
 527
 528         $ok = -x "/bin/cat";
 529         print { $ok ? $fd[1] : $fd[2] } "cat stat $ok\n";
 530         print { $fd[ 1+ ($ok || 0) ]  } "cat stat $ok\n";
 531
 532 This approach of treating C<print> and C<printf> like object methods
 533 calls doesn't work for the diamond operator.  That's because it's a
 534 real operator, not just a function with a comma-less argument.  Assuming
 535 you've been storing typeglobs in your structure as we did above, you
 536 can use the built-in function named C<readline> to read a record just
 537 as C<< <> >> does.  Given the initialization shown above for @fd, this
 538 would work, but only because readline() requires a typeglob.  It doesn't
 539 work with objects or strings, which might be a bug we haven't fixed yet.
 540
 541         $got = readline($fd[0]);
 542
 543 Let it be noted that the flakiness of indirect filehandles is not
 544 related to whether they're strings, typeglobs, objects, or anything else.
 545 It's the syntax of the fundamental operators.  Playing the object
 546 game doesn't help you at all here.
 547
 548 =head2 How can I set up a footer format to be used with write()?
 549 X<footer>
 550
 551 There's no builtin way to do this, but L<perlform> has a couple of
 552 techniques to make it possible for the intrepid hacker.
 553
 554 =head2 How can I write() into a string?
 555 X<write, into a string>
 556
 557 See L<perlform/"Accessing Formatting Internals"> for an C<swrite()> function.
 558
 559 =head2 How can I open a filehandle to a string?
 560 X<string> X<open> X<IO::String> X<filehandle>
 561
 562 (contributed by Peter J. Holzer, hjp-usenet2@hjp.at)
 563
 564 Since Perl 5.8.0 a file handle referring to a string can be created by
 565 calling open with a reference to that string instead of the filename.
 566 This file handle can then be used to read from or write to the string:
 567
 568         open(my $fh, '>', \$string) or die "Could not open string for writing";
 569         print $fh "foo\n";
 570         print $fh "bar\n";      # $string now contains "foo\nbar\n"
 571
 572         open(my $fh, '<', \$string) or die "Could not open string for reading";
 573         my $x = <$fh>;  # $x now contains "foo\n"
 574
 575 With older versions of Perl, the C<IO::String> module provides similar
 576 functionality.
 577
 578 =head2 How can I output my numbers with commas added?
 579 X<number, commify>
 580
 581 (contributed by brian d foy and Benjamin Goldberg)
 582
 583 You can use L<Number::Format> to separate places in a number.
 584 It handles locale information for those of you who want to insert
 585 full stops instead (or anything else that they want to use,
 586 really).
 587
 588 This subroutine will add commas to your number:
 589
 590         sub commify {
 591                 local $_  = shift;
 592                 1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
 593                 return $_;
 594                 }
 595
 596 This regex from Benjamin Goldberg will add commas to numbers:
 597
 598         s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
 599
 600 It is easier to see with comments:
 601
 602         s/(
 603                 ^[-+]?             # beginning of number.
 604                 \d+?               # first digits before first comma
 605                 (?=                # followed by, (but not included in the match) :
 606                         (?>(?:\d{3})+) # some positive multiple of three digits.
 607                         (?!\d)         # an *exact* multiple, not x * 3 + 1 or whatever.
 608                 )
 609                 |                  # or:
 610                 \G\d{3}            # after the last group, get three digits
 611                 (?=\d)             # but they have to have more digits after them.
 612         )/$1,/xg;
 613
 614 =head2 How can I translate tildes (~) in a filename?
 615 X<tilde> X<tilde expansion>
 616
 617 Use the E<lt>E<gt> (C<glob()>) operator, documented in L<perlfunc>.
 618 Versions of Perl older than 5.6 require that you have a shell
 619 installed that groks tildes.  Later versions of Perl have this feature
 620 built in. The C<File::KGlob> module (available from CPAN) gives more
 621 portable glob functionality.
 622
 623 Within Perl, you may use this directly:
 624
 625         $filename =~ s{
 626           ^ ~             # find a leading tilde
 627           (               # save this in $1
 628               [^/]        # a non-slash character
 629                     *     # repeated 0 or more times (0 means me)
 630           )
 631         }{
 632           $1
 633               ? (getpwnam($1))[7]
 634               : ( $ENV{HOME} || $ENV{LOGDIR} )
 635         }ex;
 636
 637 =head2 How come when I open a file read-write it wipes it out?
 638 X<clobber> X<read-write> X<clobbering> X<truncate> X<truncating>
 639
 640 Because you're using something like this, which truncates the file and
 641 I<then> gives you read-write access:
 642
 643         open(FH, "+> /path/name");              # WRONG (almost always)
 644
 645 Whoops.  You should instead use this, which will fail if the file
 646 doesn't exist.
 647
 648         open(FH, "+< /path/name");      # open for update
 649
 650 Using ">" always clobbers or creates.  Using "<" never does
 651 either.  The "+" doesn't change this.
 652
 653 Here are examples of many kinds of file opens.  Those using sysopen()
 654 all assume
 655
 656         use Fcntl;
 657
 658 To open file for reading:
 659
 660         open(FH, "< $path")                                 || die $!;
 661         sysopen(FH, $path, O_RDONLY)                        || die $!;
 662
 663 To open file for writing, create new file if needed or else truncate old file:
 664
 665         open(FH, "> $path") || die $!;
 666         sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT)        || die $!;
 667         sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666)  || die $!;
 668
 669 To open file for writing, create new file, file must not exist:
 670
 671         sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT)         || die $!;
 672         sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT, 0666)   || die $!;
 673
 674 To open file for appending, create if necessary:
 675
 676         open(FH, ">> $path") || die $!;
 677         sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT)       || die $!;
 678         sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT, 0666) || die $!;
 679
 680 To open file for appending, file must exist:
 681
 682         sysopen(FH, $path, O_WRONLY|O_APPEND)               || die $!;
 683
 684 To open file for update, file must exist:
 685
 686         open(FH, "+< $path")                                || die $!;
 687         sysopen(FH, $path, O_RDWR)                          || die $!;
 688
 689 To open file for update, create file if necessary:
 690
 691         sysopen(FH, $path, O_RDWR|O_CREAT)                  || die $!;
 692         sysopen(FH, $path, O_RDWR|O_CREAT, 0666)            || die $!;
 693
 694 To open file for update, file must not exist:
 695
 696         sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT)           || die $!;
 697         sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT, 0666)     || die $!;
 698
 699 To open a file without blocking, creating if necessary:
 700
 701         sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT)
 702             or die "can't open /foo/somefile: $!":
 703
 704 Be warned that neither creation nor deletion of files is guaranteed to
 705 be an atomic operation over NFS.  That is, two processes might both
 706 successfully create or unlink the same file!  Therefore O_EXCL
 707 isn't as exclusive as you might wish.
 708
 709 See also the new L<perlopentut> if you have it (new for 5.6).
 710
 711 =head2 Why do I sometimes get an "Argument list too long" when I use E<lt>*E<gt>?
 712 X<argument list too long>
 713
 714 The C<< <> >> operator performs a globbing operation (see above).
 715 In Perl versions earlier than v5.6.0, the internal glob() operator forks
 716 csh(1) to do the actual glob expansion, but
 717 csh can't handle more than 127 items and so gives the error message
 718 C<Argument list too long>.  People who installed tcsh as csh won't
 719 have this problem, but their users may be surprised by it.
 720
 721 To get around this, either upgrade to Perl v5.6.0 or later, do the glob
 722 yourself with readdir() and patterns, or use a module like File::KGlob,
 723 one that doesn't use the shell to do globbing.
 724
 725 =head2 Is there a leak/bug in glob()?
 726 X<glob>
 727
 728 (conributed by brian d foy)
 729
 730 Starting with Perl 5.6.0, C<glob> is implemented internally rather
 731 than relying on an external resource. As such, memory issues with
 732 C<glob> aren't a problem in modern perls.
 733
 734 =head2 How can I open a file with a leading ">" or trailing blanks?
 735 X<filename, special characters>
 736
 737 (contributed by Brian McCauley)
 738
 739 The special two argument form of Perl's open() function ignores
 740 trailing blanks in filenames and infers the mode from certain leading
 741 characters (or a trailing "|"). In older versions of Perl this was the
 742 only version of open() and so it is prevalent in old code and books.
 743
 744 Unless you have a particular reason to use the two argument form you
 745 should use the three argument form of open() which does not treat any
 746 characters in the filename as special.
 747
 748         open FILE, "<", "  file  ";  # filename is "   file   "
 749         open FILE, ">", ">file";     # filename is ">file"
 750
 751 =head2 How can I reliably rename a file?
 752 X<rename> X<mv> X<move> X<file, rename>
 753
 754 If your operating system supports a proper mv(1) utility or its
 755 functional equivalent, this works:
 756
 757         rename($old, $new) or system("mv", $old, $new);
 758
 759 It may be more portable to use the C<File::Copy> module instead.
 760 You just copy to the new file to the new name (checking return
 761 values), then delete the old one.  This isn't really the same
 762 semantically as a C<rename()>, which preserves meta-information like
 763 permissions, timestamps, inode info, etc.
 764
 765 =head2 How can I lock a file?
 766 X<lock> X<file, lock> X<flock>
 767
 768 Perl's builtin flock() function (see L<perlfunc> for details) will call
 769 flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and
 770 later), and lockf(3) if neither of the two previous system calls exists.
 771 On some systems, it may even use a different form of native locking.
 772 Here are some gotchas with Perl's flock():
 773
 774 =over 4
 775
 776 =item 1
 777
 778 Produces a fatal error if none of the three system calls (or their
 779 close equivalent) exists.
 780
 781 =item 2
 782
 783 lockf(3) does not provide shared locking, and requires that the
 784 filehandle be open for writing (or appending, or read/writing).
 785
 786 =item 3
 787
 788 Some versions of flock() can't lock files over a network (e.g. on NFS file
 789 systems), so you'd need to force the use of fcntl(2) when you build Perl.
 790 But even this is dubious at best.  See the flock entry of L<perlfunc>
 791 and the F<INSTALL> file in the source distribution for information on
 792 building Perl to do this.
 793
 794 Two potentially non-obvious but traditional flock semantics are that
 795 it waits indefinitely until the lock is granted, and that its locks are
 796 I<merely advisory>.  Such discretionary locks are more flexible, but
 797 offer fewer guarantees.  This means that files locked with flock() may
 798 be modified by programs that do not also use flock().  Cars that stop
 799 for red lights get on well with each other, but not with cars that don't
 800 stop for red lights.  See the perlport manpage, your port's specific
 801 documentation, or your system-specific local manpages for details.  It's
 802 best to assume traditional behavior if you're writing portable programs.
 803 (If you're not, you should as always feel perfectly free to write
 804 for your own system's idiosyncrasies (sometimes called "features").
 805 Slavish adherence to portability concerns shouldn't get in the way of
 806 your getting your job done.)
 807
 808 For more information on file locking, see also
 809 L<perlopentut/"File Locking"> if you have it (new for 5.6).
 810
 811 =back
 812
 813 =head2 Why can't I just open(FH, "E<gt>file.lock")?
 814 X<lock, lockfile race condition>
 815
 816 A common bit of code B<NOT TO USE> is this:
 817
 818         sleep(3) while -e "file.lock";  # PLEASE DO NOT USE
 819         open(LCK, "> file.lock");               # THIS BROKEN CODE
 820
 821 This is a classic race condition: you take two steps to do something
 822 which must be done in one.  That's why computer hardware provides an
 823 atomic test-and-set instruction.   In theory, this "ought" to work:
 824
 825         sysopen(FH, "file.lock", O_WRONLY|O_EXCL|O_CREAT)
 826                 or die "can't open  file.lock: $!";
 827
 828 except that lamentably, file creation (and deletion) is not atomic
 829 over NFS, so this won't work (at least, not every time) over the net.
 830 Various schemes involving link() have been suggested, but
 831 these tend to involve busy-wait, which is also less than desirable.
 832
 833 =head2 I still don't get locking.  I just want to increment the number in the file.  How can I do this?
 834 X<counter> X<file, counter>
 835
 836 Didn't anyone ever tell you web-page hit counters were useless?
 837 They don't count number of hits, they're a waste of time, and they serve
 838 only to stroke the writer's vanity.  It's better to pick a random number;
 839 they're more realistic.
 840
 841 Anyway, this is what you can do if you can't help yourself.
 842
 843         use Fcntl qw(:DEFAULT :flock);
 844         sysopen(FH, "numfile", O_RDWR|O_CREAT)   or die "can't open numfile: $!";
 845         flock(FH, LOCK_EX)                               or die "can't flock numfile: $!";
 846         $num = <FH> || 0;
 847         seek(FH, 0, 0)                           or die "can't rewind numfile: $!";
 848         truncate(FH, 0)                                  or die "can't truncate numfile: $!";
 849         (print FH $num+1, "\n")                  or die "can't write numfile: $!";
 850         close FH                                         or die "can't close numfile: $!";
 851
 852 Here's a much better web-page hit counter:
 853
 854         $hits = int( (time() - 850_000_000) / rand(1_000) );
 855
 856 If the count doesn't impress your friends, then the code might.  :-)
 857
 858 =head2 All I want to do is append a small amount of text to the end of a file.  Do I still have to use locking?
 859 X<append> X<file, append>
 860
 861 If you are on a system that correctly implements C<flock> and you use
 862 the example appending code from "perldoc -f flock" everything will be
 863 OK even if the OS you are on doesn't implement append mode correctly
 864 (if such a system exists.) So if you are happy to restrict yourself to
 865 OSs that implement C<flock> (and that's not really much of a
 866 restriction) then that is what you should do.
 867
 868 If you know you are only going to use a system that does correctly
 869 implement appending (i.e. not Win32) then you can omit the C<seek>
 870 from the code in the previous answer.
 871
 872 If you know you are only writing code to run on an OS and filesystem
 873 that does implement append mode correctly (a local filesystem on a
 874 modern Unix for example), and you keep the file in block-buffered mode
 875 and you write less than one buffer-full of output between each manual
 876 flushing of the buffer then each bufferload is almost guaranteed to be
 877 written to the end of the file in one chunk without getting
 878 intermingled with anyone else's output. You can also use the
 879 C<syswrite> function which is simply a wrapper around your system's
 880 C<write(2)> system call.
 881
 882 There is still a small theoretical chance that a signal will interrupt
 883 the system level C<write()> operation before completion. There is also
 884 a possibility that some STDIO implementations may call multiple system
 885 level C<write()>s even if the buffer was empty to start. There may be
 886 some systems where this probability is reduced to zero, and this is
 887 not a concern when using C<:perlio> instead of your system's STDIO.
 888
 889 =head2 How do I randomly update a binary file?
 890 X<file, binary patch>
 891
 892 If you're just trying to patch a binary, in many cases something as
 893 simple as this works:
 894
 895         perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
 896
 897 However, if you have fixed sized records, then you might do something more
 898 like this:
 899
 900         $RECSIZE = 220; # size of record, in bytes
 901         $recno   = 37;  # which record to update
 902         open(FH, "+<somewhere") || die "can't update somewhere: $!";
 903         seek(FH, $recno * $RECSIZE, 0);
 904         read(FH, $record, $RECSIZE) == $RECSIZE || die "can't read record $recno: $!";
 905         # munge the record
 906         seek(FH, -$RECSIZE, 1);
 907         print FH $record;
 908         close FH;
 909
 910 Locking and error checking are left as an exercise for the reader.
 911 Don't forget them or you'll be quite sorry.
 912
 913 =head2 How do I get a file's timestamp in perl?
 914 X<timestamp> X<file, timestamp>
 915
 916 If you want to retrieve the time at which the file was last
 917 read, written, or had its meta-data (owner, etc) changed,
 918 you use the B<-A>, B<-M>, or B<-C> file test operations as
 919 documented in L<perlfunc>.  These retrieve the age of the
 920 file (measured against the start-time of your program) in
 921 days as a floating point number. Some platforms may not have
 922 all of these times.  See L<perlport> for details. To
 923 retrieve the "raw" time in seconds since the epoch, you
 924 would call the stat function, then use localtime(),
 925 gmtime(), or POSIX::strftime() to convert this into
 926 human-readable form.
 927
 928 Here's an example:
 929
 930         $write_secs = (stat($file))[9];
 931         printf "file %s updated at %s\n", $file,
 932         scalar localtime($write_secs);
 933
 934 If you prefer something more legible, use the File::stat module
 935 (part of the standard distribution in version 5.004 and later):
 936
 937         # error checking left as an exercise for reader.
 938         use File::stat;
 939         use Time::localtime;
 940         $date_string = ctime(stat($file)->mtime);
 941         print "file $file updated at $date_string\n";
 942
 943 The POSIX::strftime() approach has the benefit of being,
 944 in theory, independent of the current locale.  See L<perllocale>
 945 for details.
 946
 947 =head2 How do I set a file's timestamp in perl?
 948 X<timestamp> X<file, timestamp>
 949
 950 You use the utime() function documented in L<perlfunc/utime>.
 951 By way of example, here's a little program that copies the
 952 read and write times from its first argument to all the rest
 953 of them.
 954
 955         if (@ARGV < 2) {
 956                 die "usage: cptimes timestamp_file other_files ...\n";
 957                 }
 958         $timestamp = shift;
 959         ($atime, $mtime) = (stat($timestamp))[8,9];
 960         utime $atime, $mtime, @ARGV;
 961
 962 Error checking is, as usual, left as an exercise for the reader.
 963
 964 The perldoc for utime also has an example that has the same
 965 effect as touch(1) on files that I<already exist>.
 966
 967 Certain file systems have a limited ability to store the times
 968 on a file at the expected level of precision.  For example, the
 969 FAT and HPFS filesystem are unable to create dates on files with
 970 a finer granularity than two seconds.  This is a limitation of
 971 the filesystems, not of utime().
 972
 973 =head2 How do I print to more than one file at once?
 974 X<print, to multiple files>
 975
 976 To connect one filehandle to several output filehandles,
 977 you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
 978
 979 If you only have to do this once, you can print individually
 980 to each filehandle.
 981
 982         for $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
 983
 984 =head2 How can I read in an entire file all at once?
 985 X<slurp> X<file, slurping>
 986
 987 You can use the File::Slurp module to do it in one step.
 988
 989         use File::Slurp;
 990
 991         $all_of_it = read_file($filename); # entire file in scalar
 992         @all_lines = read_file($filename); # one line per element
 993
 994 The customary Perl approach for processing all the lines in a file is to
 995 do so one line at a time:
 996
 997         open (INPUT, $file)     || die "can't open $file: $!";
 998         while (<INPUT>) {
 999                 chomp;
1000                 # do something with $_
1001                 }
1002         close(INPUT)            || die "can't close $file: $!";
1003
1004 This is tremendously more efficient than reading the entire file into
1005 memory as an array of lines and then processing it one element at a time,
1006 which is often--if not almost always--the wrong approach.  Whenever
1007 you see someone do this:
1008
1009         @lines = <INPUT>;
1010
1011 you should think long and hard about why you need everything loaded at
1012 once.  It's just not a scalable solution.  You might also find it more
1013 fun to use the standard Tie::File module, or the DB_File module's
1014 $DB_RECNO bindings, which allow you to tie an array to a file so that
1015 accessing an element the array actually accesses the corresponding
1016 line in the file.
1017
1018 You can read the entire filehandle contents into a scalar.
1019
1020         {
1021         local(*INPUT, $/);
1022         open (INPUT, $file)     || die "can't open $file: $!";
1023         $var = <INPUT>;
1024         }
1025
1026 That temporarily undefs your record separator, and will automatically
1027 close the file at block exit.  If the file is already open, just use this:
1028
1029         $var = do { local $/; <INPUT> };
1030
1031 For ordinary files you can also use the read function.
1032
1033         read( INPUT, $var, -s INPUT );
1034
1035 The third argument tests the byte size of the data on the INPUT filehandle
1036 and reads that many bytes into the buffer $var.
1037
1038 =head2 How can I read in a file by paragraphs?
1039 X<file, reading by paragraphs>
1040
1041 Use the C<$/> variable (see L<perlvar> for details).  You can either
1042 set it to C<""> to eliminate empty paragraphs (C<"abc\n\n\n\ndef">,
1043 for instance, gets treated as two paragraphs and not three), or
1044 C<"\n\n"> to accept empty paragraphs.
1045
1046 Note that a blank line must have no blanks in it.  Thus
1047 S<C<"fred\n \nstuff\n\n">> is one paragraph, but C<"fred\n\nstuff\n\n"> is two.
1048
1049 =head2 How can I read a single character from a file?  From the keyboard?
1050 X<getc> X<file, reading one character at a time>
1051
1052 You can use the builtin C<getc()> function for most filehandles, but
1053 it won't (easily) work on a terminal device.  For STDIN, either use
1054 the Term::ReadKey module from CPAN or use the sample code in
1055 L<perlfunc/getc>.
1056
1057 If your system supports the portable operating system programming
1058 interface (POSIX), you can use the following code, which you'll note
1059 turns off echo processing as well.
1060
1061         #!/usr/bin/perl -w
1062         use strict;
1063         $| = 1;
1064         for (1..4) {
1065                 my $got;
1066                 print "gimme: ";
1067                 $got = getone();
1068                 print "--> $got\n";
1069                 }
1070     exit;
1071
1072         BEGIN {
1073         use POSIX qw(:termios_h);
1074
1075         my ($term, $oterm, $echo, $noecho, $fd_stdin);
1076
1077         $fd_stdin = fileno(STDIN);
1078
1079         $term     = POSIX::Termios->new();
1080         $term->getattr($fd_stdin);
1081         $oterm     = $term->getlflag();
1082
1083         $echo     = ECHO | ECHOK | ICANON;
1084         $noecho   = $oterm & ~$echo;
1085
1086         sub cbreak {
1087                 $term->setlflag($noecho);
1088                 $term->setcc(VTIME, 1);
1089                 $term->setattr($fd_stdin, TCSANOW);
1090                 }
1091
1092         sub cooked {
1093                 $term->setlflag($oterm);
1094                 $term->setcc(VTIME, 0);
1095                 $term->setattr($fd_stdin, TCSANOW);
1096                 }
1097
1098         sub getone {
1099                 my $key = '';
1100                 cbreak();
1101                 sysread(STDIN, $key, 1);
1102                 cooked();
1103                 return $key;
1104                 }
1105
1106         }
1107
1108         END { cooked() }
1109
1110 The Term::ReadKey module from CPAN may be easier to use.  Recent versions
1111 include also support for non-portable systems as well.
1112
1113         use Term::ReadKey;
1114         open(TTY, "</dev/tty");
1115         print "Gimme a char: ";
1116         ReadMode "raw";
1117         $key = ReadKey 0, *TTY;
1118         ReadMode "normal";
1119         printf "\nYou said %s, char number %03d\n",
1120                 $key, ord $key;
1121
1122 =head2 How can I tell whether there's a character waiting on a filehandle?
1123
1124 The very first thing you should do is look into getting the Term::ReadKey
1125 extension from CPAN.  As we mentioned earlier, it now even has limited
1126 support for non-portable (read: not open systems, closed, proprietary,
1127 not POSIX, not Unix, etc) systems.
1128
1129 You should also check out the Frequently Asked Questions list in
1130 comp.unix.* for things like this: the answer is essentially the same.
1131 It's very system dependent.  Here's one solution that works on BSD
1132 systems:
1133
1134         sub key_ready {
1135                 my($rin, $nfd);
1136                 vec($rin, fileno(STDIN), 1) = 1;
1137                 return $nfd = select($rin,undef,undef,0);
1138                 }
1139
1140 If you want to find out how many characters are waiting, there's
1141 also the FIONREAD ioctl call to be looked at.  The I<h2ph> tool that
1142 comes with Perl tries to convert C include files to Perl code, which
1143 can be C<require>d.  FIONREAD ends up defined as a function in the
1144 I<sys/ioctl.ph> file:
1145
1146         require 'sys/ioctl.ph';
1147
1148         $size = pack("L", 0);
1149         ioctl(FH, FIONREAD(), $size)    or die "Couldn't call ioctl: $!\n";
1150         $size = unpack("L", $size);
1151
1152 If I<h2ph> wasn't installed or doesn't work for you, you can
1153 I<grep> the include files by hand:
1154
1155         % grep FIONREAD /usr/include/*/*
1156         /usr/include/asm/ioctls.h:#define FIONREAD      0x541B
1157
1158 Or write a small C program using the editor of champions:
1159
1160         % cat > fionread.c
1161         #include <sys/ioctl.h>
1162         main() {
1163             printf("%#08x\n", FIONREAD);
1164         }
1165         ^D
1166         % cc -o fionread fionread.c
1167         % ./fionread
1168         0x4004667f
1169
1170 And then hard code it, leaving porting as an exercise to your successor.
1171
1172         $FIONREAD = 0x4004667f;         # XXX: opsys dependent
1173
1174         $size = pack("L", 0);
1175         ioctl(FH, $FIONREAD, $size)     or die "Couldn't call ioctl: $!\n";
1176         $size = unpack("L", $size);
1177
1178 FIONREAD requires a filehandle connected to a stream, meaning that sockets,
1179 pipes, and tty devices work, but I<not> files.
1180
1181 =head2 How do I do a C<tail -f> in perl?
1182 X<tail> X<IO::Handle> X<File::Tail> X<clearerr>
1183
1184 First try
1185
1186         seek(GWFILE, 0, 1);
1187
1188 The statement C<seek(GWFILE, 0, 1)> doesn't change the current position,
1189 but it does clear the end-of-file condition on the handle, so that the
1190 next C<< <GWFILE> >> makes Perl try again to read something.
1191
1192 If that doesn't work (it relies on features of your stdio implementation),
1193 then you need something more like this:
1194
1195         for (;;) {
1196           for ($curpos = tell(GWFILE); <GWFILE>; $curpos = tell(GWFILE)) {
1197             # search for some stuff and put it into files
1198           }
1199           # sleep for a while
1200           seek(GWFILE, $curpos, 0);  # seek to where we had been
1201         }
1202
1203 If this still doesn't work, look into the C<clearerr> method
1204 from C<IO::Handle>, which resets the error and end-of-file states
1205 on the handle.
1206
1207 There's also a C<File::Tail> module from CPAN.
1208
1209 =head2 How do I dup() a filehandle in Perl?
1210 X<dup>
1211
1212 If you check L<perlfunc/open>, you'll see that several of the ways
1213 to call open() should do the trick.  For example:
1214
1215         open(LOG, ">>/foo/logfile");
1216         open(STDERR, ">&LOG");
1217
1218 Or even with a literal numeric descriptor:
1219
1220    $fd = $ENV{MHCONTEXTFD};
1221    open(MHCONTEXT, "<&=$fd");   # like fdopen(3S)
1222
1223 Note that "<&STDIN" makes a copy, but "<&=STDIN" make
1224 an alias.  That means if you close an aliased handle, all
1225 aliases become inaccessible.  This is not true with
1226 a copied one.
1227
1228 Error checking, as always, has been left as an exercise for the reader.
1229
1230 =head2 How do I close a file descriptor by number?
1231 X<file, closing file descriptors> X<POSIX> X<close>
1232
1233 If, for some reason, you have a file descriptor instead of a
1234 filehandle (perhaps you used C<POSIX::open>), you can use the
1235 C<close()> function from the C<POSIX> module:
1236
1237         use POSIX ();
1238
1239         POSIX::close( $fd );
1240
1241 This should rarely be necessary, as the Perl C<close()> function is to be
1242 used for things that Perl opened itself, even if it was a dup of a
1243 numeric descriptor as with C<MHCONTEXT> above.  But if you really have
1244 to, you may be able to do this:
1245
1246         require 'sys/syscall.ph';
1247         $rc = syscall(&SYS_close, $fd + 0);  # must force numeric
1248         die "can't sysclose $fd: $!" unless $rc == -1;
1249
1250 Or, just use the fdopen(3S) feature of C<open()>:
1251
1252         {
1253         open my( $fh ), "<&=$fd" or die "Cannot reopen fd=$fd: $!";
1254         close $fh;
1255         }
1256
1257 =head2 Why can't I use "C:\temp\foo" in DOS paths?  Why doesn't `C:\temp\foo.exe` work?
1258 X<filename, DOS issues>
1259
1260 Whoops!  You just put a tab and a formfeed into that filename!
1261 Remember that within double quoted strings ("like\this"), the
1262 backslash is an escape character.  The full list of these is in
1263 L<perlop/Quote and Quote-like Operators>.  Unsurprisingly, you don't
1264 have a file called "c:(tab)emp(formfeed)oo" or
1265 "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
1266
1267 Either single-quote your strings, or (preferably) use forward slashes.
1268 Since all DOS and Windows versions since something like MS-DOS 2.0 or so
1269 have treated C</> and C<\> the same in a path, you might as well use the
1270 one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
1271 awk, Tcl, Java, or Python, just to mention a few.  POSIX paths
1272 are more portable, too.
1273
1274 =head2 Why doesn't glob("*.*") get all the files?
1275 X<glob>
1276
1277 Because even on non-Unix ports, Perl's glob function follows standard
1278 Unix globbing semantics.  You'll need C<glob("*")> to get all (non-hidden)
1279 files.  This makes glob() portable even to legacy systems.  Your
1280 port may include proprietary globbing functions as well.  Check its
1281 documentation for details.
1282
1283 =head2 Why does Perl let me delete read-only files?  Why does C<-i> clobber protected files?  Isn't this a bug in Perl?
1284
1285 This is elaborately and painstakingly described in the
1286 F<file-dir-perms> article in the "Far More Than You Ever Wanted To
1287 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
1288
1289 The executive summary: learn how your filesystem works.  The
1290 permissions on a file say what can happen to the data in that file.
1291 The permissions on a directory say what can happen to the list of
1292 files in that directory.  If you delete a file, you're removing its
1293 name from the directory (so the operation depends on the permissions
1294 of the directory, not of the file).  If you try to write to the file,
1295 the permissions of the file govern whether you're allowed to.
1296
1297 =head2 How do I select a random line from a file?
1298 X<file, selecting a random line>
1299
1300 Short of loading the file into a database or pre-indexing the lines in
1301 the file, there are a couple of things that you can do.
1302
1303 Here's a reservoir-sampling algorithm from the Camel Book:
1304
1305         srand;
1306         rand($.) < 1 && ($line = $_) while <>;
1307
1308 This has a significant advantage in space over reading the whole file
1309 in.  You can find a proof of this method in I<The Art of Computer
1310 Programming>, Volume 2, Section 3.4.2, by Donald E. Knuth.
1311
1312 You can use the C<File::Random> module which provides a function
1313 for that algorithm:
1314
1315         use File::Random qw/random_line/;
1316         my $line = random_line($filename);
1317
1318 Another way is to use the C<Tie::File> module, which treats the entire
1319 file as an array.  Simply access a random array element.
1320
1321 =head2 Why do I get weird spaces when I print an array of lines?
1322
1323 (contributed by brian d foy)
1324
1325 If you are seeing spaces between the elements of your array when
1326 you print the array, you are probably interpolating the array in
1327 double quotes:
1328
1329         my @animals = qw(camel llama alpaca vicuna);
1330         print "animals are: @animals\n";
1331
1332 It's the double quotes, not the C<print>, doing this. Whenever you
1333 interpolate an array in a double quote context, Perl joins the
1334 elements with spaces (or whatever is in C<$">, which is a space by
1335 default):
1336
1337         animals are: camel llama alpaca vicuna
1338
1339 This is different than printing the array without the interpolation:
1340
1341         my @animals = qw(camel llama alpaca vicuna);
1342         print "animals are: ", @animals, "\n";
1343
1344 Now the output doesn't have the spaces between the elements because
1345 the elements of C<@animals> simply become part of the list to
1346 C<print>:
1347
1348         animals are: camelllamaalpacavicuna
1349
1350 You might notice this when each of the elements of C<@array> end with
1351 a newline. You expect to print one element per line, but notice that
1352 every line after the first is indented:
1353
1354         this is a line
1355          this is another line
1356          this is the third line
1357
1358 That extra space comes from the interpolation of the array. If you
1359 don't want to put anything between your array elements, don't use the
1360 array in double quotes. You can send it to print without them:
1361
1362         print @lines;
1363
1364 =head2 How do I traverse a directory tree?
1365
1366 (contributed by brian d foy)
1367
1368 The C<File::Find> module, which comes with Perl, does all of the hard
1369 work to traverse a directory structure. It comes with Perl. You simply
1370 call the C<find> subroutine with a callback subroutine and the
1371 directories you want to traverse:
1372
1373         use File::Find;
1374
1375         find( \&wanted, @directories );
1376
1377         sub wanted {
1378                 # full path in $File::Find::name
1379                 # just filename in $_
1380                 ... do whatever you want to do ...
1381                 }
1382
1383 The C<File::Find::Closures>, which you can download from CPAN, provides
1384 many ready-to-use subroutines that you can use with C<File::Find>.
1385
1386 The C<File::Finder>, which you can download from CPAN, can help you
1387 create the callback subroutine using something closer to the syntax of
1388 the C<find> command-line utility:
1389
1390         use File::Find;
1391         use File::Finder;
1392
1393         my $deep_dirs = File::Finder->depth->type('d')->ls->exec('rmdir','{}');
1394
1395         find( $deep_dirs->as_options, @places );
1396
1397 The C<File::Find::Rule> module, which you can download from CPAN, has
1398 a similar interface, but does the traversal for you too:
1399
1400         use File::Find::Rule;
1401
1402         my @files = File::Find::Rule->file()
1403                                                          ->name( '*.pm' )
1404                                                          ->in( @INC );
1405
1406 =head2 How do I delete a directory tree?
1407
1408 (contributed by brian d foy)
1409
1410 If you have an empty directory, you can use Perl's built-in C<rmdir>. If
1411 the directory is not empty (so, no files or subdirectories), you either
1412 have to empty it yourself (a lot of work) or use a module to help you.
1413
1414 The C<File::Path> module, which comes with Perl, has a C<rmtree> which
1415 can take care of all of the hard work for you:
1416
1417         use File::Path qw(rmtree);
1418
1419         rmtree( \@directories, 0, 0 );
1420
1421 The first argument to C<rmtree> is either a string representing a directory path
1422 or an array reference. The second argument controls progress messages, and the
1423 third argument controls the handling of files you don't have permissions to
1424 delete. See the C<File::Path> module for the details.
1425
1426 =head2 How do I copy an entire directory?
1427
1428 (contributed by Shlomi Fish)
1429
1430 To do the equivalent of C<cp -R> (i.e. copy an entire directory tree
1431 recursively) in portable Perl, you'll either need to write something yourself
1432 or find a good CPAN module such as  L<File::Copy::Recursive>.
1433 =head1 REVISION
1434
1435 Revision: $Revision$
1436
1437 Date: $Date$
1438
1439 See L<perlfaq> for source control details and availability.
1440
1441 =head1 AUTHOR AND COPYRIGHT
1442
1443 Copyright (c) 1997-2009 Tom Christiansen, Nathan Torkington, and
1444 other authors as noted. All rights reserved.
1445
1446 This documentation is free; you can redistribute it and/or modify it
1447 under the same terms as Perl itself.
1448
1449 Irrespective of its distribution, all code examples here are in the public
1450 domain.  You are permitted and encouraged to use this code and any
1451 derivatives thereof in your own programs for fun or for profit as you
1452 see fit.  A simple comment in the code giving credit to the FAQ would
1453 be courteous but is not required.