3 perlfaq5 - Files and Formats ($Revision: 1.35 $, $Date: 2005/01/21 12:26:11 $)
7 This section deals with I/O and the "f" issues: filehandles, flushing,
10 =head2 How do I flush/unbuffer an output filehandle? Why must I do this?
12 Perl does not support truly unbuffered output (except
13 insofar as you can C<syswrite(OUT, $char, 1)>), although it
14 does support is "command buffering", in which a physical
15 write is performed after every output command.
17 The C standard I/O library (stdio) normally buffers
18 characters sent to devices so that there isn't a system call
19 for each byte. In most stdio implementations, the type of
20 output buffering and the size of the buffer varies according
21 to the type of device. Perl's print() and write() functions
22 normally buffer output, while syswrite() bypasses buffering
25 If you want your output to be sent immediately when you
26 execute print() or write() (for instance, for some network
27 protocols), you must set the handle's autoflush flag. This
28 flag is the Perl variable $| and when it is set to a true
29 value, Perl will flush the handle's buffer after each
30 print() or write(). Setting $| affects buffering only for
31 the currently selected default file handle. You choose this
32 handle with the one argument select() call (see
33 L<perlvar/$E<verbar>> and L<perlfunc/select>).
35 Use select() to choose the desired handle, then set its
36 per-filehandle variables.
38 $old_fh = select(OUTPUT_HANDLE);
42 Some idioms can handle this in a single statement:
44 select((select(OUTPUT_HANDLE), $| = 1)[0]);
46 $| = 1, select $_ for select OUTPUT_HANDLE;
48 Some modules offer object-oriented access to handles and their
49 variables, although they may be overkill if this is the only
50 thing you do with them. You can use IO::Handle:
53 open(DEV, ">/dev/printer"); # but is this?
58 use IO::Socket; # this one is kinda a pipe?
59 my $sock = IO::Socket::INET->new( 'www.example.com:80' ) ;
63 =head2 How do I change one line in a file/delete a line in a file/insert a line in the middle of a file/append to the beginning of a file?
65 Use the Tie::File module, which is included in the standard
66 distribution since Perl 5.8.0.
68 =head2 How do I count the number of lines in a file?
70 One fairly efficient way is to count newlines in the file. The
71 following program uses a feature of tr///, as documented in L<perlop>.
72 If your text file doesn't end with a newline, then it's not really a
73 proper text file, so this may report one fewer line than you expect.
76 open(FILE, $filename) or die "Can't open `$filename': $!";
77 while (sysread FILE, $buffer, 4096) {
78 $lines += ($buffer =~ tr/\n//);
82 This assumes no funny games with newline translations.
84 =head2 How can I use Perl's C<-i> option from within a program?
86 C<-i> sets the value of Perl's C<$^I> variable, which in turn affects
87 the behavior of C<< <> >>; see L<perlrun> for more details. By
88 modifying the appropriate variables directly, you can get the same
89 behavior within a larger program. For example:
93 local($^I, @ARGV) = ('.orig', glob("*.c"));
96 print "This line should appear at the top of each file\n";
98 s/\b(p)earl\b/${1}erl/i; # Correct typos, preserving case
100 close ARGV if eof; # Reset $.
103 # $^I and @ARGV return to their old values here
105 This block modifies all the C<.c> files in the current directory,
106 leaving a backup of the original data from each file in a new
109 =head2 How can I copy a file?
111 (contributed by brian d foy)
113 Use the File::Copy module. It comes with Perl and can do a
114 true copy across file systems, and it does its magic in
119 copy( $original, $new_copy ) or die "Copy failed: $!";
121 If you can't use File::Copy, you'll have to do the work yourself:
122 open the original file, open the destination file, then print
123 to the destination file as you read the original.
125 =head2 How do I make a temporary file name?
127 If you don't need to know the name of the file, you can use C<open()>
128 with C<undef> in place of the file name. The C<open()> function
129 creates an anonymous temporary file.
131 open my $tmp, '+>', undef or die $!;
133 Otherwise, you can use the File::Temp module.
135 use File::Temp qw/ tempfile tempdir /;
137 $dir = tempdir( CLEANUP => 1 );
138 ($fh, $filename) = tempfile( DIR => $dir );
140 # or if you don't need to know the filename
142 $fh = tempfile( DIR => $dir );
144 The File::Temp has been a standard module since Perl 5.6.1. If you
145 don't have a modern enough Perl installed, use the C<new_tmpfile>
146 class method from the IO::File module to get a filehandle opened for
147 reading and writing. Use it if you don't need to know the file's name:
150 $fh = IO::File->new_tmpfile()
151 or die "Unable to make new temporary file: $!";
153 If you're committed to creating a temporary file by hand, use the
154 process ID and/or the current time-value. If you need to have many
155 temporary files in one process, use a counter:
159 my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
160 my $base_name = sprintf("%s/%d-%d-0000", $temp_dir, $$, time());
164 until (defined(fileno(FH)) || $count++ > 100) {
165 $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
166 # O_EXCL is required for security reasons.
167 sysopen(FH, $base_name, O_WRONLY|O_EXCL|O_CREAT);
169 if (defined(fileno(FH))
170 return (*FH, $base_name);
177 =head2 How can I manipulate fixed-record-length files?
179 The most efficient way is using L<pack()|perlfunc/"pack"> and
180 L<unpack()|perlfunc/"unpack">. This is faster than using
181 L<substr()|perlfunc/"substr"> when taking many, many strings. It is
182 slower for just a few.
184 Here is a sample chunk of code to break up and put back together again
185 some fixed-format input lines, in this case from the output of a normal,
189 # 15158 p5 T 0:00 perl /home/tchrist/scripts/now-what
190 my $PS_T = 'A6 A4 A7 A5 A*';
191 open my $ps, '-|', 'ps';
193 my @fields = qw( pid tt stat time command );
196 @process{@fields} = unpack($PS_T, $_);
197 for my $field ( @fields ) {
198 print "$field: <$process{$field}>\n";
200 print 'line=', pack($PS_T, @process{@fields} ), "\n";
203 We've used a hash slice in order to easily handle the fields of each row.
204 Storing the keys in an array means it's easy to operate on them as a
205 group or loop over them with for. It also avoids polluting the program
206 with global variables and using symbolic references.
208 =head2 How can I make a filehandle local to a subroutine? How do I pass filehandles between subroutines? How do I make an array of filehandles?
210 As of perl5.6, open() autovivifies file and directory handles
211 as references if you pass it an uninitialized scalar variable.
212 You can then pass these references just like any other scalar,
213 and use them in the place of named handles.
215 open my $fh, $file_name;
217 open local $fh, $file_name;
219 print $fh "Hello World!\n";
223 Before perl5.6, you had to deal with various typeglob idioms
224 which you may see in older code.
226 open FILE, "> $filename";
227 process_typeglob( *FILE );
228 process_reference( \*FILE );
230 sub process_typeglob { local *FH = shift; print FH "Typeglob!" }
231 sub process_reference { local $fh = shift; print $fh "Reference!" }
233 If you want to create many anonymous handles, you should
234 check out the Symbol or IO::Handle modules.
236 =head2 How can I use a filehandle indirectly?
238 An indirect filehandle is using something other than a symbol
239 in a place that a filehandle is expected. Here are ways
240 to get indirect filehandles:
242 $fh = SOME_FH; # bareword is strict-subs hostile
243 $fh = "SOME_FH"; # strict-refs hostile; same package only
244 $fh = *SOME_FH; # typeglob
245 $fh = \*SOME_FH; # ref to typeglob (bless-able)
246 $fh = *SOME_FH{IO}; # blessed IO::Handle from *SOME_FH typeglob
248 Or, you can use the C<new> method from one of the IO::* modules to
249 create an anonymous filehandle, store that in a scalar variable,
250 and use it as though it were a normal filehandle.
252 use IO::Handle; # 5.004 or higher
253 $fh = IO::Handle->new();
255 Then use any of those as you would a normal filehandle. Anywhere that
256 Perl is expecting a filehandle, an indirect filehandle may be used
257 instead. An indirect filehandle is just a scalar variable that contains
258 a filehandle. Functions like C<print>, C<open>, C<seek>, or
259 the C<< <FH> >> diamond operator will accept either a named filehandle
260 or a scalar variable containing one:
262 ($ifh, $ofh, $efh) = (*STDIN, *STDOUT, *STDERR);
263 print $ofh "Type it: ";
265 print $efh "What was that: $got";
267 If you're passing a filehandle to a function, you can write
268 the function in two ways:
272 print $fh "Sending to indirect filehandle\n";
275 Or it can localize a typeglob and use the filehandle directly:
279 print FH "Sending to localized filehandle\n";
282 Both styles work with either objects or typeglobs of real filehandles.
283 (They might also work with strings under some circumstances, but this
289 In the examples above, we assigned the filehandle to a scalar variable
290 before using it. That is because only simple scalar variables, not
291 expressions or subscripts of hashes or arrays, can be used with
292 built-ins like C<print>, C<printf>, or the diamond operator. Using
293 something other than a simple scalar variable as a filehandle is
294 illegal and won't even compile:
296 @fd = (*STDIN, *STDOUT, *STDERR);
297 print $fd[1] "Type it: "; # WRONG
298 $got = <$fd[0]> # WRONG
299 print $fd[2] "What was that: $got"; # WRONG
301 With C<print> and C<printf>, you get around this by using a block and
302 an expression where you would place the filehandle:
304 print { $fd[1] } "funny stuff\n";
305 printf { $fd[1] } "Pity the poor %x.\n", 3_735_928_559;
306 # Pity the poor deadbeef.
308 That block is a proper block like any other, so you can put more
309 complicated code there. This sends the message out to one of two places:
312 print { $ok ? $fd[1] : $fd[2] } "cat stat $ok\n";
313 print { $fd[ 1+ ($ok || 0) ] } "cat stat $ok\n";
315 This approach of treating C<print> and C<printf> like object methods
316 calls doesn't work for the diamond operator. That's because it's a
317 real operator, not just a function with a comma-less argument. Assuming
318 you've been storing typeglobs in your structure as we did above, you
319 can use the built-in function named C<readline> to read a record just
320 as C<< <> >> does. Given the initialization shown above for @fd, this
321 would work, but only because readline() requires a typeglob. It doesn't
322 work with objects or strings, which might be a bug we haven't fixed yet.
324 $got = readline($fd[0]);
326 Let it be noted that the flakiness of indirect filehandles is not
327 related to whether they're strings, typeglobs, objects, or anything else.
328 It's the syntax of the fundamental operators. Playing the object
329 game doesn't help you at all here.
331 =head2 How can I set up a footer format to be used with write()?
333 There's no builtin way to do this, but L<perlform> has a couple of
334 techniques to make it possible for the intrepid hacker.
336 =head2 How can I write() into a string?
338 See L<perlform/"Accessing Formatting Internals"> for an swrite() function.
340 =head2 How can I output my numbers with commas added?
342 This subroutine will add commas to your number:
346 1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
350 This regex from Benjamin Goldberg will add commas to numbers:
352 s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
354 It is easier to see with comments:
357 ^[-+]? # beginning of number.
358 \d+? # first digits before first comma
359 (?= # followed by, (but not included in the match) :
360 (?>(?:\d{3})+) # some positive multiple of three digits.
361 (?!\d) # an *exact* multiple, not x * 3 + 1 or whatever.
364 \G\d{3} # after the last group, get three digits
365 (?=\d) # but they have to have more digits after them.
368 =head2 How can I translate tildes (~) in a filename?
370 Use the <> (glob()) operator, documented in L<perlfunc>. Older
371 versions of Perl require that you have a shell installed that groks
372 tildes. Recent perl versions have this feature built in. The
373 File::KGlob module (available from CPAN) gives more portable glob
376 Within Perl, you may use this directly:
379 ^ ~ # find a leading tilde
381 [^/] # a non-slash character
382 * # repeated 0 or more times (0 means me)
387 : ( $ENV{HOME} || $ENV{LOGDIR} )
390 =head2 How come when I open a file read-write it wipes it out?
392 Because you're using something like this, which truncates the file and
393 I<then> gives you read-write access:
395 open(FH, "+> /path/name"); # WRONG (almost always)
397 Whoops. You should instead use this, which will fail if the file
400 open(FH, "+< /path/name"); # open for update
402 Using ">" always clobbers or creates. Using "<" never does
403 either. The "+" doesn't change this.
405 Here are examples of many kinds of file opens. Those using sysopen()
410 To open file for reading:
412 open(FH, "< $path") || die $!;
413 sysopen(FH, $path, O_RDONLY) || die $!;
415 To open file for writing, create new file if needed or else truncate old file:
417 open(FH, "> $path") || die $!;
418 sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT) || die $!;
419 sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666) || die $!;
421 To open file for writing, create new file, file must not exist:
423 sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT) || die $!;
424 sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT, 0666) || die $!;
426 To open file for appending, create if necessary:
428 open(FH, ">> $path") || die $!;
429 sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT) || die $!;
430 sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT, 0666) || die $!;
432 To open file for appending, file must exist:
434 sysopen(FH, $path, O_WRONLY|O_APPEND) || die $!;
436 To open file for update, file must exist:
438 open(FH, "+< $path") || die $!;
439 sysopen(FH, $path, O_RDWR) || die $!;
441 To open file for update, create file if necessary:
443 sysopen(FH, $path, O_RDWR|O_CREAT) || die $!;
444 sysopen(FH, $path, O_RDWR|O_CREAT, 0666) || die $!;
446 To open file for update, file must not exist:
448 sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT) || die $!;
449 sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT, 0666) || die $!;
451 To open a file without blocking, creating if necessary:
453 sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT)
454 or die "can't open /foo/somefile: $!":
456 Be warned that neither creation nor deletion of files is guaranteed to
457 be an atomic operation over NFS. That is, two processes might both
458 successfully create or unlink the same file! Therefore O_EXCL
459 isn't as exclusive as you might wish.
461 See also the new L<perlopentut> if you have it (new for 5.6).
463 =head2 Why do I sometimes get an "Argument list too long" when I use E<lt>*E<gt>?
465 The C<< <> >> operator performs a globbing operation (see above).
466 In Perl versions earlier than v5.6.0, the internal glob() operator forks
467 csh(1) to do the actual glob expansion, but
468 csh can't handle more than 127 items and so gives the error message
469 C<Argument list too long>. People who installed tcsh as csh won't
470 have this problem, but their users may be surprised by it.
472 To get around this, either upgrade to Perl v5.6.0 or later, do the glob
473 yourself with readdir() and patterns, or use a module like File::KGlob,
474 one that doesn't use the shell to do globbing.
476 =head2 Is there a leak/bug in glob()?
478 Due to the current implementation on some operating systems, when you
479 use the glob() function or its angle-bracket alias in a scalar
480 context, you may cause a memory leak and/or unpredictable behavior. It's
481 best therefore to use glob() only in list context.
483 =head2 How can I open a file with a leading ">" or trailing blanks?
485 Normally perl ignores trailing blanks in filenames, and interprets
486 certain leading characters (or a trailing "|") to mean something
489 The three argument form of open() lets you specify the mode
490 separately from the filename. The open() function treats
491 special mode characters and whitespace in the filename as
494 open FILE, "<", " file "; # filename is " file "
495 open FILE, ">", ">file"; # filename is ">file"
497 It may be a lot clearer to use sysopen(), though:
500 $badpath = "<<<something really wicked ";
501 sysopen (FH, $badpath, O_WRONLY | O_CREAT | O_TRUNC)
502 or die "can't open $badpath: $!";
504 =head2 How can I reliably rename a file?
506 If your operating system supports a proper mv(1) utility or its
507 functional equivalent, this works:
509 rename($old, $new) or system("mv", $old, $new);
511 It may be more portable to use the File::Copy module instead.
512 You just copy to the new file to the new name (checking return
513 values), then delete the old one. This isn't really the same
514 semantically as a rename(), which preserves meta-information like
515 permissions, timestamps, inode info, etc.
517 Newer versions of File::Copy export a move() function.
519 =head2 How can I lock a file?
521 Perl's builtin flock() function (see L<perlfunc> for details) will call
522 flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and
523 later), and lockf(3) if neither of the two previous system calls exists.
524 On some systems, it may even use a different form of native locking.
525 Here are some gotchas with Perl's flock():
531 Produces a fatal error if none of the three system calls (or their
532 close equivalent) exists.
536 lockf(3) does not provide shared locking, and requires that the
537 filehandle be open for writing (or appending, or read/writing).
541 Some versions of flock() can't lock files over a network (e.g. on NFS file
542 systems), so you'd need to force the use of fcntl(2) when you build Perl.
543 But even this is dubious at best. See the flock entry of L<perlfunc>
544 and the F<INSTALL> file in the source distribution for information on
545 building Perl to do this.
547 Two potentially non-obvious but traditional flock semantics are that
548 it waits indefinitely until the lock is granted, and that its locks are
549 I<merely advisory>. Such discretionary locks are more flexible, but
550 offer fewer guarantees. This means that files locked with flock() may
551 be modified by programs that do not also use flock(). Cars that stop
552 for red lights get on well with each other, but not with cars that don't
553 stop for red lights. See the perlport manpage, your port's specific
554 documentation, or your system-specific local manpages for details. It's
555 best to assume traditional behavior if you're writing portable programs.
556 (If you're not, you should as always feel perfectly free to write
557 for your own system's idiosyncrasies (sometimes called "features").
558 Slavish adherence to portability concerns shouldn't get in the way of
559 your getting your job done.)
561 For more information on file locking, see also
562 L<perlopentut/"File Locking"> if you have it (new for 5.6).
566 =head2 Why can't I just open(FH, "E<gt>file.lock")?
568 A common bit of code B<NOT TO USE> is this:
570 sleep(3) while -e "file.lock"; # PLEASE DO NOT USE
571 open(LCK, "> file.lock"); # THIS BROKEN CODE
573 This is a classic race condition: you take two steps to do something
574 which must be done in one. That's why computer hardware provides an
575 atomic test-and-set instruction. In theory, this "ought" to work:
577 sysopen(FH, "file.lock", O_WRONLY|O_EXCL|O_CREAT)
578 or die "can't open file.lock: $!";
580 except that lamentably, file creation (and deletion) is not atomic
581 over NFS, so this won't work (at least, not every time) over the net.
582 Various schemes involving link() have been suggested, but
583 these tend to involve busy-wait, which is also subdesirable.
585 =head2 I still don't get locking. I just want to increment the number in the file. How can I do this?
587 Didn't anyone ever tell you web-page hit counters were useless?
588 They don't count number of hits, they're a waste of time, and they serve
589 only to stroke the writer's vanity. It's better to pick a random number;
590 they're more realistic.
592 Anyway, this is what you can do if you can't help yourself.
594 use Fcntl qw(:DEFAULT :flock);
595 sysopen(FH, "numfile", O_RDWR|O_CREAT) or die "can't open numfile: $!";
596 flock(FH, LOCK_EX) or die "can't flock numfile: $!";
598 seek(FH, 0, 0) or die "can't rewind numfile: $!";
599 truncate(FH, 0) or die "can't truncate numfile: $!";
600 (print FH $num+1, "\n") or die "can't write numfile: $!";
601 close FH or die "can't close numfile: $!";
603 Here's a much better web-page hit counter:
605 $hits = int( (time() - 850_000_000) / rand(1_000) );
607 If the count doesn't impress your friends, then the code might. :-)
609 =head2 All I want to do is append a small amount of text to the end of a file. Do I still have to use locking?
611 If you are on a system that correctly implements flock() and you use the
612 example appending code from "perldoc -f flock" everything will be OK
613 even if the OS you are on doesn't implement append mode correctly (if
614 such a system exists.) So if you are happy to restrict yourself to OSs
615 that implement flock() (and that's not really much of a restriction)
616 then that is what you should do.
618 If you know you are only going to use a system that does correctly
619 implement appending (i.e. not Win32) then you can omit the seek() from
622 If you know you are only writing code to run on an OS and filesystem that
623 does implement append mode correctly (a local filesystem on a modern
624 Unix for example), and you keep the file in block-buffered mode and you
625 write less than one buffer-full of output between each manual flushing
626 of the buffer then each bufferload is almost guaranteed to be written to
627 the end of the file in one chunk without getting intermingled with
628 anyone else's output. You can also use the syswrite() function which is
629 simply a wrapper around your systems write(2) system call.
631 There is still a small theoretical chance that a signal will interrupt
632 the system level write() operation before completion. There is also a
633 possibility that some STDIO implementations may call multiple system
634 level write()s even if the buffer was empty to start. There may be some
635 systems where this probability is reduced to zero.
637 =head2 How do I randomly update a binary file?
639 If you're just trying to patch a binary, in many cases something as
640 simple as this works:
642 perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
644 However, if you have fixed sized records, then you might do something more
647 $RECSIZE = 220; # size of record, in bytes
648 $recno = 37; # which record to update
649 open(FH, "+<somewhere") || die "can't update somewhere: $!";
650 seek(FH, $recno * $RECSIZE, 0);
651 read(FH, $record, $RECSIZE) == $RECSIZE || die "can't read record $recno: $!";
653 seek(FH, -$RECSIZE, 1);
657 Locking and error checking are left as an exercise for the reader.
658 Don't forget them or you'll be quite sorry.
660 =head2 How do I get a file's timestamp in perl?
662 If you want to retrieve the time at which the file was last
663 read, written, or had its meta-data (owner, etc) changed,
664 you use the B<-M>, B<-A>, or B<-C> file test operations as
665 documented in L<perlfunc>. These retrieve the age of the
666 file (measured against the start-time of your program) in
667 days as a floating point number. Some platforms may not have
668 all of these times. See L<perlport> for details. To
669 retrieve the "raw" time in seconds since the epoch, you
670 would call the stat function, then use localtime(),
671 gmtime(), or POSIX::strftime() to convert this into
676 $write_secs = (stat($file))[9];
677 printf "file %s updated at %s\n", $file,
678 scalar localtime($write_secs);
680 If you prefer something more legible, use the File::stat module
681 (part of the standard distribution in version 5.004 and later):
683 # error checking left as an exercise for reader.
686 $date_string = ctime(stat($file)->mtime);
687 print "file $file updated at $date_string\n";
689 The POSIX::strftime() approach has the benefit of being,
690 in theory, independent of the current locale. See L<perllocale>
693 =head2 How do I set a file's timestamp in perl?
695 You use the utime() function documented in L<perlfunc/utime>.
696 By way of example, here's a little program that copies the
697 read and write times from its first argument to all the rest
701 die "usage: cptimes timestamp_file other_files ...\n";
704 ($atime, $mtime) = (stat($timestamp))[8,9];
705 utime $atime, $mtime, @ARGV;
707 Error checking is, as usual, left as an exercise for the reader.
709 The perldoc for utime also has an example that has the same
710 effect as touch(1) on files that I<already exist>.
712 Certain file systems have a limited ability to store the times
713 on a file at the expected level of precision. For example, the
714 FAT and HPFS filesystem are unable to create dates on files with
715 a finer granularity than two seconds. This is a limitation of
716 the filesystems, not of utime().
718 =head2 How do I print to more than one file at once?
720 To connect one filehandle to several output filehandles,
721 you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
723 If you only have to do this once, you can print individually
726 for $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
728 =head2 How can I read in an entire file all at once?
730 You can use the File::Slurp module to do it in one step.
734 $all_of_it = read_file($filename); # entire file in scalar
735 @all_lines = read_file($filename); # one line perl element
737 The customary Perl approach for processing all the lines in a file is to
738 do so one line at a time:
740 open (INPUT, $file) || die "can't open $file: $!";
743 # do something with $_
745 close(INPUT) || die "can't close $file: $!";
747 This is tremendously more efficient than reading the entire file into
748 memory as an array of lines and then processing it one element at a time,
749 which is often--if not almost always--the wrong approach. Whenever
750 you see someone do this:
754 you should think long and hard about why you need everything loaded at
755 once. It's just not a scalable solution. You might also find it more
756 fun to use the standard Tie::File module, or the DB_File module's
757 $DB_RECNO bindings, which allow you to tie an array to a file so that
758 accessing an element the array actually accesses the corresponding
761 You can read the entire filehandle contents into a scalar.
765 open (INPUT, $file) || die "can't open $file: $!";
769 That temporarily undefs your record separator, and will automatically
770 close the file at block exit. If the file is already open, just use this:
772 $var = do { local $/; <INPUT> };
774 For ordinary files you can also use the read function.
776 read( INPUT, $var, -s INPUT );
778 The third argument tests the byte size of the data on the INPUT filehandle
779 and reads that many bytes into the buffer $var.
781 =head2 How can I read in a file by paragraphs?
783 Use the C<$/> variable (see L<perlvar> for details). You can either
784 set it to C<""> to eliminate empty paragraphs (C<"abc\n\n\n\ndef">,
785 for instance, gets treated as two paragraphs and not three), or
786 C<"\n\n"> to accept empty paragraphs.
788 Note that a blank line must have no blanks in it. Thus
789 S<C<"fred\n \nstuff\n\n">> is one paragraph, but C<"fred\n\nstuff\n\n"> is two.
791 =head2 How can I read a single character from a file? From the keyboard?
793 You can use the builtin C<getc()> function for most filehandles, but
794 it won't (easily) work on a terminal device. For STDIN, either use
795 the Term::ReadKey module from CPAN or use the sample code in
798 If your system supports the portable operating system programming
799 interface (POSIX), you can use the following code, which you'll note
800 turns off echo processing as well.
814 use POSIX qw(:termios_h);
816 my ($term, $oterm, $echo, $noecho, $fd_stdin);
818 $fd_stdin = fileno(STDIN);
820 $term = POSIX::Termios->new();
821 $term->getattr($fd_stdin);
822 $oterm = $term->getlflag();
824 $echo = ECHO | ECHOK | ICANON;
825 $noecho = $oterm & ~$echo;
828 $term->setlflag($noecho);
829 $term->setcc(VTIME, 1);
830 $term->setattr($fd_stdin, TCSANOW);
834 $term->setlflag($oterm);
835 $term->setcc(VTIME, 0);
836 $term->setattr($fd_stdin, TCSANOW);
842 sysread(STDIN, $key, 1);
851 The Term::ReadKey module from CPAN may be easier to use. Recent versions
852 include also support for non-portable systems as well.
855 open(TTY, "</dev/tty");
856 print "Gimme a char: ";
858 $key = ReadKey 0, *TTY;
860 printf "\nYou said %s, char number %03d\n",
863 =head2 How can I tell whether there's a character waiting on a filehandle?
865 The very first thing you should do is look into getting the Term::ReadKey
866 extension from CPAN. As we mentioned earlier, it now even has limited
867 support for non-portable (read: not open systems, closed, proprietary,
868 not POSIX, not Unix, etc) systems.
870 You should also check out the Frequently Asked Questions list in
871 comp.unix.* for things like this: the answer is essentially the same.
872 It's very system dependent. Here's one solution that works on BSD
877 vec($rin, fileno(STDIN), 1) = 1;
878 return $nfd = select($rin,undef,undef,0);
881 If you want to find out how many characters are waiting, there's
882 also the FIONREAD ioctl call to be looked at. The I<h2ph> tool that
883 comes with Perl tries to convert C include files to Perl code, which
884 can be C<require>d. FIONREAD ends up defined as a function in the
885 I<sys/ioctl.ph> file:
887 require 'sys/ioctl.ph';
889 $size = pack("L", 0);
890 ioctl(FH, FIONREAD(), $size) or die "Couldn't call ioctl: $!\n";
891 $size = unpack("L", $size);
893 If I<h2ph> wasn't installed or doesn't work for you, you can
894 I<grep> the include files by hand:
896 % grep FIONREAD /usr/include/*/*
897 /usr/include/asm/ioctls.h:#define FIONREAD 0x541B
899 Or write a small C program using the editor of champions:
902 #include <sys/ioctl.h>
904 printf("%#08x\n", FIONREAD);
907 % cc -o fionread fionread.c
911 And then hard code it, leaving porting as an exercise to your successor.
913 $FIONREAD = 0x4004667f; # XXX: opsys dependent
915 $size = pack("L", 0);
916 ioctl(FH, $FIONREAD, $size) or die "Couldn't call ioctl: $!\n";
917 $size = unpack("L", $size);
919 FIONREAD requires a filehandle connected to a stream, meaning that sockets,
920 pipes, and tty devices work, but I<not> files.
922 =head2 How do I do a C<tail -f> in perl?
928 The statement C<seek(GWFILE, 0, 1)> doesn't change the current position,
929 but it does clear the end-of-file condition on the handle, so that the
930 next <GWFILE> makes Perl try again to read something.
932 If that doesn't work (it relies on features of your stdio implementation),
933 then you need something more like this:
936 for ($curpos = tell(GWFILE); <GWFILE>; $curpos = tell(GWFILE)) {
937 # search for some stuff and put it into files
940 seek(GWFILE, $curpos, 0); # seek to where we had been
943 If this still doesn't work, look into the POSIX module. POSIX defines
944 the clearerr() method, which can remove the end of file condition on a
945 filehandle. The method: read until end of file, clearerr(), read some
946 more. Lather, rinse, repeat.
948 There's also a File::Tail module from CPAN.
950 =head2 How do I dup() a filehandle in Perl?
952 If you check L<perlfunc/open>, you'll see that several of the ways
953 to call open() should do the trick. For example:
955 open(LOG, ">>/foo/logfile");
956 open(STDERR, ">&LOG");
958 Or even with a literal numeric descriptor:
960 $fd = $ENV{MHCONTEXTFD};
961 open(MHCONTEXT, "<&=$fd"); # like fdopen(3S)
963 Note that "<&STDIN" makes a copy, but "<&=STDIN" make
964 an alias. That means if you close an aliased handle, all
965 aliases become inaccessible. This is not true with
968 Error checking, as always, has been left as an exercise for the reader.
970 =head2 How do I close a file descriptor by number?
972 This should rarely be necessary, as the Perl close() function is to be
973 used for things that Perl opened itself, even if it was a dup of a
974 numeric descriptor as with MHCONTEXT above. But if you really have
975 to, you may be able to do this:
977 require 'sys/syscall.ph';
978 $rc = syscall(&SYS_close, $fd + 0); # must force numeric
979 die "can't sysclose $fd: $!" unless $rc == -1;
981 Or, just use the fdopen(3S) feature of open():
985 open F, "<&=$fd" or die "Cannot reopen fd=$fd: $!";
989 =head2 Why can't I use "C:\temp\foo" in DOS paths? Why doesn't `C:\temp\foo.exe` work?
991 Whoops! You just put a tab and a formfeed into that filename!
992 Remember that within double quoted strings ("like\this"), the
993 backslash is an escape character. The full list of these is in
994 L<perlop/Quote and Quote-like Operators>. Unsurprisingly, you don't
995 have a file called "c:(tab)emp(formfeed)oo" or
996 "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
998 Either single-quote your strings, or (preferably) use forward slashes.
999 Since all DOS and Windows versions since something like MS-DOS 2.0 or so
1000 have treated C</> and C<\> the same in a path, you might as well use the
1001 one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
1002 awk, Tcl, Java, or Python, just to mention a few. POSIX paths
1003 are more portable, too.
1005 =head2 Why doesn't glob("*.*") get all the files?
1007 Because even on non-Unix ports, Perl's glob function follows standard
1008 Unix globbing semantics. You'll need C<glob("*")> to get all (non-hidden)
1009 files. This makes glob() portable even to legacy systems. Your
1010 port may include proprietary globbing functions as well. Check its
1011 documentation for details.
1013 =head2 Why does Perl let me delete read-only files? Why does C<-i> clobber protected files? Isn't this a bug in Perl?
1015 This is elaborately and painstakingly described in the
1016 F<file-dir-perms> article in the "Far More Than You Ever Wanted To
1017 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
1019 The executive summary: learn how your filesystem works. The
1020 permissions on a file say what can happen to the data in that file.
1021 The permissions on a directory say what can happen to the list of
1022 files in that directory. If you delete a file, you're removing its
1023 name from the directory (so the operation depends on the permissions
1024 of the directory, not of the file). If you try to write to the file,
1025 the permissions of the file govern whether you're allowed to.
1027 =head2 How do I select a random line from a file?
1029 Here's an algorithm from the Camel Book:
1032 rand($.) < 1 && ($line = $_) while <>;
1034 This has a significant advantage in space over reading the whole file
1035 in. You can find a proof of this method in I<The Art of Computer
1036 Programming>, Volume 2, Section 3.4.2, by Donald E. Knuth.
1038 You can use the File::Random module which provides a function
1041 use File::Random qw/random_line/;
1042 my $line = random_line($filename);
1044 Another way is to use the Tie::File module, which treats the entire
1045 file as an array. Simply access a random array element.
1047 =head2 Why do I get weird spaces when I print an array of lines?
1053 joins together the elements of C<@lines> with a space between them.
1054 If C<@lines> were C<("little", "fluffy", "clouds")> then the above
1055 statement would print
1057 little fluffy clouds
1059 but if each element of C<@lines> was a line of text, ending a newline
1060 character C<("little\n", "fluffy\n", "clouds\n")> then it would print:
1066 If your array contains lines, just print them:
1070 =head1 AUTHOR AND COPYRIGHT
1072 Copyright (c) 1997-2005 Tom Christiansen, Nathan Torkington, and
1073 other authors as noted. All rights reserved.
1075 This documentation is free; you can redistribute it and/or modify it
1076 under the same terms as Perl itself.
1078 Irrespective of its distribution, all code examples here are in the public
1079 domain. You are permitted and encouraged to use this code and any
1080 derivatives thereof in your own programs for fun or for profit as you
1081 see fit. A simple comment in the code giving credit to the FAQ would
1082 be courteous but is not required.