3 perlfaq4 - Data Manipulation
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
14 Internally, your computer represents floating-point numbers in binary.
15 Digital (as in powers of two) computers cannot store all numbers
16 exactly. Some real numbers lose precision in the process. This is a
17 problem with how computers store numbers and affects all computer
18 languages, not just Perl.
20 L<perlnumber> shows the gory details of number representations and
23 To limit the number of decimal places in your numbers, you can use the
24 C<printf> or C<sprintf> function. See the L<"Floating Point
25 Arithmetic"|perlop> for more details.
29 my $number = sprintf "%.2f", 10/3;
31 =head2 Why is int() broken?
33 Your C<int()> is most probably working just fine. It's the numbers that
34 aren't quite what you think.
36 First, see the answer to "Why am I getting long decimals
37 (eg, 19.9499999999999) instead of the numbers I should be getting
42 print int(0.6/0.2-2), "\n";
44 will in most computers print 0, not 1, because even such simple
45 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
46 numbers. What you think in the above as 'three' is really more like
47 2.9999999999999995559.
49 =head2 Why isn't my octal data interpreted correctly?
51 (contributed by brian d foy)
53 You're probably trying to convert a string to a number, which Perl only
54 converts as a decimal number. When Perl converts a string to a number, it
55 ignores leading spaces and zeroes, then assumes the rest of the digits
60 print $string + 0; # prints 644
62 print $string + 44; # prints 688, certainly not octal!
64 This problem usually involves one of the Perl built-ins that has the
65 same name a Unix command that uses octal numbers as arguments on the
66 command line. In this example, C<chmod> on the command line knows that
67 its first argument is octal because that's what it does:
69 %prompt> chmod 644 file
71 If you want to use the same literal digits (644) in Perl, you have to tell
72 Perl to treat them as octal numbers either by prefixing the digits with
73 a C<0> or using C<oct>:
75 chmod( 0644, $file); # right, has leading zero
76 chmod( oct(644), $file ); # also correct
78 The problem comes in when you take your numbers from something that Perl
79 thinks is a string, such as a command line argument in C<@ARGV>:
81 chmod( $ARGV[0], $file); # wrong, even if "0644"
83 chmod( oct($ARGV[0]), $file ); # correct, treat string as octal
85 You can always check the value you're using by printing it in octal
86 notation to ensure it matches what you think it should be. Print it
87 in octal and decimal format:
89 printf "0%o %d", $number, $number;
91 =head2 Does Perl have a round() function? What about ceil() and floor()? Trig functions?
93 Remember that C<int()> merely truncates toward 0. For rounding to a
94 certain number of digits, C<sprintf()> or C<printf()> is usually the
97 printf("%.3f", 3.1415926535); # prints 3.142
99 The C<POSIX> module (part of the standard Perl distribution)
100 implements C<ceil()>, C<floor()>, and a number of other mathematical
101 and trigonometric functions.
104 $ceil = ceil(3.5); # 4
105 $floor = floor(3.5); # 3
107 In 5.000 to 5.003 perls, trigonometry was done in the C<Math::Complex>
108 module. With 5.004, the C<Math::Trig> module (part of the standard Perl
109 distribution) implements the trigonometric functions. Internally it
110 uses the C<Math::Complex> module and some functions can break out from
111 the real axis into the complex plane, for example the inverse sine of
114 Rounding in financial applications can have serious implications, and
115 the rounding method used should be specified precisely. In these
116 cases, it probably pays not to trust whichever system rounding is
117 being used by Perl, but to instead implement the rounding function you
120 To see why, notice how you'll still have an issue on half-way-point
123 for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
125 0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
126 0.8 0.8 0.9 0.9 1.0 1.0
128 Don't blame Perl. It's the same as in C. IEEE says we have to do
129 this. Perl numbers whose absolute values are integers under 2**31 (on
130 32 bit machines) will work pretty much like mathematical integers.
131 Other numbers are not guaranteed.
133 =head2 How do I convert between numeric representations/bases/radixes?
135 As always with Perl there is more than one way to do it. Below are a
136 few examples of approaches to making common conversions between number
137 representations. This is intended to be representational rather than
140 Some of the examples later in L<perlfaq4> use the C<Bit::Vector>
141 module from CPAN. The reason you might choose C<Bit::Vector> over the
142 perl built in functions is that it works with numbers of ANY size,
143 that it is optimized for speed on some operations, and for at least
144 some programmers the notation might be familiar.
148 =item How do I convert hexadecimal into decimal
150 Using perl's built in conversion of C<0x> notation:
154 Using the C<hex> function:
156 $dec = hex("DEADBEEF");
160 $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
162 Using the CPAN module C<Bit::Vector>:
165 $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
166 $dec = $vec->to_Dec();
168 =item How do I convert from decimal to hexadecimal
172 $hex = sprintf("%X", 3735928559); # upper case A-F
173 $hex = sprintf("%x", 3735928559); # lower case a-f
177 $hex = unpack("H*", pack("N", 3735928559));
179 Using C<Bit::Vector>:
182 $vec = Bit::Vector->new_Dec(32, -559038737);
183 $hex = $vec->to_Hex();
185 And C<Bit::Vector> supports odd bit counts:
188 $vec = Bit::Vector->new_Dec(33, 3735928559);
189 $vec->Resize(32); # suppress leading 0 if unwanted
190 $hex = $vec->to_Hex();
192 =item How do I convert from octal to decimal
194 Using Perl's built in conversion of numbers with leading zeros:
196 $dec = 033653337357; # note the leading 0!
198 Using the C<oct> function:
200 $dec = oct("33653337357");
202 Using C<Bit::Vector>:
205 $vec = Bit::Vector->new(32);
206 $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
207 $dec = $vec->to_Dec();
209 =item How do I convert from decimal to octal
213 $oct = sprintf("%o", 3735928559);
215 Using C<Bit::Vector>:
218 $vec = Bit::Vector->new_Dec(32, -559038737);
219 $oct = reverse join('', $vec->Chunk_List_Read(3));
221 =item How do I convert from binary to decimal
223 Perl 5.6 lets you write binary numbers directly with
226 $number = 0b10110110;
230 my $input = "10110110";
231 $decimal = oct( "0b$input" );
233 Using C<pack> and C<ord>:
235 $decimal = ord(pack('B8', '10110110'));
237 Using C<pack> and C<unpack> for larger strings:
239 $int = unpack("N", pack("B32",
240 substr("0" x 32 . "11110101011011011111011101111", -32)));
241 $dec = sprintf("%d", $int);
243 # substr() is used to left pad a 32 character string with zeros.
245 Using C<Bit::Vector>:
247 $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
248 $dec = $vec->to_Dec();
250 =item How do I convert from decimal to binary
252 Using C<sprintf> (perl 5.6+):
254 $bin = sprintf("%b", 3735928559);
258 $bin = unpack("B*", pack("N", 3735928559));
260 Using C<Bit::Vector>:
263 $vec = Bit::Vector->new_Dec(32, -559038737);
264 $bin = $vec->to_Bin();
266 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
267 are left as an exercise to the inclined reader.
271 =head2 Why doesn't & work the way I want it to?
273 The behavior of binary arithmetic operators depends on whether they're
274 used on numbers or strings. The operators treat a string as a series
275 of bits and work with that (the string C<"3"> is the bit pattern
276 C<00110011>). The operators work with the binary form of a number
277 (the number C<3> is treated as the bit pattern C<00000011>).
279 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
280 C<3>). Saying C<"11" & "3"> performs the "and" operation on strings
283 Most problems with C<&> and C<|> arise because the programmer thinks
284 they have a number but really it's a string. The rest arise because
287 if ("\020\020" & "\101\101") {
291 but a string consisting of two null bytes (the result of C<"\020\020"
292 & "\101\101">) is not a false value in Perl. You need:
294 if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
298 =head2 How do I multiply matrices?
300 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
301 or the PDL extension (also available from CPAN).
303 =head2 How do I perform an operation on a series of integers?
305 To call a function on each element in an array, and collect the
308 @results = map { my_func($_) } @array;
312 @triple = map { 3 * $_ } @single;
314 To call a function on each element of an array, but ignore the
317 foreach $iterator (@array) {
318 some_func($iterator);
321 To call a function on each integer in a (small) range, you B<can> use:
323 @results = map { some_func($_) } (5 .. 25);
325 but you should be aware that the C<..> operator creates an array of
326 all integers in the range. This can take a lot of memory for large
330 for ($i=5; $i < 500_005; $i++) {
331 push(@results, some_func($i));
334 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
335 loop will iterate over the range, without creating the entire range.
337 for my $i (5 .. 500_005) {
338 push(@results, some_func($i));
341 will not create a list of 500,000 integers.
343 =head2 How can I output Roman numerals?
345 Get the http://www.cpan.org/modules/by-module/Roman module.
347 =head2 Why aren't my random numbers random?
349 If you're using a version of Perl before 5.004, you must call C<srand>
350 once at the start of your program to seed the random number generator.
352 BEGIN { srand() if $] < 5.004 }
354 5.004 and later automatically call C<srand> at the beginning. Don't
355 call C<srand> more than once--you make your numbers less random,
358 Computers are good at being predictable and bad at being random
359 (despite appearances caused by bugs in your programs :-). see the
360 F<random> article in the "Far More Than You Ever Wanted To Know"
361 collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy
362 of Tom Phoenix, talks more about this. John von Neumann said, "Anyone
363 who attempts to generate random numbers by deterministic means is, of
364 course, living in a state of sin."
366 If you want numbers that are more random than C<rand> with C<srand>
367 provides, you should also check out the C<Math::TrulyRandom> module from
368 CPAN. It uses the imperfections in your system's timer to generate
369 random numbers, but this takes quite a while. If you want a better
370 pseudorandom generator than comes with your operating system, look at
371 "Numerical Recipes in C" at http://www.nr.com/ .
373 =head2 How do I get a random number between X and Y?
375 To get a random number between two values, you can use the C<rand()>
376 built-in to get a random number between 0 and 1. From there, you shift
377 that into the range that you want.
379 C<rand($x)> returns a number such that C<< 0 <= rand($x) < $x >>. Thus
380 what you want to have perl figure out is a random number in the range
381 from 0 to the difference between your I<X> and I<Y>.
383 That is, to get a number between 10 and 15, inclusive, you want a
384 random number between 0 and 5 that you can then add to 10.
386 my $number = 10 + int rand( 15-10+1 ); # ( 10,11,12,13,14, or 15 )
388 Hence you derive the following simple function to abstract
389 that. It selects a random integer between the two given
390 integers (inclusive), For example: C<random_int_between(50,120)>.
392 sub random_int_between {
394 # Assumes that the two arguments are integers themselves!
395 return $min if $min == $max;
396 ($min, $max) = ($max, $min) if $min > $max;
397 return $min + int rand(1 + $max - $min);
402 =head2 How do I find the day or week of the year?
404 The localtime function returns the day of the year. Without an
405 argument localtime uses the current time.
407 $day_of_year = (localtime)[7];
409 The C<POSIX> module can also format a date as the day of the year or
412 use POSIX qw/strftime/;
413 my $day_of_year = strftime "%j", localtime;
414 my $week_of_year = strftime "%W", localtime;
416 To get the day of year for any date, use C<POSIX>'s C<mktime> to get
417 a time in epoch seconds for the argument to localtime.
419 use POSIX qw/mktime strftime/;
420 my $week_of_year = strftime "%W",
421 localtime( mktime( 0, 0, 0, 18, 11, 87 ) );
423 The C<Date::Calc> module provides two functions to calculate these.
426 my $day_of_year = Day_of_Year( 1987, 12, 18 );
427 my $week_of_year = Week_of_Year( 1987, 12, 18 );
429 =head2 How do I find the current century or millennium?
431 Use the following simple functions:
434 return int((((localtime(shift || time))[5] + 1999))/100);
438 return 1+int((((localtime(shift || time))[5] + 1899))/1000);
441 On some systems, the C<POSIX> module's C<strftime()> function has been
442 extended in a non-standard way to use a C<%C> format, which they
443 sometimes claim is the "century". It isn't, because on most such
444 systems, this is only the first two digits of the four-digit year, and
445 thus cannot be used to reliably determine the current century or
448 =head2 How can I compare two dates and find the difference?
450 (contributed by brian d foy)
452 You could just store all your dates as a number and then subtract.
453 Life isn't always that simple though. If you want to work with
454 formatted dates, the C<Date::Manip>, C<Date::Calc>, or C<DateTime>
455 modules can help you.
457 =head2 How can I take a string and turn it into epoch seconds?
459 If it's a regular enough string that it always has the same format,
460 you can split it up and pass the parts to C<timelocal> in the standard
461 C<Time::Local> module. Otherwise, you should look into the C<Date::Calc>
462 and C<Date::Manip> modules from CPAN.
464 =head2 How can I find the Julian Day?
466 (contributed by brian d foy and Dave Cross)
468 You can use the C<Time::JulianDay> module available on CPAN. Ensure
469 that you really want to find a Julian day, though, as many people have
470 different ideas about Julian days. See
471 http://www.hermetic.ch/cal_stud/jdn.htm for instance.
473 You can also try the C<DateTime> module, which can convert a date/time
476 $ perl -MDateTime -le'print DateTime->today->jd'
479 Or the modified Julian Day
481 $ perl -MDateTime -le'print DateTime->today->mjd'
484 Or even the day of the year (which is what some people think of as a
487 $ perl -MDateTime -le'print DateTime->today->doy'
490 =head2 How do I find yesterday's date?
491 X<date> X<yesterday> X<DateTime> X<Date::Calc> X<Time::Local>
492 X<daylight saving time> X<day> X<Today_and_Now> X<localtime>
495 (contributed by brian d foy)
497 Use one of the Date modules. The C<DateTime> module makes it simple, and
498 give you the same time of day, only the day before.
502 my $yesterday = DateTime->now->subtract( days => 1 );
504 print "Yesterday was $yesterday\n";
506 You can also use the C<Date::Calc> module using its C<Today_and_Now>
509 use Date::Calc qw( Today_and_Now Add_Delta_DHMS );
511 my @date_time = Add_Delta_DHMS( Today_and_Now(), -1, 0, 0, 0 );
513 print "@date_time\n";
515 Most people try to use the time rather than the calendar to figure out
516 dates, but that assumes that days are twenty-four hours each. For
517 most people, there are two days a year when they aren't: the switch to
518 and from summer time throws this off. Let the modules do the work.
520 If you absolutely must do it yourself (or can't use one of the
521 modules), here's a solution using C<Time::Local>, which comes with
524 # contributed by Gunnar Hjalmarsson
526 my $today = timelocal 0, 0, 12, ( localtime )[3..5];
527 my ($d, $m, $y) = ( localtime $today-86400 )[3..5];
528 printf "Yesterday: %d-%02d-%02d\n", $y+1900, $m+1, $d;
530 In this case, you measure the day starting at noon, and subtract 24
531 hours. Even if the length of the calendar day is 23 or 25 hours,
532 you'll still end up on the previous calendar day, although not at
533 noon. Since you don't care about the time, the one hour difference
534 doesn't matter and you end up with the previous date.
536 =head2 Does Perl have a Year 2000 or 2038 problem? Is Perl Y2K compliant?
538 (contributed by brian d foy)
540 Perl itself never had a Y2K problem, although that never stopped people
541 from creating Y2K problems on their own. See the documentation for
542 C<localtime> for its proper use.
544 Starting with Perl 5.11, C<localtime> and C<gmtime> can handle dates past
545 03:14:08 January 19, 2038, when a 32-bit based time would overflow. You
546 still might get a warning on a 32-bit C<perl>:
548 % perl5.11.2 -E 'say scalar localtime( 0x9FFF_FFFFFFFF )'
549 Integer overflow in hexadecimal number at -e line 1.
550 Wed Nov 1 19:42:39 5576711
552 On a 64-bit C<perl>, you can get even larger dates for those really long
555 % perl5.11.2 -E 'say scalar gmtime( 0x9FFF_FFFFFFFF )'
556 Thu Nov 2 00:42:39 5576711
558 You're still out of luck if you need to keep tracking of decaying protons
563 =head2 How do I validate input?
565 (contributed by brian d foy)
567 There are many ways to ensure that values are what you expect or
568 want to accept. Besides the specific examples that we cover in the
569 perlfaq, you can also look at the modules with "Assert" and "Validate"
570 in their names, along with other modules such as C<Regexp::Common>.
572 Some modules have validation for particular types of input, such
573 as C<Business::ISBN>, C<Business::CreditCard>, C<Email::Valid>,
574 and C<Data::Validate::IP>.
576 =head2 How do I unescape a string?
578 It depends just what you mean by "escape". URL escapes are dealt
579 with in L<perlfaq9>. Shell escapes with the backslash (C<\>)
580 character are removed with
584 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
586 =head2 How do I remove consecutive pairs of characters?
588 (contributed by brian d foy)
590 You can use the substitution operator to find pairs of characters (or
591 runs of characters) and replace them with a single instance. In this
592 substitution, we find a character in C<(.)>. The memory parentheses
593 store the matched character in the back-reference C<\1> and we use
594 that to require that the same thing immediately follow it. We replace
595 that part of the string with the character in C<$1>.
599 We can also use the transliteration operator, C<tr///>. In this
600 example, the search list side of our C<tr///> contains nothing, but
601 the C<c> option complements that so it contains everything. The
602 replacement list also contains nothing, so the transliteration is
603 almost a no-op since it won't do any replacements (or more exactly,
604 replace the character with itself). However, the C<s> option squashes
605 duplicated and consecutive characters in the string so a character
606 does not show up next to itself
608 my $str = 'Haarlem'; # in the Netherlands
609 $str =~ tr///cs; # Now Harlem, like in New York
611 =head2 How do I expand function calls in a string?
613 (contributed by brian d foy)
615 This is documented in L<perlref>, and although it's not the easiest
616 thing to read, it does work. In each of these examples, we call the
617 function inside the braces used to dereference a reference. If we
618 have more than one return value, we can construct and dereference an
619 anonymous array. In this case, we call the function in list context.
621 print "The time values are @{ [localtime] }.\n";
623 If we want to call the function in scalar context, we have to do a bit
624 more work. We can really have any code we like inside the braces, so
625 we simply have to end with the scalar reference, although how you do
626 that is up to you, and you can use code inside the braces. Note that
627 the use of parens creates a list context, so we need C<scalar> to
628 force the scalar context on the function:
630 print "The time is ${\(scalar localtime)}.\n"
632 print "The time is ${ my $x = localtime; \$x }.\n";
634 If your function already returns a reference, you don't need to create
635 the reference yourself.
637 sub timestamp { my $t = localtime; \$t }
639 print "The time is ${ timestamp() }.\n";
641 The C<Interpolation> module can also do a lot of magic for you. You can
642 specify a variable name, in this case C<E>, to set up a tied hash that
643 does the interpolation for you. It has several other methods to do this
646 use Interpolation E => 'eval';
647 print "The time values are $E{localtime()}.\n";
649 In most cases, it is probably easier to simply use string concatenation,
650 which also forces scalar context.
652 print "The time is " . localtime() . ".\n";
654 =head2 How do I find matching/nesting anything?
656 This isn't something that can be done in one regular expression, no
657 matter how complicated. To find something between two single
658 characters, a pattern like C</x([^x]*)x/> will get the intervening
659 bits in $1. For multiple ones, then something more like
660 C</alpha(.*?)omega/> would be needed. But none of these deals with
661 nested patterns. For balanced expressions using C<(>, C<{>, C<[> or
662 C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
663 L<perlre/(??{ code })>. For other cases, you'll have to write a
666 If you are serious about writing a parser, there are a number of
667 modules or oddities that will make your life a lot easier. There are
668 the CPAN modules C<Parse::RecDescent>, C<Parse::Yapp>, and
669 C<Text::Balanced>; and the C<byacc> program. Starting from perl 5.8
670 the C<Text::Balanced> is part of the standard distribution.
672 One simple destructive, inside-out approach that you might try is to
673 pull out the smallest nesting parts one at a time:
675 while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
676 # do something with $1
679 A more complicated and sneaky approach is to make Perl's regular
680 expression engine do it for you. This is courtesy Dean Inada, and
681 rather has the nature of an Obfuscated Perl Contest entry, but it
684 # $_ contains the string to parse
685 # BEGIN and END are the opening and closing markers for the
690 ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
691 @$ = (eval{/$re/},$@!~/unmatched/i);
692 print join("\n",@$[0..$#$]) if( $$[-1] );
694 =head2 How do I reverse a string?
696 Use C<reverse()> in scalar context, as documented in
699 $reversed = reverse $string;
701 =head2 How do I expand tabs in a string?
703 You can do it yourself:
705 1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
707 Or you can just use the C<Text::Tabs> module (part of the standard Perl
711 @expanded_lines = expand(@lines_with_tabs);
713 =head2 How do I reformat a paragraph?
715 Use C<Text::Wrap> (part of the standard Perl distribution):
718 print wrap("\t", ' ', @paragraphs);
720 The paragraphs you give to C<Text::Wrap> should not contain embedded
721 newlines. C<Text::Wrap> doesn't justify the lines (flush-right).
723 Or use the CPAN module C<Text::Autoformat>. Formatting files can be
724 easily done by making a shell alias, like so:
726 alias fmt="perl -i -MText::Autoformat -n0777 \
727 -e 'print autoformat $_, {all=>1}' $*"
729 See the documentation for C<Text::Autoformat> to appreciate its many
732 =head2 How can I access or change N characters of a string?
734 You can access the first characters of a string with substr().
735 To get the first character, for example, start at position 0
736 and grab the string of length 1.
739 $string = "Just another Perl Hacker";
740 $first_char = substr( $string, 0, 1 ); # 'J'
742 To change part of a string, you can use the optional fourth
743 argument which is the replacement string.
745 substr( $string, 13, 4, "Perl 5.8.0" );
747 You can also use substr() as an lvalue.
749 substr( $string, 13, 4 ) = "Perl 5.8.0";
751 =head2 How do I change the Nth occurrence of something?
753 You have to keep track of N yourself. For example, let's say you want
754 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
755 C<"whosoever"> or C<"whomsoever">, case insensitively. These
756 all assume that $_ contains the string to be altered.
760 ++$count == 5 # is it the 5th?
761 ? "${2}soever" # yes, swap
762 : $1 # renege and leave it there
765 In the more general case, you can use the C</g> modifier in a C<while>
766 loop, keeping count of matches.
770 $_ = "One fish two fish red fish blue fish";
771 while (/(\w+)\s+fish\b/gi) {
772 if (++$count == $WANT) {
773 print "The third fish is a $1 one.\n";
777 That prints out: C<"The third fish is a red one."> You can also use a
778 repetition count and repeated pattern like this:
780 /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
782 =head2 How can I count the number of occurrences of a substring within a string?
784 There are a number of ways, with varying efficiency. If you want a
785 count of a certain single character (X) within a string, you can use the
786 C<tr///> function like so:
788 $string = "ThisXlineXhasXsomeXx'sXinXit";
789 $count = ($string =~ tr/X//);
790 print "There are $count X characters in the string";
792 This is fine if you are just looking for a single character. However,
793 if you are trying to count multiple character substrings within a
794 larger string, C<tr///> won't work. What you can do is wrap a while()
795 loop around a global pattern match. For example, let's count negative
798 $string = "-9 55 48 -2 23 -76 4 14 -44";
799 while ($string =~ /-\d+/g) { $count++ }
800 print "There are $count negative numbers in the string";
802 Another version uses a global match in list context, then assigns the
803 result to a scalar, producing a count of the number of matches.
805 $count = () = $string =~ /-\d+/g;
807 =head2 How do I capitalize all the words on one line?
808 X<Text::Autoformat> X<capitalize> X<case, title> X<case, sentence>
810 (contributed by brian d foy)
812 Damian Conway's L<Text::Autoformat> handles all of the thinking
815 use Text::Autoformat;
816 my $x = "Dr. Strangelove or: How I Learned to Stop ".
817 "Worrying and Love the Bomb";
820 for my $style (qw( sentence title highlight )) {
821 print autoformat($x, { case => $style }), "\n";
824 How do you want to capitalize those words?
826 FRED AND BARNEY'S LODGE # all uppercase
827 Fred And Barney's Lodge # title case
828 Fred and Barney's Lodge # highlight case
830 It's not as easy a problem as it looks. How many words do you think
831 are in there? Wait for it... wait for it.... If you answered 5
832 you're right. Perl words are groups of C<\w+>, but that's not what
833 you want to capitalize. How is Perl supposed to know not to capitalize
834 that C<s> after the apostrophe? You could try a regular expression:
837 (^\w) #at the beginning of the line
839 (\s\w) #preceded by whitespace
843 $string =~ s/([\w']+)/\u\L$1/g;
845 Now, what if you don't want to capitalize that "and"? Just use
846 L<Text::Autoformat> and get on with the next problem. :)
848 =head2 How can I split a [character] delimited string except when inside [character]?
850 Several modules can handle this sort of parsing--C<Text::Balanced>,
851 C<Text::CSV>, C<Text::CSV_XS>, and C<Text::ParseWords>, among others.
853 Take the example case of trying to split a string that is
854 comma-separated into its different fields. You can't use C<split(/,/)>
855 because you shouldn't split if the comma is inside quotes. For
856 example, take a data line like this:
858 SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
860 Due to the restriction of the quotes, this is a fairly complex
861 problem. Thankfully, we have Jeffrey Friedl, author of
862 I<Mastering Regular Expressions>, to handle these for us. He
863 suggests (assuming your string is contained in C<$text>):
866 push(@new, $+) while $text =~ m{
867 "([^\"\\]*(?:\\.[^\"\\]*)*)",? # groups the phrase inside the quotes
871 push(@new, undef) if substr($text,-1,1) eq ',';
873 If you want to represent quotation marks inside a
874 quotation-mark-delimited field, escape them with backslashes (eg,
877 Alternatively, the C<Text::ParseWords> module (part of the standard
878 Perl distribution) lets you say:
880 use Text::ParseWords;
881 @new = quotewords(",", 0, $text);
883 =head2 How do I strip blank space from the beginning/end of a string?
885 (contributed by brian d foy)
887 A substitution can do this for you. For a single line, you want to
888 replace all the leading or trailing whitespace with nothing. You
889 can do that with a pair of substitutions.
894 You can also write that as a single substitution, although it turns
895 out the combined statement is slower than the separate ones. That
896 might not matter to you, though.
900 In this regular expression, the alternation matches either at the
901 beginning or the end of the string since the anchors have a lower
902 precedence than the alternation. With the C</g> flag, the substitution
903 makes all possible matches, so it gets both. Remember, the trailing
904 newline matches the C<\s+>, and the C<$> anchor can match to the
905 physical end of the string, so the newline disappears too. Just add
906 the newline to the output, which has the added benefit of preserving
907 "blank" (consisting entirely of whitespace) lines which the C<^\s+>
908 would remove all by itself.
916 For a multi-line string, you can apply the regular expression
917 to each logical line in the string by adding the C</m> flag (for
918 "multi-line"). With the C</m> flag, the C<$> matches I<before> an
919 embedded newline, so it doesn't remove it. It still removes the
920 newline at the end of the string.
922 $string =~ s/^\s+|\s+$//gm;
924 Remember that lines consisting entirely of whitespace will disappear,
925 since the first part of the alternation can match the entire string
926 and replace it with nothing. If need to keep embedded blank lines,
927 you have to do a little more work. Instead of matching any whitespace
928 (since that includes a newline), just match the other whitespace.
930 $string =~ s/^[\t\f ]+|[\t\f ]+$//mg;
932 =head2 How do I pad a string with blanks or pad a number with zeroes?
934 In the following examples, C<$pad_len> is the length to which you wish
935 to pad the string, C<$text> or C<$num> contains the string to be padded,
936 and C<$pad_char> contains the padding character. You can use a single
937 character string constant instead of the C<$pad_char> variable if you
938 know what it is in advance. And in the same way you can use an integer in
939 place of C<$pad_len> if you know the pad length in advance.
941 The simplest method uses the C<sprintf> function. It can pad on the left
942 or right with blanks and on the left with zeroes and it will not
943 truncate the result. The C<pack> function can only pad strings on the
944 right with blanks and it will truncate the result to a maximum length of
947 # Left padding a string with blanks (no truncation):
948 $padded = sprintf("%${pad_len}s", $text);
949 $padded = sprintf("%*s", $pad_len, $text); # same thing
951 # Right padding a string with blanks (no truncation):
952 $padded = sprintf("%-${pad_len}s", $text);
953 $padded = sprintf("%-*s", $pad_len, $text); # same thing
955 # Left padding a number with 0 (no truncation):
956 $padded = sprintf("%0${pad_len}d", $num);
957 $padded = sprintf("%0*d", $pad_len, $num); # same thing
959 # Right padding a string with blanks using pack (will truncate):
960 $padded = pack("A$pad_len",$text);
962 If you need to pad with a character other than blank or zero you can use
963 one of the following methods. They all generate a pad string with the
964 C<x> operator and combine that with C<$text>. These methods do
965 not truncate C<$text>.
967 Left and right padding with any character, creating a new string:
969 $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
970 $padded = $text . $pad_char x ( $pad_len - length( $text ) );
972 Left and right padding with any character, modifying C<$text> directly:
974 substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
975 $text .= $pad_char x ( $pad_len - length( $text ) );
977 =head2 How do I extract selected columns from a string?
979 (contributed by brian d foy)
981 If you know where the columns that contain the data, you can
982 use C<substr> to extract a single column.
984 my $column = substr( $line, $start_column, $length );
986 You can use C<split> if the columns are separated by whitespace or
987 some other delimiter, as long as whitespace or the delimiter cannot
988 appear as part of the data.
990 my $line = ' fred barney betty ';
991 my @columns = split /\s+/, $line;
992 # ( '', 'fred', 'barney', 'betty' );
994 my $line = 'fred||barney||betty';
995 my @columns = split /\|/, $line;
996 # ( 'fred', '', 'barney', '', 'betty' );
998 If you want to work with comma-separated values, don't do this since
999 that format is a bit more complicated. Use one of the modules that
1000 handle that format, such as C<Text::CSV>, C<Text::CSV_XS>, or
1003 If you want to break apart an entire line of fixed columns, you can use
1004 C<unpack> with the A (ASCII) format. By using a number after the format
1005 specifier, you can denote the column width. See the C<pack> and C<unpack>
1006 entries in L<perlfunc> for more details.
1008 my @fields = unpack( $line, "A8 A8 A8 A16 A4" );
1010 Note that spaces in the format argument to C<unpack> do not denote literal
1011 spaces. If you have space separated data, you may want C<split> instead.
1013 =head2 How do I find the soundex value of a string?
1015 (contributed by brian d foy)
1017 You can use the Text::Soundex module. If you want to do fuzzy or close
1018 matching, you might also try the C<String::Approx>, and
1019 C<Text::Metaphone>, and C<Text::DoubleMetaphone> modules.
1021 =head2 How can I expand variables in text strings?
1023 (contributed by brian d foy)
1025 If you can avoid it, don't, or if you can use a templating system,
1026 such as C<Text::Template> or C<Template> Toolkit, do that instead. You
1027 might even be able to get the job done with C<sprintf> or C<printf>:
1029 my $string = sprintf 'Say hello to %s and %s', $foo, $bar;
1031 However, for the one-off simple case where I don't want to pull out a
1032 full templating system, I'll use a string that has two Perl scalar
1033 variables in it. In this example, I want to expand C<$foo> and C<$bar>
1034 to their variable's values:
1038 $string = 'Say hello to $foo and $bar';
1040 One way I can do this involves the substitution operator and a double
1041 C</e> flag. The first C</e> evaluates C<$1> on the replacement side and
1042 turns it into C<$foo>. The second /e starts with C<$foo> and replaces
1043 it with its value. C<$foo>, then, turns into 'Fred', and that's finally
1044 what's left in the string:
1046 $string =~ s/(\$\w+)/$1/eeg; # 'Say hello to Fred and Barney'
1048 The C</e> will also silently ignore violations of strict, replacing
1049 undefined variable names with the empty string. Since I'm using the
1050 C</e> flag (twice even!), I have all of the same security problems I
1051 have with C<eval> in its string form. If there's something odd in
1052 C<$foo>, perhaps something like C<@{[ system "rm -rf /" ]}>, then
1053 I could get myself in trouble.
1055 To get around the security problem, I could also pull the values from
1056 a hash instead of evaluating variable names. Using a single C</e>, I
1057 can check the hash to ensure the value exists, and if it doesn't, I
1058 can replace the missing value with a marker, in this case C<???> to
1059 signal that I missed something:
1061 my $string = 'This has $foo and $bar';
1063 my %Replacements = (
1067 # $string =~ s/\$(\w+)/$Replacements{$1}/g;
1068 $string =~ s/\$(\w+)/
1069 exists $Replacements{$1} ? $Replacements{$1} : '???'
1074 =head2 What's wrong with always quoting "$vars"?
1076 The problem is that those double-quotes force
1077 stringification--coercing numbers and references into strings--even
1078 when you don't want them to be strings. Think of it this way:
1079 double-quote expansion is used to produce new strings. If you already
1080 have a string, why do you need more?
1082 If you get used to writing odd things like these:
1085 $new = "$old"; # BAD
1086 somefunc("$var"); # BAD
1088 You'll be in trouble. Those should (in 99.8% of the cases) be
1089 the simpler and more direct:
1095 Otherwise, besides slowing you down, you're going to break code when
1096 the thing in the scalar is actually neither a string nor a number, but
1102 my $oref = "$aref"; # WRONG
1105 You can also get into subtle problems on those few operations in Perl
1106 that actually do care about the difference between a string and a
1107 number, such as the magical C<++> autoincrement operator or the
1110 Stringification also destroys arrays.
1113 print "@lines"; # WRONG - extra blanks
1114 print @lines; # right
1116 =head2 Why don't my E<lt>E<lt>HERE documents work?
1118 Check for these three things:
1122 =item There must be no space after the E<lt>E<lt> part.
1124 =item There (probably) should be a semicolon at the end.
1126 =item You can't (easily) have any space in front of the tag.
1130 If you want to indent the text in the here document, you
1134 ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1139 But the HERE_TARGET must still be flush against the margin.
1140 If you want that indented also, you'll have to quote
1143 ($quote = <<' FINIS') =~ s/^\s+//gm;
1144 ...we will have peace, when you and all your works have
1145 perished--and the works of your dark master to whom you
1146 would deliver us. You are a liar, Saruman, and a corrupter
1147 of men's hearts. --Theoden in /usr/src/perl/taint.c
1149 $quote =~ s/\s+--/\n--/;
1151 A nice general-purpose fixer-upper function for indented here documents
1152 follows. It expects to be called with a here document as its argument.
1153 It looks to see whether each line begins with a common substring, and
1154 if so, strips that substring off. Otherwise, it takes the amount of leading
1155 whitespace found on the first line and removes that much off each
1160 my ($white, $leader); # common whitespace and common leading string
1161 if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1162 ($white, $leader) = ($2, quotemeta($1));
1164 ($white, $leader) = (/^(\s+)/, '');
1166 s/^\s*?$leader(?:$white)?//gm;
1170 This works with leading special strings, dynamically determined:
1172 $remember_the_main = fix<<' MAIN_INTERPRETER_LOOP';
1175 @@@ SAVEI32(runlevel);
1177 @@@ while ( op = (*op->op_ppaddr)() );
1181 MAIN_INTERPRETER_LOOP
1183 Or with a fixed amount of leading whitespace, with remaining
1184 indentation correctly preserved:
1186 $poem = fix<<EVER_ON_AND_ON;
1187 Now far ahead the Road has gone,
1188 And I must follow, if I can,
1189 Pursuing it with eager feet,
1190 Until it joins some larger way
1191 Where many paths and errands meet.
1192 And whither then? I cannot say.
1193 --Bilbo in /usr/src/perl/pp_ctl.c
1198 =head2 What is the difference between a list and an array?
1200 (contributed by brian d foy)
1202 A list is a fixed collection of scalars. An array is a variable that
1203 holds a variable collection of scalars. An array can supply its collection
1204 for list operations, so list operations also work on arrays:
1207 ( 'dog', 'cat', 'bird' )[2,3];
1211 foreach ( qw( dog cat bird ) ) { ... }
1212 foreach ( @animals ) { ... }
1214 my @three = grep { length == 3 } qw( dog cat bird );
1215 my @three = grep { length == 3 } @animals;
1217 # supply an argument list
1218 wash_animals( qw( dog cat bird ) );
1219 wash_animals( @animals );
1221 Array operations, which change the scalars, reaaranges them, or adds
1222 or subtracts some scalars, only work on arrays. These can't work on a
1223 list, which is fixed. Array operations include C<shift>, C<unshift>,
1224 C<push>, C<pop>, and C<splice>.
1226 An array can also change its length:
1228 $#animals = 1; # truncate to two elements
1229 $#animals = 10000; # pre-extend to 10,001 elements
1231 You can change an array element, but you can't change a list element:
1233 $animals[0] = 'Rottweiler';
1234 qw( dog cat bird )[0] = 'Rottweiler'; # syntax error!
1236 foreach ( @animals ) {
1237 s/^d/fr/; # works fine
1240 foreach ( qw( dog cat bird ) ) {
1241 s/^d/fr/; # Error! Modification of read only value!
1244 However, if the list element is itself a variable, it appears that you
1245 can change a list element. However, the list element is the variable, not
1246 the data. You're not changing the list element, but something the list
1247 element refers to. The list element itself doesn't change: it's still
1250 You also have to be careful about context. You can assign an array to
1251 a scalar to get the number of elements in the array. This only works
1254 my $count = @animals; # only works with arrays
1256 If you try to do the same thing with what you think is a list, you
1257 get a quite different result. Although it looks like you have a list
1258 on the righthand side, Perl actually sees a bunch of scalars separated
1261 my $scalar = ( 'dog', 'cat', 'bird' ); # $scalar gets bird
1263 Since you're assigning to a scalar, the righthand side is in scalar
1264 context. The comma operator (yes, it's an operator!) in scalar
1265 context evaluates its lefthand side, throws away the result, and
1266 evaluates it's righthand side and returns the result. In effect,
1267 that list-lookalike assigns to C<$scalar> it's rightmost value. Many
1268 people mess this up becuase they choose a list-lookalike whose
1269 last element is also the count they expect:
1271 my $scalar = ( 1, 2, 3 ); # $scalar gets 3, accidentally
1273 =head2 What is the difference between $array[1] and @array[1]?
1275 (contributed by brian d foy)
1277 The difference is the sigil, that special character in front of the
1278 array name. The C<$> sigil means "exactly one item", while the C<@>
1279 sigil means "zero or more items". The C<$> gets you a single scalar,
1280 while the C<@> gets you a list.
1282 The confusion arises because people incorrectly assume that the sigil
1283 denotes the variable type.
1285 The C<$array[1]> is a single-element access to the array. It's going
1286 to return the item in index 1 (or undef if there is no item there).
1287 If you intend to get exactly one element from the array, this is the
1288 form you should use.
1290 The C<@array[1]> is an array slice, although it has only one index.
1291 You can pull out multiple elements simultaneously by specifying
1292 additional indices as a list, like C<@array[1,4,3,0]>.
1294 Using a slice on the lefthand side of the assignment supplies list
1295 context to the righthand side. This can lead to unexpected results.
1296 For instance, if you want to read a single line from a filehandle,
1297 assigning to a scalar value is fine:
1299 $array[1] = <STDIN>;
1301 However, in list context, the line input operator returns all of the
1302 lines as a list. The first line goes into C<@array[1]> and the rest
1303 of the lines mysteriously disappear:
1305 @array[1] = <STDIN>; # most likely not what you want
1307 Either the C<use warnings> pragma or the B<-w> flag will warn you when
1308 you use an array slice with a single index.
1310 =head2 How can I remove duplicate elements from a list or array?
1312 (contributed by brian d foy)
1314 Use a hash. When you think the words "unique" or "duplicated", think
1317 If you don't care about the order of the elements, you could just
1318 create the hash then extract the keys. It's not important how you
1319 create that hash: just that you use C<keys> to get the unique
1322 my %hash = map { $_, 1 } @array;
1323 # or a hash slice: @hash{ @array } = ();
1324 # or a foreach: $hash{$_} = 1 foreach ( @array );
1326 my @unique = keys %hash;
1328 If you want to use a module, try the C<uniq> function from
1329 C<List::MoreUtils>. In list context it returns the unique elements,
1330 preserving their order in the list. In scalar context, it returns the
1331 number of unique elements.
1333 use List::MoreUtils qw(uniq);
1335 my @unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 1,2,3,4,5,6,7
1336 my $unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 7
1338 You can also go through each element and skip the ones you've seen
1339 before. Use a hash to keep track. The first time the loop sees an
1340 element, that element has no key in C<%Seen>. The C<next> statement
1341 creates the key and immediately uses its value, which is C<undef>, so
1342 the loop continues to the C<push> and increments the value for that
1343 key. The next time the loop sees that same element, its key exists in
1344 the hash I<and> the value for that key is true (since it's not 0 or
1345 C<undef>), so the next skips that iteration and the loop goes to the
1351 foreach my $elem ( @array )
1353 next if $seen{ $elem }++;
1354 push @unique, $elem;
1357 You can write this more briefly using a grep, which does the
1361 my @unique = grep { ! $seen{ $_ }++ } @array;
1363 =head2 How can I tell whether a certain element is contained in a list or array?
1365 (portions of this answer contributed by Anno Siegel and brian d foy)
1367 Hearing the word "in" is an I<in>dication that you probably should have
1368 used a hash, not a list or array, to store your data. Hashes are
1369 designed to answer this question quickly and efficiently. Arrays aren't.
1371 That being said, there are several ways to approach this. In Perl 5.10
1372 and later, you can use the smart match operator to check that an item is
1373 contained in an array or a hash:
1377 if( $item ~~ @array )
1379 say "The array contains $item"
1382 if( $item ~~ %hash )
1384 say "The hash contains $item"
1387 With earlier versions of Perl, you have to do a bit more work. If you
1388 are going to make this query many times over arbitrary string values,
1389 the fastest way is probably to invert the original array and maintain a
1390 hash whose keys are the first array's values:
1392 @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1394 for (@blues) { $is_blue{$_} = 1 }
1396 Now you can check whether C<$is_blue{$some_color}>. It might have
1397 been a good idea to keep the blues all in a hash in the first place.
1399 If the values are all small integers, you could use a simple indexed
1400 array. This kind of an array will take up less space:
1402 @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1403 @is_tiny_prime = ();
1404 for (@primes) { $is_tiny_prime[$_] = 1 }
1405 # or simply @istiny_prime[@primes] = (1) x @primes;
1407 Now you check whether $is_tiny_prime[$some_number].
1409 If the values in question are integers instead of strings, you can save
1410 quite a lot of space by using bit strings instead:
1412 @articles = ( 1..10, 150..2000, 2017 );
1414 for (@articles) { vec($read,$_,1) = 1 }
1416 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1418 These methods guarantee fast individual tests but require a re-organization
1419 of the original list or array. They only pay off if you have to test
1420 multiple values against the same array.
1422 If you are testing only once, the standard module C<List::Util> exports
1423 the function C<first> for this purpose. It works by stopping once it
1424 finds the element. It's written in C for speed, and its Perl equivalent
1425 looks like this subroutine:
1430 return $_ if &{$code}();
1435 If speed is of little concern, the common idiom uses grep in scalar context
1436 (which returns the number of items that passed its condition) to traverse the
1437 entire list. This does have the benefit of telling you how many matches it
1440 my $is_there = grep $_ eq $whatever, @array;
1442 If you want to actually extract the matching elements, simply use grep in
1445 my @matches = grep $_ eq $whatever, @array;
1447 =head2 How do I compute the difference of two arrays? How do I compute the intersection of two arrays?
1449 Use a hash. Here's code to do both and more. It assumes that each
1450 element is unique in a given array:
1452 @union = @intersection = @difference = ();
1454 foreach $element (@array1, @array2) { $count{$element}++ }
1455 foreach $element (keys %count) {
1456 push @union, $element;
1457 push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1460 Note that this is the I<symmetric difference>, that is, all elements
1461 in either A or in B but not in both. Think of it as an xor operation.
1463 =head2 How do I test whether two arrays or hashes are equal?
1465 With Perl 5.10 and later, the smart match operator can give you the answer
1466 with the least amount of work:
1470 if( @array1 ~~ @array2 )
1472 say "The arrays are the same";
1475 if( %hash1 ~~ %hash2 ) # doesn't check values!
1477 say "The hash keys are the same";
1480 The following code works for single-level arrays. It uses a
1481 stringwise comparison, and does not distinguish defined versus
1482 undefined empty strings. Modify if you have other needs.
1484 $are_equal = compare_arrays(\@frogs, \@toads);
1486 sub compare_arrays {
1487 my ($first, $second) = @_;
1488 no warnings; # silence spurious -w undef complaints
1489 return 0 unless @$first == @$second;
1490 for (my $i = 0; $i < @$first; $i++) {
1491 return 0 if $first->[$i] ne $second->[$i];
1496 For multilevel structures, you may wish to use an approach more
1497 like this one. It uses the CPAN module C<FreezeThaw>:
1499 use FreezeThaw qw(cmpStr);
1500 @a = @b = ( "this", "that", [ "more", "stuff" ] );
1502 printf "a and b contain %s arrays\n",
1503 cmpStr(\@a, \@b) == 0
1507 This approach also works for comparing hashes. Here we'll demonstrate
1508 two different answers:
1510 use FreezeThaw qw(cmpStr cmpStrHard);
1512 %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1516 printf "a and b contain %s hashes\n",
1517 cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1519 printf "a and b contain %s hashes\n",
1520 cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1523 The first reports that both those the hashes contain the same data,
1524 while the second reports that they do not. Which you prefer is left as
1525 an exercise to the reader.
1527 =head2 How do I find the first array element for which a condition is true?
1529 To find the first array element which satisfies a condition, you can
1530 use the C<first()> function in the C<List::Util> module, which comes
1531 with Perl 5.8. This example finds the first element that contains
1534 use List::Util qw(first);
1536 my $element = first { /Perl/ } @array;
1538 If you cannot use C<List::Util>, you can make your own loop to do the
1539 same thing. Once you find the element, you stop the loop with last.
1542 foreach ( @array ) {
1543 if( /Perl/ ) { $found = $_; last }
1546 If you want the array index, you can iterate through the indices
1547 and check the array element at each index until you find one
1548 that satisfies the condition.
1550 my( $found, $index ) = ( undef, -1 );
1551 for( $i = 0; $i < @array; $i++ ) {
1552 if( $array[$i] =~ /Perl/ ) {
1553 $found = $array[$i];
1559 =head2 How do I handle linked lists?
1561 In general, you usually don't need a linked list in Perl, since with
1562 regular arrays, you can push and pop or shift and unshift at either
1563 end, or you can use splice to add and/or remove arbitrary number of
1564 elements at arbitrary points. Both pop and shift are O(1)
1565 operations on Perl's dynamic arrays. In the absence of shifts and
1566 pops, push in general needs to reallocate on the order every log(N)
1567 times, and unshift will need to copy pointers each time.
1569 If you really, really wanted, you could use structures as described in
1570 L<perldsc> or L<perltoot> and do just what the algorithm book tells
1571 you to do. For example, imagine a list node like this:
1578 You could walk the list this way:
1581 for ($node = $head; $node; $node = $node->{LINK}) {
1582 print $node->{VALUE}, " ";
1586 You could add to the list this way:
1589 $tail = append($head, 1); # grow a new head
1590 for $value ( 2 .. 10 ) {
1591 $tail = append($tail, $value);
1595 my($list, $value) = @_;
1596 my $node = { VALUE => $value };
1598 $node->{LINK} = $list->{LINK};
1599 $list->{LINK} = $node;
1602 $_[0] = $node; # replace caller's version
1607 But again, Perl's built-in are virtually always good enough.
1609 =head2 How do I handle circular lists?
1610 X<circular> X<array> X<Tie::Cycle> X<Array::Iterator::Circular>
1613 (contributed by brian d foy)
1615 If you want to cycle through an array endlessly, you can increment the
1616 index modulo the number of elements in the array:
1618 my @array = qw( a b c );
1622 print $array[ $i++ % @array ], "\n";
1626 You can also use C<Tie::Cycle> to use a scalar that always has the
1627 next element of the circular array:
1631 tie my $cycle, 'Tie::Cycle', [ qw( FFFFFF 000000 FFFF00 ) ];
1633 print $cycle; # FFFFFF
1634 print $cycle; # 000000
1635 print $cycle; # FFFF00
1637 The C<Array::Iterator::Circular> creates an iterator object for
1640 use Array::Iterator::Circular;
1642 my $color_iterator = Array::Iterator::Circular->new(
1643 qw(red green blue orange)
1646 foreach ( 1 .. 20 ) {
1647 print $color_iterator->next, "\n";
1650 =head2 How do I shuffle an array randomly?
1652 If you either have Perl 5.8.0 or later installed, or if you have
1653 Scalar-List-Utils 1.03 or later installed, you can say:
1655 use List::Util 'shuffle';
1657 @shuffled = shuffle(@list);
1659 If not, you can use a Fisher-Yates shuffle.
1661 sub fisher_yates_shuffle {
1662 my $deck = shift; # $deck is a reference to an array
1663 return unless @$deck; # must not be empty!
1667 my $j = int rand ($i+1);
1668 @$deck[$i,$j] = @$deck[$j,$i];
1672 # shuffle my mpeg collection
1674 my @mpeg = <audio/*/*.mp3>;
1675 fisher_yates_shuffle( \@mpeg ); # randomize @mpeg in place
1678 Note that the above implementation shuffles an array in place,
1679 unlike the C<List::Util::shuffle()> which takes a list and returns
1680 a new shuffled list.
1682 You've probably seen shuffling algorithms that work using splice,
1683 randomly picking another element to swap the current element with
1687 @old = 1 .. 10; # just a demo
1689 push(@new, splice(@old, rand @old, 1));
1692 This is bad because splice is already O(N), and since you do it N
1693 times, you just invented a quadratic algorithm; that is, O(N**2).
1694 This does not scale, although Perl is so efficient that you probably
1695 won't notice this until you have rather largish arrays.
1697 =head2 How do I process/modify each element of an array?
1699 Use C<for>/C<foreach>:
1702 s/foo/bar/; # change that word
1703 tr/XZ/ZX/; # swap those letters
1706 Here's another; let's compute spherical volumes:
1708 for (@volumes = @radii) { # @volumes has changed parts
1710 $_ *= (4/3) * 3.14159; # this will be constant folded
1713 which can also be done with C<map()> which is made to transform
1714 one list into another:
1716 @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1718 If you want to do the same thing to modify the values of the
1719 hash, you can use the C<values> function. As of Perl 5.6
1720 the values are not copied, so if you modify $orbit (in this
1721 case), you modify the value.
1723 for $orbit ( values %orbits ) {
1724 ($orbit **= 3) *= (4/3) * 3.14159;
1727 Prior to perl 5.6 C<values> returned copies of the values,
1728 so older perl code often contains constructions such as
1729 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1730 the hash is to be modified.
1732 =head2 How do I select a random element from an array?
1734 Use the C<rand()> function (see L<perlfunc/rand>):
1736 $index = rand @array;
1737 $element = $array[$index];
1741 my $element = $array[ rand @array ];
1743 =head2 How do I permute N elements of a list?
1744 X<List::Permuter> X<permute> X<Algorithm::Loops> X<Knuth>
1745 X<The Art of Computer Programming> X<Fischer-Krause>
1747 Use the C<List::Permutor> module on CPAN. If the list is actually an
1748 array, try the C<Algorithm::Permute> module (also on CPAN). It's
1749 written in XS code and is very efficient:
1751 use Algorithm::Permute;
1753 my @array = 'a'..'d';
1754 my $p_iterator = Algorithm::Permute->new ( \@array );
1756 while (my @perm = $p_iterator->next) {
1757 print "next permutation: (@perm)\n";
1760 For even faster execution, you could do:
1762 use Algorithm::Permute;
1764 my @array = 'a'..'d';
1766 Algorithm::Permute::permute {
1767 print "next permutation: (@array)\n";
1770 Here's a little program that generates all permutations of all the
1771 words on each line of input. The algorithm embodied in the
1772 C<permute()> function is discussed in Volume 4 (still unpublished) of
1773 Knuth's I<The Art of Computer Programming> and will work on any list:
1776 # Fischer-Krause ordered permutation generator
1781 while ( $code->(@_[@idx]) ) {
1783 --$p while $idx[$p-1] > $idx[$p];
1784 my $q = $p or return;
1785 push @idx, reverse splice @idx, $p;
1786 ++$q while $idx[$p-1] > $idx[$q];
1787 @idx[$p-1,$q]=@idx[$q,$p-1];
1791 permute { print "@_\n" } split;
1793 The C<Algorithm::Loops> module also provides the C<NextPermute> and
1794 C<NextPermuteNum> functions which efficiently find all unique permutations
1795 of an array, even if it contains duplicate values, modifying it in-place:
1796 if its elements are in reverse-sorted order then the array is reversed,
1797 making it sorted, and it returns false; otherwise the next
1798 permutation is returned.
1800 C<NextPermute> uses string order and C<NextPermuteNum> numeric order, so
1801 you can enumerate all the permutations of C<0..9> like this:
1803 use Algorithm::Loops qw(NextPermuteNum);
1806 do { print "@list\n" } while NextPermuteNum @list;
1808 =head2 How do I sort an array by (anything)?
1810 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1812 @list = sort { $a <=> $b } @list;
1814 The default sort function is cmp, string comparison, which would
1815 sort C<(1, 2, 10)> into C<(1, 10, 2)>. C<< <=> >>, used above, is
1816 the numerical comparison operator.
1818 If you have a complicated function needed to pull out the part you
1819 want to sort on, then don't do it inside the sort function. Pull it
1820 out first, because the sort BLOCK can be called many times for the
1821 same element. Here's an example of how to pull out the first word
1822 after the first number on each item, and then sort those words
1827 ($item) = /\d+\s*(\S+)/;
1828 push @idx, uc($item);
1830 @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1832 which could also be written this way, using a trick
1833 that's come to be known as the Schwartzian Transform:
1835 @sorted = map { $_->[0] }
1836 sort { $a->[1] cmp $b->[1] }
1837 map { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1839 If you need to sort on several fields, the following paradigm is useful.
1842 field1($a) <=> field1($b) ||
1843 field2($a) cmp field2($b) ||
1844 field3($a) cmp field3($b)
1847 This can be conveniently combined with precalculation of keys as given
1850 See the F<sort> article in the "Far More Than You Ever Wanted
1851 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1852 more about this approach.
1854 See also the question later in L<perlfaq4> on sorting hashes.
1856 =head2 How do I manipulate arrays of bits?
1858 Use C<pack()> and C<unpack()>, or else C<vec()> and the bitwise
1861 For example, you don't have to store individual bits in an array
1862 (which would mean that you're wasting a lot of space). To convert an
1863 array of bits to a string, use C<vec()> to set the right bits. This
1864 sets C<$vec> to have bit N set only if C<$ints[N]> was set:
1866 @ints = (...); # array of bits, e.g. ( 1, 0, 0, 1, 1, 0 ... )
1868 foreach( 0 .. $#ints ) {
1869 vec($vec,$_,1) = 1 if $ints[$_];
1872 The string C<$vec> only takes up as many bits as it needs. For
1873 instance, if you had 16 entries in C<@ints>, C<$vec> only needs two
1874 bytes to store them (not counting the scalar variable overhead).
1876 Here's how, given a vector in C<$vec>, you can get those bits into
1877 your C<@ints> array:
1879 sub bitvec_to_list {
1882 # Find null-byte density then select best algorithm
1883 if ($vec =~ tr/\0// / length $vec > 0.95) {
1887 # This method is faster with mostly null-bytes
1888 while($vec =~ /[^\0]/g ) {
1889 $i = -9 + 8 * pos $vec;
1890 push @ints, $i if vec($vec, ++$i, 1);
1891 push @ints, $i if vec($vec, ++$i, 1);
1892 push @ints, $i if vec($vec, ++$i, 1);
1893 push @ints, $i if vec($vec, ++$i, 1);
1894 push @ints, $i if vec($vec, ++$i, 1);
1895 push @ints, $i if vec($vec, ++$i, 1);
1896 push @ints, $i if vec($vec, ++$i, 1);
1897 push @ints, $i if vec($vec, ++$i, 1);
1901 # This method is a fast general algorithm
1903 my $bits = unpack "b*", $vec;
1904 push @ints, 0 if $bits =~ s/^(\d)// && $1;
1905 push @ints, pos $bits while($bits =~ /1/g);
1911 This method gets faster the more sparse the bit vector is.
1912 (Courtesy of Tim Bunce and Winfried Koenig.)
1914 You can make the while loop a lot shorter with this suggestion
1915 from Benjamin Goldberg:
1917 while($vec =~ /[^\0]+/g ) {
1918 push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1921 Or use the CPAN module C<Bit::Vector>:
1923 $vector = Bit::Vector->new($num_of_bits);
1924 $vector->Index_List_Store(@ints);
1925 @ints = $vector->Index_List_Read();
1927 C<Bit::Vector> provides efficient methods for bit vector, sets of
1928 small integers and "big int" math.
1930 Here's a more extensive illustration using vec():
1933 $vector = "\xff\x0f\xef\xfe";
1934 print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1935 unpack("N", $vector), "\n";
1936 $is_set = vec($vector, 23, 1);
1937 print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1955 my ($offset, $width, $value) = @_;
1957 vec($vector, $offset, $width) = $value;
1958 print "offset=$offset width=$width value=$value\n";
1964 my $bits = unpack("b*", $vector);
1968 print "vector length in bytes: ", length($vector), "\n";
1969 @bytes = unpack("A8" x length($vector), $bits);
1970 print "bits are: @bytes\n\n";
1973 =head2 Why does defined() return true on empty arrays and hashes?
1975 The short story is that you should probably only use defined on scalars or
1976 functions, not on aggregates (arrays and hashes). See L<perlfunc/defined>
1977 in the 5.004 release or later of Perl for more detail.
1979 =head1 Data: Hashes (Associative Arrays)
1981 =head2 How do I process an entire hash?
1983 (contributed by brian d foy)
1985 There are a couple of ways that you can process an entire hash. You
1986 can get a list of keys, then go through each key, or grab a one
1987 key-value pair at a time.
1989 To go through all of the keys, use the C<keys> function. This extracts
1990 all of the keys of the hash and gives them back to you as a list. You
1991 can then get the value through the particular key you're processing:
1993 foreach my $key ( keys %hash ) {
1994 my $value = $hash{$key}
1998 Once you have the list of keys, you can process that list before you
1999 process the hash elements. For instance, you can sort the keys so you
2000 can process them in lexical order:
2002 foreach my $key ( sort keys %hash ) {
2003 my $value = $hash{$key}
2007 Or, you might want to only process some of the items. If you only want
2008 to deal with the keys that start with C<text:>, you can select just
2009 those using C<grep>:
2011 foreach my $key ( grep /^text:/, keys %hash ) {
2012 my $value = $hash{$key}
2016 If the hash is very large, you might not want to create a long list of
2017 keys. To save some memory, you can grab one key-value pair at a time using
2018 C<each()>, which returns a pair you haven't seen yet:
2020 while( my( $key, $value ) = each( %hash ) ) {
2024 The C<each> operator returns the pairs in apparently random order, so if
2025 ordering matters to you, you'll have to stick with the C<keys> method.
2027 The C<each()> operator can be a bit tricky though. You can't add or
2028 delete keys of the hash while you're using it without possibly
2029 skipping or re-processing some pairs after Perl internally rehashes
2030 all of the elements. Additionally, a hash has only one iterator, so if
2031 you use C<keys>, C<values>, or C<each> on the same hash, you can reset
2032 the iterator and mess up your processing. See the C<each> entry in
2033 L<perlfunc> for more details.
2035 =head2 How do I merge two hashes?
2036 X<hash> X<merge> X<slice, hash>
2038 (contributed by brian d foy)
2040 Before you decide to merge two hashes, you have to decide what to do
2041 if both hashes contain keys that are the same and if you want to leave
2042 the original hashes as they were.
2044 If you want to preserve the original hashes, copy one hash (C<%hash1>)
2045 to a new hash (C<%new_hash>), then add the keys from the other hash
2046 (C<%hash2> to the new hash. Checking that the key already exists in
2047 C<%new_hash> gives you a chance to decide what to do with the
2050 my %new_hash = %hash1; # make a copy; leave %hash1 alone
2052 foreach my $key2 ( keys %hash2 )
2054 if( exists $new_hash{$key2} )
2056 warn "Key [$key2] is in both hashes!";
2057 # handle the duplicate (perhaps only warning)
2063 $new_hash{$key2} = $hash2{$key2};
2067 If you don't want to create a new hash, you can still use this looping
2068 technique; just change the C<%new_hash> to C<%hash1>.
2070 foreach my $key2 ( keys %hash2 )
2072 if( exists $hash1{$key2} )
2074 warn "Key [$key2] is in both hashes!";
2075 # handle the duplicate (perhaps only warning)
2081 $hash1{$key2} = $hash2{$key2};
2085 If you don't care that one hash overwrites keys and values from the other, you
2086 could just use a hash slice to add one hash to another. In this case, values
2087 from C<%hash2> replace values from C<%hash1> when they have keys in common:
2089 @hash1{ keys %hash2 } = values %hash2;
2091 =head2 What happens if I add or remove keys from a hash while iterating over it?
2093 (contributed by brian d foy)
2095 The easy answer is "Don't do that!"
2097 If you iterate through the hash with each(), you can delete the key
2098 most recently returned without worrying about it. If you delete or add
2099 other keys, the iterator may skip or double up on them since perl
2100 may rearrange the hash table. See the
2101 entry for C<each()> in L<perlfunc>.
2103 =head2 How do I look up a hash element by value?
2105 Create a reverse hash:
2107 %by_value = reverse %by_key;
2108 $key = $by_value{$value};
2110 That's not particularly efficient. It would be more space-efficient
2113 while (($key, $value) = each %by_key) {
2114 $by_value{$value} = $key;
2117 If your hash could have repeated values, the methods above will only find
2118 one of the associated keys. This may or may not worry you. If it does
2119 worry you, you can always reverse the hash into a hash of arrays instead:
2121 while (($key, $value) = each %by_key) {
2122 push @{$key_list_by_value{$value}}, $key;
2125 =head2 How can I know how many entries are in a hash?
2127 (contributed by brian d foy)
2129 This is very similar to "How do I process an entire hash?", also in
2130 L<perlfaq4>, but a bit simpler in the common cases.
2132 You can use the C<keys()> built-in function in scalar context to find out
2133 have many entries you have in a hash:
2135 my $key_count = keys %hash; # must be scalar context!
2137 If you want to find out how many entries have a defined value, that's
2138 a bit different. You have to check each value. A C<grep> is handy:
2140 my $defined_value_count = grep { defined } values %hash;
2142 You can use that same structure to count the entries any way that
2143 you like. If you want the count of the keys with vowels in them,
2144 you just test for that instead:
2146 my $vowel_count = grep { /[aeiou]/ } keys %hash;
2148 The C<grep> in scalar context returns the count. If you want the list
2149 of matching items, just use it in list context instead:
2151 my @defined_values = grep { defined } values %hash;
2153 The C<keys()> function also resets the iterator, which means that you may
2154 see strange results if you use this between uses of other hash operators
2157 =head2 How do I sort a hash (optionally by value instead of key)?
2159 (contributed by brian d foy)
2161 To sort a hash, start with the keys. In this example, we give the list of
2162 keys to the sort function which then compares them ASCIIbetically (which
2163 might be affected by your locale settings). The output list has the keys
2164 in ASCIIbetical order. Once we have the keys, we can go through them to
2165 create a report which lists the keys in ASCIIbetical order.
2167 my @keys = sort { $a cmp $b } keys %hash;
2169 foreach my $key ( @keys )
2171 printf "%-20s %6d\n", $key, $hash{$key};
2174 We could get more fancy in the C<sort()> block though. Instead of
2175 comparing the keys, we can compute a value with them and use that
2176 value as the comparison.
2178 For instance, to make our report order case-insensitive, we use
2179 the C<\L> sequence in a double-quoted string to make everything
2180 lowercase. The C<sort()> block then compares the lowercased
2181 values to determine in which order to put the keys.
2183 my @keys = sort { "\L$a" cmp "\L$b" } keys %hash;
2185 Note: if the computation is expensive or the hash has many elements,
2186 you may want to look at the Schwartzian Transform to cache the
2187 computation results.
2189 If we want to sort by the hash value instead, we use the hash key
2190 to look it up. We still get out a list of keys, but this time they
2191 are ordered by their value.
2193 my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash;
2195 From there we can get more complex. If the hash values are the same,
2196 we can provide a secondary sort on the hash key.
2199 $hash{$a} <=> $hash{$b}
2204 =head2 How can I always keep my hash sorted?
2205 X<hash tie sort DB_File Tie::IxHash>
2207 You can look into using the C<DB_File> module and C<tie()> using the
2208 C<$DB_BTREE> hash bindings as documented in L<DB_File/"In Memory
2209 Databases">. The C<Tie::IxHash> module from CPAN might also be
2210 instructive. Although this does keep your hash sorted, you might not
2211 like the slow down you suffer from the tie interface. Are you sure you
2214 =head2 What's the difference between "delete" and "undef" with hashes?
2216 Hashes contain pairs of scalars: the first is the key, the
2217 second is the value. The key will be coerced to a string,
2218 although the value can be any kind of scalar: string,
2219 number, or reference. If a key C<$key> is present in
2220 %hash, C<exists($hash{$key})> will return true. The value
2221 for a given key can be C<undef>, in which case
2222 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
2223 will return true. This corresponds to (C<$key>, C<undef>)
2226 Pictures help... Here's the C<%hash> table:
2236 And these conditions hold
2240 defined $hash{'d'} is true
2241 defined $hash{'a'} is true
2242 exists $hash{'a'} is true (Perl 5 only)
2243 grep ($_ eq 'a', keys %hash) is true
2249 your table now reads:
2260 and these conditions now hold; changes in caps:
2264 defined $hash{'d'} is true
2265 defined $hash{'a'} is FALSE
2266 exists $hash{'a'} is true (Perl 5 only)
2267 grep ($_ eq 'a', keys %hash) is true
2269 Notice the last two: you have an undef value, but a defined key!
2275 your table now reads:
2284 and these conditions now hold; changes in caps:
2288 defined $hash{'d'} is true
2289 defined $hash{'a'} is false
2290 exists $hash{'a'} is FALSE (Perl 5 only)
2291 grep ($_ eq 'a', keys %hash) is FALSE
2293 See, the whole entry is gone!
2295 =head2 Why don't my tied hashes make the defined/exists distinction?
2297 This depends on the tied hash's implementation of EXISTS().
2298 For example, there isn't the concept of undef with hashes
2299 that are tied to DBM* files. It also means that exists() and
2300 defined() do the same thing with a DBM* file, and what they
2301 end up doing is not what they do with ordinary hashes.
2303 =head2 How do I reset an each() operation part-way through?
2305 (contributed by brian d foy)
2307 You can use the C<keys> or C<values> functions to reset C<each>. To
2308 simply reset the iterator used by C<each> without doing anything else,
2309 use one of them in void context:
2311 keys %hash; # resets iterator, nothing else.
2312 values %hash; # resets iterator, nothing else.
2314 See the documentation for C<each> in L<perlfunc>.
2316 =head2 How can I get the unique keys from two hashes?
2318 First you extract the keys from the hashes into lists, then solve
2319 the "removing duplicates" problem described above. For example:
2322 for $element (keys(%foo), keys(%bar)) {
2329 @uniq = keys %{{%foo,%bar}};
2331 Or if you really want to save space:
2334 while (defined ($key = each %foo)) {
2337 while (defined ($key = each %bar)) {
2342 =head2 How can I store a multidimensional array in a DBM file?
2344 Either stringify the structure yourself (no fun), or else
2345 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
2346 it on top of either DB_File or GDBM_File.
2348 =head2 How can I make my hash remember the order I put elements into it?
2350 Use the C<Tie::IxHash> from CPAN.
2354 tie my %myhash, 'Tie::IxHash';
2356 for (my $i=0; $i<20; $i++) {
2360 my @keys = keys %myhash;
2361 # @keys = (0,1,2,3,...)
2363 =head2 Why does passing a subroutine an undefined element in a hash create it?
2365 (contributed by brian d foy)
2367 Are you using a really old version of Perl?
2369 Normally, accessing a hash key's value for a nonexistent key will
2370 I<not> create the key.
2373 my $value = $hash{ 'foo' };
2374 print "This won't print\n" if exists $hash{ 'foo' };
2376 Passing C<$hash{ 'foo' }> to a subroutine used to be a special case, though.
2377 Since you could assign directly to C<$_[0]>, Perl had to be ready to
2378 make that assignment so it created the hash key ahead of time:
2380 my_sub( $hash{ 'foo' } );
2381 print "This will print before 5.004\n" if exists $hash{ 'foo' };
2384 # $_[0] = 'bar'; # create hash key in case you do this
2388 Since Perl 5.004, however, this situation is a special case and Perl
2389 creates the hash key only when you make the assignment:
2391 my_sub( $hash{ 'foo' } );
2392 print "This will print, even after 5.004\n" if exists $hash{ 'foo' };
2398 However, if you want the old behavior (and think carefully about that
2399 because it's a weird side effect), you can pass a hash slice instead.
2400 Perl 5.004 didn't make this a special case:
2402 my_sub( @hash{ qw/foo/ } );
2404 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
2406 Usually a hash ref, perhaps like this:
2411 TITLE => "deputy peon",
2414 PALS => [ "Norbert", "Rhys", "Phineas"],
2417 References are documented in L<perlref> and the upcoming L<perlreftut>.
2418 Examples of complex data structures are given in L<perldsc> and
2419 L<perllol>. Examples of structures and object-oriented classes are
2422 =head2 How can I use a reference as a hash key?
2424 (contributed by brian d foy and Ben Morrow)
2426 Hash keys are strings, so you can't really use a reference as the key.
2427 When you try to do that, perl turns the reference into its stringified
2428 form (for instance, C<HASH(0xDEADBEEF)>). From there you can't get
2429 back the reference from the stringified form, at least without doing
2430 some extra work on your own.
2432 Remember that the entry in the hash will still be there even if
2433 the referenced variable goes out of scope, and that it is entirely
2434 possible for Perl to subsequently allocate a different variable at
2435 the same address. This will mean a new variable might accidentally
2436 be associated with the value for an old.
2438 If you have Perl 5.10 or later, and you just want to store a value
2439 against the reference for lookup later, you can use the core
2440 Hash::Util::Fieldhash module. This will also handle renaming the
2441 keys if you use multiple threads (which causes all variables to be
2442 reallocated at new addresses, changing their stringification), and
2443 garbage-collecting the entries when the referenced variable goes out
2446 If you actually need to be able to get a real reference back from
2447 each hash entry, you can use the Tie::RefHash module, which does the
2448 required work for you.
2452 =head2 How do I handle binary data correctly?
2454 Perl is binary clean, so it can handle binary data just fine.
2455 On Windows or DOS, however, you have to use C<binmode> for binary
2456 files to avoid conversions for line endings. In general, you should
2457 use C<binmode> any time you want to work with binary data.
2459 Also see L<perlfunc/"binmode"> or L<perlopentut>.
2461 If you're concerned about 8-bit textual data then see L<perllocale>.
2462 If you want to deal with multibyte characters, however, there are
2463 some gotchas. See the section on Regular Expressions.
2465 =head2 How do I determine whether a scalar is a number/whole/integer/float?
2467 Assuming that you don't care about IEEE notations like "NaN" or
2468 "Infinity", you probably just want to use a regular expression.
2470 if (/\D/) { print "has nondigits\n" }
2471 if (/^\d+$/) { print "is a whole number\n" }
2472 if (/^-?\d+$/) { print "is an integer\n" }
2473 if (/^[+-]?\d+$/) { print "is a +/- integer\n" }
2474 if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
2475 if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
2476 if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
2477 { print "a C float\n" }
2479 There are also some commonly used modules for the task.
2480 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2481 internal function C<looks_like_number> for determining whether a
2482 variable looks like a number. L<Data::Types> exports functions that
2483 validate data types using both the above and other regular
2484 expressions. Thirdly, there is C<Regexp::Common> which has regular
2485 expressions to match various types of numbers. Those three modules are
2486 available from the CPAN.
2488 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2489 function. Its semantics are somewhat cumbersome, so here's a
2490 C<getnum> wrapper function for more convenient access. This function
2491 takes a string and returns the number it found, or C<undef> for input
2492 that isn't a C float. The C<is_numeric> function is a front end to
2493 C<getnum> if you just want to say, "Is this a float?"
2496 use POSIX qw(strtod);
2501 my($num, $unparsed) = strtod($str);
2502 if (($str eq '') || ($unparsed != 0) || $!) {
2510 sub is_numeric { defined getnum($_[0]) }
2512 Or you could check out the L<String::Scanf> module on the CPAN
2513 instead. The C<POSIX> module (part of the standard Perl distribution)
2514 provides the C<strtod> and C<strtol> for converting strings to double
2515 and longs, respectively.
2517 =head2 How do I keep persistent data across program calls?
2519 For some specific applications, you can use one of the DBM modules.
2520 See L<AnyDBM_File>. More generically, you should consult the C<FreezeThaw>
2521 or C<Storable> modules from CPAN. Starting from Perl 5.8 C<Storable> is part
2522 of the standard distribution. Here's one example using C<Storable>'s C<store>
2523 and C<retrieve> functions:
2526 store(\%hash, "filename");
2529 $href = retrieve("filename"); # by ref
2530 %hash = %{ retrieve("filename") }; # direct to hash
2532 =head2 How do I print out or copy a recursive data structure?
2534 The C<Data::Dumper> module on CPAN (or the 5.005 release of Perl) is great
2535 for printing out data structures. The C<Storable> module on CPAN (or the
2536 5.8 release of Perl), provides a function called C<dclone> that recursively
2537 copies its argument.
2539 use Storable qw(dclone);
2542 Where C<$r1> can be a reference to any kind of data structure you'd like.
2543 It will be deeply copied. Because C<dclone> takes and returns references,
2544 you'd have to add extra punctuation if you had a hash of arrays that
2547 %newhash = %{ dclone(\%oldhash) };
2549 =head2 How do I define methods for every class/object?
2551 (contributed by Ben Morrow)
2553 You can use the C<UNIVERSAL> class (see L<UNIVERSAL>). However, please
2554 be very careful to consider the consequences of doing this: adding
2555 methods to every object is very likely to have unintended
2556 consequences. If possible, it would be better to have all your object
2557 inherit from some common base class, or to use an object system like
2558 Moose that supports roles.
2560 =head2 How do I verify a credit card checksum?
2562 Get the C<Business::CreditCard> module from CPAN.
2564 =head2 How do I pack arrays of doubles or floats for XS code?
2566 The arrays.h/arrays.c code in the C<PGPLOT> module on CPAN does just this.
2567 If you're doing a lot of float or double processing, consider using
2568 the C<PDL> module from CPAN instead--it makes number-crunching easy.
2570 See L<http://search.cpan.org/dist/PGPLOT> for the code.
2572 =head1 AUTHOR AND COPYRIGHT
2574 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
2575 other authors as noted. All rights reserved.
2577 This documentation is free; you can redistribute it and/or modify it
2578 under the same terms as Perl itself.
2580 Irrespective of its distribution, all code examples in this file
2581 are hereby placed into the public domain. You are permitted and
2582 encouraged to use this code in your own programs for fun
2583 or for profit as you see fit. A simple comment in the code giving
2584 credit would be courteous but is not required.