3 perlfaq4 - Data Manipulation ($Revision: 1.64 $, $Date: 2005/04/27 00:18:04 $)
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
14 Internally, your computer represents floating-point numbers
15 in binary. Digital (as in powers of two) computers cannot
16 store all numbers exactly. Some real numbers lose precision
17 in the process. This is a problem with how computers store
18 numbers and affects all computer languages, not just Perl.
20 L<perlnumber> show the gory details of number
21 representations and conversions.
23 To limit the number of decimal places in your numbers, you
24 can use the printf or sprintf function. See the
25 L<"Floating Point Arithmetic"|perlop> for more details.
29 my $number = sprintf "%.2f", 10/3;
31 =head2 Why is int() broken?
33 Your int() is most probably working just fine. It's the numbers that
34 aren't quite what you think.
36 First, see the above item "Why am I getting long decimals
37 (eg, 19.9499999999999) instead of the numbers I should be getting
42 print int(0.6/0.2-2), "\n";
44 will in most computers print 0, not 1, because even such simple
45 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
46 numbers. What you think in the above as 'three' is really more like
47 2.9999999999999995559.
49 =head2 Why isn't my octal data interpreted correctly?
51 Perl only understands octal and hex numbers as such when they occur as
52 literals in your program. Octal literals in perl must start with a
53 leading "0" and hexadecimal literals must start with a leading "0x".
54 If they are read in from somewhere and assigned, no automatic
55 conversion takes place. You must explicitly use oct() or hex() if you
56 want the values converted to decimal. oct() interprets hex ("0x350"),
57 octal ("0350" or even without the leading "0", like "377") and binary
58 ("0b1010") numbers, while hex() only converts hexadecimal ones, with
59 or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
60 The inverse mapping from decimal to octal can be done with either the
61 "%o" or "%O" sprintf() formats.
63 This problem shows up most often when people try using chmod(), mkdir(),
64 umask(), or sysopen(), which by widespread tradition typically take
67 chmod(644, $file); # WRONG
68 chmod(0644, $file); # right
70 Note the mistake in the first line was specifying the decimal literal
71 644, rather than the intended octal literal 0644. The problem can
74 printf("%#o",644); # prints 01204
76 Surely you had not intended C<chmod(01204, $file);> - did you? If you
77 want to use numeric literals as arguments to chmod() et al. then please
78 try to express them as octal constants, that is with a leading zero and
79 with the following digits restricted to the set 0..7.
81 =head2 Does Perl have a round() function? What about ceil() and floor()? Trig functions?
83 Remember that int() merely truncates toward 0. For rounding to a
84 certain number of digits, sprintf() or printf() is usually the easiest
87 printf("%.3f", 3.1415926535); # prints 3.142
89 The POSIX module (part of the standard Perl distribution) implements
90 ceil(), floor(), and a number of other mathematical and trigonometric
94 $ceil = ceil(3.5); # 4
95 $floor = floor(3.5); # 3
97 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
98 module. With 5.004, the Math::Trig module (part of the standard Perl
99 distribution) implements the trigonometric functions. Internally it
100 uses the Math::Complex module and some functions can break out from
101 the real axis into the complex plane, for example the inverse sine of
104 Rounding in financial applications can have serious implications, and
105 the rounding method used should be specified precisely. In these
106 cases, it probably pays not to trust whichever system rounding is
107 being used by Perl, but to instead implement the rounding function you
110 To see why, notice how you'll still have an issue on half-way-point
113 for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
115 0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
116 0.8 0.8 0.9 0.9 1.0 1.0
118 Don't blame Perl. It's the same as in C. IEEE says we have to do this.
119 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
120 machines) will work pretty much like mathematical integers. Other numbers
123 =head2 How do I convert between numeric representations/bases/radixes?
125 As always with Perl there is more than one way to do it. Below
126 are a few examples of approaches to making common conversions
127 between number representations. This is intended to be representational
128 rather than exhaustive.
130 Some of the examples below use the Bit::Vector module from CPAN.
131 The reason you might choose Bit::Vector over the perl built in
132 functions is that it works with numbers of ANY size, that it is
133 optimized for speed on some operations, and for at least some
134 programmers the notation might be familiar.
138 =item How do I convert hexadecimal into decimal
140 Using perl's built in conversion of 0x notation:
144 Using the hex function:
146 $dec = hex("DEADBEEF");
150 $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
152 Using the CPAN module Bit::Vector:
155 $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
156 $dec = $vec->to_Dec();
158 =item How do I convert from decimal to hexadecimal
162 $hex = sprintf("%X", 3735928559); # upper case A-F
163 $hex = sprintf("%x", 3735928559); # lower case a-f
167 $hex = unpack("H*", pack("N", 3735928559));
172 $vec = Bit::Vector->new_Dec(32, -559038737);
173 $hex = $vec->to_Hex();
175 And Bit::Vector supports odd bit counts:
178 $vec = Bit::Vector->new_Dec(33, 3735928559);
179 $vec->Resize(32); # suppress leading 0 if unwanted
180 $hex = $vec->to_Hex();
182 =item How do I convert from octal to decimal
184 Using Perl's built in conversion of numbers with leading zeros:
186 $dec = 033653337357; # note the leading 0!
188 Using the oct function:
190 $dec = oct("33653337357");
195 $vec = Bit::Vector->new(32);
196 $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
197 $dec = $vec->to_Dec();
199 =item How do I convert from decimal to octal
203 $oct = sprintf("%o", 3735928559);
208 $vec = Bit::Vector->new_Dec(32, -559038737);
209 $oct = reverse join('', $vec->Chunk_List_Read(3));
211 =item How do I convert from binary to decimal
213 Perl 5.6 lets you write binary numbers directly with
216 $number = 0b10110110;
220 my $input = "10110110";
221 $decimal = oct( "0b$input" );
225 $decimal = ord(pack('B8', '10110110'));
227 Using pack and unpack for larger strings:
229 $int = unpack("N", pack("B32",
230 substr("0" x 32 . "11110101011011011111011101111", -32)));
231 $dec = sprintf("%d", $int);
233 # substr() is used to left pad a 32 character string with zeros.
237 $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
238 $dec = $vec->to_Dec();
240 =item How do I convert from decimal to binary
242 Using sprintf (perl 5.6+):
244 $bin = sprintf("%b", 3735928559);
248 $bin = unpack("B*", pack("N", 3735928559));
253 $vec = Bit::Vector->new_Dec(32, -559038737);
254 $bin = $vec->to_Bin();
256 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
257 are left as an exercise to the inclined reader.
261 =head2 Why doesn't & work the way I want it to?
263 The behavior of binary arithmetic operators depends on whether they're
264 used on numbers or strings. The operators treat a string as a series
265 of bits and work with that (the string C<"3"> is the bit pattern
266 C<00110011>). The operators work with the binary form of a number
267 (the number C<3> is treated as the bit pattern C<00000011>).
269 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
270 C<3>). Saying C<"11" & "3"> performs the "and" operation on strings
273 Most problems with C<&> and C<|> arise because the programmer thinks
274 they have a number but really it's a string. The rest arise because
277 if ("\020\020" & "\101\101") {
281 but a string consisting of two null bytes (the result of C<"\020\020"
282 & "\101\101">) is not a false value in Perl. You need:
284 if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
288 =head2 How do I multiply matrices?
290 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
291 or the PDL extension (also available from CPAN).
293 =head2 How do I perform an operation on a series of integers?
295 To call a function on each element in an array, and collect the
298 @results = map { my_func($_) } @array;
302 @triple = map { 3 * $_ } @single;
304 To call a function on each element of an array, but ignore the
307 foreach $iterator (@array) {
308 some_func($iterator);
311 To call a function on each integer in a (small) range, you B<can> use:
313 @results = map { some_func($_) } (5 .. 25);
315 but you should be aware that the C<..> operator creates an array of
316 all integers in the range. This can take a lot of memory for large
320 for ($i=5; $i < 500_005; $i++) {
321 push(@results, some_func($i));
324 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
325 loop will iterate over the range, without creating the entire range.
327 for my $i (5 .. 500_005) {
328 push(@results, some_func($i));
331 will not create a list of 500,000 integers.
333 =head2 How can I output Roman numerals?
335 Get the http://www.cpan.org/modules/by-module/Roman module.
337 =head2 Why aren't my random numbers random?
339 If you're using a version of Perl before 5.004, you must call C<srand>
340 once at the start of your program to seed the random number generator.
342 BEGIN { srand() if $] < 5.004 }
344 5.004 and later automatically call C<srand> at the beginning. Don't
345 call C<srand> more than once---you make your numbers less random, rather
348 Computers are good at being predictable and bad at being random
349 (despite appearances caused by bugs in your programs :-). see the
350 F<random> article in the "Far More Than You Ever Wanted To Know"
351 collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy of
352 Tom Phoenix, talks more about this. John von Neumann said, "Anyone
353 who attempts to generate random numbers by deterministic means is, of
354 course, living in a state of sin."
356 If you want numbers that are more random than C<rand> with C<srand>
357 provides, you should also check out the Math::TrulyRandom module from
358 CPAN. It uses the imperfections in your system's timer to generate
359 random numbers, but this takes quite a while. If you want a better
360 pseudorandom generator than comes with your operating system, look at
361 "Numerical Recipes in C" at http://www.nr.com/ .
363 =head2 How do I get a random number between X and Y?
365 C<rand($x)> returns a number such that
366 C<< 0 <= rand($x) < $x >>. Thus what you want to have perl
367 figure out is a random number in the range from 0 to the
368 difference between your I<X> and I<Y>.
370 That is, to get a number between 10 and 15, inclusive, you
371 want a random number between 0 and 5 that you can then add
374 my $number = 10 + int rand( 15-10+1 );
376 Hence you derive the following simple function to abstract
377 that. It selects a random integer between the two given
378 integers (inclusive), For example: C<random_int_in(50,120)>.
380 sub random_int_in ($$) {
382 # Assumes that the two arguments are integers themselves!
383 return $min if $min == $max;
384 ($min, $max) = ($max, $min) if $min > $max;
385 return $min + int rand(1 + $max - $min);
390 =head2 How do I find the day or week of the year?
392 The localtime function returns the day of the year. Without an
393 argument localtime uses the current time.
395 $day_of_year = (localtime)[7];
397 The POSIX module can also format a date as the day of the year or
400 use POSIX qw/strftime/;
401 my $day_of_year = strftime "%j", localtime;
402 my $week_of_year = strftime "%W", localtime;
404 To get the day of year for any date, use the Time::Local module to get
405 a time in epoch seconds for the argument to localtime.
407 use POSIX qw/strftime/;
409 my $week_of_year = strftime "%W",
410 localtime( timelocal( 0, 0, 0, 18, 11, 1987 ) );
412 The Date::Calc module provides two functions for to calculate these.
415 my $day_of_year = Day_of_Year( 1987, 12, 18 );
416 my $week_of_year = Week_of_Year( 1987, 12, 18 );
418 =head2 How do I find the current century or millennium?
420 Use the following simple functions:
423 return int((((localtime(shift || time))[5] + 1999))/100);
427 return 1+int((((localtime(shift || time))[5] + 1899))/1000);
430 On some systems, the POSIX module's strftime() function has
431 been extended in a non-standard way to use a C<%C> format,
432 which they sometimes claim is the "century". It isn't,
433 because on most such systems, this is only the first two
434 digits of the four-digit year, and thus cannot be used to
435 reliably determine the current century or millennium.
437 =head2 How can I compare two dates and find the difference?
439 If you're storing your dates as epoch seconds then simply subtract one
440 from the other. If you've got a structured date (distinct year, day,
441 month, hour, minute, seconds values), then for reasons of accessibility,
442 simplicity, and efficiency, merely use either timelocal or timegm (from
443 the Time::Local module in the standard distribution) to reduce structured
444 dates to epoch seconds. However, if you don't know the precise format of
445 your dates, then you should probably use either of the Date::Manip and
446 Date::Calc modules from CPAN before you go hacking up your own parsing
447 routine to handle arbitrary date formats.
449 =head2 How can I take a string and turn it into epoch seconds?
451 If it's a regular enough string that it always has the same format,
452 you can split it up and pass the parts to C<timelocal> in the standard
453 Time::Local module. Otherwise, you should look into the Date::Calc
454 and Date::Manip modules from CPAN.
456 =head2 How can I find the Julian Day?
458 (contributed by brian d foy and Dave Cross)
460 You can use the Time::JulianDay module available on CPAN. Ensure that
461 you really want to find a Julian day, though, as many people have
462 different ideas about Julian days. See
463 http://www.hermetic.ch/cal_stud/jdn.htm for instance.
465 You can also try the DateTime module, which can convert a date/time
468 $ perl -MDateTime -le'print DateTime->today->jd'
471 Or the modified Julian Day
473 $ perl -MDateTime -le'print DateTime->today->mjd'
476 Or even the day of the year (which is what some people think of as a
479 $ perl -MDateTime -le'print DateTime->today->doy'
482 =head2 How do I find yesterday's date?
484 (contributed by brian d foy)
486 Use one of the Date modules. The C<DateTime> module makes it simple, and
487 give you the same time of day, only the day before.
491 my $yesterday = DateTime->now->subtract( days => 1 );
493 print "Yesterday was $yesterday\n";
495 You can also use the C<Date::Calc> module using its Today_and_Now
498 use Date::Calc qw( Today_and_Now Add_Delta_DHMS );
500 my @date_time = Add_Delta_DHMS( Today_and_Now(), -1, 0, 0, 0 );
504 Most people try to use the time rather than the calendar to figure out
505 dates, but that assumes that days are twenty-four hours each. For
506 most people, there are two days a year when they aren't: the switch to
507 and from summer time throws this off. Let the modules do the work.
509 =head2 Does Perl have a Year 2000 problem? Is Perl Y2K compliant?
511 Short answer: No, Perl does not have a Year 2000 problem. Yes, Perl is
512 Y2K compliant (whatever that means). The programmers you've hired to
513 use it, however, probably are not.
515 Long answer: The question belies a true understanding of the issue.
516 Perl is just as Y2K compliant as your pencil--no more, and no less.
517 Can you use your pencil to write a non-Y2K-compliant memo? Of course
518 you can. Is that the pencil's fault? Of course it isn't.
520 The date and time functions supplied with Perl (gmtime and localtime)
521 supply adequate information to determine the year well beyond 2000
522 (2038 is when trouble strikes for 32-bit machines). The year returned
523 by these functions when used in a list context is the year minus 1900.
524 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
525 number. To avoid the year 2000 problem simply do not treat the year as
526 a 2-digit number. It isn't.
528 When gmtime() and localtime() are used in scalar context they return
529 a timestamp string that contains a fully-expanded year. For example,
530 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
531 2001". There's no year 2000 problem here.
533 That doesn't mean that Perl can't be used to create non-Y2K compliant
534 programs. It can. But so can your pencil. It's the fault of the user,
535 not the language. At the risk of inflaming the NRA: "Perl doesn't
536 break Y2K, people do." See http://www.perl.org/about/y2k.html for
541 =head2 How do I validate input?
543 (contributed by brian d foy)
545 There are many ways to ensure that values are what you expect or
546 want to accept. Besides the specific examples that we cover in the
547 perlfaq, you can also look at the modules with "Assert" and "Validate"
548 in their names, along with other modules such as C<Regexp::Common>.
550 Some modules have validation for particular types of input, such
551 as C<Business::ISBN>, C<Business::CreditCard>, C<Email::Valid>,
552 and C<Data::Validate::IP>.
554 =head2 How do I unescape a string?
556 It depends just what you mean by "escape". URL escapes are dealt
557 with in L<perlfaq9>. Shell escapes with the backslash (C<\>)
558 character are removed with
562 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
564 =head2 How do I remove consecutive pairs of characters?
566 (contributed by brian d foy)
568 You can use the substitution operator to find pairs of characters (or
569 runs of characters) and replace them with a single instance. In this
570 substitution, we find a character in C<(.)>. The memory parentheses
571 store the matched character in the back-reference C<\1> and we use
572 that to require that the same thing immediately follow it. We replace
573 that part of the string with the character in C<$1>.
577 We can also use the transliteration operator, C<tr///>. In this
578 example, the search list side of our C<tr///> contains nothing, but
579 the C<c> option complements that so it contains everything. The
580 replacement list also contains nothing, so the transliteration is
581 almost a no-op since it won't do any replacements (or more exactly,
582 replace the character with itself). However, the C<s> option squashes
583 duplicated and consecutive characters in the string so a character
584 does not show up next to itself
586 my $str = 'Haarlem'; # in the Netherlands
587 $str =~ tr///cs; # Now Harlem, like in New York
589 =head2 How do I expand function calls in a string?
591 (contributed by brian d foy)
593 This is documented in L<perlref>, and although it's not the easiest
594 thing to read, it does work. In each of these examples, we call the
595 function inside the braces of used to dereference a reference. If we
596 have a more than one return value, we can contruct and dereference an
597 anonymous array. In this case, we call the function in list context.
599 print "The time values are @{ [localtime] }.\n";
601 If we want to call the function in scalar context, we have to do a bit
602 more work. We can really have any code we like inside the braces, so
603 we simply have to end with the scalar reference, although how you do
604 that is up to you, and you can use code inside the braces.
606 print "The time is ${\(scalar localtime)}.\n"
608 print "The time is ${ my $x = localtime; \$x }.\n";
610 If your function already returns a reference, you don't need to create
611 the reference yourself.
613 sub timestamp { my $t = localtime; \$t }
615 print "The time is ${ timestamp() }.\n";
617 In most cases, it is probably easier to simply use string
618 concatenation, which also forces scalar context.
620 print "The time is " . localtime . ".\n";
622 =head2 How do I find matching/nesting anything?
624 This isn't something that can be done in one regular expression, no
625 matter how complicated. To find something between two single
626 characters, a pattern like C</x([^x]*)x/> will get the intervening
627 bits in $1. For multiple ones, then something more like
628 C</alpha(.*?)omega/> would be needed. But none of these deals with
629 nested patterns. For balanced expressions using C<(>, C<{>, C<[> or
630 C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
631 L<perlre/(??{ code })>. For other cases, you'll have to write a
634 If you are serious about writing a parser, there are a number of
635 modules or oddities that will make your life a lot easier. There are
636 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
637 and the byacc program. Starting from perl 5.8 the Text::Balanced is
638 part of the standard distribution.
640 One simple destructive, inside-out approach that you might try is to
641 pull out the smallest nesting parts one at a time:
643 while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
644 # do something with $1
647 A more complicated and sneaky approach is to make Perl's regular
648 expression engine do it for you. This is courtesy Dean Inada, and
649 rather has the nature of an Obfuscated Perl Contest entry, but it
652 # $_ contains the string to parse
653 # BEGIN and END are the opening and closing markers for the
658 ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
659 @$ = (eval{/$re/},$@!~/unmatched/i);
660 print join("\n",@$[0..$#$]) if( $$[-1] );
662 =head2 How do I reverse a string?
664 Use reverse() in scalar context, as documented in
667 $reversed = reverse $string;
669 =head2 How do I expand tabs in a string?
671 You can do it yourself:
673 1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
675 Or you can just use the Text::Tabs module (part of the standard Perl
679 @expanded_lines = expand(@lines_with_tabs);
681 =head2 How do I reformat a paragraph?
683 Use Text::Wrap (part of the standard Perl distribution):
686 print wrap("\t", ' ', @paragraphs);
688 The paragraphs you give to Text::Wrap should not contain embedded
689 newlines. Text::Wrap doesn't justify the lines (flush-right).
691 Or use the CPAN module Text::Autoformat. Formatting files can be easily
692 done by making a shell alias, like so:
694 alias fmt="perl -i -MText::Autoformat -n0777 \
695 -e 'print autoformat $_, {all=>1}' $*"
697 See the documentation for Text::Autoformat to appreciate its many
700 =head2 How can I access or change N characters of a string?
702 You can access the first characters of a string with substr().
703 To get the first character, for example, start at position 0
704 and grab the string of length 1.
707 $string = "Just another Perl Hacker";
708 $first_char = substr( $string, 0, 1 ); # 'J'
710 To change part of a string, you can use the optional fourth
711 argument which is the replacement string.
713 substr( $string, 13, 4, "Perl 5.8.0" );
715 You can also use substr() as an lvalue.
717 substr( $string, 13, 4 ) = "Perl 5.8.0";
719 =head2 How do I change the Nth occurrence of something?
721 You have to keep track of N yourself. For example, let's say you want
722 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
723 C<"whosoever"> or C<"whomsoever">, case insensitively. These
724 all assume that $_ contains the string to be altered.
728 ++$count == 5 # is it the 5th?
729 ? "${2}soever" # yes, swap
730 : $1 # renege and leave it there
733 In the more general case, you can use the C</g> modifier in a C<while>
734 loop, keeping count of matches.
738 $_ = "One fish two fish red fish blue fish";
739 while (/(\w+)\s+fish\b/gi) {
740 if (++$count == $WANT) {
741 print "The third fish is a $1 one.\n";
745 That prints out: C<"The third fish is a red one."> You can also use a
746 repetition count and repeated pattern like this:
748 /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
750 =head2 How can I count the number of occurrences of a substring within a string?
752 There are a number of ways, with varying efficiency. If you want a
753 count of a certain single character (X) within a string, you can use the
754 C<tr///> function like so:
756 $string = "ThisXlineXhasXsomeXx'sXinXit";
757 $count = ($string =~ tr/X//);
758 print "There are $count X characters in the string";
760 This is fine if you are just looking for a single character. However,
761 if you are trying to count multiple character substrings within a
762 larger string, C<tr///> won't work. What you can do is wrap a while()
763 loop around a global pattern match. For example, let's count negative
766 $string = "-9 55 48 -2 23 -76 4 14 -44";
767 while ($string =~ /-\d+/g) { $count++ }
768 print "There are $count negative numbers in the string";
770 Another version uses a global match in list context, then assigns the
771 result to a scalar, producing a count of the number of matches.
773 $count = () = $string =~ /-\d+/g;
775 =head2 How do I capitalize all the words on one line?
777 To make the first letter of each word upper case:
779 $line =~ s/\b(\w)/\U$1/g;
781 This has the strange effect of turning "C<don't do it>" into "C<Don'T
782 Do It>". Sometimes you might want this. Other times you might need a
783 more thorough solution (Suggested by brian d foy):
786 (^\w) #at the beginning of the line
788 (\s\w) #preceded by whitespace
791 $string =~ /([\w']+)/\u\L$1/g;
793 To make the whole line upper case:
797 To force each word to be lower case, with the first letter upper case:
799 $line =~ s/(\w+)/\u\L$1/g;
801 You can (and probably should) enable locale awareness of those
802 characters by placing a C<use locale> pragma in your program.
803 See L<perllocale> for endless details on locales.
805 This is sometimes referred to as putting something into "title
806 case", but that's not quite accurate. Consider the proper
807 capitalization of the movie I<Dr. Strangelove or: How I Learned to
808 Stop Worrying and Love the Bomb>, for example.
810 Damian Conway's L<Text::Autoformat> module provides some smart
811 case transformations:
813 use Text::Autoformat;
814 my $x = "Dr. Strangelove or: How I Learned to Stop ".
815 "Worrying and Love the Bomb";
818 for my $style (qw( sentence title highlight ))
820 print autoformat($x, { case => $style }), "\n";
823 =head2 How can I split a [character] delimited string except when inside [character]?
825 Several modules can handle this sort of pasing---Text::Balanced,
826 Text::CSV, Text::CSV_XS, and Text::ParseWords, among others.
828 Take the example case of trying to split a string that is
829 comma-separated into its different fields. You can't use C<split(/,/)>
830 because you shouldn't split if the comma is inside quotes. For
831 example, take a data line like this:
833 SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
835 Due to the restriction of the quotes, this is a fairly complex
836 problem. Thankfully, we have Jeffrey Friedl, author of
837 I<Mastering Regular Expressions>, to handle these for us. He
838 suggests (assuming your string is contained in $text):
841 push(@new, $+) while $text =~ m{
842 "([^\"\\]*(?:\\.[^\"\\]*)*)",? # groups the phrase inside the quotes
846 push(@new, undef) if substr($text,-1,1) eq ',';
848 If you want to represent quotation marks inside a
849 quotation-mark-delimited field, escape them with backslashes (eg,
852 Alternatively, the Text::ParseWords module (part of the standard Perl
853 distribution) lets you say:
855 use Text::ParseWords;
856 @new = quotewords(",", 0, $text);
858 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
860 =head2 How do I strip blank space from the beginning/end of a string?
862 (contributed by brian d foy)
864 A substitution can do this for you. For a single line, you want to
865 replace all the leading or trailing whitespace with nothing. You
866 can do that with a pair of substitutions.
871 You can also write that as a single substitution, although it turns
872 out the combined statement is slower than the separate ones. That
873 might not matter to you, though.
877 In this regular expression, the alternation matches either at the
878 beginning or the end of the string since the anchors have a lower
879 precedence than the alternation. With the C</g> flag, the substitution
880 makes all possible matches, so it gets both. Remember, the trailing
881 newline matches the C<\s+>, and the C<$> anchor can match to the
882 physical end of the string, so the newline disappears too. Just add
883 the newline to the output, which has the added benefit of preserving
884 "blank" (consisting entirely of whitespace) lines which the C<^\s+>
885 would remove all by itself.
893 For a multi-line string, you can apply the regular expression
894 to each logical line in the string by adding the C</m> flag (for
895 "multi-line"). With the C</m> flag, the C<$> matches I<before> an
896 embedded newline, so it doesn't remove it. It still removes the
897 newline at the end of the string.
899 $string =~ s/^\s+|\s+$//gm;
901 Remember that lines consisting entirely of whitespace will disappear,
902 since the first part of the alternation can match the entire string
903 and replace it with nothing. If need to keep embedded blank lines,
904 you have to do a little more work. Instead of matching any whitespace
905 (since that includes a newline), just match the other whitespace.
907 $string =~ s/^[\t\f ]+|[\t\f ]+$//mg;
909 =head2 How do I pad a string with blanks or pad a number with zeroes?
911 In the following examples, C<$pad_len> is the length to which you wish
912 to pad the string, C<$text> or C<$num> contains the string to be padded,
913 and C<$pad_char> contains the padding character. You can use a single
914 character string constant instead of the C<$pad_char> variable if you
915 know what it is in advance. And in the same way you can use an integer in
916 place of C<$pad_len> if you know the pad length in advance.
918 The simplest method uses the C<sprintf> function. It can pad on the left
919 or right with blanks and on the left with zeroes and it will not
920 truncate the result. The C<pack> function can only pad strings on the
921 right with blanks and it will truncate the result to a maximum length of
924 # Left padding a string with blanks (no truncation):
925 $padded = sprintf("%${pad_len}s", $text);
926 $padded = sprintf("%*s", $pad_len, $text); # same thing
928 # Right padding a string with blanks (no truncation):
929 $padded = sprintf("%-${pad_len}s", $text);
930 $padded = sprintf("%-*s", $pad_len, $text); # same thing
932 # Left padding a number with 0 (no truncation):
933 $padded = sprintf("%0${pad_len}d", $num);
934 $padded = sprintf("%0*d", $pad_len, $num); # same thing
936 # Right padding a string with blanks using pack (will truncate):
937 $padded = pack("A$pad_len",$text);
939 If you need to pad with a character other than blank or zero you can use
940 one of the following methods. They all generate a pad string with the
941 C<x> operator and combine that with C<$text>. These methods do
942 not truncate C<$text>.
944 Left and right padding with any character, creating a new string:
946 $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
947 $padded = $text . $pad_char x ( $pad_len - length( $text ) );
949 Left and right padding with any character, modifying C<$text> directly:
951 substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
952 $text .= $pad_char x ( $pad_len - length( $text ) );
954 =head2 How do I extract selected columns from a string?
956 Use substr() or unpack(), both documented in L<perlfunc>.
957 If you prefer thinking in terms of columns instead of widths,
958 you can use this kind of thing:
960 # determine the unpack format needed to split Linux ps output
961 # arguments are cut columns
962 my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
968 for my $place (@positions) {
969 $template .= "A" . ($place - $lastpos) . " ";
976 =head2 How do I find the soundex value of a string?
978 (contributed by brian d foy)
980 You can use the Text::Soundex module. If you want to do fuzzy or close
981 matching, you might also try the String::Approx, and Text::Metaphone,
982 and Text::DoubleMetaphone modules.
984 =head2 How can I expand variables in text strings?
986 Let's assume that you have a string that contains placeholder
989 $text = 'this has a $foo in it and a $bar';
991 You can use a substitution with a double evaluation. The
992 first /e turns C<$1> into C<$foo>, and the second /e turns
993 C<$foo> into its value. You may want to wrap this in an
994 C<eval>: if you try to get the value of an undeclared variable
995 while running under C<use strict>, you get a fatal error.
997 eval { $text =~ s/(\$\w+)/$1/eeg };
1000 It's probably better in the general case to treat those
1001 variables as entries in some special hash. For example:
1007 $text =~ s/\$(\w+)/$user_defs{$1}/g;
1009 =head2 What's wrong with always quoting "$vars"?
1011 The problem is that those double-quotes force stringification--
1012 coercing numbers and references into strings--even when you
1013 don't want them to be strings. Think of it this way: double-quote
1014 expansion is used to produce new strings. If you already
1015 have a string, why do you need more?
1017 If you get used to writing odd things like these:
1020 $new = "$old"; # BAD
1021 somefunc("$var"); # BAD
1023 You'll be in trouble. Those should (in 99.8% of the cases) be
1024 the simpler and more direct:
1030 Otherwise, besides slowing you down, you're going to break code when
1031 the thing in the scalar is actually neither a string nor a number, but
1037 my $oref = "$aref"; # WRONG
1040 You can also get into subtle problems on those few operations in Perl
1041 that actually do care about the difference between a string and a
1042 number, such as the magical C<++> autoincrement operator or the
1045 Stringification also destroys arrays.
1048 print "@lines"; # WRONG - extra blanks
1049 print @lines; # right
1051 =head2 Why don't my E<lt>E<lt>HERE documents work?
1053 Check for these three things:
1057 =item There must be no space after the E<lt>E<lt> part.
1059 =item There (probably) should be a semicolon at the end.
1061 =item You can't (easily) have any space in front of the tag.
1065 If you want to indent the text in the here document, you
1069 ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1074 But the HERE_TARGET must still be flush against the margin.
1075 If you want that indented also, you'll have to quote
1078 ($quote = <<' FINIS') =~ s/^\s+//gm;
1079 ...we will have peace, when you and all your works have
1080 perished--and the works of your dark master to whom you
1081 would deliver us. You are a liar, Saruman, and a corrupter
1082 of men's hearts. --Theoden in /usr/src/perl/taint.c
1084 $quote =~ s/\s+--/\n--/;
1086 A nice general-purpose fixer-upper function for indented here documents
1087 follows. It expects to be called with a here document as its argument.
1088 It looks to see whether each line begins with a common substring, and
1089 if so, strips that substring off. Otherwise, it takes the amount of leading
1090 whitespace found on the first line and removes that much off each
1095 my ($white, $leader); # common whitespace and common leading string
1096 if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1097 ($white, $leader) = ($2, quotemeta($1));
1099 ($white, $leader) = (/^(\s+)/, '');
1101 s/^\s*?$leader(?:$white)?//gm;
1105 This works with leading special strings, dynamically determined:
1107 $remember_the_main = fix<<' MAIN_INTERPRETER_LOOP';
1110 @@@ SAVEI32(runlevel);
1112 @@@ while ( op = (*op->op_ppaddr)() );
1116 MAIN_INTERPRETER_LOOP
1118 Or with a fixed amount of leading whitespace, with remaining
1119 indentation correctly preserved:
1121 $poem = fix<<EVER_ON_AND_ON;
1122 Now far ahead the Road has gone,
1123 And I must follow, if I can,
1124 Pursuing it with eager feet,
1125 Until it joins some larger way
1126 Where many paths and errands meet.
1127 And whither then? I cannot say.
1128 --Bilbo in /usr/src/perl/pp_ctl.c
1133 =head2 What is the difference between a list and an array?
1135 An array has a changeable length. A list does not. An array is something
1136 you can push or pop, while a list is a set of values. Some people make
1137 the distinction that a list is a value while an array is a variable.
1138 Subroutines are passed and return lists, you put things into list
1139 context, you initialize arrays with lists, and you foreach() across
1140 a list. C<@> variables are arrays, anonymous arrays are arrays, arrays
1141 in scalar context behave like the number of elements in them, subroutines
1142 access their arguments through the array C<@_>, and push/pop/shift only work
1145 As a side note, there's no such thing as a list in scalar context.
1148 $scalar = (2, 5, 7, 9);
1150 you're using the comma operator in scalar context, so it uses the scalar
1151 comma operator. There never was a list there at all! This causes the
1152 last value to be returned: 9.
1154 =head2 What is the difference between $array[1] and @array[1]?
1156 The former is a scalar value; the latter an array slice, making
1157 it a list with one (scalar) value. You should use $ when you want a
1158 scalar value (most of the time) and @ when you want a list with one
1159 scalar value in it (very, very rarely; nearly never, in fact).
1161 Sometimes it doesn't make a difference, but sometimes it does.
1162 For example, compare:
1164 $good[0] = `some program that outputs several lines`;
1168 @bad[0] = `same program that outputs several lines`;
1170 The C<use warnings> pragma and the B<-w> flag will warn you about these
1173 =head2 How can I remove duplicate elements from a list or array?
1175 (contributed by brian d foy)
1177 Use a hash. When you think the words "unique" or "duplicated", think
1180 If you don't care about the order of the elements, you could just
1181 create the hash then extract the keys. It's not important how you
1182 create that hash: just that you use C<keys> to get the unique
1185 my %hash = map { $_, 1 } @array;
1186 # or a hash slice: @hash{ @array } = ();
1187 # or a foreach: $hash{$_} = 1 foreach ( @array );
1189 my @unique = keys %hash;
1191 You can also go through each element and skip the ones you've seen
1192 before. Use a hash to keep track. The first time the loop sees an
1193 element, that element has no key in C<%Seen>. The C<next> statement
1194 creates the key and immediately uses its value, which is C<undef>, so
1195 the loop continues to the C<push> and increments the value for that
1196 key. The next time the loop sees that same element, its key exists in
1197 the hash I<and> the value for that key is true (since it's not 0 or
1198 undef), so the next skips that iteration and the loop goes to the next
1204 foreach my $elem ( @array )
1206 next if $seen{ $elem }++;
1207 push @unique, $elem;
1210 You can write this more briefly using a grep, which does the
1214 my @unique = grep { ! $seen{ $_ }++ } @array;
1216 =head2 How can I tell whether a certain element is contained in a list or array?
1218 Hearing the word "in" is an I<in>dication that you probably should have
1219 used a hash, not a list or array, to store your data. Hashes are
1220 designed to answer this question quickly and efficiently. Arrays aren't.
1222 That being said, there are several ways to approach this. If you
1223 are going to make this query many times over arbitrary string values,
1224 the fastest way is probably to invert the original array and maintain a
1225 hash whose keys are the first array's values.
1227 @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1229 for (@blues) { $is_blue{$_} = 1 }
1231 Now you can check whether $is_blue{$some_color}. It might have been a
1232 good idea to keep the blues all in a hash in the first place.
1234 If the values are all small integers, you could use a simple indexed
1235 array. This kind of an array will take up less space:
1237 @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1238 @is_tiny_prime = ();
1239 for (@primes) { $is_tiny_prime[$_] = 1 }
1240 # or simply @istiny_prime[@primes] = (1) x @primes;
1242 Now you check whether $is_tiny_prime[$some_number].
1244 If the values in question are integers instead of strings, you can save
1245 quite a lot of space by using bit strings instead:
1247 @articles = ( 1..10, 150..2000, 2017 );
1249 for (@articles) { vec($read,$_,1) = 1 }
1251 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1255 ($is_there) = grep $_ eq $whatever, @array;
1259 ($is_there) = grep /$whatever/, @array;
1261 These are slow (checks every element even if the first matches),
1262 inefficient (same reason), and potentially buggy (what if there are
1263 regex characters in $whatever?). If you're only testing once, then
1267 foreach $elt (@array) {
1268 if ($elt eq $elt_to_find) {
1273 if ($is_there) { ... }
1275 =head2 How do I compute the difference of two arrays? How do I compute the intersection of two arrays?
1277 Use a hash. Here's code to do both and more. It assumes that
1278 each element is unique in a given array:
1280 @union = @intersection = @difference = ();
1282 foreach $element (@array1, @array2) { $count{$element}++ }
1283 foreach $element (keys %count) {
1284 push @union, $element;
1285 push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1288 Note that this is the I<symmetric difference>, that is, all elements in
1289 either A or in B but not in both. Think of it as an xor operation.
1291 =head2 How do I test whether two arrays or hashes are equal?
1293 The following code works for single-level arrays. It uses a stringwise
1294 comparison, and does not distinguish defined versus undefined empty
1295 strings. Modify if you have other needs.
1297 $are_equal = compare_arrays(\@frogs, \@toads);
1299 sub compare_arrays {
1300 my ($first, $second) = @_;
1301 no warnings; # silence spurious -w undef complaints
1302 return 0 unless @$first == @$second;
1303 for (my $i = 0; $i < @$first; $i++) {
1304 return 0 if $first->[$i] ne $second->[$i];
1309 For multilevel structures, you may wish to use an approach more
1310 like this one. It uses the CPAN module FreezeThaw:
1312 use FreezeThaw qw(cmpStr);
1313 @a = @b = ( "this", "that", [ "more", "stuff" ] );
1315 printf "a and b contain %s arrays\n",
1316 cmpStr(\@a, \@b) == 0
1320 This approach also works for comparing hashes. Here
1321 we'll demonstrate two different answers:
1323 use FreezeThaw qw(cmpStr cmpStrHard);
1325 %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1329 printf "a and b contain %s hashes\n",
1330 cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1332 printf "a and b contain %s hashes\n",
1333 cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1336 The first reports that both those the hashes contain the same data,
1337 while the second reports that they do not. Which you prefer is left as
1338 an exercise to the reader.
1340 =head2 How do I find the first array element for which a condition is true?
1342 To find the first array element which satisfies a condition, you can
1343 use the first() function in the List::Util module, which comes with
1344 Perl 5.8. This example finds the first element that contains "Perl".
1346 use List::Util qw(first);
1348 my $element = first { /Perl/ } @array;
1350 If you cannot use List::Util, you can make your own loop to do the
1351 same thing. Once you find the element, you stop the loop with last.
1356 if( /Perl/ ) { $found = $_; last }
1359 If you want the array index, you can iterate through the indices
1360 and check the array element at each index until you find one
1361 that satisfies the condition.
1363 my( $found, $index ) = ( undef, -1 );
1364 for( $i = 0; $i < @array; $i++ )
1366 if( $array[$i] =~ /Perl/ )
1368 $found = $array[$i];
1374 =head2 How do I handle linked lists?
1376 In general, you usually don't need a linked list in Perl, since with
1377 regular arrays, you can push and pop or shift and unshift at either end,
1378 or you can use splice to add and/or remove arbitrary number of elements at
1379 arbitrary points. Both pop and shift are both O(1) operations on Perl's
1380 dynamic arrays. In the absence of shifts and pops, push in general
1381 needs to reallocate on the order every log(N) times, and unshift will
1382 need to copy pointers each time.
1384 If you really, really wanted, you could use structures as described in
1385 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1386 to do. For example, imagine a list node like this:
1393 You could walk the list this way:
1396 for ($node = $head; $node; $node = $node->{LINK}) {
1397 print $node->{VALUE}, " ";
1401 You could add to the list this way:
1404 $tail = append($head, 1); # grow a new head
1405 for $value ( 2 .. 10 ) {
1406 $tail = append($tail, $value);
1410 my($list, $value) = @_;
1411 my $node = { VALUE => $value };
1413 $node->{LINK} = $list->{LINK};
1414 $list->{LINK} = $node;
1416 $_[0] = $node; # replace caller's version
1421 But again, Perl's built-in are virtually always good enough.
1423 =head2 How do I handle circular lists?
1425 Circular lists could be handled in the traditional fashion with linked
1426 lists, or you could just do something like this with an array:
1428 unshift(@array, pop(@array)); # the last shall be first
1429 push(@array, shift(@array)); # and vice versa
1431 =head2 How do I shuffle an array randomly?
1433 If you either have Perl 5.8.0 or later installed, or if you have
1434 Scalar-List-Utils 1.03 or later installed, you can say:
1436 use List::Util 'shuffle';
1438 @shuffled = shuffle(@list);
1440 If not, you can use a Fisher-Yates shuffle.
1442 sub fisher_yates_shuffle {
1443 my $deck = shift; # $deck is a reference to an array
1446 my $j = int rand ($i+1);
1447 @$deck[$i,$j] = @$deck[$j,$i];
1451 # shuffle my mpeg collection
1453 my @mpeg = <audio/*/*.mp3>;
1454 fisher_yates_shuffle( \@mpeg ); # randomize @mpeg in place
1457 Note that the above implementation shuffles an array in place,
1458 unlike the List::Util::shuffle() which takes a list and returns
1459 a new shuffled list.
1461 You've probably seen shuffling algorithms that work using splice,
1462 randomly picking another element to swap the current element with
1466 @old = 1 .. 10; # just a demo
1468 push(@new, splice(@old, rand @old, 1));
1471 This is bad because splice is already O(N), and since you do it N times,
1472 you just invented a quadratic algorithm; that is, O(N**2). This does
1473 not scale, although Perl is so efficient that you probably won't notice
1474 this until you have rather largish arrays.
1476 =head2 How do I process/modify each element of an array?
1478 Use C<for>/C<foreach>:
1481 s/foo/bar/; # change that word
1482 tr/XZ/ZX/; # swap those letters
1485 Here's another; let's compute spherical volumes:
1487 for (@volumes = @radii) { # @volumes has changed parts
1489 $_ *= (4/3) * 3.14159; # this will be constant folded
1492 which can also be done with map() which is made to transform
1493 one list into another:
1495 @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1497 If you want to do the same thing to modify the values of the
1498 hash, you can use the C<values> function. As of Perl 5.6
1499 the values are not copied, so if you modify $orbit (in this
1500 case), you modify the value.
1502 for $orbit ( values %orbits ) {
1503 ($orbit **= 3) *= (4/3) * 3.14159;
1506 Prior to perl 5.6 C<values> returned copies of the values,
1507 so older perl code often contains constructions such as
1508 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1509 the hash is to be modified.
1511 =head2 How do I select a random element from an array?
1513 Use the rand() function (see L<perlfunc/rand>):
1515 $index = rand @array;
1516 $element = $array[$index];
1519 my $element = $array[ rand @array ];
1521 =head2 How do I permute N elements of a list?
1523 Use the List::Permutor module on CPAN. If the list is
1524 actually an array, try the Algorithm::Permute module (also
1525 on CPAN). It's written in XS code and is very efficient.
1527 use Algorithm::Permute;
1528 my @array = 'a'..'d';
1529 my $p_iterator = Algorithm::Permute->new ( \@array );
1530 while (my @perm = $p_iterator->next) {
1531 print "next permutation: (@perm)\n";
1534 For even faster execution, you could do:
1536 use Algorithm::Permute;
1537 my @array = 'a'..'d';
1538 Algorithm::Permute::permute {
1539 print "next permutation: (@array)\n";
1542 Here's a little program that generates all permutations of
1543 all the words on each line of input. The algorithm embodied
1544 in the permute() function is discussed in Volume 4 (still
1545 unpublished) of Knuth's I<The Art of Computer Programming>
1546 and will work on any list:
1549 # Fischer-Kause ordered permutation generator
1554 while ( $code->(@_[@idx]) ) {
1556 --$p while $idx[$p-1] > $idx[$p];
1557 my $q = $p or return;
1558 push @idx, reverse splice @idx, $p;
1559 ++$q while $idx[$p-1] > $idx[$q];
1560 @idx[$p-1,$q]=@idx[$q,$p-1];
1564 permute {print"@_\n"} split;
1566 =head2 How do I sort an array by (anything)?
1568 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1570 @list = sort { $a <=> $b } @list;
1572 The default sort function is cmp, string comparison, which would
1573 sort C<(1, 2, 10)> into C<(1, 10, 2)>. C<< <=> >>, used above, is
1574 the numerical comparison operator.
1576 If you have a complicated function needed to pull out the part you
1577 want to sort on, then don't do it inside the sort function. Pull it
1578 out first, because the sort BLOCK can be called many times for the
1579 same element. Here's an example of how to pull out the first word
1580 after the first number on each item, and then sort those words
1585 ($item) = /\d+\s*(\S+)/;
1586 push @idx, uc($item);
1588 @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1590 which could also be written this way, using a trick
1591 that's come to be known as the Schwartzian Transform:
1593 @sorted = map { $_->[0] }
1594 sort { $a->[1] cmp $b->[1] }
1595 map { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1597 If you need to sort on several fields, the following paradigm is useful.
1599 @sorted = sort { field1($a) <=> field1($b) ||
1600 field2($a) cmp field2($b) ||
1601 field3($a) cmp field3($b)
1604 This can be conveniently combined with precalculation of keys as given
1607 See the F<sort> article in the "Far More Than You Ever Wanted
1608 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1609 more about this approach.
1611 See also the question below on sorting hashes.
1613 =head2 How do I manipulate arrays of bits?
1615 Use pack() and unpack(), or else vec() and the bitwise operations.
1617 For example, this sets $vec to have bit N set if $ints[N] was set:
1620 foreach(@ints) { vec($vec,$_,1) = 1 }
1622 Here's how, given a vector in $vec, you can
1623 get those bits into your @ints array:
1625 sub bitvec_to_list {
1628 # Find null-byte density then select best algorithm
1629 if ($vec =~ tr/\0// / length $vec > 0.95) {
1632 # This method is faster with mostly null-bytes
1633 while($vec =~ /[^\0]/g ) {
1634 $i = -9 + 8 * pos $vec;
1635 push @ints, $i if vec($vec, ++$i, 1);
1636 push @ints, $i if vec($vec, ++$i, 1);
1637 push @ints, $i if vec($vec, ++$i, 1);
1638 push @ints, $i if vec($vec, ++$i, 1);
1639 push @ints, $i if vec($vec, ++$i, 1);
1640 push @ints, $i if vec($vec, ++$i, 1);
1641 push @ints, $i if vec($vec, ++$i, 1);
1642 push @ints, $i if vec($vec, ++$i, 1);
1645 # This method is a fast general algorithm
1647 my $bits = unpack "b*", $vec;
1648 push @ints, 0 if $bits =~ s/^(\d)// && $1;
1649 push @ints, pos $bits while($bits =~ /1/g);
1654 This method gets faster the more sparse the bit vector is.
1655 (Courtesy of Tim Bunce and Winfried Koenig.)
1657 You can make the while loop a lot shorter with this suggestion
1658 from Benjamin Goldberg:
1660 while($vec =~ /[^\0]+/g ) {
1661 push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1664 Or use the CPAN module Bit::Vector:
1666 $vector = Bit::Vector->new($num_of_bits);
1667 $vector->Index_List_Store(@ints);
1668 @ints = $vector->Index_List_Read();
1670 Bit::Vector provides efficient methods for bit vector, sets of small integers
1673 Here's a more extensive illustration using vec():
1676 $vector = "\xff\x0f\xef\xfe";
1677 print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1678 unpack("N", $vector), "\n";
1679 $is_set = vec($vector, 23, 1);
1680 print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1698 my ($offset, $width, $value) = @_;
1700 vec($vector, $offset, $width) = $value;
1701 print "offset=$offset width=$width value=$value\n";
1707 my $bits = unpack("b*", $vector);
1711 print "vector length in bytes: ", length($vector), "\n";
1712 @bytes = unpack("A8" x length($vector), $bits);
1713 print "bits are: @bytes\n\n";
1716 =head2 Why does defined() return true on empty arrays and hashes?
1718 The short story is that you should probably only use defined on scalars or
1719 functions, not on aggregates (arrays and hashes). See L<perlfunc/defined>
1720 in the 5.004 release or later of Perl for more detail.
1722 =head1 Data: Hashes (Associative Arrays)
1724 =head2 How do I process an entire hash?
1726 Use the each() function (see L<perlfunc/each>) if you don't care
1727 whether it's sorted:
1729 while ( ($key, $value) = each %hash) {
1730 print "$key = $value\n";
1733 If you want it sorted, you'll have to use foreach() on the result of
1734 sorting the keys as shown in an earlier question.
1736 =head2 What happens if I add or remove keys from a hash while iterating over it?
1738 (contributed by brian d foy)
1740 The easy answer is "Don't do that!"
1742 If you iterate through the hash with each(), you can delete the key
1743 most recently returned without worrying about it. If you delete or add
1744 other keys, the iterator may skip or double up on them since perl
1745 may rearrange the hash table. See the
1746 entry for C<each()> in L<perlfunc>.
1748 =head2 How do I look up a hash element by value?
1750 Create a reverse hash:
1752 %by_value = reverse %by_key;
1753 $key = $by_value{$value};
1755 That's not particularly efficient. It would be more space-efficient
1758 while (($key, $value) = each %by_key) {
1759 $by_value{$value} = $key;
1762 If your hash could have repeated values, the methods above will only find
1763 one of the associated keys. This may or may not worry you. If it does
1764 worry you, you can always reverse the hash into a hash of arrays instead:
1766 while (($key, $value) = each %by_key) {
1767 push @{$key_list_by_value{$value}}, $key;
1770 =head2 How can I know how many entries are in a hash?
1772 If you mean how many keys, then all you have to do is
1773 use the keys() function in a scalar context:
1775 $num_keys = keys %hash;
1777 The keys() function also resets the iterator, which means that you may
1778 see strange results if you use this between uses of other hash operators
1781 =head2 How do I sort a hash (optionally by value instead of key)?
1783 Internally, hashes are stored in a way that prevents you from imposing
1784 an order on key-value pairs. Instead, you have to sort a list of the
1787 @keys = sort keys %hash; # sorted by key
1789 $hash{$a} cmp $hash{$b}
1790 } keys %hash; # and by value
1792 Here we'll do a reverse numeric sort by value, and if two keys are
1793 identical, sort by length of key, or if that fails, by straight ASCII
1794 comparison of the keys (well, possibly modified by your locale--see
1798 $hash{$b} <=> $hash{$a}
1800 length($b) <=> length($a)
1805 =head2 How can I always keep my hash sorted?
1807 You can look into using the DB_File module and tie() using the
1808 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1809 The Tie::IxHash module from CPAN might also be instructive.
1811 =head2 What's the difference between "delete" and "undef" with hashes?
1813 Hashes contain pairs of scalars: the first is the key, the
1814 second is the value. The key will be coerced to a string,
1815 although the value can be any kind of scalar: string,
1816 number, or reference. If a key $key is present in
1817 %hash, C<exists($hash{$key})> will return true. The value
1818 for a given key can be C<undef>, in which case
1819 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
1820 will return true. This corresponds to (C<$key>, C<undef>)
1823 Pictures help... here's the %hash table:
1833 And these conditions hold
1837 defined $hash{'d'} is true
1838 defined $hash{'a'} is true
1839 exists $hash{'a'} is true (Perl5 only)
1840 grep ($_ eq 'a', keys %hash) is true
1846 your table now reads:
1857 and these conditions now hold; changes in caps:
1861 defined $hash{'d'} is true
1862 defined $hash{'a'} is FALSE
1863 exists $hash{'a'} is true (Perl5 only)
1864 grep ($_ eq 'a', keys %hash) is true
1866 Notice the last two: you have an undef value, but a defined key!
1872 your table now reads:
1881 and these conditions now hold; changes in caps:
1885 defined $hash{'d'} is true
1886 defined $hash{'a'} is false
1887 exists $hash{'a'} is FALSE (Perl5 only)
1888 grep ($_ eq 'a', keys %hash) is FALSE
1890 See, the whole entry is gone!
1892 =head2 Why don't my tied hashes make the defined/exists distinction?
1894 This depends on the tied hash's implementation of EXISTS().
1895 For example, there isn't the concept of undef with hashes
1896 that are tied to DBM* files. It also means that exists() and
1897 defined() do the same thing with a DBM* file, and what they
1898 end up doing is not what they do with ordinary hashes.
1900 =head2 How do I reset an each() operation part-way through?
1902 Using C<keys %hash> in scalar context returns the number of keys in
1903 the hash I<and> resets the iterator associated with the hash. You may
1904 need to do this if you use C<last> to exit a loop early so that when you
1905 re-enter it, the hash iterator has been reset.
1907 =head2 How can I get the unique keys from two hashes?
1909 First you extract the keys from the hashes into lists, then solve
1910 the "removing duplicates" problem described above. For example:
1913 for $element (keys(%foo), keys(%bar)) {
1920 @uniq = keys %{{%foo,%bar}};
1922 Or if you really want to save space:
1925 while (defined ($key = each %foo)) {
1928 while (defined ($key = each %bar)) {
1933 =head2 How can I store a multidimensional array in a DBM file?
1935 Either stringify the structure yourself (no fun), or else
1936 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1937 it on top of either DB_File or GDBM_File.
1939 =head2 How can I make my hash remember the order I put elements into it?
1941 Use the Tie::IxHash from CPAN.
1944 tie my %myhash, 'Tie::IxHash';
1945 for (my $i=0; $i<20; $i++) {
1948 my @keys = keys %myhash;
1949 # @keys = (0,1,2,3,...)
1951 =head2 Why does passing a subroutine an undefined element in a hash create it?
1953 If you say something like:
1955 somefunc($hash{"nonesuch key here"});
1957 Then that element "autovivifies"; that is, it springs into existence
1958 whether you store something there or not. That's because functions
1959 get scalars passed in by reference. If somefunc() modifies C<$_[0]>,
1960 it has to be ready to write it back into the caller's version.
1962 This has been fixed as of Perl5.004.
1964 Normally, merely accessing a key's value for a nonexistent key does
1965 I<not> cause that key to be forever there. This is different than
1968 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1970 Usually a hash ref, perhaps like this:
1975 TITLE => "deputy peon",
1978 PALS => [ "Norbert", "Rhys", "Phineas"],
1981 References are documented in L<perlref> and the upcoming L<perlreftut>.
1982 Examples of complex data structures are given in L<perldsc> and
1983 L<perllol>. Examples of structures and object-oriented classes are
1986 =head2 How can I use a reference as a hash key?
1988 You can't do this directly, but you could use the standard Tie::RefHash
1989 module distributed with Perl.
1993 =head2 How do I handle binary data correctly?
1995 Perl is binary clean, so this shouldn't be a problem. For example,
1996 this works fine (assuming the files are found):
1998 if (`cat /vmunix` =~ /gzip/) {
1999 print "Your kernel is GNU-zip enabled!\n";
2002 On less elegant (read: Byzantine) systems, however, you have
2003 to play tedious games with "text" versus "binary" files. See
2004 L<perlfunc/"binmode"> or L<perlopentut>.
2006 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
2008 If you want to deal with multibyte characters, however, there are
2009 some gotchas. See the section on Regular Expressions.
2011 =head2 How do I determine whether a scalar is a number/whole/integer/float?
2013 Assuming that you don't care about IEEE notations like "NaN" or
2014 "Infinity", you probably just want to use a regular expression.
2016 if (/\D/) { print "has nondigits\n" }
2017 if (/^\d+$/) { print "is a whole number\n" }
2018 if (/^-?\d+$/) { print "is an integer\n" }
2019 if (/^[+-]?\d+$/) { print "is a +/- integer\n" }
2020 if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
2021 if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
2022 if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
2023 { print "a C float\n" }
2025 There are also some commonly used modules for the task.
2026 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2027 internal function C<looks_like_number> for determining
2028 whether a variable looks like a number. L<Data::Types>
2029 exports functions that validate data types using both the
2030 above and other regular expressions. Thirdly, there is
2031 C<Regexp::Common> which has regular expressions to match
2032 various types of numbers. Those three modules are available
2035 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2036 function. Its semantics are somewhat cumbersome, so here's a C<getnum>
2037 wrapper function for more convenient access. This function takes
2038 a string and returns the number it found, or C<undef> for input that
2039 isn't a C float. The C<is_numeric> function is a front end to C<getnum>
2040 if you just want to say, "Is this a float?"
2043 use POSIX qw(strtod);
2048 my($num, $unparsed) = strtod($str);
2049 if (($str eq '') || ($unparsed != 0) || $!) {
2056 sub is_numeric { defined getnum($_[0]) }
2058 Or you could check out the L<String::Scanf> module on the CPAN
2059 instead. The POSIX module (part of the standard Perl distribution) provides
2060 the C<strtod> and C<strtol> for converting strings to double and longs,
2063 =head2 How do I keep persistent data across program calls?
2065 For some specific applications, you can use one of the DBM modules.
2066 See L<AnyDBM_File>. More generically, you should consult the FreezeThaw
2067 or Storable modules from CPAN. Starting from Perl 5.8 Storable is part
2068 of the standard distribution. Here's one example using Storable's C<store>
2069 and C<retrieve> functions:
2072 store(\%hash, "filename");
2075 $href = retrieve("filename"); # by ref
2076 %hash = %{ retrieve("filename") }; # direct to hash
2078 =head2 How do I print out or copy a recursive data structure?
2080 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
2081 for printing out data structures. The Storable module on CPAN (or the
2082 5.8 release of Perl), provides a function called C<dclone> that recursively
2083 copies its argument.
2085 use Storable qw(dclone);
2088 Where $r1 can be a reference to any kind of data structure you'd like.
2089 It will be deeply copied. Because C<dclone> takes and returns references,
2090 you'd have to add extra punctuation if you had a hash of arrays that
2093 %newhash = %{ dclone(\%oldhash) };
2095 =head2 How do I define methods for every class/object?
2097 Use the UNIVERSAL class (see L<UNIVERSAL>).
2099 =head2 How do I verify a credit card checksum?
2101 Get the Business::CreditCard module from CPAN.
2103 =head2 How do I pack arrays of doubles or floats for XS code?
2105 The kgbpack.c code in the PGPLOT module on CPAN does just this.
2106 If you're doing a lot of float or double processing, consider using
2107 the PDL module from CPAN instead--it makes number-crunching easy.
2109 =head1 AUTHOR AND COPYRIGHT
2111 Copyright (c) 1997-2005 Tom Christiansen, Nathan Torkington, and
2112 other authors as noted. All rights reserved.
2114 This documentation is free; you can redistribute it and/or modify it
2115 under the same terms as Perl itself.
2117 Irrespective of its distribution, all code examples in this file
2118 are hereby placed into the public domain. You are permitted and
2119 encouraged to use this code in your own programs for fun
2120 or for profit as you see fit. A simple comment in the code giving
2121 credit would be courteous but is not required.