3 perlfaq4 - Data Manipulation
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
14 For the long explanation, see David Goldberg's "What Every Computer
15 Scientist Should Know About Floating-Point Arithmetic"
16 (http://docs.sun.com/source/806-3568/ncg_goldberg.html).
18 Internally, your computer represents floating-point numbers in binary.
19 Digital (as in powers of two) computers cannot store all numbers
20 exactly. Some real numbers lose precision in the process. This is a
21 problem with how computers store numbers and affects all computer
22 languages, not just Perl.
24 L<perlnumber> shows the gory details of number representations and
27 To limit the number of decimal places in your numbers, you can use the
28 C<printf> or C<sprintf> function. See the L<"Floating Point
29 Arithmetic"|perlop> for more details.
33 my $number = sprintf "%.2f", 10/3;
35 =head2 Why is int() broken?
37 Your C<int()> is most probably working just fine. It's the numbers that
38 aren't quite what you think.
40 First, see the answer to "Why am I getting long decimals
41 (eg, 19.9499999999999) instead of the numbers I should be getting
46 print int(0.6/0.2-2), "\n";
48 will in most computers print 0, not 1, because even such simple
49 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
50 numbers. What you think in the above as 'three' is really more like
51 2.9999999999999995559.
53 =head2 Why isn't my octal data interpreted correctly?
55 (contributed by brian d foy)
57 You're probably trying to convert a string to a number, which Perl only
58 converts as a decimal number. When Perl converts a string to a number, it
59 ignores leading spaces and zeroes, then assumes the rest of the digits
64 print $string + 0; # prints 644
66 print $string + 44; # prints 688, certainly not octal!
68 This problem usually involves one of the Perl built-ins that has the
69 same name a Unix command that uses octal numbers as arguments on the
70 command line. In this example, C<chmod> on the command line knows that
71 its first argument is octal because that's what it does:
73 %prompt> chmod 644 file
75 If you want to use the same literal digits (644) in Perl, you have to tell
76 Perl to treat them as octal numbers either by prefixing the digits with
77 a C<0> or using C<oct>:
79 chmod( 0644, $file); # right, has leading zero
80 chmod( oct(644), $file ); # also correct
82 The problem comes in when you take your numbers from something that Perl
83 thinks is a string, such as a command line argument in C<@ARGV>:
85 chmod( $ARGV[0], $file); # wrong, even if "0644"
87 chmod( oct($ARGV[0]), $file ); # correct, treat string as octal
89 You can always check the value you're using by printing it in octal
90 notation to ensure it matches what you think it should be. Print it
91 in octal and decimal format:
93 printf "0%o %d", $number, $number;
95 =head2 Does Perl have a round() function? What about ceil() and floor()? Trig functions?
97 Remember that C<int()> merely truncates toward 0. For rounding to a
98 certain number of digits, C<sprintf()> or C<printf()> is usually the
101 printf("%.3f", 3.1415926535); # prints 3.142
103 The C<POSIX> module (part of the standard Perl distribution)
104 implements C<ceil()>, C<floor()>, and a number of other mathematical
105 and trigonometric functions.
108 $ceil = ceil(3.5); # 4
109 $floor = floor(3.5); # 3
111 In 5.000 to 5.003 perls, trigonometry was done in the C<Math::Complex>
112 module. With 5.004, the C<Math::Trig> module (part of the standard Perl
113 distribution) implements the trigonometric functions. Internally it
114 uses the C<Math::Complex> module and some functions can break out from
115 the real axis into the complex plane, for example the inverse sine of
118 Rounding in financial applications can have serious implications, and
119 the rounding method used should be specified precisely. In these
120 cases, it probably pays not to trust whichever system rounding is
121 being used by Perl, but to instead implement the rounding function you
124 To see why, notice how you'll still have an issue on half-way-point
127 for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
129 0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
130 0.8 0.8 0.9 0.9 1.0 1.0
132 Don't blame Perl. It's the same as in C. IEEE says we have to do
133 this. Perl numbers whose absolute values are integers under 2**31 (on
134 32 bit machines) will work pretty much like mathematical integers.
135 Other numbers are not guaranteed.
137 =head2 How do I convert between numeric representations/bases/radixes?
139 As always with Perl there is more than one way to do it. Below are a
140 few examples of approaches to making common conversions between number
141 representations. This is intended to be representational rather than
144 Some of the examples later in L<perlfaq4> use the C<Bit::Vector>
145 module from CPAN. The reason you might choose C<Bit::Vector> over the
146 perl built in functions is that it works with numbers of ANY size,
147 that it is optimized for speed on some operations, and for at least
148 some programmers the notation might be familiar.
152 =item How do I convert hexadecimal into decimal
154 Using perl's built in conversion of C<0x> notation:
158 Using the C<hex> function:
160 $dec = hex("DEADBEEF");
164 $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
166 Using the CPAN module C<Bit::Vector>:
169 $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
170 $dec = $vec->to_Dec();
172 =item How do I convert from decimal to hexadecimal
176 $hex = sprintf("%X", 3735928559); # upper case A-F
177 $hex = sprintf("%x", 3735928559); # lower case a-f
181 $hex = unpack("H*", pack("N", 3735928559));
183 Using C<Bit::Vector>:
186 $vec = Bit::Vector->new_Dec(32, -559038737);
187 $hex = $vec->to_Hex();
189 And C<Bit::Vector> supports odd bit counts:
192 $vec = Bit::Vector->new_Dec(33, 3735928559);
193 $vec->Resize(32); # suppress leading 0 if unwanted
194 $hex = $vec->to_Hex();
196 =item How do I convert from octal to decimal
198 Using Perl's built in conversion of numbers with leading zeros:
200 $dec = 033653337357; # note the leading 0!
202 Using the C<oct> function:
204 $dec = oct("33653337357");
206 Using C<Bit::Vector>:
209 $vec = Bit::Vector->new(32);
210 $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
211 $dec = $vec->to_Dec();
213 =item How do I convert from decimal to octal
217 $oct = sprintf("%o", 3735928559);
219 Using C<Bit::Vector>:
222 $vec = Bit::Vector->new_Dec(32, -559038737);
223 $oct = reverse join('', $vec->Chunk_List_Read(3));
225 =item How do I convert from binary to decimal
227 Perl 5.6 lets you write binary numbers directly with
230 $number = 0b10110110;
234 my $input = "10110110";
235 $decimal = oct( "0b$input" );
237 Using C<pack> and C<ord>:
239 $decimal = ord(pack('B8', '10110110'));
241 Using C<pack> and C<unpack> for larger strings:
243 $int = unpack("N", pack("B32",
244 substr("0" x 32 . "11110101011011011111011101111", -32)));
245 $dec = sprintf("%d", $int);
247 # substr() is used to left pad a 32 character string with zeros.
249 Using C<Bit::Vector>:
251 $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
252 $dec = $vec->to_Dec();
254 =item How do I convert from decimal to binary
256 Using C<sprintf> (perl 5.6+):
258 $bin = sprintf("%b", 3735928559);
262 $bin = unpack("B*", pack("N", 3735928559));
264 Using C<Bit::Vector>:
267 $vec = Bit::Vector->new_Dec(32, -559038737);
268 $bin = $vec->to_Bin();
270 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
271 are left as an exercise to the inclined reader.
275 =head2 Why doesn't & work the way I want it to?
277 The behavior of binary arithmetic operators depends on whether they're
278 used on numbers or strings. The operators treat a string as a series
279 of bits and work with that (the string C<"3"> is the bit pattern
280 C<00110011>). The operators work with the binary form of a number
281 (the number C<3> is treated as the bit pattern C<00000011>).
283 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
284 C<3>). Saying C<"11" & "3"> performs the "and" operation on strings
287 Most problems with C<&> and C<|> arise because the programmer thinks
288 they have a number but really it's a string. The rest arise because
291 if ("\020\020" & "\101\101") {
295 but a string consisting of two null bytes (the result of C<"\020\020"
296 & "\101\101">) is not a false value in Perl. You need:
298 if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
302 =head2 How do I multiply matrices?
304 Use the C<Math::Matrix> or C<Math::MatrixReal> modules (available from CPAN)
305 or the C<PDL> extension (also available from CPAN).
307 =head2 How do I perform an operation on a series of integers?
309 To call a function on each element in an array, and collect the
312 @results = map { my_func($_) } @array;
316 @triple = map { 3 * $_ } @single;
318 To call a function on each element of an array, but ignore the
321 foreach $iterator (@array) {
322 some_func($iterator);
325 To call a function on each integer in a (small) range, you B<can> use:
327 @results = map { some_func($_) } (5 .. 25);
329 but you should be aware that the C<..> operator creates an array of
330 all integers in the range. This can take a lot of memory for large
334 for ($i=5; $i < 500_005; $i++) {
335 push(@results, some_func($i));
338 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
339 loop will iterate over the range, without creating the entire range.
341 for my $i (5 .. 500_005) {
342 push(@results, some_func($i));
345 will not create a list of 500,000 integers.
347 =head2 How can I output Roman numerals?
349 Get the L<http://www.cpan.org/modules/by-module/Roman> module.
351 =head2 Why aren't my random numbers random?
353 If you're using a version of Perl before 5.004, you must call C<srand>
354 once at the start of your program to seed the random number generator.
356 BEGIN { srand() if $] < 5.004 }
358 5.004 and later automatically call C<srand> at the beginning. Don't
359 call C<srand> more than once--you make your numbers less random,
362 Computers are good at being predictable and bad at being random
363 (despite appearances caused by bugs in your programs :-). see the
364 F<random> article in the "Far More Than You Ever Wanted To Know"
365 collection in L<http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz>, courtesy
366 of Tom Phoenix, talks more about this. John von Neumann said, "Anyone
367 who attempts to generate random numbers by deterministic means is, of
368 course, living in a state of sin."
370 If you want numbers that are more random than C<rand> with C<srand>
371 provides, you should also check out the C<Math::TrulyRandom> module from
372 CPAN. It uses the imperfections in your system's timer to generate
373 random numbers, but this takes quite a while. If you want a better
374 pseudorandom generator than comes with your operating system, look at
375 "Numerical Recipes in C" at L<http://www.nr.com/>.
377 =head2 How do I get a random number between X and Y?
379 To get a random number between two values, you can use the C<rand()>
380 built-in to get a random number between 0 and 1. From there, you shift
381 that into the range that you want.
383 C<rand($x)> returns a number such that C<< 0 <= rand($x) < $x >>. Thus
384 what you want to have perl figure out is a random number in the range
385 from 0 to the difference between your I<X> and I<Y>.
387 That is, to get a number between 10 and 15, inclusive, you want a
388 random number between 0 and 5 that you can then add to 10.
390 my $number = 10 + int rand( 15-10+1 ); # ( 10,11,12,13,14, or 15 )
392 Hence you derive the following simple function to abstract
393 that. It selects a random integer between the two given
394 integers (inclusive), For example: C<random_int_between(50,120)>.
396 sub random_int_between {
398 # Assumes that the two arguments are integers themselves!
399 return $min if $min == $max;
400 ($min, $max) = ($max, $min) if $min > $max;
401 return $min + int rand(1 + $max - $min);
406 =head2 How do I find the day or week of the year?
408 The C<localtime> function returns the day of the year. Without an
409 argument C<localtime> uses the current time.
411 $day_of_year = (localtime)[7];
413 The C<POSIX> module can also format a date as the day of the year or
416 use POSIX qw/strftime/;
417 my $day_of_year = strftime "%j", localtime;
418 my $week_of_year = strftime "%W", localtime;
420 To get the day of year for any date, use C<POSIX>'s C<mktime> to get
421 a time in epoch seconds for the argument to C<localtime>.
423 use POSIX qw/mktime strftime/;
424 my $week_of_year = strftime "%W",
425 localtime( mktime( 0, 0, 0, 18, 11, 87 ) );
427 The C<Date::Calc> module provides two functions to calculate these.
430 my $day_of_year = Day_of_Year( 1987, 12, 18 );
431 my $week_of_year = Week_of_Year( 1987, 12, 18 );
433 =head2 How do I find the current century or millennium?
435 Use the following simple functions:
438 return int((((localtime(shift || time))[5] + 1999))/100);
442 return 1+int((((localtime(shift || time))[5] + 1899))/1000);
445 On some systems, the C<POSIX> module's C<strftime()> function has been
446 extended in a non-standard way to use a C<%C> format, which they
447 sometimes claim is the "century". It isn't, because on most such
448 systems, this is only the first two digits of the four-digit year, and
449 thus cannot be used to reliably determine the current century or
452 =head2 How can I compare two dates and find the difference?
454 (contributed by brian d foy)
456 You could just store all your dates as a number and then subtract.
457 Life isn't always that simple though. If you want to work with
458 formatted dates, the C<Date::Manip>, C<Date::Calc>, or C<DateTime>
459 modules can help you.
461 =head2 How can I take a string and turn it into epoch seconds?
463 If it's a regular enough string that it always has the same format,
464 you can split it up and pass the parts to C<timelocal> in the standard
465 C<Time::Local> module. Otherwise, you should look into the C<Date::Calc>
466 and C<Date::Manip> modules from CPAN.
468 =head2 How can I find the Julian Day?
470 (contributed by brian d foy and Dave Cross)
472 You can use the C<Time::JulianDay> module available on CPAN. Ensure
473 that you really want to find a Julian day, though, as many people have
474 different ideas about Julian days. See
475 http://www.hermetic.ch/cal_stud/jdn.htm for instance.
477 You can also try the C<DateTime> module, which can convert a date/time
480 $ perl -MDateTime -le'print DateTime->today->jd'
483 Or the modified Julian Day
485 $ perl -MDateTime -le'print DateTime->today->mjd'
488 Or even the day of the year (which is what some people think of as a
491 $ perl -MDateTime -le'print DateTime->today->doy'
494 =head2 How do I find yesterday's date?
495 X<date> X<yesterday> X<DateTime> X<Date::Calc> X<Time::Local>
496 X<daylight saving time> X<day> X<Today_and_Now> X<localtime>
499 (contributed by brian d foy)
501 Use one of the Date modules. The C<DateTime> module makes it simple, and
502 give you the same time of day, only the day before.
506 my $yesterday = DateTime->now->subtract( days => 1 );
508 print "Yesterday was $yesterday\n";
510 You can also use the C<Date::Calc> module using its C<Today_and_Now>
513 use Date::Calc qw( Today_and_Now Add_Delta_DHMS );
515 my @date_time = Add_Delta_DHMS( Today_and_Now(), -1, 0, 0, 0 );
517 print "@date_time\n";
519 Most people try to use the time rather than the calendar to figure out
520 dates, but that assumes that days are twenty-four hours each. For
521 most people, there are two days a year when they aren't: the switch to
522 and from summer time throws this off. Let the modules do the work.
524 If you absolutely must do it yourself (or can't use one of the
525 modules), here's a solution using C<Time::Local>, which comes with
528 # contributed by Gunnar Hjalmarsson
530 my $today = timelocal 0, 0, 12, ( localtime )[3..5];
531 my ($d, $m, $y) = ( localtime $today-86400 )[3..5];
532 printf "Yesterday: %d-%02d-%02d\n", $y+1900, $m+1, $d;
534 In this case, you measure the day starting at noon, and subtract 24
535 hours. Even if the length of the calendar day is 23 or 25 hours,
536 you'll still end up on the previous calendar day, although not at
537 noon. Since you don't care about the time, the one hour difference
538 doesn't matter and you end up with the previous date.
540 =head2 Does Perl have a Year 2000 or 2038 problem? Is Perl Y2K compliant?
542 (contributed by brian d foy)
544 Perl itself never had a Y2K problem, although that never stopped people
545 from creating Y2K problems on their own. See the documentation for
546 C<localtime> for its proper use.
548 Starting with Perl 5.11, C<localtime> and C<gmtime> can handle dates past
549 03:14:08 January 19, 2038, when a 32-bit based time would overflow. You
550 still might get a warning on a 32-bit C<perl>:
552 % perl5.11.2 -E 'say scalar localtime( 0x9FFF_FFFFFFFF )'
553 Integer overflow in hexadecimal number at -e line 1.
554 Wed Nov 1 19:42:39 5576711
556 On a 64-bit C<perl>, you can get even larger dates for those really long
559 % perl5.11.2 -E 'say scalar gmtime( 0x9FFF_FFFFFFFF )'
560 Thu Nov 2 00:42:39 5576711
562 You're still out of luck if you need to keep tracking of decaying protons
567 =head2 How do I validate input?
569 (contributed by brian d foy)
571 There are many ways to ensure that values are what you expect or
572 want to accept. Besides the specific examples that we cover in the
573 perlfaq, you can also look at the modules with "Assert" and "Validate"
574 in their names, along with other modules such as C<Regexp::Common>.
576 Some modules have validation for particular types of input, such
577 as C<Business::ISBN>, C<Business::CreditCard>, C<Email::Valid>,
578 and C<Data::Validate::IP>.
580 =head2 How do I unescape a string?
582 It depends just what you mean by "escape". URL escapes are dealt
583 with in L<perlfaq9>. Shell escapes with the backslash (C<\>)
584 character are removed with
588 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
590 =head2 How do I remove consecutive pairs of characters?
592 (contributed by brian d foy)
594 You can use the substitution operator to find pairs of characters (or
595 runs of characters) and replace them with a single instance. In this
596 substitution, we find a character in C<(.)>. The memory parentheses
597 store the matched character in the back-reference C<\1> and we use
598 that to require that the same thing immediately follow it. We replace
599 that part of the string with the character in C<$1>.
603 We can also use the transliteration operator, C<tr///>. In this
604 example, the search list side of our C<tr///> contains nothing, but
605 the C<c> option complements that so it contains everything. The
606 replacement list also contains nothing, so the transliteration is
607 almost a no-op since it won't do any replacements (or more exactly,
608 replace the character with itself). However, the C<s> option squashes
609 duplicated and consecutive characters in the string so a character
610 does not show up next to itself
612 my $str = 'Haarlem'; # in the Netherlands
613 $str =~ tr///cs; # Now Harlem, like in New York
615 =head2 How do I expand function calls in a string?
617 (contributed by brian d foy)
619 This is documented in L<perlref>, and although it's not the easiest
620 thing to read, it does work. In each of these examples, we call the
621 function inside the braces used to dereference a reference. If we
622 have more than one return value, we can construct and dereference an
623 anonymous array. In this case, we call the function in list context.
625 print "The time values are @{ [localtime] }.\n";
627 If we want to call the function in scalar context, we have to do a bit
628 more work. We can really have any code we like inside the braces, so
629 we simply have to end with the scalar reference, although how you do
630 that is up to you, and you can use code inside the braces. Note that
631 the use of parens creates a list context, so we need C<scalar> to
632 force the scalar context on the function:
634 print "The time is ${\(scalar localtime)}.\n"
636 print "The time is ${ my $x = localtime; \$x }.\n";
638 If your function already returns a reference, you don't need to create
639 the reference yourself.
641 sub timestamp { my $t = localtime; \$t }
643 print "The time is ${ timestamp() }.\n";
645 The C<Interpolation> module can also do a lot of magic for you. You can
646 specify a variable name, in this case C<E>, to set up a tied hash that
647 does the interpolation for you. It has several other methods to do this
650 use Interpolation E => 'eval';
651 print "The time values are $E{localtime()}.\n";
653 In most cases, it is probably easier to simply use string concatenation,
654 which also forces scalar context.
656 print "The time is " . localtime() . ".\n";
658 =head2 How do I find matching/nesting anything?
660 This isn't something that can be done in one regular expression, no
661 matter how complicated. To find something between two single
662 characters, a pattern like C</x([^x]*)x/> will get the intervening
663 bits in $1. For multiple ones, then something more like
664 C</alpha(.*?)omega/> would be needed. But none of these deals with
665 nested patterns. For balanced expressions using C<(>, C<{>, C<[> or
666 C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
667 L<perlre/(??{ code })>. For other cases, you'll have to write a
670 If you are serious about writing a parser, there are a number of
671 modules or oddities that will make your life a lot easier. There are
672 the CPAN modules C<Parse::RecDescent>, C<Parse::Yapp>, and
673 C<Text::Balanced>; and the C<byacc> program. Starting from perl 5.8
674 the C<Text::Balanced> is part of the standard distribution.
676 One simple destructive, inside-out approach that you might try is to
677 pull out the smallest nesting parts one at a time:
679 while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
680 # do something with $1
683 A more complicated and sneaky approach is to make Perl's regular
684 expression engine do it for you. This is courtesy Dean Inada, and
685 rather has the nature of an Obfuscated Perl Contest entry, but it
688 # $_ contains the string to parse
689 # BEGIN and END are the opening and closing markers for the
694 ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
695 @$ = (eval{/$re/},$@!~/unmatched/i);
696 print join("\n",@$[0..$#$]) if( $$[-1] );
698 =head2 How do I reverse a string?
700 Use C<reverse()> in scalar context, as documented in
703 $reversed = reverse $string;
705 =head2 How do I expand tabs in a string?
707 You can do it yourself:
709 1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
711 Or you can just use the C<Text::Tabs> module (part of the standard Perl
715 @expanded_lines = expand(@lines_with_tabs);
717 =head2 How do I reformat a paragraph?
719 Use C<Text::Wrap> (part of the standard Perl distribution):
722 print wrap("\t", ' ', @paragraphs);
724 The paragraphs you give to C<Text::Wrap> should not contain embedded
725 newlines. C<Text::Wrap> doesn't justify the lines (flush-right).
727 Or use the CPAN module C<Text::Autoformat>. Formatting files can be
728 easily done by making a shell alias, like so:
730 alias fmt="perl -i -MText::Autoformat -n0777 \
731 -e 'print autoformat $_, {all=>1}' $*"
733 See the documentation for C<Text::Autoformat> to appreciate its many
736 =head2 How can I access or change N characters of a string?
738 You can access the first characters of a string with substr().
739 To get the first character, for example, start at position 0
740 and grab the string of length 1.
743 $string = "Just another Perl Hacker";
744 $first_char = substr( $string, 0, 1 ); # 'J'
746 To change part of a string, you can use the optional fourth
747 argument which is the replacement string.
749 substr( $string, 13, 4, "Perl 5.8.0" );
751 You can also use substr() as an lvalue.
753 substr( $string, 13, 4 ) = "Perl 5.8.0";
755 =head2 How do I change the Nth occurrence of something?
757 You have to keep track of N yourself. For example, let's say you want
758 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
759 C<"whosoever"> or C<"whomsoever">, case insensitively. These
760 all assume that $_ contains the string to be altered.
764 ++$count == 5 # is it the 5th?
765 ? "${2}soever" # yes, swap
766 : $1 # renege and leave it there
769 In the more general case, you can use the C</g> modifier in a C<while>
770 loop, keeping count of matches.
774 $_ = "One fish two fish red fish blue fish";
775 while (/(\w+)\s+fish\b/gi) {
776 if (++$count == $WANT) {
777 print "The third fish is a $1 one.\n";
781 That prints out: C<"The third fish is a red one."> You can also use a
782 repetition count and repeated pattern like this:
784 /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
786 =head2 How can I count the number of occurrences of a substring within a string?
788 There are a number of ways, with varying efficiency. If you want a
789 count of a certain single character (X) within a string, you can use the
790 C<tr///> function like so:
792 $string = "ThisXlineXhasXsomeXx'sXinXit";
793 $count = ($string =~ tr/X//);
794 print "There are $count X characters in the string";
796 This is fine if you are just looking for a single character. However,
797 if you are trying to count multiple character substrings within a
798 larger string, C<tr///> won't work. What you can do is wrap a while()
799 loop around a global pattern match. For example, let's count negative
802 $string = "-9 55 48 -2 23 -76 4 14 -44";
803 while ($string =~ /-\d+/g) { $count++ }
804 print "There are $count negative numbers in the string";
806 Another version uses a global match in list context, then assigns the
807 result to a scalar, producing a count of the number of matches.
809 $count = () = $string =~ /-\d+/g;
811 =head2 How do I capitalize all the words on one line?
812 X<Text::Autoformat> X<capitalize> X<case, title> X<case, sentence>
814 (contributed by brian d foy)
816 Damian Conway's L<Text::Autoformat> handles all of the thinking
819 use Text::Autoformat;
820 my $x = "Dr. Strangelove or: How I Learned to Stop ".
821 "Worrying and Love the Bomb";
824 for my $style (qw( sentence title highlight )) {
825 print autoformat($x, { case => $style }), "\n";
828 How do you want to capitalize those words?
830 FRED AND BARNEY'S LODGE # all uppercase
831 Fred And Barney's Lodge # title case
832 Fred and Barney's Lodge # highlight case
834 It's not as easy a problem as it looks. How many words do you think
835 are in there? Wait for it... wait for it.... If you answered 5
836 you're right. Perl words are groups of C<\w+>, but that's not what
837 you want to capitalize. How is Perl supposed to know not to capitalize
838 that C<s> after the apostrophe? You could try a regular expression:
841 (^\w) #at the beginning of the line
843 (\s\w) #preceded by whitespace
847 $string =~ s/([\w']+)/\u\L$1/g;
849 Now, what if you don't want to capitalize that "and"? Just use
850 L<Text::Autoformat> and get on with the next problem. :)
852 =head2 How can I split a [character] delimited string except when inside [character]?
854 Several modules can handle this sort of parsing--C<Text::Balanced>,
855 C<Text::CSV>, C<Text::CSV_XS>, and C<Text::ParseWords>, among others.
857 Take the example case of trying to split a string that is
858 comma-separated into its different fields. You can't use C<split(/,/)>
859 because you shouldn't split if the comma is inside quotes. For
860 example, take a data line like this:
862 SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
864 Due to the restriction of the quotes, this is a fairly complex
865 problem. Thankfully, we have Jeffrey Friedl, author of
866 I<Mastering Regular Expressions>, to handle these for us. He
867 suggests (assuming your string is contained in C<$text>):
870 push(@new, $+) while $text =~ m{
871 "([^\"\\]*(?:\\.[^\"\\]*)*)",? # groups the phrase inside the quotes
875 push(@new, undef) if substr($text,-1,1) eq ',';
877 If you want to represent quotation marks inside a
878 quotation-mark-delimited field, escape them with backslashes (eg,
881 Alternatively, the C<Text::ParseWords> module (part of the standard
882 Perl distribution) lets you say:
884 use Text::ParseWords;
885 @new = quotewords(",", 0, $text);
887 =head2 How do I strip blank space from the beginning/end of a string?
889 (contributed by brian d foy)
891 A substitution can do this for you. For a single line, you want to
892 replace all the leading or trailing whitespace with nothing. You
893 can do that with a pair of substitutions.
898 You can also write that as a single substitution, although it turns
899 out the combined statement is slower than the separate ones. That
900 might not matter to you, though.
904 In this regular expression, the alternation matches either at the
905 beginning or the end of the string since the anchors have a lower
906 precedence than the alternation. With the C</g> flag, the substitution
907 makes all possible matches, so it gets both. Remember, the trailing
908 newline matches the C<\s+>, and the C<$> anchor can match to the
909 physical end of the string, so the newline disappears too. Just add
910 the newline to the output, which has the added benefit of preserving
911 "blank" (consisting entirely of whitespace) lines which the C<^\s+>
912 would remove all by itself.
920 For a multi-line string, you can apply the regular expression
921 to each logical line in the string by adding the C</m> flag (for
922 "multi-line"). With the C</m> flag, the C<$> matches I<before> an
923 embedded newline, so it doesn't remove it. It still removes the
924 newline at the end of the string.
926 $string =~ s/^\s+|\s+$//gm;
928 Remember that lines consisting entirely of whitespace will disappear,
929 since the first part of the alternation can match the entire string
930 and replace it with nothing. If need to keep embedded blank lines,
931 you have to do a little more work. Instead of matching any whitespace
932 (since that includes a newline), just match the other whitespace.
934 $string =~ s/^[\t\f ]+|[\t\f ]+$//mg;
936 =head2 How do I pad a string with blanks or pad a number with zeroes?
938 In the following examples, C<$pad_len> is the length to which you wish
939 to pad the string, C<$text> or C<$num> contains the string to be padded,
940 and C<$pad_char> contains the padding character. You can use a single
941 character string constant instead of the C<$pad_char> variable if you
942 know what it is in advance. And in the same way you can use an integer in
943 place of C<$pad_len> if you know the pad length in advance.
945 The simplest method uses the C<sprintf> function. It can pad on the left
946 or right with blanks and on the left with zeroes and it will not
947 truncate the result. The C<pack> function can only pad strings on the
948 right with blanks and it will truncate the result to a maximum length of
951 # Left padding a string with blanks (no truncation):
952 $padded = sprintf("%${pad_len}s", $text);
953 $padded = sprintf("%*s", $pad_len, $text); # same thing
955 # Right padding a string with blanks (no truncation):
956 $padded = sprintf("%-${pad_len}s", $text);
957 $padded = sprintf("%-*s", $pad_len, $text); # same thing
959 # Left padding a number with 0 (no truncation):
960 $padded = sprintf("%0${pad_len}d", $num);
961 $padded = sprintf("%0*d", $pad_len, $num); # same thing
963 # Right padding a string with blanks using pack (will truncate):
964 $padded = pack("A$pad_len",$text);
966 If you need to pad with a character other than blank or zero you can use
967 one of the following methods. They all generate a pad string with the
968 C<x> operator and combine that with C<$text>. These methods do
969 not truncate C<$text>.
971 Left and right padding with any character, creating a new string:
973 $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
974 $padded = $text . $pad_char x ( $pad_len - length( $text ) );
976 Left and right padding with any character, modifying C<$text> directly:
978 substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
979 $text .= $pad_char x ( $pad_len - length( $text ) );
981 =head2 How do I extract selected columns from a string?
983 (contributed by brian d foy)
985 If you know the columns that contain the data, you can
986 use C<substr> to extract a single column.
988 my $column = substr( $line, $start_column, $length );
990 You can use C<split> if the columns are separated by whitespace or
991 some other delimiter, as long as whitespace or the delimiter cannot
992 appear as part of the data.
994 my $line = ' fred barney betty ';
995 my @columns = split /\s+/, $line;
996 # ( '', 'fred', 'barney', 'betty' );
998 my $line = 'fred||barney||betty';
999 my @columns = split /\|/, $line;
1000 # ( 'fred', '', 'barney', '', 'betty' );
1002 If you want to work with comma-separated values, don't do this since
1003 that format is a bit more complicated. Use one of the modules that
1004 handle that format, such as C<Text::CSV>, C<Text::CSV_XS>, or
1007 If you want to break apart an entire line of fixed columns, you can use
1008 C<unpack> with the A (ASCII) format. By using a number after the format
1009 specifier, you can denote the column width. See the C<pack> and C<unpack>
1010 entries in L<perlfunc> for more details.
1012 my @fields = unpack( $line, "A8 A8 A8 A16 A4" );
1014 Note that spaces in the format argument to C<unpack> do not denote literal
1015 spaces. If you have space separated data, you may want C<split> instead.
1017 =head2 How do I find the soundex value of a string?
1019 (contributed by brian d foy)
1021 You can use the Text::Soundex module. If you want to do fuzzy or close
1022 matching, you might also try the C<String::Approx>, and
1023 C<Text::Metaphone>, and C<Text::DoubleMetaphone> modules.
1025 =head2 How can I expand variables in text strings?
1027 (contributed by brian d foy)
1029 If you can avoid it, don't, or if you can use a templating system,
1030 such as C<Text::Template> or C<Template> Toolkit, do that instead. You
1031 might even be able to get the job done with C<sprintf> or C<printf>:
1033 my $string = sprintf 'Say hello to %s and %s', $foo, $bar;
1035 However, for the one-off simple case where I don't want to pull out a
1036 full templating system, I'll use a string that has two Perl scalar
1037 variables in it. In this example, I want to expand C<$foo> and C<$bar>
1038 to their variable's values:
1042 $string = 'Say hello to $foo and $bar';
1044 One way I can do this involves the substitution operator and a double
1045 C</e> flag. The first C</e> evaluates C<$1> on the replacement side and
1046 turns it into C<$foo>. The second /e starts with C<$foo> and replaces
1047 it with its value. C<$foo>, then, turns into 'Fred', and that's finally
1048 what's left in the string:
1050 $string =~ s/(\$\w+)/$1/eeg; # 'Say hello to Fred and Barney'
1052 The C</e> will also silently ignore violations of strict, replacing
1053 undefined variable names with the empty string. Since I'm using the
1054 C</e> flag (twice even!), I have all of the same security problems I
1055 have with C<eval> in its string form. If there's something odd in
1056 C<$foo>, perhaps something like C<@{[ system "rm -rf /" ]}>, then
1057 I could get myself in trouble.
1059 To get around the security problem, I could also pull the values from
1060 a hash instead of evaluating variable names. Using a single C</e>, I
1061 can check the hash to ensure the value exists, and if it doesn't, I
1062 can replace the missing value with a marker, in this case C<???> to
1063 signal that I missed something:
1065 my $string = 'This has $foo and $bar';
1067 my %Replacements = (
1071 # $string =~ s/\$(\w+)/$Replacements{$1}/g;
1072 $string =~ s/\$(\w+)/
1073 exists $Replacements{$1} ? $Replacements{$1} : '???'
1078 =head2 What's wrong with always quoting "$vars"?
1080 The problem is that those double-quotes force
1081 stringification--coercing numbers and references into strings--even
1082 when you don't want them to be strings. Think of it this way:
1083 double-quote expansion is used to produce new strings. If you already
1084 have a string, why do you need more?
1086 If you get used to writing odd things like these:
1089 $new = "$old"; # BAD
1090 somefunc("$var"); # BAD
1092 You'll be in trouble. Those should (in 99.8% of the cases) be
1093 the simpler and more direct:
1099 Otherwise, besides slowing you down, you're going to break code when
1100 the thing in the scalar is actually neither a string nor a number, but
1106 my $oref = "$aref"; # WRONG
1109 You can also get into subtle problems on those few operations in Perl
1110 that actually do care about the difference between a string and a
1111 number, such as the magical C<++> autoincrement operator or the
1114 Stringification also destroys arrays.
1117 print "@lines"; # WRONG - extra blanks
1118 print @lines; # right
1120 =head2 Why don't my E<lt>E<lt>HERE documents work?
1122 Check for these three things:
1126 =item There must be no space after the E<lt>E<lt> part.
1128 =item There (probably) should be a semicolon at the end.
1130 =item You can't (easily) have any space in front of the tag.
1134 If you want to indent the text in the here document, you
1138 ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1143 But the HERE_TARGET must still be flush against the margin.
1144 If you want that indented also, you'll have to quote
1147 ($quote = <<' FINIS') =~ s/^\s+//gm;
1148 ...we will have peace, when you and all your works have
1149 perished--and the works of your dark master to whom you
1150 would deliver us. You are a liar, Saruman, and a corrupter
1151 of men's hearts. --Theoden in /usr/src/perl/taint.c
1153 $quote =~ s/\s+--/\n--/;
1155 A nice general-purpose fixer-upper function for indented here documents
1156 follows. It expects to be called with a here document as its argument.
1157 It looks to see whether each line begins with a common substring, and
1158 if so, strips that substring off. Otherwise, it takes the amount of leading
1159 whitespace found on the first line and removes that much off each
1164 my ($white, $leader); # common whitespace and common leading string
1165 if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1166 ($white, $leader) = ($2, quotemeta($1));
1168 ($white, $leader) = (/^(\s+)/, '');
1170 s/^\s*?$leader(?:$white)?//gm;
1174 This works with leading special strings, dynamically determined:
1176 $remember_the_main = fix<<' MAIN_INTERPRETER_LOOP';
1179 @@@ SAVEI32(runlevel);
1181 @@@ while ( op = (*op->op_ppaddr)() );
1185 MAIN_INTERPRETER_LOOP
1187 Or with a fixed amount of leading whitespace, with remaining
1188 indentation correctly preserved:
1190 $poem = fix<<EVER_ON_AND_ON;
1191 Now far ahead the Road has gone,
1192 And I must follow, if I can,
1193 Pursuing it with eager feet,
1194 Until it joins some larger way
1195 Where many paths and errands meet.
1196 And whither then? I cannot say.
1197 --Bilbo in /usr/src/perl/pp_ctl.c
1202 =head2 What is the difference between a list and an array?
1204 (contributed by brian d foy)
1206 A list is a fixed collection of scalars. An array is a variable that
1207 holds a variable collection of scalars. An array can supply its collection
1208 for list operations, so list operations also work on arrays:
1211 ( 'dog', 'cat', 'bird' )[2,3];
1215 foreach ( qw( dog cat bird ) ) { ... }
1216 foreach ( @animals ) { ... }
1218 my @three = grep { length == 3 } qw( dog cat bird );
1219 my @three = grep { length == 3 } @animals;
1221 # supply an argument list
1222 wash_animals( qw( dog cat bird ) );
1223 wash_animals( @animals );
1225 Array operations, which change the scalars, reaaranges them, or adds
1226 or subtracts some scalars, only work on arrays. These can't work on a
1227 list, which is fixed. Array operations include C<shift>, C<unshift>,
1228 C<push>, C<pop>, and C<splice>.
1230 An array can also change its length:
1232 $#animals = 1; # truncate to two elements
1233 $#animals = 10000; # pre-extend to 10,001 elements
1235 You can change an array element, but you can't change a list element:
1237 $animals[0] = 'Rottweiler';
1238 qw( dog cat bird )[0] = 'Rottweiler'; # syntax error!
1240 foreach ( @animals ) {
1241 s/^d/fr/; # works fine
1244 foreach ( qw( dog cat bird ) ) {
1245 s/^d/fr/; # Error! Modification of read only value!
1248 However, if the list element is itself a variable, it appears that you
1249 can change a list element. However, the list element is the variable, not
1250 the data. You're not changing the list element, but something the list
1251 element refers to. The list element itself doesn't change: it's still
1254 You also have to be careful about context. You can assign an array to
1255 a scalar to get the number of elements in the array. This only works
1258 my $count = @animals; # only works with arrays
1260 If you try to do the same thing with what you think is a list, you
1261 get a quite different result. Although it looks like you have a list
1262 on the righthand side, Perl actually sees a bunch of scalars separated
1265 my $scalar = ( 'dog', 'cat', 'bird' ); # $scalar gets bird
1267 Since you're assigning to a scalar, the righthand side is in scalar
1268 context. The comma operator (yes, it's an operator!) in scalar
1269 context evaluates its lefthand side, throws away the result, and
1270 evaluates it's righthand side and returns the result. In effect,
1271 that list-lookalike assigns to C<$scalar> it's rightmost value. Many
1272 people mess this up becuase they choose a list-lookalike whose
1273 last element is also the count they expect:
1275 my $scalar = ( 1, 2, 3 ); # $scalar gets 3, accidentally
1277 =head2 What is the difference between $array[1] and @array[1]?
1279 (contributed by brian d foy)
1281 The difference is the sigil, that special character in front of the
1282 array name. The C<$> sigil means "exactly one item", while the C<@>
1283 sigil means "zero or more items". The C<$> gets you a single scalar,
1284 while the C<@> gets you a list.
1286 The confusion arises because people incorrectly assume that the sigil
1287 denotes the variable type.
1289 The C<$array[1]> is a single-element access to the array. It's going
1290 to return the item in index 1 (or undef if there is no item there).
1291 If you intend to get exactly one element from the array, this is the
1292 form you should use.
1294 The C<@array[1]> is an array slice, although it has only one index.
1295 You can pull out multiple elements simultaneously by specifying
1296 additional indices as a list, like C<@array[1,4,3,0]>.
1298 Using a slice on the lefthand side of the assignment supplies list
1299 context to the righthand side. This can lead to unexpected results.
1300 For instance, if you want to read a single line from a filehandle,
1301 assigning to a scalar value is fine:
1303 $array[1] = <STDIN>;
1305 However, in list context, the line input operator returns all of the
1306 lines as a list. The first line goes into C<@array[1]> and the rest
1307 of the lines mysteriously disappear:
1309 @array[1] = <STDIN>; # most likely not what you want
1311 Either the C<use warnings> pragma or the B<-w> flag will warn you when
1312 you use an array slice with a single index.
1314 =head2 How can I remove duplicate elements from a list or array?
1316 (contributed by brian d foy)
1318 Use a hash. When you think the words "unique" or "duplicated", think
1321 If you don't care about the order of the elements, you could just
1322 create the hash then extract the keys. It's not important how you
1323 create that hash: just that you use C<keys> to get the unique
1326 my %hash = map { $_, 1 } @array;
1327 # or a hash slice: @hash{ @array } = ();
1328 # or a foreach: $hash{$_} = 1 foreach ( @array );
1330 my @unique = keys %hash;
1332 If you want to use a module, try the C<uniq> function from
1333 C<List::MoreUtils>. In list context it returns the unique elements,
1334 preserving their order in the list. In scalar context, it returns the
1335 number of unique elements.
1337 use List::MoreUtils qw(uniq);
1339 my @unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 1,2,3,4,5,6,7
1340 my $unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 7
1342 You can also go through each element and skip the ones you've seen
1343 before. Use a hash to keep track. The first time the loop sees an
1344 element, that element has no key in C<%Seen>. The C<next> statement
1345 creates the key and immediately uses its value, which is C<undef>, so
1346 the loop continues to the C<push> and increments the value for that
1347 key. The next time the loop sees that same element, its key exists in
1348 the hash I<and> the value for that key is true (since it's not 0 or
1349 C<undef>), so the next skips that iteration and the loop goes to the
1355 foreach my $elem ( @array )
1357 next if $seen{ $elem }++;
1358 push @unique, $elem;
1361 You can write this more briefly using a grep, which does the
1365 my @unique = grep { ! $seen{ $_ }++ } @array;
1367 =head2 How can I tell whether a certain element is contained in a list or array?
1369 (portions of this answer contributed by Anno Siegel and brian d foy)
1371 Hearing the word "in" is an I<in>dication that you probably should have
1372 used a hash, not a list or array, to store your data. Hashes are
1373 designed to answer this question quickly and efficiently. Arrays aren't.
1375 That being said, there are several ways to approach this. In Perl 5.10
1376 and later, you can use the smart match operator to check that an item is
1377 contained in an array or a hash:
1381 if( $item ~~ @array )
1383 say "The array contains $item"
1386 if( $item ~~ %hash )
1388 say "The hash contains $item"
1391 With earlier versions of Perl, you have to do a bit more work. If you
1392 are going to make this query many times over arbitrary string values,
1393 the fastest way is probably to invert the original array and maintain a
1394 hash whose keys are the first array's values:
1396 @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1398 for (@blues) { $is_blue{$_} = 1 }
1400 Now you can check whether C<$is_blue{$some_color}>. It might have
1401 been a good idea to keep the blues all in a hash in the first place.
1403 If the values are all small integers, you could use a simple indexed
1404 array. This kind of an array will take up less space:
1406 @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1407 @is_tiny_prime = ();
1408 for (@primes) { $is_tiny_prime[$_] = 1 }
1409 # or simply @istiny_prime[@primes] = (1) x @primes;
1411 Now you check whether $is_tiny_prime[$some_number].
1413 If the values in question are integers instead of strings, you can save
1414 quite a lot of space by using bit strings instead:
1416 @articles = ( 1..10, 150..2000, 2017 );
1418 for (@articles) { vec($read,$_,1) = 1 }
1420 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1422 These methods guarantee fast individual tests but require a re-organization
1423 of the original list or array. They only pay off if you have to test
1424 multiple values against the same array.
1426 If you are testing only once, the standard module C<List::Util> exports
1427 the function C<first> for this purpose. It works by stopping once it
1428 finds the element. It's written in C for speed, and its Perl equivalent
1429 looks like this subroutine:
1434 return $_ if &{$code}();
1439 If speed is of little concern, the common idiom uses grep in scalar context
1440 (which returns the number of items that passed its condition) to traverse the
1441 entire list. This does have the benefit of telling you how many matches it
1444 my $is_there = grep $_ eq $whatever, @array;
1446 If you want to actually extract the matching elements, simply use grep in
1449 my @matches = grep $_ eq $whatever, @array;
1451 =head2 How do I compute the difference of two arrays? How do I compute the intersection of two arrays?
1453 Use a hash. Here's code to do both and more. It assumes that each
1454 element is unique in a given array:
1456 @union = @intersection = @difference = ();
1458 foreach $element (@array1, @array2) { $count{$element}++ }
1459 foreach $element (keys %count) {
1460 push @union, $element;
1461 push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1464 Note that this is the I<symmetric difference>, that is, all elements
1465 in either A or in B but not in both. Think of it as an xor operation.
1467 =head2 How do I test whether two arrays or hashes are equal?
1469 With Perl 5.10 and later, the smart match operator can give you the answer
1470 with the least amount of work:
1474 if( @array1 ~~ @array2 )
1476 say "The arrays are the same";
1479 if( %hash1 ~~ %hash2 ) # doesn't check values!
1481 say "The hash keys are the same";
1484 The following code works for single-level arrays. It uses a
1485 stringwise comparison, and does not distinguish defined versus
1486 undefined empty strings. Modify if you have other needs.
1488 $are_equal = compare_arrays(\@frogs, \@toads);
1490 sub compare_arrays {
1491 my ($first, $second) = @_;
1492 no warnings; # silence spurious -w undef complaints
1493 return 0 unless @$first == @$second;
1494 for (my $i = 0; $i < @$first; $i++) {
1495 return 0 if $first->[$i] ne $second->[$i];
1500 For multilevel structures, you may wish to use an approach more
1501 like this one. It uses the CPAN module C<FreezeThaw>:
1503 use FreezeThaw qw(cmpStr);
1504 @a = @b = ( "this", "that", [ "more", "stuff" ] );
1506 printf "a and b contain %s arrays\n",
1507 cmpStr(\@a, \@b) == 0
1511 This approach also works for comparing hashes. Here we'll demonstrate
1512 two different answers:
1514 use FreezeThaw qw(cmpStr cmpStrHard);
1516 %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1520 printf "a and b contain %s hashes\n",
1521 cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1523 printf "a and b contain %s hashes\n",
1524 cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1527 The first reports that both those the hashes contain the same data,
1528 while the second reports that they do not. Which you prefer is left as
1529 an exercise to the reader.
1531 =head2 How do I find the first array element for which a condition is true?
1533 To find the first array element which satisfies a condition, you can
1534 use the C<first()> function in the C<List::Util> module, which comes
1535 with Perl 5.8. This example finds the first element that contains
1538 use List::Util qw(first);
1540 my $element = first { /Perl/ } @array;
1542 If you cannot use C<List::Util>, you can make your own loop to do the
1543 same thing. Once you find the element, you stop the loop with last.
1546 foreach ( @array ) {
1547 if( /Perl/ ) { $found = $_; last }
1550 If you want the array index, you can iterate through the indices
1551 and check the array element at each index until you find one
1552 that satisfies the condition.
1554 my( $found, $index ) = ( undef, -1 );
1555 for( $i = 0; $i < @array; $i++ ) {
1556 if( $array[$i] =~ /Perl/ ) {
1557 $found = $array[$i];
1563 =head2 How do I handle linked lists?
1565 In general, you usually don't need a linked list in Perl, since with
1566 regular arrays, you can push and pop or shift and unshift at either
1567 end, or you can use splice to add and/or remove arbitrary number of
1568 elements at arbitrary points. Both pop and shift are O(1)
1569 operations on Perl's dynamic arrays. In the absence of shifts and
1570 pops, push in general needs to reallocate on the order every log(N)
1571 times, and unshift will need to copy pointers each time.
1573 If you really, really wanted, you could use structures as described in
1574 L<perldsc> or L<perltoot> and do just what the algorithm book tells
1575 you to do. For example, imagine a list node like this:
1582 You could walk the list this way:
1585 for ($node = $head; $node; $node = $node->{LINK}) {
1586 print $node->{VALUE}, " ";
1590 You could add to the list this way:
1593 $tail = append($head, 1); # grow a new head
1594 for $value ( 2 .. 10 ) {
1595 $tail = append($tail, $value);
1599 my($list, $value) = @_;
1600 my $node = { VALUE => $value };
1602 $node->{LINK} = $list->{LINK};
1603 $list->{LINK} = $node;
1606 $_[0] = $node; # replace caller's version
1611 But again, Perl's built-in are virtually always good enough.
1613 =head2 How do I handle circular lists?
1614 X<circular> X<array> X<Tie::Cycle> X<Array::Iterator::Circular>
1617 (contributed by brian d foy)
1619 If you want to cycle through an array endlessly, you can increment the
1620 index modulo the number of elements in the array:
1622 my @array = qw( a b c );
1626 print $array[ $i++ % @array ], "\n";
1630 You can also use C<Tie::Cycle> to use a scalar that always has the
1631 next element of the circular array:
1635 tie my $cycle, 'Tie::Cycle', [ qw( FFFFFF 000000 FFFF00 ) ];
1637 print $cycle; # FFFFFF
1638 print $cycle; # 000000
1639 print $cycle; # FFFF00
1641 The C<Array::Iterator::Circular> creates an iterator object for
1644 use Array::Iterator::Circular;
1646 my $color_iterator = Array::Iterator::Circular->new(
1647 qw(red green blue orange)
1650 foreach ( 1 .. 20 ) {
1651 print $color_iterator->next, "\n";
1654 =head2 How do I shuffle an array randomly?
1656 If you either have Perl 5.8.0 or later installed, or if you have
1657 Scalar-List-Utils 1.03 or later installed, you can say:
1659 use List::Util 'shuffle';
1661 @shuffled = shuffle(@list);
1663 If not, you can use a Fisher-Yates shuffle.
1665 sub fisher_yates_shuffle {
1666 my $deck = shift; # $deck is a reference to an array
1667 return unless @$deck; # must not be empty!
1671 my $j = int rand ($i+1);
1672 @$deck[$i,$j] = @$deck[$j,$i];
1676 # shuffle my mpeg collection
1678 my @mpeg = <audio/*/*.mp3>;
1679 fisher_yates_shuffle( \@mpeg ); # randomize @mpeg in place
1682 Note that the above implementation shuffles an array in place,
1683 unlike the C<List::Util::shuffle()> which takes a list and returns
1684 a new shuffled list.
1686 You've probably seen shuffling algorithms that work using splice,
1687 randomly picking another element to swap the current element with
1691 @old = 1 .. 10; # just a demo
1693 push(@new, splice(@old, rand @old, 1));
1696 This is bad because splice is already O(N), and since you do it N
1697 times, you just invented a quadratic algorithm; that is, O(N**2).
1698 This does not scale, although Perl is so efficient that you probably
1699 won't notice this until you have rather largish arrays.
1701 =head2 How do I process/modify each element of an array?
1703 Use C<for>/C<foreach>:
1706 s/foo/bar/; # change that word
1707 tr/XZ/ZX/; # swap those letters
1710 Here's another; let's compute spherical volumes:
1712 for (@volumes = @radii) { # @volumes has changed parts
1714 $_ *= (4/3) * 3.14159; # this will be constant folded
1717 which can also be done with C<map()> which is made to transform
1718 one list into another:
1720 @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1722 If you want to do the same thing to modify the values of the
1723 hash, you can use the C<values> function. As of Perl 5.6
1724 the values are not copied, so if you modify $orbit (in this
1725 case), you modify the value.
1727 for $orbit ( values %orbits ) {
1728 ($orbit **= 3) *= (4/3) * 3.14159;
1731 Prior to perl 5.6 C<values> returned copies of the values,
1732 so older perl code often contains constructions such as
1733 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1734 the hash is to be modified.
1736 =head2 How do I select a random element from an array?
1738 Use the C<rand()> function (see L<perlfunc/rand>):
1740 $index = rand @array;
1741 $element = $array[$index];
1745 my $element = $array[ rand @array ];
1747 =head2 How do I permute N elements of a list?
1748 X<List::Permuter> X<permute> X<Algorithm::Loops> X<Knuth>
1749 X<The Art of Computer Programming> X<Fischer-Krause>
1751 Use the C<List::Permutor> module on CPAN. If the list is actually an
1752 array, try the C<Algorithm::Permute> module (also on CPAN). It's
1753 written in XS code and is very efficient:
1755 use Algorithm::Permute;
1757 my @array = 'a'..'d';
1758 my $p_iterator = Algorithm::Permute->new ( \@array );
1760 while (my @perm = $p_iterator->next) {
1761 print "next permutation: (@perm)\n";
1764 For even faster execution, you could do:
1766 use Algorithm::Permute;
1768 my @array = 'a'..'d';
1770 Algorithm::Permute::permute {
1771 print "next permutation: (@array)\n";
1774 Here's a little program that generates all permutations of all the
1775 words on each line of input. The algorithm embodied in the
1776 C<permute()> function is discussed in Volume 4 (still unpublished) of
1777 Knuth's I<The Art of Computer Programming> and will work on any list:
1780 # Fischer-Krause ordered permutation generator
1785 while ( $code->(@_[@idx]) ) {
1787 --$p while $idx[$p-1] > $idx[$p];
1788 my $q = $p or return;
1789 push @idx, reverse splice @idx, $p;
1790 ++$q while $idx[$p-1] > $idx[$q];
1791 @idx[$p-1,$q]=@idx[$q,$p-1];
1795 permute { print "@_\n" } split;
1797 The C<Algorithm::Loops> module also provides the C<NextPermute> and
1798 C<NextPermuteNum> functions which efficiently find all unique permutations
1799 of an array, even if it contains duplicate values, modifying it in-place:
1800 if its elements are in reverse-sorted order then the array is reversed,
1801 making it sorted, and it returns false; otherwise the next
1802 permutation is returned.
1804 C<NextPermute> uses string order and C<NextPermuteNum> numeric order, so
1805 you can enumerate all the permutations of C<0..9> like this:
1807 use Algorithm::Loops qw(NextPermuteNum);
1810 do { print "@list\n" } while NextPermuteNum @list;
1812 =head2 How do I sort an array by (anything)?
1814 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1816 @list = sort { $a <=> $b } @list;
1818 The default sort function is cmp, string comparison, which would
1819 sort C<(1, 2, 10)> into C<(1, 10, 2)>. C<< <=> >>, used above, is
1820 the numerical comparison operator.
1822 If you have a complicated function needed to pull out the part you
1823 want to sort on, then don't do it inside the sort function. Pull it
1824 out first, because the sort BLOCK can be called many times for the
1825 same element. Here's an example of how to pull out the first word
1826 after the first number on each item, and then sort those words
1831 ($item) = /\d+\s*(\S+)/;
1832 push @idx, uc($item);
1834 @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1836 which could also be written this way, using a trick
1837 that's come to be known as the Schwartzian Transform:
1839 @sorted = map { $_->[0] }
1840 sort { $a->[1] cmp $b->[1] }
1841 map { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1843 If you need to sort on several fields, the following paradigm is useful.
1846 field1($a) <=> field1($b) ||
1847 field2($a) cmp field2($b) ||
1848 field3($a) cmp field3($b)
1851 This can be conveniently combined with precalculation of keys as given
1854 See the F<sort> article in the "Far More Than You Ever Wanted
1855 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1856 more about this approach.
1858 See also the question later in L<perlfaq4> on sorting hashes.
1860 =head2 How do I manipulate arrays of bits?
1862 Use C<pack()> and C<unpack()>, or else C<vec()> and the bitwise
1865 For example, you don't have to store individual bits in an array
1866 (which would mean that you're wasting a lot of space). To convert an
1867 array of bits to a string, use C<vec()> to set the right bits. This
1868 sets C<$vec> to have bit N set only if C<$ints[N]> was set:
1870 @ints = (...); # array of bits, e.g. ( 1, 0, 0, 1, 1, 0 ... )
1872 foreach( 0 .. $#ints ) {
1873 vec($vec,$_,1) = 1 if $ints[$_];
1876 The string C<$vec> only takes up as many bits as it needs. For
1877 instance, if you had 16 entries in C<@ints>, C<$vec> only needs two
1878 bytes to store them (not counting the scalar variable overhead).
1880 Here's how, given a vector in C<$vec>, you can get those bits into
1881 your C<@ints> array:
1883 sub bitvec_to_list {
1886 # Find null-byte density then select best algorithm
1887 if ($vec =~ tr/\0// / length $vec > 0.95) {
1891 # This method is faster with mostly null-bytes
1892 while($vec =~ /[^\0]/g ) {
1893 $i = -9 + 8 * pos $vec;
1894 push @ints, $i if vec($vec, ++$i, 1);
1895 push @ints, $i if vec($vec, ++$i, 1);
1896 push @ints, $i if vec($vec, ++$i, 1);
1897 push @ints, $i if vec($vec, ++$i, 1);
1898 push @ints, $i if vec($vec, ++$i, 1);
1899 push @ints, $i if vec($vec, ++$i, 1);
1900 push @ints, $i if vec($vec, ++$i, 1);
1901 push @ints, $i if vec($vec, ++$i, 1);
1905 # This method is a fast general algorithm
1907 my $bits = unpack "b*", $vec;
1908 push @ints, 0 if $bits =~ s/^(\d)// && $1;
1909 push @ints, pos $bits while($bits =~ /1/g);
1915 This method gets faster the more sparse the bit vector is.
1916 (Courtesy of Tim Bunce and Winfried Koenig.)
1918 You can make the while loop a lot shorter with this suggestion
1919 from Benjamin Goldberg:
1921 while($vec =~ /[^\0]+/g ) {
1922 push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1925 Or use the CPAN module C<Bit::Vector>:
1927 $vector = Bit::Vector->new($num_of_bits);
1928 $vector->Index_List_Store(@ints);
1929 @ints = $vector->Index_List_Read();
1931 C<Bit::Vector> provides efficient methods for bit vector, sets of
1932 small integers and "big int" math.
1934 Here's a more extensive illustration using vec():
1937 $vector = "\xff\x0f\xef\xfe";
1938 print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1939 unpack("N", $vector), "\n";
1940 $is_set = vec($vector, 23, 1);
1941 print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1959 my ($offset, $width, $value) = @_;
1961 vec($vector, $offset, $width) = $value;
1962 print "offset=$offset width=$width value=$value\n";
1968 my $bits = unpack("b*", $vector);
1972 print "vector length in bytes: ", length($vector), "\n";
1973 @bytes = unpack("A8" x length($vector), $bits);
1974 print "bits are: @bytes\n\n";
1977 =head2 Why does defined() return true on empty arrays and hashes?
1979 The short story is that you should probably only use defined on scalars or
1980 functions, not on aggregates (arrays and hashes). See L<perlfunc/defined>
1981 in the 5.004 release or later of Perl for more detail.
1983 =head1 Data: Hashes (Associative Arrays)
1985 =head2 How do I process an entire hash?
1987 (contributed by brian d foy)
1989 There are a couple of ways that you can process an entire hash. You
1990 can get a list of keys, then go through each key, or grab a one
1991 key-value pair at a time.
1993 To go through all of the keys, use the C<keys> function. This extracts
1994 all of the keys of the hash and gives them back to you as a list. You
1995 can then get the value through the particular key you're processing:
1997 foreach my $key ( keys %hash ) {
1998 my $value = $hash{$key}
2002 Once you have the list of keys, you can process that list before you
2003 process the hash elements. For instance, you can sort the keys so you
2004 can process them in lexical order:
2006 foreach my $key ( sort keys %hash ) {
2007 my $value = $hash{$key}
2011 Or, you might want to only process some of the items. If you only want
2012 to deal with the keys that start with C<text:>, you can select just
2013 those using C<grep>:
2015 foreach my $key ( grep /^text:/, keys %hash ) {
2016 my $value = $hash{$key}
2020 If the hash is very large, you might not want to create a long list of
2021 keys. To save some memory, you can grab one key-value pair at a time using
2022 C<each()>, which returns a pair you haven't seen yet:
2024 while( my( $key, $value ) = each( %hash ) ) {
2028 The C<each> operator returns the pairs in apparently random order, so if
2029 ordering matters to you, you'll have to stick with the C<keys> method.
2031 The C<each()> operator can be a bit tricky though. You can't add or
2032 delete keys of the hash while you're using it without possibly
2033 skipping or re-processing some pairs after Perl internally rehashes
2034 all of the elements. Additionally, a hash has only one iterator, so if
2035 you use C<keys>, C<values>, or C<each> on the same hash, you can reset
2036 the iterator and mess up your processing. See the C<each> entry in
2037 L<perlfunc> for more details.
2039 =head2 How do I merge two hashes?
2040 X<hash> X<merge> X<slice, hash>
2042 (contributed by brian d foy)
2044 Before you decide to merge two hashes, you have to decide what to do
2045 if both hashes contain keys that are the same and if you want to leave
2046 the original hashes as they were.
2048 If you want to preserve the original hashes, copy one hash (C<%hash1>)
2049 to a new hash (C<%new_hash>), then add the keys from the other hash
2050 (C<%hash2> to the new hash. Checking that the key already exists in
2051 C<%new_hash> gives you a chance to decide what to do with the
2054 my %new_hash = %hash1; # make a copy; leave %hash1 alone
2056 foreach my $key2 ( keys %hash2 )
2058 if( exists $new_hash{$key2} )
2060 warn "Key [$key2] is in both hashes!";
2061 # handle the duplicate (perhaps only warning)
2067 $new_hash{$key2} = $hash2{$key2};
2071 If you don't want to create a new hash, you can still use this looping
2072 technique; just change the C<%new_hash> to C<%hash1>.
2074 foreach my $key2 ( keys %hash2 )
2076 if( exists $hash1{$key2} )
2078 warn "Key [$key2] is in both hashes!";
2079 # handle the duplicate (perhaps only warning)
2085 $hash1{$key2} = $hash2{$key2};
2089 If you don't care that one hash overwrites keys and values from the other, you
2090 could just use a hash slice to add one hash to another. In this case, values
2091 from C<%hash2> replace values from C<%hash1> when they have keys in common:
2093 @hash1{ keys %hash2 } = values %hash2;
2095 =head2 What happens if I add or remove keys from a hash while iterating over it?
2097 (contributed by brian d foy)
2099 The easy answer is "Don't do that!"
2101 If you iterate through the hash with each(), you can delete the key
2102 most recently returned without worrying about it. If you delete or add
2103 other keys, the iterator may skip or double up on them since perl
2104 may rearrange the hash table. See the
2105 entry for C<each()> in L<perlfunc>.
2107 =head2 How do I look up a hash element by value?
2109 Create a reverse hash:
2111 %by_value = reverse %by_key;
2112 $key = $by_value{$value};
2114 That's not particularly efficient. It would be more space-efficient
2117 while (($key, $value) = each %by_key) {
2118 $by_value{$value} = $key;
2121 If your hash could have repeated values, the methods above will only find
2122 one of the associated keys. This may or may not worry you. If it does
2123 worry you, you can always reverse the hash into a hash of arrays instead:
2125 while (($key, $value) = each %by_key) {
2126 push @{$key_list_by_value{$value}}, $key;
2129 =head2 How can I know how many entries are in a hash?
2131 (contributed by brian d foy)
2133 This is very similar to "How do I process an entire hash?", also in
2134 L<perlfaq4>, but a bit simpler in the common cases.
2136 You can use the C<keys()> built-in function in scalar context to find out
2137 have many entries you have in a hash:
2139 my $key_count = keys %hash; # must be scalar context!
2141 If you want to find out how many entries have a defined value, that's
2142 a bit different. You have to check each value. A C<grep> is handy:
2144 my $defined_value_count = grep { defined } values %hash;
2146 You can use that same structure to count the entries any way that
2147 you like. If you want the count of the keys with vowels in them,
2148 you just test for that instead:
2150 my $vowel_count = grep { /[aeiou]/ } keys %hash;
2152 The C<grep> in scalar context returns the count. If you want the list
2153 of matching items, just use it in list context instead:
2155 my @defined_values = grep { defined } values %hash;
2157 The C<keys()> function also resets the iterator, which means that you may
2158 see strange results if you use this between uses of other hash operators
2161 =head2 How do I sort a hash (optionally by value instead of key)?
2163 (contributed by brian d foy)
2165 To sort a hash, start with the keys. In this example, we give the list of
2166 keys to the sort function which then compares them ASCIIbetically (which
2167 might be affected by your locale settings). The output list has the keys
2168 in ASCIIbetical order. Once we have the keys, we can go through them to
2169 create a report which lists the keys in ASCIIbetical order.
2171 my @keys = sort { $a cmp $b } keys %hash;
2173 foreach my $key ( @keys )
2175 printf "%-20s %6d\n", $key, $hash{$key};
2178 We could get more fancy in the C<sort()> block though. Instead of
2179 comparing the keys, we can compute a value with them and use that
2180 value as the comparison.
2182 For instance, to make our report order case-insensitive, we use
2183 the C<\L> sequence in a double-quoted string to make everything
2184 lowercase. The C<sort()> block then compares the lowercased
2185 values to determine in which order to put the keys.
2187 my @keys = sort { "\L$a" cmp "\L$b" } keys %hash;
2189 Note: if the computation is expensive or the hash has many elements,
2190 you may want to look at the Schwartzian Transform to cache the
2191 computation results.
2193 If we want to sort by the hash value instead, we use the hash key
2194 to look it up. We still get out a list of keys, but this time they
2195 are ordered by their value.
2197 my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash;
2199 From there we can get more complex. If the hash values are the same,
2200 we can provide a secondary sort on the hash key.
2203 $hash{$a} <=> $hash{$b}
2208 =head2 How can I always keep my hash sorted?
2209 X<hash tie sort DB_File Tie::IxHash>
2211 You can look into using the C<DB_File> module and C<tie()> using the
2212 C<$DB_BTREE> hash bindings as documented in L<DB_File/"In Memory
2213 Databases">. The C<Tie::IxHash> module from CPAN might also be
2214 instructive. Although this does keep your hash sorted, you might not
2215 like the slow down you suffer from the tie interface. Are you sure you
2218 =head2 What's the difference between "delete" and "undef" with hashes?
2220 Hashes contain pairs of scalars: the first is the key, the
2221 second is the value. The key will be coerced to a string,
2222 although the value can be any kind of scalar: string,
2223 number, or reference. If a key C<$key> is present in
2224 %hash, C<exists($hash{$key})> will return true. The value
2225 for a given key can be C<undef>, in which case
2226 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
2227 will return true. This corresponds to (C<$key>, C<undef>)
2230 Pictures help... Here's the C<%hash> table:
2240 And these conditions hold
2244 defined $hash{'d'} is true
2245 defined $hash{'a'} is true
2246 exists $hash{'a'} is true (Perl 5 only)
2247 grep ($_ eq 'a', keys %hash) is true
2253 your table now reads:
2264 and these conditions now hold; changes in caps:
2268 defined $hash{'d'} is true
2269 defined $hash{'a'} is FALSE
2270 exists $hash{'a'} is true (Perl 5 only)
2271 grep ($_ eq 'a', keys %hash) is true
2273 Notice the last two: you have an undef value, but a defined key!
2279 your table now reads:
2288 and these conditions now hold; changes in caps:
2292 defined $hash{'d'} is true
2293 defined $hash{'a'} is false
2294 exists $hash{'a'} is FALSE (Perl 5 only)
2295 grep ($_ eq 'a', keys %hash) is FALSE
2297 See, the whole entry is gone!
2299 =head2 Why don't my tied hashes make the defined/exists distinction?
2301 This depends on the tied hash's implementation of EXISTS().
2302 For example, there isn't the concept of undef with hashes
2303 that are tied to DBM* files. It also means that exists() and
2304 defined() do the same thing with a DBM* file, and what they
2305 end up doing is not what they do with ordinary hashes.
2307 =head2 How do I reset an each() operation part-way through?
2309 (contributed by brian d foy)
2311 You can use the C<keys> or C<values> functions to reset C<each>. To
2312 simply reset the iterator used by C<each> without doing anything else,
2313 use one of them in void context:
2315 keys %hash; # resets iterator, nothing else.
2316 values %hash; # resets iterator, nothing else.
2318 See the documentation for C<each> in L<perlfunc>.
2320 =head2 How can I get the unique keys from two hashes?
2322 First you extract the keys from the hashes into lists, then solve
2323 the "removing duplicates" problem described above. For example:
2326 for $element (keys(%foo), keys(%bar)) {
2333 @uniq = keys %{{%foo,%bar}};
2335 Or if you really want to save space:
2338 while (defined ($key = each %foo)) {
2341 while (defined ($key = each %bar)) {
2346 =head2 How can I store a multidimensional array in a DBM file?
2348 Either stringify the structure yourself (no fun), or else
2349 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
2350 it on top of either DB_File or GDBM_File.
2352 =head2 How can I make my hash remember the order I put elements into it?
2354 Use the C<Tie::IxHash> from CPAN.
2358 tie my %myhash, 'Tie::IxHash';
2360 for (my $i=0; $i<20; $i++) {
2364 my @keys = keys %myhash;
2365 # @keys = (0,1,2,3,...)
2367 =head2 Why does passing a subroutine an undefined element in a hash create it?
2369 (contributed by brian d foy)
2371 Are you using a really old version of Perl?
2373 Normally, accessing a hash key's value for a nonexistent key will
2374 I<not> create the key.
2377 my $value = $hash{ 'foo' };
2378 print "This won't print\n" if exists $hash{ 'foo' };
2380 Passing C<$hash{ 'foo' }> to a subroutine used to be a special case, though.
2381 Since you could assign directly to C<$_[0]>, Perl had to be ready to
2382 make that assignment so it created the hash key ahead of time:
2384 my_sub( $hash{ 'foo' } );
2385 print "This will print before 5.004\n" if exists $hash{ 'foo' };
2388 # $_[0] = 'bar'; # create hash key in case you do this
2392 Since Perl 5.004, however, this situation is a special case and Perl
2393 creates the hash key only when you make the assignment:
2395 my_sub( $hash{ 'foo' } );
2396 print "This will print, even after 5.004\n" if exists $hash{ 'foo' };
2402 However, if you want the old behavior (and think carefully about that
2403 because it's a weird side effect), you can pass a hash slice instead.
2404 Perl 5.004 didn't make this a special case:
2406 my_sub( @hash{ qw/foo/ } );
2408 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
2410 Usually a hash ref, perhaps like this:
2415 TITLE => "deputy peon",
2418 PALS => [ "Norbert", "Rhys", "Phineas"],
2421 References are documented in L<perlref> and the upcoming L<perlreftut>.
2422 Examples of complex data structures are given in L<perldsc> and
2423 L<perllol>. Examples of structures and object-oriented classes are
2426 =head2 How can I use a reference as a hash key?
2428 (contributed by brian d foy and Ben Morrow)
2430 Hash keys are strings, so you can't really use a reference as the key.
2431 When you try to do that, perl turns the reference into its stringified
2432 form (for instance, C<HASH(0xDEADBEEF)>). From there you can't get
2433 back the reference from the stringified form, at least without doing
2434 some extra work on your own.
2436 Remember that the entry in the hash will still be there even if
2437 the referenced variable goes out of scope, and that it is entirely
2438 possible for Perl to subsequently allocate a different variable at
2439 the same address. This will mean a new variable might accidentally
2440 be associated with the value for an old.
2442 If you have Perl 5.10 or later, and you just want to store a value
2443 against the reference for lookup later, you can use the core
2444 Hash::Util::Fieldhash module. This will also handle renaming the
2445 keys if you use multiple threads (which causes all variables to be
2446 reallocated at new addresses, changing their stringification), and
2447 garbage-collecting the entries when the referenced variable goes out
2450 If you actually need to be able to get a real reference back from
2451 each hash entry, you can use the Tie::RefHash module, which does the
2452 required work for you.
2456 =head2 How do I handle binary data correctly?
2458 Perl is binary clean, so it can handle binary data just fine.
2459 On Windows or DOS, however, you have to use C<binmode> for binary
2460 files to avoid conversions for line endings. In general, you should
2461 use C<binmode> any time you want to work with binary data.
2463 Also see L<perlfunc/"binmode"> or L<perlopentut>.
2465 If you're concerned about 8-bit textual data then see L<perllocale>.
2466 If you want to deal with multibyte characters, however, there are
2467 some gotchas. See the section on Regular Expressions.
2469 =head2 How do I determine whether a scalar is a number/whole/integer/float?
2471 Assuming that you don't care about IEEE notations like "NaN" or
2472 "Infinity", you probably just want to use a regular expression.
2474 if (/\D/) { print "has nondigits\n" }
2475 if (/^\d+$/) { print "is a whole number\n" }
2476 if (/^-?\d+$/) { print "is an integer\n" }
2477 if (/^[+-]?\d+$/) { print "is a +/- integer\n" }
2478 if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
2479 if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
2480 if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
2481 { print "a C float\n" }
2483 There are also some commonly used modules for the task.
2484 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2485 internal function C<looks_like_number> for determining whether a
2486 variable looks like a number. L<Data::Types> exports functions that
2487 validate data types using both the above and other regular
2488 expressions. Thirdly, there is C<Regexp::Common> which has regular
2489 expressions to match various types of numbers. Those three modules are
2490 available from the CPAN.
2492 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2493 function. Its semantics are somewhat cumbersome, so here's a
2494 C<getnum> wrapper function for more convenient access. This function
2495 takes a string and returns the number it found, or C<undef> for input
2496 that isn't a C float. The C<is_numeric> function is a front end to
2497 C<getnum> if you just want to say, "Is this a float?"
2500 use POSIX qw(strtod);
2505 my($num, $unparsed) = strtod($str);
2506 if (($str eq '') || ($unparsed != 0) || $!) {
2514 sub is_numeric { defined getnum($_[0]) }
2516 Or you could check out the L<String::Scanf> module on the CPAN
2517 instead. The C<POSIX> module (part of the standard Perl distribution)
2518 provides the C<strtod> and C<strtol> for converting strings to double
2519 and longs, respectively.
2521 =head2 How do I keep persistent data across program calls?
2523 For some specific applications, you can use one of the DBM modules.
2524 See L<AnyDBM_File>. More generically, you should consult the C<FreezeThaw>
2525 or C<Storable> modules from CPAN. Starting from Perl 5.8 C<Storable> is part
2526 of the standard distribution. Here's one example using C<Storable>'s C<store>
2527 and C<retrieve> functions:
2530 store(\%hash, "filename");
2533 $href = retrieve("filename"); # by ref
2534 %hash = %{ retrieve("filename") }; # direct to hash
2536 =head2 How do I print out or copy a recursive data structure?
2538 The C<Data::Dumper> module on CPAN (or the 5.005 release of Perl) is great
2539 for printing out data structures. The C<Storable> module on CPAN (or the
2540 5.8 release of Perl), provides a function called C<dclone> that recursively
2541 copies its argument.
2543 use Storable qw(dclone);
2546 Where C<$r1> can be a reference to any kind of data structure you'd like.
2547 It will be deeply copied. Because C<dclone> takes and returns references,
2548 you'd have to add extra punctuation if you had a hash of arrays that
2551 %newhash = %{ dclone(\%oldhash) };
2553 =head2 How do I define methods for every class/object?
2555 (contributed by Ben Morrow)
2557 You can use the C<UNIVERSAL> class (see L<UNIVERSAL>). However, please
2558 be very careful to consider the consequences of doing this: adding
2559 methods to every object is very likely to have unintended
2560 consequences. If possible, it would be better to have all your object
2561 inherit from some common base class, or to use an object system like
2562 Moose that supports roles.
2564 =head2 How do I verify a credit card checksum?
2566 Get the C<Business::CreditCard> module from CPAN.
2568 =head2 How do I pack arrays of doubles or floats for XS code?
2570 The arrays.h/arrays.c code in the C<PGPLOT> module on CPAN does just this.
2571 If you're doing a lot of float or double processing, consider using
2572 the C<PDL> module from CPAN instead--it makes number-crunching easy.
2574 See L<http://search.cpan.org/dist/PGPLOT> for the code.
2576 =head1 AUTHOR AND COPYRIGHT
2578 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
2579 other authors as noted. All rights reserved.
2581 This documentation is free; you can redistribute it and/or modify it
2582 under the same terms as Perl itself.
2584 Irrespective of its distribution, all code examples in this file
2585 are hereby placed into the public domain. You are permitted and
2586 encouraged to use this code in your own programs for fun
2587 or for profit as you see fit. A simple comment in the code giving
2588 credit would be courteous but is not required.