3 perldata - Perl data types
9 Perl has three built-in data types: scalars, arrays of scalars, and
10 associative arrays of scalars, known as "hashes". Normal arrays
11 are ordered lists of scalars indexed by number, starting with 0 and with
12 negative subscripts counting from the end. Hashes are unordered
13 collections of scalar values indexed by their associated string key.
15 Values are usually referred to by name, or through a named reference.
16 The first character of the name tells you to what sort of data
17 structure it refers. The rest of the name tells you the particular
18 value to which it refers. Usually this name is a single I<identifier>,
19 that is, a string beginning with a letter or underscore, and
20 containing letters, underscores, and digits. In some cases, it may
21 be a chain of identifiers, separated by C<::> (or by the slightly
22 archaic C<'>); all but the last are interpreted as names of packages,
23 to locate the namespace in which to look up the final identifier
24 (see L<perlmod/Packages> for details). It's possible to substitute
25 for a simple identifier, an expression that produces a reference
26 to the value at runtime. This is described in more detail below
29 Perl also has its own built-in variables whose names don't follow
30 these rules. They have strange names so they don't accidentally
31 collide with one of your normal variables. Strings that match
32 parenthesized parts of a regular expression are saved under names
33 containing only digits after the C<$> (see L<perlop> and L<perlre>).
34 In addition, several special variables that provide windows into
35 the inner working of Perl have names containing punctuation characters
36 and control characters. These are documented in L<perlvar>.
38 Scalar values are always named with '$', even when referring to a
39 scalar that is part of an array or a hash. The '$' symbol works
40 semantically like the English word "the" in that it indicates a
41 single value is expected.
43 $days # the simple scalar value "days"
44 $days[28] # the 29th element of array @days
45 $days{'Feb'} # the 'Feb' value from hash %days
46 $#days # the last index of array @days
48 Entire arrays (and slices of arrays and hashes) are denoted by '@',
49 which works much like the word "these" or "those" does in English,
50 in that it indicates multiple values are expected.
52 @days # ($days[0], $days[1],... $days[n])
53 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
54 @days{'a','c'} # same as ($days{'a'},$days{'c'})
56 Entire hashes are denoted by '%':
58 %days # (key1, val1, key2, val2 ...)
60 In addition, subroutines are named with an initial '&', though this
61 is optional when unambiguous, just as the word "do" is often redundant
62 in English. Symbol table entries can be named with an initial '*',
63 but you don't really care about that yet (if ever :-).
65 Every variable type has its own namespace, as do several
66 non-variable identifiers. This means that you can, without fear
67 of conflict, use the same name for a scalar variable, an array, or
68 a hash--or, for that matter, for a filehandle, a directory handle, a
69 subroutine name, a format name, or a label. This means that $foo
70 and @foo are two different variables. It also means that C<$foo[1]>
71 is a part of @foo, not a part of $foo. This may seem a bit weird,
72 but that's okay, because it is weird.
74 Because variable references always start with '$', '@', or '%', the
75 "reserved" words aren't in fact reserved with respect to variable
76 names. They I<are> reserved with respect to labels and filehandles,
77 however, which don't have an initial special character. You can't
78 have a filehandle named "log", for instance. Hint: you could say
79 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
80 uppercase filehandles also improves readability and protects you
81 from conflict with future reserved words. Case I<is> significant--"FOO",
82 "Foo", and "foo" are all different names. Names that start with a
83 letter or underscore may also contain digits and underscores.
85 It is possible to replace such an alphanumeric name with an expression
86 that returns a reference to the appropriate type. For a description
87 of this, see L<perlref>.
89 Names that start with a digit may contain only more digits. Names
90 that do not start with a letter, underscore, or digit are limited to
91 one character, e.g., C<$%> or C<$$>. (Most of these one character names
92 have a predefined significance to Perl. For instance, C<$$> is the
97 The interpretation of operations and values in Perl sometimes depends
98 on the requirements of the context around the operation or value.
99 There are two major contexts: list and scalar. Certain operations
100 return list values in contexts wanting a list, and scalar values
101 otherwise. If this is true of an operation it will be mentioned in
102 the documentation for that operation. In other words, Perl overloads
103 certain operations based on whether the expected return value is
104 singular or plural. Some words in English work this way, like "fish"
107 In a reciprocal fashion, an operation provides either a scalar or a
108 list context to each of its arguments. For example, if you say
112 the integer operation provides scalar context for the <>
113 operator, which responds by reading one line from STDIN and passing it
114 back to the integer operation, which will then find the integer value
115 of that line and return that. If, on the other hand, you say
119 then the sort operation provides list context for <>, which
120 will proceed to read every line available up to the end of file, and
121 pass that list of lines back to the sort routine, which will then
122 sort those lines and return them as a list to whatever the context
125 Assignment is a little bit special in that it uses its left argument
126 to determine the context for the right argument. Assignment to a
127 scalar evaluates the right-hand side in scalar context, while
128 assignment to an array or hash evaluates the righthand side in list
129 context. Assignment to a list (or slice, which is just a list
130 anyway) also evaluates the righthand side in list context.
132 When you use the C<use warnings> pragma or Perl's B<-w> command-line
133 option, you may see warnings
134 about useless uses of constants or functions in "void context".
135 Void context just means the value has been discarded, such as a
136 statement containing only C<"fred";> or C<getpwuid(0);>. It still
137 counts as scalar context for functions that care whether or not
138 they're being called in list context.
140 User-defined subroutines may choose to care whether they are being
141 called in a void, scalar, or list context. Most subroutines do not
142 need to bother, though. That's because both scalars and lists are
143 automatically interpolated into lists. See L<perlfunc/wantarray>
144 for how you would dynamically discern your function's calling
149 All data in Perl is a scalar, an array of scalars, or a hash of
150 scalars. A scalar may contain one single value in any of three
151 different flavors: a number, a string, or a reference. In general,
152 conversion from one form to another is transparent. Although a
153 scalar may not directly hold multiple values, it may contain a
154 reference to an array or hash which in turn contains multiple values.
156 Scalars aren't necessarily one thing or another. There's no place
157 to declare a scalar variable to be of type "string", type "number",
158 type "reference", or anything else. Because of the automatic
159 conversion of scalars, operations that return scalars don't need
160 to care (and in fact, cannot care) whether their caller is looking
161 for a string, a number, or a reference. Perl is a contextually
162 polymorphic language whose scalars can be strings, numbers, or
163 references (which includes objects). Although strings and numbers
164 are considered pretty much the same thing for nearly all purposes,
165 references are strongly-typed, uncastable pointers with builtin
166 reference-counting and destructor invocation.
168 A scalar value is interpreted as TRUE in the Boolean sense if it is not
169 the null string or the number 0 (or its string equivalent, "0"). The
170 Boolean context is just a special kind of scalar context where no
171 conversion to a string or a number is ever performed.
173 There are actually two varieties of null strings (sometimes referred
174 to as "empty" strings), a defined one and an undefined one. The
175 defined version is just a string of length zero, such as C<"">.
176 The undefined version is the value that indicates that there is
177 no real value for something, such as when there was an error, or
178 at end of file, or when you refer to an uninitialized variable or
179 element of an array or hash. Although in early versions of Perl,
180 an undefined scalar could become defined when first used in a
181 place expecting a defined value, this no longer happens except for
182 rare cases of autovivification as explained in L<perlref>. You can
183 use the defined() operator to determine whether a scalar value is
184 defined (this has no meaning on arrays or hashes), and the undef()
185 operator to produce an undefined value.
187 To find out whether a given string is a valid non-zero number, it's
188 sometimes enough to test it against both numeric 0 and also lexical
189 "0" (although this will cause B<-w> noises). That's because strings
190 that aren't numbers count as 0, just as they do in B<awk>:
192 if ($str == 0 && $str ne "0") {
193 warn "That doesn't look like a number";
196 That method may be best because otherwise you won't treat IEEE
197 notations like C<NaN> or C<Infinity> properly. At other times, you
198 might prefer to determine whether string data can be used numerically
199 by calling the POSIX::strtod() function or by inspecting your string
200 with a regular expression (as documented in L<perlre>).
202 warn "has nondigits" if /\D/;
203 warn "not a natural number" unless /^\d+$/; # rejects -3
204 warn "not an integer" unless /^-?\d+$/; # rejects +3
205 warn "not an integer" unless /^[+-]?\d+$/;
206 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
207 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
209 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
211 The length of an array is a scalar value. You may find the length
212 of array @days by evaluating C<$#days>, as in B<csh>. However, this
213 isn't the length of the array; it's the subscript of the last element,
214 which is a different value since there is ordinarily a 0th element.
215 Assigning to C<$#days> actually changes the length of the array.
216 Shortening an array this way destroys intervening values. Lengthening
217 an array that was previously shortened does not recover values
218 that were in those elements. (It used to do so in Perl 4, but we
219 had to break this to make sure destructors were called when expected.)
221 You can also gain some miniscule measure of efficiency by pre-extending
222 an array that is going to get big. You can also extend an array
223 by assigning to an element that is off the end of the array. You
224 can truncate an array down to nothing by assigning the null list
225 () to it. The following are equivalent:
230 If you evaluate an array in scalar context, it returns the length
231 of the array. (Note that this is not true of lists, which return
232 the last value, like the C comma operator, nor of built-in functions,
233 which return whatever they feel like returning.) The following is
236 scalar(@whatever) == $#whatever - $[ + 1;
238 Version 5 of Perl changed the semantics of C<$[>: files that don't set
239 the value of C<$[> no longer need to worry about whether another
240 file changed its value. (In other words, use of C<$[> is deprecated.)
241 So in general you can assume that
243 scalar(@whatever) == $#whatever + 1;
245 Some programmers choose to use an explicit conversion so as to
246 leave nothing to doubt:
248 $element_count = scalar(@whatever);
250 If you evaluate a hash in scalar context, it returns false if the
251 hash is empty. If there are any key/value pairs, it returns true;
252 more precisely, the value returned is a string consisting of the
253 number of used buckets and the number of allocated buckets, separated
254 by a slash. This is pretty much useful only to find out whether
255 Perl's internal hashing algorithm is performing poorly on your data
256 set. For example, you stick 10,000 things in a hash, but evaluating
257 %HASH in scalar context reveals C<"1/16">, which means only one out
258 of sixteen buckets has been touched, and presumably contains all
259 10,000 of your items. This isn't supposed to happen.
261 You can preallocate space for a hash by assigning to the keys() function.
262 This rounds up the allocated buckets to the next power of two:
264 keys(%users) = 1000; # allocate 1024 buckets
266 =head2 Scalar value constructors
268 Numeric literals are specified in any of the following floating point or
273 .23E-10 # a very small number
274 3.14_15_92 # a very important number
275 4_294_967_296 # underscore for legibility
277 0xdead_beef # more hex
281 You are allowed to use underscores (underbars) in numeric literals for
282 legibility, as long as the underscores are spaced at least one digit
283 apart, and they do not begin or end the integer or fractional part.
284 You could, for example, group binary digits by threes (as for
285 a Unix-style mode argument such as 0b110_100_100) or by fours
286 (to represent nibbles, as in 0b1010_0110) or in other groups.
288 (Note that if you try to begin a number with an underscore, it won't
289 even be understood as a number, it will be understood as a bareword,
290 which depending on the context may mean for example a string constant,
291 a function call, or a filehandle.)
293 String literals are usually delimited by either single or double
294 quotes. They work much like quotes in the standard Unix shells:
295 double-quoted string literals are subject to backslash and variable
296 substitution; single-quoted strings are not (except for C<\'> and
297 C<\\>). The usual C-style backslash rules apply for making
298 characters such as newline, tab, etc., as well as some more exotic
299 forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
301 Hexadecimal, octal, or binary, representations in string literals
302 (e.g. '0xff') are not automatically converted to their integer
303 representation. The hex() and oct() functions make these conversions
304 for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
306 You can also embed newlines directly in your strings, i.e., they can end
307 on a different line than they begin. This is nice, but if you forget
308 your trailing quote, the error will not be reported until Perl finds
309 another line containing the quote character, which may be much further
310 on in the script. Variable substitution inside strings is limited to
311 scalar variables, arrays, and array or hash slices. (In other words,
312 names beginning with $ or @, followed by an optional bracketed
313 expression as a subscript.) The following code segment prints out "The
316 $Price = '$100'; # not interpreted
317 print "The price is $Price.\n"; # interpreted
319 As in some shells, you can enclose the variable name in braces to
320 disambiguate it from following alphanumerics (and underscores).
322 this when interpolating a variable into a string to separate the
323 variable name from a following double-colon or an apostrophe, since
324 these would be otherwise treated as a package separator:
327 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
328 print "We use ${who}speak when ${who}'s here.\n";
330 Without the braces, Perl would have looked for a $whospeak, a
331 C<$who::0>, and a C<$who's> variable. The last two would be the
332 $0 and the $s variables in the (presumably) non-existent package
335 In fact, an identifier within such curlies is forced to be a string,
336 as is any simple identifier within a hash subscript. Neither need
337 quoting. Our earlier example, C<$days{'Feb'}> can be written as
338 C<$days{Feb}> and the quotes will be assumed automatically. But
339 anything more complicated in the subscript will be interpreted as
342 A literal of the form C<v1.20.300.4000> is parsed as a string composed
343 of characters with the specified ordinals. This provides an alternative,
344 more readable way to construct strings, rather than use the somewhat less
345 readable interpolation form C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful
346 for representing Unicode strings, and for comparing version "numbers"
347 using the string comparison operators, C<cmp>, C<gt>, C<lt> etc.
348 If there are two or more dots in the literal, the leading C<v> may be
351 print v9786; # prints UTF-8 encoded SMILEY, "\x{263a}"
352 print v102.111.111; # prints "foo"
353 print 102.111.111; # same
355 Such literals are accepted by both C<require> and C<use> for
356 doing a version check. The C<$^V> special variable also contains the
357 running Perl interpreter's version in this form. See L<perlvar/$^V>.
359 The special literals __FILE__, __LINE__, and __PACKAGE__
360 represent the current filename, line number, and package name at that
361 point in your program. They may be used only as separate tokens; they
362 will not be interpolated into strings. If there is no current package
363 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
366 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
367 may be used to indicate the logical end of the script before the actual
368 end of file. Any following text is ignored.
370 Text after __DATA__ but may be read via the filehandle C<PACKNAME::DATA>,
371 where C<PACKNAME> is the package that was current when the __DATA__
372 token was encountered. The filehandle is left open pointing to the
373 contents after __DATA__. It is the program's responsibility to
374 C<close DATA> when it is done reading from it. For compatibility with
375 older scripts written before __DATA__ was introduced, __END__ behaves
376 like __DATA__ in the toplevel script (but not in files loaded with
377 C<require> or C<do>) and leaves the remaining contents of the
378 file accessible via C<main::DATA>.
380 See L<SelfLoader> for more description of __DATA__, and
381 an example of its use. Note that you cannot read from the DATA
382 filehandle in a BEGIN block: the BEGIN block is executed as soon
383 as it is seen (during compilation), at which point the corresponding
384 __DATA__ (or __END__) token has not yet been seen.
386 A word that has no other interpretation in the grammar will
387 be treated as if it were a quoted string. These are known as
388 "barewords". As with filehandles and labels, a bareword that consists
389 entirely of lowercase letters risks conflict with future reserved
390 words, and if you use the C<use warnings> pragma or the B<-w> switch,
391 Perl will warn you about any
392 such words. Some people may wish to outlaw barewords entirely. If you
397 then any bareword that would NOT be interpreted as a subroutine call
398 produces a compile-time error instead. The restriction lasts to the
399 end of the enclosing block. An inner block may countermand this
400 by saying C<no strict 'subs'>.
402 Arrays and slices are interpolated into double-quoted strings
403 by joining the elements with the delimiter specified in the C<$">
404 variable (C<$LIST_SEPARATOR> in English), space by default. The
405 following are equivalent:
407 $temp = join($", @ARGV);
412 Within search patterns (which also undergo double-quotish substitution)
413 there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
414 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
415 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
416 @foo)? If @foo doesn't otherwise exist, then it's obviously a
417 character class. If @foo exists, Perl takes a good guess about C<[bar]>,
418 and is almost always right. If it does guess wrong, or if you're just
419 plain paranoid, you can force the correct interpretation with curly
422 A line-oriented form of quoting is based on the shell "here-document"
423 syntax. Following a C<< << >> you specify a string to terminate
424 the quoted material, and all lines following the current line down to
425 the terminating string are the value of the item. The terminating
426 string may be either an identifier (a word), or some quoted text. If
427 quoted, the type of quotes you use determines the treatment of the
428 text, just as in regular quoting. An unquoted identifier works like
429 double quotes. There must be no space between the C<< << >> and
430 the identifier, unless the identifier is quoted. (If you put a space it
431 will be treated as a null identifier, which is valid, and matches the first
432 empty line.) The terminating string must appear by itself (unquoted and
433 with no surrounding whitespace) on the terminating line.
439 print << "EOF"; # same as above
443 print << `EOC`; # execute commands
448 print <<"foo", <<"bar"; # you can stack them
454 myfunc(<< "THIS", 23, <<'THAT');
461 Just don't forget that you have to put a semicolon on the end
462 to finish the statement, as Perl doesn't know you're not going to
470 If you want your here-docs to be indented with the
471 rest of the code, you'll need to remove leading whitespace
472 from each line manually:
474 ($quote = <<'FINIS') =~ s/^\s+//gm;
475 The Road goes ever on and on,
476 down from the door where it began.
479 If you use a here-doc within a delimited construct, such as in C<s///eg>,
480 the quoted material must come on the lines following the final delimiter.
495 If the terminating identifier is on the last line of the program, you
496 must be sure there is a newline after it; otherwise, Perl will give the
497 warning B<Can't find string terminator "END" anywhere before EOF...>.
499 Additionally, the quoting rules for the identifier are not related to
500 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
501 in place of C<''> and C<"">, and the only interpolation is for backslashing
502 the quoting character:
508 Finally, quoted strings cannot span multiple lines. The general rule is
509 that the identifier must be a string literal. Stick with that, and you
512 =head2 List value constructors
514 List values are denoted by separating individual values by commas
515 (and enclosing the list in parentheses where precedence requires it):
519 In a context not requiring a list value, the value of what appears
520 to be a list literal is simply the value of the final element, as
521 with the C comma operator. For example,
523 @foo = ('cc', '-E', $bar);
525 assigns the entire list value to array @foo, but
527 $foo = ('cc', '-E', $bar);
529 assigns the value of variable $bar to the scalar variable $foo.
530 Note that the value of an actual array in scalar context is the
531 length of the array; the following assigns the value 3 to $foo:
533 @foo = ('cc', '-E', $bar);
534 $foo = @foo; # $foo gets 3
536 You may have an optional comma before the closing parenthesis of a
537 list literal, so that you can say:
545 To use a here-document to assign an array, one line per element,
546 you might use an approach like this:
548 @sauces = <<End_Lines =~ m/(\S.*\S)/g;
556 LISTs do automatic interpolation of sublists. That is, when a LIST is
557 evaluated, each element of the list is evaluated in list context, and
558 the resulting list value is interpolated into LIST just as if each
559 individual element were a member of LIST. Thus arrays and hashes lose their
560 identity in a LIST--the list
562 (@foo,@bar,&SomeSub,%glarch)
564 contains all the elements of @foo followed by all the elements of @bar,
565 followed by all the elements returned by the subroutine named SomeSub
566 called in list context, followed by the key/value pairs of %glarch.
567 To make a list reference that does I<NOT> interpolate, see L<perlref>.
569 The null list is represented by (). Interpolating it in a list
570 has no effect. Thus ((),(),()) is equivalent to (). Similarly,
571 interpolating an array with no elements is the same as if no
572 array had been interpolated at that point.
574 This interpolation combines with the facts that the opening
575 and closing parentheses are optional (except necessary for
576 precedence) and lists may end with an optional comma to mean that
577 multiple commas within lists are legal syntax. The list C<1,,3> is a
578 concatenation of two lists, C<1,> and C<3>, the first of which ends
579 with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
580 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
581 we'd advise you to use this obfuscation.
583 A list value may also be subscripted like a normal array. You must
584 put the list in parentheses to avoid ambiguity. For example:
586 # Stat returns list value.
587 $time = (stat($file))[8];
590 $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
593 $hexdigit = ('a','b','c','d','e','f')[$digit-10];
595 # A "reverse comma operator".
596 return (pop(@foo),pop(@foo))[0];
598 Lists may be assigned to only when each element of the list
599 is itself legal to assign to:
601 ($a, $b, $c) = (1, 2, 3);
603 ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
605 An exception to this is that you may assign to C<undef> in a list.
606 This is useful for throwing away some of the return values of a
609 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
611 List assignment in scalar context returns the number of elements
612 produced by the expression on the right side of the assignment:
614 $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
615 $x = (($foo,$bar) = f()); # set $x to f()'s return count
617 This is handy when you want to do a list assignment in a Boolean
618 context, because most list functions return a null list when finished,
619 which when assigned produces a 0, which is interpreted as FALSE.
621 The final element may be an array or a hash:
623 ($a, $b, @rest) = split;
624 my($a, $b, %rest) = @_;
626 You can actually put an array or hash anywhere in the list, but the first one
627 in the list will soak up all the values, and anything after it will become
628 undefined. This may be useful in a my() or local().
630 A hash can be initialized using a literal list holding pairs of
631 items to be interpreted as a key and a value:
633 # same as map assignment above
634 %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
636 While literal lists and named arrays are often interchangeable, that's
637 not the case for hashes. Just because you can subscript a list value like
638 a normal array does not mean that you can subscript a list value as a
639 hash. Likewise, hashes included as parts of other lists (including
640 parameters lists and return lists from functions) always flatten out into
641 key/value pairs. That's why it's good to use references sometimes.
643 It is often more readable to use the C<< => >> operator between key/value
644 pairs. The C<< => >> operator is mostly just a more visually distinctive
645 synonym for a comma, but it also arranges for its left-hand operand to be
646 interpreted as a string--if it's a bareword that would be a legal identifier.
647 This makes it nice for initializing hashes:
655 or for initializing hash references to be used as records:
658 witch => 'Mable the Merciless',
659 cat => 'Fluffy the Ferocious',
660 date => '10/31/1776',
663 or for using call-by-named-parameter to complicated functions:
665 $field = $query->radio_group(
666 name => 'group_name',
667 values => ['eenie','meenie','minie'],
673 Note that just because a hash is initialized in that order doesn't
674 mean that it comes out in that order. See L<perlfunc/sort> for examples
675 of how to arrange for an output ordering.
679 A common way to access an array or a hash is one scalar element at a
680 time. You can also subscript a list to get a single element from it.
682 $whoami = $ENV{"USER"}; # one element from the hash
683 $parent = $ISA[0]; # one element from the array
684 $dir = (getpwnam("daemon"))[7]; # likewise, but with list
686 A slice accesses several elements of a list, an array, or a hash
687 simultaneously using a list of subscripts. It's more convenient
688 than writing out the individual elements as a list of separate
691 ($him, $her) = @folks[0,-1]; # array slice
692 @them = @folks[0 .. 3]; # array slice
693 ($who, $home) = @ENV{"USER", "HOME"}; # hash slice
694 ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
696 Since you can assign to a list of variables, you can also assign to
697 an array or hash slice.
699 @days[3..5] = qw/Wed Thu Fri/;
700 @colors{'red','blue','green'}
701 = (0xff0000, 0x0000ff, 0x00ff00);
702 @folks[0, -1] = @folks[-1, 0];
704 The previous assignments are exactly equivalent to
706 ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
707 ($colors{'red'}, $colors{'blue'}, $colors{'green'})
708 = (0xff0000, 0x0000ff, 0x00ff00);
709 ($folks[0], $folks[-1]) = ($folks[0], $folks[-1]);
711 Since changing a slice changes the original array or hash that it's
712 slicing, a C<foreach> construct will alter some--or even all--of the
713 values of the array or hash.
715 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
717 foreach (@hash{keys %hash}) {
718 s/^\s+//; # trim leading whitespace
719 s/\s+$//; # trim trailing whitespace
720 s/(\w+)/\u\L$1/g; # "titlecase" words
723 A slice of an empty list is still an empty list. Thus:
725 @a = ()[1,0]; # @a has no elements
726 @b = (@a)[0,1]; # @b has no elements
727 @c = (0,1)[2,3]; # @c has no elements
731 @a = (1)[1,0]; # @a has two elements
732 @b = (1,undef)[1,0,2]; # @b has three elements
734 This makes it easy to write loops that terminate when a null list
737 while ( ($home, $user) = (getpwent)[7,0]) {
738 printf "%-8s %s\n", $user, $home;
741 As noted earlier in this document, the scalar sense of list assignment
742 is the number of elements on the right-hand side of the assignment.
743 The null list contains no elements, so when the password file is
744 exhausted, the result is 0, not 2.
746 If you're confused about why you use an '@' there on a hash slice
747 instead of a '%', think of it like this. The type of bracket (square
748 or curly) governs whether it's an array or a hash being looked at.
749 On the other hand, the leading symbol ('$' or '@') on the array or
750 hash indicates whether you are getting back a singular value (a
751 scalar) or a plural one (a list).
753 =head2 Typeglobs and Filehandles
755 Perl uses an internal type called a I<typeglob> to hold an entire
756 symbol table entry. The type prefix of a typeglob is a C<*>, because
757 it represents all types. This used to be the preferred way to
758 pass arrays and hashes by reference into a function, but now that
759 we have real references, this is seldom needed.
761 The main use of typeglobs in modern Perl is create symbol table aliases.
766 makes $this an alias for $that, @this an alias for @that, %this an alias
767 for %that, &this an alias for &that, etc. Much safer is to use a reference.
770 local *Here::blue = \$There::green;
772 temporarily makes $Here::blue an alias for $There::green, but doesn't
773 make @Here::blue an alias for @There::green, or %Here::blue an alias for
774 %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
775 of this. Strange though this may seem, this is the basis for the whole
776 module import/export system.
778 Another use for typeglobs is to pass filehandles into a function or
779 to create new filehandles. If you need to use a typeglob to save away
780 a filehandle, do it this way:
784 or perhaps as a real reference, like this:
788 See L<perlsub> for examples of using these as indirect filehandles
791 Typeglobs are also a way to create a local filehandle using the local()
792 operator. These last until their block is exited, but may be passed back.
798 open (FH, $path) or return undef;
801 $fh = newopen('/etc/passwd');
803 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
804 for filehandle manipulations, although they're still needed to pass brand
805 new file and directory handles into or out of functions. That's because
806 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
807 In other words, C<*FH> must be used to create new symbol table entries;
808 C<*foo{THING}> cannot. When in doubt, use C<*FH>.
810 All functions that are capable of creating filehandles (open(),
811 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
812 automatically create an anonymous filehandle if the handle passed to
813 them is an uninitialized scalar variable. This allows the constructs
814 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
815 create filehandles that will conveniently be closed automatically when
816 the scope ends, provided there are no other references to them. This
817 largely eliminates the need for typeglobs when opening filehandles
818 that must be passed around, as in the following example:
822 or die "Can't open '@_': $!";
827 my $f = myopen("</etc/motd");
829 # $f implicitly closed here
832 Another way to create anonymous filehandles is with the Symbol
833 module or with the IO::Handle module and its ilk. These modules
834 have the advantage of not hiding different types of the same name
835 during the local(). See the bottom of L<perlfunc/open()> for an
840 See L<perlvar> for a description of Perl's built-in variables and
841 a discussion of legal variable names. See L<perlref>, L<perlsub>,
842 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
843 the C<*foo{THING}> syntax.