3 perldata - Perl data types
9 Perl has three built-in data types: scalars, arrays of scalars, and
10 associative arrays of scalars, known as "hashes". Normal arrays
11 are ordered lists of scalars indexed by number, starting with 0 and with
12 negative subscripts counting from the end. Hashes are unordered
13 collections of scalar values indexed by their associated string key.
15 Values are usually referred to by name, or through a named reference.
16 The first character of the name tells you to what sort of data
17 structure it refers. The rest of the name tells you the particular
18 value to which it refers. Usually this name is a single I<identifier>,
19 that is, a string beginning with a letter or underscore, and
20 containing letters, underscores, and digits. In some cases, it may
21 be a chain of identifiers, separated by C<::> (or by the slightly
22 archaic C<'>); all but the last are interpreted as names of packages,
23 to locate the namespace in which to look up the final identifier
24 (see L<perlmod/Packages> for details). It's possible to substitute
25 for a simple identifier, an expression that produces a reference
26 to the value at runtime. This is described in more detail below
29 Perl also has its own built-in variables whose names don't follow
30 these rules. They have strange names so they don't accidentally
31 collide with one of your normal variables. Strings that match
32 parenthesized parts of a regular expression are saved under names
33 containing only digits after the C<$> (see L<perlop> and L<perlre>).
34 In addition, several special variables that provide windows into
35 the inner working of Perl have names containing punctuation characters
36 and control characters. These are documented in L<perlvar>.
38 Scalar values are always named with '$', even when referring to a
39 scalar that is part of an array or a hash. The '$' symbol works
40 semantically like the English word "the" in that it indicates a
41 single value is expected.
43 $days # the simple scalar value "days"
44 $days[28] # the 29th element of array @days
45 $days{'Feb'} # the 'Feb' value from hash %days
46 $#days # the last index of array @days
48 Entire arrays (and slices of arrays and hashes) are denoted by '@',
49 which works much like the word "these" or "those" does in English,
50 in that it indicates multiple values are expected.
52 @days # ($days[0], $days[1],... $days[n])
53 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
54 @days{'a','c'} # same as ($days{'a'},$days{'c'})
56 Entire hashes are denoted by '%':
58 %days # (key1, val1, key2, val2 ...)
60 In addition, subroutines are named with an initial '&', though this
61 is optional when unambiguous, just as the word "do" is often redundant
62 in English. Symbol table entries can be named with an initial '*',
63 but you don't really care about that yet (if ever :-).
65 Every variable type has its own namespace, as do several
66 non-variable identifiers. This means that you can, without fear
67 of conflict, use the same name for a scalar variable, an array, or
68 a hash--or, for that matter, for a filehandle, a directory handle, a
69 subroutine name, a format name, or a label. This means that $foo
70 and @foo are two different variables. It also means that C<$foo[1]>
71 is a part of @foo, not a part of $foo. This may seem a bit weird,
72 but that's okay, because it is weird.
74 Because variable references always start with '$', '@', or '%', the
75 "reserved" words aren't in fact reserved with respect to variable
76 names. They I<are> reserved with respect to labels and filehandles,
77 however, which don't have an initial special character. You can't
78 have a filehandle named "log", for instance. Hint: you could say
79 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
80 uppercase filehandles also improves readability and protects you
81 from conflict with future reserved words. Case I<is> significant--"FOO",
82 "Foo", and "foo" are all different names. Names that start with a
83 letter or underscore may also contain digits and underscores.
85 It is possible to replace such an alphanumeric name with an expression
86 that returns a reference to the appropriate type. For a description
87 of this, see L<perlref>.
89 Names that start with a digit may contain only more digits. Names
90 that do not start with a letter, underscore, or digit are limited to
91 one character, e.g., C<$%> or C<$$>. (Most of these one character names
92 have a predefined significance to Perl. For instance, C<$$> is the
97 The interpretation of operations and values in Perl sometimes depends
98 on the requirements of the context around the operation or value.
99 There are two major contexts: list and scalar. Certain operations
100 return list values in contexts wanting a list, and scalar values
101 otherwise. If this is true of an operation it will be mentioned in
102 the documentation for that operation. In other words, Perl overloads
103 certain operations based on whether the expected return value is
104 singular or plural. Some words in English work this way, like "fish"
107 In a reciprocal fashion, an operation provides either a scalar or a
108 list context to each of its arguments. For example, if you say
112 the integer operation provides scalar context for the <>
113 operator, which responds by reading one line from STDIN and passing it
114 back to the integer operation, which will then find the integer value
115 of that line and return that. If, on the other hand, you say
119 then the sort operation provides list context for <>, which
120 will proceed to read every line available up to the end of file, and
121 pass that list of lines back to the sort routine, which will then
122 sort those lines and return them as a list to whatever the context
125 Assignment is a little bit special in that it uses its left argument
126 to determine the context for the right argument. Assignment to a
127 scalar evaluates the right-hand side in scalar context, while
128 assignment to an array or hash evaluates the righthand side in list
129 context. Assignment to a list (or slice, which is just a list
130 anyway) also evaluates the righthand side in list context.
132 When you use the C<use warnings> pragma or Perl's B<-w> command-line
133 option, you may see warnings
134 about useless uses of constants or functions in "void context".
135 Void context just means the value has been discarded, such as a
136 statement containing only C<"fred";> or C<getpwuid(0);>. It still
137 counts as scalar context for functions that care whether or not
138 they're being called in list context.
140 User-defined subroutines may choose to care whether they are being
141 called in a void, scalar, or list context. Most subroutines do not
142 need to bother, though. That's because both scalars and lists are
143 automatically interpolated into lists. See L<perlfunc/wantarray>
144 for how you would dynamically discern your function's calling
149 All data in Perl is a scalar, an array of scalars, or a hash of
150 scalars. A scalar may contain one single value in any of three
151 different flavors: a number, a string, or a reference. In general,
152 conversion from one form to another is transparent. Although a
153 scalar may not directly hold multiple values, it may contain a
154 reference to an array or hash which in turn contains multiple values.
156 Scalars aren't necessarily one thing or another. There's no place
157 to declare a scalar variable to be of type "string", type "number",
158 type "reference", or anything else. Because of the automatic
159 conversion of scalars, operations that return scalars don't need
160 to care (and in fact, cannot care) whether their caller is looking
161 for a string, a number, or a reference. Perl is a contextually
162 polymorphic language whose scalars can be strings, numbers, or
163 references (which includes objects). Although strings and numbers
164 are considered pretty much the same thing for nearly all purposes,
165 references are strongly-typed, uncastable pointers with builtin
166 reference-counting and destructor invocation.
168 A scalar value is interpreted as TRUE in the Boolean sense if it is not
169 the null string or the number 0 (or its string equivalent, "0"). The
170 Boolean context is just a special kind of scalar context where no
171 conversion to a string or a number is ever performed.
173 There are actually two varieties of null strings (sometimes referred
174 to as "empty" strings), a defined one and an undefined one. The
175 defined version is just a string of length zero, such as C<"">.
176 The undefined version is the value that indicates that there is
177 no real value for something, such as when there was an error, or
178 at end of file, or when you refer to an uninitialized variable or
179 element of an array or hash. Although in early versions of Perl,
180 an undefined scalar could become defined when first used in a
181 place expecting a defined value, this no longer happens except for
182 rare cases of autovivification as explained in L<perlref>. You can
183 use the defined() operator to determine whether a scalar value is
184 defined (this has no meaning on arrays or hashes), and the undef()
185 operator to produce an undefined value.
187 To find out whether a given string is a valid non-zero number, it's
188 sometimes enough to test it against both numeric 0 and also lexical
189 "0" (although this will cause B<-w> noises). That's because strings
190 that aren't numbers count as 0, just as they do in B<awk>:
192 if ($str == 0 && $str ne "0") {
193 warn "That doesn't look like a number";
196 That method may be best because otherwise you won't treat IEEE
197 notations like C<NaN> or C<Infinity> properly. At other times, you
198 might prefer to determine whether string data can be used numerically
199 by calling the POSIX::strtod() function or by inspecting your string
200 with a regular expression (as documented in L<perlre>).
202 warn "has nondigits" if /\D/;
203 warn "not a natural number" unless /^\d+$/; # rejects -3
204 warn "not an integer" unless /^-?\d+$/; # rejects +3
205 warn "not an integer" unless /^[+-]?\d+$/;
206 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
207 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
209 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
211 The length of an array is a scalar value. You may find the length
212 of array @days by evaluating C<$#days>, as in B<csh>. However, this
213 isn't the length of the array; it's the subscript of the last element,
214 which is a different value since there is ordinarily a 0th element.
215 Assigning to C<$#days> actually changes the length of the array.
216 Shortening an array this way destroys intervening values. Lengthening
217 an array that was previously shortened does not recover values
218 that were in those elements. (It used to do so in Perl 4, but we
219 had to break this to make sure destructors were called when expected.)
221 You can also gain some miniscule measure of efficiency by pre-extending
222 an array that is going to get big. You can also extend an array
223 by assigning to an element that is off the end of the array. You
224 can truncate an array down to nothing by assigning the null list
225 () to it. The following are equivalent:
230 If you evaluate an array in scalar context, it returns the length
231 of the array. (Note that this is not true of lists, which return
232 the last value, like the C comma operator, nor of built-in functions,
233 which return whatever they feel like returning.) The following is
236 scalar(@whatever) == $#whatever + 1;
238 Some programmers choose to use an explicit conversion so as to
239 leave nothing to doubt:
241 $element_count = scalar(@whatever);
243 If you evaluate a hash in scalar context, it returns false if the
244 hash is empty. If there are any key/value pairs, it returns true;
245 more precisely, the value returned is a string consisting of the
246 number of used buckets and the number of allocated buckets, separated
247 by a slash. This is pretty much useful only to find out whether
248 Perl's internal hashing algorithm is performing poorly on your data
249 set. For example, you stick 10,000 things in a hash, but evaluating
250 %HASH in scalar context reveals C<"1/16">, which means only one out
251 of sixteen buckets has been touched, and presumably contains all
252 10,000 of your items. This isn't supposed to happen.
254 You can preallocate space for a hash by assigning to the keys() function.
255 This rounds up the allocated buckets to the next power of two:
258 keys(%users) = 1000; # allocate 1024 buckets
260 =head2 Scalar value constructors
262 Numeric literals are specified in any of the following floating point or
267 .23E-10 # a very small number
268 3.14_15_92 # a very important number
269 4_294_967_296 # underscore for legibility
271 0xdead_beef # more hex
275 You are allowed to use underscores (underbars) in numeric literals
276 between digits for legibility. You could, for example, group binary
277 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
278 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
280 String literals are usually delimited by either single or double
281 quotes. They work much like quotes in the standard Unix shells:
282 double-quoted string literals are subject to backslash and variable
283 substitution; single-quoted strings are not (except for C<\'> and
284 C<\\>). The usual C-style backslash rules apply for making
285 characters such as newline, tab, etc., as well as some more exotic
286 forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
288 Hexadecimal, octal, or binary, representations in string literals
289 (e.g. '0xff') are not automatically converted to their integer
290 representation. The hex() and oct() functions make these conversions
291 for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
293 You can also embed newlines directly in your strings, i.e., they can end
294 on a different line than they begin. This is nice, but if you forget
295 your trailing quote, the error will not be reported until Perl finds
296 another line containing the quote character, which may be much further
297 on in the script. Variable substitution inside strings is limited to
298 scalar variables, arrays, and array or hash slices. (In other words,
299 names beginning with $ or @, followed by an optional bracketed
300 expression as a subscript.) The following code segment prints out "The
303 my $Price = '$100'; # not interpolated
304 print "The price is $Price.\n"; # interpolated
306 As in some shells, you can enclose the variable name in braces to
307 disambiguate it from following alphanumerics (and underscores).
309 this when interpolating a variable into a string to separate the
310 variable name from a following double-colon or an apostrophe, since
311 these would be otherwise treated as a package separator:
314 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
315 print "We use ${who}speak when ${who}'s here.\n";
317 Without the braces, Perl would have looked for a $whospeak, a
318 C<$who::0>, and a C<$who's> variable. The last two would be the
319 $0 and the $s variables in the (presumably) non-existent package
322 In fact, an identifier within such curlies is forced to be a string,
323 as is any simple identifier within a hash subscript. Neither need
324 quoting. Our earlier example, C<$days{'Feb'}> can be written as
325 C<$days{Feb}> and the quotes will be assumed automatically. But
326 anything more complicated in the subscript will be interpreted as
329 A literal of the form C<v1.20.300.4000> is parsed as a string composed
330 of characters with the specified ordinals. This form, known as
331 v-strings, provides an alternative, more readable way to construct
332 strings, rather than use the somewhat less readable interpolation form
333 C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing
334 Unicode strings, and for comparing version "numbers" using the string
335 comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or
336 more dots in the literal, the leading C<v> may be omitted.
338 print v9786; # prints UTF-8 encoded SMILEY, "\x{263a}"
339 print v102.111.111; # prints "foo"
340 print 102.111.111; # same
342 Such literals are accepted by both C<require> and C<use> for
343 doing a version check. The C<$^V> special variable also contains the
344 running Perl interpreter's version in this form. See L<perlvar/$^V>.
345 Note that using the v-strings for IPv4 addresses is not portable unless
346 you also use the inet_aton()/inet_ntoa() routines of the Socket package.
348 The special literals __FILE__, __LINE__, and __PACKAGE__
349 represent the current filename, line number, and package name at that
350 point in your program. They may be used only as separate tokens; they
351 will not be interpolated into strings. If there is no current package
352 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
355 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
356 may be used to indicate the logical end of the script before the actual
357 end of file. Any following text is ignored.
359 Text after __DATA__ but may be read via the filehandle C<PACKNAME::DATA>,
360 where C<PACKNAME> is the package that was current when the __DATA__
361 token was encountered. The filehandle is left open pointing to the
362 contents after __DATA__. It is the program's responsibility to
363 C<close DATA> when it is done reading from it. For compatibility with
364 older scripts written before __DATA__ was introduced, __END__ behaves
365 like __DATA__ in the toplevel script (but not in files loaded with
366 C<require> or C<do>) and leaves the remaining contents of the
367 file accessible via C<main::DATA>.
369 See L<SelfLoader> for more description of __DATA__, and
370 an example of its use. Note that you cannot read from the DATA
371 filehandle in a BEGIN block: the BEGIN block is executed as soon
372 as it is seen (during compilation), at which point the corresponding
373 __DATA__ (or __END__) token has not yet been seen.
375 A word that has no other interpretation in the grammar will
376 be treated as if it were a quoted string. These are known as
377 "barewords". As with filehandles and labels, a bareword that consists
378 entirely of lowercase letters risks conflict with future reserved
379 words, and if you use the C<use warnings> pragma or the B<-w> switch,
380 Perl will warn you about any
381 such words. Some people may wish to outlaw barewords entirely. If you
386 then any bareword that would NOT be interpreted as a subroutine call
387 produces a compile-time error instead. The restriction lasts to the
388 end of the enclosing block. An inner block may countermand this
389 by saying C<no strict 'subs'>.
391 Arrays and slices are interpolated into double-quoted strings
392 by joining the elements with the delimiter specified in the C<$">
393 variable (C<$LIST_SEPARATOR> in English), space by default. The
394 following are equivalent:
396 my $temp = join($", @ARGV);
401 Within search patterns (which also undergo double-quotish substitution)
402 there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
403 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
404 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
405 @foo)? If @foo doesn't otherwise exist, then it's obviously a
406 character class. If @foo exists, Perl takes a good guess about C<[bar]>,
407 and is almost always right. If it does guess wrong, or if you're just
408 plain paranoid, you can force the correct interpretation with curly
411 A line-oriented form of quoting is based on the shell "here-document"
412 syntax. Following a C<< << >> you specify a string to terminate
413 the quoted material, and all lines following the current line down to
414 the terminating string are the value of the item. The terminating
415 string may be either an identifier (a word), or some quoted text. If
416 quoted, the type of quotes you use determines the treatment of the
417 text, just as in regular quoting. An unquoted identifier works like
418 double quotes. There must be no space between the C<< << >> and
419 the identifier, unless the identifier is quoted. (If you put a space it
420 will be treated as a null identifier, which is valid, and matches the first
421 empty line.) The terminating string must appear by itself (unquoted and
422 with no surrounding whitespace) on the terminating line.
428 print << "EOF"; # same as above
432 print << `EOC`; # execute commands
437 print <<"foo", <<"bar"; # you can stack them
443 myfunc(<< "THIS", 23, <<'THAT');
450 Just don't forget that you have to put a semicolon on the end
451 to finish the statement, as Perl doesn't know you're not going to
459 If you want your here-docs to be indented with the
460 rest of the code, you'll need to remove leading whitespace
461 from each line manually:
463 (my $quote = <<'FINIS') =~ s/^\s+//gm;
464 The Road goes ever on and on,
465 down from the door where it began.
468 If you use a here-doc within a delimited construct, such as in C<s///eg>,
469 the quoted material must come on the lines following the final delimiter.
484 If the terminating identifier is on the last line of the program, you
485 must be sure there is a newline after it; otherwise, Perl will give the
486 warning B<Can't find string terminator "END" anywhere before EOF...>.
488 Additionally, the quoting rules for the identifier are not related to
489 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
490 in place of C<''> and C<"">, and the only interpolation is for backslashing
491 the quoting character:
497 Finally, quoted strings cannot span multiple lines. The general rule is
498 that the identifier must be a string literal. Stick with that, and you
501 =head2 List value constructors
503 List values are denoted by separating individual values by commas
504 (and enclosing the list in parentheses where precedence requires it):
508 In a context not requiring a list value, the value of what appears
509 to be a list literal is simply the value of the final element, as
510 with the C comma operator. For example,
512 my @foo = ('cc', '-E', $bar);
514 assigns the entire list value to array @foo, but
516 my $foo = ('cc', '-E', $bar);
518 assigns the value of variable $bar to the scalar variable $foo.
519 Note that the value of an actual array in scalar context is the
520 length of the array; the following assigns the value 3 to $foo:
522 my @foo = ('cc', '-E', $bar);
523 my $foo = @foo; # $foo gets 3
525 You may have an optional comma before the closing parenthesis of a
526 list literal, so that you can say:
534 To use a here-document to assign an array, one line per element,
535 you might use an approach like this:
537 my @sauces = <<End_Lines =~ m/(\S.*\S)/g;
545 LISTs do automatic interpolation of sublists. That is, when a LIST is
546 evaluated, each element of the list is evaluated in list context, and
547 the resulting list value is interpolated into LIST just as if each
548 individual element were a member of LIST. Thus arrays and hashes lose their
549 identity in a LIST--the list
551 (@foo,@bar,&SomeSub,%glarch)
553 contains all the elements of @foo followed by all the elements of @bar,
554 followed by all the elements returned by the subroutine named SomeSub
555 called in list context, followed by the key/value pairs of %glarch.
556 To make a list reference that does I<NOT> interpolate, see L<perlref>.
558 The null list is represented by (). Interpolating it in a list
559 has no effect. Thus ((),(),()) is equivalent to (). Similarly,
560 interpolating an array with no elements is the same as if no
561 array had been interpolated at that point.
563 This interpolation combines with the facts that the opening
564 and closing parentheses are optional (except when necessary for
565 precedence) and lists may end with an optional comma to mean that
566 multiple commas within lists are legal syntax. The list C<1,,3> is a
567 concatenation of two lists, C<1,> and C<3>, the first of which ends
568 with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
569 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
570 we'd advise you to use this obfuscation.
572 A list value may also be subscripted like a normal array. You must
573 put the list in parentheses to avoid ambiguity. For example:
575 # Stat returns list value.
576 my $time = (stat($file))[8];
579 my $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
582 my $hexdigit = ('a','b','c','d','e','f')[$digit-10];
584 # A "reverse comma operator".
585 return (pop(@foo),pop(@foo))[0];
587 Lists may be assigned to only when each element of the list
588 is itself legal to assign to:
590 my($a, $b, $c) = (1, 2, 3);
592 ($map{red}, $map{blue}, $map{green}) = (0x00f, 0x0f0, 0xf00);
594 An exception to this is that you may assign to C<undef> in a list.
595 This is useful for throwing away some of the return values of a
598 my($dev, $ino, undef, undef, $uid, $gid) = stat($file);
600 List assignment in scalar context returns the number of elements
601 produced by the expression on the right side of the assignment:
603 my $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
604 my $x = (($foo,$bar) = f()); # set $x to f()'s return count
606 This is handy when you want to do a list assignment in a Boolean
607 context, because most list functions return a null list when finished,
608 which when assigned produces a 0, which is interpreted as FALSE.
610 It's also the source of a useful idiom for executing a function or
611 performing an operation in list context and then counting the number of
612 return values, by assigning to an empty list and then using that
613 assignment in scalar context. For example, this code:
615 my $count = () = $string =~ /\d+/g;
617 will place into $count the number of digit groups found in $string.
618 This happens because the pattern match is in list context (since it
619 is being assigned to the empty list), and will therefore return a list
620 of all matching parts of the string. The list assignment in scalar
621 context will translate that into the number of elements (here, the
622 number of times the pattern matched) and assign that to $count. Note
625 my $count = $string =~ /\d+/g;
627 would not have worked, since a pattern match in scalar context will
628 only return true or false, rather than a count of matches.
630 The final element of a list assignment may be an array or a hash:
632 my($a, $b, @rest) = split;
634 my($a, $b, %rest) = @_;
636 You can actually put an array or hash anywhere in the list, but the first one
637 in the list will soak up all the values, and anything after it will become
638 undefined. This may be useful in a my() or local().
640 A hash can be initialized using a literal list holding pairs of
641 items to be interpreted as a key and a value:
643 # same as map assignment above
644 my %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
646 While literal lists and named arrays are often interchangeable, that's
647 not the case for hashes. Just because you can subscript a list value like
648 a normal array does not mean that you can subscript a list value as a
649 hash. Likewise, hashes included as parts of other lists (including
650 parameters lists and return lists from functions) always flatten out into
651 key/value pairs. That's why it's good to use references sometimes.
653 It is often more readable to use the C<< => >> operator between key/value
654 pairs. The C<< => >> operator is mostly just a more visually distinctive
655 synonym for a comma, but it also arranges for its left-hand operand to be
656 interpreted as a string--if it's a bareword that would be a legal identifier.
657 This makes it nice for initializing hashes:
665 or for initializing hash references to be used as records:
668 witch => 'Mable the Merciless',
669 cat => 'Fluffy the Ferocious',
670 date => '10/31/1776',
673 or for using call-by-named-parameter to complicated functions:
676 my $query = CGI->new;
677 my $field = $query->radio_group(
678 name => 'group_name',
679 values => ['eenie','meenie','minie'],
685 Note that just because a hash is initialized in that order doesn't
686 mean that it comes out in that order. See L<perlfunc/sort> for examples
687 of how to arrange for an output ordering.
691 A common way to access an array or a hash is one scalar element at a
692 time. You can also subscript a list to get a single element from it.
694 my $whoami = $ENV{"USER"}; # one element from the hash
695 my $parent = $ISA[0]; # one element from the array
696 my $dir = (getpwnam("daemon"))[7]; # likewise, but with list
698 A slice accesses several elements of a list, an array, or a hash
699 simultaneously using a list of subscripts. It's more convenient
700 than writing out the individual elements as a list of separate
703 my($him, $her) = @folks[0,-1]; # array slice
704 my @them = @folks[0 .. 3]; # array slice
705 my($who, $home) = @ENV{"USER", "HOME"}; # hash slice
706 my($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
708 Since you can assign to a list of variables, you can also assign to
709 an array or hash slice.
711 my( @days, %colors, @folks );
712 @days[3..5] = qw(Wed Thu Fri);
713 @colors{'red','blue','green'}
714 = (0xff0000, 0x0000ff, 0x00ff00);
715 @folks[0, -1] = @folks[-1, 0];
717 The previous assignments are exactly equivalent to
719 my( @days, %colors, @folks );
720 ($days[3], $days[4], $days[5]) = qw(Wed Thu Fri);
721 ($colors{red}, $colors{blue}, $colors{green})
722 = (0xff0000, 0x0000ff, 0x00ff00);
723 ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
725 Since changing a slice changes the original array or hash that it's
726 slicing, a C<foreach> construct will alter some--or even all--of the
727 values of the array or hash.
729 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
731 foreach (@hash{keys %hash}) {
732 s/^\s+//; # trim leading whitespace
733 s/\s+$//; # trim trailing whitespace
734 s/(\w+)/\u\L$1/g; # "titlecase" words
737 A slice of an empty list is still an empty list. Thus:
739 my @a = ()[1,0]; # @a has no elements
740 my @b = (@a)[0,1]; # @b has no elements
741 my @c = (0,1)[2,3]; # @c has no elements
745 my @a = (1)[1,0]; # @a has two elements
746 my @b = (1,undef)[1,0,2]; # @b has three elements
748 This makes it easy to write loops that terminate when a null list
751 while ( my($home, $user) = (getpwent)[7,0] ) {
752 printf "%-8s %s\n", $user, $home;
755 As noted earlier in this document, the scalar sense of list assignment
756 is the number of elements on the right-hand side of the assignment.
757 The null list contains no elements, so when the password file is
758 exhausted, the result is 0, not 2.
760 If you're confused about why you use an '@' there on a hash slice
761 instead of a '%', think of it like this. The type of bracket (square
762 or curly) governs whether it's an array or a hash being looked at.
763 On the other hand, the leading symbol ('$' or '@') on the array or
764 hash indicates whether you are getting back a singular value (a
765 scalar) or a plural one (a list).
767 =head2 Typeglobs and Filehandles
769 Perl uses an internal type called a I<typeglob> to hold an entire
770 symbol table entry. The type prefix of a typeglob is a C<*>, because
771 it represents all types. This used to be the preferred way to
772 pass arrays and hashes by reference into a function, but now that
773 we have real references, this is seldom needed.
775 The main use of typeglobs in modern Perl is create symbol table aliases.
782 makes $this an alias for $that, @this an alias for @that, %this an alias
783 for %that, &this an alias for &that, etc. Much safer is to use a reference.
786 local *Here::blue = \$There::green;
788 temporarily makes $Here::blue an alias for $There::green, but doesn't
789 make @Here::blue an alias for @There::green, or %Here::blue an alias for
790 %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
791 of this. Strange though this may seem, this is the basis for the whole
792 module import/export system. And none of it works under
793 C<use strict 'vars'>.
795 Another use for typeglobs is to pass filehandles into a function or
796 to create new filehandles. If you need to use a typeglob to save away
797 a filehandle, do it this way:
801 or perhaps as a real reference, like this:
805 See L<perlsub> for examples of using these as indirect filehandles
808 Typeglobs are also a way to create a local filehandle using the local()
809 operator. These last until their block is exited, but may be passed back.
815 open (FH, $path) or return undef;
818 my $fh = newopen('/etc/passwd');
820 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
821 for filehandle manipulations, although they're still needed to pass brand
822 new file and directory handles into or out of functions. That's because
823 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
824 In other words, C<*FH> must be used to create new symbol table entries;
825 C<*foo{THING}> cannot. When in doubt, use C<*FH>.
827 All functions that are capable of creating filehandles (open(),
828 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
829 automatically create an anonymous filehandle if the handle passed to
830 them is an uninitialized scalar variable. This allows the constructs
831 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
832 create filehandles that will conveniently be closed automatically when
833 the scope ends, provided there are no other references to them. This
834 largely eliminates the need for typeglobs when opening filehandles
835 that must be passed around, as in the following example:
838 my $filename = shift;
839 open my $fh, $filename
840 or die "Can't open '$filename': $!";
845 my $f = myopen("</etc/motd");
847 # $f implicitly closed here
850 Another way to create anonymous filehandles is with the Symbol
851 module or with the IO::Handle module and its ilk. These modules
852 have the advantage of not hiding different types of the same name
853 during the local(). See the bottom of L<perlfunc/open()> for an
858 See L<perlvar> for a description of Perl's built-in variables and
859 a discussion of legal variable names. See L<perlref>, L<perlsub>,
860 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
861 the C<*foo{THING}> syntax.