perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those who wander are lost.'
  13  *
  14  * This file holds the grammar for the Perl language. If edited, you need
  15  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
  16  * and perly.act which are derived from this.
  17  *
  18  * Note that these derived files are included and compiled twice; once
  19  * from perly.c, and once from madly.c. The second time, a number of MAD
  20  * macros are defined, which compile in extra code that allows the parse
  21  * tree to be accurately dumped. In particular:
  22  *
  23  * MAD            defined if compiling madly.c
  24  * DO_MAD(A)      expands to A  under madly.c, to null otherwise
  25  * IF_MAD(a,b)    expands to A under madly.c, to B otherwise
  26  * TOKEN_GETMAD() expands to token_getmad() under madly.c, to null otherwise
  27  * TOKEN_FREE()   similarly
  28  * OP_GETMAD()    similarly
  29  * IVAL(i)        expands to (i)->tk_lval.ival or (i)
  30  * PVAL(p)        expands to (p)->tk_lval.pval or (p)
  31  *
  32  * The main job of of this grammar is to call the various newFOO()
  33  * functions in op.c to build a syntax tree of OP structs.
  34  * It relies on the lexer in toke.c to do the tokenizing.
  35  */
  36
  37 /*  Make the parser re-entrant. */
  38
  39 %pure_parser
  40
  41 /* FIXME for MAD - is the new mintro on while and until important?  */
  42
  43 %start prog
  44
  45 %union {
  46     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
  47                                 must always be 1st union member) */
  48     char *pval;
  49     OP *opval;
  50     GV *gvval;
  51 #ifdef PERL_IN_MADLY_C
  52     TOKEN* p_tkval;
  53     TOKEN* i_tkval;
  54 #else
  55     char *p_tkval;
  56     I32 i_tkval;
  57 #endif
  58 #ifdef PERL_MAD
  59     TOKEN* tkval;
  60 #endif
  61 }
  62
  63 %token <i_tkval> '{' '}' '[' ']' '-' '+' '$' '@' '%' '*' '&' ';'
  64
  65 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  66 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  67 %token <p_tkval> LABEL
  68 %token <i_tkval> FORMAT SUB ANONSUB PACKAGE USE
  69 %token <i_tkval> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  70 %token <i_tkval> GIVEN WHEN DEFAULT
  71 %token <i_tkval> LOOPEX DOTDOT
  72 %token <i_tkval> FUNC0 FUNC1 FUNC UNIOP LSTOP
  73 %token <i_tkval> RELOP EQOP MULOP ADDOP
  74 %token <i_tkval> DOLSHARP DO HASHBRACK NOAMP
  75 %token <i_tkval> LOCAL MY MYSUB REQUIRE
  76 %token <i_tkval> COLONATTR
  77
  78 %type <ival> prog progstart remember mremember savescope
  79 %type <ival>  startsub startanonsub startformsub
  80 /* FIXME for MAD - are these two ival? */
  81 %type <ival> mydefsv mintro
  82
  83 %type <opval> decl format subrout mysubrout package use peg
  84
  85 %type <opval> block mblock lineseq line loop cond else
  86 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
  87 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr miexpr
  88 %type <opval> listexpr listexprcom indirob listop method
  89 %type <opval> formname subname proto subbody cont my_scalar
  90 %type <opval> subattrlist myattrlist myattrterm myterm
  91 %type <opval> termbinop termunop anonymous termdo
  92 %type <opval> switch case
  93 %type <p_tkval> label
  94
  95 %nonassoc <i_tkval> PREC_LOW
  96 %nonassoc LOOPEX
  97
  98 %left <i_tkval> OROP DOROP
  99 %left <i_tkval> ANDOP
 100 %right <i_tkval> NOTOP
 101 %nonassoc LSTOP LSTOPSUB
 102 %left <i_tkval> ','
 103 %right <i_tkval> ASSIGNOP
 104 %right <i_tkval> '?' ':'
 105 %nonassoc DOTDOT
 106 %left <i_tkval> OROR DORDOR
 107 %left <i_tkval> ANDAND
 108 %left <i_tkval> BITOROP
 109 %left <i_tkval> BITANDOP
 110 %nonassoc EQOP
 111 %nonassoc RELOP
 112 %nonassoc UNIOP UNIOPSUB
 113 %nonassoc REQUIRE
 114 %left <i_tkval> SHIFTOP
 115 %left ADDOP
 116 %left MULOP
 117 %left <i_tkval> MATCHOP
 118 %right <i_tkval> '!' '~' UMINUS REFGEN
 119 %right <i_tkval> POWOP
 120 %nonassoc <i_tkval> PREINC PREDEC POSTINC POSTDEC
 121 %left <i_tkval> ARROW
 122 %nonassoc <i_tkval> ')'
 123 %left <i_tkval> '('
 124 %left '[' '{'
 125
 126 %token <i_tkval> PEG
 127
 128 %% /* RULES */
 129
 130 /* The whole program */
 131 prog    :       progstart
 132         /*CONTINUED*/   lineseq
 133                         { $$ = $1; newPROG(block_end($1,$2)); }
 134         ;
 135
 136 /* An ordinary block */
 137 block   :       '{' remember lineseq '}'
 138                         { if (PL_copline > (line_t)IVAL($1))
 139                               PL_copline = (line_t)IVAL($1);
 140                           $$ = block_end($2, $3);
 141                           TOKEN_GETMAD($1,$$,'{');
 142                           TOKEN_GETMAD($4,$$,'}');
 143                         }
 144         ;
 145
 146 remember:       /* NULL */      /* start a full lexical scope */
 147                         { $$ = block_start(TRUE); }
 148         ;
 149
 150 mydefsv:        /* NULL */      /* lexicalize $_ */
 151                         { $$ = (I32) allocmy("$_"); }
 152         ;
 153
 154 progstart:
 155                 {
 156                     PL_expect = XSTATE; $$ = block_start(TRUE);
 157                 }
 158         ;
 159
 160
 161 mblock  :       '{' mremember lineseq '}'
 162                         { if (PL_copline > (line_t)IVAL($1))
 163                               PL_copline = (line_t)IVAL($1);
 164                           $$ = block_end($2, $3);
 165                           TOKEN_GETMAD($1,$$,'{');
 166                           TOKEN_GETMAD($4,$$,'}');
 167                         }
 168         ;
 169
 170 mremember:      /* NULL */      /* start a partial lexical scope */
 171                         { $$ = block_start(FALSE); }
 172         ;
 173
 174 savescope:      /* NULL */      /* remember stack pos in case of error */
 175                 { $$ = PL_savestack_ix; }
 176
 177 /* A collection of "lines" in the program */
 178 lineseq :       /* NULL */
 179                         { $$ = Nullop; }
 180         |       lineseq decl
 181                         {
 182                         $$ = IF_MAD(
 183                                 append_list(OP_LINESEQ,
 184                                     (LISTOP*)$1, (LISTOP*)$2),
 185                                 $1);
 186                         }
 187         |       lineseq savescope line
 188                         {   LEAVE_SCOPE($2);
 189                             $$ = append_list(OP_LINESEQ,
 190                                 (LISTOP*)$1, (LISTOP*)$3);
 191                             PL_pad_reset_pending = TRUE;
 192                             if ($1 && $3) PL_hints |= HINT_BLOCK_SCOPE; }
 193         ;
 194
 195 /* A "line" in the program */
 196 line    :       label cond
 197                         { $$ = newSTATEOP(0, PVAL($1), $2);
 198                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 199         |       loop    /* loops add their own labels */
 200         |       switch  /* ... and so do switches */
 201                         { $$ = $1; }
 202         |       label case
 203                         { $$ = newSTATEOP(0, PVAL($1), $2); }
 204         |       label ';'
 205                         {
 206                           if (PVAL($1)) {
 207                               $$ = newSTATEOP(0, PVAL($1), newOP(OP_NULL, 0));
 208                               TOKEN_GETMAD($1,$$,'L');
 209                               TOKEN_GETMAD($2,((LISTOP*)$$)->op_first,';');
 210                           }
 211                           else {
 212                               $$ = IF_MAD(
 213                                         newOP(OP_NULL, 0),
 214                                         Nullop);
 215                               PL_copline = NOLINE;
 216                               TOKEN_FREE($1);
 217                               TOKEN_GETMAD($2,$$,';');
 218                           }
 219                           PL_expect = XSTATE;
 220                         }
 221         |       label sideff ';'
 222                         {
 223                           $$ = newSTATEOP(0, PVAL($1), $2);
 224                           PL_expect = XSTATE;
 225                           DO_MAD(
 226                               /* sideff might already have a nexstate */
 227                               OP* op = ((LISTOP*)$$)->op_first;
 228                               if (op) {
 229                                   while (op->op_sibling &&
 230                                      op->op_sibling->op_type == OP_NEXTSTATE)
 231                                         op = op->op_sibling;
 232                                   token_getmad($1,op,'L');
 233                                   token_getmad($3,op,';');
 234                               }
 235                           )
 236                         }
 237         ;
 238
 239 /* An expression which may have a side-effect */
 240 sideff  :       error
 241                         { $$ = Nullop; }
 242         |       expr
 243                         { $$ = $1; }
 244         |       expr IF expr
 245                         { $$ = newLOGOP(OP_AND, 0, $3, $1);
 246                           TOKEN_GETMAD($2,$$,'i');
 247                         }
 248         |       expr UNLESS expr
 249                         { $$ = newLOGOP(OP_OR, 0, $3, $1);
 250                           TOKEN_GETMAD($2,$$,'i');
 251                         }
 252         |       expr WHILE expr
 253                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1);
 254                           TOKEN_GETMAD($2,$$,'w');
 255                         }
 256         |       expr UNTIL iexpr
 257                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);
 258                           TOKEN_GETMAD($2,$$,'w');
 259                         }
 260         |       expr FOR expr
 261                         { $$ = newFOROP(0, Nullch, (line_t)IVAL($2),
 262                                         Nullop, $3, $1, Nullop);
 263                           TOKEN_GETMAD($2,((LISTOP*)$$)->op_first->op_sibling,'w');
 264                         }
 265         ;
 266
 267 /* else and elsif blocks */
 268 else    :       /* NULL */
 269                         { $$ = Nullop; }
 270         |       ELSE mblock
 271                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2);
 272                           TOKEN_GETMAD($1,$$,'o');
 273                         }
 274         |       ELSIF '(' mexpr ')' mblock else
 275                         { PL_copline = (line_t)IVAL($1);
 276                             $$ = newCONDOP(0, $3, scope($5), $6);
 277                             PL_hints |= HINT_BLOCK_SCOPE;
 278                           TOKEN_GETMAD($1,$$,'I');
 279                           TOKEN_GETMAD($2,$$,'(');
 280                           TOKEN_GETMAD($4,$$,')');
 281                         }
 282         ;
 283
 284 /* Real conditional expressions */
 285 cond    :       IF '(' remember mexpr ')' mblock else
 286                         { PL_copline = (line_t)IVAL($1);
 287                             $$ = block_end($3,
 288                                    newCONDOP(0, $4, scope($6), $7));
 289                           TOKEN_GETMAD($1,$$,'I');
 290                           TOKEN_GETMAD($2,$$,'(');
 291                           TOKEN_GETMAD($5,$$,')');
 292                         }
 293         |       UNLESS '(' remember miexpr ')' mblock else
 294                         { PL_copline = (line_t)IVAL($1);
 295                             $$ = block_end($3,
 296                                    newCONDOP(0, $4, scope($6), $7));
 297                           TOKEN_GETMAD($1,$$,'I');
 298                           TOKEN_GETMAD($2,$$,'(');
 299                           TOKEN_GETMAD($5,$$,')');
 300                         }
 301         ;
 302
 303 /* Cases for a switch statement */
 304 case    :       WHEN '(' remember mexpr ')' mblock
 305         { $$ = block_end($3,
 306                 newWHENOP($4, scope($6))); }
 307         |       DEFAULT block
 308         { $$ = newWHENOP(0, scope($2)); }
 309         ;
 310
 311 /* Continue blocks */
 312 cont    :       /* NULL */
 313                         { $$ = Nullop; }
 314         |       CONTINUE block
 315                         { $$ = scope($2);
 316                           TOKEN_GETMAD($1,$$,'o');
 317                         }
 318         ;
 319
 320 /* Loops: while, until, for, and a bare block */
 321 loop    :       label WHILE '(' remember texpr ')' mintro mblock cont
 322                         { OP *innerop;
 323                           PL_copline = (line_t)$2;
 324                             $$ = block_end($4,
 325                                    newSTATEOP(0, PVAL($1),
 326                                      innerop = newWHILEOP(0, 1, (LOOP*)Nullop,
 327                                                 IVAL($2), $5, $8, $9, $7)));
 328                           TOKEN_GETMAD($1,innerop,'L');
 329                           TOKEN_GETMAD($2,innerop,'W');
 330                           TOKEN_GETMAD($3,innerop,'(');
 331                           TOKEN_GETMAD($6,innerop,')');
 332                         }
 333
 334         |       label UNTIL '(' remember iexpr ')' mintro mblock cont
 335                         { OP *innerop;
 336                           PL_copline = (line_t)$2;
 337                             $$ = block_end($4,
 338                                    newSTATEOP(0, PVAL($1),
 339                                      innerop = newWHILEOP(0, 1, (LOOP*)Nullop,
 340                                                 IVAL($2), $5, $8, $9, $7)));
 341                           TOKEN_GETMAD($1,innerop,'L');
 342                           TOKEN_GETMAD($2,innerop,'W');
 343                           TOKEN_GETMAD($3,innerop,'(');
 344                           TOKEN_GETMAD($6,innerop,')');
 345                         }
 346         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 347                         { OP *innerop;
 348                           $$ = block_end($4,
 349                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 350                                             $5, $7, $9, $10));
 351                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 352                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 353                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'d');
 354                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,'(');
 355                           TOKEN_GETMAD($8,((LISTOP*)innerop)->op_first->op_sibling,')');
 356                         }
 357         |       label FOR scalar '(' remember mexpr ')' mblock cont
 358                         { OP *innerop;
 359                           $$ = block_end($5,
 360                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 361                                     mod($3, OP_ENTERLOOP), $6, $8, $9));
 362                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 363                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 364                           TOKEN_GETMAD($4,((LISTOP*)innerop)->op_first->op_sibling,'(');
 365                           TOKEN_GETMAD($7,((LISTOP*)innerop)->op_first->op_sibling,')');
 366                         }
 367         |       label FOR '(' remember mexpr ')' mblock cont
 368                         { OP *innerop;
 369                           $$ = block_end($4,
 370                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 371                                                     Nullop, $5, $7, $8));
 372                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 373                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 374                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'(');
 375                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,')');
 376                         }
 377         |       label FOR '(' remember mnexpr ';' texpr ';' mintro mnexpr ')'
 378                     mblock
 379                         /* basically fake up an initialize-while lineseq */
 380                         { OP *forop;
 381                           PL_copline = (line_t)IVAL($2);
 382                           forop = newSTATEOP(0, PVAL($1),
 383                                             newWHILEOP(0, 1, (LOOP*)Nullop,
 384                                                 IVAL($2), scalar($7),
 385                                                 $12, $10, $9));
 386 #ifdef MAD
 387                           if (!$5)
 388                                 $5 = newOP(OP_NULL, 0);
 389                           forop = newUNOP(OP_NULL, 0, append_elem(OP_LINESEQ,
 390                                 newSTATEOP(0,
 391                                            (($1)->tk_lval.pval
 392                                            ?savepv(($1)->tk_lval.pval):Nullch),
 393                                            $5),
 394                                 forop));
 395
 396                           token_getmad($2,forop,'3');
 397                           token_getmad($3,forop,'(');
 398                           token_getmad($6,forop,'1');
 399                           token_getmad($8,forop,'2');
 400                           token_getmad($11,forop,')');
 401                           token_getmad($1,forop,'L');
 402 #else
 403                           if ($5) {
 404                                 forop = append_elem(OP_LINESEQ,
 405                                         newSTATEOP(0, ($1?savepv($1):Nullch),
 406                                                    $5),
 407                                         forop);
 408                           }
 409
 410
 411 #endif
 412                           $$ = block_end($4, forop); }
 413         |       label block cont  /* a block is a loop that happens once */
 414                         { $$ = newSTATEOP(0, PVAL($1),
 415                                  newWHILEOP(0, 1, (LOOP*)Nullop,
 416                                             NOLINE, Nullop, $2, $3, 0));
 417                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 418         ;
 419
 420 /* Switch blocks */
 421 switch  :       label GIVEN '(' remember mydefsv mexpr ')' mblock
 422                         { PL_copline = (line_t) $2;
 423                             $$ = block_end($4,
 424                                 newSTATEOP(0, PVAL($1),
 425                                     newGIVENOP($6, scope($8),
 426                                         (PADOFFSET) $5) )); }
 427         ;
 428
 429 /* determine whether there are any new my declarations */
 430 mintro  :       /* NULL */
 431                         { $$ = (PL_min_intro_pending &&
 432                             PL_max_intro_pending >=  PL_min_intro_pending);
 433                           intro_my(); }
 434
 435 /* Normal expression */
 436 nexpr   :       /* NULL */
 437                         { $$ = Nullop; }
 438         |       sideff
 439         ;
 440
 441 /* Boolean expression */
 442 texpr   :       /* NULL means true */
 443                         { YYSTYPE tmplval;
 444                           (void)scan_num("1", &tmplval);
 445                           $$ = tmplval.opval; }
 446         |       expr
 447         ;
 448
 449 /* Inverted boolean expression */
 450 iexpr   :       expr
 451                         { $$ = invert(scalar($1)); }
 452         ;
 453
 454 /* Expression with its own lexical scope */
 455 mexpr   :       expr
 456                         { $$ = $1; intro_my(); }
 457         ;
 458
 459 mnexpr  :       nexpr
 460                         { $$ = $1; intro_my(); }
 461         ;
 462
 463 miexpr  :       iexpr
 464                         { $$ = $1; intro_my(); }
 465         ;
 466
 467 /* Optional "MAIN:"-style loop labels */
 468 label   :       /* empty */
 469                         {
 470 #ifdef MAD
 471                           YYSTYPE tmplval;
 472                           tmplval.pval = Nullch;
 473                           $$ = newTOKEN(OP_NULL, tmplval, 0);
 474 #else
 475                           $$ = Nullch;
 476 #endif
 477                         }
 478         |       LABEL
 479         ;
 480
 481 /* Some kind of declaration - just hang on peg in the parse tree */
 482 decl    :       format
 483                         { $$ = $1; }
 484         |       subrout
 485                         { $$ = $1; }
 486         |       mysubrout
 487                         { $$ = $1; }
 488         |       package
 489                         { $$ = $1; }
 490         |       use
 491                         { $$ = $1; }
 492
 493     /* these two are only used by MAD */
 494
 495         |       peg
 496                         { $$ = $1; }
 497         ;
 498
 499 peg     :       PEG
 500                         { $$ = newOP(OP_NULL,0);
 501                           TOKEN_GETMAD($1,$$,'p');
 502                         }
 503         ;
 504
 505 format  :       FORMAT startformsub formname block
 506                         { SvREFCNT_inc(PL_compcv);
 507 #ifdef MAD
 508                           $$ = newFORM($2, $3, $4);
 509                           prepend_madprops($1->tk_mad, $$, 'F');
 510                           $1->tk_mad = 0;
 511                           token_free($1);
 512 #else
 513                           newFORM($2, $3, $4);
 514 #endif
 515                         }
 516         ;
 517
 518 formname:       WORD            { $$ = $1; }
 519         |       /* NULL */      { $$ = Nullop; }
 520         ;
 521
 522 /* Unimplemented "my sub foo { }" */
 523 mysubrout:      MYSUB startsub subname proto subattrlist subbody
 524                         { SvREFCNT_inc(PL_compcv);
 525 #ifdef MAD
 526                           $$ = newMYSUB($2, $3, $4, $5, $6);
 527                           token_getmad($1,$$,'d');
 528 #else
 529                           newMYSUB($2, $3, $4, $5, $6);
 530 #endif
 531                         }
 532         ;
 533
 534 /* Subroutine definition */
 535 subrout :       SUB startsub subname proto subattrlist subbody
 536                         { SvREFCNT_inc(PL_compcv);
 537 #ifdef MAD
 538                           OP* o = newSVOP(OP_ANONCODE, 0,
 539                             (SV*)newATTRSUB($2, $3, $4, $5, $6));
 540                           $$ = newOP(OP_NULL,0);
 541                           op_getmad(o,$$,'&');
 542                           op_getmad($3,$$,'n');
 543                           op_getmad($4,$$,'s');
 544                           op_getmad($5,$$,'a');
 545                           token_getmad($1,$$,'d');
 546                           append_madprops($6->op_madprop, $$, 0);
 547                           $6->op_madprop = 0;
 548 #else
 549                           newATTRSUB($2, $3, $4, $5, $6);
 550                           $$ = Nullop;
 551 #endif
 552                         }
 553         ;
 554
 555 startsub:       /* NULL */      /* start a regular subroutine scope */
 556                         { $$ = start_subparse(FALSE, 0);
 557                             SAVEFREESV(PL_compcv); }
 558
 559         ;
 560
 561 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 562                         { $$ = start_subparse(FALSE, CVf_ANON);
 563                             SAVEFREESV(PL_compcv); }
 564         ;
 565
 566 startformsub:   /* NULL */      /* start a format subroutine scope */
 567                         { $$ = start_subparse(TRUE, 0);
 568                             SAVEFREESV(PL_compcv); }
 569         ;
 570
 571 /* Name of a subroutine - must be a bareword, could be special */
 572 subname :       WORD    { const char *const name = SvPV_nolen_const(((SVOP*)$1)->op_sv);
 573                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
 574                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
 575                               || strEQ(name, "UNITCHECK"))
 576                               CvSPECIAL_on(PL_compcv);
 577                           $$ = $1; }
 578         ;
 579
 580 /* Subroutine prototype */
 581 proto   :       /* NULL */
 582                         { $$ = Nullop; }
 583         |       THING
 584         ;
 585
 586 /* Optional list of subroutine attributes */
 587 subattrlist:    /* NULL */
 588                         { $$ = Nullop; }
 589         |       COLONATTR THING
 590                         { $$ = $2;
 591                           TOKEN_GETMAD($1,$$,':');
 592                         }
 593         |       COLONATTR
 594                         { $$ = IF_MAD(
 595                                     newOP(OP_NULL, 0),
 596                                     Nullop
 597                                 );
 598                           TOKEN_GETMAD($1,$$,':');
 599                         }
 600         ;
 601
 602 /* List of attributes for a "my" variable declaration */
 603 myattrlist:     COLONATTR THING
 604                         { $$ = $2;
 605                           TOKEN_GETMAD($1,$$,':');
 606                         }
 607         |       COLONATTR
 608                         { $$ = IF_MAD(
 609                                     newOP(OP_NULL, 0),
 610                                     Nullop
 611                                 );
 612                           TOKEN_GETMAD($1,$$,':');
 613                         }
 614         ;
 615
 616 /* Subroutine body - either null or a block */
 617 subbody :       block   { $$ = $1; }
 618         |       ';'     { $$ = IF_MAD(
 619                                     newOP(OP_NULL,0),
 620                                     Nullop
 621                                 );
 622                           PL_expect = XSTATE;
 623                           TOKEN_GETMAD($1,$$,';');
 624                         }
 625         ;
 626
 627 package :       PACKAGE WORD ';'
 628                         {
 629 #ifdef MAD
 630                           $$ = package($2);
 631                           token_getmad($1,$$,'o');
 632                           token_getmad($3,$$,';');
 633 #else
 634                           package($2);
 635 #endif
 636                         }
 637         ;
 638
 639 use     :       USE startsub
 640                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
 641                     WORD WORD listexpr ';'
 642                         { SvREFCNT_inc(PL_compcv);
 643 #ifdef MAD
 644                           $$ = utilize(IVAL($1), $2, $4, $5, $6);
 645                           token_getmad($1,$$,'o');
 646                           token_getmad($7,$$,';');
 647                           if (PL_rsfp_filters && AvFILLp(PL_rsfp_filters) >= 0)
 648                               append_madprops(newMADPROP('!', MAD_PV, "", 0), $$, 0);
 649 #else
 650                           utilize(IVAL($1), $2, $4, $5, $6);
 651 #endif
 652                         }
 653         ;
 654
 655 /* Ordinary expressions; logical combinations */
 656 expr    :       expr ANDOP expr
 657                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
 658                           TOKEN_GETMAD($2,$$,'o');
 659                         }
 660         |       expr OROP expr
 661                         { $$ = newLOGOP(IVAL($2), 0, $1, $3);
 662                           TOKEN_GETMAD($2,$$,'o');
 663                         }
 664         |       expr DOROP expr
 665                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
 666                           TOKEN_GETMAD($2,$$,'o');
 667                         }
 668         |       argexpr %prec PREC_LOW
 669         ;
 670
 671 /* Expressions are a list of terms joined by commas */
 672 argexpr :       argexpr ','
 673                         {
 674 #ifdef MAD
 675                           OP* op = newNULLLIST();
 676                           token_getmad($2,op,',');
 677                           $$ = append_elem(OP_LIST, $1, op);
 678 #else
 679                           $$ = $1;
 680 #endif
 681                         }
 682         |       argexpr ',' term
 683                         {
 684                           DO_MAD(
 685                               $3 = newUNOP(OP_NULL, 0, $3);
 686                               token_getmad($2,$3,',');
 687                           )
 688                           $$ = append_elem(OP_LIST, $1, $3);
 689                         }
 690         |       term %prec PREC_LOW
 691         ;
 692
 693 /* List operators */
 694 listop  :       LSTOP indirob argexpr /* map {...} @args or print $fh @args */
 695                         { $$ = convert(IVAL($1), OPf_STACKED,
 696                                 prepend_elem(OP_LIST, newGVREF(IVAL($1),$2), $3) );
 697                           TOKEN_GETMAD($1,$$,'o');
 698                         }
 699         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
 700                         { $$ = convert(IVAL($1), OPf_STACKED,
 701                                 prepend_elem(OP_LIST, newGVREF(IVAL($1),$3), $4) );
 702                           TOKEN_GETMAD($1,$$,'o');
 703                           TOKEN_GETMAD($2,$$,'(');
 704                           TOKEN_GETMAD($5,$$,')');
 705                         }
 706         |       term ARROW method '(' listexprcom ')' /* $foo->bar(list) */
 707                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 708                                 append_elem(OP_LIST,
 709                                     prepend_elem(OP_LIST, scalar($1), $5),
 710                                     newUNOP(OP_METHOD, 0, $3)));
 711                           TOKEN_GETMAD($2,$$,'A');
 712                           TOKEN_GETMAD($4,$$,'(');
 713                           TOKEN_GETMAD($6,$$,')');
 714                         }
 715         |       term ARROW method                     /* $foo->bar */
 716                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 717                                 append_elem(OP_LIST, scalar($1),
 718                                     newUNOP(OP_METHOD, 0, $3)));
 719                           TOKEN_GETMAD($2,$$,'A');
 720                         }
 721         |       METHOD indirob listexpr              /* new Class @args */
 722                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 723                                 append_elem(OP_LIST,
 724                                     prepend_elem(OP_LIST, $2, $3),
 725                                     newUNOP(OP_METHOD, 0, $1)));
 726                         }
 727         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
 728                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 729                                 append_elem(OP_LIST,
 730                                     prepend_elem(OP_LIST, $2, $4),
 731                                     newUNOP(OP_METHOD, 0, $1)));
 732                           TOKEN_GETMAD($3,$$,'(');
 733                           TOKEN_GETMAD($5,$$,')');
 734                         }
 735         |       LSTOP listexpr                       /* print @args */
 736                         { $$ = convert(IVAL($1), 0, $2);
 737                           TOKEN_GETMAD($1,$$,'o');
 738                         }
 739         |       FUNC '(' listexprcom ')'             /* print (@args) */
 740                         { $$ = convert(IVAL($1), 0, $3);
 741                           TOKEN_GETMAD($1,$$,'o');
 742                           TOKEN_GETMAD($2,$$,'(');
 743                           TOKEN_GETMAD($4,$$,')');
 744                         }
 745         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
 746                         { SvREFCNT_inc(PL_compcv);
 747                           $3 = newANONATTRSUB($2, 0, Nullop, $3); }
 748                     listexpr            %prec LSTOP  /* ... @bar */
 749                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 750                                  append_elem(OP_LIST,
 751                                    prepend_elem(OP_LIST, $3, $5), $1));
 752                         }
 753         ;
 754
 755 /* Names of methods. May use $object->$methodname */
 756 method  :       METHOD
 757         |       scalar
 758         ;
 759
 760 /* Some kind of subscripted expression */
 761 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
 762                         /* In this and all the hash accessors, ';' is
 763                          * provided by the tokeniser */
 764                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
 765                             PL_expect = XOPERATOR;
 766                           TOKEN_GETMAD($2,$$,'{');
 767                           TOKEN_GETMAD($4,$$,';');
 768                           TOKEN_GETMAD($5,$$,'}');
 769                         }
 770         |       scalar '[' expr ']'          /* $array[$element] */
 771                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
 772                           TOKEN_GETMAD($2,$$,'[');
 773                           TOKEN_GETMAD($4,$$,']');
 774                         }
 775         |       term ARROW '[' expr ']'      /* somearef->[$element] */
 776                         { $$ = newBINOP(OP_AELEM, 0,
 777                                         ref(newAVREF($1),OP_RV2AV),
 778                                         scalar($4));
 779                           TOKEN_GETMAD($2,$$,'a');
 780                           TOKEN_GETMAD($3,$$,'[');
 781                           TOKEN_GETMAD($5,$$,']');
 782                         }
 783         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
 784                         { $$ = newBINOP(OP_AELEM, 0,
 785                                         ref(newAVREF($1),OP_RV2AV),
 786                                         scalar($3));
 787                           TOKEN_GETMAD($2,$$,'[');
 788                           TOKEN_GETMAD($4,$$,']');
 789                         }
 790         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
 791                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 792                             PL_expect = XOPERATOR;
 793                           TOKEN_GETMAD($2,$$,'{');
 794                           TOKEN_GETMAD($4,$$,';');
 795                           TOKEN_GETMAD($5,$$,'}');
 796                         }
 797         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
 798                         { $$ = newBINOP(OP_HELEM, 0,
 799                                         ref(newHVREF($1),OP_RV2HV),
 800                                         jmaybe($4));
 801                             PL_expect = XOPERATOR;
 802                           TOKEN_GETMAD($2,$$,'a');
 803                           TOKEN_GETMAD($3,$$,'{');
 804                           TOKEN_GETMAD($5,$$,';');
 805                           TOKEN_GETMAD($6,$$,'}');
 806                         }
 807         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
 808                         { $$ = newBINOP(OP_HELEM, 0,
 809                                         ref(newHVREF($1),OP_RV2HV),
 810                                         jmaybe($3));
 811                             PL_expect = XOPERATOR;
 812                           TOKEN_GETMAD($2,$$,'{');
 813                           TOKEN_GETMAD($4,$$,';');
 814                           TOKEN_GETMAD($5,$$,'}');
 815                         }
 816         |       term ARROW '(' ')'          /* $subref->() */
 817                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 818                                    newCVREF(0, scalar($1)));
 819                           TOKEN_GETMAD($2,$$,'a');
 820                           TOKEN_GETMAD($3,$$,'(');
 821                           TOKEN_GETMAD($4,$$,')');
 822                         }
 823         |       term ARROW '(' expr ')'     /* $subref->(@args) */
 824                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 825                                    append_elem(OP_LIST, $4,
 826                                        newCVREF(0, scalar($1))));
 827                           TOKEN_GETMAD($2,$$,'a');
 828                           TOKEN_GETMAD($3,$$,'(');
 829                           TOKEN_GETMAD($5,$$,')');
 830                         }
 831
 832         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
 833                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 834                                    append_elem(OP_LIST, $3,
 835                                                newCVREF(0, scalar($1))));
 836                           TOKEN_GETMAD($2,$$,'(');
 837                           TOKEN_GETMAD($4,$$,')');
 838                         }
 839         |       subscripted '(' ')'        /* $foo->{bar}->() */
 840                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 841                                    newCVREF(0, scalar($1)));
 842                           TOKEN_GETMAD($2,$$,'(');
 843                           TOKEN_GETMAD($3,$$,')');
 844                         }
 845         |       '(' expr ')' '[' expr ']'            /* list slice */
 846                         { $$ = newSLICEOP(0, $5, $2);
 847                           TOKEN_GETMAD($1,$$,'(');
 848                           TOKEN_GETMAD($3,$$,')');
 849                           TOKEN_GETMAD($4,$$,'[');
 850                           TOKEN_GETMAD($6,$$,']');
 851                         }
 852         |       '(' ')' '[' expr ']'                 /* empty list slice! */
 853                         { $$ = newSLICEOP(0, $4, Nullop);
 854                           TOKEN_GETMAD($1,$$,'(');
 855                           TOKEN_GETMAD($2,$$,')');
 856                           TOKEN_GETMAD($3,$$,'[');
 857                           TOKEN_GETMAD($5,$$,']');
 858                         }
 859     ;
 860
 861 /* Binary operators between terms */
 862 termbinop:      term ASSIGNOP term                     /* $x = $y */
 863                         { $$ = newASSIGNOP(OPf_STACKED, $1, IVAL($2), $3);
 864                           TOKEN_GETMAD($2,$$,'o');
 865                         }
 866         |       term POWOP term                        /* $x ** $y */
 867                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 868                           TOKEN_GETMAD($2,$$,'o');
 869                         }
 870         |       term MULOP term                        /* $x * $y, $x x $y */
 871                         {   if (IVAL($2) != OP_REPEAT)
 872                                 scalar($1);
 873                             $$ = newBINOP(IVAL($2), 0, $1, scalar($3));
 874                           TOKEN_GETMAD($2,$$,'o');
 875                         }
 876         |       term ADDOP term                        /* $x + $y */
 877                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 878                           TOKEN_GETMAD($2,$$,'o');
 879                         }
 880         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
 881                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 882                           TOKEN_GETMAD($2,$$,'o');
 883                         }
 884         |       term RELOP term                        /* $x > $y, etc. */
 885                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 886                           TOKEN_GETMAD($2,$$,'o');
 887                         }
 888         |       term EQOP term                         /* $x == $y, $x eq $y */
 889                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 890                           TOKEN_GETMAD($2,$$,'o');
 891                         }
 892         |       term BITANDOP term                     /* $x & $y */
 893                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 894                           TOKEN_GETMAD($2,$$,'o');
 895                         }
 896         |       term BITOROP term                      /* $x | $y */
 897                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 898                           TOKEN_GETMAD($2,$$,'o');
 899                         }
 900         |       term DOTDOT term                       /* $x..$y, $x...$y */
 901                         {
 902                           $$ = newRANGE(IVAL($2), scalar($1), scalar($3));
 903                           DO_MAD(
 904                               UNOP *op;
 905                               op = (UNOP*)$$;
 906                               op = (UNOP*)op->op_first; /* get to flop */
 907                               op = (UNOP*)op->op_first; /* get to flip */
 908                               op = (UNOP*)op->op_first; /* get to range */
 909                               token_getmad($2,(OP*)op,'o');
 910                             )
 911                         }
 912         |       term ANDAND term                       /* $x && $y */
 913                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
 914                           TOKEN_GETMAD($2,$$,'o');
 915                         }
 916         |       term OROR term                         /* $x || $y */
 917                         { $$ = newLOGOP(OP_OR, 0, $1, $3);
 918                           TOKEN_GETMAD($2,$$,'o');
 919                         }
 920         |       term DORDOR term                       /* $x // $y */
 921                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
 922                           TOKEN_GETMAD($2,$$,'o');
 923                         }
 924         |       term MATCHOP term                      /* $x =~ /$y/ */
 925                         { $$ = bind_match(IVAL($2), $1, $3);
 926                           TOKEN_GETMAD($2,
 927                                 ($$->op_type == OP_NOT
 928                                     ? ((UNOP*)$$)->op_first : $$),
 929                                 '~');
 930                         }
 931     ;
 932
 933 /* Unary operators and terms */
 934 termunop : '-' term %prec UMINUS                       /* -$x */
 935                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2));
 936                           TOKEN_GETMAD($1,$$,'o');
 937                         }
 938         |       '+' term %prec UMINUS                  /* +$x */
 939                         { $$ = IF_MAD(
 940                                     newUNOP(OP_NULL, 0, $2),
 941                                     $2
 942                                 );
 943                           TOKEN_GETMAD($1,$$,'+');
 944                         }
 945         |       '!' term                               /* !$x */
 946                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
 947                           TOKEN_GETMAD($1,$$,'o');
 948                         }
 949         |       '~' term                               /* ~$x */
 950                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));
 951                           TOKEN_GETMAD($1,$$,'o');
 952                         }
 953         |       term POSTINC                           /* $x++ */
 954                         { $$ = newUNOP(OP_POSTINC, 0,
 955                                         mod(scalar($1), OP_POSTINC));
 956                           TOKEN_GETMAD($2,$$,'o');
 957                         }
 958         |       term POSTDEC                           /* $x-- */
 959                         { $$ = newUNOP(OP_POSTDEC, 0,
 960                                         mod(scalar($1), OP_POSTDEC));
 961                           TOKEN_GETMAD($2,$$,'o');
 962                         }
 963         |       PREINC term                            /* ++$x */
 964                         { $$ = newUNOP(OP_PREINC, 0,
 965                                         mod(scalar($2), OP_PREINC));
 966                           TOKEN_GETMAD($1,$$,'o');
 967                         }
 968         |       PREDEC term                            /* --$x */
 969                         { $$ = newUNOP(OP_PREDEC, 0,
 970                                         mod(scalar($2), OP_PREDEC));
 971                           TOKEN_GETMAD($1,$$,'o');
 972                         }
 973
 974     ;
 975
 976 /* Constructors for anonymous data */
 977 anonymous:      '[' expr ']'
 978                         { $$ = newANONLIST($2);
 979                           TOKEN_GETMAD($1,$$,'[');
 980                           TOKEN_GETMAD($3,$$,']');
 981                         }
 982         |       '[' ']'
 983                         { $$ = newANONLIST(Nullop);
 984                           TOKEN_GETMAD($1,$$,'[');
 985                           TOKEN_GETMAD($2,$$,']');
 986                         }
 987         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
 988                         { $$ = newANONHASH($2);
 989                           TOKEN_GETMAD($1,$$,'{');
 990                           TOKEN_GETMAD($3,$$,';');
 991                           TOKEN_GETMAD($4,$$,'}');
 992                         }
 993         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
 994                         { $$ = newANONHASH(Nullop);
 995                           TOKEN_GETMAD($1,$$,'{');
 996                           TOKEN_GETMAD($2,$$,';');
 997                           TOKEN_GETMAD($3,$$,'}');
 998                         }
 999         |       ANONSUB startanonsub proto subattrlist block    %prec '('
1000                         { SvREFCNT_inc(PL_compcv);
1001                           $$ = newANONATTRSUB($2, $3, $4, $5);
1002                           TOKEN_GETMAD($1,$$,'o');
1003                           OP_GETMAD($3,$$,'s');
1004                           OP_GETMAD($4,$$,'a');
1005                         }
1006
1007     ;
1008
1009 /* Things called with "do" */
1010 termdo  :       DO term %prec UNIOP                     /* do $filename */
1011                         { $$ = dofile($2, IVAL($1));
1012                           TOKEN_GETMAD($1,$$,'o');
1013                         }
1014         |       DO block        %prec '('               /* do { code */
1015                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2));
1016                           TOKEN_GETMAD($1,$$,'D');
1017                         }
1018         |       DO WORD '(' ')'                         /* do somesub() */
1019                         { $$ = newUNOP(OP_ENTERSUB,
1020                             OPf_SPECIAL|OPf_STACKED,
1021                             prepend_elem(OP_LIST,
1022                                 scalar(newCVREF(
1023                                     (OPpENTERSUB_AMPER<<8),
1024                                     scalar($2)
1025                                 )),Nullop)); dep();
1026                           TOKEN_GETMAD($1,$$,'o');
1027                           TOKEN_GETMAD($3,$$,'(');
1028                           TOKEN_GETMAD($4,$$,')');
1029                         }
1030         |       DO WORD '(' expr ')'                    /* do somesub(@args) */
1031                         { $$ = newUNOP(OP_ENTERSUB,
1032                             OPf_SPECIAL|OPf_STACKED,
1033                             append_elem(OP_LIST,
1034                                 $4,
1035                                 scalar(newCVREF(
1036                                     (OPpENTERSUB_AMPER<<8),
1037                                     scalar($2)
1038                                 )))); dep();
1039                           TOKEN_GETMAD($1,$$,'o');
1040                           TOKEN_GETMAD($3,$$,'(');
1041                           TOKEN_GETMAD($5,$$,')');
1042                         }
1043         |       DO scalar '(' ')'                      /* do $subref () */
1044                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1045                             prepend_elem(OP_LIST,
1046                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();
1047                           TOKEN_GETMAD($1,$$,'o');
1048                           TOKEN_GETMAD($3,$$,'(');
1049                           TOKEN_GETMAD($4,$$,')');
1050                         }
1051         |       DO scalar '(' expr ')'                 /* do $subref (@args) */
1052                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1053                             prepend_elem(OP_LIST,
1054                                 $4,
1055                                 scalar(newCVREF(0,scalar($2))))); dep();
1056                           TOKEN_GETMAD($1,$$,'o');
1057                           TOKEN_GETMAD($3,$$,'(');
1058                           TOKEN_GETMAD($5,$$,')');
1059                         }
1060
1061         ;
1062
1063 term    :       termbinop
1064         |       termunop
1065         |       anonymous
1066         |       termdo
1067         |       term '?' term ':' term
1068                         { $$ = newCONDOP(0, $1, $3, $5);
1069                           TOKEN_GETMAD($2,$$,'?');
1070                           TOKEN_GETMAD($4,$$,':');
1071                         }
1072         |       REFGEN term                          /* \$x, \@y, \%z */
1073                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN));
1074                           TOKEN_GETMAD($1,$$,'o');
1075                         }
1076         |       myattrterm      %prec UNIOP
1077                         { $$ = $1; }
1078         |       LOCAL term      %prec UNIOP
1079                         { $$ = localize($2,IVAL($1));
1080                           TOKEN_GETMAD($1,$$,'d');
1081                         }
1082         |       '(' expr ')'
1083                         { $$ = sawparens(IF_MAD(newUNOP(OP_NULL,0,$2), $2));
1084                           TOKEN_GETMAD($1,$$,'(');
1085                           TOKEN_GETMAD($3,$$,')');
1086                         }
1087         |       '(' ')'
1088                         { $$ = sawparens(newNULLLIST());
1089                           TOKEN_GETMAD($1,$$,'(');
1090                           TOKEN_GETMAD($2,$$,')');
1091                         }
1092         |       scalar  %prec '('
1093                         { $$ = $1; }
1094         |       star    %prec '('
1095                         { $$ = $1; }
1096         |       hsh     %prec '('
1097                         { $$ = $1; }
1098         |       ary     %prec '('
1099                         { $$ = $1; }
1100         |       arylen  %prec '('                    /* $#x, $#{ something } */
1101                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1102         |       subscripted
1103                         { $$ = $1; }
1104         |       ary '[' expr ']'                     /* array slice */
1105                         { $$ = prepend_elem(OP_ASLICE,
1106                                 newOP(OP_PUSHMARK, 0),
1107                                     newLISTOP(OP_ASLICE, 0,
1108                                         list($3),
1109                                         ref($1, OP_ASLICE)));
1110                           TOKEN_GETMAD($2,$$,'[');
1111                           TOKEN_GETMAD($4,$$,']');
1112                         }
1113         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
1114                         { $$ = prepend_elem(OP_HSLICE,
1115                                 newOP(OP_PUSHMARK, 0),
1116                                     newLISTOP(OP_HSLICE, 0,
1117                                         list($3),
1118                                         ref(oopsHV($1), OP_HSLICE)));
1119                             PL_expect = XOPERATOR;
1120                           TOKEN_GETMAD($2,$$,'{');
1121                           TOKEN_GETMAD($4,$$,';');
1122                           TOKEN_GETMAD($5,$$,'}');
1123                         }
1124         |       THING   %prec '('
1125                         { $$ = $1; }
1126         |       amper                                /* &foo; */
1127                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1128         |       amper '(' ')'                        /* &foo() */
1129                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1130                           TOKEN_GETMAD($2,$$,'(');
1131                           TOKEN_GETMAD($3,$$,')');
1132                         }
1133         |       amper '(' expr ')'                   /* &foo(@args) */
1134                         {
1135                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1136                                 append_elem(OP_LIST, $3, scalar($1)));
1137                           DO_MAD(
1138                               OP* op = $$;
1139                               if (op->op_type == OP_CONST) { /* defeat const fold */
1140                                 op = (OP*)op->op_madprop->mad_val;
1141                               }
1142                               token_getmad($2,op,'(');
1143                               token_getmad($4,op,')');
1144                           )
1145                         }
1146         |       NOAMP WORD listexpr                  /* foo(@args) */
1147                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1148                             append_elem(OP_LIST, $3, scalar($2)));
1149                           TOKEN_GETMAD($1,$$,'o');
1150                         }
1151         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1152                         { $$ = newOP(IVAL($1), OPf_SPECIAL);
1153                             PL_hints |= HINT_BLOCK_SCOPE;
1154                           TOKEN_GETMAD($1,$$,'o');
1155                         }
1156         |       LOOPEX term
1157                         { $$ = newLOOPEX(IVAL($1),$2);
1158                           TOKEN_GETMAD($1,$$,'o');
1159                         }
1160         |       NOTOP argexpr                        /* not $foo */
1161                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1162                           TOKEN_GETMAD($1,$$,'o');
1163                         }
1164         |       UNIOP                                /* Unary op, $_ implied */
1165                         { $$ = newOP(IVAL($1), 0);
1166                           TOKEN_GETMAD($1,$$,'o');
1167                         }
1168         |       UNIOP block                          /* eval { foo }* */
1169                         { $$ = newUNOP(IVAL($1), 0, $2);
1170                           TOKEN_GETMAD($1,$$,'o');
1171                         }
1172         |       UNIOP term                           /* Unary op */
1173                         { $$ = newUNOP(IVAL($1), 0, $2);
1174                           TOKEN_GETMAD($1,$$,'o');
1175                         }
1176         |       REQUIRE                              /* require, $_ implied *//* FIMXE for MAD needed? */
1177                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0); }
1178         |       REQUIRE term                         /* require Foo *//* FIMXE for MAD needed? */
1179                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2); }
1180         |       UNIOPSUB
1181                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1182         |       UNIOPSUB term                        /* Sub treated as unop */
1183                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1184                             append_elem(OP_LIST, $2, scalar($1))); }
1185         |       FUNC0                                /* Nullary operator */
1186                         { $$ = newOP(IVAL($1), 0);
1187                           TOKEN_GETMAD($1,$$,'o');
1188                         }
1189         |       FUNC0 '(' ')'
1190                         { $$ = newOP(IVAL($1), 0);
1191                           TOKEN_GETMAD($1,$$,'o');
1192                           TOKEN_GETMAD($2,$$,'(');
1193                           TOKEN_GETMAD($3,$$,')');
1194                         }
1195         |       FUNC0SUB                             /* Sub treated as nullop */
1196                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1197                                 scalar($1)); }
1198         |       FUNC1 '(' ')'                        /* not () */
1199                         { $$ = (IVAL($1) == OP_NOT)
1200                             ? newUNOP(IVAL($1), 0, newSVOP(OP_CONST, 0, newSViv(0)))
1201                             : newOP(IVAL($1), OPf_SPECIAL);
1202
1203                           TOKEN_GETMAD($1,$$,'o');
1204                           TOKEN_GETMAD($2,$$,'(');
1205                           TOKEN_GETMAD($3,$$,')');
1206                         }
1207         |       FUNC1 '(' expr ')'                   /* not($foo) */
1208                         { $$ = newUNOP(IVAL($1), 0, $3);
1209                           TOKEN_GETMAD($1,$$,'o');
1210                           TOKEN_GETMAD($2,$$,'(');
1211                           TOKEN_GETMAD($4,$$,')');
1212                         }
1213         |       PMFUNC '(' argexpr ')'          /* m//, s///, tr/// */
1214                         { $$ = pmruntime($1, $3, 1);
1215                           TOKEN_GETMAD($2,$$,'(');
1216                           TOKEN_GETMAD($4,$$,')');
1217                         }
1218         |       WORD
1219         |       listop
1220         ;
1221
1222 /* "my" declarations, with optional attributes */
1223 myattrterm:     MY myterm myattrlist
1224                         { $$ = my_attrs($2,$3);
1225                           DO_MAD(
1226                               token_getmad($1,$$,'d');
1227                               append_madprops($3->op_madprop, $$, 'a');
1228                               $3->op_madprop = 0;
1229                           )
1230                         }
1231         |       MY myterm
1232                         { $$ = localize($2,IVAL($1));
1233                           TOKEN_GETMAD($1,$$,'d');
1234                         }
1235         ;
1236
1237 /* Things that can be "my"'d */
1238 myterm  :       '(' expr ')'
1239                         { $$ = sawparens($2);
1240                           TOKEN_GETMAD($1,$$,'(');
1241                           TOKEN_GETMAD($3,$$,')');
1242                         }
1243         |       '(' ')'
1244                         { $$ = sawparens(newNULLLIST());
1245                           TOKEN_GETMAD($1,$$,'(');
1246                           TOKEN_GETMAD($2,$$,')');
1247                         }
1248         |       scalar  %prec '('
1249                         { $$ = $1; }
1250         |       hsh     %prec '('
1251                         { $$ = $1; }
1252         |       ary     %prec '('
1253                         { $$ = $1; }
1254         ;
1255
1256 /* Basic list expressions */
1257 listexpr:       /* NULL */ %prec PREC_LOW
1258                         { $$ = Nullop; }
1259         |       argexpr    %prec PREC_LOW
1260                         { $$ = $1; }
1261         ;
1262
1263 listexprcom:    /* NULL */
1264                         { $$ = Nullop; }
1265         |       expr
1266                         { $$ = $1; }
1267         |       expr ','
1268                         {
1269 #ifdef MAD
1270                           OP* op = newNULLLIST();
1271                           token_getmad($2,op,',');
1272                           $$ = append_elem(OP_LIST, $1, op);
1273 #else
1274                           $$ = $1;
1275 #endif
1276
1277                         }
1278         ;
1279
1280 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1281    lexical */
1282 my_scalar:      scalar
1283                         { PL_in_my = 0; $$ = my($1); }
1284         ;
1285
1286 amper   :       '&' indirob
1287                         { $$ = newCVREF(IVAL($1),$2);
1288                           TOKEN_GETMAD($1,$$,'&');
1289                         }
1290         ;
1291
1292 scalar  :       '$' indirob
1293                         { $$ = newSVREF($2);
1294                           TOKEN_GETMAD($1,$$,'$');
1295                         }
1296         ;
1297
1298 ary     :       '@' indirob
1299                         { $$ = newAVREF($2);
1300                           TOKEN_GETMAD($1,$$,'@');
1301                         }
1302         ;
1303
1304 hsh     :       '%' indirob
1305                         { $$ = newHVREF($2);
1306                           TOKEN_GETMAD($1,$$,'%');
1307                         }
1308         ;
1309
1310 arylen  :       DOLSHARP indirob
1311                         { $$ = newAVREF($2);
1312                           TOKEN_GETMAD($1,$$,'l');
1313                         }
1314         ;
1315
1316 star    :       '*' indirob
1317                         { $$ = newGVREF(0,$2);
1318                           TOKEN_GETMAD($1,$$,'*');
1319                         }
1320         ;
1321
1322 /* Indirect objects */
1323 indirob :       WORD
1324                         { $$ = scalar($1); }
1325         |       scalar %prec PREC_LOW
1326                         { $$ = scalar($1); }
1327         |       block
1328                         { $$ = scope($1); }
1329
1330         |       PRIVATEREF
1331                         { $$ = $1; }
1332         ;