perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-1994, Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those that wander are lost.'
  13  */
  14
  15 %{
  16 #include "EXTERN.h"
  17 #include "perl.h"
  18
  19 static void
  20 dep()
  21 {
  22     deprecate("\"do\" to call subroutines");
  23 }
  24
  25 %}
  26
  27 %start prog
  28
  29 %union {
  30     I32 ival;
  31     char *pval;
  32     OP *opval;
  33     GV *gvval;
  34 }
  35
  36 %token <ival> '{' ')'
  37
  38 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  39 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  40 %token <pval> LABEL
  41 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  42 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  43 %token <ival> LOOPEX DOTDOT
  44 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
  45 %token <ival> RELOP EQOP MULOP ADDOP
  46 %token <ival> DOLSHARP DO HASHBRACK NOAMP
  47 %token LOCAL MY
  48
  49 %type <ival> prog decl local format startsub remember mremember '&'
  50 %type <opval> block mblock lineseq line loop cond else
  51 %type <opval> expr term scalar ary hsh arylen star amper sideff
  52 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
  53 %type <opval> listexpr listexprcom indirob
  54 %type <opval> listop method proto cont my_scalar
  55 %type <pval> label
  56
  57 %left <ival> OROP
  58 %left ANDOP
  59 %right NOTOP
  60 %nonassoc LSTOP LSTOPSUB
  61 %left ','
  62 %right <ival> ASSIGNOP
  63 %right '?' ':'
  64 %nonassoc DOTDOT
  65 %left OROR
  66 %left ANDAND
  67 %left <ival> BITOROP
  68 %left <ival> BITANDOP
  69 %nonassoc EQOP
  70 %nonassoc RELOP
  71 %nonassoc UNIOP UNIOPSUB
  72 %left <ival> SHIFTOP
  73 %left ADDOP
  74 %left MULOP
  75 %left <ival> MATCHOP
  76 %right '!' '~' UMINUS REFGEN
  77 %right <ival> POWOP
  78 %nonassoc PREINC PREDEC POSTINC POSTDEC
  79 %left ARROW
  80 %left '('
  81
  82 %% /* RULES */
  83
  84 prog    :       /* NULL */
  85                 {
  86 #if defined(YYDEBUG) && defined(DEBUGGING)
  87                     yydebug = (debug & 1);
  88 #endif
  89                     expect = XSTATE;
  90                 }
  91         /*CONTINUED*/   lineseq
  92                         { newPROG($2); }
  93         ;
  94
  95 block   :       '{' remember lineseq '}'
  96                         { if (copline > (line_t)$1)
  97                               copline = $1;
  98                           $$ = block_end($2, $3); }
  99         ;
 100
 101 remember:       /* NULL */      /* start a full lexical scope */
 102                         { $$ = block_start(TRUE); }
 103         ;
 104
 105 mblock  :       '{' mremember lineseq '}'
 106                         { if (copline > (line_t)$1)
 107                               copline = $1;
 108                           $$ = block_end($2, $3); }
 109         ;
 110
 111 mremember:      /* NULL */      /* start a partial lexical scope */
 112                         { $$ = block_start(FALSE); }
 113         ;
 114
 115 lineseq :       /* NULL */
 116                         { $$ = Nullop; }
 117         |       lineseq decl
 118                         { $$ = $1; }
 119         |       lineseq line
 120                         {   $$ = append_list(OP_LINESEQ,
 121                                 (LISTOP*)$1, (LISTOP*)$2);
 122                             pad_reset_pending = TRUE;
 123                             if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
 124         ;
 125
 126 line    :       label cond
 127                         { $$ = newSTATEOP(0, $1, $2); }
 128         |       loop    /* loops add their own labels */
 129         |       label ';'
 130                         { if ($1 != Nullch) {
 131                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 132                             }
 133                             else {
 134                               $$ = Nullop;
 135                               copline = NOLINE;
 136                             }
 137                             expect = XSTATE; }
 138         |       label sideff ';'
 139                         { $$ = newSTATEOP(0, $1, $2);
 140                           expect = XSTATE; }
 141         ;
 142
 143 sideff  :       error
 144                         { $$ = Nullop; }
 145         |       expr
 146                         { $$ = $1; }
 147         |       expr IF expr
 148                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 149         |       expr UNLESS expr
 150                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 151         |       expr WHILE expr
 152                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 153         |       expr UNTIL iexpr
 154                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
 155         ;
 156
 157 else    :       /* NULL */
 158                         { $$ = Nullop; }
 159         |       ELSE mblock
 160                         { $$ = scope($2); }
 161         |       ELSIF '(' mexpr ')' mblock else
 162                         { copline = $1;
 163                             $$ = newSTATEOP(0, Nullch,
 164                                    newCONDOP(0, $3, scope($5), $6));
 165                             hints |= HINT_BLOCK_SCOPE; }
 166         ;
 167
 168 cond    :       IF '(' remember mexpr ')' mblock else
 169                         { copline = $1;
 170                             $$ = block_end($3,
 171                                    newCONDOP(0, $4, scope($6), $7)); }
 172         |       UNLESS '(' remember miexpr ')' mblock else
 173                         { copline = $1;
 174                             $$ = block_end($3,
 175                                    newCONDOP(0, $4, scope($6), $7)); }
 176         |       IF block block else
 177                         { copline = $1;
 178                             deprecate("if BLOCK BLOCK");
 179                             $$ = newCONDOP(0, scope($2), scope($3), $4); }
 180         |       UNLESS block block else
 181                         { copline = $1;
 182                             deprecate("unless BLOCK BLOCK");
 183                             $$ = newCONDOP(0, invert(scalar(scope($2))),
 184                                                 scope($3), $4); }
 185         ;
 186
 187 cont    :       /* NULL */
 188                         { $$ = Nullop; }
 189         |       CONTINUE block
 190                         { $$ = scope($2); }
 191         ;
 192
 193 loop    :       label WHILE '(' remember mtexpr ')' mblock cont
 194                         { copline = $2;
 195                             $$ = block_end($4,
 196                                    newSTATEOP(0, $1,
 197                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 198                                                 $5, $7, $8))); }
 199         |       label UNTIL '(' remember miexpr ')' mblock cont
 200                         { copline = $2;
 201                             $$ = block_end($4,
 202                                    newSTATEOP(0, $1,
 203                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 204                                                 $5, $7, $8))); }
 205         |       label WHILE block block cont
 206                         { copline = $2;
 207                             $$ = newWHILEOP(0, 1, (LOOP*)Nullop,
 208                                             scope($3), $4, $5); }
 209         |       label UNTIL block block cont
 210                         { copline = $2;
 211                             $$ = newWHILEOP(0, 1, (LOOP*)Nullop,
 212                                             invert(scalar(scope($3))),
 213                                             $4, $5); }
 214         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 215                         { $$ = block_end($4,
 216                                  newFOROP(0, $1, $2, $5, $7, $9, $10)); }
 217         |       label FOR scalar '(' remember mexpr ')' mblock cont
 218                         { $$ = block_end($5,
 219                                  newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
 220                                           $6, $8, $9)); }
 221         |       label FOR '(' remember mexpr ')' mblock cont
 222                         { $$ = block_end($4,
 223                                  newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
 224         |       label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
 225                         /* basically fake up an initialize-while lineseq */
 226                         { copline = $2;
 227                             $$ = block_end($4,
 228                                    append_elem(OP_LINESEQ, scalar($5),
 229                                      newSTATEOP(0, $1,
 230                                        newWHILEOP(0, 1, (LOOP*)Nullop,
 231                                                   scalar($7),
 232                                                   $11, scalar($9))))); }
 233         |       label block cont  /* a block is a loop that happens once */
 234                         { $$ = newSTATEOP(0,
 235                                 $1, newWHILEOP(0, 1, (LOOP*)Nullop,
 236                                         Nullop, $2, $3)); }
 237         ;
 238
 239 nexpr   :       /* NULL */
 240                         { $$ = Nullop; }
 241         |       sideff
 242         ;
 243
 244 texpr   :       /* NULL means true */
 245                         { (void)scan_num("1"); $$ = yylval.opval; }
 246         |       expr
 247         ;
 248
 249 iexpr   :       expr
 250                         { $$ = invert(scalar($1)); }
 251         ;
 252
 253 mexpr   :       expr
 254                         { $$ = $1; intro_my(); }
 255         ;
 256
 257 mnexpr  :       nexpr
 258                         { $$ = $1; intro_my(); }
 259         ;
 260
 261 mtexpr  :       texpr
 262                         { $$ = $1; intro_my(); }
 263         ;
 264
 265 miexpr  :       iexpr
 266                         { $$ = $1; intro_my(); }
 267         ;
 268
 269 label   :       /* empty */
 270                         { $$ = Nullch; }
 271         |       LABEL
 272         ;
 273
 274 decl    :       format
 275                         { $$ = 0; }
 276         |       subrout
 277                         { $$ = 0; }
 278         |       package
 279                         { $$ = 0; }
 280         |       use
 281                         { $$ = 0; }
 282         ;
 283
 284 format  :       FORMAT startsub WORD block
 285                         { newFORM($2, $3, $4); }
 286         |       FORMAT startsub block
 287                         { newFORM($2, Nullop, $3); }
 288         ;
 289
 290 subrout :       SUB startsub WORD proto block
 291                         { newSUB($2, $3, $4, $5); }
 292         |       SUB startsub WORD proto ';'
 293                         { newSUB($2, $3, $4, Nullop); expect = XSTATE; }
 294         ;
 295
 296 proto   :       /* NULL */
 297                         { $$ = Nullop; }
 298         |       THING
 299         ;
 300
 301 startsub:       /* NULL */      /* start a subroutine scope */
 302                         { $$ = start_subparse(); }
 303         ;
 304
 305 package :       PACKAGE WORD ';'
 306                         { package($2); }
 307         |       PACKAGE ';'
 308                         { package(Nullop); }
 309         ;
 310
 311 use     :       USE startsub WORD WORD listexpr ';'
 312                         { utilize($1, $2, $3, $4, $5); }
 313         ;
 314
 315 expr    :       expr ANDOP expr
 316                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 317         |       expr OROP expr
 318                         { $$ = newLOGOP($2, 0, $1, $3); }
 319         |       argexpr
 320         ;
 321
 322 argexpr :       argexpr ','
 323                         { $$ = $1; }
 324         |       argexpr ',' term
 325                         { $$ = append_elem(OP_LIST, $1, $3); }
 326         |       term
 327         ;
 328
 329 listop  :       LSTOP indirob argexpr
 330                         { $$ = convert($1, OPf_STACKED,
 331                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 332         |       FUNC '(' indirob expr ')'
 333                         { $$ = convert($1, OPf_STACKED,
 334                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 335         |       term ARROW method '(' listexprcom ')'
 336                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 337                                 append_elem(OP_LIST,
 338                                     prepend_elem(OP_LIST, scalar($1), $5),
 339                                     newUNOP(OP_METHOD, 0, $3))); }
 340         |       METHOD indirob listexpr
 341                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 342                                 append_elem(OP_LIST,
 343                                     prepend_elem(OP_LIST, $2, $3),
 344                                     newUNOP(OP_METHOD, 0, $1))); }
 345         |       FUNCMETH indirob '(' listexprcom ')'
 346                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 347                                 append_elem(OP_LIST,
 348                                     prepend_elem(OP_LIST, $2, $4),
 349                                     newUNOP(OP_METHOD, 0, $1))); }
 350         |       LSTOP listexpr
 351                         { $$ = convert($1, 0, $2); }
 352         |       FUNC '(' listexprcom ')'
 353                         { $$ = convert($1, 0, $3); }
 354         |       LSTOPSUB startsub block listexpr        %prec LSTOP
 355                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 356                             append_elem(OP_LIST,
 357                               prepend_elem(OP_LIST, newANONSUB($2, 0, $3), $4),
 358                               $1)); }
 359         ;
 360
 361 method  :       METHOD
 362         |       scalar
 363         ;
 364
 365 term    :       term ASSIGNOP term
 366                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 367         |       term POWOP term
 368                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 369         |       term MULOP term
 370                         {   if ($2 != OP_REPEAT)
 371                                 scalar($1);
 372                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 373         |       term ADDOP term
 374                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 375         |       term SHIFTOP term
 376                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 377         |       term RELOP term
 378                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 379         |       term EQOP term
 380                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 381         |       term BITANDOP term
 382                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 383         |       term BITOROP term
 384                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 385         |       term DOTDOT term
 386                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 387         |       term ANDAND term
 388                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 389         |       term OROR term
 390                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 391         |       term '?' term ':' term
 392                         { $$ = newCONDOP(0, $1, $3, $5); }
 393         |       term MATCHOP term
 394                         { $$ = bind_match($2, $1, $3); }
 395
 396         |       '-' term %prec UMINUS
 397                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 398         |       '+' term %prec UMINUS
 399                         { $$ = $2; }
 400         |       '!' term
 401                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 402         |       '~' term
 403                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 404         |       REFGEN term
 405                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 406         |       term POSTINC
 407                         { $$ = newUNOP(OP_POSTINC, 0,
 408                                         mod(scalar($1), OP_POSTINC)); }
 409         |       term POSTDEC
 410                         { $$ = newUNOP(OP_POSTDEC, 0,
 411                                         mod(scalar($1), OP_POSTDEC)); }
 412         |       PREINC term
 413                         { $$ = newUNOP(OP_PREINC, 0,
 414                                         mod(scalar($2), OP_PREINC)); }
 415         |       PREDEC term
 416                         { $$ = newUNOP(OP_PREDEC, 0,
 417                                         mod(scalar($2), OP_PREDEC)); }
 418         |       local term      %prec UNIOP
 419                         { $$ = localize($2,$1); }
 420         |       '(' expr ')'
 421                         { $$ = sawparens($2); }
 422         |       '(' ')'
 423                         { $$ = sawparens(newNULLLIST()); }
 424         |       '[' expr ']'                            %prec '('
 425                         { $$ = newANONLIST($2); }
 426         |       '[' ']'                                 %prec '('
 427                         { $$ = newANONLIST(Nullop); }
 428         |       HASHBRACK expr ';' '}'                  %prec '('
 429                         { $$ = newANONHASH($2); }
 430         |       HASHBRACK ';' '}'                               %prec '('
 431                         { $$ = newANONHASH(Nullop); }
 432         |       ANONSUB startsub proto block                    %prec '('
 433                         { $$ = newANONSUB($2, $3, $4); }
 434         |       scalar  %prec '('
 435                         { $$ = $1; }
 436         |       star '{' expr ';' '}'
 437                         { $$ = newBINOP(OP_GELEM, 0, newGVREF(0,$1), $3); }
 438         |       star    %prec '('
 439                         { $$ = $1; }
 440         |       scalar '[' expr ']'     %prec '('
 441                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 442         |       term ARROW '[' expr ']' %prec '('
 443                         { $$ = newBINOP(OP_AELEM, 0,
 444                                         ref(newAVREF($1),OP_RV2AV),
 445                                         scalar($4));}
 446         |       term '[' expr ']'       %prec '('
 447                         { assertref($1); $$ = newBINOP(OP_AELEM, 0,
 448                                         ref(newAVREF($1),OP_RV2AV),
 449                                         scalar($3));}
 450         |       hsh     %prec '('
 451                         { $$ = $1; }
 452         |       ary     %prec '('
 453                         { $$ = $1; }
 454         |       arylen  %prec '('
 455                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 456         |       scalar '{' expr ';' '}' %prec '('
 457                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 458                             expect = XOPERATOR; }
 459         |       term ARROW '{' expr ';' '}'     %prec '('
 460                         { $$ = newBINOP(OP_HELEM, 0,
 461                                         ref(newHVREF($1),OP_RV2HV),
 462                                         jmaybe($4));
 463                             expect = XOPERATOR; }
 464         |       term '{' expr ';' '}'   %prec '('
 465                         { assertref($1); $$ = newBINOP(OP_HELEM, 0,
 466                                         ref(newHVREF($1),OP_RV2HV),
 467                                         jmaybe($3));
 468                             expect = XOPERATOR; }
 469         |       '(' expr ')' '[' expr ']'       %prec '('
 470                         { $$ = newSLICEOP(0, $5, $2); }
 471         |       '(' ')' '[' expr ']'    %prec '('
 472                         { $$ = newSLICEOP(0, $4, Nullop); }
 473         |       ary '[' expr ']'        %prec '('
 474                         { $$ = prepend_elem(OP_ASLICE,
 475                                 newOP(OP_PUSHMARK, 0),
 476                                     newLISTOP(OP_ASLICE, 0,
 477                                         list($3),
 478                                         ref($1, OP_ASLICE))); }
 479         |       ary '{' expr ';' '}'    %prec '('
 480                         { $$ = prepend_elem(OP_HSLICE,
 481                                 newOP(OP_PUSHMARK, 0),
 482                                     newLISTOP(OP_HSLICE, 0,
 483                                         list($3),
 484                                         ref(oopsHV($1), OP_HSLICE)));
 485                             expect = XOPERATOR; }
 486         |       THING   %prec '('
 487                         { $$ = $1; }
 488         |       amper
 489                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
 490         |       amper '(' ')'
 491                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 492         |       amper '(' expr ')'
 493                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 494                             append_elem(OP_LIST, $3, scalar($1))); }
 495         |       NOAMP WORD listexpr
 496                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 497                             append_elem(OP_LIST, $3, scalar($2))); }
 498         |       DO term %prec UNIOP
 499                         { $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
 500         |       DO block        %prec '('
 501                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 502         |       DO WORD '(' ')'
 503                         { $$ = newUNOP(OP_ENTERSUB,
 504                             OPf_SPECIAL|OPf_STACKED,
 505                             prepend_elem(OP_LIST,
 506                                 scalar(newCVREF(
 507                                     (OPpENTERSUB_AMPER<<8),
 508                                     scalar($2)
 509                                 )),Nullop)); dep();}
 510         |       DO WORD '(' expr ')'
 511                         { $$ = newUNOP(OP_ENTERSUB,
 512                             OPf_SPECIAL|OPf_STACKED,
 513                             append_elem(OP_LIST,
 514                                 $4,
 515                                 scalar(newCVREF(
 516                                     (OPpENTERSUB_AMPER<<8),
 517                                     scalar($2)
 518                                 )))); dep();}
 519         |       DO scalar '(' ')'
 520                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 521                             prepend_elem(OP_LIST,
 522                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
 523         |       DO scalar '(' expr ')'
 524                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 525                             prepend_elem(OP_LIST,
 526                                 $4,
 527                                 scalar(newCVREF(0,scalar($2))))); dep();}
 528         |       LOOPEX
 529                         { $$ = newOP($1, OPf_SPECIAL);
 530                             hints |= HINT_BLOCK_SCOPE; }
 531         |       LOOPEX term
 532                         { $$ = newLOOPEX($1,$2); }
 533         |       NOTOP argexpr
 534                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 535         |       UNIOP
 536                         { $$ = newOP($1, 0); }
 537         |       UNIOP block
 538                         { $$ = newUNOP($1, 0, $2); }
 539         |       UNIOP term
 540                         { $$ = newUNOP($1, 0, $2); }
 541         |       UNIOPSUB term
 542                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 543                             append_elem(OP_LIST, $2, scalar($1))); }
 544         |       FUNC0
 545                         { $$ = newOP($1, 0); }
 546         |       FUNC0 '(' ')'
 547                         { $$ = newOP($1, 0); }
 548         |       FUNC0SUB
 549                         { $$ = newUNOP(OP_ENTERSUB, 0,
 550                                 scalar($1)); }
 551         |       FUNC1 '(' ')'
 552                         { $$ = newOP($1, OPf_SPECIAL); }
 553         |       FUNC1 '(' expr ')'
 554                         { $$ = newUNOP($1, 0, $3); }
 555         |       PMFUNC '(' term ')'
 556                         { $$ = pmruntime($1, $3, Nullop); }
 557         |       PMFUNC '(' term ',' term ')'
 558                         { $$ = pmruntime($1, $3, $5); }
 559         |       WORD
 560         |       listop
 561         ;
 562
 563 listexpr:       /* NULL */
 564                         { $$ = Nullop; }
 565         |       argexpr
 566                         { $$ = $1; }
 567         ;
 568
 569 listexprcom:    /* NULL */
 570                         { $$ = Nullop; }
 571         |       expr
 572                         { $$ = $1; }
 573         |       expr ','
 574                         { $$ = $1; }
 575         ;
 576
 577 local   :       LOCAL   { $$ = 0; }
 578         |       MY      { $$ = 1; }
 579         ;
 580
 581 my_scalar:      scalar
 582                         { in_my = 0; $$ = my($1); }
 583         ;
 584
 585 amper   :       '&' indirob
 586                         { $$ = newCVREF($1,$2); }
 587         ;
 588
 589 scalar  :       '$' indirob
 590                         { $$ = newSVREF($2); }
 591         ;
 592
 593 ary     :       '@' indirob
 594                         { $$ = newAVREF($2); }
 595         ;
 596
 597 hsh     :       '%' indirob
 598                         { $$ = newHVREF($2); }
 599         ;
 600
 601 arylen  :       DOLSHARP indirob
 602                         { $$ = newAVREF($2); }
 603         ;
 604
 605 star    :       '*' indirob
 606                         { $$ = newGVREF(0,$2); }
 607         ;
 608
 609 indirob :       WORD
 610                         { $$ = scalar($1); }
 611         |       scalar
 612                         { $$ = scalar($1);  }
 613         |       block
 614                         { $$ = scope($1); }
 615
 616         |       PRIVATEREF
 617                         { $$ = $1; }
 618         ;
 619
 620 %% /* PROGRAM */