perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those who wander are lost.'
  13  *
  14  * This file holds the grammar for the Perl language. If edited, you need
  15  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
  16  * and perly.act which are derived from this.
  17  *
  18  * Note that these derived files are included and compiled twice; once
  19  * from perly.c, and once from madly.c. The second time, a number of MAD
  20  * macros are defined, which compile in extra code that allows the parse
  21  * tree to be accurately dumped. In particular:
  22  *
  23  * MAD            defined if compiling madly.c
  24  * DO_MAD(A)      expands to A  under madly.c, to null otherwise
  25  * IF_MAD(a,b)    expands to A under madly.c, to B otherwise
  26  * TOKEN_GETMAD() expands to token_getmad() under madly.c, to null otherwise
  27  * TOKEN_FREE()   similarly
  28  * OP_GETMAD()    similarly
  29  * IVAL(i)        expands to (i)->tk_lval.ival or (i)
  30  * PVAL(p)        expands to (p)->tk_lval.pval or (p)
  31  *
  32  * The main job of of this grammar is to call the various newFOO()
  33  * functions in op.c to build a syntax tree of OP structs.
  34  * It relies on the lexer in toke.c to do the tokenizing.
  35  *
  36  * Note: due to the way that the cleanup code works WRT to freeing ops on
  37  * the parse stack, it is dangerous to assign to the $n variables within
  38  * an action.
  39  */
  40
  41 /*  Make the parser re-entrant. */
  42
  43 %pure_parser
  44
  45 /* FIXME for MAD - is the new mintro on while and until important?  */
  46
  47 %start prog
  48
  49 %union {
  50     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
  51                                 must always be 1st union member) */
  52     char *pval;
  53     OP *opval;
  54     GV *gvval;
  55 #ifdef PERL_IN_MADLY_C
  56     TOKEN* p_tkval;
  57     TOKEN* i_tkval;
  58 #else
  59     char *p_tkval;
  60     I32 i_tkval;
  61 #endif
  62 #ifdef PERL_MAD
  63     TOKEN* tkval;
  64 #endif
  65 }
  66
  67 %token <i_tkval> '{' '}' '[' ']' '-' '+' '$' '@' '%' '*' '&' ';'
  68
  69 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  70 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  71 %token <p_tkval> LABEL
  72 %token <i_tkval> FORMAT SUB ANONSUB PACKAGE USE
  73 %token <i_tkval> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  74 %token <i_tkval> GIVEN WHEN DEFAULT
  75 %token <i_tkval> LOOPEX DOTDOT
  76 %token <i_tkval> FUNC0 FUNC1 FUNC UNIOP LSTOP
  77 %token <i_tkval> RELOP EQOP MULOP ADDOP
  78 %token <i_tkval> DOLSHARP DO HASHBRACK NOAMP
  79 %token <i_tkval> LOCAL MY MYSUB REQUIRE
  80 %token <i_tkval> COLONATTR
  81
  82 %type <ival> prog progstart remember mremember savescope
  83 %type <ival>  startsub startanonsub startformsub
  84 /* FIXME for MAD - are these two ival? */
  85 %type <ival> mydefsv mintro
  86
  87 %type <opval> decl format subrout mysubrout package use peg
  88
  89 %type <opval> block mblock lineseq line loop cond else
  90 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
  91 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr miexpr
  92 %type <opval> listexpr listexprcom indirob listop method
  93 %type <opval> formname subname proto subbody cont my_scalar
  94 %type <opval> subattrlist myattrlist myattrterm myterm
  95 %type <opval> termbinop termunop anonymous termdo
  96 %type <opval> switch case
  97 %type <p_tkval> label
  98
  99 %nonassoc <i_tkval> PREC_LOW
 100 %nonassoc LOOPEX
 101
 102 %left <i_tkval> OROP DOROP
 103 %left <i_tkval> ANDOP
 104 %right <i_tkval> NOTOP
 105 %nonassoc LSTOP LSTOPSUB
 106 %left <i_tkval> ','
 107 %right <i_tkval> ASSIGNOP
 108 %right <i_tkval> '?' ':'
 109 %nonassoc DOTDOT
 110 %left <i_tkval> OROR DORDOR
 111 %left <i_tkval> ANDAND
 112 %left <i_tkval> BITOROP
 113 %left <i_tkval> BITANDOP
 114 %nonassoc EQOP
 115 %nonassoc RELOP
 116 %nonassoc UNIOP UNIOPSUB
 117 %nonassoc REQUIRE
 118 %left <i_tkval> SHIFTOP
 119 %left ADDOP
 120 %left MULOP
 121 %left <i_tkval> MATCHOP
 122 %right <i_tkval> '!' '~' UMINUS REFGEN
 123 %right <i_tkval> POWOP
 124 %nonassoc <i_tkval> PREINC PREDEC POSTINC POSTDEC
 125 %left <i_tkval> ARROW
 126 %nonassoc <i_tkval> ')'
 127 %left <i_tkval> '('
 128 %left '[' '{'
 129
 130 %token <i_tkval> PEG
 131
 132 %% /* RULES */
 133
 134 /* The whole program */
 135 prog    :       progstart
 136         /*CONTINUED*/   lineseq
 137                         { $$ = $1; newPROG(block_end($1,$2)); }
 138         ;
 139
 140 /* An ordinary block */
 141 block   :       '{' remember lineseq '}'
 142                         { if (PL_copline > (line_t)IVAL($1))
 143                               PL_copline = (line_t)IVAL($1);
 144                           $$ = block_end($2, $3);
 145                           TOKEN_GETMAD($1,$$,'{');
 146                           TOKEN_GETMAD($4,$$,'}');
 147                         }
 148         ;
 149
 150 remember:       /* NULL */      /* start a full lexical scope */
 151                         { $$ = block_start(TRUE); }
 152         ;
 153
 154 mydefsv:        /* NULL */      /* lexicalize $_ */
 155                         { $$ = (I32) allocmy("$_"); }
 156         ;
 157
 158 progstart:
 159                 {
 160                     PL_expect = XSTATE; $$ = block_start(TRUE);
 161                 }
 162         ;
 163
 164
 165 mblock  :       '{' mremember lineseq '}'
 166                         { if (PL_copline > (line_t)IVAL($1))
 167                               PL_copline = (line_t)IVAL($1);
 168                           $$ = block_end($2, $3);
 169                           TOKEN_GETMAD($1,$$,'{');
 170                           TOKEN_GETMAD($4,$$,'}');
 171                         }
 172         ;
 173
 174 mremember:      /* NULL */      /* start a partial lexical scope */
 175                         { $$ = block_start(FALSE); }
 176         ;
 177
 178 savescope:      /* NULL */      /* remember stack pos in case of error */
 179                 { $$ = PL_savestack_ix; }
 180
 181 /* A collection of "lines" in the program */
 182 lineseq :       /* NULL */
 183                         { $$ = Nullop; }
 184         |       lineseq decl
 185                         {
 186                         $$ = IF_MAD(
 187                                 append_list(OP_LINESEQ,
 188                                     (LISTOP*)$1, (LISTOP*)$2),
 189                                 $1);
 190                         }
 191         |       lineseq savescope line
 192                         {   LEAVE_SCOPE($2);
 193                             $$ = append_list(OP_LINESEQ,
 194                                 (LISTOP*)$1, (LISTOP*)$3);
 195                             PL_pad_reset_pending = TRUE;
 196                             if ($1 && $3) PL_hints |= HINT_BLOCK_SCOPE; }
 197         ;
 198
 199 /* A "line" in the program */
 200 line    :       label cond
 201                         { $$ = newSTATEOP(0, PVAL($1), $2);
 202                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 203         |       loop    /* loops add their own labels */
 204         |       switch  /* ... and so do switches */
 205                         { $$ = $1; }
 206         |       label case
 207                         { $$ = newSTATEOP(0, PVAL($1), $2); }
 208         |       label ';'
 209                         {
 210                           if (PVAL($1)) {
 211                               $$ = newSTATEOP(0, PVAL($1), newOP(OP_NULL, 0));
 212                               TOKEN_GETMAD($1,$$,'L');
 213                               TOKEN_GETMAD($2,((LISTOP*)$$)->op_first,';');
 214                           }
 215                           else {
 216                               $$ = IF_MAD(
 217                                         newOP(OP_NULL, 0),
 218                                         Nullop);
 219                               PL_copline = NOLINE;
 220                               TOKEN_FREE($1);
 221                               TOKEN_GETMAD($2,$$,';');
 222                           }
 223                           PL_expect = XSTATE;
 224                         }
 225         |       label sideff ';'
 226                         {
 227                           $$ = newSTATEOP(0, PVAL($1), $2);
 228                           PL_expect = XSTATE;
 229                           DO_MAD(
 230                               /* sideff might already have a nexstate */
 231                               OP* op = ((LISTOP*)$$)->op_first;
 232                               if (op) {
 233                                   while (op->op_sibling &&
 234                                      op->op_sibling->op_type == OP_NEXTSTATE)
 235                                         op = op->op_sibling;
 236                                   token_getmad($1,op,'L');
 237                                   token_getmad($3,op,';');
 238                               }
 239                           )
 240                         }
 241         ;
 242
 243 /* An expression which may have a side-effect */
 244 sideff  :       error
 245                         { $$ = Nullop; }
 246         |       expr
 247                         { $$ = $1; }
 248         |       expr IF expr
 249                         { $$ = newLOGOP(OP_AND, 0, $3, $1);
 250                           TOKEN_GETMAD($2,$$,'i');
 251                         }
 252         |       expr UNLESS expr
 253                         { $$ = newLOGOP(OP_OR, 0, $3, $1);
 254                           TOKEN_GETMAD($2,$$,'i');
 255                         }
 256         |       expr WHILE expr
 257                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1);
 258                           TOKEN_GETMAD($2,$$,'w');
 259                         }
 260         |       expr UNTIL iexpr
 261                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);
 262                           TOKEN_GETMAD($2,$$,'w');
 263                         }
 264         |       expr FOR expr
 265                         { $$ = newFOROP(0, Nullch, (line_t)IVAL($2),
 266                                         Nullop, $3, $1, Nullop);
 267                           TOKEN_GETMAD($2,((LISTOP*)$$)->op_first->op_sibling,'w');
 268                         }
 269         ;
 270
 271 /* else and elsif blocks */
 272 else    :       /* NULL */
 273                         { $$ = Nullop; }
 274         |       ELSE mblock
 275                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2);
 276                           TOKEN_GETMAD($1,$$,'o');
 277                         }
 278         |       ELSIF '(' mexpr ')' mblock else
 279                         { PL_copline = (line_t)IVAL($1);
 280                             $$ = newCONDOP(0, $3, scope($5), $6);
 281                             PL_hints |= HINT_BLOCK_SCOPE;
 282                           TOKEN_GETMAD($1,$$,'I');
 283                           TOKEN_GETMAD($2,$$,'(');
 284                           TOKEN_GETMAD($4,$$,')');
 285                         }
 286         ;
 287
 288 /* Real conditional expressions */
 289 cond    :       IF '(' remember mexpr ')' mblock else
 290                         { PL_copline = (line_t)IVAL($1);
 291                             $$ = block_end($3,
 292                                    newCONDOP(0, $4, scope($6), $7));
 293                           TOKEN_GETMAD($1,$$,'I');
 294                           TOKEN_GETMAD($2,$$,'(');
 295                           TOKEN_GETMAD($5,$$,')');
 296                         }
 297         |       UNLESS '(' remember miexpr ')' mblock else
 298                         { PL_copline = (line_t)IVAL($1);
 299                             $$ = block_end($3,
 300                                    newCONDOP(0, $4, scope($6), $7));
 301                           TOKEN_GETMAD($1,$$,'I');
 302                           TOKEN_GETMAD($2,$$,'(');
 303                           TOKEN_GETMAD($5,$$,')');
 304                         }
 305         ;
 306
 307 /* Cases for a switch statement */
 308 case    :       WHEN '(' remember mexpr ')' mblock
 309         { $$ = block_end($3,
 310                 newWHENOP($4, scope($6))); }
 311         |       DEFAULT block
 312         { $$ = newWHENOP(0, scope($2)); }
 313         ;
 314
 315 /* Continue blocks */
 316 cont    :       /* NULL */
 317                         { $$ = Nullop; }
 318         |       CONTINUE block
 319                         { $$ = scope($2);
 320                           TOKEN_GETMAD($1,$$,'o');
 321                         }
 322         ;
 323
 324 /* Loops: while, until, for, and a bare block */
 325 loop    :       label WHILE '(' remember texpr ')' mintro mblock cont
 326                         { OP *innerop;
 327                           PL_copline = (line_t)$2;
 328                             $$ = block_end($4,
 329                                    newSTATEOP(0, PVAL($1),
 330                                      innerop = newWHILEOP(0, 1, (LOOP*)Nullop,
 331                                                 IVAL($2), $5, $8, $9, $7)));
 332                           TOKEN_GETMAD($1,innerop,'L');
 333                           TOKEN_GETMAD($2,innerop,'W');
 334                           TOKEN_GETMAD($3,innerop,'(');
 335                           TOKEN_GETMAD($6,innerop,')');
 336                         }
 337
 338         |       label UNTIL '(' remember iexpr ')' mintro mblock cont
 339                         { OP *innerop;
 340                           PL_copline = (line_t)$2;
 341                             $$ = block_end($4,
 342                                    newSTATEOP(0, PVAL($1),
 343                                      innerop = newWHILEOP(0, 1, (LOOP*)Nullop,
 344                                                 IVAL($2), $5, $8, $9, $7)));
 345                           TOKEN_GETMAD($1,innerop,'L');
 346                           TOKEN_GETMAD($2,innerop,'W');
 347                           TOKEN_GETMAD($3,innerop,'(');
 348                           TOKEN_GETMAD($6,innerop,')');
 349                         }
 350         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 351                         { OP *innerop;
 352                           $$ = block_end($4,
 353                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 354                                             $5, $7, $9, $10));
 355                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 356                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 357                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'d');
 358                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,'(');
 359                           TOKEN_GETMAD($8,((LISTOP*)innerop)->op_first->op_sibling,')');
 360                         }
 361         |       label FOR scalar '(' remember mexpr ')' mblock cont
 362                         { OP *innerop;
 363                           $$ = block_end($5,
 364                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 365                                     mod($3, OP_ENTERLOOP), $6, $8, $9));
 366                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 367                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 368                           TOKEN_GETMAD($4,((LISTOP*)innerop)->op_first->op_sibling,'(');
 369                           TOKEN_GETMAD($7,((LISTOP*)innerop)->op_first->op_sibling,')');
 370                         }
 371         |       label FOR '(' remember mexpr ')' mblock cont
 372                         { OP *innerop;
 373                           $$ = block_end($4,
 374                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 375                                                     Nullop, $5, $7, $8));
 376                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 377                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 378                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'(');
 379                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,')');
 380                         }
 381         |       label FOR '(' remember mnexpr ';' texpr ';' mintro mnexpr ')'
 382                     mblock
 383                         /* basically fake up an initialize-while lineseq */
 384                         { OP *forop;
 385                           PL_copline = (line_t)IVAL($2);
 386                           forop = newSTATEOP(0, PVAL($1),
 387                                             newWHILEOP(0, 1, (LOOP*)Nullop,
 388                                                 IVAL($2), scalar($7),
 389                                                 $12, $10, $9));
 390 #ifdef MAD
 391                           forop = newUNOP(OP_NULL, 0, append_elem(OP_LINESEQ,
 392                                 newSTATEOP(0,
 393                                            (($1)->tk_lval.pval
 394                                            ?savepv(($1)->tk_lval.pval):Nullch),
 395                                            ($5 ? newOP(OP_NULL, 0) : $5) ),
 396                                 forop));
 397
 398                           token_getmad($2,forop,'3');
 399                           token_getmad($3,forop,'(');
 400                           token_getmad($6,forop,'1');
 401                           token_getmad($8,forop,'2');
 402                           token_getmad($11,forop,')');
 403                           token_getmad($1,forop,'L');
 404 #else
 405                           if ($5) {
 406                                 forop = append_elem(OP_LINESEQ,
 407                                         newSTATEOP(0, ($1?savepv($1):Nullch),
 408                                                    $5),
 409                                         forop);
 410                           }
 411
 412
 413 #endif
 414                           $$ = block_end($4, forop); }
 415         |       label block cont  /* a block is a loop that happens once */
 416                         { $$ = newSTATEOP(0, PVAL($1),
 417                                  newWHILEOP(0, 1, (LOOP*)Nullop,
 418                                             NOLINE, Nullop, $2, $3, 0));
 419                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 420         ;
 421
 422 /* Switch blocks */
 423 switch  :       label GIVEN '(' remember mydefsv mexpr ')' mblock
 424                         { PL_copline = (line_t) $2;
 425                             $$ = block_end($4,
 426                                 newSTATEOP(0, PVAL($1),
 427                                     newGIVENOP($6, scope($8),
 428                                         (PADOFFSET) $5) )); }
 429         ;
 430
 431 /* determine whether there are any new my declarations */
 432 mintro  :       /* NULL */
 433                         { $$ = (PL_min_intro_pending &&
 434                             PL_max_intro_pending >=  PL_min_intro_pending);
 435                           intro_my(); }
 436
 437 /* Normal expression */
 438 nexpr   :       /* NULL */
 439                         { $$ = Nullop; }
 440         |       sideff
 441         ;
 442
 443 /* Boolean expression */
 444 texpr   :       /* NULL means true */
 445                         { YYSTYPE tmplval;
 446                           (void)scan_num("1", &tmplval);
 447                           $$ = tmplval.opval; }
 448         |       expr
 449         ;
 450
 451 /* Inverted boolean expression */
 452 iexpr   :       expr
 453                         { $$ = invert(scalar($1)); }
 454         ;
 455
 456 /* Expression with its own lexical scope */
 457 mexpr   :       expr
 458                         { $$ = $1; intro_my(); }
 459         ;
 460
 461 mnexpr  :       nexpr
 462                         { $$ = $1; intro_my(); }
 463         ;
 464
 465 miexpr  :       iexpr
 466                         { $$ = $1; intro_my(); }
 467         ;
 468
 469 /* Optional "MAIN:"-style loop labels */
 470 label   :       /* empty */
 471                         {
 472 #ifdef MAD
 473                           YYSTYPE tmplval;
 474                           tmplval.pval = Nullch;
 475                           $$ = newTOKEN(OP_NULL, tmplval, 0);
 476 #else
 477                           $$ = Nullch;
 478 #endif
 479                         }
 480         |       LABEL
 481         ;
 482
 483 /* Some kind of declaration - just hang on peg in the parse tree */
 484 decl    :       format
 485                         { $$ = $1; }
 486         |       subrout
 487                         { $$ = $1; }
 488         |       mysubrout
 489                         { $$ = $1; }
 490         |       package
 491                         { $$ = $1; }
 492         |       use
 493                         { $$ = $1; }
 494
 495     /* these two are only used by MAD */
 496
 497         |       peg
 498                         { $$ = $1; }
 499         ;
 500
 501 peg     :       PEG
 502                         { $$ = newOP(OP_NULL,0);
 503                           TOKEN_GETMAD($1,$$,'p');
 504                         }
 505         ;
 506
 507 format  :       FORMAT startformsub formname block
 508                         { SvREFCNT_inc(PL_compcv);
 509 #ifdef MAD
 510                           $$ = newFORM($2, $3, $4);
 511                           prepend_madprops($1->tk_mad, $$, 'F');
 512                           $1->tk_mad = 0;
 513                           token_free($1);
 514 #else
 515                           newFORM($2, $3, $4);
 516                           $$ = Nullop;
 517 #endif
 518                         }
 519         ;
 520
 521 formname:       WORD            { $$ = $1; }
 522         |       /* NULL */      { $$ = Nullop; }
 523         ;
 524
 525 /* Unimplemented "my sub foo { }" */
 526 mysubrout:      MYSUB startsub subname proto subattrlist subbody
 527                         { SvREFCNT_inc(PL_compcv);
 528 #ifdef MAD
 529                           $$ = newMYSUB($2, $3, $4, $5, $6);
 530                           token_getmad($1,$$,'d');
 531 #else
 532                           newMYSUB($2, $3, $4, $5, $6);
 533                           $$ = Nullop;
 534 #endif
 535                         }
 536         ;
 537
 538 /* Subroutine definition */
 539 subrout :       SUB startsub subname proto subattrlist subbody
 540                         { SvREFCNT_inc(PL_compcv);
 541 #ifdef MAD
 542                           OP* o = newSVOP(OP_ANONCODE, 0,
 543                             (SV*)newATTRSUB($2, $3, $4, $5, $6));
 544                           $$ = newOP(OP_NULL,0);
 545                           op_getmad(o,$$,'&');
 546                           op_getmad($3,$$,'n');
 547                           op_getmad($4,$$,'s');
 548                           op_getmad($5,$$,'a');
 549                           token_getmad($1,$$,'d');
 550                           append_madprops($6->op_madprop, $$, 0);
 551                           $6->op_madprop = 0;
 552 #else
 553                           newATTRSUB($2, $3, $4, $5, $6);
 554                           $$ = Nullop;
 555 #endif
 556                         }
 557         ;
 558
 559 startsub:       /* NULL */      /* start a regular subroutine scope */
 560                         { $$ = start_subparse(FALSE, 0);
 561                             SAVEFREESV(PL_compcv); }
 562
 563         ;
 564
 565 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 566                         { $$ = start_subparse(FALSE, CVf_ANON);
 567                             SAVEFREESV(PL_compcv); }
 568         ;
 569
 570 startformsub:   /* NULL */      /* start a format subroutine scope */
 571                         { $$ = start_subparse(TRUE, 0);
 572                             SAVEFREESV(PL_compcv); }
 573         ;
 574
 575 /* Name of a subroutine - must be a bareword, could be special */
 576 subname :       WORD    { const char *const name = SvPV_nolen_const(((SVOP*)$1)->op_sv);
 577                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
 578                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
 579                               || strEQ(name, "UNITCHECK"))
 580                               CvSPECIAL_on(PL_compcv);
 581                           $$ = $1; }
 582         ;
 583
 584 /* Subroutine prototype */
 585 proto   :       /* NULL */
 586                         { $$ = Nullop; }
 587         |       THING
 588         ;
 589
 590 /* Optional list of subroutine attributes */
 591 subattrlist:    /* NULL */
 592                         { $$ = Nullop; }
 593         |       COLONATTR THING
 594                         { $$ = $2;
 595                           TOKEN_GETMAD($1,$$,':');
 596                         }
 597         |       COLONATTR
 598                         { $$ = IF_MAD(
 599                                     newOP(OP_NULL, 0),
 600                                     Nullop
 601                                 );
 602                           TOKEN_GETMAD($1,$$,':');
 603                         }
 604         ;
 605
 606 /* List of attributes for a "my" variable declaration */
 607 myattrlist:     COLONATTR THING
 608                         { $$ = $2;
 609                           TOKEN_GETMAD($1,$$,':');
 610                         }
 611         |       COLONATTR
 612                         { $$ = IF_MAD(
 613                                     newOP(OP_NULL, 0),
 614                                     Nullop
 615                                 );
 616                           TOKEN_GETMAD($1,$$,':');
 617                         }
 618         ;
 619
 620 /* Subroutine body - either null or a block */
 621 subbody :       block   { $$ = $1; }
 622         |       ';'     { $$ = IF_MAD(
 623                                     newOP(OP_NULL,0),
 624                                     Nullop
 625                                 );
 626                           PL_expect = XSTATE;
 627                           TOKEN_GETMAD($1,$$,';');
 628                         }
 629         ;
 630
 631 package :       PACKAGE WORD ';'
 632                         {
 633 #ifdef MAD
 634                           $$ = package($2);
 635                           token_getmad($1,$$,'o');
 636                           token_getmad($3,$$,';');
 637 #else
 638                           package($2);
 639                           $$ = Nullop;
 640 #endif
 641                         }
 642         ;
 643
 644 use     :       USE startsub
 645                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
 646                     WORD WORD listexpr ';'
 647                         { SvREFCNT_inc(PL_compcv);
 648 #ifdef MAD
 649                           $$ = utilize(IVAL($1), $2, $4, $5, $6);
 650                           token_getmad($1,$$,'o');
 651                           token_getmad($7,$$,';');
 652                           if (PL_rsfp_filters && AvFILLp(PL_rsfp_filters) >= 0)
 653                               append_madprops(newMADPROP('!', MAD_PV, "", 0), $$, 0);
 654 #else
 655                           utilize(IVAL($1), $2, $4, $5, $6);
 656                           $$ = Nullop;
 657 #endif
 658                         }
 659         ;
 660
 661 /* Ordinary expressions; logical combinations */
 662 expr    :       expr ANDOP expr
 663                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
 664                           TOKEN_GETMAD($2,$$,'o');
 665                         }
 666         |       expr OROP expr
 667                         { $$ = newLOGOP(IVAL($2), 0, $1, $3);
 668                           TOKEN_GETMAD($2,$$,'o');
 669                         }
 670         |       expr DOROP expr
 671                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
 672                           TOKEN_GETMAD($2,$$,'o');
 673                         }
 674         |       argexpr %prec PREC_LOW
 675         ;
 676
 677 /* Expressions are a list of terms joined by commas */
 678 argexpr :       argexpr ','
 679                         {
 680 #ifdef MAD
 681                           OP* op = newNULLLIST();
 682                           token_getmad($2,op,',');
 683                           $$ = append_elem(OP_LIST, $1, op);
 684 #else
 685                           $$ = $1;
 686 #endif
 687                         }
 688         |       argexpr ',' term
 689                         {
 690                           OP* term = $3;
 691                           DO_MAD(
 692                               term = newUNOP(OP_NULL, 0, term);
 693                               token_getmad($2,term,',');
 694                           )
 695                           $$ = append_elem(OP_LIST, $1, term);
 696                         }
 697         |       term %prec PREC_LOW
 698         ;
 699
 700 /* List operators */
 701 listop  :       LSTOP indirob argexpr /* map {...} @args or print $fh @args */
 702                         { $$ = convert(IVAL($1), OPf_STACKED,
 703                                 prepend_elem(OP_LIST, newGVREF(IVAL($1),$2), $3) );
 704                           TOKEN_GETMAD($1,$$,'o');
 705                         }
 706         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
 707                         { $$ = convert(IVAL($1), OPf_STACKED,
 708                                 prepend_elem(OP_LIST, newGVREF(IVAL($1),$3), $4) );
 709                           TOKEN_GETMAD($1,$$,'o');
 710                           TOKEN_GETMAD($2,$$,'(');
 711                           TOKEN_GETMAD($5,$$,')');
 712                         }
 713         |       term ARROW method '(' listexprcom ')' /* $foo->bar(list) */
 714                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 715                                 append_elem(OP_LIST,
 716                                     prepend_elem(OP_LIST, scalar($1), $5),
 717                                     newUNOP(OP_METHOD, 0, $3)));
 718                           TOKEN_GETMAD($2,$$,'A');
 719                           TOKEN_GETMAD($4,$$,'(');
 720                           TOKEN_GETMAD($6,$$,')');
 721                         }
 722         |       term ARROW method                     /* $foo->bar */
 723                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 724                                 append_elem(OP_LIST, scalar($1),
 725                                     newUNOP(OP_METHOD, 0, $3)));
 726                           TOKEN_GETMAD($2,$$,'A');
 727                         }
 728         |       METHOD indirob listexpr              /* new Class @args */
 729                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 730                                 append_elem(OP_LIST,
 731                                     prepend_elem(OP_LIST, $2, $3),
 732                                     newUNOP(OP_METHOD, 0, $1)));
 733                         }
 734         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
 735                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 736                                 append_elem(OP_LIST,
 737                                     prepend_elem(OP_LIST, $2, $4),
 738                                     newUNOP(OP_METHOD, 0, $1)));
 739                           TOKEN_GETMAD($3,$$,'(');
 740                           TOKEN_GETMAD($5,$$,')');
 741                         }
 742         |       LSTOP listexpr                       /* print @args */
 743                         { $$ = convert(IVAL($1), 0, $2);
 744                           TOKEN_GETMAD($1,$$,'o');
 745                         }
 746         |       FUNC '(' listexprcom ')'             /* print (@args) */
 747                         { $$ = convert(IVAL($1), 0, $3);
 748                           TOKEN_GETMAD($1,$$,'o');
 749                           TOKEN_GETMAD($2,$$,'(');
 750                           TOKEN_GETMAD($4,$$,')');
 751                         }
 752         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
 753                         { SvREFCNT_inc(PL_compcv);
 754                           $<opval>$ = newANONATTRSUB($2, 0, Nullop, $3); }
 755                     listexpr            %prec LSTOP  /* ... @bar */
 756                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 757                                  append_elem(OP_LIST,
 758                                    prepend_elem(OP_LIST, $<opval>4, $5), $1));
 759                         }
 760         ;
 761
 762 /* Names of methods. May use $object->$methodname */
 763 method  :       METHOD
 764         |       scalar
 765         ;
 766
 767 /* Some kind of subscripted expression */
 768 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
 769                         /* In this and all the hash accessors, ';' is
 770                          * provided by the tokeniser */
 771                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
 772                             PL_expect = XOPERATOR;
 773                           TOKEN_GETMAD($2,$$,'{');
 774                           TOKEN_GETMAD($4,$$,';');
 775                           TOKEN_GETMAD($5,$$,'}');
 776                         }
 777         |       scalar '[' expr ']'          /* $array[$element] */
 778                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
 779                           TOKEN_GETMAD($2,$$,'[');
 780                           TOKEN_GETMAD($4,$$,']');
 781                         }
 782         |       term ARROW '[' expr ']'      /* somearef->[$element] */
 783                         { $$ = newBINOP(OP_AELEM, 0,
 784                                         ref(newAVREF($1),OP_RV2AV),
 785                                         scalar($4));
 786                           TOKEN_GETMAD($2,$$,'a');
 787                           TOKEN_GETMAD($3,$$,'[');
 788                           TOKEN_GETMAD($5,$$,']');
 789                         }
 790         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
 791                         { $$ = newBINOP(OP_AELEM, 0,
 792                                         ref(newAVREF($1),OP_RV2AV),
 793                                         scalar($3));
 794                           TOKEN_GETMAD($2,$$,'[');
 795                           TOKEN_GETMAD($4,$$,']');
 796                         }
 797         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
 798                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 799                             PL_expect = XOPERATOR;
 800                           TOKEN_GETMAD($2,$$,'{');
 801                           TOKEN_GETMAD($4,$$,';');
 802                           TOKEN_GETMAD($5,$$,'}');
 803                         }
 804         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
 805                         { $$ = newBINOP(OP_HELEM, 0,
 806                                         ref(newHVREF($1),OP_RV2HV),
 807                                         jmaybe($4));
 808                             PL_expect = XOPERATOR;
 809                           TOKEN_GETMAD($2,$$,'a');
 810                           TOKEN_GETMAD($3,$$,'{');
 811                           TOKEN_GETMAD($5,$$,';');
 812                           TOKEN_GETMAD($6,$$,'}');
 813                         }
 814         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
 815                         { $$ = newBINOP(OP_HELEM, 0,
 816                                         ref(newHVREF($1),OP_RV2HV),
 817                                         jmaybe($3));
 818                             PL_expect = XOPERATOR;
 819                           TOKEN_GETMAD($2,$$,'{');
 820                           TOKEN_GETMAD($4,$$,';');
 821                           TOKEN_GETMAD($5,$$,'}');
 822                         }
 823         |       term ARROW '(' ')'          /* $subref->() */
 824                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 825                                    newCVREF(0, scalar($1)));
 826                           TOKEN_GETMAD($2,$$,'a');
 827                           TOKEN_GETMAD($3,$$,'(');
 828                           TOKEN_GETMAD($4,$$,')');
 829                         }
 830         |       term ARROW '(' expr ')'     /* $subref->(@args) */
 831                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 832                                    append_elem(OP_LIST, $4,
 833                                        newCVREF(0, scalar($1))));
 834                           TOKEN_GETMAD($2,$$,'a');
 835                           TOKEN_GETMAD($3,$$,'(');
 836                           TOKEN_GETMAD($5,$$,')');
 837                         }
 838
 839         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
 840                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 841                                    append_elem(OP_LIST, $3,
 842                                                newCVREF(0, scalar($1))));
 843                           TOKEN_GETMAD($2,$$,'(');
 844                           TOKEN_GETMAD($4,$$,')');
 845                         }
 846         |       subscripted '(' ')'        /* $foo->{bar}->() */
 847                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 848                                    newCVREF(0, scalar($1)));
 849                           TOKEN_GETMAD($2,$$,'(');
 850                           TOKEN_GETMAD($3,$$,')');
 851                         }
 852         |       '(' expr ')' '[' expr ']'            /* list slice */
 853                         { $$ = newSLICEOP(0, $5, $2);
 854                           TOKEN_GETMAD($1,$$,'(');
 855                           TOKEN_GETMAD($3,$$,')');
 856                           TOKEN_GETMAD($4,$$,'[');
 857                           TOKEN_GETMAD($6,$$,']');
 858                         }
 859         |       '(' ')' '[' expr ']'                 /* empty list slice! */
 860                         { $$ = newSLICEOP(0, $4, Nullop);
 861                           TOKEN_GETMAD($1,$$,'(');
 862                           TOKEN_GETMAD($2,$$,')');
 863                           TOKEN_GETMAD($3,$$,'[');
 864                           TOKEN_GETMAD($5,$$,']');
 865                         }
 866     ;
 867
 868 /* Binary operators between terms */
 869 termbinop:      term ASSIGNOP term                     /* $x = $y */
 870                         { $$ = newASSIGNOP(OPf_STACKED, $1, IVAL($2), $3);
 871                           TOKEN_GETMAD($2,$$,'o');
 872                         }
 873         |       term POWOP term                        /* $x ** $y */
 874                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 875                           TOKEN_GETMAD($2,$$,'o');
 876                         }
 877         |       term MULOP term                        /* $x * $y, $x x $y */
 878                         {   if (IVAL($2) != OP_REPEAT)
 879                                 scalar($1);
 880                             $$ = newBINOP(IVAL($2), 0, $1, scalar($3));
 881                           TOKEN_GETMAD($2,$$,'o');
 882                         }
 883         |       term ADDOP term                        /* $x + $y */
 884                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 885                           TOKEN_GETMAD($2,$$,'o');
 886                         }
 887         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
 888                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 889                           TOKEN_GETMAD($2,$$,'o');
 890                         }
 891         |       term RELOP term                        /* $x > $y, etc. */
 892                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 893                           TOKEN_GETMAD($2,$$,'o');
 894                         }
 895         |       term EQOP term                         /* $x == $y, $x eq $y */
 896                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 897                           TOKEN_GETMAD($2,$$,'o');
 898                         }
 899         |       term BITANDOP term                     /* $x & $y */
 900                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 901                           TOKEN_GETMAD($2,$$,'o');
 902                         }
 903         |       term BITOROP term                      /* $x | $y */
 904                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 905                           TOKEN_GETMAD($2,$$,'o');
 906                         }
 907         |       term DOTDOT term                       /* $x..$y, $x...$y */
 908                         {
 909                           $$ = newRANGE(IVAL($2), scalar($1), scalar($3));
 910                           DO_MAD(
 911                               UNOP *op;
 912                               op = (UNOP*)$$;
 913                               op = (UNOP*)op->op_first; /* get to flop */
 914                               op = (UNOP*)op->op_first; /* get to flip */
 915                               op = (UNOP*)op->op_first; /* get to range */
 916                               token_getmad($2,(OP*)op,'o');
 917                             )
 918                         }
 919         |       term ANDAND term                       /* $x && $y */
 920                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
 921                           TOKEN_GETMAD($2,$$,'o');
 922                         }
 923         |       term OROR term                         /* $x || $y */
 924                         { $$ = newLOGOP(OP_OR, 0, $1, $3);
 925                           TOKEN_GETMAD($2,$$,'o');
 926                         }
 927         |       term DORDOR term                       /* $x // $y */
 928                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
 929                           TOKEN_GETMAD($2,$$,'o');
 930                         }
 931         |       term MATCHOP term                      /* $x =~ /$y/ */
 932                         { $$ = bind_match(IVAL($2), $1, $3);
 933                           TOKEN_GETMAD($2,
 934                                 ($$->op_type == OP_NOT
 935                                     ? ((UNOP*)$$)->op_first : $$),
 936                                 '~');
 937                         }
 938     ;
 939
 940 /* Unary operators and terms */
 941 termunop : '-' term %prec UMINUS                       /* -$x */
 942                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2));
 943                           TOKEN_GETMAD($1,$$,'o');
 944                         }
 945         |       '+' term %prec UMINUS                  /* +$x */
 946                         { $$ = IF_MAD(
 947                                     newUNOP(OP_NULL, 0, $2),
 948                                     $2
 949                                 );
 950                           TOKEN_GETMAD($1,$$,'+');
 951                         }
 952         |       '!' term                               /* !$x */
 953                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
 954                           TOKEN_GETMAD($1,$$,'o');
 955                         }
 956         |       '~' term                               /* ~$x */
 957                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));
 958                           TOKEN_GETMAD($1,$$,'o');
 959                         }
 960         |       term POSTINC                           /* $x++ */
 961                         { $$ = newUNOP(OP_POSTINC, 0,
 962                                         mod(scalar($1), OP_POSTINC));
 963                           TOKEN_GETMAD($2,$$,'o');
 964                         }
 965         |       term POSTDEC                           /* $x-- */
 966                         { $$ = newUNOP(OP_POSTDEC, 0,
 967                                         mod(scalar($1), OP_POSTDEC));
 968                           TOKEN_GETMAD($2,$$,'o');
 969                         }
 970         |       PREINC term                            /* ++$x */
 971                         { $$ = newUNOP(OP_PREINC, 0,
 972                                         mod(scalar($2), OP_PREINC));
 973                           TOKEN_GETMAD($1,$$,'o');
 974                         }
 975         |       PREDEC term                            /* --$x */
 976                         { $$ = newUNOP(OP_PREDEC, 0,
 977                                         mod(scalar($2), OP_PREDEC));
 978                           TOKEN_GETMAD($1,$$,'o');
 979                         }
 980
 981     ;
 982
 983 /* Constructors for anonymous data */
 984 anonymous:      '[' expr ']'
 985                         { $$ = newANONLIST($2);
 986                           TOKEN_GETMAD($1,$$,'[');
 987                           TOKEN_GETMAD($3,$$,']');
 988                         }
 989         |       '[' ']'
 990                         { $$ = newANONLIST(Nullop);
 991                           TOKEN_GETMAD($1,$$,'[');
 992                           TOKEN_GETMAD($2,$$,']');
 993                         }
 994         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
 995                         { $$ = newANONHASH($2);
 996                           TOKEN_GETMAD($1,$$,'{');
 997                           TOKEN_GETMAD($3,$$,';');
 998                           TOKEN_GETMAD($4,$$,'}');
 999                         }
1000         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
1001                         { $$ = newANONHASH(Nullop);
1002                           TOKEN_GETMAD($1,$$,'{');
1003                           TOKEN_GETMAD($2,$$,';');
1004                           TOKEN_GETMAD($3,$$,'}');
1005                         }
1006         |       ANONSUB startanonsub proto subattrlist block    %prec '('
1007                         { SvREFCNT_inc(PL_compcv);
1008                           $$ = newANONATTRSUB($2, $3, $4, $5);
1009                           TOKEN_GETMAD($1,$$,'o');
1010                           OP_GETMAD($3,$$,'s');
1011                           OP_GETMAD($4,$$,'a');
1012                         }
1013
1014     ;
1015
1016 /* Things called with "do" */
1017 termdo  :       DO term %prec UNIOP                     /* do $filename */
1018                         { $$ = dofile($2, IVAL($1));
1019                           TOKEN_GETMAD($1,$$,'o');
1020                         }
1021         |       DO block        %prec '('               /* do { code */
1022                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2));
1023                           TOKEN_GETMAD($1,$$,'D');
1024                         }
1025         |       DO WORD '(' ')'                         /* do somesub() */
1026                         { $$ = newUNOP(OP_ENTERSUB,
1027                             OPf_SPECIAL|OPf_STACKED,
1028                             prepend_elem(OP_LIST,
1029                                 scalar(newCVREF(
1030                                     (OPpENTERSUB_AMPER<<8),
1031                                     scalar($2)
1032                                 )),Nullop)); dep();
1033                           TOKEN_GETMAD($1,$$,'o');
1034                           TOKEN_GETMAD($3,$$,'(');
1035                           TOKEN_GETMAD($4,$$,')');
1036                         }
1037         |       DO WORD '(' expr ')'                    /* do somesub(@args) */
1038                         { $$ = newUNOP(OP_ENTERSUB,
1039                             OPf_SPECIAL|OPf_STACKED,
1040                             append_elem(OP_LIST,
1041                                 $4,
1042                                 scalar(newCVREF(
1043                                     (OPpENTERSUB_AMPER<<8),
1044                                     scalar($2)
1045                                 )))); dep();
1046                           TOKEN_GETMAD($1,$$,'o');
1047                           TOKEN_GETMAD($3,$$,'(');
1048                           TOKEN_GETMAD($5,$$,')');
1049                         }
1050         |       DO scalar '(' ')'                      /* do $subref () */
1051                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1052                             prepend_elem(OP_LIST,
1053                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();
1054                           TOKEN_GETMAD($1,$$,'o');
1055                           TOKEN_GETMAD($3,$$,'(');
1056                           TOKEN_GETMAD($4,$$,')');
1057                         }
1058         |       DO scalar '(' expr ')'                 /* do $subref (@args) */
1059                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1060                             prepend_elem(OP_LIST,
1061                                 $4,
1062                                 scalar(newCVREF(0,scalar($2))))); dep();
1063                           TOKEN_GETMAD($1,$$,'o');
1064                           TOKEN_GETMAD($3,$$,'(');
1065                           TOKEN_GETMAD($5,$$,')');
1066                         }
1067
1068         ;
1069
1070 term    :       termbinop
1071         |       termunop
1072         |       anonymous
1073         |       termdo
1074         |       term '?' term ':' term
1075                         { $$ = newCONDOP(0, $1, $3, $5);
1076                           TOKEN_GETMAD($2,$$,'?');
1077                           TOKEN_GETMAD($4,$$,':');
1078                         }
1079         |       REFGEN term                          /* \$x, \@y, \%z */
1080                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN));
1081                           TOKEN_GETMAD($1,$$,'o');
1082                         }
1083         |       myattrterm      %prec UNIOP
1084                         { $$ = $1; }
1085         |       LOCAL term      %prec UNIOP
1086                         { $$ = localize($2,IVAL($1));
1087                           TOKEN_GETMAD($1,$$,'d');
1088                         }
1089         |       '(' expr ')'
1090                         { $$ = sawparens(IF_MAD(newUNOP(OP_NULL,0,$2), $2));
1091                           TOKEN_GETMAD($1,$$,'(');
1092                           TOKEN_GETMAD($3,$$,')');
1093                         }
1094         |       '(' ')'
1095                         { $$ = sawparens(newNULLLIST());
1096                           TOKEN_GETMAD($1,$$,'(');
1097                           TOKEN_GETMAD($2,$$,')');
1098                         }
1099         |       scalar  %prec '('
1100                         { $$ = $1; }
1101         |       star    %prec '('
1102                         { $$ = $1; }
1103         |       hsh     %prec '('
1104                         { $$ = $1; }
1105         |       ary     %prec '('
1106                         { $$ = $1; }
1107         |       arylen  %prec '('                    /* $#x, $#{ something } */
1108                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1109         |       subscripted
1110                         { $$ = $1; }
1111         |       ary '[' expr ']'                     /* array slice */
1112                         { $$ = prepend_elem(OP_ASLICE,
1113                                 newOP(OP_PUSHMARK, 0),
1114                                     newLISTOP(OP_ASLICE, 0,
1115                                         list($3),
1116                                         ref($1, OP_ASLICE)));
1117                           TOKEN_GETMAD($2,$$,'[');
1118                           TOKEN_GETMAD($4,$$,']');
1119                         }
1120         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
1121                         { $$ = prepend_elem(OP_HSLICE,
1122                                 newOP(OP_PUSHMARK, 0),
1123                                     newLISTOP(OP_HSLICE, 0,
1124                                         list($3),
1125                                         ref(oopsHV($1), OP_HSLICE)));
1126                             PL_expect = XOPERATOR;
1127                           TOKEN_GETMAD($2,$$,'{');
1128                           TOKEN_GETMAD($4,$$,';');
1129                           TOKEN_GETMAD($5,$$,'}');
1130                         }
1131         |       THING   %prec '('
1132                         { $$ = $1; }
1133         |       amper                                /* &foo; */
1134                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1135         |       amper '(' ')'                        /* &foo() */
1136                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1137                           TOKEN_GETMAD($2,$$,'(');
1138                           TOKEN_GETMAD($3,$$,')');
1139                         }
1140         |       amper '(' expr ')'                   /* &foo(@args) */
1141                         {
1142                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1143                                 append_elem(OP_LIST, $3, scalar($1)));
1144                           DO_MAD(
1145                               OP* op = $$;
1146                               if (op->op_type == OP_CONST) { /* defeat const fold */
1147                                 op = (OP*)op->op_madprop->mad_val;
1148                               }
1149                               token_getmad($2,op,'(');
1150                               token_getmad($4,op,')');
1151                           )
1152                         }
1153         |       NOAMP WORD listexpr                  /* foo(@args) */
1154                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1155                             append_elem(OP_LIST, $3, scalar($2)));
1156                           TOKEN_GETMAD($1,$$,'o');
1157                         }
1158         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1159                         { $$ = newOP(IVAL($1), OPf_SPECIAL);
1160                             PL_hints |= HINT_BLOCK_SCOPE;
1161                           TOKEN_GETMAD($1,$$,'o');
1162                         }
1163         |       LOOPEX term
1164                         { $$ = newLOOPEX(IVAL($1),$2);
1165                           TOKEN_GETMAD($1,$$,'o');
1166                         }
1167         |       NOTOP argexpr                        /* not $foo */
1168                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1169                           TOKEN_GETMAD($1,$$,'o');
1170                         }
1171         |       UNIOP                                /* Unary op, $_ implied */
1172                         { $$ = newOP(IVAL($1), 0);
1173                           TOKEN_GETMAD($1,$$,'o');
1174                         }
1175         |       UNIOP block                          /* eval { foo }* */
1176                         { $$ = newUNOP(IVAL($1), 0, $2);
1177                           TOKEN_GETMAD($1,$$,'o');
1178                         }
1179         |       UNIOP term                           /* Unary op */
1180                         { $$ = newUNOP(IVAL($1), 0, $2);
1181                           TOKEN_GETMAD($1,$$,'o');
1182                         }
1183         |       REQUIRE                              /* require, $_ implied *//* FIMXE for MAD needed? */
1184                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0); }
1185         |       REQUIRE term                         /* require Foo *//* FIMXE for MAD needed? */
1186                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2); }
1187         |       UNIOPSUB
1188                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1189         |       UNIOPSUB term                        /* Sub treated as unop */
1190                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1191                             append_elem(OP_LIST, $2, scalar($1))); }
1192         |       FUNC0                                /* Nullary operator */
1193                         { $$ = newOP(IVAL($1), 0);
1194                           TOKEN_GETMAD($1,$$,'o');
1195                         }
1196         |       FUNC0 '(' ')'
1197                         { $$ = newOP(IVAL($1), 0);
1198                           TOKEN_GETMAD($1,$$,'o');
1199                           TOKEN_GETMAD($2,$$,'(');
1200                           TOKEN_GETMAD($3,$$,')');
1201                         }
1202         |       FUNC0SUB                             /* Sub treated as nullop */
1203                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1204                                 scalar($1)); }
1205         |       FUNC1 '(' ')'                        /* not () */
1206                         { $$ = (IVAL($1) == OP_NOT)
1207                             ? newUNOP(IVAL($1), 0, newSVOP(OP_CONST, 0, newSViv(0)))
1208                             : newOP(IVAL($1), OPf_SPECIAL);
1209
1210                           TOKEN_GETMAD($1,$$,'o');
1211                           TOKEN_GETMAD($2,$$,'(');
1212                           TOKEN_GETMAD($3,$$,')');
1213                         }
1214         |       FUNC1 '(' expr ')'                   /* not($foo) */
1215                         { $$ = newUNOP(IVAL($1), 0, $3);
1216                           TOKEN_GETMAD($1,$$,'o');
1217                           TOKEN_GETMAD($2,$$,'(');
1218                           TOKEN_GETMAD($4,$$,')');
1219                         }
1220         |       PMFUNC '(' argexpr ')'          /* m//, s///, tr/// */
1221                         { $$ = pmruntime($1, $3, 1);
1222                           TOKEN_GETMAD($2,$$,'(');
1223                           TOKEN_GETMAD($4,$$,')');
1224                         }
1225         |       WORD
1226         |       listop
1227         ;
1228
1229 /* "my" declarations, with optional attributes */
1230 myattrterm:     MY myterm myattrlist
1231                         { $$ = my_attrs($2,$3);
1232                           DO_MAD(
1233                               token_getmad($1,$$,'d');
1234                               append_madprops($3->op_madprop, $$, 'a');
1235                               $3->op_madprop = 0;
1236                           )
1237                         }
1238         |       MY myterm
1239                         { $$ = localize($2,IVAL($1));
1240                           TOKEN_GETMAD($1,$$,'d');
1241                         }
1242         ;
1243
1244 /* Things that can be "my"'d */
1245 myterm  :       '(' expr ')'
1246                         { $$ = sawparens($2);
1247                           TOKEN_GETMAD($1,$$,'(');
1248                           TOKEN_GETMAD($3,$$,')');
1249                         }
1250         |       '(' ')'
1251                         { $$ = sawparens(newNULLLIST());
1252                           TOKEN_GETMAD($1,$$,'(');
1253                           TOKEN_GETMAD($2,$$,')');
1254                         }
1255         |       scalar  %prec '('
1256                         { $$ = $1; }
1257         |       hsh     %prec '('
1258                         { $$ = $1; }
1259         |       ary     %prec '('
1260                         { $$ = $1; }
1261         ;
1262
1263 /* Basic list expressions */
1264 listexpr:       /* NULL */ %prec PREC_LOW
1265                         { $$ = Nullop; }
1266         |       argexpr    %prec PREC_LOW
1267                         { $$ = $1; }
1268         ;
1269
1270 listexprcom:    /* NULL */
1271                         { $$ = Nullop; }
1272         |       expr
1273                         { $$ = $1; }
1274         |       expr ','
1275                         {
1276 #ifdef MAD
1277                           OP* op = newNULLLIST();
1278                           token_getmad($2,op,',');
1279                           $$ = append_elem(OP_LIST, $1, op);
1280 #else
1281                           $$ = $1;
1282 #endif
1283
1284                         }
1285         ;
1286
1287 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1288    lexical */
1289 my_scalar:      scalar
1290                         { PL_in_my = 0; $$ = my($1); }
1291         ;
1292
1293 amper   :       '&' indirob
1294                         { $$ = newCVREF(IVAL($1),$2);
1295                           TOKEN_GETMAD($1,$$,'&');
1296                         }
1297         ;
1298
1299 scalar  :       '$' indirob
1300                         { $$ = newSVREF($2);
1301                           TOKEN_GETMAD($1,$$,'$');
1302                         }
1303         ;
1304
1305 ary     :       '@' indirob
1306                         { $$ = newAVREF($2);
1307                           TOKEN_GETMAD($1,$$,'@');
1308                         }
1309         ;
1310
1311 hsh     :       '%' indirob
1312                         { $$ = newHVREF($2);
1313                           TOKEN_GETMAD($1,$$,'%');
1314                         }
1315         ;
1316
1317 arylen  :       DOLSHARP indirob
1318                         { $$ = newAVREF($2);
1319                           TOKEN_GETMAD($1,$$,'l');
1320                         }
1321         ;
1322
1323 star    :       '*' indirob
1324                         { $$ = newGVREF(0,$2);
1325                           TOKEN_GETMAD($1,$$,'*');
1326                         }
1327         ;
1328
1329 /* Indirect objects */
1330 indirob :       WORD
1331                         { $$ = scalar($1); }
1332         |       scalar %prec PREC_LOW
1333                         { $$ = scalar($1); }
1334         |       block
1335                         { $$ = scope($1); }
1336
1337         |       PRIVATEREF
1338                         { $$ = $1; }
1339         ;