perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-2002, Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those who wander are lost.'
  13  */
  14
  15 %{
  16 #include "EXTERN.h"
  17 #define PERL_IN_PERLY_C
  18 #include "perl.h"
  19 #ifdef EBCDIC
  20 #undef YYDEBUG
  21 #endif
  22 #define dep() deprecate("\"do\" to call subroutines")
  23
  24 /* stuff included here to make perly_c.diff apply better */
  25
  26 #define yydebug     PL_yydebug
  27 #define yynerrs     PL_yynerrs
  28 #define yyerrflag   PL_yyerrflag
  29 #define yychar      PL_yychar
  30 #define yyval       PL_yyval
  31 #define yylval      PL_yylval
  32
  33 struct ysv {
  34     short* yyss;
  35     YYSTYPE* yyvs;
  36     int oldyydebug;
  37     int oldyynerrs;
  38     int oldyyerrflag;
  39     int oldyychar;
  40     YYSTYPE oldyyval;
  41     YYSTYPE oldyylval;
  42 };
  43
  44 static void yydestruct(pTHX_ void *ptr);
  45
  46 %}
  47
  48 %start prog
  49
  50 %{
  51 #if 0 /* get this from perly.h instead */
  52 %}
  53
  54 %union {
  55     I32 ival;
  56     char *pval;
  57     OP *opval;
  58     GV *gvval;
  59 }
  60
  61 %{
  62 #endif /* 0 */
  63
  64 #ifdef USE_PURE_BISON
  65 #define YYLEX_PARAM (&yychar)
  66 #define yylex yylex_r
  67 #endif
  68
  69 %}
  70
  71 %token <ival> '{'
  72
  73 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  74 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  75 %token <pval> LABEL
  76 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  77 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  78 %token <ival> LOOPEX DOTDOT
  79 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
  80 %token <ival> RELOP EQOP MULOP ADDOP
  81 %token <ival> DOLSHARP DO HASHBRACK NOAMP
  82 %token <ival> LOCAL MY MYSUB
  83 %token COLONATTR
  84
  85 %type <ival> prog decl format startsub startanonsub startformsub
  86 %type <ival> progstart remember mremember '&'
  87 %type <opval> block mblock lineseq line loop cond else
  88 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
  89 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
  90 %type <opval> listexpr listexprcom indirob listop method
  91 %type <opval> formname subname proto subbody cont my_scalar
  92 %type <opval> subattrlist myattrlist mysubrout myattrterm myterm
  93 %type <opval> termbinop termunop anonymous termdo
  94 %type <pval> label
  95
  96 %nonassoc PREC_LOW
  97 %nonassoc LOOPEX
  98
  99 %left <ival> OROP DOROP
 100 %left ANDOP
 101 %right NOTOP
 102 %nonassoc LSTOP LSTOPSUB
 103 %left ','
 104 %right <ival> ASSIGNOP
 105 %right '?' ':'
 106 %nonassoc DOTDOT
 107 %left OROR DORDOR
 108 %left ANDAND
 109 %left <ival> BITOROP
 110 %left <ival> BITANDOP
 111 %nonassoc EQOP
 112 %nonassoc RELOP
 113 %nonassoc UNIOP UNIOPSUB
 114 %left <ival> SHIFTOP
 115 %left ADDOP
 116 %left MULOP
 117 %left <ival> MATCHOP
 118 %right '!' '~' UMINUS REFGEN
 119 %right <ival> POWOP
 120 %nonassoc PREINC PREDEC POSTINC POSTDEC
 121 %left ARROW
 122 %nonassoc <ival> ')'
 123 %left '('
 124 %left '[' '{'
 125
 126 %% /* RULES */
 127
 128 /* The whole program */
 129 prog    :       progstart
 130         /*CONTINUED*/   lineseq
 131                         { $$ = $1; newPROG(block_end($1,$2)); }
 132         ;
 133
 134 /* An ordinary block */
 135 block   :       '{' remember lineseq '}'
 136                         { if (PL_copline > (line_t)$1)
 137                               PL_copline = (line_t)$1;
 138                           $$ = block_end($2, $3); }
 139         ;
 140
 141 remember:       /* NULL */      /* start a full lexical scope */
 142                         { $$ = block_start(TRUE); }
 143         ;
 144
 145 progstart:
 146                 {
 147 #if defined(YYDEBUG) && defined(DEBUGGING)
 148                     yydebug = (DEBUG_p_TEST);
 149 #endif
 150                     PL_expect = XSTATE; $$ = block_start(TRUE);
 151                 }
 152         ;
 153
 154
 155 mblock  :       '{' mremember lineseq '}'
 156                         { if (PL_copline > (line_t)$1)
 157                               PL_copline = (line_t)$1;
 158                           $$ = block_end($2, $3); }
 159         ;
 160
 161 mremember:      /* NULL */      /* start a partial lexical scope */
 162                         { $$ = block_start(FALSE); }
 163         ;
 164
 165 /* A collection of "lines" in the program */
 166 lineseq :       /* NULL */
 167                         { $$ = Nullop; }
 168         |       lineseq decl
 169                         { $$ = $1; }
 170         |       lineseq line
 171                         {   $$ = append_list(OP_LINESEQ,
 172                                 (LISTOP*)$1, (LISTOP*)$2);
 173                             PL_pad_reset_pending = TRUE;
 174                             if ($1 && $2) PL_hints |= HINT_BLOCK_SCOPE; }
 175         ;
 176
 177 /* A "line" in the program */
 178 line    :       label cond
 179                         { $$ = newSTATEOP(0, $1, $2); }
 180         |       loop    /* loops add their own labels */
 181         |       label ';'
 182                         { if ($1 != Nullch) {
 183                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 184                             }
 185                             else {
 186                               $$ = Nullop;
 187                               PL_copline = NOLINE;
 188                             }
 189                             PL_expect = XSTATE; }
 190         |       label sideff ';'
 191                         { $$ = newSTATEOP(0, $1, $2);
 192                           PL_expect = XSTATE; }
 193         ;
 194
 195 /* An expression which may have a side-effect */
 196 sideff  :       error
 197                         { $$ = Nullop; }
 198         |       expr
 199                         { $$ = $1; }
 200         |       expr IF expr
 201                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 202         |       expr UNLESS expr
 203                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 204         |       expr WHILE expr
 205                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 206         |       expr UNTIL iexpr
 207                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
 208         |       expr FOR expr
 209                         { $$ = newFOROP(0, Nullch, (line_t)$2,
 210                                         Nullop, $3, $1, Nullop); }
 211         ;
 212
 213 /* else and elsif blocks */
 214 else    :       /* NULL */
 215                         { $$ = Nullop; }
 216         |       ELSE mblock
 217                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2); }
 218         |       ELSIF '(' mexpr ')' mblock else
 219                         { PL_copline = (line_t)$1;
 220                             $$ = newCONDOP(0, $3, scope($5), $6);
 221                             PL_hints |= HINT_BLOCK_SCOPE; }
 222         ;
 223
 224 /* Real conditional expressions */
 225 cond    :       IF '(' remember mexpr ')' mblock else
 226                         { PL_copline = (line_t)$1;
 227                             $$ = block_end($3,
 228                                    newCONDOP(0, $4, scope($6), $7)); }
 229         |       UNLESS '(' remember miexpr ')' mblock else
 230                         { PL_copline = (line_t)$1;
 231                             $$ = block_end($3,
 232                                    newCONDOP(0, $4, scope($6), $7)); }
 233         ;
 234
 235 /* Continue blocks */
 236 cont    :       /* NULL */
 237                         { $$ = Nullop; }
 238         |       CONTINUE block
 239                         { $$ = scope($2); }
 240         ;
 241
 242 /* Loops: while, until, for, and a bare block */
 243 loop    :       label WHILE '(' remember mtexpr ')' mblock cont
 244                         { PL_copline = (line_t)$2;
 245                             $$ = block_end($4,
 246                                    newSTATEOP(0, $1,
 247                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 248                                                 $2, $5, $7, $8))); }
 249         |       label UNTIL '(' remember miexpr ')' mblock cont
 250                         { PL_copline = (line_t)$2;
 251                             $$ = block_end($4,
 252                                    newSTATEOP(0, $1,
 253                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 254                                                 $2, $5, $7, $8))); }
 255         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 256                         { $$ = block_end($4,
 257                                  newFOROP(0, $1, (line_t)$2, $5, $7, $9, $10)); }
 258         |       label FOR scalar '(' remember mexpr ')' mblock cont
 259                         { $$ = block_end($5,
 260                                  newFOROP(0, $1, (line_t)$2, mod($3, OP_ENTERLOOP),
 261                                           $6, $8, $9)); }
 262         |       label FOR '(' remember mexpr ')' mblock cont
 263                         { $$ = block_end($4,
 264                                  newFOROP(0, $1, (line_t)$2, Nullop, $5, $7, $8)); }
 265         |       label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
 266                         /* basically fake up an initialize-while lineseq */
 267                         { OP *forop;
 268                           PL_copline = (line_t)$2;
 269                           forop = newSTATEOP(0, $1,
 270                                             newWHILEOP(0, 1, (LOOP*)Nullop,
 271                                                 $2, scalar($7),
 272                                                 $11, $9));
 273                           if ($5) {
 274                                 forop = append_elem(OP_LINESEQ,
 275                                         newSTATEOP(0, ($1?savepv($1):Nullch),
 276                                                    $5),
 277                                         forop);
 278                           }
 279
 280                           $$ = block_end($4, forop); }
 281         |       label block cont  /* a block is a loop that happens once */
 282                         { $$ = newSTATEOP(0, $1,
 283                                  newWHILEOP(0, 1, (LOOP*)Nullop,
 284                                             NOLINE, Nullop, $2, $3)); }
 285         ;
 286
 287 /* Normal expression */
 288 nexpr   :       /* NULL */
 289                         { $$ = Nullop; }
 290         |       sideff
 291         ;
 292
 293 /* Boolean expression */
 294 texpr   :       /* NULL means true */
 295                         { (void)scan_num("1", &yylval); $$ = yylval.opval; }
 296         |       expr
 297         ;
 298
 299 /* Inverted boolean expression */
 300 iexpr   :       expr
 301                         { $$ = invert(scalar($1)); }
 302         ;
 303
 304 /* Expression with its own lexical scope */
 305 mexpr   :       expr
 306                         { $$ = $1; intro_my(); }
 307         ;
 308
 309 mnexpr  :       nexpr
 310                         { $$ = $1; intro_my(); }
 311         ;
 312
 313 mtexpr  :       texpr
 314                         { $$ = $1; intro_my(); }
 315         ;
 316
 317 miexpr  :       iexpr
 318                         { $$ = $1; intro_my(); }
 319         ;
 320
 321 /* Optional "MAIN:"-style loop labels */
 322 label   :       /* empty */
 323                         { $$ = Nullch; }
 324         |       LABEL
 325         ;
 326
 327 /* Some kind of declaration - does not take part in the parse tree */
 328 decl    :       format
 329                         { $$ = 0; }
 330         |       subrout
 331                         { $$ = 0; }
 332         |       mysubrout
 333                         { $$ = 0; }
 334         |       package
 335                         { $$ = 0; }
 336         |       use
 337                         { $$ = 0; }
 338         ;
 339
 340 format  :       FORMAT startformsub formname block
 341                         { newFORM($2, $3, $4); }
 342         ;
 343
 344 formname:       WORD            { $$ = $1; }
 345         |       /* NULL */      { $$ = Nullop; }
 346         ;
 347
 348 /* Unimplemented "my sub foo { }" */
 349 mysubrout:      MYSUB startsub subname proto subattrlist subbody
 350                         { newMYSUB($2, $3, $4, $5, $6); }
 351         ;
 352
 353 /* Subroutine definition */
 354 subrout :       SUB startsub subname proto subattrlist subbody
 355                         { newATTRSUB($2, $3, $4, $5, $6); }
 356         ;
 357
 358 startsub:       /* NULL */      /* start a regular subroutine scope */
 359                         { $$ = start_subparse(FALSE, 0); }
 360         ;
 361
 362 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 363                         { $$ = start_subparse(FALSE, CVf_ANON); }
 364         ;
 365
 366 startformsub:   /* NULL */      /* start a format subroutine scope */
 367                         { $$ = start_subparse(TRUE, 0); }
 368         ;
 369
 370 /* Name of a subroutine - must be a bareword, could be special */
 371 subname :       WORD    { STRLEN n_a; char *name = SvPV(((SVOP*)$1)->op_sv,n_a);
 372                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
 373                               || strEQ(name, "INIT") || strEQ(name, "CHECK"))
 374                               CvSPECIAL_on(PL_compcv);
 375                           $$ = $1; }
 376         ;
 377
 378 /* Subroutine prototype */
 379 proto   :       /* NULL */
 380                         { $$ = Nullop; }
 381         |       THING
 382         ;
 383
 384 /* Optional list of subroutine attributes */
 385 subattrlist:    /* NULL */
 386                         { $$ = Nullop; }
 387         |       COLONATTR THING
 388                         { $$ = $2; }
 389         |       COLONATTR
 390                         { $$ = Nullop; }
 391         ;
 392
 393 /* List of attributes for a "my" variable declaration */
 394 myattrlist:     COLONATTR THING
 395                         { $$ = $2; }
 396         |       COLONATTR
 397                         { $$ = Nullop; }
 398         ;
 399
 400 /* Subroutine body - either null or a block */
 401 subbody :       block   { $$ = $1; }
 402         |       ';'     { $$ = Nullop; PL_expect = XSTATE; }
 403         ;
 404
 405 package :       PACKAGE WORD ';'
 406                         { package($2); }
 407         ;
 408
 409 use     :       USE startsub
 410                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
 411                     WORD WORD listexpr ';'
 412                         { utilize($1, $2, $4, $5, $6); }
 413         ;
 414
 415 /* Ordinary expressions; logical combinations */
 416 expr    :       expr ANDOP expr
 417                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 418         |       expr OROP expr
 419                         { $$ = newLOGOP($2, 0, $1, $3); }
 420         |       expr DOROP expr
 421                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
 422         |       argexpr %prec PREC_LOW
 423         ;
 424
 425 /* Expressions are a list of terms joined by commas */
 426 argexpr :       argexpr ','
 427                         { $$ = $1; }
 428         |       argexpr ',' term
 429                         { $$ = append_elem(OP_LIST, $1, $3); }
 430         |       term %prec PREC_LOW
 431         ;
 432
 433 /* List operators */
 434 listop  :       LSTOP indirob argexpr          /* print $fh @args */
 435                         { $$ = convert($1, OPf_STACKED,
 436                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 437         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
 438                         { $$ = convert($1, OPf_STACKED,
 439                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 440         |       term ARROW method '(' listexprcom ')' /* $foo->bar(list) */
 441                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 442                                 append_elem(OP_LIST,
 443                                     prepend_elem(OP_LIST, scalar($1), $5),
 444                                     newUNOP(OP_METHOD, 0, $3))); }
 445         |       term ARROW method                     /* $foo->bar */
 446                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 447                                 append_elem(OP_LIST, scalar($1),
 448                                     newUNOP(OP_METHOD, 0, $3))); }
 449         |       METHOD indirob listexpr              /* new Class @args */
 450                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 451                                 append_elem(OP_LIST,
 452                                     prepend_elem(OP_LIST, $2, $3),
 453                                     newUNOP(OP_METHOD, 0, $1))); }
 454         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
 455                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 456                                 append_elem(OP_LIST,
 457                                     prepend_elem(OP_LIST, $2, $4),
 458                                     newUNOP(OP_METHOD, 0, $1))); }
 459         |       LSTOP listexpr                       /* print @args */
 460                         { $$ = convert($1, 0, $2); }
 461         |       FUNC '(' listexprcom ')'             /* print (@args) */
 462                         { $$ = convert($1, 0, $3); }
 463         |       LSTOPSUB startanonsub block          /* map { foo } ... */
 464                         { $3 = newANONATTRSUB($2, 0, Nullop, $3); }
 465                     listexpr            %prec LSTOP  /* ... @bar */
 466                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 467                                  append_elem(OP_LIST,
 468                                    prepend_elem(OP_LIST, $3, $5), $1)); }
 469         ;
 470
 471 /* Names of methods. May use $object->$methodname */
 472 method  :       METHOD
 473         |       scalar
 474         ;
 475
 476 /* Some kind of subscripted expression */
 477 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
 478                         /* In this and all the hash accessors, ';' is
 479                          * provided by the tokeniser */
 480                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); }
 481         |       scalar '[' expr ']'          /* $array[$element] */
 482                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 483         |       term ARROW '[' expr ']'      /* somearef->[$element] */
 484                         { $$ = newBINOP(OP_AELEM, 0,
 485                                         ref(newAVREF($1),OP_RV2AV),
 486                                         scalar($4));}
 487         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
 488                         { $$ = newBINOP(OP_AELEM, 0,
 489                                         ref(newAVREF($1),OP_RV2AV),
 490                                         scalar($3));}
 491         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
 492                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 493                             PL_expect = XOPERATOR; }
 494         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
 495                         { $$ = newBINOP(OP_HELEM, 0,
 496                                         ref(newHVREF($1),OP_RV2HV),
 497                                         jmaybe($4));
 498                             PL_expect = XOPERATOR; }
 499         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
 500                         { $$ = newBINOP(OP_HELEM, 0,
 501                                         ref(newHVREF($1),OP_RV2HV),
 502                                         jmaybe($3));
 503                             PL_expect = XOPERATOR; }
 504         |       term ARROW '(' ')'          /* $subref->() */
 505                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 506                                    newCVREF(0, scalar($1))); }
 507         |       term ARROW '(' expr ')'     /* $subref->(@args) */
 508                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 509                                    append_elem(OP_LIST, $4,
 510                                        newCVREF(0, scalar($1)))); }
 511
 512         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
 513                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 514                                    append_elem(OP_LIST, $3,
 515                                                newCVREF(0, scalar($1)))); }
 516         |       subscripted '(' ')'        /* $foo->{bar}->() */
 517                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 518                                    newCVREF(0, scalar($1))); }
 519     ;
 520
 521 /* Binary operators between terms */
 522 termbinop       :       term ASSIGNOP term             /* $x = $y */
 523                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 524         |       term POWOP term                        /* $x ** $y */
 525                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 526         |       term MULOP term                        /* $x * $y, $x x $y */
 527                         {   if ($2 != OP_REPEAT)
 528                                 scalar($1);
 529                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 530         |       term ADDOP term                        /* $x + $y */
 531                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 532         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
 533                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 534         |       term RELOP term                        /* $x > $y, etc. */
 535                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 536         |       term EQOP term                         /* $x == $y, $x eq $y */
 537                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 538         |       term BITANDOP term                     /* $x & $y */
 539                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 540         |       term BITOROP term                      /* $x | $y */
 541                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 542         |       term DOTDOT term                       /* $x..$y, $x...$y */
 543                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 544         |       term ANDAND term                       /* $x && $y */
 545                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 546         |       term OROR term                         /* $x || $y */
 547                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 548         |       term DORDOR term                       /* $x // $y */
 549                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
 550         |       term MATCHOP term                      /* $x =~ /$y/ */
 551                         { $$ = bind_match($2, $1, $3); }
 552     ;
 553
 554 /* Unary operators and terms */
 555 termunop : '-' term %prec UMINUS                       /* -$x */
 556                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 557         |       '+' term %prec UMINUS                  /* +$x */
 558                         { $$ = $2; }
 559         |       '!' term                               /* !$x */
 560                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 561         |       '~' term                               /* ~$x */
 562                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 563         |       term POSTINC                           /* $x++ */
 564                         { $$ = newUNOP(OP_POSTINC, 0,
 565                                         mod(scalar($1), OP_POSTINC)); }
 566         |       term POSTDEC                           /* $x-- */
 567                         { $$ = newUNOP(OP_POSTDEC, 0,
 568                                         mod(scalar($1), OP_POSTDEC)); }
 569         |       PREINC term                            /* ++$x */
 570                         { $$ = newUNOP(OP_PREINC, 0,
 571                                         mod(scalar($2), OP_PREINC)); }
 572         |       PREDEC term                            /* --$x */
 573                         { $$ = newUNOP(OP_PREDEC, 0,
 574                                         mod(scalar($2), OP_PREDEC)); }
 575
 576     ;
 577
 578 /* Constructors for anonymous data */
 579 anonymous:      '[' expr ']'
 580                         { $$ = newANONLIST($2); }
 581         |       '[' ']'
 582                         { $$ = newANONLIST(Nullop); }
 583         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
 584                         { $$ = newANONHASH($2); }
 585         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
 586                         { $$ = newANONHASH(Nullop); }
 587         |       ANONSUB startanonsub proto subattrlist block    %prec '('
 588                         { $$ = newANONATTRSUB($2, $3, $4, $5); }
 589
 590     ;
 591
 592 /* Things called with "do" */
 593 termdo  :       DO term %prec UNIOP                     /* do $filename */
 594                         { $$ = dofile($2); }
 595         |       DO block        %prec '('               /* do { code */
 596                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 597         |       DO WORD '(' ')'                         /* do somesub() */
 598                         { $$ = newUNOP(OP_ENTERSUB,
 599                             OPf_SPECIAL|OPf_STACKED,
 600                             prepend_elem(OP_LIST,
 601                                 scalar(newCVREF(
 602                                     (OPpENTERSUB_AMPER<<8),
 603                                     scalar($2)
 604                                 )),Nullop)); dep();}
 605         |       DO WORD '(' expr ')'                    /* do somesub(@args) */
 606                         { $$ = newUNOP(OP_ENTERSUB,
 607                             OPf_SPECIAL|OPf_STACKED,
 608                             append_elem(OP_LIST,
 609                                 $4,
 610                                 scalar(newCVREF(
 611                                     (OPpENTERSUB_AMPER<<8),
 612                                     scalar($2)
 613                                 )))); dep();}
 614         |       DO scalar '(' ')'                      /* do $subref () */
 615                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 616                             prepend_elem(OP_LIST,
 617                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
 618         |       DO scalar '(' expr ')'                 /* do $subref (@args) */
 619                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 620                             prepend_elem(OP_LIST,
 621                                 $4,
 622                                 scalar(newCVREF(0,scalar($2))))); dep();}
 623
 624         ;
 625
 626 term    :       termbinop
 627         |       termunop
 628         |       anonymous
 629         |       termdo
 630         |       term '?' term ':' term
 631                         { $$ = newCONDOP(0, $1, $3, $5); }
 632         |       REFGEN term                          /* \$x, \@y, \%z */
 633                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 634         |       myattrterm      %prec UNIOP
 635                         { $$ = $1; }
 636         |       LOCAL term      %prec UNIOP
 637                         { $$ = localize($2,$1); }
 638         |       '(' expr ')'
 639                         { $$ = sawparens($2); }
 640         |       '(' ')'
 641                         { $$ = sawparens(newNULLLIST()); }
 642         |       scalar  %prec '('
 643                         { $$ = $1; }
 644         |       star    %prec '('
 645                         { $$ = $1; }
 646         |       hsh     %prec '('
 647                         { $$ = $1; }
 648         |       ary     %prec '('
 649                         { $$ = $1; }
 650         |       arylen  %prec '('                    /* $#x, $#{ something } */
 651                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 652         |       subscripted
 653                         { $$ = $1; }
 654         |       '(' expr ')' '[' expr ']'            /* list slice */
 655                         { $$ = newSLICEOP(0, $5, $2); }
 656         |       '(' ')' '[' expr ']'                 /* empty list slice! */
 657                         { $$ = newSLICEOP(0, $4, Nullop); }
 658         |       ary '[' expr ']'                     /* array slice */
 659                         { $$ = prepend_elem(OP_ASLICE,
 660                                 newOP(OP_PUSHMARK, 0),
 661                                     newLISTOP(OP_ASLICE, 0,
 662                                         list($3),
 663                                         ref($1, OP_ASLICE))); }
 664         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
 665                         { $$ = prepend_elem(OP_HSLICE,
 666                                 newOP(OP_PUSHMARK, 0),
 667                                     newLISTOP(OP_HSLICE, 0,
 668                                         list($3),
 669                                         ref(oopsHV($1), OP_HSLICE)));
 670                             PL_expect = XOPERATOR; }
 671         |       THING   %prec '('
 672                         { $$ = $1; }
 673         |       amper                                /* &foo; */
 674                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
 675         |       amper '(' ')'                        /* &foo() */
 676                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 677         |       amper '(' expr ')'                   /* &foo(@args) */
 678                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 679                             append_elem(OP_LIST, $3, scalar($1))); }
 680         |       NOAMP WORD listexpr                  /* foo(@args) */
 681                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 682                             append_elem(OP_LIST, $3, scalar($2))); }
 683         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
 684                         { $$ = newOP($1, OPf_SPECIAL);
 685                             PL_hints |= HINT_BLOCK_SCOPE; }
 686         |       LOOPEX term
 687                         { $$ = newLOOPEX($1,$2); }
 688         |       NOTOP argexpr                        /* not $foo */
 689                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 690         |       UNIOP                                /* Unary op, $_ implied */
 691                         { $$ = newOP($1, 0); }
 692         |       UNIOP block                          /* eval { foo }, I *think* */
 693                         { $$ = newUNOP($1, 0, $2); }
 694         |       UNIOP term                           /* Unary op */
 695                         { $$ = newUNOP($1, 0, $2); }
 696         |       UNIOPSUB term                        /* Sub treated as unop */
 697                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 698                             append_elem(OP_LIST, $2, scalar($1))); }
 699         |       FUNC0                                /* Nullary operator */
 700                         { $$ = newOP($1, 0); }
 701         |       FUNC0 '(' ')'
 702                         { $$ = newOP($1, 0); }
 703         |       FUNC0SUB                             /* Sub treated as nullop */
 704                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 705                                 scalar($1)); }
 706         |       FUNC1 '(' ')'                        /* not () */
 707                         { $$ = newOP($1, OPf_SPECIAL); }
 708         |       FUNC1 '(' expr ')'                   /* not($foo) */
 709                         { $$ = newUNOP($1, 0, $3); }
 710         |       PMFUNC '(' term ')'                  /* split (/foo/) */
 711                         { $$ = pmruntime($1, $3, Nullop); }
 712         |       PMFUNC '(' term ',' term ')'         /* split (/foo/,$bar) */
 713                         { $$ = pmruntime($1, $3, $5); }
 714         |       WORD
 715         |       listop
 716         ;
 717
 718 /* "my" declarations, with optional attributes */
 719 myattrterm:     MY myterm myattrlist
 720                         { $$ = my_attrs($2,$3); }
 721         |       MY myterm
 722                         { $$ = localize($2,$1); }
 723         ;
 724
 725 /* Things that can be "my"'d */
 726 myterm  :       '(' expr ')'
 727                         { $$ = sawparens($2); }
 728         |       '(' ')'
 729                         { $$ = sawparens(newNULLLIST()); }
 730         |       scalar  %prec '('
 731                         { $$ = $1; }
 732         |       hsh     %prec '('
 733                         { $$ = $1; }
 734         |       ary     %prec '('
 735                         { $$ = $1; }
 736         ;
 737
 738 /* Basic list expressions */
 739 listexpr:       /* NULL */ %prec PREC_LOW
 740                         { $$ = Nullop; }
 741         |       argexpr    %prec PREC_LOW
 742                         { $$ = $1; }
 743         ;
 744
 745 listexprcom:    /* NULL */
 746                         { $$ = Nullop; }
 747         |       expr
 748                         { $$ = $1; }
 749         |       expr ','
 750                         { $$ = $1; }
 751         ;
 752
 753 /* A little bit of trickery to make "for my $foo (@bar)" actually be
 754    lexical */
 755 my_scalar:      scalar
 756                         { PL_in_my = 0; $$ = my($1); }
 757         ;
 758
 759 amper   :       '&' indirob
 760                         { $$ = newCVREF($1,$2); }
 761         ;
 762
 763 scalar  :       '$' indirob
 764                         { $$ = newSVREF($2); }
 765         ;
 766
 767 ary     :       '@' indirob
 768                         { $$ = newAVREF($2); }
 769         ;
 770
 771 hsh     :       '%' indirob
 772                         { $$ = newHVREF($2); }
 773         ;
 774
 775 arylen  :       DOLSHARP indirob
 776                         { $$ = newAVREF($2); }
 777         ;
 778
 779 star    :       '*' indirob
 780                         { $$ = newGVREF(0,$2); }
 781         ;
 782
 783 /* Indirect objects */
 784 indirob :       WORD
 785                         { $$ = scalar($1); }
 786         |       scalar %prec PREC_LOW
 787                         { $$ = scalar($1);  }
 788         |       block
 789                         { $$ = scope($1); }
 790
 791         |       PRIVATEREF
 792                         { $$ = $1; }
 793         ;
 794
 795 %% /* PROGRAM */
 796
 797 /* more stuff added to make perly_c.diff easier to apply */
 798
 799 #ifdef yyparse
 800 #undef yyparse
 801 #endif
 802 #define yyparse() Perl_yyparse(pTHX)
 803