perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-1994, Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those that wander are lost.'
  13  */
  14
  15 %{
  16 #include "EXTERN.h"
  17 #include "perl.h"
  18
  19 static void
  20 dep()
  21 {
  22     deprecate("\"do\" to call subroutines");
  23 }
  24
  25 %}
  26
  27 %start prog
  28
  29 %union {
  30     I32 ival;
  31     char *pval;
  32     OP *opval;
  33     GV *gvval;
  34 }
  35
  36 %token <ival> '{' ')'
  37
  38 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  39 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  40 %token <pval> LABEL
  41 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  42 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  43 %token <ival> LOOPEX DOTDOT
  44 %token <ival> FUNC0 FUNC1 FUNC
  45 %token <ival> RELOP EQOP MULOP ADDOP
  46 %token <ival> DOLSHARP DO LOCAL HASHBRACK NOAMP
  47
  48 %type <ival> prog decl format remember startsub
  49 %type <opval> block lineseq line loop cond nexpr else argexpr
  50 %type <opval> expr term scalar ary hsh arylen star amper sideff
  51 %type <opval> listexpr listexprcom indirob
  52 %type <opval> texpr listop method proto
  53 %type <pval> label
  54 %type <opval> cont
  55
  56 %left <ival> OROP
  57 %left ANDOP
  58 %left NOTOP
  59 %nonassoc <ival> LSTOP
  60 %left ','
  61 %right <ival> ASSIGNOP
  62 %right '?' ':'
  63 %nonassoc DOTDOT
  64 %left OROR
  65 %left ANDAND
  66 %left <ival> BITOROP
  67 %left <ival> BITANDOP
  68 %nonassoc EQOP
  69 %nonassoc RELOP
  70 %nonassoc <ival> UNIOP
  71 %left <ival> SHIFTOP
  72 %left ADDOP
  73 %left MULOP
  74 %left <ival> MATCHOP
  75 %right '!' '~' UMINUS REFGEN
  76 %right <ival> POWOP
  77 %nonassoc PREINC PREDEC POSTINC POSTDEC
  78 %left ARROW
  79 %left '('
  80
  81 %% /* RULES */
  82
  83 prog    :       /* NULL */
  84                 {
  85 #if defined(YYDEBUG) && defined(DEBUGGING)
  86                     yydebug = (debug & 1);
  87 #endif
  88                     expect = XSTATE;
  89                 }
  90         /*CONTINUED*/   lineseq
  91                         { newPROG($2); }
  92         ;
  93
  94 block   :       '{' remember lineseq '}'
  95                         { $$ = block_end($1,$2,$3); }
  96         ;
  97
  98 remember:       /* NULL */      /* start a lexical scope */
  99                         { $$ = block_start(); }
 100         ;
 101
 102 lineseq :       /* NULL */
 103                         { $$ = Nullop; }
 104         |       lineseq decl
 105                         { $$ = $1; }
 106         |       lineseq line
 107                         {   $$ = append_list(OP_LINESEQ,
 108                                 (LISTOP*)$1, (LISTOP*)$2);
 109                             pad_reset_pending = TRUE;
 110                             if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
 111         ;
 112
 113 line    :       label cond
 114                         { $$ = newSTATEOP(0, $1, $2); }
 115         |       loop    /* loops add their own labels */
 116         |       label ';'
 117                         { if ($1 != Nullch) {
 118                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 119                             }
 120                             else {
 121                               $$ = Nullop;
 122                               copline = NOLINE;
 123                             }
 124                             expect = XSTATE; }
 125         |       label sideff ';'
 126                         { $$ = newSTATEOP(0, $1, $2);
 127                           expect = XSTATE; }
 128         ;
 129
 130 sideff  :       error
 131                         { $$ = Nullop; }
 132         |       expr
 133                         { $$ = $1; }
 134         |       expr IF expr
 135                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 136         |       expr UNLESS expr
 137                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 138         |       expr WHILE expr
 139                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 140         |       expr UNTIL expr
 141                         { $$ = newLOOPOP(OPf_PARENS, 1, invert(scalar($3)), $1);}
 142         ;
 143
 144 else    :       /* NULL */
 145                         { $$ = Nullop; }
 146         |       ELSE block
 147                         { $$ = scope($2); }
 148         |       ELSIF '(' expr ')' block else
 149                         { copline = $1;
 150                             $$ = newSTATEOP(0, 0,
 151                                 newCONDOP(0, $3, scope($5), $6));
 152                             hints |= HINT_BLOCK_SCOPE; }
 153         ;
 154
 155 cond    :       IF '(' expr ')' block else
 156                         { copline = $1;
 157                             $$ = newCONDOP(0, $3, scope($5), $6); }
 158         |       UNLESS '(' expr ')' block else
 159                         { copline = $1;
 160                             $$ = newCONDOP(0,
 161                                 invert(scalar($3)), scope($5), $6); }
 162         |       IF block block else
 163                         { copline = $1;
 164                             deprecate("if BLOCK BLOCK");
 165                             $$ = newCONDOP(0, scope($2), scope($3), $4); }
 166         |       UNLESS block block else
 167                         { copline = $1;
 168                             deprecate("unless BLOCK BLOCK");
 169                             $$ = newCONDOP(0, invert(scalar(scope($2))),
 170                                                 scope($3), $4); }
 171         ;
 172
 173 cont    :       /* NULL */
 174                         { $$ = Nullop; }
 175         |       CONTINUE block
 176                         { $$ = scope($2); }
 177         ;
 178
 179 loop    :       label WHILE '(' texpr ')' block cont
 180                         { copline = $2;
 181                             $$ = newSTATEOP(0, $1,
 182                                     newWHILEOP(0, 1, (LOOP*)Nullop,
 183                                         $4, $6, $7) ); }
 184         |       label UNTIL '(' expr ')' block cont
 185                         { copline = $2;
 186                             $$ = newSTATEOP(0, $1,
 187                                     newWHILEOP(0, 1, (LOOP*)Nullop,
 188                                         invert(scalar($4)), $6, $7) ); }
 189         |       label WHILE block block cont
 190                         { copline = $2;
 191                             $$ = newSTATEOP(0, $1,
 192                                     newWHILEOP(0, 1, (LOOP*)Nullop,
 193                                         scope($3), $4, $5) ); }
 194         |       label UNTIL block block cont
 195                         { copline = $2;
 196                             $$ = newSTATEOP(0, $1,
 197                                     newWHILEOP(0, 1, (LOOP*)Nullop,
 198                                         invert(scalar(scope($3))), $4, $5)); }
 199         |       label FOR scalar '(' expr ')' block cont
 200                         { $$ = newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
 201                                 $5, $7, $8); }
 202         |       label FOR '(' expr ')' block cont
 203                         { $$ = newFOROP(0, $1, $2, Nullop, $4, $6, $7); }
 204         |       label FOR '(' nexpr ';' texpr ';' nexpr ')' block
 205                         /* basically fake up an initialize-while lineseq */
 206                         {  copline = $2;
 207                             $$ = append_elem(OP_LINESEQ,
 208                                     newSTATEOP(0, $1, scalar($4)),
 209                                     newSTATEOP(0, $1,
 210                                         newWHILEOP(0, 1, (LOOP*)Nullop,
 211                                             scalar($6), $10, scalar($8)) )); }
 212         |       label block cont  /* a block is a loop that happens once */
 213                         { $$ = newSTATEOP(0,
 214                                 $1, newWHILEOP(0, 1, (LOOP*)Nullop,
 215                                         Nullop, $2, $3)); }
 216         ;
 217
 218 nexpr   :       /* NULL */
 219                         { $$ = Nullop; }
 220         |       sideff
 221         ;
 222
 223 texpr   :       /* NULL means true */
 224                         { (void)scan_num("1"); $$ = yylval.opval; }
 225         |       expr
 226         ;
 227
 228 label   :       /* empty */
 229                         { $$ = Nullch; }
 230         |       LABEL
 231         ;
 232
 233 decl    :       format
 234                         { $$ = 0; }
 235         |       subrout
 236                         { $$ = 0; }
 237         |       package
 238                         { $$ = 0; }
 239         |       use
 240                         { $$ = 0; }
 241         ;
 242
 243 format  :       FORMAT startsub WORD block
 244                         { newFORM($2, $3, $4); }
 245         |       FORMAT startsub block
 246                         { newFORM($2, Nullop, $3); }
 247         ;
 248
 249 subrout :       SUB startsub WORD proto block
 250                         { newSUB($2, $3, $4, $5); }
 251         |       SUB startsub WORD proto ';'
 252                         { newSUB($2, $3, $4, Nullop); expect = XSTATE; }
 253         ;
 254
 255 proto   :       /* NULL */
 256                         { $$ = Nullop; }
 257         |       THING
 258         ;
 259
 260 startsub:       /* NULL */      /* start a subroutine scope */
 261                         { $$ = start_subparse(); }
 262         ;
 263
 264 package :       PACKAGE WORD ';'
 265                         { package($2); }
 266         |       PACKAGE ';'
 267                         { package(Nullop); }
 268         ;
 269
 270 use     :       USE WORD listexpr ';'
 271                         { utilize($1, $2, $3); }
 272         ;
 273
 274 expr    :       expr ANDOP expr
 275                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 276         |       expr OROP expr
 277                         { $$ = newLOGOP($2, 0, $1, $3); }
 278         |       NOTOP expr
 279                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 280         |       argexpr
 281         ;
 282
 283 argexpr :       argexpr ','
 284                         { $$ = $1; }
 285         |       argexpr ',' term
 286                         { $$ = append_elem(OP_LIST, $1, $3); }
 287         |       term
 288         ;
 289
 290 listop  :       LSTOP indirob argexpr
 291                         { $$ = convert($1, OPf_STACKED,
 292                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 293         |       FUNC '(' indirob expr ')'
 294                         { $$ = convert($1, OPf_STACKED,
 295                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 296         |       term ARROW method '(' listexprcom ')'
 297                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 298                                 append_elem(OP_LIST,
 299                                     prepend_elem(OP_LIST, $1, $5),
 300                                     newUNOP(OP_METHOD, 0, $3))); }
 301         |       METHOD indirob listexpr
 302                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 303                                 append_elem(OP_LIST,
 304                                     prepend_elem(OP_LIST, $2, $3),
 305                                     newUNOP(OP_METHOD, 0, $1))); }
 306         |       FUNCMETH indirob '(' listexprcom ')'
 307                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 308                                 append_elem(OP_LIST,
 309                                     prepend_elem(OP_LIST, $2, $4),
 310                                     newUNOP(OP_METHOD, 0, $1))); }
 311         |       LSTOP listexpr
 312                         { $$ = convert($1, 0, $2); }
 313         |       FUNC '(' listexprcom ')'
 314                         { $$ = convert($1, 0, $3); }
 315         |       LSTOPSUB startsub block listexpr        %prec LSTOP
 316                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 317                             append_elem(OP_LIST,
 318                               prepend_elem(OP_LIST, newANONSUB($2, 0, $3), $4),
 319                               $1)); }
 320         ;
 321
 322 method  :       METHOD
 323         |       scalar
 324         ;
 325
 326 term    :       term ASSIGNOP term
 327                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 328         |       term POWOP term
 329                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 330         |       term MULOP term
 331                         {   if ($2 != OP_REPEAT)
 332                                 scalar($1);
 333                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 334         |       term ADDOP term
 335                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 336         |       term SHIFTOP term
 337                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 338         |       term RELOP term
 339                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 340         |       term EQOP term
 341                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 342         |       term BITANDOP term
 343                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 344         |       term BITOROP term
 345                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 346         |       term DOTDOT term
 347                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 348         |       term ANDAND term
 349                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 350         |       term OROR term
 351                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 352         |       term '?' term ':' term
 353                         { $$ = newCONDOP(0, $1, $3, $5); }
 354         |       term MATCHOP term
 355                         { $$ = bind_match($2, $1, $3); }
 356
 357         |       '-' term %prec UMINUS
 358                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 359         |       '+' term %prec UMINUS
 360                         { $$ = $2; }
 361         |       '!' term
 362                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 363         |       '~' term
 364                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 365         |       REFGEN term
 366                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 367         |       term POSTINC
 368                         { $$ = newUNOP(OP_POSTINC, 0,
 369                                         mod(scalar($1), OP_POSTINC)); }
 370         |       term POSTDEC
 371                         { $$ = newUNOP(OP_POSTDEC, 0,
 372                                         mod(scalar($1), OP_POSTDEC)); }
 373         |       PREINC term
 374                         { $$ = newUNOP(OP_PREINC, 0,
 375                                         mod(scalar($2), OP_PREINC)); }
 376         |       PREDEC term
 377                         { $$ = newUNOP(OP_PREDEC, 0,
 378                                         mod(scalar($2), OP_PREDEC)); }
 379         |       LOCAL term      %prec UNIOP
 380                         { $$ = localize($2,$1); }
 381         |       '(' expr ')'
 382                         { $$ = sawparens($2); }
 383         |       '(' ')'
 384                         { $$ = sawparens(newNULLLIST()); }
 385         |       '[' expr ']'                            %prec '('
 386                         { $$ = newANONLIST($2); }
 387         |       '[' ']'                                 %prec '('
 388                         { $$ = newANONLIST(Nullop); }
 389         |       HASHBRACK expr ';' '}'                  %prec '('
 390                         { $$ = newANONHASH($2); }
 391         |       HASHBRACK ';' '}'                               %prec '('
 392                         { $$ = newANONHASH(Nullop); }
 393         |       ANONSUB startsub proto block                    %prec '('
 394                         { $$ = newANONSUB($2, $3, $4); }
 395         |       scalar  %prec '('
 396                         { $$ = $1; }
 397         |       star    %prec '('
 398                         { $$ = $1; }
 399         |       scalar '[' expr ']'     %prec '('
 400                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 401         |       term ARROW '[' expr ']' %prec '('
 402                         { $$ = newBINOP(OP_AELEM, 0,
 403                                         ref(newAVREF($1),OP_RV2AV),
 404                                         scalar($4));}
 405         |       term '[' expr ']'       %prec '('
 406                         { assertref($1); $$ = newBINOP(OP_AELEM, 0,
 407                                         ref(newAVREF($1),OP_RV2AV),
 408                                         scalar($3));}
 409         |       hsh     %prec '('
 410                         { $$ = $1; }
 411         |       ary     %prec '('
 412                         { $$ = $1; }
 413         |       arylen  %prec '('
 414                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 415         |       scalar '{' expr ';' '}' %prec '('
 416                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 417                             expect = XOPERATOR; }
 418         |       term ARROW '{' expr ';' '}'     %prec '('
 419                         { $$ = newBINOP(OP_HELEM, 0,
 420                                         ref(newHVREF($1),OP_RV2HV),
 421                                         jmaybe($4));
 422                             expect = XOPERATOR; }
 423         |       term '{' expr ';' '}'   %prec '('
 424                         { assertref($1); $$ = newBINOP(OP_HELEM, 0,
 425                                         ref(newHVREF($1),OP_RV2HV),
 426                                         jmaybe($3));
 427                             expect = XOPERATOR; }
 428         |       '(' expr ')' '[' expr ']'       %prec '('
 429                         { $$ = newSLICEOP(0, $5, $2); }
 430         |       '(' ')' '[' expr ']'    %prec '('
 431                         { $$ = newSLICEOP(0, $4, Nullop); }
 432         |       ary '[' expr ']'        %prec '('
 433                         { $$ = prepend_elem(OP_ASLICE,
 434                                 newOP(OP_PUSHMARK, 0),
 435                                     newLISTOP(OP_ASLICE, 0,
 436                                         list($3),
 437                                         ref($1, OP_ASLICE))); }
 438         |       ary '{' expr ';' '}'    %prec '('
 439                         { $$ = prepend_elem(OP_HSLICE,
 440                                 newOP(OP_PUSHMARK, 0),
 441                                     newLISTOP(OP_HSLICE, 0,
 442                                         list($3),
 443                                         ref(oopsHV($1), OP_HSLICE)));
 444                             expect = XOPERATOR; }
 445         |       THING   %prec '('
 446                         { $$ = $1; }
 447         |       amper
 448                         { $$ = newUNOP(OP_ENTERSUB, 0,
 449                                 scalar($1)); }
 450         |       amper '(' ')'
 451                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 452         |       amper '(' expr ')'
 453                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 454                             append_elem(OP_LIST, $3, scalar($1))); }
 455         |       NOAMP WORD listexpr
 456                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 457                             append_elem(OP_LIST,
 458                                 $3, newCVREF(scalar($2)))); }
 459         |       DO term %prec UNIOP
 460                         { $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
 461         |       DO block        %prec '('
 462                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 463         |       DO WORD '(' ')'
 464                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 465                             prepend_elem(OP_LIST,
 466                                 scalar(newCVREF(scalar($2))), Nullop)); dep();}
 467         |       DO WORD '(' expr ')'
 468                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 469                             append_elem(OP_LIST,
 470                                 $4,
 471                                 scalar(newCVREF(scalar($2))))); dep();}
 472         |       DO scalar '(' ')'
 473                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 474                             prepend_elem(OP_LIST,
 475                                 scalar(newCVREF(scalar($2))), Nullop)); dep();}
 476         |       DO scalar '(' expr ')'
 477                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 478                             prepend_elem(OP_LIST,
 479                                 $4,
 480                                 scalar(newCVREF(scalar($2))))); dep();}
 481         |       LOOPEX
 482                         { $$ = newOP($1, OPf_SPECIAL);
 483                             hints |= HINT_BLOCK_SCOPE; }
 484         |       LOOPEX term
 485                         { $$ = newLOOPEX($1,$2); }
 486         |       UNIOP
 487                         { $$ = newOP($1, 0); }
 488         |       UNIOP block
 489                         { $$ = newUNOP($1, 0, $2); }
 490         |       UNIOP term
 491                         { $$ = newUNOP($1, 0, $2); }
 492         |       UNIOPSUB term
 493                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 494                             append_elem(OP_LIST, $2, scalar($1))); }
 495         |       FUNC0
 496                         { $$ = newOP($1, 0); }
 497         |       FUNC0 '(' ')'
 498                         { $$ = newOP($1, 0); }
 499         |       FUNC0SUB
 500                         { $$ = newUNOP(OP_ENTERSUB, 0,
 501                                 scalar($1)); }
 502         |       FUNC1 '(' ')'
 503                         { $$ = newOP($1, OPf_SPECIAL); }
 504         |       FUNC1 '(' expr ')'
 505                         { $$ = newUNOP($1, 0, $3); }
 506         |       PMFUNC '(' term ')'
 507                         { $$ = pmruntime($1, $3, Nullop); }
 508         |       PMFUNC '(' term ',' term ')'
 509                         { $$ = pmruntime($1, $3, $5); }
 510         |       WORD
 511         |       listop
 512         ;
 513
 514 listexpr:       /* NULL */
 515                         { $$ = Nullop; }
 516         |       argexpr
 517                         { $$ = $1; }
 518         ;
 519
 520 listexprcom:    /* NULL */
 521                         { $$ = Nullop; }
 522         |       expr
 523                         { $$ = $1; }
 524         |       expr ','
 525                         { $$ = $1; }
 526         ;
 527
 528 amper   :       '&' indirob
 529                         { $$ = newCVREF($2); }
 530         ;
 531
 532 scalar  :       '$' indirob
 533                         { $$ = newSVREF($2); }
 534         ;
 535
 536 ary     :       '@' indirob
 537                         { $$ = newAVREF($2); }
 538         ;
 539
 540 hsh     :       '%' indirob
 541                         { $$ = newHVREF($2); }
 542         ;
 543
 544 arylen  :       DOLSHARP indirob
 545                         { $$ = newAVREF($2); }
 546         ;
 547
 548 star    :       '*' indirob
 549                         { $$ = newGVREF(0,$2); }
 550         ;
 551
 552 indirob :       WORD
 553                         { $$ = scalar($1); }
 554         |       scalar
 555                         { $$ = scalar($1);  }
 556         |       block
 557                         { $$ = scope($1); }
 558
 559         |       PRIVATEREF
 560                         { $$ = $1; }
 561         ;
 562
 563 %% /* PROGRAM */