perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-1994, Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those that wander are lost.'
  13  */
  14
  15 %{
  16 #include "EXTERN.h"
  17 #include "perl.h"
  18
  19 static void
  20 dep()
  21 {
  22     deprecate("\"do\" to call subroutines");
  23 }
  24
  25 %}
  26
  27 %start prog
  28
  29 %union {
  30     I32 ival;
  31     char *pval;
  32     OP *opval;
  33     GV *gvval;
  34 }
  35
  36 %token <ival> '{' ')'
  37
  38 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  39 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  40 %token <pval> LABEL
  41 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  42 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  43 %token <ival> LOOPEX DOTDOT
  44 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
  45 %token <ival> RELOP EQOP MULOP ADDOP
  46 %token <ival> DOLSHARP DO HASHBRACK NOAMP
  47 %token LOCAL MY
  48
  49 %type <ival> prog decl local format startsub startanonsub
  50 %type <ival> remember mremember '&'
  51 %type <opval> block mblock lineseq line loop cond else
  52 %type <opval> expr term scalar ary hsh arylen star amper sideff
  53 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
  54 %type <opval> listexpr listexprcom indirob
  55 %type <opval> listop method subname proto subbody cont my_scalar
  56 %type <pval> label
  57
  58 %left <ival> OROP
  59 %left ANDOP
  60 %right NOTOP
  61 %nonassoc LSTOP LSTOPSUB
  62 %left ','
  63 %right <ival> ASSIGNOP
  64 %right '?' ':'
  65 %nonassoc DOTDOT
  66 %left OROR
  67 %left ANDAND
  68 %left <ival> BITOROP
  69 %left <ival> BITANDOP
  70 %nonassoc EQOP
  71 %nonassoc RELOP
  72 %nonassoc UNIOP UNIOPSUB
  73 %left <ival> SHIFTOP
  74 %left ADDOP
  75 %left MULOP
  76 %left <ival> MATCHOP
  77 %right '!' '~' UMINUS REFGEN
  78 %right <ival> POWOP
  79 %nonassoc PREINC PREDEC POSTINC POSTDEC
  80 %left ARROW
  81 %left '('
  82
  83 %% /* RULES */
  84
  85 prog    :       /* NULL */
  86                 {
  87 #if defined(YYDEBUG) && defined(DEBUGGING)
  88                     yydebug = (debug & 1);
  89 #endif
  90                     expect = XSTATE;
  91                 }
  92         /*CONTINUED*/   lineseq
  93                         { newPROG($2); }
  94         ;
  95
  96 block   :       '{' remember lineseq '}'
  97                         { if (copline > (line_t)$1)
  98                               copline = $1;
  99                           $$ = block_end($2, $3); }
 100         ;
 101
 102 remember:       /* NULL */      /* start a full lexical scope */
 103                         { $$ = block_start(TRUE); }
 104         ;
 105
 106 mblock  :       '{' mremember lineseq '}'
 107                         { if (copline > (line_t)$1)
 108                               copline = $1;
 109                           $$ = block_end($2, $3); }
 110         ;
 111
 112 mremember:      /* NULL */      /* start a partial lexical scope */
 113                         { $$ = block_start(FALSE); }
 114         ;
 115
 116 lineseq :       /* NULL */
 117                         { $$ = Nullop; }
 118         |       lineseq decl
 119                         { $$ = $1; }
 120         |       lineseq line
 121                         {   $$ = append_list(OP_LINESEQ,
 122                                 (LISTOP*)$1, (LISTOP*)$2);
 123                             pad_reset_pending = TRUE;
 124                             if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
 125         ;
 126
 127 line    :       label cond
 128                         { $$ = newSTATEOP(0, $1, $2); }
 129         |       loop    /* loops add their own labels */
 130         |       label ';'
 131                         { if ($1 != Nullch) {
 132                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 133                             }
 134                             else {
 135                               $$ = Nullop;
 136                               copline = NOLINE;
 137                             }
 138                             expect = XSTATE; }
 139         |       label sideff ';'
 140                         { $$ = newSTATEOP(0, $1, $2);
 141                           expect = XSTATE; }
 142         ;
 143
 144 sideff  :       error
 145                         { $$ = Nullop; }
 146         |       expr
 147                         { $$ = $1; }
 148         |       expr IF expr
 149                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 150         |       expr UNLESS expr
 151                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 152         |       expr WHILE expr
 153                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 154         |       expr UNTIL iexpr
 155                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
 156         ;
 157
 158 else    :       /* NULL */
 159                         { $$ = Nullop; }
 160         |       ELSE mblock
 161                         { $$ = scope($2); }
 162         |       ELSIF '(' mexpr ')' mblock else
 163                         { copline = $1;
 164                             $$ = newSTATEOP(0, Nullch,
 165                                    newCONDOP(0, $3, scope($5), $6));
 166                             hints |= HINT_BLOCK_SCOPE; }
 167         ;
 168
 169 cond    :       IF '(' remember mexpr ')' mblock else
 170                         { copline = $1;
 171                             $$ = block_end($3,
 172                                    newCONDOP(0, $4, scope($6), $7)); }
 173         |       UNLESS '(' remember miexpr ')' mblock else
 174                         { copline = $1;
 175                             $$ = block_end($3,
 176                                    newCONDOP(0, $4, scope($6), $7)); }
 177         ;
 178
 179 cont    :       /* NULL */
 180                         { $$ = Nullop; }
 181         |       CONTINUE block
 182                         { $$ = scope($2); }
 183         ;
 184
 185 loop    :       label WHILE '(' remember mtexpr ')' mblock cont
 186                         { copline = $2;
 187                             $$ = block_end($4,
 188                                    newSTATEOP(0, $1,
 189                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 190                                                 $5, $7, $8))); }
 191         |       label UNTIL '(' remember miexpr ')' mblock cont
 192                         { copline = $2;
 193                             $$ = block_end($4,
 194                                    newSTATEOP(0, $1,
 195                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 196                                                 $5, $7, $8))); }
 197         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 198                         { $$ = block_end($4,
 199                                  newFOROP(0, $1, $2, $5, $7, $9, $10)); }
 200         |       label FOR scalar '(' remember mexpr ')' mblock cont
 201                         { $$ = block_end($5,
 202                                  newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
 203                                           $6, $8, $9)); }
 204         |       label FOR '(' remember mexpr ')' mblock cont
 205                         { $$ = block_end($4,
 206                                  newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
 207         |       label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
 208                         /* basically fake up an initialize-while lineseq */
 209                         { copline = $2;
 210                             $$ = block_end($4,
 211                                    append_elem(OP_LINESEQ, scalar($5),
 212                                      newSTATEOP(0, $1,
 213                                        newWHILEOP(0, 1, (LOOP*)Nullop,
 214                                                   scalar($7),
 215                                                   $11, scalar($9))))); }
 216         |       label block cont  /* a block is a loop that happens once */
 217                         { $$ = newSTATEOP(0,
 218                                 $1, newWHILEOP(0, 1, (LOOP*)Nullop,
 219                                         Nullop, $2, $3)); }
 220         ;
 221
 222 nexpr   :       /* NULL */
 223                         { $$ = Nullop; }
 224         |       sideff
 225         ;
 226
 227 texpr   :       /* NULL means true */
 228                         { (void)scan_num("1"); $$ = yylval.opval; }
 229         |       expr
 230         ;
 231
 232 iexpr   :       expr
 233                         { $$ = invert(scalar($1)); }
 234         ;
 235
 236 mexpr   :       expr
 237                         { $$ = $1; intro_my(); }
 238         ;
 239
 240 mnexpr  :       nexpr
 241                         { $$ = $1; intro_my(); }
 242         ;
 243
 244 mtexpr  :       texpr
 245                         { $$ = $1; intro_my(); }
 246         ;
 247
 248 miexpr  :       iexpr
 249                         { $$ = $1; intro_my(); }
 250         ;
 251
 252 label   :       /* empty */
 253                         { $$ = Nullch; }
 254         |       LABEL
 255         ;
 256
 257 decl    :       format
 258                         { $$ = 0; }
 259         |       subrout
 260                         { $$ = 0; }
 261         |       package
 262                         { $$ = 0; }
 263         |       use
 264                         { $$ = 0; }
 265         ;
 266
 267 format  :       FORMAT startsub WORD block
 268                         { newFORM($2, $3, $4); }
 269         |       FORMAT startsub block
 270                         { newFORM($2, Nullop, $3); }
 271         ;
 272
 273 subrout :       SUB startsub subname proto subbody
 274                         { newSUB($2, $3, $4, $5); }
 275         ;
 276
 277 startsub:       /* NULL */      /* start a subroutine scope */
 278                         { $$ = start_subparse(); }
 279         ;
 280
 281 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 282                         { $$ = start_subparse();
 283                           CvANON_on(compcv); }
 284         ;
 285
 286 subname :       WORD    { char *name = SvPVx(((SVOP*)$1)->op_sv, na);
 287                           if (strEQ(name, "BEGIN") || strEQ(name, "END"))
 288                               CvUNIQUE_on(compcv);
 289                           $$ = $1; }
 290         ;
 291
 292 proto   :       /* NULL */
 293                         { $$ = Nullop; }
 294         |       THING
 295         ;
 296
 297 subbody :       block   { $$ = $1; }
 298         |       ';'     { $$ = Nullop; expect = XSTATE; }
 299         ;
 300
 301 package :       PACKAGE WORD ';'
 302                         { package($2); }
 303         |       PACKAGE ';'
 304                         { package(Nullop); }
 305         ;
 306
 307 use     :       USE startsub
 308                         { CvUNIQUE_on(compcv); /* It's a BEGIN {} */ }
 309                     WORD WORD listexpr ';'
 310                         { utilize($1, $2, $4, $5, $6); }
 311         ;
 312
 313 expr    :       expr ANDOP expr
 314                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 315         |       expr OROP expr
 316                         { $$ = newLOGOP($2, 0, $1, $3); }
 317         |       argexpr
 318         ;
 319
 320 argexpr :       argexpr ','
 321                         { $$ = $1; }
 322         |       argexpr ',' term
 323                         { $$ = append_elem(OP_LIST, $1, $3); }
 324         |       term
 325         ;
 326
 327 listop  :       LSTOP indirob argexpr
 328                         { $$ = convert($1, OPf_STACKED,
 329                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 330         |       FUNC '(' indirob expr ')'
 331                         { $$ = convert($1, OPf_STACKED,
 332                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 333         |       term ARROW method '(' listexprcom ')'
 334                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 335                                 append_elem(OP_LIST,
 336                                     prepend_elem(OP_LIST, scalar($1), $5),
 337                                     newUNOP(OP_METHOD, 0, $3))); }
 338         |       METHOD indirob listexpr
 339                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 340                                 append_elem(OP_LIST,
 341                                     prepend_elem(OP_LIST, $2, $3),
 342                                     newUNOP(OP_METHOD, 0, $1))); }
 343         |       FUNCMETH indirob '(' listexprcom ')'
 344                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 345                                 append_elem(OP_LIST,
 346                                     prepend_elem(OP_LIST, $2, $4),
 347                                     newUNOP(OP_METHOD, 0, $1))); }
 348         |       LSTOP listexpr
 349                         { $$ = convert($1, 0, $2); }
 350         |       FUNC '(' listexprcom ')'
 351                         { $$ = convert($1, 0, $3); }
 352         |       LSTOPSUB startanonsub block
 353                         { $3 = newANONSUB($2, 0, $3); }
 354                     listexpr            %prec LSTOP
 355                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 356                                  append_elem(OP_LIST,
 357                                    prepend_elem(OP_LIST, $3, $5), $1)); }
 358         ;
 359
 360 method  :       METHOD
 361         |       scalar
 362         ;
 363
 364 term    :       term ASSIGNOP term
 365                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 366         |       term POWOP term
 367                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 368         |       term MULOP term
 369                         {   if ($2 != OP_REPEAT)
 370                                 scalar($1);
 371                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 372         |       term ADDOP term
 373                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 374         |       term SHIFTOP term
 375                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 376         |       term RELOP term
 377                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 378         |       term EQOP term
 379                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 380         |       term BITANDOP term
 381                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 382         |       term BITOROP term
 383                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 384         |       term DOTDOT term
 385                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 386         |       term ANDAND term
 387                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 388         |       term OROR term
 389                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 390         |       term '?' term ':' term
 391                         { $$ = newCONDOP(0, $1, $3, $5); }
 392         |       term MATCHOP term
 393                         { $$ = bind_match($2, $1, $3); }
 394
 395         |       '-' term %prec UMINUS
 396                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 397         |       '+' term %prec UMINUS
 398                         { $$ = $2; }
 399         |       '!' term
 400                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 401         |       '~' term
 402                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 403         |       REFGEN term
 404                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 405         |       term POSTINC
 406                         { $$ = newUNOP(OP_POSTINC, 0,
 407                                         mod(scalar($1), OP_POSTINC)); }
 408         |       term POSTDEC
 409                         { $$ = newUNOP(OP_POSTDEC, 0,
 410                                         mod(scalar($1), OP_POSTDEC)); }
 411         |       PREINC term
 412                         { $$ = newUNOP(OP_PREINC, 0,
 413                                         mod(scalar($2), OP_PREINC)); }
 414         |       PREDEC term
 415                         { $$ = newUNOP(OP_PREDEC, 0,
 416                                         mod(scalar($2), OP_PREDEC)); }
 417         |       local term      %prec UNIOP
 418                         { $$ = localize($2,$1); }
 419         |       '(' expr ')'
 420                         { $$ = sawparens($2); }
 421         |       '(' ')'
 422                         { $$ = sawparens(newNULLLIST()); }
 423         |       '[' expr ']'                            %prec '('
 424                         { $$ = newANONLIST($2); }
 425         |       '[' ']'                                 %prec '('
 426                         { $$ = newANONLIST(Nullop); }
 427         |       HASHBRACK expr ';' '}'                  %prec '('
 428                         { $$ = newANONHASH($2); }
 429         |       HASHBRACK ';' '}'                               %prec '('
 430                         { $$ = newANONHASH(Nullop); }
 431         |       ANONSUB startanonsub proto block                %prec '('
 432                         { $$ = newANONSUB($2, $3, $4); }
 433         |       scalar  %prec '('
 434                         { $$ = $1; }
 435         |       star '{' expr ';' '}'
 436                         { $$ = newBINOP(OP_GELEM, 0, newGVREF(0,$1), $3); }
 437         |       star    %prec '('
 438                         { $$ = $1; }
 439         |       scalar '[' expr ']'     %prec '('
 440                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 441         |       term ARROW '[' expr ']' %prec '('
 442                         { $$ = newBINOP(OP_AELEM, 0,
 443                                         ref(newAVREF($1),OP_RV2AV),
 444                                         scalar($4));}
 445         |       term '[' expr ']'       %prec '('
 446                         { assertref($1); $$ = newBINOP(OP_AELEM, 0,
 447                                         ref(newAVREF($1),OP_RV2AV),
 448                                         scalar($3));}
 449         |       hsh     %prec '('
 450                         { $$ = $1; }
 451         |       ary     %prec '('
 452                         { $$ = $1; }
 453         |       arylen  %prec '('
 454                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 455         |       scalar '{' expr ';' '}' %prec '('
 456                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 457                             expect = XOPERATOR; }
 458         |       term ARROW '{' expr ';' '}'     %prec '('
 459                         { $$ = newBINOP(OP_HELEM, 0,
 460                                         ref(newHVREF($1),OP_RV2HV),
 461                                         jmaybe($4));
 462                             expect = XOPERATOR; }
 463         |       term '{' expr ';' '}'   %prec '('
 464                         { assertref($1); $$ = newBINOP(OP_HELEM, 0,
 465                                         ref(newHVREF($1),OP_RV2HV),
 466                                         jmaybe($3));
 467                             expect = XOPERATOR; }
 468         |       '(' expr ')' '[' expr ']'       %prec '('
 469                         { $$ = newSLICEOP(0, $5, $2); }
 470         |       '(' ')' '[' expr ']'    %prec '('
 471                         { $$ = newSLICEOP(0, $4, Nullop); }
 472         |       ary '[' expr ']'        %prec '('
 473                         { $$ = prepend_elem(OP_ASLICE,
 474                                 newOP(OP_PUSHMARK, 0),
 475                                     newLISTOP(OP_ASLICE, 0,
 476                                         list($3),
 477                                         ref($1, OP_ASLICE))); }
 478         |       ary '{' expr ';' '}'    %prec '('
 479                         { $$ = prepend_elem(OP_HSLICE,
 480                                 newOP(OP_PUSHMARK, 0),
 481                                     newLISTOP(OP_HSLICE, 0,
 482                                         list($3),
 483                                         ref(oopsHV($1), OP_HSLICE)));
 484                             expect = XOPERATOR; }
 485         |       THING   %prec '('
 486                         { $$ = $1; }
 487         |       amper
 488                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
 489         |       amper '(' ')'
 490                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 491         |       amper '(' expr ')'
 492                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 493                             append_elem(OP_LIST, $3, scalar($1))); }
 494         |       NOAMP WORD listexpr
 495                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 496                             append_elem(OP_LIST, $3, scalar($2))); }
 497         |       DO term %prec UNIOP
 498                         { $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
 499         |       DO block        %prec '('
 500                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 501         |       DO WORD '(' ')'
 502                         { $$ = newUNOP(OP_ENTERSUB,
 503                             OPf_SPECIAL|OPf_STACKED,
 504                             prepend_elem(OP_LIST,
 505                                 scalar(newCVREF(
 506                                     (OPpENTERSUB_AMPER<<8),
 507                                     scalar($2)
 508                                 )),Nullop)); dep();}
 509         |       DO WORD '(' expr ')'
 510                         { $$ = newUNOP(OP_ENTERSUB,
 511                             OPf_SPECIAL|OPf_STACKED,
 512                             append_elem(OP_LIST,
 513                                 $4,
 514                                 scalar(newCVREF(
 515                                     (OPpENTERSUB_AMPER<<8),
 516                                     scalar($2)
 517                                 )))); dep();}
 518         |       DO scalar '(' ')'
 519                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 520                             prepend_elem(OP_LIST,
 521                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
 522         |       DO scalar '(' expr ')'
 523                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 524                             prepend_elem(OP_LIST,
 525                                 $4,
 526                                 scalar(newCVREF(0,scalar($2))))); dep();}
 527         |       LOOPEX
 528                         { $$ = newOP($1, OPf_SPECIAL);
 529                             hints |= HINT_BLOCK_SCOPE; }
 530         |       LOOPEX term
 531                         { $$ = newLOOPEX($1,$2); }
 532         |       NOTOP argexpr
 533                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 534         |       UNIOP
 535                         { $$ = newOP($1, 0); }
 536         |       UNIOP block
 537                         { $$ = newUNOP($1, 0, $2); }
 538         |       UNIOP term
 539                         { $$ = newUNOP($1, 0, $2); }
 540         |       UNIOPSUB term
 541                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 542                             append_elem(OP_LIST, $2, scalar($1))); }
 543         |       FUNC0
 544                         { $$ = newOP($1, 0); }
 545         |       FUNC0 '(' ')'
 546                         { $$ = newOP($1, 0); }
 547         |       FUNC0SUB
 548                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 549                                 scalar($1)); }
 550         |       FUNC1 '(' ')'
 551                         { $$ = newOP($1, OPf_SPECIAL); }
 552         |       FUNC1 '(' expr ')'
 553                         { $$ = newUNOP($1, 0, $3); }
 554         |       PMFUNC '(' term ')'
 555                         { $$ = pmruntime($1, $3, Nullop); }
 556         |       PMFUNC '(' term ',' term ')'
 557                         { $$ = pmruntime($1, $3, $5); }
 558         |       WORD
 559         |       listop
 560         ;
 561
 562 listexpr:       /* NULL */
 563                         { $$ = Nullop; }
 564         |       argexpr
 565                         { $$ = $1; }
 566         ;
 567
 568 listexprcom:    /* NULL */
 569                         { $$ = Nullop; }
 570         |       expr
 571                         { $$ = $1; }
 572         |       expr ','
 573                         { $$ = $1; }
 574         ;
 575
 576 local   :       LOCAL   { $$ = 0; }
 577         |       MY      { $$ = 1; }
 578         ;
 579
 580 my_scalar:      scalar
 581                         { in_my = 0; $$ = my($1); }
 582         ;
 583
 584 amper   :       '&' indirob
 585                         { $$ = newCVREF($1,$2); }
 586         ;
 587
 588 scalar  :       '$' indirob
 589                         { $$ = newSVREF($2); }
 590         ;
 591
 592 ary     :       '@' indirob
 593                         { $$ = newAVREF($2); }
 594         ;
 595
 596 hsh     :       '%' indirob
 597                         { $$ = newHVREF($2); }
 598         ;
 599
 600 arylen  :       DOLSHARP indirob
 601                         { $$ = newAVREF($2); }
 602         ;
 603
 604 star    :       '*' indirob
 605                         { $$ = newGVREF(0,$2); }
 606         ;
 607
 608 indirob :       WORD
 609                         { $$ = scalar($1); }
 610         |       scalar
 611                         { $$ = scalar($1);  }
 612         |       block
 613                         { $$ = scope($1); }
 614
 615         |       PRIVATEREF
 616                         { $$ = $1; }
 617         ;
 618
 619 %% /* PROGRAM */