perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-1994, Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those that wander are lost.'
  13  */
  14
  15 %{
  16 #include "EXTERN.h"
  17 #include "perl.h"
  18
  19 static void
  20 dep()
  21 {
  22     deprecate("\"do\" to call subroutines");
  23 }
  24
  25 %}
  26
  27 %start prog
  28
  29 %union {
  30     I32 ival;
  31     char *pval;
  32     OP *opval;
  33     GV *gvval;
  34 }
  35
  36 %token <ival> '{' ')'
  37
  38 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  39 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  40 %token <pval> LABEL
  41 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  42 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  43 %token <ival> LOOPEX DOTDOT
  44 %token <ival> FUNC0 FUNC1 FUNC
  45 %token <ival> RELOP EQOP MULOP ADDOP
  46 %token <ival> DOLSHARP DO HASHBRACK NOAMP
  47 %token LOCAL MY
  48
  49 %type <ival> prog decl local format startsub remember mremember '&'
  50 %type <opval> block mblock lineseq line loop cond else
  51 %type <opval> expr term scalar ary hsh arylen star amper sideff
  52 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
  53 %type <opval> listexpr listexprcom indirob
  54 %type <opval> listop method proto cont my_scalar
  55 %type <pval> label
  56
  57 %left <ival> OROP
  58 %left ANDOP
  59 %right NOTOP
  60 %nonassoc <ival> LSTOP
  61 %left ','
  62 %right <ival> ASSIGNOP
  63 %right '?' ':'
  64 %nonassoc DOTDOT
  65 %left OROR
  66 %left ANDAND
  67 %left <ival> BITOROP
  68 %left <ival> BITANDOP
  69 %nonassoc EQOP
  70 %nonassoc RELOP
  71 %nonassoc <ival> UNIOP
  72 %left <ival> SHIFTOP
  73 %left ADDOP
  74 %left MULOP
  75 %left <ival> MATCHOP
  76 %right '!' '~' UMINUS REFGEN
  77 %right <ival> POWOP
  78 %nonassoc PREINC PREDEC POSTINC POSTDEC
  79 %left ARROW
  80 %left '('
  81
  82 %% /* RULES */
  83
  84 prog    :       /* NULL */
  85                 {
  86 #if defined(YYDEBUG) && defined(DEBUGGING)
  87                     yydebug = (debug & 1);
  88 #endif
  89                     expect = XSTATE;
  90                 }
  91         /*CONTINUED*/   lineseq
  92                         { newPROG($2); }
  93         ;
  94
  95 block   :       '{' remember lineseq '}'
  96                         { $$ = block_end($1,$2,$3); }
  97         ;
  98
  99 remember:       /* NULL */      /* start a full lexical scope */
 100                         { $$ = block_start(TRUE); }
 101         ;
 102
 103 mblock  :       '{' mremember lineseq '}'
 104                         { $$ = block_end($1,$2,$3); }
 105         ;
 106
 107 mremember:      /* NULL */      /* start a partial lexical scope */
 108                         { $$ = block_start(FALSE); }
 109         ;
 110
 111 lineseq :       /* NULL */
 112                         { $$ = Nullop; }
 113         |       lineseq decl
 114                         { $$ = $1; }
 115         |       lineseq line
 116                         {   $$ = append_list(OP_LINESEQ,
 117                                 (LISTOP*)$1, (LISTOP*)$2);
 118                             pad_reset_pending = TRUE;
 119                             if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
 120         ;
 121
 122 line    :       label cond
 123                         { $$ = newSTATEOP(0, $1, $2); }
 124         |       loop    /* loops add their own labels */
 125         |       label ';'
 126                         { if ($1 != Nullch) {
 127                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 128                             }
 129                             else {
 130                               $$ = Nullop;
 131                               copline = NOLINE;
 132                             }
 133                             expect = XSTATE; }
 134         |       label sideff ';'
 135                         { $$ = newSTATEOP(0, $1, $2);
 136                           expect = XSTATE; }
 137         ;
 138
 139 sideff  :       error
 140                         { $$ = Nullop; }
 141         |       expr
 142                         { $$ = $1; }
 143         |       expr IF expr
 144                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 145         |       expr UNLESS expr
 146                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 147         |       expr WHILE expr
 148                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 149         |       expr UNTIL iexpr
 150                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
 151         ;
 152
 153 else    :       /* NULL */
 154                         { $$ = Nullop; }
 155         |       ELSE mblock
 156                         { $$ = scope($2); }
 157         |       ELSIF '(' mexpr ')' mblock else
 158                         { copline = $1;
 159                             $$ = newSTATEOP(0, Nullch,
 160                                    newCONDOP(0, $3, scope($5), $6));
 161                             hints |= HINT_BLOCK_SCOPE; }
 162         ;
 163
 164 cond    :       IF '(' remember mexpr ')' mblock else
 165                         { copline = $1;
 166                             $$ = block_end($1, $3,
 167                                    newCONDOP(0, $4, scope($6), $7)); }
 168         |       UNLESS '(' remember miexpr ')' mblock else
 169                         { copline = $1;
 170                             $$ = block_end($1, $3,
 171                                    newCONDOP(0, $4, scope($6), $7)); }
 172         |       IF block block else
 173                         { copline = $1;
 174                             deprecate("if BLOCK BLOCK");
 175                             $$ = newCONDOP(0, scope($2), scope($3), $4); }
 176         |       UNLESS block block else
 177                         { copline = $1;
 178                             deprecate("unless BLOCK BLOCK");
 179                             $$ = newCONDOP(0, invert(scalar(scope($2))),
 180                                                 scope($3), $4); }
 181         ;
 182
 183 cont    :       /* NULL */
 184                         { $$ = Nullop; }
 185         |       CONTINUE block
 186                         { $$ = scope($2); }
 187         ;
 188
 189 loop    :       label WHILE '(' remember mtexpr ')' mblock cont
 190                         { copline = $2;
 191                             $$ = block_end($2, $4,
 192                                    newSTATEOP(0, $1,
 193                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 194                                                 $5, $7, $8))); }
 195         |       label UNTIL '(' remember miexpr ')' mblock cont
 196                         { copline = $2;
 197                             $$ = block_end($2, $4,
 198                                    newSTATEOP(0, $1,
 199                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 200                                                 $5, $7, $8))); }
 201         |       label WHILE block block cont
 202                         { copline = $2;
 203                             $$ = newWHILEOP(0, 1, (LOOP*)Nullop,
 204                                             scope($3), $4, $5); }
 205         |       label UNTIL block block cont
 206                         { copline = $2;
 207                             $$ = newWHILEOP(0, 1, (LOOP*)Nullop,
 208                                             invert(scalar(scope($3))),
 209                                             $4, $5); }
 210         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 211                         { $$ = block_end($2, $4,
 212                                  newFOROP(0, $1, $2, $5, $7, $9, $10)); }
 213         |       label FOR scalar '(' remember mexpr ')' mblock cont
 214                         { $$ = block_end($2, $5,
 215                                  newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
 216                                           $6, $8, $9)); }
 217         |       label FOR '(' remember mexpr ')' mblock cont
 218                         { $$ = block_end($2, $4,
 219                                  newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
 220         |       label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
 221                         /* basically fake up an initialize-while lineseq */
 222                         { copline = $2;
 223                             $$ = block_end($2, $4,
 224                                    append_elem(OP_LINESEQ, scalar($5),
 225                                      newSTATEOP(0, $1,
 226                                        newWHILEOP(0, 1, (LOOP*)Nullop,
 227                                                   scalar($7),
 228                                                   $11, scalar($9))))); }
 229         |       label block cont  /* a block is a loop that happens once */
 230                         { $$ = newSTATEOP(0,
 231                                 $1, newWHILEOP(0, 1, (LOOP*)Nullop,
 232                                         Nullop, $2, $3)); }
 233         ;
 234
 235 nexpr   :       /* NULL */
 236                         { $$ = Nullop; }
 237         |       sideff
 238         ;
 239
 240 texpr   :       /* NULL means true */
 241                         { (void)scan_num("1"); $$ = yylval.opval; }
 242         |       expr
 243         ;
 244
 245 iexpr   :       expr
 246                         { $$ = invert(scalar($1)); }
 247         ;
 248
 249 mexpr   :       expr
 250                         { $$ = $1; intro_my(); }
 251         ;
 252
 253 mnexpr  :       nexpr
 254                         { $$ = $1; intro_my(); }
 255         ;
 256
 257 mtexpr  :       texpr
 258                         { $$ = $1; intro_my(); }
 259         ;
 260
 261 miexpr  :       iexpr
 262                         { $$ = $1; intro_my(); }
 263         ;
 264
 265 label   :       /* empty */
 266                         { $$ = Nullch; }
 267         |       LABEL
 268         ;
 269
 270 decl    :       format
 271                         { $$ = 0; }
 272         |       subrout
 273                         { $$ = 0; }
 274         |       package
 275                         { $$ = 0; }
 276         |       use
 277                         { $$ = 0; }
 278         ;
 279
 280 format  :       FORMAT startsub WORD block
 281                         { newFORM($2, $3, $4); }
 282         |       FORMAT startsub block
 283                         { newFORM($2, Nullop, $3); }
 284         ;
 285
 286 subrout :       SUB startsub WORD proto block
 287                         { newSUB($2, $3, $4, $5); }
 288         |       SUB startsub WORD proto ';'
 289                         { newSUB($2, $3, $4, Nullop); expect = XSTATE; }
 290         ;
 291
 292 proto   :       /* NULL */
 293                         { $$ = Nullop; }
 294         |       THING
 295         ;
 296
 297 startsub:       /* NULL */      /* start a subroutine scope */
 298                         { $$ = start_subparse(); }
 299         ;
 300
 301 package :       PACKAGE WORD ';'
 302                         { package($2); }
 303         |       PACKAGE ';'
 304                         { package(Nullop); }
 305         ;
 306
 307 use     :       USE startsub WORD WORD listexpr ';'
 308                         { utilize($1, $2, $3, $4, $5); }
 309         ;
 310
 311 expr    :       expr ANDOP expr
 312                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 313         |       expr OROP expr
 314                         { $$ = newLOGOP($2, 0, $1, $3); }
 315         |       argexpr
 316         ;
 317
 318 argexpr :       argexpr ','
 319                         { $$ = $1; }
 320         |       argexpr ',' term
 321                         { $$ = append_elem(OP_LIST, $1, $3); }
 322         |       term
 323         ;
 324
 325 listop  :       LSTOP indirob argexpr
 326                         { $$ = convert($1, OPf_STACKED,
 327                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 328         |       FUNC '(' indirob expr ')'
 329                         { $$ = convert($1, OPf_STACKED,
 330                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 331         |       term ARROW method '(' listexprcom ')'
 332                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 333                                 append_elem(OP_LIST,
 334                                     prepend_elem(OP_LIST, scalar($1), $5),
 335                                     newUNOP(OP_METHOD, 0, $3))); }
 336         |       METHOD indirob listexpr
 337                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 338                                 append_elem(OP_LIST,
 339                                     prepend_elem(OP_LIST, $2, $3),
 340                                     newUNOP(OP_METHOD, 0, $1))); }
 341         |       FUNCMETH indirob '(' listexprcom ')'
 342                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 343                                 append_elem(OP_LIST,
 344                                     prepend_elem(OP_LIST, $2, $4),
 345                                     newUNOP(OP_METHOD, 0, $1))); }
 346         |       LSTOP listexpr
 347                         { $$ = convert($1, 0, $2); }
 348         |       FUNC '(' listexprcom ')'
 349                         { $$ = convert($1, 0, $3); }
 350         |       LSTOPSUB startsub block listexpr        %prec LSTOP
 351                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 352                             append_elem(OP_LIST,
 353                               prepend_elem(OP_LIST, newANONSUB($2, 0, $3), $4),
 354                               $1)); }
 355         ;
 356
 357 method  :       METHOD
 358         |       scalar
 359         ;
 360
 361 term    :       term ASSIGNOP term
 362                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 363         |       term POWOP term
 364                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 365         |       term MULOP term
 366                         {   if ($2 != OP_REPEAT)
 367                                 scalar($1);
 368                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 369         |       term ADDOP term
 370                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 371         |       term SHIFTOP term
 372                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 373         |       term RELOP term
 374                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 375         |       term EQOP term
 376                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 377         |       term BITANDOP term
 378                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 379         |       term BITOROP term
 380                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 381         |       term DOTDOT term
 382                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 383         |       term ANDAND term
 384                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 385         |       term OROR term
 386                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 387         |       term '?' term ':' term
 388                         { $$ = newCONDOP(0, $1, $3, $5); }
 389         |       term MATCHOP term
 390                         { $$ = bind_match($2, $1, $3); }
 391
 392         |       '-' term %prec UMINUS
 393                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 394         |       '+' term %prec UMINUS
 395                         { $$ = $2; }
 396         |       '!' term
 397                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 398         |       '~' term
 399                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 400         |       REFGEN term
 401                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 402         |       term POSTINC
 403                         { $$ = newUNOP(OP_POSTINC, 0,
 404                                         mod(scalar($1), OP_POSTINC)); }
 405         |       term POSTDEC
 406                         { $$ = newUNOP(OP_POSTDEC, 0,
 407                                         mod(scalar($1), OP_POSTDEC)); }
 408         |       PREINC term
 409                         { $$ = newUNOP(OP_PREINC, 0,
 410                                         mod(scalar($2), OP_PREINC)); }
 411         |       PREDEC term
 412                         { $$ = newUNOP(OP_PREDEC, 0,
 413                                         mod(scalar($2), OP_PREDEC)); }
 414         |       local term      %prec UNIOP
 415                         { $$ = localize($2,$1); }
 416         |       '(' expr ')'
 417                         { $$ = sawparens($2); }
 418         |       '(' ')'
 419                         { $$ = sawparens(newNULLLIST()); }
 420         |       '[' expr ']'                            %prec '('
 421                         { $$ = newANONLIST($2); }
 422         |       '[' ']'                                 %prec '('
 423                         { $$ = newANONLIST(Nullop); }
 424         |       HASHBRACK expr ';' '}'                  %prec '('
 425                         { $$ = newANONHASH($2); }
 426         |       HASHBRACK ';' '}'                               %prec '('
 427                         { $$ = newANONHASH(Nullop); }
 428         |       ANONSUB startsub proto block                    %prec '('
 429                         { $$ = newANONSUB($2, $3, $4); }
 430         |       scalar  %prec '('
 431                         { $$ = $1; }
 432         |       star '{' expr ';' '}'
 433                         { $$ = newBINOP(OP_GELEM, 0, newGVREF(0,$1), $3); }
 434         |       star    %prec '('
 435                         { $$ = $1; }
 436         |       scalar '[' expr ']'     %prec '('
 437                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 438         |       term ARROW '[' expr ']' %prec '('
 439                         { $$ = newBINOP(OP_AELEM, 0,
 440                                         ref(newAVREF($1),OP_RV2AV),
 441                                         scalar($4));}
 442         |       term '[' expr ']'       %prec '('
 443                         { assertref($1); $$ = newBINOP(OP_AELEM, 0,
 444                                         ref(newAVREF($1),OP_RV2AV),
 445                                         scalar($3));}
 446         |       hsh     %prec '('
 447                         { $$ = $1; }
 448         |       ary     %prec '('
 449                         { $$ = $1; }
 450         |       arylen  %prec '('
 451                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 452         |       scalar '{' expr ';' '}' %prec '('
 453                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 454                             expect = XOPERATOR; }
 455         |       term ARROW '{' expr ';' '}'     %prec '('
 456                         { $$ = newBINOP(OP_HELEM, 0,
 457                                         ref(newHVREF($1),OP_RV2HV),
 458                                         jmaybe($4));
 459                             expect = XOPERATOR; }
 460         |       term '{' expr ';' '}'   %prec '('
 461                         { assertref($1); $$ = newBINOP(OP_HELEM, 0,
 462                                         ref(newHVREF($1),OP_RV2HV),
 463                                         jmaybe($3));
 464                             expect = XOPERATOR; }
 465         |       '(' expr ')' '[' expr ']'       %prec '('
 466                         { $$ = newSLICEOP(0, $5, $2); }
 467         |       '(' ')' '[' expr ']'    %prec '('
 468                         { $$ = newSLICEOP(0, $4, Nullop); }
 469         |       ary '[' expr ']'        %prec '('
 470                         { $$ = prepend_elem(OP_ASLICE,
 471                                 newOP(OP_PUSHMARK, 0),
 472                                     newLISTOP(OP_ASLICE, 0,
 473                                         list($3),
 474                                         ref($1, OP_ASLICE))); }
 475         |       ary '{' expr ';' '}'    %prec '('
 476                         { $$ = prepend_elem(OP_HSLICE,
 477                                 newOP(OP_PUSHMARK, 0),
 478                                     newLISTOP(OP_HSLICE, 0,
 479                                         list($3),
 480                                         ref(oopsHV($1), OP_HSLICE)));
 481                             expect = XOPERATOR; }
 482         |       THING   %prec '('
 483                         { $$ = $1; }
 484         |       amper
 485                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
 486         |       amper '(' ')'
 487                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 488         |       amper '(' expr ')'
 489                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 490                             append_elem(OP_LIST, $3, scalar($1))); }
 491         |       NOAMP WORD listexpr
 492                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 493                             append_elem(OP_LIST, $3, scalar($2))); }
 494         |       DO term %prec UNIOP
 495                         { $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
 496         |       DO block        %prec '('
 497                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 498         |       DO WORD '(' ')'
 499                         { $$ = newUNOP(OP_ENTERSUB,
 500                             OPf_SPECIAL|OPf_STACKED,
 501                             prepend_elem(OP_LIST,
 502                                 scalar(newCVREF(
 503                                     (OPpENTERSUB_AMPER<<8),
 504                                     scalar($2)
 505                                 )),Nullop)); dep();}
 506         |       DO WORD '(' expr ')'
 507                         { $$ = newUNOP(OP_ENTERSUB,
 508                             OPf_SPECIAL|OPf_STACKED,
 509                             append_elem(OP_LIST,
 510                                 $4,
 511                                 scalar(newCVREF(
 512                                     (OPpENTERSUB_AMPER<<8),
 513                                     scalar($2)
 514                                 )))); dep();}
 515         |       DO scalar '(' ')'
 516                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 517                             prepend_elem(OP_LIST,
 518                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
 519         |       DO scalar '(' expr ')'
 520                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 521                             prepend_elem(OP_LIST,
 522                                 $4,
 523                                 scalar(newCVREF(0,scalar($2))))); dep();}
 524         |       LOOPEX
 525                         { $$ = newOP($1, OPf_SPECIAL);
 526                             hints |= HINT_BLOCK_SCOPE; }
 527         |       LOOPEX term
 528                         { $$ = newLOOPEX($1,$2); }
 529         |       NOTOP argexpr
 530                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 531         |       UNIOP
 532                         { $$ = newOP($1, 0); }
 533         |       UNIOP block
 534                         { $$ = newUNOP($1, 0, $2); }
 535         |       UNIOP term
 536                         { $$ = newUNOP($1, 0, $2); }
 537         |       UNIOPSUB term
 538                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 539                             append_elem(OP_LIST, $2, scalar($1))); }
 540         |       FUNC0
 541                         { $$ = newOP($1, 0); }
 542         |       FUNC0 '(' ')'
 543                         { $$ = newOP($1, 0); }
 544         |       FUNC0SUB
 545                         { $$ = newUNOP(OP_ENTERSUB, 0,
 546                                 scalar($1)); }
 547         |       FUNC1 '(' ')'
 548                         { $$ = newOP($1, OPf_SPECIAL); }
 549         |       FUNC1 '(' expr ')'
 550                         { $$ = newUNOP($1, 0, $3); }
 551         |       PMFUNC '(' term ')'
 552                         { $$ = pmruntime($1, $3, Nullop); }
 553         |       PMFUNC '(' term ',' term ')'
 554                         { $$ = pmruntime($1, $3, $5); }
 555         |       WORD
 556         |       listop
 557         ;
 558
 559 listexpr:       /* NULL */
 560                         { $$ = Nullop; }
 561         |       argexpr
 562                         { $$ = $1; }
 563         ;
 564
 565 listexprcom:    /* NULL */
 566                         { $$ = Nullop; }
 567         |       expr
 568                         { $$ = $1; }
 569         |       expr ','
 570                         { $$ = $1; }
 571         ;
 572
 573 local   :       LOCAL   { $$ = 0; }
 574         |       MY      { $$ = 1; }
 575         ;
 576
 577 my_scalar:      scalar
 578                         { in_my = 0; $$ = my($1); }
 579         ;
 580
 581 amper   :       '&' indirob
 582                         { $$ = newCVREF($1,$2); }
 583         ;
 584
 585 scalar  :       '$' indirob
 586                         { $$ = newSVREF($2); }
 587         ;
 588
 589 ary     :       '@' indirob
 590                         { $$ = newAVREF($2); }
 591         ;
 592
 593 hsh     :       '%' indirob
 594                         { $$ = newHVREF($2); }
 595         ;
 596
 597 arylen  :       DOLSHARP indirob
 598                         { $$ = newAVREF($2); }
 599         ;
 600
 601 star    :       '*' indirob
 602                         { $$ = newGVREF(0,$2); }
 603         ;
 604
 605 indirob :       WORD
 606                         { $$ = scalar($1); }
 607         |       scalar
 608                         { $$ = scalar($1);  }
 609         |       block
 610                         { $$ = scope($1); }
 611
 612         |       PRIVATEREF
 613                         { $$ = $1; }
 614         ;
 615
 616 %% /* PROGRAM */