Don't show code closing STD{IN,OUT} before reopening, because
[p5sagit/p5-mst-13.2.git] / perly.y
1 /*    perly.y
2  *
3  *    Copyright (c) 1991-2002, Larry Wall
4  *
5  *    You may distribute under the terms of either the GNU General Public
6  *    License or the Artistic License, as specified in the README file.
7  *
8  */
9
10 /*
11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
12  * All that is gold does not glitter, not all those who wander are lost.'
13  */
14
15 %{
16 #include "EXTERN.h"
17 #define PERL_IN_PERLY_C
18 #include "perl.h"
19 #ifdef EBCDIC
20 #undef YYDEBUG
21 #endif
22 #define dep() deprecate("\"do\" to call subroutines")
23
24 /* stuff included here to make perly_c.diff apply better */
25
26 #define yydebug     PL_yydebug
27 #define yynerrs     PL_yynerrs
28 #define yyerrflag   PL_yyerrflag
29 #define yychar      PL_yychar
30 #define yyval       PL_yyval
31 #define yylval      PL_yylval
32
33 struct ysv {
34     short* yyss;
35     YYSTYPE* yyvs;
36     int oldyydebug;
37     int oldyynerrs;
38     int oldyyerrflag;
39     int oldyychar;
40     YYSTYPE oldyyval;
41     YYSTYPE oldyylval;
42 };
43
44 static void yydestruct(pTHX_ void *ptr);
45
46 %}
47
48 %start prog
49
50 %{
51 #if 0 /* get this from perly.h instead */
52 %}
53
54 %union {
55     I32 ival;
56     char *pval;
57     OP *opval;
58     GV *gvval;
59 }
60
61 %{
62 #endif /* 0 */
63
64 #ifdef USE_PURE_BISON
65 #define YYLEX_PARAM (&yychar)
66 #define yylex yylex_r
67 #endif
68
69 %}
70
71 %token <ival> '{'
72
73 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
74 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
75 %token <pval> LABEL
76 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
77 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
78 %token <ival> LOOPEX DOTDOT
79 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
80 %token <ival> RELOP EQOP MULOP ADDOP
81 %token <ival> DOLSHARP DO HASHBRACK NOAMP
82 %token <ival> LOCAL MY MYSUB
83 %token COLONATTR
84
85 %type <ival> prog decl format startsub startanonsub startformsub
86 %type <ival> progstart remember mremember '&'
87 %type <opval> block mblock lineseq line loop cond else
88 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
89 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
90 %type <opval> listexpr listexprcom indirob listop method
91 %type <opval> formname subname proto subbody cont my_scalar
92 %type <opval> subattrlist myattrlist mysubrout myattrterm myterm
93 %type <opval> termbinop termunop anonymous termdo
94 %type <pval> label
95
96 %nonassoc PREC_LOW
97 %nonassoc LOOPEX
98
99 %left <ival> OROP DOROP
100 %left ANDOP
101 %right NOTOP
102 %nonassoc LSTOP LSTOPSUB
103 %left ','
104 %right <ival> ASSIGNOP
105 %right '?' ':'
106 %nonassoc DOTDOT
107 %left OROR DORDOR
108 %left ANDAND
109 %left <ival> BITOROP
110 %left <ival> BITANDOP
111 %nonassoc EQOP
112 %nonassoc RELOP
113 %nonassoc UNIOP UNIOPSUB
114 %left <ival> SHIFTOP
115 %left ADDOP
116 %left MULOP
117 %left <ival> MATCHOP
118 %right '!' '~' UMINUS REFGEN
119 %right <ival> POWOP
120 %nonassoc PREINC PREDEC POSTINC POSTDEC
121 %left ARROW
122 %nonassoc <ival> ')'
123 %left '('
124 %left '[' '{'
125
126 %% /* RULES */
127
128 /* The whole program */
129 prog    :       progstart
130         /*CONTINUED*/   lineseq
131                         { $$ = $1; newPROG(block_end($1,$2)); }
132         ;
133
134 /* An ordinary block */
135 block   :       '{' remember lineseq '}'
136                         { if (PL_copline > (line_t)$1)
137                               PL_copline = (line_t)$1;
138                           $$ = block_end($2, $3); }
139         ;
140
141 remember:       /* NULL */      /* start a full lexical scope */
142                         { $$ = block_start(TRUE); }
143         ;
144
145 progstart:
146                 {
147 #if defined(YYDEBUG) && defined(DEBUGGING)
148                     yydebug = (DEBUG_p_TEST);
149 #endif
150                     PL_expect = XSTATE; $$ = block_start(TRUE);
151                 }
152         ;
153
154
155 mblock  :       '{' mremember lineseq '}'
156                         { if (PL_copline > (line_t)$1)
157                               PL_copline = (line_t)$1;
158                           $$ = block_end($2, $3); }
159         ;
160
161 mremember:      /* NULL */      /* start a partial lexical scope */
162                         { $$ = block_start(FALSE); }
163         ;
164
165 /* A collection of "lines" in the program */
166 lineseq :       /* NULL */
167                         { $$ = Nullop; }
168         |       lineseq decl
169                         { $$ = $1; }
170         |       lineseq line
171                         {   $$ = append_list(OP_LINESEQ,
172                                 (LISTOP*)$1, (LISTOP*)$2);
173                             PL_pad_reset_pending = TRUE;
174                             if ($1 && $2) PL_hints |= HINT_BLOCK_SCOPE; }
175         ;
176
177 /* A "line" in the program */
178 line    :       label cond
179                         { $$ = newSTATEOP(0, $1, $2); }
180         |       loop    /* loops add their own labels */
181         |       label ';'
182                         { if ($1 != Nullch) {
183                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
184                             }
185                             else {
186                               $$ = Nullop;
187                               PL_copline = NOLINE;
188                             }
189                             PL_expect = XSTATE; }
190         |       label sideff ';'
191                         { $$ = newSTATEOP(0, $1, $2);
192                           PL_expect = XSTATE; }
193         ;
194
195 /* An expression which may have a side-effect */
196 sideff  :       error
197                         { $$ = Nullop; }
198         |       expr
199                         { $$ = $1; }
200         |       expr IF expr
201                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
202         |       expr UNLESS expr
203                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
204         |       expr WHILE expr
205                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
206         |       expr UNTIL iexpr
207                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
208         |       expr FOR expr
209                         { $$ = newFOROP(0, Nullch, (line_t)$2,
210                                         Nullop, $3, $1, Nullop); }
211         ;
212
213 /* else and elsif blocks */
214 else    :       /* NULL */
215                         { $$ = Nullop; }
216         |       ELSE mblock
217                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2); }
218         |       ELSIF '(' mexpr ')' mblock else
219                         { PL_copline = (line_t)$1;
220                             $$ = newCONDOP(0, $3, scope($5), $6);
221                             PL_hints |= HINT_BLOCK_SCOPE; }
222         ;
223
224 /* Real conditional expressions */
225 cond    :       IF '(' remember mexpr ')' mblock else
226                         { PL_copline = (line_t)$1;
227                             $$ = block_end($3,
228                                    newCONDOP(0, $4, scope($6), $7)); }
229         |       UNLESS '(' remember miexpr ')' mblock else
230                         { PL_copline = (line_t)$1;
231                             $$ = block_end($3,
232                                    newCONDOP(0, $4, scope($6), $7)); }
233         ;
234
235 /* Continue blocks */
236 cont    :       /* NULL */
237                         { $$ = Nullop; }
238         |       CONTINUE block
239                         { $$ = scope($2); }
240         ;
241
242 /* Loops: while, until, for, and a bare block */
243 loop    :       label WHILE '(' remember mtexpr ')' mblock cont
244                         { PL_copline = (line_t)$2;
245                             $$ = block_end($4,
246                                    newSTATEOP(0, $1,
247                                      newWHILEOP(0, 1, (LOOP*)Nullop,
248                                                 $2, $5, $7, $8))); }
249         |       label UNTIL '(' remember miexpr ')' mblock cont
250                         { PL_copline = (line_t)$2;
251                             $$ = block_end($4,
252                                    newSTATEOP(0, $1,
253                                      newWHILEOP(0, 1, (LOOP*)Nullop,
254                                                 $2, $5, $7, $8))); }
255         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
256                         { $$ = block_end($4,
257                                  newFOROP(0, $1, (line_t)$2, $5, $7, $9, $10)); }
258         |       label FOR scalar '(' remember mexpr ')' mblock cont
259                         { $$ = block_end($5,
260                                  newFOROP(0, $1, (line_t)$2, mod($3, OP_ENTERLOOP),
261                                           $6, $8, $9)); }
262         |       label FOR '(' remember mexpr ')' mblock cont
263                         { $$ = block_end($4,
264                                  newFOROP(0, $1, (line_t)$2, Nullop, $5, $7, $8)); }
265         |       label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
266                         /* basically fake up an initialize-while lineseq */
267                         { OP *forop;
268                           PL_copline = (line_t)$2;
269                           forop = newSTATEOP(0, $1,
270                                             newWHILEOP(0, 1, (LOOP*)Nullop,
271                                                 $2, scalar($7),
272                                                 $11, $9));
273                           if ($5) {
274                                 forop = append_elem(OP_LINESEQ,
275                                         newSTATEOP(0, ($1?savepv($1):Nullch),
276                                                    $5),
277                                         forop);
278                           }
279
280                           $$ = block_end($4, forop); }
281         |       label block cont  /* a block is a loop that happens once */
282                         { $$ = newSTATEOP(0, $1,
283                                  newWHILEOP(0, 1, (LOOP*)Nullop,
284                                             NOLINE, Nullop, $2, $3)); }
285         ;
286
287 /* Normal expression */
288 nexpr   :       /* NULL */
289                         { $$ = Nullop; }
290         |       sideff
291         ;
292
293 /* Boolean expression */
294 texpr   :       /* NULL means true */
295                         { (void)scan_num("1", &yylval); $$ = yylval.opval; }
296         |       expr
297         ;
298
299 /* Inverted boolean expression */
300 iexpr   :       expr
301                         { $$ = invert(scalar($1)); }
302         ;
303
304 /* Expression with its own lexical scope */
305 mexpr   :       expr
306                         { $$ = $1; intro_my(); }
307         ;
308
309 mnexpr  :       nexpr
310                         { $$ = $1; intro_my(); }
311         ;
312
313 mtexpr  :       texpr
314                         { $$ = $1; intro_my(); }
315         ;
316
317 miexpr  :       iexpr
318                         { $$ = $1; intro_my(); }
319         ;
320
321 /* Optional "MAIN:"-style loop labels */
322 label   :       /* empty */
323                         { $$ = Nullch; }
324         |       LABEL
325         ;
326
327 /* Some kind of declaration - does not take part in the parse tree */
328 decl    :       format
329                         { $$ = 0; }
330         |       subrout
331                         { $$ = 0; }
332         |       mysubrout
333                         { $$ = 0; }
334         |       package
335                         { $$ = 0; }
336         |       use
337                         { $$ = 0; }
338         ;
339
340 format  :       FORMAT startformsub formname block
341                         { newFORM($2, $3, $4); }
342         ;
343
344 formname:       WORD            { $$ = $1; }
345         |       /* NULL */      { $$ = Nullop; }
346         ;
347
348 /* Unimplemented "my sub foo { }" */
349 mysubrout:      MYSUB startsub subname proto subattrlist subbody
350                         { newMYSUB($2, $3, $4, $5, $6); }
351         ;
352
353 /* Subroutine definition */
354 subrout :       SUB startsub subname proto subattrlist subbody
355                         { newATTRSUB($2, $3, $4, $5, $6); }
356         ;
357
358 startsub:       /* NULL */      /* start a regular subroutine scope */
359                         { $$ = start_subparse(FALSE, 0); }
360         ;
361
362 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
363                         { $$ = start_subparse(FALSE, CVf_ANON); }
364         ;
365
366 startformsub:   /* NULL */      /* start a format subroutine scope */
367                         { $$ = start_subparse(TRUE, 0); }
368         ;
369
370 /* Name of a subroutine - must be a bareword, could be special */
371 subname :       WORD    { STRLEN n_a; char *name = SvPV(((SVOP*)$1)->op_sv,n_a);
372                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
373                               || strEQ(name, "INIT") || strEQ(name, "CHECK"))
374                               CvSPECIAL_on(PL_compcv);
375                           $$ = $1; }
376         ;
377
378 /* Subroutine prototype */
379 proto   :       /* NULL */
380                         { $$ = Nullop; }
381         |       THING
382         ;
383
384 /* Optional list of subroutine attributes */
385 subattrlist:    /* NULL */
386                         { $$ = Nullop; }
387         |       COLONATTR THING
388                         { $$ = $2; }
389         |       COLONATTR
390                         { $$ = Nullop; }
391         ;
392
393 /* List of attributes for a "my" variable declaration */
394 myattrlist:     COLONATTR THING
395                         { $$ = $2; }
396         |       COLONATTR
397                         { $$ = Nullop; }
398         ;
399
400 /* Subroutine body - either null or a block */
401 subbody :       block   { $$ = $1; }
402         |       ';'     { $$ = Nullop; PL_expect = XSTATE; }
403         ;
404
405 package :       PACKAGE WORD ';'
406                         { package($2); }
407         ;
408
409 use     :       USE startsub
410                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
411                     WORD WORD listexpr ';'
412                         { utilize($1, $2, $4, $5, $6); }
413         ;
414
415 /* Ordinary expressions; logical combinations */
416 expr    :       expr ANDOP expr
417                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
418         |       expr OROP expr
419                         { $$ = newLOGOP($2, 0, $1, $3); }
420         |       expr DOROP expr
421                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
422         |       argexpr %prec PREC_LOW
423         ;
424
425 /* Expressions are a list of terms joined by commas */
426 argexpr :       argexpr ','
427                         { $$ = $1; }
428         |       argexpr ',' term
429                         { $$ = append_elem(OP_LIST, $1, $3); }
430         |       term %prec PREC_LOW
431         ;
432
433 /* List operators */
434 listop  :       LSTOP indirob argexpr          /* print $fh @args */
435                         { $$ = convert($1, OPf_STACKED,
436                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
437         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
438                         { $$ = convert($1, OPf_STACKED,
439                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
440         |       term ARROW method '(' listexprcom ')' /* $foo->bar(list) */
441                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
442                                 append_elem(OP_LIST,
443                                     prepend_elem(OP_LIST, scalar($1), $5),
444                                     newUNOP(OP_METHOD, 0, $3))); }
445         |       term ARROW method                     /* $foo->bar */
446                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
447                                 append_elem(OP_LIST, scalar($1),
448                                     newUNOP(OP_METHOD, 0, $3))); }
449         |       METHOD indirob listexpr              /* new Class @args */
450                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
451                                 append_elem(OP_LIST,
452                                     prepend_elem(OP_LIST, $2, $3),
453                                     newUNOP(OP_METHOD, 0, $1))); }
454         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
455                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
456                                 append_elem(OP_LIST,
457                                     prepend_elem(OP_LIST, $2, $4),
458                                     newUNOP(OP_METHOD, 0, $1))); }
459         |       LSTOP listexpr                       /* print @args */
460                         { $$ = convert($1, 0, $2); }
461         |       FUNC '(' listexprcom ')'             /* print (@args) */
462                         { $$ = convert($1, 0, $3); }
463         |       LSTOPSUB startanonsub block          /* map { foo } ... */
464                         { $3 = newANONATTRSUB($2, 0, Nullop, $3); }
465                     listexpr            %prec LSTOP  /* ... @bar */
466                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
467                                  append_elem(OP_LIST,
468                                    prepend_elem(OP_LIST, $3, $5), $1)); }
469         ;
470
471 /* Names of methods. May use $object->$methodname */
472 method  :       METHOD
473         |       scalar
474         ;
475
476 /* Some kind of subscripted expression */
477 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
478                         /* In this and all the hash accessors, ';' is
479                          * provided by the tokeniser */
480                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
481                             PL_expect = XOPERATOR; }
482         |       scalar '[' expr ']'          /* $array[$element] */
483                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
484         |       term ARROW '[' expr ']'      /* somearef->[$element] */
485                         { $$ = newBINOP(OP_AELEM, 0,
486                                         ref(newAVREF($1),OP_RV2AV),
487                                         scalar($4));}
488         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
489                         { $$ = newBINOP(OP_AELEM, 0,
490                                         ref(newAVREF($1),OP_RV2AV),
491                                         scalar($3));}
492         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
493                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
494                             PL_expect = XOPERATOR; }
495         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
496                         { $$ = newBINOP(OP_HELEM, 0,
497                                         ref(newHVREF($1),OP_RV2HV),
498                                         jmaybe($4));
499                             PL_expect = XOPERATOR; }
500         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
501                         { $$ = newBINOP(OP_HELEM, 0,
502                                         ref(newHVREF($1),OP_RV2HV),
503                                         jmaybe($3));
504                             PL_expect = XOPERATOR; }
505         |       term ARROW '(' ')'          /* $subref->() */
506                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
507                                    newCVREF(0, scalar($1))); }
508         |       term ARROW '(' expr ')'     /* $subref->(@args) */
509                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
510                                    append_elem(OP_LIST, $4,
511                                        newCVREF(0, scalar($1)))); }
512
513         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
514                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
515                                    append_elem(OP_LIST, $3,
516                                                newCVREF(0, scalar($1)))); }
517         |       subscripted '(' ')'        /* $foo->{bar}->() */
518                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
519                                    newCVREF(0, scalar($1))); }
520     ;
521
522 /* Binary operators between terms */
523 termbinop       :       term ASSIGNOP term             /* $x = $y */
524                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
525         |       term POWOP term                        /* $x ** $y */
526                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
527         |       term MULOP term                        /* $x * $y, $x x $y */
528                         {   if ($2 != OP_REPEAT)
529                                 scalar($1);
530                             $$ = newBINOP($2, 0, $1, scalar($3)); }
531         |       term ADDOP term                        /* $x + $y */
532                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
533         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
534                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
535         |       term RELOP term                        /* $x > $y, etc. */
536                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
537         |       term EQOP term                         /* $x == $y, $x eq $y */
538                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
539         |       term BITANDOP term                     /* $x & $y */
540                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
541         |       term BITOROP term                      /* $x | $y */
542                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
543         |       term DOTDOT term                       /* $x..$y, $x...$y */
544                         { $$ = newRANGE($2, scalar($1), scalar($3));}
545         |       term ANDAND term                       /* $x && $y */
546                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
547         |       term OROR term                         /* $x || $y */
548                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
549         |       term DORDOR term                       /* $x // $y */
550                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
551         |       term MATCHOP term                      /* $x =~ /$y/ */
552                         { $$ = bind_match($2, $1, $3); }
553     ;
554
555 /* Unary operators and terms */
556 termunop : '-' term %prec UMINUS                       /* -$x */
557                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
558         |       '+' term %prec UMINUS                  /* +$x */
559                         { $$ = $2; }
560         |       '!' term                               /* !$x */
561                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
562         |       '~' term                               /* ~$x */
563                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
564         |       term POSTINC                           /* $x++ */
565                         { $$ = newUNOP(OP_POSTINC, 0,
566                                         mod(scalar($1), OP_POSTINC)); }
567         |       term POSTDEC                           /* $x-- */
568                         { $$ = newUNOP(OP_POSTDEC, 0,
569                                         mod(scalar($1), OP_POSTDEC)); }
570         |       PREINC term                            /* ++$x */
571                         { $$ = newUNOP(OP_PREINC, 0,
572                                         mod(scalar($2), OP_PREINC)); }
573         |       PREDEC term                            /* --$x */
574                         { $$ = newUNOP(OP_PREDEC, 0,
575                                         mod(scalar($2), OP_PREDEC)); }
576
577     ;
578
579 /* Constructors for anonymous data */
580 anonymous:      '[' expr ']'
581                         { $$ = newANONLIST($2); }
582         |       '[' ']'
583                         { $$ = newANONLIST(Nullop); }
584         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
585                         { $$ = newANONHASH($2); }
586         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
587                         { $$ = newANONHASH(Nullop); }
588         |       ANONSUB startanonsub proto subattrlist block    %prec '('
589                         { $$ = newANONATTRSUB($2, $3, $4, $5); }
590
591     ;
592
593 /* Things called with "do" */
594 termdo  :       DO term %prec UNIOP                     /* do $filename */
595                         { $$ = dofile($2); }
596         |       DO block        %prec '('               /* do { code */
597                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
598         |       DO WORD '(' ')'                         /* do somesub() */
599                         { $$ = newUNOP(OP_ENTERSUB,
600                             OPf_SPECIAL|OPf_STACKED,
601                             prepend_elem(OP_LIST,
602                                 scalar(newCVREF(
603                                     (OPpENTERSUB_AMPER<<8),
604                                     scalar($2)
605                                 )),Nullop)); dep();}
606         |       DO WORD '(' expr ')'                    /* do somesub(@args) */
607                         { $$ = newUNOP(OP_ENTERSUB,
608                             OPf_SPECIAL|OPf_STACKED,
609                             append_elem(OP_LIST,
610                                 $4,
611                                 scalar(newCVREF(
612                                     (OPpENTERSUB_AMPER<<8),
613                                     scalar($2)
614                                 )))); dep();}
615         |       DO scalar '(' ')'                      /* do $subref () */
616                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
617                             prepend_elem(OP_LIST,
618                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
619         |       DO scalar '(' expr ')'                 /* do $subref (@args) */
620                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
621                             prepend_elem(OP_LIST,
622                                 $4,
623                                 scalar(newCVREF(0,scalar($2))))); dep();}
624
625         ;
626
627 term    :       termbinop
628         |       termunop
629         |       anonymous
630         |       termdo
631         |       term '?' term ':' term
632                         { $$ = newCONDOP(0, $1, $3, $5); }
633         |       REFGEN term                          /* \$x, \@y, \%z */
634                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
635         |       myattrterm      %prec UNIOP
636                         { $$ = $1; }
637         |       LOCAL term      %prec UNIOP
638                         { $$ = localize($2,$1); }
639         |       '(' expr ')'
640                         { $$ = sawparens($2); }
641         |       '(' ')'
642                         { $$ = sawparens(newNULLLIST()); }
643         |       scalar  %prec '('
644                         { $$ = $1; }
645         |       star    %prec '('
646                         { $$ = $1; }
647         |       hsh     %prec '('
648                         { $$ = $1; }
649         |       ary     %prec '('
650                         { $$ = $1; }
651         |       arylen  %prec '('                    /* $#x, $#{ something } */
652                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
653         |       subscripted
654                         { $$ = $1; }
655         |       '(' expr ')' '[' expr ']'            /* list slice */
656                         { $$ = newSLICEOP(0, $5, $2); }
657         |       '(' ')' '[' expr ']'                 /* empty list slice! */
658                         { $$ = newSLICEOP(0, $4, Nullop); }
659         |       ary '[' expr ']'                     /* array slice */
660                         { $$ = prepend_elem(OP_ASLICE,
661                                 newOP(OP_PUSHMARK, 0),
662                                     newLISTOP(OP_ASLICE, 0,
663                                         list($3),
664                                         ref($1, OP_ASLICE))); }
665         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
666                         { $$ = prepend_elem(OP_HSLICE,
667                                 newOP(OP_PUSHMARK, 0),
668                                     newLISTOP(OP_HSLICE, 0,
669                                         list($3),
670                                         ref(oopsHV($1), OP_HSLICE)));
671                             PL_expect = XOPERATOR; }
672         |       THING   %prec '('
673                         { $$ = $1; }
674         |       amper                                /* &foo; */
675                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
676         |       amper '(' ')'                        /* &foo() */
677                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
678         |       amper '(' expr ')'                   /* &foo(@args) */
679                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
680                             append_elem(OP_LIST, $3, scalar($1))); }
681         |       NOAMP WORD listexpr                  /* foo(@args) */
682                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
683                             append_elem(OP_LIST, $3, scalar($2))); }
684         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
685                         { $$ = newOP($1, OPf_SPECIAL);
686                             PL_hints |= HINT_BLOCK_SCOPE; }
687         |       LOOPEX term
688                         { $$ = newLOOPEX($1,$2); }
689         |       NOTOP argexpr                        /* not $foo */
690                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
691         |       UNIOP                                /* Unary op, $_ implied */
692                         { $$ = newOP($1, 0); }
693         |       UNIOP block                          /* eval { foo }, I *think* */
694                         { $$ = newUNOP($1, 0, $2); }
695         |       UNIOP term                           /* Unary op */
696                         { $$ = newUNOP($1, 0, $2); }
697         |       UNIOPSUB term                        /* Sub treated as unop */
698                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
699                             append_elem(OP_LIST, $2, scalar($1))); }
700         |       FUNC0                                /* Nullary operator */
701                         { $$ = newOP($1, 0); }
702         |       FUNC0 '(' ')'
703                         { $$ = newOP($1, 0); }
704         |       FUNC0SUB                             /* Sub treated as nullop */
705                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
706                                 scalar($1)); }
707         |       FUNC1 '(' ')'                        /* not () */
708                         { $$ = newOP($1, OPf_SPECIAL); }
709         |       FUNC1 '(' expr ')'                   /* not($foo) */
710                         { $$ = newUNOP($1, 0, $3); }
711         |       PMFUNC '(' term ')'                  /* split (/foo/) */
712                         { $$ = pmruntime($1, $3, Nullop); }
713         |       PMFUNC '(' term ',' term ')'         /* split (/foo/,$bar) */
714                         { $$ = pmruntime($1, $3, $5); }
715         |       WORD
716         |       listop
717         ;
718
719 /* "my" declarations, with optional attributes */
720 myattrterm:     MY myterm myattrlist
721                         { $$ = my_attrs($2,$3); }
722         |       MY myterm
723                         { $$ = localize($2,$1); }
724         ;
725
726 /* Things that can be "my"'d */
727 myterm  :       '(' expr ')'
728                         { $$ = sawparens($2); }
729         |       '(' ')'
730                         { $$ = sawparens(newNULLLIST()); }
731         |       scalar  %prec '('
732                         { $$ = $1; }
733         |       hsh     %prec '('
734                         { $$ = $1; }
735         |       ary     %prec '('
736                         { $$ = $1; }
737         ;
738
739 /* Basic list expressions */
740 listexpr:       /* NULL */ %prec PREC_LOW
741                         { $$ = Nullop; }
742         |       argexpr    %prec PREC_LOW
743                         { $$ = $1; }
744         ;
745
746 listexprcom:    /* NULL */
747                         { $$ = Nullop; }
748         |       expr
749                         { $$ = $1; }
750         |       expr ','
751                         { $$ = $1; }
752         ;
753
754 /* A little bit of trickery to make "for my $foo (@bar)" actually be
755    lexical */
756 my_scalar:      scalar
757                         { PL_in_my = 0; $$ = my($1); }
758         ;
759
760 amper   :       '&' indirob
761                         { $$ = newCVREF($1,$2); }
762         ;
763
764 scalar  :       '$' indirob
765                         { $$ = newSVREF($2); }
766         ;
767
768 ary     :       '@' indirob
769                         { $$ = newAVREF($2); }
770         ;
771
772 hsh     :       '%' indirob
773                         { $$ = newHVREF($2); }
774         ;
775
776 arylen  :       DOLSHARP indirob
777                         { $$ = newAVREF($2); }
778         ;
779
780 star    :       '*' indirob
781                         { $$ = newGVREF(0,$2); }
782         ;
783
784 /* Indirect objects */
785 indirob :       WORD
786                         { $$ = scalar($1); }
787         |       scalar %prec PREC_LOW
788                         { $$ = scalar($1);  }
789         |       block
790                         { $$ = scope($1); }
791
792         |       PRIVATEREF
793                         { $$ = $1; }
794         ;
795
796 %% /* PROGRAM */
797
798 /* more stuff added to make perly_c.diff easier to apply */
799
800 #ifdef yyparse
801 #undef yyparse
802 #endif
803 #define yyparse() Perl_yyparse(pTHX)
804