moose-class/exercises/t/lib/MooseClass/Tests.pm

   1 package MooseClass::Tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Lingua::EN::Inflect qw( A PL_N );
   7 use Test::More 'no_plan';
   8
   9 sub tests01 {
  10     has_meta('Person');
  11
  12     check_isa( 'Person', ['Moose::Object'] );
  13
  14     has_rw_attr( 'Person', $_ ) for qw( first_name last_name );
  15
  16     has_method( 'Person', 'full_name' );
  17
  18     person01();
  19
  20     has_meta('Employee');
  21
  22     check_isa( 'Employee', [ 'Person', 'Moose::Object' ] );
  23
  24     has_rw_attr( 'Employee', $_ ) for qw( title salary );
  25     has_ro_attr( 'Employee', 'ssn' );
  26
  27     has_overridden_method( 'Employee', 'full_name' );
  28
  29     employee01();
  30
  31     no_droppings('Person');
  32     is_immutable('Person');
  33
  34     no_droppings('Employee');
  35     is_immutable('Employee');
  36 }
  37
  38 sub tests02 {
  39     has_meta('Printable');
  40     requires_method( 'Printable', 'as_string' );
  41
  42     has_meta('Person');
  43     does_role( 'Person', 'Printable' );
  44     has_method( 'Person', 'as_string' );
  45
  46     has_meta('HasAccount');
  47     has_method( 'HasAccount', $_ ) for qw( deposit withdraw );
  48     has_role_attr( 'HasAccount', 'balance' );
  49
  50     does_role( 'Person', 'HasAccount' );
  51     has_method( 'Person', $_ ) for qw( deposit withdraw );
  52     has_rw_attr( 'Person', 'balance' );
  53
  54     has_meta('Employee');
  55     does_role( 'Employee', $_ ) for qw( Printable HasAccount );
  56
  57     person02();
  58     employee02();
  59
  60     no_droppings($_) for qw( Printable HasAccount );
  61
  62     tests01();
  63 }
  64
  65 sub tests03 {
  66     has_meta('Person');
  67
  68     for my $name ( qw( first_name last_name ) ) {
  69         has_rw_attr( 'Person', $name );
  70
  71         my $attr = Person->meta->get_attribute($name);
  72         ok( $attr && $attr->is_required,
  73             "$name is required in Person" );
  74     }
  75
  76     has_rw_attr( 'Person', 'title' );
  77
  78     my $person_title_attr = Person->meta->get_attribute('title');
  79     ok( !$person_title_attr->is_required, 'title is not required in Person' );
  80     is(
  81         $person_title_attr->predicate, 'has_title',
  82         'Person title attr has a has_title predicate'
  83     );
  84     is(
  85         $person_title_attr->clearer, 'clear_title',
  86         'Person title attr has a clear_title clearer'
  87     );
  88
  89     person03();
  90
  91     has_meta('Employee');
  92
  93     has_rw_attr( 'Employee', 'title', 'overridden' );
  94
  95     my $employee_title_attr = Employee->meta->get_attribute('title');
  96     is(
  97         $employee_title_attr->default, 'Worker',
  98         'title defaults to Worker in Employee'
  99     );
 100
 101     ok(
 102         !Employee->meta->has_method('full_name'),
 103         'Employee no longer implements a full_name method'
 104     );
 105
 106     has_ro_attr( 'Employee', 'salary' );
 107
 108     my $salary_attr = Employee->meta->get_attribute('salary');
 109     ok( $salary_attr->is_lazy, 'salary is lazy' );
 110     ok( !$salary_attr->init_arg,   'no init_arg for salary attribute' );
 111     ok( $salary_attr->has_builder, 'salary attr has a builder' );
 112
 113     has_method( 'Employee', '_build_salary' );
 114
 115     has_rw_attr( 'Employee', 'salary_level' );
 116
 117     my $salary_level_attr = Employee->meta->get_attribute('salary_level');
 118     is( $salary_level_attr->default, 1, 'salary_level defaults to 1' );
 119
 120     employee03();
 121
 122     my $balance_attr = Person->meta->get_attribute('balance');
 123     is( $balance_attr->default, 100, 'balance defaults to 100' );
 124 }
 125
 126 sub tests04 {
 127     has_meta('Person');
 128
 129     ok( Person->can('full_name'), 'Person has a full_name() method' )
 130         or BAIL_OUT(
 131         'Person does not have a full_name() method. Cannot continue testing.'
 132         );
 133
 134     my $meth = Person->meta()->get_method('full_name');
 135     ok(
 136         $meth && $meth->isa('Class::MOP::Method::Wrapped'),
 137         'method modifiers have been applied to the Person->full_name method'
 138     );
 139
 140     is(
 141         scalar $meth->before_modifiers,
 142         1,
 143         'Person->full_name has a single before modifier'
 144     );
 145
 146     is(
 147         scalar $meth->after_modifiers,
 148         1,
 149         'Person->full_name has a single after modifier'
 150     );
 151
 152     my $person = Person->new(
 153         first_name => 'Bilbo',
 154         last_name  => 'Baggins',
 155     );
 156
 157     is_deeply(
 158         \@Person::CALL,
 159         [],
 160         'Person::CALL global is empty before calling full_name'
 161     );
 162
 163     $person->full_name();
 164
 165     is_deeply(
 166         \@Person::CALL,
 167         [ 'calling full_name', 'called full_name' ],
 168         'Person::CALL global contains before and after strings'
 169     );
 170
 171     is(
 172         scalar $meth->around_modifiers,
 173         1,
 174         'Person->full_name has a single around modifier'
 175     );
 176
 177     my $larry = Person->new(
 178         first_name => 'Larry',
 179         last_name  => 'Wall',
 180     );
 181
 182     is(
 183         $larry->full_name,
 184         '*Larry Wall*',
 185         'full_name is wrapped by asterisks when last name is Wall'
 186     );
 187 }
 188
 189 sub tests05 {
 190     has_meta('Person');
 191
 192     for my $attr_name (qw( first_name last_name title )) {
 193         my $attr = Person->meta->get_attribute($attr_name);
 194
 195         ok(
 196             $attr->has_type_constraint,
 197             "Person $attr_name has a type constraint"
 198         );
 199         is(
 200             $attr->type_constraint->name, 'Str',
 201             "Person $attr_name type is Str"
 202         );
 203     }
 204
 205     has_meta('Employee');
 206
 207     {
 208         my $salary_level_attr = Employee->meta->get_attribute('salary_level');
 209         ok(
 210             $salary_level_attr->has_type_constraint,
 211             'Employee salary_level has a type constraint'
 212         );
 213
 214         my $tc = $salary_level_attr->type_constraint;
 215
 216         for my $invalid ( 0, 11, -14, 'foo', undef ) {
 217             my $str = defined $invalid ? $invalid : 'undef';
 218             ok(
 219                 !$tc->check($invalid),
 220                 "salary_level type rejects invalid value - $str"
 221             );
 222         }
 223
 224         for my $valid ( 1 .. 10 ) {
 225             ok(
 226                 $tc->check($valid),
 227                 "salary_level type accepts valid value - $valid"
 228             );
 229         }
 230     }
 231
 232     {
 233         my $salary_attr = Employee->meta->get_attribute('salary');
 234
 235         ok(
 236             $salary_attr->has_type_constraint,
 237             'Employee salary has a type constraint'
 238         );
 239
 240         my $tc = $salary_attr->type_constraint;
 241
 242         for my $invalid ( 0, -14, 'foo', undef ) {
 243             my $str = defined $invalid ? $invalid : 'undef';
 244             ok(
 245                 !$tc->check($invalid),
 246                 "salary type rejects invalid value - $str"
 247             );
 248         }
 249
 250         for my $valid ( 1, 100_000, 10**10 ) {
 251             ok(
 252                 $tc->check($valid),
 253                 "salary type accepts valid value - $valid"
 254             );
 255         }
 256     }
 257
 258     {
 259         my $ssn_attr = Employee->meta->get_attribute('ssn');
 260
 261         ok(
 262             $ssn_attr->has_type_constraint,
 263             'Employee ssn has a type constraint'
 264         );
 265
 266         my $tc = $ssn_attr->type_constraint;
 267
 268         for my $invalid ( 0, -14, 'foo', undef, '123-ab-1241', '123456789' ) {
 269             my $str = defined $invalid ? $invalid : 'undef';
 270             ok(
 271                 !$tc->check($invalid),
 272                 "ssn type rejects invalid value - $str"
 273             );
 274         }
 275
 276         for my $valid ( '041-12-1251', '123-45-6789', '926-41-5820' ) {
 277             ok(
 278                 $tc->check($valid),
 279                 "ssn type accepts valid value - $valid"
 280             );
 281         }
 282     }
 283
 284     no_droppings('Employee');
 285 }
 286
 287 sub tests06 {
 288     has_meta('BankAccount');
 289
 290     has_rw_attr( 'BankAccount', $_ ) for qw( balance owner );
 291
 292     my $ba_meta = BankAccount->meta;
 293
 294     ok(
 295         $ba_meta->get_attribute('owner')->is_weak_ref,
 296         'owner attribute is a weak ref'
 297     );
 298
 299     has_method( 'BankAccount', $_ ) for qw( deposit withdraw );
 300
 301     has_ro_attr( 'BankAccount', 'history' );
 302
 303     my $history_attr = $ba_meta->get_attribute('history');
 304
 305     is_deeply(
 306         $history_attr->default->(),
 307         [],
 308         'BankAccount history attribute defaults to []'
 309     );
 310
 311     {
 312         my $tc = $history_attr->type_constraint;
 313
 314         for my $invalid ( 0, 42, undef, {}, [ 'foo', 'bar' ] ) {
 315             my $str = defined $invalid ? $invalid : 'undef';
 316             ok(
 317                 !$tc->check($invalid),
 318                 "salary_level type rejects invalid value - $str"
 319             );
 320         }
 321
 322         for my $valid ( [], [1], [ 1, 2, 3 ], [ 1, -10, 9999 ] ) {
 323             ok(
 324                 $tc->check($valid),
 325                 "salary_level type accepts valid value"
 326             );
 327         }
 328     }
 329
 330     ok(
 331         $history_attr->meta()
 332             ->does_role('Moose::Meta::Attribute::Native::Trait::Array'),
 333         'BankAccount history attribute uses native delegation to an array ref'
 334     );
 335
 336     ok(
 337         $ba_meta->get_attribute('balance')->has_trigger,
 338         'BankAccount balance attribute has a trigger'
 339     );
 340
 341     has_meta('Person');
 342
 343     my $person_meta = Person->meta;
 344
 345     ok( !$person_meta->does_role('HasAccount'),
 346         'Person class does not do the HasAccount role' );
 347
 348     ok(
 349         !$person_meta->has_attribute('balance'),
 350         'Person class does not have a balance attribute'
 351     );
 352
 353     my $deposit_meth = $person_meta->get_method('deposit');
 354     isa_ok( $deposit_meth, 'Moose::Meta::Method::Delegation' );
 355
 356     my $withdraw_meth = $person_meta->get_method('withdraw');
 357     isa_ok( $withdraw_meth, 'Moose::Meta::Method::Delegation' );
 358
 359     person06();
 360
 361     has_meta('Employee');
 362
 363     no_droppings('BankAccount');
 364 }
 365
 366 sub has_meta {
 367     my $package = shift;
 368
 369     local $Test::Builder::Level = $Test::Builder::Level + 1;
 370
 371     use_ok($package)
 372         or BAIL_OUT("$package cannot be loaded");
 373
 374     ok( $package->can('meta'), "$package has a meta() method" )
 375         or BAIL_OUT(
 376         "$package does not have a meta() method (did you forget to 'use Moose'?)"
 377         );
 378 }
 379
 380 sub check_isa {
 381     my $class   = shift;
 382     my $parents = shift;
 383
 384     local $Test::Builder::Level = $Test::Builder::Level + 1;
 385
 386     my @isa = $class->meta->linearized_isa;
 387     shift @isa;    # returns $class as the first entry
 388
 389     my $count = scalar @{$parents};
 390     my $noun = PL_N( 'parent', $count );
 391
 392     is( scalar @isa, $count, "$class has $count $noun" );
 393
 394     for ( my $i = 0; $i < @{$parents}; $i++ ) {
 395         is( $isa[$i], $parents->[$i], "parent[$i] is $parents->[$i]" );
 396     }
 397 }
 398
 399 sub has_rw_attr {
 400     my $class      = shift;
 401     my $name       = shift;
 402     my $overridden = shift;
 403
 404     local $Test::Builder::Level = $Test::Builder::Level + 1;
 405
 406     my $articled = $overridden ? "an overridden $name" : A($name);
 407     ok(
 408         $class->meta->has_attribute($name),
 409         "$class has $articled attribute"
 410     );
 411
 412     my $attr = $class->meta->get_attribute($name);
 413
 414     is(
 415         $attr->get_read_method, $name,
 416         "$name attribute has a reader accessor - $name()"
 417     );
 418     is(
 419         $attr->get_write_method, $name,
 420         "$name attribute has a writer accessor - $name()"
 421     );
 422 }
 423
 424 sub has_ro_attr {
 425     my $class = shift;
 426     my $name  = shift;
 427
 428     local $Test::Builder::Level = $Test::Builder::Level + 1;
 429
 430     my $articled = A($name);
 431     ok(
 432         $class->meta->has_attribute($name),
 433         "$class has $articled attribute"
 434     );
 435
 436     my $attr = $class->meta->get_attribute($name);
 437
 438     is(
 439         $attr->get_read_method, $name,
 440         "$name attribute has a reader accessor - $name()"
 441     );
 442     is(
 443         $attr->get_write_method, undef,
 444         "$name attribute does not have a writer"
 445     );
 446 }
 447
 448 sub has_role_attr {
 449     my $role = shift;
 450     my $name = shift;
 451
 452     local $Test::Builder::Level = $Test::Builder::Level + 1;
 453
 454     my $articled = A($name);
 455     ok(
 456         $role->meta->get_attribute($name),
 457         "$role has $articled attribute"
 458     );
 459 }
 460
 461 sub has_method {
 462     my $package = shift;
 463     my $name    = shift;
 464
 465     local $Test::Builder::Level = $Test::Builder::Level + 1;
 466
 467     my $articled = A($name);
 468     ok( $package->meta->has_method($name), "$package has $articled method" );
 469 }
 470
 471 sub has_overridden_method {
 472     my $package = shift;
 473     my $name    = shift;
 474
 475     local $Test::Builder::Level = $Test::Builder::Level + 1;
 476
 477     my $articled = A($name);
 478     ok( $package->meta->has_method($name), "$package has $articled method" );
 479
 480     my $meth = $package->meta->get_method($name);
 481     isa_ok( $meth, 'Moose::Meta::Method::Overridden' );
 482 }
 483
 484 sub has_augmented_method {
 485     my $class = shift;
 486     my $name  = shift;
 487
 488     local $Test::Builder::Level = $Test::Builder::Level + 1;
 489
 490     my $articled = A($name);
 491     ok( $class->meta->has_method($name), "$class has $articled method" );
 492
 493     my $meth = $class->meta->get_method($name);
 494     isa_ok( $meth, 'Moose::Meta::Method::Augmented' );
 495 }
 496
 497 sub requires_method {
 498     my $package = shift;
 499     my $method  = shift;
 500
 501     local $Test::Builder::Level = $Test::Builder::Level + 1;
 502
 503     ok(
 504         $package->meta->requires_method($method),
 505         "$package requires the method $method"
 506     );
 507 }
 508
 509 sub no_droppings {
 510     my $package = shift;
 511
 512     local $Test::Builder::Level = $Test::Builder::Level + 1;
 513
 514     ok( !$package->can('has'), "no Moose droppings in $package" );
 515     ok( !$package->can('subtype'),
 516         "no Moose::Util::TypeConstraints droppings in $package" );
 517 }
 518
 519 sub is_immutable {
 520     my $class = shift;
 521
 522     local $Test::Builder::Level = $Test::Builder::Level + 1;
 523
 524     ok( $class->meta->is_immutable, "$class has been made immutable" );
 525 }
 526
 527 sub does_role {
 528     my $package = shift;
 529     my $role    = shift;
 530
 531     local $Test::Builder::Level = $Test::Builder::Level + 1;
 532
 533     ok( $package->meta->does_role($role), "$package does the $role role" );
 534 }
 535
 536 sub person01 {
 537     my $person = Person->new(
 538         first_name => 'Bilbo',
 539         last_name  => 'Baggins',
 540     );
 541
 542     is(
 543         $person->full_name, 'Bilbo Baggins',
 544         'full_name() is correctly implemented'
 545     );
 546
 547     $person = eval { Person->new( [ qw( Lisa Smith ) ] ) };
 548
 549     if ( my $e = $@ ) {
 550         diag(
 551             "Calling Person->new() with an array reference threw an error:\n$e"
 552         );
 553         BAIL_OUT(
 554             'You must implement Person->BUILDARGS correctly in order to continue these tests'
 555         );
 556     }
 557     else {
 558         ok( 1, 'Person->new() can accept an array reference as an argument' );
 559     }
 560
 561     is( $person->first_name, 'Lisa', 'set first_name from two-arg arrayref' );
 562     is( $person->last_name, 'Smith', 'set last_name from two-arg arrayref' );
 563
 564     eval {
 565         Person->new( sub {'foo'} );
 566     };
 567     like(
 568         $@, qr/\QSingle parameters to new() must be a HASH ref/,
 569         'Person constructor still rejects bad parameters'
 570     );
 571 }
 572
 573 sub employee01 {
 574     my $employee = Employee->new(
 575         first_name => 'Amanda',
 576         last_name  => 'Palmer',
 577         title      => 'Singer',
 578     );
 579
 580     my $called     = 0;
 581     my $orig_super = \&Employee::super;
 582     no warnings 'redefine';
 583     local *Employee::super = sub { $called++; goto &$orig_super };
 584
 585     is(
 586         $employee->full_name, 'Amanda Palmer (Singer)',
 587         'full_name() is properly overriden in Employee'
 588     );
 589     ok( $called, 'Employee->full_name calls super()' );
 590 }
 591
 592 sub person02 {
 593     my $person = Person->new(
 594         first_name => 'Bilbo',
 595         last_name  => 'Baggins',
 596         balance    => 0,
 597     );
 598
 599     is(
 600         $person->as_string, 'Bilbo Baggins',
 601         'as_string() is correctly implemented'
 602     );
 603
 604     account_tests($person);
 605 }
 606
 607 sub employee02 {
 608     my $employee = Employee->new(
 609         first_name => 'Amanda',
 610         last_name  => 'Palmer',
 611         title      => 'Singer',
 612         balance    => 0,
 613     );
 614
 615     is(
 616         $employee->as_string, 'Amanda Palmer (Singer)',
 617         'as_string() uses overridden full_name method in Employee'
 618     );
 619
 620     account_tests($employee);
 621 }
 622
 623 sub person03 {
 624     my $person = Person->new(
 625         first_name => 'Bilbo',
 626         last_name  => 'Baggins',
 627     );
 628
 629     is(
 630         $person->full_name, 'Bilbo Baggins',
 631         'full_name() is correctly implemented for a Person without a title'
 632     );
 633     ok(
 634         !$person->has_title,
 635         'Person has_title predicate is working correctly (returns false)'
 636     );
 637
 638     $person->title('Ringbearer');
 639     ok( $person->has_title,
 640         'Person has_title predicate is working correctly (returns true)' );
 641
 642     my $called    = 0;
 643     my $orig_pred = \&Person::has_title;
 644     no warnings 'redefine';
 645     local *Person::has_title = sub { $called++; goto &$orig_pred };
 646
 647     is(
 648         $person->full_name, 'Bilbo Baggins (Ringbearer)',
 649         'full_name() is correctly implemented for a Person with a title'
 650     );
 651     ok( $called,
 652         'full_name in person uses the predicate for the title attribute' );
 653
 654     $person->clear_title;
 655     ok( !$person->has_title, 'Person clear_title method cleared the title' );
 656
 657     account_tests( $person, 100 );
 658 }
 659
 660 sub employee03 {
 661     my $employee = Employee->new(
 662         first_name   => 'Jimmy',
 663         last_name    => 'Foo',
 664         salary_level => 3,
 665         salary       => 42,
 666     );
 667
 668     is(
 669         $employee->salary, 30000,
 670         'salary is calculated from salary_level, and salary passed to constructor is ignored'
 671     );
 672 }
 673
 674 sub person06 {
 675     my $account = BankAccount->new();
 676
 677     my $person = Person->new(
 678         first_name => 'Bilbo',
 679         last_name  => 'Baggins',
 680         account    => $account,
 681     );
 682
 683     is(
 684         $person->account, $account,
 685         'account object passed to Person->new is still in object'
 686     );
 687
 688     isa_ok( $person->account, 'BankAccount' );
 689     is(
 690         $person->account->owner, $person,
 691         'owner of bank account is person that created account'
 692     );
 693
 694     $person->deposit(10);
 695     is_deeply(
 696         $person->account->history, [100],
 697         'deposit was recorded in account history'
 698     );
 699
 700     $person->withdraw(15);
 701     is_deeply(
 702         $person->account->history, [ 100, 110 ],
 703         'withdrawal was recorded in account history'
 704     );
 705
 706     $person->withdraw(45);
 707     is_deeply(
 708         $person->account->history, [ 100, 110, 95 ],
 709         'withdrawal was recorded in account history'
 710     );
 711 }
 712
 713 sub account_tests {
 714     local $Test::Builder::Level = $Test::Builder::Level + 1;
 715
 716     my $person = shift;
 717     my $base_amount = shift || 0;
 718
 719     $person->deposit(50);
 720
 721     is(
 722         $person->balance, 50 + $base_amount,
 723         "balance is 50 + $base_amount",
 724     );
 725
 726     eval { $person->withdraw( 75 + $base_amount ) };
 727     like(
 728         $@, qr/\QBalance cannot be negative/,
 729         'cannot withdraw more than is in our balance'
 730     );
 731
 732     $person->withdraw(23);
 733
 734     is(
 735         $person->balance, 27 + $base_amount,
 736         'balance is 27 (+ starting balance) after deposit of 50 and withdrawal of 23'
 737     );
 738 }
 739
 740 1;