make_ext.pl

   1 #!./miniperl
   2 use strict;
   3 use warnings;
   4 use Config;
   5 BEGIN {
   6     unshift @INC, $^O eq 'MSWin32' ? '../ext/Cwd' : 'ext/Cwd';
   7 }
   8 use Cwd;
   9
  10 # To clarify, this isn't the entire suite of modules considered "toolchain"
  11 # It's not even all modules needed to build ext/
  12 # It's just the source paths of the (minimum complete set of) modules in ext/
  13 # needed to build the nonxs modules
  14 # After which, all nonxs modules are in lib, which was always sufficient to
  15 # allow miniperl to build everything else.
  16
  17 my @toolchain = qw(ext/constant/lib ext/Cwd ext/Cwd/lib ext/ExtUtils-Command/lib
  18                    ext/ExtUtils-Install/lib ext/ExtUtils-MakeMaker/lib
  19                    ext/ExtUtils-Manifest/lib ext/Text-ParseWords/lib
  20        ext/File-Path/lib ext/AutoLoader/lib);
  21
  22 # This script acts as a simple interface for building extensions.
  23
  24 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
  25 # Windows version win32/build_ext.pl hence the two invocation styles.
  26
  27 # On Unix, it primarily used by the perl Makefile one extention at a time:
  28 #
  29 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
  30 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
  31 #
  32 # On Windows or VMS,
  33 # If '--static' is specified, static extensions will be built.
  34 # If '--dynamic' is specified, dynamic extensions will be built.
  35 # If '--nonxs' is specified, nonxs extensions will be built.
  36 # If '--dynaloader' is specificied, DynaLoader will be built.
  37 # If '--all' is specified, all extensions will be built.
  38 #
  39 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
  40 #
  41 # E.g.
  42 #
  43 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
  44 #
  45 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
  46 #
  47 #     make_ext.pl MAKE=dmake --dir=..\ext
  48 #
  49 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
  50 #
  51 # Will skip building extensions which are marked with an '!' char.
  52 # Mostly because they still not ported to specified platform.
  53 #
  54 # If any extensions are listed with a '+' char then only those
  55 # extensions will be built, but only if they arent countermanded
  56 # by an '!ext' and are appropriate to the type of building being done.
  57
  58 # It may be deleted in a later release of perl so try to
  59 # avoid using it for other purposes.
  60
  61 my $is_Win32 = $^O eq 'MSWin32';
  62 my $is_VMS = $^O eq 'VMS';
  63 my $is_Unix = !$is_Win32 && !$is_VMS;
  64
  65 require FindExt if $is_Win32;
  66
  67 my (%excl, %incl, %opts, @extspec, @pass_through);
  68
  69 foreach (@ARGV) {
  70     if (/^!(.*)$/) {
  71         $excl{$1} = 1;
  72     } elsif (/^\+(.*)$/) {
  73         $incl{$1} = 1;
  74     } elsif (/^--([\w\-]+)$/) {
  75         $opts{$1} = 1;
  76     } elsif (/^--([\w\-]+)=(.*)$/) {
  77         $opts{$1} = $2;
  78     } elsif (/=/) {
  79         push @pass_through, $_;
  80     } elsif (length) {
  81         push @extspec, $_;
  82     }
  83 }
  84
  85 my $static = $opts{static} || $opts{all};
  86 my $dynamic = $opts{dynamic} || $opts{all};
  87 my $nonxs = $opts{nonxs} || $opts{all};
  88 my $dynaloader = $opts{dynaloader} || $opts{all};
  89
  90 # The Perl Makefile.SH will expand all extensions to
  91 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
  92 # A user wishing to run make_ext might use
  93 #       X (or X/Y or X::Y if nested)
  94
  95 # canonise into X/Y form (pname)
  96
  97 foreach (@extspec) {
  98     if (s{^lib/auto/}{}) {
  99         # Remove lib/auto prefix and /*.* suffix
 100         s{/[^/]+\.[^/]+$}{};
 101     } elsif (s{^ext/}{}) {
 102         # Remove ext/ prefix and /pm_to_blib suffix
 103         s{/pm_to_blib$}{};
 104         # Targets are given as files on disk, but the extension spec is still
 105         # written using /s for each ::
 106         tr!-!/!;
 107     } elsif (s{::}{\/}g) {
 108         # Convert :: to /
 109     } else {
 110         s/\..*o//;
 111     }
 112 }
 113
 114 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
 115 unshift @pass_through, 'PERL_CORE=1';
 116
 117 my $dir  = $opts{dir} || 'ext';
 118 my $target   = $opts{target};
 119 $target = 'all' unless defined $target;
 120
 121 # Previously, $make was taken from config.sh.  However, the user might
 122 # instead be running a possibly incompatible make.  This might happen if
 123 # the user types "gmake" instead of a plain "make", for example.  The
 124 # correct current value of MAKE will come through from the main perl
 125 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
 126 # case third party users of this script (are there any?) don't have the
 127 # MAKE=$(MAKE) argument, which was added after 5.004_03.
 128 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
 129     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
 130 }
 131
 132 # This isn't going to cope with anything fancy, such as spaces inside command
 133 # names, but neither did what it replaced. Once there is a use case that needs
 134 # it, please supply patches. Until then, I'm sticking to KISS
 135 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
 136 # Using an array of 0 or 1 elements makes the subsequent code simpler.
 137 my @run = $Config{run};
 138 @run = () if not defined $run[0] or $run[0] eq '';
 139
 140
 141 if ($target eq '') {
 142     die "make_ext: no make target specified (eg all or clean)\n";
 143 } elsif ($target !~ /(?:^all|clean)$/) {
 144     # for the time being we are strict about what make_ext is used for
 145     die "$0: unknown make target '$target'\n";
 146 }
 147
 148 if (!@extspec and !$static and !$dynamic and !$nonxs and !$dynaloader)  {
 149     die "$0: no extension specified\n";
 150 }
 151
 152 my $perl;
 153 my %extra_passthrough;
 154
 155 if ($is_Win32) {
 156     (my $here = getcwd()) =~ s{/}{\\}g;
 157     $perl = $^X;
 158     if ($perl =~ m#^\.\.#) {
 159         $perl = "$here\\$perl";
 160     }
 161     (my $topdir = $perl) =~ s/\\[^\\]+$//;
 162     # miniperl needs to find perlglob and pl2bat
 163     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
 164     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
 165     unless (-f "$pl2bat.bat") {
 166         my @args = ($perl, ("$pl2bat.pl") x 2);
 167         print "@args\n";
 168         system(@args) unless defined $::Cross::platform;
 169     }
 170
 171     print "In ", getcwd();
 172     chdir($dir) || die "Cannot cd to $dir\n";
 173     (my $ext = getcwd()) =~ s{/}{\\}g;
 174     FindExt::scan_ext($ext);
 175     FindExt::set_static_extensions(split ' ', $Config{static_ext});
 176
 177     my @ext;
 178     push @ext, FindExt::static_ext() if $static;
 179     push @ext, FindExt::dynamic_ext() if $dynamic;
 180     push @ext, FindExt::nonxs_ext() if $nonxs;
 181     push @ext, 'DynaLoader' if $dynaloader;
 182
 183     foreach (sort @ext) {
 184         if (%incl and !exists $incl{$_}) {
 185             #warn "Skipping extension $ext\\$_, not in inclusion list\n";
 186             next;
 187         }
 188         if (exists $excl{$_}) {
 189             warn "Skipping extension $ext\\$_, not ported to current platform";
 190             next;
 191         }
 192         push @extspec, $_;
 193         if($_ eq 'DynaLoader') {
 194             # No, we don't know why nmake can't work out the dependency chain
 195             push @{$extra_passthrough{$_}}, 'DynaLoader.c';
 196         } elsif(FindExt::is_static($_)) {
 197             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
 198         }
 199     }
 200     chdir '..'; # now in the Perl build directory
 201 }
 202 elsif ($is_VMS) {
 203     $perl = $^X;
 204     push @extspec, (split ' ', $Config{static_ext}) if $static;
 205     push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
 206     push @extspec, (split ' ', $Config{nonxs_ext}) if $nonxs;
 207     push @extspec, 'DynaLoader' if $dynaloader;
 208 }
 209
 210 {
 211     # Cwd needs to be built before Encode recurses into subdirectories.
 212     # This seems to be the simplest way to ensure this ordering:
 213     my (@first, @other);
 214     foreach (@extspec) {
 215         if ($_ eq 'Cwd') {
 216             push @first, $_;
 217         } else {
 218             push @other, $_;
 219         }
 220     }
 221     @extspec = (@first, @other);
 222 }
 223
 224 foreach my $spec (@extspec)  {
 225     my $mname = $spec;
 226     $mname =~ s!/!::!g;
 227     my $ext_pathname;
 228     if (-d "ext/$spec") {
 229         # Old style ext/Data/Dumper/
 230         $ext_pathname = "ext/$spec";
 231     } else {
 232         # New style ext/Data-Dumper/
 233         my $copy = $spec;
 234         $copy =~ tr!/!-!;
 235         $ext_pathname = "ext/$copy";
 236     }
 237
 238     if ($Config{osname} eq 'catamount') {
 239         # Snowball's chance of building extensions.
 240         die "This is $Config{osname}, not building $mname, sorry.\n";
 241     }
 242
 243     print "\tMaking $mname ($target)\n";
 244
 245     build_extension($ext_pathname, $perl, $mname,
 246                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
 247 }
 248
 249 sub build_extension {
 250     my ($ext_dir, $perl, $mname, $pass_through) = @_;
 251
 252     my $up = $ext_dir;
 253     $up =~ s![^/]+!..!g;
 254
 255     $perl ||= "$up/miniperl";
 256     my $return_dir = $up;
 257     my $lib_dir = "$up/lib";
 258     # $lib_dir must be last, as we're copying files into it, and in a parallel
 259     # make there's a race condition if one process tries to open a module that
 260     # another process has half-written.
 261     $ENV{PERL5LIB}
 262         = join $Config{path_sep}, (map {"$up/$_"} @toolchain), $lib_dir;
 263     $ENV{PERL_CORE} = 1;
 264
 265     unless (chdir "$ext_dir") {
 266         warn "Cannot cd to $ext_dir: $!";
 267         return;
 268     }
 269     my $makefile;
 270     if ($is_VMS) {
 271         $makefile = 'descrip.mms';
 272         if ($target =~ /clean$/
 273             && !-f $makefile
 274             && -f "${makefile}_old") {
 275             $makefile = "${makefile}_old";
 276         }
 277     } else {
 278         $makefile = 'Makefile';
 279     }
 280
 281     if (!-f $makefile) {
 282         if (!-f 'Makefile.PL') {
 283             print "\nCreating Makefile.PL in $ext_dir for $mname\n";
 284             # We need to cope well with various possible layouts
 285             my @dirs = split /::/, $mname;
 286             my $leaf = pop @dirs;
 287             my $leafname = "$leaf.pm";
 288             my $pathname = join '/', @dirs, $leafname;
 289             my @locations = ($leafname, $pathname, "lib/$pathname");
 290             my $fromname;
 291             foreach (@locations) {
 292                 if (-f $_) {
 293                     $fromname = $_;
 294                     last;
 295                 }
 296             }
 297
 298             unless ($fromname) {
 299                 die "For $mname tried @locations in in $ext_dir but can't find source";
 300             }
 301             open my $fh, '>', 'Makefile.PL'
 302                 or die "Can't open Makefile.PL for writing: $!";
 303             print $fh <<"EOM";
 304 #-*- buffer-read-only: t -*-
 305
 306 # This Makefile.PL was written by $0.
 307 # It will be deleted automatically by make realclean
 308
 309 use strict;
 310 use ExtUtils::MakeMaker;
 311
 312 WriteMakefile(
 313     NAME          => '$mname',
 314     VERSION_FROM  => '$fromname',
 315     ABSTRACT_FROM => '$fromname',
 316     realclean     => {FILES => 'Makefile.PL'},
 317 );
 318
 319 # ex: set ro:
 320 EOM
 321             close $fh or die "Can't close Makefile.PL: $!";
 322         }
 323         print "\nRunning Makefile.PL in $ext_dir\n";
 324
 325         # Presumably this can be simplified
 326         my @cross;
 327         if (defined $::Cross::platform) {
 328             # Inherited from win32/buildext.pl
 329             @cross = "-MCross=$::Cross::platform";
 330         } elsif ($opts{cross}) {
 331             # Inherited from make_ext.pl
 332             @cross = '-MCross';
 333         }
 334
 335         my @args = (@cross, 'Makefile.PL');
 336         if ($is_VMS) {
 337             my $libd = VMS::Filespec::vmspath($lib_dir);
 338             push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
 339         } else {
 340             push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
 341                 'INSTALLMAN3DIR=none';
 342         }
 343         push @args, @$pass_through;
 344         _quote_args(\@args) if $is_VMS;
 345         print join(' ', @run, $perl, @args), "\n";
 346         my $code = system @run, $perl, @args;
 347         warn "$code from $ext_dir\'s Makefile.PL" if $code;
 348
 349         # Right. The reason for this little hack is that we're sitting inside
 350         # a program run by ./miniperl, but there are tasks we need to perform
 351         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
 352         # Unfortunately, they can be run *after* 'clean', which deletes
 353         # ./miniperl
 354         # So we do our best to leave a set of instructions identical to what
 355         # we would do if we are run directly as 'realclean' etc
 356         # Whilst we're perfect, unfortunately the targets we call are not, as
 357         # some of them rely on a $(PERL) for their own distclean targets.
 358         # But this always used to be a problem with the old /bin/sh version of
 359         # this.
 360         if ($is_Unix) {
 361             my $suffix = '.sh';
 362             foreach my $clean_target ('realclean', 'veryclean') {
 363                 my $file = "$return_dir/$clean_target$suffix";
 364                 open my $fh, '>>', $file or die "open $file: $!";
 365                 # Quite possible that we're being run in parallel here.
 366                 # Can't use Fcntl this early to get the LOCK_EX
 367                 flock $fh, 2 or warn "flock $file: $!";
 368                 print $fh <<"EOS";
 369 cd $ext_dir
 370 if test ! -f Makefile -a -f Makefile.old; then
 371     echo "Note: Using Makefile.old"
 372     make -f Makefile.old $clean_target MAKE='@make' @pass_through
 373 else
 374     if test ! -f Makefile ; then
 375         echo "Warning: No Makefile!"
 376     fi
 377     make $clean_target MAKE='@make' @pass_through
 378 fi
 379 cd $return_dir
 380 EOS
 381                 close $fh or die "close $file: $!";
 382             }
 383         }
 384     }
 385
 386     if (not -f $makefile) {
 387         print "Warning: No Makefile!\n";
 388     }
 389
 390     if ($is_VMS) {
 391         _macroify_passthrough($pass_through);
 392         unshift @$pass_through, "/DESCRIPTION=$makefile";
 393     }
 394
 395     if (!$target or $target !~ /clean$/) {
 396         # Give makefile an opportunity to rewrite itself.
 397         # reassure users that life goes on...
 398         my @args = ('config', @$pass_through);
 399         _quote_args(\@args) if $is_VMS;
 400         system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
 401     }
 402     my @targ = ($target, @$pass_through);
 403     _quote_args(\@targ) if $is_VMS;
 404     print "Making $target in $ext_dir\n@run @make @targ\n";
 405     my $code = system(@run, @make, @targ);
 406     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
 407
 408     chdir $return_dir || die "Cannot cd to $return_dir: $!";
 409 }
 410
 411 sub _quote_args {
 412     my $args = shift; # must be array reference
 413
 414     # Do not quote qualifiers that begin with '/'.
 415     map { if (!/^\//) {
 416           $_ =~ s/\"/""/g;     # escape C<"> by doubling
 417           $_ = q(").$_.q(");
 418         }
 419     } @{$args}
 420     ;
 421 }
 422
 423 sub _macroify_passthrough {
 424     my $passthrough = shift;
 425     _quote_args($passthrough);
 426     my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
 427     @$passthrough = ();
 428     @$passthrough[0] = $macro;
 429 }