make_ext.pl

   1 #!./miniperl
   2 use strict;
   3 use warnings;
   4 use Config;
   5 BEGIN {
   6     unshift @INC, $^O eq 'MSWin32' ? '../ext/Cwd' : 'ext/Cwd';
   7 }
   8 use Cwd;
   9
  10 # To clarify, this isn't the entire suite of modules considered "toolchain"
  11 # It's not even all modules needed to build ext/
  12 # It's just the source paths of the (minimum complete set of) modules in ext/
  13 # needed to build the nonxs modules
  14 # After which, all nonxs modules are in lib, which was always sufficient to
  15 # allow miniperl to build everything else.
  16
  17 my @toolchain = qw(ext/constant/lib ext/Cwd ext/Cwd/lib ext/ExtUtils-Command/lib
  18                    ext/ExtUtils-Install/lib ext/ExtUtils-MakeMaker/lib
  19                    ext/ExtUtils-Manifest/lib ext/Text-ParseWords/lib
  20        ext/File-Path/lib ext/AutoLoader/lib);
  21
  22 my @ext_dirs = qw(ext cpan);
  23
  24 # This script acts as a simple interface for building extensions.
  25
  26 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
  27 # Windows version win32/build_ext.pl hence the two invocation styles.
  28
  29 # On Unix, it primarily used by the perl Makefile one extention at a time:
  30 #
  31 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
  32 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
  33 #
  34 # On Windows or VMS,
  35 # If '--static' is specified, static extensions will be built.
  36 # If '--dynamic' is specified, dynamic extensions will be built.
  37 # If '--nonxs' is specified, nonxs extensions will be built.
  38 # If '--dynaloader' is specificied, DynaLoader will be built.
  39 # If '--all' is specified, all extensions will be built.
  40 #
  41 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
  42 #
  43 # E.g.
  44 #
  45 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
  46 #
  47 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
  48 #
  49 #     make_ext.pl MAKE=dmake --dir=..\ext
  50 #
  51 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
  52 #
  53 # Will skip building extensions which are marked with an '!' char.
  54 # Mostly because they still not ported to specified platform.
  55 #
  56 # If any extensions are listed with a '+' char then only those
  57 # extensions will be built, but only if they arent countermanded
  58 # by an '!ext' and are appropriate to the type of building being done.
  59
  60 # It may be deleted in a later release of perl so try to
  61 # avoid using it for other purposes.
  62
  63 my $is_Win32 = $^O eq 'MSWin32';
  64 my $is_VMS = $^O eq 'VMS';
  65 my $is_Unix = !$is_Win32 && !$is_VMS;
  66
  67 require FindExt if $is_Win32;
  68
  69 my (%excl, %incl, %opts, @extspec, @pass_through);
  70
  71 foreach (@ARGV) {
  72     if (/^!(.*)$/) {
  73         $excl{$1} = 1;
  74     } elsif (/^\+(.*)$/) {
  75         $incl{$1} = 1;
  76     } elsif (/^--([\w\-]+)$/) {
  77         $opts{$1} = 1;
  78     } elsif (/^--([\w\-]+)=(.*)$/) {
  79         $opts{$1} = $2;
  80     } elsif (/=/) {
  81         push @pass_through, $_;
  82     } elsif (length) {
  83         push @extspec, $_;
  84     }
  85 }
  86
  87 my $static = $opts{static} || $opts{all};
  88 my $dynamic = $opts{dynamic} || $opts{all};
  89 my $nonxs = $opts{nonxs} || $opts{all};
  90 my $dynaloader = $opts{dynaloader} || $opts{all};
  91
  92 # The Perl Makefile.SH will expand all extensions to
  93 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
  94 # A user wishing to run make_ext might use
  95 #       X (or X/Y or X::Y if nested)
  96
  97 # canonise into X/Y form (pname)
  98
  99 foreach (@extspec) {
 100     if (s{^lib/auto/}{}) {
 101         # Remove lib/auto prefix and /*.* suffix
 102         s{/[^/]+\.[^/]+$}{};
 103     } elsif (s{^ext/}{}) {
 104         # Remove ext/ prefix and /pm_to_blib suffix
 105         s{/pm_to_blib$}{};
 106         # Targets are given as files on disk, but the extension spec is still
 107         # written using /s for each ::
 108         tr!-!/!;
 109     } elsif (s{::}{\/}g) {
 110         # Convert :: to /
 111     } else {
 112         s/\..*o//;
 113     }
 114 }
 115
 116 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
 117 unshift @pass_through, 'PERL_CORE=1';
 118
 119 my $dir  = $opts{dir} || 'ext';
 120 my $target   = $opts{target};
 121 $target = 'all' unless defined $target;
 122
 123 # Previously, $make was taken from config.sh.  However, the user might
 124 # instead be running a possibly incompatible make.  This might happen if
 125 # the user types "gmake" instead of a plain "make", for example.  The
 126 # correct current value of MAKE will come through from the main perl
 127 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
 128 # case third party users of this script (are there any?) don't have the
 129 # MAKE=$(MAKE) argument, which was added after 5.004_03.
 130 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
 131     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
 132 }
 133
 134 # This isn't going to cope with anything fancy, such as spaces inside command
 135 # names, but neither did what it replaced. Once there is a use case that needs
 136 # it, please supply patches. Until then, I'm sticking to KISS
 137 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
 138 # Using an array of 0 or 1 elements makes the subsequent code simpler.
 139 my @run = $Config{run};
 140 @run = () if not defined $run[0] or $run[0] eq '';
 141
 142
 143 if ($target eq '') {
 144     die "make_ext: no make target specified (eg all or clean)\n";
 145 } elsif ($target !~ /(?:^all|clean)$/) {
 146     # for the time being we are strict about what make_ext is used for
 147     die "$0: unknown make target '$target'\n";
 148 }
 149
 150 if (!@extspec and !$static and !$dynamic and !$nonxs and !$dynaloader)  {
 151     die "$0: no extension specified\n";
 152 }
 153
 154 my $perl;
 155 my %extra_passthrough;
 156
 157 if ($is_Win32) {
 158     (my $here = getcwd()) =~ s{/}{\\}g;
 159     $perl = $^X;
 160     if ($perl =~ m#^\.\.#) {
 161         $perl = "$here\\$perl";
 162     }
 163     (my $topdir = $perl) =~ s/\\[^\\]+$//;
 164     # miniperl needs to find perlglob and pl2bat
 165     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
 166     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
 167     unless (-f "$pl2bat.bat") {
 168         my @args = ($perl, "-I$topdir\\lib", ("$pl2bat.pl") x 2);
 169         print "@args\n";
 170         system(@args) unless defined $::Cross::platform;
 171     }
 172
 173     print "In ", getcwd();
 174     chdir($dir) || die "Cannot cd to $dir\n";
 175     (my $ext = getcwd()) =~ s{/}{\\}g;
 176     FindExt::scan_ext($ext);
 177     FindExt::set_static_extensions(split ' ', $Config{static_ext});
 178
 179     my @ext;
 180     push @ext, FindExt::static_ext() if $static;
 181     push @ext, FindExt::dynamic_ext() if $dynamic;
 182     push @ext, FindExt::nonxs_ext() if $nonxs;
 183     push @ext, 'DynaLoader' if $dynaloader;
 184
 185     foreach (sort @ext) {
 186         if (%incl and !exists $incl{$_}) {
 187             #warn "Skipping extension $ext\\$_, not in inclusion list\n";
 188             next;
 189         }
 190         if (exists $excl{$_}) {
 191             warn "Skipping extension $ext\\$_, not ported to current platform";
 192             next;
 193         }
 194         push @extspec, $_;
 195         if($_ eq 'DynaLoader') {
 196             # No, we don't know why nmake can't work out the dependency chain
 197             push @{$extra_passthrough{$_}}, 'DynaLoader.c';
 198         } elsif(FindExt::is_static($_)) {
 199             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
 200         }
 201     }
 202     chdir '..'; # now in the Perl build directory
 203 }
 204 elsif ($is_VMS) {
 205     $perl = $^X;
 206     push @extspec, (split ' ', $Config{static_ext}) if $static;
 207     push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
 208     push @extspec, (split ' ', $Config{nonxs_ext}) if $nonxs;
 209     push @extspec, 'DynaLoader' if $dynaloader;
 210 }
 211
 212 {
 213     # Cwd needs to be built before Encode recurses into subdirectories.
 214     # This seems to be the simplest way to ensure this ordering:
 215     my (@first, @other);
 216     foreach (@extspec) {
 217         if ($_ eq 'Cwd') {
 218             push @first, $_;
 219         } else {
 220             push @other, $_;
 221         }
 222     }
 223     @extspec = (@first, @other);
 224 }
 225
 226 foreach my $spec (@extspec)  {
 227     my $mname = $spec;
 228     $mname =~ s!/!::!g;
 229     my $ext_pathname;
 230     if (-d "ext/$spec") {
 231         # Old style ext/Data/Dumper/
 232         $ext_pathname = "ext/$spec";
 233     } else {
 234         # New style ext/Data-Dumper/
 235         my $copy = $spec;
 236         $copy =~ tr!/!-!;
 237         foreach my $dir (@ext_dirs) {
 238             if (-d "$dir/$copy") {
 239                 $ext_pathname = "$dir/$copy";
 240                 last;
 241             }
 242         }
 243         if (!defined $ext_pathname) {
 244             warn "Can't find extension $spec in any of @ext_dirs";
 245             next;
 246         }
 247     }
 248
 249     if ($Config{osname} eq 'catamount') {
 250         # Snowball's chance of building extensions.
 251         die "This is $Config{osname}, not building $mname, sorry.\n";
 252     }
 253
 254     print "\tMaking $mname ($target)\n";
 255
 256     build_extension($ext_pathname, $perl, $mname,
 257                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
 258 }
 259
 260 sub build_extension {
 261     my ($ext_dir, $perl, $mname, $pass_through) = @_;
 262
 263     my $up = $ext_dir;
 264     $up =~ s![^/]+!..!g;
 265
 266     $perl ||= "$up/miniperl";
 267     my $return_dir = $up;
 268     my $lib_dir = "$up/lib";
 269     # $lib_dir must be last, as we're copying files into it, and in a parallel
 270     # make there's a race condition if one process tries to open a module that
 271     # another process has half-written.
 272     $ENV{PERL5LIB}
 273         = join $Config{path_sep}, (map {"$up/$_"} @toolchain), $lib_dir;
 274     $ENV{PERL_CORE} = 1;
 275
 276     unless (chdir "$ext_dir") {
 277         warn "Cannot cd to $ext_dir: $!";
 278         return;
 279     }
 280     my $makefile;
 281     if ($is_VMS) {
 282         $makefile = 'descrip.mms';
 283         if ($target =~ /clean$/
 284             && !-f $makefile
 285             && -f "${makefile}_old") {
 286             $makefile = "${makefile}_old";
 287         }
 288     } else {
 289         $makefile = 'Makefile';
 290     }
 291
 292     if (!-f $makefile) {
 293         if (!-f 'Makefile.PL') {
 294             print "\nCreating Makefile.PL in $ext_dir for $mname\n";
 295             # We need to cope well with various possible layouts
 296             my @dirs = split /::/, $mname;
 297             my $leaf = pop @dirs;
 298             my $leafname = "$leaf.pm";
 299             my $pathname = join '/', @dirs, $leafname;
 300             my @locations = ($leafname, $pathname, "lib/$pathname");
 301             my $fromname;
 302             foreach (@locations) {
 303                 if (-f $_) {
 304                     $fromname = $_;
 305                     last;
 306                 }
 307             }
 308
 309             unless ($fromname) {
 310                 die "For $mname tried @locations in in $ext_dir but can't find source";
 311             }
 312             open my $fh, '>', 'Makefile.PL'
 313                 or die "Can't open Makefile.PL for writing: $!";
 314             print $fh <<"EOM";
 315 #-*- buffer-read-only: t -*-
 316
 317 # This Makefile.PL was written by $0.
 318 # It will be deleted automatically by make realclean
 319
 320 use strict;
 321 use ExtUtils::MakeMaker;
 322
 323 WriteMakefile(
 324     NAME          => '$mname',
 325     VERSION_FROM  => '$fromname',
 326     ABSTRACT_FROM => '$fromname',
 327     realclean     => {FILES => 'Makefile.PL'},
 328 );
 329
 330 # ex: set ro:
 331 EOM
 332             close $fh or die "Can't close Makefile.PL: $!";
 333         }
 334         print "\nRunning Makefile.PL in $ext_dir\n";
 335
 336         # Presumably this can be simplified
 337         my @cross;
 338         if (defined $::Cross::platform) {
 339             # Inherited from win32/buildext.pl
 340             @cross = "-MCross=$::Cross::platform";
 341         } elsif ($opts{cross}) {
 342             # Inherited from make_ext.pl
 343             @cross = '-MCross';
 344         }
 345
 346         my @args = (@cross, 'Makefile.PL');
 347         if ($is_VMS) {
 348             my $libd = VMS::Filespec::vmspath($lib_dir);
 349             push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
 350         } else {
 351             push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
 352                 'INSTALLMAN3DIR=none';
 353         }
 354         push @args, @$pass_through;
 355         _quote_args(\@args) if $is_VMS;
 356         print join(' ', @run, $perl, @args), "\n";
 357         my $code = system @run, $perl, @args;
 358         warn "$code from $ext_dir\'s Makefile.PL" if $code;
 359
 360         # Right. The reason for this little hack is that we're sitting inside
 361         # a program run by ./miniperl, but there are tasks we need to perform
 362         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
 363         # Unfortunately, they can be run *after* 'clean', which deletes
 364         # ./miniperl
 365         # So we do our best to leave a set of instructions identical to what
 366         # we would do if we are run directly as 'realclean' etc
 367         # Whilst we're perfect, unfortunately the targets we call are not, as
 368         # some of them rely on a $(PERL) for their own distclean targets.
 369         # But this always used to be a problem with the old /bin/sh version of
 370         # this.
 371         if ($is_Unix) {
 372             my $suffix = '.sh';
 373             foreach my $clean_target ('realclean', 'veryclean') {
 374                 my $file = "$return_dir/$clean_target$suffix";
 375                 open my $fh, '>>', $file or die "open $file: $!";
 376                 # Quite possible that we're being run in parallel here.
 377                 # Can't use Fcntl this early to get the LOCK_EX
 378                 flock $fh, 2 or warn "flock $file: $!";
 379                 print $fh <<"EOS";
 380 cd $ext_dir
 381 if test ! -f Makefile -a -f Makefile.old; then
 382     echo "Note: Using Makefile.old"
 383     make -f Makefile.old $clean_target MAKE='@make' @pass_through
 384 else
 385     if test ! -f Makefile ; then
 386         echo "Warning: No Makefile!"
 387     fi
 388     make $clean_target MAKE='@make' @pass_through
 389 fi
 390 cd $return_dir
 391 EOS
 392                 close $fh or die "close $file: $!";
 393             }
 394         }
 395     }
 396
 397     if (not -f $makefile) {
 398         print "Warning: No Makefile!\n";
 399     }
 400
 401     if ($is_VMS) {
 402         _macroify_passthrough($pass_through);
 403         unshift @$pass_through, "/DESCRIPTION=$makefile";
 404     }
 405
 406     if (!$target or $target !~ /clean$/) {
 407         # Give makefile an opportunity to rewrite itself.
 408         # reassure users that life goes on...
 409         my @args = ('config', @$pass_through);
 410         _quote_args(\@args) if $is_VMS;
 411         system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
 412     }
 413     my @targ = ($target, @$pass_through);
 414     _quote_args(\@targ) if $is_VMS;
 415     print "Making $target in $ext_dir\n@run @make @targ\n";
 416     my $code = system(@run, @make, @targ);
 417     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
 418
 419     chdir $return_dir || die "Cannot cd to $return_dir: $!";
 420 }
 421
 422 sub _quote_args {
 423     my $args = shift; # must be array reference
 424
 425     # Do not quote qualifiers that begin with '/'.
 426     map { if (!/^\//) {
 427           $_ =~ s/\"/""/g;     # escape C<"> by doubling
 428           $_ = q(").$_.q(");
 429         }
 430     } @{$args}
 431     ;
 432 }
 433
 434 sub _macroify_passthrough {
 435     my $passthrough = shift;
 436     _quote_args($passthrough);
 437     my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
 438     @$passthrough = ();
 439     @$passthrough[0] = $macro;
 440 }