lib/vars.pm

   1 package vars;
   2
   3 require 5.002;
   4
   5 our $VERSION = '1.00';
   6
   7 # The following require can't be removed during maintenance
   8 # releases, sadly, because of the risk of buggy code that does
   9 # require Carp; Carp::croak "..."; without brackets dying
  10 # if Carp hasn't been loaded in earlier compile time. :-(
  11 # We'll let those bugs get found on the development track.
  12 require Carp if $] < 5.00450;
  13
  14 use warnings::register;
  15 require strict;
  16
  17 sub import {
  18     my $callpack = caller;
  19     my ($pack, @imports, $sym, $ch) = @_;
  20     foreach (@imports) {
  21         ($ch, $sym) = unpack('a1a*', $_);
  22         if ($sym =~ tr/A-Za-z_0-9//c) {
  23             # time for a more-detailed check-up
  24             if ($sym =~ /^\w+[[{].*[]}]$/) {
  25                 require Carp;
  26                 Carp::croak("Can't declare individual elements of hash or array");
  27             } elsif (warnings::enabled() and length($sym) == 1 and $sym !~ tr/a-zA-Z//) {
  28                 warnings::warn("No need to declare built-in vars");
  29             } elsif  ( $^H &= strict::bits('vars') ) {
  30               Carp::croak("'$_' is not a valid variable name under strict vars");
  31             }
  32         }
  33         $sym = "${callpack}::$sym" unless $sym =~ /::/;
  34         *$sym =
  35           (  $ch eq "\$" ? \$$sym
  36            : $ch eq "\@" ? \@$sym
  37            : $ch eq "\%" ? \%$sym
  38            : $ch eq "\*" ? \*$sym
  39            : $ch eq "\&" ? \&$sym
  40            : do {
  41                 require Carp;
  42                 Carp::croak("'$_' is not a valid variable name");
  43              });
  44     }
  45 };
  46
  47 1;
  48 __END__
  49
  50 =head1 NAME
  51
  52 vars - Perl pragma to predeclare global variable names (obsolete)
  53
  54 =head1 SYNOPSIS
  55
  56     use vars qw($frob @mung %seen);
  57
  58 =head1 DESCRIPTION
  59
  60 NOTE: For variables in the current package, the functionality provided
  61 by this pragma has been superseded by C<our> declarations, available
  62 in Perl v5.6.0 or later.  See L<perlfunc/our>.
  63
  64 This will predeclare all the variables whose names are
  65 in the list, allowing you to use them under "use strict", and
  66 disabling any typo warnings.
  67
  68 Unlike pragmas that affect the C<$^H> hints variable, the C<use vars> and
  69 C<use subs> declarations are not BLOCK-scoped.  They are thus effective
  70 for the entire file in which they appear.  You may not rescind such
  71 declarations with C<no vars> or C<no subs>.
  72
  73 Packages such as the B<AutoLoader> and B<SelfLoader> that delay
  74 loading of subroutines within packages can create problems with
  75 package lexicals defined using C<my()>. While the B<vars> pragma
  76 cannot duplicate the effect of package lexicals (total transparency
  77 outside of the package), it can act as an acceptable substitute by
  78 pre-declaring global symbols, ensuring their availability to the
  79 later-loaded routines.
  80
  81 See L<perlmodlib/Pragmatic Modules>.
  82
  83 =cut