lib/utf8.pm

   1 package utf8;
   2
   3 $utf8::hint_bits = 0x00800000;
   4
   5 our $VERSION = '1.03';
   6
   7 sub import {
   8     $^H |= $utf8::hint_bits;
   9     $enc{caller()} = $_[1] if $_[1];
  10 }
  11
  12 sub unimport {
  13     $^H &= ~$utf8::hint_bits;
  14 }
  15
  16 sub AUTOLOAD {
  17     require "utf8_heavy.pl";
  18     goto &$AUTOLOAD if defined &$AUTOLOAD;
  19     Carp::croak("Undefined subroutine $AUTOLOAD called");
  20 }
  21
  22 1;
  23 __END__
  24
  25 =head1 NAME
  26
  27 utf8 - Perl pragma to enable/disable UTF-8 (or UTF-EBCDIC) in source code
  28
  29 =head1 SYNOPSIS
  30
  31     use utf8;
  32     no utf8;
  33
  34     # Convert a Perl scalar to/from UTF-8.
  35     $num_octets = utf8::upgrade($string);
  36     $success    = utf8::downgrade($string[, FAIL_OK]);
  37
  38     # Change the native bytes of a Perl scalar to/from UTF-8 bytes.
  39     utf8::encode($string);
  40     utf8::decode($string);
  41
  42     $flag = utf8::is_utf8(STRING); # since Perl 5.8.1
  43     $flag = utf8::valid(STRING);
  44
  45 =head1 DESCRIPTION
  46
  47 The C<use utf8> pragma tells the Perl parser to allow UTF-8 in the
  48 program text in the current lexical scope (allow UTF-EBCDIC on EBCDIC based
  49 platforms).  The C<no utf8> pragma tells Perl to switch back to treating
  50 the source text as literal bytes in the current lexical scope.
  51
  52 This pragma is primarily a compatibility device.  Perl versions
  53 earlier than 5.6 allowed arbitrary bytes in source code, whereas
  54 in future we would like to standardize on the UTF-8 encoding for
  55 source text.
  56
  57 B<Do not use this pragma for anything else than telling Perl that your
  58 script is written in UTF-8.> The utility functions described below are
  59 useful for their own purposes, but they are not really part of the
  60 "pragmatic" effect.
  61
  62 Until UTF-8 becomes the default format for source text, either this
  63 pragma or the L</encoding> pragma should be used to recognize UTF-8
  64 in the source.  When UTF-8 becomes the standard source format, this
  65 pragma will effectively become a no-op.  For convenience in what
  66 follows the term I<UTF-X> is used to refer to UTF-8 on ASCII and ISO
  67 Latin based platforms and UTF-EBCDIC on EBCDIC based platforms.
  68
  69 See also the effects of the C<-C> switch and its cousin, the
  70 C<$ENV{PERL_UNICODE}>, in L<perlrun>.
  71
  72 Enabling the C<utf8> pragma has the following effect:
  73
  74 =over 4
  75
  76 =item *
  77
  78 Bytes in the source text that have their high-bit set will be treated
  79 as being part of a literal UTF-8 character.  This includes most
  80 literals such as identifier names, string constants, and constant
  81 regular expression patterns.
  82
  83 On EBCDIC platforms characters in the Latin 1 character set are
  84 treated as being part of a literal UTF-EBCDIC character.
  85
  86 =back
  87
  88 Note that if you have bytes with the eighth bit on in your script
  89 (for example embedded Latin-1 in your string literals), C<use utf8>
  90 will be unhappy since the bytes are most probably not well-formed
  91 UTF-8.  If you want to have such bytes and use utf8, you can disable
  92 utf8 until the end the block (or file, if at top level) by C<no utf8;>.
  93
  94 If you want to automatically upgrade your 8-bit legacy bytes to UTF-8,
  95 use the L</encoding> pragma instead of this pragma.  For example, if
  96 you want to implicitly upgrade your ISO 8859-1 (Latin-1) bytes to UTF-8
  97 as used in e.g. C<chr()> and C<\x{...}>, try this:
  98
  99     use encoding "latin-1";
 100     my $c = chr(0xc4);
 101     my $x = "\x{c5}";
 102
 103 In case you are wondering: yes, C<use encoding 'utf8';> works much
 104 the same as C<use utf8;>.
 105
 106 =head2 Utility functions
 107
 108 The following functions are defined in the C<utf8::> package by the
 109 Perl core.  You do not need to say C<use utf8> to use these and in fact
 110 you should not say that  unless you really want to have UTF-8 source code.
 111
 112 =over 4
 113
 114 =item * $num_octets = utf8::upgrade($string)
 115
 116 Converts (in-place) internal representation of string to Perl's
 117 internal I<UTF-X> form.  Returns the number of octets necessary to
 118 represent the string as I<UTF-X>.  Can be used to make sure that the
 119 UTF-8 flag is on, so that C<\w> or C<lc()> work as expected on strings
 120 containing characters in the range 0x80-0xFF (oon ASCII and
 121 derivatives).  Note that this should not be used to convert a legacy
 122 byte encoding to Unicode: use Encode for that.  Affected by the
 123 encoding pragma.
 124
 125 =item * $success = utf8::downgrade($string[, FAIL_OK])
 126
 127 Converts (in-place) internal representation of string to be un-encoded
 128 bytes.  Returns true on success. On failure dies or, if the value of
 129 FAIL_OK is true, returns false.  Can be used to make sure that the
 130 UTF-8 flag is off, e.g. when you want to make sure that the substr()
 131 or length() function works with the usually faster byte algorithm.
 132 Note that this should not be used to convert Unicode back to a legacy
 133 byte encoding: use Encode for that.  B<Not> affected by the encoding
 134 pragma.
 135
 136 =item * utf8::encode($string)
 137
 138 Converts in-place the octets of the I<$string> to the octet sequence
 139 in Perl's I<UTF-X> encoding.  Returns nothing.  B<Note that this does
 140 not change the "type" of I<$string> to UTF-8>, and that this handles
 141 only ISO 8859-1 (or EBCDIC) as the source character set. Therefore
 142 this should not be used to convert a legacy 8-bit encoding to Unicode:
 143 use Encode::decode() for that.  In the very limited case of wanting to
 144 handle just ISO 8859-1 (or EBCDIC), you could use utf8::upgrade().
 145
 146 =item * utf8::decode($string)
 147
 148 Attempts to convert I<$string> in-place from Perl's I<UTF-X> encoding
 149 into octets.  Returns nothing.  B<Note that this does not change the
 150 "type" of <$string> from UTF-8>, and that this handles only ISO 8859-1
 151 (or EBCDIC) as the destination character set.  Therefore this should
 152 not be used to convert Unicode back to a legacy 8-bit encoding:
 153 use Encode::encode() for that.  In the very limited case of wanting
 154 to handle just ISO 8859-1 (or EBCDIC), you could use utf8::downgrade().
 155
 156 =item * $flag = utf8::is_utf8(STRING)
 157
 158 (Since Perl 5.8.1)  Test whether STRING is in UTF-8.  Functionally
 159 the same as Encode::is_utf8().
 160
 161 =item * $flag = utf8::valid(STRING)
 162
 163 [INTERNAL] Test whether STRING is in a consistent state regarding
 164 UTF-8.  Will return true is well-formed UTF-8 and has the UTF-8 flag
 165 on B<or> if string is held as bytes (both these states are 'consistent').
 166 Main reason for this routine is to allow Perl's testsuite to check
 167 that operations have left strings in a consistent state.  You most
 168 probably want to use utf8::is_utf8() instead.
 169
 170 =back
 171
 172 C<utf8::encode> is like C<utf8::upgrade>, but the UTF8 flag is
 173 cleared.  See L<perlunicode> for more on the UTF8 flag and the C API
 174 functions C<sv_utf8_upgrade>, C<sv_utf8_downgrade>, C<sv_utf8_encode>,
 175 and C<sv_utf8_decode>, which are wrapped by the Perl functions
 176 C<utf8::upgrade>, C<utf8::downgrade>, C<utf8::encode> and
 177 C<utf8::decode>.  Note that in the Perl 5.8.0 and 5.8.1 implementation
 178 the functions utf8::is_utf8, utf8::valid, utf8::encode, utf8::decode,
 179 utf8::upgrade, and utf8::downgrade are always available, without a
 180 C<require utf8> statement-- this may change in future releases.
 181
 182 =head1 BUGS
 183
 184 One can have Unicode in identifier names, but not in package/class or
 185 subroutine names.  While some limited functionality towards this does
 186 exist as of Perl 5.8.0, that is more accidental than designed; use of
 187 Unicode for the said purposes is unsupported.
 188
 189 One reason of this unfinishedness is its (currently) inherent
 190 unportability: since both package names and subroutine names may need
 191 to be mapped to file and directory names, the Unicode capability of
 192 the filesystem becomes important-- and there unfortunately aren't
 193 portable answers.
 194
 195 =head1 SEE ALSO
 196
 197 L<perluniintro>, L<encoding>, L<perlrun>, L<bytes>, L<perlunicode>
 198
 199 =cut