lib/syslog.pl

   1 #
   2 # syslog.pl
   3 #
   4 # $Log: syslog.pl,v $
   5 #
   6 # tom christiansen <tchrist@convex.com>
   7 # modified to use sockets by Larry Wall <lwall@jpl-devvax.jpl.nasa.gov>
   8 # NOTE: openlog now takes three arguments, just like openlog(3)
   9 #
  10 # call syslog() with a string priority and a list of printf() args
  11 # like syslog(3)
  12 #
  13 #  usage: require 'syslog.pl';
  14 #
  15 #  then (put these all in a script to test function)
  16 #
  17 #
  18 #       do openlog($program,'cons,pid','user');
  19 #       do syslog('info','this is another test');
  20 #       do syslog('mail|warning','this is a better test: %d', time);
  21 #       do closelog();
  22 #
  23 #       do syslog('debug','this is the last test');
  24 #       do openlog("$program $$",'ndelay','user');
  25 #       do syslog('notice','fooprogram: this is really done');
  26 #
  27 #       $! = 55;
  28 #       do syslog('info','problem was %m'); # %m == $! in syslog(3)
  29
  30 package syslog;
  31
  32 $host = 'localhost' unless $host;       # set $syslog'host to change
  33
  34 require 'syslog.ph';
  35
  36 $maskpri = &LOG_UPTO(&LOG_DEBUG);
  37
  38 sub main'openlog {
  39     ($ident, $logopt, $facility) = @_;  # package vars
  40     $lo_pid = $logopt =~ /\bpid\b/;
  41     $lo_ndelay = $logopt =~ /\bndelay\b/;
  42     $lo_cons = $logopt =~ /\bcons\b/;
  43     $lo_nowait = $logopt =~ /\bnowait\b/;
  44     &connect if $lo_ndelay;
  45 }
  46
  47 sub main'closelog {
  48     $facility = $ident = '';
  49     &disconnect;
  50 }
  51
  52 sub main'setlogmask {
  53     local($oldmask) = $maskpri;
  54     $maskpri = shift;
  55     $oldmask;
  56 }
  57
  58 sub main'syslog {
  59     local($priority) = shift;
  60     local($mask) = shift;
  61     local($message, $whoami);
  62     local(@words, $num, $numpri, $numfac, $sum);
  63     local($facility) = $facility;       # may need to change temporarily.
  64
  65     die "syslog: expected both priority and mask" unless $mask && $priority;
  66
  67     @words = split(/\W+/, $priority, 2);# Allow "level" or "level|facility".
  68     undef $numpri;
  69     undef $numfac;
  70     foreach (@words) {
  71         $num = &xlate($_);              # Translate word to number.
  72         if (/^kern$/ || $num < 0) {
  73             die "syslog: invalid level/facility: $_\n";
  74         }
  75         elsif ($num <= &LOG_PRIMASK) {
  76             die "syslog: too many levels given: $_\n" if defined($numpri);
  77             $numpri = $num;
  78             return 0 unless &LOG_MASK($numpri) & $maskpri;
  79         }
  80         else {
  81             die "syslog: too many facilities given: $_\n" if defined($numfac);
  82             $facility = $_;
  83             $numfac = $num;
  84         }
  85     }
  86
  87     die "syslog: level must be given\n" unless defined($numpri);
  88
  89     if (!defined($numfac)) {    # Facility not specified in this call.
  90         $facility = 'user' unless $facility;
  91         $numfac = &xlate($facility);
  92     }
  93
  94     &connect unless $connected;
  95
  96     $whoami = $ident;
  97
  98     if (!$ident && $mask =~ /^(\S.*):\s?(.*)/) {
  99         $whoami = $1;
 100         $mask = $2;
 101     }
 102
 103     unless ($whoami) {
 104         ($whoami = getlogin) ||
 105             ($whoami = getpwuid($<)) ||
 106                 ($whoami = 'syslog');
 107     }
 108
 109     $whoami .= "[$$]" if $lo_pid;
 110
 111     $mask =~ s/%m/$!/g;
 112     $mask .= "\n" unless $mask =~ /\n$/;
 113     $message = sprintf ($mask, @_);
 114
 115     $sum = $numpri + $numfac;
 116     unless (send(SYSLOG,"<$sum>$whoami: $message",0)) {
 117         if ($lo_cons) {
 118             if ($pid = fork) {
 119                 unless ($lo_nowait) {
 120                     do {$died = wait;} until $died == $pid || $died < 0;
 121                 }
 122             }
 123             else {
 124                 open(CONS,">/dev/console");
 125                 print CONS "<$facility.$priority>$whoami: $message\r";
 126                 exit if defined $pid;           # if fork failed, we're parent
 127                 close CONS;
 128             }
 129         }
 130     }
 131 }
 132
 133 sub xlate {
 134     local($name) = @_;
 135     $name =~ y/a-z/A-Z/;
 136     $name = "LOG_$name" unless $name =~ /^LOG_/;
 137     $name = "syslog'$name";
 138     eval(&$name) || -1;
 139 }
 140
 141 sub connect {
 142     $pat = 'S n C4 x8';
 143
 144     $af_unix = 1;
 145     $af_inet = 2;
 146
 147     $stream = 1;
 148     $datagram = 2;
 149
 150     ($name,$aliases,$proto) = getprotobyname('udp');
 151     $udp = $proto;
 152
 153     ($name,$aliase,$port,$proto) = getservbyname('syslog','udp');
 154     $syslog = $port;
 155
 156     if (chop($myname = `hostname`)) {
 157         ($name,$aliases,$addrtype,$length,@addrs) = gethostbyname($myname);
 158         die "Can't lookup $myname\n" unless $name;
 159         @bytes = unpack("C4",$addrs[0]);
 160     }
 161     else {
 162         @bytes = (0,0,0,0);
 163     }
 164     $this = pack($pat, $af_inet, 0, @bytes);
 165
 166     if ($host =~ /^\d+\./) {
 167         @bytes = split(/\./,$host);
 168     }
 169     else {
 170         ($name,$aliases,$addrtype,$length,@addrs) = gethostbyname($host);
 171         die "Can't lookup $host\n" unless $name;
 172         @bytes = unpack("C4",$addrs[0]);
 173     }
 174     $that = pack($pat,$af_inet,$syslog,@bytes);
 175
 176     socket(SYSLOG,$af_inet,$datagram,$udp) || die "socket: $!\n";
 177     bind(SYSLOG,$this) || die "bind: $!\n";
 178     connect(SYSLOG,$that) || die "connect: $!\n";
 179
 180     local($old) = select(SYSLOG); $| = 1; select($old);
 181     $connected = 1;
 182 }
 183
 184 sub disconnect {
 185     close SYSLOG;
 186     $connected = 0;
 187 }
 188
 189 1;