lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.004004'; # 1.4.4
  11
  12 sub VERSION {
  13   for ($_[1]) {
  14     last unless defined && !ref && int != 1;
  15     die "Major version specified as $_ - this is strictures version 1";
  16   }
  17   # disable this since Foo->VERSION(undef) correctly returns the version
  18   # and that can happen either if our caller passes undef explicitly or
  19   # because the for above autovivified $_[1] - I could make it stop but
  20   # it's pointless since we don't want to blow up if the caller does
  21   # something valid either.
  22   no warnings 'uninitialized';
  23   shift->SUPER::VERSION(@_);
  24 }
  25
  26 our $extra_load_states;
  27
  28 our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  29   || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));
  30
  31 sub import {
  32   strict->import;
  33   warnings->import(FATAL => 'all');
  34
  35   my $extra_tests = do {
  36     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  37       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  38         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  39           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  40       }
  41       $ENV{PERL_STRICTURES_EXTRA};
  42     } elsif (! _PERL_LT_5_8_4) {
  43       !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
  44          and $Smells_Like_VCS)
  45     }
  46   };
  47   if ($extra_tests) {
  48     $extra_load_states ||= do {
  49
  50       my (%rv, @failed);
  51       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  52         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  53           push @failed, $mod;
  54
  55           # courtesy of the 5.8 require bug
  56           # (we do a copy because 5.16.2 at least uses the same read-only
  57           # scalars for the qw() list and it doesn't seem worth a $^V check)
  58
  59           (my $file = $mod) =~ s|::|/|g;
  60           delete $INC{"${file}.pm"};
  61         };
  62       }
  63
  64       if (@failed) {
  65         my $failed = join ' ', @failed;
  66         print STDERR <<EOE;
  67 strictures.pm extra testing active but couldn't load all modules. Missing were:
  68
  69   $failed
  70
  71 Extra testing is auto-enabled in checkouts only, so if you're the author
  72 of a strictures-using module you need to run:
  73
  74   cpan indirect multidimensional bareword::filehandles
  75
  76 but these modules are not required by your users.
  77 EOE
  78       }
  79
  80       \%rv;
  81     };
  82
  83     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  84     multidimensional->unimport if $extra_load_states->{multidimensional};
  85     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  86   }
  87 }
  88
  89 1;
  90
  91 __END__
  92 =head1 NAME
  93
  94 strictures - turn on strict and make all warnings fatal
  95
  96 =head1 SYNOPSIS
  97
  98   use strictures 1;
  99
 100 is equivalent to
 101
 102   use strict;
 103   use warnings FATAL => 'all';
 104
 105 except when called from a file which matches:
 106
 107   (caller)[1] =~ /^(?:t|xt|lib|blib)/
 108
 109 and when either C<.git> or C<.svn> is present in the current directory (with
 110 the intention of only forcing extra tests on the author side) -- or when C<.git>
 111 or C<.svn> is present two directories up along with C<dist.ini> (which would
 112 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 113 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 114
 115   use strictures 1;
 116
 117 is equivalent to
 118
 119   use strict;
 120   use warnings FATAL => 'all';
 121   no indirect 'fatal';
 122   no multidimensional;
 123   no bareword::filehandles;
 124
 125 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 126 version increase, but any changes to the effect of C<use strictures> in
 127 normal mode will involve a major version bump.
 128
 129 If any of the extra testing modules are not present, L<strictures> will
 130 complain loudly, once, via C<warn()>, and then shut up. But you really
 131 should consider installing them, they're all great anti-footgun tools.
 132
 133 =head1 DESCRIPTION
 134
 135 I've been writing the equivalent of this module at the top of my code for
 136 about a year now. I figured it was time to make it shorter.
 137
 138 Things like the importer in C<use Moose> don't help me because they turn
 139 warnings on but don't make them fatal -- which from my point of view is
 140 useless because I want an exception to tell me my code isn't warnings-clean.
 141
 142 Any time I see a warning from my code, that indicates a mistake.
 143
 144 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 145 and then unknown (and probably undesired) subsequent behaviour.
 146
 147 I also want to ensure that obvious coding mistakes, like indirect object
 148 syntax (and not so obvious mistakes that cause things to accidentally compile
 149 as such) get caught, but not at the cost of an XS dependency and not at the
 150 cost of blowing things up on another machine.
 151
 152 Therefore, L<strictures> turns on additional checking, but only when it thinks
 153 it's running in a test file in a VCS checkout -- although if this causes
 154 undesired behaviour this can be overridden by setting the
 155 C<PERL_STRICTURES_EXTRA> environment variable.
 156
 157 If additional useful author side checks come to mind, I'll add them to the
 158 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 159 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 160 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 161 (1.0.1)).
 162
 163 If the behaviour of C<use strictures> in normal mode changes in any way, that
 164 will constitute a major version increase -- and the code already checks
 165 when its version is tested to ensure that
 166
 167   use strictures 1;
 168
 169 will continue to only introduce the current set of strictures even if 2.0 is
 170 installed.
 171
 172 =head1 METHODS
 173
 174 =head2 import
 175
 176 This method does the setup work described above in L</DESCRIPTION>
 177
 178 =head2 VERSION
 179
 180 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 181 with a version number on it and does the version check.
 182
 183 =head1 EXTRA TESTING RATIONALE
 184
 185 Every so often, somebody complains that they're deploying via C<git pull>
 186 and that they don't want L<strictures> to enable itself in this case -- and that
 187 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 188 disable extra testing would be welcome but the discussion never seems to get
 189 that far).
 190
 191 In order to allow us to skip a couple of stages and get straight to a
 192 productive conversation, here's my current rationale for turning the
 193 extra testing on via a heuristic:
 194
 195 The extra testing is all stuff that only ever blows up at compile time;
 196 this is intentional. So the oft-raised concern that it's different code being
 197 tested is only sort of the case -- none of the modules involved affect the
 198 final optree to my knowledge, so the author gets some additional compile
 199 time crashes which he/she then fixes, and the rest of the testing is
 200 completely valid for all environments.
 201
 202 The point of the extra testing -- especially C<no indirect> -- is to catch
 203 mistakes that newbie users won't even realise are mistakes without
 204 help. For example,
 205
 206   foo { ... };
 207
 208 where foo is an & prototyped sub that you forgot to import -- this is
 209 pernicious to track down since all I<seems> fine until it gets called
 210 and you get a crash. Worse still, you can fail to have imported it due
 211 to a circular require, at which point you have a load order dependent
 212 bug which I've seen before now I<only> show up in production due to tiny
 213 differences between the production and the development environment. I wrote
 214 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 215 this particular problem before L<strictures> itself existed.
 216
 217 As such, in my experience so far L<strictures>' extra testing has
 218 I<avoided> production versus development differences, not caused them.
 219
 220 Additionally, L<strictures>' policy is very much "try and provide as much
 221 protection as possible for newbies -- who won't think about whether there's
 222 an option to turn on or not" -- so having only the environment variable
 223 is not sufficient to achieve that (I get to explain that you need to add
 224 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 225 completely skip steps because they don't understand that that step
 226 is important).
 227
 228 I make no claims that the heuristic is perfect -- it's already been evolved
 229 significantly over time, especially for 1.004 where we changed things to
 230 ensure it only fires on files in your checkout (rather than L<strictures>-using
 231 modules you happened to have installed, which was just silly). However, I
 232 hope the above clarifies why a heuristic approach is not only necessary but
 233 desirable from a point of view of providing new users with as much safety as possible,
 234 and will allow any future discussion on the subject to focus on "how do we
 235 minimise annoyance to people deploying from checkouts intentionally".
 236
 237 =head1 COMMUNITY AND SUPPORT
 238
 239 =head2 IRC channel
 240
 241 irc.perl.org #toolchain
 242
 243 (or bug 'mst' in query on there or freenode)
 244
 245 =head2 Git repository
 246
 247 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 248
 249   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 250
 251 The web interface to the repository is at:
 252
 253   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 254
 255 =head1 AUTHOR
 256
 257 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 258
 259 =head1 CONTRIBUTORS
 260
 261 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 262
 263 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 264
 265 =head1 COPYRIGHT
 266
 267 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 268 as listed above.
 269
 270 =head1 LICENSE
 271
 272 This library is free software and may be distributed under the same terms
 273 as perl itself.
 274
 275 =cut