lib/sigtrap.t

   1 #!./perl
   2
   3 BEGIN {
   4         chdir 't' if -d 't';
   5         @INC = '../lib';
   6 }
   7
   8 use strict;
   9 use Config;
  10
  11 my $can_catch_kill = 0;
  12
  13 use Test::More tests => 18;
  14
  15 use_ok( 'sigtrap' );
  16
  17 package main;
  18 local %SIG;
  19
  20 # use a version of sigtrap.pm somewhat too high
  21 eval{ sigtrap->import(99999) };
  22 like( $@, qr/version 99999 required,/, 'import excessive version number' );
  23
  24 # use an invalid signal name
  25 eval{ sigtrap->import('abadsignal') };
  26 like( $@, qr/^Unrecognized argument abadsignal/, 'send bad signame to import' );
  27
  28 eval{ sigtrap->import('handler') };
  29 like( $@, qr/^No argument specified/, 'send handler without subref' );
  30
  31 sigtrap->import('AFAKE');
  32 is( $SIG{AFAKE}, \&sigtrap::handler_traceback, 'install normal handler' );
  33
  34 sigtrap->import('die', 'AFAKE', 'stack-trace', 'FAKE2');
  35 is( $SIG{AFAKE}, \&sigtrap::handler_die, 'install the die handler' );
  36 is( $SIG{FAKE2}, \&sigtrap::handler_traceback, 'install traceback handler' );
  37
  38 my @normal = qw( HUP INT PIPE TERM );
  39 @SIG{@normal} = 1 x @normal;
  40 sigtrap->import('normal-signals');
  41 is( (grep { ref $_ } @SIG{@normal}), @normal, 'check normal-signals set' );
  42
  43 my @error = qw( ABRT BUS EMT FPE ILL QUIT SEGV SYS TRAP );
  44 @SIG{@error} = 1 x @error;
  45 sigtrap->import('error-signals');
  46 is( (grep { ref $_ } @SIG{@error}), @error, 'check error-signals set' );
  47
  48 my @old = qw( ABRT BUS EMT FPE ILL PIPE QUIT SEGV SYS TERM TRAP );
  49 @SIG{@old} = 1 x @old;
  50 sigtrap->import('old-interface-signals');
  51 is( (grep { ref $_ } @SIG{@old}), @old, 'check old-interface-signals set' );
  52
  53 my $handler = sub {};
  54 sigtrap->import(handler => $handler, 'FAKE3');
  55 is( $SIG{FAKE3}, $handler, 'install custom handler' );
  56
  57 $SIG{FAKE} = 'IGNORE';
  58 sigtrap->import('untrapped', 'FAKE');
  59 is( $SIG{FAKE}, 'IGNORE', 'respect existing handler set to IGNORE' );
  60
  61 my $out = tie *STDOUT, 'TieOut';
  62 $SIG{FAKE} = 'DEFAULT';
  63 $sigtrap::Verbose = 1;
  64 sigtrap->import('any', 'FAKE');
  65 is( $SIG{FAKE}, \&sigtrap::handler_traceback, 'should set default handler' );
  66 like( $out->read, qr/^Installing handler/, 'does it talk with $Verbose set?' );
  67
  68 # handler_die croaks with first argument
  69 eval { sigtrap::handler_die('FAKE') };
  70 like( $@, qr/^Caught a SIGFAKE/, 'does handler_die() croak?' );
  71
  72 SKIP: {
  73         skip( 'kill not implemented', 3) unless $can_catch_kill and
  74                 $Config{sig_name} =~ 'ABRT';
  75
  76         $out = tie *STDERR, 'TieOut';
  77         my $line = __LINE__ + 1;
  78         eval { sigtrap::handler_traceback('kudra') };
  79         is( $@, '', 'handler_traceback() should not die' );
  80         my $trace = $out->read();
  81         like( $trace, qr/^Caught a SIGkudra/, 'check traceback message' );
  82         like( $trace, qr/eval.+sigtrap.t.+$line/, 'check trace in traceback' );
  83 } # end of SKIP
  84
  85 package TieOut;
  86
  87 sub TIEHANDLE {
  88         bless(\(my $scalar), $_[0]);
  89 }
  90
  91 sub PRINT {
  92         my $self = shift;
  93         $$self .= join '', @_;
  94 }
  95
  96 sub WRITE {
  97         my ($self, $msg, $length) = @_;
  98         $$self .= $msg;
  99 }
 100
 101 sub read {
 102         my $self = shift;
 103         substr($$self, 0, length($$self), '');
 104 }