lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 if false, a dummy ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =item * HistFile
 241
 242 file to store session history to. There is no default and so no
 243 history file is written unless this variable is explicitly set.
 244
 245 =item * HistSize
 246
 247 number of commands to store to the file specified in C<HistFile>.
 248 Default is 100.
 249
 250 =back
 251
 252 =head3 SAMPLE RCFILE
 253
 254  &parse_options("NonStop=1 LineInfo=db.out");
 255   sub afterinit { $trace = 1; }
 256
 257 The script will run without human intervention, putting trace
 258 information into C<db.out>.  (If you interrupt it, you had better
 259 reset C<LineInfo> to something I<interactive>!)
 260
 261 =head1 INTERNALS DESCRIPTION
 262
 263 =head2 DEBUGGER INTERFACE VARIABLES
 264
 265 Perl supplies the values for C<%sub>.  It effectively inserts
 266 a C<&DB::DB();> in front of each place that can have a
 267 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 268 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 269 {require 'perl5db.pl'}> before the first line.
 270
 271 After each C<require>d file is compiled, but before it is executed, a
 272 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 273 is the expanded name of the C<require>d file (as found via C<%INC>).
 274
 275 =head3 IMPORTANT INTERNAL VARIABLES
 276
 277 =head4 C<$CreateTTY>
 278
 279 Used to control when the debugger will attempt to acquire another TTY to be
 280 used for input.
 281
 282 =over
 283
 284 =item * 1 -  on C<fork()>
 285
 286 =item * 2 - debugger is started inside debugger
 287
 288 =item * 4 -  on startup
 289
 290 =back
 291
 292 =head4 C<$doret>
 293
 294 The value -2 indicates that no return value should be printed.
 295 Any other positive value causes C<DB::sub> to print return values.
 296
 297 =head4 C<$evalarg>
 298
 299 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 300 contents of C<@_> when C<DB::eval> is called.
 301
 302 =head4 C<$frame>
 303
 304 Determines what messages (if any) will get printed when a subroutine (or eval)
 305 is entered or exited.
 306
 307 =over 4
 308
 309 =item * 0 -  No enter/exit messages
 310
 311 =item * 1 - Print I<entering> messages on subroutine entry
 312
 313 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 314
 315 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 316
 317 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 318
 319 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 320
 321 =back
 322
 323 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 324 The debugger internally juggles the value of C<$frame> during execution to
 325 protect external modules that the debugger uses from getting traced.
 326
 327 =head4 C<$level>
 328
 329 Tracks current debugger nesting level. Used to figure out how many
 330 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 331 outputs a prompt. Also used to help determine if the program has finished
 332 during command parsing.
 333
 334 =head4 C<$onetimeDump>
 335
 336 Controls what (if anything) C<DB::eval()> will print after evaluating an
 337 expression.
 338
 339 =over 4
 340
 341 =item * C<undef> - don't print anything
 342
 343 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 344
 345 =item * C<methods> - print the methods callable on the first item returned
 346
 347 =back
 348
 349 =head4 C<$onetimeDumpDepth>
 350
 351 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 352 dumping a structure. Numeric. If C<undef>, print all levels.
 353
 354 =head4 C<$signal>
 355
 356 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 357 which is called before every statement, checks this and puts the user into
 358 command mode if it finds C<$signal> set to a true value.
 359
 360 =head4 C<$single>
 361
 362 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 363 each subroutine; popped again at the end of each subroutine.
 364
 365 =over 4
 366
 367 =item * 0 - run continuously.
 368
 369 =item * 1 - single-step, go into subs. The C<s> command.
 370
 371 =item * 2 - single-step, don't go into subs. The C<n> command.
 372
 373 =item * 4 - print current sub depth (turned on to force this when C<too much
 374 recursion> occurs.
 375
 376 =back
 377
 378 =head4 C<$trace>
 379
 380 Controls the output of trace information.
 381
 382 =over 4
 383
 384 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 385
 386 =item * 2 - watch expressions are active
 387
 388 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 389
 390 =back
 391
 392 =head4 C<$slave_editor>
 393
 394 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 395
 396 =head4 C<@cmdfhs>
 397
 398 Stack of filehandles that C<DB::readline()> will read commands from.
 399 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 400
 401 =head4 C<@dbline>
 402
 403 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 404 supplied by the Perl interpreter to the debugger. Contains the source.
 405
 406 =head4 C<@old_watch>
 407
 408 Previous values of watch expressions. First set when the expression is
 409 entered; reset whenever the watch expression changes.
 410
 411 =head4 C<@saved>
 412
 413 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 414 so that the debugger can substitute safe values while it's running, and
 415 restore them when it returns control.
 416
 417 =head4 C<@stack>
 418
 419 Saves the current value of C<$single> on entry to a subroutine.
 420 Manipulated by the C<c> command to turn off tracing in all subs above the
 421 current one.
 422
 423 =head4 C<@to_watch>
 424
 425 The 'watch' expressions: to be evaluated before each line is executed.
 426
 427 =head4 C<@typeahead>
 428
 429 The typeahead buffer, used by C<DB::readline>.
 430
 431 =head4 C<%alias>
 432
 433 Command aliases. Stored as character strings to be substituted for a command
 434 entered.
 435
 436 =head4 C<%break_on_load>
 437
 438 Keys are file names, values are 1 (break when this file is loaded) or undef
 439 (don't break when it is loaded).
 440
 441 =head4 C<%dbline>
 442
 443 Keys are line numbers, values are C<condition\0action>. If used in numeric
 444 context, values are 0 if not breakable, 1 if breakable, no matter what is
 445 in the actual hash entry.
 446
 447 =head4 C<%had_breakpoints>
 448
 449 Keys are file names; values are bitfields:
 450
 451 =over 4
 452
 453 =item * 1 - file has a breakpoint in it.
 454
 455 =item * 2 - file has an action in it.
 456
 457 =back
 458
 459 A zero or undefined value means this file has neither.
 460
 461 =head4 C<%option>
 462
 463 Stores the debugger options. These are character string values.
 464
 465 =head4 C<%postponed>
 466
 467 Saves breakpoints for code that hasn't been compiled yet.
 468 Keys are subroutine names, values are:
 469
 470 =over 4
 471
 472 =item * C<compile> - break when this sub is compiled
 473
 474 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 475
 476 =back
 477
 478 =head4 C<%postponed_file>
 479
 480 This hash keeps track of breakpoints that need to be set for files that have
 481 not yet been compiled. Keys are filenames; values are references to hashes.
 482 Each of these hashes is keyed by line number, and its values are breakpoint
 483 definitions (C<condition\0action>).
 484
 485 =head1 DEBUGGER INITIALIZATION
 486
 487 The debugger's initialization actually jumps all over the place inside this
 488 package. This is because there are several BEGIN blocks (which of course
 489 execute immediately) spread through the code. Why is that?
 490
 491 The debugger needs to be able to change some things and set some things up
 492 before the debugger code is compiled; most notably, the C<$deep> variable that
 493 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 494 debugger has to turn off warnings while the debugger code is compiled, but then
 495 restore them to their original setting before the program being debugged begins
 496 executing.
 497
 498 The first C<BEGIN> block simply turns off warnings by saving the current
 499 setting of C<$^W> and then setting it to zero. The second one initializes
 500 the debugger variables that are needed before the debugger begins executing.
 501 The third one puts C<$^X> back to its former value.
 502
 503 We'll detail the second C<BEGIN> block later; just remember that if you need
 504 to initialize something before the debugger starts really executing, that's
 505 where it has to go.
 506
 507 =cut
 508
 509 package DB;
 510
 511 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 512
 513 # Debugger for Perl 5.00x; perl5db.pl patch level:
 514 $VERSION = '1.33';
 515
 516 $header = "perl5db.pl version $VERSION";
 517
 518 =head1 DEBUGGER ROUTINES
 519
 520 =head2 C<DB::eval()>
 521
 522 This function replaces straight C<eval()> inside the debugger; it simplifies
 523 the process of evaluating code in the user's context.
 524
 525 The code to be evaluated is passed via the package global variable
 526 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 527
 528 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 529 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 530 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 531 user's current package, grabbed when C<DB::DB> got control.  This causes the
 532 proper context to be used when the eval is actually done.  Afterward, we
 533 restore C<$trace>, C<$single>, and C<$^D>.
 534
 535 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 536 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 537 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 538 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 539 considered sane by the debugger. If there was an C<eval()> error, we print
 540 it on the debugger's output. If C<$onetimedump> is defined, we call
 541 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 542 'methods'. Setting it to something else causes the debugger to do the eval
 543 but not print the result - handy if you want to do something else with it
 544 (the "watch expressions" code does this to get the value of the watch
 545 expression but not show it unless it matters).
 546
 547 In any case, we then return the list of output from C<eval> to the caller,
 548 and unwinding restores the former version of C<$@> in C<@saved> as well
 549 (the localization of C<$saved[0]> goes away at the end of this scope).
 550
 551 =head3 Parameters and variables influencing execution of DB::eval()
 552
 553 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 554 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 555 The variables listed below influence C<DB::eval()>'s execution directly.
 556
 557 =over 4
 558
 559 =item C<$evalarg> - the thing to actually be eval'ed
 560
 561 =item C<$trace> - Current state of execution tracing
 562
 563 =item C<$single> - Current state of single-stepping
 564
 565 =item C<$onetimeDump> - what is to be displayed after the evaluation
 566
 567 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 568
 569 =back
 570
 571 The following variables are altered by C<DB::eval()> during its execution. They
 572 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 573
 574 =over 4
 575
 576 =item C<@res> - used to capture output from actual C<eval>.
 577
 578 =item C<$otrace> - saved value of C<$trace>.
 579
 580 =item C<$osingle> - saved value of C<$single>.
 581
 582 =item C<$od> - saved value of C<$^D>.
 583
 584 =item C<$saved[0]> - saved value of C<$@>.
 585
 586 =item $\ - for output of C<$@> if there is an evaluation error.
 587
 588 =back
 589
 590 =head3 The problem of lexicals
 591
 592 The context of C<DB::eval()> presents us with some problems. Obviously,
 593 we want to be 'sandboxed' away from the debugger's internals when we do
 594 the eval, but we need some way to control how punctuation variables and
 595 debugger globals are used.
 596
 597 We can't use local, because the code inside C<DB::eval> can see localized
 598 variables; and we can't use C<my> either for the same reason. The code
 599 in this routine compromises and uses C<my>.
 600
 601 After this routine is over, we don't have user code executing in the debugger's
 602 context, so we can use C<my> freely.
 603
 604 =cut
 605
 606 ############################################## Begin lexical danger zone
 607
 608 # 'my' variables used here could leak into (that is, be visible in)
 609 # the context that the code being evaluated is executing in. This means that
 610 # the code could modify the debugger's variables.
 611 #
 612 # Fiddling with the debugger's context could be Bad. We insulate things as
 613 # much as we can.
 614
 615 sub eval {
 616
 617     # 'my' would make it visible from user code
 618     #    but so does local! --tchrist
 619     # Remember: this localizes @DB::res, not @main::res.
 620     local @res;
 621     {
 622
 623         # Try to keep the user code from messing  with us. Save these so that
 624         # even if the eval'ed code changes them, we can put them back again.
 625         # Needed because the user could refer directly to the debugger's
 626         # package globals (and any 'my' variables in this containing scope)
 627         # inside the eval(), and we want to try to stay safe.
 628         local $otrace  = $trace;
 629         local $osingle = $single;
 630         local $od      = $^D;
 631
 632         # Untaint the incoming eval() argument.
 633         { ($evalarg) = $evalarg =~ /(.*)/s; }
 634
 635         # $usercontext built in DB::DB near the comment
 636         # "set up the context for DB::eval ..."
 637         # Evaluate and save any results.
 638         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 639
 640         # Restore those old values.
 641         $trace  = $otrace;
 642         $single = $osingle;
 643         $^D     = $od;
 644     }
 645
 646     # Save the current value of $@, and preserve it in the debugger's copy
 647     # of the saved precious globals.
 648     my $at = $@;
 649
 650     # Since we're only saving $@, we only have to localize the array element
 651     # that it will be stored in.
 652     local $saved[0];    # Preserve the old value of $@
 653     eval { &DB::save };
 654
 655     # Now see whether we need to report an error back to the user.
 656     if ($at) {
 657         local $\ = '';
 658         print $OUT $at;
 659     }
 660
 661     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 662     # are package globals.
 663     elsif ($onetimeDump) {
 664         if ( $onetimeDump eq 'dump' ) {
 665             local $option{dumpDepth} = $onetimedumpDepth
 666               if defined $onetimedumpDepth;
 667             dumpit( $OUT, \@res );
 668         }
 669         elsif ( $onetimeDump eq 'methods' ) {
 670             methods( $res[0] );
 671         }
 672     } ## end elsif ($onetimeDump)
 673     @res;
 674 } ## end sub eval
 675
 676 ############################################## End lexical danger zone
 677
 678 # After this point it is safe to introduce lexicals.
 679 # The code being debugged will be executing in its own context, and
 680 # can't see the inside of the debugger.
 681 #
 682 # However, one should not overdo it: leave as much control from outside as
 683 # possible. If you make something a lexical, it's not going to be addressable
 684 # from outside the debugger even if you know its name.
 685
 686 # This file is automatically included if you do perl -d.
 687 # It's probably not useful to include this yourself.
 688 #
 689 # Before venturing further into these twisty passages, it is
 690 # wise to read the perldebguts man page or risk the ire of dragons.
 691 #
 692 # (It should be noted that perldebguts will tell you a lot about
 693 # the underlying mechanics of how the debugger interfaces into the
 694 # Perl interpreter, but not a lot about the debugger itself. The new
 695 # comments in this code try to address this problem.)
 696
 697 # Note that no subroutine call is possible until &DB::sub is defined
 698 # (for subroutines defined outside of the package DB). In fact the same is
 699 # true if $deep is not defined.
 700
 701 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 702
 703 # modified Perl debugger, to be run from Emacs in perldb-mode
 704 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 705 # Johan Vromans -- upgrade to 4.0 pl 10
 706 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 707
 708 # (We have made efforts to  clarify the comments in the change log
 709 # in other places; some of them may seem somewhat obscure as they
 710 # were originally written, and explaining them away from the code
 711 # in question seems conterproductive.. -JM)
 712
 713 ########################################################################
 714 # Changes: 0.94
 715 #   + A lot of things changed after 0.94. First of all, core now informs
 716 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 717 #     BEGIN and END. Handy with `O f=2'.
 718 #   + This can make debugger a little bit too verbose, please be patient
 719 #     and report your problems promptly.
 720 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 721 #   + Note that if DESTROY returns a reference to the object (or object),
 722 #     the deletion of data may be postponed until the next function call,
 723 #     due to the need to examine the return value.
 724 #
 725 # Changes: 0.95
 726 #   + `v' command shows versions.
 727 #
 728 # Changes: 0.96
 729 #   + `v' command shows version of readline.
 730 #     primitive completion works (dynamic variables, subs for `b' and `l',
 731 #     options). Can `p %var'
 732 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 733 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 734 #   + `c sub' documented.
 735 #   + At last enough magic combined to stop after the end of debuggee.
 736 #   + !! should work now (thanks to Emacs bracket matching an extra
 737 #     `]' in a regexp is caught).
 738 #   + `L', `D' and `A' span files now (as documented).
 739 #   + Breakpoints in `require'd code are possible (used in `R').
 740 #   +  Some additional words on internal work of debugger.
 741 #   + `b load filename' implemented.
 742 #   + `b postpone subr' implemented.
 743 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 744 #   + When restarting debugger breakpoints/actions persist.
 745 #   + Buglet: When restarting debugger only one breakpoint/action per
 746 #             autoloaded function persists.
 747 #
 748 # Changes: 0.97: NonStop will not stop in at_exit().
 749 #   + Option AutoTrace implemented.
 750 #   + Trace printed differently if frames are printed too.
 751 #   + new `inhibitExit' option.
 752 #   + printing of a very long statement interruptible.
 753 # Changes: 0.98: New command `m' for printing possible methods
 754 #   + 'l -' is a synonym for `-'.
 755 #   + Cosmetic bugs in printing stack trace.
 756 #   +  `frame' & 8 to print "expanded args" in stack trace.
 757 #   + Can list/break in imported subs.
 758 #   + new `maxTraceLen' option.
 759 #   + frame & 4 and frame & 8 granted.
 760 #   + new command `m'
 761 #   + nonstoppable lines do not have `:' near the line number.
 762 #   + `b compile subname' implemented.
 763 #   + Will not use $` any more.
 764 #   + `-' behaves sane now.
 765 # Changes: 0.99: Completion for `f', `m'.
 766 #   +  `m' will remove duplicate names instead of duplicate functions.
 767 #   + `b load' strips trailing whitespace.
 768 #     completion ignores leading `|'; takes into account current package
 769 #     when completing a subroutine name (same for `l').
 770 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 771 #   BUG FIXES:
 772 #   + Added bare minimal security checks on perldb rc files, plus
 773 #     comments on what else is needed.
 774 #   + Fixed the ornaments that made "|h" completely unusable.
 775 #     They are not used in print_help if they will hurt.  Strip pod
 776 #     if we're paging to less.
 777 #   + Fixed mis-formatting of help messages caused by ornaments
 778 #     to restore Larry's original formatting.
 779 #   + Fixed many other formatting errors.  The code is still suboptimal,
 780 #     and needs a lot of work at restructuring.  It's also misindented
 781 #     in many places.
 782 #   + Fixed bug where trying to look at an option like your pager
 783 #     shows "1".
 784 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 785 #     lose.  You should consider shell escapes not using their shell,
 786 #     or else not caring about detailed status.  This should really be
 787 #     unified into one place, too.
 788 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 789 #     tricking Perl into thinking you weren't calling a debugger command!
 790 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 791 #     suggests a leading semicolon or any other irrelevant non-whitespace
 792 #     to indicate literal Perl code.)
 793 #   + Fixed bugs that ate warnings due to wrong selected handle.
 794 #   + Fixed a precedence bug on signal stuff.
 795 #   + Fixed some unseemly wording.
 796 #   + Fixed bug in help command trying to call perl method code.
 797 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 798 #   ENHANCEMENTS:
 799 #   + Added some comments.  This code is still nasty spaghetti.
 800 #   + Added message if you clear your pre/post command stacks which was
 801 #     very easy to do if you just typed a bare >, <, or {.  (A command
 802 #     without an argument should *never* be a destructive action; this
 803 #     API is fundamentally screwed up; likewise option setting, which
 804 #     is equally buggered.)
 805 #   + Added command stack dump on argument of "?" for >, <, or {.
 806 #   + Added a semi-built-in doc viewer command that calls man with the
 807 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 808 #     or else perldoc on obstreperous platforms.
 809 #   + Added to and rearranged the help information.
 810 #   + Detected apparent misuse of { ... } to declare a block; this used
 811 #     to work but now is a command, and mysteriously gave no complaint.
 812 #
 813 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 814 #   BUG FIX:
 815 #   + This patch to perl5db.pl cleans up formatting issues on the help
 816 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 817 #     issues, plus converted the printed text to use all spaces, since
 818 #     tabs don't seem to help much here.
 819 #
 820 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 821 #   Minor bugs corrected;
 822 #   + Support for auto-creation of new TTY window on startup, either
 823 #     unconditionally, or if started as a kid of another debugger session;
 824 #   + New `O'ption CreateTTY
 825 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 826 #                         1: on fork()
 827 #                         2: debugger is started inside debugger
 828 #                         4: on startup
 829 #   + Code to auto-create a new TTY window on OS/2 (currently one
 830 #     extra window per session - need named pipes to have more...);
 831 #   + Simplified interface for custom createTTY functions (with a backward
 832 #     compatibility hack); now returns the TTY name to use; return of ''
 833 #     means that the function reset the I/O handles itself;
 834 #   + Better message on the semantic of custom createTTY function;
 835 #   + Convert the existing code to create a TTY into a custom createTTY
 836 #     function;
 837 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 838 #   + Switch line-tracing output too to the created TTY window;
 839 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 840 #   + High-level debugger API cmd_*():
 841 #      cmd_b_load($filenamepart)            # b load filenamepart
 842 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 843 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 844 #      cmd_stop()                           # Control-C
 845 #      cmd_d($lineno)                       # d lineno (B)
 846 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 847 #      the error message to the debugging output.
 848 #   + Low-level debugger API
 849 #      break_on_load($filename)             # b load filename
 850 #      @files = report_break_on_load()      # List files with load-breakpoints
 851 #      breakable_line_in_filename($name, $from [, $to])
 852 #                                           # First breakable line in the
 853 #                                           # range $from .. $to.  $to defaults
 854 #                                           # to $from, and may be less than
 855 #                                           # $to
 856 #      breakable_line($from [, $to])        # Same for the current file
 857 #      break_on_filename_line($name, $lineno [, $cond])
 858 #                                           # Set breakpoint,$cond defaults to
 859 #                                           # 1
 860 #      break_on_filename_line_range($name, $from, $to [, $cond])
 861 #                                           # As above, on the first
 862 #                                           # breakable line in range
 863 #      break_on_line($lineno [, $cond])     # As above, in the current file
 864 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 865 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 866 #                                           # The range of lines of the text
 867 #      The low-level API returns TRUE on success, and die()s on failure.
 868 #
 869 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 870 #   BUG FIXES:
 871 #   + Fixed warnings generated by "perl -dWe 42"
 872 #   + Corrected spelling errors
 873 #   + Squeezed Help (h) output into 80 columns
 874 #
 875 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 876 #   + Made "x @INC" work like it used to
 877 #
 878 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 879 #   + Fixed warnings generated by "O" (Show debugger options)
 880 #   + Fixed warnings generated by "p 42" (Print expression)
 881 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 882 #   + Added windowSize option
 883 # Changes: 1.14: Oct  9, 2001 multiple
 884 #   + Clean up after itself on VMS (Charles Lane in 12385)
 885 #   + Adding "@ file" syntax (Peter Scott in 12014)
 886 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 887 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 888 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 889 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 890 #   + Updated 1.14 change log
 891 #   + Added *dbline explainatory comments
 892 #   + Mentioning perldebguts man page
 893 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 894 #   + $onetimeDump improvements
 895 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 896 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 897 #   rationalised the following commands and added cmd_wrapper() to
 898 #   enable switching between old and frighteningly consistent new
 899 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 900 #     a(add),       A(del)            # action expr   (added del by line)
 901 #   + b(add),       B(del)            # break  [line] (was b,D)
 902 #   + w(add),       W(del)            # watch  expr   (was W,W)
 903 #                                     # added del by expr
 904 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 905 #   + m(methods),   M(modules)        # ...           (was m,v)
 906 #   + o(option)                       # lc            (was O)
 907 #   + v(view code), V(view Variables) # ...           (was w,V)
 908 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 909 #   + fixed missing cmd_O bug
 910 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 911 #   + Added missing local()s -- DB::DB is called recursively.
 912 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 913 #   + pre'n'post commands no longer trashed with no args
 914 #   + watch val joined out of eval()
 915 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 916 #   + Added comments and reformatted source. No bug fixes/enhancements.
 917 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 918 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 919 #   + Flush stdout/stderr before the debugger prompt is printed.
 920 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 921 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 922 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 923 #   + Added command to save all debugger commands for sourcing later.
 924 #   + Added command to display parent inheritance tree of given class.
 925 #   + Fixed minor newline in history bug.
 926 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 927 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 928 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + unfork the 5.8.x and 5.9.x debuggers.
 930 #   + whitespace and assertions call cleanup across versions
 931 #   + H * deletes (resets) history
 932 #   + i now handles Class + blessed objects
 933 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 934 #   + updated pod page references - clunky.
 935 #   + removed windowid restriction for forking into an xterm.
 936 #   + more whitespace again.
 937 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 938 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 939 #   + Added threads support (inc. e and E commands)
 940 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 941 #   + Added macosx_get_fork_TTY support
 942 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 943 #   + Added HistFile, HistSize
 944 # Changes: 1.31
 945 #   + Remove support for assertions and -A
 946 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
 947 #   + "update for Mac OS X 10.5" [finding the tty device]
 948 #   + "What I needed to get the forked debugger to work" [on VMS]
 949 #   + [perl #57016] debugger: o warn=0 die=0 ignored
 950 #   + Note, but don't use, PERLDBf_SAVESRC
 951 #   + Fix #7013: lvalue subs not working inside debugger
 952 # Changes: 1.32: Jun 03, 2009 Jonathan Leto <jonathan@leto.net>
 953 #   + Fix bug where a key _< with undefined value was put into the symbol table
 954 #   +   when the $filename variable is not set
 955 ########################################################################
 956
 957 =head1 DEBUGGER INITIALIZATION
 958
 959 The debugger starts up in phases.
 960
 961 =head2 BASIC SETUP
 962
 963 First, it initializes the environment it wants to run in: turning off
 964 warnings during its own compilation, defining variables which it will need
 965 to avoid warnings later, setting itself up to not exit when the program
 966 terminates, and defaulting to printing return values for the C<r> command.
 967
 968 =cut
 969
 970 # Needed for the statement after exec():
 971 #
 972 # This BEGIN block is simply used to switch off warnings during debugger
 973 # compiliation. Probably it would be better practice to fix the warnings,
 974 # but this is how it's done at the moment.
 975
 976 BEGIN {
 977     $ini_warn = $^W;
 978     $^W       = 0;
 979 }    # Switch compilation warnings off until another BEGIN.
 980
 981 local ($^W) = 0;    # Switch run-time warnings off during init.
 982
 983 =head2 THREADS SUPPORT
 984
 985 If we are running under a threaded Perl, we require threads and threads::shared
 986 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 987 threaded debugger control.  C<-dt> can also be used to set this.
 988
 989 Each new thread will be announced and the debugger prompt will always inform
 990 you of each new thread created.  It will also indicate the thread id in which
 991 we are currently running within the prompt like this:
 992
 993         [tid] DB<$i>
 994
 995 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 996 command prompt.  The prompt will show: C<[0]> when running under threads, but
 997 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 998
 999 While running under threads, when you set or delete a breakpoint (etc.), this
1000 will apply to all threads, not just the currently running one.  When you are
1001 in a currently executing thread, you will stay there until it completes.  With
1002 the current implementation it is not currently possible to hop from one thread
1003 to another.
1004
1005 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1006
1007 Note that threading support was built into the debugger as of Perl version
1008 C<5.8.6> and debugger version C<1.2.8>.
1009
1010 =cut
1011
1012 BEGIN {
1013   # ensure we can share our non-threaded variables or no-op
1014   if ($ENV{PERL5DB_THREADED}) {
1015         require threads;
1016         require threads::shared;
1017         import threads::shared qw(share);
1018         $DBGR;
1019         share(\$DBGR);
1020         lock($DBGR);
1021         print "Threads support enabled\n";
1022   } else {
1023         *lock  = sub(*) {};
1024         *share = sub(*) {};
1025   }
1026 }
1027
1028 # This would probably be better done with "use vars", but that wasn't around
1029 # when this code was originally written. (Neither was "use strict".) And on
1030 # the principle of not fiddling with something that was working, this was
1031 # left alone.
1032 warn(               # Do not ;-)
1033     # These variables control the execution of 'dumpvar.pl'.
1034     $dumpvar::hashDepth,
1035     $dumpvar::arrayDepth,
1036     $dumpvar::dumpDBFiles,
1037     $dumpvar::dumpPackages,
1038     $dumpvar::quoteHighBit,
1039     $dumpvar::printUndef,
1040     $dumpvar::globPrint,
1041     $dumpvar::usageOnly,
1042
1043     # used to save @ARGV and extract any debugger-related flags.
1044     @ARGS,
1045
1046     # used to control die() reporting in diesignal()
1047     $Carp::CarpLevel,
1048
1049     # used to prevent multiple entries to diesignal()
1050     # (if for instance diesignal() itself dies)
1051     $panic,
1052
1053     # used to prevent the debugger from running nonstop
1054     # after a restart
1055     $second_time,
1056   )
1057   if 0;
1058
1059 # without threads, $filename is not defined until DB::DB is called
1060 foreach my $k (keys (%INC)) {
1061         &share(\$main::{'_<'.$filename}) if defined $filename;
1062 };
1063
1064 # Command-line + PERLLIB:
1065 # Save the contents of @INC before they are modified elsewhere.
1066 @ini_INC = @INC;
1067
1068 # This was an attempt to clear out the previous values of various
1069 # trapped errors. Apparently it didn't help. XXX More info needed!
1070 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1071
1072 # We set these variables to safe values. We don't want to blindly turn
1073 # off warnings, because other packages may still want them.
1074 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1075                                    # (local $^W cannot help - other packages!).
1076
1077 # Default to not exiting when program finishes; print the return
1078 # value when the 'r' command is used to return from a subroutine.
1079 $inhibit_exit = $option{PrintRet} = 1;
1080
1081 =head1 OPTION PROCESSING
1082
1083 The debugger's options are actually spread out over the debugger itself and
1084 C<dumpvar.pl>; some of these are variables to be set, while others are
1085 subs to be called with a value. To try to make this a little easier to
1086 manage, the debugger uses a few data structures to define what options
1087 are legal and how they are to be processed.
1088
1089 First, the C<@options> array defines the I<names> of all the options that
1090 are to be accepted.
1091
1092 =cut
1093
1094 @options = qw(
1095   CommandSet   HistFile      HistSize
1096   hashDepth    arrayDepth    dumpDepth
1097   DumpDBFiles  DumpPackages  DumpReused
1098   compactDump  veryCompact   quote
1099   HighBit      undefPrint    globPrint
1100   PrintRet     UsageOnly     frame
1101   AutoTrace    TTY           noTTY
1102   ReadLine     NonStop       LineInfo
1103   maxTraceLen  recallCommand ShellBang
1104   pager        tkRunning     ornaments
1105   signalLevel  warnLevel     dieLevel
1106   inhibit_exit ImmediateStop bareStringify
1107   CreateTTY    RemotePort    windowSize
1108   DollarCaretP
1109 );
1110
1111 @RememberOnROptions = qw(DollarCaretP);
1112
1113 =pod
1114
1115 Second, C<optionVars> lists the variables that each option uses to save its
1116 state.
1117
1118 =cut
1119
1120 %optionVars = (
1121     hashDepth     => \$dumpvar::hashDepth,
1122     arrayDepth    => \$dumpvar::arrayDepth,
1123     CommandSet    => \$CommandSet,
1124     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1125     DumpPackages  => \$dumpvar::dumpPackages,
1126     DumpReused    => \$dumpvar::dumpReused,
1127     HighBit       => \$dumpvar::quoteHighBit,
1128     undefPrint    => \$dumpvar::printUndef,
1129     globPrint     => \$dumpvar::globPrint,
1130     UsageOnly     => \$dumpvar::usageOnly,
1131     CreateTTY     => \$CreateTTY,
1132     bareStringify => \$dumpvar::bareStringify,
1133     frame         => \$frame,
1134     AutoTrace     => \$trace,
1135     inhibit_exit  => \$inhibit_exit,
1136     maxTraceLen   => \$maxtrace,
1137     ImmediateStop => \$ImmediateStop,
1138     RemotePort    => \$remoteport,
1139     windowSize    => \$window,
1140     HistFile      => \$histfile,
1141     HistSize      => \$histsize,
1142 );
1143
1144 =pod
1145
1146 Third, C<%optionAction> defines the subroutine to be called to process each
1147 option.
1148
1149 =cut
1150
1151 %optionAction = (
1152     compactDump   => \&dumpvar::compactDump,
1153     veryCompact   => \&dumpvar::veryCompact,
1154     quote         => \&dumpvar::quote,
1155     TTY           => \&TTY,
1156     noTTY         => \&noTTY,
1157     ReadLine      => \&ReadLine,
1158     NonStop       => \&NonStop,
1159     LineInfo      => \&LineInfo,
1160     recallCommand => \&recallCommand,
1161     ShellBang     => \&shellBang,
1162     pager         => \&pager,
1163     signalLevel   => \&signalLevel,
1164     warnLevel     => \&warnLevel,
1165     dieLevel      => \&dieLevel,
1166     tkRunning     => \&tkRunning,
1167     ornaments     => \&ornaments,
1168     RemotePort    => \&RemotePort,
1169     DollarCaretP  => \&DollarCaretP,
1170 );
1171
1172 =pod
1173
1174 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1175 option is used.
1176
1177 =cut
1178
1179 # Note that this list is not complete: several options not listed here
1180 # actually require that dumpvar.pl be loaded for them to work, but are
1181 # not in the table. A subsequent patch will correct this problem; for
1182 # the moment, we're just recommenting, and we are NOT going to change
1183 # function.
1184 %optionRequire = (
1185     compactDump => 'dumpvar.pl',
1186     veryCompact => 'dumpvar.pl',
1187     quote       => 'dumpvar.pl',
1188 );
1189
1190 =pod
1191
1192 There are a number of initialization-related variables which can be set
1193 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1194 variable. These are:
1195
1196 =over 4
1197
1198 =item C<$rl> - readline control XXX needs more explanation
1199
1200 =item C<$warnLevel> - whether or not debugger takes over warning handling
1201
1202 =item C<$dieLevel> - whether or not debugger takes over die handling
1203
1204 =item C<$signalLevel> - whether or not debugger takes over signal handling
1205
1206 =item C<$pre> - preprompt actions (array reference)
1207
1208 =item C<$post> - postprompt actions (array reference)
1209
1210 =item C<$pretype>
1211
1212 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1213
1214 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1215
1216 =back
1217
1218 =cut
1219
1220 # These guys may be defined in $ENV{PERL5DB} :
1221 $rl          = 1     unless defined $rl;
1222 $warnLevel   = 1     unless defined $warnLevel;
1223 $dieLevel    = 1     unless defined $dieLevel;
1224 $signalLevel = 1     unless defined $signalLevel;
1225 $pre         = []    unless defined $pre;
1226 $post        = []    unless defined $post;
1227 $pretype     = []    unless defined $pretype;
1228 $CreateTTY   = 3     unless defined $CreateTTY;
1229 $CommandSet  = '580' unless defined $CommandSet;
1230
1231 share($rl);
1232 share($warnLevel);
1233 share($dieLevel);
1234 share($signalLevel);
1235 share($pre);
1236 share($post);
1237 share($pretype);
1238 share($rl);
1239 share($CreateTTY);
1240 share($CommandSet);
1241
1242 =pod
1243
1244 The default C<die>, C<warn>, and C<signal> handlers are set up.
1245
1246 =cut
1247
1248 warnLevel($warnLevel);
1249 dieLevel($dieLevel);
1250 signalLevel($signalLevel);
1251
1252 =pod
1253
1254 The pager to be used is needed next. We try to get it from the
1255 environment first.  If it's not defined there, we try to find it in
1256 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1257 then call the C<pager()> function to save the pager name.
1258
1259 =cut
1260
1261 # This routine makes sure $pager is set up so that '|' can use it.
1262 pager(
1263
1264     # If PAGER is defined in the environment, use it.
1265     defined $ENV{PAGER}
1266     ? $ENV{PAGER}
1267
1268       # If not, see if Config.pm defines it.
1269     : eval { require Config }
1270       && defined $Config::Config{pager}
1271     ? $Config::Config{pager}
1272
1273       # If not, fall back to 'more'.
1274     : 'more'
1275   )
1276   unless defined $pager;
1277
1278 =pod
1279
1280 We set up the command to be used to access the man pages, the command
1281 recall character (C<!> unless otherwise defined) and the shell escape
1282 character (C<!> unless otherwise defined). Yes, these do conflict, and
1283 neither works in the debugger at the moment.
1284
1285 =cut
1286
1287 setman();
1288
1289 # Set up defaults for command recall and shell escape (note:
1290 # these currently don't work in linemode debugging).
1291 &recallCommand("!") unless defined $prc;
1292 &shellBang("!")     unless defined $psh;
1293
1294 =pod
1295
1296 We then set up the gigantic string containing the debugger help.
1297 We also set the limit on the number of arguments we'll display during a
1298 trace.
1299
1300 =cut
1301
1302 sethelp();
1303
1304 # If we didn't get a default for the length of eval/stack trace args,
1305 # set it here.
1306 $maxtrace = 400 unless defined $maxtrace;
1307
1308 =head2 SETTING UP THE DEBUGGER GREETING
1309
1310 The debugger I<greeting> helps to inform the user how many debuggers are
1311 running, and whether the current debugger is the primary or a child.
1312
1313 If we are the primary, we just hang onto our pid so we'll have it when
1314 or if we start a child debugger. If we are a child, we'll set things up
1315 so we'll have a unique greeting and so the parent will give us our own
1316 TTY later.
1317
1318 We save the current contents of the C<PERLDB_PIDS> environment variable
1319 because we mess around with it. We'll also need to hang onto it because
1320 we'll need it if we restart.
1321
1322 Child debuggers make a label out of the current PID structure recorded in
1323 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1324 yet so the parent will give them one later via C<resetterm()>.
1325
1326 =cut
1327
1328 # Save the current contents of the environment; we're about to
1329 # much with it. We'll need this if we have to restart.
1330 $ini_pids = $ENV{PERLDB_PIDS};
1331
1332 if ( defined $ENV{PERLDB_PIDS} ) {
1333
1334     # We're a child. Make us a label out of the current PID structure
1335     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1336     # a term yet so the parent will give us one later via resetterm().
1337
1338     my $env_pids = $ENV{PERLDB_PIDS};
1339     $pids = "[$env_pids]";
1340
1341     # Unless we are on OpenVMS, all programs under the DCL shell run under
1342     # the same PID.
1343
1344     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1345         $term_pid         = $$;
1346     }
1347     else {
1348         $ENV{PERLDB_PIDS} .= "->$$";
1349         $term_pid = -1;
1350     }
1351
1352 } ## end if (defined $ENV{PERLDB_PIDS...
1353 else {
1354
1355     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1356     # child debugger, and mark us as the parent, so we'll know to set up
1357     # more TTY's is we have to.
1358     $ENV{PERLDB_PIDS} = "$$";
1359     $pids             = "[pid=$$]";
1360     $term_pid         = $$;
1361 }
1362
1363 $pidprompt = '';
1364
1365 # Sets up $emacs as a synonym for $slave_editor.
1366 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1367
1368 =head2 READING THE RC FILE
1369
1370 The debugger will read a file of initialization options if supplied. If
1371 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1372
1373 =cut
1374
1375 # As noted, this test really doesn't check accurately that the debugger
1376 # is running at a terminal or not.
1377
1378 my $dev_tty = '/dev/tty';
1379    $dev_tty = 'TT:' if ($^O eq 'VMS');
1380 if ( -e $dev_tty ) {                      # this is the wrong metric!
1381     $rcfile = ".perldb";
1382 }
1383 else {
1384     $rcfile = "perldb.ini";
1385 }
1386
1387 =pod
1388
1389 The debugger does a safety test of the file to be read. It must be owned
1390 either by the current user or root, and must only be writable by the owner.
1391
1392 =cut
1393
1394 # This wraps a safety test around "do" to read and evaluate the init file.
1395 #
1396 # This isn't really safe, because there's a race
1397 # between checking and opening.  The solution is to
1398 # open and fstat the handle, but then you have to read and
1399 # eval the contents.  But then the silly thing gets
1400 # your lexical scope, which is unfortunate at best.
1401 sub safe_do {
1402     my $file = shift;
1403
1404     # Just exactly what part of the word "CORE::" don't you understand?
1405     local $SIG{__WARN__};
1406     local $SIG{__DIE__};
1407
1408     unless ( is_safe_file($file) ) {
1409         CORE::warn <<EO_GRIPE;
1410 perldb: Must not source insecure rcfile $file.
1411         You or the superuser must be the owner, and it must not
1412         be writable by anyone but its owner.
1413 EO_GRIPE
1414         return;
1415     } ## end unless (is_safe_file($file...
1416
1417     do $file;
1418     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1419 } ## end sub safe_do
1420
1421 # This is the safety test itself.
1422 #
1423 # Verifies that owner is either real user or superuser and that no
1424 # one but owner may write to it.  This function is of limited use
1425 # when called on a path instead of upon a handle, because there are
1426 # no guarantees that filename (by dirent) whose file (by ino) is
1427 # eventually accessed is the same as the one tested.
1428 # Assumes that the file's existence is not in doubt.
1429 sub is_safe_file {
1430     my $path = shift;
1431     stat($path) || return;    # mysteriously vaporized
1432     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1433
1434     return 0 if $uid != 0 && $uid != $<;
1435     return 0 if $mode & 022;
1436     return 1;
1437 } ## end sub is_safe_file
1438
1439 # If the rcfile (whichever one we decided was the right one to read)
1440 # exists, we safely do it.
1441 if ( -f $rcfile ) {
1442     safe_do("./$rcfile");
1443 }
1444
1445 # If there isn't one here, try the user's home directory.
1446 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1447     safe_do("$ENV{HOME}/$rcfile");
1448 }
1449
1450 # Else try the login directory.
1451 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1452     safe_do("$ENV{LOGDIR}/$rcfile");
1453 }
1454
1455 # If the PERLDB_OPTS variable has options in it, parse those out next.
1456 if ( defined $ENV{PERLDB_OPTS} ) {
1457     parse_options( $ENV{PERLDB_OPTS} );
1458 }
1459
1460 =pod
1461
1462 The last thing we do during initialization is determine which subroutine is
1463 to be used to obtain a new terminal when a new debugger is started. Right now,
1464 the debugger only handles X Windows, OS/2, and Mac OS X (darwin).
1465
1466 =cut
1467
1468 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1469 # Works if you're running an xterm or xterm-like window, or you're on
1470 # OS/2, or on Mac OS X. This may need some expansion.
1471
1472 if (not defined &get_fork_TTY)       # only if no routine exists
1473 {
1474     if (defined $ENV{TERM}                       # If we know what kind
1475                                                  # of terminal this is,
1476         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1477         and defined $ENV{DISPLAY}                # and what display it's on,
1478       )
1479     {
1480         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1481     }
1482     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1483         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1484     }
1485     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1486             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1487             and $ENV{TERM_PROGRAM}
1488                 eq 'Apple_Terminal'              # Terminal.app
1489             )
1490     {
1491         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1492     }
1493 } ## end if (not defined &get_fork_TTY...
1494
1495 # untaint $^O, which may have been tainted by the last statement.
1496 # see bug [perl #24674]
1497 $^O =~ m/^(.*)\z/;
1498 $^O = $1;
1499
1500 # Here begin the unreadable code.  It needs fixing.
1501
1502 =head2 RESTART PROCESSING
1503
1504 This section handles the restart command. When the C<R> command is invoked, it
1505 tries to capture all of the state it can into environment variables, and
1506 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1507 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1508 the R command stuffed into the environment variables.
1509
1510   PERLDB_RESTART   - flag only, contains no restart data itself.
1511   PERLDB_HIST      - command history, if it's available
1512   PERLDB_ON_LOAD   - breakpoints set by the rc file
1513   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1514   PERLDB_VISITED   - files that had breakpoints
1515   PERLDB_FILE_...  - breakpoints for a file
1516   PERLDB_OPT       - active options
1517   PERLDB_INC       - the original @INC
1518   PERLDB_PRETYPE   - preprompt debugger actions
1519   PERLDB_PRE       - preprompt Perl code
1520   PERLDB_POST      - post-prompt Perl code
1521   PERLDB_TYPEAHEAD - typeahead captured by readline()
1522
1523 We chug through all these variables and plug the values saved in them
1524 back into the appropriate spots in the debugger.
1525
1526 =cut
1527
1528 if ( exists $ENV{PERLDB_RESTART} ) {
1529
1530     # We're restarting, so we don't need the flag that says to restart anymore.
1531     delete $ENV{PERLDB_RESTART};
1532
1533     # $restart = 1;
1534     @hist          = get_list('PERLDB_HIST');
1535     %break_on_load = get_list("PERLDB_ON_LOAD");
1536     %postponed     = get_list("PERLDB_POSTPONE");
1537
1538         share(@hist);
1539         share(@truehist);
1540         share(%break_on_load);
1541         share(%postponed);
1542
1543     # restore breakpoints/actions
1544     my @had_breakpoints = get_list("PERLDB_VISITED");
1545     for ( 0 .. $#had_breakpoints ) {
1546         my %pf = get_list("PERLDB_FILE_$_");
1547         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1548     }
1549
1550     # restore options
1551     my %opt = get_list("PERLDB_OPT");
1552     my ( $opt, $val );
1553     while ( ( $opt, $val ) = each %opt ) {
1554         $val =~ s/[\\\']/\\$1/g;
1555         parse_options("$opt'$val'");
1556     }
1557
1558     # restore original @INC
1559     @INC     = get_list("PERLDB_INC");
1560     @ini_INC = @INC;
1561
1562     # return pre/postprompt actions and typeahead buffer
1563     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1564     $pre       = [ get_list("PERLDB_PRE") ];
1565     $post      = [ get_list("PERLDB_POST") ];
1566     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1567 } ## end if (exists $ENV{PERLDB_RESTART...
1568
1569 =head2 SETTING UP THE TERMINAL
1570
1571 Now, we'll decide how the debugger is going to interact with the user.
1572 If there's no TTY, we set the debugger to run non-stop; there's not going
1573 to be anyone there to enter commands.
1574
1575 =cut
1576
1577 if ($notty) {
1578     $runnonstop = 1;
1579         share($runnonstop);
1580 }
1581
1582 =pod
1583
1584 If there is a TTY, we have to determine who it belongs to before we can
1585 proceed. If this is a slave editor or graphical debugger (denoted by
1586 the first command-line switch being '-emacs'), we shift this off and
1587 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1588
1589 =cut
1590
1591 else {
1592
1593     # Is Perl being run from a slave editor or graphical debugger?
1594     # If so, don't use readline, and set $slave_editor = 1.
1595     $slave_editor =
1596       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1597     $rl = 0, shift(@main::ARGV) if $slave_editor;
1598
1599     #require Term::ReadLine;
1600
1601 =pod
1602
1603 We then determine what the console should be on various systems:
1604
1605 =over 4
1606
1607 =item * Cygwin - We use C<stdin> instead of a separate device.
1608
1609 =cut
1610
1611     if ( $^O eq 'cygwin' ) {
1612
1613         # /dev/tty is binary. use stdin for textmode
1614         undef $console;
1615     }
1616
1617 =item * Unix - use C</dev/tty>.
1618
1619 =cut
1620
1621     elsif ( -e "/dev/tty" ) {
1622         $console = "/dev/tty";
1623     }
1624
1625 =item * Windows or MSDOS - use C<con>.
1626
1627 =cut
1628
1629     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1630         $console = "con";
1631     }
1632
1633 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1634 Console> if not.
1635
1636 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1637
1638 =cut
1639
1640     elsif ( $^O eq 'MacOS' ) {
1641         if ( $MacPerl::Version !~ /MPW/ ) {
1642             $console =
1643               "Dev:Console:Perl Debug";    # Separate window for application
1644         }
1645         else {
1646             $console = "Dev:Console";
1647         }
1648     } ## end elsif ($^O eq 'MacOS')
1649
1650 =item * VMS - use C<sys$command>.
1651
1652 =cut
1653
1654     else {
1655
1656         # everything else is ...
1657         $console = "sys\$command";
1658     }
1659
1660 =pod
1661
1662 =back
1663
1664 Several other systems don't use a specific console. We C<undef $console>
1665 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1666 with a slave editor, Epoc).
1667
1668 =cut
1669
1670     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1671
1672         # /dev/tty is binary. use stdin for textmode
1673         $console = undef;
1674     }
1675
1676     if ( $^O eq 'NetWare' ) {
1677
1678         # /dev/tty is binary. use stdin for textmode
1679         $console = undef;
1680     }
1681
1682     # In OS/2, we need to use STDIN to get textmode too, even though
1683     # it pretty much looks like Unix otherwise.
1684     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1685     {    # In OS/2
1686         $console = undef;
1687     }
1688
1689     # EPOC also falls into the 'got to use STDIN' camp.
1690     if ( $^O eq 'epoc' ) {
1691         $console = undef;
1692     }
1693
1694 =pod
1695
1696 If there is a TTY hanging around from a parent, we use that as the console.
1697
1698 =cut
1699
1700     $console = $tty if defined $tty;
1701
1702 =head2 SOCKET HANDLING
1703
1704 The debugger is capable of opening a socket and carrying out a debugging
1705 session over the socket.
1706
1707 If C<RemotePort> was defined in the options, the debugger assumes that it
1708 should try to start a debugging session on that port. It builds the socket
1709 and then tries to connect the input and output filehandles to it.
1710
1711 =cut
1712
1713     # Handle socket stuff.
1714
1715     if ( defined $remoteport ) {
1716
1717         # If RemotePort was defined in the options, connect input and output
1718         # to the socket.
1719         require IO::Socket;
1720         $OUT = new IO::Socket::INET(
1721             Timeout  => '10',
1722             PeerAddr => $remoteport,
1723             Proto    => 'tcp',
1724         );
1725         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1726         $IN = $OUT;
1727     } ## end if (defined $remoteport)
1728
1729 =pod
1730
1731 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1732 this is probably a situation where multiple debuggers are running (for example,
1733 a backticked command that starts up another debugger). We create a new IN and
1734 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1735 and if we can.
1736
1737 =cut
1738
1739     # Non-socket.
1740     else {
1741
1742         # Two debuggers running (probably a system or a backtick that invokes
1743         # the debugger itself under the running one). create a new IN and OUT
1744         # filehandle, and do the necessary mojo to create a new tty if we
1745         # know how, and we can.
1746         create_IN_OUT(4) if $CreateTTY & 4;
1747         if ($console) {
1748
1749             # If we have a console, check to see if there are separate ins and
1750             # outs to open. (They are assumed identical if not.)
1751
1752             my ( $i, $o ) = split /,/, $console;
1753             $o = $i unless defined $o;
1754
1755             # read/write on in, or just read, or read on STDIN.
1756             open( IN,      "+<$i" )
1757               || open( IN, "<$i" )
1758               || open( IN, "<&STDIN" );
1759
1760             # read/write/create/clobber out, or write/create/clobber out,
1761             # or merge with STDERR, or merge with STDOUT.
1762                  open( OUT, "+>$o" )
1763               || open( OUT, ">$o" )
1764               || open( OUT, ">&STDERR" )
1765               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1766
1767         } ## end if ($console)
1768         elsif ( not defined $console ) {
1769
1770             # No console. Open STDIN.
1771             open( IN, "<&STDIN" );
1772
1773             # merge with STDERR, or with STDOUT.
1774             open( OUT,      ">&STDERR" )
1775               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1776             $console = 'STDIN/OUT';
1777         } ## end elsif (not defined $console)
1778
1779         # Keep copies of the filehandles so that when the pager runs, it
1780         # can close standard input without clobbering ours.
1781         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1782     } ## end elsif (from if(defined $remoteport))
1783
1784     # Unbuffer DB::OUT. We need to see responses right away.
1785     my $previous = select($OUT);
1786     $| = 1;                                  # for DB::OUT
1787     select($previous);
1788
1789     # Line info goes to debugger output unless pointed elsewhere.
1790     # Pointing elsewhere makes it possible for slave editors to
1791     # keep track of file and position. We have both a filehandle
1792     # and a I/O description to keep track of.
1793     $LINEINFO = $OUT     unless defined $LINEINFO;
1794     $lineinfo = $console unless defined $lineinfo;
1795         # share($LINEINFO); # <- unable to share globs
1796         share($lineinfo);   #
1797
1798 =pod
1799
1800 To finish initialization, we show the debugger greeting,
1801 and then call the C<afterinit()> subroutine if there is one.
1802
1803 =cut
1804
1805     # Show the debugger greeting.
1806     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1807     unless ($runnonstop) {
1808         local $\ = '';
1809         local $, = '';
1810         if ( $term_pid eq '-1' ) {
1811             print $OUT "\nDaughter DB session started...\n";
1812         }
1813         else {
1814             print $OUT "\nLoading DB routines from $header\n";
1815             print $OUT (
1816                 "Editor support ",
1817                 $slave_editor ? "enabled" : "available", ".\n"
1818             );
1819             print $OUT
1820 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1821         } ## end else [ if ($term_pid eq '-1')
1822     } ## end unless ($runnonstop)
1823 } ## end else [ if ($notty)
1824
1825 # XXX This looks like a bug to me.
1826 # Why copy to @ARGS and then futz with @args?
1827 @ARGS = @ARGV;
1828 for (@args) {
1829     # Make sure backslashes before single quotes are stripped out, and
1830     # keep args unless they are numeric (XXX why?)
1831     # s/\'/\\\'/g;                      # removed while not justified understandably
1832     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1833 }
1834
1835 # If there was an afterinit() sub defined, call it. It will get
1836 # executed in our scope, so it can fiddle with debugger globals.
1837 if ( defined &afterinit ) {    # May be defined in $rcfile
1838     &afterinit();
1839 }
1840
1841 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1842 $I_m_init = 1;
1843
1844 ############################################################ Subroutines
1845
1846 =head1 SUBROUTINES
1847
1848 =head2 DB
1849
1850 This gigantic subroutine is the heart of the debugger. Called before every
1851 statement, its job is to determine if a breakpoint has been reached, and
1852 stop if so; read commands from the user, parse them, and execute
1853 them, and then send execution off to the next statement.
1854
1855 Note that the order in which the commands are processed is very important;
1856 some commands earlier in the loop will actually alter the C<$cmd> variable
1857 to create other commands to be executed later. This is all highly I<optimized>
1858 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1859 see what's happening in any given command.
1860
1861 =cut
1862
1863 sub DB {
1864
1865     # lock the debugger and get the thread id for the prompt
1866         lock($DBGR);
1867         my $tid;
1868         if ($ENV{PERL5DB_THREADED}) {
1869                 $tid = eval { "[".threads->tid."]" };
1870         }
1871
1872     # Check for whether we should be running continuously or not.
1873     # _After_ the perl program is compiled, $single is set to 1:
1874     if ( $single and not $second_time++ ) {
1875
1876         # Options say run non-stop. Run until we get an interrupt.
1877         if ($runnonstop) {    # Disable until signal
1878                 # If there's any call stack in place, turn off single
1879                 # stepping into subs throughout the stack.
1880             for ( $i = 0 ; $i <= $stack_depth ; ) {
1881                 $stack[ $i++ ] &= ~1;
1882             }
1883
1884             # And we are now no longer in single-step mode.
1885             $single = 0;
1886
1887             # If we simply returned at this point, we wouldn't get
1888             # the trace info. Fall on through.
1889             # return;
1890         } ## end if ($runnonstop)
1891
1892         elsif ($ImmediateStop) {
1893
1894             # We are supposed to stop here; XXX probably a break.
1895             $ImmediateStop = 0;    # We've processed it; turn it off
1896             $signal        = 1;    # Simulate an interrupt to force
1897                                    # us into the command loop
1898         }
1899     } ## end if ($single and not $second_time...
1900
1901     # If we're in single-step mode, or an interrupt (real or fake)
1902     # has occurred, turn off non-stop mode.
1903     $runnonstop = 0 if $single or $signal;
1904
1905     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1906     # The code being debugged may have altered them.
1907     &save;
1908
1909     # Since DB::DB gets called after every line, we can use caller() to
1910     # figure out where we last were executing. Sneaky, eh? This works because
1911     # caller is returning all the extra information when called from the
1912     # debugger.
1913     local ( $package, $filename, $line ) = caller;
1914     local $filename_ini = $filename;
1915
1916     # set up the context for DB::eval, so it can properly execute
1917     # code on behalf of the user. We add the package in so that the
1918     # code is eval'ed in the proper package (not in the debugger!).
1919     local $usercontext =
1920       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1921
1922     # Create an alias to the active file magical array to simplify
1923     # the code here.
1924     local (*dbline) = $main::{ '_<' . $filename };
1925
1926     # we need to check for pseudofiles on Mac OS (these are files
1927     # not attached to a filename, but instead stored in Dev:Pseudo)
1928     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1929         $filename_ini = $filename = 'Dev:Pseudo';
1930         *dbline = $main::{ '_<' . $filename };
1931     }
1932
1933     # Last line in the program.
1934     local $max = $#dbline;
1935
1936     # if we have something here, see if we should break.
1937     if ( $dbline{$line}
1938         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1939     {
1940
1941         # Stop if the stop criterion says to just stop.
1942         if ( $stop eq '1' ) {
1943             $signal |= 1;
1944         }
1945
1946         # It's a conditional stop; eval it in the user's context and
1947         # see if we should stop. If so, remove the one-time sigil.
1948         elsif ($stop) {
1949             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1950             &eval;
1951             $dbline{$line} =~ s/;9($|\0)/$1/;
1952         }
1953     } ## end if ($dbline{$line} && ...
1954
1955     # Preserve the current stop-or-not, and see if any of the W
1956     # (watch expressions) has changed.
1957     my $was_signal = $signal;
1958
1959     # If we have any watch expressions ...
1960     if ( $trace & 2 ) {
1961         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1962             $evalarg = $to_watch[$n];
1963             local $onetimeDump;    # Tell DB::eval() to not output results
1964
1965             # Fix context DB::eval() wants to return an array, but
1966             # we need a scalar here.
1967             my ($val) = join( "', '", &eval );
1968             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1969
1970             # Did it change?
1971             if ( $val ne $old_watch[$n] ) {
1972
1973                 # Yep! Show the difference, and fake an interrupt.
1974                 $signal = 1;
1975                 print $OUT <<EOP;
1976 Watchpoint $n:\t$to_watch[$n] changed:
1977     old value:\t$old_watch[$n]
1978     new value:\t$val
1979 EOP
1980                 $old_watch[$n] = $val;
1981             } ## end if ($val ne $old_watch...
1982         } ## end for (my $n = 0 ; $n <= ...
1983     } ## end if ($trace & 2)
1984
1985 =head2 C<watchfunction()>
1986
1987 C<watchfunction()> is a function that can be defined by the user; it is a
1988 function which will be run on each entry to C<DB::DB>; it gets the
1989 current package, filename, and line as its parameters.
1990
1991 The watchfunction can do anything it likes; it is executing in the
1992 debugger's context, so it has access to all of the debugger's internal
1993 data structures and functions.
1994
1995 C<watchfunction()> can control the debugger's actions. Any of the following
1996 will cause the debugger to return control to the user's program after
1997 C<watchfunction()> executes:
1998
1999 =over 4
2000
2001 =item *
2002
2003 Returning a false value from the C<watchfunction()> itself.
2004
2005 =item *
2006
2007 Altering C<$single> to a false value.
2008
2009 =item *
2010
2011 Altering C<$signal> to a false value.
2012
2013 =item *
2014
2015 Turning off the C<4> bit in C<$trace> (this also disables the
2016 check for C<watchfunction()>. This can be done with
2017
2018     $trace &= ~4;
2019
2020 =back
2021
2022 =cut
2023
2024     # If there's a user-defined DB::watchfunction, call it with the
2025     # current package, filename, and line. The function executes in
2026     # the DB:: package.
2027     if ( $trace & 4 ) {    # User-installed watch
2028         return
2029           if watchfunction( $package, $filename, $line )
2030           and not $single
2031           and not $was_signal
2032           and not( $trace & ~4 );
2033     } ## end if ($trace & 4)
2034
2035     # Pick up any alteration to $signal in the watchfunction, and
2036     # turn off the signal now.
2037     $was_signal = $signal;
2038     $signal     = 0;
2039
2040 =head2 GETTING READY TO EXECUTE COMMANDS
2041
2042 The debugger decides to take control if single-step mode is on, the
2043 C<t> command was entered, or the user generated a signal. If the program
2044 has fallen off the end, we set things up so that entering further commands
2045 won't cause trouble, and we say that the program is over.
2046
2047 =cut
2048
2049     # Check to see if we should grab control ($single true,
2050     # trace set appropriately, or we got a signal).
2051     if ( $single || ( $trace & 1 ) || $was_signal ) {
2052
2053         # Yes, grab control.
2054         if ($slave_editor) {
2055
2056             # Tell the editor to update its position.
2057             $position = "\032\032$filename:$line:0\n";
2058             print_lineinfo($position);
2059         }
2060
2061 =pod
2062
2063 Special check: if we're in package C<DB::fake>, we've gone through the
2064 C<END> block at least once. We set up everything so that we can continue
2065 to enter commands and have a valid context to be in.
2066
2067 =cut
2068
2069         elsif ( $package eq 'DB::fake' ) {
2070
2071             # Fallen off the end already.
2072             $term || &setterm;
2073             print_help(<<EOP);
2074 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2075   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2076   B<h q>, B<h R> or B<h o> to get additional info.
2077 EOP
2078
2079             # Set the DB::eval context appropriately.
2080             $package     = 'main';
2081             $usercontext =
2082                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2083               . "package $package;";    # this won't let them modify, alas
2084         } ## end elsif ($package eq 'DB::fake')
2085
2086 =pod
2087
2088 If the program hasn't finished executing, we scan forward to the
2089 next executable line, print that out, build the prompt from the file and line
2090 number information, and print that.
2091
2092 =cut
2093
2094         else {
2095
2096             # Still somewhere in the midst of execution. Set up the
2097             #  debugger prompt.
2098             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2099                                  # Perl 5 ones (sorry, we don't print Klingon
2100                                  #module names)
2101
2102             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2103             $prefix .= "$sub($filename:";
2104             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2105
2106             # Break up the prompt if it's really long.
2107             if ( length($prefix) > 30 ) {
2108                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2109                 $prefix   = "";
2110                 $infix    = ":\t";
2111             }
2112             else {
2113                 $infix    = "):\t";
2114                 $position = "$prefix$line$infix$dbline[$line]$after";
2115             }
2116
2117             # Print current line info, indenting if necessary.
2118             if ($frame) {
2119                 print_lineinfo( ' ' x $stack_depth,
2120                     "$line:\t$dbline[$line]$after" );
2121             }
2122             else {
2123                 print_lineinfo($position);
2124             }
2125
2126             # Scan forward, stopping at either the end or the next
2127             # unbreakable line.
2128             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2129             {    #{ vi
2130
2131                 # Drop out on null statements, block closers, and comments.
2132                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2133
2134                 # Drop out if the user interrupted us.
2135                 last if $signal;
2136
2137                 # Append a newline if the line doesn't have one. Can happen
2138                 # in eval'ed text, for instance.
2139                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2140
2141                 # Next executable line.
2142                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2143                 $position .= $incr_pos;
2144                 if ($frame) {
2145
2146                     # Print it indented if tracing is on.
2147                     print_lineinfo( ' ' x $stack_depth,
2148                         "$i:\t$dbline[$i]$after" );
2149                 }
2150                 else {
2151                     print_lineinfo($incr_pos);
2152                 }
2153             } ## end for ($i = $line + 1 ; $i...
2154         } ## end else [ if ($slave_editor)
2155     } ## end if ($single || ($trace...
2156
2157 =pod
2158
2159 If there's an action to be executed for the line we stopped at, execute it.
2160 If there are any preprompt actions, execute those as well.
2161
2162 =cut
2163
2164     # If there's an action, do it now.
2165     $evalarg = $action, &eval if $action;
2166
2167     # Are we nested another level (e.g., did we evaluate a function
2168     # that had a breakpoint in it at the debugger prompt)?
2169     if ( $single || $was_signal ) {
2170
2171         # Yes, go down a level.
2172         local $level = $level + 1;
2173
2174         # Do any pre-prompt actions.
2175         foreach $evalarg (@$pre) {
2176             &eval;
2177         }
2178
2179         # Complain about too much recursion if we passed the limit.
2180         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2181           if $single & 4;
2182
2183         # The line we're currently on. Set $incr to -1 to stay here
2184         # until we get a command that tells us to advance.
2185         $start = $line;
2186         $incr  = -1;      # for backward motion.
2187
2188         # Tack preprompt debugger actions ahead of any actual input.
2189         @typeahead = ( @$pretype, @typeahead );
2190
2191 =head2 WHERE ARE WE?
2192
2193 XXX Relocate this section?
2194
2195 The debugger normally shows the line corresponding to the current line of
2196 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2197 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2198
2199 C<$incr> controls by how many lines the I<current> line should move forward
2200 after a command is executed. If set to -1, this indicates that the I<current>
2201 line shouldn't change.
2202
2203 C<$start> is the I<current> line. It is used for things like knowing where to
2204 move forwards or backwards from when doing an C<L> or C<-> command.
2205
2206 C<$max> tells the debugger where the last line of the current file is. It's
2207 used to terminate loops most often.
2208
2209 =head2 THE COMMAND LOOP
2210
2211 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2212 in two parts:
2213
2214 =over 4
2215
2216 =item *
2217
2218 The outer part of the loop, starting at the C<CMD> label. This loop
2219 reads a command and then executes it.
2220
2221 =item *
2222
2223 The inner part of the loop, starting at the C<PIPE> label. This part
2224 is wholly contained inside the C<CMD> block and only executes a command.
2225 Used to handle commands running inside a pager.
2226
2227 =back
2228
2229 So why have two labels to restart the loop? Because sometimes, it's easier to
2230 have a command I<generate> another command and then re-execute the loop to do
2231 the new command. This is faster, but perhaps a bit more convoluted.
2232
2233 =cut
2234
2235         # The big command dispatch loop. It keeps running until the
2236         # user yields up control again.
2237         #
2238         # If we have a terminal for input, and we get something back
2239         # from readline(), keep on processing.
2240       CMD:
2241         while (
2242
2243             # We have a terminal, or can get one ...
2244             ( $term || &setterm ),
2245
2246             # ... and it belogs to this PID or we get one for this PID ...
2247             ( $term_pid == $$ or resetterm(1) ),
2248
2249             # ... and we got a line of command input ...
2250             defined(
2251                 $cmd = &readline(
2252                         "$pidprompt $tid DB"
2253                       . ( '<' x $level )
2254                       . ( $#hist + 1 )
2255                       . ( '>' x $level ) . " "
2256                 )
2257             )
2258           )
2259         {
2260
2261                         share($cmd);
2262             # ... try to execute the input as debugger commands.
2263
2264             # Don't stop running.
2265             $single = 0;
2266
2267             # No signal is active.
2268             $signal = 0;
2269
2270             # Handle continued commands (ending with \):
2271             $cmd =~ s/\\$/\n/ && do {
2272                 $cmd .= &readline("  cont: ");
2273                 redo CMD;
2274             };
2275
2276 =head4 The null command
2277
2278 A newline entered by itself means I<re-execute the last command>. We grab the
2279 command out of C<$laststep> (where it was recorded previously), and copy it
2280 back into C<$cmd> to be executed below. If there wasn't any previous command,
2281 we'll do nothing below (no command will match). If there was, we also save it
2282 in the command history and fall through to allow the command parsing to pick
2283 it up.
2284
2285 =cut
2286
2287             # Empty input means repeat the last command.
2288             $cmd =~ /^$/ && ( $cmd = $laststep );
2289             chomp($cmd);    # get rid of the annoying extra newline
2290             push( @hist, $cmd ) if length($cmd) > 1;
2291             push( @truehist, $cmd );
2292                         share(@hist);
2293                         share(@truehist);
2294
2295             # This is a restart point for commands that didn't arrive
2296             # via direct user input. It allows us to 'redo PIPE' to
2297             # re-execute command processing without reading a new command.
2298           PIPE: {
2299                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2300                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2301                 ($i) = split( /\s+/, $cmd );
2302
2303 =head3 COMMAND ALIASES
2304
2305 The debugger can create aliases for commands (these are stored in the
2306 C<%alias> hash). Before a command is executed, the command loop looks it up
2307 in the alias hash and substitutes the contents of the alias for the command,
2308 completely replacing it.
2309
2310 =cut
2311
2312                 # See if there's an alias for the command, and set it up if so.
2313                 if ( $alias{$i} ) {
2314
2315                     # Squelch signal handling; we want to keep control here
2316                     # if something goes loco during the alias eval.
2317                     local $SIG{__DIE__};
2318                     local $SIG{__WARN__};
2319
2320                     # This is a command, so we eval it in the DEBUGGER's
2321                     # scope! Otherwise, we can't see the special debugger
2322                     # variables, or get to the debugger's subs. (Well, we
2323                     # _could_, but why make it even more complicated?)
2324                     eval "\$cmd =~ $alias{$i}";
2325                     if ($@) {
2326                         local $\ = '';
2327                         print $OUT "Couldn't evaluate `$i' alias: $@";
2328                         next CMD;
2329                     }
2330                 } ## end if ($alias{$i})
2331
2332 =head3 MAIN-LINE COMMANDS
2333
2334 All of these commands work up to and after the program being debugged has
2335 terminated.
2336
2337 =head4 C<q> - quit
2338
2339 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2340 try to execute further, cleaning any restart-related stuff out of the
2341 environment, and executing with the last value of C<$?>.
2342
2343 =cut
2344
2345                 $cmd =~ /^q$/ && do {
2346                     $fall_off_end = 1;
2347                     clean_ENV();
2348                     exit $?;
2349                 };
2350
2351 =head4 C<t> - trace
2352
2353 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2354
2355 =cut
2356
2357                 $cmd =~ /^t$/ && do {
2358                     $trace ^= 1;
2359                     local $\ = '';
2360                     print $OUT "Trace = "
2361                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2362                     next CMD;
2363                 };
2364
2365 =head4 C<S> - list subroutines matching/not matching a pattern
2366
2367 Walks through C<%sub>, checking to see whether or not to print the name.
2368
2369 =cut
2370
2371                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2372
2373                     $Srev     = defined $2;     # Reverse scan?
2374                     $Spatt    = $3;             # The pattern (if any) to use.
2375                     $Snocheck = !defined $1;    # No args - print all subs.
2376
2377                     # Need to make these sane here.
2378                     local $\ = '';
2379                     local $, = '';
2380
2381                     # Search through the debugger's magical hash of subs.
2382                     # If $nocheck is true, just print the sub name.
2383                     # Otherwise, check it against the pattern. We then use
2384                     # the XOR trick to reverse the condition as required.
2385                     foreach $subname ( sort( keys %sub ) ) {
2386                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2387                             print $OUT $subname, "\n";
2388                         }
2389                     }
2390                     next CMD;
2391                 };
2392
2393 =head4 C<X> - list variables in current package
2394
2395 Since the C<V> command actually processes this, just change this to the
2396 appropriate C<V> command and fall through.
2397
2398 =cut
2399
2400                 $cmd =~ s/^X\b/V $package/;
2401
2402 =head4 C<V> - list variables
2403
2404 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2405
2406 =cut
2407
2408                 # Bare V commands get the currently-being-debugged package
2409                 # added.
2410                 $cmd =~ /^V$/ && do {
2411                     $cmd = "V $package";
2412                 };
2413
2414                 # V - show variables in package.
2415                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2416
2417                     # Save the currently selected filehandle and
2418                     # force output to debugger's filehandle (dumpvar
2419                     # just does "print" for output).
2420                     local ($savout) = select($OUT);
2421
2422                     # Grab package name and variables to dump.
2423                     $packname = $1;
2424                     @vars     = split( ' ', $2 );
2425
2426                     # If main::dumpvar isn't here, get it.
2427                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2428                     if ( defined &main::dumpvar ) {
2429
2430                         # We got it. Turn off subroutine entry/exit messages
2431                         # for the moment, along with return values.
2432                         local $frame = 0;
2433                         local $doret = -2;
2434
2435                         # must detect sigpipe failures  - not catching
2436                         # then will cause the debugger to die.
2437                         eval {
2438                             &main::dumpvar(
2439                                 $packname,
2440                                 defined $option{dumpDepth}
2441                                 ? $option{dumpDepth}
2442                                 : -1,    # assume -1 unless specified
2443                                 @vars
2444                             );
2445                         };
2446
2447                         # The die doesn't need to include the $@, because
2448                         # it will automatically get propagated for us.
2449                         if ($@) {
2450                             die unless $@ =~ /dumpvar print failed/;
2451                         }
2452                     } ## end if (defined &main::dumpvar)
2453                     else {
2454
2455                         # Couldn't load dumpvar.
2456                         print $OUT "dumpvar.pl not available.\n";
2457                     }
2458
2459                     # Restore the output filehandle, and go round again.
2460                     select($savout);
2461                     next CMD;
2462                 };
2463
2464 =head4 C<x> - evaluate and print an expression
2465
2466 Hands the expression off to C<DB::eval>, setting it up to print the value
2467 via C<dumpvar.pl> instead of just printing it directly.
2468
2469 =cut
2470
2471                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2472                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2473
2474                     # handle special  "x 3 blah" syntax XXX propagate
2475                     # doc back to special variables.
2476                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2477                         $onetimedumpDepth = $1;
2478                     }
2479                 };
2480
2481 =head4 C<m> - print methods
2482
2483 Just uses C<DB::methods> to determine what methods are available.
2484
2485 =cut
2486
2487                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2488                     methods($1);
2489                     next CMD;
2490                 };
2491
2492                 # m expr - set up DB::eval to do the work
2493                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2494                     $onetimeDump = 'methods';   #  method output gets used there
2495                 };
2496
2497 =head4 C<f> - switch files
2498
2499 =cut
2500
2501                 $cmd =~ /^f\b\s*(.*)/ && do {
2502                     $file = $1;
2503                     $file =~ s/\s+$//;
2504
2505                     # help for no arguments (old-style was return from sub).
2506                     if ( !$file ) {
2507                         print $OUT
2508                           "The old f command is now the r command.\n";    # hint
2509                         print $OUT "The new f command switches filenames.\n";
2510                         next CMD;
2511                     } ## end if (!$file)
2512
2513                     # if not in magic file list, try a close match.
2514                     if ( !defined $main::{ '_<' . $file } ) {
2515                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2516                             {
2517                                 $try = substr( $try, 2 );
2518                                 print $OUT "Choosing $try matching `$file':\n";
2519                                 $file = $try;
2520                             }
2521                         } ## end if (($try) = grep(m#^_<.*$file#...
2522                     } ## end if (!defined $main::{ ...
2523
2524                     # If not successfully switched now, we failed.
2525                     if ( !defined $main::{ '_<' . $file } ) {
2526                         print $OUT "No file matching `$file' is loaded.\n";
2527                         next CMD;
2528                     }
2529
2530                     # We switched, so switch the debugger internals around.
2531                     elsif ( $file ne $filename ) {
2532                         *dbline   = $main::{ '_<' . $file };
2533                         $max      = $#dbline;
2534                         $filename = $file;
2535                         $start    = 1;
2536                         $cmd      = "l";
2537                     } ## end elsif ($file ne $filename)
2538
2539                     # We didn't switch; say we didn't.
2540                     else {
2541                         print $OUT "Already in $file.\n";
2542                         next CMD;
2543                     }
2544                 };
2545
2546 =head4 C<.> - return to last-executed line.
2547
2548 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2549 and then we look up the line in the magical C<%dbline> hash.
2550
2551 =cut
2552
2553                 # . command.
2554                 $cmd =~ /^\.$/ && do {
2555                     $incr = -1;    # stay at current line
2556
2557                     # Reset everything to the old location.
2558                     $start    = $line;
2559                     $filename = $filename_ini;
2560                     *dbline   = $main::{ '_<' . $filename };
2561                     $max      = $#dbline;
2562
2563                     # Now where are we?
2564                     print_lineinfo($position);
2565                     next CMD;
2566                 };
2567
2568 =head4 C<-> - back one window
2569
2570 We change C<$start> to be one window back; if we go back past the first line,
2571 we set it to be the first line. We ser C<$incr> to put us back at the
2572 currently-executing line, and then put a C<l $start +> (list one window from
2573 C<$start>) in C<$cmd> to be executed later.
2574
2575 =cut
2576
2577                 # - - back a window.
2578                 $cmd =~ /^-$/ && do {
2579
2580                     # back up by a window; go to 1 if back too far.
2581                     $start -= $incr + $window + 1;
2582                     $start = 1 if $start <= 0;
2583                     $incr  = $window - 1;
2584
2585                     # Generate and execute a "l +" command (handled below).
2586                     $cmd = 'l ' . ($start) . '+';
2587                 };
2588
2589 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2590
2591 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2592 problems, most notably that the default case of several commands destroying
2593 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2594 retain the old commands for those who were used to using them or who preferred
2595 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2596 deal with them instead of processing them in-line.
2597
2598 =cut
2599
2600                 # All of these commands were remapped in perl 5.8.0;
2601                 # we send them off to the secondary dispatcher (see below).
2602                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2603                     &cmd_wrapper( $1, $2, $line );
2604                     next CMD;
2605                 };
2606
2607 =head4 C<y> - List lexicals in higher scope
2608
2609 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2610 above the current one and then displays then using C<dumpvar.pl>.
2611
2612 =cut
2613
2614                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2615
2616                     # See if we've got the necessary support.
2617                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2618                       or &warn(
2619                         $@ =~ /locate/
2620                         ? "PadWalker module not found - please install\n"
2621                         : $@
2622                       )
2623                       and next CMD;
2624
2625                     # Load up dumpvar if we don't have it. If we can, that is.
2626                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2627                     defined &main::dumpvar
2628                       or print $OUT "dumpvar.pl not available.\n"
2629                       and next CMD;
2630
2631                     # Got all the modules we need. Find them and print them.
2632                     my @vars = split( ' ', $2 || '' );
2633
2634                     # Find the pad.
2635                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2636
2637                     # Oops. Can't find it.
2638                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2639
2640                     # Show the desired vars with dumplex().
2641                     my $savout = select($OUT);
2642
2643                     # Have dumplex dump the lexicals.
2644                     dumpvar::dumplex( $_, $h->{$_},
2645                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2646                         @vars )
2647                       for sort keys %$h;
2648                     select($savout);
2649                     next CMD;
2650                 };
2651
2652 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2653
2654 All of the commands below this point don't work after the program being
2655 debugged has ended. All of them check to see if the program has ended; this
2656 allows the commands to be relocated without worrying about a 'line of
2657 demarcation' above which commands can be entered anytime, and below which
2658 they can't.
2659
2660 =head4 C<n> - single step, but don't trace down into subs
2661
2662 Done by setting C<$single> to 2, which forces subs to execute straight through
2663 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2664 so a null command knows what to re-execute.
2665
2666 =cut
2667
2668                 # n - next
2669                 $cmd =~ /^n$/ && do {
2670                     end_report(), next CMD if $finished and $level <= 1;
2671
2672                     # Single step, but don't enter subs.
2673                     $single = 2;
2674
2675                     # Save for empty command (repeat last).
2676                     $laststep = $cmd;
2677                     last CMD;
2678                 };
2679
2680 =head4 C<s> - single-step, entering subs
2681
2682 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2683 subs. Also saves C<s> as C<$lastcmd>.
2684
2685 =cut
2686
2687                 # s - single step.
2688                 $cmd =~ /^s$/ && do {
2689
2690                     # Get out and restart the command loop if program
2691                     # has finished.
2692                     end_report(), next CMD if $finished and $level <= 1;
2693
2694                     # Single step should enter subs.
2695                     $single = 1;
2696
2697                     # Save for empty command (repeat last).
2698                     $laststep = $cmd;
2699                     last CMD;
2700                 };
2701
2702 =head4 C<c> - run continuously, setting an optional breakpoint
2703
2704 Most of the code for this command is taken up with locating the optional
2705 breakpoint, which is either a subroutine name or a line number. We set
2706 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2707 in this and all call levels above this one.
2708
2709 =cut
2710
2711                 # c - start continuous execution.
2712                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2713
2714                     # Hey, show's over. The debugged program finished
2715                     # executing already.
2716                     end_report(), next CMD if $finished and $level <= 1;
2717
2718                     # Capture the place to put a one-time break.
2719                     $subname = $i = $1;
2720
2721                     #  Probably not needed, since we finish an interactive
2722                     #  sub-session anyway...
2723                     # local $filename = $filename;
2724                     # local *dbline = *dbline; # XXX Would this work?!
2725                     #
2726                     # The above question wonders if localizing the alias
2727                     # to the magic array works or not. Since it's commented
2728                     # out, we'll just leave that to speculation for now.
2729
2730                     # If the "subname" isn't all digits, we'll assume it
2731                     # is a subroutine name, and try to find it.
2732                     if ( $subname =~ /\D/ ) {    # subroutine name
2733                             # Qualify it to the current package unless it's
2734                             # already qualified.
2735                         $subname = $package . "::" . $subname
2736                           unless $subname =~ /::/;
2737
2738                         # find_sub will return "file:line_number" corresponding
2739                         # to where the subroutine is defined; we call find_sub,
2740                         # break up the return value, and assign it in one
2741                         # operation.
2742                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2743
2744                         # Force the line number to be numeric.
2745                         $i += 0;
2746
2747                         # If we got a line number, we found the sub.
2748                         if ($i) {
2749
2750                             # Switch all the debugger's internals around so
2751                             # we're actually working with that file.
2752                             $filename = $file;
2753                             *dbline   = $main::{ '_<' . $filename };
2754
2755                             # Mark that there's a breakpoint in this file.
2756                             $had_breakpoints{$filename} |= 1;
2757
2758                             # Scan forward to the first executable line
2759                             # after the 'sub whatever' line.
2760                             $max = $#dbline;
2761                             ++$i while $dbline[$i] == 0 && $i < $max;
2762                         } ## end if ($i)
2763
2764                         # We didn't find a sub by that name.
2765                         else {
2766                             print $OUT "Subroutine $subname not found.\n";
2767                             next CMD;
2768                         }
2769                     } ## end if ($subname =~ /\D/)
2770
2771                     # At this point, either the subname was all digits (an
2772                     # absolute line-break request) or we've scanned through
2773                     # the code following the definition of the sub, looking
2774                     # for an executable, which we may or may not have found.
2775                     #
2776                     # If $i (which we set $subname from) is non-zero, we
2777                     # got a request to break at some line somewhere. On
2778                     # one hand, if there wasn't any real subroutine name
2779                     # involved, this will be a request to break in the current
2780                     # file at the specified line, so we have to check to make
2781                     # sure that the line specified really is breakable.
2782                     #
2783                     # On the other hand, if there was a subname supplied, the
2784                     # preceding block has moved us to the proper file and
2785                     # location within that file, and then scanned forward
2786                     # looking for the next executable line. We have to make
2787                     # sure that one was found.
2788                     #
2789                     # On the gripping hand, we can't do anything unless the
2790                     # current value of $i points to a valid breakable line.
2791                     # Check that.
2792                     if ($i) {
2793
2794                         # Breakable?
2795                         if ( $dbline[$i] == 0 ) {
2796                             print $OUT "Line $i not breakable.\n";
2797                             next CMD;
2798                         }
2799
2800                         # Yes. Set up the one-time-break sigil.
2801                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2802                     } ## end if ($i)
2803
2804                     # Turn off stack tracing from here up.
2805                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2806                         $stack[ $i++ ] &= ~1;
2807                     }
2808                     last CMD;
2809                 };
2810
2811 =head4 C<r> - return from a subroutine
2812
2813 For C<r> to work properly, the debugger has to stop execution again
2814 immediately after the return is executed. This is done by forcing
2815 single-stepping to be on in the call level above the current one. If
2816 we are printing return values when a C<r> is executed, set C<$doret>
2817 appropriately, and force us out of the command loop.
2818
2819 =cut
2820
2821                 # r - return from the current subroutine.
2822                 $cmd =~ /^r$/ && do {
2823
2824                     # Can't do anythign if the program's over.
2825                     end_report(), next CMD if $finished and $level <= 1;
2826
2827                     # Turn on stack trace.
2828                     $stack[$stack_depth] |= 1;
2829
2830                     # Print return value unless the stack is empty.
2831                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2832                     last CMD;
2833                 };
2834
2835 =head4 C<T> - stack trace
2836
2837 Just calls C<DB::print_trace>.
2838
2839 =cut
2840
2841                 $cmd =~ /^T$/ && do {
2842                     print_trace( $OUT, 1 );    # skip DB
2843                     next CMD;
2844                 };
2845
2846 =head4 C<w> - List window around current line.
2847
2848 Just calls C<DB::cmd_w>.
2849
2850 =cut
2851
2852                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2853
2854 =head4 C<W> - watch-expression processing.
2855
2856 Just calls C<DB::cmd_W>.
2857
2858 =cut
2859
2860                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2861
2862 =head4 C</> - search forward for a string in the source
2863
2864 We take the argument and treat it as a pattern. If it turns out to be a
2865 bad one, we return the error we got from trying to C<eval> it and exit.
2866 If not, we create some code to do the search and C<eval> it so it can't
2867 mess us up.
2868
2869 =cut
2870
2871                 $cmd =~ /^\/(.*)$/ && do {
2872
2873                     # The pattern as a string.
2874                     $inpat = $1;
2875
2876                     # Remove the final slash.
2877                     $inpat =~ s:([^\\])/$:$1:;
2878
2879                     # If the pattern isn't null ...
2880                     if ( $inpat ne "" ) {
2881
2882                         # Turn of warn and die procesing for a bit.
2883                         local $SIG{__DIE__};
2884                         local $SIG{__WARN__};
2885
2886                         # Create the pattern.
2887                         eval '$inpat =~ m' . "\a$inpat\a";
2888                         if ( $@ ne "" ) {
2889
2890                             # Oops. Bad pattern. No biscuit.
2891                             # Print the eval error and go back for more
2892                             # commands.
2893                             print $OUT "$@";
2894                             next CMD;
2895                         }
2896                         $pat = $inpat;
2897                     } ## end if ($inpat ne "")
2898
2899                     # Set up to stop on wrap-around.
2900                     $end = $start;
2901
2902                     # Don't move off the current line.
2903                     $incr = -1;
2904
2905                     # Done in eval so nothing breaks if the pattern
2906                     # does something weird.
2907                     eval '
2908                         for (;;) {
2909                             # Move ahead one line.
2910                             ++$start;
2911
2912                             # Wrap if we pass the last line.
2913                             $start = 1 if ($start > $max);
2914
2915                             # Stop if we have gotten back to this line again,
2916                             last if ($start == $end);
2917
2918                             # A hit! (Note, though, that we are doing
2919                             # case-insensitive matching. Maybe a qr//
2920                             # expression would be better, so the user could
2921                             # do case-sensitive matching if desired.
2922                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2923                                 if ($slave_editor) {
2924                                     # Handle proper escaping in the slave.
2925                                     print $OUT "\032\032$filename:$start:0\n";
2926                                 }
2927                                 else {
2928                                     # Just print the line normally.
2929                                     print $OUT "$start:\t",$dbline[$start],"\n";
2930                                 }
2931                                 # And quit since we found something.
2932                                 last;
2933                             }
2934                          } ';
2935
2936                     # If we wrapped, there never was a match.
2937                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2938                     next CMD;
2939                 };
2940
2941 =head4 C<?> - search backward for a string in the source
2942
2943 Same as for C</>, except the loop runs backwards.
2944
2945 =cut
2946
2947                 # ? - backward pattern search.
2948                 $cmd =~ /^\?(.*)$/ && do {
2949
2950                     # Get the pattern, remove trailing question mark.
2951                     $inpat = $1;
2952                     $inpat =~ s:([^\\])\?$:$1:;
2953
2954                     # If we've got one ...
2955                     if ( $inpat ne "" ) {
2956
2957                         # Turn off die & warn handlers.
2958                         local $SIG{__DIE__};
2959                         local $SIG{__WARN__};
2960                         eval '$inpat =~ m' . "\a$inpat\a";
2961
2962                         if ( $@ ne "" ) {
2963
2964                             # Ouch. Not good. Print the error.
2965                             print $OUT $@;
2966                             next CMD;
2967                         }
2968                         $pat = $inpat;
2969                     } ## end if ($inpat ne "")
2970
2971                     # Where we are now is where to stop after wraparound.
2972                     $end = $start;
2973
2974                     # Don't move away from this line.
2975                     $incr = -1;
2976
2977                     # Search inside the eval to prevent pattern badness
2978                     # from killing us.
2979                     eval '
2980                         for (;;) {
2981                             # Back up a line.
2982                             --$start;
2983
2984                             # Wrap if we pass the first line.
2985
2986                             $start = $max if ($start <= 0);
2987
2988                             # Quit if we get back where we started,
2989                             last if ($start == $end);
2990
2991                             # Match?
2992                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2993                                 if ($slave_editor) {
2994                                     # Yep, follow slave editor requirements.
2995                                     print $OUT "\032\032$filename:$start:0\n";
2996                                 }
2997                                 else {
2998                                     # Yep, just print normally.
2999                                     print $OUT "$start:\t",$dbline[$start],"\n";
3000                                 }
3001
3002                                 # Found, so done.
3003                                 last;
3004                             }
3005                         } ';
3006
3007                     # Say we failed if the loop never found anything,
3008                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3009                     next CMD;
3010                 };
3011
3012 =head4 C<$rc> - Recall command
3013
3014 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3015 that the terminal supports history). It find the the command required, puts it
3016 into C<$cmd>, and redoes the loop to execute it.
3017
3018 =cut
3019
3020                 # $rc - recall command.
3021                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3022
3023                     # No arguments, take one thing off history.
3024                     pop(@hist) if length($cmd) > 1;
3025
3026                     # Relative (- found)?
3027                     #  Y - index back from most recent (by 1 if bare minus)
3028                     #  N - go to that particular command slot or the last
3029                     #      thing if nothing following.
3030                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3031
3032                     # Pick out the command desired.
3033                     $cmd = $hist[$i];
3034
3035                     # Print the command to be executed and restart the loop
3036                     # with that command in the buffer.
3037                     print $OUT $cmd, "\n";
3038                     redo CMD;
3039                 };
3040
3041 =head4 C<$sh$sh> - C<system()> command
3042
3043 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3044 C<STDOUT> from getting messed up.
3045
3046 =cut
3047
3048                 # $sh$sh - run a shell command (if it's all ASCII).
3049                 # Can't run shell commands with Unicode in the debugger, hmm.
3050                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3051
3052                     # System it.
3053                     &system($1);
3054                     next CMD;
3055                 };
3056
3057 =head4 C<$rc I<pattern> $rc> - Search command history
3058
3059 Another command to manipulate C<@hist>: this one searches it with a pattern.
3060 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3061
3062 =cut
3063
3064                 # $rc pattern $rc - find a command in the history.
3065                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3066
3067                     # Create the pattern to use.
3068                     $pat = "^$1";
3069
3070                     # Toss off last entry if length is >1 (and it always is).
3071                     pop(@hist) if length($cmd) > 1;
3072
3073                     # Look backward through the history.
3074                     for ( $i = $#hist ; $i ; --$i ) {
3075
3076                         # Stop if we find it.
3077                         last if $hist[$i] =~ /$pat/;
3078                     }
3079
3080                     if ( !$i ) {
3081
3082                         # Never found it.
3083                         print $OUT "No such command!\n\n";
3084                         next CMD;
3085                     }
3086
3087                     # Found it. Put it in the buffer, print it, and process it.
3088                     $cmd = $hist[$i];
3089                     print $OUT $cmd, "\n";
3090                     redo CMD;
3091                 };
3092
3093 =head4 C<$sh> - Invoke a shell
3094
3095 Uses C<DB::system> to invoke a shell.
3096
3097 =cut
3098
3099                 # $sh - start a shell.
3100                 $cmd =~ /^$sh$/ && do {
3101
3102                     # Run the user's shell. If none defined, run Bourne.
3103                     # We resume execution when the shell terminates.
3104                     &system( $ENV{SHELL} || "/bin/sh" );
3105                     next CMD;
3106                 };
3107
3108 =head4 C<$sh I<command>> - Force execution of a command in a shell
3109
3110 Like the above, but the command is passed to the shell. Again, we use
3111 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3112
3113 =cut
3114
3115                 # $sh command - start a shell and run a command in it.
3116                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3117
3118                     # XXX: using csh or tcsh destroys sigint retvals!
3119                     #&system($1);  # use this instead
3120
3121                     # use the user's shell, or Bourne if none defined.
3122                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3123                     next CMD;
3124                 };
3125
3126 =head4 C<H> - display commands in history
3127
3128 Prints the contents of C<@hist> (if any).
3129
3130 =cut
3131
3132                 $cmd =~ /^H\b\s*\*/ && do {
3133                     @hist = @truehist = ();
3134                     print $OUT "History cleansed\n";
3135                     next CMD;
3136                 };
3137
3138                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3139
3140                     # Anything other than negative numbers is ignored by
3141                     # the (incorrect) pattern, so this test does nothing.
3142                     $end = $2 ? ( $#hist - $2 ) : 0;
3143
3144                     # Set to the minimum if less than zero.
3145                     $hist = 0 if $hist < 0;
3146
3147                     # Start at the end of the array.
3148                     # Stay in while we're still above the ending value.
3149                     # Tick back by one each time around the loop.
3150                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3151
3152                         # Print the command  unless it has no arguments.
3153                         print $OUT "$i: ", $hist[$i], "\n"
3154                           unless $hist[$i] =~ /^.?$/;
3155                     }
3156                     next CMD;
3157                 };
3158
3159 =head4 C<man, doc, perldoc> - look up documentation
3160
3161 Just calls C<runman()> to print the appropriate document.
3162
3163 =cut
3164
3165                 # man, perldoc, doc - show manual pages.
3166                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3167                     runman($1);
3168                     next CMD;
3169                 };
3170
3171 =head4 C<p> - print
3172
3173 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3174 the bottom of the loop.
3175
3176 =cut
3177
3178                 # p - print (no args): print $_.
3179                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3180
3181                 # p - print the given expression.
3182                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3183
3184 =head4 C<=> - define command alias
3185
3186 Manipulates C<%alias> to add or list command aliases.
3187
3188 =cut
3189
3190                 # = - set up a command alias.
3191                 $cmd =~ s/^=\s*// && do {
3192                     my @keys;
3193                     if ( length $cmd == 0 ) {
3194
3195                         # No args, get current aliases.
3196                         @keys = sort keys %alias;
3197                     }
3198                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3199
3200                         # Creating a new alias. $k is alias name, $v is
3201                         # alias value.
3202
3203                         # can't use $_ or kill //g state
3204                         for my $x ( $k, $v ) {
3205
3206                             # Escape "alarm" characters.
3207                             $x =~ s/\a/\\a/g;
3208                         }
3209
3210                         # Substitute key for value, using alarm chars
3211                         # as separators (which is why we escaped them in
3212                         # the command).
3213                         $alias{$k} = "s\a$k\a$v\a";
3214
3215                         # Turn off standard warn and die behavior.
3216                         local $SIG{__DIE__};
3217                         local $SIG{__WARN__};
3218
3219                         # Is it valid Perl?
3220                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3221
3222                             # Nope. Bad alias. Say so and get out.
3223                             print $OUT "Can't alias $k to $v: $@\n";
3224                             delete $alias{$k};
3225                             next CMD;
3226                         }
3227
3228                         # We'll only list the new one.
3229                         @keys = ($k);
3230                     } ## end elsif (my ($k, $v) = ($cmd...
3231
3232                     # The argument is the alias to list.
3233                     else {
3234                         @keys = ($cmd);
3235                     }
3236
3237                     # List aliases.
3238                     for my $k (@keys) {
3239
3240                         # Messy metaquoting: Trim the substiution code off.
3241                         # We use control-G as the delimiter because it's not
3242                         # likely to appear in the alias.
3243                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3244
3245                             # Print the alias.
3246                             print $OUT "$k\t= $1\n";
3247                         }
3248                         elsif ( defined $alias{$k} ) {
3249
3250                             # Couldn't trim it off; just print the alias code.
3251                             print $OUT "$k\t$alias{$k}\n";
3252                         }
3253                         else {
3254
3255                             # No such, dude.
3256                             print "No alias for $k\n";
3257                         }
3258                     } ## end for my $k (@keys)
3259                     next CMD;
3260                 };
3261
3262 =head4 C<source> - read commands from a file.
3263
3264 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3265 pick it up.
3266
3267 =cut
3268
3269                 # source - read commands from a file (or pipe!) and execute.
3270                 $cmd =~ /^source\s+(.*\S)/ && do {
3271                     if ( open my $fh, $1 ) {
3272
3273                         # Opened OK; stick it in the list of file handles.
3274                         push @cmdfhs, $fh;
3275                     }
3276                     else {
3277
3278                         # Couldn't open it.
3279                         &warn("Can't execute `$1': $!\n");
3280                     }
3281                     next CMD;
3282                 };
3283
3284 =head4 C<save> - send current history to a file
3285
3286 Takes the complete history, (not the shrunken version you see with C<H>),
3287 and saves it to the given filename, so it can be replayed using C<source>.
3288
3289 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3290
3291 =cut
3292
3293                 # save source - write commands to a file for later use
3294                 $cmd =~ /^save\s*(.*)$/ && do {
3295                     my $file = $1 || '.perl5dbrc';    # default?
3296                     if ( open my $fh, "> $file" ) {
3297
3298                        # chomp to remove extraneous newlines from source'd files
3299                         chomp( my @truelist =
3300                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3301                               @truehist );
3302                         print $fh join( "\n", @truelist );
3303                         print "commands saved in $file\n";
3304                     }
3305                     else {
3306                         &warn("Can't save debugger commands in '$1': $!\n");
3307                     }
3308                     next CMD;
3309                 };
3310
3311 =head4 C<R> - restart
3312
3313 Restart the debugger session.
3314
3315 =head4 C<rerun> - rerun the current session
3316
3317 Return to any given position in the B<true>-history list
3318
3319 =cut
3320
3321                 # R - restart execution.
3322                 # rerun - controlled restart execution.
3323                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3324                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3325
3326                     # Close all non-system fds for a clean restart.  A more
3327                     # correct method would be to close all fds that were not
3328                     # open when the process started, but this seems to be
3329                     # hard.  See "debugger 'R'estart and open database
3330                     # connections" on p5p.
3331
3332                     my $max_fd = 1024; # default if POSIX can't be loaded
3333                     if (eval { require POSIX }) {
3334                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3335                     }
3336
3337                     if (defined $max_fd) {
3338                         foreach ($^F+1 .. $max_fd-1) {
3339                             next unless open FD_TO_CLOSE, "<&=$_";
3340                             close(FD_TO_CLOSE);
3341                         }
3342                     }
3343
3344                     # And run Perl again.  We use exec() to keep the
3345                     # PID stable (and that way $ini_pids is still valid).
3346                     exec(@args) || print $OUT "exec failed: $!\n";
3347
3348                     last CMD;
3349                 };
3350
3351 =head4 C<|, ||> - pipe output through the pager.
3352
3353 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3354 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3355 pipe to the pager (restoring the output filehandles if this fails). If this
3356 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3357 set C<$signal>, sending us back into the debugger.
3358
3359 We then trim off the pipe symbols and C<redo> the command loop at the
3360 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3361 reading another.
3362
3363 =cut
3364
3365                 # || - run command in the pager, with output to DB::OUT.
3366                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3367                     if ( $pager =~ /^\|/ ) {
3368
3369                         # Default pager is into a pipe. Redirect I/O.
3370                         open( SAVEOUT, ">&STDOUT" )
3371                           || &warn("Can't save STDOUT");
3372                         open( STDOUT, ">&OUT" )
3373                           || &warn("Can't redirect STDOUT");
3374                     } ## end if ($pager =~ /^\|/)
3375                     else {
3376
3377                         # Not into a pipe. STDOUT is safe.
3378                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3379                     }
3380
3381                     # Fix up environment to record we have less if so.
3382                     fix_less();
3383
3384                     unless ( $piped = open( OUT, $pager ) ) {
3385
3386                         # Couldn't open pipe to pager.
3387                         &warn("Can't pipe output to `$pager'");
3388                         if ( $pager =~ /^\|/ ) {
3389
3390                             # Redirect I/O back again.
3391                             open( OUT, ">&STDOUT" )    # XXX: lost message
3392                               || &warn("Can't restore DB::OUT");
3393                             open( STDOUT, ">&SAVEOUT" )
3394                               || &warn("Can't restore STDOUT");
3395                             close(SAVEOUT);
3396                         } ## end if ($pager =~ /^\|/)
3397                         else {
3398
3399                             # Redirect I/O. STDOUT already safe.
3400                             open( OUT, ">&STDOUT" )    # XXX: lost message
3401                               || &warn("Can't restore DB::OUT");
3402                         }
3403                         next CMD;
3404                     } ## end unless ($piped = open(OUT,...
3405
3406                     # Set up broken-pipe handler if necessary.
3407                     $SIG{PIPE} = \&DB::catch
3408                       if $pager =~ /^\|/
3409                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3410
3411                     # Save current filehandle, unbuffer out, and put it back.
3412                     $selected = select(OUT);
3413                     $|        = 1;
3414
3415                     # Don't put it back if pager was a pipe.
3416                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3417
3418                     # Trim off the pipe symbols and run the command now.
3419                     $cmd =~ s/^\|+\s*//;
3420                     redo PIPE;
3421                 };
3422
3423 =head3 END OF COMMAND PARSING
3424
3425 Anything left in C<$cmd> at this point is a Perl expression that we want to
3426 evaluate. We'll always evaluate in the user's context, and fully qualify
3427 any variables we might want to address in the C<DB> package.
3428
3429 =cut
3430
3431                 # t - turn trace on.
3432                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3433
3434                 # s - single-step. Remember the last command was 's'.
3435                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3436
3437                 # n - single-step, but not into subs. Remember last command
3438                 # was 'n'.
3439                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3440
3441             }    # PIPE:
3442
3443             # Make sure the flag that says "the debugger's running" is
3444             # still on, to make sure we get control again.
3445             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3446
3447             # Run *our* eval that executes in the caller's context.
3448             &eval;
3449
3450             # Turn off the one-time-dump stuff now.
3451             if ($onetimeDump) {
3452                 $onetimeDump      = undef;
3453                 $onetimedumpDepth = undef;
3454             }
3455             elsif ( $term_pid == $$ ) {
3456                 eval {          # May run under miniperl, when not available...
3457                     STDOUT->flush();
3458                     STDERR->flush();
3459                 };
3460
3461                 # XXX If this is the master pid, print a newline.
3462                 print $OUT "\n";
3463             }
3464         } ## end while (($term || &setterm...
3465
3466 =head3 POST-COMMAND PROCESSING
3467
3468 After each command, we check to see if the command output was piped anywhere.
3469 If so, we go through the necessary code to unhook the pipe and go back to
3470 our standard filehandles for input and output.
3471
3472 =cut
3473
3474         continue {    # CMD:
3475
3476             # At the end of every command:
3477             if ($piped) {
3478
3479                 # Unhook the pipe mechanism now.
3480                 if ( $pager =~ /^\|/ ) {
3481
3482                     # No error from the child.
3483                     $? = 0;
3484
3485                     # we cannot warn here: the handle is missing --tchrist
3486                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3487
3488                     # most of the $? crud was coping with broken cshisms
3489                     # $? is explicitly set to 0, so this never runs.
3490                     if ($?) {
3491                         print SAVEOUT "Pager `$pager' failed: ";
3492                         if ( $? == -1 ) {
3493                             print SAVEOUT "shell returned -1\n";
3494                         }
3495                         elsif ( $? >> 8 ) {
3496                             print SAVEOUT ( $? & 127 )
3497                               ? " (SIG#" . ( $? & 127 ) . ")"
3498                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3499                         }
3500                         else {
3501                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3502                         }
3503                     } ## end if ($?)
3504
3505                     # Reopen filehandle for our output (if we can) and
3506                     # restore STDOUT (if we can).
3507                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3508                     open( STDOUT, ">&SAVEOUT" )
3509                       || &warn("Can't restore STDOUT");
3510
3511                     # Turn off pipe exception handler if necessary.
3512                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3513
3514                     # Will stop ignoring SIGPIPE if done like nohup(1)
3515                     # does SIGINT but Perl doesn't give us a choice.
3516                 } ## end if ($pager =~ /^\|/)
3517                 else {
3518
3519                     # Non-piped "pager". Just restore STDOUT.
3520                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3521                 }
3522
3523                 # Close filehandle pager was using, restore the normal one
3524                 # if necessary,
3525                 close(SAVEOUT);
3526                 select($selected), $selected = "" unless $selected eq "";
3527
3528                 # No pipes now.
3529                 $piped = "";
3530             } ## end if ($piped)
3531         }    # CMD:
3532
3533 =head3 COMMAND LOOP TERMINATION
3534
3535 When commands have finished executing, we come here. If the user closed the
3536 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3537 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3538 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3539 The interpreter will then execute the next line and then return control to us
3540 again.
3541
3542 =cut
3543
3544         # No more commands? Quit.
3545         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3546
3547         # Evaluate post-prompt commands.
3548         foreach $evalarg (@$post) {
3549             &eval;
3550         }
3551     }    # if ($single || $signal)
3552
3553     # Put the user's globals back where you found them.
3554     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3555     ();
3556 } ## end sub DB
3557
3558 # The following code may be executed now:
3559 # BEGIN {warn 4}
3560
3561 =head2 sub
3562
3563 C<sub> is called whenever a subroutine call happens in the program being
3564 debugged. The variable C<$DB::sub> contains the name of the subroutine
3565 being called.
3566
3567 The core function of this subroutine is to actually call the sub in the proper
3568 context, capturing its output. This of course causes C<DB::DB> to get called
3569 again, repeating until the subroutine ends and returns control to C<DB::sub>
3570 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3571 return value, and returns its captured copy of the return value as its own
3572 return value. The value then feeds back into the program being debugged as if
3573 C<DB::sub> hadn't been there at all.
3574
3575 C<sub> does all the work of printing the subroutine entry and exit messages
3576 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3577 and also prints the return value if needed (for the C<r> command and if
3578 the 16 bit is set in C<$frame>).
3579
3580 It also tracks the subroutine call depth by saving the current setting of
3581 C<$single> in the C<@stack> package global; if this exceeds the value in
3582 C<$deep>, C<sub> automatically turns on printing of the current depth by
3583 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3584 of stop/don't stop on entry to subs set as it currently is set.
3585
3586 =head3 C<caller()> support
3587
3588 If C<caller()> is called from the package C<DB>, it provides some
3589 additional data, in the following order:
3590
3591 =over 4
3592
3593 =item * C<$package>
3594
3595 The package name the sub was in
3596
3597 =item * C<$filename>
3598
3599 The filename it was defined in
3600
3601 =item * C<$line>
3602
3603 The line number it was defined on
3604
3605 =item * C<$subroutine>
3606
3607 The subroutine name; C<(eval)> if an C<eval>().
3608
3609 =item * C<$hasargs>
3610
3611 1 if it has arguments, 0 if not
3612
3613 =item * C<$wantarray>
3614
3615 1 if array context, 0 if scalar context
3616
3617 =item * C<$evaltext>
3618
3619 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3620
3621 =item * C<$is_require>
3622
3623 frame was created by a C<use> or C<require> statement
3624
3625 =item * C<$hints>
3626
3627 pragma information; subject to change between versions
3628
3629 =item * C<$bitmask>
3630
3631 pragma information; subject to change between versions
3632
3633 =item * C<@DB::args>
3634
3635 arguments with which the subroutine was invoked
3636
3637 =back
3638
3639 =cut
3640
3641 sub sub {
3642         # Do not use a regex in this subroutine -> results in corrupted memory
3643         # See: [perl #66110]
3644
3645         # lock ourselves under threads
3646         lock($DBGR);
3647
3648     # Whether or not the autoloader was running, a scalar to put the
3649     # sub's return value in (if needed), and an array to put the sub's
3650     # return value in (if needed).
3651     my ( $al, $ret, @ret ) = "";
3652         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3653                 print "creating new thread\n";
3654         }
3655
3656     # If the last ten characters are '::AUTOLOAD', note we've traced
3657     # into AUTOLOAD for $sub.
3658     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3659         $al = " for $$sub" if defined $$sub;
3660     }
3661
3662     # We stack the stack pointer and then increment it to protect us
3663     # from a situation that might unwind a whole bunch of call frames
3664     # at once. Localizing the stack pointer means that it will automatically
3665     # unwind the same amount when multiple stack frames are unwound.
3666     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3667
3668     # Expand @stack.
3669     $#stack = $stack_depth;
3670
3671     # Save current single-step setting.
3672     $stack[-1] = $single;
3673
3674     # Turn off all flags except single-stepping.
3675     $single &= 1;
3676
3677     # If we've gotten really deeply recursed, turn on the flag that will
3678     # make us stop with the 'deep recursion' message.
3679     $single |= 4 if $stack_depth == $deep;
3680
3681     # If frame messages are on ...
3682     (
3683         $frame & 4    # Extended frame entry message
3684         ? (
3685             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3686
3687             # Why -1? But it works! :-(
3688             # Because print_trace will call add 1 to it and then call
3689             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3690             # in dump_trace.
3691             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3692           )
3693         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3694
3695           # standard frame entry message
3696       )
3697       if $frame;
3698
3699     # Determine the sub's return type,and capture approppriately.
3700     if (wantarray) {
3701
3702         # Called in array context. call sub and capture output.
3703         # DB::DB will recursively get control again if appropriate; we'll come
3704         # back here when the sub is finished.
3705         @ret = &$sub;
3706
3707         # Pop the single-step value back off the stack.
3708         $single |= $stack[ $stack_depth-- ];
3709
3710         # Check for exit trace messages...
3711         (
3712             $frame & 4    # Extended exit message
3713             ? (
3714                 print_lineinfo( ' ' x $stack_depth, "out " ),
3715                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3716               )
3717             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3718
3719               # Standard exit message
3720           )
3721           if $frame & 2;
3722
3723         # Print the return info if we need to.
3724         if ( $doret eq $stack_depth or $frame & 16 ) {
3725
3726             # Turn off output record separator.
3727             local $\ = '';
3728             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3729
3730             # Indent if we're printing because of $frame tracing.
3731             print $fh ' ' x $stack_depth if $frame & 16;
3732
3733             # Print the return value.
3734             print $fh "list context return from $sub:\n";
3735             dumpit( $fh, \@ret );
3736
3737             # And don't print it again.
3738             $doret = -2;
3739         } ## end if ($doret eq $stack_depth...
3740             # And we have to return the return value now.
3741         @ret;
3742     } ## end if (wantarray)
3743
3744     # Scalar context.
3745     else {
3746         if ( defined wantarray ) {
3747
3748             # Save the value if it's wanted at all.
3749             $ret = &$sub;
3750         }
3751         else {
3752
3753             # Void return, explicitly.
3754             &$sub;
3755             undef $ret;
3756         }
3757
3758         # Pop the single-step value off the stack.
3759         $single |= $stack[ $stack_depth-- ];
3760
3761         # If we're doing exit messages...
3762         (
3763             $frame & 4    # Extended messsages
3764             ? (
3765                 print_lineinfo( ' ' x $stack_depth, "out " ),
3766                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3767               )
3768             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3769
3770               # Standard messages
3771           )
3772           if $frame & 2;
3773
3774         # If we are supposed to show the return value... same as before.
3775         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3776             local $\ = '';
3777             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3778             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3779             print $fh (
3780                 defined wantarray
3781                 ? "scalar context return from $sub: "
3782                 : "void context return from $sub\n"
3783             );
3784             dumpit( $fh, $ret ) if defined wantarray;
3785             $doret = -2;
3786         } ## end if ($doret eq $stack_depth...
3787
3788         # Return the appropriate scalar value.
3789         $ret;
3790     } ## end else [ if (wantarray)
3791 } ## end sub sub
3792
3793 sub lsub : lvalue {
3794
3795         # lock ourselves under threads
3796         lock($DBGR);
3797
3798     # Whether or not the autoloader was running, a scalar to put the
3799     # sub's return value in (if needed), and an array to put the sub's
3800     # return value in (if needed).
3801     my ( $al, $ret, @ret ) = "";
3802         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3803                 print "creating new thread\n";
3804         }
3805
3806     # If the last ten characters are C'::AUTOLOAD', note we've traced
3807     # into AUTOLOAD for $sub.
3808     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3809         $al = " for $$sub";
3810     }
3811
3812     # We stack the stack pointer and then increment it to protect us
3813     # from a situation that might unwind a whole bunch of call frames
3814     # at once. Localizing the stack pointer means that it will automatically
3815     # unwind the same amount when multiple stack frames are unwound.
3816     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3817
3818     # Expand @stack.
3819     $#stack = $stack_depth;
3820
3821     # Save current single-step setting.
3822     $stack[-1] = $single;
3823
3824     # Turn off all flags except single-stepping.
3825     $single &= 1;
3826
3827     # If we've gotten really deeply recursed, turn on the flag that will
3828     # make us stop with the 'deep recursion' message.
3829     $single |= 4 if $stack_depth == $deep;
3830
3831     # If frame messages are on ...
3832     (
3833         $frame & 4    # Extended frame entry message
3834         ? (
3835             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3836
3837             # Why -1? But it works! :-(
3838             # Because print_trace will call add 1 to it and then call
3839             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3840             # in dump_trace.
3841             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3842           )
3843         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3844
3845           # standard frame entry message
3846       )
3847       if $frame;
3848
3849     # Pop the single-step value back off the stack.
3850     $single |= $stack[ $stack_depth-- ];
3851
3852     # call the original lvalue sub.
3853     &$sub;
3854 }
3855
3856 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3857
3858 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3859 Most of the changes were to systematize the command structure and to eliminate
3860 commands that threw away user input without checking.
3861
3862 The following sections describe the code added to make it easy to support
3863 multiple command sets with conflicting command names. This section is a start
3864 at unifying all command processing to make it simpler to develop commands.
3865
3866 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3867 number, and C<$dbline> (the current line) as arguments.
3868
3869 Support functions in this section which have multiple modes of failure C<die>
3870 on error; the rest simply return a false value.
3871
3872 The user-interface functions (all of the C<cmd_*> functions) just output
3873 error messages.
3874
3875 =head2 C<%set>
3876
3877 The C<%set> hash defines the mapping from command letter to subroutine
3878 name suffix.
3879
3880 C<%set> is a two-level hash, indexed by set name and then by command name.
3881 Note that trying to set the CommandSet to C<foobar> simply results in the
3882 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3883
3884 =cut
3885
3886 ### The API section
3887
3888 my %set = (    #
3889     'pre580' => {
3890         'a' => 'pre580_a',
3891         'A' => 'pre580_null',
3892         'b' => 'pre580_b',
3893         'B' => 'pre580_null',
3894         'd' => 'pre580_null',
3895         'D' => 'pre580_D',
3896         'h' => 'pre580_h',
3897         'M' => 'pre580_null',
3898         'O' => 'o',
3899         'o' => 'pre580_null',
3900         'v' => 'M',
3901         'w' => 'v',
3902         'W' => 'pre580_W',
3903     },
3904     'pre590' => {
3905         '<'  => 'pre590_prepost',
3906         '<<' => 'pre590_prepost',
3907         '>'  => 'pre590_prepost',
3908         '>>' => 'pre590_prepost',
3909         '{'  => 'pre590_prepost',
3910         '{{' => 'pre590_prepost',
3911     },
3912 );
3913
3914 =head2 C<cmd_wrapper()> (API)
3915
3916 C<cmd_wrapper()> allows the debugger to switch command sets
3917 depending on the value of the C<CommandSet> option.
3918
3919 It tries to look up the command in the C<%set> package-level I<lexical>
3920 (which means external entities can't fiddle with it) and create the name of
3921 the sub to call based on the value found in the hash (if it's there). I<All>
3922 of the commands to be handled in a set have to be added to C<%set>; if they
3923 aren't found, the 5.8.0 equivalent is called (if there is one).
3924
3925 This code uses symbolic references.
3926
3927 =cut
3928
3929 sub cmd_wrapper {
3930     my $cmd      = shift;
3931     my $line     = shift;
3932     my $dblineno = shift;
3933
3934     # Assemble the command subroutine's name by looking up the
3935     # command set and command name in %set. If we can't find it,
3936     # default to the older version of the command.
3937     my $call = 'cmd_'
3938       . ( $set{$CommandSet}{$cmd}
3939           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3940
3941     # Call the command subroutine, call it by name.
3942     return &$call( $cmd, $line, $dblineno );
3943 } ## end sub cmd_wrapper
3944
3945 =head3 C<cmd_a> (command)
3946
3947 The C<a> command handles pre-execution actions. These are associated with a
3948 particular line, so they're stored in C<%dbline>. We default to the current
3949 line if none is specified.
3950
3951 =cut
3952
3953 sub cmd_a {
3954     my $cmd    = shift;
3955     my $line   = shift || '';    # [.|line] expr
3956     my $dbline = shift;
3957
3958     # If it's dot (here), or not all digits,  use the current line.
3959     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3960
3961     # Should be a line number followed by an expression.
3962     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3963         my ( $lineno, $expr ) = ( $1, $2 );
3964
3965         # If we have an expression ...
3966         if ( length $expr ) {
3967
3968             # ... but the line isn't breakable, complain.
3969             if ( $dbline[$lineno] == 0 ) {
3970                 print $OUT
3971                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3972             }
3973             else {
3974
3975                 # It's executable. Record that the line has an action.
3976                 $had_breakpoints{$filename} |= 2;
3977
3978                 # Remove any action, temp breakpoint, etc.
3979                 $dbline{$lineno} =~ s/\0[^\0]*//;
3980
3981                 # Add the action to the line.
3982                 $dbline{$lineno} .= "\0" . action($expr);
3983             }
3984         } ## end if (length $expr)
3985     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3986     else {
3987
3988         # Syntax wrong.
3989         print $OUT
3990           "Adding an action requires an optional lineno and an expression\n"
3991           ;    # hint
3992     }
3993 } ## end sub cmd_a
3994
3995 =head3 C<cmd_A> (command)
3996
3997 Delete actions. Similar to above, except the delete code is in a separate
3998 subroutine, C<delete_action>.
3999
4000 =cut
4001
4002 sub cmd_A {
4003     my $cmd    = shift;
4004     my $line   = shift || '';
4005     my $dbline = shift;
4006
4007     # Dot is this line.
4008     $line =~ s/^\./$dbline/;
4009
4010     # Call delete_action with a null param to delete them all.
4011     # The '1' forces the eval to be true. It'll be false only
4012     # if delete_action blows up for some reason, in which case
4013     # we print $@ and get out.
4014     if ( $line eq '*' ) {
4015         eval { &delete_action(); 1 } or print $OUT $@ and return;
4016     }
4017
4018     # There's a real line  number. Pass it to delete_action.
4019     # Error trapping is as above.
4020     elsif ( $line =~ /^(\S.*)/ ) {
4021         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4022     }
4023
4024     # Swing and a miss. Bad syntax.
4025     else {
4026         print $OUT
4027           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4028     }
4029 } ## end sub cmd_A
4030
4031 =head3 C<delete_action> (API)
4032
4033 C<delete_action> accepts either a line number or C<undef>. If a line number
4034 is specified, we check for the line being executable (if it's not, it
4035 couldn't have had an  action). If it is, we just take the action off (this
4036 will get any kind of an action, including breakpoints).
4037
4038 =cut
4039
4040 sub delete_action {
4041     my $i = shift;
4042     if ( defined($i) ) {
4043
4044         # Can there be one?
4045         die "Line $i has no action .\n" if $dbline[$i] == 0;
4046
4047         # Nuke whatever's there.
4048         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4049         delete $dbline{$i} if $dbline{$i} eq '';
4050     }
4051     else {
4052         print $OUT "Deleting all actions...\n";
4053         for my $file ( keys %had_breakpoints ) {
4054             local *dbline = $main::{ '_<' . $file };
4055             my $max = $#dbline;
4056             my $was;
4057             for ( $i = 1 ; $i <= $max ; $i++ ) {
4058                 if ( defined $dbline{$i} ) {
4059                     $dbline{$i} =~ s/\0[^\0]*//;
4060                     delete $dbline{$i} if $dbline{$i} eq '';
4061                 }
4062                 unless ( $had_breakpoints{$file} &= ~2 ) {
4063                     delete $had_breakpoints{$file};
4064                 }
4065             } ## end for ($i = 1 ; $i <= $max...
4066         } ## end for my $file (keys %had_breakpoints)
4067     } ## end else [ if (defined($i))
4068 } ## end sub delete_action
4069
4070 =head3 C<cmd_b> (command)
4071
4072 Set breakpoints. Since breakpoints can be set in so many places, in so many
4073 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4074 we try to parse the command type, and then shuttle it off to an appropriate
4075 subroutine to actually do the work of setting the breakpoint in the right
4076 place.
4077
4078 =cut
4079
4080 sub cmd_b {
4081     my $cmd    = shift;
4082     my $line   = shift;    # [.|line] [cond]
4083     my $dbline = shift;
4084
4085     # Make . the current line number if it's there..
4086     $line =~ s/^\./$dbline/;
4087
4088     # No line number, no condition. Simple break on current line.
4089     if ( $line =~ /^\s*$/ ) {
4090         &cmd_b_line( $dbline, 1 );
4091     }
4092
4093     # Break on load for a file.
4094     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4095         my $file = $1;
4096         $file =~ s/\s+$//;
4097         &cmd_b_load($file);
4098     }
4099
4100     # b compile|postpone <some sub> [<condition>]
4101     # The interpreter actually traps this one for us; we just put the
4102     # necessary condition in the %postponed hash.
4103     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4104
4105         # Capture the condition if there is one. Make it true if none.
4106         my $cond = length $3 ? $3 : '1';
4107
4108         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4109         # if it was 'compile'.
4110         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4111
4112         # De-Perl4-ify the name - ' separators to ::.
4113         $subname =~ s/\'/::/g;
4114
4115         # Qualify it into the current package unless it's already qualified.
4116         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4117
4118         # Add main if it starts with ::.
4119         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4120
4121         # Save the break type for this sub.
4122         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4123     } ## end elsif ($line =~ ...
4124
4125     # b <sub name> [<condition>]
4126     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4127
4128         #
4129         $subname = $1;
4130         $cond = length $2 ? $2 : '1';
4131         &cmd_b_sub( $subname, $cond );
4132     }
4133
4134     # b <line> [<condition>].
4135     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4136
4137         # Capture the line. If none, it's the current line.
4138         $line = $1 || $dbline;
4139
4140         # If there's no condition, make it '1'.
4141         $cond = length $2 ? $2 : '1';
4142
4143         # Break on line.
4144         &cmd_b_line( $line, $cond );
4145     }
4146
4147     # Line didn't make sense.
4148     else {
4149         print "confused by line($line)?\n";
4150     }
4151 } ## end sub cmd_b
4152
4153 =head3 C<break_on_load> (API)
4154
4155 We want to break when this file is loaded. Mark this file in the
4156 C<%break_on_load> hash, and note that it has a breakpoint in
4157 C<%had_breakpoints>.
4158
4159 =cut
4160
4161 sub break_on_load {
4162     my $file = shift;
4163     $break_on_load{$file} = 1;
4164     $had_breakpoints{$file} |= 1;
4165 }
4166
4167 =head3 C<report_break_on_load> (API)
4168
4169 Gives us an array of filenames that are set to break on load. Note that
4170 only files with break-on-load are in here, so simply showing the keys
4171 suffices.
4172
4173 =cut
4174
4175 sub report_break_on_load {
4176     sort keys %break_on_load;
4177 }
4178
4179 =head3 C<cmd_b_load> (command)
4180
4181 We take the file passed in and try to find it in C<%INC> (which maps modules
4182 to files they came from). We mark those files for break-on-load via
4183 C<break_on_load> and then report that it was done.
4184
4185 =cut
4186
4187 sub cmd_b_load {
4188     my $file = shift;
4189     my @files;
4190
4191     # This is a block because that way we can use a redo inside it
4192     # even without there being any looping structure at all outside it.
4193     {
4194
4195         # Save short name and full path if found.
4196         push @files, $file;
4197         push @files, $::INC{$file} if $::INC{$file};
4198
4199         # Tack on .pm and do it again unless there was a '.' in the name
4200         # already.
4201         $file .= '.pm', redo unless $file =~ /\./;
4202     }
4203
4204     # Do the real work here.
4205     break_on_load($_) for @files;
4206
4207     # All the files that have break-on-load breakpoints.
4208     @files = report_break_on_load;
4209
4210     # Normalize for the purposes of our printing this.
4211     local $\ = '';
4212     local $" = ' ';
4213     print $OUT "Will stop on load of `@files'.\n";
4214 } ## end sub cmd_b_load
4215
4216 =head3 C<$filename_error> (API package global)
4217
4218 Several of the functions we need to implement in the API need to work both
4219 on the current file and on other files. We don't want to duplicate code, so
4220 C<$filename_error> is used to contain the name of the file that's being
4221 worked on (if it's not the current one).
4222
4223 We can now build functions in pairs: the basic function works on the current
4224 file, and uses C<$filename_error> as part of its error message. Since this is
4225 initialized to C<"">, no filename will appear when we are working on the
4226 current file.
4227
4228 The second function is a wrapper which does the following:
4229
4230 =over 4
4231
4232 =item *
4233
4234 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4235
4236 =item *
4237
4238 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4239
4240 =item *
4241
4242 Calls the first function.
4243
4244 The first function works on the I<current> file (i.e., the one we changed to),
4245 and prints C<$filename_error> in the error message (the name of the other file)
4246 if it needs to. When the functions return, C<*dbline> is restored to point
4247 to the actual current file (the one we're executing in) and
4248 C<$filename_error> is restored to C<"">. This restores everything to
4249 the way it was before the second function was called at all.
4250
4251 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4252 details.
4253
4254 =back
4255
4256 =cut
4257
4258 $filename_error = '';
4259
4260 =head3 breakable_line(from, to) (API)
4261
4262 The subroutine decides whether or not a line in the current file is breakable.
4263 It walks through C<@dbline> within the range of lines specified, looking for
4264 the first line that is breakable.
4265
4266 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4267 first line I<after> C<$to> that's breakable, if there is one.
4268
4269 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4270 first line I<before> C<$to> that's breakable, if there is one.
4271
4272 =cut
4273
4274 sub breakable_line {
4275
4276     my ( $from, $to ) = @_;
4277
4278     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4279     my $i = $from;
4280
4281     # If there are at least 2 arguments, we're trying to search a range.
4282     if ( @_ >= 2 ) {
4283
4284         # $delta is positive for a forward search, negative for a backward one.
4285         my $delta = $from < $to ? +1 : -1;
4286
4287         # Keep us from running off the ends of the file.
4288         my $limit = $delta > 0 ? $#dbline : 1;
4289
4290         # Clever test. If you're a mathematician, it's obvious why this
4291         # test works. If not:
4292         # If $delta is positive (going forward), $limit will be $#dbline.
4293         #    If $to is less than $limit, ($limit - $to) will be positive, times
4294         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4295         #    as the stopping point.
4296         #
4297         #    If $to is greater than $limit, ($limit - $to) is negative,
4298         #    times $delta of 1 (positive), so the result is < 0 and we should
4299         #    use $limit ($#dbline) as the stopping point.
4300         #
4301         # If $delta is negative (going backward), $limit will be 1.
4302         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4303         #    (negative) so the result is > 0, and we use $to as the stopping
4304         #    point.
4305         #
4306         #    If $to is less than zero, ($limit - $to) will be positive,
4307         #    times $delta of -1 (negative), so the result is not > 0, and
4308         #    we use $limit (1) as the stopping point.
4309         #
4310         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4311         #    (negative), still giving zero; the result is not > 0, and
4312         #    we use $limit (1) as the stopping point.
4313         #
4314         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4315         #    (negative), giving a positive (>0) value, so we'll set $limit to
4316         #    $to.
4317
4318         $limit = $to if ( $limit - $to ) * $delta > 0;
4319
4320         # The real search loop.
4321         # $i starts at $from (the point we want to start searching from).
4322         # We move through @dbline in the appropriate direction (determined
4323         # by $delta: either -1 (back) or +1 (ahead).
4324         # We stay in as long as we haven't hit an executable line
4325         # ($dbline[$i] == 0 means not executable) and we haven't reached
4326         # the limit yet (test similar to the above).
4327         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4328
4329     } ## end if (@_ >= 2)
4330
4331     # If $i points to a line that is executable, return that.
4332     return $i unless $dbline[$i] == 0;
4333
4334     # Format the message and print it: no breakable lines in range.
4335     my ( $pl, $upto ) = ( '', '' );
4336     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4337
4338     # If there's a filename in filename_error, we'll see it.
4339     # If not, not.
4340     die "Line$pl $from$upto$filename_error not breakable\n";
4341 } ## end sub breakable_line
4342
4343 =head3 breakable_line_in_filename(file, from, to) (API)
4344
4345 Like C<breakable_line>, but look in another file.
4346
4347 =cut
4348
4349 sub breakable_line_in_filename {
4350
4351     # Capture the file name.
4352     my ($f) = shift;
4353
4354     # Swap the magic line array over there temporarily.
4355     local *dbline = $main::{ '_<' . $f };
4356
4357     # If there's an error, it's in this other file.
4358     local $filename_error = " of `$f'";
4359
4360     # Find the breakable line.
4361     breakable_line(@_);
4362
4363     # *dbline and $filename_error get restored when this block ends.
4364
4365 } ## end sub breakable_line_in_filename
4366
4367 =head3 break_on_line(lineno, [condition]) (API)
4368
4369 Adds a breakpoint with the specified condition (or 1 if no condition was
4370 specified) to the specified line. Dies if it can't.
4371
4372 =cut
4373
4374 sub break_on_line {
4375     my ( $i, $cond ) = @_;
4376
4377     # Always true if no condition supplied.
4378     $cond = 1 unless @_ >= 2;
4379
4380     my $inii  = $i;
4381     my $after = '';
4382     my $pl    = '';
4383
4384     # Woops, not a breakable line. $filename_error allows us to say
4385     # if it was in a different file.
4386     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4387
4388     # Mark this file as having breakpoints in it.
4389     $had_breakpoints{$filename} |= 1;
4390
4391     # If there is an action or condition here already ...
4392     if ( $dbline{$i} ) {
4393
4394         # ... swap this condition for the existing one.
4395         $dbline{$i} =~ s/^[^\0]*/$cond/;
4396     }
4397     else {
4398
4399         # Nothing here - just add the condition.
4400         $dbline{$i} = $cond;
4401     }
4402 } ## end sub break_on_line
4403
4404 =head3 cmd_b_line(line, [condition]) (command)
4405
4406 Wrapper for C<break_on_line>. Prints the failure message if it
4407 doesn't work.
4408
4409 =cut
4410
4411 sub cmd_b_line {
4412     eval { break_on_line(@_); 1 } or do {
4413         local $\ = '';
4414         print $OUT $@ and return;
4415     };
4416 } ## end sub cmd_b_line
4417
4418 =head3 break_on_filename_line(file, line, [condition]) (API)
4419
4420 Switches to the file specified and then calls C<break_on_line> to set
4421 the breakpoint.
4422
4423 =cut
4424
4425 sub break_on_filename_line {
4426     my ( $f, $i, $cond ) = @_;
4427
4428     # Always true if condition left off.
4429     $cond = 1 unless @_ >= 3;
4430
4431     # Switch the magical hash temporarily.
4432     local *dbline = $main::{ '_<' . $f };
4433
4434     # Localize the variables that break_on_line uses to make its message.
4435     local $filename_error = " of `$f'";
4436     local $filename       = $f;
4437
4438     # Add the breakpoint.
4439     break_on_line( $i, $cond );
4440 } ## end sub break_on_filename_line
4441
4442 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4443
4444 Switch to another file, search the range of lines specified for an
4445 executable one, and put a breakpoint on the first one you find.
4446
4447 =cut
4448
4449 sub break_on_filename_line_range {
4450     my ( $f, $from, $to, $cond ) = @_;
4451
4452     # Find a breakable line if there is one.
4453     my $i = breakable_line_in_filename( $f, $from, $to );
4454
4455     # Always true if missing.
4456     $cond = 1 unless @_ >= 3;
4457
4458     # Add the breakpoint.
4459     break_on_filename_line( $f, $i, $cond );
4460 } ## end sub break_on_filename_line_range
4461
4462 =head3 subroutine_filename_lines(subname, [condition]) (API)
4463
4464 Search for a subroutine within a given file. The condition is ignored.
4465 Uses C<find_sub> to locate the desired subroutine.
4466
4467 =cut
4468
4469 sub subroutine_filename_lines {
4470     my ( $subname, $cond ) = @_;
4471
4472     # Returned value from find_sub() is fullpathname:startline-endline.
4473     # The match creates the list (fullpathname, start, end). Falling off
4474     # the end of the subroutine returns this implicitly.
4475     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4476 } ## end sub subroutine_filename_lines
4477
4478 =head3 break_subroutine(subname) (API)
4479
4480 Places a break on the first line possible in the specified subroutine. Uses
4481 C<subroutine_filename_lines> to find the subroutine, and
4482 C<break_on_filename_line_range> to place the break.
4483
4484 =cut
4485
4486 sub break_subroutine {
4487     my $subname = shift;
4488
4489     # Get filename, start, and end.
4490     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4491       or die "Subroutine $subname not found.\n";
4492
4493     # Null condition changes to '1' (always true).
4494     $cond = 1 unless @_ >= 2;
4495
4496     # Put a break the first place possible in the range of lines
4497     # that make up this subroutine.
4498     break_on_filename_line_range( $file, $s, $e, @_ );
4499 } ## end sub break_subroutine
4500
4501 =head3 cmd_b_sub(subname, [condition]) (command)
4502
4503 We take the incoming subroutine name and fully-qualify it as best we can.
4504
4505 =over 4
4506
4507 =item 1. If it's already fully-qualified, leave it alone.
4508
4509 =item 2. Try putting it in the current package.
4510
4511 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4512
4513 =item 4. If it starts with '::', put it in 'main::'.
4514
4515 =back
4516
4517 After all this cleanup, we call C<break_subroutine> to try to set the
4518 breakpoint.
4519
4520 =cut
4521
4522 sub cmd_b_sub {
4523     my ( $subname, $cond ) = @_;
4524
4525     # Add always-true condition if we have none.
4526     $cond = 1 unless @_ >= 2;
4527
4528     # If the subname isn't a code reference, qualify it so that
4529     # break_subroutine() will work right.
4530     unless ( ref $subname eq 'CODE' ) {
4531
4532         # Not Perl4.
4533         $subname =~ s/\'/::/g;
4534         my $s = $subname;
4535
4536         # Put it in this package unless it's already qualified.
4537         $subname = "${'package'}::" . $subname
4538           unless $subname =~ /::/;
4539
4540         # Requalify it into CORE::GLOBAL if qualifying it into this
4541         # package resulted in its not being defined, but only do so
4542         # if it really is in CORE::GLOBAL.
4543         $subname = "CORE::GLOBAL::$s"
4544           if not defined &$subname
4545           and $s !~ /::/
4546           and defined &{"CORE::GLOBAL::$s"};
4547
4548         # Put it in package 'main' if it has a leading ::.
4549         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4550
4551     } ## end unless (ref $subname eq 'CODE')
4552
4553     # Try to set the breakpoint.
4554     eval { break_subroutine( $subname, $cond ); 1 } or do {
4555         local $\ = '';
4556         print $OUT $@ and return;
4557       }
4558 } ## end sub cmd_b_sub
4559
4560 =head3 C<cmd_B> - delete breakpoint(s) (command)
4561
4562 The command mostly parses the command line and tries to turn the argument
4563 into a line spec. If it can't, it uses the current line. It then calls
4564 C<delete_breakpoint> to actually do the work.
4565
4566 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4567 thereby deleting all the breakpoints.
4568
4569 =cut
4570
4571 sub cmd_B {
4572     my $cmd = shift;
4573
4574     # No line spec? Use dbline.
4575     # If there is one, use it if it's non-zero, or wipe it out if it is.
4576     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4577     my $dbline = shift;
4578
4579     # If the line was dot, make the line the current one.
4580     $line =~ s/^\./$dbline/;
4581
4582     # If it's * we're deleting all the breakpoints.
4583     if ( $line eq '*' ) {
4584         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4585     }
4586
4587     # If there is a line spec, delete the breakpoint on that line.
4588     elsif ( $line =~ /^(\S.*)/ ) {
4589         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4590             local $\ = '';
4591             print $OUT $@ and return;
4592         };
4593     } ## end elsif ($line =~ /^(\S.*)/)
4594
4595     # No line spec.
4596     else {
4597         print $OUT
4598           "Deleting a breakpoint requires a line number, or '*' for all\n"
4599           ;    # hint
4600     }
4601 } ## end sub cmd_B
4602
4603 =head3 delete_breakpoint([line]) (API)
4604
4605 This actually does the work of deleting either a single breakpoint, or all
4606 of them.
4607
4608 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4609 just drop out with a message saying so. If it is, we remove the condition
4610 part of the 'condition\0action' that says there's a breakpoint here. If,
4611 after we've done that, there's nothing left, we delete the corresponding
4612 line in C<%dbline> to signal that no action needs to be taken for this line.
4613
4614 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4615 which lists all currently-loaded files which have breakpoints. We then look
4616 at each line in each of these files, temporarily switching the C<%dbline>
4617 and C<@dbline> structures to point to the files in question, and do what
4618 we did in the single line case: delete the condition in C<@dbline>, and
4619 delete the key in C<%dbline> if nothing's left.
4620
4621 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4622 C<%break_on_load>, because these structures contain breakpoints for files
4623 and code that haven't been loaded yet. We can just kill these off because there
4624 are no magical debugger structures associated with them.
4625
4626 =cut
4627
4628 sub delete_breakpoint {
4629     my $i = shift;
4630
4631     # If we got a line, delete just that one.
4632     if ( defined($i) ) {
4633
4634         # Woops. This line wasn't breakable at all.
4635         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4636
4637         # Kill the condition, but leave any action.
4638         $dbline{$i} =~ s/^[^\0]*//;
4639
4640         # Remove the entry entirely if there's no action left.
4641         delete $dbline{$i} if $dbline{$i} eq '';
4642     }
4643
4644     # No line; delete them all.
4645     else {
4646         print $OUT "Deleting all breakpoints...\n";
4647
4648         # %had_breakpoints lists every file that had at least one
4649         # breakpoint in it.
4650         for my $file ( keys %had_breakpoints ) {
4651
4652             # Switch to the desired file temporarily.
4653             local *dbline = $main::{ '_<' . $file };
4654
4655             my $max = $#dbline;
4656             my $was;
4657
4658             # For all lines in this file ...
4659             for ( $i = 1 ; $i <= $max ; $i++ ) {
4660
4661                 # If there's a breakpoint or action on this line ...
4662                 if ( defined $dbline{$i} ) {
4663
4664                     # ... remove the breakpoint.
4665                     $dbline{$i} =~ s/^[^\0]+//;
4666                     if ( $dbline{$i} =~ s/^\0?$// ) {
4667
4668                         # Remove the entry altogether if no action is there.
4669                         delete $dbline{$i};
4670                     }
4671                 } ## end if (defined $dbline{$i...
4672             } ## end for ($i = 1 ; $i <= $max...
4673
4674             # If, after we turn off the "there were breakpoints in this file"
4675             # bit, the entry in %had_breakpoints for this file is zero,
4676             # we should remove this file from the hash.
4677             if ( not $had_breakpoints{$file} &= ~1 ) {
4678                 delete $had_breakpoints{$file};
4679             }
4680         } ## end for my $file (keys %had_breakpoints)
4681
4682         # Kill off all the other breakpoints that are waiting for files that
4683         # haven't been loaded yet.
4684         undef %postponed;
4685         undef %postponed_file;
4686         undef %break_on_load;
4687     } ## end else [ if (defined($i))
4688 } ## end sub delete_breakpoint
4689
4690 =head3 cmd_stop (command)
4691
4692 This is meant to be part of the new command API, but it isn't called or used
4693 anywhere else in the debugger. XXX It is probably meant for use in development
4694 of new commands.
4695
4696 =cut
4697
4698 sub cmd_stop {    # As on ^C, but not signal-safy.
4699     $signal = 1;
4700 }
4701
4702 =head3 C<cmd_e> - threads
4703
4704 Display the current thread id:
4705
4706         e
4707
4708 This could be how (when implemented) to send commands to this thread id (e cmd)
4709 or that thread id (e tid cmd).
4710
4711 =cut
4712
4713 sub cmd_e {
4714     my $cmd  = shift;
4715     my $line = shift;
4716         unless (exists($INC{'threads.pm'})) {
4717                 print "threads not loaded($ENV{PERL5DB_THREADED})
4718                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4719         } else {
4720                 my $tid = threads->tid;
4721                 print "thread id: $tid\n";
4722         }
4723 } ## end sub cmd_e
4724
4725 =head3 C<cmd_E> - list of thread ids
4726
4727 Display the list of available thread ids:
4728
4729         E
4730
4731 This could be used (when implemented) to send commands to all threads (E cmd).
4732
4733 =cut
4734
4735 sub cmd_E {
4736     my $cmd  = shift;
4737     my $line = shift;
4738         unless (exists($INC{'threads.pm'})) {
4739                 print "threads not loaded($ENV{PERL5DB_THREADED})
4740                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4741         } else {
4742                 my $tid = threads->tid;
4743                 print "thread ids: ".join(', ',
4744                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4745                 )."\n";
4746         }
4747 } ## end sub cmd_E
4748
4749 =head3 C<cmd_h> - help command (command)
4750
4751 Does the work of either
4752
4753 =over 4
4754
4755 =item *
4756
4757 Showing all the debugger help
4758
4759 =item *
4760
4761 Showing help for a specific command
4762
4763 =back
4764
4765 =cut
4766
4767 sub cmd_h {
4768     my $cmd = shift;
4769
4770     # If we have no operand, assume null.
4771     my $line = shift || '';
4772
4773     # 'h h'. Print the long-format help.
4774     if ( $line =~ /^h\s*/ ) {
4775         print_help($help);
4776     }
4777
4778     # 'h <something>'. Search for the command and print only its help.
4779     elsif ( $line =~ /^(\S.*)$/ ) {
4780
4781         # support long commands; otherwise bogus errors
4782         # happen when you ask for h on <CR> for example
4783         my $asked = $1;    # the command requested
4784                            # (for proper error message)
4785
4786         my $qasked = quotemeta($asked);    # for searching; we don't
4787                                            # want to use it as a pattern.
4788                                            # XXX: finds CR but not <CR>
4789
4790         # Search the help string for the command.
4791         if (
4792             $help =~ /^                    # Start of a line
4793                       <?                   # Optional '<'
4794                       (?:[IB]<)            # Optional markup
4795                       $qasked              # The requested command
4796                      /mx
4797           )
4798         {
4799
4800             # It's there; pull it out and print it.
4801             while (
4802                 $help =~ /^
4803                               (<?            # Optional '<'
4804                                  (?:[IB]<)   # Optional markup
4805                                  $qasked     # The command
4806                                  ([\s\S]*?)  # Description line(s)
4807                               \n)            # End of last description line
4808                               (?!\s)         # Next line not starting with
4809                                              # whitespace
4810                              /mgx
4811               )
4812             {
4813                 print_help($1);
4814             }
4815         }
4816
4817         # Not found; not a debugger command.
4818         else {
4819             print_help("B<$asked> is not a debugger command.\n");
4820         }
4821     } ## end elsif ($line =~ /^(\S.*)$/)
4822
4823     # 'h' - print the summary help.
4824     else {
4825         print_help($summary);
4826     }
4827 } ## end sub cmd_h
4828
4829 =head3 C<cmd_i> - inheritance display
4830
4831 Display the (nested) parentage of the module or object given.
4832
4833 =cut
4834
4835 sub cmd_i {
4836     my $cmd  = shift;
4837     my $line = shift;
4838     eval { require Class::ISA };
4839     if ($@) {
4840         &warn( $@ =~ /locate/
4841             ? "Class::ISA module not found - please install\n"
4842             : $@ );
4843     }
4844     else {
4845       ISA:
4846         foreach my $isa ( split( /\s+/, $line ) ) {
4847             $evalarg = $isa;
4848             ($isa) = &eval;
4849             no strict 'refs';
4850             print join(
4851                 ', ',
4852                 map {    # snaffled unceremoniously from Class::ISA
4853                     "$_"
4854                       . (
4855                         defined( ${"$_\::VERSION"} )
4856                         ? ' ' . ${"$_\::VERSION"}
4857                         : undef )
4858                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4859             );
4860             print "\n";
4861         }
4862     }
4863 } ## end sub cmd_i
4864
4865 =head3 C<cmd_l> - list lines (command)
4866
4867 Most of the command is taken up with transforming all the different line
4868 specification syntaxes into 'start-stop'. After that is done, the command
4869 runs a loop over C<@dbline> for the specified range of lines. It handles
4870 the printing of each line and any markers (C<==E<gt>> for current line,
4871 C<b> for break on this line, C<a> for action on this line, C<:> for this
4872 line breakable).
4873
4874 We save the last line listed in the C<$start> global for further listing
4875 later.
4876
4877 =cut
4878
4879 sub cmd_l {
4880     my $current_line = $line;
4881     my $cmd  = shift;
4882     my $line = shift;
4883
4884     # If this is '-something', delete any spaces after the dash.
4885     $line =~ s/^-\s*$/-/;
4886
4887     # If the line is '$something', assume this is a scalar containing a
4888     # line number.
4889     if ( $line =~ /^(\$.*)/s ) {
4890
4891         # Set up for DB::eval() - evaluate in *user* context.
4892         $evalarg = $1;
4893         # $evalarg = $2;
4894         my ($s) = &eval;
4895
4896         # Ooops. Bad scalar.
4897         print( $OUT "Error: $@\n" ), next CMD if $@;
4898
4899         # Good scalar. If it's a reference, find what it points to.
4900         $s = CvGV_name($s);
4901         print( $OUT "Interpreted as: $1 $s\n" );
4902         $line = "$1 $s";
4903
4904         # Call self recursively to really do the command.
4905         &cmd_l( 'l', $s );
4906     } ## end if ($line =~ /^(\$.*)/s)
4907
4908     # l name. Try to find a sub by that name.
4909     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4910         my $s = $subname = $1;
4911
4912         # De-Perl4.
4913         $subname =~ s/\'/::/;
4914
4915         # Put it in this package unless it starts with ::.
4916         $subname = $package . "::" . $subname unless $subname =~ /::/;
4917
4918         # Put it in CORE::GLOBAL if t doesn't start with :: and
4919         # it doesn't live in this package and it lives in CORE::GLOBAL.
4920         $subname = "CORE::GLOBAL::$s"
4921           if not defined &$subname
4922           and $s !~ /::/
4923           and defined &{"CORE::GLOBAL::$s"};
4924
4925         # Put leading '::' names into 'main::'.
4926         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4927
4928         # Get name:start-stop from find_sub, and break this up at
4929         # colons.
4930         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4931
4932         # Pull off start-stop.
4933         $subrange = pop @pieces;
4934
4935         # If the name contained colons, the split broke it up.
4936         # Put it back together.
4937         $file = join( ':', @pieces );
4938
4939         # If we're not in that file, switch over to it.
4940         if ( $file ne $filename ) {
4941             print $OUT "Switching to file '$file'.\n"
4942               unless $slave_editor;
4943
4944             # Switch debugger's magic structures.
4945             *dbline   = $main::{ '_<' . $file };
4946             $max      = $#dbline;
4947             $filename = $file;
4948         } ## end if ($file ne $filename)
4949
4950         # Subrange is 'start-stop'. If this is less than a window full,
4951         # swap it to 'start+', which will list a window from the start point.
4952         if ($subrange) {
4953             if ( eval($subrange) < -$window ) {
4954                 $subrange =~ s/-.*/+/;
4955             }
4956
4957             # Call self recursively to list the range.
4958             $line = $subrange;
4959             &cmd_l( 'l', $subrange );
4960         } ## end if ($subrange)
4961
4962         # Couldn't find it.
4963         else {
4964             print $OUT "Subroutine $subname not found.\n";
4965         }
4966     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4967
4968     # Bare 'l' command.
4969     elsif ( $line =~ /^\s*$/ ) {
4970
4971         # Compute new range to list.
4972         $incr = $window - 1;
4973         $line = $start . '-' . ( $start + $incr );
4974
4975         # Recurse to do it.
4976         &cmd_l( 'l', $line );
4977     }
4978
4979     # l [start]+number_of_lines
4980     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4981
4982         # Don't reset start for 'l +nnn'.
4983         $start = $1 if $1;
4984
4985         # Increment for list. Use window size if not specified.
4986         # (Allows 'l +' to work.)
4987         $incr = $2;
4988         $incr = $window - 1 unless $incr;
4989
4990         # Create a line range we'll understand, and recurse to do it.
4991         $line = $start . '-' . ( $start + $incr );
4992         &cmd_l( 'l', $line );
4993     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4994
4995     # l start-stop or l start,stop
4996     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4997
4998         # Determine end point; use end of file if not specified.
4999         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5000
5001         # Go on to the end, and then stop.
5002         $end = $max if $end > $max;
5003
5004         # Determine start line.
5005         $i    = $2;
5006         $i    = $line if $i eq '.';
5007         $i    = 1 if $i < 1;
5008         $incr = $end - $i;
5009
5010         # If we're running under a slave editor, force it to show the lines.
5011         if ($slave_editor) {
5012             print $OUT "\032\032$filename:$i:0\n";
5013             $i = $end;
5014         }
5015
5016         # We're doing it ourselves. We want to show the line and special
5017         # markers for:
5018         # - the current line in execution
5019         # - whether a line is breakable or not
5020         # - whether a line has a break or not
5021         # - whether a line has an action or not
5022         else {
5023             for ( ; $i <= $end ; $i++ ) {
5024
5025                 # Check for breakpoints and actions.
5026                 my ( $stop, $action );
5027                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5028                   if $dbline{$i};
5029
5030                 # ==> if this is the current line in execution,
5031                 # : if it's breakable.
5032                 $arrow =
5033                   ( $i == $current_line and $filename eq $filename_ini )
5034                   ? '==>'
5035                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5036
5037                 # Add break and action indicators.
5038                 $arrow .= 'b' if $stop;
5039                 $arrow .= 'a' if $action;
5040
5041                 # Print the line.
5042                 print $OUT "$i$arrow\t", $dbline[$i];
5043
5044                 # Move on to the next line. Drop out on an interrupt.
5045                 $i++, last if $signal;
5046             } ## end for (; $i <= $end ; $i++)
5047
5048             # Line the prompt up; print a newline if the last line listed
5049             # didn't have a newline.
5050             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5051         } ## end else [ if ($slave_editor)
5052
5053         # Save the point we last listed to in case another relative 'l'
5054         # command is desired. Don't let it run off the end.
5055         $start = $i;
5056         $start = $max if $start > $max;
5057     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5058 } ## end sub cmd_l
5059
5060 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5061
5062 To list breakpoints, the command has to look determine where all of them are
5063 first. It starts a C<%had_breakpoints>, which tells us what all files have
5064 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5065 magic source and breakpoint data structures) to the file, and then look
5066 through C<%dbline> for lines with breakpoints and/or actions, listing them
5067 out. We look through C<%postponed> not-yet-compiled subroutines that have
5068 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5069 that have breakpoints.
5070
5071 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5072
5073 =cut
5074
5075 sub cmd_L {
5076     my $cmd = shift;
5077
5078     # If no argument, list everything. Pre-5.8.0 version always lists
5079     # everything
5080     my $arg = shift || 'abw';
5081     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5082
5083     # See what is wanted.
5084     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5085     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5086     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5087
5088     # Breaks and actions are found together, so we look in the same place
5089     # for both.
5090     if ( $break_wanted or $action_wanted ) {
5091
5092         # Look in all the files with breakpoints...
5093         for my $file ( keys %had_breakpoints ) {
5094
5095             # Temporary switch to this file.
5096             local *dbline = $main::{ '_<' . $file };
5097
5098             # Set up to look through the whole file.
5099             my $max = $#dbline;
5100             my $was;    # Flag: did we print something
5101                         # in this file?
5102
5103             # For each line in the file ...
5104             for ( $i = 1 ; $i <= $max ; $i++ ) {
5105
5106                 # We've got something on this line.
5107                 if ( defined $dbline{$i} ) {
5108
5109                     # Print the header if we haven't.
5110                     print $OUT "$file:\n" unless $was++;
5111
5112                     # Print the line.
5113                     print $OUT " $i:\t", $dbline[$i];
5114
5115                     # Pull out the condition and the action.
5116                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5117
5118                     # Print the break if there is one and it's wanted.
5119                     print $OUT "   break if (", $stop, ")\n"
5120                       if $stop
5121                       and $break_wanted;
5122
5123                     # Print the action if there is one and it's wanted.
5124                     print $OUT "   action:  ", $action, "\n"
5125                       if $action
5126                       and $action_wanted;
5127
5128                     # Quit if the user hit interrupt.
5129                     last if $signal;
5130                 } ## end if (defined $dbline{$i...
5131             } ## end for ($i = 1 ; $i <= $max...
5132         } ## end for my $file (keys %had_breakpoints)
5133     } ## end if ($break_wanted or $action_wanted)
5134
5135     # Look for breaks in not-yet-compiled subs:
5136     if ( %postponed and $break_wanted ) {
5137         print $OUT "Postponed breakpoints in subroutines:\n";
5138         my $subname;
5139         for $subname ( keys %postponed ) {
5140             print $OUT " $subname\t$postponed{$subname}\n";
5141             last if $signal;
5142         }
5143     } ## end if (%postponed and $break_wanted)
5144
5145     # Find files that have not-yet-loaded breaks:
5146     my @have = map {    # Combined keys
5147         keys %{ $postponed_file{$_} }
5148     } keys %postponed_file;
5149
5150     # If there are any, list them.
5151     if ( @have and ( $break_wanted or $action_wanted ) ) {
5152         print $OUT "Postponed breakpoints in files:\n";
5153         my ( $file, $line );
5154
5155         for $file ( keys %postponed_file ) {
5156             my $db = $postponed_file{$file};
5157             print $OUT " $file:\n";
5158             for $line ( sort { $a <=> $b } keys %$db ) {
5159                 print $OUT "  $line:\n";
5160                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5161                 print $OUT "    break if (", $stop, ")\n"
5162                   if $stop
5163                   and $break_wanted;
5164                 print $OUT "    action:  ", $action, "\n"
5165                   if $action
5166                   and $action_wanted;
5167                 last if $signal;
5168             } ## end for $line (sort { $a <=>...
5169             last if $signal;
5170         } ## end for $file (keys %postponed_file)
5171     } ## end if (@have and ($break_wanted...
5172     if ( %break_on_load and $break_wanted ) {
5173         print $OUT "Breakpoints on load:\n";
5174         my $file;
5175         for $file ( keys %break_on_load ) {
5176             print $OUT " $file\n";
5177             last if $signal;
5178         }
5179     } ## end if (%break_on_load and...
5180     if ($watch_wanted) {
5181         if ( $trace & 2 ) {
5182             print $OUT "Watch-expressions:\n" if @to_watch;
5183             for my $expr (@to_watch) {
5184                 print $OUT " $expr\n";
5185                 last if $signal;
5186             }
5187         } ## end if ($trace & 2)
5188     } ## end if ($watch_wanted)
5189 } ## end sub cmd_L
5190
5191 =head3 C<cmd_M> - list modules (command)
5192
5193 Just call C<list_modules>.
5194
5195 =cut
5196
5197 sub cmd_M {
5198     &list_modules();
5199 }
5200
5201 =head3 C<cmd_o> - options (command)
5202
5203 If this is just C<o> by itself, we list the current settings via
5204 C<dump_option>. If there's a nonblank value following it, we pass that on to
5205 C<parse_options> for processing.
5206
5207 =cut
5208
5209 sub cmd_o {
5210     my $cmd = shift;
5211     my $opt = shift || '';    # opt[=val]
5212
5213     # Nonblank. Try to parse and process.
5214     if ( $opt =~ /^(\S.*)/ ) {
5215         &parse_options($1);
5216     }
5217
5218     # Blank. List the current option settings.
5219     else {
5220         for (@options) {
5221             &dump_option($_);
5222         }
5223     }
5224 } ## end sub cmd_o
5225
5226 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5227
5228 Advises the user that the O command has been renamed.
5229
5230 =cut
5231
5232 sub cmd_O {
5233     print $OUT "The old O command is now the o command.\n";             # hint
5234     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5235     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5236 }
5237
5238 =head3 C<cmd_v> - view window (command)
5239
5240 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5241 move back a few lines to list the selected line in context. Uses C<cmd_l>
5242 to do the actual listing after figuring out the range of line to request.
5243
5244 =cut
5245
5246 sub cmd_v {
5247     my $cmd  = shift;
5248     my $line = shift;
5249
5250     # Extract the line to list around. (Astute readers will have noted that
5251     # this pattern will match whether or not a numeric line is specified,
5252     # which means that we'll always enter this loop (though a non-numeric
5253     # argument results in no action at all)).
5254     if ( $line =~ /^(\d*)$/ ) {
5255
5256         # Total number of lines to list (a windowful).
5257         $incr = $window - 1;
5258
5259         # Set the start to the argument given (if there was one).
5260         $start = $1 if $1;
5261
5262         # Back up by the context amount.
5263         $start -= $preview;
5264
5265         # Put together a linespec that cmd_l will like.
5266         $line = $start . '-' . ( $start + $incr );
5267
5268         # List the lines.
5269         &cmd_l( 'l', $line );
5270     } ## end if ($line =~ /^(\d*)$/)
5271 } ## end sub cmd_v
5272
5273 =head3 C<cmd_w> - add a watch expression (command)
5274
5275 The 5.8 version of this command adds a watch expression if one is specified;
5276 it does nothing if entered with no operands.
5277
5278 We extract the expression, save it, evaluate it in the user's context, and
5279 save the value. We'll re-evaluate it each time the debugger passes a line,
5280 and will stop (see the code at the top of the command loop) if the value
5281 of any of the expressions changes.
5282
5283 =cut
5284
5285 sub cmd_w {
5286     my $cmd = shift;
5287
5288     # Null expression if no arguments.
5289     my $expr = shift || '';
5290
5291     # If expression is not null ...
5292     if ( $expr =~ /^(\S.*)/ ) {
5293
5294         # ... save it.
5295         push @to_watch, $expr;
5296
5297         # Parameterize DB::eval and call it to get the expression's value
5298         # in the user's context. This version can handle expressions which
5299         # return a list value.
5300         $evalarg = $expr;
5301         my ($val) = join( ' ', &eval );
5302         $val = ( defined $val ) ? "'$val'" : 'undef';
5303
5304         # Save the current value of the expression.
5305         push @old_watch, $val;
5306
5307         # We are now watching expressions.
5308         $trace |= 2;
5309     } ## end if ($expr =~ /^(\S.*)/)
5310
5311     # You have to give one to get one.
5312     else {
5313         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5314     }
5315 } ## end sub cmd_w
5316
5317 =head3 C<cmd_W> - delete watch expressions (command)
5318
5319 This command accepts either a watch expression to be removed from the list
5320 of watch expressions, or C<*> to delete them all.
5321
5322 If C<*> is specified, we simply empty the watch expression list and the
5323 watch expression value list. We also turn off the bit that says we've got
5324 watch expressions.
5325
5326 If an expression (or partial expression) is specified, we pattern-match
5327 through the expressions and remove the ones that match. We also discard
5328 the corresponding values. If no watch expressions are left, we turn off
5329 the I<watching expressions> bit.
5330
5331 =cut
5332
5333 sub cmd_W {
5334     my $cmd  = shift;
5335     my $expr = shift || '';
5336
5337     # Delete them all.
5338     if ( $expr eq '*' ) {
5339
5340         # Not watching now.
5341         $trace &= ~2;
5342
5343         print $OUT "Deleting all watch expressions ...\n";
5344
5345         # And all gone.
5346         @to_watch = @old_watch = ();
5347     }
5348
5349     # Delete one of them.
5350     elsif ( $expr =~ /^(\S.*)/ ) {
5351
5352         # Where we are in the list.
5353         my $i_cnt = 0;
5354
5355         # For each expression ...
5356         foreach (@to_watch) {
5357             my $val = $to_watch[$i_cnt];
5358
5359             # Does this one match the command argument?
5360             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5361                                       # Yes. Turn it off, and its value too.
5362                 splice( @to_watch,  $i_cnt, 1 );
5363                 splice( @old_watch, $i_cnt, 1 );
5364             }
5365             $i_cnt++;
5366         } ## end foreach (@to_watch)
5367
5368         # We don't bother to turn watching off because
5369         #  a) we don't want to stop calling watchfunction() it it exists
5370         #  b) foreach over a null list doesn't do anything anyway
5371
5372     } ## end elsif ($expr =~ /^(\S.*)/)
5373
5374     # No command arguments entered.
5375     else {
5376         print $OUT
5377           "Deleting a watch-expression requires an expression, or '*' for all\n"
5378           ;    # hint
5379     }
5380 } ## end sub cmd_W
5381
5382 ### END of the API section
5383
5384 =head1 SUPPORT ROUTINES
5385
5386 These are general support routines that are used in a number of places
5387 throughout the debugger.
5388
5389 =head2 save
5390
5391 save() saves the user's versions of globals that would mess us up in C<@saved>,
5392 and installs the versions we like better.
5393
5394 =cut
5395
5396 sub save {
5397
5398     # Save eval failure, command failure, extended OS error, output field
5399     # separator, input record separator, output record separator and
5400     # the warning setting.
5401     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5402
5403     $,  = "";      # output field separator is null string
5404     $/  = "\n";    # input record separator is newline
5405     $\  = "";      # output record separator is null string
5406     $^W = 0;       # warnings are off
5407 } ## end sub save
5408
5409 =head2 C<print_lineinfo> - show where we are now
5410
5411 print_lineinfo prints whatever it is that it is handed; it prints it to the
5412 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5413 us to feed line information to a slave editor without messing up the
5414 debugger output.
5415
5416 =cut
5417
5418 sub print_lineinfo {
5419
5420     # Make the terminal sensible if we're not the primary debugger.
5421     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5422     local $\ = '';
5423     local $, = '';
5424     print $LINEINFO @_;
5425 } ## end sub print_lineinfo
5426
5427 =head2 C<postponed_sub>
5428
5429 Handles setting postponed breakpoints in subroutines once they're compiled.
5430 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5431 range for the subroutine, then mark the file as having a breakpoint,
5432 temporarily switch the C<*dbline> glob over to the source file, and then
5433 search the given range of lines to find a breakable line. If we find one,
5434 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5435
5436 =cut
5437
5438 # The following takes its argument via $evalarg to preserve current @_
5439
5440 sub postponed_sub {
5441
5442     # Get the subroutine name.
5443     my $subname = shift;
5444
5445     # If this is a 'break +<n> if <condition>' ...
5446     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5447
5448         # If there's no offset, use '+0'.
5449         my $offset = $1 || 0;
5450
5451         # find_sub's value is 'fullpath-filename:start-stop'. It's
5452         # possible that the filename might have colons in it too.
5453         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5454         if ($i) {
5455
5456             # We got the start line. Add the offset '+<n>' from
5457             # $postponed{subname}.
5458             $i += $offset;
5459
5460             # Switch to the file this sub is in, temporarily.
5461             local *dbline = $main::{ '_<' . $file };
5462
5463             # No warnings, please.
5464             local $^W = 0;    # != 0 is magical below
5465
5466             # This file's got a breakpoint in it.
5467             $had_breakpoints{$file} |= 1;
5468
5469             # Last line in file.
5470             my $max = $#dbline;
5471
5472             # Search forward until we hit a breakable line or get to
5473             # the end of the file.
5474             ++$i until $dbline[$i] != 0 or $i >= $max;
5475
5476             # Copy the breakpoint in and delete it from %postponed.
5477             $dbline{$i} = delete $postponed{$subname};
5478         } ## end if ($i)
5479
5480         # find_sub didn't find the sub.
5481         else {
5482             local $\ = '';
5483             print $OUT "Subroutine $subname not found.\n";
5484         }
5485         return;
5486     } ## end if ($postponed{$subname...
5487     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5488
5489     #print $OUT "In postponed_sub for `$subname'.\n";
5490 } ## end sub postponed_sub
5491
5492 =head2 C<postponed>
5493
5494 Called after each required file is compiled, but before it is executed;
5495 also called if the name of a just-compiled subroutine is a key of
5496 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5497 etc.) into the just-compiled code.
5498
5499 If this is a C<require>'d file, the incoming parameter is the glob
5500 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5501
5502 If it's a subroutine, the incoming parameter is the subroutine name.
5503
5504 =cut
5505
5506 sub postponed {
5507
5508     # If there's a break, process it.
5509     if ($ImmediateStop) {
5510
5511         # Right, we've stopped. Turn it off.
5512         $ImmediateStop = 0;
5513
5514         # Enter the command loop when DB::DB gets called.
5515         $signal = 1;
5516     }
5517
5518     # If this is a subroutine, let postponed_sub() deal with it.
5519     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5520
5521     # Not a subroutine. Deal with the file.
5522     local *dbline = shift;
5523     my $filename = $dbline;
5524     $filename =~ s/^_<//;
5525     local $\ = '';
5526     $signal = 1, print $OUT "'$filename' loaded...\n"
5527       if $break_on_load{$filename};
5528     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5529
5530     # Do we have any breakpoints to put in this file?
5531     return unless $postponed_file{$filename};
5532
5533     # Yes. Mark this file as having breakpoints.
5534     $had_breakpoints{$filename} |= 1;
5535
5536     # "Cannot be done: unsufficient magic" - we can't just put the
5537     # breakpoints saved in %postponed_file into %dbline by assigning
5538     # the whole hash; we have to do it one item at a time for the
5539     # breakpoints to be set properly.
5540     #%dbline = %{$postponed_file{$filename}};
5541
5542     # Set the breakpoints, one at a time.
5543     my $key;
5544
5545     for $key ( keys %{ $postponed_file{$filename} } ) {
5546
5547         # Stash the saved breakpoint into the current file's magic line array.
5548         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5549     }
5550
5551     # This file's been compiled; discard the stored breakpoints.
5552     delete $postponed_file{$filename};
5553
5554 } ## end sub postponed
5555
5556 =head2 C<dumpit>
5557
5558 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5559
5560 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5561 a reference to a variable (the thing to be dumped) as its input.
5562
5563 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5564 the currently-selected filehandle, thank you very much). The current
5565 values of the package globals C<$single> and C<$trace> are backed up in
5566 lexicals, and they are turned off (this keeps the debugger from trying
5567 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5568 preserve its current value and it is set to zero to prevent entry/exit
5569 messages from printing, and C<$doret> is localized as well and set to -2 to
5570 prevent return values from being shown.
5571
5572 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5573 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5574 installed version in C<@INC>, yours will be used instead. Possible security
5575 problem?).
5576
5577 It then checks to see if the subroutine C<main::dumpValue> is now defined
5578 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5579 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5580 is called, and picks up the variable to be dumped from the parameter list.
5581
5582 It checks the package global C<%options> to see if there's a C<dumpDepth>
5583 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5584 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5585 structure: -1 means dump everything.
5586
5587 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5588 warning.
5589
5590 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5591 and we then return to the caller.
5592
5593 =cut
5594
5595 sub dumpit {
5596
5597     # Save the current output filehandle and switch to the one
5598     # passed in as the first parameter.
5599     local ($savout) = select(shift);
5600
5601     # Save current settings of $single and $trace, and then turn them off.
5602     my $osingle = $single;
5603     my $otrace  = $trace;
5604     $single = $trace = 0;
5605
5606     # XXX Okay, what do $frame and $doret do, again?
5607     local $frame = 0;
5608     local $doret = -2;
5609
5610     # Load dumpvar.pl unless we've already got the sub we need from it.
5611     unless ( defined &main::dumpValue ) {
5612         do 'dumpvar.pl' or die $@;
5613     }
5614
5615     # If the load succeeded (or we already had dumpvalue()), go ahead
5616     # and dump things.
5617     if ( defined &main::dumpValue ) {
5618         local $\ = '';
5619         local $, = '';
5620         local $" = ' ';
5621         my $v = shift;
5622         my $maxdepth = shift || $option{dumpDepth};
5623         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5624         &main::dumpValue( $v, $maxdepth );
5625     } ## end if (defined &main::dumpValue)
5626
5627     # Oops, couldn't load dumpvar.pl.
5628     else {
5629         local $\ = '';
5630         print $OUT "dumpvar.pl not available.\n";
5631     }
5632
5633     # Reset $single and $trace to their old values.
5634     $single = $osingle;
5635     $trace  = $otrace;
5636
5637     # Restore the old filehandle.
5638     select($savout);
5639 } ## end sub dumpit
5640
5641 =head2 C<print_trace>
5642
5643 C<print_trace>'s job is to print a stack trace. It does this via the
5644 C<dump_trace> routine, which actually does all the ferreting-out of the
5645 stack trace data. C<print_trace> takes care of formatting it nicely and
5646 printing it to the proper filehandle.
5647
5648 Parameters:
5649
5650 =over 4
5651
5652 =item *
5653
5654 The filehandle to print to.
5655
5656 =item *
5657
5658 How many frames to skip before starting trace.
5659
5660 =item *
5661
5662 How many frames to print.
5663
5664 =item *
5665
5666 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5667
5668 =back
5669
5670 The original comment below seems to be noting that the traceback may not be
5671 correct if this routine is called in a tied method.
5672
5673 =cut
5674
5675 # Tied method do not create a context, so may get wrong message:
5676
5677 sub print_trace {
5678     local $\ = '';
5679     my $fh = shift;
5680
5681     # If this is going to a slave editor, but we're not the primary
5682     # debugger, reset it first.
5683     resetterm(1)
5684       if $fh        eq $LINEINFO    # slave editor
5685       and $LINEINFO eq $OUT         # normal output
5686       and $term_pid != $$;          # not the primary
5687
5688     # Collect the actual trace information to be formatted.
5689     # This is an array of hashes of subroutine call info.
5690     my @sub = dump_trace( $_[0] + 1, $_[1] );
5691
5692     # Grab the "short report" flag from @_.
5693     my $short = $_[2];              # Print short report, next one for sub name
5694
5695     # Run through the traceback info, format it, and print it.
5696     my $s;
5697     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5698
5699         # Drop out if the user has lost interest and hit control-C.
5700         last if $signal;
5701
5702         # Set the separator so arrys print nice.
5703         local $" = ', ';
5704
5705         # Grab and stringify the arguments if they are there.
5706         my $args =
5707           defined $sub[$i]{args}
5708           ? "(@{ $sub[$i]{args} })"
5709           : '';
5710
5711         # Shorten them up if $maxtrace says they're too long.
5712         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5713           if length $args > $maxtrace;
5714
5715         # Get the file name.
5716         my $file = $sub[$i]{file};
5717
5718         # Put in a filename header if short is off.
5719         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5720
5721         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5722         $s = $sub[$i]{sub};
5723         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5724
5725         # Short report uses trimmed file and sub names.
5726         if ($short) {
5727             my $sub = @_ >= 4 ? $_[3] : $s;
5728             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5729         } ## end if ($short)
5730
5731         # Non-short report includes full names.
5732         else {
5733             print $fh "$sub[$i]{context} = $s$args"
5734               . " called from $file"
5735               . " line $sub[$i]{line}\n";
5736         }
5737     } ## end for ($i = 0 ; $i <= $#sub...
5738 } ## end sub print_trace
5739
5740 =head2 dump_trace(skip[,count])
5741
5742 Actually collect the traceback information available via C<caller()>. It does
5743 some filtering and cleanup of the data, but mostly it just collects it to
5744 make C<print_trace()>'s job easier.
5745
5746 C<skip> defines the number of stack frames to be skipped, working backwards
5747 from the most current. C<count> determines the total number of frames to
5748 be returned; all of them (well, the first 10^9) are returned if C<count>
5749 is omitted.
5750
5751 This routine returns a list of hashes, from most-recent to least-recent
5752 stack frame. Each has the following keys and values:
5753
5754 =over 4
5755
5756 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5757
5758 =item * C<sub> - subroutine name, or C<eval> information
5759
5760 =item * C<args> - undef, or a reference to an array of arguments
5761
5762 =item * C<file> - the file in which this item was defined (if any)
5763
5764 =item * C<line> - the line on which it was defined
5765
5766 =back
5767
5768 =cut
5769
5770 sub dump_trace {
5771
5772     # How many levels to skip.
5773     my $skip = shift;
5774
5775     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5776     # it's unlikely that we'll have more than a billion stack frames. If you
5777     # do, you've got an awfully big machine...)
5778     my $count = shift || 1e9;
5779
5780     # We increment skip because caller(1) is the first level *back* from
5781     # the current one.  Add $skip to the count of frames so we have a
5782     # simple stop criterion, counting from $skip to $count+$skip.
5783     $skip++;
5784     $count += $skip;
5785
5786     # These variables are used to capture output from caller();
5787     my ( $p, $file, $line, $sub, $h, $context );
5788
5789     my ( $e, $r, @a, @sub, $args );
5790
5791     # XXX Okay... why'd we do that?
5792     my $nothard = not $frame & 8;
5793     local $frame = 0;
5794
5795     # Do not want to trace this.
5796     my $otrace = $trace;
5797     $trace = 0;
5798
5799     # Start out at the skip count.
5800     # If we haven't reached the number of frames requested, and caller() is
5801     # still returning something, stay in the loop. (If we pass the requested
5802     # number of stack frames, or we run out - caller() returns nothing - we
5803     # quit.
5804     # Up the stack frame index to go back one more level each time.
5805     for (
5806         $i = $skip ;
5807         $i < $count
5808         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5809         $i++
5810       )
5811     {
5812
5813         # Go through the arguments and save them for later.
5814         @a = ();
5815         for $arg (@args) {
5816             my $type;
5817             if ( not defined $arg ) {    # undefined parameter
5818                 push @a, "undef";
5819             }
5820
5821             elsif ( $nothard and tied $arg ) {    # tied parameter
5822                 push @a, "tied";
5823             }
5824             elsif ( $nothard and $type = ref $arg ) {    # reference
5825                 push @a, "ref($type)";
5826             }
5827             else {                                       # can be stringified
5828                 local $_ =
5829                   "$arg";    # Safe to stringify now - should not call f().
5830
5831                 # Backslash any single-quotes or backslashes.
5832                 s/([\'\\])/\\$1/g;
5833
5834                 # Single-quote it unless it's a number or a colon-separated
5835                 # name.
5836                 s/(.*)/'$1'/s
5837                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5838
5839                 # Turn high-bit characters into meta-whatever.
5840                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5841
5842                 # Turn control characters into ^-whatever.
5843                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5844
5845                 push( @a, $_ );
5846             } ## end else [ if (not defined $arg)
5847         } ## end for $arg (@args)
5848
5849         # If context is true, this is array (@)context.
5850         # If context is false, this is scalar ($) context.
5851         # If neither, context isn't defined. (This is apparently a 'can't
5852         # happen' trap.)
5853         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5854
5855         # if the sub has args ($h true), make an anonymous array of the
5856         # dumped args.
5857         $args = $h ? [@a] : undef;
5858
5859         # remove trailing newline-whitespace-semicolon-end of line sequence
5860         # from the eval text, if any.
5861         $e =~ s/\n\s*\;\s*\Z// if $e;
5862
5863         # Escape backslashed single-quotes again if necessary.
5864         $e =~ s/([\\\'])/\\$1/g if $e;
5865
5866         # if the require flag is true, the eval text is from a require.
5867         if ($r) {
5868             $sub = "require '$e'";
5869         }
5870
5871         # if it's false, the eval text is really from an eval.
5872         elsif ( defined $r ) {
5873             $sub = "eval '$e'";
5874         }
5875
5876         # If the sub is '(eval)', this is a block eval, meaning we don't
5877         # know what the eval'ed text actually was.
5878         elsif ( $sub eq '(eval)' ) {
5879             $sub = "eval {...}";
5880         }
5881
5882         # Stick the collected information into @sub as an anonymous hash.
5883         push(
5884             @sub,
5885             {
5886                 context => $context,
5887                 sub     => $sub,
5888                 args    => $args,
5889                 file    => $file,
5890                 line    => $line
5891             }
5892         );
5893
5894         # Stop processing frames if the user hit control-C.
5895         last if $signal;
5896     } ## end for ($i = $skip ; $i < ...
5897
5898     # Restore the trace value again.
5899     $trace = $otrace;
5900     @sub;
5901 } ## end sub dump_trace
5902
5903 =head2 C<action()>
5904
5905 C<action()> takes input provided as the argument to an add-action command,
5906 either pre- or post-, and makes sure it's a complete command. It doesn't do
5907 any fancy parsing; it just keeps reading input until it gets a string
5908 without a trailing backslash.
5909
5910 =cut
5911
5912 sub action {
5913     my $action = shift;
5914
5915     while ( $action =~ s/\\$// ) {
5916
5917         # We have a backslash on the end. Read more.
5918         $action .= &gets;
5919     } ## end while ($action =~ s/\\$//)
5920
5921     # Return the assembled action.
5922     $action;
5923 } ## end sub action
5924
5925 =head2 unbalanced
5926
5927 This routine mostly just packages up a regular expression to be used
5928 to check that the thing it's being matched against has properly-matched
5929 curly braces.
5930
5931 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5932 speeds things up by only creating the qr//'ed expression once; if it's
5933 already defined, we don't try to define it again. A speed hack.
5934
5935 =cut
5936
5937 sub unbalanced {
5938
5939     # I hate using globals!
5940     $balanced_brace_re ||= qr{
5941         ^ \{
5942              (?:
5943                  (?> [^{}] + )              # Non-parens without backtracking
5944                 |
5945                  (??{ $balanced_brace_re }) # Group with matching parens
5946               ) *
5947           \} $
5948    }x;
5949     return $_[0] !~ m/$balanced_brace_re/;
5950 } ## end sub unbalanced
5951
5952 =head2 C<gets()>
5953
5954 C<gets()> is a primitive (very primitive) routine to read continuations.
5955 It was devised for reading continuations for actions.
5956 it just reads more input with C<readline()> and returns it.
5957
5958 =cut
5959
5960 sub gets {
5961     &readline("cont: ");
5962 }
5963
5964 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5965
5966 The C<system()> function assumes that it can just go ahead and use STDIN and
5967 STDOUT, but under the debugger, we want it to use the debugger's input and
5968 outout filehandles.
5969
5970 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5971 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5972 and then puts everything back again.
5973
5974 =cut
5975
5976 sub system {
5977
5978     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5979     # some non-Unix systems can do system() but have problems with fork().
5980     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5981     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5982     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5983     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5984
5985     # XXX: using csh or tcsh destroys sigint retvals!
5986     system(@_);
5987     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5988     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5989     close(SAVEIN);
5990     close(SAVEOUT);
5991
5992     # most of the $? crud was coping with broken cshisms
5993     if ( $? >> 8 ) {
5994         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5995     }
5996     elsif ($?) {
5997         &warn(
5998             "(Command died of SIG#",
5999             ( $? & 127 ),
6000             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6001             ")", "\n"
6002         );
6003     } ## end elsif ($?)
6004
6005     return $?;
6006
6007 } ## end sub system
6008
6009 =head1 TTY MANAGEMENT
6010
6011 The subs here do some of the terminal management for multiple debuggers.
6012
6013 =head2 setterm
6014
6015 Top-level function called when we want to set up a new terminal for use
6016 by the debugger.
6017
6018 If the C<noTTY> debugger option was set, we'll either use the terminal
6019 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6020 to find one. If we're a forked debugger, we call C<resetterm> to try to
6021 get a whole new terminal if we can.
6022
6023 In either case, we set up the terminal next. If the C<ReadLine> option was
6024 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6025 the appropriate attributes. We then
6026
6027 =cut
6028
6029 sub setterm {
6030
6031     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6032     local $frame = 0;
6033     local $doret = -2;
6034     eval { require Term::ReadLine } or die $@;
6035
6036     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6037     if ($notty) {
6038         if ($tty) {
6039             my ( $i, $o ) = split $tty, /,/;
6040             $o = $i unless defined $o;
6041             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
6042             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
6043             $IN  = \*IN;
6044             $OUT = \*OUT;
6045             my $sel = select($OUT);
6046             $| = 1;
6047             select($sel);
6048         } ## end if ($tty)
6049
6050         # We don't have a TTY - try to find one via Term::Rendezvous.
6051         else {
6052             eval "require Term::Rendezvous;" or die;
6053
6054             # See if we have anything to pass to Term::Rendezvous.
6055             # Use $HOME/.perldbtty$$ if not.
6056             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6057
6058             # Rendezvous and get the filehandles.
6059             my $term_rv = new Term::Rendezvous $rv;
6060             $IN  = $term_rv->IN;
6061             $OUT = $term_rv->OUT;
6062         } ## end else [ if ($tty)
6063     } ## end if ($notty)
6064
6065     # We're a daughter debugger. Try to fork off another TTY.
6066     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6067         resetterm(2);
6068     }
6069
6070     # If we shouldn't use Term::ReadLine, don't.
6071     if ( !$rl ) {
6072         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6073     }
6074
6075     # We're using Term::ReadLine. Get all the attributes for this terminal.
6076     else {
6077         $term = new Term::ReadLine 'perldb', $IN, $OUT;
6078
6079         $rl_attribs = $term->Attribs;
6080         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6081           if defined $rl_attribs->{basic_word_break_characters}
6082           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6083         $rl_attribs->{special_prefixes} = '$@&%';
6084         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6085         $rl_attribs->{completion_function} = \&db_complete;
6086     } ## end else [ if (!$rl)
6087
6088     # Set up the LINEINFO filehandle.
6089     $LINEINFO = $OUT     unless defined $LINEINFO;
6090     $lineinfo = $console unless defined $lineinfo;
6091
6092     $term->MinLine(2);
6093
6094     &load_hist();
6095
6096     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6097         $term->SetHistory(@hist);
6098     }
6099
6100     # XXX Ornaments are turned on unconditionally, which is not
6101     # always a good thing.
6102     ornaments($ornaments) if defined $ornaments;
6103     $term_pid = $$;
6104 } ## end sub setterm
6105
6106 sub load_hist {
6107     $histfile //= option_val("HistFile", undef);
6108     return unless defined $histfile;
6109     open my $fh, "<", $histfile or return;
6110     local $/ = "\n";
6111     @hist = ();
6112     while (<$fh>) {
6113         chomp;
6114         push @hist, $_;
6115     }
6116     close $fh;
6117 }
6118
6119 sub save_hist {
6120     return unless defined $histfile;
6121     eval { require File::Path } or return;
6122     eval { require File::Basename } or return;
6123     File::Path::mkpath(File::Basename::dirname($histfile));
6124     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6125     $histsize //= option_val("HistSize",100);
6126     my @copy = grep { $_ ne '?' } @hist;
6127     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6128     for ($start .. $#copy) {
6129         print $fh "$copy[$_]\n";
6130     }
6131     close $fh or die "Could not write '$histfile': $!";
6132 }
6133
6134 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6135
6136 When the process being debugged forks, or the process invokes a command
6137 via C<system()> which starts a new debugger, we need to be able to get a new
6138 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6139 fight over the terminal, and you can never quite be sure who's going to get the
6140 input you're typing.
6141
6142 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6143 is tasked with doing all the necessary operating system mojo to get a new
6144 TTY (and probably another window) and to direct the new debugger to read and
6145 write there.
6146
6147 The debugger provides C<get_fork_TTY> functions which work for X Windows,
6148 OS/2, and Mac OS X. Other systems are not supported. You are encouraged
6149 to write C<get_fork_TTY> functions which work for I<your> platform
6150 and contribute them.
6151
6152 =head3 C<xterm_get_fork_TTY>
6153
6154 This function provides the C<get_fork_TTY> function for X windows. If a
6155 program running under the debugger forks, a new <xterm> window is opened and
6156 the subsidiary debugger is directed there.
6157
6158 The C<open()> call is of particular note here. We have the new C<xterm>
6159 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6160 command (which prints the device name of the TTY we'll want to use for input
6161 and output to STDOUT, then C<sleep> for a very long time, routing this output
6162 to file number 3. This way we can simply read from the <XT> filehandle (which
6163 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6164
6165 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6166 properly set up.
6167
6168 =cut
6169
6170 sub xterm_get_fork_TTY {
6171     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6172     open XT,
6173 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6174  sleep 10000000' |];
6175
6176     # Get the output from 'tty' and clean it up a little.
6177     my $tty = <XT>;
6178     chomp $tty;
6179
6180     $pidprompt = '';    # Shown anyway in titlebar
6181
6182     # We need $term defined or we can not switch to the newly created xterm
6183     if ($tty ne '' && !defined $term) {
6184         eval { require Term::ReadLine } or die $@;
6185         if ( !$rl ) {
6186             $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6187         }
6188         else {
6189             $term = new Term::ReadLine 'perldb', $IN, $OUT;
6190         }
6191     }
6192     # There's our new TTY.
6193     return $tty;
6194 } ## end sub xterm_get_fork_TTY
6195
6196 =head3 C<os2_get_fork_TTY>
6197
6198 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6199
6200 =cut
6201
6202 # This example function resets $IN, $OUT itself
6203 my $c_pipe = 0;
6204 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6205     local $\  = '';
6206     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6207     my %opt = ( title => "Daughter Perl debugger $pids $name",
6208                 ($rl ? (read_by_key => 1) : ()) );
6209     require OS2::Process;
6210     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6211       or return;
6212     $pidprompt = '';    # Shown anyway in titlebar
6213     reset_IN_OUT($in, $out);
6214     $tty = '*reset*';
6215     return '';          # Indicate that reset_IN_OUT is called
6216 } ## end sub os2_get_fork_TTY
6217
6218 =head3 C<macosx_get_fork_TTY>
6219
6220 The Mac OS X version uses AppleScript to tell Terminal.app to create
6221 a new window.
6222
6223 =cut
6224
6225 # Notes about Terminal.app's AppleScript support,
6226 # (aka things that might break in future OS versions).
6227 #
6228 # The "do script" command doesn't return a reference to the new window
6229 # it creates, but since it appears frontmost and windows are enumerated
6230 # front to back, we can use "first window" === "window 1".
6231 #
6232 # Since "do script" is implemented by supplying the argument (plus a
6233 # return character) as terminal input, there's a potential race condition
6234 # where the debugger could beat the shell to reading the command.
6235 # To prevent this, we wait for the screen to clear before proceeding.
6236 #
6237 # 10.3 and 10.4:
6238 # There's no direct accessor for the tty device name, so we fiddle
6239 # with the window title options until it says what we want.
6240 #
6241 # 10.5:
6242 # There _is_ a direct accessor for the tty device name, _and_ there's
6243 # a new possible component of the window title (the name of the settings
6244 # set).  A separate version is needed.
6245
6246 my @script_versions=
6247
6248     ([237, <<'__LEOPARD__'],
6249 tell application "Terminal"
6250     do script "clear;exec sleep 100000"
6251     tell first tab of first window
6252         copy tty to thetty
6253         set custom title to "forked perl debugger"
6254         set title displays custom title to true
6255         repeat while (length of first paragraph of (get contents)) > 0
6256             delay 0.1
6257         end repeat
6258     end tell
6259 end tell
6260 thetty
6261 __LEOPARD__
6262
6263      [100, <<'__JAGUAR_TIGER__'],
6264 tell application "Terminal"
6265     do script "clear;exec sleep 100000"
6266     tell first window
6267         set title displays shell path to false
6268         set title displays window size to false
6269         set title displays file name to false
6270         set title displays device name to true
6271         set title displays custom title to true
6272         set custom title to ""
6273         copy "/dev/" & name to thetty
6274         set custom title to "forked perl debugger"
6275         repeat while (length of first paragraph of (get contents)) > 0
6276             delay 0.1
6277         end repeat
6278     end tell
6279 end tell
6280 thetty
6281 __JAGUAR_TIGER__
6282
6283 );
6284
6285 sub macosx_get_fork_TTY
6286 {
6287     my($version,$script,$pipe,$tty);
6288
6289     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6290     foreach my $entry (@script_versions) {
6291         if ($version>=$entry->[0]) {
6292             $script=$entry->[1];
6293             last;
6294         }
6295     }
6296     return unless defined($script);
6297     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6298     $tty=readline($pipe);
6299     close($pipe);
6300     return unless defined($tty) && $tty =~ m(^/dev/);
6301     chomp $tty;
6302     return $tty;
6303 }
6304
6305 =head2 C<create_IN_OUT($flags)>
6306
6307 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6308 try to diagnose why.
6309
6310 Flags are:
6311
6312 =over 4
6313
6314 =item * 1 - Don't know how to create a new TTY.
6315
6316 =item * 2 - Debugger has forked, but we can't get a new TTY.
6317
6318 =item * 4 - standard debugger startup is happening.
6319
6320 =back
6321
6322 =cut
6323
6324 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6325
6326     # If we know how to get a new TTY, do it! $in will have
6327     # the TTY name if get_fork_TTY works.
6328     my $in = &get_fork_TTY if defined &get_fork_TTY;
6329
6330     # It used to be that
6331     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6332
6333     if ( not defined $in ) {
6334         my $why = shift;
6335
6336         # We don't know how.
6337         print_help(<<EOP) if $why == 1;
6338 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6339 EOP
6340
6341         # Forked debugger.
6342         print_help(<<EOP) if $why == 2;
6343 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6344   This may be an asynchronous session, so the parent debugger may be active.
6345 EOP
6346
6347         # Note that both debuggers are fighting over the same input.
6348         print_help(<<EOP) if $why != 4;
6349   Since two debuggers fight for the same TTY, input is severely entangled.
6350
6351 EOP
6352         print_help(<<EOP);
6353   I know how to switch the output to a different window in xterms, OS/2
6354   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6355   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6356   B<DB::get_fork_TTY()> returning this.
6357
6358   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6359   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6360
6361 EOP
6362     } ## end if (not defined $in)
6363     elsif ( $in ne '' ) {
6364         TTY($in);
6365     }
6366     else {
6367         $console = '';    # Indicate no need to open-from-the-console
6368     }
6369     undef $fork_TTY;
6370 } ## end sub create_IN_OUT
6371
6372 =head2 C<resetterm>
6373
6374 Handles rejiggering the prompt when we've forked off a new debugger.
6375
6376 If the new debugger happened because of a C<system()> that invoked a
6377 program under the debugger, the arrow between the old pid and the new
6378 in the prompt has I<two> dashes instead of one.
6379
6380 We take the current list of pids and add this one to the end. If there
6381 isn't any list yet, we make one up out of the initial pid associated with
6382 the terminal and our new pid, sticking an arrow (either one-dashed or
6383 two dashed) in between them.
6384
6385 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6386 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6387 and try to do that.
6388
6389 =cut
6390
6391 sub resetterm {    # We forked, so we need a different TTY
6392
6393     # Needs to be passed to create_IN_OUT() as well.
6394     my $in = shift;
6395
6396     # resetterm(2): got in here because of a system() starting a debugger.
6397     # resetterm(1): just forked.
6398     my $systemed = $in > 1 ? '-' : '';
6399
6400     # If there's already a list of pids, add this to the end.
6401     if ($pids) {
6402         $pids =~ s/\]/$systemed->$$]/;
6403     }
6404
6405     # No pid list. Time to make one.
6406     else {
6407         $pids = "[$term_pid->$$]";
6408     }
6409
6410     # The prompt we're going to be using for this debugger.
6411     $pidprompt = $pids;
6412
6413     # We now 0wnz this terminal.
6414     $term_pid = $$;
6415
6416     # Just return if we're not supposed to try to create a new TTY.
6417     return unless $CreateTTY & $in;
6418
6419     # Try to create a new IN/OUT pair.
6420     create_IN_OUT($in);
6421 } ## end sub resetterm
6422
6423 =head2 C<readline>
6424
6425 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6426 the next line, print a message saying we got it, add it to the terminal
6427 history (if possible), and return it.
6428
6429 If there's nothing in the typeahead buffer, check the command filehandle stack.
6430 If there are any filehandles there, read from the last one, and return the line
6431 if we got one. If not, we pop the filehandle off and close it, and try the
6432 next one up the stack.
6433
6434 If we've emptied the filehandle stack, we check to see if we've got a socket
6435 open, and we read that and return it if we do. If we don't, we just call the
6436 core C<readline()> and return its value.
6437
6438 =cut
6439
6440 sub readline {
6441
6442     # Localize to prevent it from being smashed in the program being debugged.
6443     local $.;
6444
6445     # Pull a line out of the typeahead if there's stuff there.
6446     if (@typeahead) {
6447
6448         # How many lines left.
6449         my $left = @typeahead;
6450
6451         # Get the next line.
6452         my $got = shift @typeahead;
6453
6454         # Print a message saying we got input from the typeahead.
6455         local $\ = '';
6456         print $OUT "auto(-$left)", shift, $got, "\n";
6457
6458         # Add it to the terminal history (if possible).
6459         $term->AddHistory($got)
6460           if length($got) > 1
6461           and defined $term->Features->{addHistory};
6462         return $got;
6463     } ## end if (@typeahead)
6464
6465     # We really need to read some input. Turn off entry/exit trace and
6466     # return value printing.
6467     local $frame = 0;
6468     local $doret = -2;
6469
6470     # If there are stacked filehandles to read from ...
6471     while (@cmdfhs) {
6472
6473         # Read from the last one in the stack.
6474         my $line = CORE::readline( $cmdfhs[-1] );
6475
6476         # If we got a line ...
6477         defined $line
6478           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6479           : close pop @cmdfhs;                            # Pop and close
6480     } ## end while (@cmdfhs)
6481
6482     # Nothing on the filehandle stack. Socket?
6483     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6484
6485         # Send anyting we have to send.
6486         $OUT->write( join( '', @_ ) );
6487
6488         # Receive anything there is to receive.
6489         $stuff;
6490         my $stuff = '';
6491         my $buf;
6492         do {
6493             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6494                                             # XXX Don't know. You tell me.
6495         } while length $buf and ($stuff .= $buf) !~ /\n/;
6496
6497         # What we got.
6498         $stuff;
6499     } ## end if (ref $OUT and UNIVERSAL::isa...
6500
6501     # No socket. Just read from the terminal.
6502     else {
6503         $term->readline(@_);
6504     }
6505 } ## end sub readline
6506
6507 =head1 OPTIONS SUPPORT ROUTINES
6508
6509 These routines handle listing and setting option values.
6510
6511 =head2 C<dump_option> - list the current value of an option setting
6512
6513 This routine uses C<option_val> to look up the value for an option.
6514 It cleans up escaped single-quotes and then displays the option and
6515 its value.
6516
6517 =cut
6518
6519 sub dump_option {
6520     my ( $opt, $val ) = @_;
6521     $val = option_val( $opt, 'N/A' );
6522     $val =~ s/([\\\'])/\\$1/g;
6523     printf $OUT "%20s = '%s'\n", $opt, $val;
6524 } ## end sub dump_option
6525
6526 sub options2remember {
6527     foreach my $k (@RememberOnROptions) {
6528         $option{$k} = option_val( $k, 'N/A' );
6529     }
6530     return %option;
6531 }
6532
6533 =head2 C<option_val> - find the current value of an option
6534
6535 This can't just be a simple hash lookup because of the indirect way that
6536 the option values are stored. Some are retrieved by calling a subroutine,
6537 some are just variables.
6538
6539 You must supply a default value to be used in case the option isn't set.
6540
6541 =cut
6542
6543 sub option_val {
6544     my ( $opt, $default ) = @_;
6545     my $val;
6546
6547     # Does this option exist, and is it a variable?
6548     # If so, retrieve the value via the value in %optionVars.
6549     if (    defined $optionVars{$opt}
6550         and defined ${ $optionVars{$opt} } )
6551     {
6552         $val = ${ $optionVars{$opt} };
6553     }
6554
6555     # Does this option exist, and it's a subroutine?
6556     # If so, call the subroutine via the ref in %optionAction
6557     # and capture the value.
6558     elsif ( defined $optionAction{$opt}
6559         and defined &{ $optionAction{$opt} } )
6560     {
6561         $val = &{ $optionAction{$opt} }();
6562     }
6563
6564     # If there's an action or variable for the supplied option,
6565     # but no value was set, use the default.
6566     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6567         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6568     {
6569         $val = $default;
6570     }
6571
6572     # Otherwise, do the simple hash lookup.
6573     else {
6574         $val = $option{$opt};
6575     }
6576
6577     # If the value isn't defined, use the default.
6578     # Then return whatever the value is.
6579     $val = $default unless defined $val;
6580     $val;
6581 } ## end sub option_val
6582
6583 =head2 C<parse_options>
6584
6585 Handles the parsing and execution of option setting/displaying commands.
6586
6587 An option entered by itself is assumed to be I<set me to 1> (the default value)
6588 if the option is a boolean one. If not, the user is prompted to enter a valid
6589 value or to query the current value (via C<option? >).
6590
6591 If C<option=value> is entered, we try to extract a quoted string from the
6592 value (if it is quoted). If it's not, we just use the whole value as-is.
6593
6594 We load any modules required to service this option, and then we set it: if
6595 it just gets stuck in a variable, we do that; if there's a subroutine to
6596 handle setting the option, we call that.
6597
6598 Finally, if we're running in interactive mode, we display the effect of the
6599 user's command back to the terminal, skipping this if we're setting things
6600 during initialization.
6601
6602 =cut
6603
6604 sub parse_options {
6605     local ($_) = @_;
6606     local $\ = '';
6607
6608     # These options need a value. Don't allow them to be clobbered by accident.
6609     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6610       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6611       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6612     };
6613
6614     while (length) {
6615         my $val_defaulted;
6616
6617         # Clean off excess leading whitespace.
6618         s/^\s+// && next;
6619
6620         # Options are always all word characters, followed by a non-word
6621         # separator.
6622         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6623         my ( $opt, $sep ) = ( $1, $2 );
6624
6625         # Make sure that such an option exists.
6626         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6627           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6628
6629         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6630         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6631         my $val;
6632
6633         # '?' as separator means query, but must have whitespace after it.
6634         if ( "?" eq $sep ) {
6635             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6636               last
6637               if /^\S/;
6638
6639             #&dump_option($opt);
6640         } ## end if ("?" eq $sep)
6641
6642         # Separator is whitespace (or just a carriage return).
6643         # They're going for a default, which we assume is 1.
6644         elsif ( $sep !~ /\S/ ) {
6645             $val_defaulted = 1;
6646             $val           = "1";   #  this is an evil default; make 'em set it!
6647         }
6648
6649         # Separator is =. Trying to set a value.
6650         elsif ( $sep eq "=" ) {
6651
6652             # If quoted, extract a quoted string.
6653             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6654                 my $quote = $1;
6655                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6656             }
6657
6658             # Not quoted. Use the whole thing. Warn about 'option='.
6659             else {
6660                 s/^(\S*)//;
6661                 $val = $1;
6662                 print OUT qq(Option better cleared using $opt=""\n)
6663                   unless length $val;
6664             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6665
6666         } ## end elsif ($sep eq "=")
6667
6668         # "Quoted" with [], <>, or {}.
6669         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6670             my ($end) =
6671               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6672             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6673               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6674             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6675         } ## end else [ if ("?" eq $sep)
6676
6677         # Exclude non-booleans from getting set to 1 by default.
6678         if ( $opt_needs_val{$option} && $val_defaulted ) {
6679             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6680             print $OUT
6681 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6682             next;
6683         } ## end if ($opt_needs_val{$option...
6684
6685         # Save the option value.
6686         $option{$option} = $val if defined $val;
6687
6688         # Load any module that this option requires.
6689         eval qq{
6690                 local \$frame = 0;
6691                 local \$doret = -2;
6692                 require '$optionRequire{$option}';
6693                 1;
6694                } || die    # XXX: shouldn't happen
6695           if defined $optionRequire{$option}
6696           && defined $val;
6697
6698         # Set it.
6699         # Stick it in the proper variable if it goes in a variable.
6700         ${ $optionVars{$option} } = $val
6701           if defined $optionVars{$option}
6702           && defined $val;
6703
6704         # Call the appropriate sub if it gets set via sub.
6705         &{ $optionAction{$option} }($val)
6706           if defined $optionAction{$option}
6707           && defined &{ $optionAction{$option} }
6708           && defined $val;
6709
6710         # Not initialization - echo the value we set it to.
6711         dump_option($option) unless $OUT eq \*STDERR;
6712     } ## end while (length)
6713 } ## end sub parse_options
6714
6715 =head1 RESTART SUPPORT
6716
6717 These routines are used to store (and restore) lists of items in environment
6718 variables during a restart.
6719
6720 =head2 set_list
6721
6722 Set_list packages up items to be stored in a set of environment variables
6723 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6724 the values). Values outside the standard ASCII charset are stored by encoding
6725 then as hexadecimal values.
6726
6727 =cut
6728
6729 sub set_list {
6730     my ( $stem, @list ) = @_;
6731     my $val;
6732
6733     # VAR_n: how many we have. Scalar assignment gets the number of items.
6734     $ENV{"${stem}_n"} = @list;
6735
6736     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6737     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6738     for $i ( 0 .. $#list ) {
6739         $val = $list[$i];
6740         $val =~ s/\\/\\\\/g;
6741         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6742         $ENV{"${stem}_$i"} = $val;
6743     } ## end for $i (0 .. $#list)
6744 } ## end sub set_list
6745
6746 =head2 get_list
6747
6748 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6749 back, and then pull VAR_0, VAR_1. etc. back out.
6750
6751 =cut
6752
6753 sub get_list {
6754     my $stem = shift;
6755     my @list;
6756     my $n = delete $ENV{"${stem}_n"};
6757     my $val;
6758     for $i ( 0 .. $n - 1 ) {
6759         $val = delete $ENV{"${stem}_$i"};
6760         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6761         push @list, $val;
6762     }
6763     @list;
6764 } ## end sub get_list
6765
6766 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6767
6768 =head2 catch()
6769
6770 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6771 set an already-existing global scalar variable to a constant value. This
6772 avoids allocating any memory possibly in the middle of something that will
6773 get all confused if we do, particularly under I<unsafe signals>.
6774
6775 =cut
6776
6777 sub catch {
6778     $signal = 1;
6779     return;    # Put nothing on the stack - malloc/free land!
6780 }
6781
6782 =head2 C<warn()>
6783
6784 C<warn> emits a warning, by joining together its arguments and printing
6785 them, with couple of fillips.
6786
6787 If the composited message I<doesn't> end with a newline, we automatically
6788 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6789 to be set to the filehandle to be used to output warnings; it makes no
6790 assumptions about what filehandles are available.
6791
6792 =cut
6793
6794 sub warn {
6795     my ($msg) = join( "", @_ );
6796     $msg .= ": $!\n" unless $msg =~ /\n$/;
6797     local $\ = '';
6798     print $OUT $msg;
6799 } ## end sub warn
6800
6801 =head1 INITIALIZATION TTY SUPPORT
6802
6803 =head2 C<reset_IN_OUT>
6804
6805 This routine handles restoring the debugger's input and output filehandles
6806 after we've tried and failed to move them elsewhere.  In addition, it assigns
6807 the debugger's output filehandle to $LINEINFO if it was already open there.
6808
6809 =cut
6810
6811 sub reset_IN_OUT {
6812     my $switch_li = $LINEINFO eq $OUT;
6813
6814     # If there's a term and it's able to get a new tty, try to get one.
6815     if ( $term and $term->Features->{newTTY} ) {
6816         ( $IN, $OUT ) = ( shift, shift );
6817         $term->newTTY( $IN, $OUT );
6818     }
6819
6820     # This term can't get a new tty now. Better luck later.
6821     elsif ($term) {
6822         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6823     }
6824
6825     # Set the filehndles up as they were.
6826     else {
6827         ( $IN, $OUT ) = ( shift, shift );
6828     }
6829
6830     # Unbuffer the output filehandle.
6831     my $o = select $OUT;
6832     $| = 1;
6833     select $o;
6834
6835     # Point LINEINFO to the same output filehandle if it was there before.
6836     $LINEINFO = $OUT if $switch_li;
6837 } ## end sub reset_IN_OUT
6838
6839 =head1 OPTION SUPPORT ROUTINES
6840
6841 The following routines are used to process some of the more complicated
6842 debugger options.
6843
6844 =head2 C<TTY>
6845
6846 Sets the input and output filehandles to the specified files or pipes.
6847 If the terminal supports switching, we go ahead and do it. If not, and
6848 there's already a terminal in place, we save the information to take effect
6849 on restart.
6850
6851 If there's no terminal yet (for instance, during debugger initialization),
6852 we go ahead and set C<$console> and C<$tty> to the file indicated.
6853
6854 =cut
6855
6856 sub TTY {
6857
6858     if ( @_ and $term and $term->Features->{newTTY} ) {
6859
6860         # This terminal supports switching to a new TTY.
6861         # Can be a list of two files, or on string containing both names,
6862         # comma-separated.
6863         # XXX Should this perhaps be an assignment from @_?
6864         my ( $in, $out ) = shift;
6865         if ( $in =~ /,/ ) {
6866
6867             # Split list apart if supplied.
6868             ( $in, $out ) = split /,/, $in, 2;
6869         }
6870         else {
6871
6872             # Use the same file for both input and output.
6873             $out = $in;
6874         }
6875
6876         # Open file onto the debugger's filehandles, if you can.
6877         open IN,  $in     or die "cannot open `$in' for read: $!";
6878         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6879
6880         # Swap to the new filehandles.
6881         reset_IN_OUT( \*IN, \*OUT );
6882
6883         # Save the setting for later.
6884         return $tty = $in;
6885     } ## end if (@_ and $term and $term...
6886
6887     # Terminal doesn't support new TTY, or doesn't support readline.
6888     # Can't do it now, try restarting.
6889     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6890
6891     # Useful if done through PERLDB_OPTS:
6892     $console = $tty = shift if @_;
6893
6894     # Return whatever the TTY is.
6895     $tty or $console;
6896 } ## end sub TTY
6897
6898 =head2 C<noTTY>
6899
6900 Sets the C<$notty> global, controlling whether or not the debugger tries to
6901 get a terminal to read from. If called after a terminal is already in place,
6902 we save the value to use it if we're restarted.
6903
6904 =cut
6905
6906 sub noTTY {
6907     if ($term) {
6908         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6909     }
6910     $notty = shift if @_;
6911     $notty;
6912 } ## end sub noTTY
6913
6914 =head2 C<ReadLine>
6915
6916 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6917 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6918 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6919 the value in case a restart is done so we can change it then.
6920
6921 =cut
6922
6923 sub ReadLine {
6924     if ($term) {
6925         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6926     }
6927     $rl = shift if @_;
6928     $rl;
6929 } ## end sub ReadLine
6930
6931 =head2 C<RemotePort>
6932
6933 Sets the port that the debugger will try to connect to when starting up.
6934 If the terminal's already been set up, we can't do it, but we remember the
6935 setting in case the user does a restart.
6936
6937 =cut
6938
6939 sub RemotePort {
6940     if ($term) {
6941         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6942     }
6943     $remoteport = shift if @_;
6944     $remoteport;
6945 } ## end sub RemotePort
6946
6947 =head2 C<tkRunning>
6948
6949 Checks with the terminal to see if C<Tk> is running, and returns true or
6950 false. Returns false if the current terminal doesn't support C<readline>.
6951
6952 =cut
6953
6954 sub tkRunning {
6955     if ( ${ $term->Features }{tkRunning} ) {
6956         return $term->tkRunning(@_);
6957     }
6958     else {
6959         local $\ = '';
6960         print $OUT "tkRunning not supported by current ReadLine package.\n";
6961         0;
6962     }
6963 } ## end sub tkRunning
6964
6965 =head2 C<NonStop>
6966
6967 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6968 debugger remembers the setting in case you restart, though.
6969
6970 =cut
6971
6972 sub NonStop {
6973     if ($term) {
6974         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6975           if @_;
6976     }
6977     $runnonstop = shift if @_;
6978     $runnonstop;
6979 } ## end sub NonStop
6980
6981 sub DollarCaretP {
6982     if ($term) {
6983         &warn("Some flag changes could not take effect until next 'R'!\n")
6984           if @_;
6985     }
6986     $^P = parse_DollarCaretP_flags(shift) if @_;
6987     expand_DollarCaretP_flags($^P);
6988 }
6989
6990 =head2 C<pager>
6991
6992 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6993 there already.
6994
6995 =cut
6996
6997 sub pager {
6998     if (@_) {
6999         $pager = shift;
7000         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7001     }
7002     $pager;
7003 } ## end sub pager
7004
7005 =head2 C<shellBang>
7006
7007 Sets the shell escape command, and generates a printable copy to be used
7008 in the help.
7009
7010 =cut
7011
7012 sub shellBang {
7013
7014     # If we got an argument, meta-quote it, and add '\b' if it
7015     # ends in a word character.
7016     if (@_) {
7017         $sh = quotemeta shift;
7018         $sh .= "\\b" if $sh =~ /\w$/;
7019     }
7020
7021     # Generate the printable version for the help:
7022     $psh = $sh;    # copy it
7023     $psh =~ s/\\b$//;        # Take off trailing \b if any
7024     $psh =~ s/\\(.)/$1/g;    # De-escape
7025     $psh;                    # return the printable version
7026 } ## end sub shellBang
7027
7028 =head2 C<ornaments>
7029
7030 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7031 was passed as the argument. (This means you can't override the terminal's
7032 ornaments.)
7033
7034 =cut
7035
7036 sub ornaments {
7037     if ( defined $term ) {
7038
7039         # We don't want to show warning backtraces, but we do want die() ones.
7040         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7041
7042         # No ornaments if the terminal doesn't support them.
7043         return '' unless $term->Features->{ornaments};
7044         eval { $term->ornaments(@_) } || '';
7045     }
7046
7047     # Use what was passed in if we can't determine it ourselves.
7048     else {
7049         $ornaments = shift;
7050     }
7051 } ## end sub ornaments
7052
7053 =head2 C<recallCommand>
7054
7055 Sets the recall command, and builds a printable version which will appear in
7056 the help text.
7057
7058 =cut
7059
7060 sub recallCommand {
7061
7062     # If there is input, metaquote it. Add '\b' if it ends with a word
7063     # character.
7064     if (@_) {
7065         $rc = quotemeta shift;
7066         $rc .= "\\b" if $rc =~ /\w$/;
7067     }
7068
7069     # Build it into a printable version.
7070     $prc = $rc;    # Copy it
7071     $prc =~ s/\\b$//;        # Remove trailing \b
7072     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7073     $prc;                    # Return the printable version
7074 } ## end sub recallCommand
7075
7076 =head2 C<LineInfo> - where the line number information goes
7077
7078 Called with no arguments, returns the file or pipe that line info should go to.
7079
7080 Called with an argument (a file or a pipe), it opens that onto the
7081 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7082 file or pipe again to the caller.
7083
7084 =cut
7085
7086 sub LineInfo {
7087     return $lineinfo unless @_;
7088     $lineinfo = shift;
7089
7090     #  If this is a valid "thing to be opened for output", tack a
7091     # '>' onto the front.
7092     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7093
7094     # If this is a pipe, the stream points to a slave editor.
7095     $slave_editor = ( $stream =~ /^\|/ );
7096
7097     # Open it up and unbuffer it.
7098     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
7099     $LINEINFO = \*LINEINFO;
7100     my $save = select($LINEINFO);
7101     $| = 1;
7102     select($save);
7103
7104     # Hand the file or pipe back again.
7105     $lineinfo;
7106 } ## end sub LineInfo
7107
7108 =head1 COMMAND SUPPORT ROUTINES
7109
7110 These subroutines provide functionality for various commands.
7111
7112 =head2 C<list_modules>
7113
7114 For the C<M> command: list modules loaded and their versions.
7115 Essentially just runs through the keys in %INC, picks each package's
7116 C<$VERSION> variable, gets the file name, and formats the information
7117 for output.
7118
7119 =cut
7120
7121 sub list_modules {    # versions
7122     my %version;
7123     my $file;
7124
7125     # keys are the "as-loaded" name, values are the fully-qualified path
7126     # to the file itself.
7127     for ( keys %INC ) {
7128         $file = $_;                                # get the module name
7129         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7130         s,/,::,g;                                  # change '/' to '::'
7131         s/^perl5db$/DB/;                           # Special case: debugger
7132                                                    # moves to package DB
7133         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7134
7135         # If the package has a $VERSION package global (as all good packages
7136         # should!) decode it and save as partial message.
7137         if ( defined ${ $_ . '::VERSION' } ) {
7138             $version{$file} = "${ $_ . '::VERSION' } from ";
7139         }
7140
7141         # Finish up the message with the file the package came from.
7142         $version{$file} .= $INC{$file};
7143     } ## end for (keys %INC)
7144
7145     # Hey, dumpit() formats a hash nicely, so why not use it?
7146     dumpit( $OUT, \%version );
7147 } ## end sub list_modules
7148
7149 =head2 C<sethelp()>
7150
7151 Sets up the monster string used to format and print the help.
7152
7153 =head3 HELP MESSAGE FORMAT
7154
7155 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7156 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7157 easy to parse and portable, but which still allows the help to be a little
7158 nicer than just plain text.
7159
7160 Essentially, you define the command name (usually marked up with C<< B<> >>
7161 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7162 newline. The descriptive text can also be marked up in the same way. If you
7163 need to continue the descriptive text to another line, start that line with
7164 just tabs and then enter the marked-up text.
7165
7166 If you are modifying the help text, I<be careful>. The help-string parser is
7167 not very sophisticated, and if you don't follow these rules it will mangle the
7168 help beyond hope until you fix the string.
7169
7170 =cut
7171
7172 sub sethelp {
7173
7174     # XXX: make sure there are tabs between the command and explanation,
7175     #      or print_help will screw up your formatting if you have
7176     #      eeevil ornaments enabled.  This is an insane mess.
7177
7178     $help = "
7179 Help is currently only available for the new 5.8 command set.
7180 No help is available for the old command set.
7181 We assume you know what you're doing if you switch to it.
7182
7183 B<T>        Stack trace.
7184 B<s> [I<expr>]    Single step [in I<expr>].
7185 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7186 <B<CR>>        Repeat last B<n> or B<s> command.
7187 B<r>        Return from current subroutine.
7188 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7189         at the specified position.
7190 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7191 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7192 B<l> I<line>        List single I<line>.
7193 B<l> I<subname>    List first window of lines from subroutine.
7194 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7195 B<l>        List next window of lines.
7196 B<->        List previous window of lines.
7197 B<v> [I<line>]    View window around I<line>.
7198 B<.>        Return to the executed line.
7199 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7200         I<filename> may be either the full name of the file, or a regular
7201         expression matching the full file name:
7202         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7203         Evals (with saved bodies) are considered to be filenames:
7204         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7205         (in the order of execution).
7206 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7207 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7208 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7209 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7210 B<t>        Toggle trace mode.
7211 B<t> I<expr>        Trace through execution of I<expr>.
7212 B<b>        Sets breakpoint on current line)
7213 B<b> [I<line>] [I<condition>]
7214         Set breakpoint; I<line> defaults to the current execution line;
7215         I<condition> breaks if it evaluates to true, defaults to '1'.
7216 B<b> I<subname> [I<condition>]
7217         Set breakpoint at first line of subroutine.
7218 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7219 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7220 B<b> B<postpone> I<subname> [I<condition>]
7221         Set breakpoint at first line of subroutine after
7222         it is compiled.
7223 B<b> B<compile> I<subname>
7224         Stop after the subroutine is compiled.
7225 B<B> [I<line>]    Delete the breakpoint for I<line>.
7226 B<B> I<*>             Delete all breakpoints.
7227 B<a> [I<line>] I<command>
7228         Set an action to be done before the I<line> is executed;
7229         I<line> defaults to the current execution line.
7230         Sequence is: check for breakpoint/watchpoint, print line
7231         if necessary, do action, prompt user if necessary,
7232         execute line.
7233 B<a>        Does nothing
7234 B<A> [I<line>]    Delete the action for I<line>.
7235 B<A> I<*>             Delete all actions.
7236 B<w> I<expr>        Add a global watch-expression.
7237 B<w>             Does nothing
7238 B<W> I<expr>        Delete a global watch-expression.
7239 B<W> I<*>             Delete all watch-expressions.
7240 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7241         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7242 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7243 B<x> I<expr>        Evals expression in list context, dumps the result.
7244 B<m> I<expr>        Evals expression in list context, prints methods callable
7245         on the first element of the result.
7246 B<m> I<class>        Prints methods callable via the given class.
7247 B<M>        Show versions of loaded modules.
7248 B<i> I<class>       Prints nested parents of given class.
7249 B<e>         Display current thread id.
7250 B<E>         Display all thread ids the current one will be identified: <n>.
7251 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7252
7253 B<<> ?            List Perl commands to run before each prompt.
7254 B<<> I<expr>        Define Perl command to run before each prompt.
7255 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7256 B<< *>                Delete the list of perl commands to run before each prompt.
7257 B<>> ?            List Perl commands to run after each prompt.
7258 B<>> I<expr>        Define Perl command to run after each prompt.
7259 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7260 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7261 B<{> I<db_command>    Define debugger command to run before each prompt.
7262 B<{> ?            List debugger commands to run before each prompt.
7263 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7264 B<{ *>             Delete the list of debugger commands to run before each prompt.
7265 B<$prc> I<number>    Redo a previous command (default previous command).
7266 B<$prc> I<-number>    Redo number'th-to-last command.
7267 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7268         See 'B<O> I<recallCommand>' too.
7269 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7270       . (
7271         $rc eq $sh
7272         ? ""
7273         : "
7274 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7275       ) . "
7276         See 'B<O> I<shellBang>' too.
7277 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7278 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7279 B<rerun>           Rerun session to current position.
7280 B<rerun> I<n>         Rerun session to numbered command.
7281 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7282 B<H> I<-number>    Display last number commands (default all).
7283 B<H> I<*>          Delete complete history.
7284 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7285 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7286 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7287 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7288 I<command>        Execute as a perl statement in current package.
7289 B<R>        Pure-man-restart of debugger, some of debugger state
7290         and command-line options may be lost.
7291         Currently the following settings are preserved:
7292         history, breakpoints and actions, debugger B<O>ptions
7293         and the following command-line options: I<-w>, I<-I>, I<-e>.
7294
7295 B<o> [I<opt>] ...    Set boolean option to true
7296 B<o> [I<opt>B<?>]    Query options
7297 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7298         Set options.  Use quotes if spaces in value.
7299     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7300     I<pager>            program for output of \"|cmd\";
7301     I<tkRunning>            run Tk while prompting (with ReadLine);
7302     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7303     I<inhibit_exit>        Allows stepping off the end of the script.
7304     I<ImmediateStop>        Debugger should stop as early as possible.
7305     I<RemotePort>            Remote hostname:port for remote debugging
7306   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7307     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7308     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7309     I<globPrint>             whether to print contents of globs;
7310     I<DumpDBFiles>         dump arrays holding debugged files;
7311     I<DumpPackages>         dump symbol tables of packages;
7312     I<DumpReused>             dump contents of \"reused\" addresses;
7313     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7314     I<bareStringify>         Do not print the overload-stringified value;
7315   Other options include:
7316     I<PrintRet>        affects printing of return value after B<r> command,
7317     I<frame>        affects printing messages on subroutine entry/exit.
7318     I<AutoTrace>    affects printing messages on possible breaking points.
7319     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7320     I<ornaments>     affects screen appearance of the command line.
7321     I<CreateTTY>     bits control attempts to create a new TTY on events:
7322             1: on fork()    2: debugger is started inside debugger
7323             4: on startup
7324     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7325     You can put additional initialization options I<TTY>, I<noTTY>,
7326     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7327     `B<R>' after you set them).
7328
7329 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7330 B<h>        Summary of debugger commands.
7331 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7332 B<h h>        Long help for debugger commands
7333 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7334         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7335         Set B<\$DB::doccmd> to change viewer.
7336
7337 Type `|h h' for a paged display if this was too hard to read.
7338
7339 ";    # Fix balance of vi % matching: }}}}
7340
7341     #  note: tabs in the following section are not-so-helpful
7342     $summary = <<"END_SUM";
7343 I<List/search source lines:>               I<Control script execution:>
7344   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7345   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7346   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7347   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7348   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7349   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7350 I<Debugger controls:>                        B<L>           List break/watch/actions
7351   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7352   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7353   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7354   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7355   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7356   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7357   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7358   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7359   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7360 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7361   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7362   B<p> I<expr>         Print expression (uses script's current package).
7363   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7364   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7365   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7366   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7367   B<e>     Display thread id     B<E> Display all thread ids.
7368 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7369 END_SUM
7370
7371     # ')}}; # Fix balance of vi % matching
7372
7373     # and this is really numb...
7374     $pre580_help = "
7375 B<T>        Stack trace.
7376 B<s> [I<expr>]    Single step [in I<expr>].
7377 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7378 B<CR>>        Repeat last B<n> or B<s> command.
7379 B<r>        Return from current subroutine.
7380 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7381         at the specified position.
7382 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7383 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7384 B<l> I<line>        List single I<line>.
7385 B<l> I<subname>    List first window of lines from subroutine.
7386 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7387 B<l>        List next window of lines.
7388 B<->        List previous window of lines.
7389 B<w> [I<line>]    List window around I<line>.
7390 B<.>        Return to the executed line.
7391 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7392         I<filename> may be either the full name of the file, or a regular
7393         expression matching the full file name:
7394         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7395         Evals (with saved bodies) are considered to be filenames:
7396         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7397         (in the order of execution).
7398 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7399 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7400 B<L>        List all breakpoints and actions.
7401 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7402 B<t>        Toggle trace mode.
7403 B<t> I<expr>        Trace through execution of I<expr>.
7404 B<b> [I<line>] [I<condition>]
7405         Set breakpoint; I<line> defaults to the current execution line;
7406         I<condition> breaks if it evaluates to true, defaults to '1'.
7407 B<b> I<subname> [I<condition>]
7408         Set breakpoint at first line of subroutine.
7409 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7410 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7411 B<b> B<postpone> I<subname> [I<condition>]
7412         Set breakpoint at first line of subroutine after
7413         it is compiled.
7414 B<b> B<compile> I<subname>
7415         Stop after the subroutine is compiled.
7416 B<d> [I<line>]    Delete the breakpoint for I<line>.
7417 B<D>        Delete all breakpoints.
7418 B<a> [I<line>] I<command>
7419         Set an action to be done before the I<line> is executed;
7420         I<line> defaults to the current execution line.
7421         Sequence is: check for breakpoint/watchpoint, print line
7422         if necessary, do action, prompt user if necessary,
7423         execute line.
7424 B<a> [I<line>]    Delete the action for I<line>.
7425 B<A>        Delete all actions.
7426 B<W> I<expr>        Add a global watch-expression.
7427 B<W>        Delete all watch-expressions.
7428 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7429         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7430 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7431 B<x> I<expr>        Evals expression in list context, dumps the result.
7432 B<m> I<expr>        Evals expression in list context, prints methods callable
7433         on the first element of the result.
7434 B<m> I<class>        Prints methods callable via the given class.
7435
7436 B<<> ?            List Perl commands to run before each prompt.
7437 B<<> I<expr>        Define Perl command to run before each prompt.
7438 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7439 B<>> ?            List Perl commands to run after each prompt.
7440 B<>> I<expr>        Define Perl command to run after each prompt.
7441 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7442 B<{> I<db_command>    Define debugger command to run before each prompt.
7443 B<{> ?            List debugger commands to run before each prompt.
7444 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7445 B<$prc> I<number>    Redo a previous command (default previous command).
7446 B<$prc> I<-number>    Redo number'th-to-last command.
7447 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7448         See 'B<O> I<recallCommand>' too.
7449 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7450       . (
7451         $rc eq $sh
7452         ? ""
7453         : "
7454 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7455       ) . "
7456         See 'B<O> I<shellBang>' too.
7457 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7458 B<H> I<-number>    Display last number commands (default all).
7459 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7460 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7461 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7462 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7463 I<command>        Execute as a perl statement in current package.
7464 B<v>        Show versions of loaded modules.
7465 B<R>        Pure-man-restart of debugger, some of debugger state
7466         and command-line options may be lost.
7467         Currently the following settings are preserved:
7468         history, breakpoints and actions, debugger B<O>ptions
7469         and the following command-line options: I<-w>, I<-I>, I<-e>.
7470
7471 B<O> [I<opt>] ...    Set boolean option to true
7472 B<O> [I<opt>B<?>]    Query options
7473 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7474         Set options.  Use quotes if spaces in value.
7475     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7476     I<pager>            program for output of \"|cmd\";
7477     I<tkRunning>            run Tk while prompting (with ReadLine);
7478     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7479     I<inhibit_exit>        Allows stepping off the end of the script.
7480     I<ImmediateStop>        Debugger should stop as early as possible.
7481     I<RemotePort>            Remote hostname:port for remote debugging
7482   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7483     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7484     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7485     I<globPrint>             whether to print contents of globs;
7486     I<DumpDBFiles>         dump arrays holding debugged files;
7487     I<DumpPackages>         dump symbol tables of packages;
7488     I<DumpReused>             dump contents of \"reused\" addresses;
7489     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7490     I<bareStringify>         Do not print the overload-stringified value;
7491   Other options include:
7492     I<PrintRet>        affects printing of return value after B<r> command,
7493     I<frame>        affects printing messages on subroutine entry/exit.
7494     I<AutoTrace>    affects printing messages on possible breaking points.
7495     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7496     I<ornaments>     affects screen appearance of the command line.
7497     I<CreateTTY>     bits control attempts to create a new TTY on events:
7498             1: on fork()    2: debugger is started inside debugger
7499             4: on startup
7500     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7501     You can put additional initialization options I<TTY>, I<noTTY>,
7502     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7503     `B<R>' after you set them).
7504
7505 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7506 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7507 B<h h>        Summary of debugger commands.
7508 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7509         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7510         Set B<\$DB::doccmd> to change viewer.
7511
7512 Type `|h' for a paged display if this was too hard to read.
7513
7514 ";    # Fix balance of vi % matching: }}}}
7515
7516     #  note: tabs in the following section are not-so-helpful
7517     $pre580_summary = <<"END_SUM";
7518 I<List/search source lines:>               I<Control script execution:>
7519   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7520   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7521   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7522   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7523   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7524   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7525 I<Debugger controls:>                        B<L>           List break/watch/actions
7526   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7527   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7528   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7529   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7530   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7531   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7532   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7533   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7534 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7535   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7536   B<p> I<expr>         Print expression (uses script's current package).
7537   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7538   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7539   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7540   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7541 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7542 END_SUM
7543
7544     # ')}}; # Fix balance of vi % matching
7545
7546 } ## end sub sethelp
7547
7548 =head2 C<print_help()>
7549
7550 Most of what C<print_help> does is just text formatting. It finds the
7551 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7552 terminal control characters to simulate them (courtesy of
7553 C<Term::ReadLine::TermCap>).
7554
7555 =cut
7556
7557 sub print_help {
7558     local $_ = shift;
7559
7560     # Restore proper alignment destroyed by eeevil I<> and B<>
7561     # ornaments: A pox on both their houses!
7562     #
7563     # A help command will have everything up to and including
7564     # the first tab sequence padded into a field 16 (or if indented 20)
7565     # wide.  If it's wider than that, an extra space will be added.
7566     s{
7567         ^                       # only matters at start of line
7568           ( \040{4} | \t )*     # some subcommands are indented
7569           ( < ?                 # so <CR> works
7570             [BI] < [^\t\n] + )  # find an eeevil ornament
7571           ( \t+ )               # original separation, discarded
7572           ( .* )                # this will now start (no earlier) than
7573                                 # column 16
7574     } {
7575         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7576         my $clean = $command;
7577         $clean =~ s/[BI]<([^>]*)>/$1/g;
7578
7579         # replace with this whole string:
7580         ($leadwhite ? " " x 4 : "")
7581       . $command
7582       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7583       . $text;
7584
7585     }mgex;
7586
7587     s{                          # handle bold ornaments
7588        B < ( [^>] + | > ) >
7589     } {
7590           $Term::ReadLine::TermCap::rl_term_set[2]
7591         . $1
7592         . $Term::ReadLine::TermCap::rl_term_set[3]
7593     }gex;
7594
7595     s{                         # handle italic ornaments
7596        I < ( [^>] + | > ) >
7597     } {
7598           $Term::ReadLine::TermCap::rl_term_set[0]
7599         . $1
7600         . $Term::ReadLine::TermCap::rl_term_set[1]
7601     }gex;
7602
7603     local $\ = '';
7604     print $OUT $_;
7605 } ## end sub print_help
7606
7607 =head2 C<fix_less>
7608
7609 This routine does a lot of gyrations to be sure that the pager is C<less>.
7610 It checks for C<less> masquerading as C<more> and records the result in
7611 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7612
7613 =cut
7614
7615 sub fix_less {
7616
7617     # We already know if this is set.
7618     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7619
7620     # Pager is less for sure.
7621     my $is_less = $pager =~ /\bless\b/;
7622     if ( $pager =~ /\bmore\b/ ) {
7623
7624         # Nope, set to more. See what's out there.
7625         my @st_more = stat('/usr/bin/more');
7626         my @st_less = stat('/usr/bin/less');
7627
7628         # is it really less, pretending to be more?
7629              $is_less = @st_more
7630           && @st_less
7631           && $st_more[0] == $st_less[0]
7632           && $st_more[1] == $st_less[1];
7633     } ## end if ($pager =~ /\bmore\b/)
7634
7635     # changes environment!
7636     # 'r' added so we don't do (slow) stats again.
7637     $ENV{LESS} .= 'r' if $is_less;
7638 } ## end sub fix_less
7639
7640 =head1 DIE AND WARN MANAGEMENT
7641
7642 =head2 C<diesignal>
7643
7644 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7645 to debug a debugger problem.
7646
7647 It does its best to report the error that occurred, and then forces the
7648 program, debugger, and everything to die.
7649
7650 =cut
7651
7652 sub diesignal {
7653
7654     # No entry/exit messages.
7655     local $frame = 0;
7656
7657     # No return value prints.
7658     local $doret = -2;
7659
7660     # set the abort signal handling to the default (just terminate).
7661     $SIG{'ABRT'} = 'DEFAULT';
7662
7663     # If we enter the signal handler recursively, kill myself with an
7664     # abort signal (so we just terminate).
7665     kill 'ABRT', $$ if $panic++;
7666
7667     # If we can show detailed info, do so.
7668     if ( defined &Carp::longmess ) {
7669
7670         # Don't recursively enter the warn handler, since we're carping.
7671         local $SIG{__WARN__} = '';
7672
7673         # Skip two levels before reporting traceback: we're skipping
7674         # mydie and confess.
7675         local $Carp::CarpLevel = 2;    # mydie + confess
7676
7677         # Tell us all about it.
7678         &warn( Carp::longmess("Signal @_") );
7679     }
7680
7681     # No Carp. Tell us about the signal as best we can.
7682     else {
7683         local $\ = '';
7684         print $DB::OUT "Got signal @_\n";
7685     }
7686
7687     # Drop dead.
7688     kill 'ABRT', $$;
7689 } ## end sub diesignal
7690
7691 =head2 C<dbwarn>
7692
7693 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7694 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7695
7696 =cut
7697
7698 sub dbwarn {
7699
7700     # No entry/exit trace.
7701     local $frame = 0;
7702
7703     # No return value printing.
7704     local $doret = -2;
7705
7706     # Turn off warn and die handling to prevent recursive entries to this
7707     # routine.
7708     local $SIG{__WARN__} = '';
7709     local $SIG{__DIE__}  = '';
7710
7711     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7712     # done yet), we may not be able to do a require.
7713     eval { require Carp }
7714       if defined $^S;    # If error/warning during compilation,
7715                          # require may be broken.
7716
7717     # Use the core warn() unless Carp loaded OK.
7718     CORE::warn( @_,
7719         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7720       return
7721       unless defined &Carp::longmess;
7722
7723     # Save the current values of $single and $trace, and then turn them off.
7724     my ( $mysingle, $mytrace ) = ( $single, $trace );
7725     $single = 0;
7726     $trace  = 0;
7727
7728     # We can call Carp::longmess without its being "debugged" (which we
7729     # don't want - we just want to use it!). Capture this for later.
7730     my $mess = Carp::longmess(@_);
7731
7732     # Restore $single and $trace to their original values.
7733     ( $single, $trace ) = ( $mysingle, $mytrace );
7734
7735     # Use the debugger's own special way of printing warnings to print
7736     # the stack trace message.
7737     &warn($mess);
7738 } ## end sub dbwarn
7739
7740 =head2 C<dbdie>
7741
7742 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7743 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7744 single stepping and tracing during the call to C<Carp::longmess> to avoid
7745 debugging it - we just want to use it.
7746
7747 If C<dieLevel> is zero, we let the program being debugged handle the
7748 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7749 the debugger takes over all exception handling, printing a backtrace and
7750 displaying the exception via its C<dbwarn()> routine.
7751
7752 =cut
7753
7754 sub dbdie {
7755     local $frame         = 0;
7756     local $doret         = -2;
7757     local $SIG{__DIE__}  = '';
7758     local $SIG{__WARN__} = '';
7759     my $i      = 0;
7760     my $ineval = 0;
7761     my $sub;
7762     if ( $dieLevel > 2 ) {
7763         local $SIG{__WARN__} = \&dbwarn;
7764         &warn(@_);    # Yell no matter what
7765         return;
7766     }
7767     if ( $dieLevel < 2 ) {
7768         die @_ if $^S;    # in eval propagate
7769     }
7770
7771     # The code used to check $^S to see if compiliation of the current thing
7772     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7773     eval { require Carp };
7774
7775     die( @_,
7776         "\nCannot print stack trace, load with -MCarp option to see stack" )
7777       unless defined &Carp::longmess;
7778
7779     # We do not want to debug this chunk (automatic disabling works
7780     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7781     # get the stack trace from Carp::longmess (if possible), restore $signal
7782     # and $trace, and then die with the stack trace.
7783     my ( $mysingle, $mytrace ) = ( $single, $trace );
7784     $single = 0;
7785     $trace  = 0;
7786     my $mess = "@_";
7787     {
7788
7789         package Carp;    # Do not include us in the list
7790         eval { $mess = Carp::longmess(@_); };
7791     }
7792     ( $single, $trace ) = ( $mysingle, $mytrace );
7793     die $mess;
7794 } ## end sub dbdie
7795
7796 =head2 C<warnlevel()>
7797
7798 Set the C<$DB::warnLevel> variable that stores the value of the
7799 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7800 results in the debugger taking over all warning handlers. Setting
7801 C<warnLevel> to zero leaves any warning handlers set up by the program
7802 being debugged in place.
7803
7804 =cut
7805
7806 sub warnLevel {
7807     if (@_) {
7808         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7809         $warnLevel = shift;
7810         if ($warnLevel) {
7811             $SIG{__WARN__} = \&DB::dbwarn;
7812         }
7813         elsif ($prevwarn) {
7814             $SIG{__WARN__} = $prevwarn;
7815         } else {
7816             undef $SIG{__WARN__};
7817         }
7818     } ## end if (@_)
7819     $warnLevel;
7820 } ## end sub warnLevel
7821
7822 =head2 C<dielevel>
7823
7824 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7825 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7826 zero lets you use your own C<die()> handler.
7827
7828 =cut
7829
7830 sub dieLevel {
7831     local $\ = '';
7832     if (@_) {
7833         $prevdie = $SIG{__DIE__} unless $dieLevel;
7834         $dieLevel = shift;
7835         if ($dieLevel) {
7836
7837             # Always set it to dbdie() for non-zero values.
7838             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7839
7840             # No longer exists, so don't try  to use it.
7841             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7842
7843             # If we've finished initialization, mention that stack dumps
7844             # are enabled, If dieLevel is 1, we won't stack dump if we die
7845             # in an eval().
7846             print $OUT "Stack dump during die enabled",
7847               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7848               if $I_m_init;
7849
7850             # XXX This is probably obsolete, given that diehard() is gone.
7851             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7852         } ## end if ($dieLevel)
7853
7854         # Put the old one back if there was one.
7855         elsif ($prevdie) {
7856             $SIG{__DIE__} = $prevdie;
7857             print $OUT "Default die handler restored.\n";
7858         } else {
7859             undef $SIG{__DIE__};
7860             print $OUT "Die handler removed.\n";
7861         }
7862     } ## end if (@_)
7863     $dieLevel;
7864 } ## end sub dieLevel
7865
7866 =head2 C<signalLevel>
7867
7868 Number three in a series: set C<signalLevel> to zero to keep your own
7869 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7870 takes over and handles them with C<DB::diesignal()>.
7871
7872 =cut
7873
7874 sub signalLevel {
7875     if (@_) {
7876         $prevsegv = $SIG{SEGV} unless $signalLevel;
7877         $prevbus  = $SIG{BUS}  unless $signalLevel;
7878         $signalLevel = shift;
7879         if ($signalLevel) {
7880             $SIG{SEGV} = \&DB::diesignal;
7881             $SIG{BUS}  = \&DB::diesignal;
7882         }
7883         else {
7884             $SIG{SEGV} = $prevsegv;
7885             $SIG{BUS}  = $prevbus;
7886         }
7887     } ## end if (@_)
7888     $signalLevel;
7889 } ## end sub signalLevel
7890
7891 =head1 SUBROUTINE DECODING SUPPORT
7892
7893 These subroutines are used during the C<x> and C<X> commands to try to
7894 produce as much information as possible about a code reference. They use
7895 L<Devel::Peek> to try to find the glob in which this code reference lives
7896 (if it does) - this allows us to actually code references which correspond
7897 to named subroutines (including those aliased via glob assignment).
7898
7899 =head2 C<CvGV_name()>
7900
7901 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7902 via that routine. If this fails, return the reference again (when the
7903 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7904
7905 =cut
7906
7907 sub CvGV_name {
7908     my $in   = shift;
7909     my $name = CvGV_name_or_bust($in);
7910     defined $name ? $name : $in;
7911 }
7912
7913 =head2 C<CvGV_name_or_bust> I<coderef>
7914
7915 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7916 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7917 find a glob for this ref.
7918
7919 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7920
7921 =cut
7922
7923 sub CvGV_name_or_bust {
7924     my $in = shift;
7925     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7926     return unless ref $in;
7927     $in = \&$in;            # Hard reference...
7928     eval { require Devel::Peek; 1 } or return;
7929     my $gv = Devel::Peek::CvGV($in) or return;
7930     *$gv{PACKAGE} . '::' . *$gv{NAME};
7931 } ## end sub CvGV_name_or_bust
7932
7933 =head2 C<find_sub>
7934
7935 A utility routine used in various places; finds the file where a subroutine
7936 was defined, and returns that filename and a line-number range.
7937
7938 Tries to use C<@sub> first; if it can't find it there, it tries building a
7939 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7940 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7941 this way, it brute-force searches C<%sub>, checking for identical references.
7942
7943 =cut
7944
7945 sub find_sub {
7946     my $subr = shift;
7947     $sub{$subr} or do {
7948         return unless defined &$subr;
7949         my $name = CvGV_name_or_bust($subr);
7950         my $data;
7951         $data = $sub{$name} if defined $name;
7952         return $data if defined $data;
7953
7954         # Old stupid way...
7955         $subr = \&$subr;    # Hard reference
7956         my $s;
7957         for ( keys %sub ) {
7958             $s = $_, last if $subr eq \&$_;
7959         }
7960         $sub{$s} if $s;
7961       } ## end do
7962 } ## end sub find_sub
7963
7964 =head2 C<methods>
7965
7966 A subroutine that uses the utility function C<methods_via> to find all the
7967 methods in the class corresponding to the current reference and in
7968 C<UNIVERSAL>.
7969
7970 =cut
7971
7972 sub methods {
7973
7974     # Figure out the class - either this is the class or it's a reference
7975     # to something blessed into that class.
7976     my $class = shift;
7977     $class = ref $class if ref $class;
7978
7979     local %seen;
7980
7981     # Show the methods that this class has.
7982     methods_via( $class, '', 1 );
7983
7984     # Show the methods that UNIVERSAL has.
7985     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7986 } ## end sub methods
7987
7988 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7989
7990 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7991 all the parent class methods. C<$class> is the name of the next class to
7992 try; C<$prefix> is the message prefix, which gets built up as we go up the
7993 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7994 higher in the C<@ISA> tree, 0 if we should stop.
7995
7996 =cut
7997
7998 sub methods_via {
7999
8000     # If we've processed this class already, just quit.
8001     my $class = shift;
8002     return if $seen{$class}++;
8003
8004     # This is a package that is contributing the methods we're about to print.
8005     my $prefix  = shift;
8006     my $prepend = $prefix ? "via $prefix: " : '';
8007     my @to_print;
8008
8009     # Extract from all the symbols in this class.
8010     while (my ($name, $glob) = each %{"${class}::"}) {
8011         # references directly in the symbol table are Proxy Constant
8012         # Subroutines, and are by their very nature defined
8013         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8014         # to a subroutine reference, which can be tested by defined.
8015         # $glob might also be the value -1  (from sub foo;)
8016         # or (say) '$$' (from sub foo ($$);)
8017         # \$glob will be SCALAR in both cases.
8018         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8019             && !$seen{$name}++) {
8020             push @to_print, "$prepend$name\n";
8021         }
8022     }
8023
8024     {
8025         local $\ = '';
8026         local $, = '';
8027         print $DB::OUT $_ foreach sort @to_print;
8028     }
8029
8030     # If the $crawl_upward argument is false, just quit here.
8031     return unless shift;
8032
8033     # $crawl_upward true: keep going up the tree.
8034     # Find all the classes this one is a subclass of.
8035     for $name ( @{"${class}::ISA"} ) {
8036
8037         # Set up the new prefix.
8038         $prepend = $prefix ? $prefix . " -> $name" : $name;
8039
8040         # Crawl up the tree and keep trying to crawl up.
8041         methods_via( $name, $prepend, 1 );
8042     }
8043 } ## end sub methods_via
8044
8045 =head2 C<setman> - figure out which command to use to show documentation
8046
8047 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8048
8049 =cut
8050
8051 sub setman {
8052     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
8053       ? "man"         # O Happy Day!
8054       : "perldoc";    # Alas, poor unfortunates
8055 } ## end sub setman
8056
8057 =head2 C<runman> - run the appropriate command to show documentation
8058
8059 Accepts a man page name; runs the appropriate command to display it (set up
8060 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8061 program's STDIN and STDOUT.
8062
8063 =cut
8064
8065 sub runman {
8066     my $page = shift;
8067     unless ($page) {
8068         &system("$doccmd $doccmd");
8069         return;
8070     }
8071
8072     # this way user can override, like with $doccmd="man -Mwhatever"
8073     # or even just "man " to disable the path check.
8074     unless ( $doccmd eq 'man' ) {
8075         &system("$doccmd $page");
8076         return;
8077     }
8078
8079     $page = 'perl' if lc($page) eq 'help';
8080
8081     require Config;
8082     my $man1dir = $Config::Config{'man1dir'};
8083     my $man3dir = $Config::Config{'man3dir'};
8084     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8085     my $manpath = '';
8086     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8087     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8088     chop $manpath if $manpath;
8089
8090     # harmless if missing, I figure
8091     my $oldpath = $ENV{MANPATH};
8092     $ENV{MANPATH} = $manpath if $manpath;
8093     my $nopathopt = $^O =~ /dunno what goes here/;
8094     if (
8095         CORE::system(
8096             $doccmd,
8097
8098             # I just *know* there are men without -M
8099             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8100             split ' ', $page
8101         )
8102       )
8103     {
8104         unless ( $page =~ /^perl\w/ ) {
8105 # do it this way because its easier to slurp in to keep up to date - clunky though.
8106 my @pods = qw(
8107     5004delta
8108     5005delta
8109     561delta
8110     56delta
8111     570delta
8112     571delta
8113     572delta
8114     573delta
8115     58delta
8116     581delta
8117     582delta
8118     583delta
8119     584delta
8120     590delta
8121     591delta
8122     592delta
8123     aix
8124     amiga
8125     apio
8126     api
8127     apollo
8128     artistic
8129     beos
8130     book
8131     boot
8132     bot
8133     bs2000
8134     call
8135     ce
8136     cheat
8137     clib
8138     cn
8139     compile
8140     cygwin
8141     data
8142     dbmfilter
8143     debguts
8144     debtut
8145     debug
8146     delta
8147     dgux
8148     diag
8149     doc
8150     dos
8151     dsc
8152     ebcdic
8153     embed
8154     epoc
8155     faq1
8156     faq2
8157     faq3
8158     faq4
8159     faq5
8160     faq6
8161     faq7
8162     faq8
8163     faq9
8164     faq
8165     filter
8166     fork
8167     form
8168     freebsd
8169     func
8170     gpl
8171     guts
8172     hack
8173     hist
8174     hpux
8175     hurd
8176     intern
8177     intro
8178     iol
8179     ipc
8180     irix
8181     jp
8182     ko
8183     lexwarn
8184     locale
8185     lol
8186     machten
8187     macos
8188     macosx
8189     modinstall
8190     modlib
8191     mod
8192     modstyle
8193     mpeix
8194     netware
8195     newmod
8196     number
8197     obj
8198     opentut
8199     op
8200     os2
8201     os390
8202     os400
8203     packtut
8204     plan9
8205     pod
8206     podspec
8207     port
8208     qnx
8209     ref
8210     reftut
8211     re
8212     requick
8213     reref
8214     retut
8215     run
8216     sec
8217     solaris
8218     style
8219     sub
8220     syn
8221     thrtut
8222     tie
8223     toc
8224     todo
8225     tooc
8226     toot
8227     trap
8228     tru64
8229     tw
8230     unicode
8231     uniintro
8232     util
8233     uts
8234     var
8235     vmesa
8236     vms
8237     vos
8238     win32
8239     xs
8240     xstut
8241 );
8242             if (grep { $page eq $_ } @pods) {
8243                 $page =~ s/^/perl/;
8244                 CORE::system( $doccmd,
8245                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8246                     $page );
8247             } ## end if (grep { $page eq $_...
8248         } ## end unless ($page =~ /^perl\w/)
8249     } ## end if (CORE::system($doccmd...
8250     if ( defined $oldpath ) {
8251         $ENV{MANPATH} = $manpath;
8252     }
8253     else {
8254         delete $ENV{MANPATH};
8255     }
8256 } ## end sub runman
8257
8258 #use Carp;                          # This did break, left for debugging
8259
8260 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8261
8262 Because of the way the debugger interface to the Perl core is designed, any
8263 debugger package globals that C<DB::sub()> requires have to be defined before
8264 any subroutines can be called. These are defined in the second C<BEGIN> block.
8265
8266 This block sets things up so that (basically) the world is sane
8267 before the debugger starts executing. We set up various variables that the
8268 debugger has to have set up before the Perl core starts running:
8269
8270 =over 4
8271
8272 =item *
8273
8274 The debugger's own filehandles (copies of STD and STDOUT for now).
8275
8276 =item *
8277
8278 Characters for shell escapes, the recall command, and the history command.
8279
8280 =item *
8281
8282 The maximum recursion depth.
8283
8284 =item *
8285
8286 The size of a C<w> command's window.
8287
8288 =item *
8289
8290 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8291
8292 =item *
8293
8294 The fact that we're not in a sub at all right now.
8295
8296 =item *
8297
8298 The default SIGINT handler for the debugger.
8299
8300 =item *
8301
8302 The appropriate value of the flag in C<$^D> that says the debugger is running
8303
8304 =item *
8305
8306 The current debugger recursion level
8307
8308 =item *
8309
8310 The list of postponed items and the C<$single> stack (XXX define this)
8311
8312 =item *
8313
8314 That we want no return values and no subroutine entry/exit trace.
8315
8316 =back
8317
8318 =cut
8319
8320 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8321
8322 BEGIN {    # This does not compile, alas. (XXX eh?)
8323     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8324     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8325
8326     # Define characters used by command parsing.
8327     $sh       = '!';      # Shell escape (does not work)
8328     $rc       = ',';      # Recall command (does not work)
8329     @hist     = ('?');    # Show history (does not work)
8330     @truehist = ();       # Can be saved for replay (per session)
8331
8332     # This defines the point at which you get the 'deep recursion'
8333     # warning. It MUST be defined or the debugger will not load.
8334     $deep = 100;
8335
8336     # Number of lines around the current one that are shown in the
8337     # 'w' command.
8338     $window = 10;
8339
8340     # How much before-the-current-line context the 'v' command should
8341     # use in calculating the start of the window it will display.
8342     $preview = 3;
8343
8344     # We're not in any sub yet, but we need this to be a defined value.
8345     $sub = '';
8346
8347     # Set up the debugger's interrupt handler. It simply sets a flag
8348     # ($signal) that DB::DB() will check before each command is executed.
8349     $SIG{INT} = \&DB::catch;
8350
8351     # The following lines supposedly, if uncommented, allow the debugger to
8352     # debug itself. Perhaps we can try that someday.
8353     # This may be enabled to debug debugger:
8354     #$warnLevel = 1 unless defined $warnLevel;
8355     #$dieLevel = 1 unless defined $dieLevel;
8356     #$signalLevel = 1 unless defined $signalLevel;
8357
8358     # This is the flag that says "a debugger is running, please call
8359     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8360     # execute anything in the user's context, because we always want to
8361     # get control back.
8362     $db_stop = 0;          # Compiler warning ...
8363     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8364
8365     # This variable records how many levels we're nested in debugging. Used
8366     # Used in the debugger prompt, and in determining whether it's all over or
8367     # not.
8368     $level = 0;            # Level of recursive debugging
8369
8370     # "Triggers bug (?) in perl if we postpone this until runtime."
8371     # XXX No details on this yet, or whether we should fix the bug instead
8372     # of work around it. Stay tuned.
8373     @postponed = @stack = (0);
8374
8375     # Used to track the current stack depth using the auto-stacked-variable
8376     # trick.
8377     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8378
8379     # Don't print return values on exiting a subroutine.
8380     $doret = -2;
8381
8382     # No extry/exit tracing.
8383     $frame = 0;
8384
8385 } ## end BEGIN
8386
8387 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8388
8389 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8390
8391 =head2 db_complete
8392
8393 C<readline> support - adds command completion to basic C<readline>.
8394
8395 Returns a list of possible completions to C<readline> when invoked. C<readline>
8396 will print the longest common substring following the text already entered.
8397
8398 If there is only a single possible completion, C<readline> will use it in full.
8399
8400 This code uses C<map> and C<grep> heavily to create lists of possible
8401 completion. Think LISP in this section.
8402
8403 =cut
8404
8405 sub db_complete {
8406
8407     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8408     # $text is the text to be completed.
8409     # $line is the incoming line typed by the user.
8410     # $start is the start of the text to be completed in the incoming line.
8411     my ( $text, $line, $start ) = @_;
8412
8413     # Save the initial text.
8414     # The search pattern is current package, ::, extract the next qualifier
8415     # Prefix and pack are set to undef.
8416     my ( $itext, $search, $prefix, $pack ) =
8417       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8418
8419 =head3 C<b postpone|compile>
8420
8421 =over 4
8422
8423 =item *
8424
8425 Find all the subroutines that might match in this package
8426
8427 =item *
8428
8429 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8430
8431 =item *
8432
8433 Include all the rest of the subs that are known
8434
8435 =item *
8436
8437 C<grep> out the ones that match the text we have so far
8438
8439 =item *
8440
8441 Return this as the list of possible completions
8442
8443 =back
8444
8445 =cut
8446
8447     return sort grep /^\Q$text/, ( keys %sub ),
8448       qw(postpone load compile),    # subroutines
8449       ( map { /$search/ ? ($1) : () } keys %sub )
8450       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8451
8452 =head3 C<b load>
8453
8454 Get all the possible files from C<@INC> as it currently stands and
8455 select the ones that match the text so far.
8456
8457 =cut
8458
8459     return sort grep /^\Q$text/, values %INC    # files
8460       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8461
8462 =head3  C<V> (list variable) and C<m> (list modules)
8463
8464 There are two entry points for these commands:
8465
8466 =head4 Unqualified package names
8467
8468 Get the top-level packages and grab everything that matches the text
8469 so far. For each match, recursively complete the partial packages to
8470 get all possible matching packages. Return this sorted list.
8471
8472 =cut
8473
8474     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8475       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8476       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8477
8478 =head4 Qualified package names
8479
8480 Take a partially-qualified package and find all subpackages for it
8481 by getting all the subpackages for the package so far, matching all
8482 the subpackages against the text, and discarding all of them which
8483 start with 'main::'. Return this list.
8484
8485 =cut
8486
8487     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8488       grep !/^main::/, grep /^\Q$text/,
8489       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8490       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8491       and $text =~ /^(.*[^:])::?(\w*)$/
8492       and $prefix = $1;
8493
8494 =head3 C<f> - switch files
8495
8496 Here, we want to get a fully-qualified filename for the C<f> command.
8497 Possibilities are:
8498
8499 =over 4
8500
8501 =item 1. The original source file itself
8502
8503 =item 2. A file from C<@INC>
8504
8505 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8506
8507 =back
8508
8509 =cut
8510
8511     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8512            # We might possibly want to switch to an eval (which has a "filename"
8513            # like '(eval 9)'), so we may need to clean up the completion text
8514            # before proceeding.
8515         $prefix = length($1) - length($text);
8516         $text   = $1;
8517
8518 =pod
8519
8520 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8521 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8522 out of C<%main::>, add the initial source file, and extract the ones that
8523 match the completion text so far.
8524
8525 =cut
8526
8527         return sort
8528           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8529           $0;
8530     } ## end if ($line =~ /^\|*f\s+(.*)/)
8531
8532 =head3 Subroutine name completion
8533
8534 We look through all of the defined subs (the keys of C<%sub>) and
8535 return both all the possible matches to the subroutine name plus
8536 all the matches qualified to the current package.
8537
8538 =cut
8539
8540     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8541         $text = substr $text, 1;
8542         $prefix = "&";
8543         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8544           (
8545             map { /$search/ ? ($1) : () }
8546               keys %sub
8547           );
8548     } ## end if ((substr $text, 0, ...
8549
8550 =head3  Scalar, array, and hash completion: partially qualified package
8551
8552 Much like the above, except we have to do a little more cleanup:
8553
8554 =cut
8555
8556     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8557
8558 =pod
8559
8560 =over 4
8561
8562 =item *
8563
8564 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8565
8566 =cut
8567
8568         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8569
8570 =pod
8571
8572 =item *
8573
8574 Figure out the prefix vs. what needs completing.
8575
8576 =cut
8577
8578         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8579         $text   = $2;
8580
8581 =pod
8582
8583 =item *
8584
8585 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8586
8587 =cut
8588
8589         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8590           keys %$pack;
8591
8592 =pod
8593
8594 =item *
8595
8596 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8597
8598 =cut
8599
8600         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8601             return db_complete( $out[0], $line, $start );
8602         }
8603
8604         # Return the list of possibles.
8605         return sort @out;
8606
8607     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8608
8609 =pod
8610
8611 =back
8612
8613 =head3 Symbol completion: current package or package C<main>.
8614
8615 =cut
8616
8617     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8618 =pod
8619
8620 =over 4
8621
8622 =item *
8623
8624 If it's C<main>, delete main to just get C<::> leading.
8625
8626 =cut
8627
8628         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8629
8630 =pod
8631
8632 =item *
8633
8634 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8635
8636 =cut
8637
8638         $prefix = substr $text, 0, 1;
8639         $text   = substr $text, 1;
8640
8641         my @out;
8642
8643 =pod
8644
8645 =item *
8646
8647 We look for the lexical scope above DB::DB and auto-complete lexical variables
8648 if PadWalker could be loaded.
8649
8650 =cut
8651
8652         if (not $text =~ /::/ and eval "require PadWalker; 1" and not $@ ) {
8653             my $level = 1;
8654             while (1) {
8655                 my @info = caller($level);
8656                 $level++;
8657                 $level = -1, last
8658                   if not @info;
8659                 last if $info[3] eq 'DB::DB';
8660             }
8661             if ($level > 0) {
8662                 my $lexicals = PadWalker::peek_my($level);
8663                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8664             }
8665         }
8666
8667 =pod
8668
8669 =item *
8670
8671 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8672
8673 =cut
8674
8675         push @out, map "$prefix$_", grep /^\Q$text/,
8676           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8677           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8678
8679 =item *
8680
8681 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8682
8683 =back
8684
8685 =cut
8686
8687         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8688             return db_complete( $out[0], $line, $start );
8689         }
8690
8691         # Return the list of possibles.
8692         return sort @out;
8693     } ## end if ($text =~ /^[\$@%]/)
8694
8695 =head3 Options
8696
8697 We use C<option_val()> to look up the current value of the option. If there's
8698 only a single value, we complete the command in such a way that it is a
8699 complete command for setting the option in question. If there are multiple
8700 possible values, we generate a command consisting of the option plus a trailing
8701 question mark, which, if executed, will list the current value of the option.
8702
8703 =cut
8704
8705     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8706     {    # Options after space
8707            # We look for the text to be matched in the list of possible options,
8708            # and fetch the current value.
8709         my @out = grep /^\Q$text/, @options;
8710         my $val = option_val( $out[0], undef );
8711
8712         # Set up a 'query option's value' command.
8713         my $out = '? ';
8714         if ( not defined $val or $val =~ /[\n\r]/ ) {
8715
8716             # There's really nothing else we can do.
8717         }
8718
8719         # We have a value. Create a proper option-setting command.
8720         elsif ( $val =~ /\s/ ) {
8721
8722             # XXX This may be an extraneous variable.
8723             my $found;
8724
8725             # We'll want to quote the string (because of the embedded
8726             # whtespace), but we want to make sure we don't end up with
8727             # mismatched quote characters. We try several possibilities.
8728             foreach $l ( split //, qq/\"\'\#\|/ ) {
8729
8730                 # If we didn't find this quote character in the value,
8731                 # quote it using this quote character.
8732                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8733             }
8734         } ## end elsif ($val =~ /\s/)
8735
8736         # Don't need any quotes.
8737         else {
8738             $out = "=$val ";
8739         }
8740
8741         # If there were multiple possible values, return '? ', which
8742         # makes the command into a query command. If there was just one,
8743         # have readline append that.
8744         $rl_attribs->{completer_terminator_character} =
8745           ( @out == 1 ? $out : '? ' );
8746
8747         # Return list of possibilities.
8748         return sort @out;
8749     } ## end if ((substr $line, 0, ...
8750
8751 =head3 Filename completion
8752
8753 For entering filenames. We simply call C<readline>'s C<filename_list()>
8754 method with the completion text to get the possible completions.
8755
8756 =cut
8757
8758     return $term->filename_list($text);    # filenames
8759
8760 } ## end sub db_complete
8761
8762 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8763
8764 Functions that possibly ought to be somewhere else.
8765
8766 =head2 end_report
8767
8768 Say we're done.
8769
8770 =cut
8771
8772 sub end_report {
8773     local $\ = '';
8774     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8775 }
8776
8777 =head2 clean_ENV
8778
8779 If we have $ini_pids, save it in the environment; else remove it from the
8780 environment. Used by the C<R> (restart) command.
8781
8782 =cut
8783
8784 sub clean_ENV {
8785     if ( defined($ini_pids) ) {
8786         $ENV{PERLDB_PIDS} = $ini_pids;
8787     }
8788     else {
8789         delete( $ENV{PERLDB_PIDS} );
8790     }
8791 } ## end sub clean_ENV
8792
8793 # PERLDBf_... flag names from perl.h
8794 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8795
8796 BEGIN {
8797     %DollarCaretP_flags = (
8798         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8799         PERLDBf_LINE      => 0x02,     # Keep line #
8800         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8801         PERLDBf_INTER     => 0x08,     # Preserve more data
8802         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8803         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8804         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8805         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8806         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8807         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8808         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8809         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8810     );
8811     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8812     # doesn't need to set it. It's provided for the benefit of profilers and
8813     # other code analysers.
8814
8815     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8816 }
8817
8818 sub parse_DollarCaretP_flags {
8819     my $flags = shift;
8820     $flags =~ s/^\s+//;
8821     $flags =~ s/\s+$//;
8822     my $acu = 0;
8823     foreach my $f ( split /\s*\|\s*/, $flags ) {
8824         my $value;
8825         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8826             $value = hex $1;
8827         }
8828         elsif ( $f =~ /^(\d+)$/ ) {
8829             $value = int $1;
8830         }
8831         elsif ( $f =~ /^DEFAULT$/i ) {
8832             $value = $DollarCaretP_flags{PERLDB_ALL};
8833         }
8834         else {
8835             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8836             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8837             unless ( defined $value ) {
8838                 print $OUT (
8839                     "Unrecognized \$^P flag '$f'!\n",
8840                     "Acceptable flags are: "
8841                       . join( ', ', sort keys %DollarCaretP_flags ),
8842                     ", and hexadecimal and decimal numbers.\n"
8843                 );
8844                 return undef;
8845             }
8846         }
8847         $acu |= $value;
8848     }
8849     $acu;
8850 }
8851
8852 sub expand_DollarCaretP_flags {
8853     my $DollarCaretP = shift;
8854     my @bits         = (
8855         map {
8856             my $n = ( 1 << $_ );
8857             ( $DollarCaretP & $n )
8858               ? ( $DollarCaretP_flags_r{$n}
8859                   || sprintf( '0x%x', $n ) )
8860               : ()
8861           } 0 .. 31
8862     );
8863     return @bits ? join( '|', @bits ) : 0;
8864 }
8865
8866 =over 4
8867
8868 =item rerun
8869
8870 Rerun the current session to:
8871
8872     rerun        current position
8873
8874     rerun 4      command number 4
8875
8876     rerun -4     current command minus 4 (go back 4 steps)
8877
8878 Whether this always makes sense, in the current context is unknowable, and is
8879 in part left as a useful exersize for the reader.  This sub returns the
8880 appropriate arguments to rerun the current session.
8881
8882 =cut
8883
8884 sub rerun {
8885     my $i = shift;
8886     my @args;
8887     pop(@truehist);                      # strim
8888     unless (defined $truehist[$i]) {
8889         print "Unable to return to non-existent command: $i\n";
8890     } else {
8891         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8892         my @temp = @truehist;            # store
8893         push(@DB::typeahead, @truehist); # saved
8894         @truehist = @hist = ();          # flush
8895         @args = &restart();              # setup
8896         &get_list("PERLDB_HIST");        # clean
8897         &set_list("PERLDB_HIST", @temp); # reset
8898     }
8899     return @args;
8900 }
8901
8902 =item restart
8903
8904 Restarting the debugger is a complex operation that occurs in several phases.
8905 First, we try to reconstruct the command line that was used to invoke Perl
8906 and the debugger.
8907
8908 =cut
8909
8910 sub restart {
8911     # I may not be able to resurrect you, but here goes ...
8912     print $OUT
8913 "Warning: some settings and command-line options may be lost!\n";
8914     my ( @script, @flags, $cl );
8915
8916     # If warn was on before, turn it on again.
8917     push @flags, '-w' if $ini_warn;
8918
8919     # Rebuild the -I flags that were on the initial
8920     # command line.
8921     for (@ini_INC) {
8922         push @flags, '-I', $_;
8923     }
8924
8925     # Turn on taint if it was on before.
8926     push @flags, '-T' if ${^TAINT};
8927
8928     # Arrange for setting the old INC:
8929     # Save the current @init_INC in the environment.
8930     set_list( "PERLDB_INC", @ini_INC );
8931
8932     # If this was a perl one-liner, go to the "file"
8933     # corresponding to the one-liner read all the lines
8934     # out of it (except for the first one, which is going
8935     # to be added back on again when 'perl -d' runs: that's
8936     # the 'require perl5db.pl;' line), and add them back on
8937     # to the command line to be executed.
8938     if ( $0 eq '-e' ) {
8939         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8940             chomp( $cl = ${'::_<-e'}[$_] );
8941             push @script, '-e', $cl;
8942         }
8943     } ## end if ($0 eq '-e')
8944
8945     # Otherwise we just reuse the original name we had
8946     # before.
8947     else {
8948         @script = $0;
8949     }
8950
8951 =pod
8952
8953 After the command line  has been reconstructed, the next step is to save
8954 the debugger's status in environment variables. The C<DB::set_list> routine
8955 is used to save aggregate variables (both hashes and arrays); scalars are
8956 just popped into environment variables directly.
8957
8958 =cut
8959
8960     # If the terminal supported history, grab it and
8961     # save that in the environment.
8962     set_list( "PERLDB_HIST",
8963           $term->Features->{getHistory}
8964         ? $term->GetHistory
8965         : @hist );
8966
8967     # Find all the files that were visited during this
8968     # session (i.e., the debugger had magic hashes
8969     # corresponding to them) and stick them in the environment.
8970     my @had_breakpoints = keys %had_breakpoints;
8971     set_list( "PERLDB_VISITED", @had_breakpoints );
8972
8973     # Save the debugger options we chose.
8974     set_list( "PERLDB_OPT", %option );
8975     # set_list( "PERLDB_OPT", options2remember() );
8976
8977     # Save the break-on-loads.
8978     set_list( "PERLDB_ON_LOAD", %break_on_load );
8979
8980 =pod
8981
8982 The most complex part of this is the saving of all of the breakpoints. They
8983 can live in an awful lot of places, and we have to go through all of them,
8984 find the breakpoints, and then save them in the appropriate environment
8985 variable via C<DB::set_list>.
8986
8987 =cut
8988
8989     # Go through all the breakpoints and make sure they're
8990     # still valid.
8991     my @hard;
8992     for ( 0 .. $#had_breakpoints ) {
8993
8994         # We were in this file.
8995         my $file = $had_breakpoints[$_];
8996
8997         # Grab that file's magic line hash.
8998         *dbline = $main::{ '_<' . $file };
8999
9000         # Skip out if it doesn't exist, or if the breakpoint
9001         # is in a postponed file (we'll do postponed ones
9002         # later).
9003         next unless %dbline or $postponed_file{$file};
9004
9005         # In an eval. This is a little harder, so we'll
9006         # do more processing on that below.
9007         ( push @hard, $file ), next
9008           if $file =~ /^\(\w*eval/;
9009
9010         # XXX I have no idea what this is doing. Yet.
9011         my @add;
9012         @add = %{ $postponed_file{$file} }
9013           if $postponed_file{$file};
9014
9015         # Save the list of all the breakpoints for this file.
9016         set_list( "PERLDB_FILE_$_", %dbline, @add );
9017     } ## end for (0 .. $#had_breakpoints)
9018
9019     # The breakpoint was inside an eval. This is a little
9020     # more difficult. XXX and I don't understand it.
9021     for (@hard) {
9022         # Get over to the eval in question.
9023         *dbline = $main::{ '_<' . $_ };
9024         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9025         for $sub ( keys %sub ) {
9026             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9027             $subs{$sub} = [ $1, $2 ];
9028         }
9029         unless (%subs) {
9030             print $OUT
9031               "No subroutines in $_, ignoring breakpoints.\n";
9032             next;
9033         }
9034       LINES: for $line ( keys %dbline ) {
9035
9036             # One breakpoint per sub only:
9037             my ( $offset, $sub, $found );
9038           SUBS: for $sub ( keys %subs ) {
9039                 if (
9040                     $subs{$sub}->[1] >=
9041                     $line    # Not after the subroutine
9042                     and (
9043                         not defined $offset    # Not caught
9044                         or $offset < 0
9045                     )
9046                   )
9047                 {                              # or badly caught
9048                     $found  = $sub;
9049                     $offset = $line - $subs{$sub}->[0];
9050                     $offset = "+$offset", last SUBS
9051                       if $offset >= 0;
9052                 } ## end if ($subs{$sub}->[1] >=...
9053             } ## end for $sub (keys %subs)
9054             if ( defined $offset ) {
9055                 $postponed{$found} =
9056                   "break $offset if $dbline{$line}";
9057             }
9058             else {
9059                 print $OUT
9060 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9061             }
9062         } ## end for $line (keys %dbline)
9063     } ## end for (@hard)
9064
9065     # Save the other things that don't need to be
9066     # processed.
9067     set_list( "PERLDB_POSTPONE",  %postponed );
9068     set_list( "PERLDB_PRETYPE",   @$pretype );
9069     set_list( "PERLDB_PRE",       @$pre );
9070     set_list( "PERLDB_POST",      @$post );
9071     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9072
9073     # We are oficially restarting.
9074     $ENV{PERLDB_RESTART} = 1;
9075
9076     # We are junking all child debuggers.
9077     delete $ENV{PERLDB_PIDS};    # Restore ini state
9078
9079     # Set this back to the initial pid.
9080     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9081
9082 =pod
9083
9084 After all the debugger status has been saved, we take the command we built up
9085 and then return it, so we can C<exec()> it. The debugger will spot the
9086 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9087 from the environment.
9088
9089 =cut
9090
9091     # And run Perl again. Add the "-d" flag, all the
9092     # flags we built up, the script (whether a one-liner
9093     # or a file), add on the -emacs flag for a slave editor,
9094     # and then the old arguments.
9095
9096     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9097
9098 };  # end restart
9099
9100 =back
9101
9102 =head1 END PROCESSING - THE C<END> BLOCK
9103
9104 Come here at the very end of processing. We want to go into a
9105 loop where we allow the user to enter commands and interact with the
9106 debugger, but we don't want anything else to execute.
9107
9108 First we set the C<$finished> variable, so that some commands that
9109 shouldn't be run after the end of program quit working.
9110
9111 We then figure out whether we're truly done (as in the user entered a C<q>
9112 command, or we finished execution while running nonstop). If we aren't,
9113 we set C<$single> to 1 (causing the debugger to get control again).
9114
9115 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9116 message and returns control to the debugger. Repeat.
9117
9118 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9119 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9120 break, run to completion.).
9121
9122 =cut
9123
9124 END {
9125     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9126     $fall_off_end = 1 unless $inhibit_exit;
9127
9128     # Do not stop in at_exit() and destructors on exit:
9129     if ($fall_off_end or $runnonstop) {
9130         &save_hist();
9131     } else {
9132         $DB::single = 1;
9133         DB::fake::at_exit();
9134     }
9135 } ## end END
9136
9137 =head1 PRE-5.8 COMMANDS
9138
9139 Some of the commands changed function quite a bit in the 5.8 command
9140 realignment, so much so that the old code had to be replaced completely.
9141 Because we wanted to retain the option of being able to go back to the
9142 former command set, we moved the old code off to this section.
9143
9144 There's an awful lot of duplicated code here. We've duplicated the
9145 comments to keep things clear.
9146
9147 =head2 Null command
9148
9149 Does nothing. Used to I<turn off> commands.
9150
9151 =cut
9152
9153 sub cmd_pre580_null {
9154
9155     # do nothing...
9156 }
9157
9158 =head2 Old C<a> command.
9159
9160 This version added actions if you supplied them, and deleted them
9161 if you didn't.
9162
9163 =cut
9164
9165 sub cmd_pre580_a {
9166     my $xcmd = shift;
9167     my $cmd  = shift;
9168
9169     # Argument supplied. Add the action.
9170     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9171
9172         # If the line isn't there, use the current line.
9173         $i = $1 || $line;
9174         $j = $2;
9175
9176         # If there is an action ...
9177         if ( length $j ) {
9178
9179             # ... but the line isn't breakable, skip it.
9180             if ( $dbline[$i] == 0 ) {
9181                 print $OUT "Line $i may not have an action.\n";
9182             }
9183             else {
9184
9185                 # ... and the line is breakable:
9186                 # Mark that there's an action in this file.
9187                 $had_breakpoints{$filename} |= 2;
9188
9189                 # Delete any current action.
9190                 $dbline{$i} =~ s/\0[^\0]*//;
9191
9192                 # Add the new action, continuing the line as needed.
9193                 $dbline{$i} .= "\0" . action($j);
9194             }
9195         } ## end if (length $j)
9196
9197         # No action supplied.
9198         else {
9199
9200             # Delete the action.
9201             $dbline{$i} =~ s/\0[^\0]*//;
9202
9203             # Mark as having no break or action if nothing's left.
9204             delete $dbline{$i} if $dbline{$i} eq '';
9205         }
9206     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9207 } ## end sub cmd_pre580_a
9208
9209 =head2 Old C<b> command
9210
9211 Add breakpoints.
9212
9213 =cut
9214
9215 sub cmd_pre580_b {
9216     my $xcmd   = shift;
9217     my $cmd    = shift;
9218     my $dbline = shift;
9219
9220     # Break on load.
9221     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9222         my $file = $1;
9223         $file =~ s/\s+$//;
9224         &cmd_b_load($file);
9225     }
9226
9227     # b compile|postpone <some sub> [<condition>]
9228     # The interpreter actually traps this one for us; we just put the
9229     # necessary condition in the %postponed hash.
9230     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9231
9232         # Capture the condition if there is one. Make it true if none.
9233         my $cond = length $3 ? $3 : '1';
9234
9235         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9236         # if it was 'compile'.
9237         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9238
9239         # De-Perl4-ify the name - ' separators to ::.
9240         $subname =~ s/\'/::/g;
9241
9242         # Qualify it into the current package unless it's already qualified.
9243         $subname = "${'package'}::" . $subname
9244           unless $subname =~ /::/;
9245
9246         # Add main if it starts with ::.
9247         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9248
9249         # Save the break type for this sub.
9250         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9251     } ## end elsif ($cmd =~ ...
9252
9253     # b <sub name> [<condition>]
9254     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9255         my $subname = $1;
9256         my $cond = length $2 ? $2 : '1';
9257         &cmd_b_sub( $subname, $cond );
9258     }
9259
9260     # b <line> [<condition>].
9261     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9262         my $i = $1 || $dbline;
9263         my $cond = length $2 ? $2 : '1';
9264         &cmd_b_line( $i, $cond );
9265     }
9266 } ## end sub cmd_pre580_b
9267
9268 =head2 Old C<D> command.
9269
9270 Delete all breakpoints unconditionally.
9271
9272 =cut
9273
9274 sub cmd_pre580_D {
9275     my $xcmd = shift;
9276     my $cmd  = shift;
9277     if ( $cmd =~ /^\s*$/ ) {
9278         print $OUT "Deleting all breakpoints...\n";
9279
9280         # %had_breakpoints lists every file that had at least one
9281         # breakpoint in it.
9282         my $file;
9283         for $file ( keys %had_breakpoints ) {
9284
9285             # Switch to the desired file temporarily.
9286             local *dbline = $main::{ '_<' . $file };
9287
9288             my $max = $#dbline;
9289             my $was;
9290
9291             # For all lines in this file ...
9292             for ( $i = 1 ; $i <= $max ; $i++ ) {
9293
9294                 # If there's a breakpoint or action on this line ...
9295                 if ( defined $dbline{$i} ) {
9296
9297                     # ... remove the breakpoint.
9298                     $dbline{$i} =~ s/^[^\0]+//;
9299                     if ( $dbline{$i} =~ s/^\0?$// ) {
9300
9301                         # Remove the entry altogether if no action is there.
9302                         delete $dbline{$i};
9303                     }
9304                 } ## end if (defined $dbline{$i...
9305             } ## end for ($i = 1 ; $i <= $max...
9306
9307             # If, after we turn off the "there were breakpoints in this file"
9308             # bit, the entry in %had_breakpoints for this file is zero,
9309             # we should remove this file from the hash.
9310             if ( not $had_breakpoints{$file} &= ~1 ) {
9311                 delete $had_breakpoints{$file};
9312             }
9313         } ## end for $file (keys %had_breakpoints)
9314
9315         # Kill off all the other breakpoints that are waiting for files that
9316         # haven't been loaded yet.
9317         undef %postponed;
9318         undef %postponed_file;
9319         undef %break_on_load;
9320     } ## end if ($cmd =~ /^\s*$/)
9321 } ## end sub cmd_pre580_D
9322
9323 =head2 Old C<h> command
9324
9325 Print help. Defaults to printing the long-form help; the 5.8 version
9326 prints the summary by default.
9327
9328 =cut
9329
9330 sub cmd_pre580_h {
9331     my $xcmd = shift;
9332     my $cmd  = shift;
9333
9334     # Print the *right* help, long format.
9335     if ( $cmd =~ /^\s*$/ ) {
9336         print_help($pre580_help);
9337     }
9338
9339     # 'h h' - explicitly-requested summary.
9340     elsif ( $cmd =~ /^h\s*/ ) {
9341         print_help($pre580_summary);
9342     }
9343
9344     # Find and print a command's help.
9345     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9346         my $asked  = $1;                   # for proper errmsg
9347         my $qasked = quotemeta($asked);    # for searching
9348                                            # XXX: finds CR but not <CR>
9349         if (
9350             $pre580_help =~ /^
9351                               <?           # Optional '<'
9352                               (?:[IB]<)    # Optional markup
9353                               $qasked      # The command name
9354                             /mx
9355           )
9356         {
9357
9358             while (
9359                 $pre580_help =~ /^
9360                                   (             # The command help:
9361                                    <?           # Optional '<'
9362                                    (?:[IB]<)    # Optional markup
9363                                    $qasked      # The command name
9364                                    ([\s\S]*?)   # Lines starting with tabs
9365                                    \n           # Final newline
9366                                   )
9367                                   (?!\s)/mgx
9368               )    # Line not starting with space
9369                    # (Next command's help)
9370             {
9371                 print_help($1);
9372             }
9373         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9374
9375         # Help not found.
9376         else {
9377             print_help("B<$asked> is not a debugger command.\n");
9378         }
9379     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9380 } ## end sub cmd_pre580_h
9381
9382 =head2 Old C<W> command
9383
9384 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9385
9386 =cut
9387
9388 sub cmd_pre580_W {
9389     my $xcmd = shift;
9390     my $cmd  = shift;
9391
9392     # Delete all watch expressions.
9393     if ( $cmd =~ /^$/ ) {
9394
9395         # No watching is going on.
9396         $trace &= ~2;
9397
9398         # Kill all the watch expressions and values.
9399         @to_watch = @old_watch = ();
9400     }
9401
9402     # Add a watch expression.
9403     elsif ( $cmd =~ /^(.*)/s ) {
9404
9405         # add it to the list to be watched.
9406         push @to_watch, $1;
9407
9408         # Get the current value of the expression.
9409         # Doesn't handle expressions returning list values!
9410         $evalarg = $1;
9411         my ($val) = &eval;
9412         $val = ( defined $val ) ? "'$val'" : 'undef';
9413
9414         # Save it.
9415         push @old_watch, $val;
9416
9417         # We're watching stuff.
9418         $trace |= 2;
9419
9420     } ## end elsif ($cmd =~ /^(.*)/s)
9421 } ## end sub cmd_pre580_W
9422
9423 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9424
9425 The debugger used to have a bunch of nearly-identical code to handle
9426 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9427 C<cmd_prepost> unify all this into one set of code to handle the
9428 appropriate actions.
9429
9430 =head2 C<cmd_pre590_prepost>
9431
9432 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9433 do something destructive. In pre 5.8 debuggers, the default action was to
9434 delete all the actions.
9435
9436 =cut
9437
9438 sub cmd_pre590_prepost {
9439     my $cmd    = shift;
9440     my $line   = shift || '*';
9441     my $dbline = shift;
9442
9443     return &cmd_prepost( $cmd, $line, $dbline );
9444 } ## end sub cmd_pre590_prepost
9445
9446 =head2 C<cmd_prepost>
9447
9448 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9449 Since the lists of actions are all held in arrays that are pointed to by
9450 references anyway, all we have to do is pick the right array reference and
9451 then use generic code to all, delete, or list actions.
9452
9453 =cut
9454
9455 sub cmd_prepost {
9456     my $cmd = shift;
9457
9458     # No action supplied defaults to 'list'.
9459     my $line = shift || '?';
9460
9461     # Figure out what to put in the prompt.
9462     my $which = '';
9463
9464     # Make sure we have some array or another to address later.
9465     # This means that if ssome reason the tests fail, we won't be
9466     # trying to stash actions or delete them from the wrong place.
9467     my $aref = [];
9468
9469     # < - Perl code to run before prompt.
9470     if ( $cmd =~ /^\</o ) {
9471         $which = 'pre-perl';
9472         $aref  = $pre;
9473     }
9474
9475     # > - Perl code to run after prompt.
9476     elsif ( $cmd =~ /^\>/o ) {
9477         $which = 'post-perl';
9478         $aref  = $post;
9479     }
9480
9481     # { - first check for properly-balanced braces.
9482     elsif ( $cmd =~ /^\{/o ) {
9483         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9484             print $OUT
9485 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9486         }
9487
9488         # Properly balanced. Pre-prompt debugger actions.
9489         else {
9490             $which = 'pre-debugger';
9491             $aref  = $pretype;
9492         }
9493     } ## end elsif ( $cmd =~ /^\{/o )
9494
9495     # Did we find something that makes sense?
9496     unless ($which) {
9497         print $OUT "Confused by command: $cmd\n";
9498     }
9499
9500     # Yes.
9501     else {
9502
9503         # List actions.
9504         if ( $line =~ /^\s*\?\s*$/o ) {
9505             unless (@$aref) {
9506
9507                 # Nothing there. Complain.
9508                 print $OUT "No $which actions.\n";
9509             }
9510             else {
9511
9512                 # List the actions in the selected list.
9513                 print $OUT "$which commands:\n";
9514                 foreach my $action (@$aref) {
9515                     print $OUT "\t$cmd -- $action\n";
9516                 }
9517             } ## end else
9518         } ## end if ( $line =~ /^\s*\?\s*$/o)
9519
9520         # Might be a delete.
9521         else {
9522             if ( length($cmd) == 1 ) {
9523                 if ( $line =~ /^\s*\*\s*$/o ) {
9524
9525                     # It's a delete. Get rid of the old actions in the
9526                     # selected list..
9527                     @$aref = ();
9528                     print $OUT "All $cmd actions cleared.\n";
9529                 }
9530                 else {
9531
9532                     # Replace all the actions. (This is a <, >, or {).
9533                     @$aref = action($line);
9534                 }
9535             } ## end if ( length($cmd) == 1)
9536             elsif ( length($cmd) == 2 ) {
9537
9538                 # Add the action to the line. (This is a <<, >>, or {{).
9539                 push @$aref, action($line);
9540             }
9541             else {
9542
9543                 # <<<, >>>>, {{{{{{ ... something not a command.
9544                 print $OUT
9545                   "Confused by strange length of $which command($cmd)...\n";
9546             }
9547         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9548     } ## end else
9549 } ## end sub cmd_prepost
9550
9551 =head1 C<DB::fake>
9552
9553 Contains the C<at_exit> routine that the debugger uses to issue the
9554 C<Debugged program terminated ...> message after the program completes. See
9555 the C<END> block documentation for more details.
9556
9557 =cut
9558
9559 package DB::fake;
9560
9561 sub at_exit {
9562     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9563 }
9564
9565 package DB;    # Do not trace this 1; below!
9566
9567 1;
9568
9569