lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 C<perl5db.pl> - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 i<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it isn't. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have "magical" values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135
 136 =item * First, doing an arithmetical or bitwise operation on a scalar is
 137 just about the fastest thing you can do in Perl: C<use constant> actually
 138 creates a subroutine call, and array hand hash lookups are much slower. Is
 139 this over-optimization at the expense of readability? Possibly, but the
 140 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 141 probably have to benchmark alternate implementations and see which is the
 142 best balance of readability and speed, and then document how it actually
 143 works.
 144
 145 =item * Second, it's very easy to serialize a scalar number. This is done in
 146 the restart code; the debugger state variables are saved in C<%ENV> and then
 147 restored when the debugger is restarted. Having them be just numbers makes
 148 this trivial.
 149
 150 =item * Third, some of these variables are being shared with the Perl core
 151 smack in the middle of the interpreter's execution loop. It's much faster for
 152 a C program (like the interpreter) to check a bit in a scalar than to access
 153 several different variables (or a Perl array).
 154
 155 =back
 156
 157 =head2 What are those C<XXX> comments for?
 158
 159 Any comment containing C<XXX> means that the comment is either somewhat
 160 speculative - it's not exactly clear what a given variable or chunk of
 161 code is doing, or that it is incomplete - the basics may be clear, but the
 162 subtleties are not completely documented.
 163
 164 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 165
 166 =head1 DATA STRUCTURES MAINTAINED BY CORE
 167
 168 There are a number of special data structures provided to the debugger by
 169 the Perl interpreter.
 170
 171 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 172 assignment) contains the text from C<$filename>, with each element
 173 corresponding to a single line of C<$filename>.
 174
 175 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 176 assignment) contains breakpoints and actions.  The keys are line numbers;
 177 you can set individual values, but not the whole hash. The Perl interpreter
 178 uses this hash to determine where breakpoints have been set. Any true value is
 179 considered to be a breakpoint; C<perl5db.pl> uses "$break_condition\0$action".
 180 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 181
 182 The scalar ${'_<'.$filename} contains $filename  XXX What?
 183
 184 =head1 DEBUGGER STARTUP
 185
 186 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 187 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 188 of options. In addition, this file may define a subroutine C<&afterinit>
 189 that will be executed (in the debugger's context) after the debugger has
 190 initialized itself.
 191
 192 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 193 contents as the argument of a debugger <C<o> command.
 194
 195 =head2 STARTUP-ONLY OPTIONS
 196
 197 The following options can only be specified at startup.
 198 To set them in your rcfile, add a call to
 199 C<&parse_options("optionName=new_value")>.
 200
 201 =over 4
 202
 203 =item * TTY
 204
 205 the TTY to use for debugging i/o.
 206
 207 =item * noTTY
 208
 209 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 210 uses the value of noTTY or "/tmp/perldbtty$$" to find TTY using
 211 Term::Rendezvous.  Current variant is to have the name of TTY in this
 212 file.
 213
 214 =item * ReadLine
 215
 216 If false, a dummy  ReadLine is used, so you can debug
 217 ReadLine applications.
 218
 219 =item * NonStop
 220
 221 if true, no i/o is performed until interrupt.
 222
 223 =item * LineInfo
 224
 225 file or pipe to print line number info to.  If it is a
 226 pipe, a short "emacs like" message is used.
 227
 228 =item * RemotePort
 229
 230 host:port to connect to on remote host for remote debugging.
 231
 232 =back
 233
 234 =head3 SAMPLE RCFILE
 235
 236  &parse_options("NonStop=1 LineInfo=db.out");
 237   sub afterinit { $trace = 1; }
 238
 239 The script will run without human intervention, putting trace
 240 information into C<db.out>.  (If you interrupt it, you had better
 241 reset C<LineInfo> to something "interactive"!)
 242
 243 =head1 INTERNALS DESCRIPTION
 244
 245 =head2 DEBUGGER INTERFACE VARIABLES
 246
 247 Perl supplies the values for C<%sub>.  It effectively inserts
 248 a C<&DB'DB();> in front of each place that can have a
 249 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 250 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 251 {require 'perl5db.pl'}> before the first line.
 252
 253 After each C<require>d file is compiled, but before it is executed, a
 254 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 255 is the expanded name of the C<require>d file (as found via C<%INC>).
 256
 257 =head3 IMPORTANT INTERNAL VARIABLES
 258
 259 =head4 C<$CreateTTY>
 260
 261 Used to control when the debugger will attempt to acquire another TTY to be
 262 used for input.
 263
 264 =over
 265
 266 =item * 1 -  on C<fork()>
 267
 268 =item * 2 - debugger is started inside debugger
 269
 270 =item * 4 -  on startup
 271
 272 =back
 273
 274 =head4 C<$doret>
 275
 276 The value -2 indicates that no return value should be printed.
 277 Any other positive value causes C<DB::sub> to print return values.
 278
 279 =head4 C<$evalarg>
 280
 281 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 282 contents of C<@_> when C<DB::eval> is called.
 283
 284 =head4 C<$frame>
 285
 286 Determines what messages (if any) will get printed when a subroutine (or eval)
 287 is entered or exited.
 288
 289 =over 4
 290
 291 =item * 0 -  No enter/exit messages
 292
 293 =item * 1 - Print "entering" messages on subroutine entry
 294
 295 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 296
 297 =item * 4 - Extended messages: C<in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line>>. If no other flag is on, acts like 1+4.
 298
 299 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 300
 301 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 302
 303 =back
 304
 305 To get everything, use C<$frame=30> (or C<o f-30> as a debugger command).
 306 The debugger internally juggles the value of C<$frame> during execution to
 307 protect external modules that the debugger uses from getting traced.
 308
 309 =head4 C<$level>
 310
 311 Tracks current debugger nesting level. Used to figure out how many
 312 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 313 outputs a prompt. Also used to help determine if the program has finished
 314 during command parsing.
 315
 316 =head4 C<$onetimeDump>
 317
 318 Controls what (if anything) C<DB::eval()> will print after evaluating an
 319 expression.
 320
 321 =over 4
 322
 323 =item * C<undef> - don't print anything
 324
 325 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 326
 327 =item * C<methods> - print the methods callable on the first item returned
 328
 329 =back
 330
 331 =head4 C<$onetimeDumpDepth>
 332
 333 Controls how far down C<dumpvar.pl> will go before printing '...' while
 334 dumping a structure. Numeric. If C<undef>, print all levels.
 335
 336 =head4 C<$signal>
 337
 338 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 339 which is called before every statement, checks this and puts the user into
 340 command mode if it finds C<$signal> set to a true value.
 341
 342 =head4 C<$single>
 343
 344 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 345 each subroutine; popped again at the end of each subroutine.
 346
 347 =over 4
 348
 349 =item * 0 - run continuously.
 350
 351 =item * 1 - single-step, go into subs. The 's' command.
 352
 353 =item * 2 - single-step, don't go into subs. The 'n' command.
 354
 355 =item * 4 - print current sub depth (turned on to force this when "too much
 356 recursion" occurs.
 357
 358 =back
 359
 360 =head4 C<$trace>
 361
 362 Controls the output of trace information.
 363
 364 =over 4
 365
 366 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 367
 368 =item * 2 - watch expressions are active
 369
 370 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 371
 372 =back
 373
 374 =head4 C<$slave_editor>
 375
 376 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 377
 378 =head4 C<@cmdfhs>
 379
 380 Stack of filehandles that C<DB::readline()> will read commands from.
 381 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 382
 383 =head4 C<@dbline>
 384
 385 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 386 supplied by the Perl interpreter to the debugger. Contains the source.
 387
 388 =head4 C<@old_watch>
 389
 390 Previous values of watch expressions. First set when the expression is
 391 entered; reset whenever the watch expression changes.
 392
 393 =head4 C<@saved>
 394
 395 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 396 so that the debugger can substitute safe values while it's running, and
 397 restore them when it returns control.
 398
 399 =head4 C<@stack>
 400
 401 Saves the current value of C<$single> on entry to a subroutine.
 402 Manipulated by the C<c> command to turn off tracing in all subs above the
 403 current one.
 404
 405 =head4 C<@to_watch>
 406
 407 The 'watch' expressions: to be evaluated before each line is executed.
 408
 409 =head4 C<@typeahead>
 410
 411 The typeahead buffer, used by C<DB::readline>.
 412
 413 =head4 C<%alias>
 414
 415 Command aliases. Stored as character strings to be substituted for a command
 416 entered.
 417
 418 =head4 C<%break_on_load>
 419
 420 Keys are file names, values are 1 (break when this file is loaded) or undef
 421 (don't break when it is loaded).
 422
 423 =head4 C<%dbline>
 424
 425 Keys are line numbers, values are "condition\0action". If used in numeric
 426 context, values are 0 if not breakable, 1 if breakable, no matter what is
 427 in the actual hash entry.
 428
 429 =head4 C<%had_breakpoints>
 430
 431 Keys are file names; values are bitfields:
 432
 433 =over 4
 434
 435 =item * 1 - file has a breakpoint in it.
 436
 437 =item * 2 - file has an action in it.
 438
 439 =back
 440
 441 A zero or undefined value means this file has neither.
 442
 443 =head4 C<%option>
 444
 445 Stores the debugger options. These are character string values.
 446
 447 =head4 C<%postponed>
 448
 449 Saves breakpoints for code that hasn't been compiled yet.
 450 Keys are subroutine names, values are:
 451
 452 =over 4
 453
 454 =item * 'compile' - break when this sub is compiled
 455
 456 =item * 'break +0 if <condition>' - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 457
 458 =back
 459
 460 =head4 C<%postponed_file>
 461
 462 This hash keeps track of breakpoints that need to be set for files that have
 463 not yet been compiled. Keys are filenames; values are references to hashes.
 464 Each of these hashes is keyed by line number, and its values are breakpoint
 465 definitions ("condition\0action").
 466
 467 =head1 DEBUGGER INITIALIZATION
 468
 469 The debugger's initialization actually jumps all over the place inside this
 470 package. This is because there are several BEGIN blocks (which of course
 471 execute immediately) spread through the code. Why is that?
 472
 473 The debugger needs to be able to change some things and set some things up
 474 before the debugger code is compiled; most notably, the C<$deep> variable that
 475 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 476 debugger has to turn off warnings while the debugger code is compiled, but then
 477 restore them to their original setting before the program being debugged begins
 478 executing.
 479
 480 The first C<BEGIN> block simply turns off warnings by saving the current
 481 setting of C<$^W> and then setting it to zero. The second one initializes
 482 the debugger variables that are needed before the debugger begins executing.
 483 The third one puts C<$^X> back to its former value.
 484
 485 We'll detail the second C<BEGIN> block later; just remember that if you need
 486 to initialize something before the debugger starts really executing, that's
 487 where it has to go.
 488
 489 =cut
 490
 491 package DB;
 492
 493 use IO::Handle;
 494
 495 # Debugger for Perl 5.00x; perl5db.pl patch level:
 496 $VERSION = 1.28;
 497
 498 $header = "perl5db.pl version $VERSION";
 499
 500 =head1 DEBUGGER ROUTINES
 501
 502 =head2 C<DB::eval()>
 503
 504 This function replaces straight C<eval()> inside the debugger; it simplifies
 505 the process of evaluating code in the user's context.
 506
 507 The code to be evaluated is passed via the package global variable
 508 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 509
 510 We preserve the current settings of X<C<$trace>>, X<C<$single>>, and X<C<$^D>>;
 511 add the X<C<$usercontext>> (that's the preserved values of C<$@>, C<$!>,
 512 C<$^E>, C<$,>, C<$/>, C<$\>, and C<$^W>, grabbed when C<DB::DB> got control,
 513 and the user's current package) and a add a newline before we do the C<eval()>.
 514 This causes the proper context to be used when the eval is actually done.
 515 Afterward, we restore C<$trace>, C<$single>, and C<$^D>.
 516
 517 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 518 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 519 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 520 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 521 considered sane by the debugger. If there was an C<eval()> error, we print
 522 it on the debugger's output. If X<C<$onetimedump>> is defined, we call
 523 X<C<dumpit>> if it's set to 'dump', or X<C<methods>> if it's set to
 524 'methods'. Setting it to something else causes the debugger to do the eval
 525 but not print the result - handy if you want to do something else with it
 526 (the "watch expressions" code does this to get the value of the watch
 527 expression but not show it unless it matters).
 528
 529 In any case, we then return the list of output from C<eval> to the caller,
 530 and unwinding restores the former version of C<$@> in C<@saved> as well
 531 (the localization of C<$saved[0]> goes away at the end of this scope).
 532
 533 =head3 Parameters and variables influencing execution of DB::eval()
 534
 535 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 536 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 537 The variables listed below influence C<DB::eval()>'s execution directly.
 538
 539 =over 4
 540
 541 =item C<$evalarg> - the thing to actually be eval'ed
 542
 543 =item C<$trace> - Current state of execution tracing (see X<$trace>)
 544
 545 =item C<$single> - Current state of single-stepping (see X<$single>)
 546
 547 =item C<$onetimeDump> - what is to be displayed after the evaluation
 548
 549 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 550
 551 =back
 552
 553 The following variables are altered by C<DB::eval()> during its execution. They
 554 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 555
 556 =over 4
 557
 558 =item C<@res> - used to capture output from actual C<eval>.
 559
 560 =item C<$otrace> - saved value of C<$trace>.
 561
 562 =item C<$osingle> - saved value of C<$single>.
 563
 564 =item C<$od> - saved value of C<$^D>.
 565
 566 =item C<$saved[0]> - saved value of C<$@>.
 567
 568 =item $\ - for output of C<$@> if there is an evaluation error.
 569
 570 =back
 571
 572 =head3 The problem of lexicals
 573
 574 The context of C<DB::eval()> presents us with some problems. Obviously,
 575 we want to be 'sandboxed' away from the debugger's internals when we do
 576 the eval, but we need some way to control how punctuation variables and
 577 debugger globals are used.
 578
 579 We can't use local, because the code inside C<DB::eval> can see localized
 580 variables; and we can't use C<my> either for the same reason. The code
 581 in this routine compromises and uses C<my>.
 582
 583 After this routine is over, we don't have user code executing in the debugger's
 584 context, so we can use C<my> freely.
 585
 586 =cut
 587
 588 ############################################## Begin lexical danger zone
 589
 590 # 'my' variables used here could leak into (that is, be visible in)
 591 # the context that the code being evaluated is executing in. This means that
 592 # the code could modify the debugger's variables.
 593 #
 594 # Fiddling with the debugger's context could be Bad. We insulate things as
 595 # much as we can.
 596
 597 sub eval {
 598
 599     # 'my' would make it visible from user code
 600     #    but so does local! --tchrist
 601     # Remember: this localizes @DB::res, not @main::res.
 602     local @res;
 603     {
 604
 605         # Try to keep the user code from messing  with us. Save these so that
 606         # even if the eval'ed code changes them, we can put them back again.
 607         # Needed because the user could refer directly to the debugger's
 608         # package globals (and any 'my' variables in this containing scope)
 609         # inside the eval(), and we want to try to stay safe.
 610         local $otrace  = $trace;
 611         local $osingle = $single;
 612         local $od      = $^D;
 613
 614         # Untaint the incoming eval() argument.
 615         { ($evalarg) = $evalarg =~ /(.*)/s; }
 616
 617         # $usercontext built in DB::DB near the comment
 618         # "set up the context for DB::eval ..."
 619         # Evaluate and save any results.
 620         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 621
 622         # Restore those old values.
 623         $trace  = $otrace;
 624         $single = $osingle;
 625         $^D     = $od;
 626     }
 627
 628     # Save the current value of $@, and preserve it in the debugger's copy
 629     # of the saved precious globals.
 630     my $at = $@;
 631
 632     # Since we're only saving $@, we only have to localize the array element
 633     # that it will be stored in.
 634     local $saved[0];    # Preserve the old value of $@
 635     eval { &DB::save };
 636
 637     # Now see whether we need to report an error back to the user.
 638     if ($at) {
 639         local $\ = '';
 640         print $OUT $at;
 641     }
 642
 643     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 644     # are package globals.
 645     elsif ($onetimeDump) {
 646         if ( $onetimeDump eq 'dump' ) {
 647             local $option{dumpDepth} = $onetimedumpDepth
 648               if defined $onetimedumpDepth;
 649             dumpit( $OUT, \@res );
 650         }
 651         elsif ( $onetimeDump eq 'methods' ) {
 652             methods( $res[0] );
 653         }
 654     } ## end elsif ($onetimeDump)
 655     @res;
 656 } ## end sub eval
 657
 658 ############################################## End lexical danger zone
 659
 660 # After this point it is safe to introduce lexicals.
 661 # The code being debugged will be executing in its own context, and
 662 # can't see the inside of the debugger.
 663 #
 664 # However, one should not overdo it: leave as much control from outside as
 665 # possible. If you make something a lexical, it's not going to be addressable
 666 # from outside the debugger even if you know its name.
 667
 668 # This file is automatically included if you do perl -d.
 669 # It's probably not useful to include this yourself.
 670 #
 671 # Before venturing further into these twisty passages, it is
 672 # wise to read the perldebguts man page or risk the ire of dragons.
 673 #
 674 # (It should be noted that perldebguts will tell you a lot about
 675 # the underlying mechanics of how the debugger interfaces into the
 676 # Perl interpreter, but not a lot about the debugger itself. The new
 677 # comments in this code try to address this problem.)
 678
 679 # Note that no subroutine call is possible until &DB::sub is defined
 680 # (for subroutines defined outside of the package DB). In fact the same is
 681 # true if $deep is not defined.
 682
 683 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 684
 685 # modified Perl debugger, to be run from Emacs in perldb-mode
 686 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 687 # Johan Vromans -- upgrade to 4.0 pl 10
 688 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 689
 690 # (We have made efforts to  clarify the comments in the change log
 691 # in other places; some of them may seem somewhat obscure as they
 692 # were originally written, and explaining them away from the code
 693 # in question seems conterproductive.. -JM)
 694
 695 ########################################################################
 696 # Changes: 0.94
 697 #   + A lot of things changed after 0.94. First of all, core now informs
 698 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 699 #     BEGIN and END. Handy with `O f=2'.
 700 #   + This can make debugger a little bit too verbose, please be patient
 701 #     and report your problems promptly.
 702 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 703 #   + Note that if DESTROY returns a reference to the object (or object),
 704 #     the deletion of data may be postponed until the next function call,
 705 #     due to the need to examine the return value.
 706 #
 707 # Changes: 0.95
 708 #   + `v' command shows versions.
 709 #
 710 # Changes: 0.96
 711 #   + `v' command shows version of readline.
 712 #     primitive completion works (dynamic variables, subs for `b' and `l',
 713 #     options). Can `p %var'
 714 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 715 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 716 #   + `c sub' documented.
 717 #   + At last enough magic combined to stop after the end of debuggee.
 718 #   + !! should work now (thanks to Emacs bracket matching an extra
 719 #     `]' in a regexp is caught).
 720 #   + `L', `D' and `A' span files now (as documented).
 721 #   + Breakpoints in `require'd code are possible (used in `R').
 722 #   +  Some additional words on internal work of debugger.
 723 #   + `b load filename' implemented.
 724 #   + `b postpone subr' implemented.
 725 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 726 #   + When restarting debugger breakpoints/actions persist.
 727 #   + Buglet: When restarting debugger only one breakpoint/action per
 728 #             autoloaded function persists.
 729 #
 730 # Changes: 0.97: NonStop will not stop in at_exit().
 731 #   + Option AutoTrace implemented.
 732 #   + Trace printed differently if frames are printed too.
 733 #   + new `inhibitExit' option.
 734 #   + printing of a very long statement interruptible.
 735 # Changes: 0.98: New command `m' for printing possible methods
 736 #   + 'l -' is a synonym for `-'.
 737 #   + Cosmetic bugs in printing stack trace.
 738 #   +  `frame' & 8 to print "expanded args" in stack trace.
 739 #   + Can list/break in imported subs.
 740 #   + new `maxTraceLen' option.
 741 #   + frame & 4 and frame & 8 granted.
 742 #   + new command `m'
 743 #   + nonstoppable lines do not have `:' near the line number.
 744 #   + `b compile subname' implemented.
 745 #   + Will not use $` any more.
 746 #   + `-' behaves sane now.
 747 # Changes: 0.99: Completion for `f', `m'.
 748 #   +  `m' will remove duplicate names instead of duplicate functions.
 749 #   + `b load' strips trailing whitespace.
 750 #     completion ignores leading `|'; takes into account current package
 751 #     when completing a subroutine name (same for `l').
 752 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 753 #   BUG FIXES:
 754 #   + Added bare minimal security checks on perldb rc files, plus
 755 #     comments on what else is needed.
 756 #   + Fixed the ornaments that made "|h" completely unusable.
 757 #     They are not used in print_help if they will hurt.  Strip pod
 758 #     if we're paging to less.
 759 #   + Fixed mis-formatting of help messages caused by ornaments
 760 #     to restore Larry's original formatting.
 761 #   + Fixed many other formatting errors.  The code is still suboptimal,
 762 #     and needs a lot of work at restructuring.  It's also misindented
 763 #     in many places.
 764 #   + Fixed bug where trying to look at an option like your pager
 765 #     shows "1".
 766 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 767 #     lose.  You should consider shell escapes not using their shell,
 768 #     or else not caring about detailed status.  This should really be
 769 #     unified into one place, too.
 770 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 771 #     tricking Perl into thinking you weren't calling a debugger command!
 772 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 773 #     suggests a leading semicolon or any other irrelevant non-whitespace
 774 #     to indicate literal Perl code.)
 775 #   + Fixed bugs that ate warnings due to wrong selected handle.
 776 #   + Fixed a precedence bug on signal stuff.
 777 #   + Fixed some unseemly wording.
 778 #   + Fixed bug in help command trying to call perl method code.
 779 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 780 #   ENHANCEMENTS:
 781 #   + Added some comments.  This code is still nasty spaghetti.
 782 #   + Added message if you clear your pre/post command stacks which was
 783 #     very easy to do if you just typed a bare >, <, or {.  (A command
 784 #     without an argument should *never* be a destructive action; this
 785 #     API is fundamentally screwed up; likewise option setting, which
 786 #     is equally buggered.)
 787 #   + Added command stack dump on argument of "?" for >, <, or {.
 788 #   + Added a semi-built-in doc viewer command that calls man with the
 789 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 790 #     or else perldoc on obstreperous platforms.
 791 #   + Added to and rearranged the help information.
 792 #   + Detected apparent misuse of { ... } to declare a block; this used
 793 #     to work but now is a command, and mysteriously gave no complaint.
 794 #
 795 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 796 #   BUG FIX:
 797 #   + This patch to perl5db.pl cleans up formatting issues on the help
 798 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 799 #     issues, plus converted the printed text to use all spaces, since
 800 #     tabs don't seem to help much here.
 801 #
 802 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 803 #   Minor bugs corrected;
 804 #   + Support for auto-creation of new TTY window on startup, either
 805 #     unconditionally, or if started as a kid of another debugger session;
 806 #   + New `O'ption CreateTTY
 807 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 808 #                         1: on fork()
 809 #                         2: debugger is started inside debugger
 810 #                         4: on startup
 811 #   + Code to auto-create a new TTY window on OS/2 (currently one
 812 #     extra window per session - need named pipes to have more...);
 813 #   + Simplified interface for custom createTTY functions (with a backward
 814 #     compatibility hack); now returns the TTY name to use; return of ''
 815 #     means that the function reset the I/O handles itself;
 816 #   + Better message on the semantic of custom createTTY function;
 817 #   + Convert the existing code to create a TTY into a custom createTTY
 818 #     function;
 819 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 820 #   + Switch line-tracing output too to the created TTY window;
 821 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 822 #   + High-level debugger API cmd_*():
 823 #      cmd_b_load($filenamepart)            # b load filenamepart
 824 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 825 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 826 #      cmd_stop()                           # Control-C
 827 #      cmd_d($lineno)                       # d lineno (B)
 828 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 829 #      the error message to the debugging output.
 830 #   + Low-level debugger API
 831 #      break_on_load($filename)             # b load filename
 832 #      @files = report_break_on_load()      # List files with load-breakpoints
 833 #      breakable_line_in_filename($name, $from [, $to])
 834 #                                           # First breakable line in the
 835 #                                           # range $from .. $to.  $to defaults
 836 #                                           # to $from, and may be less than
 837 #                                           # $to
 838 #      breakable_line($from [, $to])        # Same for the current file
 839 #      break_on_filename_line($name, $lineno [, $cond])
 840 #                                           # Set breakpoint,$cond defaults to
 841 #                                           # 1
 842 #      break_on_filename_line_range($name, $from, $to [, $cond])
 843 #                                           # As above, on the first
 844 #                                           # breakable line in range
 845 #      break_on_line($lineno [, $cond])     # As above, in the current file
 846 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 847 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 848 #                                           # The range of lines of the text
 849 #      The low-level API returns TRUE on success, and die()s on failure.
 850 #
 851 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 852 #   BUG FIXES:
 853 #   + Fixed warnings generated by "perl -dWe 42"
 854 #   + Corrected spelling errors
 855 #   + Squeezed Help (h) output into 80 columns
 856 #
 857 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 858 #   + Made "x @INC" work like it used to
 859 #
 860 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 861 #   + Fixed warnings generated by "O" (Show debugger options)
 862 #   + Fixed warnings generated by "p 42" (Print expression)
 863 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 864 #   + Added windowSize option
 865 # Changes: 1.14: Oct  9, 2001 multiple
 866 #   + Clean up after itself on VMS (Charles Lane in 12385)
 867 #   + Adding "@ file" syntax (Peter Scott in 12014)
 868 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 869 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 870 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 871 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 872 #   + Updated 1.14 change log
 873 #   + Added *dbline explainatory comments
 874 #   + Mentioning perldebguts man page
 875 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 876 #   + $onetimeDump improvements
 877 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 878 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 879 #   rationalised the following commands and added cmd_wrapper() to
 880 #   enable switching between old and frighteningly consistent new
 881 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 882 #     a(add),       A(del)            # action expr   (added del by line)
 883 #   + b(add),       B(del)            # break  [line] (was b,D)
 884 #   + w(add),       W(del)            # watch  expr   (was W,W)
 885 #                                     # added del by expr
 886 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 887 #   + m(methods),   M(modules)        # ...           (was m,v)
 888 #   + o(option)                       # lc            (was O)
 889 #   + v(view code), V(view Variables) # ...           (was w,V)
 890 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 891 #   + fixed missing cmd_O bug
 892 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 893 #   + Added missing local()s -- DB::DB is called recursively.
 894 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 895 #   + pre'n'post commands no longer trashed with no args
 896 #   + watch val joined out of eval()
 897 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 898 #   + Added comments and reformatted source. No bug fixes/enhancements.
 899 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 900 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 901 #   + Flush stdout/stderr before the debugger prompt is printed.
 902 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 903 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 904 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 905 #   + Added command to save all debugger commands for sourcing later.
 906 #   + Added command to display parent inheritence tree of given class.
 907 #   + Fixed minor newline in history bug.
 908 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 909 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 910 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 911 #   + unfork the 5.8.x and 5.9.x debuggers.
 912 #   + whitespace and assertions call cleanup across versions
 913 #   + H * deletes (resets) history
 914 #   + i now handles Class + blessed objects
 915 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 916 #   + updated pod page references - clunky.
 917 #   + removed windowid restriction for forking into an xterm.
 918 #   + more whitespace again.
 919 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 920 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 921 #   + Added threads support (inc. e and E commands)
 922 ####################################################################
 923
 924 =head1 DEBUGGER INITIALIZATION
 925
 926 The debugger starts up in phases.
 927
 928 =head2 BASIC SETUP
 929
 930 First, it initializes the environment it wants to run in: turning off
 931 warnings during its own compilation, defining variables which it will need
 932 to avoid warnings later, setting itself up to not exit when the program
 933 terminates, and defaulting to printing return values for the C<r> command.
 934
 935 =cut
 936
 937 # Needed for the statement after exec():
 938 #
 939 # This BEGIN block is simply used to switch off warnings during debugger
 940 # compiliation. Probably it would be better practice to fix the warnings,
 941 # but this is how it's done at the moment.
 942
 943 BEGIN {
 944     $ini_warn = $^W;
 945     $^W       = 0;
 946 }    # Switch compilation warnings off until another BEGIN.
 947
 948 # test if assertions are supported and actived:
 949 BEGIN {
 950     $ini_assertion = eval "sub asserting_test : assertion {1}; 1";
 951
 952     # $ini_assertion = undef => assertions unsupported,
 953     #        "       = 1     => assertions supported
 954     # print "\$ini_assertion=$ini_assertion\n";
 955 }
 956
 957 local ($^W) = 0;    # Switch run-time warnings off during init.
 958
 959 =head2 THREADS SUPPORT
 960
 961 If we are running under a threaded Perl, we require threads and threads::shared
 962 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 963 threaded debugger control.  C<-dt> can also be used to set this.
 964
 965 Each new thread will be announced and the debugger prompt will always inform
 966 you of each new thread created.  It will also indicate the thread id in which
 967 we are currently running within the prompt like this:
 968
 969         [tid] DB<$i>
 970
 971 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 972 command prompt.  The prompt will show: C<[0]> when running under threads, but
 973 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 974
 975 While running under threads, when you set or delete a breakpoint (etc.), this
 976 will apply to all threads, not just the currently running one.  When you are
 977 in a currently executing thread, you will stay there until it completes.  With
 978 the current implementation it is not currently possible to hop from one thread
 979 to another.
 980
 981 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 982
 983 Note that threading support was built into the debugger as of Perl version
 984 C<5.8.6> and debugger version C<1.2.8>.
 985
 986 =cut
 987
 988 BEGIN {
 989   # ensure we can share our non-threaded variables or no-op
 990   if ($ENV{PERL5DB_THREADED}) {
 991         require threads;
 992         require threads::shared;
 993         import threads::shared qw(share);
 994         $DBGR;
 995         share(\$DBGR);
 996         lock($DBGR);
 997         print "Threads support enabled\n";
 998   } else {
 999         *lock  = sub(*) {};
1000         *share = sub(*) {};
1001   }
1002 }
1003
1004 # This would probably be better done with "use vars", but that wasn't around
1005 # when this code was originally written. (Neither was "use strict".) And on
1006 # the principle of not fiddling with something that was working, this was
1007 # left alone.
1008 warn(               # Do not ;-)
1009     # These variables control the execution of 'dumpvar.pl'.
1010     $dumpvar::hashDepth,
1011     $dumpvar::arrayDepth,
1012     $dumpvar::dumpDBFiles,
1013     $dumpvar::dumpPackages,
1014     $dumpvar::quoteHighBit,
1015     $dumpvar::printUndef,
1016     $dumpvar::globPrint,
1017     $dumpvar::usageOnly,
1018
1019     # used to save @ARGV and extract any debugger-related flags.
1020     @ARGS,
1021
1022     # used to control die() reporting in diesignal()
1023     $Carp::CarpLevel,
1024
1025     # used to prevent multiple entries to diesignal()
1026     # (if for instance diesignal() itself dies)
1027     $panic,
1028
1029     # used to prevent the debugger from running nonstop
1030     # after a restart
1031     $second_time,
1032   )
1033   if 0;
1034
1035 foreach my $k (keys (%INC)) {
1036         &share(\$main::{'_<'.$filename});
1037 };
1038
1039 # Command-line + PERLLIB:
1040 # Save the contents of @INC before they are modified elsewhere.
1041 @ini_INC = @INC;
1042
1043 # This was an attempt to clear out the previous values of various
1044 # trapped errors. Apparently it didn't help. XXX More info needed!
1045 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1046
1047 # We set these variables to safe values. We don't want to blindly turn
1048 # off warnings, because other packages may still want them.
1049 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1050                                    # (local $^W cannot help - other packages!).
1051
1052 # Default to not exiting when program finishes; print the return
1053 # value when the 'r' command is used to return from a subroutine.
1054 $inhibit_exit = $option{PrintRet} = 1;
1055
1056 =head1 OPTION PROCESSING
1057
1058 The debugger's options are actually spread out over the debugger itself and
1059 C<dumpvar.pl>; some of these are variables to be set, while others are
1060 subs to be called with a value. To try to make this a little easier to
1061 manage, the debugger uses a few data structures to define what options
1062 are legal and how they are to be processed.
1063
1064 First, the C<@options> array defines the I<names> of all the options that
1065 are to be accepted.
1066
1067 =cut
1068
1069 @options = qw(
1070   CommandSet
1071   hashDepth    arrayDepth    dumpDepth
1072   DumpDBFiles  DumpPackages  DumpReused
1073   compactDump  veryCompact   quote
1074   HighBit      undefPrint    globPrint
1075   PrintRet     UsageOnly     frame
1076   AutoTrace    TTY           noTTY
1077   ReadLine     NonStop       LineInfo
1078   maxTraceLen  recallCommand ShellBang
1079   pager        tkRunning     ornaments
1080   signalLevel  warnLevel     dieLevel
1081   inhibit_exit ImmediateStop bareStringify
1082   CreateTTY    RemotePort    windowSize
1083   DollarCaretP OnlyAssertions WarnAssertions
1084 );
1085
1086 @RememberOnROptions = qw(DollarCaretP OnlyAssertions);
1087
1088 =pod
1089
1090 Second, C<optionVars> lists the variables that each option uses to save its
1091 state.
1092
1093 =cut
1094
1095 %optionVars = (
1096     hashDepth     => \$dumpvar::hashDepth,
1097     arrayDepth    => \$dumpvar::arrayDepth,
1098     CommandSet    => \$CommandSet,
1099     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1100     DumpPackages  => \$dumpvar::dumpPackages,
1101     DumpReused    => \$dumpvar::dumpReused,
1102     HighBit       => \$dumpvar::quoteHighBit,
1103     undefPrint    => \$dumpvar::printUndef,
1104     globPrint     => \$dumpvar::globPrint,
1105     UsageOnly     => \$dumpvar::usageOnly,
1106     CreateTTY     => \$CreateTTY,
1107     bareStringify => \$dumpvar::bareStringify,
1108     frame         => \$frame,
1109     AutoTrace     => \$trace,
1110     inhibit_exit  => \$inhibit_exit,
1111     maxTraceLen   => \$maxtrace,
1112     ImmediateStop => \$ImmediateStop,
1113     RemotePort    => \$remoteport,
1114     windowSize    => \$window,
1115     WarnAssertions => \$warnassertions,
1116 );
1117
1118 =pod
1119
1120 Third, C<%optionAction> defines the subroutine to be called to process each
1121 option.
1122
1123 =cut
1124
1125 %optionAction = (
1126     compactDump   => \&dumpvar::compactDump,
1127     veryCompact   => \&dumpvar::veryCompact,
1128     quote         => \&dumpvar::quote,
1129     TTY           => \&TTY,
1130     noTTY         => \&noTTY,
1131     ReadLine      => \&ReadLine,
1132     NonStop       => \&NonStop,
1133     LineInfo      => \&LineInfo,
1134     recallCommand => \&recallCommand,
1135     ShellBang     => \&shellBang,
1136     pager         => \&pager,
1137     signalLevel   => \&signalLevel,
1138     warnLevel     => \&warnLevel,
1139     dieLevel      => \&dieLevel,
1140     tkRunning     => \&tkRunning,
1141     ornaments     => \&ornaments,
1142     RemotePort    => \&RemotePort,
1143     DollarCaretP  => \&DollarCaretP,
1144     OnlyAssertions=> \&OnlyAssertions,
1145 );
1146
1147 =pod
1148
1149 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1150 option is used.
1151
1152 =cut
1153
1154 # Note that this list is not complete: several options not listed here
1155 # actually require that dumpvar.pl be loaded for them to work, but are
1156 # not in the table. A subsequent patch will correct this problem; for
1157 # the moment, we're just recommenting, and we are NOT going to change
1158 # function.
1159 %optionRequire = (
1160     compactDump => 'dumpvar.pl',
1161     veryCompact => 'dumpvar.pl',
1162     quote       => 'dumpvar.pl',
1163 );
1164
1165 =pod
1166
1167 There are a number of initialization-related variables which can be set
1168 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1169 variable. These are:
1170
1171 =over 4
1172
1173 =item C<$rl> - readline control XXX needs more explanation
1174
1175 =item C<$warnLevel> - whether or not debugger takes over warning handling
1176
1177 =item C<$dieLevel> - whether or not debugger takes over die handling
1178
1179 =item C<$signalLevel> - whether or not debugger takes over signal handling
1180
1181 =item C<$pre> - preprompt actions (array reference)
1182
1183 =item C<$post> - postprompt actions (array reference)
1184
1185 =item C<$pretype>
1186
1187 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1188
1189 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1190
1191 =back
1192
1193 =cut
1194
1195 # These guys may be defined in $ENV{PERL5DB} :
1196 $rl          = 1     unless defined $rl;
1197 $warnLevel   = 1     unless defined $warnLevel;
1198 $dieLevel    = 1     unless defined $dieLevel;
1199 $signalLevel = 1     unless defined $signalLevel;
1200 $pre         = []    unless defined $pre;
1201 $post        = []    unless defined $post;
1202 $pretype     = []    unless defined $pretype;
1203 $CreateTTY   = 3     unless defined $CreateTTY;
1204 $CommandSet  = '580' unless defined $CommandSet;
1205
1206 share($rl);
1207 share($warnLevel);
1208 share($dieLevel);
1209 share($signalLevel);
1210 share($pre);
1211 share($post);
1212 share($pretype);
1213 share($rl);
1214 share($CreateTTY);
1215 share($CommandSet);
1216
1217 =pod
1218
1219 The default C<die>, C<warn>, and C<signal> handlers are set up.
1220
1221 =cut
1222
1223 warnLevel($warnLevel);
1224 dieLevel($dieLevel);
1225 signalLevel($signalLevel);
1226
1227 =pod
1228
1229 The pager to be used is needed next. We try to get it from the
1230 environment first.  if it's not defined there, we try to find it in
1231 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1232 then call the C<pager()> function to save the pager name.
1233
1234 =cut
1235
1236 # This routine makes sure $pager is set up so that '|' can use it.
1237 pager(
1238
1239     # If PAGER is defined in the environment, use it.
1240     defined $ENV{PAGER}
1241     ? $ENV{PAGER}
1242
1243       # If not, see if Config.pm defines it.
1244     : eval { require Config }
1245       && defined $Config::Config{pager}
1246     ? $Config::Config{pager}
1247
1248       # If not, fall back to 'more'.
1249     : 'more'
1250   )
1251   unless defined $pager;
1252
1253 =pod
1254
1255 We set up the command to be used to access the man pages, the command
1256 recall character ("!" unless otherwise defined) and the shell escape
1257 character ("!" unless otherwise defined). Yes, these do conflict, and
1258 neither works in the debugger at the moment.
1259
1260 =cut
1261
1262 setman();
1263
1264 # Set up defaults for command recall and shell escape (note:
1265 # these currently don't work in linemode debugging).
1266 &recallCommand("!") unless defined $prc;
1267 &shellBang("!")     unless defined $psh;
1268
1269 =pod
1270
1271 We then set up the gigantic string containing the debugger help.
1272 We also set the limit on the number of arguments we'll display during a
1273 trace.
1274
1275 =cut
1276
1277 sethelp();
1278
1279 # If we didn't get a default for the length of eval/stack trace args,
1280 # set it here.
1281 $maxtrace = 400 unless defined $maxtrace;
1282
1283 =head2 SETTING UP THE DEBUGGER GREETING
1284
1285 The debugger 'greeting'  helps to inform the user how many debuggers are
1286 running, and whether the current debugger is the primary or a child.
1287
1288 If we are the primary, we just hang onto our pid so we'll have it when
1289 or if we start a child debugger. If we are a child, we'll set things up
1290 so we'll have a unique greeting and so the parent will give us our own
1291 TTY later.
1292
1293 We save the current contents of the C<PERLDB_PIDS> environment variable
1294 because we mess around with it. We'll also need to hang onto it because
1295 we'll need it if we restart.
1296
1297 Child debuggers make a label out of the current PID structure recorded in
1298 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1299 yet so the parent will give them one later via C<resetterm()>.
1300
1301 =cut
1302
1303 # Save the current contents of the environment; we're about to
1304 # much with it. We'll need this if we have to restart.
1305 $ini_pids = $ENV{PERLDB_PIDS};
1306
1307 if ( defined $ENV{PERLDB_PIDS} ) {
1308
1309     # We're a child. Make us a label out of the current PID structure
1310     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1311     # a term yet so the parent will give us one later via resetterm().
1312     $pids = "[$ENV{PERLDB_PIDS}]";
1313     $ENV{PERLDB_PIDS} .= "->$$";
1314     $term_pid = -1;
1315 } ## end if (defined $ENV{PERLDB_PIDS...
1316 else {
1317
1318     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1319     # child debugger, and mark us as the parent, so we'll know to set up
1320     # more TTY's is we have to.
1321     $ENV{PERLDB_PIDS} = "$$";
1322     $pids             = "{pid=$$}";
1323     $term_pid         = $$;
1324 }
1325
1326 $pidprompt = '';
1327
1328 # Sets up $emacs as a synonym for $slave_editor.
1329 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1330
1331 =head2 READING THE RC FILE
1332
1333 The debugger will read a file of initialization options if supplied. If
1334 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1335
1336 =cut
1337
1338 # As noted, this test really doesn't check accurately that the debugger
1339 # is running at a terminal or not.
1340
1341 if ( -e "/dev/tty" ) {                      # this is the wrong metric!
1342     $rcfile = ".perldb";
1343 }
1344 else {
1345     $rcfile = "perldb.ini";
1346 }
1347
1348 =pod
1349
1350 The debugger does a safety test of the file to be read. It must be owned
1351 either by the current user or root, and must only be writable by the owner.
1352
1353 =cut
1354
1355 # This wraps a safety test around "do" to read and evaluate the init file.
1356 #
1357 # This isn't really safe, because there's a race
1358 # between checking and opening.  The solution is to
1359 # open and fstat the handle, but then you have to read and
1360 # eval the contents.  But then the silly thing gets
1361 # your lexical scope, which is unfortunate at best.
1362 sub safe_do {
1363     my $file = shift;
1364
1365     # Just exactly what part of the word "CORE::" don't you understand?
1366     local $SIG{__WARN__};
1367     local $SIG{__DIE__};
1368
1369     unless ( is_safe_file($file) ) {
1370         CORE::warn <<EO_GRIPE;
1371 perldb: Must not source insecure rcfile $file.
1372         You or the superuser must be the owner, and it must not
1373         be writable by anyone but its owner.
1374 EO_GRIPE
1375         return;
1376     } ## end unless (is_safe_file($file...
1377
1378     do $file;
1379     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1380 } ## end sub safe_do
1381
1382 # This is the safety test itself.
1383 #
1384 # Verifies that owner is either real user or superuser and that no
1385 # one but owner may write to it.  This function is of limited use
1386 # when called on a path instead of upon a handle, because there are
1387 # no guarantees that filename (by dirent) whose file (by ino) is
1388 # eventually accessed is the same as the one tested.
1389 # Assumes that the file's existence is not in doubt.
1390 sub is_safe_file {
1391     my $path = shift;
1392     stat($path) || return;    # mysteriously vaporized
1393     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1394
1395     return 0 if $uid != 0 && $uid != $<;
1396     return 0 if $mode & 022;
1397     return 1;
1398 } ## end sub is_safe_file
1399
1400 # If the rcfile (whichever one we decided was the right one to read)
1401 # exists, we safely do it.
1402 if ( -f $rcfile ) {
1403     safe_do("./$rcfile");
1404 }
1405
1406 # If there isn't one here, try the user's home directory.
1407 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1408     safe_do("$ENV{HOME}/$rcfile");
1409 }
1410
1411 # Else try the login directory.
1412 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1413     safe_do("$ENV{LOGDIR}/$rcfile");
1414 }
1415
1416 # If the PERLDB_OPTS variable has options in it, parse those out next.
1417 if ( defined $ENV{PERLDB_OPTS} ) {
1418     parse_options( $ENV{PERLDB_OPTS} );
1419 }
1420
1421 =pod
1422
1423 The last thing we do during initialization is determine which subroutine is
1424 to be used to obtain a new terminal when a new debugger is started. Right now,
1425 the debugger only handles X Windows and OS/2.
1426
1427 =cut
1428
1429 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1430 # Works if you're running an xterm or xterm-like window, or you're on
1431 # OS/2. This may need some expansion: for instance, this doesn't handle
1432 # OS X Terminal windows.
1433
1434 if (
1435     not defined &get_fork_TTY    # no routine exists,
1436     and defined $ENV{TERM}       # and we know what kind
1437                                  # of terminal this is,
1438     and $ENV{TERM} eq 'xterm'    # and it's an xterm,
1439 #   and defined $ENV{WINDOWID}   # and we know what window this is, <- wrong metric
1440     and defined $ENV{DISPLAY}    # and what display it's on,
1441   )
1442 {
1443     *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1444 } ## end if (not defined &get_fork_TTY...
1445 elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1446     *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1447 }
1448
1449 # untaint $^O, which may have been tainted by the last statement.
1450 # see bug [perl #24674]
1451 $^O =~ m/^(.*)\z/;
1452 $^O = $1;
1453
1454 # Here begin the unreadable code.  It needs fixing.
1455
1456 =head2 RESTART PROCESSING
1457
1458 This section handles the restart command. When the C<R> command is invoked, it
1459 tries to capture all of the state it can into environment variables, and
1460 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1461 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1462 the R command stuffed into the environment variables.
1463
1464   PERLDB_RESTART   - flag only, contains no restart data itself.
1465   PERLDB_HIST      - command history, if it's available
1466   PERLDB_ON_LOAD   - breakpoints set by the rc file
1467   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1468   PERLDB_VISITED   - files that had breakpoints
1469   PERLDB_FILE_...  - breakpoints for a file
1470   PERLDB_OPT       - active options
1471   PERLDB_INC       - the original @INC
1472   PERLDB_PRETYPE   - preprompt debugger actions
1473   PERLDB_PRE       - preprompt Perl code
1474   PERLDB_POST      - post-prompt Perl code
1475   PERLDB_TYPEAHEAD - typeahead captured by readline()
1476
1477 We chug through all these variables and plug the values saved in them
1478 back into the appropriate spots in the debugger.
1479
1480 =cut
1481
1482 if ( exists $ENV{PERLDB_RESTART} ) {
1483
1484     # We're restarting, so we don't need the flag that says to restart anymore.
1485     delete $ENV{PERLDB_RESTART};
1486
1487     # $restart = 1;
1488     @hist          = get_list('PERLDB_HIST');
1489     %break_on_load = get_list("PERLDB_ON_LOAD");
1490     %postponed     = get_list("PERLDB_POSTPONE");
1491
1492         share(@hist);
1493         share(@truehist);
1494         share(%break_on_load);
1495         share(%postponed);
1496
1497     # restore breakpoints/actions
1498     my @had_breakpoints = get_list("PERLDB_VISITED");
1499     for ( 0 .. $#had_breakpoints ) {
1500         my %pf = get_list("PERLDB_FILE_$_");
1501         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1502     }
1503
1504     # restore options
1505     my %opt = get_list("PERLDB_OPT");
1506     my ( $opt, $val );
1507     while ( ( $opt, $val ) = each %opt ) {
1508         $val =~ s/[\\\']/\\$1/g;
1509         parse_options("$opt'$val'");
1510     }
1511
1512     # restore original @INC
1513     @INC     = get_list("PERLDB_INC");
1514     @ini_INC = @INC;
1515
1516     # return pre/postprompt actions and typeahead buffer
1517     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1518     $pre       = [ get_list("PERLDB_PRE") ];
1519     $post      = [ get_list("PERLDB_POST") ];
1520     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1521 } ## end if (exists $ENV{PERLDB_RESTART...
1522
1523 =head2 SETTING UP THE TERMINAL
1524
1525 Now, we'll decide how the debugger is going to interact with the user.
1526 If there's no TTY, we set the debugger to run non-stop; there's not going
1527 to be anyone there to enter commands.
1528
1529 =cut
1530
1531 if ($notty) {
1532     $runnonstop = 1;
1533         share($runnonstop);
1534 }
1535
1536 =pod
1537
1538 If there is a TTY, we have to determine who it belongs to before we can
1539 proceed. If this is a slave editor or graphical debugger (denoted by
1540 the first command-line switch being '-emacs'), we shift this off and
1541 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1542
1543 =cut
1544
1545 else {
1546
1547     # Is Perl being run from a slave editor or graphical debugger?
1548     # If so, don't use readline, and set $slave_editor = 1.
1549     $slave_editor =
1550       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1551     $rl = 0, shift(@main::ARGV) if $slave_editor;
1552
1553     #require Term::ReadLine;
1554
1555 =pod
1556
1557 We then determine what the console should be on various systems:
1558
1559 =over 4
1560
1561 =item * Cygwin - We use C<stdin> instead of a separate device.
1562
1563 =cut
1564
1565     if ( $^O eq 'cygwin' ) {
1566
1567         # /dev/tty is binary. use stdin for textmode
1568         undef $console;
1569     }
1570
1571 =item * Unix - use C</dev/tty>.
1572
1573 =cut
1574
1575     elsif ( -e "/dev/tty" ) {
1576         $console = "/dev/tty";
1577     }
1578
1579 =item * Windows or MSDOS - use C<con>.
1580
1581 =cut
1582
1583     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1584         $console = "con";
1585     }
1586
1587 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1588 Console> if not. (Note that Mac OS X returns 'darwin', not 'MacOS'. Also note that the debugger doesn't do anything special for 'darwin'. Maybe it should.)
1589
1590 =cut
1591
1592     elsif ( $^O eq 'MacOS' ) {
1593         if ( $MacPerl::Version !~ /MPW/ ) {
1594             $console =
1595               "Dev:Console:Perl Debug";    # Separate window for application
1596         }
1597         else {
1598             $console = "Dev:Console";
1599         }
1600     } ## end elsif ($^O eq 'MacOS')
1601
1602 =item * VMS - use C<sys$command>.
1603
1604 =cut
1605
1606     else {
1607
1608         # everything else is ...
1609         $console = "sys\$command";
1610     }
1611
1612 =pod
1613
1614 =back
1615
1616 Several other systems don't use a specific console. We C<undef $console>
1617 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1618 with a slave editor, Epoc).
1619
1620 =cut
1621
1622     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1623
1624         # /dev/tty is binary. use stdin for textmode
1625         $console = undef;
1626     }
1627
1628     if ( $^O eq 'NetWare' ) {
1629
1630         # /dev/tty is binary. use stdin for textmode
1631         $console = undef;
1632     }
1633
1634     # In OS/2, we need to use STDIN to get textmode too, even though
1635     # it pretty much looks like Unix otherwise.
1636     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1637     {    # In OS/2
1638         $console = undef;
1639     }
1640
1641     # EPOC also falls into the 'got to use STDIN' camp.
1642     if ( $^O eq 'epoc' ) {
1643         $console = undef;
1644     }
1645
1646 =pod
1647
1648 If there is a TTY hanging around from a parent, we use that as the console.
1649
1650 =cut
1651
1652     $console = $tty if defined $tty;
1653
1654 =head2 SOCKET HANDLING
1655
1656 The debugger is capable of opening a socket and carrying out a debugging
1657 session over the socket.
1658
1659 If C<RemotePort> was defined in the options, the debugger assumes that it
1660 should try to start a debugging session on that port. It builds the socket
1661 and then tries to connect the input and output filehandles to it.
1662
1663 =cut
1664
1665     # Handle socket stuff.
1666
1667     if ( defined $remoteport ) {
1668
1669         # If RemotePort was defined in the options, connect input and output
1670         # to the socket.
1671         require IO::Socket;
1672         $OUT = new IO::Socket::INET(
1673             Timeout  => '10',
1674             PeerAddr => $remoteport,
1675             Proto    => 'tcp',
1676         );
1677         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1678         $IN = $OUT;
1679     } ## end if (defined $remoteport)
1680
1681 =pod
1682
1683 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1684 this is probably a situation where multiple debuggers are running (for example,
1685 a backticked command that starts up another debugger). We create a new IN and
1686 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1687 and if we can.
1688
1689 =cut
1690
1691     # Non-socket.
1692     else {
1693
1694         # Two debuggers running (probably a system or a backtick that invokes
1695         # the debugger itself under the running one). create a new IN and OUT
1696         # filehandle, and do the necessary mojo to create a new tty if we
1697         # know how, and we can.
1698         create_IN_OUT(4) if $CreateTTY & 4;
1699         if ($console) {
1700
1701             # If we have a console, check to see if there are separate ins and
1702             # outs to open. (They are assumed identiical if not.)
1703
1704             my ( $i, $o ) = split /,/, $console;
1705             $o = $i unless defined $o;
1706
1707             # read/write on in, or just read, or read on STDIN.
1708             open( IN,      "+<$i" )
1709               || open( IN, "<$i" )
1710               || open( IN, "<&STDIN" );
1711
1712             # read/write/create/clobber out, or write/create/clobber out,
1713             # or merge with STDERR, or merge with STDOUT.
1714                  open( OUT, "+>$o" )
1715               || open( OUT, ">$o" )
1716               || open( OUT, ">&STDERR" )
1717               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1718
1719         } ## end if ($console)
1720         elsif ( not defined $console ) {
1721
1722             # No console. Open STDIN.
1723             open( IN, "<&STDIN" );
1724
1725             # merge with STDERR, or with STDOUT.
1726             open( OUT,      ">&STDERR" )
1727               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1728             $console = 'STDIN/OUT';
1729         } ## end elsif (not defined $console)
1730
1731         # Keep copies of the filehandles so that when the pager runs, it
1732         # can close standard input without clobbering ours.
1733         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1734     } ## end elsif (from if(defined $remoteport))
1735
1736     # Unbuffer DB::OUT. We need to see responses right away.
1737     my $previous = select($OUT);
1738     $| = 1;                                  # for DB::OUT
1739     select($previous);
1740
1741     # Line info goes to debugger output unless pointed elsewhere.
1742     # Pointing elsewhere makes it possible for slave editors to
1743     # keep track of file and position. We have both a filehandle
1744     # and a I/O description to keep track of.
1745     $LINEINFO = $OUT     unless defined $LINEINFO;
1746     $lineinfo = $console unless defined $lineinfo;
1747         # share($LINEINFO); # <- unable to share globs
1748         share($lineinfo);   #
1749
1750 =pod
1751
1752 To finish initialization, we show the debugger greeting,
1753 and then call the C<afterinit()> subroutine if there is one.
1754
1755 =cut
1756
1757     # Show the debugger greeting.
1758     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1759     unless ($runnonstop) {
1760         local $\ = '';
1761         local $, = '';
1762         if ( $term_pid eq '-1' ) {
1763             print $OUT "\nDaughter DB session started...\n";
1764         }
1765         else {
1766             print $OUT "\nLoading DB routines from $header\n";
1767             print $OUT (
1768                 "Editor support ",
1769                 $slave_editor ? "enabled" : "available", ".\n"
1770             );
1771             print $OUT
1772 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1773         } ## end else [ if ($term_pid eq '-1')
1774     } ## end unless ($runnonstop)
1775 } ## end else [ if ($notty)
1776
1777 # XXX This looks like a bug to me.
1778 # Why copy to @ARGS and then futz with @args?
1779 @ARGS = @ARGV;
1780 for (@args) {
1781     # Make sure backslashes before single quotes are stripped out, and
1782     # keep args unless they are numeric (XXX why?)
1783     # s/\'/\\\'/g;                      # removed while not justified understandably
1784     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1785 }
1786
1787 # If there was an afterinit() sub defined, call it. It will get
1788 # executed in our scope, so it can fiddle with debugger globals.
1789 if ( defined &afterinit ) {    # May be defined in $rcfile
1790     &afterinit();
1791 }
1792
1793 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1794 $I_m_init = 1;
1795
1796 ############################################################ Subroutines
1797
1798 =head1 SUBROUTINES
1799
1800 =head2 DB
1801
1802 This gigantic subroutine is the heart of the debugger. Called before every
1803 statement, its job is to determine if a breakpoint has been reached, and
1804 stop if so; read commands from the user, parse them, and execute
1805 them, and hen send execution off to the next statement.
1806
1807 Note that the order in which the commands are processed is very important;
1808 some commands earlier in the loop will actually alter the C<$cmd> variable
1809 to create other commands to be executed later. This is all highly "optimized"
1810 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1811 see what's happening in any given command.
1812
1813 =cut
1814
1815 sub DB {
1816
1817     # lock the debugger and get the thread id for the prompt
1818         lock($DBGR);
1819         my $tid;
1820         if ($ENV{PERL5DB_THREADED}) {
1821                 $tid = eval { "[".threads->self->tid."]" };
1822         }
1823
1824     # Check for whether we should be running continuously or not.
1825     # _After_ the perl program is compiled, $single is set to 1:
1826     if ( $single and not $second_time++ ) {
1827
1828         # Options say run non-stop. Run until we get an interrupt.
1829         if ($runnonstop) {    # Disable until signal
1830                 # If there's any call stack in place, turn off single
1831                 # stepping into subs throughout the stack.
1832             for ( $i = 0 ; $i <= $stack_depth ; ) {
1833                 $stack[ $i++ ] &= ~1;
1834             }
1835
1836             # And we are now no longer in single-step mode.
1837             $single = 0;
1838
1839             # If we simply returned at this point, we wouldn't get
1840             # the trace info. Fall on through.
1841             # return;
1842         } ## end if ($runnonstop)
1843
1844         elsif ($ImmediateStop) {
1845
1846             # We are supposed to stop here; XXX probably a break.
1847             $ImmediateStop = 0;    # We've processed it; turn it off
1848             $signal        = 1;    # Simulate an interrupt to force
1849                                    # us into the command loop
1850         }
1851     } ## end if ($single and not $second_time...
1852
1853     # If we're in single-step mode, or an interrupt (real or fake)
1854     # has occurred, turn off non-stop mode.
1855     $runnonstop = 0 if $single or $signal;
1856
1857     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1858     # The code being debugged may have altered them.
1859     &save;
1860
1861     # Since DB::DB gets called after every line, we can use caller() to
1862     # figure out where we last were executing. Sneaky, eh? This works because
1863     # caller is returning all the extra information when called from the
1864     # debugger.
1865     local ( $package, $filename, $line ) = caller;
1866     local $filename_ini = $filename;
1867
1868     # set up the context for DB::eval, so it can properly execute
1869     # code on behalf of the user. We add the package in so that the
1870     # code is eval'ed in the proper package (not in the debugger!).
1871     local $usercontext =
1872       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1873
1874     # Create an alias to the active file magical array to simplify
1875     # the code here.
1876     local (*dbline) = $main::{ '_<' . $filename };
1877
1878     # we need to check for pseudofiles on Mac OS (these are files
1879     # not attached to a filename, but instead stored in Dev:Pseudo)
1880     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1881         $filename_ini = $filename = 'Dev:Pseudo';
1882         *dbline = $main::{ '_<' . $filename };
1883     }
1884
1885     # Last line in the program.
1886     local $max = $#dbline;
1887
1888     # if we have something here, see if we should break.
1889     if ( $dbline{$line}
1890         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1891     {
1892
1893         # Stop if the stop criterion says to just stop.
1894         if ( $stop eq '1' ) {
1895             $signal |= 1;
1896         }
1897
1898         # It's a conditional stop; eval it in the user's context and
1899         # see if we should stop. If so, remove the one-time sigil.
1900         elsif ($stop) {
1901             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1902             &eval;
1903             $dbline{$line} =~ s/;9($|\0)/$1/;
1904         }
1905     } ## end if ($dbline{$line} && ...
1906
1907     # Preserve the current stop-or-not, and see if any of the W
1908     # (watch expressions) has changed.
1909     my $was_signal = $signal;
1910
1911     # If we have any watch expressions ...
1912     if ( $trace & 2 ) {
1913         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1914             $evalarg = $to_watch[$n];
1915             local $onetimeDump;    # Tell DB::eval() to not output results
1916
1917             # Fix context DB::eval() wants to return an array, but
1918             # we need a scalar here.
1919             my ($val) = join( "', '", &eval );
1920             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1921
1922             # Did it change?
1923             if ( $val ne $old_watch[$n] ) {
1924
1925                 # Yep! Show the difference, and fake an interrupt.
1926                 $signal = 1;
1927                 print $OUT <<EOP;
1928 Watchpoint $n:\t$to_watch[$n] changed:
1929     old value:\t$old_watch[$n]
1930     new value:\t$val
1931 EOP
1932                 $old_watch[$n] = $val;
1933             } ## end if ($val ne $old_watch...
1934         } ## end for (my $n = 0 ; $n <= ...
1935     } ## end if ($trace & 2)
1936
1937 =head2 C<watchfunction()>
1938
1939 C<watchfunction()> is a function that can be defined by the user; it is a
1940 function which will be run on each entry to C<DB::DB>; it gets the
1941 current package, filename, and line as its parameters.
1942
1943 The watchfunction can do anything it likes; it is executing in the
1944 debugger's context, so it has access to all of the debugger's internal
1945 data structures and functions.
1946
1947 C<watchfunction()> can control the debugger's actions. Any of the following
1948 will cause the debugger to return control to the user's program after
1949 C<watchfunction()> executes:
1950
1951 =over 4
1952
1953 =item * Returning a false value from the C<watchfunction()> itself.
1954
1955 =item * Altering C<$single> to a false value.
1956
1957 =item * Altering C<$signal> to a false value.
1958
1959 =item *  Turning off the '4' bit in C<$trace> (this also disables the
1960 check for C<watchfunction()>. This can be done with
1961
1962     $trace &= ~4;
1963
1964 =back
1965
1966 =cut
1967
1968     # If there's a user-defined DB::watchfunction, call it with the
1969     # current package, filename, and line. The function executes in
1970     # the DB:: package.
1971     if ( $trace & 4 ) {    # User-installed watch
1972         return
1973           if watchfunction( $package, $filename, $line )
1974           and not $single
1975           and not $was_signal
1976           and not( $trace & ~4 );
1977     } ## end if ($trace & 4)
1978
1979     # Pick up any alteration to $signal in the watchfunction, and
1980     # turn off the signal now.
1981     $was_signal = $signal;
1982     $signal     = 0;
1983
1984 =head2 GETTING READY TO EXECUTE COMMANDS
1985
1986 The debugger decides to take control if single-step mode is on, the
1987 C<t> command was entered, or the user generated a signal. If the program
1988 has fallen off the end, we set things up so that entering further commands
1989 won't cause trouble, and we say that the program is over.
1990
1991 =cut
1992
1993     # Check to see if we should grab control ($single true,
1994     # trace set appropriately, or we got a signal).
1995     if ( $single || ( $trace & 1 ) || $was_signal ) {
1996
1997         # Yes, grab control.
1998         if ($slave_editor) {
1999
2000             # Tell the editor to update its position.
2001             $position = "\032\032$filename:$line:0\n";
2002             print_lineinfo($position);
2003         }
2004
2005 =pod
2006
2007 Special check: if we're in package C<DB::fake>, we've gone through the
2008 C<END> block at least once. We set up everything so that we can continue
2009 to enter commands and have a valid context to be in.
2010
2011 =cut
2012
2013         elsif ( $package eq 'DB::fake' ) {
2014
2015             # Fallen off the end already.
2016             $term || &setterm;
2017             print_help(<<EOP);
2018 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2019   use B<O> I<inhibit_exit> to avoid stopping after program termination,
2020   B<h q>, B<h R> or B<h O> to get additional info.
2021 EOP
2022
2023             # Set the DB::eval context appropriately.
2024             $package     = 'main';
2025             $usercontext =
2026                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2027               . "package $package;";    # this won't let them modify, alas
2028         } ## end elsif ($package eq 'DB::fake')
2029
2030 =pod
2031
2032 If the program hasn't finished executing, we scan forward to the
2033 next executable line, print that out, build the prompt from the file and line
2034 number information, and print that.
2035
2036 =cut
2037
2038         else {
2039
2040             # Still somewhere in the midst of execution. Set up the
2041             #  debugger prompt.
2042             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2043                                  # Perl 5 ones (sorry, we don't print Klingon
2044                                  #module names)
2045
2046             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2047             $prefix .= "$sub($filename:";
2048             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2049
2050             # Break up the prompt if it's really long.
2051             if ( length($prefix) > 30 ) {
2052                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2053                 $prefix   = "";
2054                 $infix    = ":\t";
2055             }
2056             else {
2057                 $infix    = "):\t";
2058                 $position = "$prefix$line$infix$dbline[$line]$after";
2059             }
2060
2061             # Print current line info, indenting if necessary.
2062             if ($frame) {
2063                 print_lineinfo( ' ' x $stack_depth,
2064                     "$line:\t$dbline[$line]$after" );
2065             }
2066             else {
2067                 print_lineinfo($position);
2068             }
2069
2070             # Scan forward, stopping at either the end or the next
2071             # unbreakable line.
2072             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2073             {    #{ vi
2074
2075                 # Drop out on null statements, block closers, and comments.
2076                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2077
2078                 # Drop out if the user interrupted us.
2079                 last if $signal;
2080
2081                 # Append a newline if the line doesn't have one. Can happen
2082                 # in eval'ed text, for instance.
2083                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2084
2085                 # Next executable line.
2086                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2087                 $position .= $incr_pos;
2088                 if ($frame) {
2089
2090                     # Print it indented if tracing is on.
2091                     print_lineinfo( ' ' x $stack_depth,
2092                         "$i:\t$dbline[$i]$after" );
2093                 }
2094                 else {
2095                     print_lineinfo($incr_pos);
2096                 }
2097             } ## end for ($i = $line + 1 ; $i...
2098         } ## end else [ if ($slave_editor)
2099     } ## end if ($single || ($trace...
2100
2101 =pod
2102
2103 If there's an action to be executed for the line we stopped at, execute it.
2104 If there are any preprompt actions, execute those as well.
2105
2106 =cut
2107
2108     # If there's an action, do it now.
2109     $evalarg = $action, &eval if $action;
2110
2111     # Are we nested another level (e.g., did we evaluate a function
2112     # that had a breakpoint in it at the debugger prompt)?
2113     if ( $single || $was_signal ) {
2114
2115         # Yes, go down a level.
2116         local $level = $level + 1;
2117
2118         # Do any pre-prompt actions.
2119         foreach $evalarg (@$pre) {
2120             &eval;
2121         }
2122
2123         # Complain about too much recursion if we passed the limit.
2124         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2125           if $single & 4;
2126
2127         # The line we're currently on. Set $incr to -1 to stay here
2128         # until we get a command that tells us to advance.
2129         $start = $line;
2130         $incr  = -1;      # for backward motion.
2131
2132         # Tack preprompt debugger actions ahead of any actual input.
2133         @typeahead = ( @$pretype, @typeahead );
2134
2135 =head2 WHERE ARE WE?
2136
2137 XXX Relocate this section?
2138
2139 The debugger normally shows the line corresponding to the current line of
2140 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2141 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2142
2143 C<$incr> controls by how many lines the "current" line should move forward
2144 after a command is executed. If set to -1, this indicates that the "current"
2145 line shouldn't change.
2146
2147 C<$start> is the "current" line. It is used for things like knowing where to
2148 move forwards or backwards from when doing an C<L> or C<-> command.
2149
2150 C<$max> tells the debugger where the last line of the current file is. It's
2151 used to terminate loops most often.
2152
2153 =head2 THE COMMAND LOOP
2154
2155 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2156 in two parts:
2157
2158 =over 4
2159
2160 =item * The outer part of the loop, starting at the C<CMD> label. This loop
2161 reads a command and then executes it.
2162
2163 =item * The inner part of the loop, starting at the C<PIPE> label. This part
2164 is wholly contained inside the C<CMD> block and only executes a command.
2165 Used to handle commands running inside a pager.
2166
2167 =back
2168
2169 So why have two labels to restart the loop? Because sometimes, it's easier to
2170 have a command I<generate> another command and then re-execute the loop to do
2171 the new command. This is faster, but perhaps a bit more convoluted.
2172
2173 =cut
2174
2175         # The big command dispatch loop. It keeps running until the
2176         # user yields up control again.
2177         #
2178         # If we have a terminal for input, and we get something back
2179         # from readline(), keep on processing.
2180       CMD:
2181         while (
2182
2183             # We have a terminal, or can get one ...
2184             ( $term || &setterm ),
2185
2186             # ... and it belogs to this PID or we get one for this PID ...
2187             ( $term_pid == $$ or resetterm(1) ),
2188
2189             # ... and we got a line of command input ...
2190             defined(
2191                 $cmd = &readline(
2192                         "$pidprompt $tid DB"
2193                       . ( '<' x $level )
2194                       . ( $#hist + 1 )
2195                       . ( '>' x $level ) . " "
2196                 )
2197             )
2198           )
2199         {
2200
2201                         share($cmd);
2202             # ... try to execute the input as debugger commands.
2203
2204             # Don't stop running.
2205             $single = 0;
2206
2207             # No signal is active.
2208             $signal = 0;
2209
2210             # Handle continued commands (ending with \):
2211             $cmd =~ s/\\$/\n/ && do {
2212                 $cmd .= &readline("  cont: ");
2213                 redo CMD;
2214             };
2215
2216 =head4 The null command
2217
2218 A newline entered by itself means "re-execute the last command". We grab the
2219 command out of C<$laststep> (where it was recorded previously), and copy it
2220 back into C<$cmd> to be executed below. If there wasn't any previous command,
2221 we'll do nothing below (no command will match). If there was, we also save it
2222 in the command history and fall through to allow the command parsing to pick
2223 it up.
2224
2225 =cut
2226
2227             # Empty input means repeat the last command.
2228             $cmd =~ /^$/ && ( $cmd = $laststep );
2229             chomp($cmd);    # get rid of the annoying extra newline
2230             push( @hist, $cmd ) if length($cmd) > 1;
2231             push( @truehist, $cmd );
2232                         share(@hist);
2233                         share(@truehist);
2234
2235             # This is a restart point for commands that didn't arrive
2236             # via direct user input. It allows us to 'redo PIPE' to
2237             # re-execute command processing without reading a new command.
2238           PIPE: {
2239                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2240                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2241                 ($i) = split( /\s+/, $cmd );
2242
2243 =head3 COMMAND ALIASES
2244
2245 The debugger can create aliases for commands (these are stored in the
2246 C<%alias> hash). Before a command is executed, the command loop looks it up
2247 in the alias hash and substitutes the contents of the alias for the command,
2248 completely replacing it.
2249
2250 =cut
2251
2252                 # See if there's an alias for the command, and set it up if so.
2253                 if ( $alias{$i} ) {
2254
2255                     # Squelch signal handling; we want to keep control here
2256                     # if something goes loco during the alias eval.
2257                     local $SIG{__DIE__};
2258                     local $SIG{__WARN__};
2259
2260                     # This is a command, so we eval it in the DEBUGGER's
2261                     # scope! Otherwise, we can't see the special debugger
2262                     # variables, or get to the debugger's subs. (Well, we
2263                     # _could_, but why make it even more complicated?)
2264                     eval "\$cmd =~ $alias{$i}";
2265                     if ($@) {
2266                         local $\ = '';
2267                         print $OUT "Couldn't evaluate `$i' alias: $@";
2268                         next CMD;
2269                     }
2270                 } ## end if ($alias{$i})
2271
2272 =head3 MAIN-LINE COMMANDS
2273
2274 All of these commands work up to and after the program being debugged has
2275 terminated.
2276
2277 =head4 C<q> - quit
2278
2279 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2280 try to execute further, cleaning any restart-related stuff out of the
2281 environment, and executing with the last value of C<$?>.
2282
2283 =cut
2284
2285                 $cmd =~ /^q$/ && do {
2286                     $fall_off_end = 1;
2287                     clean_ENV();
2288                     exit $?;
2289                 };
2290
2291 =head4 C<t> - trace
2292
2293 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2294
2295 =cut
2296
2297                 $cmd =~ /^t$/ && do {
2298                     $trace ^= 1;
2299                     local $\ = '';
2300                     print $OUT "Trace = "
2301                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2302                     next CMD;
2303                 };
2304
2305 =head4 C<S> - list subroutines matching/not matching a pattern
2306
2307 Walks through C<%sub>, checking to see whether or not to print the name.
2308
2309 =cut
2310
2311                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2312
2313                     $Srev     = defined $2;     # Reverse scan?
2314                     $Spatt    = $3;             # The pattern (if any) to use.
2315                     $Snocheck = !defined $1;    # No args - print all subs.
2316
2317                     # Need to make these sane here.
2318                     local $\ = '';
2319                     local $, = '';
2320
2321                     # Search through the debugger's magical hash of subs.
2322                     # If $nocheck is true, just print the sub name.
2323                     # Otherwise, check it against the pattern. We then use
2324                     # the XOR trick to reverse the condition as required.
2325                     foreach $subname ( sort( keys %sub ) ) {
2326                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2327                             print $OUT $subname, "\n";
2328                         }
2329                     }
2330                     next CMD;
2331                 };
2332
2333 =head4 C<X> - list variables in current package
2334
2335 Since the C<V> command actually processes this, just change this to the
2336 appropriate C<V> command and fall through.
2337
2338 =cut
2339
2340                 $cmd =~ s/^X\b/V $package/;
2341
2342 =head4 C<V> - list variables
2343
2344 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2345
2346 =cut
2347
2348                 # Bare V commands get the currently-being-debugged package
2349                 # added.
2350                 $cmd =~ /^V$/ && do {
2351                     $cmd = "V $package";
2352                 };
2353
2354                 # V - show variables in package.
2355                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2356
2357                     # Save the currently selected filehandle and
2358                     # force output to debugger's filehandle (dumpvar
2359                     # just does "print" for output).
2360                     local ($savout) = select($OUT);
2361
2362                     # Grab package name and variables to dump.
2363                     $packname = $1;
2364                     @vars     = split( ' ', $2 );
2365
2366                     # If main::dumpvar isn't here, get it.
2367                     do 'dumpvar.pl' unless defined &main::dumpvar;
2368                     if ( defined &main::dumpvar ) {
2369
2370                         # We got it. Turn off subroutine entry/exit messages
2371                         # for the moment, along with return values.
2372                         local $frame = 0;
2373                         local $doret = -2;
2374
2375                         # must detect sigpipe failures  - not catching
2376                         # then will cause the debugger to die.
2377                         eval {
2378                             &main::dumpvar(
2379                                 $packname,
2380                                 defined $option{dumpDepth}
2381                                 ? $option{dumpDepth}
2382                                 : -1,    # assume -1 unless specified
2383                                 @vars
2384                             );
2385                         };
2386
2387                         # The die doesn't need to include the $@, because
2388                         # it will automatically get propagated for us.
2389                         if ($@) {
2390                             die unless $@ =~ /dumpvar print failed/;
2391                         }
2392                     } ## end if (defined &main::dumpvar)
2393                     else {
2394
2395                         # Couldn't load dumpvar.
2396                         print $OUT "dumpvar.pl not available.\n";
2397                     }
2398
2399                     # Restore the output filehandle, and go round again.
2400                     select($savout);
2401                     next CMD;
2402                 };
2403
2404 =head4 C<x> - evaluate and print an expression
2405
2406 Hands the expression off to C<DB::eval>, setting it up to print the value
2407 via C<dumpvar.pl> instead of just printing it directly.
2408
2409 =cut
2410
2411                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2412                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2413
2414                     # handle special  "x 3 blah" syntax XXX propagate
2415                     # doc back to special variables.
2416                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2417                         $onetimedumpDepth = $1;
2418                     }
2419                 };
2420
2421 =head4 C<m> - print methods
2422
2423 Just uses C<DB::methods> to determine what methods are available.
2424
2425 =cut
2426
2427                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2428                     methods($1);
2429                     next CMD;
2430                 };
2431
2432                 # m expr - set up DB::eval to do the work
2433                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2434                     $onetimeDump = 'methods';   #  method output gets used there
2435                 };
2436
2437 =head4 C<f> - switch files
2438
2439 =cut
2440
2441                 $cmd =~ /^f\b\s*(.*)/ && do {
2442                     $file = $1;
2443                     $file =~ s/\s+$//;
2444
2445                     # help for no arguments (old-style was return from sub).
2446                     if ( !$file ) {
2447                         print $OUT
2448                           "The old f command is now the r command.\n";    # hint
2449                         print $OUT "The new f command switches filenames.\n";
2450                         next CMD;
2451                     } ## end if (!$file)
2452
2453                     # if not in magic file list, try a close match.
2454                     if ( !defined $main::{ '_<' . $file } ) {
2455                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2456                             {
2457                                 $try = substr( $try, 2 );
2458                                 print $OUT "Choosing $try matching `$file':\n";
2459                                 $file = $try;
2460                             }
2461                         } ## end if (($try) = grep(m#^_<.*$file#...
2462                     } ## end if (!defined $main::{ ...
2463
2464                     # If not successfully switched now, we failed.
2465                     if ( !defined $main::{ '_<' . $file } ) {
2466                         print $OUT "No file matching `$file' is loaded.\n";
2467                         next CMD;
2468                     }
2469
2470                     # We switched, so switch the debugger internals around.
2471                     elsif ( $file ne $filename ) {
2472                         *dbline   = $main::{ '_<' . $file };
2473                         $max      = $#dbline;
2474                         $filename = $file;
2475                         $start    = 1;
2476                         $cmd      = "l";
2477                     } ## end elsif ($file ne $filename)
2478
2479                     # We didn't switch; say we didn't.
2480                     else {
2481                         print $OUT "Already in $file.\n";
2482                         next CMD;
2483                     }
2484                 };
2485
2486 =head4 C<.> - return to last-executed line.
2487
2488 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2489 and then we look up the line in the magical C<%dbline> hash.
2490
2491 =cut
2492
2493                 # . command.
2494                 $cmd =~ /^\.$/ && do {
2495                     $incr = -1;    # stay at current line
2496
2497                     # Reset everything to the old location.
2498                     $start    = $line;
2499                     $filename = $filename_ini;
2500                     *dbline   = $main::{ '_<' . $filename };
2501                     $max      = $#dbline;
2502
2503                     # Now where are we?
2504                     print_lineinfo($position);
2505                     next CMD;
2506                 };
2507
2508 =head4 C<-> - back one window
2509
2510 We change C<$start> to be one window back; if we go back past the first line,
2511 we set it to be the first line. We ser C<$incr> to put us back at the
2512 currently-executing line, and then put a C<l $start +> (list one window from
2513 C<$start>) in C<$cmd> to be executed later.
2514
2515 =cut
2516
2517                 # - - back a window.
2518                 $cmd =~ /^-$/ && do {
2519
2520                     # back up by a window; go to 1 if back too far.
2521                     $start -= $incr + $window + 1;
2522                     $start = 1 if $start <= 0;
2523                     $incr  = $window - 1;
2524
2525                     # Generate and execute a "l +" command (handled below).
2526                     $cmd = 'l ' . ($start) . '+';
2527                 };
2528
2529 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2530
2531 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2532 problems, most notably that the default case of several commands destroying
2533 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2534 retain the old commands for those who were used to using them or who preferred
2535 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2536 deal with them instead of processing them in-line.
2537
2538 =cut
2539
2540                 # All of these commands were remapped in perl 5.8.0;
2541                 # we send them off to the secondary dispatcher (see below).
2542                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2543                     &cmd_wrapper( $1, $2, $line );
2544                     next CMD;
2545                 };
2546
2547 =head4 C<y> - List lexicals in higher scope
2548
2549 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2550 above the current one and then displays then using C<dumpvar.pl>.
2551
2552 =cut
2553
2554                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2555
2556                     # See if we've got the necessary support.
2557                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2558                       or &warn(
2559                         $@ =~ /locate/
2560                         ? "PadWalker module not found - please install\n"
2561                         : $@
2562                       )
2563                       and next CMD;
2564
2565                     # Load up dumpvar if we don't have it. If we can, that is.
2566                     do 'dumpvar.pl' unless defined &main::dumpvar;
2567                     defined &main::dumpvar
2568                       or print $OUT "dumpvar.pl not available.\n"
2569                       and next CMD;
2570
2571                     # Got all the modules we need. Find them and print them.
2572                     my @vars = split( ' ', $2 || '' );
2573
2574                     # Find the pad.
2575                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2576
2577                     # Oops. Can't find it.
2578                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2579
2580                     # Show the desired vars with dumplex().
2581                     my $savout = select($OUT);
2582
2583                     # Have dumplex dump the lexicals.
2584                     dumpvar::dumplex( $_, $h->{$_},
2585                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2586                         @vars )
2587                       for sort keys %$h;
2588                     select($savout);
2589                     next CMD;
2590                 };
2591
2592 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2593
2594 All of the commands below this point don't work after the program being
2595 debugged has ended. All of them check to see if the program has ended; this
2596 allows the commands to be relocated without worrying about a 'line of
2597 demarcation' above which commands can be entered anytime, and below which
2598 they can't.
2599
2600 =head4 C<n> - single step, but don't trace down into subs
2601
2602 Done by setting C<$single> to 2, which forces subs to execute straight through
2603 when entered (see X<DB::sub>). We also save the C<n> command in C<$laststep>,
2604 so a null command knows what to re-execute.
2605
2606 =cut
2607
2608                 # n - next
2609                 $cmd =~ /^n$/ && do {
2610                     end_report(), next CMD if $finished and $level <= 1;
2611
2612                     # Single step, but don't enter subs.
2613                     $single = 2;
2614
2615                     # Save for empty command (repeat last).
2616                     $laststep = $cmd;
2617                     last CMD;
2618                 };
2619
2620 =head4 C<s> - single-step, entering subs
2621
2622 Sets C<$single> to 1, which causes X<DB::sub> to continue tracing inside
2623 subs. Also saves C<s> as C<$lastcmd>.
2624
2625 =cut
2626
2627                 # s - single step.
2628                 $cmd =~ /^s$/ && do {
2629
2630                     # Get out and restart the command loop if program
2631                     # has finished.
2632                     end_report(), next CMD if $finished and $level <= 1;
2633
2634                     # Single step should enter subs.
2635                     $single = 1;
2636
2637                     # Save for empty command (repeat last).
2638                     $laststep = $cmd;
2639                     last CMD;
2640                 };
2641
2642 =head4 C<c> - run continuously, setting an optional breakpoint
2643
2644 Most of the code for this command is taken up with locating the optional
2645 breakpoint, which is either a subroutine name or a line number. We set
2646 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2647 in this and all call levels above this one.
2648
2649 =cut
2650
2651                 # c - start continuous execution.
2652                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2653
2654                     # Hey, show's over. The debugged program finished
2655                     # executing already.
2656                     end_report(), next CMD if $finished and $level <= 1;
2657
2658                     # Capture the place to put a one-time break.
2659                     $subname = $i = $1;
2660
2661                     #  Probably not needed, since we finish an interactive
2662                     #  sub-session anyway...
2663                     # local $filename = $filename;
2664                     # local *dbline = *dbline; # XXX Would this work?!
2665                     #
2666                     # The above question wonders if localizing the alias
2667                     # to the magic array works or not. Since it's commented
2668                     # out, we'll just leave that to speculation for now.
2669
2670                     # If the "subname" isn't all digits, we'll assume it
2671                     # is a subroutine name, and try to find it.
2672                     if ( $subname =~ /\D/ ) {    # subroutine name
2673                             # Qualify it to the current package unless it's
2674                             # already qualified.
2675                         $subname = $package . "::" . $subname
2676                           unless $subname =~ /::/;
2677
2678                         # find_sub will return "file:line_number" corresponding
2679                         # to where the subroutine is defined; we call find_sub,
2680                         # break up the return value, and assign it in one
2681                         # operation.
2682                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2683
2684                         # Force the line number to be numeric.
2685                         $i += 0;
2686
2687                         # If we got a line number, we found the sub.
2688                         if ($i) {
2689
2690                             # Switch all the debugger's internals around so
2691                             # we're actually working with that file.
2692                             $filename = $file;
2693                             *dbline   = $main::{ '_<' . $filename };
2694
2695                             # Mark that there's a breakpoint in this file.
2696                             $had_breakpoints{$filename} |= 1;
2697
2698                             # Scan forward to the first executable line
2699                             # after the 'sub whatever' line.
2700                             $max = $#dbline;
2701                             ++$i while $dbline[$i] == 0 && $i < $max;
2702                         } ## end if ($i)
2703
2704                         # We didn't find a sub by that name.
2705                         else {
2706                             print $OUT "Subroutine $subname not found.\n";
2707                             next CMD;
2708                         }
2709                     } ## end if ($subname =~ /\D/)
2710
2711                     # At this point, either the subname was all digits (an
2712                     # absolute line-break request) or we've scanned through
2713                     # the code following the definition of the sub, looking
2714                     # for an executable, which we may or may not have found.
2715                     #
2716                     # If $i (which we set $subname from) is non-zero, we
2717                     # got a request to break at some line somewhere. On
2718                     # one hand, if there wasn't any real subroutine name
2719                     # involved, this will be a request to break in the current
2720                     # file at the specified line, so we have to check to make
2721                     # sure that the line specified really is breakable.
2722                     #
2723                     # On the other hand, if there was a subname supplied, the
2724                     # preceeding block has moved us to the proper file and
2725                     # location within that file, and then scanned forward
2726                     # looking for the next executable line. We have to make
2727                     # sure that one was found.
2728                     #
2729                     # On the gripping hand, we can't do anything unless the
2730                     # current value of $i points to a valid breakable line.
2731                     # Check that.
2732                     if ($i) {
2733
2734                         # Breakable?
2735                         if ( $dbline[$i] == 0 ) {
2736                             print $OUT "Line $i not breakable.\n";
2737                             next CMD;
2738                         }
2739
2740                         # Yes. Set up the one-time-break sigil.
2741                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2742                     } ## end if ($i)
2743
2744                     # Turn off stack tracing from here up.
2745                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2746                         $stack[ $i++ ] &= ~1;
2747                     }
2748                     last CMD;
2749                 };
2750
2751 =head4 C<r> - return from a subroutine
2752
2753 For C<r> to work properly, the debugger has to stop execution again
2754 immediately after the return is executed. This is done by forcing
2755 single-stepping to be on in the call level above the current one. If
2756 we are printing return values when a C<r> is executed, set C<$doret>
2757 appropriately, and force us out of the command loop.
2758
2759 =cut
2760
2761                 # r - return from the current subroutine.
2762                 $cmd =~ /^r$/ && do {
2763
2764                     # Can't do anythign if the program's over.
2765                     end_report(), next CMD if $finished and $level <= 1;
2766
2767                     # Turn on stack trace.
2768                     $stack[$stack_depth] |= 1;
2769
2770                     # Print return value unless the stack is empty.
2771                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2772                     last CMD;
2773                 };
2774
2775 =head4 C<T> - stack trace
2776
2777 Just calls C<DB::print_trace>.
2778
2779 =cut
2780
2781                 $cmd =~ /^T$/ && do {
2782                     print_trace( $OUT, 1 );    # skip DB
2783                     next CMD;
2784                 };
2785
2786 =head4 C<w> - List window around current line.
2787
2788 Just calls C<DB::cmd_w>.
2789
2790 =cut
2791
2792                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2793
2794 =head4 C<W> - watch-expression processing.
2795
2796 Just calls C<DB::cmd_W>.
2797
2798 =cut
2799
2800                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2801
2802 =head4 C</> - search forward for a string in the source
2803
2804 We take the argument and treat it as a pattern. If it turns out to be a
2805 bad one, we return the error we got from trying to C<eval> it and exit.
2806 If not, we create some code to do the search and C<eval> it so it can't
2807 mess us up.
2808
2809 =cut
2810
2811                 $cmd =~ /^\/(.*)$/ && do {
2812
2813                     # The pattern as a string.
2814                     $inpat = $1;
2815
2816                     # Remove the final slash.
2817                     $inpat =~ s:([^\\])/$:$1:;
2818
2819                     # If the pattern isn't null ...
2820                     if ( $inpat ne "" ) {
2821
2822                         # Turn of warn and die procesing for a bit.
2823                         local $SIG{__DIE__};
2824                         local $SIG{__WARN__};
2825
2826                         # Create the pattern.
2827                         eval '$inpat =~ m' . "\a$inpat\a";
2828                         if ( $@ ne "" ) {
2829
2830                             # Oops. Bad pattern. No biscuit.
2831                             # Print the eval error and go back for more
2832                             # commands.
2833                             print $OUT "$@";
2834                             next CMD;
2835                         }
2836                         $pat = $inpat;
2837                     } ## end if ($inpat ne "")
2838
2839                     # Set up to stop on wrap-around.
2840                     $end = $start;
2841
2842                     # Don't move off the current line.
2843                     $incr = -1;
2844
2845                     # Done in eval so nothing breaks if the pattern
2846                     # does something weird.
2847                     eval '
2848                         for (;;) {
2849                             # Move ahead one line.
2850                             ++$start;
2851
2852                             # Wrap if we pass the last line.
2853                             $start = 1 if ($start > $max);
2854
2855                             # Stop if we have gotten back to this line again,
2856                             last if ($start == $end);
2857
2858                             # A hit! (Note, though, that we are doing
2859                             # case-insensitive matching. Maybe a qr//
2860                             # expression would be better, so the user could
2861                             # do case-sensitive matching if desired.
2862                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2863                                 if ($slave_editor) {
2864                                     # Handle proper escaping in the slave.
2865                                     print $OUT "\032\032$filename:$start:0\n";
2866                                 }
2867                                 else {
2868                                     # Just print the line normally.
2869                                     print $OUT "$start:\t",$dbline[$start],"\n";
2870                                 }
2871                                 # And quit since we found something.
2872                                 last;
2873                             }
2874                          } ';
2875
2876                     # If we wrapped, there never was a match.
2877                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2878                     next CMD;
2879                 };
2880
2881 =head4 C<?> - search backward for a string in the source
2882
2883 Same as for C</>, except the loop runs backwards.
2884
2885 =cut
2886
2887                 # ? - backward pattern search.
2888                 $cmd =~ /^\?(.*)$/ && do {
2889
2890                     # Get the pattern, remove trailing question mark.
2891                     $inpat = $1;
2892                     $inpat =~ s:([^\\])\?$:$1:;
2893
2894                     # If we've got one ...
2895                     if ( $inpat ne "" ) {
2896
2897                         # Turn off die & warn handlers.
2898                         local $SIG{__DIE__};
2899                         local $SIG{__WARN__};
2900                         eval '$inpat =~ m' . "\a$inpat\a";
2901
2902                         if ( $@ ne "" ) {
2903
2904                             # Ouch. Not good. Print the error.
2905                             print $OUT $@;
2906                             next CMD;
2907                         }
2908                         $pat = $inpat;
2909                     } ## end if ($inpat ne "")
2910
2911                     # Where we are now is where to stop after wraparound.
2912                     $end = $start;
2913
2914                     # Don't move away from this line.
2915                     $incr = -1;
2916
2917                     # Search inside the eval to prevent pattern badness
2918                     # from killing us.
2919                     eval '
2920                         for (;;) {
2921                             # Back up a line.
2922                             --$start;
2923
2924                             # Wrap if we pass the first line.
2925
2926                             $start = $max if ($start <= 0);
2927
2928                             # Quit if we get back where we started,
2929                             last if ($start == $end);
2930
2931                             # Match?
2932                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2933                                 if ($slave_editor) {
2934                                     # Yep, follow slave editor requirements.
2935                                     print $OUT "\032\032$filename:$start:0\n";
2936                                 }
2937                                 else {
2938                                     # Yep, just print normally.
2939                                     print $OUT "$start:\t",$dbline[$start],"\n";
2940                                 }
2941
2942                                 # Found, so done.
2943                                 last;
2944                             }
2945                         } ';
2946
2947                     # Say we failed if the loop never found anything,
2948                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2949                     next CMD;
2950                 };
2951
2952 =head4 C<$rc> - Recall command
2953
2954 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2955 that the terminal supports history). It find the the command required, puts it
2956 into C<$cmd>, and redoes the loop to execute it.
2957
2958 =cut
2959
2960                 # $rc - recall command.
2961                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2962
2963                     # No arguments, take one thing off history.
2964                     pop(@hist) if length($cmd) > 1;
2965
2966                     # Relative (- found)?
2967                     #  Y - index back from most recent (by 1 if bare minus)
2968                     #  N - go to that particular command slot or the last
2969                     #      thing if nothing following.
2970                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2971
2972                     # Pick out the command desired.
2973                     $cmd = $hist[$i];
2974
2975                     # Print the command to be executed and restart the loop
2976                     # with that command in the buffer.
2977                     print $OUT $cmd, "\n";
2978                     redo CMD;
2979                 };
2980
2981 =head4 C<$sh$sh> - C<system()> command
2982
2983 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2984 C<STDOUT> from getting messed up.
2985
2986 =cut
2987
2988                 # $sh$sh - run a shell command (if it's all ASCII).
2989                 # Can't run shell commands with Unicode in the debugger, hmm.
2990                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2991
2992                     # System it.
2993                     &system($1);
2994                     next CMD;
2995                 };
2996
2997 =head4 C<$rc I<pattern> $rc> - Search command history
2998
2999 Another command to manipulate C<@hist>: this one searches it with a pattern.
3000 If a command is found, it is placed in C<$cmd> and executed via <redo>.
3001
3002 =cut
3003
3004                 # $rc pattern $rc - find a command in the history.
3005                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3006
3007                     # Create the pattern to use.
3008                     $pat = "^$1";
3009
3010                     # Toss off last entry if length is >1 (and it always is).
3011                     pop(@hist) if length($cmd) > 1;
3012
3013                     # Look backward through the history.
3014                     for ( $i = $#hist ; $i ; --$i ) {
3015
3016                         # Stop if we find it.
3017                         last if $hist[$i] =~ /$pat/;
3018                     }
3019
3020                     if ( !$i ) {
3021
3022                         # Never found it.
3023                         print $OUT "No such command!\n\n";
3024                         next CMD;
3025                     }
3026
3027                     # Found it. Put it in the buffer, print it, and process it.
3028                     $cmd = $hist[$i];
3029                     print $OUT $cmd, "\n";
3030                     redo CMD;
3031                 };
3032
3033 =head4 C<$sh> - Invoke a shell
3034
3035 Uses C<DB::system> to invoke a shell.
3036
3037 =cut
3038
3039                 # $sh - start a shell.
3040                 $cmd =~ /^$sh$/ && do {
3041
3042                     # Run the user's shell. If none defined, run Bourne.
3043                     # We resume execution when the shell terminates.
3044                     &system( $ENV{SHELL} || "/bin/sh" );
3045                     next CMD;
3046                 };
3047
3048 =head4 C<$sh I<command>> - Force execution of a command in a shell
3049
3050 Like the above, but the command is passed to the shell. Again, we use
3051 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3052
3053 =cut
3054
3055                 # $sh command - start a shell and run a command in it.
3056                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3057
3058                     # XXX: using csh or tcsh destroys sigint retvals!
3059                     #&system($1);  # use this instead
3060
3061                     # use the user's shell, or Bourne if none defined.
3062                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3063                     next CMD;
3064                 };
3065
3066 =head4 C<H> - display commands in history
3067
3068 Prints the contents of C<@hist> (if any).
3069
3070 =cut
3071
3072                 $cmd =~ /^H\b\s*\*/ && do {
3073                     @hist = @truehist = ();
3074                     print $OUT "History cleansed\n";
3075                     next CMD;
3076                 };
3077
3078                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3079
3080                     # Anything other than negative numbers is ignored by
3081                     # the (incorrect) pattern, so this test does nothing.
3082                     $end = $2 ? ( $#hist - $2 ) : 0;
3083
3084                     # Set to the minimum if less than zero.
3085                     $hist = 0 if $hist < 0;
3086
3087                     # Start at the end of the array.
3088                     # Stay in while we're still above the ending value.
3089                     # Tick back by one each time around the loop.
3090                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3091
3092                         # Print the command  unless it has no arguments.
3093                         print $OUT "$i: ", $hist[$i], "\n"
3094                           unless $hist[$i] =~ /^.?$/;
3095                     }
3096                     next CMD;
3097                 };
3098
3099 =head4 C<man, doc, perldoc> - look up documentation
3100
3101 Just calls C<runman()> to print the appropriate document.
3102
3103 =cut
3104
3105                 # man, perldoc, doc - show manual pages.
3106                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3107                     runman($1);
3108                     next CMD;
3109                 };
3110
3111 =head4 C<p> - print
3112
3113 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3114 the bottom of the loop.
3115
3116 =cut
3117
3118                 # p - print (no args): print $_.
3119                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3120
3121                 # p - print the given expression.
3122                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3123
3124 =head4 C<=> - define command alias
3125
3126 Manipulates C<%alias> to add or list command aliases.
3127
3128 =cut
3129
3130                 # = - set up a command alias.
3131                 $cmd =~ s/^=\s*// && do {
3132                     my @keys;
3133                     if ( length $cmd == 0 ) {
3134
3135                         # No args, get current aliases.
3136                         @keys = sort keys %alias;
3137                     }
3138                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3139
3140                         # Creating a new alias. $k is alias name, $v is
3141                         # alias value.
3142
3143                         # can't use $_ or kill //g state
3144                         for my $x ( $k, $v ) {
3145
3146                             # Escape "alarm" characters.
3147                             $x =~ s/\a/\\a/g;
3148                         }
3149
3150                         # Substitute key for value, using alarm chars
3151                         # as separators (which is why we escaped them in
3152                         # the command).
3153                         $alias{$k} = "s\a$k\a$v\a";
3154
3155                         # Turn off standard warn and die behavior.
3156                         local $SIG{__DIE__};
3157                         local $SIG{__WARN__};
3158
3159                         # Is it valid Perl?
3160                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3161
3162                             # Nope. Bad alias. Say so and get out.
3163                             print $OUT "Can't alias $k to $v: $@\n";
3164                             delete $alias{$k};
3165                             next CMD;
3166                         }
3167
3168                         # We'll only list the new one.
3169                         @keys = ($k);
3170                     } ## end elsif (my ($k, $v) = ($cmd...
3171
3172                     # The argument is the alias to list.
3173                     else {
3174                         @keys = ($cmd);
3175                     }
3176
3177                     # List aliases.
3178                     for my $k (@keys) {
3179
3180                         # Messy metaquoting: Trim the substiution code off.
3181                         # We use control-G as the delimiter because it's not
3182                         # likely to appear in the alias.
3183                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3184
3185                             # Print the alias.
3186                             print $OUT "$k\t= $1\n";
3187                         }
3188                         elsif ( defined $alias{$k} ) {
3189
3190                             # Couldn't trim it off; just print the alias code.
3191                             print $OUT "$k\t$alias{$k}\n";
3192                         }
3193                         else {
3194
3195                             # No such, dude.
3196                             print "No alias for $k\n";
3197                         }
3198                     } ## end for my $k (@keys)
3199                     next CMD;
3200                 };
3201
3202 =head4 C<source> - read commands from a file.
3203
3204 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3205 pick it up.
3206
3207 =cut
3208
3209                 # source - read commands from a file (or pipe!) and execute.
3210                 $cmd =~ /^source\s+(.*\S)/ && do {
3211                     if ( open my $fh, $1 ) {
3212
3213                         # Opened OK; stick it in the list of file handles.
3214                         push @cmdfhs, $fh;
3215                     }
3216                     else {
3217
3218                         # Couldn't open it.
3219                         &warn("Can't execute `$1': $!\n");
3220                     }
3221                     next CMD;
3222                 };
3223
3224 =head4 C<save> - send current history to a file
3225
3226 Takes the complete history, (not the shrunken version you see with C<H>),
3227 and saves it to the given filename, so it can be replayed using C<source>.
3228
3229 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3230
3231 =cut
3232
3233                 # save source - write commands to a file for later use
3234                 $cmd =~ /^save\s*(.*)$/ && do {
3235                     my $file = $1 || '.perl5dbrc';    # default?
3236                     if ( open my $fh, "> $file" ) {
3237
3238                        # chomp to remove extraneous newlines from source'd files
3239                         chomp( my @truelist =
3240                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3241                               @truehist );
3242                         print $fh join( "\n", @truelist );
3243                         print "commands saved in $file\n";
3244                     }
3245                     else {
3246                         &warn("Can't save debugger commands in '$1': $!\n");
3247                     }
3248                     next CMD;
3249                 };
3250
3251 =head4 C<R> - restart
3252
3253 Restart the debugger session.
3254
3255 =head4 C<rerun> - rerun the current session
3256
3257 Return to any given position in the B<true>-history list
3258
3259 =cut
3260
3261                 # R - restart execution.
3262                 # rerun - controlled restart execution.
3263                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3264                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3265
3266                     # Close all non-system fds for a clean restart.  A more
3267                     # correct method would be to close all fds that were not
3268                     # open when the process started, but this seems to be
3269                     # hard.  See "debugger 'R'estart and open database
3270                     # connections" on p5p.
3271
3272                     my $max_fd = 1024; # default if POSIX can't be loaded
3273                     if (eval { require POSIX }) {
3274                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3275                     }
3276
3277                     if (defined $max_fd) {
3278                         foreach ($^F+1 .. $max_fd-1) {
3279                             next unless open FD_TO_CLOSE, "<&=$_";
3280                             close(FD_TO_CLOSE);
3281                         }
3282                     }
3283
3284                     # And run Perl again.  We use exec() to keep the
3285                     # PID stable (and that way $ini_pids is still valid).
3286                     exec(@args) || print $OUT "exec failed: $!\n";
3287
3288                     last CMD;
3289                 };
3290
3291 =head4 C<|, ||> - pipe output through the pager.
3292
3293 FOR C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3294 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3295 pipe to the pager (restoring the output filehandles if this fails). If this
3296 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3297 set C<$signal>, sending us back into the debugger.
3298
3299 We then trim off the pipe symbols and C<redo> the command loop at the
3300 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3301 reading another.
3302
3303 =cut
3304
3305                 # || - run command in the pager, with output to DB::OUT.
3306                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3307                     if ( $pager =~ /^\|/ ) {
3308
3309                         # Default pager is into a pipe. Redirect I/O.
3310                         open( SAVEOUT, ">&STDOUT" )
3311                           || &warn("Can't save STDOUT");
3312                         open( STDOUT, ">&OUT" )
3313                           || &warn("Can't redirect STDOUT");
3314                     } ## end if ($pager =~ /^\|/)
3315                     else {
3316
3317                         # Not into a pipe. STDOUT is safe.
3318                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3319                     }
3320
3321                     # Fix up environment to record we have less if so.
3322                     fix_less();
3323
3324                     unless ( $piped = open( OUT, $pager ) ) {
3325
3326                         # Couldn't open pipe to pager.
3327                         &warn("Can't pipe output to `$pager'");
3328                         if ( $pager =~ /^\|/ ) {
3329
3330                             # Redirect I/O back again.
3331                             open( OUT, ">&STDOUT" )    # XXX: lost message
3332                               || &warn("Can't restore DB::OUT");
3333                             open( STDOUT, ">&SAVEOUT" )
3334                               || &warn("Can't restore STDOUT");
3335                             close(SAVEOUT);
3336                         } ## end if ($pager =~ /^\|/)
3337                         else {
3338
3339                             # Redirect I/O. STDOUT already safe.
3340                             open( OUT, ">&STDOUT" )    # XXX: lost message
3341                               || &warn("Can't restore DB::OUT");
3342                         }
3343                         next CMD;
3344                     } ## end unless ($piped = open(OUT,...
3345
3346                     # Set up broken-pipe handler if necessary.
3347                     $SIG{PIPE} = \&DB::catch
3348                       if $pager =~ /^\|/
3349                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3350
3351                     # Save current filehandle, unbuffer out, and put it back.
3352                     $selected = select(OUT);
3353                     $|        = 1;
3354
3355                     # Don't put it back if pager was a pipe.
3356                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3357
3358                     # Trim off the pipe symbols and run the command now.
3359                     $cmd =~ s/^\|+\s*//;
3360                     redo PIPE;
3361                 };
3362
3363 =head3 END OF COMMAND PARSING
3364
3365 Anything left in C<$cmd> at this point is a Perl expression that we want to
3366 evaluate. We'll always evaluate in the user's context, and fully qualify
3367 any variables we might want to address in the C<DB> package.
3368
3369 =cut
3370
3371                 # t - turn trace on.
3372                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3373
3374                 # s - single-step. Remember the last command was 's'.
3375                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3376
3377                 # n - single-step, but not into subs. Remember last command
3378                 # was 'n'.
3379                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3380
3381             }    # PIPE:
3382
3383             # Make sure the flag that says "the debugger's running" is
3384             # still on, to make sure we get control again.
3385             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3386
3387             # Run *our* eval that executes in the caller's context.
3388             &eval;
3389
3390             # Turn off the one-time-dump stuff now.
3391             if ($onetimeDump) {
3392                 $onetimeDump      = undef;
3393                 $onetimedumpDepth = undef;
3394             }
3395             elsif ( $term_pid == $$ ) {
3396                 STDOUT->flush();
3397                 STDERR->flush();
3398
3399                 # XXX If this is the master pid, print a newline.
3400                 print $OUT "\n";
3401             }
3402         } ## end while (($term || &setterm...
3403
3404 =head3 POST-COMMAND PROCESSING
3405
3406 After each command, we check to see if the command output was piped anywhere.
3407 If so, we go through the necessary code to unhook the pipe and go back to
3408 our standard filehandles for input and output.
3409
3410 =cut
3411
3412         continue {    # CMD:
3413
3414             # At the end of every command:
3415             if ($piped) {
3416
3417                 # Unhook the pipe mechanism now.
3418                 if ( $pager =~ /^\|/ ) {
3419
3420                     # No error from the child.
3421                     $? = 0;
3422
3423                     # we cannot warn here: the handle is missing --tchrist
3424                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3425
3426                     # most of the $? crud was coping with broken cshisms
3427                     # $? is explicitly set to 0, so this never runs.
3428                     if ($?) {
3429                         print SAVEOUT "Pager `$pager' failed: ";
3430                         if ( $? == -1 ) {
3431                             print SAVEOUT "shell returned -1\n";
3432                         }
3433                         elsif ( $? >> 8 ) {
3434                             print SAVEOUT ( $? & 127 )
3435                               ? " (SIG#" . ( $? & 127 ) . ")"
3436                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3437                         }
3438                         else {
3439                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3440                         }
3441                     } ## end if ($?)
3442
3443                     # Reopen filehandle for our output (if we can) and
3444                     # restore STDOUT (if we can).
3445                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3446                     open( STDOUT, ">&SAVEOUT" )
3447                       || &warn("Can't restore STDOUT");
3448
3449                     # Turn off pipe exception handler if necessary.
3450                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3451
3452                     # Will stop ignoring SIGPIPE if done like nohup(1)
3453                     # does SIGINT but Perl doesn't give us a choice.
3454                 } ## end if ($pager =~ /^\|/)
3455                 else {
3456
3457                     # Non-piped "pager". Just restore STDOUT.
3458                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3459                 }
3460
3461                 # Close filehandle pager was using, restore the normal one
3462                 # if necessary,
3463                 close(SAVEOUT);
3464                 select($selected), $selected = "" unless $selected eq "";
3465
3466                 # No pipes now.
3467                 $piped = "";
3468             } ## end if ($piped)
3469         }    # CMD:
3470
3471 =head3 COMMAND LOOP TERMINATION
3472
3473 When commands have finished executing, we come here. If the user closed the
3474 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3475 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3476 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3477 The interpreter will then execute the next line and then return control to us
3478 again.
3479
3480 =cut
3481
3482         # No more commands? Quit.
3483         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3484
3485         # Evaluate post-prompt commands.
3486         foreach $evalarg (@$post) {
3487             &eval;
3488         }
3489     }    # if ($single || $signal)
3490
3491     # Put the user's globals back where you found them.
3492     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3493     ();
3494 } ## end sub DB
3495
3496 # The following code may be executed now:
3497 # BEGIN {warn 4}
3498
3499 =head2 sub
3500
3501 C<sub> is called whenever a subroutine call happens in the program being
3502 debugged. The variable C<$DB::sub> contains the name of the subroutine
3503 being called.
3504
3505 The core function of this subroutine is to actually call the sub in the proper
3506 context, capturing its output. This of course causes C<DB::DB> to get called
3507 again, repeating until the subroutine ends and returns control to C<DB::sub>
3508 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3509 return value, and returns its captured copy of the return value as its own
3510 return value. The value then feeds back into the program being debugged as if
3511 C<DB::sub> hadn't been there at all.
3512
3513 C<sub> does all the work of printing the subroutine entry and exit messages
3514 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3515 and also prints the return value if needed (for the C<r> command and if
3516 the 16 bit is set in C<$frame>).
3517
3518 It also tracks the subroutine call depth by saving the current setting of
3519 C<$single> in the C<@stack> package global; if this exceeds the value in
3520 C<$deep>, C<sub> automatically turns on printing of the current depth by
3521 setting the 4 bit in C<$single>. In any case, it keeps the current setting
3522 of stop/don't stop on entry to subs set as it currently is set.
3523
3524 =head3 C<caller()> support
3525
3526 If C<caller()> is called from the package C<DB>, it provides some
3527 additional data, in the following order:
3528
3529 =over 4
3530
3531 =item * C<$package>
3532
3533 The package name the sub was in
3534
3535 =item * C<$filename>
3536
3537 The filename it was defined in
3538
3539 =item * C<$line>
3540
3541 The line number it was defined on
3542
3543 =item * C<$subroutine>
3544
3545 The subroutine name; C<'(eval)'> if an C<eval>().
3546
3547 =item * C<$hasargs>
3548
3549 1 if it has arguments, 0 if not
3550
3551 =item * C<$wantarray>
3552
3553 1 if array context, 0 if scalar context
3554
3555 =item * C<$evaltext>
3556
3557 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3558
3559 =item * C<$is_require>
3560
3561 frame was created by a C<use> or C<require> statement
3562
3563 =item * C<$hints>
3564
3565 pragma information; subject to change between versions
3566
3567 =item * C<$bitmask>
3568
3569 pragma information: subject to change between versions
3570
3571 =item * C<@DB::args>
3572
3573 arguments with which the subroutine was invoked
3574
3575 =back
3576
3577 =cut
3578
3579 sub sub {
3580
3581         # lock ourselves under threads
3582         lock($DBGR);
3583
3584     # Whether or not the autoloader was running, a scalar to put the
3585     # sub's return value in (if needed), and an array to put the sub's
3586     # return value in (if needed).
3587     my ( $al, $ret, @ret ) = "";
3588         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3589                 print "creating new thread\n";
3590         }
3591
3592     # If the last ten characters are C'::AUTOLOAD', note we've traced
3593     # into AUTOLOAD for $sub.
3594     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3595         $al = " for $$sub";
3596     }
3597
3598     # We stack the stack pointer and then increment it to protect us
3599     # from a situation that might unwind a whole bunch of call frames
3600     # at once. Localizing the stack pointer means that it will automatically
3601     # unwind the same amount when multiple stack frames are unwound.
3602     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3603
3604     # Expand @stack.
3605     $#stack = $stack_depth;
3606
3607     # Save current single-step setting.
3608     $stack[-1] = $single;
3609
3610     # Turn off all flags except single-stepping.
3611     $single &= 1;
3612
3613     # If we've gotten really deeply recursed, turn on the flag that will
3614     # make us stop with the 'deep recursion' message.
3615     $single |= 4 if $stack_depth == $deep;
3616
3617     # If frame messages are on ...
3618     (
3619         $frame & 4    # Extended frame entry message
3620         ? (
3621             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3622
3623             # Why -1? But it works! :-(
3624             # Because print_trace will call add 1 to it and then call
3625             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3626             # in dump_trace.
3627             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3628           )
3629         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3630
3631           # standard frame entry message
3632       )
3633       if $frame;
3634
3635     # Determine the sub's return type,and capture approppriately.
3636     if (wantarray) {
3637
3638         # Called in array context. call sub and capture output.
3639         # DB::DB will recursively get control again if appropriate; we'll come
3640         # back here when the sub is finished.
3641         if ($assertion) {
3642             $assertion = 0;
3643             eval { @ret = &$sub; };
3644             if ($@) {
3645                 print $OUT $@;
3646                 $signal = 1 unless $warnassertions;
3647             }
3648         }
3649         else {
3650             @ret = &$sub;
3651         }
3652
3653         # Pop the single-step value back off the stack.
3654         $single |= $stack[ $stack_depth-- ];
3655
3656         # Check for exit trace messages...
3657         (
3658             $frame & 4    # Extended exit message
3659             ? (
3660                 print_lineinfo( ' ' x $stack_depth, "out " ),
3661                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3662               )
3663             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3664
3665               # Standard exit message
3666           )
3667           if $frame & 2;
3668
3669         # Print the return info if we need to.
3670         if ( $doret eq $stack_depth or $frame & 16 ) {
3671
3672             # Turn off output record separator.
3673             local $\ = '';
3674             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3675
3676             # Indent if we're printing because of $frame tracing.
3677             print $fh ' ' x $stack_depth if $frame & 16;
3678
3679             # Print the return value.
3680             print $fh "list context return from $sub:\n";
3681             dumpit( $fh, \@ret );
3682
3683             # And don't print it again.
3684             $doret = -2;
3685         } ## end if ($doret eq $stack_depth...
3686             # And we have to return the return value now.
3687         @ret;
3688     } ## end if (wantarray)
3689
3690     # Scalar context.
3691     else {
3692         if ($assertion) {
3693             $assertion = 0;
3694             eval {
3695
3696                 # Save the value if it's wanted at all.
3697                 $ret = &$sub;
3698             };
3699             if ($@) {
3700                 print $OUT $@;
3701                 $signal = 1 unless $warnassertions;
3702             }
3703             $ret = undef unless defined wantarray;
3704         }
3705         else {
3706             if ( defined wantarray ) {
3707
3708                 # Save the value if it's wanted at all.
3709                 $ret = &$sub;
3710             }
3711             else {
3712
3713                 # Void return, explicitly.
3714                 &$sub;
3715                 undef $ret;
3716             }
3717         }    # if assertion
3718
3719         # Pop the single-step value off the stack.
3720         $single |= $stack[ $stack_depth-- ];
3721
3722         # If we're doing exit messages...
3723         (
3724             $frame & 4    # Extended messsages
3725             ? (
3726                 print_lineinfo( ' ' x $stack_depth, "out " ),
3727                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3728               )
3729             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3730
3731               # Standard messages
3732           )
3733           if $frame & 2;
3734
3735         # If we are supposed to show the return value... same as before.
3736         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3737             local $\ = '';
3738             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3739             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3740             print $fh (
3741                 defined wantarray
3742                 ? "scalar context return from $sub: "
3743                 : "void context return from $sub\n"
3744             );
3745             dumpit( $fh, $ret ) if defined wantarray;
3746             $doret = -2;
3747         } ## end if ($doret eq $stack_depth...
3748
3749         # Return the appropriate scalar value.
3750         $ret;
3751     } ## end else [ if (wantarray)
3752 } ## end sub sub
3753
3754 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3755
3756 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3757 Most of the changes were to systematize the command structure and to eliminate
3758 commands that threw away user input without checking.
3759
3760 The following sections describe the code added to make it easy to support
3761 multiple command sets with conflicting command names. This section is a start
3762 at unifying all command processing to make it simpler to develop commands.
3763
3764 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3765 number, and C<$dbline> (the current line) as arguments.
3766
3767 Support functions in this section which have multiple modes of failure C<die>
3768 on error; the rest simply return a false value.
3769
3770 The user-interface functions (all of the C<cmd_*> functions) just output
3771 error messages.
3772
3773 =head2 C<%set>
3774
3775 The C<%set> hash defines the mapping from command letter to subroutine
3776 name suffix.
3777
3778 C<%set> is a two-level hash, indexed by set name and then by command name.
3779 Note that trying to set the CommandSet to 'foobar' simply results in the
3780 5.8.0 command set being used, since there's no top-level entry for 'foobar'.
3781
3782 =cut
3783
3784 ### The API section
3785
3786 my %set = (    #
3787     'pre580' => {
3788         'a' => 'pre580_a',
3789         'A' => 'pre580_null',
3790         'b' => 'pre580_b',
3791         'B' => 'pre580_null',
3792         'd' => 'pre580_null',
3793         'D' => 'pre580_D',
3794         'h' => 'pre580_h',
3795         'M' => 'pre580_null',
3796         'O' => 'o',
3797         'o' => 'pre580_null',
3798         'v' => 'M',
3799         'w' => 'v',
3800         'W' => 'pre580_W',
3801     },
3802     'pre590' => {
3803         '<'  => 'pre590_prepost',
3804         '<<' => 'pre590_prepost',
3805         '>'  => 'pre590_prepost',
3806         '>>' => 'pre590_prepost',
3807         '{'  => 'pre590_prepost',
3808         '{{' => 'pre590_prepost',
3809     },
3810 );
3811
3812 =head2 C<cmd_wrapper()> (API)
3813
3814 C<cmd_wrapper()> allows the debugger to switch command sets
3815 depending on the value of the C<CommandSet> option.
3816
3817 It tries to look up the command in the X<C<%set>> package-level I<lexical>
3818 (which means external entities can't fiddle with it) and create the name of
3819 the sub to call based on the value found in the hash (if it's there). I<All>
3820 of the commands to be handled in a set have to be added to C<%set>; if they
3821 aren't found, the 5.8.0 equivalent is called (if there is one).
3822
3823 This code uses symbolic references.
3824
3825 =cut
3826
3827 sub cmd_wrapper {
3828     my $cmd      = shift;
3829     my $line     = shift;
3830     my $dblineno = shift;
3831
3832     # Assemble the command subroutine's name by looking up the
3833     # command set and command name in %set. If we can't find it,
3834     # default to the older version of the command.
3835     my $call = 'cmd_'
3836       . ( $set{$CommandSet}{$cmd}
3837           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3838
3839     # Call the command subroutine, call it by name.
3840     return &$call( $cmd, $line, $dblineno );
3841 } ## end sub cmd_wrapper
3842
3843 =head3 C<cmd_a> (command)
3844
3845 The C<a> command handles pre-execution actions. These are associated with a
3846 particular line, so they're stored in C<%dbline>. We default to the current
3847 line if none is specified.
3848
3849 =cut
3850
3851 sub cmd_a {
3852     my $cmd    = shift;
3853     my $line   = shift || '';    # [.|line] expr
3854     my $dbline = shift;
3855
3856     # If it's dot (here), or not all digits,  use the current line.
3857     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3858
3859     # Should be a line number followed by an expression.
3860     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3861         my ( $lineno, $expr ) = ( $1, $2 );
3862
3863         # If we have an expression ...
3864         if ( length $expr ) {
3865
3866             # ... but the line isn't breakable, complain.
3867             if ( $dbline[$lineno] == 0 ) {
3868                 print $OUT
3869                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3870             }
3871             else {
3872
3873                 # It's executable. Record that the line has an action.
3874                 $had_breakpoints{$filename} |= 2;
3875
3876                 # Remove any action, temp breakpoint, etc.
3877                 $dbline{$lineno} =~ s/\0[^\0]*//;
3878
3879                 # Add the action to the line.
3880                 $dbline{$lineno} .= "\0" . action($expr);
3881             }
3882         } ## end if (length $expr)
3883     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3884     else {
3885
3886         # Syntax wrong.
3887         print $OUT
3888           "Adding an action requires an optional lineno and an expression\n"
3889           ;    # hint
3890     }
3891 } ## end sub cmd_a
3892
3893 =head3 C<cmd_A> (command)
3894
3895 Delete actions. Similar to above, except the delete code is in a separate
3896 subroutine, C<delete_action>.
3897
3898 =cut
3899
3900 sub cmd_A {
3901     my $cmd    = shift;
3902     my $line   = shift || '';
3903     my $dbline = shift;
3904
3905     # Dot is this line.
3906     $line =~ s/^\./$dbline/;
3907
3908     # Call delete_action with a null param to delete them all.
3909     # The '1' forces the eval to be true. It'll be false only
3910     # if delete_action blows up for some reason, in which case
3911     # we print $@ and get out.
3912     if ( $line eq '*' ) {
3913         eval { &delete_action(); 1 } or print $OUT $@ and return;
3914     }
3915
3916     # There's a real line  number. Pass it to delete_action.
3917     # Error trapping is as above.
3918     elsif ( $line =~ /^(\S.*)/ ) {
3919         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3920     }
3921
3922     # Swing and a miss. Bad syntax.
3923     else {
3924         print $OUT
3925           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3926     }
3927 } ## end sub cmd_A
3928
3929 =head3 C<delete_action> (API)
3930
3931 C<delete_action> accepts either a line number or C<undef>. If a line number
3932 is specified, we check for the line being executable (if it's not, it
3933 couldn't have had an  action). If it is, we just take the action off (this
3934 will get any kind of an action, including breakpoints).
3935
3936 =cut
3937
3938 sub delete_action {
3939     my $i = shift;
3940     if ( defined($i) ) {
3941
3942         # Can there be one?
3943         die "Line $i has no action .\n" if $dbline[$i] == 0;
3944
3945         # Nuke whatever's there.
3946         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3947         delete $dbline{$i} if $dbline{$i} eq '';
3948     }
3949     else {
3950         print $OUT "Deleting all actions...\n";
3951         for my $file ( keys %had_breakpoints ) {
3952             local *dbline = $main::{ '_<' . $file };
3953             my $max = $#dbline;
3954             my $was;
3955             for ( $i = 1 ; $i <= $max ; $i++ ) {
3956                 if ( defined $dbline{$i} ) {
3957                     $dbline{$i} =~ s/\0[^\0]*//;
3958                     delete $dbline{$i} if $dbline{$i} eq '';
3959                 }
3960                 unless ( $had_breakpoints{$file} &= ~2 ) {
3961                     delete $had_breakpoints{$file};
3962                 }
3963             } ## end for ($i = 1 ; $i <= $max...
3964         } ## end for my $file (keys %had_breakpoints)
3965     } ## end else [ if (defined($i))
3966 } ## end sub delete_action
3967
3968 =head3 C<cmd_b> (command)
3969
3970 Set breakpoints. Since breakpoints can be set in so many places, in so many
3971 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
3972 we try to parse the command type, and then shuttle it off to an appropriate
3973 subroutine to actually do the work of setting the breakpoint in the right
3974 place.
3975
3976 =cut
3977
3978 sub cmd_b {
3979     my $cmd    = shift;
3980     my $line   = shift;    # [.|line] [cond]
3981     my $dbline = shift;
3982
3983     # Make . the current line number if it's there..
3984     $line =~ s/^\./$dbline/;
3985
3986     # No line number, no condition. Simple break on current line.
3987     if ( $line =~ /^\s*$/ ) {
3988         &cmd_b_line( $dbline, 1 );
3989     }
3990
3991     # Break on load for a file.
3992     elsif ( $line =~ /^load\b\s*(.*)/ ) {
3993         my $file = $1;
3994         $file =~ s/\s+$//;
3995         &cmd_b_load($file);
3996     }
3997
3998     # b compile|postpone <some sub> [<condition>]
3999     # The interpreter actually traps this one for us; we just put the
4000     # necessary condition in the %postponed hash.
4001     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4002
4003         # Capture the condition if there is one. Make it true if none.
4004         my $cond = length $3 ? $3 : '1';
4005
4006         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4007         # if it was 'compile'.
4008         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4009
4010         # De-Perl4-ify the name - ' separators to ::.
4011         $subname =~ s/\'/::/g;
4012
4013         # Qualify it into the current package unless it's already qualified.
4014         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4015
4016         # Add main if it starts with ::.
4017         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4018
4019         # Save the break type for this sub.
4020         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4021     } ## end elsif ($line =~ ...
4022
4023     # b <sub name> [<condition>]
4024     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4025
4026         #
4027         $subname = $1;
4028         $cond = length $2 ? $2 : '1';
4029         &cmd_b_sub( $subname, $cond );
4030     }
4031
4032     # b <line> [<condition>].
4033     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4034
4035         # Capture the line. If none, it's the current line.
4036         $line = $1 || $dbline;
4037
4038         # If there's no condition, make it '1'.
4039         $cond = length $2 ? $2 : '1';
4040
4041         # Break on line.
4042         &cmd_b_line( $line, $cond );
4043     }
4044
4045     # Line didn't make sense.
4046     else {
4047         print "confused by line($line)?\n";
4048     }
4049 } ## end sub cmd_b
4050
4051 =head3 C<break_on_load> (API)
4052
4053 We want to break when this file is loaded. Mark this file in the
4054 C<%break_on_load> hash, and note that it has a breakpoint in
4055 C<%had_breakpoints>.
4056
4057 =cut
4058
4059 sub break_on_load {
4060     my $file = shift;
4061     $break_on_load{$file} = 1;
4062     $had_breakpoints{$file} |= 1;
4063 }
4064
4065 =head3 C<report_break_on_load> (API)
4066
4067 Gives us an array of filenames that are set to break on load. Note that
4068 only files with break-on-load are in here, so simply showing the keys
4069 suffices.
4070
4071 =cut
4072
4073 sub report_break_on_load {
4074     sort keys %break_on_load;
4075 }
4076
4077 =head3 C<cmd_b_load> (command)
4078
4079 We take the file passed in and try to find it in C<%INC> (which maps modules
4080 to files they came from). We mark those files for break-on-load via
4081 C<break_on_load> and then report that it was done.
4082
4083 =cut
4084
4085 sub cmd_b_load {
4086     my $file = shift;
4087     my @files;
4088
4089     # This is a block because that way we can use a redo inside it
4090     # even without there being any looping structure at all outside it.
4091     {
4092
4093         # Save short name and full path if found.
4094         push @files, $file;
4095         push @files, $::INC{$file} if $::INC{$file};
4096
4097         # Tack on .pm and do it again unless there was a '.' in the name
4098         # already.
4099         $file .= '.pm', redo unless $file =~ /\./;
4100     }
4101
4102     # Do the real work here.
4103     break_on_load($_) for @files;
4104
4105     # All the files that have break-on-load breakpoints.
4106     @files = report_break_on_load;
4107
4108     # Normalize for the purposes of our printing this.
4109     local $\ = '';
4110     local $" = ' ';
4111     print $OUT "Will stop on load of `@files'.\n";
4112 } ## end sub cmd_b_load
4113
4114 =head3 C<$filename_error> (API package global)
4115
4116 Several of the functions we need to implement in the API need to work both
4117 on the current file and on other files. We don't want to duplicate code, so
4118 C<$filename_error> is used to contain the name of the file that's being
4119 worked on (if it's not the current one).
4120
4121 We can now build functions in pairs: the basic function works on the current
4122 file, and uses C<$filename_error> as part of its error message. Since this is
4123 initialized to C<''>, no filename will appear when we are working on the
4124 current file.
4125
4126 The second function is a wrapper which does the following:
4127
4128 =over 4
4129
4130 =item * Localizes C<$filename_error> and sets it to the name of the file to be processed.
4131
4132 =item * Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4133
4134 =item * Calls the first function.
4135
4136 The first function works on the "current" (i.e., the one we changed to) file,
4137 and prints C<$filename_error> in the error message (the name of the other file)
4138 if it needs to. When the functions return, C<*dbline> is restored to point to the actual current file (the one we're executing in) and C<$filename_error> is
4139 restored to C<''>. This restores everything to the way it was before the
4140 second function was called at all.
4141
4142 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4143 details.
4144
4145 =back
4146
4147 =cut
4148
4149 $filename_error = '';
4150
4151 =head3 breakable_line($from, $to) (API)
4152
4153 The subroutine decides whether or not a line in the current file is breakable.
4154 It walks through C<@dbline> within the range of lines specified, looking for
4155 the first line that is breakable.
4156
4157 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4158 first line I<after> C<$to> that's breakable, if there is one.
4159
4160 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4161 first line I<before> C<$to> that's breakable, if there is one.
4162
4163 =cut
4164
4165 sub breakable_line {
4166
4167     my ( $from, $to ) = @_;
4168
4169     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4170     my $i = $from;
4171
4172     # If there are at least 2 arguments, we're trying to search a range.
4173     if ( @_ >= 2 ) {
4174
4175         # $delta is positive for a forward search, negative for a backward one.
4176         my $delta = $from < $to ? +1 : -1;
4177
4178         # Keep us from running off the ends of the file.
4179         my $limit = $delta > 0 ? $#dbline : 1;
4180
4181         # Clever test. If you're a mathematician, it's obvious why this
4182         # test works. If not:
4183         # If $delta is positive (going forward), $limit will be $#dbline.
4184         #    If $to is less than $limit, ($limit - $to) will be positive, times
4185         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4186         #    as the stopping point.
4187         #
4188         #    If $to is greater than $limit, ($limit - $to) is negative,
4189         #    times $delta of 1 (positive), so the result is < 0 and we should
4190         #    use $limit ($#dbline) as the stopping point.
4191         #
4192         # If $delta is negative (going backward), $limit will be 1.
4193         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4194         #    (negative) so the result is > 0, and we use $to as the stopping
4195         #    point.
4196         #
4197         #    If $to is less than zero, ($limit - $to) will be positive,
4198         #    times $delta of -1 (negative), so the result is not > 0, and
4199         #    we use $limit (1) as the stopping point.
4200         #
4201         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4202         #    (negative), still giving zero; the result is not > 0, and
4203         #    we use $limit (1) as the stopping point.
4204         #
4205         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4206         #    (negative), giving a positive (>0) value, so we'll set $limit to
4207         #    $to.
4208
4209         $limit = $to if ( $limit - $to ) * $delta > 0;
4210
4211         # The real search loop.
4212         # $i starts at $from (the point we want to start searching from).
4213         # We move through @dbline in the appropriate direction (determined
4214         # by $delta: either -1 (back) or +1 (ahead).
4215         # We stay in as long as we haven't hit an executable line
4216         # ($dbline[$i] == 0 means not executable) and we haven't reached
4217         # the limit yet (test similar to the above).
4218         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4219
4220     } ## end if (@_ >= 2)
4221
4222     # If $i points to a line that is executable, return that.
4223     return $i unless $dbline[$i] == 0;
4224
4225     # Format the message and print it: no breakable lines in range.
4226     my ( $pl, $upto ) = ( '', '' );
4227     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4228
4229     # If there's a filename in filename_error, we'll see it.
4230     # If not, not.
4231     die "Line$pl $from$upto$filename_error not breakable\n";
4232 } ## end sub breakable_line
4233
4234 =head3 breakable_line_in_filename($file, $from, $to) (API)
4235
4236 Like C<breakable_line>, but look in another file.
4237
4238 =cut
4239
4240 sub breakable_line_in_filename {
4241
4242     # Capture the file name.
4243     my ($f) = shift;
4244
4245     # Swap the magic line array over there temporarily.
4246     local *dbline = $main::{ '_<' . $f };
4247
4248     # If there's an error, it's in this other file.
4249     local $filename_error = " of `$f'";
4250
4251     # Find the breakable line.
4252     breakable_line(@_);
4253
4254     # *dbline and $filename_error get restored when this block ends.
4255
4256 } ## end sub breakable_line_in_filename
4257
4258 =head3 break_on_line(lineno, [condition]) (API)
4259
4260 Adds a breakpoint with the specified condition (or 1 if no condition was
4261 specified) to the specified line. Dies if it can't.
4262
4263 =cut
4264
4265 sub break_on_line {
4266     my ( $i, $cond ) = @_;
4267
4268     # Always true if no condition supplied.
4269     $cond = 1 unless @_ >= 2;
4270
4271     my $inii  = $i;
4272     my $after = '';
4273     my $pl    = '';
4274
4275     # Woops, not a breakable line. $filename_error allows us to say
4276     # if it was in a different file.
4277     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4278
4279     # Mark this file as having breakpoints in it.
4280     $had_breakpoints{$filename} |= 1;
4281
4282     # If there is an action or condition here already ...
4283     if ( $dbline{$i} ) {
4284
4285         # ... swap this condition for the existing one.
4286         $dbline{$i} =~ s/^[^\0]*/$cond/;
4287     }
4288     else {
4289
4290         # Nothing here - just add the condition.
4291         $dbline{$i} = $cond;
4292     }
4293 } ## end sub break_on_line
4294
4295 =head3 cmd_b_line(line, [condition]) (command)
4296
4297 Wrapper for C<break_on_line>. Prints the failure message if it
4298 doesn't work.
4299
4300 =cut
4301
4302 sub cmd_b_line {
4303     eval { break_on_line(@_); 1 } or do {
4304         local $\ = '';
4305         print $OUT $@ and return;
4306     };
4307 } ## end sub cmd_b_line
4308
4309 =head3 break_on_filename_line(file, line, [condition]) (API)
4310
4311 Switches to the file specified and then calls C<break_on_line> to set
4312 the breakpoint.
4313
4314 =cut
4315
4316 sub break_on_filename_line {
4317     my ( $f, $i, $cond ) = @_;
4318
4319     # Always true if condition left off.
4320     $cond = 1 unless @_ >= 3;
4321
4322     # Switch the magical hash temporarily.
4323     local *dbline = $main::{ '_<' . $f };
4324
4325     # Localize the variables that break_on_line uses to make its message.
4326     local $filename_error = " of `$f'";
4327     local $filename       = $f;
4328
4329     # Add the breakpoint.
4330     break_on_line( $i, $cond );
4331 } ## end sub break_on_filename_line
4332
4333 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4334
4335 Switch to another file, search the range of lines specified for an
4336 executable one, and put a breakpoint on the first one you find.
4337
4338 =cut
4339
4340 sub break_on_filename_line_range {
4341     my ( $f, $from, $to, $cond ) = @_;
4342
4343     # Find a breakable line if there is one.
4344     my $i = breakable_line_in_filename( $f, $from, $to );
4345
4346     # Always true if missing.
4347     $cond = 1 unless @_ >= 3;
4348
4349     # Add the breakpoint.
4350     break_on_filename_line( $f, $i, $cond );
4351 } ## end sub break_on_filename_line_range
4352
4353 =head3 subroutine_filename_lines(subname, [condition]) (API)
4354
4355 Search for a subroutine within a given file. The condition is ignored.
4356 Uses C<find_sub> to locate the desired subroutine.
4357
4358 =cut
4359
4360 sub subroutine_filename_lines {
4361     my ( $subname, $cond ) = @_;
4362
4363     # Returned value from find_sub() is fullpathname:startline-endline.
4364     # The match creates the list (fullpathname, start, end). Falling off
4365     # the end of the subroutine returns this implicitly.
4366     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4367 } ## end sub subroutine_filename_lines
4368
4369 =head3 break_subroutine(subname) (API)
4370
4371 Places a break on the first line possible in the specified subroutine. Uses
4372 C<subroutine_filename_lines> to find the subroutine, and
4373 C<break_on_filename_line_range> to place the break.
4374
4375 =cut
4376
4377 sub break_subroutine {
4378     my $subname = shift;
4379
4380     # Get filename, start, and end.
4381     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4382       or die "Subroutine $subname not found.\n";
4383
4384     # Null condition changes to '1' (always true).
4385     $cond = 1 unless @_ >= 2;
4386
4387     # Put a break the first place possible in the range of lines
4388     # that make up this subroutine.
4389     break_on_filename_line_range( $file, $s, $e, @_ );
4390 } ## end sub break_subroutine
4391
4392 =head3 cmd_b_sub(subname, [condition]) (command)
4393
4394 We take the incoming subroutine name and fully-qualify it as best we can.
4395
4396 =over 4
4397
4398 =item 1. If it's already fully-qualified, leave it alone.
4399
4400 =item 2. Try putting it in the current package.
4401
4402 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4403
4404 =item 4. If it starts with '::', put it in 'main::'.
4405
4406 =back
4407
4408 After all this cleanup, we call C<break_subroutine> to try to set the
4409 breakpoint.
4410
4411 =cut
4412
4413 sub cmd_b_sub {
4414     my ( $subname, $cond ) = @_;
4415
4416     # Add always-true condition if we have none.
4417     $cond = 1 unless @_ >= 2;
4418
4419     # If the subname isn't a code reference, qualify it so that
4420     # break_subroutine() will work right.
4421     unless ( ref $subname eq 'CODE' ) {
4422
4423         # Not Perl4.
4424         $subname =~ s/\'/::/g;
4425         my $s = $subname;
4426
4427         # Put it in this package unless it's already qualified.
4428         $subname = "${'package'}::" . $subname
4429           unless $subname =~ /::/;
4430
4431         # Requalify it into CORE::GLOBAL if qualifying it into this
4432         # package resulted in its not being defined, but only do so
4433         # if it really is in CORE::GLOBAL.
4434         $subname = "CORE::GLOBAL::$s"
4435           if not defined &$subname
4436           and $s !~ /::/
4437           and defined &{"CORE::GLOBAL::$s"};
4438
4439         # Put it in package 'main' if it has a leading ::.
4440         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4441
4442     } ## end unless (ref $subname eq 'CODE')
4443
4444     # Try to set the breakpoint.
4445     eval { break_subroutine( $subname, $cond ); 1 } or do {
4446         local $\ = '';
4447         print $OUT $@ and return;
4448       }
4449 } ## end sub cmd_b_sub
4450
4451 =head3 C<cmd_B> - delete breakpoint(s) (command)
4452
4453 The command mostly parses the command line and tries to turn the argument
4454 into a line spec. If it can't, it uses the current line. It then calls
4455 C<delete_breakpoint> to actually do the work.
4456
4457 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4458 thereby deleting all the breakpoints.
4459
4460 =cut
4461
4462 sub cmd_B {
4463     my $cmd = shift;
4464
4465     # No line spec? Use dbline.
4466     # If there is one, use it if it's non-zero, or wipe it out if it is.
4467     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4468     my $dbline = shift;
4469
4470     # If the line was dot, make the line the current one.
4471     $line =~ s/^\./$dbline/;
4472
4473     # If it's * we're deleting all the breakpoints.
4474     if ( $line eq '*' ) {
4475         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4476     }
4477
4478     # If there is a line spec, delete the breakpoint on that line.
4479     elsif ( $line =~ /^(\S.*)/ ) {
4480         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4481             local $\ = '';
4482             print $OUT $@ and return;
4483         };
4484     } ## end elsif ($line =~ /^(\S.*)/)
4485
4486     # No line spec.
4487     else {
4488         print $OUT
4489           "Deleting a breakpoint requires a line number, or '*' for all\n"
4490           ;    # hint
4491     }
4492 } ## end sub cmd_B
4493
4494 =head3 delete_breakpoint([line]) (API)
4495
4496 This actually does the work of deleting either a single breakpoint, or all
4497 of them.
4498
4499 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4500 just drop out with a message saying so. If it is, we remove the condition
4501 part of the 'condition\0action' that says there's a breakpoint here. If,
4502 after we've done that, there's nothing left, we delete the corresponding
4503 line in C<%dbline> to signal that no action needs to be taken for this line.
4504
4505 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4506 which lists all currently-loaded files which have breakpoints. We then look
4507 at each line in each of these files, temporarily switching the C<%dbline>
4508 and C<@dbline> structures to point to the files in question, and do what
4509 we did in the single line case: delete the condition in C<@dbline>, and
4510 delete the key in C<%dbline> if nothing's left.
4511
4512 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4513 C<%break_on_load>, because these structures contain breakpoints for files
4514 and code that haven't been loaded yet. We can just kill these off because there
4515 are no magical debugger structures associated with them.
4516
4517 =cut
4518
4519 sub delete_breakpoint {
4520     my $i = shift;
4521
4522     # If we got a line, delete just that one.
4523     if ( defined($i) ) {
4524
4525         # Woops. This line wasn't breakable at all.
4526         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4527
4528         # Kill the condition, but leave any action.
4529         $dbline{$i} =~ s/^[^\0]*//;
4530
4531         # Remove the entry entirely if there's no action left.
4532         delete $dbline{$i} if $dbline{$i} eq '';
4533     }
4534
4535     # No line; delete them all.
4536     else {
4537         print $OUT "Deleting all breakpoints...\n";
4538
4539         # %had_breakpoints lists every file that had at least one
4540         # breakpoint in it.
4541         for my $file ( keys %had_breakpoints ) {
4542
4543             # Switch to the desired file temporarily.
4544             local *dbline = $main::{ '_<' . $file };
4545
4546             my $max = $#dbline;
4547             my $was;
4548
4549             # For all lines in this file ...
4550             for ( $i = 1 ; $i <= $max ; $i++ ) {
4551
4552                 # If there's a breakpoint or action on this line ...
4553                 if ( defined $dbline{$i} ) {
4554
4555                     # ... remove the breakpoint.
4556                     $dbline{$i} =~ s/^[^\0]+//;
4557                     if ( $dbline{$i} =~ s/^\0?$// ) {
4558
4559                         # Remove the entry altogether if no action is there.
4560                         delete $dbline{$i};
4561                     }
4562                 } ## end if (defined $dbline{$i...
4563             } ## end for ($i = 1 ; $i <= $max...
4564
4565             # If, after we turn off the "there were breakpoints in this file"
4566             # bit, the entry in %had_breakpoints for this file is zero,
4567             # we should remove this file from the hash.
4568             if ( not $had_breakpoints{$file} &= ~1 ) {
4569                 delete $had_breakpoints{$file};
4570             }
4571         } ## end for my $file (keys %had_breakpoints)
4572
4573         # Kill off all the other breakpoints that are waiting for files that
4574         # haven't been loaded yet.
4575         undef %postponed;
4576         undef %postponed_file;
4577         undef %break_on_load;
4578     } ## end else [ if (defined($i))
4579 } ## end sub delete_breakpoint
4580
4581 =head3 cmd_stop (command)
4582
4583 This is meant to be part of the new command API, but it isn't called or used
4584 anywhere else in the debugger. XXX It is probably meant for use in development
4585 of new commands.
4586
4587 =cut
4588
4589 sub cmd_stop {    # As on ^C, but not signal-safy.
4590     $signal = 1;
4591 }
4592
4593 =head3 C<cmd_e> - threads
4594
4595 Display the current thread id:
4596
4597         e
4598
4599 This could be how (when implemented) to send commands to this thread id (e cmd)
4600 or that thread id (e tid cmd).
4601
4602 =cut
4603
4604 sub cmd_e {
4605     my $cmd  = shift;
4606     my $line = shift;
4607         unless (exists($INC{'threads.pm'})) {
4608                 print "threads not loaded($ENV{PERL5DB_THREADED})
4609                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4610         } else {
4611                 my $tid = threads->self->tid;
4612                 print "thread id: $tid\n";
4613         }
4614 } ## end sub cmd_e
4615
4616 =head3 C<cmd_E> - list of thread ids
4617
4618 Display the list of available thread ids:
4619
4620         E
4621
4622 This could be used (when implemented) to send commands to all threads (E cmd).
4623
4624 =cut
4625
4626 sub cmd_E {
4627     my $cmd  = shift;
4628     my $line = shift;
4629         unless (exists($INC{'threads.pm'})) {
4630                 print "threads not loaded($ENV{PERL5DB_THREADED})
4631                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4632         } else {
4633                 my $tid = threads->self->tid;
4634                 print "thread ids: ".join(', ',
4635                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4636                 )."\n";
4637         }
4638 } ## end sub cmd_E
4639
4640 =head3 C<cmd_h> - help command (command)
4641
4642 Does the work of either
4643
4644 =over 4
4645
4646 =item * Showing all the debugger help
4647
4648 =item * Showing help for a specific command
4649
4650 =back
4651
4652 =cut
4653
4654 sub cmd_h {
4655     my $cmd = shift;
4656
4657     # If we have no operand, assume null.
4658     my $line = shift || '';
4659
4660     # 'h h'. Print the long-format help.
4661     if ( $line =~ /^h\s*/ ) {
4662         print_help($help);
4663     }
4664
4665     # 'h <something>'. Search for the command and print only its help.
4666     elsif ( $line =~ /^(\S.*)$/ ) {
4667
4668         # support long commands; otherwise bogus errors
4669         # happen when you ask for h on <CR> for example
4670         my $asked = $1;    # the command requested
4671                            # (for proper error message)
4672
4673         my $qasked = quotemeta($asked);    # for searching; we don't
4674                                            # want to use it as a pattern.
4675                                            # XXX: finds CR but not <CR>
4676
4677         # Search the help string for the command.
4678         if (
4679             $help =~ /^                    # Start of a line
4680                       <?                   # Optional '<'
4681                       (?:[IB]<)            # Optional markup
4682                       $qasked              # The requested command
4683                      /mx
4684           )
4685         {
4686
4687             # It's there; pull it out and print it.
4688             while (
4689                 $help =~ /^
4690                               (<?            # Optional '<'
4691                                  (?:[IB]<)   # Optional markup
4692                                  $qasked     # The command
4693                                  ([\s\S]*?)  # Description line(s)
4694                               \n)            # End of last description line
4695                               (?!\s)         # Next line not starting with
4696                                              # whitespace
4697                              /mgx
4698               )
4699             {
4700                 print_help($1);
4701             }
4702         }
4703
4704         # Not found; not a debugger command.
4705         else {
4706             print_help("B<$asked> is not a debugger command.\n");
4707         }
4708     } ## end elsif ($line =~ /^(\S.*)$/)
4709
4710     # 'h' - print the summary help.
4711     else {
4712         print_help($summary);
4713     }
4714 } ## end sub cmd_h
4715
4716 =head3 C<cmd_i> - inheritance display
4717
4718 Display the (nested) parentage of the module or object given.
4719
4720 =cut
4721
4722 sub cmd_i {
4723     my $cmd  = shift;
4724     my $line = shift;
4725     eval { require Class::ISA };
4726     if ($@) {
4727         &warn( $@ =~ /locate/
4728             ? "Class::ISA module not found - please install\n"
4729             : $@ );
4730     }
4731     else {
4732       ISA:
4733         foreach my $isa ( split( /\s+/, $line ) ) {
4734             $evalarg = $isa;
4735             ($isa) = &eval;
4736             no strict 'refs';
4737             print join(
4738                 ', ',
4739                 map {    # snaffled unceremoniously from Class::ISA
4740                     "$_"
4741                       . (
4742                         defined( ${"$_\::VERSION"} )
4743                         ? ' ' . ${"$_\::VERSION"}
4744                         : undef )
4745                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4746             );
4747             print "\n";
4748         }
4749     }
4750 } ## end sub cmd_i
4751
4752 =head3 C<cmd_l> - list lines (command)
4753
4754 Most of the command is taken up with transforming all the different line
4755 specification syntaxes into 'start-stop'. After that is done, the command
4756 runs a loop over C<@dbline> for the specified range of lines. It handles
4757 the printing of each line and any markers (C<==E<gt>> for current line,
4758 C<b> for break on this line, C<a> for action on this line, C<:> for this
4759 line breakable).
4760
4761 We save the last line listed in the C<$start> global for further listing
4762 later.
4763
4764 =cut
4765
4766 sub cmd_l {
4767     my $current_line = $line;
4768     my $cmd  = shift;
4769     my $line = shift;
4770
4771     # If this is '-something', delete any spaces after the dash.
4772     $line =~ s/^-\s*$/-/;
4773
4774     # If the line is '$something', assume this is a scalar containing a
4775     # line number.
4776     if ( $line =~ /^(\$.*)/s ) {
4777
4778         # Set up for DB::eval() - evaluate in *user* context.
4779         $evalarg = $1;
4780         # $evalarg = $2;
4781         my ($s) = &eval;
4782
4783         # Ooops. Bad scalar.
4784         print( $OUT "Error: $@\n" ), next CMD if $@;
4785
4786         # Good scalar. If it's a reference, find what it points to.
4787         $s = CvGV_name($s);
4788         print( $OUT "Interpreted as: $1 $s\n" );
4789         $line = "$1 $s";
4790
4791         # Call self recursively to really do the command.
4792         &cmd_l( 'l', $s );
4793     } ## end if ($line =~ /^(\$.*)/s)
4794
4795     # l name. Try to find a sub by that name.
4796     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4797         my $s = $subname = $1;
4798
4799         # De-Perl4.
4800         $subname =~ s/\'/::/;
4801
4802         # Put it in this package unless it starts with ::.
4803         $subname = $package . "::" . $subname unless $subname =~ /::/;
4804
4805         # Put it in CORE::GLOBAL if t doesn't start with :: and
4806         # it doesn't live in this package and it lives in CORE::GLOBAL.
4807         $subname = "CORE::GLOBAL::$s"
4808           if not defined &$subname
4809           and $s !~ /::/
4810           and defined &{"CORE::GLOBAL::$s"};
4811
4812         # Put leading '::' names into 'main::'.
4813         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4814
4815         # Get name:start-stop from find_sub, and break this up at
4816         # colons.
4817         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4818
4819         # Pull off start-stop.
4820         $subrange = pop @pieces;
4821
4822         # If the name contained colons, the split broke it up.
4823         # Put it back together.
4824         $file = join( ':', @pieces );
4825
4826         # If we're not in that file, switch over to it.
4827         if ( $file ne $filename ) {
4828             print $OUT "Switching to file '$file'.\n"
4829               unless $slave_editor;
4830
4831             # Switch debugger's magic structures.
4832             *dbline   = $main::{ '_<' . $file };
4833             $max      = $#dbline;
4834             $filename = $file;
4835         } ## end if ($file ne $filename)
4836
4837         # Subrange is 'start-stop'. If this is less than a window full,
4838         # swap it to 'start+', which will list a window from the start point.
4839         if ($subrange) {
4840             if ( eval($subrange) < -$window ) {
4841                 $subrange =~ s/-.*/+/;
4842             }
4843
4844             # Call self recursively to list the range.
4845             $line = $subrange;
4846             &cmd_l( 'l', $subrange );
4847         } ## end if ($subrange)
4848
4849         # Couldn't find it.
4850         else {
4851             print $OUT "Subroutine $subname not found.\n";
4852         }
4853     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4854
4855     # Bare 'l' command.
4856     elsif ( $line =~ /^\s*$/ ) {
4857
4858         # Compute new range to list.
4859         $incr = $window - 1;
4860         $line = $start . '-' . ( $start + $incr );
4861
4862         # Recurse to do it.
4863         &cmd_l( 'l', $line );
4864     }
4865
4866     # l [start]+number_of_lines
4867     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4868
4869         # Don't reset start for 'l +nnn'.
4870         $start = $1 if $1;
4871
4872         # Increment for list. Use window size if not specified.
4873         # (Allows 'l +' to work.)
4874         $incr = $2;
4875         $incr = $window - 1 unless $incr;
4876
4877         # Create a line range we'll understand, and recurse to do it.
4878         $line = $start . '-' . ( $start + $incr );
4879         &cmd_l( 'l', $line );
4880     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4881
4882     # l start-stop or l start,stop
4883     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4884
4885         # Determine end point; use end of file if not specified.
4886         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4887
4888         # Go on to the end, and then stop.
4889         $end = $max if $end > $max;
4890
4891         # Determine start line.
4892         $i    = $2;
4893         $i    = $line if $i eq '.';
4894         $i    = 1 if $i < 1;
4895         $incr = $end - $i;
4896
4897         # If we're running under a slave editor, force it to show the lines.
4898         if ($slave_editor) {
4899             print $OUT "\032\032$filename:$i:0\n";
4900             $i = $end;
4901         }
4902
4903         # We're doing it ourselves. We want to show the line and special
4904         # markers for:
4905         # - the current line in execution
4906         # - whether a line is breakable or not
4907         # - whether a line has a break or not
4908         # - whether a line has an action or not
4909         else {
4910             for ( ; $i <= $end ; $i++ ) {
4911
4912                 # Check for breakpoints and actions.
4913                 my ( $stop, $action );
4914                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
4915                   if $dbline{$i};
4916
4917                 # ==> if this is the current line in execution,
4918                 # : if it's breakable.
4919                 $arrow =
4920                   ( $i == $current_line and $filename eq $filename_ini )
4921                   ? '==>'
4922                   : ( $dbline[$i] + 0 ? ':' : ' ' );
4923
4924                 # Add break and action indicators.
4925                 $arrow .= 'b' if $stop;
4926                 $arrow .= 'a' if $action;
4927
4928                 # Print the line.
4929                 print $OUT "$i$arrow\t", $dbline[$i];
4930
4931                 # Move on to the next line. Drop out on an interrupt.
4932                 $i++, last if $signal;
4933             } ## end for (; $i <= $end ; $i++)
4934
4935             # Line the prompt up; print a newline if the last line listed
4936             # didn't have a newline.
4937             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
4938         } ## end else [ if ($slave_editor)
4939
4940         # Save the point we last listed to in case another relative 'l'
4941         # command is desired. Don't let it run off the end.
4942         $start = $i;
4943         $start = $max if $start > $max;
4944     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
4945 } ## end sub cmd_l
4946
4947 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
4948
4949 To list breakpoints, the command has to look determine where all of them are
4950 first. It starts a C<%had_breakpoints>, which tells us what all files have
4951 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
4952 magic source and breakpoint data structures) to the file, and then look
4953 through C<%dbline> for lines with breakpoints and/or actions, listing them
4954 out. We look through C<%postponed> not-yet-compiled subroutines that have
4955 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
4956 that have breakpoints.
4957
4958 Watchpoints are simpler: we just list the entries in C<@to_watch>.
4959
4960 =cut
4961
4962 sub cmd_L {
4963     my $cmd = shift;
4964
4965     # If no argument, list everything. Pre-5.8.0 version always lists
4966     # everything
4967     my $arg = shift || 'abw';
4968     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
4969
4970     # See what is wanted.
4971     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
4972     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
4973     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
4974
4975     # Breaks and actions are found together, so we look in the same place
4976     # for both.
4977     if ( $break_wanted or $action_wanted ) {
4978
4979         # Look in all the files with breakpoints...
4980         for my $file ( keys %had_breakpoints ) {
4981
4982             # Temporary switch to this file.
4983             local *dbline = $main::{ '_<' . $file };
4984
4985             # Set up to look through the whole file.
4986             my $max = $#dbline;
4987             my $was;    # Flag: did we print something
4988                         # in this file?
4989
4990             # For each line in the file ...
4991             for ( $i = 1 ; $i <= $max ; $i++ ) {
4992
4993                 # We've got something on this line.
4994                 if ( defined $dbline{$i} ) {
4995
4996                     # Print the header if we haven't.
4997                     print $OUT "$file:\n" unless $was++;
4998
4999                     # Print the line.
5000                     print $OUT " $i:\t", $dbline[$i];
5001
5002                     # Pull out the condition and the action.
5003                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5004
5005                     # Print the break if there is one and it's wanted.
5006                     print $OUT "   break if (", $stop, ")\n"
5007                       if $stop
5008                       and $break_wanted;
5009
5010                     # Print the action if there is one and it's wanted.
5011                     print $OUT "   action:  ", $action, "\n"
5012                       if $action
5013                       and $action_wanted;
5014
5015                     # Quit if the user hit interrupt.
5016                     last if $signal;
5017                 } ## end if (defined $dbline{$i...
5018             } ## end for ($i = 1 ; $i <= $max...
5019         } ## end for my $file (keys %had_breakpoints)
5020     } ## end if ($break_wanted or $action_wanted)
5021
5022     # Look for breaks in not-yet-compiled subs:
5023     if ( %postponed and $break_wanted ) {
5024         print $OUT "Postponed breakpoints in subroutines:\n";
5025         my $subname;
5026         for $subname ( keys %postponed ) {
5027             print $OUT " $subname\t$postponed{$subname}\n";
5028             last if $signal;
5029         }
5030     } ## end if (%postponed and $break_wanted)
5031
5032     # Find files that have not-yet-loaded breaks:
5033     my @have = map {    # Combined keys
5034         keys %{ $postponed_file{$_} }
5035     } keys %postponed_file;
5036
5037     # If there are any, list them.
5038     if ( @have and ( $break_wanted or $action_wanted ) ) {
5039         print $OUT "Postponed breakpoints in files:\n";
5040         my ( $file, $line );
5041
5042         for $file ( keys %postponed_file ) {
5043             my $db = $postponed_file{$file};
5044             print $OUT " $file:\n";
5045             for $line ( sort { $a <=> $b } keys %$db ) {
5046                 print $OUT "  $line:\n";
5047                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5048                 print $OUT "    break if (", $stop, ")\n"
5049                   if $stop
5050                   and $break_wanted;
5051                 print $OUT "    action:  ", $action, "\n"
5052                   if $action
5053                   and $action_wanted;
5054                 last if $signal;
5055             } ## end for $line (sort { $a <=>...
5056             last if $signal;
5057         } ## end for $file (keys %postponed_file)
5058     } ## end if (@have and ($break_wanted...
5059     if ( %break_on_load and $break_wanted ) {
5060         print $OUT "Breakpoints on load:\n";
5061         my $file;
5062         for $file ( keys %break_on_load ) {
5063             print $OUT " $file\n";
5064             last if $signal;
5065         }
5066     } ## end if (%break_on_load and...
5067     if ($watch_wanted) {
5068         if ( $trace & 2 ) {
5069             print $OUT "Watch-expressions:\n" if @to_watch;
5070             for my $expr (@to_watch) {
5071                 print $OUT " $expr\n";
5072                 last if $signal;
5073             }
5074         } ## end if ($trace & 2)
5075     } ## end if ($watch_wanted)
5076 } ## end sub cmd_L
5077
5078 =head3 C<cmd_M> - list modules (command)
5079
5080 Just call C<list_modules>.
5081
5082 =cut
5083
5084 sub cmd_M {
5085     &list_modules();
5086 }
5087
5088 =head3 C<cmd_o> - options (command)
5089
5090 If this is just C<o> by itself, we list the current settings via
5091 C<dump_option>. If there's a nonblank value following it, we pass that on to
5092 C<parse_options> for processing.
5093
5094 =cut
5095
5096 sub cmd_o {
5097     my $cmd = shift;
5098     my $opt = shift || '';    # opt[=val]
5099
5100     # Nonblank. Try to parse and process.
5101     if ( $opt =~ /^(\S.*)/ ) {
5102         &parse_options($1);
5103     }
5104
5105     # Blank. List the current option settings.
5106     else {
5107         for (@options) {
5108             &dump_option($_);
5109         }
5110     }
5111 } ## end sub cmd_o
5112
5113 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5114
5115 Advises the user that the O command has been renamed.
5116
5117 =cut
5118
5119 sub cmd_O {
5120     print $OUT "The old O command is now the o command.\n";             # hint
5121     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5122     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5123 }
5124
5125 =head3 C<cmd_v> - view window (command)
5126
5127 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5128 move back a few lines to list the selected line in context. Uses C<cmd_l>
5129 to do the actual listing after figuring out the range of line to request.
5130
5131 =cut
5132
5133 sub cmd_v {
5134     my $cmd  = shift;
5135     my $line = shift;
5136
5137     # Extract the line to list around. (Astute readers will have noted that
5138     # this pattern will match whether or not a numeric line is specified,
5139     # which means that we'll always enter this loop (though a non-numeric
5140     # argument results in no action at all)).
5141     if ( $line =~ /^(\d*)$/ ) {
5142
5143         # Total number of lines to list (a windowful).
5144         $incr = $window - 1;
5145
5146         # Set the start to the argument given (if there was one).
5147         $start = $1 if $1;
5148
5149         # Back up by the context amount.
5150         $start -= $preview;
5151
5152         # Put together a linespec that cmd_l will like.
5153         $line = $start . '-' . ( $start + $incr );
5154
5155         # List the lines.
5156         &cmd_l( 'l', $line );
5157     } ## end if ($line =~ /^(\d*)$/)
5158 } ## end sub cmd_v
5159
5160 =head3 C<cmd_w> - add a watch expression (command)
5161
5162 The 5.8 version of this command adds a watch expression if one is specified;
5163 it does nothing if entered with no operands.
5164
5165 We extract the expression, save it, evaluate it in the user's context, and
5166 save the value. We'll re-evaluate it each time the debugger passes a line,
5167 and will stop (see the code at the top of the command loop) if the value
5168 of any of the expressions changes.
5169
5170 =cut
5171
5172 sub cmd_w {
5173     my $cmd = shift;
5174
5175     # Null expression if no arguments.
5176     my $expr = shift || '';
5177
5178     # If expression is not null ...
5179     if ( $expr =~ /^(\S.*)/ ) {
5180
5181         # ... save it.
5182         push @to_watch, $expr;
5183
5184         # Parameterize DB::eval and call it to get the expression's value
5185         # in the user's context. This version can handle expressions which
5186         # return a list value.
5187         $evalarg = $expr;
5188         my ($val) = join( ' ', &eval );
5189         $val = ( defined $val ) ? "'$val'" : 'undef';
5190
5191         # Save the current value of the expression.
5192         push @old_watch, $val;
5193
5194         # We are now watching expressions.
5195         $trace |= 2;
5196     } ## end if ($expr =~ /^(\S.*)/)
5197
5198     # You have to give one to get one.
5199     else {
5200         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5201     }
5202 } ## end sub cmd_w
5203
5204 =head3 C<cmd_W> - delete watch expressions (command)
5205
5206 This command accepts either a watch expression to be removed from the list
5207 of watch expressions, or C<*> to delete them all.
5208
5209 If C<*> is specified, we simply empty the watch expression list and the
5210 watch expression value list. We also turn off the bit that says we've got
5211 watch expressions.
5212
5213 If an expression (or partial expression) is specified, we pattern-match
5214 through the expressions and remove the ones that match. We also discard
5215 the corresponding values. If no watch expressions are left, we turn off
5216 the 'watching expressions' bit.
5217
5218 =cut
5219
5220 sub cmd_W {
5221     my $cmd  = shift;
5222     my $expr = shift || '';
5223
5224     # Delete them all.
5225     if ( $expr eq '*' ) {
5226
5227         # Not watching now.
5228         $trace &= ~2;
5229
5230         print $OUT "Deleting all watch expressions ...\n";
5231
5232         # And all gone.
5233         @to_watch = @old_watch = ();
5234     }
5235
5236     # Delete one of them.
5237     elsif ( $expr =~ /^(\S.*)/ ) {
5238
5239         # Where we are in the list.
5240         my $i_cnt = 0;
5241
5242         # For each expression ...
5243         foreach (@to_watch) {
5244             my $val = $to_watch[$i_cnt];
5245
5246             # Does this one match the command argument?
5247             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5248                                       # Yes. Turn it off, and its value too.
5249                 splice( @to_watch,  $i_cnt, 1 );
5250                 splice( @old_watch, $i_cnt, 1 );
5251             }
5252             $i_cnt++;
5253         } ## end foreach (@to_watch)
5254
5255         # We don't bother to turn watching off because
5256         #  a) we don't want to stop calling watchfunction() it it exists
5257         #  b) foreach over a null list doesn't do anything anyway
5258
5259     } ## end elsif ($expr =~ /^(\S.*)/)
5260
5261     # No command arguments entered.
5262     else {
5263         print $OUT
5264           "Deleting a watch-expression requires an expression, or '*' for all\n"
5265           ;    # hint
5266     }
5267 } ## end sub cmd_W
5268
5269 ### END of the API section
5270
5271 =head1 SUPPORT ROUTINES
5272
5273 These are general support routines that are used in a number of places
5274 throughout the debugger.
5275
5276 =item cmd_P
5277
5278 Something to do with assertions
5279
5280 =cut
5281
5282 sub cmd_P {
5283     unless ($ini_assertion) {
5284         print $OUT "Assertions not supported in this Perl interpreter\n";
5285     } else {
5286         if ( $cmd =~ /^.\b\s*([+-]?)\s*(~?)\s*(\w+(\s*\|\s*\w+)*)\s*$/ ) {
5287             my ( $how, $neg, $flags ) = ( $1, $2, $3 );
5288             my $acu = parse_DollarCaretP_flags($flags);
5289             if ( defined $acu ) {
5290                 $acu = ~$acu if $neg;
5291                 if ( $how eq '+' ) { $^P |= $acu }
5292                 elsif ( $how eq '-' ) { $^P &= ~$acu }
5293                 else { $^P = $acu }
5294             }
5295
5296             # else { print $OUT "undefined acu\n" }
5297         }
5298         my $expanded = expand_DollarCaretP_flags($^P);
5299         print $OUT "Internal Perl debugger flags:\n\$^P=$expanded\n";
5300         $expanded;
5301     }
5302 }
5303
5304 =head2 save
5305
5306 save() saves the user's versions of globals that would mess us up in C<@saved>,
5307 and installs the versions we like better.
5308
5309 =cut
5310
5311 sub save {
5312
5313     # Save eval failure, command failure, extended OS error, output field
5314     # separator, input record separator, output record separator and
5315     # the warning setting.
5316     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5317
5318     $,  = "";      # output field separator is null string
5319     $/  = "\n";    # input record separator is newline
5320     $\  = "";      # output record separator is null string
5321     $^W = 0;       # warnings are off
5322 } ## end sub save
5323
5324 =head2 C<print_lineinfo> - show where we are now
5325
5326 print_lineinfo prints whatever it is that it is handed; it prints it to the
5327 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5328 us to feed line information to a slave editor without messing up the
5329 debugger output.
5330
5331 =cut
5332
5333 sub print_lineinfo {
5334
5335     # Make the terminal sensible if we're not the primary debugger.
5336     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5337     local $\ = '';
5338     local $, = '';
5339     print $LINEINFO @_;
5340 } ## end sub print_lineinfo
5341
5342 =head2 C<postponed_sub>
5343
5344 Handles setting postponed breakpoints in subroutines once they're compiled.
5345 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5346 range for the subroutine, then mark the file as having a breakpoint,
5347 temporarily switch the C<*dbline> glob over to the source file, and then
5348 search the given range of lines to find a breakable line. If we find one,
5349 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5350
5351 =cut
5352
5353 # The following takes its argument via $evalarg to preserve current @_
5354
5355 sub postponed_sub {
5356
5357     # Get the subroutine name.
5358     my $subname = shift;
5359
5360     # If this is a 'break +<n> if <condition>' ...
5361     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5362
5363         # If there's no offset, use '+0'.
5364         my $offset = $1 || 0;
5365
5366         # find_sub's value is 'fullpath-filename:start-stop'. It's
5367         # possible that the filename might have colons in it too.
5368         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5369         if ($i) {
5370
5371             # We got the start line. Add the offset '+<n>' from
5372             # $postponed{subname}.
5373             $i += $offset;
5374
5375             # Switch to the file this sub is in, temporarily.
5376             local *dbline = $main::{ '_<' . $file };
5377
5378             # No warnings, please.
5379             local $^W = 0;    # != 0 is magical below
5380
5381             # This file's got a breakpoint in it.
5382             $had_breakpoints{$file} |= 1;
5383
5384             # Last line in file.
5385             my $max = $#dbline;
5386
5387             # Search forward until we hit a breakable line or get to
5388             # the end of the file.
5389             ++$i until $dbline[$i] != 0 or $i >= $max;
5390
5391             # Copy the breakpoint in and delete it from %postponed.
5392             $dbline{$i} = delete $postponed{$subname};
5393         } ## end if ($i)
5394
5395         # find_sub didn't find the sub.
5396         else {
5397             local $\ = '';
5398             print $OUT "Subroutine $subname not found.\n";
5399         }
5400         return;
5401     } ## end if ($postponed{$subname...
5402     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5403
5404     #print $OUT "In postponed_sub for `$subname'.\n";
5405 } ## end sub postponed_sub
5406
5407 =head2 C<postponed>
5408
5409 Called after each required file is compiled, but before it is executed;
5410 also called if the name of a just-compiled subroutine is a key of
5411 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5412 etc.) into the just-compiled code.
5413
5414 If this is a C<require>'d file, the incoming parameter is the glob
5415 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5416
5417 If it's a subroutine, the incoming parameter is the subroutine name.
5418
5419 =cut
5420
5421 sub postponed {
5422
5423     # If there's a break, process it.
5424     if ($ImmediateStop) {
5425
5426         # Right, we've stopped. Turn it off.
5427         $ImmediateStop = 0;
5428
5429         # Enter the command loop when DB::DB gets called.
5430         $signal = 1;
5431     }
5432
5433     # If this is a subroutine, let postponed_sub() deal with it.
5434     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5435
5436     # Not a subroutine. Deal with the file.
5437     local *dbline = shift;
5438     my $filename = $dbline;
5439     $filename =~ s/^_<//;
5440     local $\ = '';
5441     $signal = 1, print $OUT "'$filename' loaded...\n"
5442       if $break_on_load{$filename};
5443     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5444
5445     # Do we have any breakpoints to put in this file?
5446     return unless $postponed_file{$filename};
5447
5448     # Yes. Mark this file as having breakpoints.
5449     $had_breakpoints{$filename} |= 1;
5450
5451     # "Cannot be done: unsufficient magic" - we can't just put the
5452     # breakpoints saved in %postponed_file into %dbline by assigning
5453     # the whole hash; we have to do it one item at a time for the
5454     # breakpoints to be set properly.
5455     #%dbline = %{$postponed_file{$filename}};
5456
5457     # Set the breakpoints, one at a time.
5458     my $key;
5459
5460     for $key ( keys %{ $postponed_file{$filename} } ) {
5461
5462         # Stash the saved breakpoint into the current file's magic line array.
5463         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5464     }
5465
5466     # This file's been compiled; discard the stored breakpoints.
5467     delete $postponed_file{$filename};
5468
5469 } ## end sub postponed
5470
5471 =head2 C<dumpit>
5472
5473 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5474
5475 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5476 a reference to a variable (the thing to be dumped) as its input.
5477
5478 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5479 the currently-selected filehandle, thank you very much). The current
5480 values of the package globals C<$single> and C<$trace> are backed up in
5481 lexicals, and they are turned off (this keeps the debugger from trying
5482 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5483 preserve its current value and it is set to zero to prevent entry/exit
5484 messages from printing, and C<$doret> is localized as well and set to -2 to
5485 prevent return values from being shown.
5486
5487 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5488 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5489 installed version in @INC, yours will be used instead. Possible security
5490 problem?).
5491
5492 It then checks to see if the subroutine C<main::dumpValue> is now defined
5493 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5494 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5495 is called, and picks up the variable to be dumped from the parameter list.
5496
5497 It checks the package global C<%options> to see if there's a C<dumpDepth>
5498 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5499 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5500 structure: -1 means dump everything.
5501
5502 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5503 warning.
5504
5505 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5506 and we then return to the caller.
5507
5508 =cut
5509
5510 sub dumpit {
5511
5512     # Save the current output filehandle and switch to the one
5513     # passed in as the first parameter.
5514     local ($savout) = select(shift);
5515
5516     # Save current settings of $single and $trace, and then turn them off.
5517     my $osingle = $single;
5518     my $otrace  = $trace;
5519     $single = $trace = 0;
5520
5521     # XXX Okay, what do $frame and $doret do, again?
5522     local $frame = 0;
5523     local $doret = -2;
5524
5525     # Load dumpvar.pl unless we've already got the sub we need from it.
5526     unless ( defined &main::dumpValue ) {
5527         do 'dumpvar.pl';
5528     }
5529
5530     # If the load succeeded (or we already had dumpvalue()), go ahead
5531     # and dump things.
5532     if ( defined &main::dumpValue ) {
5533         local $\ = '';
5534         local $, = '';
5535         local $" = ' ';
5536         my $v = shift;
5537         my $maxdepth = shift || $option{dumpDepth};
5538         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5539         &main::dumpValue( $v, $maxdepth );
5540     } ## end if (defined &main::dumpValue)
5541
5542     # Oops, couldn't load dumpvar.pl.
5543     else {
5544         local $\ = '';
5545         print $OUT "dumpvar.pl not available.\n";
5546     }
5547
5548     # Reset $single and $trace to their old values.
5549     $single = $osingle;
5550     $trace  = $otrace;
5551
5552     # Restore the old filehandle.
5553     select($savout);
5554 } ## end sub dumpit
5555
5556 =head2 C<print_trace>
5557
5558 C<print_trace>'s job is to print a stack trace. It does this via the
5559 C<dump_trace> routine, which actually does all the ferreting-out of the
5560 stack trace data. C<print_trace> takes care of formatting it nicely and
5561 printing it to the proper filehandle.
5562
5563 Parameters:
5564
5565 =over 4
5566
5567 =item * The filehandle to print to.
5568
5569 =item * How many frames to skip before starting trace.
5570
5571 =item * How many frames to print.
5572
5573 =item * A flag: if true, print a "short" trace without filenames, line numbers, or arguments
5574
5575 =back
5576
5577 The original comment below seems to be noting that the traceback may not be
5578 correct if this routine is called in a tied method.
5579
5580 =cut
5581
5582 # Tied method do not create a context, so may get wrong message:
5583
5584 sub print_trace {
5585     local $\ = '';
5586     my $fh = shift;
5587
5588     # If this is going to a slave editor, but we're not the primary
5589     # debugger, reset it first.
5590     resetterm(1)
5591       if $fh        eq $LINEINFO    # slave editor
5592       and $LINEINFO eq $OUT         # normal output
5593       and $term_pid != $$;          # not the primary
5594
5595     # Collect the actual trace information to be formatted.
5596     # This is an array of hashes of subroutine call info.
5597     my @sub = dump_trace( $_[0] + 1, $_[1] );
5598
5599     # Grab the "short report" flag from @_.
5600     my $short = $_[2];              # Print short report, next one for sub name
5601
5602     # Run through the traceback info, format it, and print it.
5603     my $s;
5604     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5605
5606         # Drop out if the user has lost interest and hit control-C.
5607         last if $signal;
5608
5609         # Set the separator so arrys print nice.
5610         local $" = ', ';
5611
5612         # Grab and stringify the arguments if they are there.
5613         my $args =
5614           defined $sub[$i]{args}
5615           ? "(@{ $sub[$i]{args} })"
5616           : '';
5617
5618         # Shorten them up if $maxtrace says they're too long.
5619         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5620           if length $args > $maxtrace;
5621
5622         # Get the file name.
5623         my $file = $sub[$i]{file};
5624
5625         # Put in a filename header if short is off.
5626         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5627
5628         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5629         $s = $sub[$i]{sub};
5630         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5631
5632         # Short report uses trimmed file and sub names.
5633         if ($short) {
5634             my $sub = @_ >= 4 ? $_[3] : $s;
5635             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5636         } ## end if ($short)
5637
5638         # Non-short report includes full names.
5639         else {
5640             print $fh "$sub[$i]{context} = $s$args"
5641               . " called from $file"
5642               . " line $sub[$i]{line}\n";
5643         }
5644     } ## end for ($i = 0 ; $i <= $#sub...
5645 } ## end sub print_trace
5646
5647 =head2 dump_trace(skip[,count])
5648
5649 Actually collect the traceback information available via C<caller()>. It does
5650 some filtering and cleanup of the data, but mostly it just collects it to
5651 make C<print_trace()>'s job easier.
5652
5653 C<skip> defines the number of stack frames to be skipped, working backwards
5654 from the most current. C<count> determines the total number of frames to
5655 be returned; all of them (well, the first 10^9) are returned if C<count>
5656 is omitted.
5657
5658 This routine returns a list of hashes, from most-recent to least-recent
5659 stack frame. Each has the following keys and values:
5660
5661 =over 4
5662
5663 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5664
5665 =item * C<sub> - subroutine name, or C<eval> information
5666
5667 =item * C<args> - undef, or a reference to an array of arguments
5668
5669 =item * C<file> - the file in which this item was defined (if any)
5670
5671 =item * C<line> - the line on which it was defined
5672
5673 =back
5674
5675 =cut
5676
5677 sub dump_trace {
5678
5679     # How many levels to skip.
5680     my $skip = shift;
5681
5682     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5683     # it's unlikely that we'll have more than a billion stack frames. If you
5684     # do, you've got an awfully big machine...)
5685     my $count = shift || 1e9;
5686
5687     # We increment skip because caller(1) is the first level *back* from
5688     # the current one.  Add $skip to the count of frames so we have a
5689     # simple stop criterion, counting from $skip to $count+$skip.
5690     $skip++;
5691     $count += $skip;
5692
5693     # These variables are used to capture output from caller();
5694     my ( $p, $file, $line, $sub, $h, $context );
5695
5696     my ( $e, $r, @a, @sub, $args );
5697
5698     # XXX Okay... why'd we do that?
5699     my $nothard = not $frame & 8;
5700     local $frame = 0;
5701
5702     # Do not want to trace this.
5703     my $otrace = $trace;
5704     $trace = 0;
5705
5706     # Start out at the skip count.
5707     # If we haven't reached the number of frames requested, and caller() is
5708     # still returning something, stay in the loop. (If we pass the requested
5709     # number of stack frames, or we run out - caller() returns nothing - we
5710     # quit.
5711     # Up the stack frame index to go back one more level each time.
5712     for (
5713         $i = $skip ;
5714         $i < $count
5715         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5716         $i++
5717       )
5718     {
5719
5720         # Go through the arguments and save them for later.
5721         @a = ();
5722         for $arg (@args) {
5723             my $type;
5724             if ( not defined $arg ) {    # undefined parameter
5725                 push @a, "undef";
5726             }
5727
5728             elsif ( $nothard and tied $arg ) {    # tied parameter
5729                 push @a, "tied";
5730             }
5731             elsif ( $nothard and $type = ref $arg ) {    # reference
5732                 push @a, "ref($type)";
5733             }
5734             else {                                       # can be stringified
5735                 local $_ =
5736                   "$arg";    # Safe to stringify now - should not call f().
5737
5738                 # Backslash any single-quotes or backslashes.
5739                 s/([\'\\])/\\$1/g;
5740
5741                 # Single-quote it unless it's a number or a colon-separated
5742                 # name.
5743                 s/(.*)/'$1'/s
5744                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5745
5746                 # Turn high-bit characters into meta-whatever.
5747                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5748
5749                 # Turn control characters into ^-whatever.
5750                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5751
5752                 push( @a, $_ );
5753             } ## end else [ if (not defined $arg)
5754         } ## end for $arg (@args)
5755
5756         # If context is true, this is array (@)context.
5757         # If context is false, this is scalar ($) context.
5758         # If neither, context isn't defined. (This is apparently a 'can't
5759         # happen' trap.)
5760         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5761
5762         # if the sub has args ($h true), make an anonymous array of the
5763         # dumped args.
5764         $args = $h ? [@a] : undef;
5765
5766         # remove trailing newline-whitespace-semicolon-end of line sequence
5767         # from the eval text, if any.
5768         $e =~ s/\n\s*\;\s*\Z// if $e;
5769
5770         # Escape backslashed single-quotes again if necessary.
5771         $e =~ s/([\\\'])/\\$1/g if $e;
5772
5773         # if the require flag is true, the eval text is from a require.
5774         if ($r) {
5775             $sub = "require '$e'";
5776         }
5777
5778         # if it's false, the eval text is really from an eval.
5779         elsif ( defined $r ) {
5780             $sub = "eval '$e'";
5781         }
5782
5783         # If the sub is '(eval)', this is a block eval, meaning we don't
5784         # know what the eval'ed text actually was.
5785         elsif ( $sub eq '(eval)' ) {
5786             $sub = "eval {...}";
5787         }
5788
5789         # Stick the collected information into @sub as an anonymous hash.
5790         push(
5791             @sub,
5792             {
5793                 context => $context,
5794                 sub     => $sub,
5795                 args    => $args,
5796                 file    => $file,
5797                 line    => $line
5798             }
5799         );
5800
5801         # Stop processing frames if the user hit control-C.
5802         last if $signal;
5803     } ## end for ($i = $skip ; $i < ...
5804
5805     # Restore the trace value again.
5806     $trace = $otrace;
5807     @sub;
5808 } ## end sub dump_trace
5809
5810 =head2 C<action()>
5811
5812 C<action()> takes input provided as the argument to an add-action command,
5813 either pre- or post-, and makes sure it's a complete command. It doesn't do
5814 any fancy parsing; it just keeps reading input until it gets a string
5815 without a trailing backslash.
5816
5817 =cut
5818
5819 sub action {
5820     my $action = shift;
5821
5822     while ( $action =~ s/\\$// ) {
5823
5824         # We have a backslash on the end. Read more.
5825         $action .= &gets;
5826     } ## end while ($action =~ s/\\$//)
5827
5828     # Return the assembled action.
5829     $action;
5830 } ## end sub action
5831
5832 =head2 unbalanced
5833
5834 This routine mostly just packages up a regular expression to be used
5835 to check that the thing it's being matched against has properly-matched
5836 curly braces.
5837
5838 Of note is the definition of the $balanced_brace_re global via ||=, which
5839 speeds things up by only creating the qr//'ed expression once; if it's
5840 already defined, we don't try to define it again. A speed hack.
5841
5842 =cut
5843
5844 sub unbalanced {
5845
5846     # I hate using globals!
5847     $balanced_brace_re ||= qr{
5848         ^ \{
5849              (?:
5850                  (?> [^{}] + )              # Non-parens without backtracking
5851                 |
5852                  (??{ $balanced_brace_re }) # Group with matching parens
5853               ) *
5854           \} $
5855    }x;
5856     return $_[0] !~ m/$balanced_brace_re/;
5857 } ## end sub unbalanced
5858
5859 =head2 C<gets()>
5860
5861 C<gets()> is a primitive (very primitive) routine to read continuations.
5862 It was devised for reading continuations for actions.
5863 it just reads more input with X<C<readline()>> and returns it.
5864
5865 =cut
5866
5867 sub gets {
5868     &readline("cont: ");
5869 }
5870
5871 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5872
5873 The C<system()> function assumes that it can just go ahead and use STDIN and
5874 STDOUT, but under the debugger, we want it to use the debugger's input and
5875 outout filehandles.
5876
5877 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5878 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5879 and then puts everything back again.
5880
5881 =cut
5882
5883 sub system {
5884
5885     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5886     # some non-Unix systems can do system() but have problems with fork().
5887     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5888     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5889     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5890     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5891
5892     # XXX: using csh or tcsh destroys sigint retvals!
5893     system(@_);
5894     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5895     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5896     close(SAVEIN);
5897     close(SAVEOUT);
5898
5899     # most of the $? crud was coping with broken cshisms
5900     if ( $? >> 8 ) {
5901         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5902     }
5903     elsif ($?) {
5904         &warn(
5905             "(Command died of SIG#",
5906             ( $? & 127 ),
5907             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5908             ")", "\n"
5909         );
5910     } ## end elsif ($?)
5911
5912     return $?;
5913
5914 } ## end sub system
5915
5916 =head1 TTY MANAGEMENT
5917
5918 The subs here do some of the terminal management for multiple debuggers.
5919
5920 =head2 setterm
5921
5922 Top-level function called when we want to set up a new terminal for use
5923 by the debugger.
5924
5925 If the C<noTTY> debugger option was set, we'll either use the terminal
5926 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
5927 to find one. If we're a forked debugger, we call C<resetterm> to try to
5928 get a whole new terminal if we can.
5929
5930 In either case, we set up the terminal next. If the C<ReadLine> option was
5931 true, we'll get a C<Term::ReadLine> object for the current terminal and save
5932 the appropriate attributes. We then
5933
5934 =cut
5935
5936 sub setterm {
5937
5938     # Load Term::Readline, but quietly; don't debug it and don't trace it.
5939     local $frame = 0;
5940     local $doret = -2;
5941     eval { require Term::ReadLine } or die $@;
5942
5943     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
5944     if ($notty) {
5945         if ($tty) {
5946             my ( $i, $o ) = split $tty, /,/;
5947             $o = $i unless defined $o;
5948             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
5949             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
5950             $IN  = \*IN;
5951             $OUT = \*OUT;
5952             my $sel = select($OUT);
5953             $| = 1;
5954             select($sel);
5955         } ## end if ($tty)
5956
5957         # We don't have a TTY - try to find one via Term::Rendezvous.
5958         else {
5959             eval "require Term::Rendezvous;" or die;
5960
5961             # See if we have anything to pass to Term::Rendezvous.
5962             # Use /tmp/perldbtty$$ if not.
5963             my $rv = $ENV{PERLDB_NOTTY} || "/tmp/perldbtty$$";
5964
5965             # Rendezvous and get the filehandles.
5966             my $term_rv = new Term::Rendezvous $rv;
5967             $IN  = $term_rv->IN;
5968             $OUT = $term_rv->OUT;
5969         } ## end else [ if ($tty)
5970     } ## end if ($notty)
5971
5972     # We're a daughter debugger. Try to fork off another TTY.
5973     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
5974         resetterm(2);
5975     }
5976
5977     # If we shouldn't use Term::ReadLine, don't.
5978     if ( !$rl ) {
5979         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
5980     }
5981
5982     # We're using Term::ReadLine. Get all the attributes for this terminal.
5983     else {
5984         $term = new Term::ReadLine 'perldb', $IN, $OUT;
5985
5986         $rl_attribs = $term->Attribs;
5987         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
5988           if defined $rl_attribs->{basic_word_break_characters}
5989           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
5990         $rl_attribs->{special_prefixes} = '$@&%';
5991         $rl_attribs->{completer_word_break_characters} .= '$@&%';
5992         $rl_attribs->{completion_function} = \&db_complete;
5993     } ## end else [ if (!$rl)
5994
5995     # Set up the LINEINFO filehandle.
5996     $LINEINFO = $OUT     unless defined $LINEINFO;
5997     $lineinfo = $console unless defined $lineinfo;
5998
5999     $term->MinLine(2);
6000
6001     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6002         $term->SetHistory(@hist);
6003     }
6004
6005     # XXX Ornaments are turned on unconditionally, which is not
6006     # always a good thing.
6007     ornaments($ornaments) if defined $ornaments;
6008     $term_pid = $$;
6009 } ## end sub setterm
6010
6011 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6012
6013 When the process being debugged forks, or the process invokes a command
6014 via C<system()> which starts a new debugger, we need to be able to get a new
6015 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6016 fight over the terminal, and you can never quite be sure who's going to get the
6017 input you're typing.
6018
6019 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6020 is tasked with doing all the necessary operating system mojo to get a new
6021 TTY (and probably another window) and to direct the new debugger to read and
6022 write there.
6023
6024 The debugger provides C<get_fork_TTY> functions which work for X Windows and
6025 OS/2. Other systems are not supported. You are encouraged to write
6026 C<get_fork_TTY> functions which work for I<your> platform and contribute them.
6027
6028 =head3 C<xterm_get_fork_TTY>
6029
6030 This function provides the C<get_fork_TTY> function for X windows. If a
6031 program running under the debugger forks, a new <xterm> window is opened and
6032 the subsidiary debugger is directed there.
6033
6034 The C<open()> call is of particular note here. We have the new C<xterm>
6035 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6036 command (which prints the device name of the TTY we'll want to use for input
6037 and output to STDOUT, then C<sleep> for a very long time, routing this output
6038 to file number 3. This way we can simply read from the <XT> filehandle (which
6039 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6040
6041 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6042 properly set up.
6043
6044 =cut
6045
6046 sub xterm_get_fork_TTY {
6047     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6048     open XT,
6049 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6050  sleep 10000000' |];
6051
6052     # Get the output from 'tty' and clean it up a little.
6053     my $tty = <XT>;
6054     chomp $tty;
6055
6056     $pidprompt = '';    # Shown anyway in titlebar
6057
6058     # There's our new TTY.
6059     return $tty;
6060 } ## end sub xterm_get_fork_TTY
6061
6062 =head3 C<os2_get_fork_TTY>
6063
6064 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6065
6066 =cut
6067
6068 # This example function resets $IN, $OUT itself
6069 sub os2_get_fork_TTY {
6070     local $^F = 40;    # XXXX Fixme!
6071     local $\  = '';
6072     my ( $in1, $out1, $in2, $out2 );
6073
6074     # Having -d in PERL5OPT would lead to a disaster...
6075     local $ENV{PERL5OPT} = $ENV{PERL5OPT} if $ENV{PERL5OPT};
6076     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\b//  if $ENV{PERL5OPT};
6077     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\B/-/ if $ENV{PERL5OPT};
6078     print $OUT "Making kid PERL5OPT->`$ENV{PERL5OPT}'.\n" if $ENV{PERL5OPT};
6079     local $ENV{PERL5LIB} = $ENV{PERL5LIB} ? $ENV{PERL5LIB} : $ENV{PERLLIB};
6080     $ENV{PERL5LIB} = '' unless defined $ENV{PERL5LIB};
6081     $ENV{PERL5LIB} = join ';', @ini_INC, split /;/, $ENV{PERL5LIB};
6082     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6083     my @args;
6084
6085     if (
6086             pipe $in1, $out1
6087         and pipe $in2, $out2
6088
6089         # system P_SESSION will fail if there is another process
6090         # in the same session with a "dependent" asynchronous child session.
6091         and @args = (
6092             $rl, fileno $in1, fileno $out2, "Daughter Perl debugger $pids $name"
6093         )
6094         and (
6095             ( $kpid = CORE::system 4, $^X, '-we',
6096                 <<'ES', @args ) >= 0    # P_SESSION
6097 END {sleep 5 unless $loaded}
6098 BEGIN {open STDIN,  '</dev/con' or warn "reopen stdin: $!"}
6099 use OS2::Process;
6100
6101 my ($rl, $in) = (shift, shift);        # Read from $in and pass through
6102 set_title pop;
6103 system P_NOWAIT, $^X, '-we', <<EOS or die "Cannot start a grandkid";
6104   open IN, '<&=$in' or die "open <&=$in: \$!";
6105   \$| = 1; print while sysread IN, \$_, 1<<16;
6106 EOS
6107
6108 my $out = shift;
6109 open OUT, ">&=$out" or die "Cannot open &=$out for writing: $!";
6110 select OUT;    $| = 1;
6111 require Term::ReadKey if $rl;
6112 Term::ReadKey::ReadMode(4) if $rl; # Nodelay on kbd.  Pipe is automatically nodelay...
6113 print while sysread STDIN, $_, 1<<($rl ? 16 : 0);
6114 ES
6115             or warn "system P_SESSION: $!, $^E" and 0
6116         )
6117         and close $in1
6118         and close $out2
6119       )
6120     {
6121         $pidprompt = '';    # Shown anyway in titlebar
6122         reset_IN_OUT( $in2, $out1 );
6123         $tty = '*reset*';
6124         return '';          # Indicate that reset_IN_OUT is called
6125     } ## end if (pipe $in1, $out1 and...
6126     return;
6127 } ## end sub os2_get_fork_TTY
6128
6129 =head2 C<create_IN_OUT($flags)>
6130
6131 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6132 try to diagnose why.
6133
6134 Flags are:
6135
6136 =over 4
6137
6138 =item * 1 - Don't know how to create a new TTY.
6139
6140 =item * 2 - Debugger has forked, but we can't get a new TTY.
6141
6142 =item * 4 - standard debugger startup is happening.
6143
6144 =back
6145
6146 =cut
6147
6148 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6149
6150     # If we know how to get a new TTY, do it! $in will have
6151     # the TTY name if get_fork_TTY works.
6152     my $in = &get_fork_TTY if defined &get_fork_TTY;
6153
6154     # It used to be that
6155     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6156
6157     if ( not defined $in ) {
6158         my $why = shift;
6159
6160         # We don't know how.
6161         print_help(<<EOP) if $why == 1;
6162 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6163 EOP
6164
6165         # Forked debugger.
6166         print_help(<<EOP) if $why == 2;
6167 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6168   This may be an asynchronous session, so the parent debugger may be active.
6169 EOP
6170
6171         # Note that both debuggers are fighting over the same input.
6172         print_help(<<EOP) if $why != 4;
6173   Since two debuggers fight for the same TTY, input is severely entangled.
6174
6175 EOP
6176         print_help(<<EOP);
6177   I know how to switch the output to a different window in xterms
6178   and OS/2 consoles only.  For a manual switch, put the name of the created I<TTY>
6179   in B<\$DB::fork_TTY>, or define a function B<DB::get_fork_TTY()> returning this.
6180
6181   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6182   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6183
6184 EOP
6185     } ## end if (not defined $in)
6186     elsif ( $in ne '' ) {
6187         TTY($in);
6188     }
6189     else {
6190         $console = '';    # Indicate no need to open-from-the-console
6191     }
6192     undef $fork_TTY;
6193 } ## end sub create_IN_OUT
6194
6195 =head2 C<resetterm>
6196
6197 Handles rejiggering the prompt when we've forked off a new debugger.
6198
6199 If the new debugger happened because of a C<system()> that invoked a
6200 program under the debugger, the arrow between the old pid and the new
6201 in the prompt has I<two> dashes instead of one.
6202
6203 We take the current list of pids and add this one to the end. If there
6204 isn't any list yet, we make one up out of the initial pid associated with
6205 the terminal and our new pid, sticking an arrow (either one-dashed or
6206 two dashed) in between them.
6207
6208 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6209 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6210 and try to do that.
6211
6212 =cut
6213
6214 sub resetterm {    # We forked, so we need a different TTY
6215
6216     # Needs to be passed to create_IN_OUT() as well.
6217     my $in = shift;
6218
6219     # resetterm(2): got in here because of a system() starting a debugger.
6220     # resetterm(1): just forked.
6221     my $systemed = $in > 1 ? '-' : '';
6222
6223     # If there's already a list of pids, add this to the end.
6224     if ($pids) {
6225         $pids =~ s/\]/$systemed->$$]/;
6226     }
6227
6228     # No pid list. Time to make one.
6229     else {
6230         $pids = "[$term_pid->$$]";
6231     }
6232
6233     # The prompt we're going to be using for this debugger.
6234     $pidprompt = $pids;
6235
6236     # We now 0wnz this terminal.
6237     $term_pid = $$;
6238
6239     # Just return if we're not supposed to try to create a new TTY.
6240     return unless $CreateTTY & $in;
6241
6242     # Try to create a new IN/OUT pair.
6243     create_IN_OUT($in);
6244 } ## end sub resetterm
6245
6246 =head2 C<readline>
6247
6248 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6249 the next line, print a message saying we got it, add it to the terminal
6250 history (if possible), and return it.
6251
6252 If there's nothing in the typeahead buffer, check the command filehandle stack.
6253 If there are any filehandles there, read from the last one, and return the line
6254 if we got one. If not, we pop the filehandle off and close it, and try the
6255 next one up the stack.
6256
6257 If we've emptied the filehandle stack, we check to see if we've got a socket
6258 open, and we read that and return it if we do. If we don't, we just call the
6259 core C<readline()> and return its value.
6260
6261 =cut
6262
6263 sub readline {
6264
6265     # Localize to prevent it from being smashed in the program being debugged.
6266     local $.;
6267
6268     # Pull a line out of the typeahead if there's stuff there.
6269     if (@typeahead) {
6270
6271         # How many lines left.
6272         my $left = @typeahead;
6273
6274         # Get the next line.
6275         my $got = shift @typeahead;
6276
6277         # Print a message saying we got input from the typeahead.
6278         local $\ = '';
6279         print $OUT "auto(-$left)", shift, $got, "\n";
6280
6281         # Add it to the terminal history (if possible).
6282         $term->AddHistory($got)
6283           if length($got) > 1
6284           and defined $term->Features->{addHistory};
6285         return $got;
6286     } ## end if (@typeahead)
6287
6288     # We really need to read some input. Turn off entry/exit trace and
6289     # return value printing.
6290     local $frame = 0;
6291     local $doret = -2;
6292
6293     # If there are stacked filehandles to read from ...
6294     while (@cmdfhs) {
6295
6296         # Read from the last one in the stack.
6297         my $line = CORE::readline( $cmdfhs[-1] );
6298
6299         # If we got a line ...
6300         defined $line
6301           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6302           : close pop @cmdfhs;                            # Pop and close
6303     } ## end while (@cmdfhs)
6304
6305     # Nothing on the filehandle stack. Socket?
6306     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6307
6308         # Send anyting we have to send.
6309         $OUT->write( join( '', @_ ) );
6310
6311         # Receive anything there is to receive.
6312         my $stuff;
6313         $IN->recv( $stuff, 2048 );    # XXX "what's wrong with sysread?"
6314                                       # XXX Don't know. You tell me.
6315
6316         # What we got.
6317         $stuff;
6318     } ## end if (ref $OUT and UNIVERSAL::isa...
6319
6320     # No socket. Just read from the terminal.
6321     else {
6322         $term->readline(@_);
6323     }
6324 } ## end sub readline
6325
6326 =head1 OPTIONS SUPPORT ROUTINES
6327
6328 These routines handle listing and setting option values.
6329
6330 =head2 C<dump_option> - list the current value of an option setting
6331
6332 This routine uses C<option_val> to look up the value for an option.
6333 It cleans up escaped single-quotes and then displays the option and
6334 its value.
6335
6336 =cut
6337
6338 sub dump_option {
6339     my ( $opt, $val ) = @_;
6340     $val = option_val( $opt, 'N/A' );
6341     $val =~ s/([\\\'])/\\$1/g;
6342     printf $OUT "%20s = '%s'\n", $opt, $val;
6343 } ## end sub dump_option
6344
6345 sub options2remember {
6346     foreach my $k (@RememberOnROptions) {
6347         $option{$k} = option_val( $k, 'N/A' );
6348     }
6349     return %option;
6350 }
6351
6352 =head2 C<option_val> - find the current value of an option
6353
6354 This can't just be a simple hash lookup because of the indirect way that
6355 the option values are stored. Some are retrieved by calling a subroutine,
6356 some are just variables.
6357
6358 You must supply a default value to be used in case the option isn't set.
6359
6360 =cut
6361
6362 sub option_val {
6363     my ( $opt, $default ) = @_;
6364     my $val;
6365
6366     # Does this option exist, and is it a variable?
6367     # If so, retrieve the value via the value in %optionVars.
6368     if (    defined $optionVars{$opt}
6369         and defined ${ $optionVars{$opt} } )
6370     {
6371         $val = ${ $optionVars{$opt} };
6372     }
6373
6374     # Does this option exist, and it's a subroutine?
6375     # If so, call the subroutine via the ref in %optionAction
6376     # and capture the value.
6377     elsif ( defined $optionAction{$opt}
6378         and defined &{ $optionAction{$opt} } )
6379     {
6380         $val = &{ $optionAction{$opt} }();
6381     }
6382
6383     # If there's an action or variable for the supplied option,
6384     # but no value was set, use the default.
6385     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6386         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6387     {
6388         $val = $default;
6389     }
6390
6391     # Otherwise, do the simple hash lookup.
6392     else {
6393         $val = $option{$opt};
6394     }
6395
6396     # If the value isn't defined, use the default.
6397     # Then return whatever the value is.
6398     $val = $default unless defined $val;
6399     $val;
6400 } ## end sub option_val
6401
6402 =head2 C<parse_options>
6403
6404 Handles the parsing and execution of option setting/displaying commands.
6405
6406 An option entered by itself is assumed to be 'set me to 1' (the default value)
6407 if the option is a boolean one. If not, the user is prompted to enter a valid
6408 value or to query the current value (via 'option? ').
6409
6410 If 'option=value' is entered, we try to extract a quoted string from the
6411 value (if it is quoted). If it's not, we just use the whole value as-is.
6412
6413 We load any modules required to service this option, and then we set it: if
6414 it just gets stuck in a variable, we do that; if there's a subroutine to
6415 handle setting the option, we call that.
6416
6417 Finally, if we're running in interactive mode, we display the effect of the
6418 user's command back to the terminal, skipping this if we're setting things
6419 during initialization.
6420
6421 =cut
6422
6423 sub parse_options {
6424     local ($_) = @_;
6425     local $\ = '';
6426
6427     # These options need a value. Don't allow them to be clobbered by accident.
6428     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6429       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6430       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6431     };
6432
6433     while (length) {
6434         my $val_defaulted;
6435
6436         # Clean off excess leading whitespace.
6437         s/^\s+// && next;
6438
6439         # Options are always all word characters, followed by a non-word
6440         # separator.
6441         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6442         my ( $opt, $sep ) = ( $1, $2 );
6443
6444         # Make sure that such an option exists.
6445         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6446           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6447
6448         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6449         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6450         my $val;
6451
6452         # '?' as separator means query, but must have whitespace after it.
6453         if ( "?" eq $sep ) {
6454             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6455               last
6456               if /^\S/;
6457
6458             #&dump_option($opt);
6459         } ## end if ("?" eq $sep)
6460
6461         # Separator is whitespace (or just a carriage return).
6462         # They're going for a default, which we assume is 1.
6463         elsif ( $sep !~ /\S/ ) {
6464             $val_defaulted = 1;
6465             $val           = "1";   #  this is an evil default; make 'em set it!
6466         }
6467
6468         # Separator is =. Trying to set a value.
6469         elsif ( $sep eq "=" ) {
6470
6471             # If quoted, extract a quoted string.
6472             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6473                 my $quote = $1;
6474                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6475             }
6476
6477             # Not quoted. Use the whole thing. Warn about 'option='.
6478             else {
6479                 s/^(\S*)//;
6480                 $val = $1;
6481                 print OUT qq(Option better cleared using $opt=""\n)
6482                   unless length $val;
6483             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6484
6485         } ## end elsif ($sep eq "=")
6486
6487         # "Quoted" with [], <>, or {}.
6488         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6489             my ($end) =
6490               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6491             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6492               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6493             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6494         } ## end else [ if ("?" eq $sep)
6495
6496         # Exclude non-booleans from getting set to 1 by default.
6497         if ( $opt_needs_val{$option} && $val_defaulted ) {
6498             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6499             print $OUT
6500 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6501             next;
6502         } ## end if ($opt_needs_val{$option...
6503
6504         # Save the option value.
6505         $option{$option} = $val if defined $val;
6506
6507         # Load any module that this option requires.
6508         eval qq{
6509                 local \$frame = 0;
6510                 local \$doret = -2;
6511                 require '$optionRequire{$option}';
6512                 1;
6513                } || die    # XXX: shouldn't happen
6514           if defined $optionRequire{$option}
6515           && defined $val;
6516
6517         # Set it.
6518         # Stick it in the proper variable if it goes in a variable.
6519         ${ $optionVars{$option} } = $val
6520           if defined $optionVars{$option}
6521           && defined $val;
6522
6523         # Call the appropriate sub if it gets set via sub.
6524         &{ $optionAction{$option} }($val)
6525           if defined $optionAction{$option}
6526           && defined &{ $optionAction{$option} }
6527           && defined $val;
6528
6529         # Not initialization - echo the value we set it to.
6530         dump_option($option) unless $OUT eq \*STDERR;
6531     } ## end while (length)
6532 } ## end sub parse_options
6533
6534 =head1 RESTART SUPPORT
6535
6536 These routines are used to store (and restore) lists of items in environment
6537 variables during a restart.
6538
6539 =head2 set_list
6540
6541 Set_list packages up items to be stored in a set of environment variables
6542 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6543 the values). Values outside the standard ASCII charset are stored by encoding
6544 then as hexadecimal values.
6545
6546 =cut
6547
6548 sub set_list {
6549     my ( $stem, @list ) = @_;
6550     my $val;
6551
6552     # VAR_n: how many we have. Scalar assignment gets the number of items.
6553     $ENV{"${stem}_n"} = @list;
6554
6555     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6556     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6557     for $i ( 0 .. $#list ) {
6558         $val = $list[$i];
6559         $val =~ s/\\/\\\\/g;
6560         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6561         $ENV{"${stem}_$i"} = $val;
6562     } ## end for $i (0 .. $#list)
6563 } ## end sub set_list
6564
6565 =head2 get_list
6566
6567 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6568 back, and then pull VAR_0, VAR_1. etc. back out.
6569
6570 =cut
6571
6572 sub get_list {
6573     my $stem = shift;
6574     my @list;
6575     my $n = delete $ENV{"${stem}_n"};
6576     my $val;
6577     for $i ( 0 .. $n - 1 ) {
6578         $val = delete $ENV{"${stem}_$i"};
6579         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6580         push @list, $val;
6581     }
6582     @list;
6583 } ## end sub get_list
6584
6585 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6586
6587 =head2 catch()
6588
6589 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6590 set an already-existing global scalar variable to a constant value. This
6591 avoids allocating any memory possibly in the middle of something that will
6592 get all confused if we do.
6593
6594 =cut
6595
6596 sub catch {
6597     $signal = 1;
6598     return;    # Put nothing on the stack - malloc/free land!
6599 }
6600
6601 =head2 C<warn()>
6602
6603 C<warn> emits a warning, by joining together its arguments and printing
6604 them, with couple of fillips.
6605
6606 If the composited message I<doesn't> end with a newline, we automatically
6607 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6608 to be set to the filehandle to be used to output warnings; it makes no
6609 assumptions about what filehandles are available.
6610
6611 =cut
6612
6613 sub warn {
6614     my ($msg) = join( "", @_ );
6615     $msg .= ": $!\n" unless $msg =~ /\n$/;
6616     local $\ = '';
6617     print $OUT $msg;
6618 } ## end sub warn
6619
6620 =head1 INITIALIZATION TTY SUPPORT
6621
6622 =head2 C<reset_IN_OUT>
6623
6624 This routine handles restoring the debugger's input and output filehandles
6625 after we've tried and failed to move them elsewhere.  In addition, it assigns
6626 the debugger's output filehandle to $LINEINFO if it was already open there.
6627
6628 =cut
6629
6630 sub reset_IN_OUT {
6631     my $switch_li = $LINEINFO eq $OUT;
6632
6633     # If there's a term and it's able to get a new tty, try to get one.
6634     if ( $term and $term->Features->{newTTY} ) {
6635         ( $IN, $OUT ) = ( shift, shift );
6636         $term->newTTY( $IN, $OUT );
6637     }
6638
6639     # This term can't get a new tty now. Better luck later.
6640     elsif ($term) {
6641         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6642     }
6643
6644     # Set the filehndles up as they were.
6645     else {
6646         ( $IN, $OUT ) = ( shift, shift );
6647     }
6648
6649     # Unbuffer the output filehandle.
6650     my $o = select $OUT;
6651     $| = 1;
6652     select $o;
6653
6654     # Point LINEINFO to the same output filehandle if it was there before.
6655     $LINEINFO = $OUT if $switch_li;
6656 } ## end sub reset_IN_OUT
6657
6658 =head1 OPTION SUPPORT ROUTINES
6659
6660 The following routines are used to process some of the more complicated
6661 debugger options.
6662
6663 =head2 C<TTY>
6664
6665 Sets the input and output filehandles to the specified files or pipes.
6666 If the terminal supports switching, we go ahead and do it. If not, and
6667 there's already a terminal in place, we save the information to take effect
6668 on restart.
6669
6670 If there's no terminal yet (for instance, during debugger initialization),
6671 we go ahead and set C<$console> and C<$tty> to the file indicated.
6672
6673 =cut
6674
6675 sub TTY {
6676     if ( @_ and $term and $term->Features->{newTTY} ) {
6677
6678         # This terminal supports switching to a new TTY.
6679         # Can be a list of two files, or on string containing both names,
6680         # comma-separated.
6681         # XXX Should this perhaps be an assignment from @_?
6682         my ( $in, $out ) = shift;
6683         if ( $in =~ /,/ ) {
6684
6685             # Split list apart if supplied.
6686             ( $in, $out ) = split /,/, $in, 2;
6687         }
6688         else {
6689
6690             # Use the same file for both input and output.
6691             $out = $in;
6692         }
6693
6694         # Open file onto the debugger's filehandles, if you can.
6695         open IN,  $in     or die "cannot open `$in' for read: $!";
6696         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6697
6698         # Swap to the new filehandles.
6699         reset_IN_OUT( \*IN, \*OUT );
6700
6701         # Save the setting for later.
6702         return $tty = $in;
6703     } ## end if (@_ and $term and $term...
6704
6705     # Terminal doesn't support new TTY, or doesn't support readline.
6706     # Can't do it now, try restarting.
6707     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6708
6709     # Useful if done through PERLDB_OPTS:
6710     $console = $tty = shift if @_;
6711
6712     # Return whatever the TTY is.
6713     $tty or $console;
6714 } ## end sub TTY
6715
6716 =head2 C<noTTY>
6717
6718 Sets the C<$notty> global, controlling whether or not the debugger tries to
6719 get a terminal to read from. If called after a terminal is already in place,
6720 we save the value to use it if we're restarted.
6721
6722 =cut
6723
6724 sub noTTY {
6725     if ($term) {
6726         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6727     }
6728     $notty = shift if @_;
6729     $notty;
6730 } ## end sub noTTY
6731
6732 =head2 C<ReadLine>
6733
6734 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6735 (essentially, no C<readline> processing on this "terminal"). Otherwise, we
6736 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6737 the value in case a restart is done so we can change it then.
6738
6739 =cut
6740
6741 sub ReadLine {
6742     if ($term) {
6743         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6744     }
6745     $rl = shift if @_;
6746     $rl;
6747 } ## end sub ReadLine
6748
6749 =head2 C<RemotePort>
6750
6751 Sets the port that the debugger will try to connect to when starting up.
6752 If the terminal's already been set up, we can't do it, but we remember the
6753 setting in case the user does a restart.
6754
6755 =cut
6756
6757 sub RemotePort {
6758     if ($term) {
6759         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6760     }
6761     $remoteport = shift if @_;
6762     $remoteport;
6763 } ## end sub RemotePort
6764
6765 =head2 C<tkRunning>
6766
6767 Checks with the terminal to see if C<Tk> is running, and returns true or
6768 false. Returns false if the current terminal doesn't support C<readline>.
6769
6770 =cut
6771
6772 sub tkRunning {
6773     if ( ${ $term->Features }{tkRunning} ) {
6774         return $term->tkRunning(@_);
6775     }
6776     else {
6777         local $\ = '';
6778         print $OUT "tkRunning not supported by current ReadLine package.\n";
6779         0;
6780     }
6781 } ## end sub tkRunning
6782
6783 =head2 C<NonStop>
6784
6785 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6786 debugger remembers the setting in case you restart, though.
6787
6788 =cut
6789
6790 sub NonStop {
6791     if ($term) {
6792         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6793           if @_;
6794     }
6795     $runnonstop = shift if @_;
6796     $runnonstop;
6797 } ## end sub NonStop
6798
6799 sub DollarCaretP {
6800     if ($term) {
6801         &warn("Some flag changes could not take effect until next 'R'!\n")
6802           if @_;
6803     }
6804     $^P = parse_DollarCaretP_flags(shift) if @_;
6805     expand_DollarCaretP_flags($^P);
6806 }
6807
6808 sub OnlyAssertions {
6809     if ($term) {
6810         &warn("Too late to set up OnlyAssertions mode, enabled on next 'R'!\n")
6811           if @_;
6812     }
6813     if (@_) {
6814         unless ( defined $ini_assertion ) {
6815             if ($term) {
6816                 &warn("Current Perl interpreter doesn't support assertions");
6817             }
6818             return 0;
6819         }
6820         if (shift) {
6821             unless ($ini_assertion) {
6822                 print "Assertions will be active on next 'R'!\n";
6823                 $ini_assertion = 1;
6824             }
6825             $^P &= ~$DollarCaretP_flags{PERLDBf_SUB};
6826             $^P |= $DollarCaretP_flags{PERLDBf_ASSERTION};
6827         }
6828         else {
6829             $^P |= $DollarCaretP_flags{PERLDBf_SUB};
6830         }
6831     }
6832     !( $^P & $DollarCaretP_flags{PERLDBf_SUB} ) || 0;
6833 }
6834
6835 =head2 C<pager>
6836
6837 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6838 there already.
6839
6840 =cut
6841
6842 sub pager {
6843     if (@_) {
6844         $pager = shift;
6845         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6846     }
6847     $pager;
6848 } ## end sub pager
6849
6850 =head2 C<shellBang>
6851
6852 Sets the shell escape command, and generates a printable copy to be used
6853 in the help.
6854
6855 =cut
6856
6857 sub shellBang {
6858
6859     # If we got an argument, meta-quote it, and add '\b' if it
6860     # ends in a word character.
6861     if (@_) {
6862         $sh = quotemeta shift;
6863         $sh .= "\\b" if $sh =~ /\w$/;
6864     }
6865
6866     # Generate the printable version for the help:
6867     $psh = $sh;    # copy it
6868     $psh =~ s/\\b$//;        # Take off trailing \b if any
6869     $psh =~ s/\\(.)/$1/g;    # De-escape
6870     $psh;                    # return the printable version
6871 } ## end sub shellBang
6872
6873 =head2 C<ornaments>
6874
6875 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
6876 was passed as the argument. (This means you can't override the terminal's
6877 ornaments.)
6878
6879 =cut
6880
6881 sub ornaments {
6882     if ( defined $term ) {
6883
6884         # We don't want to show warning backtraces, but we do want die() ones.
6885         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
6886
6887         # No ornaments if the terminal doesn't support them.
6888         return '' unless $term->Features->{ornaments};
6889         eval { $term->ornaments(@_) } || '';
6890     }
6891
6892     # Use what was passed in if we can't determine it ourselves.
6893     else {
6894         $ornaments = shift;
6895     }
6896 } ## end sub ornaments
6897
6898 =head2 C<recallCommand>
6899
6900 Sets the recall command, and builds a printable version which will appear in
6901 the help text.
6902
6903 =cut
6904
6905 sub recallCommand {
6906
6907     # If there is input, metaquote it. Add '\b' if it ends with a word
6908     # character.
6909     if (@_) {
6910         $rc = quotemeta shift;
6911         $rc .= "\\b" if $rc =~ /\w$/;
6912     }
6913
6914     # Build it into a printable version.
6915     $prc = $rc;    # Copy it
6916     $prc =~ s/\\b$//;        # Remove trailing \b
6917     $prc =~ s/\\(.)/$1/g;    # Remove escapes
6918     $prc;                    # Return the printable version
6919 } ## end sub recallCommand
6920
6921 =head2 C<LineInfo> - where the line number information goes
6922
6923 Called with no arguments, returns the file or pipe that line info should go to.
6924
6925 Called with an argument (a file or a pipe), it opens that onto the
6926 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
6927 file or pipe again to the caller.
6928
6929 =cut
6930
6931 sub LineInfo {
6932     return $lineinfo unless @_;
6933     $lineinfo = shift;
6934
6935     #  If this is a valid "thing to be opened for output", tack a
6936     # '>' onto the front.
6937     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
6938
6939     # If this is a pipe, the stream points to a slave editor.
6940     $slave_editor = ( $stream =~ /^\|/ );
6941
6942     # Open it up and unbuffer it.
6943     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
6944     $LINEINFO = \*LINEINFO;
6945     my $save = select($LINEINFO);
6946     $| = 1;
6947     select($save);
6948
6949     # Hand the file or pipe back again.
6950     $lineinfo;
6951 } ## end sub LineInfo
6952
6953 =head1 COMMAND SUPPORT ROUTINES
6954
6955 These subroutines provide functionality for various commands.
6956
6957 =head2 C<list_modules>
6958
6959 For the C<M> command: list modules loaded and their versions.
6960 Essentially just runs through the keys in %INC, picks up the
6961 $VERSION package globals from each package, gets the file name, and formats the
6962 information for output.
6963
6964 =cut
6965
6966 sub list_modules {    # versions
6967     my %version;
6968     my $file;
6969
6970     # keys are the "as-loaded" name, values are the fully-qualified path
6971     # to the file itself.
6972     for ( keys %INC ) {
6973         $file = $_;                                # get the module name
6974         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
6975         s,/,::,g;                                  # change '/' to '::'
6976         s/^perl5db$/DB/;                           # Special case: debugger
6977                                                    # moves to package DB
6978         s/^Term::ReadLine::readline$/readline/;    # simplify readline
6979
6980         # If the package has a $VERSION package global (as all good packages
6981         # should!) decode it and save as partial message.
6982         if ( defined ${ $_ . '::VERSION' } ) {
6983             $version{$file} = "${ $_ . '::VERSION' } from ";
6984         }
6985
6986         # Finish up the message with the file the package came from.
6987         $version{$file} .= $INC{$file};
6988     } ## end for (keys %INC)
6989
6990     # Hey, dumpit() formats a hash nicely, so why not use it?
6991     dumpit( $OUT, \%version );
6992 } ## end sub list_modules
6993
6994 =head2 C<sethelp()>
6995
6996 Sets up the monster string used to format and print the help.
6997
6998 =head3 HELP MESSAGE FORMAT
6999
7000 The help message is a peculiar format unto itself; it mixes C<pod> 'ornaments'
7001 (BE<lt>E<gt>, IE<gt>E<lt>) with tabs to come up with a format that's fairly
7002 easy to parse and portable, but which still allows the help to be a little
7003 nicer than just plain text.
7004
7005 Essentially, you define the command name (usually marked up with BE<gt>E<lt>
7006 and IE<gt>E<lt>), followed by a tab, and then the descriptive text, ending in a newline. The descriptive text can also be marked up in the same way. If you
7007 need to continue the descriptive text to another line, start that line with
7008 just tabs and then enter the marked-up text.
7009
7010 If you are modifying the help text, I<be careful>. The help-string parser is
7011 not very sophisticated, and if you don't follow these rules it will mangle the
7012 help beyond hope until you fix the string.
7013
7014 =cut
7015
7016 sub sethelp {
7017
7018     # XXX: make sure there are tabs between the command and explanation,
7019     #      or print_help will screw up your formatting if you have
7020     #      eeevil ornaments enabled.  This is an insane mess.
7021
7022     $help = "
7023 Help is currently only available for the new 5.8 command set.
7024 No help is available for the old command set.
7025 We assume you know what you're doing if you switch to it.
7026
7027 B<T>        Stack trace.
7028 B<s> [I<expr>]    Single step [in I<expr>].
7029 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7030 <B<CR>>        Repeat last B<n> or B<s> command.
7031 B<r>        Return from current subroutine.
7032 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7033         at the specified position.
7034 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7035 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7036 B<l> I<line>        List single I<line>.
7037 B<l> I<subname>    List first window of lines from subroutine.
7038 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7039 B<l>        List next window of lines.
7040 B<->        List previous window of lines.
7041 B<v> [I<line>]    View window around I<line>.
7042 B<.>        Return to the executed line.
7043 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7044         I<filename> may be either the full name of the file, or a regular
7045         expression matching the full file name:
7046         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7047         Evals (with saved bodies) are considered to be filenames:
7048         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7049         (in the order of execution).
7050 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7051 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7052 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7053 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7054 B<t>        Toggle trace mode.
7055 B<t> I<expr>        Trace through execution of I<expr>.
7056 B<b>        Sets breakpoint on current line)
7057 B<b> [I<line>] [I<condition>]
7058         Set breakpoint; I<line> defaults to the current execution line;
7059         I<condition> breaks if it evaluates to true, defaults to '1'.
7060 B<b> I<subname> [I<condition>]
7061         Set breakpoint at first line of subroutine.
7062 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7063 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7064 B<b> B<postpone> I<subname> [I<condition>]
7065         Set breakpoint at first line of subroutine after
7066         it is compiled.
7067 B<b> B<compile> I<subname>
7068         Stop after the subroutine is compiled.
7069 B<B> [I<line>]    Delete the breakpoint for I<line>.
7070 B<B> I<*>             Delete all breakpoints.
7071 B<a> [I<line>] I<command>
7072         Set an action to be done before the I<line> is executed;
7073         I<line> defaults to the current execution line.
7074         Sequence is: check for breakpoint/watchpoint, print line
7075         if necessary, do action, prompt user if necessary,
7076         execute line.
7077 B<a>        Does nothing
7078 B<A> [I<line>]    Delete the action for I<line>.
7079 B<A> I<*>             Delete all actions.
7080 B<w> I<expr>        Add a global watch-expression.
7081 B<w>             Does nothing
7082 B<W> I<expr>        Delete a global watch-expression.
7083 B<W> I<*>             Delete all watch-expressions.
7084 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7085         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7086 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7087 B<x> I<expr>        Evals expression in list context, dumps the result.
7088 B<m> I<expr>        Evals expression in list context, prints methods callable
7089         on the first element of the result.
7090 B<m> I<class>        Prints methods callable via the given class.
7091 B<M>        Show versions of loaded modules.
7092 B<i> I<class>       Prints nested parents of given class.
7093 B<e>         Display current thread id.
7094 B<E>         Display all thread ids the current one will be identified: <n>.
7095 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7096 B<P> Something to do with assertions...
7097
7098 B<<> ?            List Perl commands to run before each prompt.
7099 B<<> I<expr>        Define Perl command to run before each prompt.
7100 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7101 B<< *>                Delete the list of perl commands to run before each prompt.
7102 B<>> ?            List Perl commands to run after each prompt.
7103 B<>> I<expr>        Define Perl command to run after each prompt.
7104 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7105 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7106 B<{> I<db_command>    Define debugger command to run before each prompt.
7107 B<{> ?            List debugger commands to run before each prompt.
7108 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7109 B<{ *>             Delete the list of debugger commands to run before each prompt.
7110 B<$prc> I<number>    Redo a previous command (default previous command).
7111 B<$prc> I<-number>    Redo number'th-to-last command.
7112 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7113         See 'B<O> I<recallCommand>' too.
7114 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7115       . (
7116         $rc eq $sh
7117         ? ""
7118         : "
7119 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7120       ) . "
7121         See 'B<O> I<shellBang>' too.
7122 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7123 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7124 B<rerun>           Rerun session to current position.
7125 B<rerun> I<n>         Rerun session to numbered command.
7126 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7127 B<H> I<-number>    Display last number commands (default all).
7128 B<H> I<*>          Delete complete history.
7129 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7130 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7131 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7132 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7133 I<command>        Execute as a perl statement in current package.
7134 B<R>        Pure-man-restart of debugger, some of debugger state
7135         and command-line options may be lost.
7136         Currently the following settings are preserved:
7137         history, breakpoints and actions, debugger B<O>ptions
7138         and the following command-line options: I<-w>, I<-I>, I<-e>.
7139
7140 B<o> [I<opt>] ...    Set boolean option to true
7141 B<o> [I<opt>B<?>]    Query options
7142 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7143         Set options.  Use quotes in spaces in value.
7144     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7145     I<pager>            program for output of \"|cmd\";
7146     I<tkRunning>            run Tk while prompting (with ReadLine);
7147     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7148     I<inhibit_exit>        Allows stepping off the end of the script.
7149     I<ImmediateStop>        Debugger should stop as early as possible.
7150     I<RemotePort>            Remote hostname:port for remote debugging
7151   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7152     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7153     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7154     I<globPrint>             whether to print contents of globs;
7155     I<DumpDBFiles>         dump arrays holding debugged files;
7156     I<DumpPackages>         dump symbol tables of packages;
7157     I<DumpReused>             dump contents of \"reused\" addresses;
7158     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7159     I<bareStringify>         Do not print the overload-stringified value;
7160   Other options include:
7161     I<PrintRet>        affects printing of return value after B<r> command,
7162     I<frame>        affects printing messages on subroutine entry/exit.
7163     I<AutoTrace>    affects printing messages on possible breaking points.
7164     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7165     I<ornaments>     affects screen appearance of the command line.
7166     I<CreateTTY>     bits control attempts to create a new TTY on events:
7167             1: on fork()    2: debugger is started inside debugger
7168             4: on startup
7169     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7170     You can put additional initialization options I<TTY>, I<noTTY>,
7171     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7172     `B<R>' after you set them).
7173
7174 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7175 B<h>        Summary of debugger commands.
7176 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7177 B<h h>        Long help for debugger commands
7178 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7179         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7180         Set B<\$DB::doccmd> to change viewer.
7181
7182 Type `|h h' for a paged display if this was too hard to read.
7183
7184 ";    # Fix balance of vi % matching: }}}}
7185
7186     #  note: tabs in the following section are not-so-helpful
7187     $summary = <<"END_SUM";
7188 I<List/search source lines:>               I<Control script execution:>
7189   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7190   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7191   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7192   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7193   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7194   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7195 I<Debugger controls:>                        B<L>           List break/watch/actions
7196   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7197   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7198   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7199   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7200   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7201   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7202   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7203   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7204   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7205 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7206   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7207   B<p> I<expr>         Print expression (uses script's current package).
7208   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7209   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7210   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7211   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7212   B<e>     Display thread id     B<E> Display all thread ids.
7213 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7214 END_SUM
7215
7216     # ')}}; # Fix balance of vi % matching
7217
7218     # and this is really numb...
7219     $pre580_help = "
7220 B<T>        Stack trace.
7221 B<s> [I<expr>]    Single step [in I<expr>].
7222 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7223 B<CR>>        Repeat last B<n> or B<s> command.
7224 B<r>        Return from current subroutine.
7225 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7226         at the specified position.
7227 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7228 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7229 B<l> I<line>        List single I<line>.
7230 B<l> I<subname>    List first window of lines from subroutine.
7231 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7232 B<l>        List next window of lines.
7233 B<->        List previous window of lines.
7234 B<w> [I<line>]    List window around I<line>.
7235 B<.>        Return to the executed line.
7236 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7237         I<filename> may be either the full name of the file, or a regular
7238         expression matching the full file name:
7239         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7240         Evals (with saved bodies) are considered to be filenames:
7241         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7242         (in the order of execution).
7243 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7244 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7245 B<L>        List all breakpoints and actions.
7246 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7247 B<t>        Toggle trace mode.
7248 B<t> I<expr>        Trace through execution of I<expr>.
7249 B<b> [I<line>] [I<condition>]
7250         Set breakpoint; I<line> defaults to the current execution line;
7251         I<condition> breaks if it evaluates to true, defaults to '1'.
7252 B<b> I<subname> [I<condition>]
7253         Set breakpoint at first line of subroutine.
7254 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7255 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7256 B<b> B<postpone> I<subname> [I<condition>]
7257         Set breakpoint at first line of subroutine after
7258         it is compiled.
7259 B<b> B<compile> I<subname>
7260         Stop after the subroutine is compiled.
7261 B<d> [I<line>]    Delete the breakpoint for I<line>.
7262 B<D>        Delete all breakpoints.
7263 B<a> [I<line>] I<command>
7264         Set an action to be done before the I<line> is executed;
7265         I<line> defaults to the current execution line.
7266         Sequence is: check for breakpoint/watchpoint, print line
7267         if necessary, do action, prompt user if necessary,
7268         execute line.
7269 B<a> [I<line>]    Delete the action for I<line>.
7270 B<A>        Delete all actions.
7271 B<W> I<expr>        Add a global watch-expression.
7272 B<W>        Delete all watch-expressions.
7273 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7274         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7275 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7276 B<x> I<expr>        Evals expression in list context, dumps the result.
7277 B<m> I<expr>        Evals expression in list context, prints methods callable
7278         on the first element of the result.
7279 B<m> I<class>        Prints methods callable via the given class.
7280
7281 B<<> ?            List Perl commands to run before each prompt.
7282 B<<> I<expr>        Define Perl command to run before each prompt.
7283 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7284 B<>> ?            List Perl commands to run after each prompt.
7285 B<>> I<expr>        Define Perl command to run after each prompt.
7286 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7287 B<{> I<db_command>    Define debugger command to run before each prompt.
7288 B<{> ?            List debugger commands to run before each prompt.
7289 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7290 B<$prc> I<number>    Redo a previous command (default previous command).
7291 B<$prc> I<-number>    Redo number'th-to-last command.
7292 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7293         See 'B<O> I<recallCommand>' too.
7294 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7295       . (
7296         $rc eq $sh
7297         ? ""
7298         : "
7299 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7300       ) . "
7301         See 'B<O> I<shellBang>' too.
7302 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7303 B<H> I<-number>    Display last number commands (default all).
7304 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7305 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7306 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7307 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7308 I<command>        Execute as a perl statement in current package.
7309 B<v>        Show versions of loaded modules.
7310 B<R>        Pure-man-restart of debugger, some of debugger state
7311         and command-line options may be lost.
7312         Currently the following settings are preserved:
7313         history, breakpoints and actions, debugger B<O>ptions
7314         and the following command-line options: I<-w>, I<-I>, I<-e>.
7315
7316 B<O> [I<opt>] ...    Set boolean option to true
7317 B<O> [I<opt>B<?>]    Query options
7318 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7319         Set options.  Use quotes in spaces in value.
7320     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7321     I<pager>            program for output of \"|cmd\";
7322     I<tkRunning>            run Tk while prompting (with ReadLine);
7323     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7324     I<inhibit_exit>        Allows stepping off the end of the script.
7325     I<ImmediateStop>        Debugger should stop as early as possible.
7326     I<RemotePort>            Remote hostname:port for remote debugging
7327   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7328     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7329     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7330     I<globPrint>             whether to print contents of globs;
7331     I<DumpDBFiles>         dump arrays holding debugged files;
7332     I<DumpPackages>         dump symbol tables of packages;
7333     I<DumpReused>             dump contents of \"reused\" addresses;
7334     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7335     I<bareStringify>         Do not print the overload-stringified value;
7336   Other options include:
7337     I<PrintRet>        affects printing of return value after B<r> command,
7338     I<frame>        affects printing messages on subroutine entry/exit.
7339     I<AutoTrace>    affects printing messages on possible breaking points.
7340     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7341     I<ornaments>     affects screen appearance of the command line.
7342     I<CreateTTY>     bits control attempts to create a new TTY on events:
7343             1: on fork()    2: debugger is started inside debugger
7344             4: on startup
7345     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7346     You can put additional initialization options I<TTY>, I<noTTY>,
7347     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7348     `B<R>' after you set them).
7349
7350 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7351 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7352 B<h h>        Summary of debugger commands.
7353 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7354         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7355         Set B<\$DB::doccmd> to change viewer.
7356
7357 Type `|h' for a paged display if this was too hard to read.
7358
7359 ";    # Fix balance of vi % matching: }}}}
7360
7361     #  note: tabs in the following section are not-so-helpful
7362     $pre580_summary = <<"END_SUM";
7363 I<List/search source lines:>               I<Control script execution:>
7364   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7365   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7366   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7367   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7368   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7369   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7370 I<Debugger controls:>                        B<L>           List break/watch/actions
7371   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7372   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7373   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7374   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7375   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7376   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7377   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7378   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7379 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7380   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7381   B<p> I<expr>         Print expression (uses script's current package).
7382   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7383   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7384   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7385   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7386 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7387 END_SUM
7388
7389     # ')}}; # Fix balance of vi % matching
7390
7391 } ## end sub sethelp
7392
7393 =head2 C<print_help()>
7394
7395 Most of what C<print_help> does is just text formatting. It finds the
7396 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7397 terminal control characters to simulate them (courtesy of
7398 <Term::ReadLine::TermCap>).
7399
7400 =cut
7401
7402 sub print_help {
7403     local $_ = shift;
7404
7405     # Restore proper alignment destroyed by eeevil I<> and B<>
7406     # ornaments: A pox on both their houses!
7407     #
7408     # A help command will have everything up to and including
7409     # the first tab sequence padded into a field 16 (or if indented 20)
7410     # wide.  If it's wider than that, an extra space will be added.
7411     s{
7412         ^                       # only matters at start of line
7413           ( \040{4} | \t )*     # some subcommands are indented
7414           ( < ?                 # so <CR> works
7415             [BI] < [^\t\n] + )  # find an eeevil ornament
7416           ( \t+ )               # original separation, discarded
7417           ( .* )                # this will now start (no earlier) than
7418                                 # column 16
7419     } {
7420         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7421         my $clean = $command;
7422         $clean =~ s/[BI]<([^>]*)>/$1/g;
7423
7424         # replace with this whole string:
7425         ($leadwhite ? " " x 4 : "")
7426       . $command
7427       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7428       . $text;
7429
7430     }mgex;
7431
7432     s{                          # handle bold ornaments
7433        B < ( [^>] + | > ) >
7434     } {
7435           $Term::ReadLine::TermCap::rl_term_set[2]
7436         . $1
7437         . $Term::ReadLine::TermCap::rl_term_set[3]
7438     }gex;
7439
7440     s{                         # handle italic ornaments
7441        I < ( [^>] + | > ) >
7442     } {
7443           $Term::ReadLine::TermCap::rl_term_set[0]
7444         . $1
7445         . $Term::ReadLine::TermCap::rl_term_set[1]
7446     }gex;
7447
7448     local $\ = '';
7449     print $OUT $_;
7450 } ## end sub print_help
7451
7452 =head2 C<fix_less>
7453
7454 This routine does a lot of gyrations to be sure that the pager is C<less>.
7455 It checks for C<less> masquerading as C<more> and records the result in
7456 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7457
7458 =cut
7459
7460 sub fix_less {
7461
7462     # We already know if this is set.
7463     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7464
7465     # Pager is less for sure.
7466     my $is_less = $pager =~ /\bless\b/;
7467     if ( $pager =~ /\bmore\b/ ) {
7468
7469         # Nope, set to more. See what's out there.
7470         my @st_more = stat('/usr/bin/more');
7471         my @st_less = stat('/usr/bin/less');
7472
7473         # is it really less, pretending to be more?
7474              $is_less = @st_more
7475           && @st_less
7476           && $st_more[0] == $st_less[0]
7477           && $st_more[1] == $st_less[1];
7478     } ## end if ($pager =~ /\bmore\b/)
7479
7480     # changes environment!
7481     # 'r' added so we don't do (slow) stats again.
7482     $ENV{LESS} .= 'r' if $is_less;
7483 } ## end sub fix_less
7484
7485 =head1 DIE AND WARN MANAGEMENT
7486
7487 =head2 C<diesignal>
7488
7489 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7490 to debug a debugger problem.
7491
7492 It does its best to report the error that occurred, and then forces the
7493 program, debugger, and everything to die.
7494
7495 =cut
7496
7497 sub diesignal {
7498
7499     # No entry/exit messages.
7500     local $frame = 0;
7501
7502     # No return value prints.
7503     local $doret = -2;
7504
7505     # set the abort signal handling to the default (just terminate).
7506     $SIG{'ABRT'} = 'DEFAULT';
7507
7508     # If we enter the signal handler recursively, kill myself with an
7509     # abort signal (so we just terminate).
7510     kill 'ABRT', $$ if $panic++;
7511
7512     # If we can show detailed info, do so.
7513     if ( defined &Carp::longmess ) {
7514
7515         # Don't recursively enter the warn handler, since we're carping.
7516         local $SIG{__WARN__} = '';
7517
7518         # Skip two levels before reporting traceback: we're skipping
7519         # mydie and confess.
7520         local $Carp::CarpLevel = 2;    # mydie + confess
7521
7522         # Tell us all about it.
7523         &warn( Carp::longmess("Signal @_") );
7524     }
7525
7526     # No Carp. Tell us about the signal as best we can.
7527     else {
7528         local $\ = '';
7529         print $DB::OUT "Got signal @_\n";
7530     }
7531
7532     # Drop dead.
7533     kill 'ABRT', $$;
7534 } ## end sub diesignal
7535
7536 =head2 C<dbwarn>
7537
7538 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7539 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7540
7541 =cut
7542
7543 sub dbwarn {
7544
7545     # No entry/exit trace.
7546     local $frame = 0;
7547
7548     # No return value printing.
7549     local $doret = -2;
7550
7551     # Turn off warn and die handling to prevent recursive entries to this
7552     # routine.
7553     local $SIG{__WARN__} = '';
7554     local $SIG{__DIE__}  = '';
7555
7556     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7557     # done yet), we may not be able to do a require.
7558     eval { require Carp }
7559       if defined $^S;    # If error/warning during compilation,
7560                          # require may be broken.
7561
7562     # Use the core warn() unless Carp loaded OK.
7563     CORE::warn( @_,
7564         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7565       return
7566       unless defined &Carp::longmess;
7567
7568     # Save the current values of $single and $trace, and then turn them off.
7569     my ( $mysingle, $mytrace ) = ( $single, $trace );
7570     $single = 0;
7571     $trace  = 0;
7572
7573     # We can call Carp::longmess without its being "debugged" (which we
7574     # don't want - we just want to use it!). Capture this for later.
7575     my $mess = Carp::longmess(@_);
7576
7577     # Restore $single and $trace to their original values.
7578     ( $single, $trace ) = ( $mysingle, $mytrace );
7579
7580     # Use the debugger's own special way of printing warnings to print
7581     # the stack trace message.
7582     &warn($mess);
7583 } ## end sub dbwarn
7584
7585 =head2 C<dbdie>
7586
7587 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7588 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7589 single stepping and tracing during the call to C<Carp::longmess> to avoid
7590 debugging it - we just want to use it.
7591
7592 If C<dieLevel> is zero, we let the program being debugged handle the
7593 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7594 the debugger takes over all exception handling, printing a backtrace and
7595 displaying the exception via its C<dbwarn()> routine.
7596
7597 =cut
7598
7599 sub dbdie {
7600     local $frame         = 0;
7601     local $doret         = -2;
7602     local $SIG{__DIE__}  = '';
7603     local $SIG{__WARN__} = '';
7604     my $i      = 0;
7605     my $ineval = 0;
7606     my $sub;
7607     if ( $dieLevel > 2 ) {
7608         local $SIG{__WARN__} = \&dbwarn;
7609         &warn(@_);    # Yell no matter what
7610         return;
7611     }
7612     if ( $dieLevel < 2 ) {
7613         die @_ if $^S;    # in eval propagate
7614     }
7615
7616     # The code used to check $^S to see if compiliation of the current thing
7617     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7618     eval { require Carp };
7619
7620     die( @_,
7621         "\nCannot print stack trace, load with -MCarp option to see stack" )
7622       unless defined &Carp::longmess;
7623
7624     # We do not want to debug this chunk (automatic disabling works
7625     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7626     # get the stack trace from Carp::longmess (if possible), restore $signal
7627     # and $trace, and then die with the stack trace.
7628     my ( $mysingle, $mytrace ) = ( $single, $trace );
7629     $single = 0;
7630     $trace  = 0;
7631     my $mess = "@_";
7632     {
7633
7634         package Carp;    # Do not include us in the list
7635         eval { $mess = Carp::longmess(@_); };
7636     }
7637     ( $single, $trace ) = ( $mysingle, $mytrace );
7638     die $mess;
7639 } ## end sub dbdie
7640
7641 =head2 C<warnlevel()>
7642
7643 Set the C<$DB::warnLevel> variable that stores the value of the
7644 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7645 results in the debugger taking over all warning handlers. Setting
7646 C<warnLevel> to zero leaves any warning handlers set up by the program
7647 being debugged in place.
7648
7649 =cut
7650
7651 sub warnLevel {
7652     if (@_) {
7653         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7654         $warnLevel = shift;
7655         if ($warnLevel) {
7656             $SIG{__WARN__} = \&DB::dbwarn;
7657         }
7658         elsif ($prevwarn) {
7659             $SIG{__WARN__} = $prevwarn;
7660         }
7661     } ## end if (@_)
7662     $warnLevel;
7663 } ## end sub warnLevel
7664
7665 =head2 C<dielevel>
7666
7667 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7668 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7669 zero lets you use your own C<die()> handler.
7670
7671 =cut
7672
7673 sub dieLevel {
7674     local $\ = '';
7675     if (@_) {
7676         $prevdie = $SIG{__DIE__} unless $dieLevel;
7677         $dieLevel = shift;
7678         if ($dieLevel) {
7679
7680             # Always set it to dbdie() for non-zero values.
7681             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7682
7683             # No longer exists, so don't try  to use it.
7684             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7685
7686             # If we've finished initialization, mention that stack dumps
7687             # are enabled, If dieLevel is 1, we won't stack dump if we die
7688             # in an eval().
7689             print $OUT "Stack dump during die enabled",
7690               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7691               if $I_m_init;
7692
7693             # XXX This is probably obsolete, given that diehard() is gone.
7694             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7695         } ## end if ($dieLevel)
7696
7697         # Put the old one back if there was one.
7698         elsif ($prevdie) {
7699             $SIG{__DIE__} = $prevdie;
7700             print $OUT "Default die handler restored.\n";
7701         }
7702     } ## end if (@_)
7703     $dieLevel;
7704 } ## end sub dieLevel
7705
7706 =head2 C<signalLevel>
7707
7708 Number three in a series: set C<signalLevel> to zero to keep your own
7709 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7710 takes over and handles them with C<DB::diesignal()>.
7711
7712 =cut
7713
7714 sub signalLevel {
7715     if (@_) {
7716         $prevsegv = $SIG{SEGV} unless $signalLevel;
7717         $prevbus  = $SIG{BUS}  unless $signalLevel;
7718         $signalLevel = shift;
7719         if ($signalLevel) {
7720             $SIG{SEGV} = \&DB::diesignal;
7721             $SIG{BUS}  = \&DB::diesignal;
7722         }
7723         else {
7724             $SIG{SEGV} = $prevsegv;
7725             $SIG{BUS}  = $prevbus;
7726         }
7727     } ## end if (@_)
7728     $signalLevel;
7729 } ## end sub signalLevel
7730
7731 =head1 SUBROUTINE DECODING SUPPORT
7732
7733 These subroutines are used during the C<x> and C<X> commands to try to
7734 produce as much information as possible about a code reference. They use
7735 L<Devel::Peek> to try to find the glob in which this code reference lives
7736 (if it does) - this allows us to actually code references which correspond
7737 to named subroutines (including those aliased via glob assignment).
7738
7739 =head2 C<CvGV_name()>
7740
7741 Wrapper for X<CvGV_name_or_bust>; tries to get the name of a reference
7742 via that routine. If this fails, return the reference again (when the
7743 reference is stringified, it'll come out as "SOMETHING(0X...)").
7744
7745 =cut
7746
7747 sub CvGV_name {
7748     my $in   = shift;
7749     my $name = CvGV_name_or_bust($in);
7750     defined $name ? $name : $in;
7751 }
7752
7753 =head2 C<CvGV_name_or_bust> I<coderef>
7754
7755 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7756 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7757 find a glob for this ref.
7758
7759 Returns "I<package>::I<glob name>" if the code ref is found in a glob.
7760
7761 =cut
7762
7763 sub CvGV_name_or_bust {
7764     my $in = shift;
7765     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7766     return unless ref $in;
7767     $in = \&$in;            # Hard reference...
7768     eval { require Devel::Peek; 1 } or return;
7769     my $gv = Devel::Peek::CvGV($in) or return;
7770     *$gv{PACKAGE} . '::' . *$gv{NAME};
7771 } ## end sub CvGV_name_or_bust
7772
7773 =head2 C<find_sub>
7774
7775 A utility routine used in various places; finds the file where a subroutine
7776 was defined, and returns that filename and a line-number range.
7777
7778 Tries to use X<@sub> first; if it can't find it there, it tries building a
7779 reference to the subroutine and uses X<CvGV_name_or_bust> to locate it,
7780 loading it into X<@sub> as a side effect (XXX I think). If it can't find it
7781 this way, it brute-force searches X<%sub>, checking for identical references.
7782
7783 =cut
7784
7785 sub find_sub {
7786     my $subr = shift;
7787     $sub{$subr} or do {
7788         return unless defined &$subr;
7789         my $name = CvGV_name_or_bust($subr);
7790         my $data;
7791         $data = $sub{$name} if defined $name;
7792         return $data if defined $data;
7793
7794         # Old stupid way...
7795         $subr = \&$subr;    # Hard reference
7796         my $s;
7797         for ( keys %sub ) {
7798             $s = $_, last if $subr eq \&$_;
7799         }
7800         $sub{$s} if $s;
7801       } ## end do
7802 } ## end sub find_sub
7803
7804 =head2 C<methods>
7805
7806 A subroutine that uses the utility function X<methods_via> to find all the
7807 methods in the class corresponding to the current reference and in
7808 C<UNIVERSAL>.
7809
7810 =cut
7811
7812 sub methods {
7813
7814     # Figure out the class - either this is the class or it's a reference
7815     # to something blessed into that class.
7816     my $class = shift;
7817     $class = ref $class if ref $class;
7818
7819     local %seen;
7820
7821     # Show the methods that this class has.
7822     methods_via( $class, '', 1 );
7823
7824     # Show the methods that UNIVERSAL has.
7825     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7826 } ## end sub methods
7827
7828 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7829
7830 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7831 all the parent class methods. C<$class> is the name of the next class to
7832 try; C<$prefix> is the message prefix, which gets built up as we go up the
7833 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7834 higher in the C<@ISA> tree, 0 if we should stop.
7835
7836 =cut
7837
7838 sub methods_via {
7839
7840     # If we've processed this class already, just quit.
7841     my $class = shift;
7842     return if $seen{$class}++;
7843
7844     # This is a package that is contributing the methods we're about to print.
7845     my $prefix  = shift;
7846     my $prepend = $prefix ? "via $prefix: " : '';
7847
7848     my $name;
7849     for $name (
7850
7851         # Keep if this is a defined subroutine in this class.
7852         grep { defined &{ ${"${class}::"}{$_} } }
7853
7854         # Extract from all the symbols in this class.
7855         sort keys %{"${class}::"}
7856       )
7857     {
7858
7859         # If we printed this already, skip it.
7860         next if $seen{$name}++;
7861
7862         # Print the new method name.
7863         local $\ = '';
7864         local $, = '';
7865         print $DB::OUT "$prepend$name\n";
7866     } ## end for $name (grep { defined...
7867
7868     # If the $crawl_upward argument is false, just quit here.
7869     return unless shift;
7870
7871     # $crawl_upward true: keep going up the tree.
7872     # Find all the classes this one is a subclass of.
7873     for $name ( @{"${class}::ISA"} ) {
7874
7875         # Set up the new prefix.
7876         $prepend = $prefix ? $prefix . " -> $name" : $name;
7877
7878         # Crawl up the tree and keep trying to crawl up.
7879         methods_via( $name, $prepend, 1 );
7880     }
7881 } ## end sub methods_via
7882
7883 =head2 C<setman> - figure out which command to use to show documentation
7884
7885 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
7886
7887 =cut
7888
7889 sub setman {
7890     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
7891       ? "man"         # O Happy Day!
7892       : "perldoc";    # Alas, poor unfortunates
7893 } ## end sub setman
7894
7895 =head2 C<runman> - run the appropriate command to show documentation
7896
7897 Accepts a man page name; runs the appropriate command to display it (set up
7898 during debugger initialization). Uses C<DB::system> to avoid mucking up the
7899 program's STDIN and STDOUT.
7900
7901 =cut
7902
7903 sub runman {
7904     my $page = shift;
7905     unless ($page) {
7906         &system("$doccmd $doccmd");
7907         return;
7908     }
7909
7910     # this way user can override, like with $doccmd="man -Mwhatever"
7911     # or even just "man " to disable the path check.
7912     unless ( $doccmd eq 'man' ) {
7913         &system("$doccmd $page");
7914         return;
7915     }
7916
7917     $page = 'perl' if lc($page) eq 'help';
7918
7919     require Config;
7920     my $man1dir = $Config::Config{'man1dir'};
7921     my $man3dir = $Config::Config{'man3dir'};
7922     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
7923     my $manpath = '';
7924     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
7925     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
7926     chop $manpath if $manpath;
7927
7928     # harmless if missing, I figure
7929     my $oldpath = $ENV{MANPATH};
7930     $ENV{MANPATH} = $manpath if $manpath;
7931     my $nopathopt = $^O =~ /dunno what goes here/;
7932     if (
7933         CORE::system(
7934             $doccmd,
7935
7936             # I just *know* there are men without -M
7937             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
7938             split ' ', $page
7939         )
7940       )
7941     {
7942         unless ( $page =~ /^perl\w/ ) {
7943 # do it this way because its easier to slurp in to keep up to date - clunky though.
7944 my @pods = qw(
7945     5004delta
7946     5005delta
7947     561delta
7948     56delta
7949     570delta
7950     571delta
7951     572delta
7952     573delta
7953     58delta
7954     581delta
7955     582delta
7956     583delta
7957     584delta
7958     590delta
7959     591delta
7960     592delta
7961     aix
7962     amiga
7963     apio
7964     api
7965     apollo
7966     artistic
7967     beos
7968     book
7969     boot
7970     bot
7971     bs2000
7972     call
7973     ce
7974     cheat
7975     clib
7976     cn
7977     compile
7978     cygwin
7979     data
7980     dbmfilter
7981     debguts
7982     debtut
7983     debug
7984     delta
7985     dgux
7986     diag
7987     doc
7988     dos
7989     dsc
7990     ebcdic
7991     embed
7992     epoc
7993     faq1
7994     faq2
7995     faq3
7996     faq4
7997     faq5
7998     faq6
7999     faq7
8000     faq8
8001     faq9
8002     faq
8003     filter
8004     fork
8005     form
8006     freebsd
8007     func
8008     gpl
8009     guts
8010     hack
8011     hist
8012     hpux
8013     hurd
8014     intern
8015     intro
8016     iol
8017     ipc
8018     irix
8019     jp
8020     ko
8021     lexwarn
8022     locale
8023     lol
8024     machten
8025     macos
8026     macosx
8027     mint
8028     modinstall
8029     modlib
8030     mod
8031     modstyle
8032     mpeix
8033     netware
8034     newmod
8035     number
8036     obj
8037     opentut
8038     op
8039     os2
8040     os390
8041     os400
8042     othrtut
8043     packtut
8044     plan9
8045     pod
8046     podspec
8047     port
8048     qnx
8049     ref
8050     reftut
8051     re
8052     requick
8053     reref
8054     retut
8055     run
8056     sec
8057     solaris
8058     style
8059     sub
8060     syn
8061     thrtut
8062     tie
8063     toc
8064     todo
8065     tooc
8066     toot
8067     trap
8068     tru64
8069     tw
8070     unicode
8071     uniintro
8072     util
8073     uts
8074     var
8075     vmesa
8076     vms
8077     vos
8078     win32
8079     xs
8080     xstut
8081 );
8082             if (grep { $page eq $_ } @pods) {
8083                 $page =~ s/^/perl/;
8084                 CORE::system( $doccmd,
8085                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8086                     $page );
8087             } ## end if (grep { $page eq $_...
8088         } ## end unless ($page =~ /^perl\w/)
8089     } ## end if (CORE::system($doccmd...
8090     if ( defined $oldpath ) {
8091         $ENV{MANPATH} = $manpath;
8092     }
8093     else {
8094         delete $ENV{MANPATH};
8095     }
8096 } ## end sub runman
8097
8098 #use Carp;                          # This did break, left for debugging
8099
8100 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8101
8102 Because of the way the debugger interface to the Perl core is designed, any
8103 debugger package globals that C<DB::sub()> requires have to be defined before
8104 any subroutines can be called. These are defined in the second C<BEGIN> block.
8105
8106 This block sets things up so that (basically) the world is sane
8107 before the debugger starts executing. We set up various variables that the
8108 debugger has to have set up before the Perl core starts running:
8109
8110 =over 4
8111
8112 =item * The debugger's own filehandles (copies of STD and STDOUT for now).
8113
8114 =item * Characters for shell escapes, the recall command, and the history command.
8115
8116 =item * The maximum recursion depth.
8117
8118 =item * The size of a C<w> command's window.
8119
8120 =item * The before-this-line context to be printed in a C<v> (view a window around this line) command.
8121
8122 =item * The fact that we're not in a sub at all right now.
8123
8124 =item * The default SIGINT handler for the debugger.
8125
8126 =item * The appropriate value of the flag in C<$^D> that says the debugger is running
8127
8128 =item * The current debugger recursion level
8129
8130 =item * The list of postponed (XXX define) items and the C<$single> stack
8131
8132 =item * That we want no return values and no subroutine entry/exit trace.
8133
8134 =back
8135
8136 =cut
8137
8138 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8139
8140 BEGIN {    # This does not compile, alas. (XXX eh?)
8141     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8142     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8143
8144     # Define characters used by command parsing.
8145     $sh       = '!';      # Shell escape (does not work)
8146     $rc       = ',';      # Recall command (does not work)
8147     @hist     = ('?');    # Show history (does not work)
8148     @truehist = ();       # Can be saved for replay (per session)
8149
8150     # This defines the point at which you get the 'deep recursion'
8151     # warning. It MUST be defined or the debugger will not load.
8152     $deep = 100;
8153
8154     # Number of lines around the current one that are shown in the
8155     # 'w' command.
8156     $window = 10;
8157
8158     # How much before-the-current-line context the 'v' command should
8159     # use in calculating the start of the window it will display.
8160     $preview = 3;
8161
8162     # We're not in any sub yet, but we need this to be a defined value.
8163     $sub = '';
8164
8165     # Set up the debugger's interrupt handler. It simply sets a flag
8166     # ($signal) that DB::DB() will check before each command is executed.
8167     $SIG{INT} = \&DB::catch;
8168
8169     # The following lines supposedly, if uncommented, allow the debugger to
8170     # debug itself. Perhaps we can try that someday.
8171     # This may be enabled to debug debugger:
8172     #$warnLevel = 1 unless defined $warnLevel;
8173     #$dieLevel = 1 unless defined $dieLevel;
8174     #$signalLevel = 1 unless defined $signalLevel;
8175
8176     # This is the flag that says "a debugger is running, please call
8177     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8178     # execute anything in the user's context, because we always want to
8179     # get control back.
8180     $db_stop = 0;          # Compiler warning ...
8181     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8182
8183     # This variable records how many levels we're nested in debugging. Used
8184     # Used in the debugger prompt, and in determining whether it's all over or
8185     # not.
8186     $level = 0;            # Level of recursive debugging
8187
8188     # "Triggers bug (?) in perl if we postpone this until runtime."
8189     # XXX No details on this yet, or whether we should fix the bug instead
8190     # of work around it. Stay tuned.
8191     @postponed = @stack = (0);
8192
8193     # Used to track the current stack depth using the auto-stacked-variable
8194     # trick.
8195     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8196
8197     # Don't print return values on exiting a subroutine.
8198     $doret = -2;
8199
8200     # No extry/exit tracing.
8201     $frame = 0;
8202
8203 } ## end BEGIN
8204
8205 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8206
8207 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8208
8209 =head2 db_complete
8210
8211 C<readline> support - adds command completion to basic C<readline>.
8212
8213 Returns a list of possible completions to C<readline> when invoked. C<readline>
8214 will print the longest common substring following the text already entered.
8215
8216 If there is only a single possible completion, C<readline> will use it in full.
8217
8218 This code uses C<map> and C<grep> heavily to create lists of possible
8219 completion. Think LISP in this section.
8220
8221 =cut
8222
8223 sub db_complete {
8224
8225     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8226     # $text is the text to be completed.
8227     # $line is the incoming line typed by the user.
8228     # $start is the start of the text to be completed in the incoming line.
8229     my ( $text, $line, $start ) = @_;
8230
8231     # Save the initial text.
8232     # The search pattern is current package, ::, extract the next qualifier
8233     # Prefix and pack are set to undef.
8234     my ( $itext, $search, $prefix, $pack ) =
8235       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8236
8237 =head3 C<b postpone|compile>
8238
8239 =over 4
8240
8241 =item * Find all the subroutines that might match in this package
8242
8243 =item * Add "postpone", "load", and "compile" as possibles (we may be completing the keyword itself
8244
8245 =item * Include all the rest of the subs that are known
8246
8247 =item * C<grep> out the ones that match the text we have so far
8248
8249 =item * Return this as the list of possible completions
8250
8251 =back
8252
8253 =cut
8254
8255     return sort grep /^\Q$text/, ( keys %sub ),
8256       qw(postpone load compile),    # subroutines
8257       ( map { /$search/ ? ($1) : () } keys %sub )
8258       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8259
8260 =head3 C<b load>
8261
8262 Get all the possible files from @INC as it currently stands and
8263 select the ones that match the text so far.
8264
8265 =cut
8266
8267     return sort grep /^\Q$text/, values %INC    # files
8268       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8269
8270 =head3  C<V> (list variable) and C<m> (list modules)
8271
8272 There are two entry points for these commands:
8273
8274 =head4 Unqualified package names
8275
8276 Get the top-level packages and grab everything that matches the text
8277 so far. For each match, recursively complete the partial packages to
8278 get all possible matching packages. Return this sorted list.
8279
8280 =cut
8281
8282     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8283       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8284       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8285
8286 =head4 Qualified package names
8287
8288 Take a partially-qualified package and find all subpackages for it
8289 by getting all the subpackages for the package so far, matching all
8290 the subpackages against the text, and discarding all of them which
8291 start with 'main::'. Return this list.
8292
8293 =cut
8294
8295     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8296       grep !/^main::/, grep /^\Q$text/,
8297       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8298       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8299       and $text =~ /^(.*[^:])::?(\w*)$/
8300       and $prefix = $1;
8301
8302 =head3 C<f> - switch files
8303
8304 Here, we want to get a fully-qualified filename for the C<f> command.
8305 Possibilities are:
8306
8307 =over 4
8308
8309 =item 1. The original source file itself
8310
8311 =item 2. A file from C<@INC>
8312
8313 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8314
8315 =back
8316
8317 =cut
8318
8319     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8320            # We might possibly want to switch to an eval (which has a "filename"
8321            # like '(eval 9)'), so we may need to clean up the completion text
8322            # before proceeding.
8323         $prefix = length($1) - length($text);
8324         $text   = $1;
8325
8326 =pod
8327
8328 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8329 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8330 out of C<%main::>, add the initial source file, and extract the ones that
8331 match the completion text so far.
8332
8333 =cut
8334
8335         return sort
8336           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8337           $0;
8338     } ## end if ($line =~ /^\|*f\s+(.*)/)
8339
8340 =head3 Subroutine name completion
8341
8342 We look through all of the defined subs (the keys of C<%sub>) and
8343 return both all the possible matches to the subroutine name plus
8344 all the matches qualified to the current package.
8345
8346 =cut
8347
8348     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8349         $text = substr $text, 1;
8350         $prefix = "&";
8351         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8352           (
8353             map { /$search/ ? ($1) : () }
8354               keys %sub
8355           );
8356     } ## end if ((substr $text, 0, ...
8357
8358 =head3  Scalar, array, and hash completion: partially qualified package
8359
8360 Much like the above, except we have to do a little more cleanup:
8361
8362 =cut
8363
8364     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8365
8366 =pod
8367
8368 =over 4
8369
8370 =item * Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8371
8372 =cut
8373
8374         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8375
8376 =pod
8377
8378 =item * Figure out the prefix vs. what needs completing.
8379
8380 =cut
8381
8382         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8383         $text   = $2;
8384
8385 =pod
8386
8387 =item * Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8388
8389 =cut
8390
8391         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8392           keys %$pack;
8393
8394 =pod
8395
8396 =item * If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8397
8398 =cut
8399
8400         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8401             return db_complete( $out[0], $line, $start );
8402         }
8403
8404         # Return the list of possibles.
8405         return sort @out;
8406
8407     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8408
8409 =pod
8410
8411 =back
8412
8413 =head3 Symbol completion: current package or package C<main>.
8414
8415 =cut
8416
8417     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8418
8419 =pod
8420
8421 =over 4
8422
8423 =item * If it's C<main>, delete main to just get C<::> leading.
8424
8425 =cut
8426
8427         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8428
8429 =pod
8430
8431 =item * We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8432
8433 =cut
8434
8435         $prefix = substr $text, 0, 1;
8436         $text   = substr $text, 1;
8437
8438 =pod
8439
8440 =item * If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8441
8442 =cut
8443
8444         my @out = map "$prefix$_", grep /^\Q$text/,
8445           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8446           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8447
8448 =item * If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8449
8450 =back
8451
8452 =cut
8453
8454         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8455             return db_complete( $out[0], $line, $start );
8456         }
8457
8458         # Return the list of possibles.
8459         return sort @out;
8460     } ## end if ($text =~ /^[\$@%]/)
8461
8462 =head3 Options
8463
8464 We use C<option_val()> to look up the current value of the option. If there's
8465 only a single value, we complete the command in such a way that it is a
8466 complete command for setting the option in question. If there are multiple
8467 possible values, we generate a command consisting of the option plus a trailing
8468 question mark, which, if executed, will list the current value of the option.
8469
8470 =cut
8471
8472     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8473     {    # Options after space
8474            # We look for the text to be matched in the list of possible options,
8475            # and fetch the current value.
8476         my @out = grep /^\Q$text/, @options;
8477         my $val = option_val( $out[0], undef );
8478
8479         # Set up a 'query option's value' command.
8480         my $out = '? ';
8481         if ( not defined $val or $val =~ /[\n\r]/ ) {
8482
8483             # There's really nothing else we can do.
8484         }
8485
8486         # We have a value. Create a proper option-setting command.
8487         elsif ( $val =~ /\s/ ) {
8488
8489             # XXX This may be an extraneous variable.
8490             my $found;
8491
8492             # We'll want to quote the string (because of the embedded
8493             # whtespace), but we want to make sure we don't end up with
8494             # mismatched quote characters. We try several possibilities.
8495             foreach $l ( split //, qq/\"\'\#\|/ ) {
8496
8497                 # If we didn't find this quote character in the value,
8498                 # quote it using this quote character.
8499                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8500             }
8501         } ## end elsif ($val =~ /\s/)
8502
8503         # Don't need any quotes.
8504         else {
8505             $out = "=$val ";
8506         }
8507
8508         # If there were multiple possible values, return '? ', which
8509         # makes the command into a query command. If there was just one,
8510         # have readline append that.
8511         $rl_attribs->{completer_terminator_character} =
8512           ( @out == 1 ? $out : '? ' );
8513
8514         # Return list of possibilities.
8515         return sort @out;
8516     } ## end if ((substr $line, 0, ...
8517
8518 =head3 Filename completion
8519
8520 For entering filenames. We simply call C<readline>'s C<filename_list()>
8521 method with the completion text to get the possible completions.
8522
8523 =cut
8524
8525     return $term->filename_list($text);    # filenames
8526
8527 } ## end sub db_complete
8528
8529 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8530
8531 Functions that possibly ought to be somewhere else.
8532
8533 =head2 end_report
8534
8535 Say we're done.
8536
8537 =cut
8538
8539 sub end_report {
8540     local $\ = '';
8541     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8542 }
8543
8544 =head2 clean_ENV
8545
8546 If we have $ini_pids, save it in the environment; else remove it from the
8547 environment. Used by the C<R> (restart) command.
8548
8549 =cut
8550
8551 sub clean_ENV {
8552     if ( defined($ini_pids) ) {
8553         $ENV{PERLDB_PIDS} = $ini_pids;
8554     }
8555     else {
8556         delete( $ENV{PERLDB_PIDS} );
8557     }
8558 } ## end sub clean_ENV
8559
8560 # PERLDBf_... flag names from perl.h
8561 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8562
8563 BEGIN {
8564     %DollarCaretP_flags = (
8565         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8566         PERLDBf_LINE      => 0x02,     # Keep line #
8567         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8568         PERLDBf_INTER     => 0x08,     # Preserve more data
8569         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8570         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8571         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8572         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8573         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8574         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8575         PERLDBf_ASSERTION => 0x400,    # Debug assertion subs enter/exit
8576         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO, _ASSERTION
8577     );
8578
8579     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8580 }
8581
8582 sub parse_DollarCaretP_flags {
8583     my $flags = shift;
8584     $flags =~ s/^\s+//;
8585     $flags =~ s/\s+$//;
8586     my $acu = 0;
8587     foreach my $f ( split /\s*\|\s*/, $flags ) {
8588         my $value;
8589         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8590             $value = hex $1;
8591         }
8592         elsif ( $f =~ /^(\d+)$/ ) {
8593             $value = int $1;
8594         }
8595         elsif ( $f =~ /^DEFAULT$/i ) {
8596             $value = $DollarCaretP_flags{PERLDB_ALL};
8597         }
8598         else {
8599             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8600             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8601             unless ( defined $value ) {
8602                 print $OUT (
8603                     "Unrecognized \$^P flag '$f'!\n",
8604                     "Acceptable flags are: "
8605                       . join( ', ', sort keys %DollarCaretP_flags ),
8606                     ", and hexadecimal and decimal numbers.\n"
8607                 );
8608                 return undef;
8609             }
8610         }
8611         $acu |= $value;
8612     }
8613     $acu;
8614 }
8615
8616 sub expand_DollarCaretP_flags {
8617     my $DollarCaretP = shift;
8618     my @bits         = (
8619         map {
8620             my $n = ( 1 << $_ );
8621             ( $DollarCaretP & $n )
8622               ? ( $DollarCaretP_flags_r{$n}
8623                   || sprintf( '0x%x', $n ) )
8624               : ()
8625           } 0 .. 31
8626     );
8627     return @bits ? join( '|', @bits ) : 0;
8628 }
8629
8630 =item rerun
8631
8632 Rerun the current session to:
8633
8634     rerun        current position
8635
8636     rerun 4      command number 4
8637
8638     rerun -4     current command minus 4 (go back 4 steps)
8639
8640 Whether this always makes sense, in the current context is unknowable, and is
8641 in part left as a useful exersize for the reader.  This sub returns the
8642 appropriate arguments to rerun the current session.
8643
8644 =cut
8645
8646 sub rerun {
8647     my $i = shift;
8648     my @args;
8649     pop(@truehist);                      # strim
8650     unless (defined $truehist[$i]) {
8651         print "Unable to return to non-existent command: $i\n";
8652     } else {
8653         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8654         my @temp = @truehist;            # store
8655         push(@DB::typeahead, @truehist); # saved
8656         @truehist = @hist = ();          # flush
8657         @args = &restart();              # setup
8658         &get_list("PERLDB_HIST");        # clean
8659         &set_list("PERLDB_HIST", @temp); # reset
8660     }
8661     return @args;
8662 }
8663
8664 =item restart
8665
8666 Restarting the debugger is a complex operation that occurs in several phases.
8667 First, we try to reconstruct the command line that was used to invoke Perl
8668 and the debugger.
8669
8670 =cut
8671
8672 sub restart {
8673     # I may not be able to resurrect you, but here goes ...
8674     print $OUT
8675 "Warning: some settings and command-line options may be lost!\n";
8676     my ( @script, @flags, $cl );
8677
8678     # If warn was on before, turn it on again.
8679     push @flags, '-w' if $ini_warn;
8680     if ( $ini_assertion and @{^ASSERTING} ) {
8681         push @flags,
8682           ( map { /\:\^\(\?\:(.*)\)\$\)/ ? "-A$1" : "-A$_" }
8683               @{^ASSERTING} );
8684     }
8685
8686     # Rebuild the -I flags that were on the initial
8687     # command line.
8688     for (@ini_INC) {
8689         push @flags, '-I', $_;
8690     }
8691
8692     # Turn on taint if it was on before.
8693     push @flags, '-T' if ${^TAINT};
8694
8695     # Arrange for setting the old INC:
8696     # Save the current @init_INC in the environment.
8697     set_list( "PERLDB_INC", @ini_INC );
8698
8699     # If this was a perl one-liner, go to the "file"
8700     # corresponding to the one-liner read all the lines
8701     # out of it (except for the first one, which is going
8702     # to be added back on again when 'perl -d' runs: that's
8703     # the 'require perl5db.pl;' line), and add them back on
8704     # to the command line to be executed.
8705     if ( $0 eq '-e' ) {
8706         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8707             chomp( $cl = ${'::_<-e'}[$_] );
8708             push @script, '-e', $cl;
8709         }
8710     } ## end if ($0 eq '-e')
8711
8712     # Otherwise we just reuse the original name we had
8713     # before.
8714     else {
8715         @script = $0;
8716     }
8717
8718 =pod
8719
8720 After the command line  has been reconstructed, the next step is to save
8721 the debugger's status in environment variables. The C<DB::set_list> routine
8722 is used to save aggregate variables (both hashes and arrays); scalars are
8723 just popped into environment variables directly.
8724
8725 =cut
8726
8727     # If the terminal supported history, grab it and
8728     # save that in the environment.
8729     set_list( "PERLDB_HIST",
8730           $term->Features->{getHistory}
8731         ? $term->GetHistory
8732         : @hist );
8733
8734     # Find all the files that were visited during this
8735     # session (i.e., the debugger had magic hashes
8736     # corresponding to them) and stick them in the environment.
8737     my @had_breakpoints = keys %had_breakpoints;
8738     set_list( "PERLDB_VISITED", @had_breakpoints );
8739
8740     # Save the debugger options we chose.
8741     set_list( "PERLDB_OPT", %option );
8742     # set_list( "PERLDB_OPT", options2remember() );
8743
8744     # Save the break-on-loads.
8745     set_list( "PERLDB_ON_LOAD", %break_on_load );
8746
8747 =pod
8748
8749 The most complex part of this is the saving of all of the breakpoints. They
8750 can live in an awful lot of places, and we have to go through all of them,
8751 find the breakpoints, and then save them in the appropriate environment
8752 variable via C<DB::set_list>.
8753
8754 =cut
8755
8756     # Go through all the breakpoints and make sure they're
8757     # still valid.
8758     my @hard;
8759     for ( 0 .. $#had_breakpoints ) {
8760
8761         # We were in this file.
8762         my $file = $had_breakpoints[$_];
8763
8764         # Grab that file's magic line hash.
8765         *dbline = $main::{ '_<' . $file };
8766
8767         # Skip out if it doesn't exist, or if the breakpoint
8768         # is in a postponed file (we'll do postponed ones
8769         # later).
8770         next unless %dbline or $postponed_file{$file};
8771
8772         # In an eval. This is a little harder, so we'll
8773         # do more processing on that below.
8774         ( push @hard, $file ), next
8775           if $file =~ /^\(\w*eval/;
8776
8777         # XXX I have no idea what this is doing. Yet.
8778         my @add;
8779         @add = %{ $postponed_file{$file} }
8780           if $postponed_file{$file};
8781
8782         # Save the list of all the breakpoints for this file.
8783         set_list( "PERLDB_FILE_$_", %dbline, @add );
8784     } ## end for (0 .. $#had_breakpoints)
8785
8786     # The breakpoint was inside an eval. This is a little
8787     # more difficult. XXX and I don't understand it.
8788     for (@hard) {
8789         # Get over to the eval in question.
8790         *dbline = $main::{ '_<' . $_ };
8791         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8792         for $sub ( keys %sub ) {
8793             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8794             $subs{$sub} = [ $1, $2 ];
8795         }
8796         unless (%subs) {
8797             print $OUT
8798               "No subroutines in $_, ignoring breakpoints.\n";
8799             next;
8800         }
8801       LINES: for $line ( keys %dbline ) {
8802
8803             # One breakpoint per sub only:
8804             my ( $offset, $sub, $found );
8805           SUBS: for $sub ( keys %subs ) {
8806                 if (
8807                     $subs{$sub}->[1] >=
8808                     $line    # Not after the subroutine
8809                     and (
8810                         not defined $offset    # Not caught
8811                         or $offset < 0
8812                     )
8813                   )
8814                 {                              # or badly caught
8815                     $found  = $sub;
8816                     $offset = $line - $subs{$sub}->[0];
8817                     $offset = "+$offset", last SUBS
8818                       if $offset >= 0;
8819                 } ## end if ($subs{$sub}->[1] >=...
8820             } ## end for $sub (keys %subs)
8821             if ( defined $offset ) {
8822                 $postponed{$found} =
8823                   "break $offset if $dbline{$line}";
8824             }
8825             else {
8826                 print $OUT
8827 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
8828             }
8829         } ## end for $line (keys %dbline)
8830     } ## end for (@hard)
8831
8832     # Save the other things that don't need to be
8833     # processed.
8834     set_list( "PERLDB_POSTPONE",  %postponed );
8835     set_list( "PERLDB_PRETYPE",   @$pretype );
8836     set_list( "PERLDB_PRE",       @$pre );
8837     set_list( "PERLDB_POST",      @$post );
8838     set_list( "PERLDB_TYPEAHEAD", @typeahead );
8839
8840     # We are oficially restarting.
8841     $ENV{PERLDB_RESTART} = 1;
8842
8843     # We are junking all child debuggers.
8844     delete $ENV{PERLDB_PIDS};    # Restore ini state
8845
8846     # Set this back to the initial pid.
8847     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
8848
8849 =pod
8850
8851 After all the debugger status has been saved, we take the command we built up
8852 and then return it, so we can C<exec()> it. The debugger will spot the
8853 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
8854 from the environment.
8855
8856 =cut
8857
8858     # And run Perl again. Add the "-d" flag, all the
8859     # flags we built up, the script (whether a one-liner
8860     # or a file), add on the -emacs flag for a slave editor,
8861     # and then the old arguments.
8862
8863     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
8864
8865 };  # end restart
8866
8867 =head1 END PROCESSING - THE C<END> BLOCK
8868
8869 Come here at the very end of processing. We want to go into a
8870 loop where we allow the user to enter commands and interact with the
8871 debugger, but we don't want anything else to execute.
8872
8873 First we set the C<$finished> variable, so that some commands that
8874 shouldn't be run after the end of program quit working.
8875
8876 We then figure out whether we're truly done (as in the user entered a C<q>
8877 command, or we finished execution while running nonstop). If we aren't,
8878 we set C<$single> to 1 (causing the debugger to get control again).
8879
8880 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...">
8881 message and returns control to the debugger. Repeat.
8882
8883 When the user finally enters a C<q> command, C<$fall_off_end> is set to
8884 1 and the C<END> block simply exits with C<$single> set to 0 (don't
8885 break, run to completion.).
8886
8887 =cut
8888
8889 END {
8890     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
8891     $fall_off_end = 1 unless $inhibit_exit;
8892
8893     # Do not stop in at_exit() and destructors on exit:
8894     $DB::single = !$fall_off_end && !$runnonstop;
8895     DB::fake::at_exit() unless $fall_off_end or $runnonstop;
8896 } ## end END
8897
8898 =head1 PRE-5.8 COMMANDS
8899
8900 Some of the commands changed function quite a bit in the 5.8 command
8901 realignment, so much so that the old code had to be replaced completely.
8902 Because we wanted to retain the option of being able to go back to the
8903 former command set, we moved the old code off to this section.
8904
8905 There's an awful lot of duplicated code here. We've duplicated the
8906 comments to keep things clear.
8907
8908 =head2 Null command
8909
8910 Does nothing. Used to 'turn off' commands.
8911
8912 =cut
8913
8914 sub cmd_pre580_null {
8915
8916     # do nothing...
8917 }
8918
8919 =head2 Old C<a> command.
8920
8921 This version added actions if you supplied them, and deleted them
8922 if you didn't.
8923
8924 =cut
8925
8926 sub cmd_pre580_a {
8927     my $xcmd = shift;
8928     my $cmd  = shift;
8929
8930     # Argument supplied. Add the action.
8931     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
8932
8933         # If the line isn't there, use the current line.
8934         $i = $1 || $line;
8935         $j = $2;
8936
8937         # If there is an action ...
8938         if ( length $j ) {
8939
8940             # ... but the line isn't breakable, skip it.
8941             if ( $dbline[$i] == 0 ) {
8942                 print $OUT "Line $i may not have an action.\n";
8943             }
8944             else {
8945
8946                 # ... and the line is breakable:
8947                 # Mark that there's an action in this file.
8948                 $had_breakpoints{$filename} |= 2;
8949
8950                 # Delete any current action.
8951                 $dbline{$i} =~ s/\0[^\0]*//;
8952
8953                 # Add the new action, continuing the line as needed.
8954                 $dbline{$i} .= "\0" . action($j);
8955             }
8956         } ## end if (length $j)
8957
8958         # No action supplied.
8959         else {
8960
8961             # Delete the action.
8962             $dbline{$i} =~ s/\0[^\0]*//;
8963
8964             # Mark as having no break or action if nothing's left.
8965             delete $dbline{$i} if $dbline{$i} eq '';
8966         }
8967     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
8968 } ## end sub cmd_pre580_a
8969
8970 =head2 Old C<b> command
8971
8972 Add breakpoints.
8973
8974 =cut
8975
8976 sub cmd_pre580_b {
8977     my $xcmd   = shift;
8978     my $cmd    = shift;
8979     my $dbline = shift;
8980
8981     # Break on load.
8982     if ( $cmd =~ /^load\b\s*(.*)/ ) {
8983         my $file = $1;
8984         $file =~ s/\s+$//;
8985         &cmd_b_load($file);
8986     }
8987
8988     # b compile|postpone <some sub> [<condition>]
8989     # The interpreter actually traps this one for us; we just put the
8990     # necessary condition in the %postponed hash.
8991     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
8992
8993         # Capture the condition if there is one. Make it true if none.
8994         my $cond = length $3 ? $3 : '1';
8995
8996         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
8997         # if it was 'compile'.
8998         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
8999
9000         # De-Perl4-ify the name - ' separators to ::.
9001         $subname =~ s/\'/::/g;
9002
9003         # Qualify it into the current package unless it's already qualified.
9004         $subname = "${'package'}::" . $subname
9005           unless $subname =~ /::/;
9006
9007         # Add main if it starts with ::.
9008         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9009
9010         # Save the break type for this sub.
9011         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9012     } ## end elsif ($cmd =~ ...
9013
9014     # b <sub name> [<condition>]
9015     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9016         my $subname = $1;
9017         my $cond = length $2 ? $2 : '1';
9018         &cmd_b_sub( $subname, $cond );
9019     }
9020
9021     # b <line> [<condition>].
9022     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9023         my $i = $1 || $dbline;
9024         my $cond = length $2 ? $2 : '1';
9025         &cmd_b_line( $i, $cond );
9026     }
9027 } ## end sub cmd_pre580_b
9028
9029 =head2 Old C<D> command.
9030
9031 Delete all breakpoints unconditionally.
9032
9033 =cut
9034
9035 sub cmd_pre580_D {
9036     my $xcmd = shift;
9037     my $cmd  = shift;
9038     if ( $cmd =~ /^\s*$/ ) {
9039         print $OUT "Deleting all breakpoints...\n";
9040
9041         # %had_breakpoints lists every file that had at least one
9042         # breakpoint in it.
9043         my $file;
9044         for $file ( keys %had_breakpoints ) {
9045
9046             # Switch to the desired file temporarily.
9047             local *dbline = $main::{ '_<' . $file };
9048
9049             my $max = $#dbline;
9050             my $was;
9051
9052             # For all lines in this file ...
9053             for ( $i = 1 ; $i <= $max ; $i++ ) {
9054
9055                 # If there's a breakpoint or action on this line ...
9056                 if ( defined $dbline{$i} ) {
9057
9058                     # ... remove the breakpoint.
9059                     $dbline{$i} =~ s/^[^\0]+//;
9060                     if ( $dbline{$i} =~ s/^\0?$// ) {
9061
9062                         # Remove the entry altogether if no action is there.
9063                         delete $dbline{$i};
9064                     }
9065                 } ## end if (defined $dbline{$i...
9066             } ## end for ($i = 1 ; $i <= $max...
9067
9068             # If, after we turn off the "there were breakpoints in this file"
9069             # bit, the entry in %had_breakpoints for this file is zero,
9070             # we should remove this file from the hash.
9071             if ( not $had_breakpoints{$file} &= ~1 ) {
9072                 delete $had_breakpoints{$file};
9073             }
9074         } ## end for $file (keys %had_breakpoints)
9075
9076         # Kill off all the other breakpoints that are waiting for files that
9077         # haven't been loaded yet.
9078         undef %postponed;
9079         undef %postponed_file;
9080         undef %break_on_load;
9081     } ## end if ($cmd =~ /^\s*$/)
9082 } ## end sub cmd_pre580_D
9083
9084 =head2 Old C<h> command
9085
9086 Print help. Defaults to printing the long-form help; the 5.8 version
9087 prints the summary by default.
9088
9089 =cut
9090
9091 sub cmd_pre580_h {
9092     my $xcmd = shift;
9093     my $cmd  = shift;
9094
9095     # Print the *right* help, long format.
9096     if ( $cmd =~ /^\s*$/ ) {
9097         print_help($pre580_help);
9098     }
9099
9100     # 'h h' - explicitly-requested summary.
9101     elsif ( $cmd =~ /^h\s*/ ) {
9102         print_help($pre580_summary);
9103     }
9104
9105     # Find and print a command's help.
9106     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9107         my $asked  = $1;                   # for proper errmsg
9108         my $qasked = quotemeta($asked);    # for searching
9109                                            # XXX: finds CR but not <CR>
9110         if (
9111             $pre580_help =~ /^
9112                               <?           # Optional '<'
9113                               (?:[IB]<)    # Optional markup
9114                               $qasked      # The command name
9115                             /mx
9116           )
9117         {
9118
9119             while (
9120                 $pre580_help =~ /^
9121                                   (             # The command help:
9122                                    <?           # Optional '<'
9123                                    (?:[IB]<)    # Optional markup
9124                                    $qasked      # The command name
9125                                    ([\s\S]*?)   # Lines starting with tabs
9126                                    \n           # Final newline
9127                                   )
9128                                   (?!\s)/mgx
9129               )    # Line not starting with space
9130                    # (Next command's help)
9131             {
9132                 print_help($1);
9133             }
9134         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9135
9136         # Help not found.
9137         else {
9138             print_help("B<$asked> is not a debugger command.\n");
9139         }
9140     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9141 } ## end sub cmd_pre580_h
9142
9143 =head2 Old C<W> command
9144
9145 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9146
9147 =cut
9148
9149 sub cmd_pre580_W {
9150     my $xcmd = shift;
9151     my $cmd  = shift;
9152
9153     # Delete all watch expressions.
9154     if ( $cmd =~ /^$/ ) {
9155
9156         # No watching is going on.
9157         $trace &= ~2;
9158
9159         # Kill all the watch expressions and values.
9160         @to_watch = @old_watch = ();
9161     }
9162
9163     # Add a watch expression.
9164     elsif ( $cmd =~ /^(.*)/s ) {
9165
9166         # add it to the list to be watched.
9167         push @to_watch, $1;
9168
9169         # Get the current value of the expression.
9170         # Doesn't handle expressions returning list values!
9171         $evalarg = $1;
9172         my ($val) = &eval;
9173         $val = ( defined $val ) ? "'$val'" : 'undef';
9174
9175         # Save it.
9176         push @old_watch, $val;
9177
9178         # We're watching stuff.
9179         $trace |= 2;
9180
9181     } ## end elsif ($cmd =~ /^(.*)/s)
9182 } ## end sub cmd_pre580_W
9183
9184 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9185
9186 The debugger used to have a bunch of nearly-identical code to handle
9187 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9188 C<cmd_prepost> unify all this into one set of code to handle the
9189 appropriate actions.
9190
9191 =head2 C<cmd_pre590_prepost>
9192
9193 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9194 do something destructive. In pre 5.8 debuggers, the default action was to
9195 delete all the actions.
9196
9197 =cut
9198
9199 sub cmd_pre590_prepost {
9200     my $cmd    = shift;
9201     my $line   = shift || '*';
9202     my $dbline = shift;
9203
9204     return &cmd_prepost( $cmd, $line, $dbline );
9205 } ## end sub cmd_pre590_prepost
9206
9207 =head2 C<cmd_prepost>
9208
9209 Actually does all the handling foe C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9210 Since the lists of actions are all held in arrays that are pointed to by
9211 references anyway, all we have to do is pick the right array reference and
9212 then use generic code to all, delete, or list actions.
9213
9214 =cut
9215
9216 sub cmd_prepost {
9217     my $cmd = shift;
9218
9219     # No action supplied defaults to 'list'.
9220     my $line = shift || '?';
9221
9222     # Figure out what to put in the prompt.
9223     my $which = '';
9224
9225     # Make sure we have some array or another to address later.
9226     # This means that if ssome reason the tests fail, we won't be
9227     # trying to stash actions or delete them from the wrong place.
9228     my $aref = [];
9229
9230     # < - Perl code to run before prompt.
9231     if ( $cmd =~ /^\</o ) {
9232         $which = 'pre-perl';
9233         $aref  = $pre;
9234     }
9235
9236     # > - Perl code to run after prompt.
9237     elsif ( $cmd =~ /^\>/o ) {
9238         $which = 'post-perl';
9239         $aref  = $post;
9240     }
9241
9242     # { - first check for properly-balanced braces.
9243     elsif ( $cmd =~ /^\{/o ) {
9244         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9245             print $OUT
9246 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9247         }
9248
9249         # Properly balanced. Pre-prompt debugger actions.
9250         else {
9251             $which = 'pre-debugger';
9252             $aref  = $pretype;
9253         }
9254     } ## end elsif ( $cmd =~ /^\{/o )
9255
9256     # Did we find something that makes sense?
9257     unless ($which) {
9258         print $OUT "Confused by command: $cmd\n";
9259     }
9260
9261     # Yes.
9262     else {
9263
9264         # List actions.
9265         if ( $line =~ /^\s*\?\s*$/o ) {
9266             unless (@$aref) {
9267
9268                 # Nothing there. Complain.
9269                 print $OUT "No $which actions.\n";
9270             }
9271             else {
9272
9273                 # List the actions in the selected list.
9274                 print $OUT "$which commands:\n";
9275                 foreach my $action (@$aref) {
9276                     print $OUT "\t$cmd -- $action\n";
9277                 }
9278             } ## end else
9279         } ## end if ( $line =~ /^\s*\?\s*$/o)
9280
9281         # Might be a delete.
9282         else {
9283             if ( length($cmd) == 1 ) {
9284                 if ( $line =~ /^\s*\*\s*$/o ) {
9285
9286                     # It's a delete. Get rid of the old actions in the
9287                     # selected list..
9288                     @$aref = ();
9289                     print $OUT "All $cmd actions cleared.\n";
9290                 }
9291                 else {
9292
9293                     # Replace all the actions. (This is a <, >, or {).
9294                     @$aref = action($line);
9295                 }
9296             } ## end if ( length($cmd) == 1)
9297             elsif ( length($cmd) == 2 ) {
9298
9299                 # Add the action to the line. (This is a <<, >>, or {{).
9300                 push @$aref, action($line);
9301             }
9302             else {
9303
9304                 # <<<, >>>>, {{{{{{ ... something not a command.
9305                 print $OUT
9306                   "Confused by strange length of $which command($cmd)...\n";
9307             }
9308         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9309     } ## end else
9310 } ## end sub cmd_prepost
9311
9312 =head1 C<DB::fake>
9313
9314 Contains the C<at_exit> routine that the debugger uses to issue the
9315 C<Debugged program terminated ...> message after the program completes. See
9316 the C<END> block documentation for more details.
9317
9318 =cut
9319
9320 package DB::fake;
9321
9322 sub at_exit {
9323     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9324 }
9325
9326 package DB;    # Do not trace this 1; below!
9327
9328 1;
9329
9330