lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 if false, a dummy ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =item * HistFile
 241
 242 file to store session history to. There is no default and so no
 243 history file is written unless this variable is explicitly set.
 244
 245 =item * HistSize
 246
 247 number of commands to store to the file specified in C<HistFile>.
 248 Default is 100.
 249
 250 =back
 251
 252 =head3 SAMPLE RCFILE
 253
 254  &parse_options("NonStop=1 LineInfo=db.out");
 255   sub afterinit { $trace = 1; }
 256
 257 The script will run without human intervention, putting trace
 258 information into C<db.out>.  (If you interrupt it, you had better
 259 reset C<LineInfo> to something I<interactive>!)
 260
 261 =head1 INTERNALS DESCRIPTION
 262
 263 =head2 DEBUGGER INTERFACE VARIABLES
 264
 265 Perl supplies the values for C<%sub>.  It effectively inserts
 266 a C<&DB::DB();> in front of each place that can have a
 267 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 268 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 269 {require 'perl5db.pl'}> before the first line.
 270
 271 After each C<require>d file is compiled, but before it is executed, a
 272 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 273 is the expanded name of the C<require>d file (as found via C<%INC>).
 274
 275 =head3 IMPORTANT INTERNAL VARIABLES
 276
 277 =head4 C<$CreateTTY>
 278
 279 Used to control when the debugger will attempt to acquire another TTY to be
 280 used for input.
 281
 282 =over
 283
 284 =item * 1 -  on C<fork()>
 285
 286 =item * 2 - debugger is started inside debugger
 287
 288 =item * 4 -  on startup
 289
 290 =back
 291
 292 =head4 C<$doret>
 293
 294 The value -2 indicates that no return value should be printed.
 295 Any other positive value causes C<DB::sub> to print return values.
 296
 297 =head4 C<$evalarg>
 298
 299 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 300 contents of C<@_> when C<DB::eval> is called.
 301
 302 =head4 C<$frame>
 303
 304 Determines what messages (if any) will get printed when a subroutine (or eval)
 305 is entered or exited.
 306
 307 =over 4
 308
 309 =item * 0 -  No enter/exit messages
 310
 311 =item * 1 - Print I<entering> messages on subroutine entry
 312
 313 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 314
 315 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 316
 317 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 318
 319 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 320
 321 =back
 322
 323 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 324 The debugger internally juggles the value of C<$frame> during execution to
 325 protect external modules that the debugger uses from getting traced.
 326
 327 =head4 C<$level>
 328
 329 Tracks current debugger nesting level. Used to figure out how many
 330 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 331 outputs a prompt. Also used to help determine if the program has finished
 332 during command parsing.
 333
 334 =head4 C<$onetimeDump>
 335
 336 Controls what (if anything) C<DB::eval()> will print after evaluating an
 337 expression.
 338
 339 =over 4
 340
 341 =item * C<undef> - don't print anything
 342
 343 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 344
 345 =item * C<methods> - print the methods callable on the first item returned
 346
 347 =back
 348
 349 =head4 C<$onetimeDumpDepth>
 350
 351 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 352 dumping a structure. Numeric. If C<undef>, print all levels.
 353
 354 =head4 C<$signal>
 355
 356 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 357 which is called before every statement, checks this and puts the user into
 358 command mode if it finds C<$signal> set to a true value.
 359
 360 =head4 C<$single>
 361
 362 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 363 each subroutine; popped again at the end of each subroutine.
 364
 365 =over 4
 366
 367 =item * 0 - run continuously.
 368
 369 =item * 1 - single-step, go into subs. The C<s> command.
 370
 371 =item * 2 - single-step, don't go into subs. The C<n> command.
 372
 373 =item * 4 - print current sub depth (turned on to force this when C<too much
 374 recursion> occurs.
 375
 376 =back
 377
 378 =head4 C<$trace>
 379
 380 Controls the output of trace information.
 381
 382 =over 4
 383
 384 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 385
 386 =item * 2 - watch expressions are active
 387
 388 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 389
 390 =back
 391
 392 =head4 C<$slave_editor>
 393
 394 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 395
 396 =head4 C<@cmdfhs>
 397
 398 Stack of filehandles that C<DB::readline()> will read commands from.
 399 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 400
 401 =head4 C<@dbline>
 402
 403 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 404 supplied by the Perl interpreter to the debugger. Contains the source.
 405
 406 =head4 C<@old_watch>
 407
 408 Previous values of watch expressions. First set when the expression is
 409 entered; reset whenever the watch expression changes.
 410
 411 =head4 C<@saved>
 412
 413 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 414 so that the debugger can substitute safe values while it's running, and
 415 restore them when it returns control.
 416
 417 =head4 C<@stack>
 418
 419 Saves the current value of C<$single> on entry to a subroutine.
 420 Manipulated by the C<c> command to turn off tracing in all subs above the
 421 current one.
 422
 423 =head4 C<@to_watch>
 424
 425 The 'watch' expressions: to be evaluated before each line is executed.
 426
 427 =head4 C<@typeahead>
 428
 429 The typeahead buffer, used by C<DB::readline>.
 430
 431 =head4 C<%alias>
 432
 433 Command aliases. Stored as character strings to be substituted for a command
 434 entered.
 435
 436 =head4 C<%break_on_load>
 437
 438 Keys are file names, values are 1 (break when this file is loaded) or undef
 439 (don't break when it is loaded).
 440
 441 =head4 C<%dbline>
 442
 443 Keys are line numbers, values are C<condition\0action>. If used in numeric
 444 context, values are 0 if not breakable, 1 if breakable, no matter what is
 445 in the actual hash entry.
 446
 447 =head4 C<%had_breakpoints>
 448
 449 Keys are file names; values are bitfields:
 450
 451 =over 4
 452
 453 =item * 1 - file has a breakpoint in it.
 454
 455 =item * 2 - file has an action in it.
 456
 457 =back
 458
 459 A zero or undefined value means this file has neither.
 460
 461 =head4 C<%option>
 462
 463 Stores the debugger options. These are character string values.
 464
 465 =head4 C<%postponed>
 466
 467 Saves breakpoints for code that hasn't been compiled yet.
 468 Keys are subroutine names, values are:
 469
 470 =over 4
 471
 472 =item * C<compile> - break when this sub is compiled
 473
 474 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 475
 476 =back
 477
 478 =head4 C<%postponed_file>
 479
 480 This hash keeps track of breakpoints that need to be set for files that have
 481 not yet been compiled. Keys are filenames; values are references to hashes.
 482 Each of these hashes is keyed by line number, and its values are breakpoint
 483 definitions (C<condition\0action>).
 484
 485 =head1 DEBUGGER INITIALIZATION
 486
 487 The debugger's initialization actually jumps all over the place inside this
 488 package. This is because there are several BEGIN blocks (which of course
 489 execute immediately) spread through the code. Why is that?
 490
 491 The debugger needs to be able to change some things and set some things up
 492 before the debugger code is compiled; most notably, the C<$deep> variable that
 493 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 494 debugger has to turn off warnings while the debugger code is compiled, but then
 495 restore them to their original setting before the program being debugged begins
 496 executing.
 497
 498 The first C<BEGIN> block simply turns off warnings by saving the current
 499 setting of C<$^W> and then setting it to zero. The second one initializes
 500 the debugger variables that are needed before the debugger begins executing.
 501 The third one puts C<$^X> back to its former value.
 502
 503 We'll detail the second C<BEGIN> block later; just remember that if you need
 504 to initialize something before the debugger starts really executing, that's
 505 where it has to go.
 506
 507 =cut
 508
 509 package DB;
 510
 511 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 512
 513 # Debugger for Perl 5.00x; perl5db.pl patch level:
 514 $VERSION = 1.30;
 515
 516 $header = "perl5db.pl version $VERSION";
 517
 518 =head1 DEBUGGER ROUTINES
 519
 520 =head2 C<DB::eval()>
 521
 522 This function replaces straight C<eval()> inside the debugger; it simplifies
 523 the process of evaluating code in the user's context.
 524
 525 The code to be evaluated is passed via the package global variable
 526 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 527
 528 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 529 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 530 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 531 user's current package, grabbed when C<DB::DB> got control.  This causes the
 532 proper context to be used when the eval is actually done.  Afterward, we
 533 restore C<$trace>, C<$single>, and C<$^D>.
 534
 535 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 536 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 537 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 538 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 539 considered sane by the debugger. If there was an C<eval()> error, we print
 540 it on the debugger's output. If C<$onetimedump> is defined, we call
 541 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 542 'methods'. Setting it to something else causes the debugger to do the eval
 543 but not print the result - handy if you want to do something else with it
 544 (the "watch expressions" code does this to get the value of the watch
 545 expression but not show it unless it matters).
 546
 547 In any case, we then return the list of output from C<eval> to the caller,
 548 and unwinding restores the former version of C<$@> in C<@saved> as well
 549 (the localization of C<$saved[0]> goes away at the end of this scope).
 550
 551 =head3 Parameters and variables influencing execution of DB::eval()
 552
 553 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 554 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 555 The variables listed below influence C<DB::eval()>'s execution directly.
 556
 557 =over 4
 558
 559 =item C<$evalarg> - the thing to actually be eval'ed
 560
 561 =item C<$trace> - Current state of execution tracing
 562
 563 =item C<$single> - Current state of single-stepping
 564
 565 =item C<$onetimeDump> - what is to be displayed after the evaluation
 566
 567 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 568
 569 =back
 570
 571 The following variables are altered by C<DB::eval()> during its execution. They
 572 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 573
 574 =over 4
 575
 576 =item C<@res> - used to capture output from actual C<eval>.
 577
 578 =item C<$otrace> - saved value of C<$trace>.
 579
 580 =item C<$osingle> - saved value of C<$single>.
 581
 582 =item C<$od> - saved value of C<$^D>.
 583
 584 =item C<$saved[0]> - saved value of C<$@>.
 585
 586 =item $\ - for output of C<$@> if there is an evaluation error.
 587
 588 =back
 589
 590 =head3 The problem of lexicals
 591
 592 The context of C<DB::eval()> presents us with some problems. Obviously,
 593 we want to be 'sandboxed' away from the debugger's internals when we do
 594 the eval, but we need some way to control how punctuation variables and
 595 debugger globals are used.
 596
 597 We can't use local, because the code inside C<DB::eval> can see localized
 598 variables; and we can't use C<my> either for the same reason. The code
 599 in this routine compromises and uses C<my>.
 600
 601 After this routine is over, we don't have user code executing in the debugger's
 602 context, so we can use C<my> freely.
 603
 604 =cut
 605
 606 ############################################## Begin lexical danger zone
 607
 608 # 'my' variables used here could leak into (that is, be visible in)
 609 # the context that the code being evaluated is executing in. This means that
 610 # the code could modify the debugger's variables.
 611 #
 612 # Fiddling with the debugger's context could be Bad. We insulate things as
 613 # much as we can.
 614
 615 sub eval {
 616
 617     # 'my' would make it visible from user code
 618     #    but so does local! --tchrist
 619     # Remember: this localizes @DB::res, not @main::res.
 620     local @res;
 621     {
 622
 623         # Try to keep the user code from messing  with us. Save these so that
 624         # even if the eval'ed code changes them, we can put them back again.
 625         # Needed because the user could refer directly to the debugger's
 626         # package globals (and any 'my' variables in this containing scope)
 627         # inside the eval(), and we want to try to stay safe.
 628         local $otrace  = $trace;
 629         local $osingle = $single;
 630         local $od      = $^D;
 631
 632         # Untaint the incoming eval() argument.
 633         { ($evalarg) = $evalarg =~ /(.*)/s; }
 634
 635         # $usercontext built in DB::DB near the comment
 636         # "set up the context for DB::eval ..."
 637         # Evaluate and save any results.
 638         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 639
 640         # Restore those old values.
 641         $trace  = $otrace;
 642         $single = $osingle;
 643         $^D     = $od;
 644     }
 645
 646     # Save the current value of $@, and preserve it in the debugger's copy
 647     # of the saved precious globals.
 648     my $at = $@;
 649
 650     # Since we're only saving $@, we only have to localize the array element
 651     # that it will be stored in.
 652     local $saved[0];    # Preserve the old value of $@
 653     eval { &DB::save };
 654
 655     # Now see whether we need to report an error back to the user.
 656     if ($at) {
 657         local $\ = '';
 658         print $OUT $at;
 659     }
 660
 661     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 662     # are package globals.
 663     elsif ($onetimeDump) {
 664         if ( $onetimeDump eq 'dump' ) {
 665             local $option{dumpDepth} = $onetimedumpDepth
 666               if defined $onetimedumpDepth;
 667             dumpit( $OUT, \@res );
 668         }
 669         elsif ( $onetimeDump eq 'methods' ) {
 670             methods( $res[0] );
 671         }
 672     } ## end elsif ($onetimeDump)
 673     @res;
 674 } ## end sub eval
 675
 676 ############################################## End lexical danger zone
 677
 678 # After this point it is safe to introduce lexicals.
 679 # The code being debugged will be executing in its own context, and
 680 # can't see the inside of the debugger.
 681 #
 682 # However, one should not overdo it: leave as much control from outside as
 683 # possible. If you make something a lexical, it's not going to be addressable
 684 # from outside the debugger even if you know its name.
 685
 686 # This file is automatically included if you do perl -d.
 687 # It's probably not useful to include this yourself.
 688 #
 689 # Before venturing further into these twisty passages, it is
 690 # wise to read the perldebguts man page or risk the ire of dragons.
 691 #
 692 # (It should be noted that perldebguts will tell you a lot about
 693 # the underlying mechanics of how the debugger interfaces into the
 694 # Perl interpreter, but not a lot about the debugger itself. The new
 695 # comments in this code try to address this problem.)
 696
 697 # Note that no subroutine call is possible until &DB::sub is defined
 698 # (for subroutines defined outside of the package DB). In fact the same is
 699 # true if $deep is not defined.
 700
 701 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 702
 703 # modified Perl debugger, to be run from Emacs in perldb-mode
 704 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 705 # Johan Vromans -- upgrade to 4.0 pl 10
 706 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 707
 708 # (We have made efforts to  clarify the comments in the change log
 709 # in other places; some of them may seem somewhat obscure as they
 710 # were originally written, and explaining them away from the code
 711 # in question seems conterproductive.. -JM)
 712
 713 ########################################################################
 714 # Changes: 0.94
 715 #   + A lot of things changed after 0.94. First of all, core now informs
 716 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 717 #     BEGIN and END. Handy with `O f=2'.
 718 #   + This can make debugger a little bit too verbose, please be patient
 719 #     and report your problems promptly.
 720 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 721 #   + Note that if DESTROY returns a reference to the object (or object),
 722 #     the deletion of data may be postponed until the next function call,
 723 #     due to the need to examine the return value.
 724 #
 725 # Changes: 0.95
 726 #   + `v' command shows versions.
 727 #
 728 # Changes: 0.96
 729 #   + `v' command shows version of readline.
 730 #     primitive completion works (dynamic variables, subs for `b' and `l',
 731 #     options). Can `p %var'
 732 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 733 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 734 #   + `c sub' documented.
 735 #   + At last enough magic combined to stop after the end of debuggee.
 736 #   + !! should work now (thanks to Emacs bracket matching an extra
 737 #     `]' in a regexp is caught).
 738 #   + `L', `D' and `A' span files now (as documented).
 739 #   + Breakpoints in `require'd code are possible (used in `R').
 740 #   +  Some additional words on internal work of debugger.
 741 #   + `b load filename' implemented.
 742 #   + `b postpone subr' implemented.
 743 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 744 #   + When restarting debugger breakpoints/actions persist.
 745 #   + Buglet: When restarting debugger only one breakpoint/action per
 746 #             autoloaded function persists.
 747 #
 748 # Changes: 0.97: NonStop will not stop in at_exit().
 749 #   + Option AutoTrace implemented.
 750 #   + Trace printed differently if frames are printed too.
 751 #   + new `inhibitExit' option.
 752 #   + printing of a very long statement interruptible.
 753 # Changes: 0.98: New command `m' for printing possible methods
 754 #   + 'l -' is a synonym for `-'.
 755 #   + Cosmetic bugs in printing stack trace.
 756 #   +  `frame' & 8 to print "expanded args" in stack trace.
 757 #   + Can list/break in imported subs.
 758 #   + new `maxTraceLen' option.
 759 #   + frame & 4 and frame & 8 granted.
 760 #   + new command `m'
 761 #   + nonstoppable lines do not have `:' near the line number.
 762 #   + `b compile subname' implemented.
 763 #   + Will not use $` any more.
 764 #   + `-' behaves sane now.
 765 # Changes: 0.99: Completion for `f', `m'.
 766 #   +  `m' will remove duplicate names instead of duplicate functions.
 767 #   + `b load' strips trailing whitespace.
 768 #     completion ignores leading `|'; takes into account current package
 769 #     when completing a subroutine name (same for `l').
 770 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 771 #   BUG FIXES:
 772 #   + Added bare minimal security checks on perldb rc files, plus
 773 #     comments on what else is needed.
 774 #   + Fixed the ornaments that made "|h" completely unusable.
 775 #     They are not used in print_help if they will hurt.  Strip pod
 776 #     if we're paging to less.
 777 #   + Fixed mis-formatting of help messages caused by ornaments
 778 #     to restore Larry's original formatting.
 779 #   + Fixed many other formatting errors.  The code is still suboptimal,
 780 #     and needs a lot of work at restructuring.  It's also misindented
 781 #     in many places.
 782 #   + Fixed bug where trying to look at an option like your pager
 783 #     shows "1".
 784 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 785 #     lose.  You should consider shell escapes not using their shell,
 786 #     or else not caring about detailed status.  This should really be
 787 #     unified into one place, too.
 788 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 789 #     tricking Perl into thinking you weren't calling a debugger command!
 790 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 791 #     suggests a leading semicolon or any other irrelevant non-whitespace
 792 #     to indicate literal Perl code.)
 793 #   + Fixed bugs that ate warnings due to wrong selected handle.
 794 #   + Fixed a precedence bug on signal stuff.
 795 #   + Fixed some unseemly wording.
 796 #   + Fixed bug in help command trying to call perl method code.
 797 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 798 #   ENHANCEMENTS:
 799 #   + Added some comments.  This code is still nasty spaghetti.
 800 #   + Added message if you clear your pre/post command stacks which was
 801 #     very easy to do if you just typed a bare >, <, or {.  (A command
 802 #     without an argument should *never* be a destructive action; this
 803 #     API is fundamentally screwed up; likewise option setting, which
 804 #     is equally buggered.)
 805 #   + Added command stack dump on argument of "?" for >, <, or {.
 806 #   + Added a semi-built-in doc viewer command that calls man with the
 807 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 808 #     or else perldoc on obstreperous platforms.
 809 #   + Added to and rearranged the help information.
 810 #   + Detected apparent misuse of { ... } to declare a block; this used
 811 #     to work but now is a command, and mysteriously gave no complaint.
 812 #
 813 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 814 #   BUG FIX:
 815 #   + This patch to perl5db.pl cleans up formatting issues on the help
 816 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 817 #     issues, plus converted the printed text to use all spaces, since
 818 #     tabs don't seem to help much here.
 819 #
 820 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 821 #   Minor bugs corrected;
 822 #   + Support for auto-creation of new TTY window on startup, either
 823 #     unconditionally, or if started as a kid of another debugger session;
 824 #   + New `O'ption CreateTTY
 825 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 826 #                         1: on fork()
 827 #                         2: debugger is started inside debugger
 828 #                         4: on startup
 829 #   + Code to auto-create a new TTY window on OS/2 (currently one
 830 #     extra window per session - need named pipes to have more...);
 831 #   + Simplified interface for custom createTTY functions (with a backward
 832 #     compatibility hack); now returns the TTY name to use; return of ''
 833 #     means that the function reset the I/O handles itself;
 834 #   + Better message on the semantic of custom createTTY function;
 835 #   + Convert the existing code to create a TTY into a custom createTTY
 836 #     function;
 837 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 838 #   + Switch line-tracing output too to the created TTY window;
 839 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 840 #   + High-level debugger API cmd_*():
 841 #      cmd_b_load($filenamepart)            # b load filenamepart
 842 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 843 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 844 #      cmd_stop()                           # Control-C
 845 #      cmd_d($lineno)                       # d lineno (B)
 846 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 847 #      the error message to the debugging output.
 848 #   + Low-level debugger API
 849 #      break_on_load($filename)             # b load filename
 850 #      @files = report_break_on_load()      # List files with load-breakpoints
 851 #      breakable_line_in_filename($name, $from [, $to])
 852 #                                           # First breakable line in the
 853 #                                           # range $from .. $to.  $to defaults
 854 #                                           # to $from, and may be less than
 855 #                                           # $to
 856 #      breakable_line($from [, $to])        # Same for the current file
 857 #      break_on_filename_line($name, $lineno [, $cond])
 858 #                                           # Set breakpoint,$cond defaults to
 859 #                                           # 1
 860 #      break_on_filename_line_range($name, $from, $to [, $cond])
 861 #                                           # As above, on the first
 862 #                                           # breakable line in range
 863 #      break_on_line($lineno [, $cond])     # As above, in the current file
 864 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 865 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 866 #                                           # The range of lines of the text
 867 #      The low-level API returns TRUE on success, and die()s on failure.
 868 #
 869 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 870 #   BUG FIXES:
 871 #   + Fixed warnings generated by "perl -dWe 42"
 872 #   + Corrected spelling errors
 873 #   + Squeezed Help (h) output into 80 columns
 874 #
 875 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 876 #   + Made "x @INC" work like it used to
 877 #
 878 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 879 #   + Fixed warnings generated by "O" (Show debugger options)
 880 #   + Fixed warnings generated by "p 42" (Print expression)
 881 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 882 #   + Added windowSize option
 883 # Changes: 1.14: Oct  9, 2001 multiple
 884 #   + Clean up after itself on VMS (Charles Lane in 12385)
 885 #   + Adding "@ file" syntax (Peter Scott in 12014)
 886 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 887 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 888 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 889 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 890 #   + Updated 1.14 change log
 891 #   + Added *dbline explainatory comments
 892 #   + Mentioning perldebguts man page
 893 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 894 #   + $onetimeDump improvements
 895 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 896 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 897 #   rationalised the following commands and added cmd_wrapper() to
 898 #   enable switching between old and frighteningly consistent new
 899 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 900 #     a(add),       A(del)            # action expr   (added del by line)
 901 #   + b(add),       B(del)            # break  [line] (was b,D)
 902 #   + w(add),       W(del)            # watch  expr   (was W,W)
 903 #                                     # added del by expr
 904 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 905 #   + m(methods),   M(modules)        # ...           (was m,v)
 906 #   + o(option)                       # lc            (was O)
 907 #   + v(view code), V(view Variables) # ...           (was w,V)
 908 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 909 #   + fixed missing cmd_O bug
 910 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 911 #   + Added missing local()s -- DB::DB is called recursively.
 912 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 913 #   + pre'n'post commands no longer trashed with no args
 914 #   + watch val joined out of eval()
 915 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 916 #   + Added comments and reformatted source. No bug fixes/enhancements.
 917 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 918 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 919 #   + Flush stdout/stderr before the debugger prompt is printed.
 920 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 921 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 922 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 923 #   + Added command to save all debugger commands for sourcing later.
 924 #   + Added command to display parent inheritance tree of given class.
 925 #   + Fixed minor newline in history bug.
 926 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 927 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 928 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + unfork the 5.8.x and 5.9.x debuggers.
 930 #   + whitespace and assertions call cleanup across versions
 931 #   + H * deletes (resets) history
 932 #   + i now handles Class + blessed objects
 933 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 934 #   + updated pod page references - clunky.
 935 #   + removed windowid restriction for forking into an xterm.
 936 #   + more whitespace again.
 937 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 938 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 939 #   + Added threads support (inc. e and E commands)
 940 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 941 #   + Added macosx_get_fork_TTY support
 942 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 943 #   + Added HistFile, HistSize
 944 ########################################################################
 945
 946 =head1 DEBUGGER INITIALIZATION
 947
 948 The debugger starts up in phases.
 949
 950 =head2 BASIC SETUP
 951
 952 First, it initializes the environment it wants to run in: turning off
 953 warnings during its own compilation, defining variables which it will need
 954 to avoid warnings later, setting itself up to not exit when the program
 955 terminates, and defaulting to printing return values for the C<r> command.
 956
 957 =cut
 958
 959 # Needed for the statement after exec():
 960 #
 961 # This BEGIN block is simply used to switch off warnings during debugger
 962 # compiliation. Probably it would be better practice to fix the warnings,
 963 # but this is how it's done at the moment.
 964
 965 BEGIN {
 966     $ini_warn = $^W;
 967     $^W       = 0;
 968 }    # Switch compilation warnings off until another BEGIN.
 969
 970 # test if assertions are supported and actived:
 971 BEGIN {
 972     $ini_assertion = eval "sub asserting_test : assertion {1}; 1";
 973
 974     # $ini_assertion = undef => assertions unsupported,
 975     #        "       = 1     => assertions supported
 976     # print "\$ini_assertion=$ini_assertion\n";
 977 }
 978
 979 local ($^W) = 0;    # Switch run-time warnings off during init.
 980
 981 =head2 THREADS SUPPORT
 982
 983 If we are running under a threaded Perl, we require threads and threads::shared
 984 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 985 threaded debugger control.  C<-dt> can also be used to set this.
 986
 987 Each new thread will be announced and the debugger prompt will always inform
 988 you of each new thread created.  It will also indicate the thread id in which
 989 we are currently running within the prompt like this:
 990
 991         [tid] DB<$i>
 992
 993 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 994 command prompt.  The prompt will show: C<[0]> when running under threads, but
 995 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 996
 997 While running under threads, when you set or delete a breakpoint (etc.), this
 998 will apply to all threads, not just the currently running one.  When you are
 999 in a currently executing thread, you will stay there until it completes.  With
1000 the current implementation it is not currently possible to hop from one thread
1001 to another.
1002
1003 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1004
1005 Note that threading support was built into the debugger as of Perl version
1006 C<5.8.6> and debugger version C<1.2.8>.
1007
1008 =cut
1009
1010 BEGIN {
1011   # ensure we can share our non-threaded variables or no-op
1012   if ($ENV{PERL5DB_THREADED}) {
1013         require threads;
1014         require threads::shared;
1015         import threads::shared qw(share);
1016         $DBGR;
1017         share(\$DBGR);
1018         lock($DBGR);
1019         print "Threads support enabled\n";
1020   } else {
1021         *lock  = sub(*) {};
1022         *share = sub(*) {};
1023   }
1024 }
1025
1026 # This would probably be better done with "use vars", but that wasn't around
1027 # when this code was originally written. (Neither was "use strict".) And on
1028 # the principle of not fiddling with something that was working, this was
1029 # left alone.
1030 warn(               # Do not ;-)
1031     # These variables control the execution of 'dumpvar.pl'.
1032     $dumpvar::hashDepth,
1033     $dumpvar::arrayDepth,
1034     $dumpvar::dumpDBFiles,
1035     $dumpvar::dumpPackages,
1036     $dumpvar::quoteHighBit,
1037     $dumpvar::printUndef,
1038     $dumpvar::globPrint,
1039     $dumpvar::usageOnly,
1040
1041     # used to save @ARGV and extract any debugger-related flags.
1042     @ARGS,
1043
1044     # used to control die() reporting in diesignal()
1045     $Carp::CarpLevel,
1046
1047     # used to prevent multiple entries to diesignal()
1048     # (if for instance diesignal() itself dies)
1049     $panic,
1050
1051     # used to prevent the debugger from running nonstop
1052     # after a restart
1053     $second_time,
1054   )
1055   if 0;
1056
1057 foreach my $k (keys (%INC)) {
1058         &share(\$main::{'_<'.$filename});
1059 };
1060
1061 # Command-line + PERLLIB:
1062 # Save the contents of @INC before they are modified elsewhere.
1063 @ini_INC = @INC;
1064
1065 # This was an attempt to clear out the previous values of various
1066 # trapped errors. Apparently it didn't help. XXX More info needed!
1067 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1068
1069 # We set these variables to safe values. We don't want to blindly turn
1070 # off warnings, because other packages may still want them.
1071 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1072                                    # (local $^W cannot help - other packages!).
1073
1074 # Default to not exiting when program finishes; print the return
1075 # value when the 'r' command is used to return from a subroutine.
1076 $inhibit_exit = $option{PrintRet} = 1;
1077
1078 =head1 OPTION PROCESSING
1079
1080 The debugger's options are actually spread out over the debugger itself and
1081 C<dumpvar.pl>; some of these are variables to be set, while others are
1082 subs to be called with a value. To try to make this a little easier to
1083 manage, the debugger uses a few data structures to define what options
1084 are legal and how they are to be processed.
1085
1086 First, the C<@options> array defines the I<names> of all the options that
1087 are to be accepted.
1088
1089 =cut
1090
1091 @options = qw(
1092   CommandSet   HistFile      HistSize
1093   hashDepth    arrayDepth    dumpDepth
1094   DumpDBFiles  DumpPackages  DumpReused
1095   compactDump  veryCompact   quote
1096   HighBit      undefPrint    globPrint
1097   PrintRet     UsageOnly     frame
1098   AutoTrace    TTY           noTTY
1099   ReadLine     NonStop       LineInfo
1100   maxTraceLen  recallCommand ShellBang
1101   pager        tkRunning     ornaments
1102   signalLevel  warnLevel     dieLevel
1103   inhibit_exit ImmediateStop bareStringify
1104   CreateTTY    RemotePort    windowSize
1105   DollarCaretP OnlyAssertions WarnAssertions
1106 );
1107
1108 @RememberOnROptions = qw(DollarCaretP OnlyAssertions);
1109
1110 =pod
1111
1112 Second, C<optionVars> lists the variables that each option uses to save its
1113 state.
1114
1115 =cut
1116
1117 %optionVars = (
1118     hashDepth     => \$dumpvar::hashDepth,
1119     arrayDepth    => \$dumpvar::arrayDepth,
1120     CommandSet    => \$CommandSet,
1121     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1122     DumpPackages  => \$dumpvar::dumpPackages,
1123     DumpReused    => \$dumpvar::dumpReused,
1124     HighBit       => \$dumpvar::quoteHighBit,
1125     undefPrint    => \$dumpvar::printUndef,
1126     globPrint     => \$dumpvar::globPrint,
1127     UsageOnly     => \$dumpvar::usageOnly,
1128     CreateTTY     => \$CreateTTY,
1129     bareStringify => \$dumpvar::bareStringify,
1130     frame         => \$frame,
1131     AutoTrace     => \$trace,
1132     inhibit_exit  => \$inhibit_exit,
1133     maxTraceLen   => \$maxtrace,
1134     ImmediateStop => \$ImmediateStop,
1135     RemotePort    => \$remoteport,
1136     windowSize    => \$window,
1137     WarnAssertions => \$warnassertions,
1138     HistFile      => \$histfile,
1139     HistSize      => \$histsize,
1140 );
1141
1142 =pod
1143
1144 Third, C<%optionAction> defines the subroutine to be called to process each
1145 option.
1146
1147 =cut
1148
1149 %optionAction = (
1150     compactDump   => \&dumpvar::compactDump,
1151     veryCompact   => \&dumpvar::veryCompact,
1152     quote         => \&dumpvar::quote,
1153     TTY           => \&TTY,
1154     noTTY         => \&noTTY,
1155     ReadLine      => \&ReadLine,
1156     NonStop       => \&NonStop,
1157     LineInfo      => \&LineInfo,
1158     recallCommand => \&recallCommand,
1159     ShellBang     => \&shellBang,
1160     pager         => \&pager,
1161     signalLevel   => \&signalLevel,
1162     warnLevel     => \&warnLevel,
1163     dieLevel      => \&dieLevel,
1164     tkRunning     => \&tkRunning,
1165     ornaments     => \&ornaments,
1166     RemotePort    => \&RemotePort,
1167     DollarCaretP  => \&DollarCaretP,
1168     OnlyAssertions=> \&OnlyAssertions,
1169 );
1170
1171 =pod
1172
1173 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1174 option is used.
1175
1176 =cut
1177
1178 # Note that this list is not complete: several options not listed here
1179 # actually require that dumpvar.pl be loaded for them to work, but are
1180 # not in the table. A subsequent patch will correct this problem; for
1181 # the moment, we're just recommenting, and we are NOT going to change
1182 # function.
1183 %optionRequire = (
1184     compactDump => 'dumpvar.pl',
1185     veryCompact => 'dumpvar.pl',
1186     quote       => 'dumpvar.pl',
1187 );
1188
1189 =pod
1190
1191 There are a number of initialization-related variables which can be set
1192 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1193 variable. These are:
1194
1195 =over 4
1196
1197 =item C<$rl> - readline control XXX needs more explanation
1198
1199 =item C<$warnLevel> - whether or not debugger takes over warning handling
1200
1201 =item C<$dieLevel> - whether or not debugger takes over die handling
1202
1203 =item C<$signalLevel> - whether or not debugger takes over signal handling
1204
1205 =item C<$pre> - preprompt actions (array reference)
1206
1207 =item C<$post> - postprompt actions (array reference)
1208
1209 =item C<$pretype>
1210
1211 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1212
1213 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1214
1215 =back
1216
1217 =cut
1218
1219 # These guys may be defined in $ENV{PERL5DB} :
1220 $rl          = 1     unless defined $rl;
1221 $warnLevel   = 1     unless defined $warnLevel;
1222 $dieLevel    = 1     unless defined $dieLevel;
1223 $signalLevel = 1     unless defined $signalLevel;
1224 $pre         = []    unless defined $pre;
1225 $post        = []    unless defined $post;
1226 $pretype     = []    unless defined $pretype;
1227 $CreateTTY   = 3     unless defined $CreateTTY;
1228 $CommandSet  = '580' unless defined $CommandSet;
1229
1230 share($rl);
1231 share($warnLevel);
1232 share($dieLevel);
1233 share($signalLevel);
1234 share($pre);
1235 share($post);
1236 share($pretype);
1237 share($rl);
1238 share($CreateTTY);
1239 share($CommandSet);
1240
1241 =pod
1242
1243 The default C<die>, C<warn>, and C<signal> handlers are set up.
1244
1245 =cut
1246
1247 warnLevel($warnLevel);
1248 dieLevel($dieLevel);
1249 signalLevel($signalLevel);
1250
1251 =pod
1252
1253 The pager to be used is needed next. We try to get it from the
1254 environment first.  If it's not defined there, we try to find it in
1255 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1256 then call the C<pager()> function to save the pager name.
1257
1258 =cut
1259
1260 # This routine makes sure $pager is set up so that '|' can use it.
1261 pager(
1262
1263     # If PAGER is defined in the environment, use it.
1264     defined $ENV{PAGER}
1265     ? $ENV{PAGER}
1266
1267       # If not, see if Config.pm defines it.
1268     : eval { require Config }
1269       && defined $Config::Config{pager}
1270     ? $Config::Config{pager}
1271
1272       # If not, fall back to 'more'.
1273     : 'more'
1274   )
1275   unless defined $pager;
1276
1277 =pod
1278
1279 We set up the command to be used to access the man pages, the command
1280 recall character (C<!> unless otherwise defined) and the shell escape
1281 character (C<!> unless otherwise defined). Yes, these do conflict, and
1282 neither works in the debugger at the moment.
1283
1284 =cut
1285
1286 setman();
1287
1288 # Set up defaults for command recall and shell escape (note:
1289 # these currently don't work in linemode debugging).
1290 &recallCommand("!") unless defined $prc;
1291 &shellBang("!")     unless defined $psh;
1292
1293 =pod
1294
1295 We then set up the gigantic string containing the debugger help.
1296 We also set the limit on the number of arguments we'll display during a
1297 trace.
1298
1299 =cut
1300
1301 sethelp();
1302
1303 # If we didn't get a default for the length of eval/stack trace args,
1304 # set it here.
1305 $maxtrace = 400 unless defined $maxtrace;
1306
1307 =head2 SETTING UP THE DEBUGGER GREETING
1308
1309 The debugger I<greeting> helps to inform the user how many debuggers are
1310 running, and whether the current debugger is the primary or a child.
1311
1312 If we are the primary, we just hang onto our pid so we'll have it when
1313 or if we start a child debugger. If we are a child, we'll set things up
1314 so we'll have a unique greeting and so the parent will give us our own
1315 TTY later.
1316
1317 We save the current contents of the C<PERLDB_PIDS> environment variable
1318 because we mess around with it. We'll also need to hang onto it because
1319 we'll need it if we restart.
1320
1321 Child debuggers make a label out of the current PID structure recorded in
1322 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1323 yet so the parent will give them one later via C<resetterm()>.
1324
1325 =cut
1326
1327 # Save the current contents of the environment; we're about to
1328 # much with it. We'll need this if we have to restart.
1329 $ini_pids = $ENV{PERLDB_PIDS};
1330
1331 if ( defined $ENV{PERLDB_PIDS} ) {
1332
1333     # We're a child. Make us a label out of the current PID structure
1334     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1335     # a term yet so the parent will give us one later via resetterm().
1336
1337     my $env_pids = $ENV{PERLDB_PIDS};
1338     $pids = "[$env_pids]";
1339
1340     # Unless we are on OpenVMS, all programs under the DCL shell run under
1341     # the same PID.
1342
1343     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1344         $term_pid         = $$;
1345     }
1346     else {
1347         $ENV{PERLDB_PIDS} .= "->$$";
1348         $term_pid = -1;
1349     }
1350
1351 } ## end if (defined $ENV{PERLDB_PIDS...
1352 else {
1353
1354     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1355     # child debugger, and mark us as the parent, so we'll know to set up
1356     # more TTY's is we have to.
1357     $ENV{PERLDB_PIDS} = "$$";
1358     $pids             = "[pid=$$]";
1359     $term_pid         = $$;
1360 }
1361
1362 $pidprompt = '';
1363
1364 # Sets up $emacs as a synonym for $slave_editor.
1365 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1366
1367 =head2 READING THE RC FILE
1368
1369 The debugger will read a file of initialization options if supplied. If
1370 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1371
1372 =cut
1373
1374 # As noted, this test really doesn't check accurately that the debugger
1375 # is running at a terminal or not.
1376
1377 if ( -e "/dev/tty" ) {                      # this is the wrong metric!
1378     $rcfile = ".perldb";
1379 }
1380 else {
1381     $rcfile = "perldb.ini";
1382 }
1383
1384 =pod
1385
1386 The debugger does a safety test of the file to be read. It must be owned
1387 either by the current user or root, and must only be writable by the owner.
1388
1389 =cut
1390
1391 # This wraps a safety test around "do" to read and evaluate the init file.
1392 #
1393 # This isn't really safe, because there's a race
1394 # between checking and opening.  The solution is to
1395 # open and fstat the handle, but then you have to read and
1396 # eval the contents.  But then the silly thing gets
1397 # your lexical scope, which is unfortunate at best.
1398 sub safe_do {
1399     my $file = shift;
1400
1401     # Just exactly what part of the word "CORE::" don't you understand?
1402     local $SIG{__WARN__};
1403     local $SIG{__DIE__};
1404
1405     unless ( is_safe_file($file) ) {
1406         CORE::warn <<EO_GRIPE;
1407 perldb: Must not source insecure rcfile $file.
1408         You or the superuser must be the owner, and it must not
1409         be writable by anyone but its owner.
1410 EO_GRIPE
1411         return;
1412     } ## end unless (is_safe_file($file...
1413
1414     do $file;
1415     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1416 } ## end sub safe_do
1417
1418 # This is the safety test itself.
1419 #
1420 # Verifies that owner is either real user or superuser and that no
1421 # one but owner may write to it.  This function is of limited use
1422 # when called on a path instead of upon a handle, because there are
1423 # no guarantees that filename (by dirent) whose file (by ino) is
1424 # eventually accessed is the same as the one tested.
1425 # Assumes that the file's existence is not in doubt.
1426 sub is_safe_file {
1427     my $path = shift;
1428     stat($path) || return;    # mysteriously vaporized
1429     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1430
1431     return 0 if $uid != 0 && $uid != $<;
1432     return 0 if $mode & 022;
1433     return 1;
1434 } ## end sub is_safe_file
1435
1436 # If the rcfile (whichever one we decided was the right one to read)
1437 # exists, we safely do it.
1438 if ( -f $rcfile ) {
1439     safe_do("./$rcfile");
1440 }
1441
1442 # If there isn't one here, try the user's home directory.
1443 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1444     safe_do("$ENV{HOME}/$rcfile");
1445 }
1446
1447 # Else try the login directory.
1448 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1449     safe_do("$ENV{LOGDIR}/$rcfile");
1450 }
1451
1452 # If the PERLDB_OPTS variable has options in it, parse those out next.
1453 if ( defined $ENV{PERLDB_OPTS} ) {
1454     parse_options( $ENV{PERLDB_OPTS} );
1455 }
1456
1457 =pod
1458
1459 The last thing we do during initialization is determine which subroutine is
1460 to be used to obtain a new terminal when a new debugger is started. Right now,
1461 the debugger only handles X Windows, OS/2, and Mac OS X (darwin).
1462
1463 =cut
1464
1465 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1466 # Works if you're running an xterm or xterm-like window, or you're on
1467 # OS/2, or on Mac OS X. This may need some expansion.
1468
1469 if (not defined &get_fork_TTY)       # only if no routine exists
1470 {
1471     if (defined $ENV{TERM}                       # If we know what kind
1472                                                  # of terminal this is,
1473         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1474         and defined $ENV{DISPLAY}                # and what display it's on,
1475       )
1476     {
1477         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1478     }
1479     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1480         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1481     }
1482     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1483             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1484             and $ENV{TERM_PROGRAM}
1485                 eq 'Apple_Terminal'              # Terminal.app
1486             )
1487     {
1488         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1489     }
1490 } ## end if (not defined &get_fork_TTY...
1491
1492 # untaint $^O, which may have been tainted by the last statement.
1493 # see bug [perl #24674]
1494 $^O =~ m/^(.*)\z/;
1495 $^O = $1;
1496
1497 # Here begin the unreadable code.  It needs fixing.
1498
1499 =head2 RESTART PROCESSING
1500
1501 This section handles the restart command. When the C<R> command is invoked, it
1502 tries to capture all of the state it can into environment variables, and
1503 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1504 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1505 the R command stuffed into the environment variables.
1506
1507   PERLDB_RESTART   - flag only, contains no restart data itself.
1508   PERLDB_HIST      - command history, if it's available
1509   PERLDB_ON_LOAD   - breakpoints set by the rc file
1510   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1511   PERLDB_VISITED   - files that had breakpoints
1512   PERLDB_FILE_...  - breakpoints for a file
1513   PERLDB_OPT       - active options
1514   PERLDB_INC       - the original @INC
1515   PERLDB_PRETYPE   - preprompt debugger actions
1516   PERLDB_PRE       - preprompt Perl code
1517   PERLDB_POST      - post-prompt Perl code
1518   PERLDB_TYPEAHEAD - typeahead captured by readline()
1519
1520 We chug through all these variables and plug the values saved in them
1521 back into the appropriate spots in the debugger.
1522
1523 =cut
1524
1525 if ( exists $ENV{PERLDB_RESTART} ) {
1526
1527     # We're restarting, so we don't need the flag that says to restart anymore.
1528     delete $ENV{PERLDB_RESTART};
1529
1530     # $restart = 1;
1531     @hist          = get_list('PERLDB_HIST');
1532     %break_on_load = get_list("PERLDB_ON_LOAD");
1533     %postponed     = get_list("PERLDB_POSTPONE");
1534
1535         share(@hist);
1536         share(@truehist);
1537         share(%break_on_load);
1538         share(%postponed);
1539
1540     # restore breakpoints/actions
1541     my @had_breakpoints = get_list("PERLDB_VISITED");
1542     for ( 0 .. $#had_breakpoints ) {
1543         my %pf = get_list("PERLDB_FILE_$_");
1544         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1545     }
1546
1547     # restore options
1548     my %opt = get_list("PERLDB_OPT");
1549     my ( $opt, $val );
1550     while ( ( $opt, $val ) = each %opt ) {
1551         $val =~ s/[\\\']/\\$1/g;
1552         parse_options("$opt'$val'");
1553     }
1554
1555     # restore original @INC
1556     @INC     = get_list("PERLDB_INC");
1557     @ini_INC = @INC;
1558
1559     # return pre/postprompt actions and typeahead buffer
1560     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1561     $pre       = [ get_list("PERLDB_PRE") ];
1562     $post      = [ get_list("PERLDB_POST") ];
1563     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1564 } ## end if (exists $ENV{PERLDB_RESTART...
1565
1566 =head2 SETTING UP THE TERMINAL
1567
1568 Now, we'll decide how the debugger is going to interact with the user.
1569 If there's no TTY, we set the debugger to run non-stop; there's not going
1570 to be anyone there to enter commands.
1571
1572 =cut
1573
1574 if ($notty) {
1575     $runnonstop = 1;
1576         share($runnonstop);
1577 }
1578
1579 =pod
1580
1581 If there is a TTY, we have to determine who it belongs to before we can
1582 proceed. If this is a slave editor or graphical debugger (denoted by
1583 the first command-line switch being '-emacs'), we shift this off and
1584 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1585
1586 =cut
1587
1588 else {
1589
1590     # Is Perl being run from a slave editor or graphical debugger?
1591     # If so, don't use readline, and set $slave_editor = 1.
1592     $slave_editor =
1593       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1594     $rl = 0, shift(@main::ARGV) if $slave_editor;
1595
1596     #require Term::ReadLine;
1597
1598 =pod
1599
1600 We then determine what the console should be on various systems:
1601
1602 =over 4
1603
1604 =item * Cygwin - We use C<stdin> instead of a separate device.
1605
1606 =cut
1607
1608     if ( $^O eq 'cygwin' ) {
1609
1610         # /dev/tty is binary. use stdin for textmode
1611         undef $console;
1612     }
1613
1614 =item * Unix - use C</dev/tty>.
1615
1616 =cut
1617
1618     elsif ( -e "/dev/tty" ) {
1619         $console = "/dev/tty";
1620     }
1621
1622 =item * Windows or MSDOS - use C<con>.
1623
1624 =cut
1625
1626     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1627         $console = "con";
1628     }
1629
1630 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1631 Console> if not.
1632
1633 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1634
1635 =cut
1636
1637     elsif ( $^O eq 'MacOS' ) {
1638         if ( $MacPerl::Version !~ /MPW/ ) {
1639             $console =
1640               "Dev:Console:Perl Debug";    # Separate window for application
1641         }
1642         else {
1643             $console = "Dev:Console";
1644         }
1645     } ## end elsif ($^O eq 'MacOS')
1646
1647 =item * VMS - use C<sys$command>.
1648
1649 =cut
1650
1651     else {
1652
1653         # everything else is ...
1654         $console = "sys\$command";
1655     }
1656
1657 =pod
1658
1659 =back
1660
1661 Several other systems don't use a specific console. We C<undef $console>
1662 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1663 with a slave editor, Epoc).
1664
1665 =cut
1666
1667     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1668
1669         # /dev/tty is binary. use stdin for textmode
1670         $console = undef;
1671     }
1672
1673     if ( $^O eq 'NetWare' ) {
1674
1675         # /dev/tty is binary. use stdin for textmode
1676         $console = undef;
1677     }
1678
1679     # In OS/2, we need to use STDIN to get textmode too, even though
1680     # it pretty much looks like Unix otherwise.
1681     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1682     {    # In OS/2
1683         $console = undef;
1684     }
1685
1686     # EPOC also falls into the 'got to use STDIN' camp.
1687     if ( $^O eq 'epoc' ) {
1688         $console = undef;
1689     }
1690
1691 =pod
1692
1693 If there is a TTY hanging around from a parent, we use that as the console.
1694
1695 =cut
1696
1697     $console = $tty if defined $tty;
1698
1699 =head2 SOCKET HANDLING
1700
1701 The debugger is capable of opening a socket and carrying out a debugging
1702 session over the socket.
1703
1704 If C<RemotePort> was defined in the options, the debugger assumes that it
1705 should try to start a debugging session on that port. It builds the socket
1706 and then tries to connect the input and output filehandles to it.
1707
1708 =cut
1709
1710     # Handle socket stuff.
1711
1712     if ( defined $remoteport ) {
1713
1714         # If RemotePort was defined in the options, connect input and output
1715         # to the socket.
1716         require IO::Socket;
1717         $OUT = new IO::Socket::INET(
1718             Timeout  => '10',
1719             PeerAddr => $remoteport,
1720             Proto    => 'tcp',
1721         );
1722         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1723         $IN = $OUT;
1724     } ## end if (defined $remoteport)
1725
1726 =pod
1727
1728 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1729 this is probably a situation where multiple debuggers are running (for example,
1730 a backticked command that starts up another debugger). We create a new IN and
1731 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1732 and if we can.
1733
1734 =cut
1735
1736     # Non-socket.
1737     else {
1738
1739         # Two debuggers running (probably a system or a backtick that invokes
1740         # the debugger itself under the running one). create a new IN and OUT
1741         # filehandle, and do the necessary mojo to create a new tty if we
1742         # know how, and we can.
1743         create_IN_OUT(4) if $CreateTTY & 4;
1744         if ($console) {
1745
1746             # If we have a console, check to see if there are separate ins and
1747             # outs to open. (They are assumed identical if not.)
1748
1749             my ( $i, $o ) = split /,/, $console;
1750             $o = $i unless defined $o;
1751
1752             # read/write on in, or just read, or read on STDIN.
1753             open( IN,      "+<$i" )
1754               || open( IN, "<$i" )
1755               || open( IN, "<&STDIN" );
1756
1757             # read/write/create/clobber out, or write/create/clobber out,
1758             # or merge with STDERR, or merge with STDOUT.
1759                  open( OUT, "+>$o" )
1760               || open( OUT, ">$o" )
1761               || open( OUT, ">&STDERR" )
1762               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1763
1764         } ## end if ($console)
1765         elsif ( not defined $console ) {
1766
1767             # No console. Open STDIN.
1768             open( IN, "<&STDIN" );
1769
1770             # merge with STDERR, or with STDOUT.
1771             open( OUT,      ">&STDERR" )
1772               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1773             $console = 'STDIN/OUT';
1774         } ## end elsif (not defined $console)
1775
1776         # Keep copies of the filehandles so that when the pager runs, it
1777         # can close standard input without clobbering ours.
1778         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1779     } ## end elsif (from if(defined $remoteport))
1780
1781     # Unbuffer DB::OUT. We need to see responses right away.
1782     my $previous = select($OUT);
1783     $| = 1;                                  # for DB::OUT
1784     select($previous);
1785
1786     # Line info goes to debugger output unless pointed elsewhere.
1787     # Pointing elsewhere makes it possible for slave editors to
1788     # keep track of file and position. We have both a filehandle
1789     # and a I/O description to keep track of.
1790     $LINEINFO = $OUT     unless defined $LINEINFO;
1791     $lineinfo = $console unless defined $lineinfo;
1792         # share($LINEINFO); # <- unable to share globs
1793         share($lineinfo);   #
1794
1795 =pod
1796
1797 To finish initialization, we show the debugger greeting,
1798 and then call the C<afterinit()> subroutine if there is one.
1799
1800 =cut
1801
1802     # Show the debugger greeting.
1803     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1804     unless ($runnonstop) {
1805         local $\ = '';
1806         local $, = '';
1807         if ( $term_pid eq '-1' ) {
1808             print $OUT "\nDaughter DB session started...\n";
1809         }
1810         else {
1811             print $OUT "\nLoading DB routines from $header\n";
1812             print $OUT (
1813                 "Editor support ",
1814                 $slave_editor ? "enabled" : "available", ".\n"
1815             );
1816             print $OUT
1817 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1818         } ## end else [ if ($term_pid eq '-1')
1819     } ## end unless ($runnonstop)
1820 } ## end else [ if ($notty)
1821
1822 # XXX This looks like a bug to me.
1823 # Why copy to @ARGS and then futz with @args?
1824 @ARGS = @ARGV;
1825 for (@args) {
1826     # Make sure backslashes before single quotes are stripped out, and
1827     # keep args unless they are numeric (XXX why?)
1828     # s/\'/\\\'/g;                      # removed while not justified understandably
1829     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1830 }
1831
1832 # If there was an afterinit() sub defined, call it. It will get
1833 # executed in our scope, so it can fiddle with debugger globals.
1834 if ( defined &afterinit ) {    # May be defined in $rcfile
1835     &afterinit();
1836 }
1837
1838 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1839 $I_m_init = 1;
1840
1841 ############################################################ Subroutines
1842
1843 =head1 SUBROUTINES
1844
1845 =head2 DB
1846
1847 This gigantic subroutine is the heart of the debugger. Called before every
1848 statement, its job is to determine if a breakpoint has been reached, and
1849 stop if so; read commands from the user, parse them, and execute
1850 them, and hen send execution off to the next statement.
1851
1852 Note that the order in which the commands are processed is very important;
1853 some commands earlier in the loop will actually alter the C<$cmd> variable
1854 to create other commands to be executed later. This is all highly I<optimized>
1855 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1856 see what's happening in any given command.
1857
1858 =cut
1859
1860 sub DB {
1861
1862     # lock the debugger and get the thread id for the prompt
1863         lock($DBGR);
1864         my $tid;
1865         if ($ENV{PERL5DB_THREADED}) {
1866                 $tid = eval { "[".threads->tid."]" };
1867         }
1868
1869     # Check for whether we should be running continuously or not.
1870     # _After_ the perl program is compiled, $single is set to 1:
1871     if ( $single and not $second_time++ ) {
1872
1873         # Options say run non-stop. Run until we get an interrupt.
1874         if ($runnonstop) {    # Disable until signal
1875                 # If there's any call stack in place, turn off single
1876                 # stepping into subs throughout the stack.
1877             for ( $i = 0 ; $i <= $stack_depth ; ) {
1878                 $stack[ $i++ ] &= ~1;
1879             }
1880
1881             # And we are now no longer in single-step mode.
1882             $single = 0;
1883
1884             # If we simply returned at this point, we wouldn't get
1885             # the trace info. Fall on through.
1886             # return;
1887         } ## end if ($runnonstop)
1888
1889         elsif ($ImmediateStop) {
1890
1891             # We are supposed to stop here; XXX probably a break.
1892             $ImmediateStop = 0;    # We've processed it; turn it off
1893             $signal        = 1;    # Simulate an interrupt to force
1894                                    # us into the command loop
1895         }
1896     } ## end if ($single and not $second_time...
1897
1898     # If we're in single-step mode, or an interrupt (real or fake)
1899     # has occurred, turn off non-stop mode.
1900     $runnonstop = 0 if $single or $signal;
1901
1902     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1903     # The code being debugged may have altered them.
1904     &save;
1905
1906     # Since DB::DB gets called after every line, we can use caller() to
1907     # figure out where we last were executing. Sneaky, eh? This works because
1908     # caller is returning all the extra information when called from the
1909     # debugger.
1910     local ( $package, $filename, $line ) = caller;
1911     local $filename_ini = $filename;
1912
1913     # set up the context for DB::eval, so it can properly execute
1914     # code on behalf of the user. We add the package in so that the
1915     # code is eval'ed in the proper package (not in the debugger!).
1916     local $usercontext =
1917       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1918
1919     # Create an alias to the active file magical array to simplify
1920     # the code here.
1921     local (*dbline) = $main::{ '_<' . $filename };
1922
1923     # we need to check for pseudofiles on Mac OS (these are files
1924     # not attached to a filename, but instead stored in Dev:Pseudo)
1925     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1926         $filename_ini = $filename = 'Dev:Pseudo';
1927         *dbline = $main::{ '_<' . $filename };
1928     }
1929
1930     # Last line in the program.
1931     local $max = $#dbline;
1932
1933     # if we have something here, see if we should break.
1934     if ( $dbline{$line}
1935         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1936     {
1937
1938         # Stop if the stop criterion says to just stop.
1939         if ( $stop eq '1' ) {
1940             $signal |= 1;
1941         }
1942
1943         # It's a conditional stop; eval it in the user's context and
1944         # see if we should stop. If so, remove the one-time sigil.
1945         elsif ($stop) {
1946             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1947             &eval;
1948             $dbline{$line} =~ s/;9($|\0)/$1/;
1949         }
1950     } ## end if ($dbline{$line} && ...
1951
1952     # Preserve the current stop-or-not, and see if any of the W
1953     # (watch expressions) has changed.
1954     my $was_signal = $signal;
1955
1956     # If we have any watch expressions ...
1957     if ( $trace & 2 ) {
1958         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1959             $evalarg = $to_watch[$n];
1960             local $onetimeDump;    # Tell DB::eval() to not output results
1961
1962             # Fix context DB::eval() wants to return an array, but
1963             # we need a scalar here.
1964             my ($val) = join( "', '", &eval );
1965             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1966
1967             # Did it change?
1968             if ( $val ne $old_watch[$n] ) {
1969
1970                 # Yep! Show the difference, and fake an interrupt.
1971                 $signal = 1;
1972                 print $OUT <<EOP;
1973 Watchpoint $n:\t$to_watch[$n] changed:
1974     old value:\t$old_watch[$n]
1975     new value:\t$val
1976 EOP
1977                 $old_watch[$n] = $val;
1978             } ## end if ($val ne $old_watch...
1979         } ## end for (my $n = 0 ; $n <= ...
1980     } ## end if ($trace & 2)
1981
1982 =head2 C<watchfunction()>
1983
1984 C<watchfunction()> is a function that can be defined by the user; it is a
1985 function which will be run on each entry to C<DB::DB>; it gets the
1986 current package, filename, and line as its parameters.
1987
1988 The watchfunction can do anything it likes; it is executing in the
1989 debugger's context, so it has access to all of the debugger's internal
1990 data structures and functions.
1991
1992 C<watchfunction()> can control the debugger's actions. Any of the following
1993 will cause the debugger to return control to the user's program after
1994 C<watchfunction()> executes:
1995
1996 =over 4
1997
1998 =item *
1999
2000 Returning a false value from the C<watchfunction()> itself.
2001
2002 =item *
2003
2004 Altering C<$single> to a false value.
2005
2006 =item *
2007
2008 Altering C<$signal> to a false value.
2009
2010 =item *
2011
2012 Turning off the C<4> bit in C<$trace> (this also disables the
2013 check for C<watchfunction()>. This can be done with
2014
2015     $trace &= ~4;
2016
2017 =back
2018
2019 =cut
2020
2021     # If there's a user-defined DB::watchfunction, call it with the
2022     # current package, filename, and line. The function executes in
2023     # the DB:: package.
2024     if ( $trace & 4 ) {    # User-installed watch
2025         return
2026           if watchfunction( $package, $filename, $line )
2027           and not $single
2028           and not $was_signal
2029           and not( $trace & ~4 );
2030     } ## end if ($trace & 4)
2031
2032     # Pick up any alteration to $signal in the watchfunction, and
2033     # turn off the signal now.
2034     $was_signal = $signal;
2035     $signal     = 0;
2036
2037 =head2 GETTING READY TO EXECUTE COMMANDS
2038
2039 The debugger decides to take control if single-step mode is on, the
2040 C<t> command was entered, or the user generated a signal. If the program
2041 has fallen off the end, we set things up so that entering further commands
2042 won't cause trouble, and we say that the program is over.
2043
2044 =cut
2045
2046     # Check to see if we should grab control ($single true,
2047     # trace set appropriately, or we got a signal).
2048     if ( $single || ( $trace & 1 ) || $was_signal ) {
2049
2050         # Yes, grab control.
2051         if ($slave_editor) {
2052
2053             # Tell the editor to update its position.
2054             $position = "\032\032$filename:$line:0\n";
2055             print_lineinfo($position);
2056         }
2057
2058 =pod
2059
2060 Special check: if we're in package C<DB::fake>, we've gone through the
2061 C<END> block at least once. We set up everything so that we can continue
2062 to enter commands and have a valid context to be in.
2063
2064 =cut
2065
2066         elsif ( $package eq 'DB::fake' ) {
2067
2068             # Fallen off the end already.
2069             $term || &setterm;
2070             print_help(<<EOP);
2071 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2072   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2073   B<h q>, B<h R> or B<h o> to get additional info.
2074 EOP
2075
2076             # Set the DB::eval context appropriately.
2077             $package     = 'main';
2078             $usercontext =
2079                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2080               . "package $package;";    # this won't let them modify, alas
2081         } ## end elsif ($package eq 'DB::fake')
2082
2083 =pod
2084
2085 If the program hasn't finished executing, we scan forward to the
2086 next executable line, print that out, build the prompt from the file and line
2087 number information, and print that.
2088
2089 =cut
2090
2091         else {
2092
2093             # Still somewhere in the midst of execution. Set up the
2094             #  debugger prompt.
2095             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2096                                  # Perl 5 ones (sorry, we don't print Klingon
2097                                  #module names)
2098
2099             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2100             $prefix .= "$sub($filename:";
2101             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2102
2103             # Break up the prompt if it's really long.
2104             if ( length($prefix) > 30 ) {
2105                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2106                 $prefix   = "";
2107                 $infix    = ":\t";
2108             }
2109             else {
2110                 $infix    = "):\t";
2111                 $position = "$prefix$line$infix$dbline[$line]$after";
2112             }
2113
2114             # Print current line info, indenting if necessary.
2115             if ($frame) {
2116                 print_lineinfo( ' ' x $stack_depth,
2117                     "$line:\t$dbline[$line]$after" );
2118             }
2119             else {
2120                 print_lineinfo($position);
2121             }
2122
2123             # Scan forward, stopping at either the end or the next
2124             # unbreakable line.
2125             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2126             {    #{ vi
2127
2128                 # Drop out on null statements, block closers, and comments.
2129                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2130
2131                 # Drop out if the user interrupted us.
2132                 last if $signal;
2133
2134                 # Append a newline if the line doesn't have one. Can happen
2135                 # in eval'ed text, for instance.
2136                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2137
2138                 # Next executable line.
2139                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2140                 $position .= $incr_pos;
2141                 if ($frame) {
2142
2143                     # Print it indented if tracing is on.
2144                     print_lineinfo( ' ' x $stack_depth,
2145                         "$i:\t$dbline[$i]$after" );
2146                 }
2147                 else {
2148                     print_lineinfo($incr_pos);
2149                 }
2150             } ## end for ($i = $line + 1 ; $i...
2151         } ## end else [ if ($slave_editor)
2152     } ## end if ($single || ($trace...
2153
2154 =pod
2155
2156 If there's an action to be executed for the line we stopped at, execute it.
2157 If there are any preprompt actions, execute those as well.
2158
2159 =cut
2160
2161     # If there's an action, do it now.
2162     $evalarg = $action, &eval if $action;
2163
2164     # Are we nested another level (e.g., did we evaluate a function
2165     # that had a breakpoint in it at the debugger prompt)?
2166     if ( $single || $was_signal ) {
2167
2168         # Yes, go down a level.
2169         local $level = $level + 1;
2170
2171         # Do any pre-prompt actions.
2172         foreach $evalarg (@$pre) {
2173             &eval;
2174         }
2175
2176         # Complain about too much recursion if we passed the limit.
2177         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2178           if $single & 4;
2179
2180         # The line we're currently on. Set $incr to -1 to stay here
2181         # until we get a command that tells us to advance.
2182         $start = $line;
2183         $incr  = -1;      # for backward motion.
2184
2185         # Tack preprompt debugger actions ahead of any actual input.
2186         @typeahead = ( @$pretype, @typeahead );
2187
2188 =head2 WHERE ARE WE?
2189
2190 XXX Relocate this section?
2191
2192 The debugger normally shows the line corresponding to the current line of
2193 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2194 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2195
2196 C<$incr> controls by how many lines the I<current> line should move forward
2197 after a command is executed. If set to -1, this indicates that the I<current>
2198 line shouldn't change.
2199
2200 C<$start> is the I<current> line. It is used for things like knowing where to
2201 move forwards or backwards from when doing an C<L> or C<-> command.
2202
2203 C<$max> tells the debugger where the last line of the current file is. It's
2204 used to terminate loops most often.
2205
2206 =head2 THE COMMAND LOOP
2207
2208 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2209 in two parts:
2210
2211 =over 4
2212
2213 =item *
2214
2215 The outer part of the loop, starting at the C<CMD> label. This loop
2216 reads a command and then executes it.
2217
2218 =item *
2219
2220 The inner part of the loop, starting at the C<PIPE> label. This part
2221 is wholly contained inside the C<CMD> block and only executes a command.
2222 Used to handle commands running inside a pager.
2223
2224 =back
2225
2226 So why have two labels to restart the loop? Because sometimes, it's easier to
2227 have a command I<generate> another command and then re-execute the loop to do
2228 the new command. This is faster, but perhaps a bit more convoluted.
2229
2230 =cut
2231
2232         # The big command dispatch loop. It keeps running until the
2233         # user yields up control again.
2234         #
2235         # If we have a terminal for input, and we get something back
2236         # from readline(), keep on processing.
2237       CMD:
2238         while (
2239
2240             # We have a terminal, or can get one ...
2241             ( $term || &setterm ),
2242
2243             # ... and it belogs to this PID or we get one for this PID ...
2244             ( $term_pid == $$ or resetterm(1) ),
2245
2246             # ... and we got a line of command input ...
2247             defined(
2248                 $cmd = &readline(
2249                         "$pidprompt $tid DB"
2250                       . ( '<' x $level )
2251                       . ( $#hist + 1 )
2252                       . ( '>' x $level ) . " "
2253                 )
2254             )
2255           )
2256         {
2257
2258                         share($cmd);
2259             # ... try to execute the input as debugger commands.
2260
2261             # Don't stop running.
2262             $single = 0;
2263
2264             # No signal is active.
2265             $signal = 0;
2266
2267             # Handle continued commands (ending with \):
2268             $cmd =~ s/\\$/\n/ && do {
2269                 $cmd .= &readline("  cont: ");
2270                 redo CMD;
2271             };
2272
2273 =head4 The null command
2274
2275 A newline entered by itself means I<re-execute the last command>. We grab the
2276 command out of C<$laststep> (where it was recorded previously), and copy it
2277 back into C<$cmd> to be executed below. If there wasn't any previous command,
2278 we'll do nothing below (no command will match). If there was, we also save it
2279 in the command history and fall through to allow the command parsing to pick
2280 it up.
2281
2282 =cut
2283
2284             # Empty input means repeat the last command.
2285             $cmd =~ /^$/ && ( $cmd = $laststep );
2286             chomp($cmd);    # get rid of the annoying extra newline
2287             push( @hist, $cmd ) if length($cmd) > 1;
2288             push( @truehist, $cmd );
2289                         share(@hist);
2290                         share(@truehist);
2291
2292             # This is a restart point for commands that didn't arrive
2293             # via direct user input. It allows us to 'redo PIPE' to
2294             # re-execute command processing without reading a new command.
2295           PIPE: {
2296                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2297                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2298                 ($i) = split( /\s+/, $cmd );
2299
2300 =head3 COMMAND ALIASES
2301
2302 The debugger can create aliases for commands (these are stored in the
2303 C<%alias> hash). Before a command is executed, the command loop looks it up
2304 in the alias hash and substitutes the contents of the alias for the command,
2305 completely replacing it.
2306
2307 =cut
2308
2309                 # See if there's an alias for the command, and set it up if so.
2310                 if ( $alias{$i} ) {
2311
2312                     # Squelch signal handling; we want to keep control here
2313                     # if something goes loco during the alias eval.
2314                     local $SIG{__DIE__};
2315                     local $SIG{__WARN__};
2316
2317                     # This is a command, so we eval it in the DEBUGGER's
2318                     # scope! Otherwise, we can't see the special debugger
2319                     # variables, or get to the debugger's subs. (Well, we
2320                     # _could_, but why make it even more complicated?)
2321                     eval "\$cmd =~ $alias{$i}";
2322                     if ($@) {
2323                         local $\ = '';
2324                         print $OUT "Couldn't evaluate `$i' alias: $@";
2325                         next CMD;
2326                     }
2327                 } ## end if ($alias{$i})
2328
2329 =head3 MAIN-LINE COMMANDS
2330
2331 All of these commands work up to and after the program being debugged has
2332 terminated.
2333
2334 =head4 C<q> - quit
2335
2336 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2337 try to execute further, cleaning any restart-related stuff out of the
2338 environment, and executing with the last value of C<$?>.
2339
2340 =cut
2341
2342                 $cmd =~ /^q$/ && do {
2343                     $fall_off_end = 1;
2344                     clean_ENV();
2345                     exit $?;
2346                 };
2347
2348 =head4 C<t> - trace
2349
2350 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2351
2352 =cut
2353
2354                 $cmd =~ /^t$/ && do {
2355                     $trace ^= 1;
2356                     local $\ = '';
2357                     print $OUT "Trace = "
2358                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2359                     next CMD;
2360                 };
2361
2362 =head4 C<S> - list subroutines matching/not matching a pattern
2363
2364 Walks through C<%sub>, checking to see whether or not to print the name.
2365
2366 =cut
2367
2368                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2369
2370                     $Srev     = defined $2;     # Reverse scan?
2371                     $Spatt    = $3;             # The pattern (if any) to use.
2372                     $Snocheck = !defined $1;    # No args - print all subs.
2373
2374                     # Need to make these sane here.
2375                     local $\ = '';
2376                     local $, = '';
2377
2378                     # Search through the debugger's magical hash of subs.
2379                     # If $nocheck is true, just print the sub name.
2380                     # Otherwise, check it against the pattern. We then use
2381                     # the XOR trick to reverse the condition as required.
2382                     foreach $subname ( sort( keys %sub ) ) {
2383                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2384                             print $OUT $subname, "\n";
2385                         }
2386                     }
2387                     next CMD;
2388                 };
2389
2390 =head4 C<X> - list variables in current package
2391
2392 Since the C<V> command actually processes this, just change this to the
2393 appropriate C<V> command and fall through.
2394
2395 =cut
2396
2397                 $cmd =~ s/^X\b/V $package/;
2398
2399 =head4 C<V> - list variables
2400
2401 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2402
2403 =cut
2404
2405                 # Bare V commands get the currently-being-debugged package
2406                 # added.
2407                 $cmd =~ /^V$/ && do {
2408                     $cmd = "V $package";
2409                 };
2410
2411                 # V - show variables in package.
2412                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2413
2414                     # Save the currently selected filehandle and
2415                     # force output to debugger's filehandle (dumpvar
2416                     # just does "print" for output).
2417                     local ($savout) = select($OUT);
2418
2419                     # Grab package name and variables to dump.
2420                     $packname = $1;
2421                     @vars     = split( ' ', $2 );
2422
2423                     # If main::dumpvar isn't here, get it.
2424                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2425                     if ( defined &main::dumpvar ) {
2426
2427                         # We got it. Turn off subroutine entry/exit messages
2428                         # for the moment, along with return values.
2429                         local $frame = 0;
2430                         local $doret = -2;
2431
2432                         # must detect sigpipe failures  - not catching
2433                         # then will cause the debugger to die.
2434                         eval {
2435                             &main::dumpvar(
2436                                 $packname,
2437                                 defined $option{dumpDepth}
2438                                 ? $option{dumpDepth}
2439                                 : -1,    # assume -1 unless specified
2440                                 @vars
2441                             );
2442                         };
2443
2444                         # The die doesn't need to include the $@, because
2445                         # it will automatically get propagated for us.
2446                         if ($@) {
2447                             die unless $@ =~ /dumpvar print failed/;
2448                         }
2449                     } ## end if (defined &main::dumpvar)
2450                     else {
2451
2452                         # Couldn't load dumpvar.
2453                         print $OUT "dumpvar.pl not available.\n";
2454                     }
2455
2456                     # Restore the output filehandle, and go round again.
2457                     select($savout);
2458                     next CMD;
2459                 };
2460
2461 =head4 C<x> - evaluate and print an expression
2462
2463 Hands the expression off to C<DB::eval>, setting it up to print the value
2464 via C<dumpvar.pl> instead of just printing it directly.
2465
2466 =cut
2467
2468                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2469                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2470
2471                     # handle special  "x 3 blah" syntax XXX propagate
2472                     # doc back to special variables.
2473                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2474                         $onetimedumpDepth = $1;
2475                     }
2476                 };
2477
2478 =head4 C<m> - print methods
2479
2480 Just uses C<DB::methods> to determine what methods are available.
2481
2482 =cut
2483
2484                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2485                     methods($1);
2486                     next CMD;
2487                 };
2488
2489                 # m expr - set up DB::eval to do the work
2490                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2491                     $onetimeDump = 'methods';   #  method output gets used there
2492                 };
2493
2494 =head4 C<f> - switch files
2495
2496 =cut
2497
2498                 $cmd =~ /^f\b\s*(.*)/ && do {
2499                     $file = $1;
2500                     $file =~ s/\s+$//;
2501
2502                     # help for no arguments (old-style was return from sub).
2503                     if ( !$file ) {
2504                         print $OUT
2505                           "The old f command is now the r command.\n";    # hint
2506                         print $OUT "The new f command switches filenames.\n";
2507                         next CMD;
2508                     } ## end if (!$file)
2509
2510                     # if not in magic file list, try a close match.
2511                     if ( !defined $main::{ '_<' . $file } ) {
2512                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2513                             {
2514                                 $try = substr( $try, 2 );
2515                                 print $OUT "Choosing $try matching `$file':\n";
2516                                 $file = $try;
2517                             }
2518                         } ## end if (($try) = grep(m#^_<.*$file#...
2519                     } ## end if (!defined $main::{ ...
2520
2521                     # If not successfully switched now, we failed.
2522                     if ( !defined $main::{ '_<' . $file } ) {
2523                         print $OUT "No file matching `$file' is loaded.\n";
2524                         next CMD;
2525                     }
2526
2527                     # We switched, so switch the debugger internals around.
2528                     elsif ( $file ne $filename ) {
2529                         *dbline   = $main::{ '_<' . $file };
2530                         $max      = $#dbline;
2531                         $filename = $file;
2532                         $start    = 1;
2533                         $cmd      = "l";
2534                     } ## end elsif ($file ne $filename)
2535
2536                     # We didn't switch; say we didn't.
2537                     else {
2538                         print $OUT "Already in $file.\n";
2539                         next CMD;
2540                     }
2541                 };
2542
2543 =head4 C<.> - return to last-executed line.
2544
2545 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2546 and then we look up the line in the magical C<%dbline> hash.
2547
2548 =cut
2549
2550                 # . command.
2551                 $cmd =~ /^\.$/ && do {
2552                     $incr = -1;    # stay at current line
2553
2554                     # Reset everything to the old location.
2555                     $start    = $line;
2556                     $filename = $filename_ini;
2557                     *dbline   = $main::{ '_<' . $filename };
2558                     $max      = $#dbline;
2559
2560                     # Now where are we?
2561                     print_lineinfo($position);
2562                     next CMD;
2563                 };
2564
2565 =head4 C<-> - back one window
2566
2567 We change C<$start> to be one window back; if we go back past the first line,
2568 we set it to be the first line. We ser C<$incr> to put us back at the
2569 currently-executing line, and then put a C<l $start +> (list one window from
2570 C<$start>) in C<$cmd> to be executed later.
2571
2572 =cut
2573
2574                 # - - back a window.
2575                 $cmd =~ /^-$/ && do {
2576
2577                     # back up by a window; go to 1 if back too far.
2578                     $start -= $incr + $window + 1;
2579                     $start = 1 if $start <= 0;
2580                     $incr  = $window - 1;
2581
2582                     # Generate and execute a "l +" command (handled below).
2583                     $cmd = 'l ' . ($start) . '+';
2584                 };
2585
2586 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2587
2588 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2589 problems, most notably that the default case of several commands destroying
2590 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2591 retain the old commands for those who were used to using them or who preferred
2592 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2593 deal with them instead of processing them in-line.
2594
2595 =cut
2596
2597                 # All of these commands were remapped in perl 5.8.0;
2598                 # we send them off to the secondary dispatcher (see below).
2599                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2600                     &cmd_wrapper( $1, $2, $line );
2601                     next CMD;
2602                 };
2603
2604 =head4 C<y> - List lexicals in higher scope
2605
2606 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2607 above the current one and then displays then using C<dumpvar.pl>.
2608
2609 =cut
2610
2611                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2612
2613                     # See if we've got the necessary support.
2614                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2615                       or &warn(
2616                         $@ =~ /locate/
2617                         ? "PadWalker module not found - please install\n"
2618                         : $@
2619                       )
2620                       and next CMD;
2621
2622                     # Load up dumpvar if we don't have it. If we can, that is.
2623                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2624                     defined &main::dumpvar
2625                       or print $OUT "dumpvar.pl not available.\n"
2626                       and next CMD;
2627
2628                     # Got all the modules we need. Find them and print them.
2629                     my @vars = split( ' ', $2 || '' );
2630
2631                     # Find the pad.
2632                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2633
2634                     # Oops. Can't find it.
2635                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2636
2637                     # Show the desired vars with dumplex().
2638                     my $savout = select($OUT);
2639
2640                     # Have dumplex dump the lexicals.
2641                     dumpvar::dumplex( $_, $h->{$_},
2642                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2643                         @vars )
2644                       for sort keys %$h;
2645                     select($savout);
2646                     next CMD;
2647                 };
2648
2649 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2650
2651 All of the commands below this point don't work after the program being
2652 debugged has ended. All of them check to see if the program has ended; this
2653 allows the commands to be relocated without worrying about a 'line of
2654 demarcation' above which commands can be entered anytime, and below which
2655 they can't.
2656
2657 =head4 C<n> - single step, but don't trace down into subs
2658
2659 Done by setting C<$single> to 2, which forces subs to execute straight through
2660 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2661 so a null command knows what to re-execute.
2662
2663 =cut
2664
2665                 # n - next
2666                 $cmd =~ /^n$/ && do {
2667                     end_report(), next CMD if $finished and $level <= 1;
2668
2669                     # Single step, but don't enter subs.
2670                     $single = 2;
2671
2672                     # Save for empty command (repeat last).
2673                     $laststep = $cmd;
2674                     last CMD;
2675                 };
2676
2677 =head4 C<s> - single-step, entering subs
2678
2679 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2680 subs. Also saves C<s> as C<$lastcmd>.
2681
2682 =cut
2683
2684                 # s - single step.
2685                 $cmd =~ /^s$/ && do {
2686
2687                     # Get out and restart the command loop if program
2688                     # has finished.
2689                     end_report(), next CMD if $finished and $level <= 1;
2690
2691                     # Single step should enter subs.
2692                     $single = 1;
2693
2694                     # Save for empty command (repeat last).
2695                     $laststep = $cmd;
2696                     last CMD;
2697                 };
2698
2699 =head4 C<c> - run continuously, setting an optional breakpoint
2700
2701 Most of the code for this command is taken up with locating the optional
2702 breakpoint, which is either a subroutine name or a line number. We set
2703 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2704 in this and all call levels above this one.
2705
2706 =cut
2707
2708                 # c - start continuous execution.
2709                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2710
2711                     # Hey, show's over. The debugged program finished
2712                     # executing already.
2713                     end_report(), next CMD if $finished and $level <= 1;
2714
2715                     # Capture the place to put a one-time break.
2716                     $subname = $i = $1;
2717
2718                     #  Probably not needed, since we finish an interactive
2719                     #  sub-session anyway...
2720                     # local $filename = $filename;
2721                     # local *dbline = *dbline; # XXX Would this work?!
2722                     #
2723                     # The above question wonders if localizing the alias
2724                     # to the magic array works or not. Since it's commented
2725                     # out, we'll just leave that to speculation for now.
2726
2727                     # If the "subname" isn't all digits, we'll assume it
2728                     # is a subroutine name, and try to find it.
2729                     if ( $subname =~ /\D/ ) {    # subroutine name
2730                             # Qualify it to the current package unless it's
2731                             # already qualified.
2732                         $subname = $package . "::" . $subname
2733                           unless $subname =~ /::/;
2734
2735                         # find_sub will return "file:line_number" corresponding
2736                         # to where the subroutine is defined; we call find_sub,
2737                         # break up the return value, and assign it in one
2738                         # operation.
2739                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2740
2741                         # Force the line number to be numeric.
2742                         $i += 0;
2743
2744                         # If we got a line number, we found the sub.
2745                         if ($i) {
2746
2747                             # Switch all the debugger's internals around so
2748                             # we're actually working with that file.
2749                             $filename = $file;
2750                             *dbline   = $main::{ '_<' . $filename };
2751
2752                             # Mark that there's a breakpoint in this file.
2753                             $had_breakpoints{$filename} |= 1;
2754
2755                             # Scan forward to the first executable line
2756                             # after the 'sub whatever' line.
2757                             $max = $#dbline;
2758                             ++$i while $dbline[$i] == 0 && $i < $max;
2759                         } ## end if ($i)
2760
2761                         # We didn't find a sub by that name.
2762                         else {
2763                             print $OUT "Subroutine $subname not found.\n";
2764                             next CMD;
2765                         }
2766                     } ## end if ($subname =~ /\D/)
2767
2768                     # At this point, either the subname was all digits (an
2769                     # absolute line-break request) or we've scanned through
2770                     # the code following the definition of the sub, looking
2771                     # for an executable, which we may or may not have found.
2772                     #
2773                     # If $i (which we set $subname from) is non-zero, we
2774                     # got a request to break at some line somewhere. On
2775                     # one hand, if there wasn't any real subroutine name
2776                     # involved, this will be a request to break in the current
2777                     # file at the specified line, so we have to check to make
2778                     # sure that the line specified really is breakable.
2779                     #
2780                     # On the other hand, if there was a subname supplied, the
2781                     # preceding block has moved us to the proper file and
2782                     # location within that file, and then scanned forward
2783                     # looking for the next executable line. We have to make
2784                     # sure that one was found.
2785                     #
2786                     # On the gripping hand, we can't do anything unless the
2787                     # current value of $i points to a valid breakable line.
2788                     # Check that.
2789                     if ($i) {
2790
2791                         # Breakable?
2792                         if ( $dbline[$i] == 0 ) {
2793                             print $OUT "Line $i not breakable.\n";
2794                             next CMD;
2795                         }
2796
2797                         # Yes. Set up the one-time-break sigil.
2798                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2799                     } ## end if ($i)
2800
2801                     # Turn off stack tracing from here up.
2802                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2803                         $stack[ $i++ ] &= ~1;
2804                     }
2805                     last CMD;
2806                 };
2807
2808 =head4 C<r> - return from a subroutine
2809
2810 For C<r> to work properly, the debugger has to stop execution again
2811 immediately after the return is executed. This is done by forcing
2812 single-stepping to be on in the call level above the current one. If
2813 we are printing return values when a C<r> is executed, set C<$doret>
2814 appropriately, and force us out of the command loop.
2815
2816 =cut
2817
2818                 # r - return from the current subroutine.
2819                 $cmd =~ /^r$/ && do {
2820
2821                     # Can't do anythign if the program's over.
2822                     end_report(), next CMD if $finished and $level <= 1;
2823
2824                     # Turn on stack trace.
2825                     $stack[$stack_depth] |= 1;
2826
2827                     # Print return value unless the stack is empty.
2828                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2829                     last CMD;
2830                 };
2831
2832 =head4 C<T> - stack trace
2833
2834 Just calls C<DB::print_trace>.
2835
2836 =cut
2837
2838                 $cmd =~ /^T$/ && do {
2839                     print_trace( $OUT, 1 );    # skip DB
2840                     next CMD;
2841                 };
2842
2843 =head4 C<w> - List window around current line.
2844
2845 Just calls C<DB::cmd_w>.
2846
2847 =cut
2848
2849                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2850
2851 =head4 C<W> - watch-expression processing.
2852
2853 Just calls C<DB::cmd_W>.
2854
2855 =cut
2856
2857                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2858
2859 =head4 C</> - search forward for a string in the source
2860
2861 We take the argument and treat it as a pattern. If it turns out to be a
2862 bad one, we return the error we got from trying to C<eval> it and exit.
2863 If not, we create some code to do the search and C<eval> it so it can't
2864 mess us up.
2865
2866 =cut
2867
2868                 $cmd =~ /^\/(.*)$/ && do {
2869
2870                     # The pattern as a string.
2871                     $inpat = $1;
2872
2873                     # Remove the final slash.
2874                     $inpat =~ s:([^\\])/$:$1:;
2875
2876                     # If the pattern isn't null ...
2877                     if ( $inpat ne "" ) {
2878
2879                         # Turn of warn and die procesing for a bit.
2880                         local $SIG{__DIE__};
2881                         local $SIG{__WARN__};
2882
2883                         # Create the pattern.
2884                         eval '$inpat =~ m' . "\a$inpat\a";
2885                         if ( $@ ne "" ) {
2886
2887                             # Oops. Bad pattern. No biscuit.
2888                             # Print the eval error and go back for more
2889                             # commands.
2890                             print $OUT "$@";
2891                             next CMD;
2892                         }
2893                         $pat = $inpat;
2894                     } ## end if ($inpat ne "")
2895
2896                     # Set up to stop on wrap-around.
2897                     $end = $start;
2898
2899                     # Don't move off the current line.
2900                     $incr = -1;
2901
2902                     # Done in eval so nothing breaks if the pattern
2903                     # does something weird.
2904                     eval '
2905                         for (;;) {
2906                             # Move ahead one line.
2907                             ++$start;
2908
2909                             # Wrap if we pass the last line.
2910                             $start = 1 if ($start > $max);
2911
2912                             # Stop if we have gotten back to this line again,
2913                             last if ($start == $end);
2914
2915                             # A hit! (Note, though, that we are doing
2916                             # case-insensitive matching. Maybe a qr//
2917                             # expression would be better, so the user could
2918                             # do case-sensitive matching if desired.
2919                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2920                                 if ($slave_editor) {
2921                                     # Handle proper escaping in the slave.
2922                                     print $OUT "\032\032$filename:$start:0\n";
2923                                 }
2924                                 else {
2925                                     # Just print the line normally.
2926                                     print $OUT "$start:\t",$dbline[$start],"\n";
2927                                 }
2928                                 # And quit since we found something.
2929                                 last;
2930                             }
2931                          } ';
2932
2933                     # If we wrapped, there never was a match.
2934                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2935                     next CMD;
2936                 };
2937
2938 =head4 C<?> - search backward for a string in the source
2939
2940 Same as for C</>, except the loop runs backwards.
2941
2942 =cut
2943
2944                 # ? - backward pattern search.
2945                 $cmd =~ /^\?(.*)$/ && do {
2946
2947                     # Get the pattern, remove trailing question mark.
2948                     $inpat = $1;
2949                     $inpat =~ s:([^\\])\?$:$1:;
2950
2951                     # If we've got one ...
2952                     if ( $inpat ne "" ) {
2953
2954                         # Turn off die & warn handlers.
2955                         local $SIG{__DIE__};
2956                         local $SIG{__WARN__};
2957                         eval '$inpat =~ m' . "\a$inpat\a";
2958
2959                         if ( $@ ne "" ) {
2960
2961                             # Ouch. Not good. Print the error.
2962                             print $OUT $@;
2963                             next CMD;
2964                         }
2965                         $pat = $inpat;
2966                     } ## end if ($inpat ne "")
2967
2968                     # Where we are now is where to stop after wraparound.
2969                     $end = $start;
2970
2971                     # Don't move away from this line.
2972                     $incr = -1;
2973
2974                     # Search inside the eval to prevent pattern badness
2975                     # from killing us.
2976                     eval '
2977                         for (;;) {
2978                             # Back up a line.
2979                             --$start;
2980
2981                             # Wrap if we pass the first line.
2982
2983                             $start = $max if ($start <= 0);
2984
2985                             # Quit if we get back where we started,
2986                             last if ($start == $end);
2987
2988                             # Match?
2989                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2990                                 if ($slave_editor) {
2991                                     # Yep, follow slave editor requirements.
2992                                     print $OUT "\032\032$filename:$start:0\n";
2993                                 }
2994                                 else {
2995                                     # Yep, just print normally.
2996                                     print $OUT "$start:\t",$dbline[$start],"\n";
2997                                 }
2998
2999                                 # Found, so done.
3000                                 last;
3001                             }
3002                         } ';
3003
3004                     # Say we failed if the loop never found anything,
3005                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3006                     next CMD;
3007                 };
3008
3009 =head4 C<$rc> - Recall command
3010
3011 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3012 that the terminal supports history). It find the the command required, puts it
3013 into C<$cmd>, and redoes the loop to execute it.
3014
3015 =cut
3016
3017                 # $rc - recall command.
3018                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3019
3020                     # No arguments, take one thing off history.
3021                     pop(@hist) if length($cmd) > 1;
3022
3023                     # Relative (- found)?
3024                     #  Y - index back from most recent (by 1 if bare minus)
3025                     #  N - go to that particular command slot or the last
3026                     #      thing if nothing following.
3027                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3028
3029                     # Pick out the command desired.
3030                     $cmd = $hist[$i];
3031
3032                     # Print the command to be executed and restart the loop
3033                     # with that command in the buffer.
3034                     print $OUT $cmd, "\n";
3035                     redo CMD;
3036                 };
3037
3038 =head4 C<$sh$sh> - C<system()> command
3039
3040 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3041 C<STDOUT> from getting messed up.
3042
3043 =cut
3044
3045                 # $sh$sh - run a shell command (if it's all ASCII).
3046                 # Can't run shell commands with Unicode in the debugger, hmm.
3047                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3048
3049                     # System it.
3050                     &system($1);
3051                     next CMD;
3052                 };
3053
3054 =head4 C<$rc I<pattern> $rc> - Search command history
3055
3056 Another command to manipulate C<@hist>: this one searches it with a pattern.
3057 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3058
3059 =cut
3060
3061                 # $rc pattern $rc - find a command in the history.
3062                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3063
3064                     # Create the pattern to use.
3065                     $pat = "^$1";
3066
3067                     # Toss off last entry if length is >1 (and it always is).
3068                     pop(@hist) if length($cmd) > 1;
3069
3070                     # Look backward through the history.
3071                     for ( $i = $#hist ; $i ; --$i ) {
3072
3073                         # Stop if we find it.
3074                         last if $hist[$i] =~ /$pat/;
3075                     }
3076
3077                     if ( !$i ) {
3078
3079                         # Never found it.
3080                         print $OUT "No such command!\n\n";
3081                         next CMD;
3082                     }
3083
3084                     # Found it. Put it in the buffer, print it, and process it.
3085                     $cmd = $hist[$i];
3086                     print $OUT $cmd, "\n";
3087                     redo CMD;
3088                 };
3089
3090 =head4 C<$sh> - Invoke a shell
3091
3092 Uses C<DB::system> to invoke a shell.
3093
3094 =cut
3095
3096                 # $sh - start a shell.
3097                 $cmd =~ /^$sh$/ && do {
3098
3099                     # Run the user's shell. If none defined, run Bourne.
3100                     # We resume execution when the shell terminates.
3101                     &system( $ENV{SHELL} || "/bin/sh" );
3102                     next CMD;
3103                 };
3104
3105 =head4 C<$sh I<command>> - Force execution of a command in a shell
3106
3107 Like the above, but the command is passed to the shell. Again, we use
3108 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3109
3110 =cut
3111
3112                 # $sh command - start a shell and run a command in it.
3113                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3114
3115                     # XXX: using csh or tcsh destroys sigint retvals!
3116                     #&system($1);  # use this instead
3117
3118                     # use the user's shell, or Bourne if none defined.
3119                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3120                     next CMD;
3121                 };
3122
3123 =head4 C<H> - display commands in history
3124
3125 Prints the contents of C<@hist> (if any).
3126
3127 =cut
3128
3129                 $cmd =~ /^H\b\s*\*/ && do {
3130                     @hist = @truehist = ();
3131                     print $OUT "History cleansed\n";
3132                     next CMD;
3133                 };
3134
3135                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3136
3137                     # Anything other than negative numbers is ignored by
3138                     # the (incorrect) pattern, so this test does nothing.
3139                     $end = $2 ? ( $#hist - $2 ) : 0;
3140
3141                     # Set to the minimum if less than zero.
3142                     $hist = 0 if $hist < 0;
3143
3144                     # Start at the end of the array.
3145                     # Stay in while we're still above the ending value.
3146                     # Tick back by one each time around the loop.
3147                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3148
3149                         # Print the command  unless it has no arguments.
3150                         print $OUT "$i: ", $hist[$i], "\n"
3151                           unless $hist[$i] =~ /^.?$/;
3152                     }
3153                     next CMD;
3154                 };
3155
3156 =head4 C<man, doc, perldoc> - look up documentation
3157
3158 Just calls C<runman()> to print the appropriate document.
3159
3160 =cut
3161
3162                 # man, perldoc, doc - show manual pages.
3163                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3164                     runman($1);
3165                     next CMD;
3166                 };
3167
3168 =head4 C<p> - print
3169
3170 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3171 the bottom of the loop.
3172
3173 =cut
3174
3175                 # p - print (no args): print $_.
3176                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3177
3178                 # p - print the given expression.
3179                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3180
3181 =head4 C<=> - define command alias
3182
3183 Manipulates C<%alias> to add or list command aliases.
3184
3185 =cut
3186
3187                 # = - set up a command alias.
3188                 $cmd =~ s/^=\s*// && do {
3189                     my @keys;
3190                     if ( length $cmd == 0 ) {
3191
3192                         # No args, get current aliases.
3193                         @keys = sort keys %alias;
3194                     }
3195                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3196
3197                         # Creating a new alias. $k is alias name, $v is
3198                         # alias value.
3199
3200                         # can't use $_ or kill //g state
3201                         for my $x ( $k, $v ) {
3202
3203                             # Escape "alarm" characters.
3204                             $x =~ s/\a/\\a/g;
3205                         }
3206
3207                         # Substitute key for value, using alarm chars
3208                         # as separators (which is why we escaped them in
3209                         # the command).
3210                         $alias{$k} = "s\a$k\a$v\a";
3211
3212                         # Turn off standard warn and die behavior.
3213                         local $SIG{__DIE__};
3214                         local $SIG{__WARN__};
3215
3216                         # Is it valid Perl?
3217                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3218
3219                             # Nope. Bad alias. Say so and get out.
3220                             print $OUT "Can't alias $k to $v: $@\n";
3221                             delete $alias{$k};
3222                             next CMD;
3223                         }
3224
3225                         # We'll only list the new one.
3226                         @keys = ($k);
3227                     } ## end elsif (my ($k, $v) = ($cmd...
3228
3229                     # The argument is the alias to list.
3230                     else {
3231                         @keys = ($cmd);
3232                     }
3233
3234                     # List aliases.
3235                     for my $k (@keys) {
3236
3237                         # Messy metaquoting: Trim the substiution code off.
3238                         # We use control-G as the delimiter because it's not
3239                         # likely to appear in the alias.
3240                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3241
3242                             # Print the alias.
3243                             print $OUT "$k\t= $1\n";
3244                         }
3245                         elsif ( defined $alias{$k} ) {
3246
3247                             # Couldn't trim it off; just print the alias code.
3248                             print $OUT "$k\t$alias{$k}\n";
3249                         }
3250                         else {
3251
3252                             # No such, dude.
3253                             print "No alias for $k\n";
3254                         }
3255                     } ## end for my $k (@keys)
3256                     next CMD;
3257                 };
3258
3259 =head4 C<source> - read commands from a file.
3260
3261 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3262 pick it up.
3263
3264 =cut
3265
3266                 # source - read commands from a file (or pipe!) and execute.
3267                 $cmd =~ /^source\s+(.*\S)/ && do {
3268                     if ( open my $fh, $1 ) {
3269
3270                         # Opened OK; stick it in the list of file handles.
3271                         push @cmdfhs, $fh;
3272                     }
3273                     else {
3274
3275                         # Couldn't open it.
3276                         &warn("Can't execute `$1': $!\n");
3277                     }
3278                     next CMD;
3279                 };
3280
3281 =head4 C<save> - send current history to a file
3282
3283 Takes the complete history, (not the shrunken version you see with C<H>),
3284 and saves it to the given filename, so it can be replayed using C<source>.
3285
3286 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3287
3288 =cut
3289
3290                 # save source - write commands to a file for later use
3291                 $cmd =~ /^save\s*(.*)$/ && do {
3292                     my $file = $1 || '.perl5dbrc';    # default?
3293                     if ( open my $fh, "> $file" ) {
3294
3295                        # chomp to remove extraneous newlines from source'd files
3296                         chomp( my @truelist =
3297                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3298                               @truehist );
3299                         print $fh join( "\n", @truelist );
3300                         print "commands saved in $file\n";
3301                     }
3302                     else {
3303                         &warn("Can't save debugger commands in '$1': $!\n");
3304                     }
3305                     next CMD;
3306                 };
3307
3308 =head4 C<R> - restart
3309
3310 Restart the debugger session.
3311
3312 =head4 C<rerun> - rerun the current session
3313
3314 Return to any given position in the B<true>-history list
3315
3316 =cut
3317
3318                 # R - restart execution.
3319                 # rerun - controlled restart execution.
3320                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3321                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3322
3323                     # Close all non-system fds for a clean restart.  A more
3324                     # correct method would be to close all fds that were not
3325                     # open when the process started, but this seems to be
3326                     # hard.  See "debugger 'R'estart and open database
3327                     # connections" on p5p.
3328
3329                     my $max_fd = 1024; # default if POSIX can't be loaded
3330                     if (eval { require POSIX }) {
3331                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3332                     }
3333
3334                     if (defined $max_fd) {
3335                         foreach ($^F+1 .. $max_fd-1) {
3336                             next unless open FD_TO_CLOSE, "<&=$_";
3337                             close(FD_TO_CLOSE);
3338                         }
3339                     }
3340
3341                     # And run Perl again.  We use exec() to keep the
3342                     # PID stable (and that way $ini_pids is still valid).
3343                     exec(@args) || print $OUT "exec failed: $!\n";
3344
3345                     last CMD;
3346                 };
3347
3348 =head4 C<|, ||> - pipe output through the pager.
3349
3350 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3351 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3352 pipe to the pager (restoring the output filehandles if this fails). If this
3353 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3354 set C<$signal>, sending us back into the debugger.
3355
3356 We then trim off the pipe symbols and C<redo> the command loop at the
3357 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3358 reading another.
3359
3360 =cut
3361
3362                 # || - run command in the pager, with output to DB::OUT.
3363                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3364                     if ( $pager =~ /^\|/ ) {
3365
3366                         # Default pager is into a pipe. Redirect I/O.
3367                         open( SAVEOUT, ">&STDOUT" )
3368                           || &warn("Can't save STDOUT");
3369                         open( STDOUT, ">&OUT" )
3370                           || &warn("Can't redirect STDOUT");
3371                     } ## end if ($pager =~ /^\|/)
3372                     else {
3373
3374                         # Not into a pipe. STDOUT is safe.
3375                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3376                     }
3377
3378                     # Fix up environment to record we have less if so.
3379                     fix_less();
3380
3381                     unless ( $piped = open( OUT, $pager ) ) {
3382
3383                         # Couldn't open pipe to pager.
3384                         &warn("Can't pipe output to `$pager'");
3385                         if ( $pager =~ /^\|/ ) {
3386
3387                             # Redirect I/O back again.
3388                             open( OUT, ">&STDOUT" )    # XXX: lost message
3389                               || &warn("Can't restore DB::OUT");
3390                             open( STDOUT, ">&SAVEOUT" )
3391                               || &warn("Can't restore STDOUT");
3392                             close(SAVEOUT);
3393                         } ## end if ($pager =~ /^\|/)
3394                         else {
3395
3396                             # Redirect I/O. STDOUT already safe.
3397                             open( OUT, ">&STDOUT" )    # XXX: lost message
3398                               || &warn("Can't restore DB::OUT");
3399                         }
3400                         next CMD;
3401                     } ## end unless ($piped = open(OUT,...
3402
3403                     # Set up broken-pipe handler if necessary.
3404                     $SIG{PIPE} = \&DB::catch
3405                       if $pager =~ /^\|/
3406                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3407
3408                     # Save current filehandle, unbuffer out, and put it back.
3409                     $selected = select(OUT);
3410                     $|        = 1;
3411
3412                     # Don't put it back if pager was a pipe.
3413                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3414
3415                     # Trim off the pipe symbols and run the command now.
3416                     $cmd =~ s/^\|+\s*//;
3417                     redo PIPE;
3418                 };
3419
3420 =head3 END OF COMMAND PARSING
3421
3422 Anything left in C<$cmd> at this point is a Perl expression that we want to
3423 evaluate. We'll always evaluate in the user's context, and fully qualify
3424 any variables we might want to address in the C<DB> package.
3425
3426 =cut
3427
3428                 # t - turn trace on.
3429                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3430
3431                 # s - single-step. Remember the last command was 's'.
3432                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3433
3434                 # n - single-step, but not into subs. Remember last command
3435                 # was 'n'.
3436                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3437
3438             }    # PIPE:
3439
3440             # Make sure the flag that says "the debugger's running" is
3441             # still on, to make sure we get control again.
3442             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3443
3444             # Run *our* eval that executes in the caller's context.
3445             &eval;
3446
3447             # Turn off the one-time-dump stuff now.
3448             if ($onetimeDump) {
3449                 $onetimeDump      = undef;
3450                 $onetimedumpDepth = undef;
3451             }
3452             elsif ( $term_pid == $$ ) {
3453                 eval {          # May run under miniperl, when not available...
3454                     STDOUT->flush();
3455                     STDERR->flush();
3456                 };
3457
3458                 # XXX If this is the master pid, print a newline.
3459                 print $OUT "\n";
3460             }
3461         } ## end while (($term || &setterm...
3462
3463 =head3 POST-COMMAND PROCESSING
3464
3465 After each command, we check to see if the command output was piped anywhere.
3466 If so, we go through the necessary code to unhook the pipe and go back to
3467 our standard filehandles for input and output.
3468
3469 =cut
3470
3471         continue {    # CMD:
3472
3473             # At the end of every command:
3474             if ($piped) {
3475
3476                 # Unhook the pipe mechanism now.
3477                 if ( $pager =~ /^\|/ ) {
3478
3479                     # No error from the child.
3480                     $? = 0;
3481
3482                     # we cannot warn here: the handle is missing --tchrist
3483                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3484
3485                     # most of the $? crud was coping with broken cshisms
3486                     # $? is explicitly set to 0, so this never runs.
3487                     if ($?) {
3488                         print SAVEOUT "Pager `$pager' failed: ";
3489                         if ( $? == -1 ) {
3490                             print SAVEOUT "shell returned -1\n";
3491                         }
3492                         elsif ( $? >> 8 ) {
3493                             print SAVEOUT ( $? & 127 )
3494                               ? " (SIG#" . ( $? & 127 ) . ")"
3495                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3496                         }
3497                         else {
3498                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3499                         }
3500                     } ## end if ($?)
3501
3502                     # Reopen filehandle for our output (if we can) and
3503                     # restore STDOUT (if we can).
3504                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3505                     open( STDOUT, ">&SAVEOUT" )
3506                       || &warn("Can't restore STDOUT");
3507
3508                     # Turn off pipe exception handler if necessary.
3509                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3510
3511                     # Will stop ignoring SIGPIPE if done like nohup(1)
3512                     # does SIGINT but Perl doesn't give us a choice.
3513                 } ## end if ($pager =~ /^\|/)
3514                 else {
3515
3516                     # Non-piped "pager". Just restore STDOUT.
3517                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3518                 }
3519
3520                 # Close filehandle pager was using, restore the normal one
3521                 # if necessary,
3522                 close(SAVEOUT);
3523                 select($selected), $selected = "" unless $selected eq "";
3524
3525                 # No pipes now.
3526                 $piped = "";
3527             } ## end if ($piped)
3528         }    # CMD:
3529
3530 =head3 COMMAND LOOP TERMINATION
3531
3532 When commands have finished executing, we come here. If the user closed the
3533 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3534 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3535 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3536 The interpreter will then execute the next line and then return control to us
3537 again.
3538
3539 =cut
3540
3541         # No more commands? Quit.
3542         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3543
3544         # Evaluate post-prompt commands.
3545         foreach $evalarg (@$post) {
3546             &eval;
3547         }
3548     }    # if ($single || $signal)
3549
3550     # Put the user's globals back where you found them.
3551     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3552     ();
3553 } ## end sub DB
3554
3555 # The following code may be executed now:
3556 # BEGIN {warn 4}
3557
3558 =head2 sub
3559
3560 C<sub> is called whenever a subroutine call happens in the program being
3561 debugged. The variable C<$DB::sub> contains the name of the subroutine
3562 being called.
3563
3564 The core function of this subroutine is to actually call the sub in the proper
3565 context, capturing its output. This of course causes C<DB::DB> to get called
3566 again, repeating until the subroutine ends and returns control to C<DB::sub>
3567 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3568 return value, and returns its captured copy of the return value as its own
3569 return value. The value then feeds back into the program being debugged as if
3570 C<DB::sub> hadn't been there at all.
3571
3572 C<sub> does all the work of printing the subroutine entry and exit messages
3573 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3574 and also prints the return value if needed (for the C<r> command and if
3575 the 16 bit is set in C<$frame>).
3576
3577 It also tracks the subroutine call depth by saving the current setting of
3578 C<$single> in the C<@stack> package global; if this exceeds the value in
3579 C<$deep>, C<sub> automatically turns on printing of the current depth by
3580 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3581 of stop/don't stop on entry to subs set as it currently is set.
3582
3583 =head3 C<caller()> support
3584
3585 If C<caller()> is called from the package C<DB>, it provides some
3586 additional data, in the following order:
3587
3588 =over 4
3589
3590 =item * C<$package>
3591
3592 The package name the sub was in
3593
3594 =item * C<$filename>
3595
3596 The filename it was defined in
3597
3598 =item * C<$line>
3599
3600 The line number it was defined on
3601
3602 =item * C<$subroutine>
3603
3604 The subroutine name; C<(eval)> if an C<eval>().
3605
3606 =item * C<$hasargs>
3607
3608 1 if it has arguments, 0 if not
3609
3610 =item * C<$wantarray>
3611
3612 1 if array context, 0 if scalar context
3613
3614 =item * C<$evaltext>
3615
3616 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3617
3618 =item * C<$is_require>
3619
3620 frame was created by a C<use> or C<require> statement
3621
3622 =item * C<$hints>
3623
3624 pragma information; subject to change between versions
3625
3626 =item * C<$bitmask>
3627
3628 pragma information; subject to change between versions
3629
3630 =item * C<@DB::args>
3631
3632 arguments with which the subroutine was invoked
3633
3634 =back
3635
3636 =cut
3637
3638 sub sub {
3639
3640         # lock ourselves under threads
3641         lock($DBGR);
3642
3643     # Whether or not the autoloader was running, a scalar to put the
3644     # sub's return value in (if needed), and an array to put the sub's
3645     # return value in (if needed).
3646     my ( $al, $ret, @ret ) = "";
3647         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3648                 print "creating new thread\n";
3649         }
3650
3651     # If the last ten characters are C'::AUTOLOAD', note we've traced
3652     # into AUTOLOAD for $sub.
3653     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3654         $al = " for $$sub";
3655     }
3656
3657     # We stack the stack pointer and then increment it to protect us
3658     # from a situation that might unwind a whole bunch of call frames
3659     # at once. Localizing the stack pointer means that it will automatically
3660     # unwind the same amount when multiple stack frames are unwound.
3661     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3662
3663     # Expand @stack.
3664     $#stack = $stack_depth;
3665
3666     # Save current single-step setting.
3667     $stack[-1] = $single;
3668
3669     # Turn off all flags except single-stepping.
3670     $single &= 1;
3671
3672     # If we've gotten really deeply recursed, turn on the flag that will
3673     # make us stop with the 'deep recursion' message.
3674     $single |= 4 if $stack_depth == $deep;
3675
3676     # If frame messages are on ...
3677     (
3678         $frame & 4    # Extended frame entry message
3679         ? (
3680             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3681
3682             # Why -1? But it works! :-(
3683             # Because print_trace will call add 1 to it and then call
3684             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3685             # in dump_trace.
3686             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3687           )
3688         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3689
3690           # standard frame entry message
3691       )
3692       if $frame;
3693
3694     # Determine the sub's return type,and capture approppriately.
3695     if (wantarray) {
3696
3697         # Called in array context. call sub and capture output.
3698         # DB::DB will recursively get control again if appropriate; we'll come
3699         # back here when the sub is finished.
3700         if ($assertion) {
3701             $assertion = 0;
3702             eval { @ret = &$sub; };
3703             if ($@) {
3704                 print $OUT $@;
3705                 $signal = 1 unless $warnassertions;
3706             }
3707         }
3708         else {
3709             @ret = &$sub;
3710         }
3711
3712         # Pop the single-step value back off the stack.
3713         $single |= $stack[ $stack_depth-- ];
3714
3715         # Check for exit trace messages...
3716         (
3717             $frame & 4    # Extended exit message
3718             ? (
3719                 print_lineinfo( ' ' x $stack_depth, "out " ),
3720                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3721               )
3722             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3723
3724               # Standard exit message
3725           )
3726           if $frame & 2;
3727
3728         # Print the return info if we need to.
3729         if ( $doret eq $stack_depth or $frame & 16 ) {
3730
3731             # Turn off output record separator.
3732             local $\ = '';
3733             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3734
3735             # Indent if we're printing because of $frame tracing.
3736             print $fh ' ' x $stack_depth if $frame & 16;
3737
3738             # Print the return value.
3739             print $fh "list context return from $sub:\n";
3740             dumpit( $fh, \@ret );
3741
3742             # And don't print it again.
3743             $doret = -2;
3744         } ## end if ($doret eq $stack_depth...
3745             # And we have to return the return value now.
3746         @ret;
3747     } ## end if (wantarray)
3748
3749     # Scalar context.
3750     else {
3751         if ($assertion) {
3752             $assertion = 0;
3753             eval {
3754
3755                 # Save the value if it's wanted at all.
3756                 $ret = &$sub;
3757             };
3758             if ($@) {
3759                 print $OUT $@;
3760                 $signal = 1 unless $warnassertions;
3761             }
3762             $ret = undef unless defined wantarray;
3763         }
3764         else {
3765             if ( defined wantarray ) {
3766
3767                 # Save the value if it's wanted at all.
3768                 $ret = &$sub;
3769             }
3770             else {
3771
3772                 # Void return, explicitly.
3773                 &$sub;
3774                 undef $ret;
3775             }
3776         }    # if assertion
3777
3778         # Pop the single-step value off the stack.
3779         $single |= $stack[ $stack_depth-- ];
3780
3781         # If we're doing exit messages...
3782         (
3783             $frame & 4    # Extended messsages
3784             ? (
3785                 print_lineinfo( ' ' x $stack_depth, "out " ),
3786                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3787               )
3788             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3789
3790               # Standard messages
3791           )
3792           if $frame & 2;
3793
3794         # If we are supposed to show the return value... same as before.
3795         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3796             local $\ = '';
3797             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3798             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3799             print $fh (
3800                 defined wantarray
3801                 ? "scalar context return from $sub: "
3802                 : "void context return from $sub\n"
3803             );
3804             dumpit( $fh, $ret ) if defined wantarray;
3805             $doret = -2;
3806         } ## end if ($doret eq $stack_depth...
3807
3808         # Return the appropriate scalar value.
3809         $ret;
3810     } ## end else [ if (wantarray)
3811 } ## end sub sub
3812
3813 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3814
3815 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3816 Most of the changes were to systematize the command structure and to eliminate
3817 commands that threw away user input without checking.
3818
3819 The following sections describe the code added to make it easy to support
3820 multiple command sets with conflicting command names. This section is a start
3821 at unifying all command processing to make it simpler to develop commands.
3822
3823 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3824 number, and C<$dbline> (the current line) as arguments.
3825
3826 Support functions in this section which have multiple modes of failure C<die>
3827 on error; the rest simply return a false value.
3828
3829 The user-interface functions (all of the C<cmd_*> functions) just output
3830 error messages.
3831
3832 =head2 C<%set>
3833
3834 The C<%set> hash defines the mapping from command letter to subroutine
3835 name suffix.
3836
3837 C<%set> is a two-level hash, indexed by set name and then by command name.
3838 Note that trying to set the CommandSet to C<foobar> simply results in the
3839 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3840
3841 =cut
3842
3843 ### The API section
3844
3845 my %set = (    #
3846     'pre580' => {
3847         'a' => 'pre580_a',
3848         'A' => 'pre580_null',
3849         'b' => 'pre580_b',
3850         'B' => 'pre580_null',
3851         'd' => 'pre580_null',
3852         'D' => 'pre580_D',
3853         'h' => 'pre580_h',
3854         'M' => 'pre580_null',
3855         'O' => 'o',
3856         'o' => 'pre580_null',
3857         'v' => 'M',
3858         'w' => 'v',
3859         'W' => 'pre580_W',
3860     },
3861     'pre590' => {
3862         '<'  => 'pre590_prepost',
3863         '<<' => 'pre590_prepost',
3864         '>'  => 'pre590_prepost',
3865         '>>' => 'pre590_prepost',
3866         '{'  => 'pre590_prepost',
3867         '{{' => 'pre590_prepost',
3868     },
3869 );
3870
3871 =head2 C<cmd_wrapper()> (API)
3872
3873 C<cmd_wrapper()> allows the debugger to switch command sets
3874 depending on the value of the C<CommandSet> option.
3875
3876 It tries to look up the command in the C<%set> package-level I<lexical>
3877 (which means external entities can't fiddle with it) and create the name of
3878 the sub to call based on the value found in the hash (if it's there). I<All>
3879 of the commands to be handled in a set have to be added to C<%set>; if they
3880 aren't found, the 5.8.0 equivalent is called (if there is one).
3881
3882 This code uses symbolic references.
3883
3884 =cut
3885
3886 sub cmd_wrapper {
3887     my $cmd      = shift;
3888     my $line     = shift;
3889     my $dblineno = shift;
3890
3891     # Assemble the command subroutine's name by looking up the
3892     # command set and command name in %set. If we can't find it,
3893     # default to the older version of the command.
3894     my $call = 'cmd_'
3895       . ( $set{$CommandSet}{$cmd}
3896           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3897
3898     # Call the command subroutine, call it by name.
3899     return &$call( $cmd, $line, $dblineno );
3900 } ## end sub cmd_wrapper
3901
3902 =head3 C<cmd_a> (command)
3903
3904 The C<a> command handles pre-execution actions. These are associated with a
3905 particular line, so they're stored in C<%dbline>. We default to the current
3906 line if none is specified.
3907
3908 =cut
3909
3910 sub cmd_a {
3911     my $cmd    = shift;
3912     my $line   = shift || '';    # [.|line] expr
3913     my $dbline = shift;
3914
3915     # If it's dot (here), or not all digits,  use the current line.
3916     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3917
3918     # Should be a line number followed by an expression.
3919     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3920         my ( $lineno, $expr ) = ( $1, $2 );
3921
3922         # If we have an expression ...
3923         if ( length $expr ) {
3924
3925             # ... but the line isn't breakable, complain.
3926             if ( $dbline[$lineno] == 0 ) {
3927                 print $OUT
3928                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3929             }
3930             else {
3931
3932                 # It's executable. Record that the line has an action.
3933                 $had_breakpoints{$filename} |= 2;
3934
3935                 # Remove any action, temp breakpoint, etc.
3936                 $dbline{$lineno} =~ s/\0[^\0]*//;
3937
3938                 # Add the action to the line.
3939                 $dbline{$lineno} .= "\0" . action($expr);
3940             }
3941         } ## end if (length $expr)
3942     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3943     else {
3944
3945         # Syntax wrong.
3946         print $OUT
3947           "Adding an action requires an optional lineno and an expression\n"
3948           ;    # hint
3949     }
3950 } ## end sub cmd_a
3951
3952 =head3 C<cmd_A> (command)
3953
3954 Delete actions. Similar to above, except the delete code is in a separate
3955 subroutine, C<delete_action>.
3956
3957 =cut
3958
3959 sub cmd_A {
3960     my $cmd    = shift;
3961     my $line   = shift || '';
3962     my $dbline = shift;
3963
3964     # Dot is this line.
3965     $line =~ s/^\./$dbline/;
3966
3967     # Call delete_action with a null param to delete them all.
3968     # The '1' forces the eval to be true. It'll be false only
3969     # if delete_action blows up for some reason, in which case
3970     # we print $@ and get out.
3971     if ( $line eq '*' ) {
3972         eval { &delete_action(); 1 } or print $OUT $@ and return;
3973     }
3974
3975     # There's a real line  number. Pass it to delete_action.
3976     # Error trapping is as above.
3977     elsif ( $line =~ /^(\S.*)/ ) {
3978         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3979     }
3980
3981     # Swing and a miss. Bad syntax.
3982     else {
3983         print $OUT
3984           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3985     }
3986 } ## end sub cmd_A
3987
3988 =head3 C<delete_action> (API)
3989
3990 C<delete_action> accepts either a line number or C<undef>. If a line number
3991 is specified, we check for the line being executable (if it's not, it
3992 couldn't have had an  action). If it is, we just take the action off (this
3993 will get any kind of an action, including breakpoints).
3994
3995 =cut
3996
3997 sub delete_action {
3998     my $i = shift;
3999     if ( defined($i) ) {
4000
4001         # Can there be one?
4002         die "Line $i has no action .\n" if $dbline[$i] == 0;
4003
4004         # Nuke whatever's there.
4005         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4006         delete $dbline{$i} if $dbline{$i} eq '';
4007     }
4008     else {
4009         print $OUT "Deleting all actions...\n";
4010         for my $file ( keys %had_breakpoints ) {
4011             local *dbline = $main::{ '_<' . $file };
4012             my $max = $#dbline;
4013             my $was;
4014             for ( $i = 1 ; $i <= $max ; $i++ ) {
4015                 if ( defined $dbline{$i} ) {
4016                     $dbline{$i} =~ s/\0[^\0]*//;
4017                     delete $dbline{$i} if $dbline{$i} eq '';
4018                 }
4019                 unless ( $had_breakpoints{$file} &= ~2 ) {
4020                     delete $had_breakpoints{$file};
4021                 }
4022             } ## end for ($i = 1 ; $i <= $max...
4023         } ## end for my $file (keys %had_breakpoints)
4024     } ## end else [ if (defined($i))
4025 } ## end sub delete_action
4026
4027 =head3 C<cmd_b> (command)
4028
4029 Set breakpoints. Since breakpoints can be set in so many places, in so many
4030 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4031 we try to parse the command type, and then shuttle it off to an appropriate
4032 subroutine to actually do the work of setting the breakpoint in the right
4033 place.
4034
4035 =cut
4036
4037 sub cmd_b {
4038     my $cmd    = shift;
4039     my $line   = shift;    # [.|line] [cond]
4040     my $dbline = shift;
4041
4042     # Make . the current line number if it's there..
4043     $line =~ s/^\./$dbline/;
4044
4045     # No line number, no condition. Simple break on current line.
4046     if ( $line =~ /^\s*$/ ) {
4047         &cmd_b_line( $dbline, 1 );
4048     }
4049
4050     # Break on load for a file.
4051     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4052         my $file = $1;
4053         $file =~ s/\s+$//;
4054         &cmd_b_load($file);
4055     }
4056
4057     # b compile|postpone <some sub> [<condition>]
4058     # The interpreter actually traps this one for us; we just put the
4059     # necessary condition in the %postponed hash.
4060     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4061
4062         # Capture the condition if there is one. Make it true if none.
4063         my $cond = length $3 ? $3 : '1';
4064
4065         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4066         # if it was 'compile'.
4067         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4068
4069         # De-Perl4-ify the name - ' separators to ::.
4070         $subname =~ s/\'/::/g;
4071
4072         # Qualify it into the current package unless it's already qualified.
4073         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4074
4075         # Add main if it starts with ::.
4076         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4077
4078         # Save the break type for this sub.
4079         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4080     } ## end elsif ($line =~ ...
4081
4082     # b <sub name> [<condition>]
4083     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4084
4085         #
4086         $subname = $1;
4087         $cond = length $2 ? $2 : '1';
4088         &cmd_b_sub( $subname, $cond );
4089     }
4090
4091     # b <line> [<condition>].
4092     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4093
4094         # Capture the line. If none, it's the current line.
4095         $line = $1 || $dbline;
4096
4097         # If there's no condition, make it '1'.
4098         $cond = length $2 ? $2 : '1';
4099
4100         # Break on line.
4101         &cmd_b_line( $line, $cond );
4102     }
4103
4104     # Line didn't make sense.
4105     else {
4106         print "confused by line($line)?\n";
4107     }
4108 } ## end sub cmd_b
4109
4110 =head3 C<break_on_load> (API)
4111
4112 We want to break when this file is loaded. Mark this file in the
4113 C<%break_on_load> hash, and note that it has a breakpoint in
4114 C<%had_breakpoints>.
4115
4116 =cut
4117
4118 sub break_on_load {
4119     my $file = shift;
4120     $break_on_load{$file} = 1;
4121     $had_breakpoints{$file} |= 1;
4122 }
4123
4124 =head3 C<report_break_on_load> (API)
4125
4126 Gives us an array of filenames that are set to break on load. Note that
4127 only files with break-on-load are in here, so simply showing the keys
4128 suffices.
4129
4130 =cut
4131
4132 sub report_break_on_load {
4133     sort keys %break_on_load;
4134 }
4135
4136 =head3 C<cmd_b_load> (command)
4137
4138 We take the file passed in and try to find it in C<%INC> (which maps modules
4139 to files they came from). We mark those files for break-on-load via
4140 C<break_on_load> and then report that it was done.
4141
4142 =cut
4143
4144 sub cmd_b_load {
4145     my $file = shift;
4146     my @files;
4147
4148     # This is a block because that way we can use a redo inside it
4149     # even without there being any looping structure at all outside it.
4150     {
4151
4152         # Save short name and full path if found.
4153         push @files, $file;
4154         push @files, $::INC{$file} if $::INC{$file};
4155
4156         # Tack on .pm and do it again unless there was a '.' in the name
4157         # already.
4158         $file .= '.pm', redo unless $file =~ /\./;
4159     }
4160
4161     # Do the real work here.
4162     break_on_load($_) for @files;
4163
4164     # All the files that have break-on-load breakpoints.
4165     @files = report_break_on_load;
4166
4167     # Normalize for the purposes of our printing this.
4168     local $\ = '';
4169     local $" = ' ';
4170     print $OUT "Will stop on load of `@files'.\n";
4171 } ## end sub cmd_b_load
4172
4173 =head3 C<$filename_error> (API package global)
4174
4175 Several of the functions we need to implement in the API need to work both
4176 on the current file and on other files. We don't want to duplicate code, so
4177 C<$filename_error> is used to contain the name of the file that's being
4178 worked on (if it's not the current one).
4179
4180 We can now build functions in pairs: the basic function works on the current
4181 file, and uses C<$filename_error> as part of its error message. Since this is
4182 initialized to C<"">, no filename will appear when we are working on the
4183 current file.
4184
4185 The second function is a wrapper which does the following:
4186
4187 =over 4
4188
4189 =item *
4190
4191 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4192
4193 =item *
4194
4195 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4196
4197 =item *
4198
4199 Calls the first function.
4200
4201 The first function works on the I<current> file (i.e., the one we changed to),
4202 and prints C<$filename_error> in the error message (the name of the other file)
4203 if it needs to. When the functions return, C<*dbline> is restored to point
4204 to the actual current file (the one we're executing in) and
4205 C<$filename_error> is restored to C<"">. This restores everything to
4206 the way it was before the second function was called at all.
4207
4208 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4209 details.
4210
4211 =back
4212
4213 =cut
4214
4215 $filename_error = '';
4216
4217 =head3 breakable_line(from, to) (API)
4218
4219 The subroutine decides whether or not a line in the current file is breakable.
4220 It walks through C<@dbline> within the range of lines specified, looking for
4221 the first line that is breakable.
4222
4223 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4224 first line I<after> C<$to> that's breakable, if there is one.
4225
4226 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4227 first line I<before> C<$to> that's breakable, if there is one.
4228
4229 =cut
4230
4231 sub breakable_line {
4232
4233     my ( $from, $to ) = @_;
4234
4235     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4236     my $i = $from;
4237
4238     # If there are at least 2 arguments, we're trying to search a range.
4239     if ( @_ >= 2 ) {
4240
4241         # $delta is positive for a forward search, negative for a backward one.
4242         my $delta = $from < $to ? +1 : -1;
4243
4244         # Keep us from running off the ends of the file.
4245         my $limit = $delta > 0 ? $#dbline : 1;
4246
4247         # Clever test. If you're a mathematician, it's obvious why this
4248         # test works. If not:
4249         # If $delta is positive (going forward), $limit will be $#dbline.
4250         #    If $to is less than $limit, ($limit - $to) will be positive, times
4251         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4252         #    as the stopping point.
4253         #
4254         #    If $to is greater than $limit, ($limit - $to) is negative,
4255         #    times $delta of 1 (positive), so the result is < 0 and we should
4256         #    use $limit ($#dbline) as the stopping point.
4257         #
4258         # If $delta is negative (going backward), $limit will be 1.
4259         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4260         #    (negative) so the result is > 0, and we use $to as the stopping
4261         #    point.
4262         #
4263         #    If $to is less than zero, ($limit - $to) will be positive,
4264         #    times $delta of -1 (negative), so the result is not > 0, and
4265         #    we use $limit (1) as the stopping point.
4266         #
4267         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4268         #    (negative), still giving zero; the result is not > 0, and
4269         #    we use $limit (1) as the stopping point.
4270         #
4271         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4272         #    (negative), giving a positive (>0) value, so we'll set $limit to
4273         #    $to.
4274
4275         $limit = $to if ( $limit - $to ) * $delta > 0;
4276
4277         # The real search loop.
4278         # $i starts at $from (the point we want to start searching from).
4279         # We move through @dbline in the appropriate direction (determined
4280         # by $delta: either -1 (back) or +1 (ahead).
4281         # We stay in as long as we haven't hit an executable line
4282         # ($dbline[$i] == 0 means not executable) and we haven't reached
4283         # the limit yet (test similar to the above).
4284         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4285
4286     } ## end if (@_ >= 2)
4287
4288     # If $i points to a line that is executable, return that.
4289     return $i unless $dbline[$i] == 0;
4290
4291     # Format the message and print it: no breakable lines in range.
4292     my ( $pl, $upto ) = ( '', '' );
4293     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4294
4295     # If there's a filename in filename_error, we'll see it.
4296     # If not, not.
4297     die "Line$pl $from$upto$filename_error not breakable\n";
4298 } ## end sub breakable_line
4299
4300 =head3 breakable_line_in_filename(file, from, to) (API)
4301
4302 Like C<breakable_line>, but look in another file.
4303
4304 =cut
4305
4306 sub breakable_line_in_filename {
4307
4308     # Capture the file name.
4309     my ($f) = shift;
4310
4311     # Swap the magic line array over there temporarily.
4312     local *dbline = $main::{ '_<' . $f };
4313
4314     # If there's an error, it's in this other file.
4315     local $filename_error = " of `$f'";
4316
4317     # Find the breakable line.
4318     breakable_line(@_);
4319
4320     # *dbline and $filename_error get restored when this block ends.
4321
4322 } ## end sub breakable_line_in_filename
4323
4324 =head3 break_on_line(lineno, [condition]) (API)
4325
4326 Adds a breakpoint with the specified condition (or 1 if no condition was
4327 specified) to the specified line. Dies if it can't.
4328
4329 =cut
4330
4331 sub break_on_line {
4332     my ( $i, $cond ) = @_;
4333
4334     # Always true if no condition supplied.
4335     $cond = 1 unless @_ >= 2;
4336
4337     my $inii  = $i;
4338     my $after = '';
4339     my $pl    = '';
4340
4341     # Woops, not a breakable line. $filename_error allows us to say
4342     # if it was in a different file.
4343     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4344
4345     # Mark this file as having breakpoints in it.
4346     $had_breakpoints{$filename} |= 1;
4347
4348     # If there is an action or condition here already ...
4349     if ( $dbline{$i} ) {
4350
4351         # ... swap this condition for the existing one.
4352         $dbline{$i} =~ s/^[^\0]*/$cond/;
4353     }
4354     else {
4355
4356         # Nothing here - just add the condition.
4357         $dbline{$i} = $cond;
4358     }
4359 } ## end sub break_on_line
4360
4361 =head3 cmd_b_line(line, [condition]) (command)
4362
4363 Wrapper for C<break_on_line>. Prints the failure message if it
4364 doesn't work.
4365
4366 =cut
4367
4368 sub cmd_b_line {
4369     eval { break_on_line(@_); 1 } or do {
4370         local $\ = '';
4371         print $OUT $@ and return;
4372     };
4373 } ## end sub cmd_b_line
4374
4375 =head3 break_on_filename_line(file, line, [condition]) (API)
4376
4377 Switches to the file specified and then calls C<break_on_line> to set
4378 the breakpoint.
4379
4380 =cut
4381
4382 sub break_on_filename_line {
4383     my ( $f, $i, $cond ) = @_;
4384
4385     # Always true if condition left off.
4386     $cond = 1 unless @_ >= 3;
4387
4388     # Switch the magical hash temporarily.
4389     local *dbline = $main::{ '_<' . $f };
4390
4391     # Localize the variables that break_on_line uses to make its message.
4392     local $filename_error = " of `$f'";
4393     local $filename       = $f;
4394
4395     # Add the breakpoint.
4396     break_on_line( $i, $cond );
4397 } ## end sub break_on_filename_line
4398
4399 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4400
4401 Switch to another file, search the range of lines specified for an
4402 executable one, and put a breakpoint on the first one you find.
4403
4404 =cut
4405
4406 sub break_on_filename_line_range {
4407     my ( $f, $from, $to, $cond ) = @_;
4408
4409     # Find a breakable line if there is one.
4410     my $i = breakable_line_in_filename( $f, $from, $to );
4411
4412     # Always true if missing.
4413     $cond = 1 unless @_ >= 3;
4414
4415     # Add the breakpoint.
4416     break_on_filename_line( $f, $i, $cond );
4417 } ## end sub break_on_filename_line_range
4418
4419 =head3 subroutine_filename_lines(subname, [condition]) (API)
4420
4421 Search for a subroutine within a given file. The condition is ignored.
4422 Uses C<find_sub> to locate the desired subroutine.
4423
4424 =cut
4425
4426 sub subroutine_filename_lines {
4427     my ( $subname, $cond ) = @_;
4428
4429     # Returned value from find_sub() is fullpathname:startline-endline.
4430     # The match creates the list (fullpathname, start, end). Falling off
4431     # the end of the subroutine returns this implicitly.
4432     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4433 } ## end sub subroutine_filename_lines
4434
4435 =head3 break_subroutine(subname) (API)
4436
4437 Places a break on the first line possible in the specified subroutine. Uses
4438 C<subroutine_filename_lines> to find the subroutine, and
4439 C<break_on_filename_line_range> to place the break.
4440
4441 =cut
4442
4443 sub break_subroutine {
4444     my $subname = shift;
4445
4446     # Get filename, start, and end.
4447     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4448       or die "Subroutine $subname not found.\n";
4449
4450     # Null condition changes to '1' (always true).
4451     $cond = 1 unless @_ >= 2;
4452
4453     # Put a break the first place possible in the range of lines
4454     # that make up this subroutine.
4455     break_on_filename_line_range( $file, $s, $e, @_ );
4456 } ## end sub break_subroutine
4457
4458 =head3 cmd_b_sub(subname, [condition]) (command)
4459
4460 We take the incoming subroutine name and fully-qualify it as best we can.
4461
4462 =over 4
4463
4464 =item 1. If it's already fully-qualified, leave it alone.
4465
4466 =item 2. Try putting it in the current package.
4467
4468 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4469
4470 =item 4. If it starts with '::', put it in 'main::'.
4471
4472 =back
4473
4474 After all this cleanup, we call C<break_subroutine> to try to set the
4475 breakpoint.
4476
4477 =cut
4478
4479 sub cmd_b_sub {
4480     my ( $subname, $cond ) = @_;
4481
4482     # Add always-true condition if we have none.
4483     $cond = 1 unless @_ >= 2;
4484
4485     # If the subname isn't a code reference, qualify it so that
4486     # break_subroutine() will work right.
4487     unless ( ref $subname eq 'CODE' ) {
4488
4489         # Not Perl4.
4490         $subname =~ s/\'/::/g;
4491         my $s = $subname;
4492
4493         # Put it in this package unless it's already qualified.
4494         $subname = "${'package'}::" . $subname
4495           unless $subname =~ /::/;
4496
4497         # Requalify it into CORE::GLOBAL if qualifying it into this
4498         # package resulted in its not being defined, but only do so
4499         # if it really is in CORE::GLOBAL.
4500         $subname = "CORE::GLOBAL::$s"
4501           if not defined &$subname
4502           and $s !~ /::/
4503           and defined &{"CORE::GLOBAL::$s"};
4504
4505         # Put it in package 'main' if it has a leading ::.
4506         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4507
4508     } ## end unless (ref $subname eq 'CODE')
4509
4510     # Try to set the breakpoint.
4511     eval { break_subroutine( $subname, $cond ); 1 } or do {
4512         local $\ = '';
4513         print $OUT $@ and return;
4514       }
4515 } ## end sub cmd_b_sub
4516
4517 =head3 C<cmd_B> - delete breakpoint(s) (command)
4518
4519 The command mostly parses the command line and tries to turn the argument
4520 into a line spec. If it can't, it uses the current line. It then calls
4521 C<delete_breakpoint> to actually do the work.
4522
4523 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4524 thereby deleting all the breakpoints.
4525
4526 =cut
4527
4528 sub cmd_B {
4529     my $cmd = shift;
4530
4531     # No line spec? Use dbline.
4532     # If there is one, use it if it's non-zero, or wipe it out if it is.
4533     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4534     my $dbline = shift;
4535
4536     # If the line was dot, make the line the current one.
4537     $line =~ s/^\./$dbline/;
4538
4539     # If it's * we're deleting all the breakpoints.
4540     if ( $line eq '*' ) {
4541         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4542     }
4543
4544     # If there is a line spec, delete the breakpoint on that line.
4545     elsif ( $line =~ /^(\S.*)/ ) {
4546         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4547             local $\ = '';
4548             print $OUT $@ and return;
4549         };
4550     } ## end elsif ($line =~ /^(\S.*)/)
4551
4552     # No line spec.
4553     else {
4554         print $OUT
4555           "Deleting a breakpoint requires a line number, or '*' for all\n"
4556           ;    # hint
4557     }
4558 } ## end sub cmd_B
4559
4560 =head3 delete_breakpoint([line]) (API)
4561
4562 This actually does the work of deleting either a single breakpoint, or all
4563 of them.
4564
4565 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4566 just drop out with a message saying so. If it is, we remove the condition
4567 part of the 'condition\0action' that says there's a breakpoint here. If,
4568 after we've done that, there's nothing left, we delete the corresponding
4569 line in C<%dbline> to signal that no action needs to be taken for this line.
4570
4571 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4572 which lists all currently-loaded files which have breakpoints. We then look
4573 at each line in each of these files, temporarily switching the C<%dbline>
4574 and C<@dbline> structures to point to the files in question, and do what
4575 we did in the single line case: delete the condition in C<@dbline>, and
4576 delete the key in C<%dbline> if nothing's left.
4577
4578 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4579 C<%break_on_load>, because these structures contain breakpoints for files
4580 and code that haven't been loaded yet. We can just kill these off because there
4581 are no magical debugger structures associated with them.
4582
4583 =cut
4584
4585 sub delete_breakpoint {
4586     my $i = shift;
4587
4588     # If we got a line, delete just that one.
4589     if ( defined($i) ) {
4590
4591         # Woops. This line wasn't breakable at all.
4592         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4593
4594         # Kill the condition, but leave any action.
4595         $dbline{$i} =~ s/^[^\0]*//;
4596
4597         # Remove the entry entirely if there's no action left.
4598         delete $dbline{$i} if $dbline{$i} eq '';
4599     }
4600
4601     # No line; delete them all.
4602     else {
4603         print $OUT "Deleting all breakpoints...\n";
4604
4605         # %had_breakpoints lists every file that had at least one
4606         # breakpoint in it.
4607         for my $file ( keys %had_breakpoints ) {
4608
4609             # Switch to the desired file temporarily.
4610             local *dbline = $main::{ '_<' . $file };
4611
4612             my $max = $#dbline;
4613             my $was;
4614
4615             # For all lines in this file ...
4616             for ( $i = 1 ; $i <= $max ; $i++ ) {
4617
4618                 # If there's a breakpoint or action on this line ...
4619                 if ( defined $dbline{$i} ) {
4620
4621                     # ... remove the breakpoint.
4622                     $dbline{$i} =~ s/^[^\0]+//;
4623                     if ( $dbline{$i} =~ s/^\0?$// ) {
4624
4625                         # Remove the entry altogether if no action is there.
4626                         delete $dbline{$i};
4627                     }
4628                 } ## end if (defined $dbline{$i...
4629             } ## end for ($i = 1 ; $i <= $max...
4630
4631             # If, after we turn off the "there were breakpoints in this file"
4632             # bit, the entry in %had_breakpoints for this file is zero,
4633             # we should remove this file from the hash.
4634             if ( not $had_breakpoints{$file} &= ~1 ) {
4635                 delete $had_breakpoints{$file};
4636             }
4637         } ## end for my $file (keys %had_breakpoints)
4638
4639         # Kill off all the other breakpoints that are waiting for files that
4640         # haven't been loaded yet.
4641         undef %postponed;
4642         undef %postponed_file;
4643         undef %break_on_load;
4644     } ## end else [ if (defined($i))
4645 } ## end sub delete_breakpoint
4646
4647 =head3 cmd_stop (command)
4648
4649 This is meant to be part of the new command API, but it isn't called or used
4650 anywhere else in the debugger. XXX It is probably meant for use in development
4651 of new commands.
4652
4653 =cut
4654
4655 sub cmd_stop {    # As on ^C, but not signal-safy.
4656     $signal = 1;
4657 }
4658
4659 =head3 C<cmd_e> - threads
4660
4661 Display the current thread id:
4662
4663         e
4664
4665 This could be how (when implemented) to send commands to this thread id (e cmd)
4666 or that thread id (e tid cmd).
4667
4668 =cut
4669
4670 sub cmd_e {
4671     my $cmd  = shift;
4672     my $line = shift;
4673         unless (exists($INC{'threads.pm'})) {
4674                 print "threads not loaded($ENV{PERL5DB_THREADED})
4675                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4676         } else {
4677                 my $tid = threads->tid;
4678                 print "thread id: $tid\n";
4679         }
4680 } ## end sub cmd_e
4681
4682 =head3 C<cmd_E> - list of thread ids
4683
4684 Display the list of available thread ids:
4685
4686         E
4687
4688 This could be used (when implemented) to send commands to all threads (E cmd).
4689
4690 =cut
4691
4692 sub cmd_E {
4693     my $cmd  = shift;
4694     my $line = shift;
4695         unless (exists($INC{'threads.pm'})) {
4696                 print "threads not loaded($ENV{PERL5DB_THREADED})
4697                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4698         } else {
4699                 my $tid = threads->tid;
4700                 print "thread ids: ".join(', ',
4701                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4702                 )."\n";
4703         }
4704 } ## end sub cmd_E
4705
4706 =head3 C<cmd_h> - help command (command)
4707
4708 Does the work of either
4709
4710 =over 4
4711
4712 =item *
4713
4714 Showing all the debugger help
4715
4716 =item *
4717
4718 Showing help for a specific command
4719
4720 =back
4721
4722 =cut
4723
4724 sub cmd_h {
4725     my $cmd = shift;
4726
4727     # If we have no operand, assume null.
4728     my $line = shift || '';
4729
4730     # 'h h'. Print the long-format help.
4731     if ( $line =~ /^h\s*/ ) {
4732         print_help($help);
4733     }
4734
4735     # 'h <something>'. Search for the command and print only its help.
4736     elsif ( $line =~ /^(\S.*)$/ ) {
4737
4738         # support long commands; otherwise bogus errors
4739         # happen when you ask for h on <CR> for example
4740         my $asked = $1;    # the command requested
4741                            # (for proper error message)
4742
4743         my $qasked = quotemeta($asked);    # for searching; we don't
4744                                            # want to use it as a pattern.
4745                                            # XXX: finds CR but not <CR>
4746
4747         # Search the help string for the command.
4748         if (
4749             $help =~ /^                    # Start of a line
4750                       <?                   # Optional '<'
4751                       (?:[IB]<)            # Optional markup
4752                       $qasked              # The requested command
4753                      /mx
4754           )
4755         {
4756
4757             # It's there; pull it out and print it.
4758             while (
4759                 $help =~ /^
4760                               (<?            # Optional '<'
4761                                  (?:[IB]<)   # Optional markup
4762                                  $qasked     # The command
4763                                  ([\s\S]*?)  # Description line(s)
4764                               \n)            # End of last description line
4765                               (?!\s)         # Next line not starting with
4766                                              # whitespace
4767                              /mgx
4768               )
4769             {
4770                 print_help($1);
4771             }
4772         }
4773
4774         # Not found; not a debugger command.
4775         else {
4776             print_help("B<$asked> is not a debugger command.\n");
4777         }
4778     } ## end elsif ($line =~ /^(\S.*)$/)
4779
4780     # 'h' - print the summary help.
4781     else {
4782         print_help($summary);
4783     }
4784 } ## end sub cmd_h
4785
4786 =head3 C<cmd_i> - inheritance display
4787
4788 Display the (nested) parentage of the module or object given.
4789
4790 =cut
4791
4792 sub cmd_i {
4793     my $cmd  = shift;
4794     my $line = shift;
4795     eval { require Class::ISA };
4796     if ($@) {
4797         &warn( $@ =~ /locate/
4798             ? "Class::ISA module not found - please install\n"
4799             : $@ );
4800     }
4801     else {
4802       ISA:
4803         foreach my $isa ( split( /\s+/, $line ) ) {
4804             $evalarg = $isa;
4805             ($isa) = &eval;
4806             no strict 'refs';
4807             print join(
4808                 ', ',
4809                 map {    # snaffled unceremoniously from Class::ISA
4810                     "$_"
4811                       . (
4812                         defined( ${"$_\::VERSION"} )
4813                         ? ' ' . ${"$_\::VERSION"}
4814                         : undef )
4815                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4816             );
4817             print "\n";
4818         }
4819     }
4820 } ## end sub cmd_i
4821
4822 =head3 C<cmd_l> - list lines (command)
4823
4824 Most of the command is taken up with transforming all the different line
4825 specification syntaxes into 'start-stop'. After that is done, the command
4826 runs a loop over C<@dbline> for the specified range of lines. It handles
4827 the printing of each line and any markers (C<==E<gt>> for current line,
4828 C<b> for break on this line, C<a> for action on this line, C<:> for this
4829 line breakable).
4830
4831 We save the last line listed in the C<$start> global for further listing
4832 later.
4833
4834 =cut
4835
4836 sub cmd_l {
4837     my $current_line = $line;
4838     my $cmd  = shift;
4839     my $line = shift;
4840
4841     # If this is '-something', delete any spaces after the dash.
4842     $line =~ s/^-\s*$/-/;
4843
4844     # If the line is '$something', assume this is a scalar containing a
4845     # line number.
4846     if ( $line =~ /^(\$.*)/s ) {
4847
4848         # Set up for DB::eval() - evaluate in *user* context.
4849         $evalarg = $1;
4850         # $evalarg = $2;
4851         my ($s) = &eval;
4852
4853         # Ooops. Bad scalar.
4854         print( $OUT "Error: $@\n" ), next CMD if $@;
4855
4856         # Good scalar. If it's a reference, find what it points to.
4857         $s = CvGV_name($s);
4858         print( $OUT "Interpreted as: $1 $s\n" );
4859         $line = "$1 $s";
4860
4861         # Call self recursively to really do the command.
4862         &cmd_l( 'l', $s );
4863     } ## end if ($line =~ /^(\$.*)/s)
4864
4865     # l name. Try to find a sub by that name.
4866     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4867         my $s = $subname = $1;
4868
4869         # De-Perl4.
4870         $subname =~ s/\'/::/;
4871
4872         # Put it in this package unless it starts with ::.
4873         $subname = $package . "::" . $subname unless $subname =~ /::/;
4874
4875         # Put it in CORE::GLOBAL if t doesn't start with :: and
4876         # it doesn't live in this package and it lives in CORE::GLOBAL.
4877         $subname = "CORE::GLOBAL::$s"
4878           if not defined &$subname
4879           and $s !~ /::/
4880           and defined &{"CORE::GLOBAL::$s"};
4881
4882         # Put leading '::' names into 'main::'.
4883         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4884
4885         # Get name:start-stop from find_sub, and break this up at
4886         # colons.
4887         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4888
4889         # Pull off start-stop.
4890         $subrange = pop @pieces;
4891
4892         # If the name contained colons, the split broke it up.
4893         # Put it back together.
4894         $file = join( ':', @pieces );
4895
4896         # If we're not in that file, switch over to it.
4897         if ( $file ne $filename ) {
4898             print $OUT "Switching to file '$file'.\n"
4899               unless $slave_editor;
4900
4901             # Switch debugger's magic structures.
4902             *dbline   = $main::{ '_<' . $file };
4903             $max      = $#dbline;
4904             $filename = $file;
4905         } ## end if ($file ne $filename)
4906
4907         # Subrange is 'start-stop'. If this is less than a window full,
4908         # swap it to 'start+', which will list a window from the start point.
4909         if ($subrange) {
4910             if ( eval($subrange) < -$window ) {
4911                 $subrange =~ s/-.*/+/;
4912             }
4913
4914             # Call self recursively to list the range.
4915             $line = $subrange;
4916             &cmd_l( 'l', $subrange );
4917         } ## end if ($subrange)
4918
4919         # Couldn't find it.
4920         else {
4921             print $OUT "Subroutine $subname not found.\n";
4922         }
4923     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4924
4925     # Bare 'l' command.
4926     elsif ( $line =~ /^\s*$/ ) {
4927
4928         # Compute new range to list.
4929         $incr = $window - 1;
4930         $line = $start . '-' . ( $start + $incr );
4931
4932         # Recurse to do it.
4933         &cmd_l( 'l', $line );
4934     }
4935
4936     # l [start]+number_of_lines
4937     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4938
4939         # Don't reset start for 'l +nnn'.
4940         $start = $1 if $1;
4941
4942         # Increment for list. Use window size if not specified.
4943         # (Allows 'l +' to work.)
4944         $incr = $2;
4945         $incr = $window - 1 unless $incr;
4946
4947         # Create a line range we'll understand, and recurse to do it.
4948         $line = $start . '-' . ( $start + $incr );
4949         &cmd_l( 'l', $line );
4950     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4951
4952     # l start-stop or l start,stop
4953     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4954
4955         # Determine end point; use end of file if not specified.
4956         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4957
4958         # Go on to the end, and then stop.
4959         $end = $max if $end > $max;
4960
4961         # Determine start line.
4962         $i    = $2;
4963         $i    = $line if $i eq '.';
4964         $i    = 1 if $i < 1;
4965         $incr = $end - $i;
4966
4967         # If we're running under a slave editor, force it to show the lines.
4968         if ($slave_editor) {
4969             print $OUT "\032\032$filename:$i:0\n";
4970             $i = $end;
4971         }
4972
4973         # We're doing it ourselves. We want to show the line and special
4974         # markers for:
4975         # - the current line in execution
4976         # - whether a line is breakable or not
4977         # - whether a line has a break or not
4978         # - whether a line has an action or not
4979         else {
4980             for ( ; $i <= $end ; $i++ ) {
4981
4982                 # Check for breakpoints and actions.
4983                 my ( $stop, $action );
4984                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
4985                   if $dbline{$i};
4986
4987                 # ==> if this is the current line in execution,
4988                 # : if it's breakable.
4989                 $arrow =
4990                   ( $i == $current_line and $filename eq $filename_ini )
4991                   ? '==>'
4992                   : ( $dbline[$i] + 0 ? ':' : ' ' );
4993
4994                 # Add break and action indicators.
4995                 $arrow .= 'b' if $stop;
4996                 $arrow .= 'a' if $action;
4997
4998                 # Print the line.
4999                 print $OUT "$i$arrow\t", $dbline[$i];
5000
5001                 # Move on to the next line. Drop out on an interrupt.
5002                 $i++, last if $signal;
5003             } ## end for (; $i <= $end ; $i++)
5004
5005             # Line the prompt up; print a newline if the last line listed
5006             # didn't have a newline.
5007             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5008         } ## end else [ if ($slave_editor)
5009
5010         # Save the point we last listed to in case another relative 'l'
5011         # command is desired. Don't let it run off the end.
5012         $start = $i;
5013         $start = $max if $start > $max;
5014     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5015 } ## end sub cmd_l
5016
5017 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5018
5019 To list breakpoints, the command has to look determine where all of them are
5020 first. It starts a C<%had_breakpoints>, which tells us what all files have
5021 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5022 magic source and breakpoint data structures) to the file, and then look
5023 through C<%dbline> for lines with breakpoints and/or actions, listing them
5024 out. We look through C<%postponed> not-yet-compiled subroutines that have
5025 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5026 that have breakpoints.
5027
5028 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5029
5030 =cut
5031
5032 sub cmd_L {
5033     my $cmd = shift;
5034
5035     # If no argument, list everything. Pre-5.8.0 version always lists
5036     # everything
5037     my $arg = shift || 'abw';
5038     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5039
5040     # See what is wanted.
5041     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5042     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5043     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5044
5045     # Breaks and actions are found together, so we look in the same place
5046     # for both.
5047     if ( $break_wanted or $action_wanted ) {
5048
5049         # Look in all the files with breakpoints...
5050         for my $file ( keys %had_breakpoints ) {
5051
5052             # Temporary switch to this file.
5053             local *dbline = $main::{ '_<' . $file };
5054
5055             # Set up to look through the whole file.
5056             my $max = $#dbline;
5057             my $was;    # Flag: did we print something
5058                         # in this file?
5059
5060             # For each line in the file ...
5061             for ( $i = 1 ; $i <= $max ; $i++ ) {
5062
5063                 # We've got something on this line.
5064                 if ( defined $dbline{$i} ) {
5065
5066                     # Print the header if we haven't.
5067                     print $OUT "$file:\n" unless $was++;
5068
5069                     # Print the line.
5070                     print $OUT " $i:\t", $dbline[$i];
5071
5072                     # Pull out the condition and the action.
5073                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5074
5075                     # Print the break if there is one and it's wanted.
5076                     print $OUT "   break if (", $stop, ")\n"
5077                       if $stop
5078                       and $break_wanted;
5079
5080                     # Print the action if there is one and it's wanted.
5081                     print $OUT "   action:  ", $action, "\n"
5082                       if $action
5083                       and $action_wanted;
5084
5085                     # Quit if the user hit interrupt.
5086                     last if $signal;
5087                 } ## end if (defined $dbline{$i...
5088             } ## end for ($i = 1 ; $i <= $max...
5089         } ## end for my $file (keys %had_breakpoints)
5090     } ## end if ($break_wanted or $action_wanted)
5091
5092     # Look for breaks in not-yet-compiled subs:
5093     if ( %postponed and $break_wanted ) {
5094         print $OUT "Postponed breakpoints in subroutines:\n";
5095         my $subname;
5096         for $subname ( keys %postponed ) {
5097             print $OUT " $subname\t$postponed{$subname}\n";
5098             last if $signal;
5099         }
5100     } ## end if (%postponed and $break_wanted)
5101
5102     # Find files that have not-yet-loaded breaks:
5103     my @have = map {    # Combined keys
5104         keys %{ $postponed_file{$_} }
5105     } keys %postponed_file;
5106
5107     # If there are any, list them.
5108     if ( @have and ( $break_wanted or $action_wanted ) ) {
5109         print $OUT "Postponed breakpoints in files:\n";
5110         my ( $file, $line );
5111
5112         for $file ( keys %postponed_file ) {
5113             my $db = $postponed_file{$file};
5114             print $OUT " $file:\n";
5115             for $line ( sort { $a <=> $b } keys %$db ) {
5116                 print $OUT "  $line:\n";
5117                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5118                 print $OUT "    break if (", $stop, ")\n"
5119                   if $stop
5120                   and $break_wanted;
5121                 print $OUT "    action:  ", $action, "\n"
5122                   if $action
5123                   and $action_wanted;
5124                 last if $signal;
5125             } ## end for $line (sort { $a <=>...
5126             last if $signal;
5127         } ## end for $file (keys %postponed_file)
5128     } ## end if (@have and ($break_wanted...
5129     if ( %break_on_load and $break_wanted ) {
5130         print $OUT "Breakpoints on load:\n";
5131         my $file;
5132         for $file ( keys %break_on_load ) {
5133             print $OUT " $file\n";
5134             last if $signal;
5135         }
5136     } ## end if (%break_on_load and...
5137     if ($watch_wanted) {
5138         if ( $trace & 2 ) {
5139             print $OUT "Watch-expressions:\n" if @to_watch;
5140             for my $expr (@to_watch) {
5141                 print $OUT " $expr\n";
5142                 last if $signal;
5143             }
5144         } ## end if ($trace & 2)
5145     } ## end if ($watch_wanted)
5146 } ## end sub cmd_L
5147
5148 =head3 C<cmd_M> - list modules (command)
5149
5150 Just call C<list_modules>.
5151
5152 =cut
5153
5154 sub cmd_M {
5155     &list_modules();
5156 }
5157
5158 =head3 C<cmd_o> - options (command)
5159
5160 If this is just C<o> by itself, we list the current settings via
5161 C<dump_option>. If there's a nonblank value following it, we pass that on to
5162 C<parse_options> for processing.
5163
5164 =cut
5165
5166 sub cmd_o {
5167     my $cmd = shift;
5168     my $opt = shift || '';    # opt[=val]
5169
5170     # Nonblank. Try to parse and process.
5171     if ( $opt =~ /^(\S.*)/ ) {
5172         &parse_options($1);
5173     }
5174
5175     # Blank. List the current option settings.
5176     else {
5177         for (@options) {
5178             &dump_option($_);
5179         }
5180     }
5181 } ## end sub cmd_o
5182
5183 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5184
5185 Advises the user that the O command has been renamed.
5186
5187 =cut
5188
5189 sub cmd_O {
5190     print $OUT "The old O command is now the o command.\n";             # hint
5191     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5192     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5193 }
5194
5195 =head3 C<cmd_v> - view window (command)
5196
5197 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5198 move back a few lines to list the selected line in context. Uses C<cmd_l>
5199 to do the actual listing after figuring out the range of line to request.
5200
5201 =cut
5202
5203 sub cmd_v {
5204     my $cmd  = shift;
5205     my $line = shift;
5206
5207     # Extract the line to list around. (Astute readers will have noted that
5208     # this pattern will match whether or not a numeric line is specified,
5209     # which means that we'll always enter this loop (though a non-numeric
5210     # argument results in no action at all)).
5211     if ( $line =~ /^(\d*)$/ ) {
5212
5213         # Total number of lines to list (a windowful).
5214         $incr = $window - 1;
5215
5216         # Set the start to the argument given (if there was one).
5217         $start = $1 if $1;
5218
5219         # Back up by the context amount.
5220         $start -= $preview;
5221
5222         # Put together a linespec that cmd_l will like.
5223         $line = $start . '-' . ( $start + $incr );
5224
5225         # List the lines.
5226         &cmd_l( 'l', $line );
5227     } ## end if ($line =~ /^(\d*)$/)
5228 } ## end sub cmd_v
5229
5230 =head3 C<cmd_w> - add a watch expression (command)
5231
5232 The 5.8 version of this command adds a watch expression if one is specified;
5233 it does nothing if entered with no operands.
5234
5235 We extract the expression, save it, evaluate it in the user's context, and
5236 save the value. We'll re-evaluate it each time the debugger passes a line,
5237 and will stop (see the code at the top of the command loop) if the value
5238 of any of the expressions changes.
5239
5240 =cut
5241
5242 sub cmd_w {
5243     my $cmd = shift;
5244
5245     # Null expression if no arguments.
5246     my $expr = shift || '';
5247
5248     # If expression is not null ...
5249     if ( $expr =~ /^(\S.*)/ ) {
5250
5251         # ... save it.
5252         push @to_watch, $expr;
5253
5254         # Parameterize DB::eval and call it to get the expression's value
5255         # in the user's context. This version can handle expressions which
5256         # return a list value.
5257         $evalarg = $expr;
5258         my ($val) = join( ' ', &eval );
5259         $val = ( defined $val ) ? "'$val'" : 'undef';
5260
5261         # Save the current value of the expression.
5262         push @old_watch, $val;
5263
5264         # We are now watching expressions.
5265         $trace |= 2;
5266     } ## end if ($expr =~ /^(\S.*)/)
5267
5268     # You have to give one to get one.
5269     else {
5270         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5271     }
5272 } ## end sub cmd_w
5273
5274 =head3 C<cmd_W> - delete watch expressions (command)
5275
5276 This command accepts either a watch expression to be removed from the list
5277 of watch expressions, or C<*> to delete them all.
5278
5279 If C<*> is specified, we simply empty the watch expression list and the
5280 watch expression value list. We also turn off the bit that says we've got
5281 watch expressions.
5282
5283 If an expression (or partial expression) is specified, we pattern-match
5284 through the expressions and remove the ones that match. We also discard
5285 the corresponding values. If no watch expressions are left, we turn off
5286 the I<watching expressions> bit.
5287
5288 =cut
5289
5290 sub cmd_W {
5291     my $cmd  = shift;
5292     my $expr = shift || '';
5293
5294     # Delete them all.
5295     if ( $expr eq '*' ) {
5296
5297         # Not watching now.
5298         $trace &= ~2;
5299
5300         print $OUT "Deleting all watch expressions ...\n";
5301
5302         # And all gone.
5303         @to_watch = @old_watch = ();
5304     }
5305
5306     # Delete one of them.
5307     elsif ( $expr =~ /^(\S.*)/ ) {
5308
5309         # Where we are in the list.
5310         my $i_cnt = 0;
5311
5312         # For each expression ...
5313         foreach (@to_watch) {
5314             my $val = $to_watch[$i_cnt];
5315
5316             # Does this one match the command argument?
5317             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5318                                       # Yes. Turn it off, and its value too.
5319                 splice( @to_watch,  $i_cnt, 1 );
5320                 splice( @old_watch, $i_cnt, 1 );
5321             }
5322             $i_cnt++;
5323         } ## end foreach (@to_watch)
5324
5325         # We don't bother to turn watching off because
5326         #  a) we don't want to stop calling watchfunction() it it exists
5327         #  b) foreach over a null list doesn't do anything anyway
5328
5329     } ## end elsif ($expr =~ /^(\S.*)/)
5330
5331     # No command arguments entered.
5332     else {
5333         print $OUT
5334           "Deleting a watch-expression requires an expression, or '*' for all\n"
5335           ;    # hint
5336     }
5337 } ## end sub cmd_W
5338
5339 ### END of the API section
5340
5341 =head1 SUPPORT ROUTINES
5342
5343 These are general support routines that are used in a number of places
5344 throughout the debugger.
5345
5346 =over 4
5347
5348 =item cmd_P
5349
5350 Something to do with assertions
5351
5352 =back
5353
5354 =cut
5355
5356 sub cmd_P {
5357     unless ($ini_assertion) {
5358         print $OUT "Assertions not supported in this Perl interpreter\n";
5359     } else {
5360         if ( $cmd =~ /^.\b\s*([+-]?)\s*(~?)\s*(\w+(\s*\|\s*\w+)*)\s*$/ ) {
5361             my ( $how, $neg, $flags ) = ( $1, $2, $3 );
5362             my $acu = parse_DollarCaretP_flags($flags);
5363             if ( defined $acu ) {
5364                 $acu = ~$acu if $neg;
5365                 if ( $how eq '+' ) { $^P |= $acu }
5366                 elsif ( $how eq '-' ) { $^P &= ~$acu }
5367                 else { $^P = $acu }
5368             }
5369
5370             # else { print $OUT "undefined acu\n" }
5371         }
5372         my $expanded = expand_DollarCaretP_flags($^P);
5373         print $OUT "Internal Perl debugger flags:\n\$^P=$expanded\n";
5374         $expanded;
5375     }
5376 }
5377
5378 =head2 save
5379
5380 save() saves the user's versions of globals that would mess us up in C<@saved>,
5381 and installs the versions we like better.
5382
5383 =cut
5384
5385 sub save {
5386
5387     # Save eval failure, command failure, extended OS error, output field
5388     # separator, input record separator, output record separator and
5389     # the warning setting.
5390     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5391
5392     $,  = "";      # output field separator is null string
5393     $/  = "\n";    # input record separator is newline
5394     $\  = "";      # output record separator is null string
5395     $^W = 0;       # warnings are off
5396 } ## end sub save
5397
5398 =head2 C<print_lineinfo> - show where we are now
5399
5400 print_lineinfo prints whatever it is that it is handed; it prints it to the
5401 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5402 us to feed line information to a slave editor without messing up the
5403 debugger output.
5404
5405 =cut
5406
5407 sub print_lineinfo {
5408
5409     # Make the terminal sensible if we're not the primary debugger.
5410     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5411     local $\ = '';
5412     local $, = '';
5413     print $LINEINFO @_;
5414 } ## end sub print_lineinfo
5415
5416 =head2 C<postponed_sub>
5417
5418 Handles setting postponed breakpoints in subroutines once they're compiled.
5419 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5420 range for the subroutine, then mark the file as having a breakpoint,
5421 temporarily switch the C<*dbline> glob over to the source file, and then
5422 search the given range of lines to find a breakable line. If we find one,
5423 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5424
5425 =cut
5426
5427 # The following takes its argument via $evalarg to preserve current @_
5428
5429 sub postponed_sub {
5430
5431     # Get the subroutine name.
5432     my $subname = shift;
5433
5434     # If this is a 'break +<n> if <condition>' ...
5435     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5436
5437         # If there's no offset, use '+0'.
5438         my $offset = $1 || 0;
5439
5440         # find_sub's value is 'fullpath-filename:start-stop'. It's
5441         # possible that the filename might have colons in it too.
5442         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5443         if ($i) {
5444
5445             # We got the start line. Add the offset '+<n>' from
5446             # $postponed{subname}.
5447             $i += $offset;
5448
5449             # Switch to the file this sub is in, temporarily.
5450             local *dbline = $main::{ '_<' . $file };
5451
5452             # No warnings, please.
5453             local $^W = 0;    # != 0 is magical below
5454
5455             # This file's got a breakpoint in it.
5456             $had_breakpoints{$file} |= 1;
5457
5458             # Last line in file.
5459             my $max = $#dbline;
5460
5461             # Search forward until we hit a breakable line or get to
5462             # the end of the file.
5463             ++$i until $dbline[$i] != 0 or $i >= $max;
5464
5465             # Copy the breakpoint in and delete it from %postponed.
5466             $dbline{$i} = delete $postponed{$subname};
5467         } ## end if ($i)
5468
5469         # find_sub didn't find the sub.
5470         else {
5471             local $\ = '';
5472             print $OUT "Subroutine $subname not found.\n";
5473         }
5474         return;
5475     } ## end if ($postponed{$subname...
5476     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5477
5478     #print $OUT "In postponed_sub for `$subname'.\n";
5479 } ## end sub postponed_sub
5480
5481 =head2 C<postponed>
5482
5483 Called after each required file is compiled, but before it is executed;
5484 also called if the name of a just-compiled subroutine is a key of
5485 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5486 etc.) into the just-compiled code.
5487
5488 If this is a C<require>'d file, the incoming parameter is the glob
5489 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5490
5491 If it's a subroutine, the incoming parameter is the subroutine name.
5492
5493 =cut
5494
5495 sub postponed {
5496
5497     # If there's a break, process it.
5498     if ($ImmediateStop) {
5499
5500         # Right, we've stopped. Turn it off.
5501         $ImmediateStop = 0;
5502
5503         # Enter the command loop when DB::DB gets called.
5504         $signal = 1;
5505     }
5506
5507     # If this is a subroutine, let postponed_sub() deal with it.
5508     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5509
5510     # Not a subroutine. Deal with the file.
5511     local *dbline = shift;
5512     my $filename = $dbline;
5513     $filename =~ s/^_<//;
5514     local $\ = '';
5515     $signal = 1, print $OUT "'$filename' loaded...\n"
5516       if $break_on_load{$filename};
5517     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5518
5519     # Do we have any breakpoints to put in this file?
5520     return unless $postponed_file{$filename};
5521
5522     # Yes. Mark this file as having breakpoints.
5523     $had_breakpoints{$filename} |= 1;
5524
5525     # "Cannot be done: unsufficient magic" - we can't just put the
5526     # breakpoints saved in %postponed_file into %dbline by assigning
5527     # the whole hash; we have to do it one item at a time for the
5528     # breakpoints to be set properly.
5529     #%dbline = %{$postponed_file{$filename}};
5530
5531     # Set the breakpoints, one at a time.
5532     my $key;
5533
5534     for $key ( keys %{ $postponed_file{$filename} } ) {
5535
5536         # Stash the saved breakpoint into the current file's magic line array.
5537         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5538     }
5539
5540     # This file's been compiled; discard the stored breakpoints.
5541     delete $postponed_file{$filename};
5542
5543 } ## end sub postponed
5544
5545 =head2 C<dumpit>
5546
5547 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5548
5549 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5550 a reference to a variable (the thing to be dumped) as its input.
5551
5552 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5553 the currently-selected filehandle, thank you very much). The current
5554 values of the package globals C<$single> and C<$trace> are backed up in
5555 lexicals, and they are turned off (this keeps the debugger from trying
5556 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5557 preserve its current value and it is set to zero to prevent entry/exit
5558 messages from printing, and C<$doret> is localized as well and set to -2 to
5559 prevent return values from being shown.
5560
5561 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5562 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5563 installed version in C<@INC>, yours will be used instead. Possible security
5564 problem?).
5565
5566 It then checks to see if the subroutine C<main::dumpValue> is now defined
5567 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5568 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5569 is called, and picks up the variable to be dumped from the parameter list.
5570
5571 It checks the package global C<%options> to see if there's a C<dumpDepth>
5572 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5573 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5574 structure: -1 means dump everything.
5575
5576 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5577 warning.
5578
5579 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5580 and we then return to the caller.
5581
5582 =cut
5583
5584 sub dumpit {
5585
5586     # Save the current output filehandle and switch to the one
5587     # passed in as the first parameter.
5588     local ($savout) = select(shift);
5589
5590     # Save current settings of $single and $trace, and then turn them off.
5591     my $osingle = $single;
5592     my $otrace  = $trace;
5593     $single = $trace = 0;
5594
5595     # XXX Okay, what do $frame and $doret do, again?
5596     local $frame = 0;
5597     local $doret = -2;
5598
5599     # Load dumpvar.pl unless we've already got the sub we need from it.
5600     unless ( defined &main::dumpValue ) {
5601         do 'dumpvar.pl' or die $@;
5602     }
5603
5604     # If the load succeeded (or we already had dumpvalue()), go ahead
5605     # and dump things.
5606     if ( defined &main::dumpValue ) {
5607         local $\ = '';
5608         local $, = '';
5609         local $" = ' ';
5610         my $v = shift;
5611         my $maxdepth = shift || $option{dumpDepth};
5612         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5613         &main::dumpValue( $v, $maxdepth );
5614     } ## end if (defined &main::dumpValue)
5615
5616     # Oops, couldn't load dumpvar.pl.
5617     else {
5618         local $\ = '';
5619         print $OUT "dumpvar.pl not available.\n";
5620     }
5621
5622     # Reset $single and $trace to their old values.
5623     $single = $osingle;
5624     $trace  = $otrace;
5625
5626     # Restore the old filehandle.
5627     select($savout);
5628 } ## end sub dumpit
5629
5630 =head2 C<print_trace>
5631
5632 C<print_trace>'s job is to print a stack trace. It does this via the
5633 C<dump_trace> routine, which actually does all the ferreting-out of the
5634 stack trace data. C<print_trace> takes care of formatting it nicely and
5635 printing it to the proper filehandle.
5636
5637 Parameters:
5638
5639 =over 4
5640
5641 =item *
5642
5643 The filehandle to print to.
5644
5645 =item *
5646
5647 How many frames to skip before starting trace.
5648
5649 =item *
5650
5651 How many frames to print.
5652
5653 =item *
5654
5655 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5656
5657 =back
5658
5659 The original comment below seems to be noting that the traceback may not be
5660 correct if this routine is called in a tied method.
5661
5662 =cut
5663
5664 # Tied method do not create a context, so may get wrong message:
5665
5666 sub print_trace {
5667     local $\ = '';
5668     my $fh = shift;
5669
5670     # If this is going to a slave editor, but we're not the primary
5671     # debugger, reset it first.
5672     resetterm(1)
5673       if $fh        eq $LINEINFO    # slave editor
5674       and $LINEINFO eq $OUT         # normal output
5675       and $term_pid != $$;          # not the primary
5676
5677     # Collect the actual trace information to be formatted.
5678     # This is an array of hashes of subroutine call info.
5679     my @sub = dump_trace( $_[0] + 1, $_[1] );
5680
5681     # Grab the "short report" flag from @_.
5682     my $short = $_[2];              # Print short report, next one for sub name
5683
5684     # Run through the traceback info, format it, and print it.
5685     my $s;
5686     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5687
5688         # Drop out if the user has lost interest and hit control-C.
5689         last if $signal;
5690
5691         # Set the separator so arrys print nice.
5692         local $" = ', ';
5693
5694         # Grab and stringify the arguments if they are there.
5695         my $args =
5696           defined $sub[$i]{args}
5697           ? "(@{ $sub[$i]{args} })"
5698           : '';
5699
5700         # Shorten them up if $maxtrace says they're too long.
5701         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5702           if length $args > $maxtrace;
5703
5704         # Get the file name.
5705         my $file = $sub[$i]{file};
5706
5707         # Put in a filename header if short is off.
5708         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5709
5710         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5711         $s = $sub[$i]{sub};
5712         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5713
5714         # Short report uses trimmed file and sub names.
5715         if ($short) {
5716             my $sub = @_ >= 4 ? $_[3] : $s;
5717             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5718         } ## end if ($short)
5719
5720         # Non-short report includes full names.
5721         else {
5722             print $fh "$sub[$i]{context} = $s$args"
5723               . " called from $file"
5724               . " line $sub[$i]{line}\n";
5725         }
5726     } ## end for ($i = 0 ; $i <= $#sub...
5727 } ## end sub print_trace
5728
5729 =head2 dump_trace(skip[,count])
5730
5731 Actually collect the traceback information available via C<caller()>. It does
5732 some filtering and cleanup of the data, but mostly it just collects it to
5733 make C<print_trace()>'s job easier.
5734
5735 C<skip> defines the number of stack frames to be skipped, working backwards
5736 from the most current. C<count> determines the total number of frames to
5737 be returned; all of them (well, the first 10^9) are returned if C<count>
5738 is omitted.
5739
5740 This routine returns a list of hashes, from most-recent to least-recent
5741 stack frame. Each has the following keys and values:
5742
5743 =over 4
5744
5745 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5746
5747 =item * C<sub> - subroutine name, or C<eval> information
5748
5749 =item * C<args> - undef, or a reference to an array of arguments
5750
5751 =item * C<file> - the file in which this item was defined (if any)
5752
5753 =item * C<line> - the line on which it was defined
5754
5755 =back
5756
5757 =cut
5758
5759 sub dump_trace {
5760
5761     # How many levels to skip.
5762     my $skip = shift;
5763
5764     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5765     # it's unlikely that we'll have more than a billion stack frames. If you
5766     # do, you've got an awfully big machine...)
5767     my $count = shift || 1e9;
5768
5769     # We increment skip because caller(1) is the first level *back* from
5770     # the current one.  Add $skip to the count of frames so we have a
5771     # simple stop criterion, counting from $skip to $count+$skip.
5772     $skip++;
5773     $count += $skip;
5774
5775     # These variables are used to capture output from caller();
5776     my ( $p, $file, $line, $sub, $h, $context );
5777
5778     my ( $e, $r, @a, @sub, $args );
5779
5780     # XXX Okay... why'd we do that?
5781     my $nothard = not $frame & 8;
5782     local $frame = 0;
5783
5784     # Do not want to trace this.
5785     my $otrace = $trace;
5786     $trace = 0;
5787
5788     # Start out at the skip count.
5789     # If we haven't reached the number of frames requested, and caller() is
5790     # still returning something, stay in the loop. (If we pass the requested
5791     # number of stack frames, or we run out - caller() returns nothing - we
5792     # quit.
5793     # Up the stack frame index to go back one more level each time.
5794     for (
5795         $i = $skip ;
5796         $i < $count
5797         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5798         $i++
5799       )
5800     {
5801
5802         # Go through the arguments and save them for later.
5803         @a = ();
5804         for $arg (@args) {
5805             my $type;
5806             if ( not defined $arg ) {    # undefined parameter
5807                 push @a, "undef";
5808             }
5809
5810             elsif ( $nothard and tied $arg ) {    # tied parameter
5811                 push @a, "tied";
5812             }
5813             elsif ( $nothard and $type = ref $arg ) {    # reference
5814                 push @a, "ref($type)";
5815             }
5816             else {                                       # can be stringified
5817                 local $_ =
5818                   "$arg";    # Safe to stringify now - should not call f().
5819
5820                 # Backslash any single-quotes or backslashes.
5821                 s/([\'\\])/\\$1/g;
5822
5823                 # Single-quote it unless it's a number or a colon-separated
5824                 # name.
5825                 s/(.*)/'$1'/s
5826                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5827
5828                 # Turn high-bit characters into meta-whatever.
5829                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5830
5831                 # Turn control characters into ^-whatever.
5832                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5833
5834                 push( @a, $_ );
5835             } ## end else [ if (not defined $arg)
5836         } ## end for $arg (@args)
5837
5838         # If context is true, this is array (@)context.
5839         # If context is false, this is scalar ($) context.
5840         # If neither, context isn't defined. (This is apparently a 'can't
5841         # happen' trap.)
5842         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5843
5844         # if the sub has args ($h true), make an anonymous array of the
5845         # dumped args.
5846         $args = $h ? [@a] : undef;
5847
5848         # remove trailing newline-whitespace-semicolon-end of line sequence
5849         # from the eval text, if any.
5850         $e =~ s/\n\s*\;\s*\Z// if $e;
5851
5852         # Escape backslashed single-quotes again if necessary.
5853         $e =~ s/([\\\'])/\\$1/g if $e;
5854
5855         # if the require flag is true, the eval text is from a require.
5856         if ($r) {
5857             $sub = "require '$e'";
5858         }
5859
5860         # if it's false, the eval text is really from an eval.
5861         elsif ( defined $r ) {
5862             $sub = "eval '$e'";
5863         }
5864
5865         # If the sub is '(eval)', this is a block eval, meaning we don't
5866         # know what the eval'ed text actually was.
5867         elsif ( $sub eq '(eval)' ) {
5868             $sub = "eval {...}";
5869         }
5870
5871         # Stick the collected information into @sub as an anonymous hash.
5872         push(
5873             @sub,
5874             {
5875                 context => $context,
5876                 sub     => $sub,
5877                 args    => $args,
5878                 file    => $file,
5879                 line    => $line
5880             }
5881         );
5882
5883         # Stop processing frames if the user hit control-C.
5884         last if $signal;
5885     } ## end for ($i = $skip ; $i < ...
5886
5887     # Restore the trace value again.
5888     $trace = $otrace;
5889     @sub;
5890 } ## end sub dump_trace
5891
5892 =head2 C<action()>
5893
5894 C<action()> takes input provided as the argument to an add-action command,
5895 either pre- or post-, and makes sure it's a complete command. It doesn't do
5896 any fancy parsing; it just keeps reading input until it gets a string
5897 without a trailing backslash.
5898
5899 =cut
5900
5901 sub action {
5902     my $action = shift;
5903
5904     while ( $action =~ s/\\$// ) {
5905
5906         # We have a backslash on the end. Read more.
5907         $action .= &gets;
5908     } ## end while ($action =~ s/\\$//)
5909
5910     # Return the assembled action.
5911     $action;
5912 } ## end sub action
5913
5914 =head2 unbalanced
5915
5916 This routine mostly just packages up a regular expression to be used
5917 to check that the thing it's being matched against has properly-matched
5918 curly braces.
5919
5920 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5921 speeds things up by only creating the qr//'ed expression once; if it's
5922 already defined, we don't try to define it again. A speed hack.
5923
5924 =cut
5925
5926 sub unbalanced {
5927
5928     # I hate using globals!
5929     $balanced_brace_re ||= qr{
5930         ^ \{
5931              (?:
5932                  (?> [^{}] + )              # Non-parens without backtracking
5933                 |
5934                  (??{ $balanced_brace_re }) # Group with matching parens
5935               ) *
5936           \} $
5937    }x;
5938     return $_[0] !~ m/$balanced_brace_re/;
5939 } ## end sub unbalanced
5940
5941 =head2 C<gets()>
5942
5943 C<gets()> is a primitive (very primitive) routine to read continuations.
5944 It was devised for reading continuations for actions.
5945 it just reads more input with C<readline()> and returns it.
5946
5947 =cut
5948
5949 sub gets {
5950     &readline("cont: ");
5951 }
5952
5953 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5954
5955 The C<system()> function assumes that it can just go ahead and use STDIN and
5956 STDOUT, but under the debugger, we want it to use the debugger's input and
5957 outout filehandles.
5958
5959 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5960 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5961 and then puts everything back again.
5962
5963 =cut
5964
5965 sub system {
5966
5967     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5968     # some non-Unix systems can do system() but have problems with fork().
5969     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5970     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5971     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5972     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5973
5974     # XXX: using csh or tcsh destroys sigint retvals!
5975     system(@_);
5976     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5977     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5978     close(SAVEIN);
5979     close(SAVEOUT);
5980
5981     # most of the $? crud was coping with broken cshisms
5982     if ( $? >> 8 ) {
5983         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5984     }
5985     elsif ($?) {
5986         &warn(
5987             "(Command died of SIG#",
5988             ( $? & 127 ),
5989             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5990             ")", "\n"
5991         );
5992     } ## end elsif ($?)
5993
5994     return $?;
5995
5996 } ## end sub system
5997
5998 =head1 TTY MANAGEMENT
5999
6000 The subs here do some of the terminal management for multiple debuggers.
6001
6002 =head2 setterm
6003
6004 Top-level function called when we want to set up a new terminal for use
6005 by the debugger.
6006
6007 If the C<noTTY> debugger option was set, we'll either use the terminal
6008 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6009 to find one. If we're a forked debugger, we call C<resetterm> to try to
6010 get a whole new terminal if we can.
6011
6012 In either case, we set up the terminal next. If the C<ReadLine> option was
6013 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6014 the appropriate attributes. We then
6015
6016 =cut
6017
6018 sub setterm {
6019
6020     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6021     local $frame = 0;
6022     local $doret = -2;
6023     eval { require Term::ReadLine } or die $@;
6024
6025     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6026     if ($notty) {
6027         if ($tty) {
6028             my ( $i, $o ) = split $tty, /,/;
6029             $o = $i unless defined $o;
6030             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
6031             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
6032             $IN  = \*IN;
6033             $OUT = \*OUT;
6034             my $sel = select($OUT);
6035             $| = 1;
6036             select($sel);
6037         } ## end if ($tty)
6038
6039         # We don't have a TTY - try to find one via Term::Rendezvous.
6040         else {
6041             eval "require Term::Rendezvous;" or die;
6042
6043             # See if we have anything to pass to Term::Rendezvous.
6044             # Use $HOME/.perldbtty$$ if not.
6045             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6046
6047             # Rendezvous and get the filehandles.
6048             my $term_rv = new Term::Rendezvous $rv;
6049             $IN  = $term_rv->IN;
6050             $OUT = $term_rv->OUT;
6051         } ## end else [ if ($tty)
6052     } ## end if ($notty)
6053
6054     # We're a daughter debugger. Try to fork off another TTY.
6055     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6056         resetterm(2);
6057     }
6058
6059     # If we shouldn't use Term::ReadLine, don't.
6060     if ( !$rl ) {
6061         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6062     }
6063
6064     # We're using Term::ReadLine. Get all the attributes for this terminal.
6065     else {
6066         $term = new Term::ReadLine 'perldb', $IN, $OUT;
6067
6068         $rl_attribs = $term->Attribs;
6069         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6070           if defined $rl_attribs->{basic_word_break_characters}
6071           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6072         $rl_attribs->{special_prefixes} = '$@&%';
6073         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6074         $rl_attribs->{completion_function} = \&db_complete;
6075     } ## end else [ if (!$rl)
6076
6077     # Set up the LINEINFO filehandle.
6078     $LINEINFO = $OUT     unless defined $LINEINFO;
6079     $lineinfo = $console unless defined $lineinfo;
6080
6081     $term->MinLine(2);
6082
6083     &load_hist();
6084
6085     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6086         $term->SetHistory(@hist);
6087     }
6088
6089     # XXX Ornaments are turned on unconditionally, which is not
6090     # always a good thing.
6091     ornaments($ornaments) if defined $ornaments;
6092     $term_pid = $$;
6093 } ## end sub setterm
6094
6095 sub load_hist {
6096     $histfile //= option_val("HistFile", undef);
6097     return unless defined $histfile;
6098     open my $fh, "<", $histfile or return;
6099     local $/ = "\n";
6100     @hist = ();
6101     while (<$fh>) {
6102         chomp;
6103         push @hist, $_;
6104     }
6105     close $fh;
6106 }
6107
6108 sub save_hist {
6109     return unless defined $histfile;
6110     eval { require File::Path } or return;
6111     eval { require File::Basename } or return;
6112     File::Path::mkpath(File::Basename::dirname($histfile));
6113     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6114     $histsize //= option_val("HistSize",100);
6115     my @copy = grep { $_ ne '?' } @hist;
6116     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6117     for ($start .. $#copy) {
6118         print $fh "$copy[$_]\n";
6119     }
6120     close $fh or die "Could not write '$histfile': $!";
6121 }
6122
6123 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6124
6125 When the process being debugged forks, or the process invokes a command
6126 via C<system()> which starts a new debugger, we need to be able to get a new
6127 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6128 fight over the terminal, and you can never quite be sure who's going to get the
6129 input you're typing.
6130
6131 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6132 is tasked with doing all the necessary operating system mojo to get a new
6133 TTY (and probably another window) and to direct the new debugger to read and
6134 write there.
6135
6136 The debugger provides C<get_fork_TTY> functions which work for X Windows,
6137 OS/2, and Mac OS X. Other systems are not supported. You are encouraged
6138 to write C<get_fork_TTY> functions which work for I<your> platform
6139 and contribute them.
6140
6141 =head3 C<xterm_get_fork_TTY>
6142
6143 This function provides the C<get_fork_TTY> function for X windows. If a
6144 program running under the debugger forks, a new <xterm> window is opened and
6145 the subsidiary debugger is directed there.
6146
6147 The C<open()> call is of particular note here. We have the new C<xterm>
6148 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6149 command (which prints the device name of the TTY we'll want to use for input
6150 and output to STDOUT, then C<sleep> for a very long time, routing this output
6151 to file number 3. This way we can simply read from the <XT> filehandle (which
6152 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6153
6154 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6155 properly set up.
6156
6157 =cut
6158
6159 sub xterm_get_fork_TTY {
6160     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6161     open XT,
6162 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6163  sleep 10000000' |];
6164
6165     # Get the output from 'tty' and clean it up a little.
6166     my $tty = <XT>;
6167     chomp $tty;
6168
6169     $pidprompt = '';    # Shown anyway in titlebar
6170
6171     # There's our new TTY.
6172     return $tty;
6173 } ## end sub xterm_get_fork_TTY
6174
6175 =head3 C<os2_get_fork_TTY>
6176
6177 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6178
6179 =cut
6180
6181 # This example function resets $IN, $OUT itself
6182 my $c_pipe = 0;
6183 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6184     local $\  = '';
6185     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6186     my %opt = ( title => "Daughter Perl debugger $pids $name",
6187                 ($rl ? (read_by_key => 1) : ()) );
6188     require OS2::Process;
6189     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6190       or return;
6191     $pidprompt = '';    # Shown anyway in titlebar
6192     reset_IN_OUT($in, $out);
6193     $tty = '*reset*';
6194     return '';          # Indicate that reset_IN_OUT is called
6195 } ## end sub os2_get_fork_TTY
6196
6197 =head3 C<macosx_get_fork_TTY>
6198
6199 The Mac OS X version uses AppleScript to tell Terminal.app to create
6200 a new window.
6201
6202 =cut
6203
6204 # Notes about Terminal.app's AppleScript support,
6205 # (aka things that might break in future OS versions).
6206 #
6207 # The "do script" command doesn't return a reference to the new window
6208 # it creates, but since it appears frontmost and windows are enumerated
6209 # front to back, we can use "first window" === "window 1".
6210 #
6211 # There's no direct accessor for the tty device name, so we fiddle
6212 # with the window title options until it says what we want.
6213 #
6214 # Since "do script" is implemented by supplying the argument (plus a
6215 # return character) as terminal input, there's a potential race condition
6216 # where the debugger could beat the shell to reading the command.
6217 # To prevent this, we wait for the screen to clear before proceeding.
6218 #
6219 # Tested and found to be functional in Mac OS X 10.3.9 and 10.4.8.
6220
6221 sub macosx_get_fork_TTY
6222 {
6223     my($pipe,$tty);
6224
6225     return unless open($pipe,'-|','/usr/bin/osascript','-e',<<'__SCRIPT__');
6226 tell application "Terminal"
6227     do script "clear;exec sleep 100000"
6228     tell first window
6229         set title displays shell path to false
6230         set title displays window size to false
6231         set title displays file name to false
6232         set title displays device name to true
6233         set title displays custom title to true
6234         set custom title to ""
6235         copy name to thetitle
6236         set custom title to "forked perl debugger"
6237         repeat while (length of first paragraph of (get contents)) > 0
6238             delay 0.1
6239         end repeat
6240     end tell
6241 end tell
6242 "/dev/" & thetitle
6243 __SCRIPT__
6244
6245     $tty=readline($pipe);
6246     close($pipe);
6247     return unless defined($tty) && $tty =~ m(^/dev/);
6248     chomp $tty;
6249     return $tty;
6250 }
6251
6252 =head2 C<create_IN_OUT($flags)>
6253
6254 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6255 try to diagnose why.
6256
6257 Flags are:
6258
6259 =over 4
6260
6261 =item * 1 - Don't know how to create a new TTY.
6262
6263 =item * 2 - Debugger has forked, but we can't get a new TTY.
6264
6265 =item * 4 - standard debugger startup is happening.
6266
6267 =back
6268
6269 =cut
6270
6271 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6272
6273     # If we know how to get a new TTY, do it! $in will have
6274     # the TTY name if get_fork_TTY works.
6275     my $in = &get_fork_TTY if defined &get_fork_TTY;
6276
6277     # It used to be that
6278     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6279
6280     if ( not defined $in ) {
6281         my $why = shift;
6282
6283         # We don't know how.
6284         print_help(<<EOP) if $why == 1;
6285 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6286 EOP
6287
6288         # Forked debugger.
6289         print_help(<<EOP) if $why == 2;
6290 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6291   This may be an asynchronous session, so the parent debugger may be active.
6292 EOP
6293
6294         # Note that both debuggers are fighting over the same input.
6295         print_help(<<EOP) if $why != 4;
6296   Since two debuggers fight for the same TTY, input is severely entangled.
6297
6298 EOP
6299         print_help(<<EOP);
6300   I know how to switch the output to a different window in xterms, OS/2
6301   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6302   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6303   B<DB::get_fork_TTY()> returning this.
6304
6305   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6306   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6307
6308 EOP
6309     } ## end if (not defined $in)
6310     elsif ( $in ne '' ) {
6311         TTY($in);
6312     }
6313     else {
6314         $console = '';    # Indicate no need to open-from-the-console
6315     }
6316     undef $fork_TTY;
6317 } ## end sub create_IN_OUT
6318
6319 =head2 C<resetterm>
6320
6321 Handles rejiggering the prompt when we've forked off a new debugger.
6322
6323 If the new debugger happened because of a C<system()> that invoked a
6324 program under the debugger, the arrow between the old pid and the new
6325 in the prompt has I<two> dashes instead of one.
6326
6327 We take the current list of pids and add this one to the end. If there
6328 isn't any list yet, we make one up out of the initial pid associated with
6329 the terminal and our new pid, sticking an arrow (either one-dashed or
6330 two dashed) in between them.
6331
6332 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6333 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6334 and try to do that.
6335
6336 =cut
6337
6338 sub resetterm {    # We forked, so we need a different TTY
6339
6340     # Needs to be passed to create_IN_OUT() as well.
6341     my $in = shift;
6342
6343     # resetterm(2): got in here because of a system() starting a debugger.
6344     # resetterm(1): just forked.
6345     my $systemed = $in > 1 ? '-' : '';
6346
6347     # If there's already a list of pids, add this to the end.
6348     if ($pids) {
6349         $pids =~ s/\]/$systemed->$$]/;
6350     }
6351
6352     # No pid list. Time to make one.
6353     else {
6354         $pids = "[$term_pid->$$]";
6355     }
6356
6357     # The prompt we're going to be using for this debugger.
6358     $pidprompt = $pids;
6359
6360     # We now 0wnz this terminal.
6361     $term_pid = $$;
6362
6363     # Just return if we're not supposed to try to create a new TTY.
6364     return unless $CreateTTY & $in;
6365
6366     # Try to create a new IN/OUT pair.
6367     create_IN_OUT($in);
6368 } ## end sub resetterm
6369
6370 =head2 C<readline>
6371
6372 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6373 the next line, print a message saying we got it, add it to the terminal
6374 history (if possible), and return it.
6375
6376 If there's nothing in the typeahead buffer, check the command filehandle stack.
6377 If there are any filehandles there, read from the last one, and return the line
6378 if we got one. If not, we pop the filehandle off and close it, and try the
6379 next one up the stack.
6380
6381 If we've emptied the filehandle stack, we check to see if we've got a socket
6382 open, and we read that and return it if we do. If we don't, we just call the
6383 core C<readline()> and return its value.
6384
6385 =cut
6386
6387 sub readline {
6388
6389     # Localize to prevent it from being smashed in the program being debugged.
6390     local $.;
6391
6392     # Pull a line out of the typeahead if there's stuff there.
6393     if (@typeahead) {
6394
6395         # How many lines left.
6396         my $left = @typeahead;
6397
6398         # Get the next line.
6399         my $got = shift @typeahead;
6400
6401         # Print a message saying we got input from the typeahead.
6402         local $\ = '';
6403         print $OUT "auto(-$left)", shift, $got, "\n";
6404
6405         # Add it to the terminal history (if possible).
6406         $term->AddHistory($got)
6407           if length($got) > 1
6408           and defined $term->Features->{addHistory};
6409         return $got;
6410     } ## end if (@typeahead)
6411
6412     # We really need to read some input. Turn off entry/exit trace and
6413     # return value printing.
6414     local $frame = 0;
6415     local $doret = -2;
6416
6417     # If there are stacked filehandles to read from ...
6418     while (@cmdfhs) {
6419
6420         # Read from the last one in the stack.
6421         my $line = CORE::readline( $cmdfhs[-1] );
6422
6423         # If we got a line ...
6424         defined $line
6425           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6426           : close pop @cmdfhs;                            # Pop and close
6427     } ## end while (@cmdfhs)
6428
6429     # Nothing on the filehandle stack. Socket?
6430     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6431
6432         # Send anyting we have to send.
6433         $OUT->write( join( '', @_ ) );
6434
6435         # Receive anything there is to receive.
6436         $stuff;
6437         my $stuff = '';
6438         my $buf;
6439         do {
6440             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6441                                             # XXX Don't know. You tell me.
6442         } while length $buf and ($stuff .= $buf) !~ /\n/;
6443
6444         # What we got.
6445         $stuff;
6446     } ## end if (ref $OUT and UNIVERSAL::isa...
6447
6448     # No socket. Just read from the terminal.
6449     else {
6450         $term->readline(@_);
6451     }
6452 } ## end sub readline
6453
6454 =head1 OPTIONS SUPPORT ROUTINES
6455
6456 These routines handle listing and setting option values.
6457
6458 =head2 C<dump_option> - list the current value of an option setting
6459
6460 This routine uses C<option_val> to look up the value for an option.
6461 It cleans up escaped single-quotes and then displays the option and
6462 its value.
6463
6464 =cut
6465
6466 sub dump_option {
6467     my ( $opt, $val ) = @_;
6468     $val = option_val( $opt, 'N/A' );
6469     $val =~ s/([\\\'])/\\$1/g;
6470     printf $OUT "%20s = '%s'\n", $opt, $val;
6471 } ## end sub dump_option
6472
6473 sub options2remember {
6474     foreach my $k (@RememberOnROptions) {
6475         $option{$k} = option_val( $k, 'N/A' );
6476     }
6477     return %option;
6478 }
6479
6480 =head2 C<option_val> - find the current value of an option
6481
6482 This can't just be a simple hash lookup because of the indirect way that
6483 the option values are stored. Some are retrieved by calling a subroutine,
6484 some are just variables.
6485
6486 You must supply a default value to be used in case the option isn't set.
6487
6488 =cut
6489
6490 sub option_val {
6491     my ( $opt, $default ) = @_;
6492     my $val;
6493
6494     # Does this option exist, and is it a variable?
6495     # If so, retrieve the value via the value in %optionVars.
6496     if (    defined $optionVars{$opt}
6497         and defined ${ $optionVars{$opt} } )
6498     {
6499         $val = ${ $optionVars{$opt} };
6500     }
6501
6502     # Does this option exist, and it's a subroutine?
6503     # If so, call the subroutine via the ref in %optionAction
6504     # and capture the value.
6505     elsif ( defined $optionAction{$opt}
6506         and defined &{ $optionAction{$opt} } )
6507     {
6508         $val = &{ $optionAction{$opt} }();
6509     }
6510
6511     # If there's an action or variable for the supplied option,
6512     # but no value was set, use the default.
6513     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6514         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6515     {
6516         $val = $default;
6517     }
6518
6519     # Otherwise, do the simple hash lookup.
6520     else {
6521         $val = $option{$opt};
6522     }
6523
6524     # If the value isn't defined, use the default.
6525     # Then return whatever the value is.
6526     $val = $default unless defined $val;
6527     $val;
6528 } ## end sub option_val
6529
6530 =head2 C<parse_options>
6531
6532 Handles the parsing and execution of option setting/displaying commands.
6533
6534 An option entered by itself is assumed to be I<set me to 1> (the default value)
6535 if the option is a boolean one. If not, the user is prompted to enter a valid
6536 value or to query the current value (via C<option? >).
6537
6538 If C<option=value> is entered, we try to extract a quoted string from the
6539 value (if it is quoted). If it's not, we just use the whole value as-is.
6540
6541 We load any modules required to service this option, and then we set it: if
6542 it just gets stuck in a variable, we do that; if there's a subroutine to
6543 handle setting the option, we call that.
6544
6545 Finally, if we're running in interactive mode, we display the effect of the
6546 user's command back to the terminal, skipping this if we're setting things
6547 during initialization.
6548
6549 =cut
6550
6551 sub parse_options {
6552     local ($_) = @_;
6553     local $\ = '';
6554
6555     # These options need a value. Don't allow them to be clobbered by accident.
6556     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6557       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6558       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6559     };
6560
6561     while (length) {
6562         my $val_defaulted;
6563
6564         # Clean off excess leading whitespace.
6565         s/^\s+// && next;
6566
6567         # Options are always all word characters, followed by a non-word
6568         # separator.
6569         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6570         my ( $opt, $sep ) = ( $1, $2 );
6571
6572         # Make sure that such an option exists.
6573         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6574           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6575
6576         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6577         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6578         my $val;
6579
6580         # '?' as separator means query, but must have whitespace after it.
6581         if ( "?" eq $sep ) {
6582             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6583               last
6584               if /^\S/;
6585
6586             #&dump_option($opt);
6587         } ## end if ("?" eq $sep)
6588
6589         # Separator is whitespace (or just a carriage return).
6590         # They're going for a default, which we assume is 1.
6591         elsif ( $sep !~ /\S/ ) {
6592             $val_defaulted = 1;
6593             $val           = "1";   #  this is an evil default; make 'em set it!
6594         }
6595
6596         # Separator is =. Trying to set a value.
6597         elsif ( $sep eq "=" ) {
6598
6599             # If quoted, extract a quoted string.
6600             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6601                 my $quote = $1;
6602                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6603             }
6604
6605             # Not quoted. Use the whole thing. Warn about 'option='.
6606             else {
6607                 s/^(\S*)//;
6608                 $val = $1;
6609                 print OUT qq(Option better cleared using $opt=""\n)
6610                   unless length $val;
6611             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6612
6613         } ## end elsif ($sep eq "=")
6614
6615         # "Quoted" with [], <>, or {}.
6616         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6617             my ($end) =
6618               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6619             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6620               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6621             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6622         } ## end else [ if ("?" eq $sep)
6623
6624         # Exclude non-booleans from getting set to 1 by default.
6625         if ( $opt_needs_val{$option} && $val_defaulted ) {
6626             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6627             print $OUT
6628 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6629             next;
6630         } ## end if ($opt_needs_val{$option...
6631
6632         # Save the option value.
6633         $option{$option} = $val if defined $val;
6634
6635         # Load any module that this option requires.
6636         eval qq{
6637                 local \$frame = 0;
6638                 local \$doret = -2;
6639                 require '$optionRequire{$option}';
6640                 1;
6641                } || die    # XXX: shouldn't happen
6642           if defined $optionRequire{$option}
6643           && defined $val;
6644
6645         # Set it.
6646         # Stick it in the proper variable if it goes in a variable.
6647         ${ $optionVars{$option} } = $val
6648           if defined $optionVars{$option}
6649           && defined $val;
6650
6651         # Call the appropriate sub if it gets set via sub.
6652         &{ $optionAction{$option} }($val)
6653           if defined $optionAction{$option}
6654           && defined &{ $optionAction{$option} }
6655           && defined $val;
6656
6657         # Not initialization - echo the value we set it to.
6658         dump_option($option) unless $OUT eq \*STDERR;
6659     } ## end while (length)
6660 } ## end sub parse_options
6661
6662 =head1 RESTART SUPPORT
6663
6664 These routines are used to store (and restore) lists of items in environment
6665 variables during a restart.
6666
6667 =head2 set_list
6668
6669 Set_list packages up items to be stored in a set of environment variables
6670 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6671 the values). Values outside the standard ASCII charset are stored by encoding
6672 then as hexadecimal values.
6673
6674 =cut
6675
6676 sub set_list {
6677     my ( $stem, @list ) = @_;
6678     my $val;
6679
6680     # VAR_n: how many we have. Scalar assignment gets the number of items.
6681     $ENV{"${stem}_n"} = @list;
6682
6683     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6684     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6685     for $i ( 0 .. $#list ) {
6686         $val = $list[$i];
6687         $val =~ s/\\/\\\\/g;
6688         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6689         $ENV{"${stem}_$i"} = $val;
6690     } ## end for $i (0 .. $#list)
6691 } ## end sub set_list
6692
6693 =head2 get_list
6694
6695 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6696 back, and then pull VAR_0, VAR_1. etc. back out.
6697
6698 =cut
6699
6700 sub get_list {
6701     my $stem = shift;
6702     my @list;
6703     my $n = delete $ENV{"${stem}_n"};
6704     my $val;
6705     for $i ( 0 .. $n - 1 ) {
6706         $val = delete $ENV{"${stem}_$i"};
6707         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6708         push @list, $val;
6709     }
6710     @list;
6711 } ## end sub get_list
6712
6713 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6714
6715 =head2 catch()
6716
6717 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6718 set an already-existing global scalar variable to a constant value. This
6719 avoids allocating any memory possibly in the middle of something that will
6720 get all confused if we do, particularly under I<unsafe signals>.
6721
6722 =cut
6723
6724 sub catch {
6725     $signal = 1;
6726     return;    # Put nothing on the stack - malloc/free land!
6727 }
6728
6729 =head2 C<warn()>
6730
6731 C<warn> emits a warning, by joining together its arguments and printing
6732 them, with couple of fillips.
6733
6734 If the composited message I<doesn't> end with a newline, we automatically
6735 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6736 to be set to the filehandle to be used to output warnings; it makes no
6737 assumptions about what filehandles are available.
6738
6739 =cut
6740
6741 sub warn {
6742     my ($msg) = join( "", @_ );
6743     $msg .= ": $!\n" unless $msg =~ /\n$/;
6744     local $\ = '';
6745     print $OUT $msg;
6746 } ## end sub warn
6747
6748 =head1 INITIALIZATION TTY SUPPORT
6749
6750 =head2 C<reset_IN_OUT>
6751
6752 This routine handles restoring the debugger's input and output filehandles
6753 after we've tried and failed to move them elsewhere.  In addition, it assigns
6754 the debugger's output filehandle to $LINEINFO if it was already open there.
6755
6756 =cut
6757
6758 sub reset_IN_OUT {
6759     my $switch_li = $LINEINFO eq $OUT;
6760
6761     # If there's a term and it's able to get a new tty, try to get one.
6762     if ( $term and $term->Features->{newTTY} ) {
6763         ( $IN, $OUT ) = ( shift, shift );
6764         $term->newTTY( $IN, $OUT );
6765     }
6766
6767     # This term can't get a new tty now. Better luck later.
6768     elsif ($term) {
6769         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6770     }
6771
6772     # Set the filehndles up as they were.
6773     else {
6774         ( $IN, $OUT ) = ( shift, shift );
6775     }
6776
6777     # Unbuffer the output filehandle.
6778     my $o = select $OUT;
6779     $| = 1;
6780     select $o;
6781
6782     # Point LINEINFO to the same output filehandle if it was there before.
6783     $LINEINFO = $OUT if $switch_li;
6784 } ## end sub reset_IN_OUT
6785
6786 =head1 OPTION SUPPORT ROUTINES
6787
6788 The following routines are used to process some of the more complicated
6789 debugger options.
6790
6791 =head2 C<TTY>
6792
6793 Sets the input and output filehandles to the specified files or pipes.
6794 If the terminal supports switching, we go ahead and do it. If not, and
6795 there's already a terminal in place, we save the information to take effect
6796 on restart.
6797
6798 If there's no terminal yet (for instance, during debugger initialization),
6799 we go ahead and set C<$console> and C<$tty> to the file indicated.
6800
6801 =cut
6802
6803 sub TTY {
6804
6805     # With VMS we can get here with $term undefined, so we do not
6806     # switch to this terminal.  There may be a better place to make
6807     # sure that $term is defined on VMS
6808     if ( @_ and ($^O eq 'VMS') and !defined($term) ) {
6809         eval { require Term::ReadLine } or die $@;
6810         if ( !$rl ) {
6811             $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6812         }
6813         else {
6814             $term = new Term::ReadLine 'perldb', $IN, $OUT;
6815         }
6816     }
6817     if ( @_ and $term and $term->Features->{newTTY} ) {
6818
6819         # This terminal supports switching to a new TTY.
6820         # Can be a list of two files, or on string containing both names,
6821         # comma-separated.
6822         # XXX Should this perhaps be an assignment from @_?
6823         my ( $in, $out ) = shift;
6824         if ( $in =~ /,/ ) {
6825
6826             # Split list apart if supplied.
6827             ( $in, $out ) = split /,/, $in, 2;
6828         }
6829         else {
6830
6831             # Use the same file for both input and output.
6832             $out = $in;
6833         }
6834
6835         # Open file onto the debugger's filehandles, if you can.
6836         open IN,  $in     or die "cannot open `$in' for read: $!";
6837         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6838
6839         # Swap to the new filehandles.
6840         reset_IN_OUT( \*IN, \*OUT );
6841
6842         # Save the setting for later.
6843         return $tty = $in;
6844     } ## end if (@_ and $term and $term...
6845
6846     # Terminal doesn't support new TTY, or doesn't support readline.
6847     # Can't do it now, try restarting.
6848     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6849
6850     # Useful if done through PERLDB_OPTS:
6851     $console = $tty = shift if @_;
6852
6853     # Return whatever the TTY is.
6854     $tty or $console;
6855 } ## end sub TTY
6856
6857 =head2 C<noTTY>
6858
6859 Sets the C<$notty> global, controlling whether or not the debugger tries to
6860 get a terminal to read from. If called after a terminal is already in place,
6861 we save the value to use it if we're restarted.
6862
6863 =cut
6864
6865 sub noTTY {
6866     if ($term) {
6867         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6868     }
6869     $notty = shift if @_;
6870     $notty;
6871 } ## end sub noTTY
6872
6873 =head2 C<ReadLine>
6874
6875 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6876 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6877 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6878 the value in case a restart is done so we can change it then.
6879
6880 =cut
6881
6882 sub ReadLine {
6883     if ($term) {
6884         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6885     }
6886     $rl = shift if @_;
6887     $rl;
6888 } ## end sub ReadLine
6889
6890 =head2 C<RemotePort>
6891
6892 Sets the port that the debugger will try to connect to when starting up.
6893 If the terminal's already been set up, we can't do it, but we remember the
6894 setting in case the user does a restart.
6895
6896 =cut
6897
6898 sub RemotePort {
6899     if ($term) {
6900         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6901     }
6902     $remoteport = shift if @_;
6903     $remoteport;
6904 } ## end sub RemotePort
6905
6906 =head2 C<tkRunning>
6907
6908 Checks with the terminal to see if C<Tk> is running, and returns true or
6909 false. Returns false if the current terminal doesn't support C<readline>.
6910
6911 =cut
6912
6913 sub tkRunning {
6914     if ( ${ $term->Features }{tkRunning} ) {
6915         return $term->tkRunning(@_);
6916     }
6917     else {
6918         local $\ = '';
6919         print $OUT "tkRunning not supported by current ReadLine package.\n";
6920         0;
6921     }
6922 } ## end sub tkRunning
6923
6924 =head2 C<NonStop>
6925
6926 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6927 debugger remembers the setting in case you restart, though.
6928
6929 =cut
6930
6931 sub NonStop {
6932     if ($term) {
6933         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6934           if @_;
6935     }
6936     $runnonstop = shift if @_;
6937     $runnonstop;
6938 } ## end sub NonStop
6939
6940 sub DollarCaretP {
6941     if ($term) {
6942         &warn("Some flag changes could not take effect until next 'R'!\n")
6943           if @_;
6944     }
6945     $^P = parse_DollarCaretP_flags(shift) if @_;
6946     expand_DollarCaretP_flags($^P);
6947 }
6948
6949 sub OnlyAssertions {
6950     if ($term) {
6951         &warn("Too late to set up OnlyAssertions mode, enabled on next 'R'!\n")
6952           if @_;
6953     }
6954     if (@_) {
6955         unless ( defined $ini_assertion ) {
6956             if ($term) {
6957                 &warn("Current Perl interpreter doesn't support assertions");
6958             }
6959             return 0;
6960         }
6961         if (shift) {
6962             unless ($ini_assertion) {
6963                 print "Assertions will be active on next 'R'!\n";
6964                 $ini_assertion = 1;
6965             }
6966             $^P &= ~$DollarCaretP_flags{PERLDBf_SUB};
6967             $^P |= $DollarCaretP_flags{PERLDBf_ASSERTION};
6968         }
6969         else {
6970             $^P |= $DollarCaretP_flags{PERLDBf_SUB};
6971         }
6972     }
6973     !( $^P & $DollarCaretP_flags{PERLDBf_SUB} ) || 0;
6974 }
6975
6976 =head2 C<pager>
6977
6978 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6979 there already.
6980
6981 =cut
6982
6983 sub pager {
6984     if (@_) {
6985         $pager = shift;
6986         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6987     }
6988     $pager;
6989 } ## end sub pager
6990
6991 =head2 C<shellBang>
6992
6993 Sets the shell escape command, and generates a printable copy to be used
6994 in the help.
6995
6996 =cut
6997
6998 sub shellBang {
6999
7000     # If we got an argument, meta-quote it, and add '\b' if it
7001     # ends in a word character.
7002     if (@_) {
7003         $sh = quotemeta shift;
7004         $sh .= "\\b" if $sh =~ /\w$/;
7005     }
7006
7007     # Generate the printable version for the help:
7008     $psh = $sh;    # copy it
7009     $psh =~ s/\\b$//;        # Take off trailing \b if any
7010     $psh =~ s/\\(.)/$1/g;    # De-escape
7011     $psh;                    # return the printable version
7012 } ## end sub shellBang
7013
7014 =head2 C<ornaments>
7015
7016 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7017 was passed as the argument. (This means you can't override the terminal's
7018 ornaments.)
7019
7020 =cut
7021
7022 sub ornaments {
7023     if ( defined $term ) {
7024
7025         # We don't want to show warning backtraces, but we do want die() ones.
7026         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7027
7028         # No ornaments if the terminal doesn't support them.
7029         return '' unless $term->Features->{ornaments};
7030         eval { $term->ornaments(@_) } || '';
7031     }
7032
7033     # Use what was passed in if we can't determine it ourselves.
7034     else {
7035         $ornaments = shift;
7036     }
7037 } ## end sub ornaments
7038
7039 =head2 C<recallCommand>
7040
7041 Sets the recall command, and builds a printable version which will appear in
7042 the help text.
7043
7044 =cut
7045
7046 sub recallCommand {
7047
7048     # If there is input, metaquote it. Add '\b' if it ends with a word
7049     # character.
7050     if (@_) {
7051         $rc = quotemeta shift;
7052         $rc .= "\\b" if $rc =~ /\w$/;
7053     }
7054
7055     # Build it into a printable version.
7056     $prc = $rc;    # Copy it
7057     $prc =~ s/\\b$//;        # Remove trailing \b
7058     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7059     $prc;                    # Return the printable version
7060 } ## end sub recallCommand
7061
7062 =head2 C<LineInfo> - where the line number information goes
7063
7064 Called with no arguments, returns the file or pipe that line info should go to.
7065
7066 Called with an argument (a file or a pipe), it opens that onto the
7067 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7068 file or pipe again to the caller.
7069
7070 =cut
7071
7072 sub LineInfo {
7073     return $lineinfo unless @_;
7074     $lineinfo = shift;
7075
7076     #  If this is a valid "thing to be opened for output", tack a
7077     # '>' onto the front.
7078     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7079
7080     # If this is a pipe, the stream points to a slave editor.
7081     $slave_editor = ( $stream =~ /^\|/ );
7082
7083     # Open it up and unbuffer it.
7084     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
7085     $LINEINFO = \*LINEINFO;
7086     my $save = select($LINEINFO);
7087     $| = 1;
7088     select($save);
7089
7090     # Hand the file or pipe back again.
7091     $lineinfo;
7092 } ## end sub LineInfo
7093
7094 =head1 COMMAND SUPPORT ROUTINES
7095
7096 These subroutines provide functionality for various commands.
7097
7098 =head2 C<list_modules>
7099
7100 For the C<M> command: list modules loaded and their versions.
7101 Essentially just runs through the keys in %INC, picks each package's
7102 C<$VERSION> variable, gets the file name, and formats the information
7103 for output.
7104
7105 =cut
7106
7107 sub list_modules {    # versions
7108     my %version;
7109     my $file;
7110
7111     # keys are the "as-loaded" name, values are the fully-qualified path
7112     # to the file itself.
7113     for ( keys %INC ) {
7114         $file = $_;                                # get the module name
7115         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7116         s,/,::,g;                                  # change '/' to '::'
7117         s/^perl5db$/DB/;                           # Special case: debugger
7118                                                    # moves to package DB
7119         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7120
7121         # If the package has a $VERSION package global (as all good packages
7122         # should!) decode it and save as partial message.
7123         if ( defined ${ $_ . '::VERSION' } ) {
7124             $version{$file} = "${ $_ . '::VERSION' } from ";
7125         }
7126
7127         # Finish up the message with the file the package came from.
7128         $version{$file} .= $INC{$file};
7129     } ## end for (keys %INC)
7130
7131     # Hey, dumpit() formats a hash nicely, so why not use it?
7132     dumpit( $OUT, \%version );
7133 } ## end sub list_modules
7134
7135 =head2 C<sethelp()>
7136
7137 Sets up the monster string used to format and print the help.
7138
7139 =head3 HELP MESSAGE FORMAT
7140
7141 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7142 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7143 easy to parse and portable, but which still allows the help to be a little
7144 nicer than just plain text.
7145
7146 Essentially, you define the command name (usually marked up with C<< B<> >>
7147 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7148 newline. The descriptive text can also be marked up in the same way. If you
7149 need to continue the descriptive text to another line, start that line with
7150 just tabs and then enter the marked-up text.
7151
7152 If you are modifying the help text, I<be careful>. The help-string parser is
7153 not very sophisticated, and if you don't follow these rules it will mangle the
7154 help beyond hope until you fix the string.
7155
7156 =cut
7157
7158 sub sethelp {
7159
7160     # XXX: make sure there are tabs between the command and explanation,
7161     #      or print_help will screw up your formatting if you have
7162     #      eeevil ornaments enabled.  This is an insane mess.
7163
7164     $help = "
7165 Help is currently only available for the new 5.8 command set.
7166 No help is available for the old command set.
7167 We assume you know what you're doing if you switch to it.
7168
7169 B<T>        Stack trace.
7170 B<s> [I<expr>]    Single step [in I<expr>].
7171 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7172 <B<CR>>        Repeat last B<n> or B<s> command.
7173 B<r>        Return from current subroutine.
7174 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7175         at the specified position.
7176 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7177 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7178 B<l> I<line>        List single I<line>.
7179 B<l> I<subname>    List first window of lines from subroutine.
7180 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7181 B<l>        List next window of lines.
7182 B<->        List previous window of lines.
7183 B<v> [I<line>]    View window around I<line>.
7184 B<.>        Return to the executed line.
7185 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7186         I<filename> may be either the full name of the file, or a regular
7187         expression matching the full file name:
7188         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7189         Evals (with saved bodies) are considered to be filenames:
7190         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7191         (in the order of execution).
7192 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7193 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7194 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7195 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7196 B<t>        Toggle trace mode.
7197 B<t> I<expr>        Trace through execution of I<expr>.
7198 B<b>        Sets breakpoint on current line)
7199 B<b> [I<line>] [I<condition>]
7200         Set breakpoint; I<line> defaults to the current execution line;
7201         I<condition> breaks if it evaluates to true, defaults to '1'.
7202 B<b> I<subname> [I<condition>]
7203         Set breakpoint at first line of subroutine.
7204 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7205 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7206 B<b> B<postpone> I<subname> [I<condition>]
7207         Set breakpoint at first line of subroutine after
7208         it is compiled.
7209 B<b> B<compile> I<subname>
7210         Stop after the subroutine is compiled.
7211 B<B> [I<line>]    Delete the breakpoint for I<line>.
7212 B<B> I<*>             Delete all breakpoints.
7213 B<a> [I<line>] I<command>
7214         Set an action to be done before the I<line> is executed;
7215         I<line> defaults to the current execution line.
7216         Sequence is: check for breakpoint/watchpoint, print line
7217         if necessary, do action, prompt user if necessary,
7218         execute line.
7219 B<a>        Does nothing
7220 B<A> [I<line>]    Delete the action for I<line>.
7221 B<A> I<*>             Delete all actions.
7222 B<w> I<expr>        Add a global watch-expression.
7223 B<w>             Does nothing
7224 B<W> I<expr>        Delete a global watch-expression.
7225 B<W> I<*>             Delete all watch-expressions.
7226 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7227         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7228 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7229 B<x> I<expr>        Evals expression in list context, dumps the result.
7230 B<m> I<expr>        Evals expression in list context, prints methods callable
7231         on the first element of the result.
7232 B<m> I<class>        Prints methods callable via the given class.
7233 B<M>        Show versions of loaded modules.
7234 B<i> I<class>       Prints nested parents of given class.
7235 B<e>         Display current thread id.
7236 B<E>         Display all thread ids the current one will be identified: <n>.
7237 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7238 B<P> Something to do with assertions...
7239
7240 B<<> ?            List Perl commands to run before each prompt.
7241 B<<> I<expr>        Define Perl command to run before each prompt.
7242 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7243 B<< *>                Delete the list of perl commands to run before each prompt.
7244 B<>> ?            List Perl commands to run after each prompt.
7245 B<>> I<expr>        Define Perl command to run after each prompt.
7246 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7247 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7248 B<{> I<db_command>    Define debugger command to run before each prompt.
7249 B<{> ?            List debugger commands to run before each prompt.
7250 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7251 B<{ *>             Delete the list of debugger commands to run before each prompt.
7252 B<$prc> I<number>    Redo a previous command (default previous command).
7253 B<$prc> I<-number>    Redo number'th-to-last command.
7254 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7255         See 'B<O> I<recallCommand>' too.
7256 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7257       . (
7258         $rc eq $sh
7259         ? ""
7260         : "
7261 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7262       ) . "
7263         See 'B<O> I<shellBang>' too.
7264 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7265 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7266 B<rerun>           Rerun session to current position.
7267 B<rerun> I<n>         Rerun session to numbered command.
7268 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7269 B<H> I<-number>    Display last number commands (default all).
7270 B<H> I<*>          Delete complete history.
7271 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7272 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7273 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7274 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7275 I<command>        Execute as a perl statement in current package.
7276 B<R>        Pure-man-restart of debugger, some of debugger state
7277         and command-line options may be lost.
7278         Currently the following settings are preserved:
7279         history, breakpoints and actions, debugger B<O>ptions
7280         and the following command-line options: I<-w>, I<-I>, I<-e>.
7281
7282 B<o> [I<opt>] ...    Set boolean option to true
7283 B<o> [I<opt>B<?>]    Query options
7284 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7285         Set options.  Use quotes if spaces in value.
7286     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7287     I<pager>            program for output of \"|cmd\";
7288     I<tkRunning>            run Tk while prompting (with ReadLine);
7289     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7290     I<inhibit_exit>        Allows stepping off the end of the script.
7291     I<ImmediateStop>        Debugger should stop as early as possible.
7292     I<RemotePort>            Remote hostname:port for remote debugging
7293   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7294     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7295     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7296     I<globPrint>             whether to print contents of globs;
7297     I<DumpDBFiles>         dump arrays holding debugged files;
7298     I<DumpPackages>         dump symbol tables of packages;
7299     I<DumpReused>             dump contents of \"reused\" addresses;
7300     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7301     I<bareStringify>         Do not print the overload-stringified value;
7302   Other options include:
7303     I<PrintRet>        affects printing of return value after B<r> command,
7304     I<frame>        affects printing messages on subroutine entry/exit.
7305     I<AutoTrace>    affects printing messages on possible breaking points.
7306     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7307     I<ornaments>     affects screen appearance of the command line.
7308     I<CreateTTY>     bits control attempts to create a new TTY on events:
7309             1: on fork()    2: debugger is started inside debugger
7310             4: on startup
7311     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7312     You can put additional initialization options I<TTY>, I<noTTY>,
7313     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7314     `B<R>' after you set them).
7315
7316 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7317 B<h>        Summary of debugger commands.
7318 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7319 B<h h>        Long help for debugger commands
7320 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7321         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7322         Set B<\$DB::doccmd> to change viewer.
7323
7324 Type `|h h' for a paged display if this was too hard to read.
7325
7326 ";    # Fix balance of vi % matching: }}}}
7327
7328     #  note: tabs in the following section are not-so-helpful
7329     $summary = <<"END_SUM";
7330 I<List/search source lines:>               I<Control script execution:>
7331   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7332   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7333   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7334   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7335   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7336   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7337 I<Debugger controls:>                        B<L>           List break/watch/actions
7338   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7339   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7340   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7341   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7342   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7343   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7344   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7345   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7346   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7347 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7348   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7349   B<p> I<expr>         Print expression (uses script's current package).
7350   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7351   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7352   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7353   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7354   B<e>     Display thread id     B<E> Display all thread ids.
7355 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7356 END_SUM
7357
7358     # ')}}; # Fix balance of vi % matching
7359
7360     # and this is really numb...
7361     $pre580_help = "
7362 B<T>        Stack trace.
7363 B<s> [I<expr>]    Single step [in I<expr>].
7364 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7365 B<CR>>        Repeat last B<n> or B<s> command.
7366 B<r>        Return from current subroutine.
7367 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7368         at the specified position.
7369 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7370 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7371 B<l> I<line>        List single I<line>.
7372 B<l> I<subname>    List first window of lines from subroutine.
7373 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7374 B<l>        List next window of lines.
7375 B<->        List previous window of lines.
7376 B<w> [I<line>]    List window around I<line>.
7377 B<.>        Return to the executed line.
7378 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7379         I<filename> may be either the full name of the file, or a regular
7380         expression matching the full file name:
7381         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7382         Evals (with saved bodies) are considered to be filenames:
7383         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7384         (in the order of execution).
7385 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7386 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7387 B<L>        List all breakpoints and actions.
7388 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7389 B<t>        Toggle trace mode.
7390 B<t> I<expr>        Trace through execution of I<expr>.
7391 B<b> [I<line>] [I<condition>]
7392         Set breakpoint; I<line> defaults to the current execution line;
7393         I<condition> breaks if it evaluates to true, defaults to '1'.
7394 B<b> I<subname> [I<condition>]
7395         Set breakpoint at first line of subroutine.
7396 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7397 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7398 B<b> B<postpone> I<subname> [I<condition>]
7399         Set breakpoint at first line of subroutine after
7400         it is compiled.
7401 B<b> B<compile> I<subname>
7402         Stop after the subroutine is compiled.
7403 B<d> [I<line>]    Delete the breakpoint for I<line>.
7404 B<D>        Delete all breakpoints.
7405 B<a> [I<line>] I<command>
7406         Set an action to be done before the I<line> is executed;
7407         I<line> defaults to the current execution line.
7408         Sequence is: check for breakpoint/watchpoint, print line
7409         if necessary, do action, prompt user if necessary,
7410         execute line.
7411 B<a> [I<line>]    Delete the action for I<line>.
7412 B<A>        Delete all actions.
7413 B<W> I<expr>        Add a global watch-expression.
7414 B<W>        Delete all watch-expressions.
7415 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7416         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7417 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7418 B<x> I<expr>        Evals expression in list context, dumps the result.
7419 B<m> I<expr>        Evals expression in list context, prints methods callable
7420         on the first element of the result.
7421 B<m> I<class>        Prints methods callable via the given class.
7422
7423 B<<> ?            List Perl commands to run before each prompt.
7424 B<<> I<expr>        Define Perl command to run before each prompt.
7425 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7426 B<>> ?            List Perl commands to run after each prompt.
7427 B<>> I<expr>        Define Perl command to run after each prompt.
7428 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7429 B<{> I<db_command>    Define debugger command to run before each prompt.
7430 B<{> ?            List debugger commands to run before each prompt.
7431 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7432 B<$prc> I<number>    Redo a previous command (default previous command).
7433 B<$prc> I<-number>    Redo number'th-to-last command.
7434 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7435         See 'B<O> I<recallCommand>' too.
7436 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7437       . (
7438         $rc eq $sh
7439         ? ""
7440         : "
7441 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7442       ) . "
7443         See 'B<O> I<shellBang>' too.
7444 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7445 B<H> I<-number>    Display last number commands (default all).
7446 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7447 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7448 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7449 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7450 I<command>        Execute as a perl statement in current package.
7451 B<v>        Show versions of loaded modules.
7452 B<R>        Pure-man-restart of debugger, some of debugger state
7453         and command-line options may be lost.
7454         Currently the following settings are preserved:
7455         history, breakpoints and actions, debugger B<O>ptions
7456         and the following command-line options: I<-w>, I<-I>, I<-e>.
7457
7458 B<O> [I<opt>] ...    Set boolean option to true
7459 B<O> [I<opt>B<?>]    Query options
7460 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7461         Set options.  Use quotes if spaces in value.
7462     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7463     I<pager>            program for output of \"|cmd\";
7464     I<tkRunning>            run Tk while prompting (with ReadLine);
7465     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7466     I<inhibit_exit>        Allows stepping off the end of the script.
7467     I<ImmediateStop>        Debugger should stop as early as possible.
7468     I<RemotePort>            Remote hostname:port for remote debugging
7469   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7470     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7471     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7472     I<globPrint>             whether to print contents of globs;
7473     I<DumpDBFiles>         dump arrays holding debugged files;
7474     I<DumpPackages>         dump symbol tables of packages;
7475     I<DumpReused>             dump contents of \"reused\" addresses;
7476     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7477     I<bareStringify>         Do not print the overload-stringified value;
7478   Other options include:
7479     I<PrintRet>        affects printing of return value after B<r> command,
7480     I<frame>        affects printing messages on subroutine entry/exit.
7481     I<AutoTrace>    affects printing messages on possible breaking points.
7482     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7483     I<ornaments>     affects screen appearance of the command line.
7484     I<CreateTTY>     bits control attempts to create a new TTY on events:
7485             1: on fork()    2: debugger is started inside debugger
7486             4: on startup
7487     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7488     You can put additional initialization options I<TTY>, I<noTTY>,
7489     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7490     `B<R>' after you set them).
7491
7492 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7493 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7494 B<h h>        Summary of debugger commands.
7495 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7496         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7497         Set B<\$DB::doccmd> to change viewer.
7498
7499 Type `|h' for a paged display if this was too hard to read.
7500
7501 ";    # Fix balance of vi % matching: }}}}
7502
7503     #  note: tabs in the following section are not-so-helpful
7504     $pre580_summary = <<"END_SUM";
7505 I<List/search source lines:>               I<Control script execution:>
7506   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7507   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7508   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7509   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7510   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7511   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7512 I<Debugger controls:>                        B<L>           List break/watch/actions
7513   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7514   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7515   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7516   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7517   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7518   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7519   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7520   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7521 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7522   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7523   B<p> I<expr>         Print expression (uses script's current package).
7524   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7525   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7526   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7527   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7528 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7529 END_SUM
7530
7531     # ')}}; # Fix balance of vi % matching
7532
7533 } ## end sub sethelp
7534
7535 =head2 C<print_help()>
7536
7537 Most of what C<print_help> does is just text formatting. It finds the
7538 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7539 terminal control characters to simulate them (courtesy of
7540 C<Term::ReadLine::TermCap>).
7541
7542 =cut
7543
7544 sub print_help {
7545     local $_ = shift;
7546
7547     # Restore proper alignment destroyed by eeevil I<> and B<>
7548     # ornaments: A pox on both their houses!
7549     #
7550     # A help command will have everything up to and including
7551     # the first tab sequence padded into a field 16 (or if indented 20)
7552     # wide.  If it's wider than that, an extra space will be added.
7553     s{
7554         ^                       # only matters at start of line
7555           ( \040{4} | \t )*     # some subcommands are indented
7556           ( < ?                 # so <CR> works
7557             [BI] < [^\t\n] + )  # find an eeevil ornament
7558           ( \t+ )               # original separation, discarded
7559           ( .* )                # this will now start (no earlier) than
7560                                 # column 16
7561     } {
7562         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7563         my $clean = $command;
7564         $clean =~ s/[BI]<([^>]*)>/$1/g;
7565
7566         # replace with this whole string:
7567         ($leadwhite ? " " x 4 : "")
7568       . $command
7569       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7570       . $text;
7571
7572     }mgex;
7573
7574     s{                          # handle bold ornaments
7575        B < ( [^>] + | > ) >
7576     } {
7577           $Term::ReadLine::TermCap::rl_term_set[2]
7578         . $1
7579         . $Term::ReadLine::TermCap::rl_term_set[3]
7580     }gex;
7581
7582     s{                         # handle italic ornaments
7583        I < ( [^>] + | > ) >
7584     } {
7585           $Term::ReadLine::TermCap::rl_term_set[0]
7586         . $1
7587         . $Term::ReadLine::TermCap::rl_term_set[1]
7588     }gex;
7589
7590     local $\ = '';
7591     print $OUT $_;
7592 } ## end sub print_help
7593
7594 =head2 C<fix_less>
7595
7596 This routine does a lot of gyrations to be sure that the pager is C<less>.
7597 It checks for C<less> masquerading as C<more> and records the result in
7598 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7599
7600 =cut
7601
7602 sub fix_less {
7603
7604     # We already know if this is set.
7605     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7606
7607     # Pager is less for sure.
7608     my $is_less = $pager =~ /\bless\b/;
7609     if ( $pager =~ /\bmore\b/ ) {
7610
7611         # Nope, set to more. See what's out there.
7612         my @st_more = stat('/usr/bin/more');
7613         my @st_less = stat('/usr/bin/less');
7614
7615         # is it really less, pretending to be more?
7616              $is_less = @st_more
7617           && @st_less
7618           && $st_more[0] == $st_less[0]
7619           && $st_more[1] == $st_less[1];
7620     } ## end if ($pager =~ /\bmore\b/)
7621
7622     # changes environment!
7623     # 'r' added so we don't do (slow) stats again.
7624     $ENV{LESS} .= 'r' if $is_less;
7625 } ## end sub fix_less
7626
7627 =head1 DIE AND WARN MANAGEMENT
7628
7629 =head2 C<diesignal>
7630
7631 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7632 to debug a debugger problem.
7633
7634 It does its best to report the error that occurred, and then forces the
7635 program, debugger, and everything to die.
7636
7637 =cut
7638
7639 sub diesignal {
7640
7641     # No entry/exit messages.
7642     local $frame = 0;
7643
7644     # No return value prints.
7645     local $doret = -2;
7646
7647     # set the abort signal handling to the default (just terminate).
7648     $SIG{'ABRT'} = 'DEFAULT';
7649
7650     # If we enter the signal handler recursively, kill myself with an
7651     # abort signal (so we just terminate).
7652     kill 'ABRT', $$ if $panic++;
7653
7654     # If we can show detailed info, do so.
7655     if ( defined &Carp::longmess ) {
7656
7657         # Don't recursively enter the warn handler, since we're carping.
7658         local $SIG{__WARN__} = '';
7659
7660         # Skip two levels before reporting traceback: we're skipping
7661         # mydie and confess.
7662         local $Carp::CarpLevel = 2;    # mydie + confess
7663
7664         # Tell us all about it.
7665         &warn( Carp::longmess("Signal @_") );
7666     }
7667
7668     # No Carp. Tell us about the signal as best we can.
7669     else {
7670         local $\ = '';
7671         print $DB::OUT "Got signal @_\n";
7672     }
7673
7674     # Drop dead.
7675     kill 'ABRT', $$;
7676 } ## end sub diesignal
7677
7678 =head2 C<dbwarn>
7679
7680 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7681 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7682
7683 =cut
7684
7685 sub dbwarn {
7686
7687     # No entry/exit trace.
7688     local $frame = 0;
7689
7690     # No return value printing.
7691     local $doret = -2;
7692
7693     # Turn off warn and die handling to prevent recursive entries to this
7694     # routine.
7695     local $SIG{__WARN__} = '';
7696     local $SIG{__DIE__}  = '';
7697
7698     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7699     # done yet), we may not be able to do a require.
7700     eval { require Carp }
7701       if defined $^S;    # If error/warning during compilation,
7702                          # require may be broken.
7703
7704     # Use the core warn() unless Carp loaded OK.
7705     CORE::warn( @_,
7706         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7707       return
7708       unless defined &Carp::longmess;
7709
7710     # Save the current values of $single and $trace, and then turn them off.
7711     my ( $mysingle, $mytrace ) = ( $single, $trace );
7712     $single = 0;
7713     $trace  = 0;
7714
7715     # We can call Carp::longmess without its being "debugged" (which we
7716     # don't want - we just want to use it!). Capture this for later.
7717     my $mess = Carp::longmess(@_);
7718
7719     # Restore $single and $trace to their original values.
7720     ( $single, $trace ) = ( $mysingle, $mytrace );
7721
7722     # Use the debugger's own special way of printing warnings to print
7723     # the stack trace message.
7724     &warn($mess);
7725 } ## end sub dbwarn
7726
7727 =head2 C<dbdie>
7728
7729 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7730 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7731 single stepping and tracing during the call to C<Carp::longmess> to avoid
7732 debugging it - we just want to use it.
7733
7734 If C<dieLevel> is zero, we let the program being debugged handle the
7735 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7736 the debugger takes over all exception handling, printing a backtrace and
7737 displaying the exception via its C<dbwarn()> routine.
7738
7739 =cut
7740
7741 sub dbdie {
7742     local $frame         = 0;
7743     local $doret         = -2;
7744     local $SIG{__DIE__}  = '';
7745     local $SIG{__WARN__} = '';
7746     my $i      = 0;
7747     my $ineval = 0;
7748     my $sub;
7749     if ( $dieLevel > 2 ) {
7750         local $SIG{__WARN__} = \&dbwarn;
7751         &warn(@_);    # Yell no matter what
7752         return;
7753     }
7754     if ( $dieLevel < 2 ) {
7755         die @_ if $^S;    # in eval propagate
7756     }
7757
7758     # The code used to check $^S to see if compiliation of the current thing
7759     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7760     eval { require Carp };
7761
7762     die( @_,
7763         "\nCannot print stack trace, load with -MCarp option to see stack" )
7764       unless defined &Carp::longmess;
7765
7766     # We do not want to debug this chunk (automatic disabling works
7767     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7768     # get the stack trace from Carp::longmess (if possible), restore $signal
7769     # and $trace, and then die with the stack trace.
7770     my ( $mysingle, $mytrace ) = ( $single, $trace );
7771     $single = 0;
7772     $trace  = 0;
7773     my $mess = "@_";
7774     {
7775
7776         package Carp;    # Do not include us in the list
7777         eval { $mess = Carp::longmess(@_); };
7778     }
7779     ( $single, $trace ) = ( $mysingle, $mytrace );
7780     die $mess;
7781 } ## end sub dbdie
7782
7783 =head2 C<warnlevel()>
7784
7785 Set the C<$DB::warnLevel> variable that stores the value of the
7786 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7787 results in the debugger taking over all warning handlers. Setting
7788 C<warnLevel> to zero leaves any warning handlers set up by the program
7789 being debugged in place.
7790
7791 =cut
7792
7793 sub warnLevel {
7794     if (@_) {
7795         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7796         $warnLevel = shift;
7797         if ($warnLevel) {
7798             $SIG{__WARN__} = \&DB::dbwarn;
7799         }
7800         elsif ($prevwarn) {
7801             $SIG{__WARN__} = $prevwarn;
7802         }
7803     } ## end if (@_)
7804     $warnLevel;
7805 } ## end sub warnLevel
7806
7807 =head2 C<dielevel>
7808
7809 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7810 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7811 zero lets you use your own C<die()> handler.
7812
7813 =cut
7814
7815 sub dieLevel {
7816     local $\ = '';
7817     if (@_) {
7818         $prevdie = $SIG{__DIE__} unless $dieLevel;
7819         $dieLevel = shift;
7820         if ($dieLevel) {
7821
7822             # Always set it to dbdie() for non-zero values.
7823             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7824
7825             # No longer exists, so don't try  to use it.
7826             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7827
7828             # If we've finished initialization, mention that stack dumps
7829             # are enabled, If dieLevel is 1, we won't stack dump if we die
7830             # in an eval().
7831             print $OUT "Stack dump during die enabled",
7832               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7833               if $I_m_init;
7834
7835             # XXX This is probably obsolete, given that diehard() is gone.
7836             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7837         } ## end if ($dieLevel)
7838
7839         # Put the old one back if there was one.
7840         elsif ($prevdie) {
7841             $SIG{__DIE__} = $prevdie;
7842             print $OUT "Default die handler restored.\n";
7843         }
7844     } ## end if (@_)
7845     $dieLevel;
7846 } ## end sub dieLevel
7847
7848 =head2 C<signalLevel>
7849
7850 Number three in a series: set C<signalLevel> to zero to keep your own
7851 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7852 takes over and handles them with C<DB::diesignal()>.
7853
7854 =cut
7855
7856 sub signalLevel {
7857     if (@_) {
7858         $prevsegv = $SIG{SEGV} unless $signalLevel;
7859         $prevbus  = $SIG{BUS}  unless $signalLevel;
7860         $signalLevel = shift;
7861         if ($signalLevel) {
7862             $SIG{SEGV} = \&DB::diesignal;
7863             $SIG{BUS}  = \&DB::diesignal;
7864         }
7865         else {
7866             $SIG{SEGV} = $prevsegv;
7867             $SIG{BUS}  = $prevbus;
7868         }
7869     } ## end if (@_)
7870     $signalLevel;
7871 } ## end sub signalLevel
7872
7873 =head1 SUBROUTINE DECODING SUPPORT
7874
7875 These subroutines are used during the C<x> and C<X> commands to try to
7876 produce as much information as possible about a code reference. They use
7877 L<Devel::Peek> to try to find the glob in which this code reference lives
7878 (if it does) - this allows us to actually code references which correspond
7879 to named subroutines (including those aliased via glob assignment).
7880
7881 =head2 C<CvGV_name()>
7882
7883 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7884 via that routine. If this fails, return the reference again (when the
7885 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7886
7887 =cut
7888
7889 sub CvGV_name {
7890     my $in   = shift;
7891     my $name = CvGV_name_or_bust($in);
7892     defined $name ? $name : $in;
7893 }
7894
7895 =head2 C<CvGV_name_or_bust> I<coderef>
7896
7897 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7898 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7899 find a glob for this ref.
7900
7901 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7902
7903 =cut
7904
7905 sub CvGV_name_or_bust {
7906     my $in = shift;
7907     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7908     return unless ref $in;
7909     $in = \&$in;            # Hard reference...
7910     eval { require Devel::Peek; 1 } or return;
7911     my $gv = Devel::Peek::CvGV($in) or return;
7912     *$gv{PACKAGE} . '::' . *$gv{NAME};
7913 } ## end sub CvGV_name_or_bust
7914
7915 =head2 C<find_sub>
7916
7917 A utility routine used in various places; finds the file where a subroutine
7918 was defined, and returns that filename and a line-number range.
7919
7920 Tries to use C<@sub> first; if it can't find it there, it tries building a
7921 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7922 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7923 this way, it brute-force searches C<%sub>, checking for identical references.
7924
7925 =cut
7926
7927 sub find_sub {
7928     my $subr = shift;
7929     $sub{$subr} or do {
7930         return unless defined &$subr;
7931         my $name = CvGV_name_or_bust($subr);
7932         my $data;
7933         $data = $sub{$name} if defined $name;
7934         return $data if defined $data;
7935
7936         # Old stupid way...
7937         $subr = \&$subr;    # Hard reference
7938         my $s;
7939         for ( keys %sub ) {
7940             $s = $_, last if $subr eq \&$_;
7941         }
7942         $sub{$s} if $s;
7943       } ## end do
7944 } ## end sub find_sub
7945
7946 =head2 C<methods>
7947
7948 A subroutine that uses the utility function C<methods_via> to find all the
7949 methods in the class corresponding to the current reference and in
7950 C<UNIVERSAL>.
7951
7952 =cut
7953
7954 sub methods {
7955
7956     # Figure out the class - either this is the class or it's a reference
7957     # to something blessed into that class.
7958     my $class = shift;
7959     $class = ref $class if ref $class;
7960
7961     local %seen;
7962
7963     # Show the methods that this class has.
7964     methods_via( $class, '', 1 );
7965
7966     # Show the methods that UNIVERSAL has.
7967     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7968 } ## end sub methods
7969
7970 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7971
7972 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7973 all the parent class methods. C<$class> is the name of the next class to
7974 try; C<$prefix> is the message prefix, which gets built up as we go up the
7975 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7976 higher in the C<@ISA> tree, 0 if we should stop.
7977
7978 =cut
7979
7980 sub methods_via {
7981
7982     # If we've processed this class already, just quit.
7983     my $class = shift;
7984     return if $seen{$class}++;
7985
7986     # This is a package that is contributing the methods we're about to print.
7987     my $prefix  = shift;
7988     my $prepend = $prefix ? "via $prefix: " : '';
7989
7990     my $name;
7991     for $name (
7992
7993         # Keep if this is a defined subroutine in this class.
7994         grep { defined &{ ${"${class}::"}{$_} } }
7995
7996         # Extract from all the symbols in this class.
7997         sort keys %{"${class}::"}
7998       )
7999     {
8000
8001         # If we printed this already, skip it.
8002         next if $seen{$name}++;
8003
8004         # Print the new method name.
8005         local $\ = '';
8006         local $, = '';
8007         print $DB::OUT "$prepend$name\n";
8008     } ## end for $name (grep { defined...
8009
8010     # If the $crawl_upward argument is false, just quit here.
8011     return unless shift;
8012
8013     # $crawl_upward true: keep going up the tree.
8014     # Find all the classes this one is a subclass of.
8015     for $name ( @{"${class}::ISA"} ) {
8016
8017         # Set up the new prefix.
8018         $prepend = $prefix ? $prefix . " -> $name" : $name;
8019
8020         # Crawl up the tree and keep trying to crawl up.
8021         methods_via( $name, $prepend, 1 );
8022     }
8023 } ## end sub methods_via
8024
8025 =head2 C<setman> - figure out which command to use to show documentation
8026
8027 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8028
8029 =cut
8030
8031 sub setman {
8032     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
8033       ? "man"         # O Happy Day!
8034       : "perldoc";    # Alas, poor unfortunates
8035 } ## end sub setman
8036
8037 =head2 C<runman> - run the appropriate command to show documentation
8038
8039 Accepts a man page name; runs the appropriate command to display it (set up
8040 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8041 program's STDIN and STDOUT.
8042
8043 =cut
8044
8045 sub runman {
8046     my $page = shift;
8047     unless ($page) {
8048         &system("$doccmd $doccmd");
8049         return;
8050     }
8051
8052     # this way user can override, like with $doccmd="man -Mwhatever"
8053     # or even just "man " to disable the path check.
8054     unless ( $doccmd eq 'man' ) {
8055         &system("$doccmd $page");
8056         return;
8057     }
8058
8059     $page = 'perl' if lc($page) eq 'help';
8060
8061     require Config;
8062     my $man1dir = $Config::Config{'man1dir'};
8063     my $man3dir = $Config::Config{'man3dir'};
8064     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8065     my $manpath = '';
8066     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8067     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8068     chop $manpath if $manpath;
8069
8070     # harmless if missing, I figure
8071     my $oldpath = $ENV{MANPATH};
8072     $ENV{MANPATH} = $manpath if $manpath;
8073     my $nopathopt = $^O =~ /dunno what goes here/;
8074     if (
8075         CORE::system(
8076             $doccmd,
8077
8078             # I just *know* there are men without -M
8079             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8080             split ' ', $page
8081         )
8082       )
8083     {
8084         unless ( $page =~ /^perl\w/ ) {
8085 # do it this way because its easier to slurp in to keep up to date - clunky though.
8086 my @pods = qw(
8087     5004delta
8088     5005delta
8089     561delta
8090     56delta
8091     570delta
8092     571delta
8093     572delta
8094     573delta
8095     58delta
8096     581delta
8097     582delta
8098     583delta
8099     584delta
8100     590delta
8101     591delta
8102     592delta
8103     aix
8104     amiga
8105     apio
8106     api
8107     apollo
8108     artistic
8109     beos
8110     book
8111     boot
8112     bot
8113     bs2000
8114     call
8115     ce
8116     cheat
8117     clib
8118     cn
8119     compile
8120     cygwin
8121     data
8122     dbmfilter
8123     debguts
8124     debtut
8125     debug
8126     delta
8127     dgux
8128     diag
8129     doc
8130     dos
8131     dsc
8132     ebcdic
8133     embed
8134     epoc
8135     faq1
8136     faq2
8137     faq3
8138     faq4
8139     faq5
8140     faq6
8141     faq7
8142     faq8
8143     faq9
8144     faq
8145     filter
8146     fork
8147     form
8148     freebsd
8149     func
8150     gpl
8151     guts
8152     hack
8153     hist
8154     hpux
8155     hurd
8156     intern
8157     intro
8158     iol
8159     ipc
8160     irix
8161     jp
8162     ko
8163     lexwarn
8164     locale
8165     lol
8166     machten
8167     macos
8168     macosx
8169     mint
8170     modinstall
8171     modlib
8172     mod
8173     modstyle
8174     mpeix
8175     netware
8176     newmod
8177     number
8178     obj
8179     opentut
8180     op
8181     os2
8182     os390
8183     os400
8184     othrtut
8185     packtut
8186     plan9
8187     pod
8188     podspec
8189     port
8190     qnx
8191     ref
8192     reftut
8193     re
8194     requick
8195     reref
8196     retut
8197     run
8198     sec
8199     solaris
8200     style
8201     sub
8202     syn
8203     thrtut
8204     tie
8205     toc
8206     todo
8207     tooc
8208     toot
8209     trap
8210     tru64
8211     tw
8212     unicode
8213     uniintro
8214     util
8215     uts
8216     var
8217     vmesa
8218     vms
8219     vos
8220     win32
8221     xs
8222     xstut
8223 );
8224             if (grep { $page eq $_ } @pods) {
8225                 $page =~ s/^/perl/;
8226                 CORE::system( $doccmd,
8227                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8228                     $page );
8229             } ## end if (grep { $page eq $_...
8230         } ## end unless ($page =~ /^perl\w/)
8231     } ## end if (CORE::system($doccmd...
8232     if ( defined $oldpath ) {
8233         $ENV{MANPATH} = $manpath;
8234     }
8235     else {
8236         delete $ENV{MANPATH};
8237     }
8238 } ## end sub runman
8239
8240 #use Carp;                          # This did break, left for debugging
8241
8242 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8243
8244 Because of the way the debugger interface to the Perl core is designed, any
8245 debugger package globals that C<DB::sub()> requires have to be defined before
8246 any subroutines can be called. These are defined in the second C<BEGIN> block.
8247
8248 This block sets things up so that (basically) the world is sane
8249 before the debugger starts executing. We set up various variables that the
8250 debugger has to have set up before the Perl core starts running:
8251
8252 =over 4
8253
8254 =item *
8255
8256 The debugger's own filehandles (copies of STD and STDOUT for now).
8257
8258 =item *
8259
8260 Characters for shell escapes, the recall command, and the history command.
8261
8262 =item *
8263
8264 The maximum recursion depth.
8265
8266 =item *
8267
8268 The size of a C<w> command's window.
8269
8270 =item *
8271
8272 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8273
8274 =item *
8275
8276 The fact that we're not in a sub at all right now.
8277
8278 =item *
8279
8280 The default SIGINT handler for the debugger.
8281
8282 =item *
8283
8284 The appropriate value of the flag in C<$^D> that says the debugger is running
8285
8286 =item *
8287
8288 The current debugger recursion level
8289
8290 =item *
8291
8292 The list of postponed items and the C<$single> stack (XXX define this)
8293
8294 =item *
8295
8296 That we want no return values and no subroutine entry/exit trace.
8297
8298 =back
8299
8300 =cut
8301
8302 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8303
8304 BEGIN {    # This does not compile, alas. (XXX eh?)
8305     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8306     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8307
8308     # Define characters used by command parsing.
8309     $sh       = '!';      # Shell escape (does not work)
8310     $rc       = ',';      # Recall command (does not work)
8311     @hist     = ('?');    # Show history (does not work)
8312     @truehist = ();       # Can be saved for replay (per session)
8313
8314     # This defines the point at which you get the 'deep recursion'
8315     # warning. It MUST be defined or the debugger will not load.
8316     $deep = 100;
8317
8318     # Number of lines around the current one that are shown in the
8319     # 'w' command.
8320     $window = 10;
8321
8322     # How much before-the-current-line context the 'v' command should
8323     # use in calculating the start of the window it will display.
8324     $preview = 3;
8325
8326     # We're not in any sub yet, but we need this to be a defined value.
8327     $sub = '';
8328
8329     # Set up the debugger's interrupt handler. It simply sets a flag
8330     # ($signal) that DB::DB() will check before each command is executed.
8331     $SIG{INT} = \&DB::catch;
8332
8333     # The following lines supposedly, if uncommented, allow the debugger to
8334     # debug itself. Perhaps we can try that someday.
8335     # This may be enabled to debug debugger:
8336     #$warnLevel = 1 unless defined $warnLevel;
8337     #$dieLevel = 1 unless defined $dieLevel;
8338     #$signalLevel = 1 unless defined $signalLevel;
8339
8340     # This is the flag that says "a debugger is running, please call
8341     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8342     # execute anything in the user's context, because we always want to
8343     # get control back.
8344     $db_stop = 0;          # Compiler warning ...
8345     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8346
8347     # This variable records how many levels we're nested in debugging. Used
8348     # Used in the debugger prompt, and in determining whether it's all over or
8349     # not.
8350     $level = 0;            # Level of recursive debugging
8351
8352     # "Triggers bug (?) in perl if we postpone this until runtime."
8353     # XXX No details on this yet, or whether we should fix the bug instead
8354     # of work around it. Stay tuned.
8355     @postponed = @stack = (0);
8356
8357     # Used to track the current stack depth using the auto-stacked-variable
8358     # trick.
8359     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8360
8361     # Don't print return values on exiting a subroutine.
8362     $doret = -2;
8363
8364     # No extry/exit tracing.
8365     $frame = 0;
8366
8367 } ## end BEGIN
8368
8369 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8370
8371 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8372
8373 =head2 db_complete
8374
8375 C<readline> support - adds command completion to basic C<readline>.
8376
8377 Returns a list of possible completions to C<readline> when invoked. C<readline>
8378 will print the longest common substring following the text already entered.
8379
8380 If there is only a single possible completion, C<readline> will use it in full.
8381
8382 This code uses C<map> and C<grep> heavily to create lists of possible
8383 completion. Think LISP in this section.
8384
8385 =cut
8386
8387 sub db_complete {
8388
8389     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8390     # $text is the text to be completed.
8391     # $line is the incoming line typed by the user.
8392     # $start is the start of the text to be completed in the incoming line.
8393     my ( $text, $line, $start ) = @_;
8394
8395     # Save the initial text.
8396     # The search pattern is current package, ::, extract the next qualifier
8397     # Prefix and pack are set to undef.
8398     my ( $itext, $search, $prefix, $pack ) =
8399       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8400
8401 =head3 C<b postpone|compile>
8402
8403 =over 4
8404
8405 =item *
8406
8407 Find all the subroutines that might match in this package
8408
8409 =item *
8410
8411 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8412
8413 =item *
8414
8415 Include all the rest of the subs that are known
8416
8417 =item *
8418
8419 C<grep> out the ones that match the text we have so far
8420
8421 =item *
8422
8423 Return this as the list of possible completions
8424
8425 =back
8426
8427 =cut
8428
8429     return sort grep /^\Q$text/, ( keys %sub ),
8430       qw(postpone load compile),    # subroutines
8431       ( map { /$search/ ? ($1) : () } keys %sub )
8432       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8433
8434 =head3 C<b load>
8435
8436 Get all the possible files from C<@INC> as it currently stands and
8437 select the ones that match the text so far.
8438
8439 =cut
8440
8441     return sort grep /^\Q$text/, values %INC    # files
8442       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8443
8444 =head3  C<V> (list variable) and C<m> (list modules)
8445
8446 There are two entry points for these commands:
8447
8448 =head4 Unqualified package names
8449
8450 Get the top-level packages and grab everything that matches the text
8451 so far. For each match, recursively complete the partial packages to
8452 get all possible matching packages. Return this sorted list.
8453
8454 =cut
8455
8456     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8457       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8458       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8459
8460 =head4 Qualified package names
8461
8462 Take a partially-qualified package and find all subpackages for it
8463 by getting all the subpackages for the package so far, matching all
8464 the subpackages against the text, and discarding all of them which
8465 start with 'main::'. Return this list.
8466
8467 =cut
8468
8469     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8470       grep !/^main::/, grep /^\Q$text/,
8471       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8472       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8473       and $text =~ /^(.*[^:])::?(\w*)$/
8474       and $prefix = $1;
8475
8476 =head3 C<f> - switch files
8477
8478 Here, we want to get a fully-qualified filename for the C<f> command.
8479 Possibilities are:
8480
8481 =over 4
8482
8483 =item 1. The original source file itself
8484
8485 =item 2. A file from C<@INC>
8486
8487 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8488
8489 =back
8490
8491 =cut
8492
8493     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8494            # We might possibly want to switch to an eval (which has a "filename"
8495            # like '(eval 9)'), so we may need to clean up the completion text
8496            # before proceeding.
8497         $prefix = length($1) - length($text);
8498         $text   = $1;
8499
8500 =pod
8501
8502 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8503 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8504 out of C<%main::>, add the initial source file, and extract the ones that
8505 match the completion text so far.
8506
8507 =cut
8508
8509         return sort
8510           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8511           $0;
8512     } ## end if ($line =~ /^\|*f\s+(.*)/)
8513
8514 =head3 Subroutine name completion
8515
8516 We look through all of the defined subs (the keys of C<%sub>) and
8517 return both all the possible matches to the subroutine name plus
8518 all the matches qualified to the current package.
8519
8520 =cut
8521
8522     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8523         $text = substr $text, 1;
8524         $prefix = "&";
8525         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8526           (
8527             map { /$search/ ? ($1) : () }
8528               keys %sub
8529           );
8530     } ## end if ((substr $text, 0, ...
8531
8532 =head3  Scalar, array, and hash completion: partially qualified package
8533
8534 Much like the above, except we have to do a little more cleanup:
8535
8536 =cut
8537
8538     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8539
8540 =pod
8541
8542 =over 4
8543
8544 =item *
8545
8546 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8547
8548 =cut
8549
8550         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8551
8552 =pod
8553
8554 =item *
8555
8556 Figure out the prefix vs. what needs completing.
8557
8558 =cut
8559
8560         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8561         $text   = $2;
8562
8563 =pod
8564
8565 =item *
8566
8567 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8568
8569 =cut
8570
8571         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8572           keys %$pack;
8573
8574 =pod
8575
8576 =item *
8577
8578 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8579
8580 =cut
8581
8582         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8583             return db_complete( $out[0], $line, $start );
8584         }
8585
8586         # Return the list of possibles.
8587         return sort @out;
8588
8589     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8590
8591 =pod
8592
8593 =back
8594
8595 =head3 Symbol completion: current package or package C<main>.
8596
8597 =cut
8598
8599     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8600
8601 =pod
8602
8603 =over 4
8604
8605 =item *
8606
8607 If it's C<main>, delete main to just get C<::> leading.
8608
8609 =cut
8610
8611         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8612
8613 =pod
8614
8615 =item *
8616
8617 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8618
8619 =cut
8620
8621         $prefix = substr $text, 0, 1;
8622         $text   = substr $text, 1;
8623
8624 =pod
8625
8626 =item *
8627
8628 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8629
8630 =cut
8631
8632         my @out = map "$prefix$_", grep /^\Q$text/,
8633           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8634           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8635
8636 =item *
8637
8638 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8639
8640 =back
8641
8642 =cut
8643
8644         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8645             return db_complete( $out[0], $line, $start );
8646         }
8647
8648         # Return the list of possibles.
8649         return sort @out;
8650     } ## end if ($text =~ /^[\$@%]/)
8651
8652 =head3 Options
8653
8654 We use C<option_val()> to look up the current value of the option. If there's
8655 only a single value, we complete the command in such a way that it is a
8656 complete command for setting the option in question. If there are multiple
8657 possible values, we generate a command consisting of the option plus a trailing
8658 question mark, which, if executed, will list the current value of the option.
8659
8660 =cut
8661
8662     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8663     {    # Options after space
8664            # We look for the text to be matched in the list of possible options,
8665            # and fetch the current value.
8666         my @out = grep /^\Q$text/, @options;
8667         my $val = option_val( $out[0], undef );
8668
8669         # Set up a 'query option's value' command.
8670         my $out = '? ';
8671         if ( not defined $val or $val =~ /[\n\r]/ ) {
8672
8673             # There's really nothing else we can do.
8674         }
8675
8676         # We have a value. Create a proper option-setting command.
8677         elsif ( $val =~ /\s/ ) {
8678
8679             # XXX This may be an extraneous variable.
8680             my $found;
8681
8682             # We'll want to quote the string (because of the embedded
8683             # whtespace), but we want to make sure we don't end up with
8684             # mismatched quote characters. We try several possibilities.
8685             foreach $l ( split //, qq/\"\'\#\|/ ) {
8686
8687                 # If we didn't find this quote character in the value,
8688                 # quote it using this quote character.
8689                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8690             }
8691         } ## end elsif ($val =~ /\s/)
8692
8693         # Don't need any quotes.
8694         else {
8695             $out = "=$val ";
8696         }
8697
8698         # If there were multiple possible values, return '? ', which
8699         # makes the command into a query command. If there was just one,
8700         # have readline append that.
8701         $rl_attribs->{completer_terminator_character} =
8702           ( @out == 1 ? $out : '? ' );
8703
8704         # Return list of possibilities.
8705         return sort @out;
8706     } ## end if ((substr $line, 0, ...
8707
8708 =head3 Filename completion
8709
8710 For entering filenames. We simply call C<readline>'s C<filename_list()>
8711 method with the completion text to get the possible completions.
8712
8713 =cut
8714
8715     return $term->filename_list($text);    # filenames
8716
8717 } ## end sub db_complete
8718
8719 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8720
8721 Functions that possibly ought to be somewhere else.
8722
8723 =head2 end_report
8724
8725 Say we're done.
8726
8727 =cut
8728
8729 sub end_report {
8730     local $\ = '';
8731     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8732 }
8733
8734 =head2 clean_ENV
8735
8736 If we have $ini_pids, save it in the environment; else remove it from the
8737 environment. Used by the C<R> (restart) command.
8738
8739 =cut
8740
8741 sub clean_ENV {
8742     if ( defined($ini_pids) ) {
8743         $ENV{PERLDB_PIDS} = $ini_pids;
8744     }
8745     else {
8746         delete( $ENV{PERLDB_PIDS} );
8747     }
8748 } ## end sub clean_ENV
8749
8750 # PERLDBf_... flag names from perl.h
8751 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8752
8753 BEGIN {
8754     %DollarCaretP_flags = (
8755         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8756         PERLDBf_LINE      => 0x02,     # Keep line #
8757         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8758         PERLDBf_INTER     => 0x08,     # Preserve more data
8759         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8760         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8761         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8762         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8763         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8764         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8765         PERLDBf_ASSERTION => 0x400,    # Debug assertion subs enter/exit
8766         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO, _ASSERTION
8767     );
8768
8769     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8770 }
8771
8772 sub parse_DollarCaretP_flags {
8773     my $flags = shift;
8774     $flags =~ s/^\s+//;
8775     $flags =~ s/\s+$//;
8776     my $acu = 0;
8777     foreach my $f ( split /\s*\|\s*/, $flags ) {
8778         my $value;
8779         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8780             $value = hex $1;
8781         }
8782         elsif ( $f =~ /^(\d+)$/ ) {
8783             $value = int $1;
8784         }
8785         elsif ( $f =~ /^DEFAULT$/i ) {
8786             $value = $DollarCaretP_flags{PERLDB_ALL};
8787         }
8788         else {
8789             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8790             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8791             unless ( defined $value ) {
8792                 print $OUT (
8793                     "Unrecognized \$^P flag '$f'!\n",
8794                     "Acceptable flags are: "
8795                       . join( ', ', sort keys %DollarCaretP_flags ),
8796                     ", and hexadecimal and decimal numbers.\n"
8797                 );
8798                 return undef;
8799             }
8800         }
8801         $acu |= $value;
8802     }
8803     $acu;
8804 }
8805
8806 sub expand_DollarCaretP_flags {
8807     my $DollarCaretP = shift;
8808     my @bits         = (
8809         map {
8810             my $n = ( 1 << $_ );
8811             ( $DollarCaretP & $n )
8812               ? ( $DollarCaretP_flags_r{$n}
8813                   || sprintf( '0x%x', $n ) )
8814               : ()
8815           } 0 .. 31
8816     );
8817     return @bits ? join( '|', @bits ) : 0;
8818 }
8819
8820 =over 4
8821
8822 =item rerun
8823
8824 Rerun the current session to:
8825
8826     rerun        current position
8827
8828     rerun 4      command number 4
8829
8830     rerun -4     current command minus 4 (go back 4 steps)
8831
8832 Whether this always makes sense, in the current context is unknowable, and is
8833 in part left as a useful exersize for the reader.  This sub returns the
8834 appropriate arguments to rerun the current session.
8835
8836 =cut
8837
8838 sub rerun {
8839     my $i = shift;
8840     my @args;
8841     pop(@truehist);                      # strim
8842     unless (defined $truehist[$i]) {
8843         print "Unable to return to non-existent command: $i\n";
8844     } else {
8845         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8846         my @temp = @truehist;            # store
8847         push(@DB::typeahead, @truehist); # saved
8848         @truehist = @hist = ();          # flush
8849         @args = &restart();              # setup
8850         &get_list("PERLDB_HIST");        # clean
8851         &set_list("PERLDB_HIST", @temp); # reset
8852     }
8853     return @args;
8854 }
8855
8856 =item restart
8857
8858 Restarting the debugger is a complex operation that occurs in several phases.
8859 First, we try to reconstruct the command line that was used to invoke Perl
8860 and the debugger.
8861
8862 =cut
8863
8864 sub restart {
8865     # I may not be able to resurrect you, but here goes ...
8866     print $OUT
8867 "Warning: some settings and command-line options may be lost!\n";
8868     my ( @script, @flags, $cl );
8869
8870     # If warn was on before, turn it on again.
8871     push @flags, '-w' if $ini_warn;
8872     if ( $ini_assertion and @{^ASSERTING} ) {
8873         push @flags,
8874           ( map { /\:\^\(\?\:(.*)\)\$\)/ ? "-A$1" : "-A$_" }
8875               @{^ASSERTING} );
8876     }
8877
8878     # Rebuild the -I flags that were on the initial
8879     # command line.
8880     for (@ini_INC) {
8881         push @flags, '-I', $_;
8882     }
8883
8884     # Turn on taint if it was on before.
8885     push @flags, '-T' if ${^TAINT};
8886
8887     # Arrange for setting the old INC:
8888     # Save the current @init_INC in the environment.
8889     set_list( "PERLDB_INC", @ini_INC );
8890
8891     # If this was a perl one-liner, go to the "file"
8892     # corresponding to the one-liner read all the lines
8893     # out of it (except for the first one, which is going
8894     # to be added back on again when 'perl -d' runs: that's
8895     # the 'require perl5db.pl;' line), and add them back on
8896     # to the command line to be executed.
8897     if ( $0 eq '-e' ) {
8898         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8899             chomp( $cl = ${'::_<-e'}[$_] );
8900             push @script, '-e', $cl;
8901         }
8902     } ## end if ($0 eq '-e')
8903
8904     # Otherwise we just reuse the original name we had
8905     # before.
8906     else {
8907         @script = $0;
8908     }
8909
8910 =pod
8911
8912 After the command line  has been reconstructed, the next step is to save
8913 the debugger's status in environment variables. The C<DB::set_list> routine
8914 is used to save aggregate variables (both hashes and arrays); scalars are
8915 just popped into environment variables directly.
8916
8917 =cut
8918
8919     # If the terminal supported history, grab it and
8920     # save that in the environment.
8921     set_list( "PERLDB_HIST",
8922           $term->Features->{getHistory}
8923         ? $term->GetHistory
8924         : @hist );
8925
8926     # Find all the files that were visited during this
8927     # session (i.e., the debugger had magic hashes
8928     # corresponding to them) and stick them in the environment.
8929     my @had_breakpoints = keys %had_breakpoints;
8930     set_list( "PERLDB_VISITED", @had_breakpoints );
8931
8932     # Save the debugger options we chose.
8933     set_list( "PERLDB_OPT", %option );
8934     # set_list( "PERLDB_OPT", options2remember() );
8935
8936     # Save the break-on-loads.
8937     set_list( "PERLDB_ON_LOAD", %break_on_load );
8938
8939 =pod
8940
8941 The most complex part of this is the saving of all of the breakpoints. They
8942 can live in an awful lot of places, and we have to go through all of them,
8943 find the breakpoints, and then save them in the appropriate environment
8944 variable via C<DB::set_list>.
8945
8946 =cut
8947
8948     # Go through all the breakpoints and make sure they're
8949     # still valid.
8950     my @hard;
8951     for ( 0 .. $#had_breakpoints ) {
8952
8953         # We were in this file.
8954         my $file = $had_breakpoints[$_];
8955
8956         # Grab that file's magic line hash.
8957         *dbline = $main::{ '_<' . $file };
8958
8959         # Skip out if it doesn't exist, or if the breakpoint
8960         # is in a postponed file (we'll do postponed ones
8961         # later).
8962         next unless %dbline or $postponed_file{$file};
8963
8964         # In an eval. This is a little harder, so we'll
8965         # do more processing on that below.
8966         ( push @hard, $file ), next
8967           if $file =~ /^\(\w*eval/;
8968
8969         # XXX I have no idea what this is doing. Yet.
8970         my @add;
8971         @add = %{ $postponed_file{$file} }
8972           if $postponed_file{$file};
8973
8974         # Save the list of all the breakpoints for this file.
8975         set_list( "PERLDB_FILE_$_", %dbline, @add );
8976     } ## end for (0 .. $#had_breakpoints)
8977
8978     # The breakpoint was inside an eval. This is a little
8979     # more difficult. XXX and I don't understand it.
8980     for (@hard) {
8981         # Get over to the eval in question.
8982         *dbline = $main::{ '_<' . $_ };
8983         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8984         for $sub ( keys %sub ) {
8985             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8986             $subs{$sub} = [ $1, $2 ];
8987         }
8988         unless (%subs) {
8989             print $OUT
8990               "No subroutines in $_, ignoring breakpoints.\n";
8991             next;
8992         }
8993       LINES: for $line ( keys %dbline ) {
8994
8995             # One breakpoint per sub only:
8996             my ( $offset, $sub, $found );
8997           SUBS: for $sub ( keys %subs ) {
8998                 if (
8999                     $subs{$sub}->[1] >=
9000                     $line    # Not after the subroutine
9001                     and (
9002                         not defined $offset    # Not caught
9003                         or $offset < 0
9004                     )
9005                   )
9006                 {                              # or badly caught
9007                     $found  = $sub;
9008                     $offset = $line - $subs{$sub}->[0];
9009                     $offset = "+$offset", last SUBS
9010                       if $offset >= 0;
9011                 } ## end if ($subs{$sub}->[1] >=...
9012             } ## end for $sub (keys %subs)
9013             if ( defined $offset ) {
9014                 $postponed{$found} =
9015                   "break $offset if $dbline{$line}";
9016             }
9017             else {
9018                 print $OUT
9019 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9020             }
9021         } ## end for $line (keys %dbline)
9022     } ## end for (@hard)
9023
9024     # Save the other things that don't need to be
9025     # processed.
9026     set_list( "PERLDB_POSTPONE",  %postponed );
9027     set_list( "PERLDB_PRETYPE",   @$pretype );
9028     set_list( "PERLDB_PRE",       @$pre );
9029     set_list( "PERLDB_POST",      @$post );
9030     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9031
9032     # We are oficially restarting.
9033     $ENV{PERLDB_RESTART} = 1;
9034
9035     # We are junking all child debuggers.
9036     delete $ENV{PERLDB_PIDS};    # Restore ini state
9037
9038     # Set this back to the initial pid.
9039     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9040
9041 =pod
9042
9043 After all the debugger status has been saved, we take the command we built up
9044 and then return it, so we can C<exec()> it. The debugger will spot the
9045 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9046 from the environment.
9047
9048 =cut
9049
9050     # And run Perl again. Add the "-d" flag, all the
9051     # flags we built up, the script (whether a one-liner
9052     # or a file), add on the -emacs flag for a slave editor,
9053     # and then the old arguments.
9054
9055     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9056
9057 };  # end restart
9058
9059 =back
9060
9061 =head1 END PROCESSING - THE C<END> BLOCK
9062
9063 Come here at the very end of processing. We want to go into a
9064 loop where we allow the user to enter commands and interact with the
9065 debugger, but we don't want anything else to execute.
9066
9067 First we set the C<$finished> variable, so that some commands that
9068 shouldn't be run after the end of program quit working.
9069
9070 We then figure out whether we're truly done (as in the user entered a C<q>
9071 command, or we finished execution while running nonstop). If we aren't,
9072 we set C<$single> to 1 (causing the debugger to get control again).
9073
9074 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9075 message and returns control to the debugger. Repeat.
9076
9077 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9078 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9079 break, run to completion.).
9080
9081 =cut
9082
9083 END {
9084     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9085     $fall_off_end = 1 unless $inhibit_exit;
9086
9087     # Do not stop in at_exit() and destructors on exit:
9088     if ($fall_off_end or $runnonstop) {
9089         &save_hist();
9090     } else {
9091         $DB::single = 1;
9092         DB::fake::at_exit();
9093     }
9094 } ## end END
9095
9096 =head1 PRE-5.8 COMMANDS
9097
9098 Some of the commands changed function quite a bit in the 5.8 command
9099 realignment, so much so that the old code had to be replaced completely.
9100 Because we wanted to retain the option of being able to go back to the
9101 former command set, we moved the old code off to this section.
9102
9103 There's an awful lot of duplicated code here. We've duplicated the
9104 comments to keep things clear.
9105
9106 =head2 Null command
9107
9108 Does nothing. Used to I<turn off> commands.
9109
9110 =cut
9111
9112 sub cmd_pre580_null {
9113
9114     # do nothing...
9115 }
9116
9117 =head2 Old C<a> command.
9118
9119 This version added actions if you supplied them, and deleted them
9120 if you didn't.
9121
9122 =cut
9123
9124 sub cmd_pre580_a {
9125     my $xcmd = shift;
9126     my $cmd  = shift;
9127
9128     # Argument supplied. Add the action.
9129     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9130
9131         # If the line isn't there, use the current line.
9132         $i = $1 || $line;
9133         $j = $2;
9134
9135         # If there is an action ...
9136         if ( length $j ) {
9137
9138             # ... but the line isn't breakable, skip it.
9139             if ( $dbline[$i] == 0 ) {
9140                 print $OUT "Line $i may not have an action.\n";
9141             }
9142             else {
9143
9144                 # ... and the line is breakable:
9145                 # Mark that there's an action in this file.
9146                 $had_breakpoints{$filename} |= 2;
9147
9148                 # Delete any current action.
9149                 $dbline{$i} =~ s/\0[^\0]*//;
9150
9151                 # Add the new action, continuing the line as needed.
9152                 $dbline{$i} .= "\0" . action($j);
9153             }
9154         } ## end if (length $j)
9155
9156         # No action supplied.
9157         else {
9158
9159             # Delete the action.
9160             $dbline{$i} =~ s/\0[^\0]*//;
9161
9162             # Mark as having no break or action if nothing's left.
9163             delete $dbline{$i} if $dbline{$i} eq '';
9164         }
9165     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9166 } ## end sub cmd_pre580_a
9167
9168 =head2 Old C<b> command
9169
9170 Add breakpoints.
9171
9172 =cut
9173
9174 sub cmd_pre580_b {
9175     my $xcmd   = shift;
9176     my $cmd    = shift;
9177     my $dbline = shift;
9178
9179     # Break on load.
9180     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9181         my $file = $1;
9182         $file =~ s/\s+$//;
9183         &cmd_b_load($file);
9184     }
9185
9186     # b compile|postpone <some sub> [<condition>]
9187     # The interpreter actually traps this one for us; we just put the
9188     # necessary condition in the %postponed hash.
9189     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9190
9191         # Capture the condition if there is one. Make it true if none.
9192         my $cond = length $3 ? $3 : '1';
9193
9194         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9195         # if it was 'compile'.
9196         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9197
9198         # De-Perl4-ify the name - ' separators to ::.
9199         $subname =~ s/\'/::/g;
9200
9201         # Qualify it into the current package unless it's already qualified.
9202         $subname = "${'package'}::" . $subname
9203           unless $subname =~ /::/;
9204
9205         # Add main if it starts with ::.
9206         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9207
9208         # Save the break type for this sub.
9209         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9210     } ## end elsif ($cmd =~ ...
9211
9212     # b <sub name> [<condition>]
9213     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9214         my $subname = $1;
9215         my $cond = length $2 ? $2 : '1';
9216         &cmd_b_sub( $subname, $cond );
9217     }
9218
9219     # b <line> [<condition>].
9220     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9221         my $i = $1 || $dbline;
9222         my $cond = length $2 ? $2 : '1';
9223         &cmd_b_line( $i, $cond );
9224     }
9225 } ## end sub cmd_pre580_b
9226
9227 =head2 Old C<D> command.
9228
9229 Delete all breakpoints unconditionally.
9230
9231 =cut
9232
9233 sub cmd_pre580_D {
9234     my $xcmd = shift;
9235     my $cmd  = shift;
9236     if ( $cmd =~ /^\s*$/ ) {
9237         print $OUT "Deleting all breakpoints...\n";
9238
9239         # %had_breakpoints lists every file that had at least one
9240         # breakpoint in it.
9241         my $file;
9242         for $file ( keys %had_breakpoints ) {
9243
9244             # Switch to the desired file temporarily.
9245             local *dbline = $main::{ '_<' . $file };
9246
9247             my $max = $#dbline;
9248             my $was;
9249
9250             # For all lines in this file ...
9251             for ( $i = 1 ; $i <= $max ; $i++ ) {
9252
9253                 # If there's a breakpoint or action on this line ...
9254                 if ( defined $dbline{$i} ) {
9255
9256                     # ... remove the breakpoint.
9257                     $dbline{$i} =~ s/^[^\0]+//;
9258                     if ( $dbline{$i} =~ s/^\0?$// ) {
9259
9260                         # Remove the entry altogether if no action is there.
9261                         delete $dbline{$i};
9262                     }
9263                 } ## end if (defined $dbline{$i...
9264             } ## end for ($i = 1 ; $i <= $max...
9265
9266             # If, after we turn off the "there were breakpoints in this file"
9267             # bit, the entry in %had_breakpoints for this file is zero,
9268             # we should remove this file from the hash.
9269             if ( not $had_breakpoints{$file} &= ~1 ) {
9270                 delete $had_breakpoints{$file};
9271             }
9272         } ## end for $file (keys %had_breakpoints)
9273
9274         # Kill off all the other breakpoints that are waiting for files that
9275         # haven't been loaded yet.
9276         undef %postponed;
9277         undef %postponed_file;
9278         undef %break_on_load;
9279     } ## end if ($cmd =~ /^\s*$/)
9280 } ## end sub cmd_pre580_D
9281
9282 =head2 Old C<h> command
9283
9284 Print help. Defaults to printing the long-form help; the 5.8 version
9285 prints the summary by default.
9286
9287 =cut
9288
9289 sub cmd_pre580_h {
9290     my $xcmd = shift;
9291     my $cmd  = shift;
9292
9293     # Print the *right* help, long format.
9294     if ( $cmd =~ /^\s*$/ ) {
9295         print_help($pre580_help);
9296     }
9297
9298     # 'h h' - explicitly-requested summary.
9299     elsif ( $cmd =~ /^h\s*/ ) {
9300         print_help($pre580_summary);
9301     }
9302
9303     # Find and print a command's help.
9304     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9305         my $asked  = $1;                   # for proper errmsg
9306         my $qasked = quotemeta($asked);    # for searching
9307                                            # XXX: finds CR but not <CR>
9308         if (
9309             $pre580_help =~ /^
9310                               <?           # Optional '<'
9311                               (?:[IB]<)    # Optional markup
9312                               $qasked      # The command name
9313                             /mx
9314           )
9315         {
9316
9317             while (
9318                 $pre580_help =~ /^
9319                                   (             # The command help:
9320                                    <?           # Optional '<'
9321                                    (?:[IB]<)    # Optional markup
9322                                    $qasked      # The command name
9323                                    ([\s\S]*?)   # Lines starting with tabs
9324                                    \n           # Final newline
9325                                   )
9326                                   (?!\s)/mgx
9327               )    # Line not starting with space
9328                    # (Next command's help)
9329             {
9330                 print_help($1);
9331             }
9332         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9333
9334         # Help not found.
9335         else {
9336             print_help("B<$asked> is not a debugger command.\n");
9337         }
9338     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9339 } ## end sub cmd_pre580_h
9340
9341 =head2 Old C<W> command
9342
9343 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9344
9345 =cut
9346
9347 sub cmd_pre580_W {
9348     my $xcmd = shift;
9349     my $cmd  = shift;
9350
9351     # Delete all watch expressions.
9352     if ( $cmd =~ /^$/ ) {
9353
9354         # No watching is going on.
9355         $trace &= ~2;
9356
9357         # Kill all the watch expressions and values.
9358         @to_watch = @old_watch = ();
9359     }
9360
9361     # Add a watch expression.
9362     elsif ( $cmd =~ /^(.*)/s ) {
9363
9364         # add it to the list to be watched.
9365         push @to_watch, $1;
9366
9367         # Get the current value of the expression.
9368         # Doesn't handle expressions returning list values!
9369         $evalarg = $1;
9370         my ($val) = &eval;
9371         $val = ( defined $val ) ? "'$val'" : 'undef';
9372
9373         # Save it.
9374         push @old_watch, $val;
9375
9376         # We're watching stuff.
9377         $trace |= 2;
9378
9379     } ## end elsif ($cmd =~ /^(.*)/s)
9380 } ## end sub cmd_pre580_W
9381
9382 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9383
9384 The debugger used to have a bunch of nearly-identical code to handle
9385 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9386 C<cmd_prepost> unify all this into one set of code to handle the
9387 appropriate actions.
9388
9389 =head2 C<cmd_pre590_prepost>
9390
9391 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9392 do something destructive. In pre 5.8 debuggers, the default action was to
9393 delete all the actions.
9394
9395 =cut
9396
9397 sub cmd_pre590_prepost {
9398     my $cmd    = shift;
9399     my $line   = shift || '*';
9400     my $dbline = shift;
9401
9402     return &cmd_prepost( $cmd, $line, $dbline );
9403 } ## end sub cmd_pre590_prepost
9404
9405 =head2 C<cmd_prepost>
9406
9407 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9408 Since the lists of actions are all held in arrays that are pointed to by
9409 references anyway, all we have to do is pick the right array reference and
9410 then use generic code to all, delete, or list actions.
9411
9412 =cut
9413
9414 sub cmd_prepost {
9415     my $cmd = shift;
9416
9417     # No action supplied defaults to 'list'.
9418     my $line = shift || '?';
9419
9420     # Figure out what to put in the prompt.
9421     my $which = '';
9422
9423     # Make sure we have some array or another to address later.
9424     # This means that if ssome reason the tests fail, we won't be
9425     # trying to stash actions or delete them from the wrong place.
9426     my $aref = [];
9427
9428     # < - Perl code to run before prompt.
9429     if ( $cmd =~ /^\</o ) {
9430         $which = 'pre-perl';
9431         $aref  = $pre;
9432     }
9433
9434     # > - Perl code to run after prompt.
9435     elsif ( $cmd =~ /^\>/o ) {
9436         $which = 'post-perl';
9437         $aref  = $post;
9438     }
9439
9440     # { - first check for properly-balanced braces.
9441     elsif ( $cmd =~ /^\{/o ) {
9442         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9443             print $OUT
9444 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9445         }
9446
9447         # Properly balanced. Pre-prompt debugger actions.
9448         else {
9449             $which = 'pre-debugger';
9450             $aref  = $pretype;
9451         }
9452     } ## end elsif ( $cmd =~ /^\{/o )
9453
9454     # Did we find something that makes sense?
9455     unless ($which) {
9456         print $OUT "Confused by command: $cmd\n";
9457     }
9458
9459     # Yes.
9460     else {
9461
9462         # List actions.
9463         if ( $line =~ /^\s*\?\s*$/o ) {
9464             unless (@$aref) {
9465
9466                 # Nothing there. Complain.
9467                 print $OUT "No $which actions.\n";
9468             }
9469             else {
9470
9471                 # List the actions in the selected list.
9472                 print $OUT "$which commands:\n";
9473                 foreach my $action (@$aref) {
9474                     print $OUT "\t$cmd -- $action\n";
9475                 }
9476             } ## end else
9477         } ## end if ( $line =~ /^\s*\?\s*$/o)
9478
9479         # Might be a delete.
9480         else {
9481             if ( length($cmd) == 1 ) {
9482                 if ( $line =~ /^\s*\*\s*$/o ) {
9483
9484                     # It's a delete. Get rid of the old actions in the
9485                     # selected list..
9486                     @$aref = ();
9487                     print $OUT "All $cmd actions cleared.\n";
9488                 }
9489                 else {
9490
9491                     # Replace all the actions. (This is a <, >, or {).
9492                     @$aref = action($line);
9493                 }
9494             } ## end if ( length($cmd) == 1)
9495             elsif ( length($cmd) == 2 ) {
9496
9497                 # Add the action to the line. (This is a <<, >>, or {{).
9498                 push @$aref, action($line);
9499             }
9500             else {
9501
9502                 # <<<, >>>>, {{{{{{ ... something not a command.
9503                 print $OUT
9504                   "Confused by strange length of $which command($cmd)...\n";
9505             }
9506         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9507     } ## end else
9508 } ## end sub cmd_prepost
9509
9510 =head1 C<DB::fake>
9511
9512 Contains the C<at_exit> routine that the debugger uses to issue the
9513 C<Debugged program terminated ...> message after the program completes. See
9514 the C<END> block documentation for more details.
9515
9516 =cut
9517
9518 package DB::fake;
9519
9520 sub at_exit {
9521     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9522 }
9523
9524 package DB;    # Do not trace this 1; below!
9525
9526 1;
9527
9528