lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 C<perl5db.pl> - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 i<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it isn't. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have "magical" values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135
 136 =item * First, doing an arithmetical or bitwise operation on a scalar is
 137 just about the fastest thing you can do in Perl: C<use constant> actually
 138 creates a subroutine call, and array hand hash lookups are much slower. Is
 139 this over-optimization at the expense of readability? Possibly, but the
 140 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 141 probably have to benchmark alternate implementations and see which is the
 142 best balance of readability and speed, and then document how it actually
 143 works.
 144
 145 =item * Second, it's very easy to serialize a scalar number. This is done in
 146 the restart code; the debugger state variables are saved in C<%ENV> and then
 147 restored when the debugger is restarted. Having them be just numbers makes
 148 this trivial.
 149
 150 =item * Third, some of these variables are being shared with the Perl core
 151 smack in the middle of the interpreter's execution loop. It's much faster for
 152 a C program (like the interpreter) to check a bit in a scalar than to access
 153 several different variables (or a Perl array).
 154
 155 =back
 156
 157 =head2 What are those C<XXX> comments for?
 158
 159 Any comment containing C<XXX> means that the comment is either somewhat
 160 speculative - it's not exactly clear what a given variable or chunk of
 161 code is doing, or that it is incomplete - the basics may be clear, but the
 162 subtleties are not completely documented.
 163
 164 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 165
 166 =head1 DATA STRUCTURES MAINTAINED BY CORE
 167
 168 There are a number of special data structures provided to the debugger by
 169 the Perl interpreter.
 170
 171 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 172 assignment) contains the text from C<$filename>, with each element
 173 corresponding to a single line of C<$filename>.
 174
 175 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 176 assignment) contains breakpoints and actions.  The keys are line numbers;
 177 you can set individual values, but not the whole hash. The Perl interpreter
 178 uses this hash to determine where breakpoints have been set. Any true value is
 179 considered to be a breakpoint; C<perl5db.pl> uses "$break_condition\0$action".
 180 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 181
 182 The scalar ${'_<'.$filename} contains $filename  XXX What?
 183
 184 =head1 DEBUGGER STARTUP
 185
 186 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 187 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 188 of options. In addition, this file may define a subroutine C<&afterinit>
 189 that will be executed (in the debugger's context) after the debugger has
 190 initialized itself.
 191
 192 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 193 contents as the argument of a debugger <C<o> command.
 194
 195 =head2 STARTUP-ONLY OPTIONS
 196
 197 The following options can only be specified at startup.
 198 To set them in your rcfile, add a call to
 199 C<&parse_options("optionName=new_value")>.
 200
 201 =over 4
 202
 203 =item * TTY
 204
 205 the TTY to use for debugging i/o.
 206
 207 =item * noTTY
 208
 209 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 210 uses the value of noTTY or "/tmp/perldbtty$$" to find TTY using
 211 Term::Rendezvous.  Current variant is to have the name of TTY in this
 212 file.
 213
 214 =item * ReadLine
 215
 216 If false, a dummy  ReadLine is used, so you can debug
 217 ReadLine applications.
 218
 219 =item * NonStop
 220
 221 if true, no i/o is performed until interrupt.
 222
 223 =item * LineInfo
 224
 225 file or pipe to print line number info to.  If it is a
 226 pipe, a short "emacs like" message is used.
 227
 228 =item * RemotePort
 229
 230 host:port to connect to on remote host for remote debugging.
 231
 232 =back
 233
 234 =head3 SAMPLE RCFILE
 235
 236  &parse_options("NonStop=1 LineInfo=db.out");
 237   sub afterinit { $trace = 1; }
 238
 239 The script will run without human intervention, putting trace
 240 information into C<db.out>.  (If you interrupt it, you had better
 241 reset C<LineInfo> to something "interactive"!)
 242
 243 =head1 INTERNALS DESCRIPTION
 244
 245 =head2 DEBUGGER INTERFACE VARIABLES
 246
 247 Perl supplies the values for C<%sub>.  It effectively inserts
 248 a C<&DB'DB();> in front of each place that can have a
 249 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 250 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 251 {require 'perl5db.pl'}> before the first line.
 252
 253 After each C<require>d file is compiled, but before it is executed, a
 254 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 255 is the expanded name of the C<require>d file (as found via C<%INC>).
 256
 257 =head3 IMPORTANT INTERNAL VARIABLES
 258
 259 =head4 C<$CreateTTY>
 260
 261 Used to control when the debugger will attempt to acquire another TTY to be
 262 used for input.
 263
 264 =over
 265
 266 =item * 1 -  on C<fork()>
 267
 268 =item * 2 - debugger is started inside debugger
 269
 270 =item * 4 -  on startup
 271
 272 =back
 273
 274 =head4 C<$doret>
 275
 276 The value -2 indicates that no return value should be printed.
 277 Any other positive value causes C<DB::sub> to print return values.
 278
 279 =head4 C<$evalarg>
 280
 281 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 282 contents of C<@_> when C<DB::eval> is called.
 283
 284 =head4 C<$frame>
 285
 286 Determines what messages (if any) will get printed when a subroutine (or eval)
 287 is entered or exited.
 288
 289 =over 4
 290
 291 =item * 0 -  No enter/exit messages
 292
 293 =item * 1 - Print "entering" messages on subroutine entry
 294
 295 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 296
 297 =item * 4 - Extended messages: C<in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line>>. If no other flag is on, acts like 1+4.
 298
 299 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 300
 301 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 302
 303 =back
 304
 305 To get everything, use C<$frame=30> (or C<o f-30> as a debugger command).
 306 The debugger internally juggles the value of C<$frame> during execution to
 307 protect external modules that the debugger uses from getting traced.
 308
 309 =head4 C<$level>
 310
 311 Tracks current debugger nesting level. Used to figure out how many
 312 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 313 outputs a prompt. Also used to help determine if the program has finished
 314 during command parsing.
 315
 316 =head4 C<$onetimeDump>
 317
 318 Controls what (if anything) C<DB::eval()> will print after evaluating an
 319 expression.
 320
 321 =over 4
 322
 323 =item * C<undef> - don't print anything
 324
 325 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 326
 327 =item * C<methods> - print the methods callable on the first item returned
 328
 329 =back
 330
 331 =head4 C<$onetimeDumpDepth>
 332
 333 Controls how far down C<dumpvar.pl> will go before printing '...' while
 334 dumping a structure. Numeric. If C<undef>, print all levels.
 335
 336 =head4 C<$signal>
 337
 338 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 339 which is called before every statement, checks this and puts the user into
 340 command mode if it finds C<$signal> set to a true value.
 341
 342 =head4 C<$single>
 343
 344 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 345 each subroutine; popped again at the end of each subroutine.
 346
 347 =over 4
 348
 349 =item * 0 - run continuously.
 350
 351 =item * 1 - single-step, go into subs. The 's' command.
 352
 353 =item * 2 - single-step, don't go into subs. The 'n' command.
 354
 355 =item * 4 - print current sub depth (turned on to force this when "too much
 356 recursion" occurs.
 357
 358 =back
 359
 360 =head4 C<$trace>
 361
 362 Controls the output of trace information.
 363
 364 =over 4
 365
 366 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 367
 368 =item * 2 - watch expressions are active
 369
 370 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 371
 372 =back
 373
 374 =head4 C<$slave_editor>
 375
 376 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 377
 378 =head4 C<@cmdfhs>
 379
 380 Stack of filehandles that C<DB::readline()> will read commands from.
 381 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 382
 383 =head4 C<@dbline>
 384
 385 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 386 supplied by the Perl interpreter to the debugger. Contains the source.
 387
 388 =head4 C<@old_watch>
 389
 390 Previous values of watch expressions. First set when the expression is
 391 entered; reset whenever the watch expression changes.
 392
 393 =head4 C<@saved>
 394
 395 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 396 so that the debugger can substitute safe values while it's running, and
 397 restore them when it returns control.
 398
 399 =head4 C<@stack>
 400
 401 Saves the current value of C<$single> on entry to a subroutine.
 402 Manipulated by the C<c> command to turn off tracing in all subs above the
 403 current one.
 404
 405 =head4 C<@to_watch>
 406
 407 The 'watch' expressions: to be evaluated before each line is executed.
 408
 409 =head4 C<@typeahead>
 410
 411 The typeahead buffer, used by C<DB::readline>.
 412
 413 =head4 C<%alias>
 414
 415 Command aliases. Stored as character strings to be substituted for a command
 416 entered.
 417
 418 =head4 C<%break_on_load>
 419
 420 Keys are file names, values are 1 (break when this file is loaded) or undef
 421 (don't break when it is loaded).
 422
 423 =head4 C<%dbline>
 424
 425 Keys are line numbers, values are "condition\0action". If used in numeric
 426 context, values are 0 if not breakable, 1 if breakable, no matter what is
 427 in the actual hash entry.
 428
 429 =head4 C<%had_breakpoints>
 430
 431 Keys are file names; values are bitfields:
 432
 433 =over 4
 434
 435 =item * 1 - file has a breakpoint in it.
 436
 437 =item * 2 - file has an action in it.
 438
 439 =back
 440
 441 A zero or undefined value means this file has neither.
 442
 443 =head4 C<%option>
 444
 445 Stores the debugger options. These are character string values.
 446
 447 =head4 C<%postponed>
 448
 449 Saves breakpoints for code that hasn't been compiled yet.
 450 Keys are subroutine names, values are:
 451
 452 =over 4
 453
 454 =item * 'compile' - break when this sub is compiled
 455
 456 =item * 'break +0 if <condition>' - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 457
 458 =back
 459
 460 =head4 C<%postponed_file>
 461
 462 This hash keeps track of breakpoints that need to be set for files that have
 463 not yet been compiled. Keys are filenames; values are references to hashes.
 464 Each of these hashes is keyed by line number, and its values are breakpoint
 465 definitions ("condition\0action").
 466
 467 =head1 DEBUGGER INITIALIZATION
 468
 469 The debugger's initialization actually jumps all over the place inside this
 470 package. This is because there are several BEGIN blocks (which of course
 471 execute immediately) spread through the code. Why is that?
 472
 473 The debugger needs to be able to change some things and set some things up
 474 before the debugger code is compiled; most notably, the C<$deep> variable that
 475 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 476 debugger has to turn off warnings while the debugger code is compiled, but then
 477 restore them to their original setting before the program being debugged begins
 478 executing.
 479
 480 The first C<BEGIN> block simply turns off warnings by saving the current
 481 setting of C<$^W> and then setting it to zero. The second one initializes
 482 the debugger variables that are needed before the debugger begins executing.
 483 The third one puts C<$^X> back to its former value.
 484
 485 We'll detail the second C<BEGIN> block later; just remember that if you need
 486 to initialize something before the debugger starts really executing, that's
 487 where it has to go.
 488
 489 =cut
 490
 491 package DB;
 492
 493 use IO::Handle;
 494
 495 # Debugger for Perl 5.00x; perl5db.pl patch level:
 496 $VERSION = 1.27;
 497
 498 $header = "perl5db.pl version $VERSION";
 499
 500 =head1 DEBUGGER ROUTINES
 501
 502 =head2 C<DB::eval()>
 503
 504 This function replaces straight C<eval()> inside the debugger; it simplifies
 505 the process of evaluating code in the user's context.
 506
 507 The code to be evaluated is passed via the package global variable
 508 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 509
 510 We preserve the current settings of X<C<$trace>>, X<C<$single>>, and X<C<$^D>>;
 511 add the X<C<$usercontext>> (that's the preserved values of C<$@>, C<$!>,
 512 C<$^E>, C<$,>, C<$/>, C<$\>, and C<$^W>, grabbed when C<DB::DB> got control,
 513 and the user's current package) and a add a newline before we do the C<eval()>.
 514 This causes the proper context to be used when the eval is actually done.
 515 Afterward, we restore C<$trace>, C<$single>, and C<$^D>.
 516
 517 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 518 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 519 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 520 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 521 considered sane by the debugger. If there was an C<eval()> error, we print
 522 it on the debugger's output. If X<C<$onetimedump>> is defined, we call
 523 X<C<dumpit>> if it's set to 'dump', or X<C<methods>> if it's set to
 524 'methods'. Setting it to something else causes the debugger to do the eval
 525 but not print the result - handy if you want to do something else with it
 526 (the "watch expressions" code does this to get the value of the watch
 527 expression but not show it unless it matters).
 528
 529 In any case, we then return the list of output from C<eval> to the caller,
 530 and unwinding restores the former version of C<$@> in C<@saved> as well
 531 (the localization of C<$saved[0]> goes away at the end of this scope).
 532
 533 =head3 Parameters and variables influencing execution of DB::eval()
 534
 535 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 536 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 537 The variables listed below influence C<DB::eval()>'s execution directly.
 538
 539 =over 4
 540
 541 =item C<$evalarg> - the thing to actually be eval'ed
 542
 543 =item C<$trace> - Current state of execution tracing (see X<$trace>)
 544
 545 =item C<$single> - Current state of single-stepping (see X<$single>)
 546
 547 =item C<$onetimeDump> - what is to be displayed after the evaluation
 548
 549 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 550
 551 =back
 552
 553 The following variables are altered by C<DB::eval()> during its execution. They
 554 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 555
 556 =over 4
 557
 558 =item C<@res> - used to capture output from actual C<eval>.
 559
 560 =item C<$otrace> - saved value of C<$trace>.
 561
 562 =item C<$osingle> - saved value of C<$single>.
 563
 564 =item C<$od> - saved value of C<$^D>.
 565
 566 =item C<$saved[0]> - saved value of C<$@>.
 567
 568 =item $\ - for output of C<$@> if there is an evaluation error.
 569
 570 =back
 571
 572 =head3 The problem of lexicals
 573
 574 The context of C<DB::eval()> presents us with some problems. Obviously,
 575 we want to be 'sandboxed' away from the debugger's internals when we do
 576 the eval, but we need some way to control how punctuation variables and
 577 debugger globals are used.
 578
 579 We can't use local, because the code inside C<DB::eval> can see localized
 580 variables; and we can't use C<my> either for the same reason. The code
 581 in this routine compromises and uses C<my>.
 582
 583 After this routine is over, we don't have user code executing in the debugger's
 584 context, so we can use C<my> freely.
 585
 586 =cut
 587
 588 ############################################## Begin lexical danger zone
 589
 590 # 'my' variables used here could leak into (that is, be visible in)
 591 # the context that the code being evaluated is executing in. This means that
 592 # the code could modify the debugger's variables.
 593 #
 594 # Fiddling with the debugger's context could be Bad. We insulate things as
 595 # much as we can.
 596
 597 sub eval {
 598
 599     # 'my' would make it visible from user code
 600     #    but so does local! --tchrist
 601     # Remember: this localizes @DB::res, not @main::res.
 602     local @res;
 603     {
 604
 605         # Try to keep the user code from messing  with us. Save these so that
 606         # even if the eval'ed code changes them, we can put them back again.
 607         # Needed because the user could refer directly to the debugger's
 608         # package globals (and any 'my' variables in this containing scope)
 609         # inside the eval(), and we want to try to stay safe.
 610         local $otrace  = $trace;
 611         local $osingle = $single;
 612         local $od      = $^D;
 613
 614         # Untaint the incoming eval() argument.
 615         { ($evalarg) = $evalarg =~ /(.*)/s; }
 616
 617         # $usercontext built in DB::DB near the comment
 618         # "set up the context for DB::eval ..."
 619         # Evaluate and save any results.
 620         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 621
 622         # Restore those old values.
 623         $trace  = $otrace;
 624         $single = $osingle;
 625         $^D     = $od;
 626     }
 627
 628     # Save the current value of $@, and preserve it in the debugger's copy
 629     # of the saved precious globals.
 630     my $at = $@;
 631
 632     # Since we're only saving $@, we only have to localize the array element
 633     # that it will be stored in.
 634     local $saved[0];    # Preserve the old value of $@
 635     eval { &DB::save };
 636
 637     # Now see whether we need to report an error back to the user.
 638     if ($at) {
 639         local $\ = '';
 640         print $OUT $at;
 641     }
 642
 643     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 644     # are package globals.
 645     elsif ($onetimeDump) {
 646         if ( $onetimeDump eq 'dump' ) {
 647             local $option{dumpDepth} = $onetimedumpDepth
 648               if defined $onetimedumpDepth;
 649             dumpit( $OUT, \@res );
 650         }
 651         elsif ( $onetimeDump eq 'methods' ) {
 652             methods( $res[0] );
 653         }
 654     } ## end elsif ($onetimeDump)
 655     @res;
 656 } ## end sub eval
 657
 658 ############################################## End lexical danger zone
 659
 660 # After this point it is safe to introduce lexicals.
 661 # The code being debugged will be executing in its own context, and
 662 # can't see the inside of the debugger.
 663 #
 664 # However, one should not overdo it: leave as much control from outside as
 665 # possible. If you make something a lexical, it's not going to be addressable
 666 # from outside the debugger even if you know its name.
 667
 668 # This file is automatically included if you do perl -d.
 669 # It's probably not useful to include this yourself.
 670 #
 671 # Before venturing further into these twisty passages, it is
 672 # wise to read the perldebguts man page or risk the ire of dragons.
 673 #
 674 # (It should be noted that perldebguts will tell you a lot about
 675 # the underlying mechanics of how the debugger interfaces into the
 676 # Perl interpreter, but not a lot about the debugger itself. The new
 677 # comments in this code try to address this problem.)
 678
 679 # Note that no subroutine call is possible until &DB::sub is defined
 680 # (for subroutines defined outside of the package DB). In fact the same is
 681 # true if $deep is not defined.
 682 #
 683 # $Log: perldb.pl,v $
 684
 685 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 686
 687 # modified Perl debugger, to be run from Emacs in perldb-mode
 688 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 689 # Johan Vromans -- upgrade to 4.0 pl 10
 690 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 691
 692 # (We have made efforts to  clarify the comments in the change log
 693 # in other places; some of them may seem somewhat obscure as they
 694 # were originally written, and explaining them away from the code
 695 # in question seems conterproductive.. -JM)
 696
 697 ########################################################################
 698 # Changes: 0.94
 699 #   + A lot of things changed after 0.94. First of all, core now informs
 700 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 701 #     BEGIN and END. Handy with `O f=2'.
 702 #   + This can make debugger a little bit too verbose, please be patient
 703 #     and report your problems promptly.
 704 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 705 #   + Note that if DESTROY returns a reference to the object (or object),
 706 #     the deletion of data may be postponed until the next function call,
 707 #     due to the need to examine the return value.
 708 #
 709 # Changes: 0.95
 710 #   + `v' command shows versions.
 711 #
 712 # Changes: 0.96
 713 #   + `v' command shows version of readline.
 714 #     primitive completion works (dynamic variables, subs for `b' and `l',
 715 #     options). Can `p %var'
 716 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 717 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 718 #   + `c sub' documented.
 719 #   + At last enough magic combined to stop after the end of debuggee.
 720 #   + !! should work now (thanks to Emacs bracket matching an extra
 721 #     `]' in a regexp is caught).
 722 #   + `L', `D' and `A' span files now (as documented).
 723 #   + Breakpoints in `require'd code are possible (used in `R').
 724 #   +  Some additional words on internal work of debugger.
 725 #   + `b load filename' implemented.
 726 #   + `b postpone subr' implemented.
 727 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 728 #   + When restarting debugger breakpoints/actions persist.
 729 #   + Buglet: When restarting debugger only one breakpoint/action per
 730 #             autoloaded function persists.
 731 #
 732 # Changes: 0.97: NonStop will not stop in at_exit().
 733 #   + Option AutoTrace implemented.
 734 #   + Trace printed differently if frames are printed too.
 735 #   + new `inhibitExit' option.
 736 #   + printing of a very long statement interruptible.
 737 # Changes: 0.98: New command `m' for printing possible methods
 738 #   + 'l -' is a synonym for `-'.
 739 #   + Cosmetic bugs in printing stack trace.
 740 #   +  `frame' & 8 to print "expanded args" in stack trace.
 741 #   + Can list/break in imported subs.
 742 #   + new `maxTraceLen' option.
 743 #   + frame & 4 and frame & 8 granted.
 744 #   + new command `m'
 745 #   + nonstoppable lines do not have `:' near the line number.
 746 #   + `b compile subname' implemented.
 747 #   + Will not use $` any more.
 748 #   + `-' behaves sane now.
 749 # Changes: 0.99: Completion for `f', `m'.
 750 #   +  `m' will remove duplicate names instead of duplicate functions.
 751 #   + `b load' strips trailing whitespace.
 752 #     completion ignores leading `|'; takes into account current package
 753 #     when completing a subroutine name (same for `l').
 754 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 755 #   BUG FIXES:
 756 #   + Added bare minimal security checks on perldb rc files, plus
 757 #     comments on what else is needed.
 758 #   + Fixed the ornaments that made "|h" completely unusable.
 759 #     They are not used in print_help if they will hurt.  Strip pod
 760 #     if we're paging to less.
 761 #   + Fixed mis-formatting of help messages caused by ornaments
 762 #     to restore Larry's original formatting.
 763 #   + Fixed many other formatting errors.  The code is still suboptimal,
 764 #     and needs a lot of work at restructuring.  It's also misindented
 765 #     in many places.
 766 #   + Fixed bug where trying to look at an option like your pager
 767 #     shows "1".
 768 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 769 #     lose.  You should consider shell escapes not using their shell,
 770 #     or else not caring about detailed status.  This should really be
 771 #     unified into one place, too.
 772 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 773 #     tricking Perl into thinking you weren't calling a debugger command!
 774 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 775 #     suggests a leading semicolon or any other irrelevant non-whitespace
 776 #     to indicate literal Perl code.)
 777 #   + Fixed bugs that ate warnings due to wrong selected handle.
 778 #   + Fixed a precedence bug on signal stuff.
 779 #   + Fixed some unseemly wording.
 780 #   + Fixed bug in help command trying to call perl method code.
 781 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 782 #   ENHANCEMENTS:
 783 #   + Added some comments.  This code is still nasty spaghetti.
 784 #   + Added message if you clear your pre/post command stacks which was
 785 #     very easy to do if you just typed a bare >, <, or {.  (A command
 786 #     without an argument should *never* be a destructive action; this
 787 #     API is fundamentally screwed up; likewise option setting, which
 788 #     is equally buggered.)
 789 #   + Added command stack dump on argument of "?" for >, <, or {.
 790 #   + Added a semi-built-in doc viewer command that calls man with the
 791 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 792 #     or else perldoc on obstreperous platforms.
 793 #   + Added to and rearranged the help information.
 794 #   + Detected apparent misuse of { ... } to declare a block; this used
 795 #     to work but now is a command, and mysteriously gave no complaint.
 796 #
 797 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 798 #   BUG FIX:
 799 #   + This patch to perl5db.pl cleans up formatting issues on the help
 800 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 801 #     issues, plus converted the printed text to use all spaces, since
 802 #     tabs don't seem to help much here.
 803 #
 804 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 805 #   Minor bugs corrected;
 806 #   + Support for auto-creation of new TTY window on startup, either
 807 #     unconditionally, or if started as a kid of another debugger session;
 808 #   + New `O'ption CreateTTY
 809 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 810 #                         1: on fork()
 811 #                         2: debugger is started inside debugger
 812 #                         4: on startup
 813 #   + Code to auto-create a new TTY window on OS/2 (currently one
 814 #     extra window per session - need named pipes to have more...);
 815 #   + Simplified interface for custom createTTY functions (with a backward
 816 #     compatibility hack); now returns the TTY name to use; return of ''
 817 #     means that the function reset the I/O handles itself;
 818 #   + Better message on the semantic of custom createTTY function;
 819 #   + Convert the existing code to create a TTY into a custom createTTY
 820 #     function;
 821 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 822 #   + Switch line-tracing output too to the created TTY window;
 823 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 824 #   + High-level debugger API cmd_*():
 825 #      cmd_b_load($filenamepart)            # b load filenamepart
 826 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 827 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 828 #      cmd_stop()                           # Control-C
 829 #      cmd_d($lineno)                       # d lineno (B)
 830 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 831 #      the error message to the debugging output.
 832 #   + Low-level debugger API
 833 #      break_on_load($filename)             # b load filename
 834 #      @files = report_break_on_load()      # List files with load-breakpoints
 835 #      breakable_line_in_filename($name, $from [, $to])
 836 #                                           # First breakable line in the
 837 #                                           # range $from .. $to.  $to defaults
 838 #                                           # to $from, and may be less than
 839 #                                           # $to
 840 #      breakable_line($from [, $to])        # Same for the current file
 841 #      break_on_filename_line($name, $lineno [, $cond])
 842 #                                           # Set breakpoint,$cond defaults to
 843 #                                           # 1
 844 #      break_on_filename_line_range($name, $from, $to [, $cond])
 845 #                                           # As above, on the first
 846 #                                           # breakable line in range
 847 #      break_on_line($lineno [, $cond])     # As above, in the current file
 848 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 849 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 850 #                                           # The range of lines of the text
 851 #      The low-level API returns TRUE on success, and die()s on failure.
 852 #
 853 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 854 #   BUG FIXES:
 855 #   + Fixed warnings generated by "perl -dWe 42"
 856 #   + Corrected spelling errors
 857 #   + Squeezed Help (h) output into 80 columns
 858 #
 859 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 860 #   + Made "x @INC" work like it used to
 861 #
 862 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 863 #   + Fixed warnings generated by "O" (Show debugger options)
 864 #   + Fixed warnings generated by "p 42" (Print expression)
 865 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 866 #   + Added windowSize option
 867 # Changes: 1.14: Oct  9, 2001 multiple
 868 #   + Clean up after itself on VMS (Charles Lane in 12385)
 869 #   + Adding "@ file" syntax (Peter Scott in 12014)
 870 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 871 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 872 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 873 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 874 #   + Updated 1.14 change log
 875 #   + Added *dbline explainatory comments
 876 #   + Mentioning perldebguts man page
 877 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 878 #   + $onetimeDump improvements
 879 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 880 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 881 #   rationalised the following commands and added cmd_wrapper() to
 882 #   enable switching between old and frighteningly consistent new
 883 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 884 #     a(add),       A(del)            # action expr   (added del by line)
 885 #   + b(add),       B(del)            # break  [line] (was b,D)
 886 #   + w(add),       W(del)            # watch  expr   (was W,W)
 887 #                                     # added del by expr
 888 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 889 #   + m(methods),   M(modules)        # ...           (was m,v)
 890 #   + o(option)                       # lc            (was O)
 891 #   + v(view code), V(view Variables) # ...           (was w,V)
 892 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 893 #   + fixed missing cmd_O bug
 894 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 895 #   + Added missing local()s -- DB::DB is called recursively.
 896 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 897 #   + pre'n'post commands no longer trashed with no args
 898 #   + watch val joined out of eval()
 899 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 900 #   + Added comments and reformatted source. No bug fixes/enhancements.
 901 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 902 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 903 #   + Flush stdout/stderr before the debugger prompt is printed.
 904 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 905 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 906 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 907 #   + Added command to save all debugger commands for sourcing later.
 908 #   + Added command to display parent inheritence tree of given class.
 909 #   + Fixed minor newline in history bug.
 910 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 911 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 912 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 913 #   + unfork the 5.8.x and 5.9.x debuggers.
 914 #   + whitespace and assertions call cleanup across versions
 915 #   + H * deletes (resets) history
 916 #   + i now handles Class + blessed objects
 917 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 918 #   + updated pod page references - clunky.
 919 #   + removed windowid restriction for forking into an xterm.
 920 #   + more whitespace again.
 921 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 922 ####################################################################
 923
 924 =head1 DEBUGGER INITIALIZATION
 925
 926 The debugger starts up in phases.
 927
 928 =head2 BASIC SETUP
 929
 930 First, it initializes the environment it wants to run in: turning off
 931 warnings during its own compilation, defining variables which it will need
 932 to avoid warnings later, setting itself up to not exit when the program
 933 terminates, and defaulting to printing return values for the C<r> command.
 934
 935 =cut
 936
 937 # Needed for the statement after exec():
 938 #
 939 # This BEGIN block is simply used to switch off warnings during debugger
 940 # compiliation. Probably it would be better practice to fix the warnings,
 941 # but this is how it's done at the moment.
 942
 943 BEGIN {
 944     $ini_warn = $^W;
 945     $^W       = 0;
 946 }    # Switch compilation warnings off until another BEGIN.
 947
 948 # test if assertions are supported and actived:
 949 BEGIN {
 950     $ini_assertion = eval "sub asserting_test : assertion {1}; 1";
 951
 952     # $ini_assertion = undef => assertions unsupported,
 953     #        "       = 1     => assertions supported
 954     # print "\$ini_assertion=$ini_assertion\n";
 955 }
 956
 957 local ($^W) = 0;    # Switch run-time warnings off during init.
 958
 959 # This would probably be better done with "use vars", but that wasn't around
 960 # when this code was originally written. (Neither was "use strict".) And on
 961 # the principle of not fiddling with something that was working, this was
 962 # left alone.
 963 warn(               # Do not ;-)
 964                     # These variables control the execution of 'dumpvar.pl'.
 965     $dumpvar::hashDepth,
 966     $dumpvar::arrayDepth,
 967     $dumpvar::dumpDBFiles,
 968     $dumpvar::dumpPackages,
 969     $dumpvar::quoteHighBit,
 970     $dumpvar::printUndef,
 971     $dumpvar::globPrint,
 972     $dumpvar::usageOnly,
 973
 974     # used to save @ARGV and extract any debugger-related flags.
 975     @ARGS,
 976
 977     # used to control die() reporting in diesignal()
 978     $Carp::CarpLevel,
 979
 980     # used to prevent multiple entries to diesignal()
 981     # (if for instance diesignal() itself dies)
 982     $panic,
 983
 984     # used to prevent the debugger from running nonstop
 985     # after a restart
 986     $second_time,
 987   )
 988   if 0;
 989
 990 # Command-line + PERLLIB:
 991 # Save the contents of @INC before they are modified elsewhere.
 992 @ini_INC = @INC;
 993
 994 # This was an attempt to clear out the previous values of various
 995 # trapped errors. Apparently it didn't help. XXX More info needed!
 996 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 997
 998 # We set these variables to safe values. We don't want to blindly turn
 999 # off warnings, because other packages may still want them.
1000 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1001                                    # (local $^W cannot help - other packages!).
1002
1003 # Default to not exiting when program finishes; print the return
1004 # value when the 'r' command is used to return from a subroutine.
1005 $inhibit_exit = $option{PrintRet} = 1;
1006
1007 =head1 OPTION PROCESSING
1008
1009 The debugger's options are actually spread out over the debugger itself and
1010 C<dumpvar.pl>; some of these are variables to be set, while others are
1011 subs to be called with a value. To try to make this a little easier to
1012 manage, the debugger uses a few data structures to define what options
1013 are legal and how they are to be processed.
1014
1015 First, the C<@options> array defines the I<names> of all the options that
1016 are to be accepted.
1017
1018 =cut
1019
1020 @options = qw(
1021   CommandSet
1022   hashDepth    arrayDepth    dumpDepth
1023   DumpDBFiles  DumpPackages  DumpReused
1024   compactDump  veryCompact   quote
1025   HighBit      undefPrint    globPrint
1026   PrintRet     UsageOnly     frame
1027   AutoTrace    TTY           noTTY
1028   ReadLine     NonStop       LineInfo
1029   maxTraceLen  recallCommand ShellBang
1030   pager        tkRunning     ornaments
1031   signalLevel  warnLevel     dieLevel
1032   inhibit_exit ImmediateStop bareStringify
1033   CreateTTY    RemotePort    windowSize
1034   DollarCaretP OnlyAssertions WarnAssertions
1035 );
1036
1037 @RememberOnROptions = qw(DollarCaretP OnlyAssertions);
1038
1039 =pod
1040
1041 Second, C<optionVars> lists the variables that each option uses to save its
1042 state.
1043
1044 =cut
1045
1046 %optionVars = (
1047     hashDepth     => \$dumpvar::hashDepth,
1048     arrayDepth    => \$dumpvar::arrayDepth,
1049     CommandSet    => \$CommandSet,
1050     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1051     DumpPackages  => \$dumpvar::dumpPackages,
1052     DumpReused    => \$dumpvar::dumpReused,
1053     HighBit       => \$dumpvar::quoteHighBit,
1054     undefPrint    => \$dumpvar::printUndef,
1055     globPrint     => \$dumpvar::globPrint,
1056     UsageOnly     => \$dumpvar::usageOnly,
1057     CreateTTY     => \$CreateTTY,
1058     bareStringify => \$dumpvar::bareStringify,
1059     frame         => \$frame,
1060     AutoTrace     => \$trace,
1061     inhibit_exit  => \$inhibit_exit,
1062     maxTraceLen   => \$maxtrace,
1063     ImmediateStop => \$ImmediateStop,
1064     RemotePort    => \$remoteport,
1065     windowSize    => \$window,
1066     WarnAssertions => \$warnassertions,
1067 );
1068
1069 =pod
1070
1071 Third, C<%optionAction> defines the subroutine to be called to process each
1072 option.
1073
1074 =cut
1075
1076 %optionAction = (
1077     compactDump   => \&dumpvar::compactDump,
1078     veryCompact   => \&dumpvar::veryCompact,
1079     quote         => \&dumpvar::quote,
1080     TTY           => \&TTY,
1081     noTTY         => \&noTTY,
1082     ReadLine      => \&ReadLine,
1083     NonStop       => \&NonStop,
1084     LineInfo      => \&LineInfo,
1085     recallCommand => \&recallCommand,
1086     ShellBang     => \&shellBang,
1087     pager         => \&pager,
1088     signalLevel   => \&signalLevel,
1089     warnLevel     => \&warnLevel,
1090     dieLevel      => \&dieLevel,
1091     tkRunning     => \&tkRunning,
1092     ornaments     => \&ornaments,
1093     RemotePort    => \&RemotePort,
1094     DollarCaretP  => \&DollarCaretP,
1095     OnlyAssertions=> \&OnlyAssertions,
1096 );
1097
1098 =pod
1099
1100 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1101 option is used.
1102
1103 =cut
1104
1105 # Note that this list is not complete: several options not listed here
1106 # actually require that dumpvar.pl be loaded for them to work, but are
1107 # not in the table. A subsequent patch will correct this problem; for
1108 # the moment, we're just recommenting, and we are NOT going to change
1109 # function.
1110 %optionRequire = (
1111     compactDump => 'dumpvar.pl',
1112     veryCompact => 'dumpvar.pl',
1113     quote       => 'dumpvar.pl',
1114 );
1115
1116 =pod
1117
1118 There are a number of initialization-related variables which can be set
1119 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1120 variable. These are:
1121
1122 =over 4
1123
1124 =item C<$rl> - readline control XXX needs more explanation
1125
1126 =item C<$warnLevel> - whether or not debugger takes over warning handling
1127
1128 =item C<$dieLevel> - whether or not debugger takes over die handling
1129
1130 =item C<$signalLevel> - whether or not debugger takes over signal handling
1131
1132 =item C<$pre> - preprompt actions (array reference)
1133
1134 =item C<$post> - postprompt actions (array reference)
1135
1136 =item C<$pretype>
1137
1138 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1139
1140 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1141
1142 =back
1143
1144 =cut
1145
1146 # These guys may be defined in $ENV{PERL5DB} :
1147 $rl          = 1     unless defined $rl;
1148 $warnLevel   = 1     unless defined $warnLevel;
1149 $dieLevel    = 1     unless defined $dieLevel;
1150 $signalLevel = 1     unless defined $signalLevel;
1151 $pre         = []    unless defined $pre;
1152 $post        = []    unless defined $post;
1153 $pretype     = []    unless defined $pretype;
1154 $CreateTTY   = 3     unless defined $CreateTTY;
1155 $CommandSet  = '580' unless defined $CommandSet;
1156
1157 =pod
1158
1159 The default C<die>, C<warn>, and C<signal> handlers are set up.
1160
1161 =cut
1162
1163 warnLevel($warnLevel);
1164 dieLevel($dieLevel);
1165 signalLevel($signalLevel);
1166
1167 =pod
1168
1169 The pager to be used is needed next. We try to get it from the
1170 environment first.  if it's not defined there, we try to find it in
1171 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1172 then call the C<pager()> function to save the pager name.
1173
1174 =cut
1175
1176 # This routine makes sure $pager is set up so that '|' can use it.
1177 pager(
1178
1179     # If PAGER is defined in the environment, use it.
1180     defined $ENV{PAGER}
1181     ? $ENV{PAGER}
1182
1183       # If not, see if Config.pm defines it.
1184     : eval { require Config }
1185       && defined $Config::Config{pager}
1186     ? $Config::Config{pager}
1187
1188       # If not, fall back to 'more'.
1189     : 'more'
1190   )
1191   unless defined $pager;
1192
1193 =pod
1194
1195 We set up the command to be used to access the man pages, the command
1196 recall character ("!" unless otherwise defined) and the shell escape
1197 character ("!" unless otherwise defined). Yes, these do conflict, and
1198 neither works in the debugger at the moment.
1199
1200 =cut
1201
1202 setman();
1203
1204 # Set up defaults for command recall and shell escape (note:
1205 # these currently don't work in linemode debugging).
1206 &recallCommand("!") unless defined $prc;
1207 &shellBang("!")     unless defined $psh;
1208
1209 =pod
1210
1211 We then set up the gigantic string containing the debugger help.
1212 We also set the limit on the number of arguments we'll display during a
1213 trace.
1214
1215 =cut
1216
1217 sethelp();
1218
1219 # If we didn't get a default for the length of eval/stack trace args,
1220 # set it here.
1221 $maxtrace = 400 unless defined $maxtrace;
1222
1223 =head2 SETTING UP THE DEBUGGER GREETING
1224
1225 The debugger 'greeting'  helps to inform the user how many debuggers are
1226 running, and whether the current debugger is the primary or a child.
1227
1228 If we are the primary, we just hang onto our pid so we'll have it when
1229 or if we start a child debugger. If we are a child, we'll set things up
1230 so we'll have a unique greeting and so the parent will give us our own
1231 TTY later.
1232
1233 We save the current contents of the C<PERLDB_PIDS> environment variable
1234 because we mess around with it. We'll also need to hang onto it because
1235 we'll need it if we restart.
1236
1237 Child debuggers make a label out of the current PID structure recorded in
1238 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1239 yet so the parent will give them one later via C<resetterm()>.
1240
1241 =cut
1242
1243 # Save the current contents of the environment; we're about to
1244 # much with it. We'll need this if we have to restart.
1245 $ini_pids = $ENV{PERLDB_PIDS};
1246
1247 if ( defined $ENV{PERLDB_PIDS} ) {
1248
1249     # We're a child. Make us a label out of the current PID structure
1250     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1251     # a term yet so the parent will give us one later via resetterm().
1252     $pids = "[$ENV{PERLDB_PIDS}]";
1253     $ENV{PERLDB_PIDS} .= "->$$";
1254     $term_pid = -1;
1255 } ## end if (defined $ENV{PERLDB_PIDS...
1256 else {
1257
1258     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1259     # child debugger, and mark us as the parent, so we'll know to set up
1260     # more TTY's is we have to.
1261     $ENV{PERLDB_PIDS} = "$$";
1262     $pids             = "{pid=$$}";
1263     $term_pid         = $$;
1264 }
1265
1266 $pidprompt = '';
1267
1268 # Sets up $emacs as a synonym for $slave_editor.
1269 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1270
1271 =head2 READING THE RC FILE
1272
1273 The debugger will read a file of initialization options if supplied. If
1274 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1275
1276 =cut
1277
1278 # As noted, this test really doesn't check accurately that the debugger
1279 # is running at a terminal or not.
1280
1281 if ( -e "/dev/tty" ) {                      # this is the wrong metric!
1282     $rcfile = ".perldb";
1283 }
1284 else {
1285     $rcfile = "perldb.ini";
1286 }
1287
1288 =pod
1289
1290 The debugger does a safety test of the file to be read. It must be owned
1291 either by the current user or root, and must only be writable by the owner.
1292
1293 =cut
1294
1295 # This wraps a safety test around "do" to read and evaluate the init file.
1296 #
1297 # This isn't really safe, because there's a race
1298 # between checking and opening.  The solution is to
1299 # open and fstat the handle, but then you have to read and
1300 # eval the contents.  But then the silly thing gets
1301 # your lexical scope, which is unfortunate at best.
1302 sub safe_do {
1303     my $file = shift;
1304
1305     # Just exactly what part of the word "CORE::" don't you understand?
1306     local $SIG{__WARN__};
1307     local $SIG{__DIE__};
1308
1309     unless ( is_safe_file($file) ) {
1310         CORE::warn <<EO_GRIPE;
1311 perldb: Must not source insecure rcfile $file.
1312         You or the superuser must be the owner, and it must not
1313         be writable by anyone but its owner.
1314 EO_GRIPE
1315         return;
1316     } ## end unless (is_safe_file($file...
1317
1318     do $file;
1319     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1320 } ## end sub safe_do
1321
1322 # This is the safety test itself.
1323 #
1324 # Verifies that owner is either real user or superuser and that no
1325 # one but owner may write to it.  This function is of limited use
1326 # when called on a path instead of upon a handle, because there are
1327 # no guarantees that filename (by dirent) whose file (by ino) is
1328 # eventually accessed is the same as the one tested.
1329 # Assumes that the file's existence is not in doubt.
1330 sub is_safe_file {
1331     my $path = shift;
1332     stat($path) || return;    # mysteriously vaporized
1333     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1334
1335     return 0 if $uid != 0 && $uid != $<;
1336     return 0 if $mode & 022;
1337     return 1;
1338 } ## end sub is_safe_file
1339
1340 # If the rcfile (whichever one we decided was the right one to read)
1341 # exists, we safely do it.
1342 if ( -f $rcfile ) {
1343     safe_do("./$rcfile");
1344 }
1345
1346 # If there isn't one here, try the user's home directory.
1347 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1348     safe_do("$ENV{HOME}/$rcfile");
1349 }
1350
1351 # Else try the login directory.
1352 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1353     safe_do("$ENV{LOGDIR}/$rcfile");
1354 }
1355
1356 # If the PERLDB_OPTS variable has options in it, parse those out next.
1357 if ( defined $ENV{PERLDB_OPTS} ) {
1358     parse_options( $ENV{PERLDB_OPTS} );
1359 }
1360
1361 =pod
1362
1363 The last thing we do during initialization is determine which subroutine is
1364 to be used to obtain a new terminal when a new debugger is started. Right now,
1365 the debugger only handles X Windows and OS/2.
1366
1367 =cut
1368
1369 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1370 # Works if you're running an xterm or xterm-like window, or you're on
1371 # OS/2. This may need some expansion: for instance, this doesn't handle
1372 # OS X Terminal windows.
1373
1374 if (
1375     not defined &get_fork_TTY    # no routine exists,
1376     and defined $ENV{TERM}       # and we know what kind
1377                                  # of terminal this is,
1378     and $ENV{TERM} eq 'xterm'    # and it's an xterm,
1379 #   and defined $ENV{WINDOWID}   # and we know what window this is, <- wrong metric
1380     and defined $ENV{DISPLAY}    # and what display it's on,
1381   )
1382 {
1383     *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1384 } ## end if (not defined &get_fork_TTY...
1385 elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1386     *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1387 }
1388
1389 # untaint $^O, which may have been tainted by the last statement.
1390 # see bug [perl #24674]
1391 $^O =~ m/^(.*)\z/;
1392 $^O = $1;
1393
1394 # Here begin the unreadable code.  It needs fixing.
1395
1396 =head2 RESTART PROCESSING
1397
1398 This section handles the restart command. When the C<R> command is invoked, it
1399 tries to capture all of the state it can into environment variables, and
1400 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1401 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1402 the R command stuffed into the environment variables.
1403
1404   PERLDB_RESTART   - flag only, contains no restart data itself.
1405   PERLDB_HIST      - command history, if it's available
1406   PERLDB_ON_LOAD   - breakpoints set by the rc file
1407   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1408   PERLDB_VISITED   - files that had breakpoints
1409   PERLDB_FILE_...  - breakpoints for a file
1410   PERLDB_OPT       - active options
1411   PERLDB_INC       - the original @INC
1412   PERLDB_PRETYPE   - preprompt debugger actions
1413   PERLDB_PRE       - preprompt Perl code
1414   PERLDB_POST      - post-prompt Perl code
1415   PERLDB_TYPEAHEAD - typeahead captured by readline()
1416
1417 We chug through all these variables and plug the values saved in them
1418 back into the appropriate spots in the debugger.
1419
1420 =cut
1421
1422 if ( exists $ENV{PERLDB_RESTART} ) {
1423
1424     # We're restarting, so we don't need the flag that says to restart anymore.
1425     delete $ENV{PERLDB_RESTART};
1426
1427     # $restart = 1;
1428     @hist          = get_list('PERLDB_HIST');
1429     %break_on_load = get_list("PERLDB_ON_LOAD");
1430     %postponed     = get_list("PERLDB_POSTPONE");
1431
1432     # restore breakpoints/actions
1433     my @had_breakpoints = get_list("PERLDB_VISITED");
1434     for ( 0 .. $#had_breakpoints ) {
1435         my %pf = get_list("PERLDB_FILE_$_");
1436         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1437     }
1438
1439     # restore options
1440     my %opt = get_list("PERLDB_OPT");
1441     my ( $opt, $val );
1442     while ( ( $opt, $val ) = each %opt ) {
1443         $val =~ s/[\\\']/\\$1/g;
1444         parse_options("$opt'$val'");
1445     }
1446
1447     # restore original @INC
1448     @INC     = get_list("PERLDB_INC");
1449     @ini_INC = @INC;
1450
1451     # return pre/postprompt actions and typeahead buffer
1452     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1453     $pre       = [ get_list("PERLDB_PRE") ];
1454     $post      = [ get_list("PERLDB_POST") ];
1455     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1456 } ## end if (exists $ENV{PERLDB_RESTART...
1457
1458 =head2 SETTING UP THE TERMINAL
1459
1460 Now, we'll decide how the debugger is going to interact with the user.
1461 If there's no TTY, we set the debugger to run non-stop; there's not going
1462 to be anyone there to enter commands.
1463
1464 =cut
1465
1466 if ($notty) {
1467     $runnonstop = 1;
1468 }
1469
1470 =pod
1471
1472 If there is a TTY, we have to determine who it belongs to before we can
1473 proceed. If this is a slave editor or graphical debugger (denoted by
1474 the first command-line switch being '-emacs'), we shift this off and
1475 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1476
1477 =cut
1478
1479 else {
1480
1481     # Is Perl being run from a slave editor or graphical debugger?
1482     # If so, don't use readline, and set $slave_editor = 1.
1483     $slave_editor =
1484       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1485     $rl = 0, shift(@main::ARGV) if $slave_editor;
1486
1487     #require Term::ReadLine;
1488
1489 =pod
1490
1491 We then determine what the console should be on various systems:
1492
1493 =over 4
1494
1495 =item * Cygwin - We use C<stdin> instead of a separate device.
1496
1497 =cut
1498
1499     if ( $^O eq 'cygwin' ) {
1500
1501         # /dev/tty is binary. use stdin for textmode
1502         undef $console;
1503     }
1504
1505 =item * Unix - use C</dev/tty>.
1506
1507 =cut
1508
1509     elsif ( -e "/dev/tty" ) {
1510         $console = "/dev/tty";
1511     }
1512
1513 =item * Windows or MSDOS - use C<con>.
1514
1515 =cut
1516
1517     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1518         $console = "con";
1519     }
1520
1521 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1522 Console> if not. (Note that Mac OS X returns 'darwin', not 'MacOS'. Also note that the debugger doesn't do anything special for 'darwin'. Maybe it should.)
1523
1524 =cut
1525
1526     elsif ( $^O eq 'MacOS' ) {
1527         if ( $MacPerl::Version !~ /MPW/ ) {
1528             $console =
1529               "Dev:Console:Perl Debug";    # Separate window for application
1530         }
1531         else {
1532             $console = "Dev:Console";
1533         }
1534     } ## end elsif ($^O eq 'MacOS')
1535
1536 =item * VMS - use C<sys$command>.
1537
1538 =cut
1539
1540     else {
1541
1542         # everything else is ...
1543         $console = "sys\$command";
1544     }
1545
1546 =pod
1547
1548 =back
1549
1550 Several other systems don't use a specific console. We C<undef $console>
1551 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1552 with a slave editor, Epoc).
1553
1554 =cut
1555
1556     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1557
1558         # /dev/tty is binary. use stdin for textmode
1559         $console = undef;
1560     }
1561
1562     if ( $^O eq 'NetWare' ) {
1563
1564         # /dev/tty is binary. use stdin for textmode
1565         $console = undef;
1566     }
1567
1568     # In OS/2, we need to use STDIN to get textmode too, even though
1569     # it pretty much looks like Unix otherwise.
1570     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1571     {    # In OS/2
1572         $console = undef;
1573     }
1574
1575     # EPOC also falls into the 'got to use STDIN' camp.
1576     if ( $^O eq 'epoc' ) {
1577         $console = undef;
1578     }
1579
1580 =pod
1581
1582 If there is a TTY hanging around from a parent, we use that as the console.
1583
1584 =cut
1585
1586     $console = $tty if defined $tty;
1587
1588 =head2 SOCKET HANDLING
1589
1590 The debugger is capable of opening a socket and carrying out a debugging
1591 session over the socket.
1592
1593 If C<RemotePort> was defined in the options, the debugger assumes that it
1594 should try to start a debugging session on that port. It builds the socket
1595 and then tries to connect the input and output filehandles to it.
1596
1597 =cut
1598
1599     # Handle socket stuff.
1600
1601     if ( defined $remoteport ) {
1602
1603         # If RemotePort was defined in the options, connect input and output
1604         # to the socket.
1605         require IO::Socket;
1606         $OUT = new IO::Socket::INET(
1607             Timeout  => '10',
1608             PeerAddr => $remoteport,
1609             Proto    => 'tcp',
1610         );
1611         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1612         $IN = $OUT;
1613     } ## end if (defined $remoteport)
1614
1615 =pod
1616
1617 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1618 this is probably a situation where multiple debuggers are running (for example,
1619 a backticked command that starts up another debugger). We create a new IN and
1620 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1621 and if we can.
1622
1623 =cut
1624
1625     # Non-socket.
1626     else {
1627
1628         # Two debuggers running (probably a system or a backtick that invokes
1629         # the debugger itself under the running one). create a new IN and OUT
1630         # filehandle, and do the necessary mojo to create a new tty if we
1631         # know how, and we can.
1632         create_IN_OUT(4) if $CreateTTY & 4;
1633         if ($console) {
1634
1635             # If we have a console, check to see if there are separate ins and
1636             # outs to open. (They are assumed identiical if not.)
1637
1638             my ( $i, $o ) = split /,/, $console;
1639             $o = $i unless defined $o;
1640
1641             # read/write on in, or just read, or read on STDIN.
1642             open( IN,      "+<$i" )
1643               || open( IN, "<$i" )
1644               || open( IN, "<&STDIN" );
1645
1646             # read/write/create/clobber out, or write/create/clobber out,
1647             # or merge with STDERR, or merge with STDOUT.
1648                  open( OUT, "+>$o" )
1649               || open( OUT, ">$o" )
1650               || open( OUT, ">&STDERR" )
1651               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1652
1653         } ## end if ($console)
1654         elsif ( not defined $console ) {
1655
1656             # No console. Open STDIN.
1657             open( IN, "<&STDIN" );
1658
1659             # merge with STDERR, or with STDOUT.
1660             open( OUT,      ">&STDERR" )
1661               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1662             $console = 'STDIN/OUT';
1663         } ## end elsif (not defined $console)
1664
1665         # Keep copies of the filehandles so that when the pager runs, it
1666         # can close standard input without clobbering ours.
1667         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1668     } ## end elsif (from if(defined $remoteport))
1669
1670     # Unbuffer DB::OUT. We need to see responses right away.
1671     my $previous = select($OUT);
1672     $| = 1;                                  # for DB::OUT
1673     select($previous);
1674
1675     # Line info goes to debugger output unless pointed elsewhere.
1676     # Pointing elsewhere makes it possible for slave editors to
1677     # keep track of file and position. We have both a filehandle
1678     # and a I/O description to keep track of.
1679     $LINEINFO = $OUT     unless defined $LINEINFO;
1680     $lineinfo = $console unless defined $lineinfo;
1681
1682 =pod
1683
1684 To finish initialization, we show the debugger greeting,
1685 and then call the C<afterinit()> subroutine if there is one.
1686
1687 =cut
1688
1689     # Show the debugger greeting.
1690     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1691     unless ($runnonstop) {
1692         local $\ = '';
1693         local $, = '';
1694         if ( $term_pid eq '-1' ) {
1695             print $OUT "\nDaughter DB session started...\n";
1696         }
1697         else {
1698             print $OUT "\nLoading DB routines from $header\n";
1699             print $OUT (
1700                 "Editor support ",
1701                 $slave_editor ? "enabled" : "available", ".\n"
1702             );
1703             print $OUT
1704 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1705         } ## end else [ if ($term_pid eq '-1')
1706     } ## end unless ($runnonstop)
1707 } ## end else [ if ($notty)
1708
1709 # XXX This looks like a bug to me.
1710 # Why copy to @ARGS and then futz with @args?
1711 @ARGS = @ARGV;
1712 for (@args) {
1713     # Make sure backslashes before single quotes are stripped out, and
1714     # keep args unless they are numeric (XXX why?)
1715     # s/\'/\\\'/g;                      # removed while not justified understandably
1716     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1717 }
1718
1719 # If there was an afterinit() sub defined, call it. It will get
1720 # executed in our scope, so it can fiddle with debugger globals.
1721 if ( defined &afterinit ) {    # May be defined in $rcfile
1722     &afterinit();
1723 }
1724
1725 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1726 $I_m_init = 1;
1727
1728 ############################################################ Subroutines
1729
1730 =head1 SUBROUTINES
1731
1732 =head2 DB
1733
1734 This gigantic subroutine is the heart of the debugger. Called before every
1735 statement, its job is to determine if a breakpoint has been reached, and
1736 stop if so; read commands from the user, parse them, and execute
1737 them, and hen send execution off to the next statement.
1738
1739 Note that the order in which the commands are processed is very important;
1740 some commands earlier in the loop will actually alter the C<$cmd> variable
1741 to create other commands to be executed later. This is all highly "optimized"
1742 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1743 see what's happening in any given command.
1744
1745 =cut
1746
1747 sub DB {
1748
1749     # Check for whether we should be running continuously or not.
1750     # _After_ the perl program is compiled, $single is set to 1:
1751     if ( $single and not $second_time++ ) {
1752
1753         # Options say run non-stop. Run until we get an interrupt.
1754         if ($runnonstop) {    # Disable until signal
1755                 # If there's any call stack in place, turn off single
1756                 # stepping into subs throughout the stack.
1757             for ( $i = 0 ; $i <= $stack_depth ; ) {
1758                 $stack[ $i++ ] &= ~1;
1759             }
1760
1761             # And we are now no longer in single-step mode.
1762             $single = 0;
1763
1764             # If we simply returned at this point, we wouldn't get
1765             # the trace info. Fall on through.
1766             # return;
1767         } ## end if ($runnonstop)
1768
1769         elsif ($ImmediateStop) {
1770
1771             # We are supposed to stop here; XXX probably a break.
1772             $ImmediateStop = 0;    # We've processed it; turn it off
1773             $signal        = 1;    # Simulate an interrupt to force
1774                                    # us into the command loop
1775         }
1776     } ## end if ($single and not $second_time...
1777
1778     # If we're in single-step mode, or an interrupt (real or fake)
1779     # has occurred, turn off non-stop mode.
1780     $runnonstop = 0 if $single or $signal;
1781
1782     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1783     # The code being debugged may have altered them.
1784     &save;
1785
1786     # Since DB::DB gets called after every line, we can use caller() to
1787     # figure out where we last were executing. Sneaky, eh? This works because
1788     # caller is returning all the extra information when called from the
1789     # debugger.
1790     local ( $package, $filename, $line ) = caller;
1791     local $filename_ini = $filename;
1792
1793     # set up the context for DB::eval, so it can properly execute
1794     # code on behalf of the user. We add the package in so that the
1795     # code is eval'ed in the proper package (not in the debugger!).
1796     local $usercontext =
1797       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1798
1799     # Create an alias to the active file magical array to simplify
1800     # the code here.
1801     local (*dbline) = $main::{ '_<' . $filename };
1802
1803     # we need to check for pseudofiles on Mac OS (these are files
1804     # not attached to a filename, but instead stored in Dev:Pseudo)
1805     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1806         $filename_ini = $filename = 'Dev:Pseudo';
1807         *dbline = $main::{ '_<' . $filename };
1808     }
1809
1810     # Last line in the program.
1811     local $max = $#dbline;
1812
1813     # if we have something here, see if we should break.
1814     if ( $dbline{$line}
1815         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1816     {
1817
1818         # Stop if the stop criterion says to just stop.
1819         if ( $stop eq '1' ) {
1820             $signal |= 1;
1821         }
1822
1823         # It's a conditional stop; eval it in the user's context and
1824         # see if we should stop. If so, remove the one-time sigil.
1825         elsif ($stop) {
1826             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1827             &eval;
1828             $dbline{$line} =~ s/;9($|\0)/$1/;
1829         }
1830     } ## end if ($dbline{$line} && ...
1831
1832     # Preserve the current stop-or-not, and see if any of the W
1833     # (watch expressions) has changed.
1834     my $was_signal = $signal;
1835
1836     # If we have any watch expressions ...
1837     if ( $trace & 2 ) {
1838         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1839             $evalarg = $to_watch[$n];
1840             local $onetimeDump;    # Tell DB::eval() to not output results
1841
1842             # Fix context DB::eval() wants to return an array, but
1843             # we need a scalar here.
1844             my ($val) = join( "', '", &eval );
1845             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1846
1847             # Did it change?
1848             if ( $val ne $old_watch[$n] ) {
1849
1850                 # Yep! Show the difference, and fake an interrupt.
1851                 $signal = 1;
1852                 print $OUT <<EOP;
1853 Watchpoint $n:\t$to_watch[$n] changed:
1854     old value:\t$old_watch[$n]
1855     new value:\t$val
1856 EOP
1857                 $old_watch[$n] = $val;
1858             } ## end if ($val ne $old_watch...
1859         } ## end for (my $n = 0 ; $n <= ...
1860     } ## end if ($trace & 2)
1861
1862 =head2 C<watchfunction()>
1863
1864 C<watchfunction()> is a function that can be defined by the user; it is a
1865 function which will be run on each entry to C<DB::DB>; it gets the
1866 current package, filename, and line as its parameters.
1867
1868 The watchfunction can do anything it likes; it is executing in the
1869 debugger's context, so it has access to all of the debugger's internal
1870 data structures and functions.
1871
1872 C<watchfunction()> can control the debugger's actions. Any of the following
1873 will cause the debugger to return control to the user's program after
1874 C<watchfunction()> executes:
1875
1876 =over 4
1877
1878 =item * Returning a false value from the C<watchfunction()> itself.
1879
1880 =item * Altering C<$single> to a false value.
1881
1882 =item * Altering C<$signal> to a false value.
1883
1884 =item *  Turning off the '4' bit in C<$trace> (this also disables the
1885 check for C<watchfunction()>. This can be done with
1886
1887     $trace &= ~4;
1888
1889 =back
1890
1891 =cut
1892
1893     # If there's a user-defined DB::watchfunction, call it with the
1894     # current package, filename, and line. The function executes in
1895     # the DB:: package.
1896     if ( $trace & 4 ) {    # User-installed watch
1897         return
1898           if watchfunction( $package, $filename, $line )
1899           and not $single
1900           and not $was_signal
1901           and not( $trace & ~4 );
1902     } ## end if ($trace & 4)
1903
1904     # Pick up any alteration to $signal in the watchfunction, and
1905     # turn off the signal now.
1906     $was_signal = $signal;
1907     $signal     = 0;
1908
1909 =head2 GETTING READY TO EXECUTE COMMANDS
1910
1911 The debugger decides to take control if single-step mode is on, the
1912 C<t> command was entered, or the user generated a signal. If the program
1913 has fallen off the end, we set things up so that entering further commands
1914 won't cause trouble, and we say that the program is over.
1915
1916 =cut
1917
1918     # Check to see if we should grab control ($single true,
1919     # trace set appropriately, or we got a signal).
1920     if ( $single || ( $trace & 1 ) || $was_signal ) {
1921
1922         # Yes, grab control.
1923         if ($slave_editor) {
1924
1925             # Tell the editor to update its position.
1926             $position = "\032\032$filename:$line:0\n";
1927             print_lineinfo($position);
1928         }
1929
1930 =pod
1931
1932 Special check: if we're in package C<DB::fake>, we've gone through the
1933 C<END> block at least once. We set up everything so that we can continue
1934 to enter commands and have a valid context to be in.
1935
1936 =cut
1937
1938         elsif ( $package eq 'DB::fake' ) {
1939
1940             # Fallen off the end already.
1941             $term || &setterm;
1942             print_help(<<EOP);
1943 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1944   use B<O> I<inhibit_exit> to avoid stopping after program termination,
1945   B<h q>, B<h R> or B<h O> to get additional info.
1946 EOP
1947
1948             # Set the DB::eval context appropriately.
1949             $package     = 'main';
1950             $usercontext =
1951                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
1952               . "package $package;";    # this won't let them modify, alas
1953         } ## end elsif ($package eq 'DB::fake')
1954
1955 =pod
1956
1957 If the program hasn't finished executing, we scan forward to the
1958 next executable line, print that out, build the prompt from the file and line
1959 number information, and print that.
1960
1961 =cut
1962
1963         else {
1964
1965             # Still somewhere in the midst of execution. Set up the
1966             #  debugger prompt.
1967             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1968                                  # Perl 5 ones (sorry, we don't print Klingon
1969                                  #module names)
1970
1971             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
1972             $prefix .= "$sub($filename:";
1973             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1974
1975             # Break up the prompt if it's really long.
1976             if ( length($prefix) > 30 ) {
1977                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1978                 $prefix   = "";
1979                 $infix    = ":\t";
1980             }
1981             else {
1982                 $infix    = "):\t";
1983                 $position = "$prefix$line$infix$dbline[$line]$after";
1984             }
1985
1986             # Print current line info, indenting if necessary.
1987             if ($frame) {
1988                 print_lineinfo( ' ' x $stack_depth,
1989                     "$line:\t$dbline[$line]$after" );
1990             }
1991             else {
1992                 print_lineinfo($position);
1993             }
1994
1995             # Scan forward, stopping at either the end or the next
1996             # unbreakable line.
1997             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
1998             {    #{ vi
1999
2000                 # Drop out on null statements, block closers, and comments.
2001                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2002
2003                 # Drop out if the user interrupted us.
2004                 last if $signal;
2005
2006                 # Append a newline if the line doesn't have one. Can happen
2007                 # in eval'ed text, for instance.
2008                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2009
2010                 # Next executable line.
2011                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2012                 $position .= $incr_pos;
2013                 if ($frame) {
2014
2015                     # Print it indented if tracing is on.
2016                     print_lineinfo( ' ' x $stack_depth,
2017                         "$i:\t$dbline[$i]$after" );
2018                 }
2019                 else {
2020                     print_lineinfo($incr_pos);
2021                 }
2022             } ## end for ($i = $line + 1 ; $i...
2023         } ## end else [ if ($slave_editor)
2024     } ## end if ($single || ($trace...
2025
2026 =pod
2027
2028 If there's an action to be executed for the line we stopped at, execute it.
2029 If there are any preprompt actions, execute those as well.
2030
2031 =cut
2032
2033     # If there's an action, do it now.
2034     $evalarg = $action, &eval if $action;
2035
2036     # Are we nested another level (e.g., did we evaluate a function
2037     # that had a breakpoint in it at the debugger prompt)?
2038     if ( $single || $was_signal ) {
2039
2040         # Yes, go down a level.
2041         local $level = $level + 1;
2042
2043         # Do any pre-prompt actions.
2044         foreach $evalarg (@$pre) {
2045             &eval;
2046         }
2047
2048         # Complain about too much recursion if we passed the limit.
2049         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2050           if $single & 4;
2051
2052         # The line we're currently on. Set $incr to -1 to stay here
2053         # until we get a command that tells us to advance.
2054         $start = $line;
2055         $incr  = -1;      # for backward motion.
2056
2057         # Tack preprompt debugger actions ahead of any actual input.
2058         @typeahead = ( @$pretype, @typeahead );
2059
2060 =head2 WHERE ARE WE?
2061
2062 XXX Relocate this section?
2063
2064 The debugger normally shows the line corresponding to the current line of
2065 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2066 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2067
2068 C<$incr> controls by how many lines the "current" line should move forward
2069 after a command is executed. If set to -1, this indicates that the "current"
2070 line shouldn't change.
2071
2072 C<$start> is the "current" line. It is used for things like knowing where to
2073 move forwards or backwards from when doing an C<L> or C<-> command.
2074
2075 C<$max> tells the debugger where the last line of the current file is. It's
2076 used to terminate loops most often.
2077
2078 =head2 THE COMMAND LOOP
2079
2080 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2081 in two parts:
2082
2083 =over 4
2084
2085 =item * The outer part of the loop, starting at the C<CMD> label. This loop
2086 reads a command and then executes it.
2087
2088 =item * The inner part of the loop, starting at the C<PIPE> label. This part
2089 is wholly contained inside the C<CMD> block and only executes a command.
2090 Used to handle commands running inside a pager.
2091
2092 =back
2093
2094 So why have two labels to restart the loop? Because sometimes, it's easier to
2095 have a command I<generate> another command and then re-execute the loop to do
2096 the new command. This is faster, but perhaps a bit more convoluted.
2097
2098 =cut
2099
2100         # The big command dispatch loop. It keeps running until the
2101         # user yields up control again.
2102         #
2103         # If we have a terminal for input, and we get something back
2104         # from readline(), keep on processing.
2105       CMD:
2106         while (
2107
2108             # We have a terminal, or can get one ...
2109             ( $term || &setterm ),
2110
2111             # ... and it belogs to this PID or we get one for this PID ...
2112             ( $term_pid == $$ or resetterm(1) ),
2113
2114             # ... and we got a line of command input ...
2115             defined(
2116                 $cmd = &readline(
2117                         "$pidprompt  DB"
2118                       . ( '<' x $level )
2119                       . ( $#hist + 1 )
2120                       . ( '>' x $level ) . " "
2121                 )
2122             )
2123           )
2124         {
2125
2126             # ... try to execute the input as debugger commands.
2127
2128             # Don't stop running.
2129             $single = 0;
2130
2131             # No signal is active.
2132             $signal = 0;
2133
2134             # Handle continued commands (ending with \):
2135             $cmd =~ s/\\$/\n/ && do {
2136                 $cmd .= &readline("  cont: ");
2137                 redo CMD;
2138             };
2139
2140 =head4 The null command
2141
2142 A newline entered by itself means "re-execute the last command". We grab the
2143 command out of C<$laststep> (where it was recorded previously), and copy it
2144 back into C<$cmd> to be executed below. If there wasn't any previous command,
2145 we'll do nothing below (no command will match). If there was, we also save it
2146 in the command history and fall through to allow the command parsing to pick
2147 it up.
2148
2149 =cut
2150
2151             # Empty input means repeat the last command.
2152             $cmd =~ /^$/ && ( $cmd = $laststep );
2153             chomp($cmd);    # get rid of the annoying extra newline
2154             push( @hist, $cmd ) if length($cmd) > 1;
2155             push( @truehist, $cmd );
2156
2157             # This is a restart point for commands that didn't arrive
2158             # via direct user input. It allows us to 'redo PIPE' to
2159             # re-execute command processing without reading a new command.
2160           PIPE: {
2161                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2162                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2163                 ($i) = split( /\s+/, $cmd );
2164
2165 =head3 COMMAND ALIASES
2166
2167 The debugger can create aliases for commands (these are stored in the
2168 C<%alias> hash). Before a command is executed, the command loop looks it up
2169 in the alias hash and substitutes the contents of the alias for the command,
2170 completely replacing it.
2171
2172 =cut
2173
2174                 # See if there's an alias for the command, and set it up if so.
2175                 if ( $alias{$i} ) {
2176
2177                     # Squelch signal handling; we want to keep control here
2178                     # if something goes loco during the alias eval.
2179                     local $SIG{__DIE__};
2180                     local $SIG{__WARN__};
2181
2182                     # This is a command, so we eval it in the DEBUGGER's
2183                     # scope! Otherwise, we can't see the special debugger
2184                     # variables, or get to the debugger's subs. (Well, we
2185                     # _could_, but why make it even more complicated?)
2186                     eval "\$cmd =~ $alias{$i}";
2187                     if ($@) {
2188                         local $\ = '';
2189                         print $OUT "Couldn't evaluate `$i' alias: $@";
2190                         next CMD;
2191                     }
2192                 } ## end if ($alias{$i})
2193
2194 =head3 MAIN-LINE COMMANDS
2195
2196 All of these commands work up to and after the program being debugged has
2197 terminated.
2198
2199 =head4 C<q> - quit
2200
2201 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2202 try to execute further, cleaning any restart-related stuff out of the
2203 environment, and executing with the last value of C<$?>.
2204
2205 =cut
2206
2207                 $cmd =~ /^q$/ && do {
2208                     $fall_off_end = 1;
2209                     clean_ENV();
2210                     exit $?;
2211                 };
2212
2213 =head4 C<t> - trace
2214
2215 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2216
2217 =cut
2218
2219                 $cmd =~ /^t$/ && do {
2220                     $trace ^= 1;
2221                     local $\ = '';
2222                     print $OUT "Trace = "
2223                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2224                     next CMD;
2225                 };
2226
2227 =head4 C<S> - list subroutines matching/not matching a pattern
2228
2229 Walks through C<%sub>, checking to see whether or not to print the name.
2230
2231 =cut
2232
2233                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2234
2235                     $Srev     = defined $2;     # Reverse scan?
2236                     $Spatt    = $3;             # The pattern (if any) to use.
2237                     $Snocheck = !defined $1;    # No args - print all subs.
2238
2239                     # Need to make these sane here.
2240                     local $\ = '';
2241                     local $, = '';
2242
2243                     # Search through the debugger's magical hash of subs.
2244                     # If $nocheck is true, just print the sub name.
2245                     # Otherwise, check it against the pattern. We then use
2246                     # the XOR trick to reverse the condition as required.
2247                     foreach $subname ( sort( keys %sub ) ) {
2248                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2249                             print $OUT $subname, "\n";
2250                         }
2251                     }
2252                     next CMD;
2253                 };
2254
2255 =head4 C<X> - list variables in current package
2256
2257 Since the C<V> command actually processes this, just change this to the
2258 appropriate C<V> command and fall through.
2259
2260 =cut
2261
2262                 $cmd =~ s/^X\b/V $package/;
2263
2264 =head4 C<V> - list variables
2265
2266 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2267
2268 =cut
2269
2270                 # Bare V commands get the currently-being-debugged package
2271                 # added.
2272                 $cmd =~ /^V$/ && do {
2273                     $cmd = "V $package";
2274                 };
2275
2276                 # V - show variables in package.
2277                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2278
2279                     # Save the currently selected filehandle and
2280                     # force output to debugger's filehandle (dumpvar
2281                     # just does "print" for output).
2282                     local ($savout) = select($OUT);
2283
2284                     # Grab package name and variables to dump.
2285                     $packname = $1;
2286                     @vars     = split( ' ', $2 );
2287
2288                     # If main::dumpvar isn't here, get it.
2289                     do 'dumpvar.pl' unless defined &main::dumpvar;
2290                     if ( defined &main::dumpvar ) {
2291
2292                         # We got it. Turn off subroutine entry/exit messages
2293                         # for the moment, along with return values.
2294                         local $frame = 0;
2295                         local $doret = -2;
2296
2297                         # must detect sigpipe failures  - not catching
2298                         # then will cause the debugger to die.
2299                         eval {
2300                             &main::dumpvar(
2301                                 $packname,
2302                                 defined $option{dumpDepth}
2303                                 ? $option{dumpDepth}
2304                                 : -1,    # assume -1 unless specified
2305                                 @vars
2306                             );
2307                         };
2308
2309                         # The die doesn't need to include the $@, because
2310                         # it will automatically get propagated for us.
2311                         if ($@) {
2312                             die unless $@ =~ /dumpvar print failed/;
2313                         }
2314                     } ## end if (defined &main::dumpvar)
2315                     else {
2316
2317                         # Couldn't load dumpvar.
2318                         print $OUT "dumpvar.pl not available.\n";
2319                     }
2320
2321                     # Restore the output filehandle, and go round again.
2322                     select($savout);
2323                     next CMD;
2324                 };
2325
2326 =head4 C<x> - evaluate and print an expression
2327
2328 Hands the expression off to C<DB::eval>, setting it up to print the value
2329 via C<dumpvar.pl> instead of just printing it directly.
2330
2331 =cut
2332
2333                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2334                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2335
2336                     # handle special  "x 3 blah" syntax XXX propagate
2337                     # doc back to special variables.
2338                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2339                         $onetimedumpDepth = $1;
2340                     }
2341                 };
2342
2343 =head4 C<m> - print methods
2344
2345 Just uses C<DB::methods> to determine what methods are available.
2346
2347 =cut
2348
2349                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2350                     methods($1);
2351                     next CMD;
2352                 };
2353
2354                 # m expr - set up DB::eval to do the work
2355                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2356                     $onetimeDump = 'methods';   #  method output gets used there
2357                 };
2358
2359 =head4 C<f> - switch files
2360
2361 =cut
2362
2363                 $cmd =~ /^f\b\s*(.*)/ && do {
2364                     $file = $1;
2365                     $file =~ s/\s+$//;
2366
2367                     # help for no arguments (old-style was return from sub).
2368                     if ( !$file ) {
2369                         print $OUT
2370                           "The old f command is now the r command.\n";    # hint
2371                         print $OUT "The new f command switches filenames.\n";
2372                         next CMD;
2373                     } ## end if (!$file)
2374
2375                     # if not in magic file list, try a close match.
2376                     if ( !defined $main::{ '_<' . $file } ) {
2377                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2378                             {
2379                                 $try = substr( $try, 2 );
2380                                 print $OUT "Choosing $try matching `$file':\n";
2381                                 $file = $try;
2382                             }
2383                         } ## end if (($try) = grep(m#^_<.*$file#...
2384                     } ## end if (!defined $main::{ ...
2385
2386                     # If not successfully switched now, we failed.
2387                     if ( !defined $main::{ '_<' . $file } ) {
2388                         print $OUT "No file matching `$file' is loaded.\n";
2389                         next CMD;
2390                     }
2391
2392                     # We switched, so switch the debugger internals around.
2393                     elsif ( $file ne $filename ) {
2394                         *dbline   = $main::{ '_<' . $file };
2395                         $max      = $#dbline;
2396                         $filename = $file;
2397                         $start    = 1;
2398                         $cmd      = "l";
2399                     } ## end elsif ($file ne $filename)
2400
2401                     # We didn't switch; say we didn't.
2402                     else {
2403                         print $OUT "Already in $file.\n";
2404                         next CMD;
2405                     }
2406                 };
2407
2408 =head4 C<.> - return to last-executed line.
2409
2410 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2411 and then we look up the line in the magical C<%dbline> hash.
2412
2413 =cut
2414
2415                 # . command.
2416                 $cmd =~ /^\.$/ && do {
2417                     $incr = -1;    # stay at current line
2418
2419                     # Reset everything to the old location.
2420                     $start    = $line;
2421                     $filename = $filename_ini;
2422                     *dbline   = $main::{ '_<' . $filename };
2423                     $max      = $#dbline;
2424
2425                     # Now where are we?
2426                     print_lineinfo($position);
2427                     next CMD;
2428                 };
2429
2430 =head4 C<-> - back one window
2431
2432 We change C<$start> to be one window back; if we go back past the first line,
2433 we set it to be the first line. We ser C<$incr> to put us back at the
2434 currently-executing line, and then put a C<l $start +> (list one window from
2435 C<$start>) in C<$cmd> to be executed later.
2436
2437 =cut
2438
2439                 # - - back a window.
2440                 $cmd =~ /^-$/ && do {
2441
2442                     # back up by a window; go to 1 if back too far.
2443                     $start -= $incr + $window + 1;
2444                     $start = 1 if $start <= 0;
2445                     $incr  = $window - 1;
2446
2447                     # Generate and execute a "l +" command (handled below).
2448                     $cmd = 'l ' . ($start) . '+';
2449                 };
2450
2451 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2452
2453 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2454 problems, most notably that the default case of several commands destroying
2455 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2456 retain the old commands for those who were used to using them or who preferred
2457 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2458 deal with them instead of processing them in-line.
2459
2460 =cut
2461
2462                 # All of these commands were remapped in perl 5.8.0;
2463                 # we send them off to the secondary dispatcher (see below).
2464                 $cmd =~ /^([aAbBhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2465                     &cmd_wrapper( $1, $2, $line );
2466                     next CMD;
2467                 };
2468
2469 =head4 C<y> - List lexicals in higher scope
2470
2471 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2472 above the current one and then displays then using C<dumpvar.pl>.
2473
2474 =cut
2475
2476                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2477
2478                     # See if we've got the necessary support.
2479                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2480                       or &warn(
2481                         $@ =~ /locate/
2482                         ? "PadWalker module not found - please install\n"
2483                         : $@
2484                       )
2485                       and next CMD;
2486
2487                     # Load up dumpvar if we don't have it. If we can, that is.
2488                     do 'dumpvar.pl' unless defined &main::dumpvar;
2489                     defined &main::dumpvar
2490                       or print $OUT "dumpvar.pl not available.\n"
2491                       and next CMD;
2492
2493                     # Got all the modules we need. Find them and print them.
2494                     my @vars = split( ' ', $2 || '' );
2495
2496                     # Find the pad.
2497                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2498
2499                     # Oops. Can't find it.
2500                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2501
2502                     # Show the desired vars with dumplex().
2503                     my $savout = select($OUT);
2504
2505                     # Have dumplex dump the lexicals.
2506                     dumpvar::dumplex( $_, $h->{$_},
2507                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2508                         @vars )
2509                       for sort keys %$h;
2510                     select($savout);
2511                     next CMD;
2512                 };
2513
2514 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2515
2516 All of the commands below this point don't work after the program being
2517 debugged has ended. All of them check to see if the program has ended; this
2518 allows the commands to be relocated without worrying about a 'line of
2519 demarcation' above which commands can be entered anytime, and below which
2520 they can't.
2521
2522 =head4 C<n> - single step, but don't trace down into subs
2523
2524 Done by setting C<$single> to 2, which forces subs to execute straight through
2525 when entered (see X<DB::sub>). We also save the C<n> command in C<$laststep>,
2526 so a null command knows what to re-execute.
2527
2528 =cut
2529
2530                 # n - next
2531                 $cmd =~ /^n$/ && do {
2532                     end_report(), next CMD if $finished and $level <= 1;
2533
2534                     # Single step, but don't enter subs.
2535                     $single = 2;
2536
2537                     # Save for empty command (repeat last).
2538                     $laststep = $cmd;
2539                     last CMD;
2540                 };
2541
2542 =head4 C<s> - single-step, entering subs
2543
2544 Sets C<$single> to 1, which causes X<DB::sub> to continue tracing inside
2545 subs. Also saves C<s> as C<$lastcmd>.
2546
2547 =cut
2548
2549                 # s - single step.
2550                 $cmd =~ /^s$/ && do {
2551
2552                     # Get out and restart the command loop if program
2553                     # has finished.
2554                     end_report(), next CMD if $finished and $level <= 1;
2555
2556                     # Single step should enter subs.
2557                     $single = 1;
2558
2559                     # Save for empty command (repeat last).
2560                     $laststep = $cmd;
2561                     last CMD;
2562                 };
2563
2564 =head4 C<c> - run continuously, setting an optional breakpoint
2565
2566 Most of the code for this command is taken up with locating the optional
2567 breakpoint, which is either a subroutine name or a line number. We set
2568 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2569 in this and all call levels above this one.
2570
2571 =cut
2572
2573                 # c - start continuous execution.
2574                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2575
2576                     # Hey, show's over. The debugged program finished
2577                     # executing already.
2578                     end_report(), next CMD if $finished and $level <= 1;
2579
2580                     # Capture the place to put a one-time break.
2581                     $subname = $i = $1;
2582
2583                     #  Probably not needed, since we finish an interactive
2584                     #  sub-session anyway...
2585                     # local $filename = $filename;
2586                     # local *dbline = *dbline; # XXX Would this work?!
2587                     #
2588                     # The above question wonders if localizing the alias
2589                     # to the magic array works or not. Since it's commented
2590                     # out, we'll just leave that to speculation for now.
2591
2592                     # If the "subname" isn't all digits, we'll assume it
2593                     # is a subroutine name, and try to find it.
2594                     if ( $subname =~ /\D/ ) {    # subroutine name
2595                             # Qualify it to the current package unless it's
2596                             # already qualified.
2597                         $subname = $package . "::" . $subname
2598                           unless $subname =~ /::/;
2599
2600                         # find_sub will return "file:line_number" corresponding
2601                         # to where the subroutine is defined; we call find_sub,
2602                         # break up the return value, and assign it in one
2603                         # operation.
2604                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2605
2606                         # Force the line number to be numeric.
2607                         $i += 0;
2608
2609                         # If we got a line number, we found the sub.
2610                         if ($i) {
2611
2612                             # Switch all the debugger's internals around so
2613                             # we're actually working with that file.
2614                             $filename = $file;
2615                             *dbline   = $main::{ '_<' . $filename };
2616
2617                             # Mark that there's a breakpoint in this file.
2618                             $had_breakpoints{$filename} |= 1;
2619
2620                             # Scan forward to the first executable line
2621                             # after the 'sub whatever' line.
2622                             $max = $#dbline;
2623                             ++$i while $dbline[$i] == 0 && $i < $max;
2624                         } ## end if ($i)
2625
2626                         # We didn't find a sub by that name.
2627                         else {
2628                             print $OUT "Subroutine $subname not found.\n";
2629                             next CMD;
2630                         }
2631                     } ## end if ($subname =~ /\D/)
2632
2633                     # At this point, either the subname was all digits (an
2634                     # absolute line-break request) or we've scanned through
2635                     # the code following the definition of the sub, looking
2636                     # for an executable, which we may or may not have found.
2637                     #
2638                     # If $i (which we set $subname from) is non-zero, we
2639                     # got a request to break at some line somewhere. On
2640                     # one hand, if there wasn't any real subroutine name
2641                     # involved, this will be a request to break in the current
2642                     # file at the specified line, so we have to check to make
2643                     # sure that the line specified really is breakable.
2644                     #
2645                     # On the other hand, if there was a subname supplied, the
2646                     # preceeding block has moved us to the proper file and
2647                     # location within that file, and then scanned forward
2648                     # looking for the next executable line. We have to make
2649                     # sure that one was found.
2650                     #
2651                     # On the gripping hand, we can't do anything unless the
2652                     # current value of $i points to a valid breakable line.
2653                     # Check that.
2654                     if ($i) {
2655
2656                         # Breakable?
2657                         if ( $dbline[$i] == 0 ) {
2658                             print $OUT "Line $i not breakable.\n";
2659                             next CMD;
2660                         }
2661
2662                         # Yes. Set up the one-time-break sigil.
2663                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2664                     } ## end if ($i)
2665
2666                     # Turn off stack tracing from here up.
2667                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2668                         $stack[ $i++ ] &= ~1;
2669                     }
2670                     last CMD;
2671                 };
2672
2673 =head4 C<r> - return from a subroutine
2674
2675 For C<r> to work properly, the debugger has to stop execution again
2676 immediately after the return is executed. This is done by forcing
2677 single-stepping to be on in the call level above the current one. If
2678 we are printing return values when a C<r> is executed, set C<$doret>
2679 appropriately, and force us out of the command loop.
2680
2681 =cut
2682
2683                 # r - return from the current subroutine.
2684                 $cmd =~ /^r$/ && do {
2685
2686                     # Can't do anythign if the program's over.
2687                     end_report(), next CMD if $finished and $level <= 1;
2688
2689                     # Turn on stack trace.
2690                     $stack[$stack_depth] |= 1;
2691
2692                     # Print return value unless the stack is empty.
2693                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2694                     last CMD;
2695                 };
2696
2697 =head4 C<T> - stack trace
2698
2699 Just calls C<DB::print_trace>.
2700
2701 =cut
2702
2703                 $cmd =~ /^T$/ && do {
2704                     print_trace( $OUT, 1 );    # skip DB
2705                     next CMD;
2706                 };
2707
2708 =head4 C<w> - List window around current line.
2709
2710 Just calls C<DB::cmd_w>.
2711
2712 =cut
2713
2714                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2715
2716 =head4 C<W> - watch-expression processing.
2717
2718 Just calls C<DB::cmd_W>.
2719
2720 =cut
2721
2722                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2723
2724 =head4 C</> - search forward for a string in the source
2725
2726 We take the argument and treat it as a pattern. If it turns out to be a
2727 bad one, we return the error we got from trying to C<eval> it and exit.
2728 If not, we create some code to do the search and C<eval> it so it can't
2729 mess us up.
2730
2731 =cut
2732
2733                 $cmd =~ /^\/(.*)$/ && do {
2734
2735                     # The pattern as a string.
2736                     $inpat = $1;
2737
2738                     # Remove the final slash.
2739                     $inpat =~ s:([^\\])/$:$1:;
2740
2741                     # If the pattern isn't null ...
2742                     if ( $inpat ne "" ) {
2743
2744                         # Turn of warn and die procesing for a bit.
2745                         local $SIG{__DIE__};
2746                         local $SIG{__WARN__};
2747
2748                         # Create the pattern.
2749                         eval '$inpat =~ m' . "\a$inpat\a";
2750                         if ( $@ ne "" ) {
2751
2752                             # Oops. Bad pattern. No biscuit.
2753                             # Print the eval error and go back for more
2754                             # commands.
2755                             print $OUT "$@";
2756                             next CMD;
2757                         }
2758                         $pat = $inpat;
2759                     } ## end if ($inpat ne "")
2760
2761                     # Set up to stop on wrap-around.
2762                     $end = $start;
2763
2764                     # Don't move off the current line.
2765                     $incr = -1;
2766
2767                     # Done in eval so nothing breaks if the pattern
2768                     # does something weird.
2769                     eval '
2770                         for (;;) {
2771                             # Move ahead one line.
2772                             ++$start;
2773
2774                             # Wrap if we pass the last line.
2775                             $start = 1 if ($start > $max);
2776
2777                             # Stop if we have gotten back to this line again,
2778                             last if ($start == $end);
2779
2780                             # A hit! (Note, though, that we are doing
2781                             # case-insensitive matching. Maybe a qr//
2782                             # expression would be better, so the user could
2783                             # do case-sensitive matching if desired.
2784                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2785                                 if ($slave_editor) {
2786                                     # Handle proper escaping in the slave.
2787                                     print $OUT "\032\032$filename:$start:0\n";
2788                                 }
2789                                 else {
2790                                     # Just print the line normally.
2791                                     print $OUT "$start:\t",$dbline[$start],"\n";
2792                                 }
2793                                 # And quit since we found something.
2794                                 last;
2795                             }
2796                          } ';
2797
2798                     # If we wrapped, there never was a match.
2799                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2800                     next CMD;
2801                 };
2802
2803 =head4 C<?> - search backward for a string in the source
2804
2805 Same as for C</>, except the loop runs backwards.
2806
2807 =cut
2808
2809                 # ? - backward pattern search.
2810                 $cmd =~ /^\?(.*)$/ && do {
2811
2812                     # Get the pattern, remove trailing question mark.
2813                     $inpat = $1;
2814                     $inpat =~ s:([^\\])\?$:$1:;
2815
2816                     # If we've got one ...
2817                     if ( $inpat ne "" ) {
2818
2819                         # Turn off die & warn handlers.
2820                         local $SIG{__DIE__};
2821                         local $SIG{__WARN__};
2822                         eval '$inpat =~ m' . "\a$inpat\a";
2823
2824                         if ( $@ ne "" ) {
2825
2826                             # Ouch. Not good. Print the error.
2827                             print $OUT $@;
2828                             next CMD;
2829                         }
2830                         $pat = $inpat;
2831                     } ## end if ($inpat ne "")
2832
2833                     # Where we are now is where to stop after wraparound.
2834                     $end = $start;
2835
2836                     # Don't move away from this line.
2837                     $incr = -1;
2838
2839                     # Search inside the eval to prevent pattern badness
2840                     # from killing us.
2841                     eval '
2842                         for (;;) {
2843                             # Back up a line.
2844                             --$start;
2845
2846                             # Wrap if we pass the first line.
2847
2848                             $start = $max if ($start <= 0);
2849
2850                             # Quit if we get back where we started,
2851                             last if ($start == $end);
2852
2853                             # Match?
2854                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2855                                 if ($slave_editor) {
2856                                     # Yep, follow slave editor requirements.
2857                                     print $OUT "\032\032$filename:$start:0\n";
2858                                 }
2859                                 else {
2860                                     # Yep, just print normally.
2861                                     print $OUT "$start:\t",$dbline[$start],"\n";
2862                                 }
2863
2864                                 # Found, so done.
2865                                 last;
2866                             }
2867                         } ';
2868
2869                     # Say we failed if the loop never found anything,
2870                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2871                     next CMD;
2872                 };
2873
2874 =head4 C<$rc> - Recall command
2875
2876 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2877 that the terminal supports history). It find the the command required, puts it
2878 into C<$cmd>, and redoes the loop to execute it.
2879
2880 =cut
2881
2882                 # $rc - recall command.
2883                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2884
2885                     # No arguments, take one thing off history.
2886                     pop(@hist) if length($cmd) > 1;
2887
2888                     # Relative (- found)?
2889                     #  Y - index back from most recent (by 1 if bare minus)
2890                     #  N - go to that particular command slot or the last
2891                     #      thing if nothing following.
2892                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2893
2894                     # Pick out the command desired.
2895                     $cmd = $hist[$i];
2896
2897                     # Print the command to be executed and restart the loop
2898                     # with that command in the buffer.
2899                     print $OUT $cmd, "\n";
2900                     redo CMD;
2901                 };
2902
2903 =head4 C<$sh$sh> - C<system()> command
2904
2905 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2906 C<STDOUT> from getting messed up.
2907
2908 =cut
2909
2910                 # $sh$sh - run a shell command (if it's all ASCII).
2911                 # Can't run shell commands with Unicode in the debugger, hmm.
2912                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2913
2914                     # System it.
2915                     &system($1);
2916                     next CMD;
2917                 };
2918
2919 =head4 C<$rc I<pattern> $rc> - Search command history
2920
2921 Another command to manipulate C<@hist>: this one searches it with a pattern.
2922 If a command is found, it is placed in C<$cmd> and executed via <redo>.
2923
2924 =cut
2925
2926                 # $rc pattern $rc - find a command in the history.
2927                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2928
2929                     # Create the pattern to use.
2930                     $pat = "^$1";
2931
2932                     # Toss off last entry if length is >1 (and it always is).
2933                     pop(@hist) if length($cmd) > 1;
2934
2935                     # Look backward through the history.
2936                     for ( $i = $#hist ; $i ; --$i ) {
2937
2938                         # Stop if we find it.
2939                         last if $hist[$i] =~ /$pat/;
2940                     }
2941
2942                     if ( !$i ) {
2943
2944                         # Never found it.
2945                         print $OUT "No such command!\n\n";
2946                         next CMD;
2947                     }
2948
2949                     # Found it. Put it in the buffer, print it, and process it.
2950                     $cmd = $hist[$i];
2951                     print $OUT $cmd, "\n";
2952                     redo CMD;
2953                 };
2954
2955 =head4 C<$sh> - Invoke a shell
2956
2957 Uses C<DB::system> to invoke a shell.
2958
2959 =cut
2960
2961                 # $sh - start a shell.
2962                 $cmd =~ /^$sh$/ && do {
2963
2964                     # Run the user's shell. If none defined, run Bourne.
2965                     # We resume execution when the shell terminates.
2966                     &system( $ENV{SHELL} || "/bin/sh" );
2967                     next CMD;
2968                 };
2969
2970 =head4 C<$sh I<command>> - Force execution of a command in a shell
2971
2972 Like the above, but the command is passed to the shell. Again, we use
2973 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2974
2975 =cut
2976
2977                 # $sh command - start a shell and run a command in it.
2978                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
2979
2980                     # XXX: using csh or tcsh destroys sigint retvals!
2981                     #&system($1);  # use this instead
2982
2983                     # use the user's shell, or Bourne if none defined.
2984                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
2985                     next CMD;
2986                 };
2987
2988 =head4 C<H> - display commands in history
2989
2990 Prints the contents of C<@hist> (if any).
2991
2992 =cut
2993
2994                 $cmd =~ /^H\b\s*\*/ && do {
2995                     @hist = @truehist = ();
2996                     print $OUT "History cleansed\n";
2997                     next CMD;
2998                 };
2999
3000                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3001
3002                     # Anything other than negative numbers is ignored by
3003                     # the (incorrect) pattern, so this test does nothing.
3004                     $end = $2 ? ( $#hist - $2 ) : 0;
3005
3006                     # Set to the minimum if less than zero.
3007                     $hist = 0 if $hist < 0;
3008
3009                     # Start at the end of the array.
3010                     # Stay in while we're still above the ending value.
3011                     # Tick back by one each time around the loop.
3012                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3013
3014                         # Print the command  unless it has no arguments.
3015                         print $OUT "$i: ", $hist[$i], "\n"
3016                           unless $hist[$i] =~ /^.?$/;
3017                     }
3018                     next CMD;
3019                 };
3020
3021 =head4 C<man, doc, perldoc> - look up documentation
3022
3023 Just calls C<runman()> to print the appropriate document.
3024
3025 =cut
3026
3027                 # man, perldoc, doc - show manual pages.
3028                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3029                     runman($1);
3030                     next CMD;
3031                 };
3032
3033 =head4 C<p> - print
3034
3035 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3036 the bottom of the loop.
3037
3038 =cut
3039
3040                 # p - print (no args): print $_.
3041                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3042
3043                 # p - print the given expression.
3044                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3045
3046 =head4 C<=> - define command alias
3047
3048 Manipulates C<%alias> to add or list command aliases.
3049
3050 =cut
3051
3052                 # = - set up a command alias.
3053                 $cmd =~ s/^=\s*// && do {
3054                     my @keys;
3055                     if ( length $cmd == 0 ) {
3056
3057                         # No args, get current aliases.
3058                         @keys = sort keys %alias;
3059                     }
3060                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3061
3062                         # Creating a new alias. $k is alias name, $v is
3063                         # alias value.
3064
3065                         # can't use $_ or kill //g state
3066                         for my $x ( $k, $v ) {
3067
3068                             # Escape "alarm" characters.
3069                             $x =~ s/\a/\\a/g;
3070                         }
3071
3072                         # Substitute key for value, using alarm chars
3073                         # as separators (which is why we escaped them in
3074                         # the command).
3075                         $alias{$k} = "s\a$k\a$v\a";
3076
3077                         # Turn off standard warn and die behavior.
3078                         local $SIG{__DIE__};
3079                         local $SIG{__WARN__};
3080
3081                         # Is it valid Perl?
3082                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3083
3084                             # Nope. Bad alias. Say so and get out.
3085                             print $OUT "Can't alias $k to $v: $@\n";
3086                             delete $alias{$k};
3087                             next CMD;
3088                         }
3089
3090                         # We'll only list the new one.
3091                         @keys = ($k);
3092                     } ## end elsif (my ($k, $v) = ($cmd...
3093
3094                     # The argument is the alias to list.
3095                     else {
3096                         @keys = ($cmd);
3097                     }
3098
3099                     # List aliases.
3100                     for my $k (@keys) {
3101
3102                         # Messy metaquoting: Trim the substiution code off.
3103                         # We use control-G as the delimiter because it's not
3104                         # likely to appear in the alias.
3105                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3106
3107                             # Print the alias.
3108                             print $OUT "$k\t= $1\n";
3109                         }
3110                         elsif ( defined $alias{$k} ) {
3111
3112                             # Couldn't trim it off; just print the alias code.
3113                             print $OUT "$k\t$alias{$k}\n";
3114                         }
3115                         else {
3116
3117                             # No such, dude.
3118                             print "No alias for $k\n";
3119                         }
3120                     } ## end for my $k (@keys)
3121                     next CMD;
3122                 };
3123
3124 =head4 C<source> - read commands from a file.
3125
3126 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3127 pick it up.
3128
3129 =cut
3130
3131                 # source - read commands from a file (or pipe!) and execute.
3132                 $cmd =~ /^source\s+(.*\S)/ && do {
3133                     if ( open my $fh, $1 ) {
3134
3135                         # Opened OK; stick it in the list of file handles.
3136                         push @cmdfhs, $fh;
3137                     }
3138                     else {
3139
3140                         # Couldn't open it.
3141                         &warn("Can't execute `$1': $!\n");
3142                     }
3143                     next CMD;
3144                 };
3145
3146 =head4 C<save> - send current history to a file
3147
3148 Takes the complete history, (not the shrunken version you see with C<H>),
3149 and saves it to the given filename, so it can be replayed using C<source>.
3150
3151 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3152
3153 =cut
3154
3155                 # save source - write commands to a file for later use
3156                 $cmd =~ /^save\s*(.*)$/ && do {
3157                     my $file = $1 || '.perl5dbrc';    # default?
3158                     if ( open my $fh, "> $file" ) {
3159
3160                        # chomp to remove extraneous newlines from source'd files
3161                         chomp( my @truelist =
3162                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3163                               @truehist );
3164                         print $fh join( "\n", @truelist );
3165                         print "commands saved in $file\n";
3166                     }
3167                     else {
3168                         &warn("Can't save debugger commands in '$1': $!\n");
3169                     }
3170                     next CMD;
3171                 };
3172
3173 =head4 C<R> - restart
3174
3175 Restart the debugger session.
3176
3177 =head4 C<rerun> - rerun the current session
3178
3179 Return to any given position in the B<true>-history list
3180
3181 =cut
3182
3183                 # R - restart execution.
3184                 # rerun - controlled restart execution.
3185                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3186                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3187
3188                     # And run Perl again.  We use exec() to keep the
3189                     # PID stable (and that way $ini_pids is still valid).
3190                     exec(@args) || print $OUT "exec failed: $!\n";
3191
3192                     last CMD;
3193                 };
3194
3195 =head4 C<|, ||> - pipe output through the pager.
3196
3197 FOR C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3198 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3199 pipe to the pager (restoring the output filehandles if this fails). If this
3200 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3201 set C<$signal>, sending us back into the debugger.
3202
3203 We then trim off the pipe symbols and C<redo> the command loop at the
3204 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3205 reading another.
3206
3207 =cut
3208
3209                 # || - run command in the pager, with output to DB::OUT.
3210                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3211                     if ( $pager =~ /^\|/ ) {
3212
3213                         # Default pager is into a pipe. Redirect I/O.
3214                         open( SAVEOUT, ">&STDOUT" )
3215                           || &warn("Can't save STDOUT");
3216                         open( STDOUT, ">&OUT" )
3217                           || &warn("Can't redirect STDOUT");
3218                     } ## end if ($pager =~ /^\|/)
3219                     else {
3220
3221                         # Not into a pipe. STDOUT is safe.
3222                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3223                     }
3224
3225                     # Fix up environment to record we have less if so.
3226                     fix_less();
3227
3228                     unless ( $piped = open( OUT, $pager ) ) {
3229
3230                         # Couldn't open pipe to pager.
3231                         &warn("Can't pipe output to `$pager'");
3232                         if ( $pager =~ /^\|/ ) {
3233
3234                             # Redirect I/O back again.
3235                             open( OUT, ">&STDOUT" )    # XXX: lost message
3236                               || &warn("Can't restore DB::OUT");
3237                             open( STDOUT, ">&SAVEOUT" )
3238                               || &warn("Can't restore STDOUT");
3239                             close(SAVEOUT);
3240                         } ## end if ($pager =~ /^\|/)
3241                         else {
3242
3243                             # Redirect I/O. STDOUT already safe.
3244                             open( OUT, ">&STDOUT" )    # XXX: lost message
3245                               || &warn("Can't restore DB::OUT");
3246                         }
3247                         next CMD;
3248                     } ## end unless ($piped = open(OUT,...
3249
3250                     # Set up broken-pipe handler if necessary.
3251                     $SIG{PIPE} = \&DB::catch
3252                       if $pager =~ /^\|/
3253                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3254
3255                     # Save current filehandle, unbuffer out, and put it back.
3256                     $selected = select(OUT);
3257                     $|        = 1;
3258
3259                     # Don't put it back if pager was a pipe.
3260                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3261
3262                     # Trim off the pipe symbols and run the command now.
3263                     $cmd =~ s/^\|+\s*//;
3264                     redo PIPE;
3265                 };
3266
3267 =head3 END OF COMMAND PARSING
3268
3269 Anything left in C<$cmd> at this point is a Perl expression that we want to
3270 evaluate. We'll always evaluate in the user's context, and fully qualify
3271 any variables we might want to address in the C<DB> package.
3272
3273 =cut
3274
3275                 # t - turn trace on.
3276                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3277
3278                 # s - single-step. Remember the last command was 's'.
3279                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3280
3281                 # n - single-step, but not into subs. Remember last command
3282                 # was 'n'.
3283                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3284
3285             }    # PIPE:
3286
3287             # Make sure the flag that says "the debugger's running" is
3288             # still on, to make sure we get control again.
3289             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3290
3291             # Run *our* eval that executes in the caller's context.
3292             &eval;
3293
3294             # Turn off the one-time-dump stuff now.
3295             if ($onetimeDump) {
3296                 $onetimeDump      = undef;
3297                 $onetimedumpDepth = undef;
3298             }
3299             elsif ( $term_pid == $$ ) {
3300                 STDOUT->flush();
3301                 STDERR->flush();
3302
3303                 # XXX If this is the master pid, print a newline.
3304                 print $OUT "\n";
3305             }
3306         } ## end while (($term || &setterm...
3307
3308 =head3 POST-COMMAND PROCESSING
3309
3310 After each command, we check to see if the command output was piped anywhere.
3311 If so, we go through the necessary code to unhook the pipe and go back to
3312 our standard filehandles for input and output.
3313
3314 =cut
3315
3316         continue {    # CMD:
3317
3318             # At the end of every command:
3319             if ($piped) {
3320
3321                 # Unhook the pipe mechanism now.
3322                 if ( $pager =~ /^\|/ ) {
3323
3324                     # No error from the child.
3325                     $? = 0;
3326
3327                     # we cannot warn here: the handle is missing --tchrist
3328                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3329
3330                     # most of the $? crud was coping with broken cshisms
3331                     # $? is explicitly set to 0, so this never runs.
3332                     if ($?) {
3333                         print SAVEOUT "Pager `$pager' failed: ";
3334                         if ( $? == -1 ) {
3335                             print SAVEOUT "shell returned -1\n";
3336                         }
3337                         elsif ( $? >> 8 ) {
3338                             print SAVEOUT ( $? & 127 )
3339                               ? " (SIG#" . ( $? & 127 ) . ")"
3340                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3341                         }
3342                         else {
3343                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3344                         }
3345                     } ## end if ($?)
3346
3347                     # Reopen filehandle for our output (if we can) and
3348                     # restore STDOUT (if we can).
3349                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3350                     open( STDOUT, ">&SAVEOUT" )
3351                       || &warn("Can't restore STDOUT");
3352
3353                     # Turn off pipe exception handler if necessary.
3354                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3355
3356                     # Will stop ignoring SIGPIPE if done like nohup(1)
3357                     # does SIGINT but Perl doesn't give us a choice.
3358                 } ## end if ($pager =~ /^\|/)
3359                 else {
3360
3361                     # Non-piped "pager". Just restore STDOUT.
3362                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3363                 }
3364
3365                 # Close filehandle pager was using, restore the normal one
3366                 # if necessary,
3367                 close(SAVEOUT);
3368                 select($selected), $selected = "" unless $selected eq "";
3369
3370                 # No pipes now.
3371                 $piped = "";
3372             } ## end if ($piped)
3373         }    # CMD:
3374
3375 =head3 COMMAND LOOP TERMINATION
3376
3377 When commands have finished executing, we come here. If the user closed the
3378 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3379 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3380 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3381 The interpreter will then execute the next line and then return control to us
3382 again.
3383
3384 =cut
3385
3386         # No more commands? Quit.
3387         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3388
3389         # Evaluate post-prompt commands.
3390         foreach $evalarg (@$post) {
3391             &eval;
3392         }
3393     }    # if ($single || $signal)
3394
3395     # Put the user's globals back where you found them.
3396     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3397     ();
3398 } ## end sub DB
3399
3400 # The following code may be executed now:
3401 # BEGIN {warn 4}
3402
3403 =head2 sub
3404
3405 C<sub> is called whenever a subroutine call happens in the program being
3406 debugged. The variable C<$DB::sub> contains the name of the subroutine
3407 being called.
3408
3409 The core function of this subroutine is to actually call the sub in the proper
3410 context, capturing its output. This of course causes C<DB::DB> to get called
3411 again, repeating until the subroutine ends and returns control to C<DB::sub>
3412 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3413 return value, and returns its captured copy of the return value as its own
3414 return value. The value then feeds back into the program being debugged as if
3415 C<DB::sub> hadn't been there at all.
3416
3417 C<sub> does all the work of printing the subroutine entry and exit messages
3418 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3419 and also prints the return value if needed (for the C<r> command and if
3420 the 16 bit is set in C<$frame>).
3421
3422 It also tracks the subroutine call depth by saving the current setting of
3423 C<$single> in the C<@stack> package global; if this exceeds the value in
3424 C<$deep>, C<sub> automatically turns on printing of the current depth by
3425 setting the 4 bit in C<$single>. In any case, it keeps the current setting
3426 of stop/don't stop on entry to subs set as it currently is set.
3427
3428 =head3 C<caller()> support
3429
3430 If C<caller()> is called from the package C<DB>, it provides some
3431 additional data, in the following order:
3432
3433 =over 4
3434
3435 =item * C<$package>
3436
3437 The package name the sub was in
3438
3439 =item * C<$filename>
3440
3441 The filename it was defined in
3442
3443 =item * C<$line>
3444
3445 The line number it was defined on
3446
3447 =item * C<$subroutine>
3448
3449 The subroutine name; C<'(eval)'> if an C<eval>().
3450
3451 =item * C<$hasargs>
3452
3453 1 if it has arguments, 0 if not
3454
3455 =item * C<$wantarray>
3456
3457 1 if array context, 0 if scalar context
3458
3459 =item * C<$evaltext>
3460
3461 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3462
3463 =item * C<$is_require>
3464
3465 frame was created by a C<use> or C<require> statement
3466
3467 =item * C<$hints>
3468
3469 pragma information; subject to change between versions
3470
3471 =item * C<$bitmask>
3472
3473 pragma information: subject to change between versions
3474
3475 =item * C<@DB::args>
3476
3477 arguments with which the subroutine was invoked
3478
3479 =back
3480
3481 =cut
3482
3483 sub sub {
3484
3485     # Whether or not the autoloader was running, a scalar to put the
3486     # sub's return value in (if needed), and an array to put the sub's
3487     # return value in (if needed).
3488     my ( $al, $ret, @ret ) = "";
3489
3490     # If the last ten characters are C'::AUTOLOAD', note we've traced
3491     # into AUTOLOAD for $sub.
3492     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3493         $al = " for $$sub";
3494     }
3495
3496     # We stack the stack pointer and then increment it to protect us
3497     # from a situation that might unwind a whole bunch of call frames
3498     # at once. Localizing the stack pointer means that it will automatically
3499     # unwind the same amount when multiple stack frames are unwound.
3500     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3501
3502     # Expand @stack.
3503     $#stack = $stack_depth;
3504
3505     # Save current single-step setting.
3506     $stack[-1] = $single;
3507
3508     # Turn off all flags except single-stepping.
3509     $single &= 1;
3510
3511     # If we've gotten really deeply recursed, turn on the flag that will
3512     # make us stop with the 'deep recursion' message.
3513     $single |= 4 if $stack_depth == $deep;
3514
3515     # If frame messages are on ...
3516     (
3517         $frame & 4    # Extended frame entry message
3518         ? (
3519             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3520
3521             # Why -1? But it works! :-(
3522             # Because print_trace will call add 1 to it and then call
3523             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3524             # in dump_trace.
3525             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3526           )
3527         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3528
3529           # standard frame entry message
3530       )
3531       if $frame;
3532
3533     # Determine the sub's return type,and capture approppriately.
3534     if (wantarray) {
3535
3536         # Called in array context. call sub and capture output.
3537         # DB::DB will recursively get control again if appropriate; we'll come
3538         # back here when the sub is finished.
3539         if ($assertion) {
3540             $assertion = 0;
3541             eval { @ret = &$sub; };
3542             if ($@) {
3543                 print $OUT $@;
3544                 $signal = 1 unless $warnassertions;
3545             }
3546         }
3547         else {
3548             @ret = &$sub;
3549         }
3550
3551         # Pop the single-step value back off the stack.
3552         $single |= $stack[ $stack_depth-- ];
3553
3554         # Check for exit trace messages...
3555         (
3556             $frame & 4    # Extended exit message
3557             ? (
3558                 print_lineinfo( ' ' x $stack_depth, "out " ),
3559                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3560               )
3561             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3562
3563               # Standard exit message
3564           )
3565           if $frame & 2;
3566
3567         # Print the return info if we need to.
3568         if ( $doret eq $stack_depth or $frame & 16 ) {
3569
3570             # Turn off output record separator.
3571             local $\ = '';
3572             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3573
3574             # Indent if we're printing because of $frame tracing.
3575             print $fh ' ' x $stack_depth if $frame & 16;
3576
3577             # Print the return value.
3578             print $fh "list context return from $sub:\n";
3579             dumpit( $fh, \@ret );
3580
3581             # And don't print it again.
3582             $doret = -2;
3583         } ## end if ($doret eq $stack_depth...
3584             # And we have to return the return value now.
3585         @ret;
3586     } ## end if (wantarray)
3587
3588     # Scalar context.
3589     else {
3590         if ($assertion) {
3591             $assertion = 0;
3592             eval {
3593
3594                 # Save the value if it's wanted at all.
3595                 $ret = &$sub;
3596             };
3597             if ($@) {
3598                 print $OUT $@;
3599                 $signal = 1 unless $warnassertions;
3600             }
3601             $ret = undef unless defined wantarray;
3602         }
3603         else {
3604             if ( defined wantarray ) {
3605
3606                 # Save the value if it's wanted at all.
3607                 $ret = &$sub;
3608             }
3609             else {
3610
3611                 # Void return, explicitly.
3612                 &$sub;
3613                 undef $ret;
3614             }
3615         }    # if assertion
3616
3617         # Pop the single-step value off the stack.
3618         $single |= $stack[ $stack_depth-- ];
3619
3620         # If we're doing exit messages...
3621         (
3622             $frame & 4    # Extended messsages
3623             ? (
3624                 print_lineinfo( ' ' x $stack_depth, "out " ),
3625                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3626               )
3627             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3628
3629               # Standard messages
3630           )
3631           if $frame & 2;
3632
3633         # If we are supposed to show the return value... same as before.
3634         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3635             local $\ = '';
3636             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3637             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3638             print $fh (
3639                 defined wantarray
3640                 ? "scalar context return from $sub: "
3641                 : "void context return from $sub\n"
3642             );
3643             dumpit( $fh, $ret ) if defined wantarray;
3644             $doret = -2;
3645         } ## end if ($doret eq $stack_depth...
3646
3647         # Return the appropriate scalar value.
3648         $ret;
3649     } ## end else [ if (wantarray)
3650 } ## end sub sub
3651
3652 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3653
3654 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3655 Most of the changes were to systematize the command structure and to eliminate
3656 commands that threw away user input without checking.
3657
3658 The following sections describe the code added to make it easy to support
3659 multiple command sets with conflicting command names. This section is a start
3660 at unifying all command processing to make it simpler to develop commands.
3661
3662 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3663 number, and C<$dbline> (the current line) as arguments.
3664
3665 Support functions in this section which have multiple modes of failure C<die>
3666 on error; the rest simply return a false value.
3667
3668 The user-interface functions (all of the C<cmd_*> functions) just output
3669 error messages.
3670
3671 =head2 C<%set>
3672
3673 The C<%set> hash defines the mapping from command letter to subroutine
3674 name suffix.
3675
3676 C<%set> is a two-level hash, indexed by set name and then by command name.
3677 Note that trying to set the CommandSet to 'foobar' simply results in the
3678 5.8.0 command set being used, since there's no top-level entry for 'foobar'.
3679
3680 =cut
3681
3682 ### The API section
3683
3684 my %set = (    #
3685     'pre580' => {
3686         'a' => 'pre580_a',
3687         'A' => 'pre580_null',
3688         'b' => 'pre580_b',
3689         'B' => 'pre580_null',
3690         'd' => 'pre580_null',
3691         'D' => 'pre580_D',
3692         'h' => 'pre580_h',
3693         'M' => 'pre580_null',
3694         'O' => 'o',
3695         'o' => 'pre580_null',
3696         'v' => 'M',
3697         'w' => 'v',
3698         'W' => 'pre580_W',
3699     },
3700     'pre590' => {
3701         '<'  => 'pre590_prepost',
3702         '<<' => 'pre590_prepost',
3703         '>'  => 'pre590_prepost',
3704         '>>' => 'pre590_prepost',
3705         '{'  => 'pre590_prepost',
3706         '{{' => 'pre590_prepost',
3707     },
3708 );
3709
3710 =head2 C<cmd_wrapper()> (API)
3711
3712 C<cmd_wrapper()> allows the debugger to switch command sets
3713 depending on the value of the C<CommandSet> option.
3714
3715 It tries to look up the command in the X<C<%set>> package-level I<lexical>
3716 (which means external entities can't fiddle with it) and create the name of
3717 the sub to call based on the value found in the hash (if it's there). I<All>
3718 of the commands to be handled in a set have to be added to C<%set>; if they
3719 aren't found, the 5.8.0 equivalent is called (if there is one).
3720
3721 This code uses symbolic references.
3722
3723 =cut
3724
3725 sub cmd_wrapper {
3726     my $cmd      = shift;
3727     my $line     = shift;
3728     my $dblineno = shift;
3729
3730     # Assemble the command subroutine's name by looking up the
3731     # command set and command name in %set. If we can't find it,
3732     # default to the older version of the command.
3733     my $call = 'cmd_'
3734       . ( $set{$CommandSet}{$cmd}
3735           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3736
3737     # Call the command subroutine, call it by name.
3738     return &$call( $cmd, $line, $dblineno );
3739 } ## end sub cmd_wrapper
3740
3741 =head3 C<cmd_a> (command)
3742
3743 The C<a> command handles pre-execution actions. These are associated with a
3744 particular line, so they're stored in C<%dbline>. We default to the current
3745 line if none is specified.
3746
3747 =cut
3748
3749 sub cmd_a {
3750     my $cmd    = shift;
3751     my $line   = shift || '';    # [.|line] expr
3752     my $dbline = shift;
3753
3754     # If it's dot (here), or not all digits,  use the current line.
3755     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3756
3757     # Should be a line number followed by an expression.
3758     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3759         my ( $lineno, $expr ) = ( $1, $2 );
3760
3761         # If we have an expression ...
3762         if ( length $expr ) {
3763
3764             # ... but the line isn't breakable, complain.
3765             if ( $dbline[$lineno] == 0 ) {
3766                 print $OUT
3767                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3768             }
3769             else {
3770
3771                 # It's executable. Record that the line has an action.
3772                 $had_breakpoints{$filename} |= 2;
3773
3774                 # Remove any action, temp breakpoint, etc.
3775                 $dbline{$lineno} =~ s/\0[^\0]*//;
3776
3777                 # Add the action to the line.
3778                 $dbline{$lineno} .= "\0" . action($expr);
3779             }
3780         } ## end if (length $expr)
3781     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3782     else {
3783
3784         # Syntax wrong.
3785         print $OUT
3786           "Adding an action requires an optional lineno and an expression\n"
3787           ;    # hint
3788     }
3789 } ## end sub cmd_a
3790
3791 =head3 C<cmd_A> (command)
3792
3793 Delete actions. Similar to above, except the delete code is in a separate
3794 subroutine, C<delete_action>.
3795
3796 =cut
3797
3798 sub cmd_A {
3799     my $cmd    = shift;
3800     my $line   = shift || '';
3801     my $dbline = shift;
3802
3803     # Dot is this line.
3804     $line =~ s/^\./$dbline/;
3805
3806     # Call delete_action with a null param to delete them all.
3807     # The '1' forces the eval to be true. It'll be false only
3808     # if delete_action blows up for some reason, in which case
3809     # we print $@ and get out.
3810     if ( $line eq '*' ) {
3811         eval { &delete_action(); 1 } or print $OUT $@ and return;
3812     }
3813
3814     # There's a real line  number. Pass it to delete_action.
3815     # Error trapping is as above.
3816     elsif ( $line =~ /^(\S.*)/ ) {
3817         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3818     }
3819
3820     # Swing and a miss. Bad syntax.
3821     else {
3822         print $OUT
3823           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3824     }
3825 } ## end sub cmd_A
3826
3827 =head3 C<delete_action> (API)
3828
3829 C<delete_action> accepts either a line number or C<undef>. If a line number
3830 is specified, we check for the line being executable (if it's not, it
3831 couldn't have had an  action). If it is, we just take the action off (this
3832 will get any kind of an action, including breakpoints).
3833
3834 =cut
3835
3836 sub delete_action {
3837     my $i = shift;
3838     if ( defined($i) ) {
3839
3840         # Can there be one?
3841         die "Line $i has no action .\n" if $dbline[$i] == 0;
3842
3843         # Nuke whatever's there.
3844         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3845         delete $dbline{$i} if $dbline{$i} eq '';
3846     }
3847     else {
3848         print $OUT "Deleting all actions...\n";
3849         for my $file ( keys %had_breakpoints ) {
3850             local *dbline = $main::{ '_<' . $file };
3851             my $max = $#dbline;
3852             my $was;
3853             for ( $i = 1 ; $i <= $max ; $i++ ) {
3854                 if ( defined $dbline{$i} ) {
3855                     $dbline{$i} =~ s/\0[^\0]*//;
3856                     delete $dbline{$i} if $dbline{$i} eq '';
3857                 }
3858                 unless ( $had_breakpoints{$file} &= ~2 ) {
3859                     delete $had_breakpoints{$file};
3860                 }
3861             } ## end for ($i = 1 ; $i <= $max...
3862         } ## end for my $file (keys %had_breakpoints)
3863     } ## end else [ if (defined($i))
3864 } ## end sub delete_action
3865
3866 =head3 C<cmd_b> (command)
3867
3868 Set breakpoints. Since breakpoints can be set in so many places, in so many
3869 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
3870 we try to parse the command type, and then shuttle it off to an appropriate
3871 subroutine to actually do the work of setting the breakpoint in the right
3872 place.
3873
3874 =cut
3875
3876 sub cmd_b {
3877     my $cmd    = shift;
3878     my $line   = shift;    # [.|line] [cond]
3879     my $dbline = shift;
3880
3881     # Make . the current line number if it's there..
3882     $line =~ s/^\./$dbline/;
3883
3884     # No line number, no condition. Simple break on current line.
3885     if ( $line =~ /^\s*$/ ) {
3886         &cmd_b_line( $dbline, 1 );
3887     }
3888
3889     # Break on load for a file.
3890     elsif ( $line =~ /^load\b\s*(.*)/ ) {
3891         my $file = $1;
3892         $file =~ s/\s+$//;
3893         &cmd_b_load($file);
3894     }
3895
3896     # b compile|postpone <some sub> [<condition>]
3897     # The interpreter actually traps this one for us; we just put the
3898     # necessary condition in the %postponed hash.
3899     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
3900
3901         # Capture the condition if there is one. Make it true if none.
3902         my $cond = length $3 ? $3 : '1';
3903
3904         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
3905         # if it was 'compile'.
3906         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
3907
3908         # De-Perl4-ify the name - ' separators to ::.
3909         $subname =~ s/\'/::/g;
3910
3911         # Qualify it into the current package unless it's already qualified.
3912         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
3913
3914         # Add main if it starts with ::.
3915         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
3916
3917         # Save the break type for this sub.
3918         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
3919     } ## end elsif ($line =~ ...
3920
3921     # b <sub name> [<condition>]
3922     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
3923
3924         #
3925         $subname = $1;
3926         $cond = length $2 ? $2 : '1';
3927         &cmd_b_sub( $subname, $cond );
3928     }
3929
3930     # b <line> [<condition>].
3931     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
3932
3933         # Capture the line. If none, it's the current line.
3934         $line = $1 || $dbline;
3935
3936         # If there's no condition, make it '1'.
3937         $cond = length $2 ? $2 : '1';
3938
3939         # Break on line.
3940         &cmd_b_line( $line, $cond );
3941     }
3942
3943     # Line didn't make sense.
3944     else {
3945         print "confused by line($line)?\n";
3946     }
3947 } ## end sub cmd_b
3948
3949 =head3 C<break_on_load> (API)
3950
3951 We want to break when this file is loaded. Mark this file in the
3952 C<%break_on_load> hash, and note that it has a breakpoint in
3953 C<%had_breakpoints>.
3954
3955 =cut
3956
3957 sub break_on_load {
3958     my $file = shift;
3959     $break_on_load{$file} = 1;
3960     $had_breakpoints{$file} |= 1;
3961 }
3962
3963 =head3 C<report_break_on_load> (API)
3964
3965 Gives us an array of filenames that are set to break on load. Note that
3966 only files with break-on-load are in here, so simply showing the keys
3967 suffices.
3968
3969 =cut
3970
3971 sub report_break_on_load {
3972     sort keys %break_on_load;
3973 }
3974
3975 =head3 C<cmd_b_load> (command)
3976
3977 We take the file passed in and try to find it in C<%INC> (which maps modules
3978 to files they came from). We mark those files for break-on-load via
3979 C<break_on_load> and then report that it was done.
3980
3981 =cut
3982
3983 sub cmd_b_load {
3984     my $file = shift;
3985     my @files;
3986
3987     # This is a block because that way we can use a redo inside it
3988     # even without there being any looping structure at all outside it.
3989     {
3990
3991         # Save short name and full path if found.
3992         push @files, $file;
3993         push @files, $::INC{$file} if $::INC{$file};
3994
3995         # Tack on .pm and do it again unless there was a '.' in the name
3996         # already.
3997         $file .= '.pm', redo unless $file =~ /\./;
3998     }
3999
4000     # Do the real work here.
4001     break_on_load($_) for @files;
4002
4003     # All the files that have break-on-load breakpoints.
4004     @files = report_break_on_load;
4005
4006     # Normalize for the purposes of our printing this.
4007     local $\ = '';
4008     local $" = ' ';
4009     print $OUT "Will stop on load of `@files'.\n";
4010 } ## end sub cmd_b_load
4011
4012 =head3 C<$filename_error> (API package global)
4013
4014 Several of the functions we need to implement in the API need to work both
4015 on the current file and on other files. We don't want to duplicate code, so
4016 C<$filename_error> is used to contain the name of the file that's being
4017 worked on (if it's not the current one).
4018
4019 We can now build functions in pairs: the basic function works on the current
4020 file, and uses C<$filename_error> as part of its error message. Since this is
4021 initialized to C<''>, no filename will appear when we are working on the
4022 current file.
4023
4024 The second function is a wrapper which does the following:
4025
4026 =over 4
4027
4028 =item * Localizes C<$filename_error> and sets it to the name of the file to be processed.
4029
4030 =item * Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4031
4032 =item * Calls the first function.
4033
4034 The first function works on the "current" (i.e., the one we changed to) file,
4035 and prints C<$filename_error> in the error message (the name of the other file)
4036 if it needs to. When the functions return, C<*dbline> is restored to point to the actual current file (the one we're executing in) and C<$filename_error> is
4037 restored to C<''>. This restores everything to the way it was before the
4038 second function was called at all.
4039
4040 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4041 details.
4042
4043 =back
4044
4045 =cut
4046
4047 $filename_error = '';
4048
4049 =head3 breakable_line($from, $to) (API)
4050
4051 The subroutine decides whether or not a line in the current file is breakable.
4052 It walks through C<@dbline> within the range of lines specified, looking for
4053 the first line that is breakable.
4054
4055 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4056 first line I<after> C<$to> that's breakable, if there is one.
4057
4058 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4059 first line I<before> C<$to> that's breakable, if there is one.
4060
4061 =cut
4062
4063 sub breakable_line {
4064
4065     my ( $from, $to ) = @_;
4066
4067     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4068     my $i = $from;
4069
4070     # If there are at least 2 arguments, we're trying to search a range.
4071     if ( @_ >= 2 ) {
4072
4073         # $delta is positive for a forward search, negative for a backward one.
4074         my $delta = $from < $to ? +1 : -1;
4075
4076         # Keep us from running off the ends of the file.
4077         my $limit = $delta > 0 ? $#dbline : 1;
4078
4079         # Clever test. If you're a mathematician, it's obvious why this
4080         # test works. If not:
4081         # If $delta is positive (going forward), $limit will be $#dbline.
4082         #    If $to is less than $limit, ($limit - $to) will be positive, times
4083         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4084         #    as the stopping point.
4085         #
4086         #    If $to is greater than $limit, ($limit - $to) is negative,
4087         #    times $delta of 1 (positive), so the result is < 0 and we should
4088         #    use $limit ($#dbline) as the stopping point.
4089         #
4090         # If $delta is negative (going backward), $limit will be 1.
4091         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4092         #    (negative) so the result is > 0, and we use $to as the stopping
4093         #    point.
4094         #
4095         #    If $to is less than zero, ($limit - $to) will be positive,
4096         #    times $delta of -1 (negative), so the result is not > 0, and
4097         #    we use $limit (1) as the stopping point.
4098         #
4099         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4100         #    (negative), still giving zero; the result is not > 0, and
4101         #    we use $limit (1) as the stopping point.
4102         #
4103         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4104         #    (negative), giving a positive (>0) value, so we'll set $limit to
4105         #    $to.
4106
4107         $limit = $to if ( $limit - $to ) * $delta > 0;
4108
4109         # The real search loop.
4110         # $i starts at $from (the point we want to start searching from).
4111         # We move through @dbline in the appropriate direction (determined
4112         # by $delta: either -1 (back) or +1 (ahead).
4113         # We stay in as long as we haven't hit an executable line
4114         # ($dbline[$i] == 0 means not executable) and we haven't reached
4115         # the limit yet (test similar to the above).
4116         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4117
4118     } ## end if (@_ >= 2)
4119
4120     # If $i points to a line that is executable, return that.
4121     return $i unless $dbline[$i] == 0;
4122
4123     # Format the message and print it: no breakable lines in range.
4124     my ( $pl, $upto ) = ( '', '' );
4125     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4126
4127     # If there's a filename in filename_error, we'll see it.
4128     # If not, not.
4129     die "Line$pl $from$upto$filename_error not breakable\n";
4130 } ## end sub breakable_line
4131
4132 =head3 breakable_line_in_filename($file, $from, $to) (API)
4133
4134 Like C<breakable_line>, but look in another file.
4135
4136 =cut
4137
4138 sub breakable_line_in_filename {
4139
4140     # Capture the file name.
4141     my ($f) = shift;
4142
4143     # Swap the magic line array over there temporarily.
4144     local *dbline = $main::{ '_<' . $f };
4145
4146     # If there's an error, it's in this other file.
4147     local $filename_error = " of `$f'";
4148
4149     # Find the breakable line.
4150     breakable_line(@_);
4151
4152     # *dbline and $filename_error get restored when this block ends.
4153
4154 } ## end sub breakable_line_in_filename
4155
4156 =head3 break_on_line(lineno, [condition]) (API)
4157
4158 Adds a breakpoint with the specified condition (or 1 if no condition was
4159 specified) to the specified line. Dies if it can't.
4160
4161 =cut
4162
4163 sub break_on_line {
4164     my ( $i, $cond ) = @_;
4165
4166     # Always true if no condition supplied.
4167     $cond = 1 unless @_ >= 2;
4168
4169     my $inii  = $i;
4170     my $after = '';
4171     my $pl    = '';
4172
4173     # Woops, not a breakable line. $filename_error allows us to say
4174     # if it was in a different file.
4175     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4176
4177     # Mark this file as having breakpoints in it.
4178     $had_breakpoints{$filename} |= 1;
4179
4180     # If there is an action or condition here already ...
4181     if ( $dbline{$i} ) {
4182
4183         # ... swap this condition for the existing one.
4184         $dbline{$i} =~ s/^[^\0]*/$cond/;
4185     }
4186     else {
4187
4188         # Nothing here - just add the condition.
4189         $dbline{$i} = $cond;
4190     }
4191 } ## end sub break_on_line
4192
4193 =head3 cmd_b_line(line, [condition]) (command)
4194
4195 Wrapper for C<break_on_line>. Prints the failure message if it
4196 doesn't work.
4197
4198 =cut
4199
4200 sub cmd_b_line {
4201     eval { break_on_line(@_); 1 } or do {
4202         local $\ = '';
4203         print $OUT $@ and return;
4204     };
4205 } ## end sub cmd_b_line
4206
4207 =head3 break_on_filename_line(file, line, [condition]) (API)
4208
4209 Switches to the file specified and then calls C<break_on_line> to set
4210 the breakpoint.
4211
4212 =cut
4213
4214 sub break_on_filename_line {
4215     my ( $f, $i, $cond ) = @_;
4216
4217     # Always true if condition left off.
4218     $cond = 1 unless @_ >= 3;
4219
4220     # Switch the magical hash temporarily.
4221     local *dbline = $main::{ '_<' . $f };
4222
4223     # Localize the variables that break_on_line uses to make its message.
4224     local $filename_error = " of `$f'";
4225     local $filename       = $f;
4226
4227     # Add the breakpoint.
4228     break_on_line( $i, $cond );
4229 } ## end sub break_on_filename_line
4230
4231 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4232
4233 Switch to another file, search the range of lines specified for an
4234 executable one, and put a breakpoint on the first one you find.
4235
4236 =cut
4237
4238 sub break_on_filename_line_range {
4239     my ( $f, $from, $to, $cond ) = @_;
4240
4241     # Find a breakable line if there is one.
4242     my $i = breakable_line_in_filename( $f, $from, $to );
4243
4244     # Always true if missing.
4245     $cond = 1 unless @_ >= 3;
4246
4247     # Add the breakpoint.
4248     break_on_filename_line( $f, $i, $cond );
4249 } ## end sub break_on_filename_line_range
4250
4251 =head3 subroutine_filename_lines(subname, [condition]) (API)
4252
4253 Search for a subroutine within a given file. The condition is ignored.
4254 Uses C<find_sub> to locate the desired subroutine.
4255
4256 =cut
4257
4258 sub subroutine_filename_lines {
4259     my ( $subname, $cond ) = @_;
4260
4261     # Returned value from find_sub() is fullpathname:startline-endline.
4262     # The match creates the list (fullpathname, start, end). Falling off
4263     # the end of the subroutine returns this implicitly.
4264     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4265 } ## end sub subroutine_filename_lines
4266
4267 =head3 break_subroutine(subname) (API)
4268
4269 Places a break on the first line possible in the specified subroutine. Uses
4270 C<subroutine_filename_lines> to find the subroutine, and
4271 C<break_on_filename_line_range> to place the break.
4272
4273 =cut
4274
4275 sub break_subroutine {
4276     my $subname = shift;
4277
4278     # Get filename, start, and end.
4279     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4280       or die "Subroutine $subname not found.\n";
4281
4282     # Null condition changes to '1' (always true).
4283     $cond = 1 unless @_ >= 2;
4284
4285     # Put a break the first place possible in the range of lines
4286     # that make up this subroutine.
4287     break_on_filename_line_range( $file, $s, $e, @_ );
4288 } ## end sub break_subroutine
4289
4290 =head3 cmd_b_sub(subname, [condition]) (command)
4291
4292 We take the incoming subroutine name and fully-qualify it as best we can.
4293
4294 =over 4
4295
4296 =item 1. If it's already fully-qualified, leave it alone.
4297
4298 =item 2. Try putting it in the current package.
4299
4300 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4301
4302 =item 4. If it starts with '::', put it in 'main::'.
4303
4304 =back
4305
4306 After all this cleanup, we call C<break_subroutine> to try to set the
4307 breakpoint.
4308
4309 =cut
4310
4311 sub cmd_b_sub {
4312     my ( $subname, $cond ) = @_;
4313
4314     # Add always-true condition if we have none.
4315     $cond = 1 unless @_ >= 2;
4316
4317     # If the subname isn't a code reference, qualify it so that
4318     # break_subroutine() will work right.
4319     unless ( ref $subname eq 'CODE' ) {
4320
4321         # Not Perl4.
4322         $subname =~ s/\'/::/g;
4323         my $s = $subname;
4324
4325         # Put it in this package unless it's already qualified.
4326         $subname = "${'package'}::" . $subname
4327           unless $subname =~ /::/;
4328
4329         # Requalify it into CORE::GLOBAL if qualifying it into this
4330         # package resulted in its not being defined, but only do so
4331         # if it really is in CORE::GLOBAL.
4332         $subname = "CORE::GLOBAL::$s"
4333           if not defined &$subname
4334           and $s !~ /::/
4335           and defined &{"CORE::GLOBAL::$s"};
4336
4337         # Put it in package 'main' if it has a leading ::.
4338         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4339
4340     } ## end unless (ref $subname eq 'CODE')
4341
4342     # Try to set the breakpoint.
4343     eval { break_subroutine( $subname, $cond ); 1 } or do {
4344         local $\ = '';
4345         print $OUT $@ and return;
4346       }
4347 } ## end sub cmd_b_sub
4348
4349 =head3 C<cmd_B> - delete breakpoint(s) (command)
4350
4351 The command mostly parses the command line and tries to turn the argument
4352 into a line spec. If it can't, it uses the current line. It then calls
4353 C<delete_breakpoint> to actually do the work.
4354
4355 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4356 thereby deleting all the breakpoints.
4357
4358 =cut
4359
4360 sub cmd_B {
4361     my $cmd = shift;
4362
4363     # No line spec? Use dbline.
4364     # If there is one, use it if it's non-zero, or wipe it out if it is.
4365     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4366     my $dbline = shift;
4367
4368     # If the line was dot, make the line the current one.
4369     $line =~ s/^\./$dbline/;
4370
4371     # If it's * we're deleting all the breakpoints.
4372     if ( $line eq '*' ) {
4373         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4374     }
4375
4376     # If there is a line spec, delete the breakpoint on that line.
4377     elsif ( $line =~ /^(\S.*)/ ) {
4378         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4379             local $\ = '';
4380             print $OUT $@ and return;
4381         };
4382     } ## end elsif ($line =~ /^(\S.*)/)
4383
4384     # No line spec.
4385     else {
4386         print $OUT
4387           "Deleting a breakpoint requires a line number, or '*' for all\n"
4388           ;    # hint
4389     }
4390 } ## end sub cmd_B
4391
4392 =head3 delete_breakpoint([line]) (API)
4393
4394 This actually does the work of deleting either a single breakpoint, or all
4395 of them.
4396
4397 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4398 just drop out with a message saying so. If it is, we remove the condition
4399 part of the 'condition\0action' that says there's a breakpoint here. If,
4400 after we've done that, there's nothing left, we delete the corresponding
4401 line in C<%dbline> to signal that no action needs to be taken for this line.
4402
4403 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4404 which lists all currently-loaded files which have breakpoints. We then look
4405 at each line in each of these files, temporarily switching the C<%dbline>
4406 and C<@dbline> structures to point to the files in question, and do what
4407 we did in the single line case: delete the condition in C<@dbline>, and
4408 delete the key in C<%dbline> if nothing's left.
4409
4410 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4411 C<%break_on_load>, because these structures contain breakpoints for files
4412 and code that haven't been loaded yet. We can just kill these off because there
4413 are no magical debugger structures associated with them.
4414
4415 =cut
4416
4417 sub delete_breakpoint {
4418     my $i = shift;
4419
4420     # If we got a line, delete just that one.
4421     if ( defined($i) ) {
4422
4423         # Woops. This line wasn't breakable at all.
4424         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4425
4426         # Kill the condition, but leave any action.
4427         $dbline{$i} =~ s/^[^\0]*//;
4428
4429         # Remove the entry entirely if there's no action left.
4430         delete $dbline{$i} if $dbline{$i} eq '';
4431     }
4432
4433     # No line; delete them all.
4434     else {
4435         print $OUT "Deleting all breakpoints...\n";
4436
4437         # %had_breakpoints lists every file that had at least one
4438         # breakpoint in it.
4439         for my $file ( keys %had_breakpoints ) {
4440
4441             # Switch to the desired file temporarily.
4442             local *dbline = $main::{ '_<' . $file };
4443
4444             my $max = $#dbline;
4445             my $was;
4446
4447             # For all lines in this file ...
4448             for ( $i = 1 ; $i <= $max ; $i++ ) {
4449
4450                 # If there's a breakpoint or action on this line ...
4451                 if ( defined $dbline{$i} ) {
4452
4453                     # ... remove the breakpoint.
4454                     $dbline{$i} =~ s/^[^\0]+//;
4455                     if ( $dbline{$i} =~ s/^\0?$// ) {
4456
4457                         # Remove the entry altogether if no action is there.
4458                         delete $dbline{$i};
4459                     }
4460                 } ## end if (defined $dbline{$i...
4461             } ## end for ($i = 1 ; $i <= $max...
4462
4463             # If, after we turn off the "there were breakpoints in this file"
4464             # bit, the entry in %had_breakpoints for this file is zero,
4465             # we should remove this file from the hash.
4466             if ( not $had_breakpoints{$file} &= ~1 ) {
4467                 delete $had_breakpoints{$file};
4468             }
4469         } ## end for my $file (keys %had_breakpoints)
4470
4471         # Kill off all the other breakpoints that are waiting for files that
4472         # haven't been loaded yet.
4473         undef %postponed;
4474         undef %postponed_file;
4475         undef %break_on_load;
4476     } ## end else [ if (defined($i))
4477 } ## end sub delete_breakpoint
4478
4479 =head3 cmd_stop (command)
4480
4481 This is meant to be part of the new command API, but it isn't called or used
4482 anywhere else in the debugger. XXX It is probably meant for use in development
4483 of new commands.
4484
4485 =cut
4486
4487 sub cmd_stop {    # As on ^C, but not signal-safy.
4488     $signal = 1;
4489 }
4490
4491 =head3 C<cmd_h> - help command (command)
4492
4493 Does the work of either
4494
4495 =over 4
4496
4497 =item * Showing all the debugger help
4498
4499 =item * Showing help for a specific command
4500
4501 =back
4502
4503 =cut
4504
4505 sub cmd_h {
4506     my $cmd = shift;
4507
4508     # If we have no operand, assume null.
4509     my $line = shift || '';
4510
4511     # 'h h'. Print the long-format help.
4512     if ( $line =~ /^h\s*/ ) {
4513         print_help($help);
4514     }
4515
4516     # 'h <something>'. Search for the command and print only its help.
4517     elsif ( $line =~ /^(\S.*)$/ ) {
4518
4519         # support long commands; otherwise bogus errors
4520         # happen when you ask for h on <CR> for example
4521         my $asked = $1;    # the command requested
4522                            # (for proper error message)
4523
4524         my $qasked = quotemeta($asked);    # for searching; we don't
4525                                            # want to use it as a pattern.
4526                                            # XXX: finds CR but not <CR>
4527
4528         # Search the help string for the command.
4529         if (
4530             $help =~ /^                    # Start of a line
4531                       <?                   # Optional '<'
4532                       (?:[IB]<)            # Optional markup
4533                       $qasked              # The requested command
4534                      /mx
4535           )
4536         {
4537
4538             # It's there; pull it out and print it.
4539             while (
4540                 $help =~ /^
4541                               (<?            # Optional '<'
4542                                  (?:[IB]<)   # Optional markup
4543                                  $qasked     # The command
4544                                  ([\s\S]*?)  # Description line(s)
4545                               \n)            # End of last description line
4546                               (?!\s)         # Next line not starting with
4547                                              # whitespace
4548                              /mgx
4549               )
4550             {
4551                 print_help($1);
4552             }
4553         }
4554
4555         # Not found; not a debugger command.
4556         else {
4557             print_help("B<$asked> is not a debugger command.\n");
4558         }
4559     } ## end elsif ($line =~ /^(\S.*)$/)
4560
4561     # 'h' - print the summary help.
4562     else {
4563         print_help($summary);
4564     }
4565 } ## end sub cmd_h
4566
4567 =head3 C<cmd_i> - inheritance display
4568
4569 Display the (nested) parentage of the module or object given.
4570
4571 =cut
4572
4573 sub cmd_i {
4574     my $cmd  = shift;
4575     my $line = shift;
4576     eval { require Class::ISA };
4577     if ($@) {
4578         &warn( $@ =~ /locate/
4579             ? "Class::ISA module not found - please install\n"
4580             : $@ );
4581     }
4582     else {
4583       ISA:
4584         foreach my $isa ( split( /\s+/, $line ) ) {
4585             $evalarg = $isa;
4586             ($isa) = &eval;
4587             no strict 'refs';
4588             print join(
4589                 ', ',
4590                 map {    # snaffled unceremoniously from Class::ISA
4591                     "$_"
4592                       . (
4593                         defined( ${"$_\::VERSION"} )
4594                         ? ' ' . ${"$_\::VERSION"}
4595                         : undef )
4596                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4597             );
4598             print "\n";
4599         }
4600     }
4601 } ## end sub cmd_i
4602
4603 =head3 C<cmd_l> - list lines (command)
4604
4605 Most of the command is taken up with transforming all the different line
4606 specification syntaxes into 'start-stop'. After that is done, the command
4607 runs a loop over C<@dbline> for the specified range of lines. It handles
4608 the printing of each line and any markers (C<==E<gt>> for current line,
4609 C<b> for break on this line, C<a> for action on this line, C<:> for this
4610 line breakable).
4611
4612 We save the last line listed in the C<$start> global for further listing
4613 later.
4614
4615 =cut
4616
4617 sub cmd_l {
4618     my $current_line = $line;
4619     my $cmd  = shift;
4620     my $line = shift;
4621
4622     # If this is '-something', delete any spaces after the dash.
4623     $line =~ s/^-\s*$/-/;
4624
4625     # If the line is '$something', assume this is a scalar containing a
4626     # line number.
4627     if ( $line =~ /^(\$.*)/s ) {
4628
4629         # Set up for DB::eval() - evaluate in *user* context.
4630         $evalarg = $1;
4631         # $evalarg = $2;
4632         my ($s) = &eval;
4633
4634         # Ooops. Bad scalar.
4635         print( $OUT "Error: $@\n" ), next CMD if $@;
4636
4637         # Good scalar. If it's a reference, find what it points to.
4638         $s = CvGV_name($s);
4639         print( $OUT "Interpreted as: $1 $s\n" );
4640         $line = "$1 $s";
4641
4642         # Call self recursively to really do the command.
4643         &cmd_l( 'l', $s );
4644     } ## end if ($line =~ /^(\$.*)/s)
4645
4646     # l name. Try to find a sub by that name.
4647     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4648         my $s = $subname = $1;
4649
4650         # De-Perl4.
4651         $subname =~ s/\'/::/;
4652
4653         # Put it in this package unless it starts with ::.
4654         $subname = $package . "::" . $subname unless $subname =~ /::/;
4655
4656         # Put it in CORE::GLOBAL if t doesn't start with :: and
4657         # it doesn't live in this package and it lives in CORE::GLOBAL.
4658         $subname = "CORE::GLOBAL::$s"
4659           if not defined &$subname
4660           and $s !~ /::/
4661           and defined &{"CORE::GLOBAL::$s"};
4662
4663         # Put leading '::' names into 'main::'.
4664         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4665
4666         # Get name:start-stop from find_sub, and break this up at
4667         # colons.
4668         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4669
4670         # Pull off start-stop.
4671         $subrange = pop @pieces;
4672
4673         # If the name contained colons, the split broke it up.
4674         # Put it back together.
4675         $file = join( ':', @pieces );
4676
4677         # If we're not in that file, switch over to it.
4678         if ( $file ne $filename ) {
4679             print $OUT "Switching to file '$file'.\n"
4680               unless $slave_editor;
4681
4682             # Switch debugger's magic structures.
4683             *dbline   = $main::{ '_<' . $file };
4684             $max      = $#dbline;
4685             $filename = $file;
4686         } ## end if ($file ne $filename)
4687
4688         # Subrange is 'start-stop'. If this is less than a window full,
4689         # swap it to 'start+', which will list a window from the start point.
4690         if ($subrange) {
4691             if ( eval($subrange) < -$window ) {
4692                 $subrange =~ s/-.*/+/;
4693             }
4694
4695             # Call self recursively to list the range.
4696             $line = $subrange;
4697             &cmd_l( 'l', $subrange );
4698         } ## end if ($subrange)
4699
4700         # Couldn't find it.
4701         else {
4702             print $OUT "Subroutine $subname not found.\n";
4703         }
4704     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4705
4706     # Bare 'l' command.
4707     elsif ( $line =~ /^\s*$/ ) {
4708
4709         # Compute new range to list.
4710         $incr = $window - 1;
4711         $line = $start . '-' . ( $start + $incr );
4712
4713         # Recurse to do it.
4714         &cmd_l( 'l', $line );
4715     }
4716
4717     # l [start]+number_of_lines
4718     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4719
4720         # Don't reset start for 'l +nnn'.
4721         $start = $1 if $1;
4722
4723         # Increment for list. Use window size if not specified.
4724         # (Allows 'l +' to work.)
4725         $incr = $2;
4726         $incr = $window - 1 unless $incr;
4727
4728         # Create a line range we'll understand, and recurse to do it.
4729         $line = $start . '-' . ( $start + $incr );
4730         &cmd_l( 'l', $line );
4731     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4732
4733     # l start-stop or l start,stop
4734     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4735
4736         # Determine end point; use end of file if not specified.
4737         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4738
4739         # Go on to the end, and then stop.
4740         $end = $max if $end > $max;
4741
4742         # Determine start line.
4743         $i    = $2;
4744         $i    = $line if $i eq '.';
4745         $i    = 1 if $i < 1;
4746         $incr = $end - $i;
4747
4748         # If we're running under a slave editor, force it to show the lines.
4749         if ($slave_editor) {
4750             print $OUT "\032\032$filename:$i:0\n";
4751             $i = $end;
4752         }
4753
4754         # We're doing it ourselves. We want to show the line and special
4755         # markers for:
4756         # - the current line in execution
4757         # - whether a line is breakable or not
4758         # - whether a line has a break or not
4759         # - whether a line has an action or not
4760         else {
4761             for ( ; $i <= $end ; $i++ ) {
4762
4763                 # Check for breakpoints and actions.
4764                 my ( $stop, $action );
4765                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
4766                   if $dbline{$i};
4767
4768                 # ==> if this is the current line in execution,
4769                 # : if it's breakable.
4770                 $arrow =
4771                   ( $i == $current_line and $filename eq $filename_ini )
4772                   ? '==>'
4773                   : ( $dbline[$i] + 0 ? ':' : ' ' );
4774
4775                 # Add break and action indicators.
4776                 $arrow .= 'b' if $stop;
4777                 $arrow .= 'a' if $action;
4778
4779                 # Print the line.
4780                 print $OUT "$i$arrow\t", $dbline[$i];
4781
4782                 # Move on to the next line. Drop out on an interrupt.
4783                 $i++, last if $signal;
4784             } ## end for (; $i <= $end ; $i++)
4785
4786             # Line the prompt up; print a newline if the last line listed
4787             # didn't have a newline.
4788             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
4789         } ## end else [ if ($slave_editor)
4790
4791         # Save the point we last listed to in case another relative 'l'
4792         # command is desired. Don't let it run off the end.
4793         $start = $i;
4794         $start = $max if $start > $max;
4795     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
4796 } ## end sub cmd_l
4797
4798 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
4799
4800 To list breakpoints, the command has to look determine where all of them are
4801 first. It starts a C<%had_breakpoints>, which tells us what all files have
4802 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
4803 magic source and breakpoint data structures) to the file, and then look
4804 through C<%dbline> for lines with breakpoints and/or actions, listing them
4805 out. We look through C<%postponed> not-yet-compiled subroutines that have
4806 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
4807 that have breakpoints.
4808
4809 Watchpoints are simpler: we just list the entries in C<@to_watch>.
4810
4811 =cut
4812
4813 sub cmd_L {
4814     my $cmd = shift;
4815
4816     # If no argument, list everything. Pre-5.8.0 version always lists
4817     # everything
4818     my $arg = shift || 'abw';
4819     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
4820
4821     # See what is wanted.
4822     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
4823     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
4824     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
4825
4826     # Breaks and actions are found together, so we look in the same place
4827     # for both.
4828     if ( $break_wanted or $action_wanted ) {
4829
4830         # Look in all the files with breakpoints...
4831         for my $file ( keys %had_breakpoints ) {
4832
4833             # Temporary switch to this file.
4834             local *dbline = $main::{ '_<' . $file };
4835
4836             # Set up to look through the whole file.
4837             my $max = $#dbline;
4838             my $was;    # Flag: did we print something
4839                         # in this file?
4840
4841             # For each line in the file ...
4842             for ( $i = 1 ; $i <= $max ; $i++ ) {
4843
4844                 # We've got something on this line.
4845                 if ( defined $dbline{$i} ) {
4846
4847                     # Print the header if we haven't.
4848                     print $OUT "$file:\n" unless $was++;
4849
4850                     # Print the line.
4851                     print $OUT " $i:\t", $dbline[$i];
4852
4853                     # Pull out the condition and the action.
4854                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
4855
4856                     # Print the break if there is one and it's wanted.
4857                     print $OUT "   break if (", $stop, ")\n"
4858                       if $stop
4859                       and $break_wanted;
4860
4861                     # Print the action if there is one and it's wanted.
4862                     print $OUT "   action:  ", $action, "\n"
4863                       if $action
4864                       and $action_wanted;
4865
4866                     # Quit if the user hit interrupt.
4867                     last if $signal;
4868                 } ## end if (defined $dbline{$i...
4869             } ## end for ($i = 1 ; $i <= $max...
4870         } ## end for my $file (keys %had_breakpoints)
4871     } ## end if ($break_wanted or $action_wanted)
4872
4873     # Look for breaks in not-yet-compiled subs:
4874     if ( %postponed and $break_wanted ) {
4875         print $OUT "Postponed breakpoints in subroutines:\n";
4876         my $subname;
4877         for $subname ( keys %postponed ) {
4878             print $OUT " $subname\t$postponed{$subname}\n";
4879             last if $signal;
4880         }
4881     } ## end if (%postponed and $break_wanted)
4882
4883     # Find files that have not-yet-loaded breaks:
4884     my @have = map {    # Combined keys
4885         keys %{ $postponed_file{$_} }
4886     } keys %postponed_file;
4887
4888     # If there are any, list them.
4889     if ( @have and ( $break_wanted or $action_wanted ) ) {
4890         print $OUT "Postponed breakpoints in files:\n";
4891         my ( $file, $line );
4892
4893         for $file ( keys %postponed_file ) {
4894             my $db = $postponed_file{$file};
4895             print $OUT " $file:\n";
4896             for $line ( sort { $a <=> $b } keys %$db ) {
4897                 print $OUT "  $line:\n";
4898                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
4899                 print $OUT "    break if (", $stop, ")\n"
4900                   if $stop
4901                   and $break_wanted;
4902                 print $OUT "    action:  ", $action, "\n"
4903                   if $action
4904                   and $action_wanted;
4905                 last if $signal;
4906             } ## end for $line (sort { $a <=>...
4907             last if $signal;
4908         } ## end for $file (keys %postponed_file)
4909     } ## end if (@have and ($break_wanted...
4910     if ( %break_on_load and $break_wanted ) {
4911         print $OUT "Breakpoints on load:\n";
4912         my $file;
4913         for $file ( keys %break_on_load ) {
4914             print $OUT " $file\n";
4915             last if $signal;
4916         }
4917     } ## end if (%break_on_load and...
4918     if ($watch_wanted) {
4919         if ( $trace & 2 ) {
4920             print $OUT "Watch-expressions:\n" if @to_watch;
4921             for my $expr (@to_watch) {
4922                 print $OUT " $expr\n";
4923                 last if $signal;
4924             }
4925         } ## end if ($trace & 2)
4926     } ## end if ($watch_wanted)
4927 } ## end sub cmd_L
4928
4929 =head3 C<cmd_M> - list modules (command)
4930
4931 Just call C<list_modules>.
4932
4933 =cut
4934
4935 sub cmd_M {
4936     &list_modules();
4937 }
4938
4939 =head3 C<cmd_o> - options (command)
4940
4941 If this is just C<o> by itself, we list the current settings via
4942 C<dump_option>. If there's a nonblank value following it, we pass that on to
4943 C<parse_options> for processing.
4944
4945 =cut
4946
4947 sub cmd_o {
4948     my $cmd = shift;
4949     my $opt = shift || '';    # opt[=val]
4950
4951     # Nonblank. Try to parse and process.
4952     if ( $opt =~ /^(\S.*)/ ) {
4953         &parse_options($1);
4954     }
4955
4956     # Blank. List the current option settings.
4957     else {
4958         for (@options) {
4959             &dump_option($_);
4960         }
4961     }
4962 } ## end sub cmd_o
4963
4964 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
4965
4966 Advises the user that the O command has been renamed.
4967
4968 =cut
4969
4970 sub cmd_O {
4971     print $OUT "The old O command is now the o command.\n";             # hint
4972     print $OUT "Use 'h' to get current command help synopsis or\n";     #
4973     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
4974 }
4975
4976 =head3 C<cmd_v> - view window (command)
4977
4978 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
4979 move back a few lines to list the selected line in context. Uses C<cmd_l>
4980 to do the actual listing after figuring out the range of line to request.
4981
4982 =cut
4983
4984 sub cmd_v {
4985     my $cmd  = shift;
4986     my $line = shift;
4987
4988     # Extract the line to list around. (Astute readers will have noted that
4989     # this pattern will match whether or not a numeric line is specified,
4990     # which means that we'll always enter this loop (though a non-numeric
4991     # argument results in no action at all)).
4992     if ( $line =~ /^(\d*)$/ ) {
4993
4994         # Total number of lines to list (a windowful).
4995         $incr = $window - 1;
4996
4997         # Set the start to the argument given (if there was one).
4998         $start = $1 if $1;
4999
5000         # Back up by the context amount.
5001         $start -= $preview;
5002
5003         # Put together a linespec that cmd_l will like.
5004         $line = $start . '-' . ( $start + $incr );
5005
5006         # List the lines.
5007         &cmd_l( 'l', $line );
5008     } ## end if ($line =~ /^(\d*)$/)
5009 } ## end sub cmd_v
5010
5011 =head3 C<cmd_w> - add a watch expression (command)
5012
5013 The 5.8 version of this command adds a watch expression if one is specified;
5014 it does nothing if entered with no operands.
5015
5016 We extract the expression, save it, evaluate it in the user's context, and
5017 save the value. We'll re-evaluate it each time the debugger passes a line,
5018 and will stop (see the code at the top of the command loop) if the value
5019 of any of the expressions changes.
5020
5021 =cut
5022
5023 sub cmd_w {
5024     my $cmd = shift;
5025
5026     # Null expression if no arguments.
5027     my $expr = shift || '';
5028
5029     # If expression is not null ...
5030     if ( $expr =~ /^(\S.*)/ ) {
5031
5032         # ... save it.
5033         push @to_watch, $expr;
5034
5035         # Parameterize DB::eval and call it to get the expression's value
5036         # in the user's context. This version can handle expressions which
5037         # return a list value.
5038         $evalarg = $expr;
5039         my ($val) = join( ' ', &eval );
5040         $val = ( defined $val ) ? "'$val'" : 'undef';
5041
5042         # Save the current value of the expression.
5043         push @old_watch, $val;
5044
5045         # We are now watching expressions.
5046         $trace |= 2;
5047     } ## end if ($expr =~ /^(\S.*)/)
5048
5049     # You have to give one to get one.
5050     else {
5051         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5052     }
5053 } ## end sub cmd_w
5054
5055 =head3 C<cmd_W> - delete watch expressions (command)
5056
5057 This command accepts either a watch expression to be removed from the list
5058 of watch expressions, or C<*> to delete them all.
5059
5060 If C<*> is specified, we simply empty the watch expression list and the
5061 watch expression value list. We also turn off the bit that says we've got
5062 watch expressions.
5063
5064 If an expression (or partial expression) is specified, we pattern-match
5065 through the expressions and remove the ones that match. We also discard
5066 the corresponding values. If no watch expressions are left, we turn off
5067 the 'watching expressions' bit.
5068
5069 =cut
5070
5071 sub cmd_W {
5072     my $cmd  = shift;
5073     my $expr = shift || '';
5074
5075     # Delete them all.
5076     if ( $expr eq '*' ) {
5077
5078         # Not watching now.
5079         $trace &= ~2;
5080
5081         print $OUT "Deleting all watch expressions ...\n";
5082
5083         # And all gone.
5084         @to_watch = @old_watch = ();
5085     }
5086
5087     # Delete one of them.
5088     elsif ( $expr =~ /^(\S.*)/ ) {
5089
5090         # Where we are in the list.
5091         my $i_cnt = 0;
5092
5093         # For each expression ...
5094         foreach (@to_watch) {
5095             my $val = $to_watch[$i_cnt];
5096
5097             # Does this one match the command argument?
5098             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5099                                       # Yes. Turn it off, and its value too.
5100                 splice( @to_watch,  $i_cnt, 1 );
5101                 splice( @old_watch, $i_cnt, 1 );
5102             }
5103             $i_cnt++;
5104         } ## end foreach (@to_watch)
5105
5106         # We don't bother to turn watching off because
5107         #  a) we don't want to stop calling watchfunction() it it exists
5108         #  b) foreach over a null list doesn't do anything anyway
5109
5110     } ## end elsif ($expr =~ /^(\S.*)/)
5111
5112     # No command arguments entered.
5113     else {
5114         print $OUT
5115           "Deleting a watch-expression requires an expression, or '*' for all\n"
5116           ;    # hint
5117     }
5118 } ## end sub cmd_W
5119
5120 ### END of the API section
5121
5122 =head1 SUPPORT ROUTINES
5123
5124 These are general support routines that are used in a number of places
5125 throughout the debugger.
5126
5127 =item cmd_P
5128
5129 Something to do with assertions
5130
5131 =cut
5132
5133 sub cmd_P {
5134     unless ($ini_assertion) {
5135         print $OUT "Assertions not supported in this Perl interpreter\n";
5136     } else {
5137         if ( $cmd =~ /^.\b\s*([+-]?)\s*(~?)\s*(\w+(\s*\|\s*\w+)*)\s*$/ ) {
5138             my ( $how, $neg, $flags ) = ( $1, $2, $3 );
5139             my $acu = parse_DollarCaretP_flags($flags);
5140             if ( defined $acu ) {
5141                 $acu = ~$acu if $neg;
5142                 if ( $how eq '+' ) { $^P |= $acu }
5143                 elsif ( $how eq '-' ) { $^P &= ~$acu }
5144                 else { $^P = $acu }
5145             }
5146
5147             # else { print $OUT "undefined acu\n" }
5148         }
5149         my $expanded = expand_DollarCaretP_flags($^P);
5150         print $OUT "Internal Perl debugger flags:\n\$^P=$expanded\n";
5151         $expanded;
5152     }
5153 }
5154
5155 =head2 save
5156
5157 save() saves the user's versions of globals that would mess us up in C<@saved>,
5158 and installs the versions we like better.
5159
5160 =cut
5161
5162 sub save {
5163
5164     # Save eval failure, command failure, extended OS error, output field
5165     # separator, input record separator, output record separator and
5166     # the warning setting.
5167     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5168
5169     $,  = "";      # output field separator is null string
5170     $/  = "\n";    # input record separator is newline
5171     $\  = "";      # output record separator is null string
5172     $^W = 0;       # warnings are off
5173 } ## end sub save
5174
5175 =head2 C<print_lineinfo> - show where we are now
5176
5177 print_lineinfo prints whatever it is that it is handed; it prints it to the
5178 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5179 us to feed line information to a slave editor without messing up the
5180 debugger output.
5181
5182 =cut
5183
5184 sub print_lineinfo {
5185
5186     # Make the terminal sensible if we're not the primary debugger.
5187     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5188     local $\ = '';
5189     local $, = '';
5190     print $LINEINFO @_;
5191 } ## end sub print_lineinfo
5192
5193 =head2 C<postponed_sub>
5194
5195 Handles setting postponed breakpoints in subroutines once they're compiled.
5196 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5197 range for the subroutine, then mark the file as having a breakpoint,
5198 temporarily switch the C<*dbline> glob over to the source file, and then
5199 search the given range of lines to find a breakable line. If we find one,
5200 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5201
5202 =cut
5203
5204 # The following takes its argument via $evalarg to preserve current @_
5205
5206 sub postponed_sub {
5207
5208     # Get the subroutine name.
5209     my $subname = shift;
5210
5211     # If this is a 'break +<n> if <condition>' ...
5212     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5213
5214         # If there's no offset, use '+0'.
5215         my $offset = $1 || 0;
5216
5217         # find_sub's value is 'fullpath-filename:start-stop'. It's
5218         # possible that the filename might have colons in it too.
5219         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5220         if ($i) {
5221
5222             # We got the start line. Add the offset '+<n>' from
5223             # $postponed{subname}.
5224             $i += $offset;
5225
5226             # Switch to the file this sub is in, temporarily.
5227             local *dbline = $main::{ '_<' . $file };
5228
5229             # No warnings, please.
5230             local $^W = 0;    # != 0 is magical below
5231
5232             # This file's got a breakpoint in it.
5233             $had_breakpoints{$file} |= 1;
5234
5235             # Last line in file.
5236             my $max = $#dbline;
5237
5238             # Search forward until we hit a breakable line or get to
5239             # the end of the file.
5240             ++$i until $dbline[$i] != 0 or $i >= $max;
5241
5242             # Copy the breakpoint in and delete it from %postponed.
5243             $dbline{$i} = delete $postponed{$subname};
5244         } ## end if ($i)
5245
5246         # find_sub didn't find the sub.
5247         else {
5248             local $\ = '';
5249             print $OUT "Subroutine $subname not found.\n";
5250         }
5251         return;
5252     } ## end if ($postponed{$subname...
5253     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5254
5255     #print $OUT "In postponed_sub for `$subname'.\n";
5256 } ## end sub postponed_sub
5257
5258 =head2 C<postponed>
5259
5260 Called after each required file is compiled, but before it is executed;
5261 also called if the name of a just-compiled subroutine is a key of
5262 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5263 etc.) into the just-compiled code.
5264
5265 If this is a C<require>'d file, the incoming parameter is the glob
5266 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5267
5268 If it's a subroutine, the incoming parameter is the subroutine name.
5269
5270 =cut
5271
5272 sub postponed {
5273
5274     # If there's a break, process it.
5275     if ($ImmediateStop) {
5276
5277         # Right, we've stopped. Turn it off.
5278         $ImmediateStop = 0;
5279
5280         # Enter the command loop when DB::DB gets called.
5281         $signal = 1;
5282     }
5283
5284     # If this is a subroutine, let postponed_sub() deal with it.
5285     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5286
5287     # Not a subroutine. Deal with the file.
5288     local *dbline = shift;
5289     my $filename = $dbline;
5290     $filename =~ s/^_<//;
5291     local $\ = '';
5292     $signal = 1, print $OUT "'$filename' loaded...\n"
5293       if $break_on_load{$filename};
5294     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5295
5296     # Do we have any breakpoints to put in this file?
5297     return unless $postponed_file{$filename};
5298
5299     # Yes. Mark this file as having breakpoints.
5300     $had_breakpoints{$filename} |= 1;
5301
5302     # "Cannot be done: unsufficient magic" - we can't just put the
5303     # breakpoints saved in %postponed_file into %dbline by assigning
5304     # the whole hash; we have to do it one item at a time for the
5305     # breakpoints to be set properly.
5306     #%dbline = %{$postponed_file{$filename}};
5307
5308     # Set the breakpoints, one at a time.
5309     my $key;
5310
5311     for $key ( keys %{ $postponed_file{$filename} } ) {
5312
5313         # Stash the saved breakpoint into the current file's magic line array.
5314         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5315     }
5316
5317     # This file's been compiled; discard the stored breakpoints.
5318     delete $postponed_file{$filename};
5319
5320 } ## end sub postponed
5321
5322 =head2 C<dumpit>
5323
5324 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5325
5326 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5327 a reference to a variable (the thing to be dumped) as its input.
5328
5329 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5330 the currently-selected filehandle, thank you very much). The current
5331 values of the package globals C<$single> and C<$trace> are backed up in
5332 lexicals, and they are turned off (this keeps the debugger from trying
5333 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5334 preserve its current value and it is set to zero to prevent entry/exit
5335 messages from printing, and C<$doret> is localized as well and set to -2 to
5336 prevent return values from being shown.
5337
5338 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5339 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5340 installed version in @INC, yours will be used instead. Possible security
5341 problem?).
5342
5343 It then checks to see if the subroutine C<main::dumpValue> is now defined
5344 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5345 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5346 is called, and picks up the variable to be dumped from the parameter list.
5347
5348 It checks the package global C<%options> to see if there's a C<dumpDepth>
5349 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5350 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5351 structure: -1 means dump everything.
5352
5353 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5354 warning.
5355
5356 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5357 and we then return to the caller.
5358
5359 =cut
5360
5361 sub dumpit {
5362
5363     # Save the current output filehandle and switch to the one
5364     # passed in as the first parameter.
5365     local ($savout) = select(shift);
5366
5367     # Save current settings of $single and $trace, and then turn them off.
5368     my $osingle = $single;
5369     my $otrace  = $trace;
5370     $single = $trace = 0;
5371
5372     # XXX Okay, what do $frame and $doret do, again?
5373     local $frame = 0;
5374     local $doret = -2;
5375
5376     # Load dumpvar.pl unless we've already got the sub we need from it.
5377     unless ( defined &main::dumpValue ) {
5378         do 'dumpvar.pl';
5379     }
5380
5381     # If the load succeeded (or we already had dumpvalue()), go ahead
5382     # and dump things.
5383     if ( defined &main::dumpValue ) {
5384         local $\ = '';
5385         local $, = '';
5386         local $" = ' ';
5387         my $v = shift;
5388         my $maxdepth = shift || $option{dumpDepth};
5389         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5390         &main::dumpValue( $v, $maxdepth );
5391     } ## end if (defined &main::dumpValue)
5392
5393     # Oops, couldn't load dumpvar.pl.
5394     else {
5395         local $\ = '';
5396         print $OUT "dumpvar.pl not available.\n";
5397     }
5398
5399     # Reset $single and $trace to their old values.
5400     $single = $osingle;
5401     $trace  = $otrace;
5402
5403     # Restore the old filehandle.
5404     select($savout);
5405 } ## end sub dumpit
5406
5407 =head2 C<print_trace>
5408
5409 C<print_trace>'s job is to print a stack trace. It does this via the
5410 C<dump_trace> routine, which actually does all the ferreting-out of the
5411 stack trace data. C<print_trace> takes care of formatting it nicely and
5412 printing it to the proper filehandle.
5413
5414 Parameters:
5415
5416 =over 4
5417
5418 =item * The filehandle to print to.
5419
5420 =item * How many frames to skip before starting trace.
5421
5422 =item * How many frames to print.
5423
5424 =item * A flag: if true, print a "short" trace without filenames, line numbers, or arguments
5425
5426 =back
5427
5428 The original comment below seems to be noting that the traceback may not be
5429 correct if this routine is called in a tied method.
5430
5431 =cut
5432
5433 # Tied method do not create a context, so may get wrong message:
5434
5435 sub print_trace {
5436     local $\ = '';
5437     my $fh = shift;
5438
5439     # If this is going to a slave editor, but we're not the primary
5440     # debugger, reset it first.
5441     resetterm(1)
5442       if $fh        eq $LINEINFO    # slave editor
5443       and $LINEINFO eq $OUT         # normal output
5444       and $term_pid != $$;          # not the primary
5445
5446     # Collect the actual trace information to be formatted.
5447     # This is an array of hashes of subroutine call info.
5448     my @sub = dump_trace( $_[0] + 1, $_[1] );
5449
5450     # Grab the "short report" flag from @_.
5451     my $short = $_[2];              # Print short report, next one for sub name
5452
5453     # Run through the traceback info, format it, and print it.
5454     my $s;
5455     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5456
5457         # Drop out if the user has lost interest and hit control-C.
5458         last if $signal;
5459
5460         # Set the separator so arrys print nice.
5461         local $" = ', ';
5462
5463         # Grab and stringify the arguments if they are there.
5464         my $args =
5465           defined $sub[$i]{args}
5466           ? "(@{ $sub[$i]{args} })"
5467           : '';
5468
5469         # Shorten them up if $maxtrace says they're too long.
5470         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5471           if length $args > $maxtrace;
5472
5473         # Get the file name.
5474         my $file = $sub[$i]{file};
5475
5476         # Put in a filename header if short is off.
5477         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5478
5479         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5480         $s = $sub[$i]{sub};
5481         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5482
5483         # Short report uses trimmed file and sub names.
5484         if ($short) {
5485             my $sub = @_ >= 4 ? $_[3] : $s;
5486             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5487         } ## end if ($short)
5488
5489         # Non-short report includes full names.
5490         else {
5491             print $fh "$sub[$i]{context} = $s$args"
5492               . " called from $file"
5493               . " line $sub[$i]{line}\n";
5494         }
5495     } ## end for ($i = 0 ; $i <= $#sub...
5496 } ## end sub print_trace
5497
5498 =head2 dump_trace(skip[,count])
5499
5500 Actually collect the traceback information available via C<caller()>. It does
5501 some filtering and cleanup of the data, but mostly it just collects it to
5502 make C<print_trace()>'s job easier.
5503
5504 C<skip> defines the number of stack frames to be skipped, working backwards
5505 from the most current. C<count> determines the total number of frames to
5506 be returned; all of them (well, the first 10^9) are returned if C<count>
5507 is omitted.
5508
5509 This routine returns a list of hashes, from most-recent to least-recent
5510 stack frame. Each has the following keys and values:
5511
5512 =over 4
5513
5514 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5515
5516 =item * C<sub> - subroutine name, or C<eval> information
5517
5518 =item * C<args> - undef, or a reference to an array of arguments
5519
5520 =item * C<file> - the file in which this item was defined (if any)
5521
5522 =item * C<line> - the line on which it was defined
5523
5524 =back
5525
5526 =cut
5527
5528 sub dump_trace {
5529
5530     # How many levels to skip.
5531     my $skip = shift;
5532
5533     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5534     # it's unlikely that we'll have more than a billion stack frames. If you
5535     # do, you've got an awfully big machine...)
5536     my $count = shift || 1e9;
5537
5538     # We increment skip because caller(1) is the first level *back* from
5539     # the current one.  Add $skip to the count of frames so we have a
5540     # simple stop criterion, counting from $skip to $count+$skip.
5541     $skip++;
5542     $count += $skip;
5543
5544     # These variables are used to capture output from caller();
5545     my ( $p, $file, $line, $sub, $h, $context );
5546
5547     my ( $e, $r, @a, @sub, $args );
5548
5549     # XXX Okay... why'd we do that?
5550     my $nothard = not $frame & 8;
5551     local $frame = 0;
5552
5553     # Do not want to trace this.
5554     my $otrace = $trace;
5555     $trace = 0;
5556
5557     # Start out at the skip count.
5558     # If we haven't reached the number of frames requested, and caller() is
5559     # still returning something, stay in the loop. (If we pass the requested
5560     # number of stack frames, or we run out - caller() returns nothing - we
5561     # quit.
5562     # Up the stack frame index to go back one more level each time.
5563     for (
5564         $i = $skip ;
5565         $i < $count
5566         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5567         $i++
5568       )
5569     {
5570
5571         # Go through the arguments and save them for later.
5572         @a = ();
5573         for $arg (@args) {
5574             my $type;
5575             if ( not defined $arg ) {    # undefined parameter
5576                 push @a, "undef";
5577             }
5578
5579             elsif ( $nothard and tied $arg ) {    # tied parameter
5580                 push @a, "tied";
5581             }
5582             elsif ( $nothard and $type = ref $arg ) {    # reference
5583                 push @a, "ref($type)";
5584             }
5585             else {                                       # can be stringified
5586                 local $_ =
5587                   "$arg";    # Safe to stringify now - should not call f().
5588
5589                 # Backslash any single-quotes or backslashes.
5590                 s/([\'\\])/\\$1/g;
5591
5592                 # Single-quote it unless it's a number or a colon-separated
5593                 # name.
5594                 s/(.*)/'$1'/s
5595                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5596
5597                 # Turn high-bit characters into meta-whatever.
5598                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5599
5600                 # Turn control characters into ^-whatever.
5601                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5602
5603                 push( @a, $_ );
5604             } ## end else [ if (not defined $arg)
5605         } ## end for $arg (@args)
5606
5607         # If context is true, this is array (@)context.
5608         # If context is false, this is scalar ($) context.
5609         # If neither, context isn't defined. (This is apparently a 'can't
5610         # happen' trap.)
5611         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5612
5613         # if the sub has args ($h true), make an anonymous array of the
5614         # dumped args.
5615         $args = $h ? [@a] : undef;
5616
5617         # remove trailing newline-whitespace-semicolon-end of line sequence
5618         # from the eval text, if any.
5619         $e =~ s/\n\s*\;\s*\Z// if $e;
5620
5621         # Escape backslashed single-quotes again if necessary.
5622         $e =~ s/([\\\'])/\\$1/g if $e;
5623
5624         # if the require flag is true, the eval text is from a require.
5625         if ($r) {
5626             $sub = "require '$e'";
5627         }
5628
5629         # if it's false, the eval text is really from an eval.
5630         elsif ( defined $r ) {
5631             $sub = "eval '$e'";
5632         }
5633
5634         # If the sub is '(eval)', this is a block eval, meaning we don't
5635         # know what the eval'ed text actually was.
5636         elsif ( $sub eq '(eval)' ) {
5637             $sub = "eval {...}";
5638         }
5639
5640         # Stick the collected information into @sub as an anonymous hash.
5641         push(
5642             @sub,
5643             {
5644                 context => $context,
5645                 sub     => $sub,
5646                 args    => $args,
5647                 file    => $file,
5648                 line    => $line
5649             }
5650         );
5651
5652         # Stop processing frames if the user hit control-C.
5653         last if $signal;
5654     } ## end for ($i = $skip ; $i < ...
5655
5656     # Restore the trace value again.
5657     $trace = $otrace;
5658     @sub;
5659 } ## end sub dump_trace
5660
5661 =head2 C<action()>
5662
5663 C<action()> takes input provided as the argument to an add-action command,
5664 either pre- or post-, and makes sure it's a complete command. It doesn't do
5665 any fancy parsing; it just keeps reading input until it gets a string
5666 without a trailing backslash.
5667
5668 =cut
5669
5670 sub action {
5671     my $action = shift;
5672
5673     while ( $action =~ s/\\$// ) {
5674
5675         # We have a backslash on the end. Read more.
5676         $action .= &gets;
5677     } ## end while ($action =~ s/\\$//)
5678
5679     # Return the assembled action.
5680     $action;
5681 } ## end sub action
5682
5683 =head2 unbalanced
5684
5685 This routine mostly just packages up a regular expression to be used
5686 to check that the thing it's being matched against has properly-matched
5687 curly braces.
5688
5689 Of note is the definition of the $balanced_brace_re global via ||=, which
5690 speeds things up by only creating the qr//'ed expression once; if it's
5691 already defined, we don't try to define it again. A speed hack.
5692
5693 =cut
5694
5695 sub unbalanced {
5696
5697     # I hate using globals!
5698     $balanced_brace_re ||= qr{
5699         ^ \{
5700              (?:
5701                  (?> [^{}] + )              # Non-parens without backtracking
5702                 |
5703                  (??{ $balanced_brace_re }) # Group with matching parens
5704               ) *
5705           \} $
5706    }x;
5707     return $_[0] !~ m/$balanced_brace_re/;
5708 } ## end sub unbalanced
5709
5710 =head2 C<gets()>
5711
5712 C<gets()> is a primitive (very primitive) routine to read continuations.
5713 It was devised for reading continuations for actions.
5714 it just reads more input with X<C<readline()>> and returns it.
5715
5716 =cut
5717
5718 sub gets {
5719     &readline("cont: ");
5720 }
5721
5722 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5723
5724 The C<system()> function assumes that it can just go ahead and use STDIN and
5725 STDOUT, but under the debugger, we want it to use the debugger's input and
5726 outout filehandles.
5727
5728 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5729 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5730 and then puts everything back again.
5731
5732 =cut
5733
5734 sub system {
5735
5736     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5737     # some non-Unix systems can do system() but have problems with fork().
5738     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5739     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5740     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5741     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5742
5743     # XXX: using csh or tcsh destroys sigint retvals!
5744     system(@_);
5745     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5746     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5747     close(SAVEIN);
5748     close(SAVEOUT);
5749
5750     # most of the $? crud was coping with broken cshisms
5751     if ( $? >> 8 ) {
5752         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5753     }
5754     elsif ($?) {
5755         &warn(
5756             "(Command died of SIG#",
5757             ( $? & 127 ),
5758             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5759             ")", "\n"
5760         );
5761     } ## end elsif ($?)
5762
5763     return $?;
5764
5765 } ## end sub system
5766
5767 =head1 TTY MANAGEMENT
5768
5769 The subs here do some of the terminal management for multiple debuggers.
5770
5771 =head2 setterm
5772
5773 Top-level function called when we want to set up a new terminal for use
5774 by the debugger.
5775
5776 If the C<noTTY> debugger option was set, we'll either use the terminal
5777 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
5778 to find one. If we're a forked debugger, we call C<resetterm> to try to
5779 get a whole new terminal if we can.
5780
5781 In either case, we set up the terminal next. If the C<ReadLine> option was
5782 true, we'll get a C<Term::ReadLine> object for the current terminal and save
5783 the appropriate attributes. We then
5784
5785 =cut
5786
5787 sub setterm {
5788
5789     # Load Term::Readline, but quietly; don't debug it and don't trace it.
5790     local $frame = 0;
5791     local $doret = -2;
5792     eval { require Term::ReadLine } or die $@;
5793
5794     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
5795     if ($notty) {
5796         if ($tty) {
5797             my ( $i, $o ) = split $tty, /,/;
5798             $o = $i unless defined $o;
5799             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
5800             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
5801             $IN  = \*IN;
5802             $OUT = \*OUT;
5803             my $sel = select($OUT);
5804             $| = 1;
5805             select($sel);
5806         } ## end if ($tty)
5807
5808         # We don't have a TTY - try to find one via Term::Rendezvous.
5809         else {
5810             eval "require Term::Rendezvous;" or die;
5811
5812             # See if we have anything to pass to Term::Rendezvous.
5813             # Use /tmp/perldbtty$$ if not.
5814             my $rv = $ENV{PERLDB_NOTTY} || "/tmp/perldbtty$$";
5815
5816             # Rendezvous and get the filehandles.
5817             my $term_rv = new Term::Rendezvous $rv;
5818             $IN  = $term_rv->IN;
5819             $OUT = $term_rv->OUT;
5820         } ## end else [ if ($tty)
5821     } ## end if ($notty)
5822
5823     # We're a daughter debugger. Try to fork off another TTY.
5824     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
5825         resetterm(2);
5826     }
5827
5828     # If we shouldn't use Term::ReadLine, don't.
5829     if ( !$rl ) {
5830         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
5831     }
5832
5833     # We're using Term::ReadLine. Get all the attributes for this terminal.
5834     else {
5835         $term = new Term::ReadLine 'perldb', $IN, $OUT;
5836
5837         $rl_attribs = $term->Attribs;
5838         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
5839           if defined $rl_attribs->{basic_word_break_characters}
5840           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
5841         $rl_attribs->{special_prefixes} = '$@&%';
5842         $rl_attribs->{completer_word_break_characters} .= '$@&%';
5843         $rl_attribs->{completion_function} = \&db_complete;
5844     } ## end else [ if (!$rl)
5845
5846     # Set up the LINEINFO filehandle.
5847     $LINEINFO = $OUT     unless defined $LINEINFO;
5848     $lineinfo = $console unless defined $lineinfo;
5849
5850     $term->MinLine(2);
5851
5852     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
5853         $term->SetHistory(@hist);
5854     }
5855
5856     # XXX Ornaments are turned on unconditionally, which is not
5857     # always a good thing.
5858     ornaments($ornaments) if defined $ornaments;
5859     $term_pid = $$;
5860 } ## end sub setterm
5861
5862 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
5863
5864 When the process being debugged forks, or the process invokes a command
5865 via C<system()> which starts a new debugger, we need to be able to get a new
5866 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
5867 fight over the terminal, and you can never quite be sure who's going to get the
5868 input you're typing.
5869
5870 C<get_fork_TTY> is a glob-aliased function which calls the real function that
5871 is tasked with doing all the necessary operating system mojo to get a new
5872 TTY (and probably another window) and to direct the new debugger to read and
5873 write there.
5874
5875 The debugger provides C<get_fork_TTY> functions which work for X Windows and
5876 OS/2. Other systems are not supported. You are encouraged to write
5877 C<get_fork_TTY> functions which work for I<your> platform and contribute them.
5878
5879 =head3 C<xterm_get_fork_TTY>
5880
5881 This function provides the C<get_fork_TTY> function for X windows. If a
5882 program running under the debugger forks, a new <xterm> window is opened and
5883 the subsidiary debugger is directed there.
5884
5885 The C<open()> call is of particular note here. We have the new C<xterm>
5886 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
5887 command (which prints the device name of the TTY we'll want to use for input
5888 and output to STDOUT, then C<sleep> for a very long time, routing this output
5889 to file number 3. This way we can simply read from the <XT> filehandle (which
5890 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
5891
5892 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
5893 properly set up.
5894
5895 =cut
5896
5897 sub xterm_get_fork_TTY {
5898     ( my $name = $0 ) =~ s,^.*[/\\],,s;
5899     open XT,
5900 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
5901  sleep 10000000' |];
5902
5903     # Get the output from 'tty' and clean it up a little.
5904     my $tty = <XT>;
5905     chomp $tty;
5906
5907     $pidprompt = '';    # Shown anyway in titlebar
5908
5909     # There's our new TTY.
5910     return $tty;
5911 } ## end sub xterm_get_fork_TTY
5912
5913 =head3 C<os2_get_fork_TTY>
5914
5915 XXX It behooves an OS/2 expert to write the necessary documentation for this!
5916
5917 =cut
5918
5919 # This example function resets $IN, $OUT itself
5920 sub os2_get_fork_TTY {
5921     local $^F = 40;    # XXXX Fixme!
5922     local $\  = '';
5923     my ( $in1, $out1, $in2, $out2 );
5924
5925     # Having -d in PERL5OPT would lead to a disaster...
5926     local $ENV{PERL5OPT} = $ENV{PERL5OPT} if $ENV{PERL5OPT};
5927     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\b//  if $ENV{PERL5OPT};
5928     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\B/-/ if $ENV{PERL5OPT};
5929     print $OUT "Making kid PERL5OPT->`$ENV{PERL5OPT}'.\n" if $ENV{PERL5OPT};
5930     local $ENV{PERL5LIB} = $ENV{PERL5LIB} ? $ENV{PERL5LIB} : $ENV{PERLLIB};
5931     $ENV{PERL5LIB} = '' unless defined $ENV{PERL5LIB};
5932     $ENV{PERL5LIB} = join ';', @ini_INC, split /;/, $ENV{PERL5LIB};
5933     ( my $name = $0 ) =~ s,^.*[/\\],,s;
5934     my @args;
5935
5936     if (
5937             pipe $in1, $out1
5938         and pipe $in2, $out2
5939
5940         # system P_SESSION will fail if there is another process
5941         # in the same session with a "dependent" asynchronous child session.
5942         and @args = (
5943             $rl, fileno $in1, fileno $out2, "Daughter Perl debugger $pids $name"
5944         )
5945         and (
5946             ( $kpid = CORE::system 4, $^X, '-we',
5947                 <<'ES', @args ) >= 0    # P_SESSION
5948 END {sleep 5 unless $loaded}
5949 BEGIN {open STDIN,  '</dev/con' or warn "reopen stdin: $!"}
5950 use OS2::Process;
5951
5952 my ($rl, $in) = (shift, shift);        # Read from $in and pass through
5953 set_title pop;
5954 system P_NOWAIT, $^X, '-we', <<EOS or die "Cannot start a grandkid";
5955   open IN, '<&=$in' or die "open <&=$in: \$!";
5956   \$| = 1; print while sysread IN, \$_, 1<<16;
5957 EOS
5958
5959 my $out = shift;
5960 open OUT, ">&=$out" or die "Cannot open &=$out for writing: $!";
5961 select OUT;    $| = 1;
5962 require Term::ReadKey if $rl;
5963 Term::ReadKey::ReadMode(4) if $rl; # Nodelay on kbd.  Pipe is automatically nodelay...
5964 print while sysread STDIN, $_, 1<<($rl ? 16 : 0);
5965 ES
5966             or warn "system P_SESSION: $!, $^E" and 0
5967         )
5968         and close $in1
5969         and close $out2
5970       )
5971     {
5972         $pidprompt = '';    # Shown anyway in titlebar
5973         reset_IN_OUT( $in2, $out1 );
5974         $tty = '*reset*';
5975         return '';          # Indicate that reset_IN_OUT is called
5976     } ## end if (pipe $in1, $out1 and...
5977     return;
5978 } ## end sub os2_get_fork_TTY
5979
5980 =head2 C<create_IN_OUT($flags)>
5981
5982 Create a new pair of filehandles, pointing to a new TTY. If impossible,
5983 try to diagnose why.
5984
5985 Flags are:
5986
5987 =over 4
5988
5989 =item * 1 - Don't know how to create a new TTY.
5990
5991 =item * 2 - Debugger has forked, but we can't get a new TTY.
5992
5993 =item * 4 - standard debugger startup is happening.
5994
5995 =back
5996
5997 =cut
5998
5999 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6000
6001     # If we know how to get a new TTY, do it! $in will have
6002     # the TTY name if get_fork_TTY works.
6003     my $in = &get_fork_TTY if defined &get_fork_TTY;
6004
6005     # It used to be that
6006     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6007
6008     if ( not defined $in ) {
6009         my $why = shift;
6010
6011         # We don't know how.
6012         print_help(<<EOP) if $why == 1;
6013 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6014 EOP
6015
6016         # Forked debugger.
6017         print_help(<<EOP) if $why == 2;
6018 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6019   This may be an asynchronous session, so the parent debugger may be active.
6020 EOP
6021
6022         # Note that both debuggers are fighting over the same input.
6023         print_help(<<EOP) if $why != 4;
6024   Since two debuggers fight for the same TTY, input is severely entangled.
6025
6026 EOP
6027         print_help(<<EOP);
6028   I know how to switch the output to a different window in xterms
6029   and OS/2 consoles only.  For a manual switch, put the name of the created I<TTY>
6030   in B<\$DB::fork_TTY>, or define a function B<DB::get_fork_TTY()> returning this.
6031
6032   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6033   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6034
6035 EOP
6036     } ## end if (not defined $in)
6037     elsif ( $in ne '' ) {
6038         TTY($in);
6039     }
6040     else {
6041         $console = '';    # Indicate no need to open-from-the-console
6042     }
6043     undef $fork_TTY;
6044 } ## end sub create_IN_OUT
6045
6046 =head2 C<resetterm>
6047
6048 Handles rejiggering the prompt when we've forked off a new debugger.
6049
6050 If the new debugger happened because of a C<system()> that invoked a
6051 program under the debugger, the arrow between the old pid and the new
6052 in the prompt has I<two> dashes instead of one.
6053
6054 We take the current list of pids and add this one to the end. If there
6055 isn't any list yet, we make one up out of the initial pid associated with
6056 the terminal and our new pid, sticking an arrow (either one-dashed or
6057 two dashed) in between them.
6058
6059 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6060 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6061 and try to do that.
6062
6063 =cut
6064
6065 sub resetterm {    # We forked, so we need a different TTY
6066
6067     # Needs to be passed to create_IN_OUT() as well.
6068     my $in = shift;
6069
6070     # resetterm(2): got in here because of a system() starting a debugger.
6071     # resetterm(1): just forked.
6072     my $systemed = $in > 1 ? '-' : '';
6073
6074     # If there's already a list of pids, add this to the end.
6075     if ($pids) {
6076         $pids =~ s/\]/$systemed->$$]/;
6077     }
6078
6079     # No pid list. Time to make one.
6080     else {
6081         $pids = "[$term_pid->$$]";
6082     }
6083
6084     # The prompt we're going to be using for this debugger.
6085     $pidprompt = $pids;
6086
6087     # We now 0wnz this terminal.
6088     $term_pid = $$;
6089
6090     # Just return if we're not supposed to try to create a new TTY.
6091     return unless $CreateTTY & $in;
6092
6093     # Try to create a new IN/OUT pair.
6094     create_IN_OUT($in);
6095 } ## end sub resetterm
6096
6097 =head2 C<readline>
6098
6099 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6100 the next line, print a message saying we got it, add it to the terminal
6101 history (if possible), and return it.
6102
6103 If there's nothing in the typeahead buffer, check the command filehandle stack.
6104 If there are any filehandles there, read from the last one, and return the line
6105 if we got one. If not, we pop the filehandle off and close it, and try the
6106 next one up the stack.
6107
6108 If we've emptied the filehandle stack, we check to see if we've got a socket
6109 open, and we read that and return it if we do. If we don't, we just call the
6110 core C<readline()> and return its value.
6111
6112 =cut
6113
6114 sub readline {
6115
6116     # Localize to prevent it from being smashed in the program being debugged.
6117     local $.;
6118
6119     # Pull a line out of the typeahead if there's stuff there.
6120     if (@typeahead) {
6121
6122         # How many lines left.
6123         my $left = @typeahead;
6124
6125         # Get the next line.
6126         my $got = shift @typeahead;
6127
6128         # Print a message saying we got input from the typeahead.
6129         local $\ = '';
6130         print $OUT "auto(-$left)", shift, $got, "\n";
6131
6132         # Add it to the terminal history (if possible).
6133         $term->AddHistory($got)
6134           if length($got) > 1
6135           and defined $term->Features->{addHistory};
6136         return $got;
6137     } ## end if (@typeahead)
6138
6139     # We really need to read some input. Turn off entry/exit trace and
6140     # return value printing.
6141     local $frame = 0;
6142     local $doret = -2;
6143
6144     # If there are stacked filehandles to read from ...
6145     while (@cmdfhs) {
6146
6147         # Read from the last one in the stack.
6148         my $line = CORE::readline( $cmdfhs[-1] );
6149
6150         # If we got a line ...
6151         defined $line
6152           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6153           : close pop @cmdfhs;                            # Pop and close
6154     } ## end while (@cmdfhs)
6155
6156     # Nothing on the filehandle stack. Socket?
6157     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6158
6159         # Send anyting we have to send.
6160         $OUT->write( join( '', @_ ) );
6161
6162         # Receive anything there is to receive.
6163         my $stuff;
6164         $IN->recv( $stuff, 2048 );    # XXX "what's wrong with sysread?"
6165                                       # XXX Don't know. You tell me.
6166
6167         # What we got.
6168         $stuff;
6169     } ## end if (ref $OUT and UNIVERSAL::isa...
6170
6171     # No socket. Just read from the terminal.
6172     else {
6173         $term->readline(@_);
6174     }
6175 } ## end sub readline
6176
6177 =head1 OPTIONS SUPPORT ROUTINES
6178
6179 These routines handle listing and setting option values.
6180
6181 =head2 C<dump_option> - list the current value of an option setting
6182
6183 This routine uses C<option_val> to look up the value for an option.
6184 It cleans up escaped single-quotes and then displays the option and
6185 its value.
6186
6187 =cut
6188
6189 sub dump_option {
6190     my ( $opt, $val ) = @_;
6191     $val = option_val( $opt, 'N/A' );
6192     $val =~ s/([\\\'])/\\$1/g;
6193     printf $OUT "%20s = '%s'\n", $opt, $val;
6194 } ## end sub dump_option
6195
6196 sub options2remember {
6197     foreach my $k (@RememberOnROptions) {
6198         $option{$k} = option_val( $k, 'N/A' );
6199     }
6200     return %option;
6201 }
6202
6203 =head2 C<option_val> - find the current value of an option
6204
6205 This can't just be a simple hash lookup because of the indirect way that
6206 the option values are stored. Some are retrieved by calling a subroutine,
6207 some are just variables.
6208
6209 You must supply a default value to be used in case the option isn't set.
6210
6211 =cut
6212
6213 sub option_val {
6214     my ( $opt, $default ) = @_;
6215     my $val;
6216
6217     # Does this option exist, and is it a variable?
6218     # If so, retrieve the value via the value in %optionVars.
6219     if (    defined $optionVars{$opt}
6220         and defined ${ $optionVars{$opt} } )
6221     {
6222         $val = ${ $optionVars{$opt} };
6223     }
6224
6225     # Does this option exist, and it's a subroutine?
6226     # If so, call the subroutine via the ref in %optionAction
6227     # and capture the value.
6228     elsif ( defined $optionAction{$opt}
6229         and defined &{ $optionAction{$opt} } )
6230     {
6231         $val = &{ $optionAction{$opt} }();
6232     }
6233
6234     # If there's an action or variable for the supplied option,
6235     # but no value was set, use the default.
6236     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6237         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6238     {
6239         $val = $default;
6240     }
6241
6242     # Otherwise, do the simple hash lookup.
6243     else {
6244         $val = $option{$opt};
6245     }
6246
6247     # If the value isn't defined, use the default.
6248     # Then return whatever the value is.
6249     $val = $default unless defined $val;
6250     $val;
6251 } ## end sub option_val
6252
6253 =head2 C<parse_options>
6254
6255 Handles the parsing and execution of option setting/displaying commands.
6256
6257 An option entered by itself is assumed to be 'set me to 1' (the default value)
6258 if the option is a boolean one. If not, the user is prompted to enter a valid
6259 value or to query the current value (via 'option? ').
6260
6261 If 'option=value' is entered, we try to extract a quoted string from the
6262 value (if it is quoted). If it's not, we just use the whole value as-is.
6263
6264 We load any modules required to service this option, and then we set it: if
6265 it just gets stuck in a variable, we do that; if there's a subroutine to
6266 handle setting the option, we call that.
6267
6268 Finally, if we're running in interactive mode, we display the effect of the
6269 user's command back to the terminal, skipping this if we're setting things
6270 during initialization.
6271
6272 =cut
6273
6274 sub parse_options {
6275     local ($_) = @_;
6276     local $\ = '';
6277
6278     # These options need a value. Don't allow them to be clobbered by accident.
6279     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6280       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6281       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6282     };
6283
6284     while (length) {
6285         my $val_defaulted;
6286
6287         # Clean off excess leading whitespace.
6288         s/^\s+// && next;
6289
6290         # Options are always all word characters, followed by a non-word
6291         # separator.
6292         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6293         my ( $opt, $sep ) = ( $1, $2 );
6294
6295         # Make sure that such an option exists.
6296         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6297           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6298
6299         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6300         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6301         my $val;
6302
6303         # '?' as separator means query, but must have whitespace after it.
6304         if ( "?" eq $sep ) {
6305             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6306               last
6307               if /^\S/;
6308
6309             #&dump_option($opt);
6310         } ## end if ("?" eq $sep)
6311
6312         # Separator is whitespace (or just a carriage return).
6313         # They're going for a default, which we assume is 1.
6314         elsif ( $sep !~ /\S/ ) {
6315             $val_defaulted = 1;
6316             $val           = "1";   #  this is an evil default; make 'em set it!
6317         }
6318
6319         # Separator is =. Trying to set a value.
6320         elsif ( $sep eq "=" ) {
6321
6322             # If quoted, extract a quoted string.
6323             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6324                 my $quote = $1;
6325                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6326             }
6327
6328             # Not quoted. Use the whole thing. Warn about 'option='.
6329             else {
6330                 s/^(\S*)//;
6331                 $val = $1;
6332                 print OUT qq(Option better cleared using $opt=""\n)
6333                   unless length $val;
6334             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6335
6336         } ## end elsif ($sep eq "=")
6337
6338         # "Quoted" with [], <>, or {}.
6339         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6340             my ($end) =
6341               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6342             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6343               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6344             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6345         } ## end else [ if ("?" eq $sep)
6346
6347         # Exclude non-booleans from getting set to 1 by default.
6348         if ( $opt_needs_val{$option} && $val_defaulted ) {
6349             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6350             print $OUT
6351 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6352             next;
6353         } ## end if ($opt_needs_val{$option...
6354
6355         # Save the option value.
6356         $option{$option} = $val if defined $val;
6357
6358         # Load any module that this option requires.
6359         eval qq{
6360                 local \$frame = 0;
6361                 local \$doret = -2;
6362                 require '$optionRequire{$option}';
6363                 1;
6364                } || die    # XXX: shouldn't happen
6365           if defined $optionRequire{$option}
6366           && defined $val;
6367
6368         # Set it.
6369         # Stick it in the proper variable if it goes in a variable.
6370         ${ $optionVars{$option} } = $val
6371           if defined $optionVars{$option}
6372           && defined $val;
6373
6374         # Call the appropriate sub if it gets set via sub.
6375         &{ $optionAction{$option} }($val)
6376           if defined $optionAction{$option}
6377           && defined &{ $optionAction{$option} }
6378           && defined $val;
6379
6380         # Not initialization - echo the value we set it to.
6381         dump_option($option) unless $OUT eq \*STDERR;
6382     } ## end while (length)
6383 } ## end sub parse_options
6384
6385 =head1 RESTART SUPPORT
6386
6387 These routines are used to store (and restore) lists of items in environment
6388 variables during a restart.
6389
6390 =head2 set_list
6391
6392 Set_list packages up items to be stored in a set of environment variables
6393 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6394 the values). Values outside the standard ASCII charset are stored by encoding
6395 then as hexadecimal values.
6396
6397 =cut
6398
6399 sub set_list {
6400     my ( $stem, @list ) = @_;
6401     my $val;
6402
6403     # VAR_n: how many we have. Scalar assignment gets the number of items.
6404     $ENV{"${stem}_n"} = @list;
6405
6406     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6407     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6408     for $i ( 0 .. $#list ) {
6409         $val = $list[$i];
6410         $val =~ s/\\/\\\\/g;
6411         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6412         $ENV{"${stem}_$i"} = $val;
6413     } ## end for $i (0 .. $#list)
6414 } ## end sub set_list
6415
6416 =head2 get_list
6417
6418 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6419 back, and then pull VAR_0, VAR_1. etc. back out.
6420
6421 =cut
6422
6423 sub get_list {
6424     my $stem = shift;
6425     my @list;
6426     my $n = delete $ENV{"${stem}_n"};
6427     my $val;
6428     for $i ( 0 .. $n - 1 ) {
6429         $val = delete $ENV{"${stem}_$i"};
6430         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6431         push @list, $val;
6432     }
6433     @list;
6434 } ## end sub get_list
6435
6436 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6437
6438 =head2 catch()
6439
6440 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6441 set an already-existing global scalar variable to a constant value. This
6442 avoids allocating any memory possibly in the middle of something that will
6443 get all confused if we do.
6444
6445 =cut
6446
6447 sub catch {
6448     $signal = 1;
6449     return;    # Put nothing on the stack - malloc/free land!
6450 }
6451
6452 =head2 C<warn()>
6453
6454 C<warn> emits a warning, by joining together its arguments and printing
6455 them, with couple of fillips.
6456
6457 If the composited message I<doesn't> end with a newline, we automatically
6458 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6459 to be set to the filehandle to be used to output warnings; it makes no
6460 assumptions about what filehandles are available.
6461
6462 =cut
6463
6464 sub warn {
6465     my ($msg) = join( "", @_ );
6466     $msg .= ": $!\n" unless $msg =~ /\n$/;
6467     local $\ = '';
6468     print $OUT $msg;
6469 } ## end sub warn
6470
6471 =head1 INITIALIZATION TTY SUPPORT
6472
6473 =head2 C<reset_IN_OUT>
6474
6475 This routine handles restoring the debugger's input and output filehandles
6476 after we've tried and failed to move them elsewhere.  In addition, it assigns
6477 the debugger's output filehandle to $LINEINFO if it was already open there.
6478
6479 =cut
6480
6481 sub reset_IN_OUT {
6482     my $switch_li = $LINEINFO eq $OUT;
6483
6484     # If there's a term and it's able to get a new tty, try to get one.
6485     if ( $term and $term->Features->{newTTY} ) {
6486         ( $IN, $OUT ) = ( shift, shift );
6487         $term->newTTY( $IN, $OUT );
6488     }
6489
6490     # This term can't get a new tty now. Better luck later.
6491     elsif ($term) {
6492         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6493     }
6494
6495     # Set the filehndles up as they were.
6496     else {
6497         ( $IN, $OUT ) = ( shift, shift );
6498     }
6499
6500     # Unbuffer the output filehandle.
6501     my $o = select $OUT;
6502     $| = 1;
6503     select $o;
6504
6505     # Point LINEINFO to the same output filehandle if it was there before.
6506     $LINEINFO = $OUT if $switch_li;
6507 } ## end sub reset_IN_OUT
6508
6509 =head1 OPTION SUPPORT ROUTINES
6510
6511 The following routines are used to process some of the more complicated
6512 debugger options.
6513
6514 =head2 C<TTY>
6515
6516 Sets the input and output filehandles to the specified files or pipes.
6517 If the terminal supports switching, we go ahead and do it. If not, and
6518 there's already a terminal in place, we save the information to take effect
6519 on restart.
6520
6521 If there's no terminal yet (for instance, during debugger initialization),
6522 we go ahead and set C<$console> and C<$tty> to the file indicated.
6523
6524 =cut
6525
6526 sub TTY {
6527     if ( @_ and $term and $term->Features->{newTTY} ) {
6528
6529         # This terminal supports switching to a new TTY.
6530         # Can be a list of two files, or on string containing both names,
6531         # comma-separated.
6532         # XXX Should this perhaps be an assignment from @_?
6533         my ( $in, $out ) = shift;
6534         if ( $in =~ /,/ ) {
6535
6536             # Split list apart if supplied.
6537             ( $in, $out ) = split /,/, $in, 2;
6538         }
6539         else {
6540
6541             # Use the same file for both input and output.
6542             $out = $in;
6543         }
6544
6545         # Open file onto the debugger's filehandles, if you can.
6546         open IN,  $in     or die "cannot open `$in' for read: $!";
6547         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6548
6549         # Swap to the new filehandles.
6550         reset_IN_OUT( \*IN, \*OUT );
6551
6552         # Save the setting for later.
6553         return $tty = $in;
6554     } ## end if (@_ and $term and $term...
6555
6556     # Terminal doesn't support new TTY, or doesn't support readline.
6557     # Can't do it now, try restarting.
6558     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6559
6560     # Useful if done through PERLDB_OPTS:
6561     $console = $tty = shift if @_;
6562
6563     # Return whatever the TTY is.
6564     $tty or $console;
6565 } ## end sub TTY
6566
6567 =head2 C<noTTY>
6568
6569 Sets the C<$notty> global, controlling whether or not the debugger tries to
6570 get a terminal to read from. If called after a terminal is already in place,
6571 we save the value to use it if we're restarted.
6572
6573 =cut
6574
6575 sub noTTY {
6576     if ($term) {
6577         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6578     }
6579     $notty = shift if @_;
6580     $notty;
6581 } ## end sub noTTY
6582
6583 =head2 C<ReadLine>
6584
6585 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6586 (essentially, no C<readline> processing on this "terminal"). Otherwise, we
6587 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6588 the value in case a restart is done so we can change it then.
6589
6590 =cut
6591
6592 sub ReadLine {
6593     if ($term) {
6594         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6595     }
6596     $rl = shift if @_;
6597     $rl;
6598 } ## end sub ReadLine
6599
6600 =head2 C<RemotePort>
6601
6602 Sets the port that the debugger will try to connect to when starting up.
6603 If the terminal's already been set up, we can't do it, but we remember the
6604 setting in case the user does a restart.
6605
6606 =cut
6607
6608 sub RemotePort {
6609     if ($term) {
6610         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6611     }
6612     $remoteport = shift if @_;
6613     $remoteport;
6614 } ## end sub RemotePort
6615
6616 =head2 C<tkRunning>
6617
6618 Checks with the terminal to see if C<Tk> is running, and returns true or
6619 false. Returns false if the current terminal doesn't support C<readline>.
6620
6621 =cut
6622
6623 sub tkRunning {
6624     if ( ${ $term->Features }{tkRunning} ) {
6625         return $term->tkRunning(@_);
6626     }
6627     else {
6628         local $\ = '';
6629         print $OUT "tkRunning not supported by current ReadLine package.\n";
6630         0;
6631     }
6632 } ## end sub tkRunning
6633
6634 =head2 C<NonStop>
6635
6636 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6637 debugger remembers the setting in case you restart, though.
6638
6639 =cut
6640
6641 sub NonStop {
6642     if ($term) {
6643         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6644           if @_;
6645     }
6646     $runnonstop = shift if @_;
6647     $runnonstop;
6648 } ## end sub NonStop
6649
6650 sub DollarCaretP {
6651     if ($term) {
6652         &warn("Some flag changes could not take effect until next 'R'!\n")
6653           if @_;
6654     }
6655     $^P = parse_DollarCaretP_flags(shift) if @_;
6656     expand_DollarCaretP_flags($^P);
6657 }
6658
6659 sub OnlyAssertions {
6660     if ($term) {
6661         &warn("Too late to set up OnlyAssertions mode, enabled on next 'R'!\n")
6662           if @_;
6663     }
6664     if (@_) {
6665         unless ( defined $ini_assertion ) {
6666             if ($term) {
6667                 &warn("Current Perl interpreter doesn't support assertions");
6668             }
6669             return 0;
6670         }
6671         if (shift) {
6672             unless ($ini_assertion) {
6673                 print "Assertions will be active on next 'R'!\n";
6674                 $ini_assertion = 1;
6675             }
6676             $^P &= ~$DollarCaretP_flags{PERLDBf_SUB};
6677             $^P |= $DollarCaretP_flags{PERLDBf_ASSERTION};
6678         }
6679         else {
6680             $^P |= $DollarCaretP_flags{PERLDBf_SUB};
6681         }
6682     }
6683     !( $^P & $DollarCaretP_flags{PERLDBf_SUB} ) || 0;
6684 }
6685
6686 =head2 C<pager>
6687
6688 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6689 there already.
6690
6691 =cut
6692
6693 sub pager {
6694     if (@_) {
6695         $pager = shift;
6696         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6697     }
6698     $pager;
6699 } ## end sub pager
6700
6701 =head2 C<shellBang>
6702
6703 Sets the shell escape command, and generates a printable copy to be used
6704 in the help.
6705
6706 =cut
6707
6708 sub shellBang {
6709
6710     # If we got an argument, meta-quote it, and add '\b' if it
6711     # ends in a word character.
6712     if (@_) {
6713         $sh = quotemeta shift;
6714         $sh .= "\\b" if $sh =~ /\w$/;
6715     }
6716
6717     # Generate the printable version for the help:
6718     $psh = $sh;    # copy it
6719     $psh =~ s/\\b$//;        # Take off trailing \b if any
6720     $psh =~ s/\\(.)/$1/g;    # De-escape
6721     $psh;                    # return the printable version
6722 } ## end sub shellBang
6723
6724 =head2 C<ornaments>
6725
6726 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
6727 was passed as the argument. (This means you can't override the terminal's
6728 ornaments.)
6729
6730 =cut
6731
6732 sub ornaments {
6733     if ( defined $term ) {
6734
6735         # We don't want to show warning backtraces, but we do want die() ones.
6736         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
6737
6738         # No ornaments if the terminal doesn't support them.
6739         return '' unless $term->Features->{ornaments};
6740         eval { $term->ornaments(@_) } || '';
6741     }
6742
6743     # Use what was passed in if we can't determine it ourselves.
6744     else {
6745         $ornaments = shift;
6746     }
6747 } ## end sub ornaments
6748
6749 =head2 C<recallCommand>
6750
6751 Sets the recall command, and builds a printable version which will appear in
6752 the help text.
6753
6754 =cut
6755
6756 sub recallCommand {
6757
6758     # If there is input, metaquote it. Add '\b' if it ends with a word
6759     # character.
6760     if (@_) {
6761         $rc = quotemeta shift;
6762         $rc .= "\\b" if $rc =~ /\w$/;
6763     }
6764
6765     # Build it into a printable version.
6766     $prc = $rc;    # Copy it
6767     $prc =~ s/\\b$//;        # Remove trailing \b
6768     $prc =~ s/\\(.)/$1/g;    # Remove escapes
6769     $prc;                    # Return the printable version
6770 } ## end sub recallCommand
6771
6772 =head2 C<LineInfo> - where the line number information goes
6773
6774 Called with no arguments, returns the file or pipe that line info should go to.
6775
6776 Called with an argument (a file or a pipe), it opens that onto the
6777 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
6778 file or pipe again to the caller.
6779
6780 =cut
6781
6782 sub LineInfo {
6783     return $lineinfo unless @_;
6784     $lineinfo = shift;
6785
6786     #  If this is a valid "thing to be opened for output", tack a
6787     # '>' onto the front.
6788     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
6789
6790     # If this is a pipe, the stream points to a slave editor.
6791     $slave_editor = ( $stream =~ /^\|/ );
6792
6793     # Open it up and unbuffer it.
6794     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
6795     $LINEINFO = \*LINEINFO;
6796     my $save = select($LINEINFO);
6797     $| = 1;
6798     select($save);
6799
6800     # Hand the file or pipe back again.
6801     $lineinfo;
6802 } ## end sub LineInfo
6803
6804 =head1 COMMAND SUPPORT ROUTINES
6805
6806 These subroutines provide functionality for various commands.
6807
6808 =head2 C<list_modules>
6809
6810 For the C<M> command: list modules loaded and their versions.
6811 Essentially just runs through the keys in %INC, picks up the
6812 $VERSION package globals from each package, gets the file name, and formats the
6813 information for output.
6814
6815 =cut
6816
6817 sub list_modules {    # versions
6818     my %version;
6819     my $file;
6820
6821     # keys are the "as-loaded" name, values are the fully-qualified path
6822     # to the file itself.
6823     for ( keys %INC ) {
6824         $file = $_;                                # get the module name
6825         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
6826         s,/,::,g;                                  # change '/' to '::'
6827         s/^perl5db$/DB/;                           # Special case: debugger
6828                                                    # moves to package DB
6829         s/^Term::ReadLine::readline$/readline/;    # simplify readline
6830
6831         # If the package has a $VERSION package global (as all good packages
6832         # should!) decode it and save as partial message.
6833         if ( defined ${ $_ . '::VERSION' } ) {
6834             $version{$file} = "${ $_ . '::VERSION' } from ";
6835         }
6836
6837         # Finish up the message with the file the package came from.
6838         $version{$file} .= $INC{$file};
6839     } ## end for (keys %INC)
6840
6841     # Hey, dumpit() formats a hash nicely, so why not use it?
6842     dumpit( $OUT, \%version );
6843 } ## end sub list_modules
6844
6845 =head2 C<sethelp()>
6846
6847 Sets up the monster string used to format and print the help.
6848
6849 =head3 HELP MESSAGE FORMAT
6850
6851 The help message is a peculiar format unto itself; it mixes C<pod> 'ornaments'
6852 (BE<lt>E<gt>, IE<gt>E<lt>) with tabs to come up with a format that's fairly
6853 easy to parse and portable, but which still allows the help to be a little
6854 nicer than just plain text.
6855
6856 Essentially, you define the command name (usually marked up with BE<gt>E<lt>
6857 and IE<gt>E<lt>), followed by a tab, and then the descriptive text, ending in a newline. The descriptive text can also be marked up in the same way. If you
6858 need to continue the descriptive text to another line, start that line with
6859 just tabs and then enter the marked-up text.
6860
6861 If you are modifying the help text, I<be careful>. The help-string parser is
6862 not very sophisticated, and if you don't follow these rules it will mangle the
6863 help beyond hope until you fix the string.
6864
6865 =cut
6866
6867 sub sethelp {
6868
6869     # XXX: make sure there are tabs between the command and explanation,
6870     #      or print_help will screw up your formatting if you have
6871     #      eeevil ornaments enabled.  This is an insane mess.
6872
6873     $help = "
6874 Help is currently only available for the new 5.8 command set.
6875 No help is available for the old command set.
6876 We assume you know what you're doing if you switch to it.
6877
6878 B<T>        Stack trace.
6879 B<s> [I<expr>]    Single step [in I<expr>].
6880 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
6881 <B<CR>>        Repeat last B<n> or B<s> command.
6882 B<r>        Return from current subroutine.
6883 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
6884         at the specified position.
6885 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
6886 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
6887 B<l> I<line>        List single I<line>.
6888 B<l> I<subname>    List first window of lines from subroutine.
6889 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
6890 B<l>        List next window of lines.
6891 B<->        List previous window of lines.
6892 B<v> [I<line>]    View window around I<line>.
6893 B<.>        Return to the executed line.
6894 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
6895         I<filename> may be either the full name of the file, or a regular
6896         expression matching the full file name:
6897         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
6898         Evals (with saved bodies) are considered to be filenames:
6899         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
6900         (in the order of execution).
6901 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
6902 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
6903 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
6904 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
6905 B<t>        Toggle trace mode.
6906 B<t> I<expr>        Trace through execution of I<expr>.
6907 B<b>        Sets breakpoint on current line)
6908 B<b> [I<line>] [I<condition>]
6909         Set breakpoint; I<line> defaults to the current execution line;
6910         I<condition> breaks if it evaluates to true, defaults to '1'.
6911 B<b> I<subname> [I<condition>]
6912         Set breakpoint at first line of subroutine.
6913 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
6914 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
6915 B<b> B<postpone> I<subname> [I<condition>]
6916         Set breakpoint at first line of subroutine after
6917         it is compiled.
6918 B<b> B<compile> I<subname>
6919         Stop after the subroutine is compiled.
6920 B<B> [I<line>]    Delete the breakpoint for I<line>.
6921 B<B> I<*>             Delete all breakpoints.
6922 B<a> [I<line>] I<command>
6923         Set an action to be done before the I<line> is executed;
6924         I<line> defaults to the current execution line.
6925         Sequence is: check for breakpoint/watchpoint, print line
6926         if necessary, do action, prompt user if necessary,
6927         execute line.
6928 B<a>        Does nothing
6929 B<A> [I<line>]    Delete the action for I<line>.
6930 B<A> I<*>             Delete all actions.
6931 B<w> I<expr>        Add a global watch-expression.
6932 B<w>             Does nothing
6933 B<W> I<expr>        Delete a global watch-expression.
6934 B<W> I<*>             Delete all watch-expressions.
6935 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
6936         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
6937 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
6938 B<x> I<expr>        Evals expression in list context, dumps the result.
6939 B<m> I<expr>        Evals expression in list context, prints methods callable
6940         on the first element of the result.
6941 B<m> I<class>        Prints methods callable via the given class.
6942 B<M>        Show versions of loaded modules.
6943 B<i> I<class>       Prints nested parents of given class.
6944 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
6945 B<P> Something to do with assertions...
6946
6947 B<<> ?            List Perl commands to run before each prompt.
6948 B<<> I<expr>        Define Perl command to run before each prompt.
6949 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
6950 B<< *>                Delete the list of perl commands to run before each prompt.
6951 B<>> ?            List Perl commands to run after each prompt.
6952 B<>> I<expr>        Define Perl command to run after each prompt.
6953 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
6954 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
6955 B<{> I<db_command>    Define debugger command to run before each prompt.
6956 B<{> ?            List debugger commands to run before each prompt.
6957 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
6958 B<{ *>             Delete the list of debugger commands to run before each prompt.
6959 B<$prc> I<number>    Redo a previous command (default previous command).
6960 B<$prc> I<-number>    Redo number'th-to-last command.
6961 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
6962         See 'B<O> I<recallCommand>' too.
6963 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
6964       . (
6965         $rc eq $sh
6966         ? ""
6967         : "
6968 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
6969       ) . "
6970         See 'B<O> I<shellBang>' too.
6971 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
6972 B<save> I<file>       Save current debugger session (actual history) to I<file>.
6973 B<rerun>           Rerun session to current position.
6974 B<rerun> I<n>         Rerun session to numbered command.
6975 B<rerun> I<-n>        Rerun session to number'th-to-last command.
6976 B<H> I<-number>    Display last number commands (default all).
6977 B<H> I<*>          Delete complete history.
6978 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
6979 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
6980 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
6981 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
6982 I<command>        Execute as a perl statement in current package.
6983 B<R>        Pure-man-restart of debugger, some of debugger state
6984         and command-line options may be lost.
6985         Currently the following settings are preserved:
6986         history, breakpoints and actions, debugger B<O>ptions
6987         and the following command-line options: I<-w>, I<-I>, I<-e>.
6988
6989 B<o> [I<opt>] ...    Set boolean option to true
6990 B<o> [I<opt>B<?>]    Query options
6991 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
6992         Set options.  Use quotes in spaces in value.
6993     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
6994     I<pager>            program for output of \"|cmd\";
6995     I<tkRunning>            run Tk while prompting (with ReadLine);
6996     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
6997     I<inhibit_exit>        Allows stepping off the end of the script.
6998     I<ImmediateStop>        Debugger should stop as early as possible.
6999     I<RemotePort>            Remote hostname:port for remote debugging
7000   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7001     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7002     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7003     I<globPrint>             whether to print contents of globs;
7004     I<DumpDBFiles>         dump arrays holding debugged files;
7005     I<DumpPackages>         dump symbol tables of packages;
7006     I<DumpReused>             dump contents of \"reused\" addresses;
7007     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7008     I<bareStringify>         Do not print the overload-stringified value;
7009   Other options include:
7010     I<PrintRet>        affects printing of return value after B<r> command,
7011     I<frame>        affects printing messages on subroutine entry/exit.
7012     I<AutoTrace>    affects printing messages on possible breaking points.
7013     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7014     I<ornaments>     affects screen appearance of the command line.
7015     I<CreateTTY>     bits control attempts to create a new TTY on events:
7016             1: on fork()    2: debugger is started inside debugger
7017             4: on startup
7018     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7019     You can put additional initialization options I<TTY>, I<noTTY>,
7020     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7021     `B<R>' after you set them).
7022
7023 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7024 B<h>        Summary of debugger commands.
7025 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7026 B<h h>        Long help for debugger commands
7027 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7028         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7029         Set B<\$DB::doccmd> to change viewer.
7030
7031 Type `|h h' for a paged display if this was too hard to read.
7032
7033 ";    # Fix balance of vi % matching: }}}}
7034
7035     #  note: tabs in the following section are not-so-helpful
7036     $summary = <<"END_SUM";
7037 I<List/search source lines:>               I<Control script execution:>
7038   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7039   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7040   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7041   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7042   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7043   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7044 I<Debugger controls:>                        B<L>           List break/watch/actions
7045   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7046   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7047   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7048   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7049   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7050   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7051   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7052   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7053   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7054 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7055   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7056   B<p> I<expr>         Print expression (uses script's current package).
7057   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7058   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7059   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7060   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7061 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7062 END_SUM
7063
7064     # ')}}; # Fix balance of vi % matching
7065
7066     # and this is really numb...
7067     $pre580_help = "
7068 B<T>        Stack trace.
7069 B<s> [I<expr>]    Single step [in I<expr>].
7070 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7071 B<CR>>        Repeat last B<n> or B<s> command.
7072 B<r>        Return from current subroutine.
7073 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7074         at the specified position.
7075 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7076 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7077 B<l> I<line>        List single I<line>.
7078 B<l> I<subname>    List first window of lines from subroutine.
7079 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7080 B<l>        List next window of lines.
7081 B<->        List previous window of lines.
7082 B<w> [I<line>]    List window around I<line>.
7083 B<.>        Return to the executed line.
7084 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7085         I<filename> may be either the full name of the file, or a regular
7086         expression matching the full file name:
7087         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7088         Evals (with saved bodies) are considered to be filenames:
7089         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7090         (in the order of execution).
7091 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7092 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7093 B<L>        List all breakpoints and actions.
7094 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7095 B<t>        Toggle trace mode.
7096 B<t> I<expr>        Trace through execution of I<expr>.
7097 B<b> [I<line>] [I<condition>]
7098         Set breakpoint; I<line> defaults to the current execution line;
7099         I<condition> breaks if it evaluates to true, defaults to '1'.
7100 B<b> I<subname> [I<condition>]
7101         Set breakpoint at first line of subroutine.
7102 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7103 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7104 B<b> B<postpone> I<subname> [I<condition>]
7105         Set breakpoint at first line of subroutine after
7106         it is compiled.
7107 B<b> B<compile> I<subname>
7108         Stop after the subroutine is compiled.
7109 B<d> [I<line>]    Delete the breakpoint for I<line>.
7110 B<D>        Delete all breakpoints.
7111 B<a> [I<line>] I<command>
7112         Set an action to be done before the I<line> is executed;
7113         I<line> defaults to the current execution line.
7114         Sequence is: check for breakpoint/watchpoint, print line
7115         if necessary, do action, prompt user if necessary,
7116         execute line.
7117 B<a> [I<line>]    Delete the action for I<line>.
7118 B<A>        Delete all actions.
7119 B<W> I<expr>        Add a global watch-expression.
7120 B<W>        Delete all watch-expressions.
7121 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7122         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7123 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7124 B<x> I<expr>        Evals expression in list context, dumps the result.
7125 B<m> I<expr>        Evals expression in list context, prints methods callable
7126         on the first element of the result.
7127 B<m> I<class>        Prints methods callable via the given class.
7128
7129 B<<> ?            List Perl commands to run before each prompt.
7130 B<<> I<expr>        Define Perl command to run before each prompt.
7131 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7132 B<>> ?            List Perl commands to run after each prompt.
7133 B<>> I<expr>        Define Perl command to run after each prompt.
7134 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7135 B<{> I<db_command>    Define debugger command to run before each prompt.
7136 B<{> ?            List debugger commands to run before each prompt.
7137 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7138 B<$prc> I<number>    Redo a previous command (default previous command).
7139 B<$prc> I<-number>    Redo number'th-to-last command.
7140 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7141         See 'B<O> I<recallCommand>' too.
7142 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7143       . (
7144         $rc eq $sh
7145         ? ""
7146         : "
7147 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7148       ) . "
7149         See 'B<O> I<shellBang>' too.
7150 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7151 B<H> I<-number>    Display last number commands (default all).
7152 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7153 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7154 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7155 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7156 I<command>        Execute as a perl statement in current package.
7157 B<v>        Show versions of loaded modules.
7158 B<R>        Pure-man-restart of debugger, some of debugger state
7159         and command-line options may be lost.
7160         Currently the following settings are preserved:
7161         history, breakpoints and actions, debugger B<O>ptions
7162         and the following command-line options: I<-w>, I<-I>, I<-e>.
7163
7164 B<O> [I<opt>] ...    Set boolean option to true
7165 B<O> [I<opt>B<?>]    Query options
7166 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7167         Set options.  Use quotes in spaces in value.
7168     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7169     I<pager>            program for output of \"|cmd\";
7170     I<tkRunning>            run Tk while prompting (with ReadLine);
7171     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7172     I<inhibit_exit>        Allows stepping off the end of the script.
7173     I<ImmediateStop>        Debugger should stop as early as possible.
7174     I<RemotePort>            Remote hostname:port for remote debugging
7175   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7176     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7177     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7178     I<globPrint>             whether to print contents of globs;
7179     I<DumpDBFiles>         dump arrays holding debugged files;
7180     I<DumpPackages>         dump symbol tables of packages;
7181     I<DumpReused>             dump contents of \"reused\" addresses;
7182     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7183     I<bareStringify>         Do not print the overload-stringified value;
7184   Other options include:
7185     I<PrintRet>        affects printing of return value after B<r> command,
7186     I<frame>        affects printing messages on subroutine entry/exit.
7187     I<AutoTrace>    affects printing messages on possible breaking points.
7188     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7189     I<ornaments>     affects screen appearance of the command line.
7190     I<CreateTTY>     bits control attempts to create a new TTY on events:
7191             1: on fork()    2: debugger is started inside debugger
7192             4: on startup
7193     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7194     You can put additional initialization options I<TTY>, I<noTTY>,
7195     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7196     `B<R>' after you set them).
7197
7198 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7199 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7200 B<h h>        Summary of debugger commands.
7201 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7202         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7203         Set B<\$DB::doccmd> to change viewer.
7204
7205 Type `|h' for a paged display if this was too hard to read.
7206
7207 ";    # Fix balance of vi % matching: }}}}
7208
7209     #  note: tabs in the following section are not-so-helpful
7210     $pre580_summary = <<"END_SUM";
7211 I<List/search source lines:>               I<Control script execution:>
7212   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7213   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7214   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7215   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7216   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7217   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7218 I<Debugger controls:>                        B<L>           List break/watch/actions
7219   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7220   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7221   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7222   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7223   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7224   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7225   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7226   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7227 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7228   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7229   B<p> I<expr>         Print expression (uses script's current package).
7230   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7231   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7232   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7233   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7234 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7235 END_SUM
7236
7237     # ')}}; # Fix balance of vi % matching
7238
7239 } ## end sub sethelp
7240
7241 =head2 C<print_help()>
7242
7243 Most of what C<print_help> does is just text formatting. It finds the
7244 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7245 terminal control characters to simulate them (courtesy of
7246 <Term::ReadLine::TermCap>).
7247
7248 =cut
7249
7250 sub print_help {
7251     local $_ = shift;
7252
7253     # Restore proper alignment destroyed by eeevil I<> and B<>
7254     # ornaments: A pox on both their houses!
7255     #
7256     # A help command will have everything up to and including
7257     # the first tab sequence padded into a field 16 (or if indented 20)
7258     # wide.  If it's wider than that, an extra space will be added.
7259     s{
7260         ^                       # only matters at start of line
7261           ( \040{4} | \t )*     # some subcommands are indented
7262           ( < ?                 # so <CR> works
7263             [BI] < [^\t\n] + )  # find an eeevil ornament
7264           ( \t+ )               # original separation, discarded
7265           ( .* )                # this will now start (no earlier) than
7266                                 # column 16
7267     } {
7268         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7269         my $clean = $command;
7270         $clean =~ s/[BI]<([^>]*)>/$1/g;
7271
7272         # replace with this whole string:
7273         ($leadwhite ? " " x 4 : "")
7274       . $command
7275       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7276       . $text;
7277
7278     }mgex;
7279
7280     s{                          # handle bold ornaments
7281        B < ( [^>] + | > ) >
7282     } {
7283           $Term::ReadLine::TermCap::rl_term_set[2]
7284         . $1
7285         . $Term::ReadLine::TermCap::rl_term_set[3]
7286     }gex;
7287
7288     s{                         # handle italic ornaments
7289        I < ( [^>] + | > ) >
7290     } {
7291           $Term::ReadLine::TermCap::rl_term_set[0]
7292         . $1
7293         . $Term::ReadLine::TermCap::rl_term_set[1]
7294     }gex;
7295
7296     local $\ = '';
7297     print $OUT $_;
7298 } ## end sub print_help
7299
7300 =head2 C<fix_less>
7301
7302 This routine does a lot of gyrations to be sure that the pager is C<less>.
7303 It checks for C<less> masquerading as C<more> and records the result in
7304 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7305
7306 =cut
7307
7308 sub fix_less {
7309
7310     # We already know if this is set.
7311     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7312
7313     # Pager is less for sure.
7314     my $is_less = $pager =~ /\bless\b/;
7315     if ( $pager =~ /\bmore\b/ ) {
7316
7317         # Nope, set to more. See what's out there.
7318         my @st_more = stat('/usr/bin/more');
7319         my @st_less = stat('/usr/bin/less');
7320
7321         # is it really less, pretending to be more?
7322              $is_less = @st_more
7323           && @st_less
7324           && $st_more[0] == $st_less[0]
7325           && $st_more[1] == $st_less[1];
7326     } ## end if ($pager =~ /\bmore\b/)
7327
7328     # changes environment!
7329     # 'r' added so we don't do (slow) stats again.
7330     $ENV{LESS} .= 'r' if $is_less;
7331 } ## end sub fix_less
7332
7333 =head1 DIE AND WARN MANAGEMENT
7334
7335 =head2 C<diesignal>
7336
7337 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7338 to debug a debugger problem.
7339
7340 It does its best to report the error that occurred, and then forces the
7341 program, debugger, and everything to die.
7342
7343 =cut
7344
7345 sub diesignal {
7346
7347     # No entry/exit messages.
7348     local $frame = 0;
7349
7350     # No return value prints.
7351     local $doret = -2;
7352
7353     # set the abort signal handling to the default (just terminate).
7354     $SIG{'ABRT'} = 'DEFAULT';
7355
7356     # If we enter the signal handler recursively, kill myself with an
7357     # abort signal (so we just terminate).
7358     kill 'ABRT', $$ if $panic++;
7359
7360     # If we can show detailed info, do so.
7361     if ( defined &Carp::longmess ) {
7362
7363         # Don't recursively enter the warn handler, since we're carping.
7364         local $SIG{__WARN__} = '';
7365
7366         # Skip two levels before reporting traceback: we're skipping
7367         # mydie and confess.
7368         local $Carp::CarpLevel = 2;    # mydie + confess
7369
7370         # Tell us all about it.
7371         &warn( Carp::longmess("Signal @_") );
7372     }
7373
7374     # No Carp. Tell us about the signal as best we can.
7375     else {
7376         local $\ = '';
7377         print $DB::OUT "Got signal @_\n";
7378     }
7379
7380     # Drop dead.
7381     kill 'ABRT', $$;
7382 } ## end sub diesignal
7383
7384 =head2 C<dbwarn>
7385
7386 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7387 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7388
7389 =cut
7390
7391 sub dbwarn {
7392
7393     # No entry/exit trace.
7394     local $frame = 0;
7395
7396     # No return value printing.
7397     local $doret = -2;
7398
7399     # Turn off warn and die handling to prevent recursive entries to this
7400     # routine.
7401     local $SIG{__WARN__} = '';
7402     local $SIG{__DIE__}  = '';
7403
7404     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7405     # done yet), we may not be able to do a require.
7406     eval { require Carp }
7407       if defined $^S;    # If error/warning during compilation,
7408                          # require may be broken.
7409
7410     # Use the core warn() unless Carp loaded OK.
7411     CORE::warn( @_,
7412         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7413       return
7414       unless defined &Carp::longmess;
7415
7416     # Save the current values of $single and $trace, and then turn them off.
7417     my ( $mysingle, $mytrace ) = ( $single, $trace );
7418     $single = 0;
7419     $trace  = 0;
7420
7421     # We can call Carp::longmess without its being "debugged" (which we
7422     # don't want - we just want to use it!). Capture this for later.
7423     my $mess = Carp::longmess(@_);
7424
7425     # Restore $single and $trace to their original values.
7426     ( $single, $trace ) = ( $mysingle, $mytrace );
7427
7428     # Use the debugger's own special way of printing warnings to print
7429     # the stack trace message.
7430     &warn($mess);
7431 } ## end sub dbwarn
7432
7433 =head2 C<dbdie>
7434
7435 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7436 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7437 single stepping and tracing during the call to C<Carp::longmess> to avoid
7438 debugging it - we just want to use it.
7439
7440 If C<dieLevel> is zero, we let the program being debugged handle the
7441 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7442 the debugger takes over all exception handling, printing a backtrace and
7443 displaying the exception via its C<dbwarn()> routine.
7444
7445 =cut
7446
7447 sub dbdie {
7448     local $frame         = 0;
7449     local $doret         = -2;
7450     local $SIG{__DIE__}  = '';
7451     local $SIG{__WARN__} = '';
7452     my $i      = 0;
7453     my $ineval = 0;
7454     my $sub;
7455     if ( $dieLevel > 2 ) {
7456         local $SIG{__WARN__} = \&dbwarn;
7457         &warn(@_);    # Yell no matter what
7458         return;
7459     }
7460     if ( $dieLevel < 2 ) {
7461         die @_ if $^S;    # in eval propagate
7462     }
7463
7464     # The code used to check $^S to see if compiliation of the current thing
7465     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7466     eval { require Carp };
7467
7468     die( @_,
7469         "\nCannot print stack trace, load with -MCarp option to see stack" )
7470       unless defined &Carp::longmess;
7471
7472     # We do not want to debug this chunk (automatic disabling works
7473     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7474     # get the stack trace from Carp::longmess (if possible), restore $signal
7475     # and $trace, and then die with the stack trace.
7476     my ( $mysingle, $mytrace ) = ( $single, $trace );
7477     $single = 0;
7478     $trace  = 0;
7479     my $mess = "@_";
7480     {
7481
7482         package Carp;    # Do not include us in the list
7483         eval { $mess = Carp::longmess(@_); };
7484     }
7485     ( $single, $trace ) = ( $mysingle, $mytrace );
7486     die $mess;
7487 } ## end sub dbdie
7488
7489 =head2 C<warnlevel()>
7490
7491 Set the C<$DB::warnLevel> variable that stores the value of the
7492 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7493 results in the debugger taking over all warning handlers. Setting
7494 C<warnLevel> to zero leaves any warning handlers set up by the program
7495 being debugged in place.
7496
7497 =cut
7498
7499 sub warnLevel {
7500     if (@_) {
7501         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7502         $warnLevel = shift;
7503         if ($warnLevel) {
7504             $SIG{__WARN__} = \&DB::dbwarn;
7505         }
7506         elsif ($prevwarn) {
7507             $SIG{__WARN__} = $prevwarn;
7508         }
7509     } ## end if (@_)
7510     $warnLevel;
7511 } ## end sub warnLevel
7512
7513 =head2 C<dielevel>
7514
7515 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7516 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7517 zero lets you use your own C<die()> handler.
7518
7519 =cut
7520
7521 sub dieLevel {
7522     local $\ = '';
7523     if (@_) {
7524         $prevdie = $SIG{__DIE__} unless $dieLevel;
7525         $dieLevel = shift;
7526         if ($dieLevel) {
7527
7528             # Always set it to dbdie() for non-zero values.
7529             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7530
7531             # No longer exists, so don't try  to use it.
7532             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7533
7534             # If we've finished initialization, mention that stack dumps
7535             # are enabled, If dieLevel is 1, we won't stack dump if we die
7536             # in an eval().
7537             print $OUT "Stack dump during die enabled",
7538               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7539               if $I_m_init;
7540
7541             # XXX This is probably obsolete, given that diehard() is gone.
7542             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7543         } ## end if ($dieLevel)
7544
7545         # Put the old one back if there was one.
7546         elsif ($prevdie) {
7547             $SIG{__DIE__} = $prevdie;
7548             print $OUT "Default die handler restored.\n";
7549         }
7550     } ## end if (@_)
7551     $dieLevel;
7552 } ## end sub dieLevel
7553
7554 =head2 C<signalLevel>
7555
7556 Number three in a series: set C<signalLevel> to zero to keep your own
7557 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7558 takes over and handles them with C<DB::diesignal()>.
7559
7560 =cut
7561
7562 sub signalLevel {
7563     if (@_) {
7564         $prevsegv = $SIG{SEGV} unless $signalLevel;
7565         $prevbus  = $SIG{BUS}  unless $signalLevel;
7566         $signalLevel = shift;
7567         if ($signalLevel) {
7568             $SIG{SEGV} = \&DB::diesignal;
7569             $SIG{BUS}  = \&DB::diesignal;
7570         }
7571         else {
7572             $SIG{SEGV} = $prevsegv;
7573             $SIG{BUS}  = $prevbus;
7574         }
7575     } ## end if (@_)
7576     $signalLevel;
7577 } ## end sub signalLevel
7578
7579 =head1 SUBROUTINE DECODING SUPPORT
7580
7581 These subroutines are used during the C<x> and C<X> commands to try to
7582 produce as much information as possible about a code reference. They use
7583 L<Devel::Peek> to try to find the glob in which this code reference lives
7584 (if it does) - this allows us to actually code references which correspond
7585 to named subroutines (including those aliased via glob assignment).
7586
7587 =head2 C<CvGV_name()>
7588
7589 Wrapper for X<CvGV_name_or_bust>; tries to get the name of a reference
7590 via that routine. If this fails, return the reference again (when the
7591 reference is stringified, it'll come out as "SOMETHING(0X...)").
7592
7593 =cut
7594
7595 sub CvGV_name {
7596     my $in   = shift;
7597     my $name = CvGV_name_or_bust($in);
7598     defined $name ? $name : $in;
7599 }
7600
7601 =head2 C<CvGV_name_or_bust> I<coderef>
7602
7603 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7604 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7605 find a glob for this ref.
7606
7607 Returns "I<package>::I<glob name>" if the code ref is found in a glob.
7608
7609 =cut
7610
7611 sub CvGV_name_or_bust {
7612     my $in = shift;
7613     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7614     return unless ref $in;
7615     $in = \&$in;            # Hard reference...
7616     eval { require Devel::Peek; 1 } or return;
7617     my $gv = Devel::Peek::CvGV($in) or return;
7618     *$gv{PACKAGE} . '::' . *$gv{NAME};
7619 } ## end sub CvGV_name_or_bust
7620
7621 =head2 C<find_sub>
7622
7623 A utility routine used in various places; finds the file where a subroutine
7624 was defined, and returns that filename and a line-number range.
7625
7626 Tries to use X<@sub> first; if it can't find it there, it tries building a
7627 reference to the subroutine and uses X<CvGV_name_or_bust> to locate it,
7628 loading it into X<@sub> as a side effect (XXX I think). If it can't find it
7629 this way, it brute-force searches X<%sub>, checking for identical references.
7630
7631 =cut
7632
7633 sub find_sub {
7634     my $subr = shift;
7635     $sub{$subr} or do {
7636         return unless defined &$subr;
7637         my $name = CvGV_name_or_bust($subr);
7638         my $data;
7639         $data = $sub{$name} if defined $name;
7640         return $data if defined $data;
7641
7642         # Old stupid way...
7643         $subr = \&$subr;    # Hard reference
7644         my $s;
7645         for ( keys %sub ) {
7646             $s = $_, last if $subr eq \&$_;
7647         }
7648         $sub{$s} if $s;
7649       } ## end do
7650 } ## end sub find_sub
7651
7652 =head2 C<methods>
7653
7654 A subroutine that uses the utility function X<methods_via> to find all the
7655 methods in the class corresponding to the current reference and in
7656 C<UNIVERSAL>.
7657
7658 =cut
7659
7660 sub methods {
7661
7662     # Figure out the class - either this is the class or it's a reference
7663     # to something blessed into that class.
7664     my $class = shift;
7665     $class = ref $class if ref $class;
7666
7667     local %seen;
7668
7669     # Show the methods that this class has.
7670     methods_via( $class, '', 1 );
7671
7672     # Show the methods that UNIVERSAL has.
7673     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7674 } ## end sub methods
7675
7676 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7677
7678 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7679 all the parent class methods. C<$class> is the name of the next class to
7680 try; C<$prefix> is the message prefix, which gets built up as we go up the
7681 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7682 higher in the C<@ISA> tree, 0 if we should stop.
7683
7684 =cut
7685
7686 sub methods_via {
7687
7688     # If we've processed this class already, just quit.
7689     my $class = shift;
7690     return if $seen{$class}++;
7691
7692     # This is a package that is contributing the methods we're about to print.
7693     my $prefix  = shift;
7694     my $prepend = $prefix ? "via $prefix: " : '';
7695
7696     my $name;
7697     for $name (
7698
7699         # Keep if this is a defined subroutine in this class.
7700         grep { defined &{ ${"${class}::"}{$_} } }
7701
7702         # Extract from all the symbols in this class.
7703         sort keys %{"${class}::"}
7704       )
7705     {
7706
7707         # If we printed this already, skip it.
7708         next if $seen{$name}++;
7709
7710         # Print the new method name.
7711         local $\ = '';
7712         local $, = '';
7713         print $DB::OUT "$prepend$name\n";
7714     } ## end for $name (grep { defined...
7715
7716     # If the $crawl_upward argument is false, just quit here.
7717     return unless shift;
7718
7719     # $crawl_upward true: keep going up the tree.
7720     # Find all the classes this one is a subclass of.
7721     for $name ( @{"${class}::ISA"} ) {
7722
7723         # Set up the new prefix.
7724         $prepend = $prefix ? $prefix . " -> $name" : $name;
7725
7726         # Crawl up the tree and keep trying to crawl up.
7727         methods_via( $name, $prepend, 1 );
7728     }
7729 } ## end sub methods_via
7730
7731 =head2 C<setman> - figure out which command to use to show documentation
7732
7733 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
7734
7735 =cut
7736
7737 sub setman {
7738     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
7739       ? "man"         # O Happy Day!
7740       : "perldoc";    # Alas, poor unfortunates
7741 } ## end sub setman
7742
7743 =head2 C<runman> - run the appropriate command to show documentation
7744
7745 Accepts a man page name; runs the appropriate command to display it (set up
7746 during debugger initialization). Uses C<DB::system> to avoid mucking up the
7747 program's STDIN and STDOUT.
7748
7749 =cut
7750
7751 sub runman {
7752     my $page = shift;
7753     unless ($page) {
7754         &system("$doccmd $doccmd");
7755         return;
7756     }
7757
7758     # this way user can override, like with $doccmd="man -Mwhatever"
7759     # or even just "man " to disable the path check.
7760     unless ( $doccmd eq 'man' ) {
7761         &system("$doccmd $page");
7762         return;
7763     }
7764
7765     $page = 'perl' if lc($page) eq 'help';
7766
7767     require Config;
7768     my $man1dir = $Config::Config{'man1dir'};
7769     my $man3dir = $Config::Config{'man3dir'};
7770     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
7771     my $manpath = '';
7772     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
7773     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
7774     chop $manpath if $manpath;
7775
7776     # harmless if missing, I figure
7777     my $oldpath = $ENV{MANPATH};
7778     $ENV{MANPATH} = $manpath if $manpath;
7779     my $nopathopt = $^O =~ /dunno what goes here/;
7780     if (
7781         CORE::system(
7782             $doccmd,
7783
7784             # I just *know* there are men without -M
7785             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
7786             split ' ', $page
7787         )
7788       )
7789     {
7790         unless ( $page =~ /^perl\w/ ) {
7791 # do it this way because its easier to slurp in to keep up to date - clunky though.
7792 my @pods = qw(
7793     5004delta
7794     5005delta
7795     561delta
7796     56delta
7797     570delta
7798     571delta
7799     572delta
7800     573delta
7801     58delta
7802     581delta
7803     582delta
7804     583delta
7805     584delta
7806     590delta
7807     591delta
7808     592delta
7809     aix
7810     amiga
7811     apio
7812     api
7813     apollo
7814     artistic
7815     beos
7816     book
7817     boot
7818     bot
7819     bs2000
7820     call
7821     ce
7822     cheat
7823     clib
7824     cn
7825     compile
7826     cygwin
7827     data
7828     dbmfilter
7829     debguts
7830     debtut
7831     debug
7832     delta
7833     dgux
7834     diag
7835     doc
7836     dos
7837     dsc
7838     ebcdic
7839     embed
7840     epoc
7841     faq1
7842     faq2
7843     faq3
7844     faq4
7845     faq5
7846     faq6
7847     faq7
7848     faq8
7849     faq9
7850     faq
7851     filter
7852     fork
7853     form
7854     freebsd
7855     func
7856     gpl
7857     guts
7858     hack
7859     hist
7860     hpux
7861     hurd
7862     intern
7863     intro
7864     iol
7865     ipc
7866     irix
7867     jp
7868     ko
7869     lexwarn
7870     locale
7871     lol
7872     machten
7873     macos
7874     macosx
7875     mint
7876     modinstall
7877     modlib
7878     mod
7879     modstyle
7880     mpeix
7881     netware
7882     newmod
7883     number
7884     obj
7885     opentut
7886     op
7887     os2
7888     os390
7889     os400
7890     othrtut
7891     packtut
7892     plan9
7893     pod
7894     podspec
7895     port
7896     qnx
7897     ref
7898     reftut
7899     re
7900     requick
7901     reref
7902     retut
7903     run
7904     sec
7905     solaris
7906     style
7907     sub
7908     syn
7909     thrtut
7910     tie
7911     toc
7912     todo
7913     tooc
7914     toot
7915     trap
7916     tru64
7917     tw
7918     unicode
7919     uniintro
7920     util
7921     uts
7922     var
7923     vmesa
7924     vms
7925     vos
7926     win32
7927     xs
7928     xstut
7929 );
7930             if (grep { $page eq $_ } @pods) {
7931                 $page =~ s/^/perl/;
7932                 CORE::system( $doccmd,
7933                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
7934                     $page );
7935             } ## end if (grep { $page eq $_...
7936         } ## end unless ($page =~ /^perl\w/)
7937     } ## end if (CORE::system($doccmd...
7938     if ( defined $oldpath ) {
7939         $ENV{MANPATH} = $manpath;
7940     }
7941     else {
7942         delete $ENV{MANPATH};
7943     }
7944 } ## end sub runman
7945
7946 #use Carp;                          # This did break, left for debugging
7947
7948 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
7949
7950 Because of the way the debugger interface to the Perl core is designed, any
7951 debugger package globals that C<DB::sub()> requires have to be defined before
7952 any subroutines can be called. These are defined in the second C<BEGIN> block.
7953
7954 This block sets things up so that (basically) the world is sane
7955 before the debugger starts executing. We set up various variables that the
7956 debugger has to have set up before the Perl core starts running:
7957
7958 =over 4
7959
7960 =item * The debugger's own filehandles (copies of STD and STDOUT for now).
7961
7962 =item * Characters for shell escapes, the recall command, and the history command.
7963
7964 =item * The maximum recursion depth.
7965
7966 =item * The size of a C<w> command's window.
7967
7968 =item * The before-this-line context to be printed in a C<v> (view a window around this line) command.
7969
7970 =item * The fact that we're not in a sub at all right now.
7971
7972 =item * The default SIGINT handler for the debugger.
7973
7974 =item * The appropriate value of the flag in C<$^D> that says the debugger is running
7975
7976 =item * The current debugger recursion level
7977
7978 =item * The list of postponed (XXX define) items and the C<$single> stack
7979
7980 =item * That we want no return values and no subroutine entry/exit trace.
7981
7982 =back
7983
7984 =cut
7985
7986 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
7987
7988 BEGIN {    # This does not compile, alas. (XXX eh?)
7989     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
7990     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
7991
7992     # Define characters used by command parsing.
7993     $sh       = '!';      # Shell escape (does not work)
7994     $rc       = ',';      # Recall command (does not work)
7995     @hist     = ('?');    # Show history (does not work)
7996     @truehist = ();       # Can be saved for replay (per session)
7997
7998     # This defines the point at which you get the 'deep recursion'
7999     # warning. It MUST be defined or the debugger will not load.
8000     $deep = 100;
8001
8002     # Number of lines around the current one that are shown in the
8003     # 'w' command.
8004     $window = 10;
8005
8006     # How much before-the-current-line context the 'v' command should
8007     # use in calculating the start of the window it will display.
8008     $preview = 3;
8009
8010     # We're not in any sub yet, but we need this to be a defined value.
8011     $sub = '';
8012
8013     # Set up the debugger's interrupt handler. It simply sets a flag
8014     # ($signal) that DB::DB() will check before each command is executed.
8015     $SIG{INT} = \&DB::catch;
8016
8017     # The following lines supposedly, if uncommented, allow the debugger to
8018     # debug itself. Perhaps we can try that someday.
8019     # This may be enabled to debug debugger:
8020     #$warnLevel = 1 unless defined $warnLevel;
8021     #$dieLevel = 1 unless defined $dieLevel;
8022     #$signalLevel = 1 unless defined $signalLevel;
8023
8024     # This is the flag that says "a debugger is running, please call
8025     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8026     # execute anything in the user's context, because we always want to
8027     # get control back.
8028     $db_stop = 0;          # Compiler warning ...
8029     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8030
8031     # This variable records how many levels we're nested in debugging. Used
8032     # Used in the debugger prompt, and in determining whether it's all over or
8033     # not.
8034     $level = 0;            # Level of recursive debugging
8035
8036     # "Triggers bug (?) in perl if we postpone this until runtime."
8037     # XXX No details on this yet, or whether we should fix the bug instead
8038     # of work around it. Stay tuned.
8039     @postponed = @stack = (0);
8040
8041     # Used to track the current stack depth using the auto-stacked-variable
8042     # trick.
8043     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8044
8045     # Don't print return values on exiting a subroutine.
8046     $doret = -2;
8047
8048     # No extry/exit tracing.
8049     $frame = 0;
8050
8051 } ## end BEGIN
8052
8053 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8054
8055 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8056
8057 =head2 db_complete
8058
8059 C<readline> support - adds command completion to basic C<readline>.
8060
8061 Returns a list of possible completions to C<readline> when invoked. C<readline>
8062 will print the longest common substring following the text already entered.
8063
8064 If there is only a single possible completion, C<readline> will use it in full.
8065
8066 This code uses C<map> and C<grep> heavily to create lists of possible
8067 completion. Think LISP in this section.
8068
8069 =cut
8070
8071 sub db_complete {
8072
8073     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8074     # $text is the text to be completed.
8075     # $line is the incoming line typed by the user.
8076     # $start is the start of the text to be completed in the incoming line.
8077     my ( $text, $line, $start ) = @_;
8078
8079     # Save the initial text.
8080     # The search pattern is current package, ::, extract the next qualifier
8081     # Prefix and pack are set to undef.
8082     my ( $itext, $search, $prefix, $pack ) =
8083       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8084
8085 =head3 C<b postpone|compile>
8086
8087 =over 4
8088
8089 =item * Find all the subroutines that might match in this package
8090
8091 =item * Add "postpone", "load", and "compile" as possibles (we may be completing the keyword itself
8092
8093 =item * Include all the rest of the subs that are known
8094
8095 =item * C<grep> out the ones that match the text we have so far
8096
8097 =item * Return this as the list of possible completions
8098
8099 =back
8100
8101 =cut
8102
8103     return sort grep /^\Q$text/, ( keys %sub ),
8104       qw(postpone load compile),    # subroutines
8105       ( map { /$search/ ? ($1) : () } keys %sub )
8106       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8107
8108 =head3 C<b load>
8109
8110 Get all the possible files from @INC as it currently stands and
8111 select the ones that match the text so far.
8112
8113 =cut
8114
8115     return sort grep /^\Q$text/, values %INC    # files
8116       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8117
8118 =head3  C<V> (list variable) and C<m> (list modules)
8119
8120 There are two entry points for these commands:
8121
8122 =head4 Unqualified package names
8123
8124 Get the top-level packages and grab everything that matches the text
8125 so far. For each match, recursively complete the partial packages to
8126 get all possible matching packages. Return this sorted list.
8127
8128 =cut
8129
8130     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8131       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8132       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8133
8134 =head4 Qualified package names
8135
8136 Take a partially-qualified package and find all subpackages for it
8137 by getting all the subpackages for the package so far, matching all
8138 the subpackages against the text, and discarding all of them which
8139 start with 'main::'. Return this list.
8140
8141 =cut
8142
8143     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8144       grep !/^main::/, grep /^\Q$text/,
8145       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8146       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8147       and $text =~ /^(.*[^:])::?(\w*)$/
8148       and $prefix = $1;
8149
8150 =head3 C<f> - switch files
8151
8152 Here, we want to get a fully-qualified filename for the C<f> command.
8153 Possibilities are:
8154
8155 =over 4
8156
8157 =item 1. The original source file itself
8158
8159 =item 2. A file from C<@INC>
8160
8161 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8162
8163 =back
8164
8165 =cut
8166
8167     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8168            # We might possibly want to switch to an eval (which has a "filename"
8169            # like '(eval 9)'), so we may need to clean up the completion text
8170            # before proceeding.
8171         $prefix = length($1) - length($text);
8172         $text   = $1;
8173
8174 =pod
8175
8176 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8177 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8178 out of C<%main::>, add the initial source file, and extract the ones that
8179 match the completion text so far.
8180
8181 =cut
8182
8183         return sort
8184           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8185           $0;
8186     } ## end if ($line =~ /^\|*f\s+(.*)/)
8187
8188 =head3 Subroutine name completion
8189
8190 We look through all of the defined subs (the keys of C<%sub>) and
8191 return both all the possible matches to the subroutine name plus
8192 all the matches qualified to the current package.
8193
8194 =cut
8195
8196     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8197         $text = substr $text, 1;
8198         $prefix = "&";
8199         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8200           (
8201             map { /$search/ ? ($1) : () }
8202               keys %sub
8203           );
8204     } ## end if ((substr $text, 0, ...
8205
8206 =head3  Scalar, array, and hash completion: partially qualified package
8207
8208 Much like the above, except we have to do a little more cleanup:
8209
8210 =cut
8211
8212     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8213
8214 =pod
8215
8216 =over 4
8217
8218 =item * Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8219
8220 =cut
8221
8222         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8223
8224 =pod
8225
8226 =item * Figure out the prefix vs. what needs completing.
8227
8228 =cut
8229
8230         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8231         $text   = $2;
8232
8233 =pod
8234
8235 =item * Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8236
8237 =cut
8238
8239         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8240           keys %$pack;
8241
8242 =pod
8243
8244 =item * If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8245
8246 =cut
8247
8248         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8249             return db_complete( $out[0], $line, $start );
8250         }
8251
8252         # Return the list of possibles.
8253         return sort @out;
8254
8255     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8256
8257 =pod
8258
8259 =back
8260
8261 =head3 Symbol completion: current package or package C<main>.
8262
8263 =cut
8264
8265     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8266
8267 =pod
8268
8269 =over 4
8270
8271 =item * If it's C<main>, delete main to just get C<::> leading.
8272
8273 =cut
8274
8275         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8276
8277 =pod
8278
8279 =item * We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8280
8281 =cut
8282
8283         $prefix = substr $text, 0, 1;
8284         $text   = substr $text, 1;
8285
8286 =pod
8287
8288 =item * If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8289
8290 =cut
8291
8292         my @out = map "$prefix$_", grep /^\Q$text/,
8293           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8294           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8295
8296 =item * If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8297
8298 =back
8299
8300 =cut
8301
8302         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8303             return db_complete( $out[0], $line, $start );
8304         }
8305
8306         # Return the list of possibles.
8307         return sort @out;
8308     } ## end if ($text =~ /^[\$@%]/)
8309
8310 =head3 Options
8311
8312 We use C<option_val()> to look up the current value of the option. If there's
8313 only a single value, we complete the command in such a way that it is a
8314 complete command for setting the option in question. If there are multiple
8315 possible values, we generate a command consisting of the option plus a trailing
8316 question mark, which, if executed, will list the current value of the option.
8317
8318 =cut
8319
8320     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8321     {    # Options after space
8322            # We look for the text to be matched in the list of possible options,
8323            # and fetch the current value.
8324         my @out = grep /^\Q$text/, @options;
8325         my $val = option_val( $out[0], undef );
8326
8327         # Set up a 'query option's value' command.
8328         my $out = '? ';
8329         if ( not defined $val or $val =~ /[\n\r]/ ) {
8330
8331             # There's really nothing else we can do.
8332         }
8333
8334         # We have a value. Create a proper option-setting command.
8335         elsif ( $val =~ /\s/ ) {
8336
8337             # XXX This may be an extraneous variable.
8338             my $found;
8339
8340             # We'll want to quote the string (because of the embedded
8341             # whtespace), but we want to make sure we don't end up with
8342             # mismatched quote characters. We try several possibilities.
8343             foreach $l ( split //, qq/\"\'\#\|/ ) {
8344
8345                 # If we didn't find this quote character in the value,
8346                 # quote it using this quote character.
8347                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8348             }
8349         } ## end elsif ($val =~ /\s/)
8350
8351         # Don't need any quotes.
8352         else {
8353             $out = "=$val ";
8354         }
8355
8356         # If there were multiple possible values, return '? ', which
8357         # makes the command into a query command. If there was just one,
8358         # have readline append that.
8359         $rl_attribs->{completer_terminator_character} =
8360           ( @out == 1 ? $out : '? ' );
8361
8362         # Return list of possibilities.
8363         return sort @out;
8364     } ## end if ((substr $line, 0, ...
8365
8366 =head3 Filename completion
8367
8368 For entering filenames. We simply call C<readline>'s C<filename_list()>
8369 method with the completion text to get the possible completions.
8370
8371 =cut
8372
8373     return $term->filename_list($text);    # filenames
8374
8375 } ## end sub db_complete
8376
8377 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8378
8379 Functions that possibly ought to be somewhere else.
8380
8381 =head2 end_report
8382
8383 Say we're done.
8384
8385 =cut
8386
8387 sub end_report {
8388     local $\ = '';
8389     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8390 }
8391
8392 =head2 clean_ENV
8393
8394 If we have $ini_pids, save it in the environment; else remove it from the
8395 environment. Used by the C<R> (restart) command.
8396
8397 =cut
8398
8399 sub clean_ENV {
8400     if ( defined($ini_pids) ) {
8401         $ENV{PERLDB_PIDS} = $ini_pids;
8402     }
8403     else {
8404         delete( $ENV{PERLDB_PIDS} );
8405     }
8406 } ## end sub clean_ENV
8407
8408 # PERLDBf_... flag names from perl.h
8409 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8410
8411 BEGIN {
8412     %DollarCaretP_flags = (
8413         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8414         PERLDBf_LINE      => 0x02,     # Keep line #
8415         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8416         PERLDBf_INTER     => 0x08,     # Preserve more data
8417         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8418         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8419         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8420         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8421         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8422         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8423         PERLDBf_ASSERTION => 0x400,    # Debug assertion subs enter/exit
8424         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO, _ASSERTION
8425     );
8426
8427     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8428 }
8429
8430 sub parse_DollarCaretP_flags {
8431     my $flags = shift;
8432     $flags =~ s/^\s+//;
8433     $flags =~ s/\s+$//;
8434     my $acu = 0;
8435     foreach my $f ( split /\s*\|\s*/, $flags ) {
8436         my $value;
8437         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8438             $value = hex $1;
8439         }
8440         elsif ( $f =~ /^(\d+)$/ ) {
8441             $value = int $1;
8442         }
8443         elsif ( $f =~ /^DEFAULT$/i ) {
8444             $value = $DollarCaretP_flags{PERLDB_ALL};
8445         }
8446         else {
8447             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8448             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8449             unless ( defined $value ) {
8450                 print $OUT (
8451                     "Unrecognized \$^P flag '$f'!\n",
8452                     "Acceptable flags are: "
8453                       . join( ', ', sort keys %DollarCaretP_flags ),
8454                     ", and hexadecimal and decimal numbers.\n"
8455                 );
8456                 return undef;
8457             }
8458         }
8459         $acu |= $value;
8460     }
8461     $acu;
8462 }
8463
8464 sub expand_DollarCaretP_flags {
8465     my $DollarCaretP = shift;
8466     my @bits         = (
8467         map {
8468             my $n = ( 1 << $_ );
8469             ( $DollarCaretP & $n )
8470               ? ( $DollarCaretP_flags_r{$n}
8471                   || sprintf( '0x%x', $n ) )
8472               : ()
8473           } 0 .. 31
8474     );
8475     return @bits ? join( '|', @bits ) : 0;
8476 }
8477
8478 =item rerun
8479
8480 Rerun the current session to:
8481
8482     rerun        current position
8483
8484     rerun 4      command number 4
8485
8486     rerun -4     current command minus 4 (go back 4 steps)
8487
8488 Whether this always makes sense, in the current context is unknowable, and is
8489 in part left as a useful exersize for the reader.  This sub returns the
8490 appropriate arguments to rerun the current session.
8491
8492 =cut
8493
8494 sub rerun {
8495     my $i = shift;
8496     my @args;
8497     pop(@truehist);                      # strim
8498     unless (defined $truehist[$i]) {
8499         print "Unable to return to non-existent command: $i\n";
8500     } else {
8501         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8502         my @temp = @truehist;            # store
8503         push(@DB::typeahead, @truehist); # saved
8504         @truehist = @hist = ();          # flush
8505         @args = &restart();              # setup
8506         &get_list("PERLDB_HIST");        # clean
8507         &set_list("PERLDB_HIST", @temp); # reset
8508     }
8509     return @args;
8510 }
8511
8512 =item restart
8513
8514 Restarting the debugger is a complex operation that occurs in several phases.
8515 First, we try to reconstruct the command line that was used to invoke Perl
8516 and the debugger.
8517
8518 =cut
8519
8520 sub restart {
8521     # I may not be able to resurrect you, but here goes ...
8522     print $OUT
8523 "Warning: some settings and command-line options may be lost!\n";
8524     my ( @script, @flags, $cl );
8525
8526     # If warn was on before, turn it on again.
8527     push @flags, '-w' if $ini_warn;
8528     if ( $ini_assertion and @{^ASSERTING} ) {
8529         push @flags,
8530           ( map { /\:\^\(\?\:(.*)\)\$\)/ ? "-A$1" : "-A$_" }
8531               @{^ASSERTING} );
8532     }
8533
8534     # Rebuild the -I flags that were on the initial
8535     # command line.
8536     for (@ini_INC) {
8537         push @flags, '-I', $_;
8538     }
8539
8540     # Turn on taint if it was on before.
8541     push @flags, '-T' if ${^TAINT};
8542
8543     # Arrange for setting the old INC:
8544     # Save the current @init_INC in the environment.
8545     set_list( "PERLDB_INC", @ini_INC );
8546
8547     # If this was a perl one-liner, go to the "file"
8548     # corresponding to the one-liner read all the lines
8549     # out of it (except for the first one, which is going
8550     # to be added back on again when 'perl -d' runs: that's
8551     # the 'require perl5db.pl;' line), and add them back on
8552     # to the command line to be executed.
8553     if ( $0 eq '-e' ) {
8554         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8555             chomp( $cl = ${'::_<-e'}[$_] );
8556             push @script, '-e', $cl;
8557         }
8558     } ## end if ($0 eq '-e')
8559
8560     # Otherwise we just reuse the original name we had
8561     # before.
8562     else {
8563         @script = $0;
8564     }
8565
8566 =pod
8567
8568 After the command line  has been reconstructed, the next step is to save
8569 the debugger's status in environment variables. The C<DB::set_list> routine
8570 is used to save aggregate variables (both hashes and arrays); scalars are
8571 just popped into environment variables directly.
8572
8573 =cut
8574
8575     # If the terminal supported history, grab it and
8576     # save that in the environment.
8577     set_list( "PERLDB_HIST",
8578           $term->Features->{getHistory}
8579         ? $term->GetHistory
8580         : @hist );
8581
8582     # Find all the files that were visited during this
8583     # session (i.e., the debugger had magic hashes
8584     # corresponding to them) and stick them in the environment.
8585     my @had_breakpoints = keys %had_breakpoints;
8586     set_list( "PERLDB_VISITED", @had_breakpoints );
8587
8588     # Save the debugger options we chose.
8589     set_list( "PERLDB_OPT", %option );
8590     # set_list( "PERLDB_OPT", options2remember() );
8591
8592     # Save the break-on-loads.
8593     set_list( "PERLDB_ON_LOAD", %break_on_load );
8594
8595 =pod
8596
8597 The most complex part of this is the saving of all of the breakpoints. They
8598 can live in an awful lot of places, and we have to go through all of them,
8599 find the breakpoints, and then save them in the appropriate environment
8600 variable via C<DB::set_list>.
8601
8602 =cut
8603
8604     # Go through all the breakpoints and make sure they're
8605     # still valid.
8606     my @hard;
8607     for ( 0 .. $#had_breakpoints ) {
8608
8609         # We were in this file.
8610         my $file = $had_breakpoints[$_];
8611
8612         # Grab that file's magic line hash.
8613         *dbline = $main::{ '_<' . $file };
8614
8615         # Skip out if it doesn't exist, or if the breakpoint
8616         # is in a postponed file (we'll do postponed ones
8617         # later).
8618         next unless %dbline or $postponed_file{$file};
8619
8620         # In an eval. This is a little harder, so we'll
8621         # do more processing on that below.
8622         ( push @hard, $file ), next
8623           if $file =~ /^\(\w*eval/;
8624
8625         # XXX I have no idea what this is doing. Yet.
8626         my @add;
8627         @add = %{ $postponed_file{$file} }
8628           if $postponed_file{$file};
8629
8630         # Save the list of all the breakpoints for this file.
8631         set_list( "PERLDB_FILE_$_", %dbline, @add );
8632     } ## end for (0 .. $#had_breakpoints)
8633
8634     # The breakpoint was inside an eval. This is a little
8635     # more difficult. XXX and I don't understand it.
8636     for (@hard) {
8637         # Get over to the eval in question.
8638         *dbline = $main::{ '_<' . $_ };
8639         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8640         for $sub ( keys %sub ) {
8641             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8642             $subs{$sub} = [ $1, $2 ];
8643         }
8644         unless (%subs) {
8645             print $OUT
8646               "No subroutines in $_, ignoring breakpoints.\n";
8647             next;
8648         }
8649       LINES: for $line ( keys %dbline ) {
8650
8651             # One breakpoint per sub only:
8652             my ( $offset, $sub, $found );
8653           SUBS: for $sub ( keys %subs ) {
8654                 if (
8655                     $subs{$sub}->[1] >=
8656                     $line    # Not after the subroutine
8657                     and (
8658                         not defined $offset    # Not caught
8659                         or $offset < 0
8660                     )
8661                   )
8662                 {                              # or badly caught
8663                     $found  = $sub;
8664                     $offset = $line - $subs{$sub}->[0];
8665                     $offset = "+$offset", last SUBS
8666                       if $offset >= 0;
8667                 } ## end if ($subs{$sub}->[1] >=...
8668             } ## end for $sub (keys %subs)
8669             if ( defined $offset ) {
8670                 $postponed{$found} =
8671                   "break $offset if $dbline{$line}";
8672             }
8673             else {
8674                 print $OUT
8675 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
8676             }
8677         } ## end for $line (keys %dbline)
8678     } ## end for (@hard)
8679
8680     # Save the other things that don't need to be
8681     # processed.
8682     set_list( "PERLDB_POSTPONE",  %postponed );
8683     set_list( "PERLDB_PRETYPE",   @$pretype );
8684     set_list( "PERLDB_PRE",       @$pre );
8685     set_list( "PERLDB_POST",      @$post );
8686     set_list( "PERLDB_TYPEAHEAD", @typeahead );
8687
8688     # We are oficially restarting.
8689     $ENV{PERLDB_RESTART} = 1;
8690
8691     # We are junking all child debuggers.
8692     delete $ENV{PERLDB_PIDS};    # Restore ini state
8693
8694     # Set this back to the initial pid.
8695     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
8696
8697 =pod
8698
8699 After all the debugger status has been saved, we take the command we built up
8700 and then return it, so we can C<exec()> it. The debugger will spot the
8701 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
8702 from the environment.
8703
8704 =cut
8705
8706     # And run Perl again. Add the "-d" flag, all the
8707     # flags we built up, the script (whether a one-liner
8708     # or a file), add on the -emacs flag for a slave editor,
8709     # and then the old arguments.
8710
8711     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
8712
8713 };  # end restart
8714
8715 =head1 END PROCESSING - THE C<END> BLOCK
8716
8717 Come here at the very end of processing. We want to go into a
8718 loop where we allow the user to enter commands and interact with the
8719 debugger, but we don't want anything else to execute.
8720
8721 First we set the C<$finished> variable, so that some commands that
8722 shouldn't be run after the end of program quit working.
8723
8724 We then figure out whether we're truly done (as in the user entered a C<q>
8725 command, or we finished execution while running nonstop). If we aren't,
8726 we set C<$single> to 1 (causing the debugger to get control again).
8727
8728 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...">
8729 message and returns control to the debugger. Repeat.
8730
8731 When the user finally enters a C<q> command, C<$fall_off_end> is set to
8732 1 and the C<END> block simply exits with C<$single> set to 0 (don't
8733 break, run to completion.).
8734
8735 =cut
8736
8737 END {
8738     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
8739     $fall_off_end = 1 unless $inhibit_exit;
8740
8741     # Do not stop in at_exit() and destructors on exit:
8742     $DB::single = !$fall_off_end && !$runnonstop;
8743     DB::fake::at_exit() unless $fall_off_end or $runnonstop;
8744 } ## end END
8745
8746 =head1 PRE-5.8 COMMANDS
8747
8748 Some of the commands changed function quite a bit in the 5.8 command
8749 realignment, so much so that the old code had to be replaced completely.
8750 Because we wanted to retain the option of being able to go back to the
8751 former command set, we moved the old code off to this section.
8752
8753 There's an awful lot of duplicated code here. We've duplicated the
8754 comments to keep things clear.
8755
8756 =head2 Null command
8757
8758 Does nothing. Used to 'turn off' commands.
8759
8760 =cut
8761
8762 sub cmd_pre580_null {
8763
8764     # do nothing...
8765 }
8766
8767 =head2 Old C<a> command.
8768
8769 This version added actions if you supplied them, and deleted them
8770 if you didn't.
8771
8772 =cut
8773
8774 sub cmd_pre580_a {
8775     my $xcmd = shift;
8776     my $cmd  = shift;
8777
8778     # Argument supplied. Add the action.
8779     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
8780
8781         # If the line isn't there, use the current line.
8782         $i = $1 || $line;
8783         $j = $2;
8784
8785         # If there is an action ...
8786         if ( length $j ) {
8787
8788             # ... but the line isn't breakable, skip it.
8789             if ( $dbline[$i] == 0 ) {
8790                 print $OUT "Line $i may not have an action.\n";
8791             }
8792             else {
8793
8794                 # ... and the line is breakable:
8795                 # Mark that there's an action in this file.
8796                 $had_breakpoints{$filename} |= 2;
8797
8798                 # Delete any current action.
8799                 $dbline{$i} =~ s/\0[^\0]*//;
8800
8801                 # Add the new action, continuing the line as needed.
8802                 $dbline{$i} .= "\0" . action($j);
8803             }
8804         } ## end if (length $j)
8805
8806         # No action supplied.
8807         else {
8808
8809             # Delete the action.
8810             $dbline{$i} =~ s/\0[^\0]*//;
8811
8812             # Mark as having no break or action if nothing's left.
8813             delete $dbline{$i} if $dbline{$i} eq '';
8814         }
8815     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
8816 } ## end sub cmd_pre580_a
8817
8818 =head2 Old C<b> command
8819
8820 Add breakpoints.
8821
8822 =cut
8823
8824 sub cmd_pre580_b {
8825     my $xcmd   = shift;
8826     my $cmd    = shift;
8827     my $dbline = shift;
8828
8829     # Break on load.
8830     if ( $cmd =~ /^load\b\s*(.*)/ ) {
8831         my $file = $1;
8832         $file =~ s/\s+$//;
8833         &cmd_b_load($file);
8834     }
8835
8836     # b compile|postpone <some sub> [<condition>]
8837     # The interpreter actually traps this one for us; we just put the
8838     # necessary condition in the %postponed hash.
8839     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
8840
8841         # Capture the condition if there is one. Make it true if none.
8842         my $cond = length $3 ? $3 : '1';
8843
8844         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
8845         # if it was 'compile'.
8846         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
8847
8848         # De-Perl4-ify the name - ' separators to ::.
8849         $subname =~ s/\'/::/g;
8850
8851         # Qualify it into the current package unless it's already qualified.
8852         $subname = "${'package'}::" . $subname
8853           unless $subname =~ /::/;
8854
8855         # Add main if it starts with ::.
8856         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
8857
8858         # Save the break type for this sub.
8859         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
8860     } ## end elsif ($cmd =~ ...
8861
8862     # b <sub name> [<condition>]
8863     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
8864         my $subname = $1;
8865         my $cond = length $2 ? $2 : '1';
8866         &cmd_b_sub( $subname, $cond );
8867     }
8868
8869     # b <line> [<condition>].
8870     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
8871         my $i = $1 || $dbline;
8872         my $cond = length $2 ? $2 : '1';
8873         &cmd_b_line( $i, $cond );
8874     }
8875 } ## end sub cmd_pre580_b
8876
8877 =head2 Old C<D> command.
8878
8879 Delete all breakpoints unconditionally.
8880
8881 =cut
8882
8883 sub cmd_pre580_D {
8884     my $xcmd = shift;
8885     my $cmd  = shift;
8886     if ( $cmd =~ /^\s*$/ ) {
8887         print $OUT "Deleting all breakpoints...\n";
8888
8889         # %had_breakpoints lists every file that had at least one
8890         # breakpoint in it.
8891         my $file;
8892         for $file ( keys %had_breakpoints ) {
8893
8894             # Switch to the desired file temporarily.
8895             local *dbline = $main::{ '_<' . $file };
8896
8897             my $max = $#dbline;
8898             my $was;
8899
8900             # For all lines in this file ...
8901             for ( $i = 1 ; $i <= $max ; $i++ ) {
8902
8903                 # If there's a breakpoint or action on this line ...
8904                 if ( defined $dbline{$i} ) {
8905
8906                     # ... remove the breakpoint.
8907                     $dbline{$i} =~ s/^[^\0]+//;
8908                     if ( $dbline{$i} =~ s/^\0?$// ) {
8909
8910                         # Remove the entry altogether if no action is there.
8911                         delete $dbline{$i};
8912                     }
8913                 } ## end if (defined $dbline{$i...
8914             } ## end for ($i = 1 ; $i <= $max...
8915
8916             # If, after we turn off the "there were breakpoints in this file"
8917             # bit, the entry in %had_breakpoints for this file is zero,
8918             # we should remove this file from the hash.
8919             if ( not $had_breakpoints{$file} &= ~1 ) {
8920                 delete $had_breakpoints{$file};
8921             }
8922         } ## end for $file (keys %had_breakpoints)
8923
8924         # Kill off all the other breakpoints that are waiting for files that
8925         # haven't been loaded yet.
8926         undef %postponed;
8927         undef %postponed_file;
8928         undef %break_on_load;
8929     } ## end if ($cmd =~ /^\s*$/)
8930 } ## end sub cmd_pre580_D
8931
8932 =head2 Old C<h> command
8933
8934 Print help. Defaults to printing the long-form help; the 5.8 version
8935 prints the summary by default.
8936
8937 =cut
8938
8939 sub cmd_pre580_h {
8940     my $xcmd = shift;
8941     my $cmd  = shift;
8942
8943     # Print the *right* help, long format.
8944     if ( $cmd =~ /^\s*$/ ) {
8945         print_help($pre580_help);
8946     }
8947
8948     # 'h h' - explicitly-requested summary.
8949     elsif ( $cmd =~ /^h\s*/ ) {
8950         print_help($pre580_summary);
8951     }
8952
8953     # Find and print a command's help.
8954     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
8955         my $asked  = $1;                   # for proper errmsg
8956         my $qasked = quotemeta($asked);    # for searching
8957                                            # XXX: finds CR but not <CR>
8958         if (
8959             $pre580_help =~ /^
8960                               <?           # Optional '<'
8961                               (?:[IB]<)    # Optional markup
8962                               $qasked      # The command name
8963                             /mx
8964           )
8965         {
8966
8967             while (
8968                 $pre580_help =~ /^
8969                                   (             # The command help:
8970                                    <?           # Optional '<'
8971                                    (?:[IB]<)    # Optional markup
8972                                    $qasked      # The command name
8973                                    ([\s\S]*?)   # Lines starting with tabs
8974                                    \n           # Final newline
8975                                   )
8976                                   (?!\s)/mgx
8977               )    # Line not starting with space
8978                    # (Next command's help)
8979             {
8980                 print_help($1);
8981             }
8982         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
8983
8984         # Help not found.
8985         else {
8986             print_help("B<$asked> is not a debugger command.\n");
8987         }
8988     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
8989 } ## end sub cmd_pre580_h
8990
8991 =head2 Old C<W> command
8992
8993 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
8994
8995 =cut
8996
8997 sub cmd_pre580_W {
8998     my $xcmd = shift;
8999     my $cmd  = shift;
9000
9001     # Delete all watch expressions.
9002     if ( $cmd =~ /^$/ ) {
9003
9004         # No watching is going on.
9005         $trace &= ~2;
9006
9007         # Kill all the watch expressions and values.
9008         @to_watch = @old_watch = ();
9009     }
9010
9011     # Add a watch expression.
9012     elsif ( $cmd =~ /^(.*)/s ) {
9013
9014         # add it to the list to be watched.
9015         push @to_watch, $1;
9016
9017         # Get the current value of the expression.
9018         # Doesn't handle expressions returning list values!
9019         $evalarg = $1;
9020         my ($val) = &eval;
9021         $val = ( defined $val ) ? "'$val'" : 'undef';
9022
9023         # Save it.
9024         push @old_watch, $val;
9025
9026         # We're watching stuff.
9027         $trace |= 2;
9028
9029     } ## end elsif ($cmd =~ /^(.*)/s)
9030 } ## end sub cmd_pre580_W
9031
9032 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9033
9034 The debugger used to have a bunch of nearly-identical code to handle
9035 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9036 C<cmd_prepost> unify all this into one set of code to handle the
9037 appropriate actions.
9038
9039 =head2 C<cmd_pre590_prepost>
9040
9041 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9042 do something destructive. In pre 5.8 debuggers, the default action was to
9043 delete all the actions.
9044
9045 =cut
9046
9047 sub cmd_pre590_prepost {
9048     my $cmd    = shift;
9049     my $line   = shift || '*';
9050     my $dbline = shift;
9051
9052     return &cmd_prepost( $cmd, $line, $dbline );
9053 } ## end sub cmd_pre590_prepost
9054
9055 =head2 C<cmd_prepost>
9056
9057 Actually does all the handling foe C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9058 Since the lists of actions are all held in arrays that are pointed to by
9059 references anyway, all we have to do is pick the right array reference and
9060 then use generic code to all, delete, or list actions.
9061
9062 =cut
9063
9064 sub cmd_prepost {
9065     my $cmd = shift;
9066
9067     # No action supplied defaults to 'list'.
9068     my $line = shift || '?';
9069
9070     # Figure out what to put in the prompt.
9071     my $which = '';
9072
9073     # Make sure we have some array or another to address later.
9074     # This means that if ssome reason the tests fail, we won't be
9075     # trying to stash actions or delete them from the wrong place.
9076     my $aref = [];
9077
9078     # < - Perl code to run before prompt.
9079     if ( $cmd =~ /^\</o ) {
9080         $which = 'pre-perl';
9081         $aref  = $pre;
9082     }
9083
9084     # > - Perl code to run after prompt.
9085     elsif ( $cmd =~ /^\>/o ) {
9086         $which = 'post-perl';
9087         $aref  = $post;
9088     }
9089
9090     # { - first check for properly-balanced braces.
9091     elsif ( $cmd =~ /^\{/o ) {
9092         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9093             print $OUT
9094 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9095         }
9096
9097         # Properly balanced. Pre-prompt debugger actions.
9098         else {
9099             $which = 'pre-debugger';
9100             $aref  = $pretype;
9101         }
9102     } ## end elsif ( $cmd =~ /^\{/o )
9103
9104     # Did we find something that makes sense?
9105     unless ($which) {
9106         print $OUT "Confused by command: $cmd\n";
9107     }
9108
9109     # Yes.
9110     else {
9111
9112         # List actions.
9113         if ( $line =~ /^\s*\?\s*$/o ) {
9114             unless (@$aref) {
9115
9116                 # Nothing there. Complain.
9117                 print $OUT "No $which actions.\n";
9118             }
9119             else {
9120
9121                 # List the actions in the selected list.
9122                 print $OUT "$which commands:\n";
9123                 foreach my $action (@$aref) {
9124                     print $OUT "\t$cmd -- $action\n";
9125                 }
9126             } ## end else
9127         } ## end if ( $line =~ /^\s*\?\s*$/o)
9128
9129         # Might be a delete.
9130         else {
9131             if ( length($cmd) == 1 ) {
9132                 if ( $line =~ /^\s*\*\s*$/o ) {
9133
9134                     # It's a delete. Get rid of the old actions in the
9135                     # selected list..
9136                     @$aref = ();
9137                     print $OUT "All $cmd actions cleared.\n";
9138                 }
9139                 else {
9140
9141                     # Replace all the actions. (This is a <, >, or {).
9142                     @$aref = action($line);
9143                 }
9144             } ## end if ( length($cmd) == 1)
9145             elsif ( length($cmd) == 2 ) {
9146
9147                 # Add the action to the line. (This is a <<, >>, or {{).
9148                 push @$aref, action($line);
9149             }
9150             else {
9151
9152                 # <<<, >>>>, {{{{{{ ... something not a command.
9153                 print $OUT
9154                   "Confused by strange length of $which command($cmd)...\n";
9155             }
9156         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9157     } ## end else
9158 } ## end sub cmd_prepost
9159
9160 =head1 C<DB::fake>
9161
9162 Contains the C<at_exit> routine that the debugger uses to issue the
9163 C<Debugged program terminated ...> message after the program completes. See
9164 the C<END> block documentation for more details.
9165
9166 =cut
9167
9168 package DB::fake;
9169
9170 sub at_exit {
9171     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9172 }
9173
9174 package DB;    # Do not trace this 1; below!
9175
9176 1;
9177
9178