lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 If false, a dummy  ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =back
 241
 242 =head3 SAMPLE RCFILE
 243
 244  &parse_options("NonStop=1 LineInfo=db.out");
 245   sub afterinit { $trace = 1; }
 246
 247 The script will run without human intervention, putting trace
 248 information into C<db.out>.  (If you interrupt it, you had better
 249 reset C<LineInfo> to something I<interactive>!)
 250
 251 =head1 INTERNALS DESCRIPTION
 252
 253 =head2 DEBUGGER INTERFACE VARIABLES
 254
 255 Perl supplies the values for C<%sub>.  It effectively inserts
 256 a C<&DB::DB();> in front of each place that can have a
 257 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 258 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 259 {require 'perl5db.pl'}> before the first line.
 260
 261 After each C<require>d file is compiled, but before it is executed, a
 262 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 263 is the expanded name of the C<require>d file (as found via C<%INC>).
 264
 265 =head3 IMPORTANT INTERNAL VARIABLES
 266
 267 =head4 C<$CreateTTY>
 268
 269 Used to control when the debugger will attempt to acquire another TTY to be
 270 used for input.
 271
 272 =over
 273
 274 =item * 1 -  on C<fork()>
 275
 276 =item * 2 - debugger is started inside debugger
 277
 278 =item * 4 -  on startup
 279
 280 =back
 281
 282 =head4 C<$doret>
 283
 284 The value -2 indicates that no return value should be printed.
 285 Any other positive value causes C<DB::sub> to print return values.
 286
 287 =head4 C<$evalarg>
 288
 289 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 290 contents of C<@_> when C<DB::eval> is called.
 291
 292 =head4 C<$frame>
 293
 294 Determines what messages (if any) will get printed when a subroutine (or eval)
 295 is entered or exited.
 296
 297 =over 4
 298
 299 =item * 0 -  No enter/exit messages
 300
 301 =item * 1 - Print I<entering> messages on subroutine entry
 302
 303 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 304
 305 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 306
 307 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 308
 309 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 310
 311 =back
 312
 313 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 314 The debugger internally juggles the value of C<$frame> during execution to
 315 protect external modules that the debugger uses from getting traced.
 316
 317 =head4 C<$level>
 318
 319 Tracks current debugger nesting level. Used to figure out how many
 320 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 321 outputs a prompt. Also used to help determine if the program has finished
 322 during command parsing.
 323
 324 =head4 C<$onetimeDump>
 325
 326 Controls what (if anything) C<DB::eval()> will print after evaluating an
 327 expression.
 328
 329 =over 4
 330
 331 =item * C<undef> - don't print anything
 332
 333 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 334
 335 =item * C<methods> - print the methods callable on the first item returned
 336
 337 =back
 338
 339 =head4 C<$onetimeDumpDepth>
 340
 341 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 342 dumping a structure. Numeric. If C<undef>, print all levels.
 343
 344 =head4 C<$signal>
 345
 346 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 347 which is called before every statement, checks this and puts the user into
 348 command mode if it finds C<$signal> set to a true value.
 349
 350 =head4 C<$single>
 351
 352 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 353 each subroutine; popped again at the end of each subroutine.
 354
 355 =over 4
 356
 357 =item * 0 - run continuously.
 358
 359 =item * 1 - single-step, go into subs. The C<s> command.
 360
 361 =item * 2 - single-step, don't go into subs. The C<n> command.
 362
 363 =item * 4 - print current sub depth (turned on to force this when C<too much
 364 recursion> occurs.
 365
 366 =back
 367
 368 =head4 C<$trace>
 369
 370 Controls the output of trace information.
 371
 372 =over 4
 373
 374 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 375
 376 =item * 2 - watch expressions are active
 377
 378 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 379
 380 =back
 381
 382 =head4 C<$slave_editor>
 383
 384 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 385
 386 =head4 C<@cmdfhs>
 387
 388 Stack of filehandles that C<DB::readline()> will read commands from.
 389 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 390
 391 =head4 C<@dbline>
 392
 393 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 394 supplied by the Perl interpreter to the debugger. Contains the source.
 395
 396 =head4 C<@old_watch>
 397
 398 Previous values of watch expressions. First set when the expression is
 399 entered; reset whenever the watch expression changes.
 400
 401 =head4 C<@saved>
 402
 403 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 404 so that the debugger can substitute safe values while it's running, and
 405 restore them when it returns control.
 406
 407 =head4 C<@stack>
 408
 409 Saves the current value of C<$single> on entry to a subroutine.
 410 Manipulated by the C<c> command to turn off tracing in all subs above the
 411 current one.
 412
 413 =head4 C<@to_watch>
 414
 415 The 'watch' expressions: to be evaluated before each line is executed.
 416
 417 =head4 C<@typeahead>
 418
 419 The typeahead buffer, used by C<DB::readline>.
 420
 421 =head4 C<%alias>
 422
 423 Command aliases. Stored as character strings to be substituted for a command
 424 entered.
 425
 426 =head4 C<%break_on_load>
 427
 428 Keys are file names, values are 1 (break when this file is loaded) or undef
 429 (don't break when it is loaded).
 430
 431 =head4 C<%dbline>
 432
 433 Keys are line numbers, values are C<condition\0action>. If used in numeric
 434 context, values are 0 if not breakable, 1 if breakable, no matter what is
 435 in the actual hash entry.
 436
 437 =head4 C<%had_breakpoints>
 438
 439 Keys are file names; values are bitfields:
 440
 441 =over 4
 442
 443 =item * 1 - file has a breakpoint in it.
 444
 445 =item * 2 - file has an action in it.
 446
 447 =back
 448
 449 A zero or undefined value means this file has neither.
 450
 451 =head4 C<%option>
 452
 453 Stores the debugger options. These are character string values.
 454
 455 =head4 C<%postponed>
 456
 457 Saves breakpoints for code that hasn't been compiled yet.
 458 Keys are subroutine names, values are:
 459
 460 =over 4
 461
 462 =item * C<compile> - break when this sub is compiled
 463
 464 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 465
 466 =back
 467
 468 =head4 C<%postponed_file>
 469
 470 This hash keeps track of breakpoints that need to be set for files that have
 471 not yet been compiled. Keys are filenames; values are references to hashes.
 472 Each of these hashes is keyed by line number, and its values are breakpoint
 473 definitions (C<condition\0action>).
 474
 475 =head1 DEBUGGER INITIALIZATION
 476
 477 The debugger's initialization actually jumps all over the place inside this
 478 package. This is because there are several BEGIN blocks (which of course
 479 execute immediately) spread through the code. Why is that?
 480
 481 The debugger needs to be able to change some things and set some things up
 482 before the debugger code is compiled; most notably, the C<$deep> variable that
 483 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 484 debugger has to turn off warnings while the debugger code is compiled, but then
 485 restore them to their original setting before the program being debugged begins
 486 executing.
 487
 488 The first C<BEGIN> block simply turns off warnings by saving the current
 489 setting of C<$^W> and then setting it to zero. The second one initializes
 490 the debugger variables that are needed before the debugger begins executing.
 491 The third one puts C<$^X> back to its former value.
 492
 493 We'll detail the second C<BEGIN> block later; just remember that if you need
 494 to initialize something before the debugger starts really executing, that's
 495 where it has to go.
 496
 497 =cut
 498
 499 package DB;
 500
 501 use IO::Handle;
 502
 503 # Debugger for Perl 5.00x; perl5db.pl patch level:
 504 $VERSION = 1.28;
 505
 506 $header = "perl5db.pl version $VERSION";
 507
 508 =head1 DEBUGGER ROUTINES
 509
 510 =head2 C<DB::eval()>
 511
 512 This function replaces straight C<eval()> inside the debugger; it simplifies
 513 the process of evaluating code in the user's context.
 514
 515 The code to be evaluated is passed via the package global variable
 516 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 517
 518 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 519 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 520 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 521 user's current package, grabbed when C<DB::DB> got control.  This causes the
 522 proper context to be used when the eval is actually done.  Afterward, we
 523 restore C<$trace>, C<$single>, and C<$^D>.
 524
 525 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 526 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 527 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 528 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 529 considered sane by the debugger. If there was an C<eval()> error, we print
 530 it on the debugger's output. If C<$onetimedump> is defined, we call
 531 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 532 'methods'. Setting it to something else causes the debugger to do the eval
 533 but not print the result - handy if you want to do something else with it
 534 (the "watch expressions" code does this to get the value of the watch
 535 expression but not show it unless it matters).
 536
 537 In any case, we then return the list of output from C<eval> to the caller,
 538 and unwinding restores the former version of C<$@> in C<@saved> as well
 539 (the localization of C<$saved[0]> goes away at the end of this scope).
 540
 541 =head3 Parameters and variables influencing execution of DB::eval()
 542
 543 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 544 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 545 The variables listed below influence C<DB::eval()>'s execution directly.
 546
 547 =over 4
 548
 549 =item C<$evalarg> - the thing to actually be eval'ed
 550
 551 =item C<$trace> - Current state of execution tracing
 552
 553 =item C<$single> - Current state of single-stepping
 554
 555 =item C<$onetimeDump> - what is to be displayed after the evaluation
 556
 557 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 558
 559 =back
 560
 561 The following variables are altered by C<DB::eval()> during its execution. They
 562 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 563
 564 =over 4
 565
 566 =item C<@res> - used to capture output from actual C<eval>.
 567
 568 =item C<$otrace> - saved value of C<$trace>.
 569
 570 =item C<$osingle> - saved value of C<$single>.
 571
 572 =item C<$od> - saved value of C<$^D>.
 573
 574 =item C<$saved[0]> - saved value of C<$@>.
 575
 576 =item $\ - for output of C<$@> if there is an evaluation error.
 577
 578 =back
 579
 580 =head3 The problem of lexicals
 581
 582 The context of C<DB::eval()> presents us with some problems. Obviously,
 583 we want to be 'sandboxed' away from the debugger's internals when we do
 584 the eval, but we need some way to control how punctuation variables and
 585 debugger globals are used.
 586
 587 We can't use local, because the code inside C<DB::eval> can see localized
 588 variables; and we can't use C<my> either for the same reason. The code
 589 in this routine compromises and uses C<my>.
 590
 591 After this routine is over, we don't have user code executing in the debugger's
 592 context, so we can use C<my> freely.
 593
 594 =cut
 595
 596 ############################################## Begin lexical danger zone
 597
 598 # 'my' variables used here could leak into (that is, be visible in)
 599 # the context that the code being evaluated is executing in. This means that
 600 # the code could modify the debugger's variables.
 601 #
 602 # Fiddling with the debugger's context could be Bad. We insulate things as
 603 # much as we can.
 604
 605 sub eval {
 606
 607     # 'my' would make it visible from user code
 608     #    but so does local! --tchrist
 609     # Remember: this localizes @DB::res, not @main::res.
 610     local @res;
 611     {
 612
 613         # Try to keep the user code from messing  with us. Save these so that
 614         # even if the eval'ed code changes them, we can put them back again.
 615         # Needed because the user could refer directly to the debugger's
 616         # package globals (and any 'my' variables in this containing scope)
 617         # inside the eval(), and we want to try to stay safe.
 618         local $otrace  = $trace;
 619         local $osingle = $single;
 620         local $od      = $^D;
 621
 622         # Untaint the incoming eval() argument.
 623         { ($evalarg) = $evalarg =~ /(.*)/s; }
 624
 625         # $usercontext built in DB::DB near the comment
 626         # "set up the context for DB::eval ..."
 627         # Evaluate and save any results.
 628         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 629
 630         # Restore those old values.
 631         $trace  = $otrace;
 632         $single = $osingle;
 633         $^D     = $od;
 634     }
 635
 636     # Save the current value of $@, and preserve it in the debugger's copy
 637     # of the saved precious globals.
 638     my $at = $@;
 639
 640     # Since we're only saving $@, we only have to localize the array element
 641     # that it will be stored in.
 642     local $saved[0];    # Preserve the old value of $@
 643     eval { &DB::save };
 644
 645     # Now see whether we need to report an error back to the user.
 646     if ($at) {
 647         local $\ = '';
 648         print $OUT $at;
 649     }
 650
 651     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 652     # are package globals.
 653     elsif ($onetimeDump) {
 654         if ( $onetimeDump eq 'dump' ) {
 655             local $option{dumpDepth} = $onetimedumpDepth
 656               if defined $onetimedumpDepth;
 657             dumpit( $OUT, \@res );
 658         }
 659         elsif ( $onetimeDump eq 'methods' ) {
 660             methods( $res[0] );
 661         }
 662     } ## end elsif ($onetimeDump)
 663     @res;
 664 } ## end sub eval
 665
 666 ############################################## End lexical danger zone
 667
 668 # After this point it is safe to introduce lexicals.
 669 # The code being debugged will be executing in its own context, and
 670 # can't see the inside of the debugger.
 671 #
 672 # However, one should not overdo it: leave as much control from outside as
 673 # possible. If you make something a lexical, it's not going to be addressable
 674 # from outside the debugger even if you know its name.
 675
 676 # This file is automatically included if you do perl -d.
 677 # It's probably not useful to include this yourself.
 678 #
 679 # Before venturing further into these twisty passages, it is
 680 # wise to read the perldebguts man page or risk the ire of dragons.
 681 #
 682 # (It should be noted that perldebguts will tell you a lot about
 683 # the underlying mechanics of how the debugger interfaces into the
 684 # Perl interpreter, but not a lot about the debugger itself. The new
 685 # comments in this code try to address this problem.)
 686
 687 # Note that no subroutine call is possible until &DB::sub is defined
 688 # (for subroutines defined outside of the package DB). In fact the same is
 689 # true if $deep is not defined.
 690
 691 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 692
 693 # modified Perl debugger, to be run from Emacs in perldb-mode
 694 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 695 # Johan Vromans -- upgrade to 4.0 pl 10
 696 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 697
 698 # (We have made efforts to  clarify the comments in the change log
 699 # in other places; some of them may seem somewhat obscure as they
 700 # were originally written, and explaining them away from the code
 701 # in question seems conterproductive.. -JM)
 702
 703 ########################################################################
 704 # Changes: 0.94
 705 #   + A lot of things changed after 0.94. First of all, core now informs
 706 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 707 #     BEGIN and END. Handy with `O f=2'.
 708 #   + This can make debugger a little bit too verbose, please be patient
 709 #     and report your problems promptly.
 710 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 711 #   + Note that if DESTROY returns a reference to the object (or object),
 712 #     the deletion of data may be postponed until the next function call,
 713 #     due to the need to examine the return value.
 714 #
 715 # Changes: 0.95
 716 #   + `v' command shows versions.
 717 #
 718 # Changes: 0.96
 719 #   + `v' command shows version of readline.
 720 #     primitive completion works (dynamic variables, subs for `b' and `l',
 721 #     options). Can `p %var'
 722 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 723 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 724 #   + `c sub' documented.
 725 #   + At last enough magic combined to stop after the end of debuggee.
 726 #   + !! should work now (thanks to Emacs bracket matching an extra
 727 #     `]' in a regexp is caught).
 728 #   + `L', `D' and `A' span files now (as documented).
 729 #   + Breakpoints in `require'd code are possible (used in `R').
 730 #   +  Some additional words on internal work of debugger.
 731 #   + `b load filename' implemented.
 732 #   + `b postpone subr' implemented.
 733 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 734 #   + When restarting debugger breakpoints/actions persist.
 735 #   + Buglet: When restarting debugger only one breakpoint/action per
 736 #             autoloaded function persists.
 737 #
 738 # Changes: 0.97: NonStop will not stop in at_exit().
 739 #   + Option AutoTrace implemented.
 740 #   + Trace printed differently if frames are printed too.
 741 #   + new `inhibitExit' option.
 742 #   + printing of a very long statement interruptible.
 743 # Changes: 0.98: New command `m' for printing possible methods
 744 #   + 'l -' is a synonym for `-'.
 745 #   + Cosmetic bugs in printing stack trace.
 746 #   +  `frame' & 8 to print "expanded args" in stack trace.
 747 #   + Can list/break in imported subs.
 748 #   + new `maxTraceLen' option.
 749 #   + frame & 4 and frame & 8 granted.
 750 #   + new command `m'
 751 #   + nonstoppable lines do not have `:' near the line number.
 752 #   + `b compile subname' implemented.
 753 #   + Will not use $` any more.
 754 #   + `-' behaves sane now.
 755 # Changes: 0.99: Completion for `f', `m'.
 756 #   +  `m' will remove duplicate names instead of duplicate functions.
 757 #   + `b load' strips trailing whitespace.
 758 #     completion ignores leading `|'; takes into account current package
 759 #     when completing a subroutine name (same for `l').
 760 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 761 #   BUG FIXES:
 762 #   + Added bare minimal security checks on perldb rc files, plus
 763 #     comments on what else is needed.
 764 #   + Fixed the ornaments that made "|h" completely unusable.
 765 #     They are not used in print_help if they will hurt.  Strip pod
 766 #     if we're paging to less.
 767 #   + Fixed mis-formatting of help messages caused by ornaments
 768 #     to restore Larry's original formatting.
 769 #   + Fixed many other formatting errors.  The code is still suboptimal,
 770 #     and needs a lot of work at restructuring.  It's also misindented
 771 #     in many places.
 772 #   + Fixed bug where trying to look at an option like your pager
 773 #     shows "1".
 774 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 775 #     lose.  You should consider shell escapes not using their shell,
 776 #     or else not caring about detailed status.  This should really be
 777 #     unified into one place, too.
 778 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 779 #     tricking Perl into thinking you weren't calling a debugger command!
 780 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 781 #     suggests a leading semicolon or any other irrelevant non-whitespace
 782 #     to indicate literal Perl code.)
 783 #   + Fixed bugs that ate warnings due to wrong selected handle.
 784 #   + Fixed a precedence bug on signal stuff.
 785 #   + Fixed some unseemly wording.
 786 #   + Fixed bug in help command trying to call perl method code.
 787 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 788 #   ENHANCEMENTS:
 789 #   + Added some comments.  This code is still nasty spaghetti.
 790 #   + Added message if you clear your pre/post command stacks which was
 791 #     very easy to do if you just typed a bare >, <, or {.  (A command
 792 #     without an argument should *never* be a destructive action; this
 793 #     API is fundamentally screwed up; likewise option setting, which
 794 #     is equally buggered.)
 795 #   + Added command stack dump on argument of "?" for >, <, or {.
 796 #   + Added a semi-built-in doc viewer command that calls man with the
 797 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 798 #     or else perldoc on obstreperous platforms.
 799 #   + Added to and rearranged the help information.
 800 #   + Detected apparent misuse of { ... } to declare a block; this used
 801 #     to work but now is a command, and mysteriously gave no complaint.
 802 #
 803 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 804 #   BUG FIX:
 805 #   + This patch to perl5db.pl cleans up formatting issues on the help
 806 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 807 #     issues, plus converted the printed text to use all spaces, since
 808 #     tabs don't seem to help much here.
 809 #
 810 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 811 #   Minor bugs corrected;
 812 #   + Support for auto-creation of new TTY window on startup, either
 813 #     unconditionally, or if started as a kid of another debugger session;
 814 #   + New `O'ption CreateTTY
 815 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 816 #                         1: on fork()
 817 #                         2: debugger is started inside debugger
 818 #                         4: on startup
 819 #   + Code to auto-create a new TTY window on OS/2 (currently one
 820 #     extra window per session - need named pipes to have more...);
 821 #   + Simplified interface for custom createTTY functions (with a backward
 822 #     compatibility hack); now returns the TTY name to use; return of ''
 823 #     means that the function reset the I/O handles itself;
 824 #   + Better message on the semantic of custom createTTY function;
 825 #   + Convert the existing code to create a TTY into a custom createTTY
 826 #     function;
 827 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 828 #   + Switch line-tracing output too to the created TTY window;
 829 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 830 #   + High-level debugger API cmd_*():
 831 #      cmd_b_load($filenamepart)            # b load filenamepart
 832 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 833 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 834 #      cmd_stop()                           # Control-C
 835 #      cmd_d($lineno)                       # d lineno (B)
 836 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 837 #      the error message to the debugging output.
 838 #   + Low-level debugger API
 839 #      break_on_load($filename)             # b load filename
 840 #      @files = report_break_on_load()      # List files with load-breakpoints
 841 #      breakable_line_in_filename($name, $from [, $to])
 842 #                                           # First breakable line in the
 843 #                                           # range $from .. $to.  $to defaults
 844 #                                           # to $from, and may be less than
 845 #                                           # $to
 846 #      breakable_line($from [, $to])        # Same for the current file
 847 #      break_on_filename_line($name, $lineno [, $cond])
 848 #                                           # Set breakpoint,$cond defaults to
 849 #                                           # 1
 850 #      break_on_filename_line_range($name, $from, $to [, $cond])
 851 #                                           # As above, on the first
 852 #                                           # breakable line in range
 853 #      break_on_line($lineno [, $cond])     # As above, in the current file
 854 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 855 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 856 #                                           # The range of lines of the text
 857 #      The low-level API returns TRUE on success, and die()s on failure.
 858 #
 859 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 860 #   BUG FIXES:
 861 #   + Fixed warnings generated by "perl -dWe 42"
 862 #   + Corrected spelling errors
 863 #   + Squeezed Help (h) output into 80 columns
 864 #
 865 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 866 #   + Made "x @INC" work like it used to
 867 #
 868 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 869 #   + Fixed warnings generated by "O" (Show debugger options)
 870 #   + Fixed warnings generated by "p 42" (Print expression)
 871 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 872 #   + Added windowSize option
 873 # Changes: 1.14: Oct  9, 2001 multiple
 874 #   + Clean up after itself on VMS (Charles Lane in 12385)
 875 #   + Adding "@ file" syntax (Peter Scott in 12014)
 876 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 877 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 878 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 879 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 880 #   + Updated 1.14 change log
 881 #   + Added *dbline explainatory comments
 882 #   + Mentioning perldebguts man page
 883 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 884 #   + $onetimeDump improvements
 885 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 886 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 887 #   rationalised the following commands and added cmd_wrapper() to
 888 #   enable switching between old and frighteningly consistent new
 889 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 890 #     a(add),       A(del)            # action expr   (added del by line)
 891 #   + b(add),       B(del)            # break  [line] (was b,D)
 892 #   + w(add),       W(del)            # watch  expr   (was W,W)
 893 #                                     # added del by expr
 894 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 895 #   + m(methods),   M(modules)        # ...           (was m,v)
 896 #   + o(option)                       # lc            (was O)
 897 #   + v(view code), V(view Variables) # ...           (was w,V)
 898 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 899 #   + fixed missing cmd_O bug
 900 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 901 #   + Added missing local()s -- DB::DB is called recursively.
 902 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 903 #   + pre'n'post commands no longer trashed with no args
 904 #   + watch val joined out of eval()
 905 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 906 #   + Added comments and reformatted source. No bug fixes/enhancements.
 907 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 908 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 909 #   + Flush stdout/stderr before the debugger prompt is printed.
 910 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 911 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 912 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 913 #   + Added command to save all debugger commands for sourcing later.
 914 #   + Added command to display parent inheritance tree of given class.
 915 #   + Fixed minor newline in history bug.
 916 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 917 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 918 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 919 #   + unfork the 5.8.x and 5.9.x debuggers.
 920 #   + whitespace and assertions call cleanup across versions
 921 #   + H * deletes (resets) history
 922 #   + i now handles Class + blessed objects
 923 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 924 #   + updated pod page references - clunky.
 925 #   + removed windowid restriction for forking into an xterm.
 926 #   + more whitespace again.
 927 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 928 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + Added threads support (inc. e and E commands)
 930 ####################################################################
 931
 932 =head1 DEBUGGER INITIALIZATION
 933
 934 The debugger starts up in phases.
 935
 936 =head2 BASIC SETUP
 937
 938 First, it initializes the environment it wants to run in: turning off
 939 warnings during its own compilation, defining variables which it will need
 940 to avoid warnings later, setting itself up to not exit when the program
 941 terminates, and defaulting to printing return values for the C<r> command.
 942
 943 =cut
 944
 945 # Needed for the statement after exec():
 946 #
 947 # This BEGIN block is simply used to switch off warnings during debugger
 948 # compiliation. Probably it would be better practice to fix the warnings,
 949 # but this is how it's done at the moment.
 950
 951 BEGIN {
 952     $ini_warn = $^W;
 953     $^W       = 0;
 954 }    # Switch compilation warnings off until another BEGIN.
 955
 956 # test if assertions are supported and actived:
 957 BEGIN {
 958     $ini_assertion = eval "sub asserting_test : assertion {1}; 1";
 959
 960     # $ini_assertion = undef => assertions unsupported,
 961     #        "       = 1     => assertions supported
 962     # print "\$ini_assertion=$ini_assertion\n";
 963 }
 964
 965 local ($^W) = 0;    # Switch run-time warnings off during init.
 966
 967 =head2 THREADS SUPPORT
 968
 969 If we are running under a threaded Perl, we require threads and threads::shared
 970 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 971 threaded debugger control.  C<-dt> can also be used to set this.
 972
 973 Each new thread will be announced and the debugger prompt will always inform
 974 you of each new thread created.  It will also indicate the thread id in which
 975 we are currently running within the prompt like this:
 976
 977         [tid] DB<$i>
 978
 979 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 980 command prompt.  The prompt will show: C<[0]> when running under threads, but
 981 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 982
 983 While running under threads, when you set or delete a breakpoint (etc.), this
 984 will apply to all threads, not just the currently running one.  When you are
 985 in a currently executing thread, you will stay there until it completes.  With
 986 the current implementation it is not currently possible to hop from one thread
 987 to another.
 988
 989 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 990
 991 Note that threading support was built into the debugger as of Perl version
 992 C<5.8.6> and debugger version C<1.2.8>.
 993
 994 =cut
 995
 996 BEGIN {
 997   # ensure we can share our non-threaded variables or no-op
 998   if ($ENV{PERL5DB_THREADED}) {
 999         require threads;
1000         require threads::shared;
1001         import threads::shared qw(share);
1002         $DBGR;
1003         share(\$DBGR);
1004         lock($DBGR);
1005         print "Threads support enabled\n";
1006   } else {
1007         *lock  = sub(*) {};
1008         *share = sub(*) {};
1009   }
1010 }
1011
1012 # This would probably be better done with "use vars", but that wasn't around
1013 # when this code was originally written. (Neither was "use strict".) And on
1014 # the principle of not fiddling with something that was working, this was
1015 # left alone.
1016 warn(               # Do not ;-)
1017     # These variables control the execution of 'dumpvar.pl'.
1018     $dumpvar::hashDepth,
1019     $dumpvar::arrayDepth,
1020     $dumpvar::dumpDBFiles,
1021     $dumpvar::dumpPackages,
1022     $dumpvar::quoteHighBit,
1023     $dumpvar::printUndef,
1024     $dumpvar::globPrint,
1025     $dumpvar::usageOnly,
1026
1027     # used to save @ARGV and extract any debugger-related flags.
1028     @ARGS,
1029
1030     # used to control die() reporting in diesignal()
1031     $Carp::CarpLevel,
1032
1033     # used to prevent multiple entries to diesignal()
1034     # (if for instance diesignal() itself dies)
1035     $panic,
1036
1037     # used to prevent the debugger from running nonstop
1038     # after a restart
1039     $second_time,
1040   )
1041   if 0;
1042
1043 foreach my $k (keys (%INC)) {
1044         &share(\$main::{'_<'.$filename});
1045 };
1046
1047 # Command-line + PERLLIB:
1048 # Save the contents of @INC before they are modified elsewhere.
1049 @ini_INC = @INC;
1050
1051 # This was an attempt to clear out the previous values of various
1052 # trapped errors. Apparently it didn't help. XXX More info needed!
1053 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1054
1055 # We set these variables to safe values. We don't want to blindly turn
1056 # off warnings, because other packages may still want them.
1057 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1058                                    # (local $^W cannot help - other packages!).
1059
1060 # Default to not exiting when program finishes; print the return
1061 # value when the 'r' command is used to return from a subroutine.
1062 $inhibit_exit = $option{PrintRet} = 1;
1063
1064 =head1 OPTION PROCESSING
1065
1066 The debugger's options are actually spread out over the debugger itself and
1067 C<dumpvar.pl>; some of these are variables to be set, while others are
1068 subs to be called with a value. To try to make this a little easier to
1069 manage, the debugger uses a few data structures to define what options
1070 are legal and how they are to be processed.
1071
1072 First, the C<@options> array defines the I<names> of all the options that
1073 are to be accepted.
1074
1075 =cut
1076
1077 @options = qw(
1078   CommandSet
1079   hashDepth    arrayDepth    dumpDepth
1080   DumpDBFiles  DumpPackages  DumpReused
1081   compactDump  veryCompact   quote
1082   HighBit      undefPrint    globPrint
1083   PrintRet     UsageOnly     frame
1084   AutoTrace    TTY           noTTY
1085   ReadLine     NonStop       LineInfo
1086   maxTraceLen  recallCommand ShellBang
1087   pager        tkRunning     ornaments
1088   signalLevel  warnLevel     dieLevel
1089   inhibit_exit ImmediateStop bareStringify
1090   CreateTTY    RemotePort    windowSize
1091   DollarCaretP OnlyAssertions WarnAssertions
1092 );
1093
1094 @RememberOnROptions = qw(DollarCaretP OnlyAssertions);
1095
1096 =pod
1097
1098 Second, C<optionVars> lists the variables that each option uses to save its
1099 state.
1100
1101 =cut
1102
1103 %optionVars = (
1104     hashDepth     => \$dumpvar::hashDepth,
1105     arrayDepth    => \$dumpvar::arrayDepth,
1106     CommandSet    => \$CommandSet,
1107     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1108     DumpPackages  => \$dumpvar::dumpPackages,
1109     DumpReused    => \$dumpvar::dumpReused,
1110     HighBit       => \$dumpvar::quoteHighBit,
1111     undefPrint    => \$dumpvar::printUndef,
1112     globPrint     => \$dumpvar::globPrint,
1113     UsageOnly     => \$dumpvar::usageOnly,
1114     CreateTTY     => \$CreateTTY,
1115     bareStringify => \$dumpvar::bareStringify,
1116     frame         => \$frame,
1117     AutoTrace     => \$trace,
1118     inhibit_exit  => \$inhibit_exit,
1119     maxTraceLen   => \$maxtrace,
1120     ImmediateStop => \$ImmediateStop,
1121     RemotePort    => \$remoteport,
1122     windowSize    => \$window,
1123     WarnAssertions => \$warnassertions,
1124 );
1125
1126 =pod
1127
1128 Third, C<%optionAction> defines the subroutine to be called to process each
1129 option.
1130
1131 =cut
1132
1133 %optionAction = (
1134     compactDump   => \&dumpvar::compactDump,
1135     veryCompact   => \&dumpvar::veryCompact,
1136     quote         => \&dumpvar::quote,
1137     TTY           => \&TTY,
1138     noTTY         => \&noTTY,
1139     ReadLine      => \&ReadLine,
1140     NonStop       => \&NonStop,
1141     LineInfo      => \&LineInfo,
1142     recallCommand => \&recallCommand,
1143     ShellBang     => \&shellBang,
1144     pager         => \&pager,
1145     signalLevel   => \&signalLevel,
1146     warnLevel     => \&warnLevel,
1147     dieLevel      => \&dieLevel,
1148     tkRunning     => \&tkRunning,
1149     ornaments     => \&ornaments,
1150     RemotePort    => \&RemotePort,
1151     DollarCaretP  => \&DollarCaretP,
1152     OnlyAssertions=> \&OnlyAssertions,
1153 );
1154
1155 =pod
1156
1157 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1158 option is used.
1159
1160 =cut
1161
1162 # Note that this list is not complete: several options not listed here
1163 # actually require that dumpvar.pl be loaded for them to work, but are
1164 # not in the table. A subsequent patch will correct this problem; for
1165 # the moment, we're just recommenting, and we are NOT going to change
1166 # function.
1167 %optionRequire = (
1168     compactDump => 'dumpvar.pl',
1169     veryCompact => 'dumpvar.pl',
1170     quote       => 'dumpvar.pl',
1171 );
1172
1173 =pod
1174
1175 There are a number of initialization-related variables which can be set
1176 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1177 variable. These are:
1178
1179 =over 4
1180
1181 =item C<$rl> - readline control XXX needs more explanation
1182
1183 =item C<$warnLevel> - whether or not debugger takes over warning handling
1184
1185 =item C<$dieLevel> - whether or not debugger takes over die handling
1186
1187 =item C<$signalLevel> - whether or not debugger takes over signal handling
1188
1189 =item C<$pre> - preprompt actions (array reference)
1190
1191 =item C<$post> - postprompt actions (array reference)
1192
1193 =item C<$pretype>
1194
1195 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1196
1197 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1198
1199 =back
1200
1201 =cut
1202
1203 # These guys may be defined in $ENV{PERL5DB} :
1204 $rl          = 1     unless defined $rl;
1205 $warnLevel   = 1     unless defined $warnLevel;
1206 $dieLevel    = 1     unless defined $dieLevel;
1207 $signalLevel = 1     unless defined $signalLevel;
1208 $pre         = []    unless defined $pre;
1209 $post        = []    unless defined $post;
1210 $pretype     = []    unless defined $pretype;
1211 $CreateTTY   = 3     unless defined $CreateTTY;
1212 $CommandSet  = '580' unless defined $CommandSet;
1213
1214 share($rl);
1215 share($warnLevel);
1216 share($dieLevel);
1217 share($signalLevel);
1218 share($pre);
1219 share($post);
1220 share($pretype);
1221 share($rl);
1222 share($CreateTTY);
1223 share($CommandSet);
1224
1225 =pod
1226
1227 The default C<die>, C<warn>, and C<signal> handlers are set up.
1228
1229 =cut
1230
1231 warnLevel($warnLevel);
1232 dieLevel($dieLevel);
1233 signalLevel($signalLevel);
1234
1235 =pod
1236
1237 The pager to be used is needed next. We try to get it from the
1238 environment first.  if it's not defined there, we try to find it in
1239 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1240 then call the C<pager()> function to save the pager name.
1241
1242 =cut
1243
1244 # This routine makes sure $pager is set up so that '|' can use it.
1245 pager(
1246
1247     # If PAGER is defined in the environment, use it.
1248     defined $ENV{PAGER}
1249     ? $ENV{PAGER}
1250
1251       # If not, see if Config.pm defines it.
1252     : eval { require Config }
1253       && defined $Config::Config{pager}
1254     ? $Config::Config{pager}
1255
1256       # If not, fall back to 'more'.
1257     : 'more'
1258   )
1259   unless defined $pager;
1260
1261 =pod
1262
1263 We set up the command to be used to access the man pages, the command
1264 recall character (C<!> unless otherwise defined) and the shell escape
1265 character (C<!> unless otherwise defined). Yes, these do conflict, and
1266 neither works in the debugger at the moment.
1267
1268 =cut
1269
1270 setman();
1271
1272 # Set up defaults for command recall and shell escape (note:
1273 # these currently don't work in linemode debugging).
1274 &recallCommand("!") unless defined $prc;
1275 &shellBang("!")     unless defined $psh;
1276
1277 =pod
1278
1279 We then set up the gigantic string containing the debugger help.
1280 We also set the limit on the number of arguments we'll display during a
1281 trace.
1282
1283 =cut
1284
1285 sethelp();
1286
1287 # If we didn't get a default for the length of eval/stack trace args,
1288 # set it here.
1289 $maxtrace = 400 unless defined $maxtrace;
1290
1291 =head2 SETTING UP THE DEBUGGER GREETING
1292
1293 The debugger I<greeting> helps to inform the user how many debuggers are
1294 running, and whether the current debugger is the primary or a child.
1295
1296 If we are the primary, we just hang onto our pid so we'll have it when
1297 or if we start a child debugger. If we are a child, we'll set things up
1298 so we'll have a unique greeting and so the parent will give us our own
1299 TTY later.
1300
1301 We save the current contents of the C<PERLDB_PIDS> environment variable
1302 because we mess around with it. We'll also need to hang onto it because
1303 we'll need it if we restart.
1304
1305 Child debuggers make a label out of the current PID structure recorded in
1306 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1307 yet so the parent will give them one later via C<resetterm()>.
1308
1309 =cut
1310
1311 # Save the current contents of the environment; we're about to
1312 # much with it. We'll need this if we have to restart.
1313 $ini_pids = $ENV{PERLDB_PIDS};
1314
1315 if ( defined $ENV{PERLDB_PIDS} ) {
1316
1317     # We're a child. Make us a label out of the current PID structure
1318     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1319     # a term yet so the parent will give us one later via resetterm().
1320
1321     my $env_pids = $ENV{PERLDB_PIDS};
1322     $pids = "[$env_pids]";
1323
1324     # Unless we are on OpenVMS, all programs under the DCL shell run under
1325     # the same PID.
1326
1327     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1328         $term_pid         = $$;
1329     }
1330     else {
1331         $ENV{PERLDB_PIDS} .= "->$$";
1332         $term_pid = -1;
1333     }
1334
1335 } ## end if (defined $ENV{PERLDB_PIDS...
1336 else {
1337
1338     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1339     # child debugger, and mark us as the parent, so we'll know to set up
1340     # more TTY's is we have to.
1341     $ENV{PERLDB_PIDS} = "$$";
1342     $pids             = "{pid=$$}";
1343     $term_pid         = $$;
1344 }
1345
1346 $pidprompt = '';
1347
1348 # Sets up $emacs as a synonym for $slave_editor.
1349 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1350
1351 =head2 READING THE RC FILE
1352
1353 The debugger will read a file of initialization options if supplied. If
1354 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1355
1356 =cut
1357
1358 # As noted, this test really doesn't check accurately that the debugger
1359 # is running at a terminal or not.
1360
1361 if ( -e "/dev/tty" ) {                      # this is the wrong metric!
1362     $rcfile = ".perldb";
1363 }
1364 else {
1365     $rcfile = "perldb.ini";
1366 }
1367
1368 =pod
1369
1370 The debugger does a safety test of the file to be read. It must be owned
1371 either by the current user or root, and must only be writable by the owner.
1372
1373 =cut
1374
1375 # This wraps a safety test around "do" to read and evaluate the init file.
1376 #
1377 # This isn't really safe, because there's a race
1378 # between checking and opening.  The solution is to
1379 # open and fstat the handle, but then you have to read and
1380 # eval the contents.  But then the silly thing gets
1381 # your lexical scope, which is unfortunate at best.
1382 sub safe_do {
1383     my $file = shift;
1384
1385     # Just exactly what part of the word "CORE::" don't you understand?
1386     local $SIG{__WARN__};
1387     local $SIG{__DIE__};
1388
1389     unless ( is_safe_file($file) ) {
1390         CORE::warn <<EO_GRIPE;
1391 perldb: Must not source insecure rcfile $file.
1392         You or the superuser must be the owner, and it must not
1393         be writable by anyone but its owner.
1394 EO_GRIPE
1395         return;
1396     } ## end unless (is_safe_file($file...
1397
1398     do $file;
1399     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1400 } ## end sub safe_do
1401
1402 # This is the safety test itself.
1403 #
1404 # Verifies that owner is either real user or superuser and that no
1405 # one but owner may write to it.  This function is of limited use
1406 # when called on a path instead of upon a handle, because there are
1407 # no guarantees that filename (by dirent) whose file (by ino) is
1408 # eventually accessed is the same as the one tested.
1409 # Assumes that the file's existence is not in doubt.
1410 sub is_safe_file {
1411     my $path = shift;
1412     stat($path) || return;    # mysteriously vaporized
1413     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1414
1415     return 0 if $uid != 0 && $uid != $<;
1416     return 0 if $mode & 022;
1417     return 1;
1418 } ## end sub is_safe_file
1419
1420 # If the rcfile (whichever one we decided was the right one to read)
1421 # exists, we safely do it.
1422 if ( -f $rcfile ) {
1423     safe_do("./$rcfile");
1424 }
1425
1426 # If there isn't one here, try the user's home directory.
1427 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1428     safe_do("$ENV{HOME}/$rcfile");
1429 }
1430
1431 # Else try the login directory.
1432 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1433     safe_do("$ENV{LOGDIR}/$rcfile");
1434 }
1435
1436 # If the PERLDB_OPTS variable has options in it, parse those out next.
1437 if ( defined $ENV{PERLDB_OPTS} ) {
1438     parse_options( $ENV{PERLDB_OPTS} );
1439 }
1440
1441 =pod
1442
1443 The last thing we do during initialization is determine which subroutine is
1444 to be used to obtain a new terminal when a new debugger is started. Right now,
1445 the debugger only handles X Windows and OS/2.
1446
1447 =cut
1448
1449 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1450 # Works if you're running an xterm or xterm-like window, or you're on
1451 # OS/2. This may need some expansion: for instance, this doesn't handle
1452 # OS X Terminal windows.
1453
1454 if (
1455     not defined &get_fork_TTY    # no routine exists,
1456     and defined $ENV{TERM}       # and we know what kind
1457                                  # of terminal this is,
1458     and $ENV{TERM} eq 'xterm'    # and it's an xterm,
1459 #   and defined $ENV{WINDOWID}   # and we know what window this is, <- wrong metric
1460     and defined $ENV{DISPLAY}    # and what display it's on,
1461   )
1462 {
1463     *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1464 } ## end if (not defined &get_fork_TTY...
1465 elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1466     *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1467 }
1468
1469 # untaint $^O, which may have been tainted by the last statement.
1470 # see bug [perl #24674]
1471 $^O =~ m/^(.*)\z/;
1472 $^O = $1;
1473
1474 # Here begin the unreadable code.  It needs fixing.
1475
1476 =head2 RESTART PROCESSING
1477
1478 This section handles the restart command. When the C<R> command is invoked, it
1479 tries to capture all of the state it can into environment variables, and
1480 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1481 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1482 the R command stuffed into the environment variables.
1483
1484   PERLDB_RESTART   - flag only, contains no restart data itself.
1485   PERLDB_HIST      - command history, if it's available
1486   PERLDB_ON_LOAD   - breakpoints set by the rc file
1487   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1488   PERLDB_VISITED   - files that had breakpoints
1489   PERLDB_FILE_...  - breakpoints for a file
1490   PERLDB_OPT       - active options
1491   PERLDB_INC       - the original @INC
1492   PERLDB_PRETYPE   - preprompt debugger actions
1493   PERLDB_PRE       - preprompt Perl code
1494   PERLDB_POST      - post-prompt Perl code
1495   PERLDB_TYPEAHEAD - typeahead captured by readline()
1496
1497 We chug through all these variables and plug the values saved in them
1498 back into the appropriate spots in the debugger.
1499
1500 =cut
1501
1502 if ( exists $ENV{PERLDB_RESTART} ) {
1503
1504     # We're restarting, so we don't need the flag that says to restart anymore.
1505     delete $ENV{PERLDB_RESTART};
1506
1507     # $restart = 1;
1508     @hist          = get_list('PERLDB_HIST');
1509     %break_on_load = get_list("PERLDB_ON_LOAD");
1510     %postponed     = get_list("PERLDB_POSTPONE");
1511
1512         share(@hist);
1513         share(@truehist);
1514         share(%break_on_load);
1515         share(%postponed);
1516
1517     # restore breakpoints/actions
1518     my @had_breakpoints = get_list("PERLDB_VISITED");
1519     for ( 0 .. $#had_breakpoints ) {
1520         my %pf = get_list("PERLDB_FILE_$_");
1521         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1522     }
1523
1524     # restore options
1525     my %opt = get_list("PERLDB_OPT");
1526     my ( $opt, $val );
1527     while ( ( $opt, $val ) = each %opt ) {
1528         $val =~ s/[\\\']/\\$1/g;
1529         parse_options("$opt'$val'");
1530     }
1531
1532     # restore original @INC
1533     @INC     = get_list("PERLDB_INC");
1534     @ini_INC = @INC;
1535
1536     # return pre/postprompt actions and typeahead buffer
1537     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1538     $pre       = [ get_list("PERLDB_PRE") ];
1539     $post      = [ get_list("PERLDB_POST") ];
1540     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1541 } ## end if (exists $ENV{PERLDB_RESTART...
1542
1543 =head2 SETTING UP THE TERMINAL
1544
1545 Now, we'll decide how the debugger is going to interact with the user.
1546 If there's no TTY, we set the debugger to run non-stop; there's not going
1547 to be anyone there to enter commands.
1548
1549 =cut
1550
1551 if ($notty) {
1552     $runnonstop = 1;
1553         share($runnonstop);
1554 }
1555
1556 =pod
1557
1558 If there is a TTY, we have to determine who it belongs to before we can
1559 proceed. If this is a slave editor or graphical debugger (denoted by
1560 the first command-line switch being '-emacs'), we shift this off and
1561 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1562
1563 =cut
1564
1565 else {
1566
1567     # Is Perl being run from a slave editor or graphical debugger?
1568     # If so, don't use readline, and set $slave_editor = 1.
1569     $slave_editor =
1570       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1571     $rl = 0, shift(@main::ARGV) if $slave_editor;
1572
1573     #require Term::ReadLine;
1574
1575 =pod
1576
1577 We then determine what the console should be on various systems:
1578
1579 =over 4
1580
1581 =item * Cygwin - We use C<stdin> instead of a separate device.
1582
1583 =cut
1584
1585     if ( $^O eq 'cygwin' ) {
1586
1587         # /dev/tty is binary. use stdin for textmode
1588         undef $console;
1589     }
1590
1591 =item * Unix - use C</dev/tty>.
1592
1593 =cut
1594
1595     elsif ( -e "/dev/tty" ) {
1596         $console = "/dev/tty";
1597     }
1598
1599 =item * Windows or MSDOS - use C<con>.
1600
1601 =cut
1602
1603     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1604         $console = "con";
1605     }
1606
1607 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1608 Console> if not.
1609
1610 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1611
1612 =cut
1613
1614     elsif ( $^O eq 'MacOS' ) {
1615         if ( $MacPerl::Version !~ /MPW/ ) {
1616             $console =
1617               "Dev:Console:Perl Debug";    # Separate window for application
1618         }
1619         else {
1620             $console = "Dev:Console";
1621         }
1622     } ## end elsif ($^O eq 'MacOS')
1623
1624 =item * VMS - use C<sys$command>.
1625
1626 =cut
1627
1628     else {
1629
1630         # everything else is ...
1631         $console = "sys\$command";
1632     }
1633
1634 =pod
1635
1636 =back
1637
1638 Several other systems don't use a specific console. We C<undef $console>
1639 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1640 with a slave editor, Epoc).
1641
1642 =cut
1643
1644     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1645
1646         # /dev/tty is binary. use stdin for textmode
1647         $console = undef;
1648     }
1649
1650     if ( $^O eq 'NetWare' ) {
1651
1652         # /dev/tty is binary. use stdin for textmode
1653         $console = undef;
1654     }
1655
1656     # In OS/2, we need to use STDIN to get textmode too, even though
1657     # it pretty much looks like Unix otherwise.
1658     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1659     {    # In OS/2
1660         $console = undef;
1661     }
1662
1663     # EPOC also falls into the 'got to use STDIN' camp.
1664     if ( $^O eq 'epoc' ) {
1665         $console = undef;
1666     }
1667
1668 =pod
1669
1670 If there is a TTY hanging around from a parent, we use that as the console.
1671
1672 =cut
1673
1674     $console = $tty if defined $tty;
1675
1676 =head2 SOCKET HANDLING
1677
1678 The debugger is capable of opening a socket and carrying out a debugging
1679 session over the socket.
1680
1681 If C<RemotePort> was defined in the options, the debugger assumes that it
1682 should try to start a debugging session on that port. It builds the socket
1683 and then tries to connect the input and output filehandles to it.
1684
1685 =cut
1686
1687     # Handle socket stuff.
1688
1689     if ( defined $remoteport ) {
1690
1691         # If RemotePort was defined in the options, connect input and output
1692         # to the socket.
1693         require IO::Socket;
1694         $OUT = new IO::Socket::INET(
1695             Timeout  => '10',
1696             PeerAddr => $remoteport,
1697             Proto    => 'tcp',
1698         );
1699         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1700         $IN = $OUT;
1701     } ## end if (defined $remoteport)
1702
1703 =pod
1704
1705 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1706 this is probably a situation where multiple debuggers are running (for example,
1707 a backticked command that starts up another debugger). We create a new IN and
1708 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1709 and if we can.
1710
1711 =cut
1712
1713     # Non-socket.
1714     else {
1715
1716         # Two debuggers running (probably a system or a backtick that invokes
1717         # the debugger itself under the running one). create a new IN and OUT
1718         # filehandle, and do the necessary mojo to create a new tty if we
1719         # know how, and we can.
1720         create_IN_OUT(4) if $CreateTTY & 4;
1721         if ($console) {
1722
1723             # If we have a console, check to see if there are separate ins and
1724             # outs to open. (They are assumed identiical if not.)
1725
1726             my ( $i, $o ) = split /,/, $console;
1727             $o = $i unless defined $o;
1728
1729             # read/write on in, or just read, or read on STDIN.
1730             open( IN,      "+<$i" )
1731               || open( IN, "<$i" )
1732               || open( IN, "<&STDIN" );
1733
1734             # read/write/create/clobber out, or write/create/clobber out,
1735             # or merge with STDERR, or merge with STDOUT.
1736                  open( OUT, "+>$o" )
1737               || open( OUT, ">$o" )
1738               || open( OUT, ">&STDERR" )
1739               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1740
1741         } ## end if ($console)
1742         elsif ( not defined $console ) {
1743
1744             # No console. Open STDIN.
1745             open( IN, "<&STDIN" );
1746
1747             # merge with STDERR, or with STDOUT.
1748             open( OUT,      ">&STDERR" )
1749               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1750             $console = 'STDIN/OUT';
1751         } ## end elsif (not defined $console)
1752
1753         # Keep copies of the filehandles so that when the pager runs, it
1754         # can close standard input without clobbering ours.
1755         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1756     } ## end elsif (from if(defined $remoteport))
1757
1758     # Unbuffer DB::OUT. We need to see responses right away.
1759     my $previous = select($OUT);
1760     $| = 1;                                  # for DB::OUT
1761     select($previous);
1762
1763     # Line info goes to debugger output unless pointed elsewhere.
1764     # Pointing elsewhere makes it possible for slave editors to
1765     # keep track of file and position. We have both a filehandle
1766     # and a I/O description to keep track of.
1767     $LINEINFO = $OUT     unless defined $LINEINFO;
1768     $lineinfo = $console unless defined $lineinfo;
1769         # share($LINEINFO); # <- unable to share globs
1770         share($lineinfo);   #
1771
1772 =pod
1773
1774 To finish initialization, we show the debugger greeting,
1775 and then call the C<afterinit()> subroutine if there is one.
1776
1777 =cut
1778
1779     # Show the debugger greeting.
1780     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1781     unless ($runnonstop) {
1782         local $\ = '';
1783         local $, = '';
1784         if ( $term_pid eq '-1' ) {
1785             print $OUT "\nDaughter DB session started...\n";
1786         }
1787         else {
1788             print $OUT "\nLoading DB routines from $header\n";
1789             print $OUT (
1790                 "Editor support ",
1791                 $slave_editor ? "enabled" : "available", ".\n"
1792             );
1793             print $OUT
1794 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1795         } ## end else [ if ($term_pid eq '-1')
1796     } ## end unless ($runnonstop)
1797 } ## end else [ if ($notty)
1798
1799 # XXX This looks like a bug to me.
1800 # Why copy to @ARGS and then futz with @args?
1801 @ARGS = @ARGV;
1802 for (@args) {
1803     # Make sure backslashes before single quotes are stripped out, and
1804     # keep args unless they are numeric (XXX why?)
1805     # s/\'/\\\'/g;                      # removed while not justified understandably
1806     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1807 }
1808
1809 # If there was an afterinit() sub defined, call it. It will get
1810 # executed in our scope, so it can fiddle with debugger globals.
1811 if ( defined &afterinit ) {    # May be defined in $rcfile
1812     &afterinit();
1813 }
1814
1815 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1816 $I_m_init = 1;
1817
1818 ############################################################ Subroutines
1819
1820 =head1 SUBROUTINES
1821
1822 =head2 DB
1823
1824 This gigantic subroutine is the heart of the debugger. Called before every
1825 statement, its job is to determine if a breakpoint has been reached, and
1826 stop if so; read commands from the user, parse them, and execute
1827 them, and hen send execution off to the next statement.
1828
1829 Note that the order in which the commands are processed is very important;
1830 some commands earlier in the loop will actually alter the C<$cmd> variable
1831 to create other commands to be executed later. This is all highly I<optimized>
1832 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1833 see what's happening in any given command.
1834
1835 =cut
1836
1837 sub DB {
1838
1839     # lock the debugger and get the thread id for the prompt
1840         lock($DBGR);
1841         my $tid;
1842         if ($ENV{PERL5DB_THREADED}) {
1843                 $tid = eval { "[".threads->self->tid."]" };
1844         }
1845
1846     # Check for whether we should be running continuously or not.
1847     # _After_ the perl program is compiled, $single is set to 1:
1848     if ( $single and not $second_time++ ) {
1849
1850         # Options say run non-stop. Run until we get an interrupt.
1851         if ($runnonstop) {    # Disable until signal
1852                 # If there's any call stack in place, turn off single
1853                 # stepping into subs throughout the stack.
1854             for ( $i = 0 ; $i <= $stack_depth ; ) {
1855                 $stack[ $i++ ] &= ~1;
1856             }
1857
1858             # And we are now no longer in single-step mode.
1859             $single = 0;
1860
1861             # If we simply returned at this point, we wouldn't get
1862             # the trace info. Fall on through.
1863             # return;
1864         } ## end if ($runnonstop)
1865
1866         elsif ($ImmediateStop) {
1867
1868             # We are supposed to stop here; XXX probably a break.
1869             $ImmediateStop = 0;    # We've processed it; turn it off
1870             $signal        = 1;    # Simulate an interrupt to force
1871                                    # us into the command loop
1872         }
1873     } ## end if ($single and not $second_time...
1874
1875     # If we're in single-step mode, or an interrupt (real or fake)
1876     # has occurred, turn off non-stop mode.
1877     $runnonstop = 0 if $single or $signal;
1878
1879     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1880     # The code being debugged may have altered them.
1881     &save;
1882
1883     # Since DB::DB gets called after every line, we can use caller() to
1884     # figure out where we last were executing. Sneaky, eh? This works because
1885     # caller is returning all the extra information when called from the
1886     # debugger.
1887     local ( $package, $filename, $line ) = caller;
1888     local $filename_ini = $filename;
1889
1890     # set up the context for DB::eval, so it can properly execute
1891     # code on behalf of the user. We add the package in so that the
1892     # code is eval'ed in the proper package (not in the debugger!).
1893     local $usercontext =
1894       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1895
1896     # Create an alias to the active file magical array to simplify
1897     # the code here.
1898     local (*dbline) = $main::{ '_<' . $filename };
1899
1900     # we need to check for pseudofiles on Mac OS (these are files
1901     # not attached to a filename, but instead stored in Dev:Pseudo)
1902     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1903         $filename_ini = $filename = 'Dev:Pseudo';
1904         *dbline = $main::{ '_<' . $filename };
1905     }
1906
1907     # Last line in the program.
1908     local $max = $#dbline;
1909
1910     # if we have something here, see if we should break.
1911     if ( $dbline{$line}
1912         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1913     {
1914
1915         # Stop if the stop criterion says to just stop.
1916         if ( $stop eq '1' ) {
1917             $signal |= 1;
1918         }
1919
1920         # It's a conditional stop; eval it in the user's context and
1921         # see if we should stop. If so, remove the one-time sigil.
1922         elsif ($stop) {
1923             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1924             &eval;
1925             $dbline{$line} =~ s/;9($|\0)/$1/;
1926         }
1927     } ## end if ($dbline{$line} && ...
1928
1929     # Preserve the current stop-or-not, and see if any of the W
1930     # (watch expressions) has changed.
1931     my $was_signal = $signal;
1932
1933     # If we have any watch expressions ...
1934     if ( $trace & 2 ) {
1935         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1936             $evalarg = $to_watch[$n];
1937             local $onetimeDump;    # Tell DB::eval() to not output results
1938
1939             # Fix context DB::eval() wants to return an array, but
1940             # we need a scalar here.
1941             my ($val) = join( "', '", &eval );
1942             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1943
1944             # Did it change?
1945             if ( $val ne $old_watch[$n] ) {
1946
1947                 # Yep! Show the difference, and fake an interrupt.
1948                 $signal = 1;
1949                 print $OUT <<EOP;
1950 Watchpoint $n:\t$to_watch[$n] changed:
1951     old value:\t$old_watch[$n]
1952     new value:\t$val
1953 EOP
1954                 $old_watch[$n] = $val;
1955             } ## end if ($val ne $old_watch...
1956         } ## end for (my $n = 0 ; $n <= ...
1957     } ## end if ($trace & 2)
1958
1959 =head2 C<watchfunction()>
1960
1961 C<watchfunction()> is a function that can be defined by the user; it is a
1962 function which will be run on each entry to C<DB::DB>; it gets the
1963 current package, filename, and line as its parameters.
1964
1965 The watchfunction can do anything it likes; it is executing in the
1966 debugger's context, so it has access to all of the debugger's internal
1967 data structures and functions.
1968
1969 C<watchfunction()> can control the debugger's actions. Any of the following
1970 will cause the debugger to return control to the user's program after
1971 C<watchfunction()> executes:
1972
1973 =over 4
1974
1975 =item *
1976
1977 Returning a false value from the C<watchfunction()> itself.
1978
1979 =item *
1980
1981 Altering C<$single> to a false value.
1982
1983 =item *
1984
1985 Altering C<$signal> to a false value.
1986
1987 =item *
1988
1989 Turning off the C<4> bit in C<$trace> (this also disables the
1990 check for C<watchfunction()>. This can be done with
1991
1992     $trace &= ~4;
1993
1994 =back
1995
1996 =cut
1997
1998     # If there's a user-defined DB::watchfunction, call it with the
1999     # current package, filename, and line. The function executes in
2000     # the DB:: package.
2001     if ( $trace & 4 ) {    # User-installed watch
2002         return
2003           if watchfunction( $package, $filename, $line )
2004           and not $single
2005           and not $was_signal
2006           and not( $trace & ~4 );
2007     } ## end if ($trace & 4)
2008
2009     # Pick up any alteration to $signal in the watchfunction, and
2010     # turn off the signal now.
2011     $was_signal = $signal;
2012     $signal     = 0;
2013
2014 =head2 GETTING READY TO EXECUTE COMMANDS
2015
2016 The debugger decides to take control if single-step mode is on, the
2017 C<t> command was entered, or the user generated a signal. If the program
2018 has fallen off the end, we set things up so that entering further commands
2019 won't cause trouble, and we say that the program is over.
2020
2021 =cut
2022
2023     # Check to see if we should grab control ($single true,
2024     # trace set appropriately, or we got a signal).
2025     if ( $single || ( $trace & 1 ) || $was_signal ) {
2026
2027         # Yes, grab control.
2028         if ($slave_editor) {
2029
2030             # Tell the editor to update its position.
2031             $position = "\032\032$filename:$line:0\n";
2032             print_lineinfo($position);
2033         }
2034
2035 =pod
2036
2037 Special check: if we're in package C<DB::fake>, we've gone through the
2038 C<END> block at least once. We set up everything so that we can continue
2039 to enter commands and have a valid context to be in.
2040
2041 =cut
2042
2043         elsif ( $package eq 'DB::fake' ) {
2044
2045             # Fallen off the end already.
2046             $term || &setterm;
2047             print_help(<<EOP);
2048 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2049   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2050   B<h q>, B<h R> or B<h o> to get additional info.
2051 EOP
2052
2053             # Set the DB::eval context appropriately.
2054             $package     = 'main';
2055             $usercontext =
2056                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2057               . "package $package;";    # this won't let them modify, alas
2058         } ## end elsif ($package eq 'DB::fake')
2059
2060 =pod
2061
2062 If the program hasn't finished executing, we scan forward to the
2063 next executable line, print that out, build the prompt from the file and line
2064 number information, and print that.
2065
2066 =cut
2067
2068         else {
2069
2070             # Still somewhere in the midst of execution. Set up the
2071             #  debugger prompt.
2072             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2073                                  # Perl 5 ones (sorry, we don't print Klingon
2074                                  #module names)
2075
2076             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2077             $prefix .= "$sub($filename:";
2078             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2079
2080             # Break up the prompt if it's really long.
2081             if ( length($prefix) > 30 ) {
2082                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2083                 $prefix   = "";
2084                 $infix    = ":\t";
2085             }
2086             else {
2087                 $infix    = "):\t";
2088                 $position = "$prefix$line$infix$dbline[$line]$after";
2089             }
2090
2091             # Print current line info, indenting if necessary.
2092             if ($frame) {
2093                 print_lineinfo( ' ' x $stack_depth,
2094                     "$line:\t$dbline[$line]$after" );
2095             }
2096             else {
2097                 print_lineinfo($position);
2098             }
2099
2100             # Scan forward, stopping at either the end or the next
2101             # unbreakable line.
2102             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2103             {    #{ vi
2104
2105                 # Drop out on null statements, block closers, and comments.
2106                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2107
2108                 # Drop out if the user interrupted us.
2109                 last if $signal;
2110
2111                 # Append a newline if the line doesn't have one. Can happen
2112                 # in eval'ed text, for instance.
2113                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2114
2115                 # Next executable line.
2116                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2117                 $position .= $incr_pos;
2118                 if ($frame) {
2119
2120                     # Print it indented if tracing is on.
2121                     print_lineinfo( ' ' x $stack_depth,
2122                         "$i:\t$dbline[$i]$after" );
2123                 }
2124                 else {
2125                     print_lineinfo($incr_pos);
2126                 }
2127             } ## end for ($i = $line + 1 ; $i...
2128         } ## end else [ if ($slave_editor)
2129     } ## end if ($single || ($trace...
2130
2131 =pod
2132
2133 If there's an action to be executed for the line we stopped at, execute it.
2134 If there are any preprompt actions, execute those as well.
2135
2136 =cut
2137
2138     # If there's an action, do it now.
2139     $evalarg = $action, &eval if $action;
2140
2141     # Are we nested another level (e.g., did we evaluate a function
2142     # that had a breakpoint in it at the debugger prompt)?
2143     if ( $single || $was_signal ) {
2144
2145         # Yes, go down a level.
2146         local $level = $level + 1;
2147
2148         # Do any pre-prompt actions.
2149         foreach $evalarg (@$pre) {
2150             &eval;
2151         }
2152
2153         # Complain about too much recursion if we passed the limit.
2154         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2155           if $single & 4;
2156
2157         # The line we're currently on. Set $incr to -1 to stay here
2158         # until we get a command that tells us to advance.
2159         $start = $line;
2160         $incr  = -1;      # for backward motion.
2161
2162         # Tack preprompt debugger actions ahead of any actual input.
2163         @typeahead = ( @$pretype, @typeahead );
2164
2165 =head2 WHERE ARE WE?
2166
2167 XXX Relocate this section?
2168
2169 The debugger normally shows the line corresponding to the current line of
2170 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2171 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2172
2173 C<$incr> controls by how many lines the I<current> line should move forward
2174 after a command is executed. If set to -1, this indicates that the I<current>
2175 line shouldn't change.
2176
2177 C<$start> is the I<current> line. It is used for things like knowing where to
2178 move forwards or backwards from when doing an C<L> or C<-> command.
2179
2180 C<$max> tells the debugger where the last line of the current file is. It's
2181 used to terminate loops most often.
2182
2183 =head2 THE COMMAND LOOP
2184
2185 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2186 in two parts:
2187
2188 =over 4
2189
2190 =item *
2191
2192 The outer part of the loop, starting at the C<CMD> label. This loop
2193 reads a command and then executes it.
2194
2195 =item *
2196
2197 The inner part of the loop, starting at the C<PIPE> label. This part
2198 is wholly contained inside the C<CMD> block and only executes a command.
2199 Used to handle commands running inside a pager.
2200
2201 =back
2202
2203 So why have two labels to restart the loop? Because sometimes, it's easier to
2204 have a command I<generate> another command and then re-execute the loop to do
2205 the new command. This is faster, but perhaps a bit more convoluted.
2206
2207 =cut
2208
2209         # The big command dispatch loop. It keeps running until the
2210         # user yields up control again.
2211         #
2212         # If we have a terminal for input, and we get something back
2213         # from readline(), keep on processing.
2214       CMD:
2215         while (
2216
2217             # We have a terminal, or can get one ...
2218             ( $term || &setterm ),
2219
2220             # ... and it belogs to this PID or we get one for this PID ...
2221             ( $term_pid == $$ or resetterm(1) ),
2222
2223             # ... and we got a line of command input ...
2224             defined(
2225                 $cmd = &readline(
2226                         "$pidprompt $tid DB"
2227                       . ( '<' x $level )
2228                       . ( $#hist + 1 )
2229                       . ( '>' x $level ) . " "
2230                 )
2231             )
2232           )
2233         {
2234
2235                         share($cmd);
2236             # ... try to execute the input as debugger commands.
2237
2238             # Don't stop running.
2239             $single = 0;
2240
2241             # No signal is active.
2242             $signal = 0;
2243
2244             # Handle continued commands (ending with \):
2245             $cmd =~ s/\\$/\n/ && do {
2246                 $cmd .= &readline("  cont: ");
2247                 redo CMD;
2248             };
2249
2250 =head4 The null command
2251
2252 A newline entered by itself means I<re-execute the last command>. We grab the
2253 command out of C<$laststep> (where it was recorded previously), and copy it
2254 back into C<$cmd> to be executed below. If there wasn't any previous command,
2255 we'll do nothing below (no command will match). If there was, we also save it
2256 in the command history and fall through to allow the command parsing to pick
2257 it up.
2258
2259 =cut
2260
2261             # Empty input means repeat the last command.
2262             $cmd =~ /^$/ && ( $cmd = $laststep );
2263             chomp($cmd);    # get rid of the annoying extra newline
2264             push( @hist, $cmd ) if length($cmd) > 1;
2265             push( @truehist, $cmd );
2266                         share(@hist);
2267                         share(@truehist);
2268
2269             # This is a restart point for commands that didn't arrive
2270             # via direct user input. It allows us to 'redo PIPE' to
2271             # re-execute command processing without reading a new command.
2272           PIPE: {
2273                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2274                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2275                 ($i) = split( /\s+/, $cmd );
2276
2277 =head3 COMMAND ALIASES
2278
2279 The debugger can create aliases for commands (these are stored in the
2280 C<%alias> hash). Before a command is executed, the command loop looks it up
2281 in the alias hash and substitutes the contents of the alias for the command,
2282 completely replacing it.
2283
2284 =cut
2285
2286                 # See if there's an alias for the command, and set it up if so.
2287                 if ( $alias{$i} ) {
2288
2289                     # Squelch signal handling; we want to keep control here
2290                     # if something goes loco during the alias eval.
2291                     local $SIG{__DIE__};
2292                     local $SIG{__WARN__};
2293
2294                     # This is a command, so we eval it in the DEBUGGER's
2295                     # scope! Otherwise, we can't see the special debugger
2296                     # variables, or get to the debugger's subs. (Well, we
2297                     # _could_, but why make it even more complicated?)
2298                     eval "\$cmd =~ $alias{$i}";
2299                     if ($@) {
2300                         local $\ = '';
2301                         print $OUT "Couldn't evaluate `$i' alias: $@";
2302                         next CMD;
2303                     }
2304                 } ## end if ($alias{$i})
2305
2306 =head3 MAIN-LINE COMMANDS
2307
2308 All of these commands work up to and after the program being debugged has
2309 terminated.
2310
2311 =head4 C<q> - quit
2312
2313 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2314 try to execute further, cleaning any restart-related stuff out of the
2315 environment, and executing with the last value of C<$?>.
2316
2317 =cut
2318
2319                 $cmd =~ /^q$/ && do {
2320                     $fall_off_end = 1;
2321                     clean_ENV();
2322                     exit $?;
2323                 };
2324
2325 =head4 C<t> - trace
2326
2327 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2328
2329 =cut
2330
2331                 $cmd =~ /^t$/ && do {
2332                     $trace ^= 1;
2333                     local $\ = '';
2334                     print $OUT "Trace = "
2335                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2336                     next CMD;
2337                 };
2338
2339 =head4 C<S> - list subroutines matching/not matching a pattern
2340
2341 Walks through C<%sub>, checking to see whether or not to print the name.
2342
2343 =cut
2344
2345                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2346
2347                     $Srev     = defined $2;     # Reverse scan?
2348                     $Spatt    = $3;             # The pattern (if any) to use.
2349                     $Snocheck = !defined $1;    # No args - print all subs.
2350
2351                     # Need to make these sane here.
2352                     local $\ = '';
2353                     local $, = '';
2354
2355                     # Search through the debugger's magical hash of subs.
2356                     # If $nocheck is true, just print the sub name.
2357                     # Otherwise, check it against the pattern. We then use
2358                     # the XOR trick to reverse the condition as required.
2359                     foreach $subname ( sort( keys %sub ) ) {
2360                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2361                             print $OUT $subname, "\n";
2362                         }
2363                     }
2364                     next CMD;
2365                 };
2366
2367 =head4 C<X> - list variables in current package
2368
2369 Since the C<V> command actually processes this, just change this to the
2370 appropriate C<V> command and fall through.
2371
2372 =cut
2373
2374                 $cmd =~ s/^X\b/V $package/;
2375
2376 =head4 C<V> - list variables
2377
2378 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2379
2380 =cut
2381
2382                 # Bare V commands get the currently-being-debugged package
2383                 # added.
2384                 $cmd =~ /^V$/ && do {
2385                     $cmd = "V $package";
2386                 };
2387
2388                 # V - show variables in package.
2389                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2390
2391                     # Save the currently selected filehandle and
2392                     # force output to debugger's filehandle (dumpvar
2393                     # just does "print" for output).
2394                     local ($savout) = select($OUT);
2395
2396                     # Grab package name and variables to dump.
2397                     $packname = $1;
2398                     @vars     = split( ' ', $2 );
2399
2400                     # If main::dumpvar isn't here, get it.
2401                     do 'dumpvar.pl' unless defined &main::dumpvar;
2402                     if ( defined &main::dumpvar ) {
2403
2404                         # We got it. Turn off subroutine entry/exit messages
2405                         # for the moment, along with return values.
2406                         local $frame = 0;
2407                         local $doret = -2;
2408
2409                         # must detect sigpipe failures  - not catching
2410                         # then will cause the debugger to die.
2411                         eval {
2412                             &main::dumpvar(
2413                                 $packname,
2414                                 defined $option{dumpDepth}
2415                                 ? $option{dumpDepth}
2416                                 : -1,    # assume -1 unless specified
2417                                 @vars
2418                             );
2419                         };
2420
2421                         # The die doesn't need to include the $@, because
2422                         # it will automatically get propagated for us.
2423                         if ($@) {
2424                             die unless $@ =~ /dumpvar print failed/;
2425                         }
2426                     } ## end if (defined &main::dumpvar)
2427                     else {
2428
2429                         # Couldn't load dumpvar.
2430                         print $OUT "dumpvar.pl not available.\n";
2431                     }
2432
2433                     # Restore the output filehandle, and go round again.
2434                     select($savout);
2435                     next CMD;
2436                 };
2437
2438 =head4 C<x> - evaluate and print an expression
2439
2440 Hands the expression off to C<DB::eval>, setting it up to print the value
2441 via C<dumpvar.pl> instead of just printing it directly.
2442
2443 =cut
2444
2445                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2446                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2447
2448                     # handle special  "x 3 blah" syntax XXX propagate
2449                     # doc back to special variables.
2450                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2451                         $onetimedumpDepth = $1;
2452                     }
2453                 };
2454
2455 =head4 C<m> - print methods
2456
2457 Just uses C<DB::methods> to determine what methods are available.
2458
2459 =cut
2460
2461                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2462                     methods($1);
2463                     next CMD;
2464                 };
2465
2466                 # m expr - set up DB::eval to do the work
2467                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2468                     $onetimeDump = 'methods';   #  method output gets used there
2469                 };
2470
2471 =head4 C<f> - switch files
2472
2473 =cut
2474
2475                 $cmd =~ /^f\b\s*(.*)/ && do {
2476                     $file = $1;
2477                     $file =~ s/\s+$//;
2478
2479                     # help for no arguments (old-style was return from sub).
2480                     if ( !$file ) {
2481                         print $OUT
2482                           "The old f command is now the r command.\n";    # hint
2483                         print $OUT "The new f command switches filenames.\n";
2484                         next CMD;
2485                     } ## end if (!$file)
2486
2487                     # if not in magic file list, try a close match.
2488                     if ( !defined $main::{ '_<' . $file } ) {
2489                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2490                             {
2491                                 $try = substr( $try, 2 );
2492                                 print $OUT "Choosing $try matching `$file':\n";
2493                                 $file = $try;
2494                             }
2495                         } ## end if (($try) = grep(m#^_<.*$file#...
2496                     } ## end if (!defined $main::{ ...
2497
2498                     # If not successfully switched now, we failed.
2499                     if ( !defined $main::{ '_<' . $file } ) {
2500                         print $OUT "No file matching `$file' is loaded.\n";
2501                         next CMD;
2502                     }
2503
2504                     # We switched, so switch the debugger internals around.
2505                     elsif ( $file ne $filename ) {
2506                         *dbline   = $main::{ '_<' . $file };
2507                         $max      = $#dbline;
2508                         $filename = $file;
2509                         $start    = 1;
2510                         $cmd      = "l";
2511                     } ## end elsif ($file ne $filename)
2512
2513                     # We didn't switch; say we didn't.
2514                     else {
2515                         print $OUT "Already in $file.\n";
2516                         next CMD;
2517                     }
2518                 };
2519
2520 =head4 C<.> - return to last-executed line.
2521
2522 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2523 and then we look up the line in the magical C<%dbline> hash.
2524
2525 =cut
2526
2527                 # . command.
2528                 $cmd =~ /^\.$/ && do {
2529                     $incr = -1;    # stay at current line
2530
2531                     # Reset everything to the old location.
2532                     $start    = $line;
2533                     $filename = $filename_ini;
2534                     *dbline   = $main::{ '_<' . $filename };
2535                     $max      = $#dbline;
2536
2537                     # Now where are we?
2538                     print_lineinfo($position);
2539                     next CMD;
2540                 };
2541
2542 =head4 C<-> - back one window
2543
2544 We change C<$start> to be one window back; if we go back past the first line,
2545 we set it to be the first line. We ser C<$incr> to put us back at the
2546 currently-executing line, and then put a C<l $start +> (list one window from
2547 C<$start>) in C<$cmd> to be executed later.
2548
2549 =cut
2550
2551                 # - - back a window.
2552                 $cmd =~ /^-$/ && do {
2553
2554                     # back up by a window; go to 1 if back too far.
2555                     $start -= $incr + $window + 1;
2556                     $start = 1 if $start <= 0;
2557                     $incr  = $window - 1;
2558
2559                     # Generate and execute a "l +" command (handled below).
2560                     $cmd = 'l ' . ($start) . '+';
2561                 };
2562
2563 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2564
2565 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2566 problems, most notably that the default case of several commands destroying
2567 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2568 retain the old commands for those who were used to using them or who preferred
2569 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2570 deal with them instead of processing them in-line.
2571
2572 =cut
2573
2574                 # All of these commands were remapped in perl 5.8.0;
2575                 # we send them off to the secondary dispatcher (see below).
2576                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2577                     &cmd_wrapper( $1, $2, $line );
2578                     next CMD;
2579                 };
2580
2581 =head4 C<y> - List lexicals in higher scope
2582
2583 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2584 above the current one and then displays then using C<dumpvar.pl>.
2585
2586 =cut
2587
2588                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2589
2590                     # See if we've got the necessary support.
2591                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2592                       or &warn(
2593                         $@ =~ /locate/
2594                         ? "PadWalker module not found - please install\n"
2595                         : $@
2596                       )
2597                       and next CMD;
2598
2599                     # Load up dumpvar if we don't have it. If we can, that is.
2600                     do 'dumpvar.pl' unless defined &main::dumpvar;
2601                     defined &main::dumpvar
2602                       or print $OUT "dumpvar.pl not available.\n"
2603                       and next CMD;
2604
2605                     # Got all the modules we need. Find them and print them.
2606                     my @vars = split( ' ', $2 || '' );
2607
2608                     # Find the pad.
2609                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2610
2611                     # Oops. Can't find it.
2612                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2613
2614                     # Show the desired vars with dumplex().
2615                     my $savout = select($OUT);
2616
2617                     # Have dumplex dump the lexicals.
2618                     dumpvar::dumplex( $_, $h->{$_},
2619                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2620                         @vars )
2621                       for sort keys %$h;
2622                     select($savout);
2623                     next CMD;
2624                 };
2625
2626 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2627
2628 All of the commands below this point don't work after the program being
2629 debugged has ended. All of them check to see if the program has ended; this
2630 allows the commands to be relocated without worrying about a 'line of
2631 demarcation' above which commands can be entered anytime, and below which
2632 they can't.
2633
2634 =head4 C<n> - single step, but don't trace down into subs
2635
2636 Done by setting C<$single> to 2, which forces subs to execute straight through
2637 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2638 so a null command knows what to re-execute.
2639
2640 =cut
2641
2642                 # n - next
2643                 $cmd =~ /^n$/ && do {
2644                     end_report(), next CMD if $finished and $level <= 1;
2645
2646                     # Single step, but don't enter subs.
2647                     $single = 2;
2648
2649                     # Save for empty command (repeat last).
2650                     $laststep = $cmd;
2651                     last CMD;
2652                 };
2653
2654 =head4 C<s> - single-step, entering subs
2655
2656 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2657 subs. Also saves C<s> as C<$lastcmd>.
2658
2659 =cut
2660
2661                 # s - single step.
2662                 $cmd =~ /^s$/ && do {
2663
2664                     # Get out and restart the command loop if program
2665                     # has finished.
2666                     end_report(), next CMD if $finished and $level <= 1;
2667
2668                     # Single step should enter subs.
2669                     $single = 1;
2670
2671                     # Save for empty command (repeat last).
2672                     $laststep = $cmd;
2673                     last CMD;
2674                 };
2675
2676 =head4 C<c> - run continuously, setting an optional breakpoint
2677
2678 Most of the code for this command is taken up with locating the optional
2679 breakpoint, which is either a subroutine name or a line number. We set
2680 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2681 in this and all call levels above this one.
2682
2683 =cut
2684
2685                 # c - start continuous execution.
2686                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2687
2688                     # Hey, show's over. The debugged program finished
2689                     # executing already.
2690                     end_report(), next CMD if $finished and $level <= 1;
2691
2692                     # Capture the place to put a one-time break.
2693                     $subname = $i = $1;
2694
2695                     #  Probably not needed, since we finish an interactive
2696                     #  sub-session anyway...
2697                     # local $filename = $filename;
2698                     # local *dbline = *dbline; # XXX Would this work?!
2699                     #
2700                     # The above question wonders if localizing the alias
2701                     # to the magic array works or not. Since it's commented
2702                     # out, we'll just leave that to speculation for now.
2703
2704                     # If the "subname" isn't all digits, we'll assume it
2705                     # is a subroutine name, and try to find it.
2706                     if ( $subname =~ /\D/ ) {    # subroutine name
2707                             # Qualify it to the current package unless it's
2708                             # already qualified.
2709                         $subname = $package . "::" . $subname
2710                           unless $subname =~ /::/;
2711
2712                         # find_sub will return "file:line_number" corresponding
2713                         # to where the subroutine is defined; we call find_sub,
2714                         # break up the return value, and assign it in one
2715                         # operation.
2716                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2717
2718                         # Force the line number to be numeric.
2719                         $i += 0;
2720
2721                         # If we got a line number, we found the sub.
2722                         if ($i) {
2723
2724                             # Switch all the debugger's internals around so
2725                             # we're actually working with that file.
2726                             $filename = $file;
2727                             *dbline   = $main::{ '_<' . $filename };
2728
2729                             # Mark that there's a breakpoint in this file.
2730                             $had_breakpoints{$filename} |= 1;
2731
2732                             # Scan forward to the first executable line
2733                             # after the 'sub whatever' line.
2734                             $max = $#dbline;
2735                             ++$i while $dbline[$i] == 0 && $i < $max;
2736                         } ## end if ($i)
2737
2738                         # We didn't find a sub by that name.
2739                         else {
2740                             print $OUT "Subroutine $subname not found.\n";
2741                             next CMD;
2742                         }
2743                     } ## end if ($subname =~ /\D/)
2744
2745                     # At this point, either the subname was all digits (an
2746                     # absolute line-break request) or we've scanned through
2747                     # the code following the definition of the sub, looking
2748                     # for an executable, which we may or may not have found.
2749                     #
2750                     # If $i (which we set $subname from) is non-zero, we
2751                     # got a request to break at some line somewhere. On
2752                     # one hand, if there wasn't any real subroutine name
2753                     # involved, this will be a request to break in the current
2754                     # file at the specified line, so we have to check to make
2755                     # sure that the line specified really is breakable.
2756                     #
2757                     # On the other hand, if there was a subname supplied, the
2758                     # preceding block has moved us to the proper file and
2759                     # location within that file, and then scanned forward
2760                     # looking for the next executable line. We have to make
2761                     # sure that one was found.
2762                     #
2763                     # On the gripping hand, we can't do anything unless the
2764                     # current value of $i points to a valid breakable line.
2765                     # Check that.
2766                     if ($i) {
2767
2768                         # Breakable?
2769                         if ( $dbline[$i] == 0 ) {
2770                             print $OUT "Line $i not breakable.\n";
2771                             next CMD;
2772                         }
2773
2774                         # Yes. Set up the one-time-break sigil.
2775                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2776                     } ## end if ($i)
2777
2778                     # Turn off stack tracing from here up.
2779                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2780                         $stack[ $i++ ] &= ~1;
2781                     }
2782                     last CMD;
2783                 };
2784
2785 =head4 C<r> - return from a subroutine
2786
2787 For C<r> to work properly, the debugger has to stop execution again
2788 immediately after the return is executed. This is done by forcing
2789 single-stepping to be on in the call level above the current one. If
2790 we are printing return values when a C<r> is executed, set C<$doret>
2791 appropriately, and force us out of the command loop.
2792
2793 =cut
2794
2795                 # r - return from the current subroutine.
2796                 $cmd =~ /^r$/ && do {
2797
2798                     # Can't do anythign if the program's over.
2799                     end_report(), next CMD if $finished and $level <= 1;
2800
2801                     # Turn on stack trace.
2802                     $stack[$stack_depth] |= 1;
2803
2804                     # Print return value unless the stack is empty.
2805                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2806                     last CMD;
2807                 };
2808
2809 =head4 C<T> - stack trace
2810
2811 Just calls C<DB::print_trace>.
2812
2813 =cut
2814
2815                 $cmd =~ /^T$/ && do {
2816                     print_trace( $OUT, 1 );    # skip DB
2817                     next CMD;
2818                 };
2819
2820 =head4 C<w> - List window around current line.
2821
2822 Just calls C<DB::cmd_w>.
2823
2824 =cut
2825
2826                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2827
2828 =head4 C<W> - watch-expression processing.
2829
2830 Just calls C<DB::cmd_W>.
2831
2832 =cut
2833
2834                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2835
2836 =head4 C</> - search forward for a string in the source
2837
2838 We take the argument and treat it as a pattern. If it turns out to be a
2839 bad one, we return the error we got from trying to C<eval> it and exit.
2840 If not, we create some code to do the search and C<eval> it so it can't
2841 mess us up.
2842
2843 =cut
2844
2845                 $cmd =~ /^\/(.*)$/ && do {
2846
2847                     # The pattern as a string.
2848                     $inpat = $1;
2849
2850                     # Remove the final slash.
2851                     $inpat =~ s:([^\\])/$:$1:;
2852
2853                     # If the pattern isn't null ...
2854                     if ( $inpat ne "" ) {
2855
2856                         # Turn of warn and die procesing for a bit.
2857                         local $SIG{__DIE__};
2858                         local $SIG{__WARN__};
2859
2860                         # Create the pattern.
2861                         eval '$inpat =~ m' . "\a$inpat\a";
2862                         if ( $@ ne "" ) {
2863
2864                             # Oops. Bad pattern. No biscuit.
2865                             # Print the eval error and go back for more
2866                             # commands.
2867                             print $OUT "$@";
2868                             next CMD;
2869                         }
2870                         $pat = $inpat;
2871                     } ## end if ($inpat ne "")
2872
2873                     # Set up to stop on wrap-around.
2874                     $end = $start;
2875
2876                     # Don't move off the current line.
2877                     $incr = -1;
2878
2879                     # Done in eval so nothing breaks if the pattern
2880                     # does something weird.
2881                     eval '
2882                         for (;;) {
2883                             # Move ahead one line.
2884                             ++$start;
2885
2886                             # Wrap if we pass the last line.
2887                             $start = 1 if ($start > $max);
2888
2889                             # Stop if we have gotten back to this line again,
2890                             last if ($start == $end);
2891
2892                             # A hit! (Note, though, that we are doing
2893                             # case-insensitive matching. Maybe a qr//
2894                             # expression would be better, so the user could
2895                             # do case-sensitive matching if desired.
2896                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2897                                 if ($slave_editor) {
2898                                     # Handle proper escaping in the slave.
2899                                     print $OUT "\032\032$filename:$start:0\n";
2900                                 }
2901                                 else {
2902                                     # Just print the line normally.
2903                                     print $OUT "$start:\t",$dbline[$start],"\n";
2904                                 }
2905                                 # And quit since we found something.
2906                                 last;
2907                             }
2908                          } ';
2909
2910                     # If we wrapped, there never was a match.
2911                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2912                     next CMD;
2913                 };
2914
2915 =head4 C<?> - search backward for a string in the source
2916
2917 Same as for C</>, except the loop runs backwards.
2918
2919 =cut
2920
2921                 # ? - backward pattern search.
2922                 $cmd =~ /^\?(.*)$/ && do {
2923
2924                     # Get the pattern, remove trailing question mark.
2925                     $inpat = $1;
2926                     $inpat =~ s:([^\\])\?$:$1:;
2927
2928                     # If we've got one ...
2929                     if ( $inpat ne "" ) {
2930
2931                         # Turn off die & warn handlers.
2932                         local $SIG{__DIE__};
2933                         local $SIG{__WARN__};
2934                         eval '$inpat =~ m' . "\a$inpat\a";
2935
2936                         if ( $@ ne "" ) {
2937
2938                             # Ouch. Not good. Print the error.
2939                             print $OUT $@;
2940                             next CMD;
2941                         }
2942                         $pat = $inpat;
2943                     } ## end if ($inpat ne "")
2944
2945                     # Where we are now is where to stop after wraparound.
2946                     $end = $start;
2947
2948                     # Don't move away from this line.
2949                     $incr = -1;
2950
2951                     # Search inside the eval to prevent pattern badness
2952                     # from killing us.
2953                     eval '
2954                         for (;;) {
2955                             # Back up a line.
2956                             --$start;
2957
2958                             # Wrap if we pass the first line.
2959
2960                             $start = $max if ($start <= 0);
2961
2962                             # Quit if we get back where we started,
2963                             last if ($start == $end);
2964
2965                             # Match?
2966                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2967                                 if ($slave_editor) {
2968                                     # Yep, follow slave editor requirements.
2969                                     print $OUT "\032\032$filename:$start:0\n";
2970                                 }
2971                                 else {
2972                                     # Yep, just print normally.
2973                                     print $OUT "$start:\t",$dbline[$start],"\n";
2974                                 }
2975
2976                                 # Found, so done.
2977                                 last;
2978                             }
2979                         } ';
2980
2981                     # Say we failed if the loop never found anything,
2982                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2983                     next CMD;
2984                 };
2985
2986 =head4 C<$rc> - Recall command
2987
2988 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2989 that the terminal supports history). It find the the command required, puts it
2990 into C<$cmd>, and redoes the loop to execute it.
2991
2992 =cut
2993
2994                 # $rc - recall command.
2995                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2996
2997                     # No arguments, take one thing off history.
2998                     pop(@hist) if length($cmd) > 1;
2999
3000                     # Relative (- found)?
3001                     #  Y - index back from most recent (by 1 if bare minus)
3002                     #  N - go to that particular command slot or the last
3003                     #      thing if nothing following.
3004                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3005
3006                     # Pick out the command desired.
3007                     $cmd = $hist[$i];
3008
3009                     # Print the command to be executed and restart the loop
3010                     # with that command in the buffer.
3011                     print $OUT $cmd, "\n";
3012                     redo CMD;
3013                 };
3014
3015 =head4 C<$sh$sh> - C<system()> command
3016
3017 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3018 C<STDOUT> from getting messed up.
3019
3020 =cut
3021
3022                 # $sh$sh - run a shell command (if it's all ASCII).
3023                 # Can't run shell commands with Unicode in the debugger, hmm.
3024                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3025
3026                     # System it.
3027                     &system($1);
3028                     next CMD;
3029                 };
3030
3031 =head4 C<$rc I<pattern> $rc> - Search command history
3032
3033 Another command to manipulate C<@hist>: this one searches it with a pattern.
3034 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3035
3036 =cut
3037
3038                 # $rc pattern $rc - find a command in the history.
3039                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3040
3041                     # Create the pattern to use.
3042                     $pat = "^$1";
3043
3044                     # Toss off last entry if length is >1 (and it always is).
3045                     pop(@hist) if length($cmd) > 1;
3046
3047                     # Look backward through the history.
3048                     for ( $i = $#hist ; $i ; --$i ) {
3049
3050                         # Stop if we find it.
3051                         last if $hist[$i] =~ /$pat/;
3052                     }
3053
3054                     if ( !$i ) {
3055
3056                         # Never found it.
3057                         print $OUT "No such command!\n\n";
3058                         next CMD;
3059                     }
3060
3061                     # Found it. Put it in the buffer, print it, and process it.
3062                     $cmd = $hist[$i];
3063                     print $OUT $cmd, "\n";
3064                     redo CMD;
3065                 };
3066
3067 =head4 C<$sh> - Invoke a shell
3068
3069 Uses C<DB::system> to invoke a shell.
3070
3071 =cut
3072
3073                 # $sh - start a shell.
3074                 $cmd =~ /^$sh$/ && do {
3075
3076                     # Run the user's shell. If none defined, run Bourne.
3077                     # We resume execution when the shell terminates.
3078                     &system( $ENV{SHELL} || "/bin/sh" );
3079                     next CMD;
3080                 };
3081
3082 =head4 C<$sh I<command>> - Force execution of a command in a shell
3083
3084 Like the above, but the command is passed to the shell. Again, we use
3085 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3086
3087 =cut
3088
3089                 # $sh command - start a shell and run a command in it.
3090                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3091
3092                     # XXX: using csh or tcsh destroys sigint retvals!
3093                     #&system($1);  # use this instead
3094
3095                     # use the user's shell, or Bourne if none defined.
3096                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3097                     next CMD;
3098                 };
3099
3100 =head4 C<H> - display commands in history
3101
3102 Prints the contents of C<@hist> (if any).
3103
3104 =cut
3105
3106                 $cmd =~ /^H\b\s*\*/ && do {
3107                     @hist = @truehist = ();
3108                     print $OUT "History cleansed\n";
3109                     next CMD;
3110                 };
3111
3112                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3113
3114                     # Anything other than negative numbers is ignored by
3115                     # the (incorrect) pattern, so this test does nothing.
3116                     $end = $2 ? ( $#hist - $2 ) : 0;
3117
3118                     # Set to the minimum if less than zero.
3119                     $hist = 0 if $hist < 0;
3120
3121                     # Start at the end of the array.
3122                     # Stay in while we're still above the ending value.
3123                     # Tick back by one each time around the loop.
3124                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3125
3126                         # Print the command  unless it has no arguments.
3127                         print $OUT "$i: ", $hist[$i], "\n"
3128                           unless $hist[$i] =~ /^.?$/;
3129                     }
3130                     next CMD;
3131                 };
3132
3133 =head4 C<man, doc, perldoc> - look up documentation
3134
3135 Just calls C<runman()> to print the appropriate document.
3136
3137 =cut
3138
3139                 # man, perldoc, doc - show manual pages.
3140                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3141                     runman($1);
3142                     next CMD;
3143                 };
3144
3145 =head4 C<p> - print
3146
3147 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3148 the bottom of the loop.
3149
3150 =cut
3151
3152                 # p - print (no args): print $_.
3153                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3154
3155                 # p - print the given expression.
3156                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3157
3158 =head4 C<=> - define command alias
3159
3160 Manipulates C<%alias> to add or list command aliases.
3161
3162 =cut
3163
3164                 # = - set up a command alias.
3165                 $cmd =~ s/^=\s*// && do {
3166                     my @keys;
3167                     if ( length $cmd == 0 ) {
3168
3169                         # No args, get current aliases.
3170                         @keys = sort keys %alias;
3171                     }
3172                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3173
3174                         # Creating a new alias. $k is alias name, $v is
3175                         # alias value.
3176
3177                         # can't use $_ or kill //g state
3178                         for my $x ( $k, $v ) {
3179
3180                             # Escape "alarm" characters.
3181                             $x =~ s/\a/\\a/g;
3182                         }
3183
3184                         # Substitute key for value, using alarm chars
3185                         # as separators (which is why we escaped them in
3186                         # the command).
3187                         $alias{$k} = "s\a$k\a$v\a";
3188
3189                         # Turn off standard warn and die behavior.
3190                         local $SIG{__DIE__};
3191                         local $SIG{__WARN__};
3192
3193                         # Is it valid Perl?
3194                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3195
3196                             # Nope. Bad alias. Say so and get out.
3197                             print $OUT "Can't alias $k to $v: $@\n";
3198                             delete $alias{$k};
3199                             next CMD;
3200                         }
3201
3202                         # We'll only list the new one.
3203                         @keys = ($k);
3204                     } ## end elsif (my ($k, $v) = ($cmd...
3205
3206                     # The argument is the alias to list.
3207                     else {
3208                         @keys = ($cmd);
3209                     }
3210
3211                     # List aliases.
3212                     for my $k (@keys) {
3213
3214                         # Messy metaquoting: Trim the substiution code off.
3215                         # We use control-G as the delimiter because it's not
3216                         # likely to appear in the alias.
3217                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3218
3219                             # Print the alias.
3220                             print $OUT "$k\t= $1\n";
3221                         }
3222                         elsif ( defined $alias{$k} ) {
3223
3224                             # Couldn't trim it off; just print the alias code.
3225                             print $OUT "$k\t$alias{$k}\n";
3226                         }
3227                         else {
3228
3229                             # No such, dude.
3230                             print "No alias for $k\n";
3231                         }
3232                     } ## end for my $k (@keys)
3233                     next CMD;
3234                 };
3235
3236 =head4 C<source> - read commands from a file.
3237
3238 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3239 pick it up.
3240
3241 =cut
3242
3243                 # source - read commands from a file (or pipe!) and execute.
3244                 $cmd =~ /^source\s+(.*\S)/ && do {
3245                     if ( open my $fh, $1 ) {
3246
3247                         # Opened OK; stick it in the list of file handles.
3248                         push @cmdfhs, $fh;
3249                     }
3250                     else {
3251
3252                         # Couldn't open it.
3253                         &warn("Can't execute `$1': $!\n");
3254                     }
3255                     next CMD;
3256                 };
3257
3258 =head4 C<save> - send current history to a file
3259
3260 Takes the complete history, (not the shrunken version you see with C<H>),
3261 and saves it to the given filename, so it can be replayed using C<source>.
3262
3263 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3264
3265 =cut
3266
3267                 # save source - write commands to a file for later use
3268                 $cmd =~ /^save\s*(.*)$/ && do {
3269                     my $file = $1 || '.perl5dbrc';    # default?
3270                     if ( open my $fh, "> $file" ) {
3271
3272                        # chomp to remove extraneous newlines from source'd files
3273                         chomp( my @truelist =
3274                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3275                               @truehist );
3276                         print $fh join( "\n", @truelist );
3277                         print "commands saved in $file\n";
3278                     }
3279                     else {
3280                         &warn("Can't save debugger commands in '$1': $!\n");
3281                     }
3282                     next CMD;
3283                 };
3284
3285 =head4 C<R> - restart
3286
3287 Restart the debugger session.
3288
3289 =head4 C<rerun> - rerun the current session
3290
3291 Return to any given position in the B<true>-history list
3292
3293 =cut
3294
3295                 # R - restart execution.
3296                 # rerun - controlled restart execution.
3297                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3298                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3299
3300                     # Close all non-system fds for a clean restart.  A more
3301                     # correct method would be to close all fds that were not
3302                     # open when the process started, but this seems to be
3303                     # hard.  See "debugger 'R'estart and open database
3304                     # connections" on p5p.
3305
3306                     my $max_fd = 1024; # default if POSIX can't be loaded
3307                     if (eval { require POSIX }) {
3308                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3309                     }
3310
3311                     if (defined $max_fd) {
3312                         foreach ($^F+1 .. $max_fd-1) {
3313                             next unless open FD_TO_CLOSE, "<&=$_";
3314                             close(FD_TO_CLOSE);
3315                         }
3316                     }
3317
3318                     # And run Perl again.  We use exec() to keep the
3319                     # PID stable (and that way $ini_pids is still valid).
3320                     exec(@args) || print $OUT "exec failed: $!\n";
3321
3322                     last CMD;
3323                 };
3324
3325 =head4 C<|, ||> - pipe output through the pager.
3326
3327 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3328 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3329 pipe to the pager (restoring the output filehandles if this fails). If this
3330 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3331 set C<$signal>, sending us back into the debugger.
3332
3333 We then trim off the pipe symbols and C<redo> the command loop at the
3334 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3335 reading another.
3336
3337 =cut
3338
3339                 # || - run command in the pager, with output to DB::OUT.
3340                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3341                     if ( $pager =~ /^\|/ ) {
3342
3343                         # Default pager is into a pipe. Redirect I/O.
3344                         open( SAVEOUT, ">&STDOUT" )
3345                           || &warn("Can't save STDOUT");
3346                         open( STDOUT, ">&OUT" )
3347                           || &warn("Can't redirect STDOUT");
3348                     } ## end if ($pager =~ /^\|/)
3349                     else {
3350
3351                         # Not into a pipe. STDOUT is safe.
3352                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3353                     }
3354
3355                     # Fix up environment to record we have less if so.
3356                     fix_less();
3357
3358                     unless ( $piped = open( OUT, $pager ) ) {
3359
3360                         # Couldn't open pipe to pager.
3361                         &warn("Can't pipe output to `$pager'");
3362                         if ( $pager =~ /^\|/ ) {
3363
3364                             # Redirect I/O back again.
3365                             open( OUT, ">&STDOUT" )    # XXX: lost message
3366                               || &warn("Can't restore DB::OUT");
3367                             open( STDOUT, ">&SAVEOUT" )
3368                               || &warn("Can't restore STDOUT");
3369                             close(SAVEOUT);
3370                         } ## end if ($pager =~ /^\|/)
3371                         else {
3372
3373                             # Redirect I/O. STDOUT already safe.
3374                             open( OUT, ">&STDOUT" )    # XXX: lost message
3375                               || &warn("Can't restore DB::OUT");
3376                         }
3377                         next CMD;
3378                     } ## end unless ($piped = open(OUT,...
3379
3380                     # Set up broken-pipe handler if necessary.
3381                     $SIG{PIPE} = \&DB::catch
3382                       if $pager =~ /^\|/
3383                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3384
3385                     # Save current filehandle, unbuffer out, and put it back.
3386                     $selected = select(OUT);
3387                     $|        = 1;
3388
3389                     # Don't put it back if pager was a pipe.
3390                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3391
3392                     # Trim off the pipe symbols and run the command now.
3393                     $cmd =~ s/^\|+\s*//;
3394                     redo PIPE;
3395                 };
3396
3397 =head3 END OF COMMAND PARSING
3398
3399 Anything left in C<$cmd> at this point is a Perl expression that we want to
3400 evaluate. We'll always evaluate in the user's context, and fully qualify
3401 any variables we might want to address in the C<DB> package.
3402
3403 =cut
3404
3405                 # t - turn trace on.
3406                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3407
3408                 # s - single-step. Remember the last command was 's'.
3409                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3410
3411                 # n - single-step, but not into subs. Remember last command
3412                 # was 'n'.
3413                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3414
3415             }    # PIPE:
3416
3417             # Make sure the flag that says "the debugger's running" is
3418             # still on, to make sure we get control again.
3419             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3420
3421             # Run *our* eval that executes in the caller's context.
3422             &eval;
3423
3424             # Turn off the one-time-dump stuff now.
3425             if ($onetimeDump) {
3426                 $onetimeDump      = undef;
3427                 $onetimedumpDepth = undef;
3428             }
3429             elsif ( $term_pid == $$ ) {
3430                 STDOUT->flush();
3431                 STDERR->flush();
3432
3433                 # XXX If this is the master pid, print a newline.
3434                 print $OUT "\n";
3435             }
3436         } ## end while (($term || &setterm...
3437
3438 =head3 POST-COMMAND PROCESSING
3439
3440 After each command, we check to see if the command output was piped anywhere.
3441 If so, we go through the necessary code to unhook the pipe and go back to
3442 our standard filehandles for input and output.
3443
3444 =cut
3445
3446         continue {    # CMD:
3447
3448             # At the end of every command:
3449             if ($piped) {
3450
3451                 # Unhook the pipe mechanism now.
3452                 if ( $pager =~ /^\|/ ) {
3453
3454                     # No error from the child.
3455                     $? = 0;
3456
3457                     # we cannot warn here: the handle is missing --tchrist
3458                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3459
3460                     # most of the $? crud was coping with broken cshisms
3461                     # $? is explicitly set to 0, so this never runs.
3462                     if ($?) {
3463                         print SAVEOUT "Pager `$pager' failed: ";
3464                         if ( $? == -1 ) {
3465                             print SAVEOUT "shell returned -1\n";
3466                         }
3467                         elsif ( $? >> 8 ) {
3468                             print SAVEOUT ( $? & 127 )
3469                               ? " (SIG#" . ( $? & 127 ) . ")"
3470                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3471                         }
3472                         else {
3473                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3474                         }
3475                     } ## end if ($?)
3476
3477                     # Reopen filehandle for our output (if we can) and
3478                     # restore STDOUT (if we can).
3479                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3480                     open( STDOUT, ">&SAVEOUT" )
3481                       || &warn("Can't restore STDOUT");
3482
3483                     # Turn off pipe exception handler if necessary.
3484                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3485
3486                     # Will stop ignoring SIGPIPE if done like nohup(1)
3487                     # does SIGINT but Perl doesn't give us a choice.
3488                 } ## end if ($pager =~ /^\|/)
3489                 else {
3490
3491                     # Non-piped "pager". Just restore STDOUT.
3492                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3493                 }
3494
3495                 # Close filehandle pager was using, restore the normal one
3496                 # if necessary,
3497                 close(SAVEOUT);
3498                 select($selected), $selected = "" unless $selected eq "";
3499
3500                 # No pipes now.
3501                 $piped = "";
3502             } ## end if ($piped)
3503         }    # CMD:
3504
3505 =head3 COMMAND LOOP TERMINATION
3506
3507 When commands have finished executing, we come here. If the user closed the
3508 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3509 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3510 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3511 The interpreter will then execute the next line and then return control to us
3512 again.
3513
3514 =cut
3515
3516         # No more commands? Quit.
3517         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3518
3519         # Evaluate post-prompt commands.
3520         foreach $evalarg (@$post) {
3521             &eval;
3522         }
3523     }    # if ($single || $signal)
3524
3525     # Put the user's globals back where you found them.
3526     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3527     ();
3528 } ## end sub DB
3529
3530 # The following code may be executed now:
3531 # BEGIN {warn 4}
3532
3533 =head2 sub
3534
3535 C<sub> is called whenever a subroutine call happens in the program being
3536 debugged. The variable C<$DB::sub> contains the name of the subroutine
3537 being called.
3538
3539 The core function of this subroutine is to actually call the sub in the proper
3540 context, capturing its output. This of course causes C<DB::DB> to get called
3541 again, repeating until the subroutine ends and returns control to C<DB::sub>
3542 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3543 return value, and returns its captured copy of the return value as its own
3544 return value. The value then feeds back into the program being debugged as if
3545 C<DB::sub> hadn't been there at all.
3546
3547 C<sub> does all the work of printing the subroutine entry and exit messages
3548 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3549 and also prints the return value if needed (for the C<r> command and if
3550 the 16 bit is set in C<$frame>).
3551
3552 It also tracks the subroutine call depth by saving the current setting of
3553 C<$single> in the C<@stack> package global; if this exceeds the value in
3554 C<$deep>, C<sub> automatically turns on printing of the current depth by
3555 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3556 of stop/don't stop on entry to subs set as it currently is set.
3557
3558 =head3 C<caller()> support
3559
3560 If C<caller()> is called from the package C<DB>, it provides some
3561 additional data, in the following order:
3562
3563 =over 4
3564
3565 =item * C<$package>
3566
3567 The package name the sub was in
3568
3569 =item * C<$filename>
3570
3571 The filename it was defined in
3572
3573 =item * C<$line>
3574
3575 The line number it was defined on
3576
3577 =item * C<$subroutine>
3578
3579 The subroutine name; C<(eval)> if an C<eval>().
3580
3581 =item * C<$hasargs>
3582
3583 1 if it has arguments, 0 if not
3584
3585 =item * C<$wantarray>
3586
3587 1 if array context, 0 if scalar context
3588
3589 =item * C<$evaltext>
3590
3591 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3592
3593 =item * C<$is_require>
3594
3595 frame was created by a C<use> or C<require> statement
3596
3597 =item * C<$hints>
3598
3599 pragma information; subject to change between versions
3600
3601 =item * C<$bitmask>
3602
3603 pragma information; subject to change between versions
3604
3605 =item * C<@DB::args>
3606
3607 arguments with which the subroutine was invoked
3608
3609 =back
3610
3611 =cut
3612
3613 sub sub {
3614
3615         # lock ourselves under threads
3616         lock($DBGR);
3617
3618     # Whether or not the autoloader was running, a scalar to put the
3619     # sub's return value in (if needed), and an array to put the sub's
3620     # return value in (if needed).
3621     my ( $al, $ret, @ret ) = "";
3622         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3623                 print "creating new thread\n";
3624         }
3625
3626     # If the last ten characters are C'::AUTOLOAD', note we've traced
3627     # into AUTOLOAD for $sub.
3628     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3629         $al = " for $$sub";
3630     }
3631
3632     # We stack the stack pointer and then increment it to protect us
3633     # from a situation that might unwind a whole bunch of call frames
3634     # at once. Localizing the stack pointer means that it will automatically
3635     # unwind the same amount when multiple stack frames are unwound.
3636     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3637
3638     # Expand @stack.
3639     $#stack = $stack_depth;
3640
3641     # Save current single-step setting.
3642     $stack[-1] = $single;
3643
3644     # Turn off all flags except single-stepping.
3645     $single &= 1;
3646
3647     # If we've gotten really deeply recursed, turn on the flag that will
3648     # make us stop with the 'deep recursion' message.
3649     $single |= 4 if $stack_depth == $deep;
3650
3651     # If frame messages are on ...
3652     (
3653         $frame & 4    # Extended frame entry message
3654         ? (
3655             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3656
3657             # Why -1? But it works! :-(
3658             # Because print_trace will call add 1 to it and then call
3659             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3660             # in dump_trace.
3661             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3662           )
3663         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3664
3665           # standard frame entry message
3666       )
3667       if $frame;
3668
3669     # Determine the sub's return type,and capture approppriately.
3670     if (wantarray) {
3671
3672         # Called in array context. call sub and capture output.
3673         # DB::DB will recursively get control again if appropriate; we'll come
3674         # back here when the sub is finished.
3675         if ($assertion) {
3676             $assertion = 0;
3677             eval { @ret = &$sub; };
3678             if ($@) {
3679                 print $OUT $@;
3680                 $signal = 1 unless $warnassertions;
3681             }
3682         }
3683         else {
3684             @ret = &$sub;
3685         }
3686
3687         # Pop the single-step value back off the stack.
3688         $single |= $stack[ $stack_depth-- ];
3689
3690         # Check for exit trace messages...
3691         (
3692             $frame & 4    # Extended exit message
3693             ? (
3694                 print_lineinfo( ' ' x $stack_depth, "out " ),
3695                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3696               )
3697             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3698
3699               # Standard exit message
3700           )
3701           if $frame & 2;
3702
3703         # Print the return info if we need to.
3704         if ( $doret eq $stack_depth or $frame & 16 ) {
3705
3706             # Turn off output record separator.
3707             local $\ = '';
3708             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3709
3710             # Indent if we're printing because of $frame tracing.
3711             print $fh ' ' x $stack_depth if $frame & 16;
3712
3713             # Print the return value.
3714             print $fh "list context return from $sub:\n";
3715             dumpit( $fh, \@ret );
3716
3717             # And don't print it again.
3718             $doret = -2;
3719         } ## end if ($doret eq $stack_depth...
3720             # And we have to return the return value now.
3721         @ret;
3722     } ## end if (wantarray)
3723
3724     # Scalar context.
3725     else {
3726         if ($assertion) {
3727             $assertion = 0;
3728             eval {
3729
3730                 # Save the value if it's wanted at all.
3731                 $ret = &$sub;
3732             };
3733             if ($@) {
3734                 print $OUT $@;
3735                 $signal = 1 unless $warnassertions;
3736             }
3737             $ret = undef unless defined wantarray;
3738         }
3739         else {
3740             if ( defined wantarray ) {
3741
3742                 # Save the value if it's wanted at all.
3743                 $ret = &$sub;
3744             }
3745             else {
3746
3747                 # Void return, explicitly.
3748                 &$sub;
3749                 undef $ret;
3750             }
3751         }    # if assertion
3752
3753         # Pop the single-step value off the stack.
3754         $single |= $stack[ $stack_depth-- ];
3755
3756         # If we're doing exit messages...
3757         (
3758             $frame & 4    # Extended messsages
3759             ? (
3760                 print_lineinfo( ' ' x $stack_depth, "out " ),
3761                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3762               )
3763             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3764
3765               # Standard messages
3766           )
3767           if $frame & 2;
3768
3769         # If we are supposed to show the return value... same as before.
3770         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3771             local $\ = '';
3772             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3773             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3774             print $fh (
3775                 defined wantarray
3776                 ? "scalar context return from $sub: "
3777                 : "void context return from $sub\n"
3778             );
3779             dumpit( $fh, $ret ) if defined wantarray;
3780             $doret = -2;
3781         } ## end if ($doret eq $stack_depth...
3782
3783         # Return the appropriate scalar value.
3784         $ret;
3785     } ## end else [ if (wantarray)
3786 } ## end sub sub
3787
3788 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3789
3790 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3791 Most of the changes were to systematize the command structure and to eliminate
3792 commands that threw away user input without checking.
3793
3794 The following sections describe the code added to make it easy to support
3795 multiple command sets with conflicting command names. This section is a start
3796 at unifying all command processing to make it simpler to develop commands.
3797
3798 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3799 number, and C<$dbline> (the current line) as arguments.
3800
3801 Support functions in this section which have multiple modes of failure C<die>
3802 on error; the rest simply return a false value.
3803
3804 The user-interface functions (all of the C<cmd_*> functions) just output
3805 error messages.
3806
3807 =head2 C<%set>
3808
3809 The C<%set> hash defines the mapping from command letter to subroutine
3810 name suffix.
3811
3812 C<%set> is a two-level hash, indexed by set name and then by command name.
3813 Note that trying to set the CommandSet to C<foobar> simply results in the
3814 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3815
3816 =cut
3817
3818 ### The API section
3819
3820 my %set = (    #
3821     'pre580' => {
3822         'a' => 'pre580_a',
3823         'A' => 'pre580_null',
3824         'b' => 'pre580_b',
3825         'B' => 'pre580_null',
3826         'd' => 'pre580_null',
3827         'D' => 'pre580_D',
3828         'h' => 'pre580_h',
3829         'M' => 'pre580_null',
3830         'O' => 'o',
3831         'o' => 'pre580_null',
3832         'v' => 'M',
3833         'w' => 'v',
3834         'W' => 'pre580_W',
3835     },
3836     'pre590' => {
3837         '<'  => 'pre590_prepost',
3838         '<<' => 'pre590_prepost',
3839         '>'  => 'pre590_prepost',
3840         '>>' => 'pre590_prepost',
3841         '{'  => 'pre590_prepost',
3842         '{{' => 'pre590_prepost',
3843     },
3844 );
3845
3846 =head2 C<cmd_wrapper()> (API)
3847
3848 C<cmd_wrapper()> allows the debugger to switch command sets
3849 depending on the value of the C<CommandSet> option.
3850
3851 It tries to look up the command in the C<%set> package-level I<lexical>
3852 (which means external entities can't fiddle with it) and create the name of
3853 the sub to call based on the value found in the hash (if it's there). I<All>
3854 of the commands to be handled in a set have to be added to C<%set>; if they
3855 aren't found, the 5.8.0 equivalent is called (if there is one).
3856
3857 This code uses symbolic references.
3858
3859 =cut
3860
3861 sub cmd_wrapper {
3862     my $cmd      = shift;
3863     my $line     = shift;
3864     my $dblineno = shift;
3865
3866     # Assemble the command subroutine's name by looking up the
3867     # command set and command name in %set. If we can't find it,
3868     # default to the older version of the command.
3869     my $call = 'cmd_'
3870       . ( $set{$CommandSet}{$cmd}
3871           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3872
3873     # Call the command subroutine, call it by name.
3874     return &$call( $cmd, $line, $dblineno );
3875 } ## end sub cmd_wrapper
3876
3877 =head3 C<cmd_a> (command)
3878
3879 The C<a> command handles pre-execution actions. These are associated with a
3880 particular line, so they're stored in C<%dbline>. We default to the current
3881 line if none is specified.
3882
3883 =cut
3884
3885 sub cmd_a {
3886     my $cmd    = shift;
3887     my $line   = shift || '';    # [.|line] expr
3888     my $dbline = shift;
3889
3890     # If it's dot (here), or not all digits,  use the current line.
3891     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3892
3893     # Should be a line number followed by an expression.
3894     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3895         my ( $lineno, $expr ) = ( $1, $2 );
3896
3897         # If we have an expression ...
3898         if ( length $expr ) {
3899
3900             # ... but the line isn't breakable, complain.
3901             if ( $dbline[$lineno] == 0 ) {
3902                 print $OUT
3903                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3904             }
3905             else {
3906
3907                 # It's executable. Record that the line has an action.
3908                 $had_breakpoints{$filename} |= 2;
3909
3910                 # Remove any action, temp breakpoint, etc.
3911                 $dbline{$lineno} =~ s/\0[^\0]*//;
3912
3913                 # Add the action to the line.
3914                 $dbline{$lineno} .= "\0" . action($expr);
3915             }
3916         } ## end if (length $expr)
3917     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3918     else {
3919
3920         # Syntax wrong.
3921         print $OUT
3922           "Adding an action requires an optional lineno and an expression\n"
3923           ;    # hint
3924     }
3925 } ## end sub cmd_a
3926
3927 =head3 C<cmd_A> (command)
3928
3929 Delete actions. Similar to above, except the delete code is in a separate
3930 subroutine, C<delete_action>.
3931
3932 =cut
3933
3934 sub cmd_A {
3935     my $cmd    = shift;
3936     my $line   = shift || '';
3937     my $dbline = shift;
3938
3939     # Dot is this line.
3940     $line =~ s/^\./$dbline/;
3941
3942     # Call delete_action with a null param to delete them all.
3943     # The '1' forces the eval to be true. It'll be false only
3944     # if delete_action blows up for some reason, in which case
3945     # we print $@ and get out.
3946     if ( $line eq '*' ) {
3947         eval { &delete_action(); 1 } or print $OUT $@ and return;
3948     }
3949
3950     # There's a real line  number. Pass it to delete_action.
3951     # Error trapping is as above.
3952     elsif ( $line =~ /^(\S.*)/ ) {
3953         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3954     }
3955
3956     # Swing and a miss. Bad syntax.
3957     else {
3958         print $OUT
3959           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3960     }
3961 } ## end sub cmd_A
3962
3963 =head3 C<delete_action> (API)
3964
3965 C<delete_action> accepts either a line number or C<undef>. If a line number
3966 is specified, we check for the line being executable (if it's not, it
3967 couldn't have had an  action). If it is, we just take the action off (this
3968 will get any kind of an action, including breakpoints).
3969
3970 =cut
3971
3972 sub delete_action {
3973     my $i = shift;
3974     if ( defined($i) ) {
3975
3976         # Can there be one?
3977         die "Line $i has no action .\n" if $dbline[$i] == 0;
3978
3979         # Nuke whatever's there.
3980         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3981         delete $dbline{$i} if $dbline{$i} eq '';
3982     }
3983     else {
3984         print $OUT "Deleting all actions...\n";
3985         for my $file ( keys %had_breakpoints ) {
3986             local *dbline = $main::{ '_<' . $file };
3987             my $max = $#dbline;
3988             my $was;
3989             for ( $i = 1 ; $i <= $max ; $i++ ) {
3990                 if ( defined $dbline{$i} ) {
3991                     $dbline{$i} =~ s/\0[^\0]*//;
3992                     delete $dbline{$i} if $dbline{$i} eq '';
3993                 }
3994                 unless ( $had_breakpoints{$file} &= ~2 ) {
3995                     delete $had_breakpoints{$file};
3996                 }
3997             } ## end for ($i = 1 ; $i <= $max...
3998         } ## end for my $file (keys %had_breakpoints)
3999     } ## end else [ if (defined($i))
4000 } ## end sub delete_action
4001
4002 =head3 C<cmd_b> (command)
4003
4004 Set breakpoints. Since breakpoints can be set in so many places, in so many
4005 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4006 we try to parse the command type, and then shuttle it off to an appropriate
4007 subroutine to actually do the work of setting the breakpoint in the right
4008 place.
4009
4010 =cut
4011
4012 sub cmd_b {
4013     my $cmd    = shift;
4014     my $line   = shift;    # [.|line] [cond]
4015     my $dbline = shift;
4016
4017     # Make . the current line number if it's there..
4018     $line =~ s/^\./$dbline/;
4019
4020     # No line number, no condition. Simple break on current line.
4021     if ( $line =~ /^\s*$/ ) {
4022         &cmd_b_line( $dbline, 1 );
4023     }
4024
4025     # Break on load for a file.
4026     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4027         my $file = $1;
4028         $file =~ s/\s+$//;
4029         &cmd_b_load($file);
4030     }
4031
4032     # b compile|postpone <some sub> [<condition>]
4033     # The interpreter actually traps this one for us; we just put the
4034     # necessary condition in the %postponed hash.
4035     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4036
4037         # Capture the condition if there is one. Make it true if none.
4038         my $cond = length $3 ? $3 : '1';
4039
4040         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4041         # if it was 'compile'.
4042         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4043
4044         # De-Perl4-ify the name - ' separators to ::.
4045         $subname =~ s/\'/::/g;
4046
4047         # Qualify it into the current package unless it's already qualified.
4048         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4049
4050         # Add main if it starts with ::.
4051         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4052
4053         # Save the break type for this sub.
4054         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4055     } ## end elsif ($line =~ ...
4056
4057     # b <sub name> [<condition>]
4058     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4059
4060         #
4061         $subname = $1;
4062         $cond = length $2 ? $2 : '1';
4063         &cmd_b_sub( $subname, $cond );
4064     }
4065
4066     # b <line> [<condition>].
4067     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4068
4069         # Capture the line. If none, it's the current line.
4070         $line = $1 || $dbline;
4071
4072         # If there's no condition, make it '1'.
4073         $cond = length $2 ? $2 : '1';
4074
4075         # Break on line.
4076         &cmd_b_line( $line, $cond );
4077     }
4078
4079     # Line didn't make sense.
4080     else {
4081         print "confused by line($line)?\n";
4082     }
4083 } ## end sub cmd_b
4084
4085 =head3 C<break_on_load> (API)
4086
4087 We want to break when this file is loaded. Mark this file in the
4088 C<%break_on_load> hash, and note that it has a breakpoint in
4089 C<%had_breakpoints>.
4090
4091 =cut
4092
4093 sub break_on_load {
4094     my $file = shift;
4095     $break_on_load{$file} = 1;
4096     $had_breakpoints{$file} |= 1;
4097 }
4098
4099 =head3 C<report_break_on_load> (API)
4100
4101 Gives us an array of filenames that are set to break on load. Note that
4102 only files with break-on-load are in here, so simply showing the keys
4103 suffices.
4104
4105 =cut
4106
4107 sub report_break_on_load {
4108     sort keys %break_on_load;
4109 }
4110
4111 =head3 C<cmd_b_load> (command)
4112
4113 We take the file passed in and try to find it in C<%INC> (which maps modules
4114 to files they came from). We mark those files for break-on-load via
4115 C<break_on_load> and then report that it was done.
4116
4117 =cut
4118
4119 sub cmd_b_load {
4120     my $file = shift;
4121     my @files;
4122
4123     # This is a block because that way we can use a redo inside it
4124     # even without there being any looping structure at all outside it.
4125     {
4126
4127         # Save short name and full path if found.
4128         push @files, $file;
4129         push @files, $::INC{$file} if $::INC{$file};
4130
4131         # Tack on .pm and do it again unless there was a '.' in the name
4132         # already.
4133         $file .= '.pm', redo unless $file =~ /\./;
4134     }
4135
4136     # Do the real work here.
4137     break_on_load($_) for @files;
4138
4139     # All the files that have break-on-load breakpoints.
4140     @files = report_break_on_load;
4141
4142     # Normalize for the purposes of our printing this.
4143     local $\ = '';
4144     local $" = ' ';
4145     print $OUT "Will stop on load of `@files'.\n";
4146 } ## end sub cmd_b_load
4147
4148 =head3 C<$filename_error> (API package global)
4149
4150 Several of the functions we need to implement in the API need to work both
4151 on the current file and on other files. We don't want to duplicate code, so
4152 C<$filename_error> is used to contain the name of the file that's being
4153 worked on (if it's not the current one).
4154
4155 We can now build functions in pairs: the basic function works on the current
4156 file, and uses C<$filename_error> as part of its error message. Since this is
4157 initialized to C<"">, no filename will appear when we are working on the
4158 current file.
4159
4160 The second function is a wrapper which does the following:
4161
4162 =over 4
4163
4164 =item *
4165
4166 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4167
4168 =item *
4169
4170 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4171
4172 =item *
4173
4174 Calls the first function.
4175
4176 The first function works on the I<current> file (i.e., the one we changed to),
4177 and prints C<$filename_error> in the error message (the name of the other file)
4178 if it needs to. When the functions return, C<*dbline> is restored to point
4179 to the actual current file (the one we're executing in) and
4180 C<$filename_error> is restored to C<"">. This restores everything to
4181 the way it was before the second function was called at all.
4182
4183 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4184 details.
4185
4186 =back
4187
4188 =cut
4189
4190 $filename_error = '';
4191
4192 =head3 breakable_line(from, to) (API)
4193
4194 The subroutine decides whether or not a line in the current file is breakable.
4195 It walks through C<@dbline> within the range of lines specified, looking for
4196 the first line that is breakable.
4197
4198 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4199 first line I<after> C<$to> that's breakable, if there is one.
4200
4201 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4202 first line I<before> C<$to> that's breakable, if there is one.
4203
4204 =cut
4205
4206 sub breakable_line {
4207
4208     my ( $from, $to ) = @_;
4209
4210     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4211     my $i = $from;
4212
4213     # If there are at least 2 arguments, we're trying to search a range.
4214     if ( @_ >= 2 ) {
4215
4216         # $delta is positive for a forward search, negative for a backward one.
4217         my $delta = $from < $to ? +1 : -1;
4218
4219         # Keep us from running off the ends of the file.
4220         my $limit = $delta > 0 ? $#dbline : 1;
4221
4222         # Clever test. If you're a mathematician, it's obvious why this
4223         # test works. If not:
4224         # If $delta is positive (going forward), $limit will be $#dbline.
4225         #    If $to is less than $limit, ($limit - $to) will be positive, times
4226         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4227         #    as the stopping point.
4228         #
4229         #    If $to is greater than $limit, ($limit - $to) is negative,
4230         #    times $delta of 1 (positive), so the result is < 0 and we should
4231         #    use $limit ($#dbline) as the stopping point.
4232         #
4233         # If $delta is negative (going backward), $limit will be 1.
4234         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4235         #    (negative) so the result is > 0, and we use $to as the stopping
4236         #    point.
4237         #
4238         #    If $to is less than zero, ($limit - $to) will be positive,
4239         #    times $delta of -1 (negative), so the result is not > 0, and
4240         #    we use $limit (1) as the stopping point.
4241         #
4242         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4243         #    (negative), still giving zero; the result is not > 0, and
4244         #    we use $limit (1) as the stopping point.
4245         #
4246         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4247         #    (negative), giving a positive (>0) value, so we'll set $limit to
4248         #    $to.
4249
4250         $limit = $to if ( $limit - $to ) * $delta > 0;
4251
4252         # The real search loop.
4253         # $i starts at $from (the point we want to start searching from).
4254         # We move through @dbline in the appropriate direction (determined
4255         # by $delta: either -1 (back) or +1 (ahead).
4256         # We stay in as long as we haven't hit an executable line
4257         # ($dbline[$i] == 0 means not executable) and we haven't reached
4258         # the limit yet (test similar to the above).
4259         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4260
4261     } ## end if (@_ >= 2)
4262
4263     # If $i points to a line that is executable, return that.
4264     return $i unless $dbline[$i] == 0;
4265
4266     # Format the message and print it: no breakable lines in range.
4267     my ( $pl, $upto ) = ( '', '' );
4268     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4269
4270     # If there's a filename in filename_error, we'll see it.
4271     # If not, not.
4272     die "Line$pl $from$upto$filename_error not breakable\n";
4273 } ## end sub breakable_line
4274
4275 =head3 breakable_line_in_filename(file, from, to) (API)
4276
4277 Like C<breakable_line>, but look in another file.
4278
4279 =cut
4280
4281 sub breakable_line_in_filename {
4282
4283     # Capture the file name.
4284     my ($f) = shift;
4285
4286     # Swap the magic line array over there temporarily.
4287     local *dbline = $main::{ '_<' . $f };
4288
4289     # If there's an error, it's in this other file.
4290     local $filename_error = " of `$f'";
4291
4292     # Find the breakable line.
4293     breakable_line(@_);
4294
4295     # *dbline and $filename_error get restored when this block ends.
4296
4297 } ## end sub breakable_line_in_filename
4298
4299 =head3 break_on_line(lineno, [condition]) (API)
4300
4301 Adds a breakpoint with the specified condition (or 1 if no condition was
4302 specified) to the specified line. Dies if it can't.
4303
4304 =cut
4305
4306 sub break_on_line {
4307     my ( $i, $cond ) = @_;
4308
4309     # Always true if no condition supplied.
4310     $cond = 1 unless @_ >= 2;
4311
4312     my $inii  = $i;
4313     my $after = '';
4314     my $pl    = '';
4315
4316     # Woops, not a breakable line. $filename_error allows us to say
4317     # if it was in a different file.
4318     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4319
4320     # Mark this file as having breakpoints in it.
4321     $had_breakpoints{$filename} |= 1;
4322
4323     # If there is an action or condition here already ...
4324     if ( $dbline{$i} ) {
4325
4326         # ... swap this condition for the existing one.
4327         $dbline{$i} =~ s/^[^\0]*/$cond/;
4328     }
4329     else {
4330
4331         # Nothing here - just add the condition.
4332         $dbline{$i} = $cond;
4333     }
4334 } ## end sub break_on_line
4335
4336 =head3 cmd_b_line(line, [condition]) (command)
4337
4338 Wrapper for C<break_on_line>. Prints the failure message if it
4339 doesn't work.
4340
4341 =cut
4342
4343 sub cmd_b_line {
4344     eval { break_on_line(@_); 1 } or do {
4345         local $\ = '';
4346         print $OUT $@ and return;
4347     };
4348 } ## end sub cmd_b_line
4349
4350 =head3 break_on_filename_line(file, line, [condition]) (API)
4351
4352 Switches to the file specified and then calls C<break_on_line> to set
4353 the breakpoint.
4354
4355 =cut
4356
4357 sub break_on_filename_line {
4358     my ( $f, $i, $cond ) = @_;
4359
4360     # Always true if condition left off.
4361     $cond = 1 unless @_ >= 3;
4362
4363     # Switch the magical hash temporarily.
4364     local *dbline = $main::{ '_<' . $f };
4365
4366     # Localize the variables that break_on_line uses to make its message.
4367     local $filename_error = " of `$f'";
4368     local $filename       = $f;
4369
4370     # Add the breakpoint.
4371     break_on_line( $i, $cond );
4372 } ## end sub break_on_filename_line
4373
4374 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4375
4376 Switch to another file, search the range of lines specified for an
4377 executable one, and put a breakpoint on the first one you find.
4378
4379 =cut
4380
4381 sub break_on_filename_line_range {
4382     my ( $f, $from, $to, $cond ) = @_;
4383
4384     # Find a breakable line if there is one.
4385     my $i = breakable_line_in_filename( $f, $from, $to );
4386
4387     # Always true if missing.
4388     $cond = 1 unless @_ >= 3;
4389
4390     # Add the breakpoint.
4391     break_on_filename_line( $f, $i, $cond );
4392 } ## end sub break_on_filename_line_range
4393
4394 =head3 subroutine_filename_lines(subname, [condition]) (API)
4395
4396 Search for a subroutine within a given file. The condition is ignored.
4397 Uses C<find_sub> to locate the desired subroutine.
4398
4399 =cut
4400
4401 sub subroutine_filename_lines {
4402     my ( $subname, $cond ) = @_;
4403
4404     # Returned value from find_sub() is fullpathname:startline-endline.
4405     # The match creates the list (fullpathname, start, end). Falling off
4406     # the end of the subroutine returns this implicitly.
4407     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4408 } ## end sub subroutine_filename_lines
4409
4410 =head3 break_subroutine(subname) (API)
4411
4412 Places a break on the first line possible in the specified subroutine. Uses
4413 C<subroutine_filename_lines> to find the subroutine, and
4414 C<break_on_filename_line_range> to place the break.
4415
4416 =cut
4417
4418 sub break_subroutine {
4419     my $subname = shift;
4420
4421     # Get filename, start, and end.
4422     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4423       or die "Subroutine $subname not found.\n";
4424
4425     # Null condition changes to '1' (always true).
4426     $cond = 1 unless @_ >= 2;
4427
4428     # Put a break the first place possible in the range of lines
4429     # that make up this subroutine.
4430     break_on_filename_line_range( $file, $s, $e, @_ );
4431 } ## end sub break_subroutine
4432
4433 =head3 cmd_b_sub(subname, [condition]) (command)
4434
4435 We take the incoming subroutine name and fully-qualify it as best we can.
4436
4437 =over 4
4438
4439 =item 1. If it's already fully-qualified, leave it alone.
4440
4441 =item 2. Try putting it in the current package.
4442
4443 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4444
4445 =item 4. If it starts with '::', put it in 'main::'.
4446
4447 =back
4448
4449 After all this cleanup, we call C<break_subroutine> to try to set the
4450 breakpoint.
4451
4452 =cut
4453
4454 sub cmd_b_sub {
4455     my ( $subname, $cond ) = @_;
4456
4457     # Add always-true condition if we have none.
4458     $cond = 1 unless @_ >= 2;
4459
4460     # If the subname isn't a code reference, qualify it so that
4461     # break_subroutine() will work right.
4462     unless ( ref $subname eq 'CODE' ) {
4463
4464         # Not Perl4.
4465         $subname =~ s/\'/::/g;
4466         my $s = $subname;
4467
4468         # Put it in this package unless it's already qualified.
4469         $subname = "${'package'}::" . $subname
4470           unless $subname =~ /::/;
4471
4472         # Requalify it into CORE::GLOBAL if qualifying it into this
4473         # package resulted in its not being defined, but only do so
4474         # if it really is in CORE::GLOBAL.
4475         $subname = "CORE::GLOBAL::$s"
4476           if not defined &$subname
4477           and $s !~ /::/
4478           and defined &{"CORE::GLOBAL::$s"};
4479
4480         # Put it in package 'main' if it has a leading ::.
4481         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4482
4483     } ## end unless (ref $subname eq 'CODE')
4484
4485     # Try to set the breakpoint.
4486     eval { break_subroutine( $subname, $cond ); 1 } or do {
4487         local $\ = '';
4488         print $OUT $@ and return;
4489       }
4490 } ## end sub cmd_b_sub
4491
4492 =head3 C<cmd_B> - delete breakpoint(s) (command)
4493
4494 The command mostly parses the command line and tries to turn the argument
4495 into a line spec. If it can't, it uses the current line. It then calls
4496 C<delete_breakpoint> to actually do the work.
4497
4498 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4499 thereby deleting all the breakpoints.
4500
4501 =cut
4502
4503 sub cmd_B {
4504     my $cmd = shift;
4505
4506     # No line spec? Use dbline.
4507     # If there is one, use it if it's non-zero, or wipe it out if it is.
4508     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4509     my $dbline = shift;
4510
4511     # If the line was dot, make the line the current one.
4512     $line =~ s/^\./$dbline/;
4513
4514     # If it's * we're deleting all the breakpoints.
4515     if ( $line eq '*' ) {
4516         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4517     }
4518
4519     # If there is a line spec, delete the breakpoint on that line.
4520     elsif ( $line =~ /^(\S.*)/ ) {
4521         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4522             local $\ = '';
4523             print $OUT $@ and return;
4524         };
4525     } ## end elsif ($line =~ /^(\S.*)/)
4526
4527     # No line spec.
4528     else {
4529         print $OUT
4530           "Deleting a breakpoint requires a line number, or '*' for all\n"
4531           ;    # hint
4532     }
4533 } ## end sub cmd_B
4534
4535 =head3 delete_breakpoint([line]) (API)
4536
4537 This actually does the work of deleting either a single breakpoint, or all
4538 of them.
4539
4540 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4541 just drop out with a message saying so. If it is, we remove the condition
4542 part of the 'condition\0action' that says there's a breakpoint here. If,
4543 after we've done that, there's nothing left, we delete the corresponding
4544 line in C<%dbline> to signal that no action needs to be taken for this line.
4545
4546 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4547 which lists all currently-loaded files which have breakpoints. We then look
4548 at each line in each of these files, temporarily switching the C<%dbline>
4549 and C<@dbline> structures to point to the files in question, and do what
4550 we did in the single line case: delete the condition in C<@dbline>, and
4551 delete the key in C<%dbline> if nothing's left.
4552
4553 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4554 C<%break_on_load>, because these structures contain breakpoints for files
4555 and code that haven't been loaded yet. We can just kill these off because there
4556 are no magical debugger structures associated with them.
4557
4558 =cut
4559
4560 sub delete_breakpoint {
4561     my $i = shift;
4562
4563     # If we got a line, delete just that one.
4564     if ( defined($i) ) {
4565
4566         # Woops. This line wasn't breakable at all.
4567         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4568
4569         # Kill the condition, but leave any action.
4570         $dbline{$i} =~ s/^[^\0]*//;
4571
4572         # Remove the entry entirely if there's no action left.
4573         delete $dbline{$i} if $dbline{$i} eq '';
4574     }
4575
4576     # No line; delete them all.
4577     else {
4578         print $OUT "Deleting all breakpoints...\n";
4579
4580         # %had_breakpoints lists every file that had at least one
4581         # breakpoint in it.
4582         for my $file ( keys %had_breakpoints ) {
4583
4584             # Switch to the desired file temporarily.
4585             local *dbline = $main::{ '_<' . $file };
4586
4587             my $max = $#dbline;
4588             my $was;
4589
4590             # For all lines in this file ...
4591             for ( $i = 1 ; $i <= $max ; $i++ ) {
4592
4593                 # If there's a breakpoint or action on this line ...
4594                 if ( defined $dbline{$i} ) {
4595
4596                     # ... remove the breakpoint.
4597                     $dbline{$i} =~ s/^[^\0]+//;
4598                     if ( $dbline{$i} =~ s/^\0?$// ) {
4599
4600                         # Remove the entry altogether if no action is there.
4601                         delete $dbline{$i};
4602                     }
4603                 } ## end if (defined $dbline{$i...
4604             } ## end for ($i = 1 ; $i <= $max...
4605
4606             # If, after we turn off the "there were breakpoints in this file"
4607             # bit, the entry in %had_breakpoints for this file is zero,
4608             # we should remove this file from the hash.
4609             if ( not $had_breakpoints{$file} &= ~1 ) {
4610                 delete $had_breakpoints{$file};
4611             }
4612         } ## end for my $file (keys %had_breakpoints)
4613
4614         # Kill off all the other breakpoints that are waiting for files that
4615         # haven't been loaded yet.
4616         undef %postponed;
4617         undef %postponed_file;
4618         undef %break_on_load;
4619     } ## end else [ if (defined($i))
4620 } ## end sub delete_breakpoint
4621
4622 =head3 cmd_stop (command)
4623
4624 This is meant to be part of the new command API, but it isn't called or used
4625 anywhere else in the debugger. XXX It is probably meant for use in development
4626 of new commands.
4627
4628 =cut
4629
4630 sub cmd_stop {    # As on ^C, but not signal-safy.
4631     $signal = 1;
4632 }
4633
4634 =head3 C<cmd_e> - threads
4635
4636 Display the current thread id:
4637
4638         e
4639
4640 This could be how (when implemented) to send commands to this thread id (e cmd)
4641 or that thread id (e tid cmd).
4642
4643 =cut
4644
4645 sub cmd_e {
4646     my $cmd  = shift;
4647     my $line = shift;
4648         unless (exists($INC{'threads.pm'})) {
4649                 print "threads not loaded($ENV{PERL5DB_THREADED})
4650                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4651         } else {
4652                 my $tid = threads->self->tid;
4653                 print "thread id: $tid\n";
4654         }
4655 } ## end sub cmd_e
4656
4657 =head3 C<cmd_E> - list of thread ids
4658
4659 Display the list of available thread ids:
4660
4661         E
4662
4663 This could be used (when implemented) to send commands to all threads (E cmd).
4664
4665 =cut
4666
4667 sub cmd_E {
4668     my $cmd  = shift;
4669     my $line = shift;
4670         unless (exists($INC{'threads.pm'})) {
4671                 print "threads not loaded($ENV{PERL5DB_THREADED})
4672                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4673         } else {
4674                 my $tid = threads->self->tid;
4675                 print "thread ids: ".join(', ',
4676                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4677                 )."\n";
4678         }
4679 } ## end sub cmd_E
4680
4681 =head3 C<cmd_h> - help command (command)
4682
4683 Does the work of either
4684
4685 =over 4
4686
4687 =item *
4688
4689 Showing all the debugger help
4690
4691 =item *
4692
4693 Showing help for a specific command
4694
4695 =back
4696
4697 =cut
4698
4699 sub cmd_h {
4700     my $cmd = shift;
4701
4702     # If we have no operand, assume null.
4703     my $line = shift || '';
4704
4705     # 'h h'. Print the long-format help.
4706     if ( $line =~ /^h\s*/ ) {
4707         print_help($help);
4708     }
4709
4710     # 'h <something>'. Search for the command and print only its help.
4711     elsif ( $line =~ /^(\S.*)$/ ) {
4712
4713         # support long commands; otherwise bogus errors
4714         # happen when you ask for h on <CR> for example
4715         my $asked = $1;    # the command requested
4716                            # (for proper error message)
4717
4718         my $qasked = quotemeta($asked);    # for searching; we don't
4719                                            # want to use it as a pattern.
4720                                            # XXX: finds CR but not <CR>
4721
4722         # Search the help string for the command.
4723         if (
4724             $help =~ /^                    # Start of a line
4725                       <?                   # Optional '<'
4726                       (?:[IB]<)            # Optional markup
4727                       $qasked              # The requested command
4728                      /mx
4729           )
4730         {
4731
4732             # It's there; pull it out and print it.
4733             while (
4734                 $help =~ /^
4735                               (<?            # Optional '<'
4736                                  (?:[IB]<)   # Optional markup
4737                                  $qasked     # The command
4738                                  ([\s\S]*?)  # Description line(s)
4739                               \n)            # End of last description line
4740                               (?!\s)         # Next line not starting with
4741                                              # whitespace
4742                              /mgx
4743               )
4744             {
4745                 print_help($1);
4746             }
4747         }
4748
4749         # Not found; not a debugger command.
4750         else {
4751             print_help("B<$asked> is not a debugger command.\n");
4752         }
4753     } ## end elsif ($line =~ /^(\S.*)$/)
4754
4755     # 'h' - print the summary help.
4756     else {
4757         print_help($summary);
4758     }
4759 } ## end sub cmd_h
4760
4761 =head3 C<cmd_i> - inheritance display
4762
4763 Display the (nested) parentage of the module or object given.
4764
4765 =cut
4766
4767 sub cmd_i {
4768     my $cmd  = shift;
4769     my $line = shift;
4770     eval { require Class::ISA };
4771     if ($@) {
4772         &warn( $@ =~ /locate/
4773             ? "Class::ISA module not found - please install\n"
4774             : $@ );
4775     }
4776     else {
4777       ISA:
4778         foreach my $isa ( split( /\s+/, $line ) ) {
4779             $evalarg = $isa;
4780             ($isa) = &eval;
4781             no strict 'refs';
4782             print join(
4783                 ', ',
4784                 map {    # snaffled unceremoniously from Class::ISA
4785                     "$_"
4786                       . (
4787                         defined( ${"$_\::VERSION"} )
4788                         ? ' ' . ${"$_\::VERSION"}
4789                         : undef )
4790                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4791             );
4792             print "\n";
4793         }
4794     }
4795 } ## end sub cmd_i
4796
4797 =head3 C<cmd_l> - list lines (command)
4798
4799 Most of the command is taken up with transforming all the different line
4800 specification syntaxes into 'start-stop'. After that is done, the command
4801 runs a loop over C<@dbline> for the specified range of lines. It handles
4802 the printing of each line and any markers (C<==E<gt>> for current line,
4803 C<b> for break on this line, C<a> for action on this line, C<:> for this
4804 line breakable).
4805
4806 We save the last line listed in the C<$start> global for further listing
4807 later.
4808
4809 =cut
4810
4811 sub cmd_l {
4812     my $current_line = $line;
4813     my $cmd  = shift;
4814     my $line = shift;
4815
4816     # If this is '-something', delete any spaces after the dash.
4817     $line =~ s/^-\s*$/-/;
4818
4819     # If the line is '$something', assume this is a scalar containing a
4820     # line number.
4821     if ( $line =~ /^(\$.*)/s ) {
4822
4823         # Set up for DB::eval() - evaluate in *user* context.
4824         $evalarg = $1;
4825         # $evalarg = $2;
4826         my ($s) = &eval;
4827
4828         # Ooops. Bad scalar.
4829         print( $OUT "Error: $@\n" ), next CMD if $@;
4830
4831         # Good scalar. If it's a reference, find what it points to.
4832         $s = CvGV_name($s);
4833         print( $OUT "Interpreted as: $1 $s\n" );
4834         $line = "$1 $s";
4835
4836         # Call self recursively to really do the command.
4837         &cmd_l( 'l', $s );
4838     } ## end if ($line =~ /^(\$.*)/s)
4839
4840     # l name. Try to find a sub by that name.
4841     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4842         my $s = $subname = $1;
4843
4844         # De-Perl4.
4845         $subname =~ s/\'/::/;
4846
4847         # Put it in this package unless it starts with ::.
4848         $subname = $package . "::" . $subname unless $subname =~ /::/;
4849
4850         # Put it in CORE::GLOBAL if t doesn't start with :: and
4851         # it doesn't live in this package and it lives in CORE::GLOBAL.
4852         $subname = "CORE::GLOBAL::$s"
4853           if not defined &$subname
4854           and $s !~ /::/
4855           and defined &{"CORE::GLOBAL::$s"};
4856
4857         # Put leading '::' names into 'main::'.
4858         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4859
4860         # Get name:start-stop from find_sub, and break this up at
4861         # colons.
4862         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4863
4864         # Pull off start-stop.
4865         $subrange = pop @pieces;
4866
4867         # If the name contained colons, the split broke it up.
4868         # Put it back together.
4869         $file = join( ':', @pieces );
4870
4871         # If we're not in that file, switch over to it.
4872         if ( $file ne $filename ) {
4873             print $OUT "Switching to file '$file'.\n"
4874               unless $slave_editor;
4875
4876             # Switch debugger's magic structures.
4877             *dbline   = $main::{ '_<' . $file };
4878             $max      = $#dbline;
4879             $filename = $file;
4880         } ## end if ($file ne $filename)
4881
4882         # Subrange is 'start-stop'. If this is less than a window full,
4883         # swap it to 'start+', which will list a window from the start point.
4884         if ($subrange) {
4885             if ( eval($subrange) < -$window ) {
4886                 $subrange =~ s/-.*/+/;
4887             }
4888
4889             # Call self recursively to list the range.
4890             $line = $subrange;
4891             &cmd_l( 'l', $subrange );
4892         } ## end if ($subrange)
4893
4894         # Couldn't find it.
4895         else {
4896             print $OUT "Subroutine $subname not found.\n";
4897         }
4898     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4899
4900     # Bare 'l' command.
4901     elsif ( $line =~ /^\s*$/ ) {
4902
4903         # Compute new range to list.
4904         $incr = $window - 1;
4905         $line = $start . '-' . ( $start + $incr );
4906
4907         # Recurse to do it.
4908         &cmd_l( 'l', $line );
4909     }
4910
4911     # l [start]+number_of_lines
4912     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4913
4914         # Don't reset start for 'l +nnn'.
4915         $start = $1 if $1;
4916
4917         # Increment for list. Use window size if not specified.
4918         # (Allows 'l +' to work.)
4919         $incr = $2;
4920         $incr = $window - 1 unless $incr;
4921
4922         # Create a line range we'll understand, and recurse to do it.
4923         $line = $start . '-' . ( $start + $incr );
4924         &cmd_l( 'l', $line );
4925     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4926
4927     # l start-stop or l start,stop
4928     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4929
4930         # Determine end point; use end of file if not specified.
4931         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4932
4933         # Go on to the end, and then stop.
4934         $end = $max if $end > $max;
4935
4936         # Determine start line.
4937         $i    = $2;
4938         $i    = $line if $i eq '.';
4939         $i    = 1 if $i < 1;
4940         $incr = $end - $i;
4941
4942         # If we're running under a slave editor, force it to show the lines.
4943         if ($slave_editor) {
4944             print $OUT "\032\032$filename:$i:0\n";
4945             $i = $end;
4946         }
4947
4948         # We're doing it ourselves. We want to show the line and special
4949         # markers for:
4950         # - the current line in execution
4951         # - whether a line is breakable or not
4952         # - whether a line has a break or not
4953         # - whether a line has an action or not
4954         else {
4955             for ( ; $i <= $end ; $i++ ) {
4956
4957                 # Check for breakpoints and actions.
4958                 my ( $stop, $action );
4959                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
4960                   if $dbline{$i};
4961
4962                 # ==> if this is the current line in execution,
4963                 # : if it's breakable.
4964                 $arrow =
4965                   ( $i == $current_line and $filename eq $filename_ini )
4966                   ? '==>'
4967                   : ( $dbline[$i] + 0 ? ':' : ' ' );
4968
4969                 # Add break and action indicators.
4970                 $arrow .= 'b' if $stop;
4971                 $arrow .= 'a' if $action;
4972
4973                 # Print the line.
4974                 print $OUT "$i$arrow\t", $dbline[$i];
4975
4976                 # Move on to the next line. Drop out on an interrupt.
4977                 $i++, last if $signal;
4978             } ## end for (; $i <= $end ; $i++)
4979
4980             # Line the prompt up; print a newline if the last line listed
4981             # didn't have a newline.
4982             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
4983         } ## end else [ if ($slave_editor)
4984
4985         # Save the point we last listed to in case another relative 'l'
4986         # command is desired. Don't let it run off the end.
4987         $start = $i;
4988         $start = $max if $start > $max;
4989     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
4990 } ## end sub cmd_l
4991
4992 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
4993
4994 To list breakpoints, the command has to look determine where all of them are
4995 first. It starts a C<%had_breakpoints>, which tells us what all files have
4996 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
4997 magic source and breakpoint data structures) to the file, and then look
4998 through C<%dbline> for lines with breakpoints and/or actions, listing them
4999 out. We look through C<%postponed> not-yet-compiled subroutines that have
5000 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5001 that have breakpoints.
5002
5003 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5004
5005 =cut
5006
5007 sub cmd_L {
5008     my $cmd = shift;
5009
5010     # If no argument, list everything. Pre-5.8.0 version always lists
5011     # everything
5012     my $arg = shift || 'abw';
5013     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5014
5015     # See what is wanted.
5016     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5017     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5018     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5019
5020     # Breaks and actions are found together, so we look in the same place
5021     # for both.
5022     if ( $break_wanted or $action_wanted ) {
5023
5024         # Look in all the files with breakpoints...
5025         for my $file ( keys %had_breakpoints ) {
5026
5027             # Temporary switch to this file.
5028             local *dbline = $main::{ '_<' . $file };
5029
5030             # Set up to look through the whole file.
5031             my $max = $#dbline;
5032             my $was;    # Flag: did we print something
5033                         # in this file?
5034
5035             # For each line in the file ...
5036             for ( $i = 1 ; $i <= $max ; $i++ ) {
5037
5038                 # We've got something on this line.
5039                 if ( defined $dbline{$i} ) {
5040
5041                     # Print the header if we haven't.
5042                     print $OUT "$file:\n" unless $was++;
5043
5044                     # Print the line.
5045                     print $OUT " $i:\t", $dbline[$i];
5046
5047                     # Pull out the condition and the action.
5048                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5049
5050                     # Print the break if there is one and it's wanted.
5051                     print $OUT "   break if (", $stop, ")\n"
5052                       if $stop
5053                       and $break_wanted;
5054
5055                     # Print the action if there is one and it's wanted.
5056                     print $OUT "   action:  ", $action, "\n"
5057                       if $action
5058                       and $action_wanted;
5059
5060                     # Quit if the user hit interrupt.
5061                     last if $signal;
5062                 } ## end if (defined $dbline{$i...
5063             } ## end for ($i = 1 ; $i <= $max...
5064         } ## end for my $file (keys %had_breakpoints)
5065     } ## end if ($break_wanted or $action_wanted)
5066
5067     # Look for breaks in not-yet-compiled subs:
5068     if ( %postponed and $break_wanted ) {
5069         print $OUT "Postponed breakpoints in subroutines:\n";
5070         my $subname;
5071         for $subname ( keys %postponed ) {
5072             print $OUT " $subname\t$postponed{$subname}\n";
5073             last if $signal;
5074         }
5075     } ## end if (%postponed and $break_wanted)
5076
5077     # Find files that have not-yet-loaded breaks:
5078     my @have = map {    # Combined keys
5079         keys %{ $postponed_file{$_} }
5080     } keys %postponed_file;
5081
5082     # If there are any, list them.
5083     if ( @have and ( $break_wanted or $action_wanted ) ) {
5084         print $OUT "Postponed breakpoints in files:\n";
5085         my ( $file, $line );
5086
5087         for $file ( keys %postponed_file ) {
5088             my $db = $postponed_file{$file};
5089             print $OUT " $file:\n";
5090             for $line ( sort { $a <=> $b } keys %$db ) {
5091                 print $OUT "  $line:\n";
5092                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5093                 print $OUT "    break if (", $stop, ")\n"
5094                   if $stop
5095                   and $break_wanted;
5096                 print $OUT "    action:  ", $action, "\n"
5097                   if $action
5098                   and $action_wanted;
5099                 last if $signal;
5100             } ## end for $line (sort { $a <=>...
5101             last if $signal;
5102         } ## end for $file (keys %postponed_file)
5103     } ## end if (@have and ($break_wanted...
5104     if ( %break_on_load and $break_wanted ) {
5105         print $OUT "Breakpoints on load:\n";
5106         my $file;
5107         for $file ( keys %break_on_load ) {
5108             print $OUT " $file\n";
5109             last if $signal;
5110         }
5111     } ## end if (%break_on_load and...
5112     if ($watch_wanted) {
5113         if ( $trace & 2 ) {
5114             print $OUT "Watch-expressions:\n" if @to_watch;
5115             for my $expr (@to_watch) {
5116                 print $OUT " $expr\n";
5117                 last if $signal;
5118             }
5119         } ## end if ($trace & 2)
5120     } ## end if ($watch_wanted)
5121 } ## end sub cmd_L
5122
5123 =head3 C<cmd_M> - list modules (command)
5124
5125 Just call C<list_modules>.
5126
5127 =cut
5128
5129 sub cmd_M {
5130     &list_modules();
5131 }
5132
5133 =head3 C<cmd_o> - options (command)
5134
5135 If this is just C<o> by itself, we list the current settings via
5136 C<dump_option>. If there's a nonblank value following it, we pass that on to
5137 C<parse_options> for processing.
5138
5139 =cut
5140
5141 sub cmd_o {
5142     my $cmd = shift;
5143     my $opt = shift || '';    # opt[=val]
5144
5145     # Nonblank. Try to parse and process.
5146     if ( $opt =~ /^(\S.*)/ ) {
5147         &parse_options($1);
5148     }
5149
5150     # Blank. List the current option settings.
5151     else {
5152         for (@options) {
5153             &dump_option($_);
5154         }
5155     }
5156 } ## end sub cmd_o
5157
5158 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5159
5160 Advises the user that the O command has been renamed.
5161
5162 =cut
5163
5164 sub cmd_O {
5165     print $OUT "The old O command is now the o command.\n";             # hint
5166     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5167     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5168 }
5169
5170 =head3 C<cmd_v> - view window (command)
5171
5172 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5173 move back a few lines to list the selected line in context. Uses C<cmd_l>
5174 to do the actual listing after figuring out the range of line to request.
5175
5176 =cut
5177
5178 sub cmd_v {
5179     my $cmd  = shift;
5180     my $line = shift;
5181
5182     # Extract the line to list around. (Astute readers will have noted that
5183     # this pattern will match whether or not a numeric line is specified,
5184     # which means that we'll always enter this loop (though a non-numeric
5185     # argument results in no action at all)).
5186     if ( $line =~ /^(\d*)$/ ) {
5187
5188         # Total number of lines to list (a windowful).
5189         $incr = $window - 1;
5190
5191         # Set the start to the argument given (if there was one).
5192         $start = $1 if $1;
5193
5194         # Back up by the context amount.
5195         $start -= $preview;
5196
5197         # Put together a linespec that cmd_l will like.
5198         $line = $start . '-' . ( $start + $incr );
5199
5200         # List the lines.
5201         &cmd_l( 'l', $line );
5202     } ## end if ($line =~ /^(\d*)$/)
5203 } ## end sub cmd_v
5204
5205 =head3 C<cmd_w> - add a watch expression (command)
5206
5207 The 5.8 version of this command adds a watch expression if one is specified;
5208 it does nothing if entered with no operands.
5209
5210 We extract the expression, save it, evaluate it in the user's context, and
5211 save the value. We'll re-evaluate it each time the debugger passes a line,
5212 and will stop (see the code at the top of the command loop) if the value
5213 of any of the expressions changes.
5214
5215 =cut
5216
5217 sub cmd_w {
5218     my $cmd = shift;
5219
5220     # Null expression if no arguments.
5221     my $expr = shift || '';
5222
5223     # If expression is not null ...
5224     if ( $expr =~ /^(\S.*)/ ) {
5225
5226         # ... save it.
5227         push @to_watch, $expr;
5228
5229         # Parameterize DB::eval and call it to get the expression's value
5230         # in the user's context. This version can handle expressions which
5231         # return a list value.
5232         $evalarg = $expr;
5233         my ($val) = join( ' ', &eval );
5234         $val = ( defined $val ) ? "'$val'" : 'undef';
5235
5236         # Save the current value of the expression.
5237         push @old_watch, $val;
5238
5239         # We are now watching expressions.
5240         $trace |= 2;
5241     } ## end if ($expr =~ /^(\S.*)/)
5242
5243     # You have to give one to get one.
5244     else {
5245         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5246     }
5247 } ## end sub cmd_w
5248
5249 =head3 C<cmd_W> - delete watch expressions (command)
5250
5251 This command accepts either a watch expression to be removed from the list
5252 of watch expressions, or C<*> to delete them all.
5253
5254 If C<*> is specified, we simply empty the watch expression list and the
5255 watch expression value list. We also turn off the bit that says we've got
5256 watch expressions.
5257
5258 If an expression (or partial expression) is specified, we pattern-match
5259 through the expressions and remove the ones that match. We also discard
5260 the corresponding values. If no watch expressions are left, we turn off
5261 the I<watching expressions> bit.
5262
5263 =cut
5264
5265 sub cmd_W {
5266     my $cmd  = shift;
5267     my $expr = shift || '';
5268
5269     # Delete them all.
5270     if ( $expr eq '*' ) {
5271
5272         # Not watching now.
5273         $trace &= ~2;
5274
5275         print $OUT "Deleting all watch expressions ...\n";
5276
5277         # And all gone.
5278         @to_watch = @old_watch = ();
5279     }
5280
5281     # Delete one of them.
5282     elsif ( $expr =~ /^(\S.*)/ ) {
5283
5284         # Where we are in the list.
5285         my $i_cnt = 0;
5286
5287         # For each expression ...
5288         foreach (@to_watch) {
5289             my $val = $to_watch[$i_cnt];
5290
5291             # Does this one match the command argument?
5292             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5293                                       # Yes. Turn it off, and its value too.
5294                 splice( @to_watch,  $i_cnt, 1 );
5295                 splice( @old_watch, $i_cnt, 1 );
5296             }
5297             $i_cnt++;
5298         } ## end foreach (@to_watch)
5299
5300         # We don't bother to turn watching off because
5301         #  a) we don't want to stop calling watchfunction() it it exists
5302         #  b) foreach over a null list doesn't do anything anyway
5303
5304     } ## end elsif ($expr =~ /^(\S.*)/)
5305
5306     # No command arguments entered.
5307     else {
5308         print $OUT
5309           "Deleting a watch-expression requires an expression, or '*' for all\n"
5310           ;    # hint
5311     }
5312 } ## end sub cmd_W
5313
5314 ### END of the API section
5315
5316 =head1 SUPPORT ROUTINES
5317
5318 These are general support routines that are used in a number of places
5319 throughout the debugger.
5320
5321 =over 4
5322
5323 =item cmd_P
5324
5325 Something to do with assertions
5326
5327 =back
5328
5329 =cut
5330
5331 sub cmd_P {
5332     unless ($ini_assertion) {
5333         print $OUT "Assertions not supported in this Perl interpreter\n";
5334     } else {
5335         if ( $cmd =~ /^.\b\s*([+-]?)\s*(~?)\s*(\w+(\s*\|\s*\w+)*)\s*$/ ) {
5336             my ( $how, $neg, $flags ) = ( $1, $2, $3 );
5337             my $acu = parse_DollarCaretP_flags($flags);
5338             if ( defined $acu ) {
5339                 $acu = ~$acu if $neg;
5340                 if ( $how eq '+' ) { $^P |= $acu }
5341                 elsif ( $how eq '-' ) { $^P &= ~$acu }
5342                 else { $^P = $acu }
5343             }
5344
5345             # else { print $OUT "undefined acu\n" }
5346         }
5347         my $expanded = expand_DollarCaretP_flags($^P);
5348         print $OUT "Internal Perl debugger flags:\n\$^P=$expanded\n";
5349         $expanded;
5350     }
5351 }
5352
5353 =head2 save
5354
5355 save() saves the user's versions of globals that would mess us up in C<@saved>,
5356 and installs the versions we like better.
5357
5358 =cut
5359
5360 sub save {
5361
5362     # Save eval failure, command failure, extended OS error, output field
5363     # separator, input record separator, output record separator and
5364     # the warning setting.
5365     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5366
5367     $,  = "";      # output field separator is null string
5368     $/  = "\n";    # input record separator is newline
5369     $\  = "";      # output record separator is null string
5370     $^W = 0;       # warnings are off
5371 } ## end sub save
5372
5373 =head2 C<print_lineinfo> - show where we are now
5374
5375 print_lineinfo prints whatever it is that it is handed; it prints it to the
5376 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5377 us to feed line information to a slave editor without messing up the
5378 debugger output.
5379
5380 =cut
5381
5382 sub print_lineinfo {
5383
5384     # Make the terminal sensible if we're not the primary debugger.
5385     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5386     local $\ = '';
5387     local $, = '';
5388     print $LINEINFO @_;
5389 } ## end sub print_lineinfo
5390
5391 =head2 C<postponed_sub>
5392
5393 Handles setting postponed breakpoints in subroutines once they're compiled.
5394 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5395 range for the subroutine, then mark the file as having a breakpoint,
5396 temporarily switch the C<*dbline> glob over to the source file, and then
5397 search the given range of lines to find a breakable line. If we find one,
5398 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5399
5400 =cut
5401
5402 # The following takes its argument via $evalarg to preserve current @_
5403
5404 sub postponed_sub {
5405
5406     # Get the subroutine name.
5407     my $subname = shift;
5408
5409     # If this is a 'break +<n> if <condition>' ...
5410     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5411
5412         # If there's no offset, use '+0'.
5413         my $offset = $1 || 0;
5414
5415         # find_sub's value is 'fullpath-filename:start-stop'. It's
5416         # possible that the filename might have colons in it too.
5417         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5418         if ($i) {
5419
5420             # We got the start line. Add the offset '+<n>' from
5421             # $postponed{subname}.
5422             $i += $offset;
5423
5424             # Switch to the file this sub is in, temporarily.
5425             local *dbline = $main::{ '_<' . $file };
5426
5427             # No warnings, please.
5428             local $^W = 0;    # != 0 is magical below
5429
5430             # This file's got a breakpoint in it.
5431             $had_breakpoints{$file} |= 1;
5432
5433             # Last line in file.
5434             my $max = $#dbline;
5435
5436             # Search forward until we hit a breakable line or get to
5437             # the end of the file.
5438             ++$i until $dbline[$i] != 0 or $i >= $max;
5439
5440             # Copy the breakpoint in and delete it from %postponed.
5441             $dbline{$i} = delete $postponed{$subname};
5442         } ## end if ($i)
5443
5444         # find_sub didn't find the sub.
5445         else {
5446             local $\ = '';
5447             print $OUT "Subroutine $subname not found.\n";
5448         }
5449         return;
5450     } ## end if ($postponed{$subname...
5451     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5452
5453     #print $OUT "In postponed_sub for `$subname'.\n";
5454 } ## end sub postponed_sub
5455
5456 =head2 C<postponed>
5457
5458 Called after each required file is compiled, but before it is executed;
5459 also called if the name of a just-compiled subroutine is a key of
5460 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5461 etc.) into the just-compiled code.
5462
5463 If this is a C<require>'d file, the incoming parameter is the glob
5464 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5465
5466 If it's a subroutine, the incoming parameter is the subroutine name.
5467
5468 =cut
5469
5470 sub postponed {
5471
5472     # If there's a break, process it.
5473     if ($ImmediateStop) {
5474
5475         # Right, we've stopped. Turn it off.
5476         $ImmediateStop = 0;
5477
5478         # Enter the command loop when DB::DB gets called.
5479         $signal = 1;
5480     }
5481
5482     # If this is a subroutine, let postponed_sub() deal with it.
5483     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5484
5485     # Not a subroutine. Deal with the file.
5486     local *dbline = shift;
5487     my $filename = $dbline;
5488     $filename =~ s/^_<//;
5489     local $\ = '';
5490     $signal = 1, print $OUT "'$filename' loaded...\n"
5491       if $break_on_load{$filename};
5492     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5493
5494     # Do we have any breakpoints to put in this file?
5495     return unless $postponed_file{$filename};
5496
5497     # Yes. Mark this file as having breakpoints.
5498     $had_breakpoints{$filename} |= 1;
5499
5500     # "Cannot be done: unsufficient magic" - we can't just put the
5501     # breakpoints saved in %postponed_file into %dbline by assigning
5502     # the whole hash; we have to do it one item at a time for the
5503     # breakpoints to be set properly.
5504     #%dbline = %{$postponed_file{$filename}};
5505
5506     # Set the breakpoints, one at a time.
5507     my $key;
5508
5509     for $key ( keys %{ $postponed_file{$filename} } ) {
5510
5511         # Stash the saved breakpoint into the current file's magic line array.
5512         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5513     }
5514
5515     # This file's been compiled; discard the stored breakpoints.
5516     delete $postponed_file{$filename};
5517
5518 } ## end sub postponed
5519
5520 =head2 C<dumpit>
5521
5522 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5523
5524 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5525 a reference to a variable (the thing to be dumped) as its input.
5526
5527 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5528 the currently-selected filehandle, thank you very much). The current
5529 values of the package globals C<$single> and C<$trace> are backed up in
5530 lexicals, and they are turned off (this keeps the debugger from trying
5531 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5532 preserve its current value and it is set to zero to prevent entry/exit
5533 messages from printing, and C<$doret> is localized as well and set to -2 to
5534 prevent return values from being shown.
5535
5536 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5537 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5538 installed version in C<@INC>, yours will be used instead. Possible security
5539 problem?).
5540
5541 It then checks to see if the subroutine C<main::dumpValue> is now defined
5542 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5543 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5544 is called, and picks up the variable to be dumped from the parameter list.
5545
5546 It checks the package global C<%options> to see if there's a C<dumpDepth>
5547 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5548 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5549 structure: -1 means dump everything.
5550
5551 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5552 warning.
5553
5554 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5555 and we then return to the caller.
5556
5557 =cut
5558
5559 sub dumpit {
5560
5561     # Save the current output filehandle and switch to the one
5562     # passed in as the first parameter.
5563     local ($savout) = select(shift);
5564
5565     # Save current settings of $single and $trace, and then turn them off.
5566     my $osingle = $single;
5567     my $otrace  = $trace;
5568     $single = $trace = 0;
5569
5570     # XXX Okay, what do $frame and $doret do, again?
5571     local $frame = 0;
5572     local $doret = -2;
5573
5574     # Load dumpvar.pl unless we've already got the sub we need from it.
5575     unless ( defined &main::dumpValue ) {
5576         do 'dumpvar.pl';
5577     }
5578
5579     # If the load succeeded (or we already had dumpvalue()), go ahead
5580     # and dump things.
5581     if ( defined &main::dumpValue ) {
5582         local $\ = '';
5583         local $, = '';
5584         local $" = ' ';
5585         my $v = shift;
5586         my $maxdepth = shift || $option{dumpDepth};
5587         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5588         &main::dumpValue( $v, $maxdepth );
5589     } ## end if (defined &main::dumpValue)
5590
5591     # Oops, couldn't load dumpvar.pl.
5592     else {
5593         local $\ = '';
5594         print $OUT "dumpvar.pl not available.\n";
5595     }
5596
5597     # Reset $single and $trace to their old values.
5598     $single = $osingle;
5599     $trace  = $otrace;
5600
5601     # Restore the old filehandle.
5602     select($savout);
5603 } ## end sub dumpit
5604
5605 =head2 C<print_trace>
5606
5607 C<print_trace>'s job is to print a stack trace. It does this via the
5608 C<dump_trace> routine, which actually does all the ferreting-out of the
5609 stack trace data. C<print_trace> takes care of formatting it nicely and
5610 printing it to the proper filehandle.
5611
5612 Parameters:
5613
5614 =over 4
5615
5616 =item *
5617
5618 The filehandle to print to.
5619
5620 =item *
5621
5622 How many frames to skip before starting trace.
5623
5624 =item *
5625
5626 How many frames to print.
5627
5628 =item *
5629
5630 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5631
5632 =back
5633
5634 The original comment below seems to be noting that the traceback may not be
5635 correct if this routine is called in a tied method.
5636
5637 =cut
5638
5639 # Tied method do not create a context, so may get wrong message:
5640
5641 sub print_trace {
5642     local $\ = '';
5643     my $fh = shift;
5644
5645     # If this is going to a slave editor, but we're not the primary
5646     # debugger, reset it first.
5647     resetterm(1)
5648       if $fh        eq $LINEINFO    # slave editor
5649       and $LINEINFO eq $OUT         # normal output
5650       and $term_pid != $$;          # not the primary
5651
5652     # Collect the actual trace information to be formatted.
5653     # This is an array of hashes of subroutine call info.
5654     my @sub = dump_trace( $_[0] + 1, $_[1] );
5655
5656     # Grab the "short report" flag from @_.
5657     my $short = $_[2];              # Print short report, next one for sub name
5658
5659     # Run through the traceback info, format it, and print it.
5660     my $s;
5661     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5662
5663         # Drop out if the user has lost interest and hit control-C.
5664         last if $signal;
5665
5666         # Set the separator so arrys print nice.
5667         local $" = ', ';
5668
5669         # Grab and stringify the arguments if they are there.
5670         my $args =
5671           defined $sub[$i]{args}
5672           ? "(@{ $sub[$i]{args} })"
5673           : '';
5674
5675         # Shorten them up if $maxtrace says they're too long.
5676         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5677           if length $args > $maxtrace;
5678
5679         # Get the file name.
5680         my $file = $sub[$i]{file};
5681
5682         # Put in a filename header if short is off.
5683         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5684
5685         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5686         $s = $sub[$i]{sub};
5687         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5688
5689         # Short report uses trimmed file and sub names.
5690         if ($short) {
5691             my $sub = @_ >= 4 ? $_[3] : $s;
5692             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5693         } ## end if ($short)
5694
5695         # Non-short report includes full names.
5696         else {
5697             print $fh "$sub[$i]{context} = $s$args"
5698               . " called from $file"
5699               . " line $sub[$i]{line}\n";
5700         }
5701     } ## end for ($i = 0 ; $i <= $#sub...
5702 } ## end sub print_trace
5703
5704 =head2 dump_trace(skip[,count])
5705
5706 Actually collect the traceback information available via C<caller()>. It does
5707 some filtering and cleanup of the data, but mostly it just collects it to
5708 make C<print_trace()>'s job easier.
5709
5710 C<skip> defines the number of stack frames to be skipped, working backwards
5711 from the most current. C<count> determines the total number of frames to
5712 be returned; all of them (well, the first 10^9) are returned if C<count>
5713 is omitted.
5714
5715 This routine returns a list of hashes, from most-recent to least-recent
5716 stack frame. Each has the following keys and values:
5717
5718 =over 4
5719
5720 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5721
5722 =item * C<sub> - subroutine name, or C<eval> information
5723
5724 =item * C<args> - undef, or a reference to an array of arguments
5725
5726 =item * C<file> - the file in which this item was defined (if any)
5727
5728 =item * C<line> - the line on which it was defined
5729
5730 =back
5731
5732 =cut
5733
5734 sub dump_trace {
5735
5736     # How many levels to skip.
5737     my $skip = shift;
5738
5739     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5740     # it's unlikely that we'll have more than a billion stack frames. If you
5741     # do, you've got an awfully big machine...)
5742     my $count = shift || 1e9;
5743
5744     # We increment skip because caller(1) is the first level *back* from
5745     # the current one.  Add $skip to the count of frames so we have a
5746     # simple stop criterion, counting from $skip to $count+$skip.
5747     $skip++;
5748     $count += $skip;
5749
5750     # These variables are used to capture output from caller();
5751     my ( $p, $file, $line, $sub, $h, $context );
5752
5753     my ( $e, $r, @a, @sub, $args );
5754
5755     # XXX Okay... why'd we do that?
5756     my $nothard = not $frame & 8;
5757     local $frame = 0;
5758
5759     # Do not want to trace this.
5760     my $otrace = $trace;
5761     $trace = 0;
5762
5763     # Start out at the skip count.
5764     # If we haven't reached the number of frames requested, and caller() is
5765     # still returning something, stay in the loop. (If we pass the requested
5766     # number of stack frames, or we run out - caller() returns nothing - we
5767     # quit.
5768     # Up the stack frame index to go back one more level each time.
5769     for (
5770         $i = $skip ;
5771         $i < $count
5772         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5773         $i++
5774       )
5775     {
5776
5777         # Go through the arguments and save them for later.
5778         @a = ();
5779         for $arg (@args) {
5780             my $type;
5781             if ( not defined $arg ) {    # undefined parameter
5782                 push @a, "undef";
5783             }
5784
5785             elsif ( $nothard and tied $arg ) {    # tied parameter
5786                 push @a, "tied";
5787             }
5788             elsif ( $nothard and $type = ref $arg ) {    # reference
5789                 push @a, "ref($type)";
5790             }
5791             else {                                       # can be stringified
5792                 local $_ =
5793                   "$arg";    # Safe to stringify now - should not call f().
5794
5795                 # Backslash any single-quotes or backslashes.
5796                 s/([\'\\])/\\$1/g;
5797
5798                 # Single-quote it unless it's a number or a colon-separated
5799                 # name.
5800                 s/(.*)/'$1'/s
5801                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5802
5803                 # Turn high-bit characters into meta-whatever.
5804                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5805
5806                 # Turn control characters into ^-whatever.
5807                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5808
5809                 push( @a, $_ );
5810             } ## end else [ if (not defined $arg)
5811         } ## end for $arg (@args)
5812
5813         # If context is true, this is array (@)context.
5814         # If context is false, this is scalar ($) context.
5815         # If neither, context isn't defined. (This is apparently a 'can't
5816         # happen' trap.)
5817         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5818
5819         # if the sub has args ($h true), make an anonymous array of the
5820         # dumped args.
5821         $args = $h ? [@a] : undef;
5822
5823         # remove trailing newline-whitespace-semicolon-end of line sequence
5824         # from the eval text, if any.
5825         $e =~ s/\n\s*\;\s*\Z// if $e;
5826
5827         # Escape backslashed single-quotes again if necessary.
5828         $e =~ s/([\\\'])/\\$1/g if $e;
5829
5830         # if the require flag is true, the eval text is from a require.
5831         if ($r) {
5832             $sub = "require '$e'";
5833         }
5834
5835         # if it's false, the eval text is really from an eval.
5836         elsif ( defined $r ) {
5837             $sub = "eval '$e'";
5838         }
5839
5840         # If the sub is '(eval)', this is a block eval, meaning we don't
5841         # know what the eval'ed text actually was.
5842         elsif ( $sub eq '(eval)' ) {
5843             $sub = "eval {...}";
5844         }
5845
5846         # Stick the collected information into @sub as an anonymous hash.
5847         push(
5848             @sub,
5849             {
5850                 context => $context,
5851                 sub     => $sub,
5852                 args    => $args,
5853                 file    => $file,
5854                 line    => $line
5855             }
5856         );
5857
5858         # Stop processing frames if the user hit control-C.
5859         last if $signal;
5860     } ## end for ($i = $skip ; $i < ...
5861
5862     # Restore the trace value again.
5863     $trace = $otrace;
5864     @sub;
5865 } ## end sub dump_trace
5866
5867 =head2 C<action()>
5868
5869 C<action()> takes input provided as the argument to an add-action command,
5870 either pre- or post-, and makes sure it's a complete command. It doesn't do
5871 any fancy parsing; it just keeps reading input until it gets a string
5872 without a trailing backslash.
5873
5874 =cut
5875
5876 sub action {
5877     my $action = shift;
5878
5879     while ( $action =~ s/\\$// ) {
5880
5881         # We have a backslash on the end. Read more.
5882         $action .= &gets;
5883     } ## end while ($action =~ s/\\$//)
5884
5885     # Return the assembled action.
5886     $action;
5887 } ## end sub action
5888
5889 =head2 unbalanced
5890
5891 This routine mostly just packages up a regular expression to be used
5892 to check that the thing it's being matched against has properly-matched
5893 curly braces.
5894
5895 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5896 speeds things up by only creating the qr//'ed expression once; if it's
5897 already defined, we don't try to define it again. A speed hack.
5898
5899 =cut
5900
5901 sub unbalanced {
5902
5903     # I hate using globals!
5904     $balanced_brace_re ||= qr{
5905         ^ \{
5906              (?:
5907                  (?> [^{}] + )              # Non-parens without backtracking
5908                 |
5909                  (??{ $balanced_brace_re }) # Group with matching parens
5910               ) *
5911           \} $
5912    }x;
5913     return $_[0] !~ m/$balanced_brace_re/;
5914 } ## end sub unbalanced
5915
5916 =head2 C<gets()>
5917
5918 C<gets()> is a primitive (very primitive) routine to read continuations.
5919 It was devised for reading continuations for actions.
5920 it just reads more input with C<readline()> and returns it.
5921
5922 =cut
5923
5924 sub gets {
5925     &readline("cont: ");
5926 }
5927
5928 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5929
5930 The C<system()> function assumes that it can just go ahead and use STDIN and
5931 STDOUT, but under the debugger, we want it to use the debugger's input and
5932 outout filehandles.
5933
5934 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5935 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5936 and then puts everything back again.
5937
5938 =cut
5939
5940 sub system {
5941
5942     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5943     # some non-Unix systems can do system() but have problems with fork().
5944     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5945     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5946     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5947     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5948
5949     # XXX: using csh or tcsh destroys sigint retvals!
5950     system(@_);
5951     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5952     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5953     close(SAVEIN);
5954     close(SAVEOUT);
5955
5956     # most of the $? crud was coping with broken cshisms
5957     if ( $? >> 8 ) {
5958         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5959     }
5960     elsif ($?) {
5961         &warn(
5962             "(Command died of SIG#",
5963             ( $? & 127 ),
5964             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5965             ")", "\n"
5966         );
5967     } ## end elsif ($?)
5968
5969     return $?;
5970
5971 } ## end sub system
5972
5973 =head1 TTY MANAGEMENT
5974
5975 The subs here do some of the terminal management for multiple debuggers.
5976
5977 =head2 setterm
5978
5979 Top-level function called when we want to set up a new terminal for use
5980 by the debugger.
5981
5982 If the C<noTTY> debugger option was set, we'll either use the terminal
5983 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
5984 to find one. If we're a forked debugger, we call C<resetterm> to try to
5985 get a whole new terminal if we can.
5986
5987 In either case, we set up the terminal next. If the C<ReadLine> option was
5988 true, we'll get a C<Term::ReadLine> object for the current terminal and save
5989 the appropriate attributes. We then
5990
5991 =cut
5992
5993 sub setterm {
5994
5995     # Load Term::Readline, but quietly; don't debug it and don't trace it.
5996     local $frame = 0;
5997     local $doret = -2;
5998     eval { require Term::ReadLine } or die $@;
5999
6000     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6001     if ($notty) {
6002         if ($tty) {
6003             my ( $i, $o ) = split $tty, /,/;
6004             $o = $i unless defined $o;
6005             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
6006             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
6007             $IN  = \*IN;
6008             $OUT = \*OUT;
6009             my $sel = select($OUT);
6010             $| = 1;
6011             select($sel);
6012         } ## end if ($tty)
6013
6014         # We don't have a TTY - try to find one via Term::Rendezvous.
6015         else {
6016             eval "require Term::Rendezvous;" or die;
6017
6018             # See if we have anything to pass to Term::Rendezvous.
6019             # Use $HOME/.perldbtty$$ if not.
6020             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6021
6022             # Rendezvous and get the filehandles.
6023             my $term_rv = new Term::Rendezvous $rv;
6024             $IN  = $term_rv->IN;
6025             $OUT = $term_rv->OUT;
6026         } ## end else [ if ($tty)
6027     } ## end if ($notty)
6028
6029     # We're a daughter debugger. Try to fork off another TTY.
6030     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6031         resetterm(2);
6032     }
6033
6034     # If we shouldn't use Term::ReadLine, don't.
6035     if ( !$rl ) {
6036         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6037     }
6038
6039     # We're using Term::ReadLine. Get all the attributes for this terminal.
6040     else {
6041         $term = new Term::ReadLine 'perldb', $IN, $OUT;
6042
6043         $rl_attribs = $term->Attribs;
6044         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6045           if defined $rl_attribs->{basic_word_break_characters}
6046           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6047         $rl_attribs->{special_prefixes} = '$@&%';
6048         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6049         $rl_attribs->{completion_function} = \&db_complete;
6050     } ## end else [ if (!$rl)
6051
6052     # Set up the LINEINFO filehandle.
6053     $LINEINFO = $OUT     unless defined $LINEINFO;
6054     $lineinfo = $console unless defined $lineinfo;
6055
6056     $term->MinLine(2);
6057
6058     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6059         $term->SetHistory(@hist);
6060     }
6061
6062     # XXX Ornaments are turned on unconditionally, which is not
6063     # always a good thing.
6064     ornaments($ornaments) if defined $ornaments;
6065     $term_pid = $$;
6066 } ## end sub setterm
6067
6068 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6069
6070 When the process being debugged forks, or the process invokes a command
6071 via C<system()> which starts a new debugger, we need to be able to get a new
6072 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6073 fight over the terminal, and you can never quite be sure who's going to get the
6074 input you're typing.
6075
6076 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6077 is tasked with doing all the necessary operating system mojo to get a new
6078 TTY (and probably another window) and to direct the new debugger to read and
6079 write there.
6080
6081 The debugger provides C<get_fork_TTY> functions which work for X Windows and
6082 OS/2. Other systems are not supported. You are encouraged to write
6083 C<get_fork_TTY> functions which work for I<your> platform and contribute them.
6084
6085 =head3 C<xterm_get_fork_TTY>
6086
6087 This function provides the C<get_fork_TTY> function for X windows. If a
6088 program running under the debugger forks, a new <xterm> window is opened and
6089 the subsidiary debugger is directed there.
6090
6091 The C<open()> call is of particular note here. We have the new C<xterm>
6092 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6093 command (which prints the device name of the TTY we'll want to use for input
6094 and output to STDOUT, then C<sleep> for a very long time, routing this output
6095 to file number 3. This way we can simply read from the <XT> filehandle (which
6096 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6097
6098 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6099 properly set up.
6100
6101 =cut
6102
6103 sub xterm_get_fork_TTY {
6104     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6105     open XT,
6106 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6107  sleep 10000000' |];
6108
6109     # Get the output from 'tty' and clean it up a little.
6110     my $tty = <XT>;
6111     chomp $tty;
6112
6113     $pidprompt = '';    # Shown anyway in titlebar
6114
6115     # There's our new TTY.
6116     return $tty;
6117 } ## end sub xterm_get_fork_TTY
6118
6119 =head3 C<os2_get_fork_TTY>
6120
6121 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6122
6123 =cut
6124
6125 # This example function resets $IN, $OUT itself
6126 sub os2_get_fork_TTY {
6127     local $^F = 40;    # XXXX Fixme!
6128     local $\  = '';
6129     my ( $in1, $out1, $in2, $out2 );
6130
6131     # Having -d in PERL5OPT would lead to a disaster...
6132     local $ENV{PERL5OPT} = $ENV{PERL5OPT} if $ENV{PERL5OPT};
6133     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\b//  if $ENV{PERL5OPT};
6134     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\B/-/ if $ENV{PERL5OPT};
6135     print $OUT "Making kid PERL5OPT->`$ENV{PERL5OPT}'.\n" if $ENV{PERL5OPT};
6136     local $ENV{PERL5LIB} = $ENV{PERL5LIB} ? $ENV{PERL5LIB} : $ENV{PERLLIB};
6137     $ENV{PERL5LIB} = '' unless defined $ENV{PERL5LIB};
6138     $ENV{PERL5LIB} = join ';', @ini_INC, split /;/, $ENV{PERL5LIB};
6139     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6140     my @args;
6141
6142     if (
6143             pipe $in1, $out1
6144         and pipe $in2, $out2
6145
6146         # system P_SESSION will fail if there is another process
6147         # in the same session with a "dependent" asynchronous child session.
6148         and @args = (
6149             $rl, fileno $in1, fileno $out2, "Daughter Perl debugger $pids $name"
6150         )
6151         and (
6152             ( $kpid = CORE::system 4, $^X, '-we',
6153                 <<'ES', @args ) >= 0    # P_SESSION
6154 END {sleep 5 unless $loaded}
6155 BEGIN {open STDIN,  '</dev/con' or warn "reopen stdin: $!"}
6156 use OS2::Process;
6157
6158 my ($rl, $in) = (shift, shift);        # Read from $in and pass through
6159 set_title pop;
6160 system P_NOWAIT, $^X, '-we', <<EOS or die "Cannot start a grandkid";
6161   open IN, '<&=$in' or die "open <&=$in: \$!";
6162   \$| = 1; print while sysread IN, \$_, 1<<16;
6163 EOS
6164
6165 my $out = shift;
6166 open OUT, ">&=$out" or die "Cannot open &=$out for writing: $!";
6167 select OUT;    $| = 1;
6168 require Term::ReadKey if $rl;
6169 Term::ReadKey::ReadMode(4) if $rl; # Nodelay on kbd.  Pipe is automatically nodelay...
6170 print while sysread STDIN, $_, 1<<($rl ? 16 : 0);
6171 ES
6172             or warn "system P_SESSION: $!, $^E" and 0
6173         )
6174         and close $in1
6175         and close $out2
6176       )
6177     {
6178         $pidprompt = '';    # Shown anyway in titlebar
6179         reset_IN_OUT( $in2, $out1 );
6180         $tty = '*reset*';
6181         return '';          # Indicate that reset_IN_OUT is called
6182     } ## end if (pipe $in1, $out1 and...
6183     return;
6184 } ## end sub os2_get_fork_TTY
6185
6186 =head2 C<create_IN_OUT($flags)>
6187
6188 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6189 try to diagnose why.
6190
6191 Flags are:
6192
6193 =over 4
6194
6195 =item * 1 - Don't know how to create a new TTY.
6196
6197 =item * 2 - Debugger has forked, but we can't get a new TTY.
6198
6199 =item * 4 - standard debugger startup is happening.
6200
6201 =back
6202
6203 =cut
6204
6205 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6206
6207     # If we know how to get a new TTY, do it! $in will have
6208     # the TTY name if get_fork_TTY works.
6209     my $in = &get_fork_TTY if defined &get_fork_TTY;
6210
6211     # It used to be that
6212     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6213
6214     if ( not defined $in ) {
6215         my $why = shift;
6216
6217         # We don't know how.
6218         print_help(<<EOP) if $why == 1;
6219 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6220 EOP
6221
6222         # Forked debugger.
6223         print_help(<<EOP) if $why == 2;
6224 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6225   This may be an asynchronous session, so the parent debugger may be active.
6226 EOP
6227
6228         # Note that both debuggers are fighting over the same input.
6229         print_help(<<EOP) if $why != 4;
6230   Since two debuggers fight for the same TTY, input is severely entangled.
6231
6232 EOP
6233         print_help(<<EOP);
6234   I know how to switch the output to a different window in xterms
6235   and OS/2 consoles only.  For a manual switch, put the name of the created I<TTY>
6236   in B<\$DB::fork_TTY>, or define a function B<DB::get_fork_TTY()> returning this.
6237
6238   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6239   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6240
6241 EOP
6242     } ## end if (not defined $in)
6243     elsif ( $in ne '' ) {
6244         TTY($in);
6245     }
6246     else {
6247         $console = '';    # Indicate no need to open-from-the-console
6248     }
6249     undef $fork_TTY;
6250 } ## end sub create_IN_OUT
6251
6252 =head2 C<resetterm>
6253
6254 Handles rejiggering the prompt when we've forked off a new debugger.
6255
6256 If the new debugger happened because of a C<system()> that invoked a
6257 program under the debugger, the arrow between the old pid and the new
6258 in the prompt has I<two> dashes instead of one.
6259
6260 We take the current list of pids and add this one to the end. If there
6261 isn't any list yet, we make one up out of the initial pid associated with
6262 the terminal and our new pid, sticking an arrow (either one-dashed or
6263 two dashed) in between them.
6264
6265 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6266 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6267 and try to do that.
6268
6269 =cut
6270
6271 sub resetterm {    # We forked, so we need a different TTY
6272
6273     # Needs to be passed to create_IN_OUT() as well.
6274     my $in = shift;
6275
6276     # resetterm(2): got in here because of a system() starting a debugger.
6277     # resetterm(1): just forked.
6278     my $systemed = $in > 1 ? '-' : '';
6279
6280     # If there's already a list of pids, add this to the end.
6281     if ($pids) {
6282         $pids =~ s/\]/$systemed->$$]/;
6283     }
6284
6285     # No pid list. Time to make one.
6286     else {
6287         $pids = "[$term_pid->$$]";
6288     }
6289
6290     # The prompt we're going to be using for this debugger.
6291     $pidprompt = $pids;
6292
6293     # We now 0wnz this terminal.
6294     $term_pid = $$;
6295
6296     # Just return if we're not supposed to try to create a new TTY.
6297     return unless $CreateTTY & $in;
6298
6299     # Try to create a new IN/OUT pair.
6300     create_IN_OUT($in);
6301 } ## end sub resetterm
6302
6303 =head2 C<readline>
6304
6305 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6306 the next line, print a message saying we got it, add it to the terminal
6307 history (if possible), and return it.
6308
6309 If there's nothing in the typeahead buffer, check the command filehandle stack.
6310 If there are any filehandles there, read from the last one, and return the line
6311 if we got one. If not, we pop the filehandle off and close it, and try the
6312 next one up the stack.
6313
6314 If we've emptied the filehandle stack, we check to see if we've got a socket
6315 open, and we read that and return it if we do. If we don't, we just call the
6316 core C<readline()> and return its value.
6317
6318 =cut
6319
6320 sub readline {
6321
6322     # Localize to prevent it from being smashed in the program being debugged.
6323     local $.;
6324
6325     # Pull a line out of the typeahead if there's stuff there.
6326     if (@typeahead) {
6327
6328         # How many lines left.
6329         my $left = @typeahead;
6330
6331         # Get the next line.
6332         my $got = shift @typeahead;
6333
6334         # Print a message saying we got input from the typeahead.
6335         local $\ = '';
6336         print $OUT "auto(-$left)", shift, $got, "\n";
6337
6338         # Add it to the terminal history (if possible).
6339         $term->AddHistory($got)
6340           if length($got) > 1
6341           and defined $term->Features->{addHistory};
6342         return $got;
6343     } ## end if (@typeahead)
6344
6345     # We really need to read some input. Turn off entry/exit trace and
6346     # return value printing.
6347     local $frame = 0;
6348     local $doret = -2;
6349
6350     # If there are stacked filehandles to read from ...
6351     while (@cmdfhs) {
6352
6353         # Read from the last one in the stack.
6354         my $line = CORE::readline( $cmdfhs[-1] );
6355
6356         # If we got a line ...
6357         defined $line
6358           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6359           : close pop @cmdfhs;                            # Pop and close
6360     } ## end while (@cmdfhs)
6361
6362     # Nothing on the filehandle stack. Socket?
6363     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6364
6365         # Send anyting we have to send.
6366         $OUT->write( join( '', @_ ) );
6367
6368         # Receive anything there is to receive.
6369         $stuff;
6370         my $stuff = '';
6371         my $buf;
6372         do {
6373             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6374                                             # XXX Don't know. You tell me.
6375         } while length $buf and ($stuff .= $buf) !~ /\n/;
6376
6377         # What we got.
6378         $stuff;
6379     } ## end if (ref $OUT and UNIVERSAL::isa...
6380
6381     # No socket. Just read from the terminal.
6382     else {
6383         $term->readline(@_);
6384     }
6385 } ## end sub readline
6386
6387 =head1 OPTIONS SUPPORT ROUTINES
6388
6389 These routines handle listing and setting option values.
6390
6391 =head2 C<dump_option> - list the current value of an option setting
6392
6393 This routine uses C<option_val> to look up the value for an option.
6394 It cleans up escaped single-quotes and then displays the option and
6395 its value.
6396
6397 =cut
6398
6399 sub dump_option {
6400     my ( $opt, $val ) = @_;
6401     $val = option_val( $opt, 'N/A' );
6402     $val =~ s/([\\\'])/\\$1/g;
6403     printf $OUT "%20s = '%s'\n", $opt, $val;
6404 } ## end sub dump_option
6405
6406 sub options2remember {
6407     foreach my $k (@RememberOnROptions) {
6408         $option{$k} = option_val( $k, 'N/A' );
6409     }
6410     return %option;
6411 }
6412
6413 =head2 C<option_val> - find the current value of an option
6414
6415 This can't just be a simple hash lookup because of the indirect way that
6416 the option values are stored. Some are retrieved by calling a subroutine,
6417 some are just variables.
6418
6419 You must supply a default value to be used in case the option isn't set.
6420
6421 =cut
6422
6423 sub option_val {
6424     my ( $opt, $default ) = @_;
6425     my $val;
6426
6427     # Does this option exist, and is it a variable?
6428     # If so, retrieve the value via the value in %optionVars.
6429     if (    defined $optionVars{$opt}
6430         and defined ${ $optionVars{$opt} } )
6431     {
6432         $val = ${ $optionVars{$opt} };
6433     }
6434
6435     # Does this option exist, and it's a subroutine?
6436     # If so, call the subroutine via the ref in %optionAction
6437     # and capture the value.
6438     elsif ( defined $optionAction{$opt}
6439         and defined &{ $optionAction{$opt} } )
6440     {
6441         $val = &{ $optionAction{$opt} }();
6442     }
6443
6444     # If there's an action or variable for the supplied option,
6445     # but no value was set, use the default.
6446     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6447         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6448     {
6449         $val = $default;
6450     }
6451
6452     # Otherwise, do the simple hash lookup.
6453     else {
6454         $val = $option{$opt};
6455     }
6456
6457     # If the value isn't defined, use the default.
6458     # Then return whatever the value is.
6459     $val = $default unless defined $val;
6460     $val;
6461 } ## end sub option_val
6462
6463 =head2 C<parse_options>
6464
6465 Handles the parsing and execution of option setting/displaying commands.
6466
6467 An option entered by itself is assumed to be I<set me to 1> (the default value)
6468 if the option is a boolean one. If not, the user is prompted to enter a valid
6469 value or to query the current value (via C<option? >).
6470
6471 If C<option=value> is entered, we try to extract a quoted string from the
6472 value (if it is quoted). If it's not, we just use the whole value as-is.
6473
6474 We load any modules required to service this option, and then we set it: if
6475 it just gets stuck in a variable, we do that; if there's a subroutine to
6476 handle setting the option, we call that.
6477
6478 Finally, if we're running in interactive mode, we display the effect of the
6479 user's command back to the terminal, skipping this if we're setting things
6480 during initialization.
6481
6482 =cut
6483
6484 sub parse_options {
6485     local ($_) = @_;
6486     local $\ = '';
6487
6488     # These options need a value. Don't allow them to be clobbered by accident.
6489     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6490       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6491       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6492     };
6493
6494     while (length) {
6495         my $val_defaulted;
6496
6497         # Clean off excess leading whitespace.
6498         s/^\s+// && next;
6499
6500         # Options are always all word characters, followed by a non-word
6501         # separator.
6502         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6503         my ( $opt, $sep ) = ( $1, $2 );
6504
6505         # Make sure that such an option exists.
6506         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6507           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6508
6509         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6510         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6511         my $val;
6512
6513         # '?' as separator means query, but must have whitespace after it.
6514         if ( "?" eq $sep ) {
6515             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6516               last
6517               if /^\S/;
6518
6519             #&dump_option($opt);
6520         } ## end if ("?" eq $sep)
6521
6522         # Separator is whitespace (or just a carriage return).
6523         # They're going for a default, which we assume is 1.
6524         elsif ( $sep !~ /\S/ ) {
6525             $val_defaulted = 1;
6526             $val           = "1";   #  this is an evil default; make 'em set it!
6527         }
6528
6529         # Separator is =. Trying to set a value.
6530         elsif ( $sep eq "=" ) {
6531
6532             # If quoted, extract a quoted string.
6533             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6534                 my $quote = $1;
6535                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6536             }
6537
6538             # Not quoted. Use the whole thing. Warn about 'option='.
6539             else {
6540                 s/^(\S*)//;
6541                 $val = $1;
6542                 print OUT qq(Option better cleared using $opt=""\n)
6543                   unless length $val;
6544             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6545
6546         } ## end elsif ($sep eq "=")
6547
6548         # "Quoted" with [], <>, or {}.
6549         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6550             my ($end) =
6551               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6552             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6553               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6554             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6555         } ## end else [ if ("?" eq $sep)
6556
6557         # Exclude non-booleans from getting set to 1 by default.
6558         if ( $opt_needs_val{$option} && $val_defaulted ) {
6559             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6560             print $OUT
6561 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6562             next;
6563         } ## end if ($opt_needs_val{$option...
6564
6565         # Save the option value.
6566         $option{$option} = $val if defined $val;
6567
6568         # Load any module that this option requires.
6569         eval qq{
6570                 local \$frame = 0;
6571                 local \$doret = -2;
6572                 require '$optionRequire{$option}';
6573                 1;
6574                } || die    # XXX: shouldn't happen
6575           if defined $optionRequire{$option}
6576           && defined $val;
6577
6578         # Set it.
6579         # Stick it in the proper variable if it goes in a variable.
6580         ${ $optionVars{$option} } = $val
6581           if defined $optionVars{$option}
6582           && defined $val;
6583
6584         # Call the appropriate sub if it gets set via sub.
6585         &{ $optionAction{$option} }($val)
6586           if defined $optionAction{$option}
6587           && defined &{ $optionAction{$option} }
6588           && defined $val;
6589
6590         # Not initialization - echo the value we set it to.
6591         dump_option($option) unless $OUT eq \*STDERR;
6592     } ## end while (length)
6593 } ## end sub parse_options
6594
6595 =head1 RESTART SUPPORT
6596
6597 These routines are used to store (and restore) lists of items in environment
6598 variables during a restart.
6599
6600 =head2 set_list
6601
6602 Set_list packages up items to be stored in a set of environment variables
6603 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6604 the values). Values outside the standard ASCII charset are stored by encoding
6605 then as hexadecimal values.
6606
6607 =cut
6608
6609 sub set_list {
6610     my ( $stem, @list ) = @_;
6611     my $val;
6612
6613     # VAR_n: how many we have. Scalar assignment gets the number of items.
6614     $ENV{"${stem}_n"} = @list;
6615
6616     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6617     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6618     for $i ( 0 .. $#list ) {
6619         $val = $list[$i];
6620         $val =~ s/\\/\\\\/g;
6621         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6622         $ENV{"${stem}_$i"} = $val;
6623     } ## end for $i (0 .. $#list)
6624 } ## end sub set_list
6625
6626 =head2 get_list
6627
6628 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6629 back, and then pull VAR_0, VAR_1. etc. back out.
6630
6631 =cut
6632
6633 sub get_list {
6634     my $stem = shift;
6635     my @list;
6636     my $n = delete $ENV{"${stem}_n"};
6637     my $val;
6638     for $i ( 0 .. $n - 1 ) {
6639         $val = delete $ENV{"${stem}_$i"};
6640         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6641         push @list, $val;
6642     }
6643     @list;
6644 } ## end sub get_list
6645
6646 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6647
6648 =head2 catch()
6649
6650 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6651 set an already-existing global scalar variable to a constant value. This
6652 avoids allocating any memory possibly in the middle of something that will
6653 get all confused if we do, particularly under I<unsafe signals>.
6654
6655 =cut
6656
6657 sub catch {
6658     $signal = 1;
6659     return;    # Put nothing on the stack - malloc/free land!
6660 }
6661
6662 =head2 C<warn()>
6663
6664 C<warn> emits a warning, by joining together its arguments and printing
6665 them, with couple of fillips.
6666
6667 If the composited message I<doesn't> end with a newline, we automatically
6668 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6669 to be set to the filehandle to be used to output warnings; it makes no
6670 assumptions about what filehandles are available.
6671
6672 =cut
6673
6674 sub warn {
6675     my ($msg) = join( "", @_ );
6676     $msg .= ": $!\n" unless $msg =~ /\n$/;
6677     local $\ = '';
6678     print $OUT $msg;
6679 } ## end sub warn
6680
6681 =head1 INITIALIZATION TTY SUPPORT
6682
6683 =head2 C<reset_IN_OUT>
6684
6685 This routine handles restoring the debugger's input and output filehandles
6686 after we've tried and failed to move them elsewhere.  In addition, it assigns
6687 the debugger's output filehandle to $LINEINFO if it was already open there.
6688
6689 =cut
6690
6691 sub reset_IN_OUT {
6692     my $switch_li = $LINEINFO eq $OUT;
6693
6694     # If there's a term and it's able to get a new tty, try to get one.
6695     if ( $term and $term->Features->{newTTY} ) {
6696         ( $IN, $OUT ) = ( shift, shift );
6697         $term->newTTY( $IN, $OUT );
6698     }
6699
6700     # This term can't get a new tty now. Better luck later.
6701     elsif ($term) {
6702         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6703     }
6704
6705     # Set the filehndles up as they were.
6706     else {
6707         ( $IN, $OUT ) = ( shift, shift );
6708     }
6709
6710     # Unbuffer the output filehandle.
6711     my $o = select $OUT;
6712     $| = 1;
6713     select $o;
6714
6715     # Point LINEINFO to the same output filehandle if it was there before.
6716     $LINEINFO = $OUT if $switch_li;
6717 } ## end sub reset_IN_OUT
6718
6719 =head1 OPTION SUPPORT ROUTINES
6720
6721 The following routines are used to process some of the more complicated
6722 debugger options.
6723
6724 =head2 C<TTY>
6725
6726 Sets the input and output filehandles to the specified files or pipes.
6727 If the terminal supports switching, we go ahead and do it. If not, and
6728 there's already a terminal in place, we save the information to take effect
6729 on restart.
6730
6731 If there's no terminal yet (for instance, during debugger initialization),
6732 we go ahead and set C<$console> and C<$tty> to the file indicated.
6733
6734 =cut
6735
6736 sub TTY {
6737     if ( @_ and $term and $term->Features->{newTTY} ) {
6738
6739         # This terminal supports switching to a new TTY.
6740         # Can be a list of two files, or on string containing both names,
6741         # comma-separated.
6742         # XXX Should this perhaps be an assignment from @_?
6743         my ( $in, $out ) = shift;
6744         if ( $in =~ /,/ ) {
6745
6746             # Split list apart if supplied.
6747             ( $in, $out ) = split /,/, $in, 2;
6748         }
6749         else {
6750
6751             # Use the same file for both input and output.
6752             $out = $in;
6753         }
6754
6755         # Open file onto the debugger's filehandles, if you can.
6756         open IN,  $in     or die "cannot open `$in' for read: $!";
6757         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6758
6759         # Swap to the new filehandles.
6760         reset_IN_OUT( \*IN, \*OUT );
6761
6762         # Save the setting for later.
6763         return $tty = $in;
6764     } ## end if (@_ and $term and $term...
6765
6766     # Terminal doesn't support new TTY, or doesn't support readline.
6767     # Can't do it now, try restarting.
6768     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6769
6770     # Useful if done through PERLDB_OPTS:
6771     $console = $tty = shift if @_;
6772
6773     # Return whatever the TTY is.
6774     $tty or $console;
6775 } ## end sub TTY
6776
6777 =head2 C<noTTY>
6778
6779 Sets the C<$notty> global, controlling whether or not the debugger tries to
6780 get a terminal to read from. If called after a terminal is already in place,
6781 we save the value to use it if we're restarted.
6782
6783 =cut
6784
6785 sub noTTY {
6786     if ($term) {
6787         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6788     }
6789     $notty = shift if @_;
6790     $notty;
6791 } ## end sub noTTY
6792
6793 =head2 C<ReadLine>
6794
6795 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6796 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6797 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6798 the value in case a restart is done so we can change it then.
6799
6800 =cut
6801
6802 sub ReadLine {
6803     if ($term) {
6804         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6805     }
6806     $rl = shift if @_;
6807     $rl;
6808 } ## end sub ReadLine
6809
6810 =head2 C<RemotePort>
6811
6812 Sets the port that the debugger will try to connect to when starting up.
6813 If the terminal's already been set up, we can't do it, but we remember the
6814 setting in case the user does a restart.
6815
6816 =cut
6817
6818 sub RemotePort {
6819     if ($term) {
6820         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6821     }
6822     $remoteport = shift if @_;
6823     $remoteport;
6824 } ## end sub RemotePort
6825
6826 =head2 C<tkRunning>
6827
6828 Checks with the terminal to see if C<Tk> is running, and returns true or
6829 false. Returns false if the current terminal doesn't support C<readline>.
6830
6831 =cut
6832
6833 sub tkRunning {
6834     if ( ${ $term->Features }{tkRunning} ) {
6835         return $term->tkRunning(@_);
6836     }
6837     else {
6838         local $\ = '';
6839         print $OUT "tkRunning not supported by current ReadLine package.\n";
6840         0;
6841     }
6842 } ## end sub tkRunning
6843
6844 =head2 C<NonStop>
6845
6846 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6847 debugger remembers the setting in case you restart, though.
6848
6849 =cut
6850
6851 sub NonStop {
6852     if ($term) {
6853         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6854           if @_;
6855     }
6856     $runnonstop = shift if @_;
6857     $runnonstop;
6858 } ## end sub NonStop
6859
6860 sub DollarCaretP {
6861     if ($term) {
6862         &warn("Some flag changes could not take effect until next 'R'!\n")
6863           if @_;
6864     }
6865     $^P = parse_DollarCaretP_flags(shift) if @_;
6866     expand_DollarCaretP_flags($^P);
6867 }
6868
6869 sub OnlyAssertions {
6870     if ($term) {
6871         &warn("Too late to set up OnlyAssertions mode, enabled on next 'R'!\n")
6872           if @_;
6873     }
6874     if (@_) {
6875         unless ( defined $ini_assertion ) {
6876             if ($term) {
6877                 &warn("Current Perl interpreter doesn't support assertions");
6878             }
6879             return 0;
6880         }
6881         if (shift) {
6882             unless ($ini_assertion) {
6883                 print "Assertions will be active on next 'R'!\n";
6884                 $ini_assertion = 1;
6885             }
6886             $^P &= ~$DollarCaretP_flags{PERLDBf_SUB};
6887             $^P |= $DollarCaretP_flags{PERLDBf_ASSERTION};
6888         }
6889         else {
6890             $^P |= $DollarCaretP_flags{PERLDBf_SUB};
6891         }
6892     }
6893     !( $^P & $DollarCaretP_flags{PERLDBf_SUB} ) || 0;
6894 }
6895
6896 =head2 C<pager>
6897
6898 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6899 there already.
6900
6901 =cut
6902
6903 sub pager {
6904     if (@_) {
6905         $pager = shift;
6906         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6907     }
6908     $pager;
6909 } ## end sub pager
6910
6911 =head2 C<shellBang>
6912
6913 Sets the shell escape command, and generates a printable copy to be used
6914 in the help.
6915
6916 =cut
6917
6918 sub shellBang {
6919
6920     # If we got an argument, meta-quote it, and add '\b' if it
6921     # ends in a word character.
6922     if (@_) {
6923         $sh = quotemeta shift;
6924         $sh .= "\\b" if $sh =~ /\w$/;
6925     }
6926
6927     # Generate the printable version for the help:
6928     $psh = $sh;    # copy it
6929     $psh =~ s/\\b$//;        # Take off trailing \b if any
6930     $psh =~ s/\\(.)/$1/g;    # De-escape
6931     $psh;                    # return the printable version
6932 } ## end sub shellBang
6933
6934 =head2 C<ornaments>
6935
6936 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
6937 was passed as the argument. (This means you can't override the terminal's
6938 ornaments.)
6939
6940 =cut
6941
6942 sub ornaments {
6943     if ( defined $term ) {
6944
6945         # We don't want to show warning backtraces, but we do want die() ones.
6946         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
6947
6948         # No ornaments if the terminal doesn't support them.
6949         return '' unless $term->Features->{ornaments};
6950         eval { $term->ornaments(@_) } || '';
6951     }
6952
6953     # Use what was passed in if we can't determine it ourselves.
6954     else {
6955         $ornaments = shift;
6956     }
6957 } ## end sub ornaments
6958
6959 =head2 C<recallCommand>
6960
6961 Sets the recall command, and builds a printable version which will appear in
6962 the help text.
6963
6964 =cut
6965
6966 sub recallCommand {
6967
6968     # If there is input, metaquote it. Add '\b' if it ends with a word
6969     # character.
6970     if (@_) {
6971         $rc = quotemeta shift;
6972         $rc .= "\\b" if $rc =~ /\w$/;
6973     }
6974
6975     # Build it into a printable version.
6976     $prc = $rc;    # Copy it
6977     $prc =~ s/\\b$//;        # Remove trailing \b
6978     $prc =~ s/\\(.)/$1/g;    # Remove escapes
6979     $prc;                    # Return the printable version
6980 } ## end sub recallCommand
6981
6982 =head2 C<LineInfo> - where the line number information goes
6983
6984 Called with no arguments, returns the file or pipe that line info should go to.
6985
6986 Called with an argument (a file or a pipe), it opens that onto the
6987 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
6988 file or pipe again to the caller.
6989
6990 =cut
6991
6992 sub LineInfo {
6993     return $lineinfo unless @_;
6994     $lineinfo = shift;
6995
6996     #  If this is a valid "thing to be opened for output", tack a
6997     # '>' onto the front.
6998     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
6999
7000     # If this is a pipe, the stream points to a slave editor.
7001     $slave_editor = ( $stream =~ /^\|/ );
7002
7003     # Open it up and unbuffer it.
7004     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
7005     $LINEINFO = \*LINEINFO;
7006     my $save = select($LINEINFO);
7007     $| = 1;
7008     select($save);
7009
7010     # Hand the file or pipe back again.
7011     $lineinfo;
7012 } ## end sub LineInfo
7013
7014 =head1 COMMAND SUPPORT ROUTINES
7015
7016 These subroutines provide functionality for various commands.
7017
7018 =head2 C<list_modules>
7019
7020 For the C<M> command: list modules loaded and their versions.
7021 Essentially just runs through the keys in %INC, picks each package's
7022 C<$VERSION> variable, gets the file name, and formats the information
7023 for output.
7024
7025 =cut
7026
7027 sub list_modules {    # versions
7028     my %version;
7029     my $file;
7030
7031     # keys are the "as-loaded" name, values are the fully-qualified path
7032     # to the file itself.
7033     for ( keys %INC ) {
7034         $file = $_;                                # get the module name
7035         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7036         s,/,::,g;                                  # change '/' to '::'
7037         s/^perl5db$/DB/;                           # Special case: debugger
7038                                                    # moves to package DB
7039         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7040
7041         # If the package has a $VERSION package global (as all good packages
7042         # should!) decode it and save as partial message.
7043         if ( defined ${ $_ . '::VERSION' } ) {
7044             $version{$file} = "${ $_ . '::VERSION' } from ";
7045         }
7046
7047         # Finish up the message with the file the package came from.
7048         $version{$file} .= $INC{$file};
7049     } ## end for (keys %INC)
7050
7051     # Hey, dumpit() formats a hash nicely, so why not use it?
7052     dumpit( $OUT, \%version );
7053 } ## end sub list_modules
7054
7055 =head2 C<sethelp()>
7056
7057 Sets up the monster string used to format and print the help.
7058
7059 =head3 HELP MESSAGE FORMAT
7060
7061 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7062 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7063 easy to parse and portable, but which still allows the help to be a little
7064 nicer than just plain text.
7065
7066 Essentially, you define the command name (usually marked up with C<< B<> >>
7067 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7068 newline. The descriptive text can also be marked up in the same way. If you
7069 need to continue the descriptive text to another line, start that line with
7070 just tabs and then enter the marked-up text.
7071
7072 If you are modifying the help text, I<be careful>. The help-string parser is
7073 not very sophisticated, and if you don't follow these rules it will mangle the
7074 help beyond hope until you fix the string.
7075
7076 =cut
7077
7078 sub sethelp {
7079
7080     # XXX: make sure there are tabs between the command and explanation,
7081     #      or print_help will screw up your formatting if you have
7082     #      eeevil ornaments enabled.  This is an insane mess.
7083
7084     $help = "
7085 Help is currently only available for the new 5.8 command set.
7086 No help is available for the old command set.
7087 We assume you know what you're doing if you switch to it.
7088
7089 B<T>        Stack trace.
7090 B<s> [I<expr>]    Single step [in I<expr>].
7091 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7092 <B<CR>>        Repeat last B<n> or B<s> command.
7093 B<r>        Return from current subroutine.
7094 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7095         at the specified position.
7096 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7097 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7098 B<l> I<line>        List single I<line>.
7099 B<l> I<subname>    List first window of lines from subroutine.
7100 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7101 B<l>        List next window of lines.
7102 B<->        List previous window of lines.
7103 B<v> [I<line>]    View window around I<line>.
7104 B<.>        Return to the executed line.
7105 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7106         I<filename> may be either the full name of the file, or a regular
7107         expression matching the full file name:
7108         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7109         Evals (with saved bodies) are considered to be filenames:
7110         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7111         (in the order of execution).
7112 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7113 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7114 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7115 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7116 B<t>        Toggle trace mode.
7117 B<t> I<expr>        Trace through execution of I<expr>.
7118 B<b>        Sets breakpoint on current line)
7119 B<b> [I<line>] [I<condition>]
7120         Set breakpoint; I<line> defaults to the current execution line;
7121         I<condition> breaks if it evaluates to true, defaults to '1'.
7122 B<b> I<subname> [I<condition>]
7123         Set breakpoint at first line of subroutine.
7124 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7125 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7126 B<b> B<postpone> I<subname> [I<condition>]
7127         Set breakpoint at first line of subroutine after
7128         it is compiled.
7129 B<b> B<compile> I<subname>
7130         Stop after the subroutine is compiled.
7131 B<B> [I<line>]    Delete the breakpoint for I<line>.
7132 B<B> I<*>             Delete all breakpoints.
7133 B<a> [I<line>] I<command>
7134         Set an action to be done before the I<line> is executed;
7135         I<line> defaults to the current execution line.
7136         Sequence is: check for breakpoint/watchpoint, print line
7137         if necessary, do action, prompt user if necessary,
7138         execute line.
7139 B<a>        Does nothing
7140 B<A> [I<line>]    Delete the action for I<line>.
7141 B<A> I<*>             Delete all actions.
7142 B<w> I<expr>        Add a global watch-expression.
7143 B<w>             Does nothing
7144 B<W> I<expr>        Delete a global watch-expression.
7145 B<W> I<*>             Delete all watch-expressions.
7146 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7147         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7148 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7149 B<x> I<expr>        Evals expression in list context, dumps the result.
7150 B<m> I<expr>        Evals expression in list context, prints methods callable
7151         on the first element of the result.
7152 B<m> I<class>        Prints methods callable via the given class.
7153 B<M>        Show versions of loaded modules.
7154 B<i> I<class>       Prints nested parents of given class.
7155 B<e>         Display current thread id.
7156 B<E>         Display all thread ids the current one will be identified: <n>.
7157 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7158 B<P> Something to do with assertions...
7159
7160 B<<> ?            List Perl commands to run before each prompt.
7161 B<<> I<expr>        Define Perl command to run before each prompt.
7162 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7163 B<< *>                Delete the list of perl commands to run before each prompt.
7164 B<>> ?            List Perl commands to run after each prompt.
7165 B<>> I<expr>        Define Perl command to run after each prompt.
7166 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7167 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7168 B<{> I<db_command>    Define debugger command to run before each prompt.
7169 B<{> ?            List debugger commands to run before each prompt.
7170 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7171 B<{ *>             Delete the list of debugger commands to run before each prompt.
7172 B<$prc> I<number>    Redo a previous command (default previous command).
7173 B<$prc> I<-number>    Redo number'th-to-last command.
7174 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7175         See 'B<O> I<recallCommand>' too.
7176 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7177       . (
7178         $rc eq $sh
7179         ? ""
7180         : "
7181 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7182       ) . "
7183         See 'B<O> I<shellBang>' too.
7184 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7185 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7186 B<rerun>           Rerun session to current position.
7187 B<rerun> I<n>         Rerun session to numbered command.
7188 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7189 B<H> I<-number>    Display last number commands (default all).
7190 B<H> I<*>          Delete complete history.
7191 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7192 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7193 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7194 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7195 I<command>        Execute as a perl statement in current package.
7196 B<R>        Pure-man-restart of debugger, some of debugger state
7197         and command-line options may be lost.
7198         Currently the following settings are preserved:
7199         history, breakpoints and actions, debugger B<O>ptions
7200         and the following command-line options: I<-w>, I<-I>, I<-e>.
7201
7202 B<o> [I<opt>] ...    Set boolean option to true
7203 B<o> [I<opt>B<?>]    Query options
7204 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7205         Set options.  Use quotes in spaces in value.
7206     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7207     I<pager>            program for output of \"|cmd\";
7208     I<tkRunning>            run Tk while prompting (with ReadLine);
7209     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7210     I<inhibit_exit>        Allows stepping off the end of the script.
7211     I<ImmediateStop>        Debugger should stop as early as possible.
7212     I<RemotePort>            Remote hostname:port for remote debugging
7213   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7214     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7215     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7216     I<globPrint>             whether to print contents of globs;
7217     I<DumpDBFiles>         dump arrays holding debugged files;
7218     I<DumpPackages>         dump symbol tables of packages;
7219     I<DumpReused>             dump contents of \"reused\" addresses;
7220     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7221     I<bareStringify>         Do not print the overload-stringified value;
7222   Other options include:
7223     I<PrintRet>        affects printing of return value after B<r> command,
7224     I<frame>        affects printing messages on subroutine entry/exit.
7225     I<AutoTrace>    affects printing messages on possible breaking points.
7226     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7227     I<ornaments>     affects screen appearance of the command line.
7228     I<CreateTTY>     bits control attempts to create a new TTY on events:
7229             1: on fork()    2: debugger is started inside debugger
7230             4: on startup
7231     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7232     You can put additional initialization options I<TTY>, I<noTTY>,
7233     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7234     `B<R>' after you set them).
7235
7236 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7237 B<h>        Summary of debugger commands.
7238 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7239 B<h h>        Long help for debugger commands
7240 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7241         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7242         Set B<\$DB::doccmd> to change viewer.
7243
7244 Type `|h h' for a paged display if this was too hard to read.
7245
7246 ";    # Fix balance of vi % matching: }}}}
7247
7248     #  note: tabs in the following section are not-so-helpful
7249     $summary = <<"END_SUM";
7250 I<List/search source lines:>               I<Control script execution:>
7251   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7252   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7253   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7254   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7255   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7256   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7257 I<Debugger controls:>                        B<L>           List break/watch/actions
7258   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7259   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7260   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7261   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7262   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7263   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7264   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7265   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7266   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7267 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7268   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7269   B<p> I<expr>         Print expression (uses script's current package).
7270   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7271   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7272   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7273   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7274   B<e>     Display thread id     B<E> Display all thread ids.
7275 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7276 END_SUM
7277
7278     # ')}}; # Fix balance of vi % matching
7279
7280     # and this is really numb...
7281     $pre580_help = "
7282 B<T>        Stack trace.
7283 B<s> [I<expr>]    Single step [in I<expr>].
7284 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7285 B<CR>>        Repeat last B<n> or B<s> command.
7286 B<r>        Return from current subroutine.
7287 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7288         at the specified position.
7289 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7290 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7291 B<l> I<line>        List single I<line>.
7292 B<l> I<subname>    List first window of lines from subroutine.
7293 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7294 B<l>        List next window of lines.
7295 B<->        List previous window of lines.
7296 B<w> [I<line>]    List window around I<line>.
7297 B<.>        Return to the executed line.
7298 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7299         I<filename> may be either the full name of the file, or a regular
7300         expression matching the full file name:
7301         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7302         Evals (with saved bodies) are considered to be filenames:
7303         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7304         (in the order of execution).
7305 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7306 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7307 B<L>        List all breakpoints and actions.
7308 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7309 B<t>        Toggle trace mode.
7310 B<t> I<expr>        Trace through execution of I<expr>.
7311 B<b> [I<line>] [I<condition>]
7312         Set breakpoint; I<line> defaults to the current execution line;
7313         I<condition> breaks if it evaluates to true, defaults to '1'.
7314 B<b> I<subname> [I<condition>]
7315         Set breakpoint at first line of subroutine.
7316 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7317 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7318 B<b> B<postpone> I<subname> [I<condition>]
7319         Set breakpoint at first line of subroutine after
7320         it is compiled.
7321 B<b> B<compile> I<subname>
7322         Stop after the subroutine is compiled.
7323 B<d> [I<line>]    Delete the breakpoint for I<line>.
7324 B<D>        Delete all breakpoints.
7325 B<a> [I<line>] I<command>
7326         Set an action to be done before the I<line> is executed;
7327         I<line> defaults to the current execution line.
7328         Sequence is: check for breakpoint/watchpoint, print line
7329         if necessary, do action, prompt user if necessary,
7330         execute line.
7331 B<a> [I<line>]    Delete the action for I<line>.
7332 B<A>        Delete all actions.
7333 B<W> I<expr>        Add a global watch-expression.
7334 B<W>        Delete all watch-expressions.
7335 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7336         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7337 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7338 B<x> I<expr>        Evals expression in list context, dumps the result.
7339 B<m> I<expr>        Evals expression in list context, prints methods callable
7340         on the first element of the result.
7341 B<m> I<class>        Prints methods callable via the given class.
7342
7343 B<<> ?            List Perl commands to run before each prompt.
7344 B<<> I<expr>        Define Perl command to run before each prompt.
7345 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7346 B<>> ?            List Perl commands to run after each prompt.
7347 B<>> I<expr>        Define Perl command to run after each prompt.
7348 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7349 B<{> I<db_command>    Define debugger command to run before each prompt.
7350 B<{> ?            List debugger commands to run before each prompt.
7351 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7352 B<$prc> I<number>    Redo a previous command (default previous command).
7353 B<$prc> I<-number>    Redo number'th-to-last command.
7354 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7355         See 'B<O> I<recallCommand>' too.
7356 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7357       . (
7358         $rc eq $sh
7359         ? ""
7360         : "
7361 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7362       ) . "
7363         See 'B<O> I<shellBang>' too.
7364 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7365 B<H> I<-number>    Display last number commands (default all).
7366 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7367 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7368 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7369 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7370 I<command>        Execute as a perl statement in current package.
7371 B<v>        Show versions of loaded modules.
7372 B<R>        Pure-man-restart of debugger, some of debugger state
7373         and command-line options may be lost.
7374         Currently the following settings are preserved:
7375         history, breakpoints and actions, debugger B<O>ptions
7376         and the following command-line options: I<-w>, I<-I>, I<-e>.
7377
7378 B<O> [I<opt>] ...    Set boolean option to true
7379 B<O> [I<opt>B<?>]    Query options
7380 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7381         Set options.  Use quotes in spaces in value.
7382     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7383     I<pager>            program for output of \"|cmd\";
7384     I<tkRunning>            run Tk while prompting (with ReadLine);
7385     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7386     I<inhibit_exit>        Allows stepping off the end of the script.
7387     I<ImmediateStop>        Debugger should stop as early as possible.
7388     I<RemotePort>            Remote hostname:port for remote debugging
7389   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7390     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7391     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7392     I<globPrint>             whether to print contents of globs;
7393     I<DumpDBFiles>         dump arrays holding debugged files;
7394     I<DumpPackages>         dump symbol tables of packages;
7395     I<DumpReused>             dump contents of \"reused\" addresses;
7396     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7397     I<bareStringify>         Do not print the overload-stringified value;
7398   Other options include:
7399     I<PrintRet>        affects printing of return value after B<r> command,
7400     I<frame>        affects printing messages on subroutine entry/exit.
7401     I<AutoTrace>    affects printing messages on possible breaking points.
7402     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7403     I<ornaments>     affects screen appearance of the command line.
7404     I<CreateTTY>     bits control attempts to create a new TTY on events:
7405             1: on fork()    2: debugger is started inside debugger
7406             4: on startup
7407     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7408     You can put additional initialization options I<TTY>, I<noTTY>,
7409     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7410     `B<R>' after you set them).
7411
7412 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7413 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7414 B<h h>        Summary of debugger commands.
7415 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7416         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7417         Set B<\$DB::doccmd> to change viewer.
7418
7419 Type `|h' for a paged display if this was too hard to read.
7420
7421 ";    # Fix balance of vi % matching: }}}}
7422
7423     #  note: tabs in the following section are not-so-helpful
7424     $pre580_summary = <<"END_SUM";
7425 I<List/search source lines:>               I<Control script execution:>
7426   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7427   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7428   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7429   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7430   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7431   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7432 I<Debugger controls:>                        B<L>           List break/watch/actions
7433   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7434   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7435   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7436   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7437   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7438   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7439   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7440   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7441 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7442   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7443   B<p> I<expr>         Print expression (uses script's current package).
7444   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7445   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7446   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7447   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7448 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7449 END_SUM
7450
7451     # ')}}; # Fix balance of vi % matching
7452
7453 } ## end sub sethelp
7454
7455 =head2 C<print_help()>
7456
7457 Most of what C<print_help> does is just text formatting. It finds the
7458 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7459 terminal control characters to simulate them (courtesy of
7460 C<Term::ReadLine::TermCap>).
7461
7462 =cut
7463
7464 sub print_help {
7465     local $_ = shift;
7466
7467     # Restore proper alignment destroyed by eeevil I<> and B<>
7468     # ornaments: A pox on both their houses!
7469     #
7470     # A help command will have everything up to and including
7471     # the first tab sequence padded into a field 16 (or if indented 20)
7472     # wide.  If it's wider than that, an extra space will be added.
7473     s{
7474         ^                       # only matters at start of line
7475           ( \040{4} | \t )*     # some subcommands are indented
7476           ( < ?                 # so <CR> works
7477             [BI] < [^\t\n] + )  # find an eeevil ornament
7478           ( \t+ )               # original separation, discarded
7479           ( .* )                # this will now start (no earlier) than
7480                                 # column 16
7481     } {
7482         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7483         my $clean = $command;
7484         $clean =~ s/[BI]<([^>]*)>/$1/g;
7485
7486         # replace with this whole string:
7487         ($leadwhite ? " " x 4 : "")
7488       . $command
7489       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7490       . $text;
7491
7492     }mgex;
7493
7494     s{                          # handle bold ornaments
7495        B < ( [^>] + | > ) >
7496     } {
7497           $Term::ReadLine::TermCap::rl_term_set[2]
7498         . $1
7499         . $Term::ReadLine::TermCap::rl_term_set[3]
7500     }gex;
7501
7502     s{                         # handle italic ornaments
7503        I < ( [^>] + | > ) >
7504     } {
7505           $Term::ReadLine::TermCap::rl_term_set[0]
7506         . $1
7507         . $Term::ReadLine::TermCap::rl_term_set[1]
7508     }gex;
7509
7510     local $\ = '';
7511     print $OUT $_;
7512 } ## end sub print_help
7513
7514 =head2 C<fix_less>
7515
7516 This routine does a lot of gyrations to be sure that the pager is C<less>.
7517 It checks for C<less> masquerading as C<more> and records the result in
7518 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7519
7520 =cut
7521
7522 sub fix_less {
7523
7524     # We already know if this is set.
7525     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7526
7527     # Pager is less for sure.
7528     my $is_less = $pager =~ /\bless\b/;
7529     if ( $pager =~ /\bmore\b/ ) {
7530
7531         # Nope, set to more. See what's out there.
7532         my @st_more = stat('/usr/bin/more');
7533         my @st_less = stat('/usr/bin/less');
7534
7535         # is it really less, pretending to be more?
7536              $is_less = @st_more
7537           && @st_less
7538           && $st_more[0] == $st_less[0]
7539           && $st_more[1] == $st_less[1];
7540     } ## end if ($pager =~ /\bmore\b/)
7541
7542     # changes environment!
7543     # 'r' added so we don't do (slow) stats again.
7544     $ENV{LESS} .= 'r' if $is_less;
7545 } ## end sub fix_less
7546
7547 =head1 DIE AND WARN MANAGEMENT
7548
7549 =head2 C<diesignal>
7550
7551 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7552 to debug a debugger problem.
7553
7554 It does its best to report the error that occurred, and then forces the
7555 program, debugger, and everything to die.
7556
7557 =cut
7558
7559 sub diesignal {
7560
7561     # No entry/exit messages.
7562     local $frame = 0;
7563
7564     # No return value prints.
7565     local $doret = -2;
7566
7567     # set the abort signal handling to the default (just terminate).
7568     $SIG{'ABRT'} = 'DEFAULT';
7569
7570     # If we enter the signal handler recursively, kill myself with an
7571     # abort signal (so we just terminate).
7572     kill 'ABRT', $$ if $panic++;
7573
7574     # If we can show detailed info, do so.
7575     if ( defined &Carp::longmess ) {
7576
7577         # Don't recursively enter the warn handler, since we're carping.
7578         local $SIG{__WARN__} = '';
7579
7580         # Skip two levels before reporting traceback: we're skipping
7581         # mydie and confess.
7582         local $Carp::CarpLevel = 2;    # mydie + confess
7583
7584         # Tell us all about it.
7585         &warn( Carp::longmess("Signal @_") );
7586     }
7587
7588     # No Carp. Tell us about the signal as best we can.
7589     else {
7590         local $\ = '';
7591         print $DB::OUT "Got signal @_\n";
7592     }
7593
7594     # Drop dead.
7595     kill 'ABRT', $$;
7596 } ## end sub diesignal
7597
7598 =head2 C<dbwarn>
7599
7600 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7601 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7602
7603 =cut
7604
7605 sub dbwarn {
7606
7607     # No entry/exit trace.
7608     local $frame = 0;
7609
7610     # No return value printing.
7611     local $doret = -2;
7612
7613     # Turn off warn and die handling to prevent recursive entries to this
7614     # routine.
7615     local $SIG{__WARN__} = '';
7616     local $SIG{__DIE__}  = '';
7617
7618     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7619     # done yet), we may not be able to do a require.
7620     eval { require Carp }
7621       if defined $^S;    # If error/warning during compilation,
7622                          # require may be broken.
7623
7624     # Use the core warn() unless Carp loaded OK.
7625     CORE::warn( @_,
7626         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7627       return
7628       unless defined &Carp::longmess;
7629
7630     # Save the current values of $single and $trace, and then turn them off.
7631     my ( $mysingle, $mytrace ) = ( $single, $trace );
7632     $single = 0;
7633     $trace  = 0;
7634
7635     # We can call Carp::longmess without its being "debugged" (which we
7636     # don't want - we just want to use it!). Capture this for later.
7637     my $mess = Carp::longmess(@_);
7638
7639     # Restore $single and $trace to their original values.
7640     ( $single, $trace ) = ( $mysingle, $mytrace );
7641
7642     # Use the debugger's own special way of printing warnings to print
7643     # the stack trace message.
7644     &warn($mess);
7645 } ## end sub dbwarn
7646
7647 =head2 C<dbdie>
7648
7649 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7650 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7651 single stepping and tracing during the call to C<Carp::longmess> to avoid
7652 debugging it - we just want to use it.
7653
7654 If C<dieLevel> is zero, we let the program being debugged handle the
7655 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7656 the debugger takes over all exception handling, printing a backtrace and
7657 displaying the exception via its C<dbwarn()> routine.
7658
7659 =cut
7660
7661 sub dbdie {
7662     local $frame         = 0;
7663     local $doret         = -2;
7664     local $SIG{__DIE__}  = '';
7665     local $SIG{__WARN__} = '';
7666     my $i      = 0;
7667     my $ineval = 0;
7668     my $sub;
7669     if ( $dieLevel > 2 ) {
7670         local $SIG{__WARN__} = \&dbwarn;
7671         &warn(@_);    # Yell no matter what
7672         return;
7673     }
7674     if ( $dieLevel < 2 ) {
7675         die @_ if $^S;    # in eval propagate
7676     }
7677
7678     # The code used to check $^S to see if compiliation of the current thing
7679     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7680     eval { require Carp };
7681
7682     die( @_,
7683         "\nCannot print stack trace, load with -MCarp option to see stack" )
7684       unless defined &Carp::longmess;
7685
7686     # We do not want to debug this chunk (automatic disabling works
7687     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7688     # get the stack trace from Carp::longmess (if possible), restore $signal
7689     # and $trace, and then die with the stack trace.
7690     my ( $mysingle, $mytrace ) = ( $single, $trace );
7691     $single = 0;
7692     $trace  = 0;
7693     my $mess = "@_";
7694     {
7695
7696         package Carp;    # Do not include us in the list
7697         eval { $mess = Carp::longmess(@_); };
7698     }
7699     ( $single, $trace ) = ( $mysingle, $mytrace );
7700     die $mess;
7701 } ## end sub dbdie
7702
7703 =head2 C<warnlevel()>
7704
7705 Set the C<$DB::warnLevel> variable that stores the value of the
7706 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7707 results in the debugger taking over all warning handlers. Setting
7708 C<warnLevel> to zero leaves any warning handlers set up by the program
7709 being debugged in place.
7710
7711 =cut
7712
7713 sub warnLevel {
7714     if (@_) {
7715         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7716         $warnLevel = shift;
7717         if ($warnLevel) {
7718             $SIG{__WARN__} = \&DB::dbwarn;
7719         }
7720         elsif ($prevwarn) {
7721             $SIG{__WARN__} = $prevwarn;
7722         }
7723     } ## end if (@_)
7724     $warnLevel;
7725 } ## end sub warnLevel
7726
7727 =head2 C<dielevel>
7728
7729 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7730 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7731 zero lets you use your own C<die()> handler.
7732
7733 =cut
7734
7735 sub dieLevel {
7736     local $\ = '';
7737     if (@_) {
7738         $prevdie = $SIG{__DIE__} unless $dieLevel;
7739         $dieLevel = shift;
7740         if ($dieLevel) {
7741
7742             # Always set it to dbdie() for non-zero values.
7743             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7744
7745             # No longer exists, so don't try  to use it.
7746             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7747
7748             # If we've finished initialization, mention that stack dumps
7749             # are enabled, If dieLevel is 1, we won't stack dump if we die
7750             # in an eval().
7751             print $OUT "Stack dump during die enabled",
7752               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7753               if $I_m_init;
7754
7755             # XXX This is probably obsolete, given that diehard() is gone.
7756             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7757         } ## end if ($dieLevel)
7758
7759         # Put the old one back if there was one.
7760         elsif ($prevdie) {
7761             $SIG{__DIE__} = $prevdie;
7762             print $OUT "Default die handler restored.\n";
7763         }
7764     } ## end if (@_)
7765     $dieLevel;
7766 } ## end sub dieLevel
7767
7768 =head2 C<signalLevel>
7769
7770 Number three in a series: set C<signalLevel> to zero to keep your own
7771 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7772 takes over and handles them with C<DB::diesignal()>.
7773
7774 =cut
7775
7776 sub signalLevel {
7777     if (@_) {
7778         $prevsegv = $SIG{SEGV} unless $signalLevel;
7779         $prevbus  = $SIG{BUS}  unless $signalLevel;
7780         $signalLevel = shift;
7781         if ($signalLevel) {
7782             $SIG{SEGV} = \&DB::diesignal;
7783             $SIG{BUS}  = \&DB::diesignal;
7784         }
7785         else {
7786             $SIG{SEGV} = $prevsegv;
7787             $SIG{BUS}  = $prevbus;
7788         }
7789     } ## end if (@_)
7790     $signalLevel;
7791 } ## end sub signalLevel
7792
7793 =head1 SUBROUTINE DECODING SUPPORT
7794
7795 These subroutines are used during the C<x> and C<X> commands to try to
7796 produce as much information as possible about a code reference. They use
7797 L<Devel::Peek> to try to find the glob in which this code reference lives
7798 (if it does) - this allows us to actually code references which correspond
7799 to named subroutines (including those aliased via glob assignment).
7800
7801 =head2 C<CvGV_name()>
7802
7803 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7804 via that routine. If this fails, return the reference again (when the
7805 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7806
7807 =cut
7808
7809 sub CvGV_name {
7810     my $in   = shift;
7811     my $name = CvGV_name_or_bust($in);
7812     defined $name ? $name : $in;
7813 }
7814
7815 =head2 C<CvGV_name_or_bust> I<coderef>
7816
7817 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7818 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7819 find a glob for this ref.
7820
7821 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7822
7823 =cut
7824
7825 sub CvGV_name_or_bust {
7826     my $in = shift;
7827     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7828     return unless ref $in;
7829     $in = \&$in;            # Hard reference...
7830     eval { require Devel::Peek; 1 } or return;
7831     my $gv = Devel::Peek::CvGV($in) or return;
7832     *$gv{PACKAGE} . '::' . *$gv{NAME};
7833 } ## end sub CvGV_name_or_bust
7834
7835 =head2 C<find_sub>
7836
7837 A utility routine used in various places; finds the file where a subroutine
7838 was defined, and returns that filename and a line-number range.
7839
7840 Tries to use C<@sub> first; if it can't find it there, it tries building a
7841 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7842 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7843 this way, it brute-force searches C<%sub>, checking for identical references.
7844
7845 =cut
7846
7847 sub find_sub {
7848     my $subr = shift;
7849     $sub{$subr} or do {
7850         return unless defined &$subr;
7851         my $name = CvGV_name_or_bust($subr);
7852         my $data;
7853         $data = $sub{$name} if defined $name;
7854         return $data if defined $data;
7855
7856         # Old stupid way...
7857         $subr = \&$subr;    # Hard reference
7858         my $s;
7859         for ( keys %sub ) {
7860             $s = $_, last if $subr eq \&$_;
7861         }
7862         $sub{$s} if $s;
7863       } ## end do
7864 } ## end sub find_sub
7865
7866 =head2 C<methods>
7867
7868 A subroutine that uses the utility function C<methods_via> to find all the
7869 methods in the class corresponding to the current reference and in
7870 C<UNIVERSAL>.
7871
7872 =cut
7873
7874 sub methods {
7875
7876     # Figure out the class - either this is the class or it's a reference
7877     # to something blessed into that class.
7878     my $class = shift;
7879     $class = ref $class if ref $class;
7880
7881     local %seen;
7882
7883     # Show the methods that this class has.
7884     methods_via( $class, '', 1 );
7885
7886     # Show the methods that UNIVERSAL has.
7887     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7888 } ## end sub methods
7889
7890 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7891
7892 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7893 all the parent class methods. C<$class> is the name of the next class to
7894 try; C<$prefix> is the message prefix, which gets built up as we go up the
7895 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7896 higher in the C<@ISA> tree, 0 if we should stop.
7897
7898 =cut
7899
7900 sub methods_via {
7901
7902     # If we've processed this class already, just quit.
7903     my $class = shift;
7904     return if $seen{$class}++;
7905
7906     # This is a package that is contributing the methods we're about to print.
7907     my $prefix  = shift;
7908     my $prepend = $prefix ? "via $prefix: " : '';
7909
7910     my $name;
7911     for $name (
7912
7913         # Keep if this is a defined subroutine in this class.
7914         grep { defined &{ ${"${class}::"}{$_} } }
7915
7916         # Extract from all the symbols in this class.
7917         sort keys %{"${class}::"}
7918       )
7919     {
7920
7921         # If we printed this already, skip it.
7922         next if $seen{$name}++;
7923
7924         # Print the new method name.
7925         local $\ = '';
7926         local $, = '';
7927         print $DB::OUT "$prepend$name\n";
7928     } ## end for $name (grep { defined...
7929
7930     # If the $crawl_upward argument is false, just quit here.
7931     return unless shift;
7932
7933     # $crawl_upward true: keep going up the tree.
7934     # Find all the classes this one is a subclass of.
7935     for $name ( @{"${class}::ISA"} ) {
7936
7937         # Set up the new prefix.
7938         $prepend = $prefix ? $prefix . " -> $name" : $name;
7939
7940         # Crawl up the tree and keep trying to crawl up.
7941         methods_via( $name, $prepend, 1 );
7942     }
7943 } ## end sub methods_via
7944
7945 =head2 C<setman> - figure out which command to use to show documentation
7946
7947 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
7948
7949 =cut
7950
7951 sub setman {
7952     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
7953       ? "man"         # O Happy Day!
7954       : "perldoc";    # Alas, poor unfortunates
7955 } ## end sub setman
7956
7957 =head2 C<runman> - run the appropriate command to show documentation
7958
7959 Accepts a man page name; runs the appropriate command to display it (set up
7960 during debugger initialization). Uses C<DB::system> to avoid mucking up the
7961 program's STDIN and STDOUT.
7962
7963 =cut
7964
7965 sub runman {
7966     my $page = shift;
7967     unless ($page) {
7968         &system("$doccmd $doccmd");
7969         return;
7970     }
7971
7972     # this way user can override, like with $doccmd="man -Mwhatever"
7973     # or even just "man " to disable the path check.
7974     unless ( $doccmd eq 'man' ) {
7975         &system("$doccmd $page");
7976         return;
7977     }
7978
7979     $page = 'perl' if lc($page) eq 'help';
7980
7981     require Config;
7982     my $man1dir = $Config::Config{'man1dir'};
7983     my $man3dir = $Config::Config{'man3dir'};
7984     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
7985     my $manpath = '';
7986     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
7987     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
7988     chop $manpath if $manpath;
7989
7990     # harmless if missing, I figure
7991     my $oldpath = $ENV{MANPATH};
7992     $ENV{MANPATH} = $manpath if $manpath;
7993     my $nopathopt = $^O =~ /dunno what goes here/;
7994     if (
7995         CORE::system(
7996             $doccmd,
7997
7998             # I just *know* there are men without -M
7999             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8000             split ' ', $page
8001         )
8002       )
8003     {
8004         unless ( $page =~ /^perl\w/ ) {
8005 # do it this way because its easier to slurp in to keep up to date - clunky though.
8006 my @pods = qw(
8007     5004delta
8008     5005delta
8009     561delta
8010     56delta
8011     570delta
8012     571delta
8013     572delta
8014     573delta
8015     58delta
8016     581delta
8017     582delta
8018     583delta
8019     584delta
8020     590delta
8021     591delta
8022     592delta
8023     aix
8024     amiga
8025     apio
8026     api
8027     apollo
8028     artistic
8029     beos
8030     book
8031     boot
8032     bot
8033     bs2000
8034     call
8035     ce
8036     cheat
8037     clib
8038     cn
8039     compile
8040     cygwin
8041     data
8042     dbmfilter
8043     debguts
8044     debtut
8045     debug
8046     delta
8047     dgux
8048     diag
8049     doc
8050     dos
8051     dsc
8052     ebcdic
8053     embed
8054     epoc
8055     faq1
8056     faq2
8057     faq3
8058     faq4
8059     faq5
8060     faq6
8061     faq7
8062     faq8
8063     faq9
8064     faq
8065     filter
8066     fork
8067     form
8068     freebsd
8069     func
8070     gpl
8071     guts
8072     hack
8073     hist
8074     hpux
8075     hurd
8076     intern
8077     intro
8078     iol
8079     ipc
8080     irix
8081     jp
8082     ko
8083     lexwarn
8084     locale
8085     lol
8086     machten
8087     macos
8088     macosx
8089     mint
8090     modinstall
8091     modlib
8092     mod
8093     modstyle
8094     mpeix
8095     netware
8096     newmod
8097     number
8098     obj
8099     opentut
8100     op
8101     os2
8102     os390
8103     os400
8104     othrtut
8105     packtut
8106     plan9
8107     pod
8108     podspec
8109     port
8110     qnx
8111     ref
8112     reftut
8113     re
8114     requick
8115     reref
8116     retut
8117     run
8118     sec
8119     solaris
8120     style
8121     sub
8122     syn
8123     thrtut
8124     tie
8125     toc
8126     todo
8127     tooc
8128     toot
8129     trap
8130     tru64
8131     tw
8132     unicode
8133     uniintro
8134     util
8135     uts
8136     var
8137     vmesa
8138     vms
8139     vos
8140     win32
8141     xs
8142     xstut
8143 );
8144             if (grep { $page eq $_ } @pods) {
8145                 $page =~ s/^/perl/;
8146                 CORE::system( $doccmd,
8147                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8148                     $page );
8149             } ## end if (grep { $page eq $_...
8150         } ## end unless ($page =~ /^perl\w/)
8151     } ## end if (CORE::system($doccmd...
8152     if ( defined $oldpath ) {
8153         $ENV{MANPATH} = $manpath;
8154     }
8155     else {
8156         delete $ENV{MANPATH};
8157     }
8158 } ## end sub runman
8159
8160 #use Carp;                          # This did break, left for debugging
8161
8162 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8163
8164 Because of the way the debugger interface to the Perl core is designed, any
8165 debugger package globals that C<DB::sub()> requires have to be defined before
8166 any subroutines can be called. These are defined in the second C<BEGIN> block.
8167
8168 This block sets things up so that (basically) the world is sane
8169 before the debugger starts executing. We set up various variables that the
8170 debugger has to have set up before the Perl core starts running:
8171
8172 =over 4
8173
8174 =item *
8175
8176 The debugger's own filehandles (copies of STD and STDOUT for now).
8177
8178 =item *
8179
8180 Characters for shell escapes, the recall command, and the history command.
8181
8182 =item *
8183
8184 The maximum recursion depth.
8185
8186 =item *
8187
8188 The size of a C<w> command's window.
8189
8190 =item *
8191
8192 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8193
8194 =item *
8195
8196 The fact that we're not in a sub at all right now.
8197
8198 =item *
8199
8200 The default SIGINT handler for the debugger.
8201
8202 =item *
8203
8204 The appropriate value of the flag in C<$^D> that says the debugger is running
8205
8206 =item *
8207
8208 The current debugger recursion level
8209
8210 =item *
8211
8212 The list of postponed items and the C<$single> stack (XXX define this)
8213
8214 =item *
8215
8216 That we want no return values and no subroutine entry/exit trace.
8217
8218 =back
8219
8220 =cut
8221
8222 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8223
8224 BEGIN {    # This does not compile, alas. (XXX eh?)
8225     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8226     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8227
8228     # Define characters used by command parsing.
8229     $sh       = '!';      # Shell escape (does not work)
8230     $rc       = ',';      # Recall command (does not work)
8231     @hist     = ('?');    # Show history (does not work)
8232     @truehist = ();       # Can be saved for replay (per session)
8233
8234     # This defines the point at which you get the 'deep recursion'
8235     # warning. It MUST be defined or the debugger will not load.
8236     $deep = 100;
8237
8238     # Number of lines around the current one that are shown in the
8239     # 'w' command.
8240     $window = 10;
8241
8242     # How much before-the-current-line context the 'v' command should
8243     # use in calculating the start of the window it will display.
8244     $preview = 3;
8245
8246     # We're not in any sub yet, but we need this to be a defined value.
8247     $sub = '';
8248
8249     # Set up the debugger's interrupt handler. It simply sets a flag
8250     # ($signal) that DB::DB() will check before each command is executed.
8251     $SIG{INT} = \&DB::catch;
8252
8253     # The following lines supposedly, if uncommented, allow the debugger to
8254     # debug itself. Perhaps we can try that someday.
8255     # This may be enabled to debug debugger:
8256     #$warnLevel = 1 unless defined $warnLevel;
8257     #$dieLevel = 1 unless defined $dieLevel;
8258     #$signalLevel = 1 unless defined $signalLevel;
8259
8260     # This is the flag that says "a debugger is running, please call
8261     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8262     # execute anything in the user's context, because we always want to
8263     # get control back.
8264     $db_stop = 0;          # Compiler warning ...
8265     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8266
8267     # This variable records how many levels we're nested in debugging. Used
8268     # Used in the debugger prompt, and in determining whether it's all over or
8269     # not.
8270     $level = 0;            # Level of recursive debugging
8271
8272     # "Triggers bug (?) in perl if we postpone this until runtime."
8273     # XXX No details on this yet, or whether we should fix the bug instead
8274     # of work around it. Stay tuned.
8275     @postponed = @stack = (0);
8276
8277     # Used to track the current stack depth using the auto-stacked-variable
8278     # trick.
8279     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8280
8281     # Don't print return values on exiting a subroutine.
8282     $doret = -2;
8283
8284     # No extry/exit tracing.
8285     $frame = 0;
8286
8287 } ## end BEGIN
8288
8289 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8290
8291 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8292
8293 =head2 db_complete
8294
8295 C<readline> support - adds command completion to basic C<readline>.
8296
8297 Returns a list of possible completions to C<readline> when invoked. C<readline>
8298 will print the longest common substring following the text already entered.
8299
8300 If there is only a single possible completion, C<readline> will use it in full.
8301
8302 This code uses C<map> and C<grep> heavily to create lists of possible
8303 completion. Think LISP in this section.
8304
8305 =cut
8306
8307 sub db_complete {
8308
8309     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8310     # $text is the text to be completed.
8311     # $line is the incoming line typed by the user.
8312     # $start is the start of the text to be completed in the incoming line.
8313     my ( $text, $line, $start ) = @_;
8314
8315     # Save the initial text.
8316     # The search pattern is current package, ::, extract the next qualifier
8317     # Prefix and pack are set to undef.
8318     my ( $itext, $search, $prefix, $pack ) =
8319       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8320
8321 =head3 C<b postpone|compile>
8322
8323 =over 4
8324
8325 =item *
8326
8327 Find all the subroutines that might match in this package
8328
8329 =item *
8330
8331 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8332
8333 =item *
8334
8335 Include all the rest of the subs that are known
8336
8337 =item *
8338
8339 C<grep> out the ones that match the text we have so far
8340
8341 =item *
8342
8343 Return this as the list of possible completions
8344
8345 =back
8346
8347 =cut
8348
8349     return sort grep /^\Q$text/, ( keys %sub ),
8350       qw(postpone load compile),    # subroutines
8351       ( map { /$search/ ? ($1) : () } keys %sub )
8352       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8353
8354 =head3 C<b load>
8355
8356 Get all the possible files from C<@INC> as it currently stands and
8357 select the ones that match the text so far.
8358
8359 =cut
8360
8361     return sort grep /^\Q$text/, values %INC    # files
8362       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8363
8364 =head3  C<V> (list variable) and C<m> (list modules)
8365
8366 There are two entry points for these commands:
8367
8368 =head4 Unqualified package names
8369
8370 Get the top-level packages and grab everything that matches the text
8371 so far. For each match, recursively complete the partial packages to
8372 get all possible matching packages. Return this sorted list.
8373
8374 =cut
8375
8376     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8377       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8378       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8379
8380 =head4 Qualified package names
8381
8382 Take a partially-qualified package and find all subpackages for it
8383 by getting all the subpackages for the package so far, matching all
8384 the subpackages against the text, and discarding all of them which
8385 start with 'main::'. Return this list.
8386
8387 =cut
8388
8389     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8390       grep !/^main::/, grep /^\Q$text/,
8391       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8392       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8393       and $text =~ /^(.*[^:])::?(\w*)$/
8394       and $prefix = $1;
8395
8396 =head3 C<f> - switch files
8397
8398 Here, we want to get a fully-qualified filename for the C<f> command.
8399 Possibilities are:
8400
8401 =over 4
8402
8403 =item 1. The original source file itself
8404
8405 =item 2. A file from C<@INC>
8406
8407 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8408
8409 =back
8410
8411 =cut
8412
8413     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8414            # We might possibly want to switch to an eval (which has a "filename"
8415            # like '(eval 9)'), so we may need to clean up the completion text
8416            # before proceeding.
8417         $prefix = length($1) - length($text);
8418         $text   = $1;
8419
8420 =pod
8421
8422 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8423 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8424 out of C<%main::>, add the initial source file, and extract the ones that
8425 match the completion text so far.
8426
8427 =cut
8428
8429         return sort
8430           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8431           $0;
8432     } ## end if ($line =~ /^\|*f\s+(.*)/)
8433
8434 =head3 Subroutine name completion
8435
8436 We look through all of the defined subs (the keys of C<%sub>) and
8437 return both all the possible matches to the subroutine name plus
8438 all the matches qualified to the current package.
8439
8440 =cut
8441
8442     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8443         $text = substr $text, 1;
8444         $prefix = "&";
8445         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8446           (
8447             map { /$search/ ? ($1) : () }
8448               keys %sub
8449           );
8450     } ## end if ((substr $text, 0, ...
8451
8452 =head3  Scalar, array, and hash completion: partially qualified package
8453
8454 Much like the above, except we have to do a little more cleanup:
8455
8456 =cut
8457
8458     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8459
8460 =pod
8461
8462 =over 4
8463
8464 =item *
8465
8466 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8467
8468 =cut
8469
8470         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8471
8472 =pod
8473
8474 =item *
8475
8476 Figure out the prefix vs. what needs completing.
8477
8478 =cut
8479
8480         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8481         $text   = $2;
8482
8483 =pod
8484
8485 =item *
8486
8487 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8488
8489 =cut
8490
8491         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8492           keys %$pack;
8493
8494 =pod
8495
8496 =item *
8497
8498 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8499
8500 =cut
8501
8502         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8503             return db_complete( $out[0], $line, $start );
8504         }
8505
8506         # Return the list of possibles.
8507         return sort @out;
8508
8509     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8510
8511 =pod
8512
8513 =back
8514
8515 =head3 Symbol completion: current package or package C<main>.
8516
8517 =cut
8518
8519     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8520
8521 =pod
8522
8523 =over 4
8524
8525 =item *
8526
8527 If it's C<main>, delete main to just get C<::> leading.
8528
8529 =cut
8530
8531         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8532
8533 =pod
8534
8535 =item *
8536
8537 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8538
8539 =cut
8540
8541         $prefix = substr $text, 0, 1;
8542         $text   = substr $text, 1;
8543
8544 =pod
8545
8546 =item *
8547
8548 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8549
8550 =cut
8551
8552         my @out = map "$prefix$_", grep /^\Q$text/,
8553           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8554           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8555
8556 =item *
8557
8558 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8559
8560 =back
8561
8562 =cut
8563
8564         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8565             return db_complete( $out[0], $line, $start );
8566         }
8567
8568         # Return the list of possibles.
8569         return sort @out;
8570     } ## end if ($text =~ /^[\$@%]/)
8571
8572 =head3 Options
8573
8574 We use C<option_val()> to look up the current value of the option. If there's
8575 only a single value, we complete the command in such a way that it is a
8576 complete command for setting the option in question. If there are multiple
8577 possible values, we generate a command consisting of the option plus a trailing
8578 question mark, which, if executed, will list the current value of the option.
8579
8580 =cut
8581
8582     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8583     {    # Options after space
8584            # We look for the text to be matched in the list of possible options,
8585            # and fetch the current value.
8586         my @out = grep /^\Q$text/, @options;
8587         my $val = option_val( $out[0], undef );
8588
8589         # Set up a 'query option's value' command.
8590         my $out = '? ';
8591         if ( not defined $val or $val =~ /[\n\r]/ ) {
8592
8593             # There's really nothing else we can do.
8594         }
8595
8596         # We have a value. Create a proper option-setting command.
8597         elsif ( $val =~ /\s/ ) {
8598
8599             # XXX This may be an extraneous variable.
8600             my $found;
8601
8602             # We'll want to quote the string (because of the embedded
8603             # whtespace), but we want to make sure we don't end up with
8604             # mismatched quote characters. We try several possibilities.
8605             foreach $l ( split //, qq/\"\'\#\|/ ) {
8606
8607                 # If we didn't find this quote character in the value,
8608                 # quote it using this quote character.
8609                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8610             }
8611         } ## end elsif ($val =~ /\s/)
8612
8613         # Don't need any quotes.
8614         else {
8615             $out = "=$val ";
8616         }
8617
8618         # If there were multiple possible values, return '? ', which
8619         # makes the command into a query command. If there was just one,
8620         # have readline append that.
8621         $rl_attribs->{completer_terminator_character} =
8622           ( @out == 1 ? $out : '? ' );
8623
8624         # Return list of possibilities.
8625         return sort @out;
8626     } ## end if ((substr $line, 0, ...
8627
8628 =head3 Filename completion
8629
8630 For entering filenames. We simply call C<readline>'s C<filename_list()>
8631 method with the completion text to get the possible completions.
8632
8633 =cut
8634
8635     return $term->filename_list($text);    # filenames
8636
8637 } ## end sub db_complete
8638
8639 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8640
8641 Functions that possibly ought to be somewhere else.
8642
8643 =head2 end_report
8644
8645 Say we're done.
8646
8647 =cut
8648
8649 sub end_report {
8650     local $\ = '';
8651     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8652 }
8653
8654 =head2 clean_ENV
8655
8656 If we have $ini_pids, save it in the environment; else remove it from the
8657 environment. Used by the C<R> (restart) command.
8658
8659 =cut
8660
8661 sub clean_ENV {
8662     if ( defined($ini_pids) ) {
8663         $ENV{PERLDB_PIDS} = $ini_pids;
8664     }
8665     else {
8666         delete( $ENV{PERLDB_PIDS} );
8667     }
8668 } ## end sub clean_ENV
8669
8670 # PERLDBf_... flag names from perl.h
8671 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8672
8673 BEGIN {
8674     %DollarCaretP_flags = (
8675         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8676         PERLDBf_LINE      => 0x02,     # Keep line #
8677         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8678         PERLDBf_INTER     => 0x08,     # Preserve more data
8679         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8680         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8681         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8682         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8683         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8684         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8685         PERLDBf_ASSERTION => 0x400,    # Debug assertion subs enter/exit
8686         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO, _ASSERTION
8687     );
8688
8689     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8690 }
8691
8692 sub parse_DollarCaretP_flags {
8693     my $flags = shift;
8694     $flags =~ s/^\s+//;
8695     $flags =~ s/\s+$//;
8696     my $acu = 0;
8697     foreach my $f ( split /\s*\|\s*/, $flags ) {
8698         my $value;
8699         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8700             $value = hex $1;
8701         }
8702         elsif ( $f =~ /^(\d+)$/ ) {
8703             $value = int $1;
8704         }
8705         elsif ( $f =~ /^DEFAULT$/i ) {
8706             $value = $DollarCaretP_flags{PERLDB_ALL};
8707         }
8708         else {
8709             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8710             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8711             unless ( defined $value ) {
8712                 print $OUT (
8713                     "Unrecognized \$^P flag '$f'!\n",
8714                     "Acceptable flags are: "
8715                       . join( ', ', sort keys %DollarCaretP_flags ),
8716                     ", and hexadecimal and decimal numbers.\n"
8717                 );
8718                 return undef;
8719             }
8720         }
8721         $acu |= $value;
8722     }
8723     $acu;
8724 }
8725
8726 sub expand_DollarCaretP_flags {
8727     my $DollarCaretP = shift;
8728     my @bits         = (
8729         map {
8730             my $n = ( 1 << $_ );
8731             ( $DollarCaretP & $n )
8732               ? ( $DollarCaretP_flags_r{$n}
8733                   || sprintf( '0x%x', $n ) )
8734               : ()
8735           } 0 .. 31
8736     );
8737     return @bits ? join( '|', @bits ) : 0;
8738 }
8739
8740 =over 4
8741
8742 =item rerun
8743
8744 Rerun the current session to:
8745
8746     rerun        current position
8747
8748     rerun 4      command number 4
8749
8750     rerun -4     current command minus 4 (go back 4 steps)
8751
8752 Whether this always makes sense, in the current context is unknowable, and is
8753 in part left as a useful exersize for the reader.  This sub returns the
8754 appropriate arguments to rerun the current session.
8755
8756 =cut
8757
8758 sub rerun {
8759     my $i = shift;
8760     my @args;
8761     pop(@truehist);                      # strim
8762     unless (defined $truehist[$i]) {
8763         print "Unable to return to non-existent command: $i\n";
8764     } else {
8765         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8766         my @temp = @truehist;            # store
8767         push(@DB::typeahead, @truehist); # saved
8768         @truehist = @hist = ();          # flush
8769         @args = &restart();              # setup
8770         &get_list("PERLDB_HIST");        # clean
8771         &set_list("PERLDB_HIST", @temp); # reset
8772     }
8773     return @args;
8774 }
8775
8776 =item restart
8777
8778 Restarting the debugger is a complex operation that occurs in several phases.
8779 First, we try to reconstruct the command line that was used to invoke Perl
8780 and the debugger.
8781
8782 =cut
8783
8784 sub restart {
8785     # I may not be able to resurrect you, but here goes ...
8786     print $OUT
8787 "Warning: some settings and command-line options may be lost!\n";
8788     my ( @script, @flags, $cl );
8789
8790     # If warn was on before, turn it on again.
8791     push @flags, '-w' if $ini_warn;
8792     if ( $ini_assertion and @{^ASSERTING} ) {
8793         push @flags,
8794           ( map { /\:\^\(\?\:(.*)\)\$\)/ ? "-A$1" : "-A$_" }
8795               @{^ASSERTING} );
8796     }
8797
8798     # Rebuild the -I flags that were on the initial
8799     # command line.
8800     for (@ini_INC) {
8801         push @flags, '-I', $_;
8802     }
8803
8804     # Turn on taint if it was on before.
8805     push @flags, '-T' if ${^TAINT};
8806
8807     # Arrange for setting the old INC:
8808     # Save the current @init_INC in the environment.
8809     set_list( "PERLDB_INC", @ini_INC );
8810
8811     # If this was a perl one-liner, go to the "file"
8812     # corresponding to the one-liner read all the lines
8813     # out of it (except for the first one, which is going
8814     # to be added back on again when 'perl -d' runs: that's
8815     # the 'require perl5db.pl;' line), and add them back on
8816     # to the command line to be executed.
8817     if ( $0 eq '-e' ) {
8818         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8819             chomp( $cl = ${'::_<-e'}[$_] );
8820             push @script, '-e', $cl;
8821         }
8822     } ## end if ($0 eq '-e')
8823
8824     # Otherwise we just reuse the original name we had
8825     # before.
8826     else {
8827         @script = $0;
8828     }
8829
8830 =pod
8831
8832 After the command line  has been reconstructed, the next step is to save
8833 the debugger's status in environment variables. The C<DB::set_list> routine
8834 is used to save aggregate variables (both hashes and arrays); scalars are
8835 just popped into environment variables directly.
8836
8837 =cut
8838
8839     # If the terminal supported history, grab it and
8840     # save that in the environment.
8841     set_list( "PERLDB_HIST",
8842           $term->Features->{getHistory}
8843         ? $term->GetHistory
8844         : @hist );
8845
8846     # Find all the files that were visited during this
8847     # session (i.e., the debugger had magic hashes
8848     # corresponding to them) and stick them in the environment.
8849     my @had_breakpoints = keys %had_breakpoints;
8850     set_list( "PERLDB_VISITED", @had_breakpoints );
8851
8852     # Save the debugger options we chose.
8853     set_list( "PERLDB_OPT", %option );
8854     # set_list( "PERLDB_OPT", options2remember() );
8855
8856     # Save the break-on-loads.
8857     set_list( "PERLDB_ON_LOAD", %break_on_load );
8858
8859 =pod
8860
8861 The most complex part of this is the saving of all of the breakpoints. They
8862 can live in an awful lot of places, and we have to go through all of them,
8863 find the breakpoints, and then save them in the appropriate environment
8864 variable via C<DB::set_list>.
8865
8866 =cut
8867
8868     # Go through all the breakpoints and make sure they're
8869     # still valid.
8870     my @hard;
8871     for ( 0 .. $#had_breakpoints ) {
8872
8873         # We were in this file.
8874         my $file = $had_breakpoints[$_];
8875
8876         # Grab that file's magic line hash.
8877         *dbline = $main::{ '_<' . $file };
8878
8879         # Skip out if it doesn't exist, or if the breakpoint
8880         # is in a postponed file (we'll do postponed ones
8881         # later).
8882         next unless %dbline or $postponed_file{$file};
8883
8884         # In an eval. This is a little harder, so we'll
8885         # do more processing on that below.
8886         ( push @hard, $file ), next
8887           if $file =~ /^\(\w*eval/;
8888
8889         # XXX I have no idea what this is doing. Yet.
8890         my @add;
8891         @add = %{ $postponed_file{$file} }
8892           if $postponed_file{$file};
8893
8894         # Save the list of all the breakpoints for this file.
8895         set_list( "PERLDB_FILE_$_", %dbline, @add );
8896     } ## end for (0 .. $#had_breakpoints)
8897
8898     # The breakpoint was inside an eval. This is a little
8899     # more difficult. XXX and I don't understand it.
8900     for (@hard) {
8901         # Get over to the eval in question.
8902         *dbline = $main::{ '_<' . $_ };
8903         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8904         for $sub ( keys %sub ) {
8905             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8906             $subs{$sub} = [ $1, $2 ];
8907         }
8908         unless (%subs) {
8909             print $OUT
8910               "No subroutines in $_, ignoring breakpoints.\n";
8911             next;
8912         }
8913       LINES: for $line ( keys %dbline ) {
8914
8915             # One breakpoint per sub only:
8916             my ( $offset, $sub, $found );
8917           SUBS: for $sub ( keys %subs ) {
8918                 if (
8919                     $subs{$sub}->[1] >=
8920                     $line    # Not after the subroutine
8921                     and (
8922                         not defined $offset    # Not caught
8923                         or $offset < 0
8924                     )
8925                   )
8926                 {                              # or badly caught
8927                     $found  = $sub;
8928                     $offset = $line - $subs{$sub}->[0];
8929                     $offset = "+$offset", last SUBS
8930                       if $offset >= 0;
8931                 } ## end if ($subs{$sub}->[1] >=...
8932             } ## end for $sub (keys %subs)
8933             if ( defined $offset ) {
8934                 $postponed{$found} =
8935                   "break $offset if $dbline{$line}";
8936             }
8937             else {
8938                 print $OUT
8939 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
8940             }
8941         } ## end for $line (keys %dbline)
8942     } ## end for (@hard)
8943
8944     # Save the other things that don't need to be
8945     # processed.
8946     set_list( "PERLDB_POSTPONE",  %postponed );
8947     set_list( "PERLDB_PRETYPE",   @$pretype );
8948     set_list( "PERLDB_PRE",       @$pre );
8949     set_list( "PERLDB_POST",      @$post );
8950     set_list( "PERLDB_TYPEAHEAD", @typeahead );
8951
8952     # We are oficially restarting.
8953     $ENV{PERLDB_RESTART} = 1;
8954
8955     # We are junking all child debuggers.
8956     delete $ENV{PERLDB_PIDS};    # Restore ini state
8957
8958     # Set this back to the initial pid.
8959     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
8960
8961 =pod
8962
8963 After all the debugger status has been saved, we take the command we built up
8964 and then return it, so we can C<exec()> it. The debugger will spot the
8965 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
8966 from the environment.
8967
8968 =cut
8969
8970     # And run Perl again. Add the "-d" flag, all the
8971     # flags we built up, the script (whether a one-liner
8972     # or a file), add on the -emacs flag for a slave editor,
8973     # and then the old arguments.
8974
8975     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
8976
8977 };  # end restart
8978
8979 =back
8980
8981 =head1 END PROCESSING - THE C<END> BLOCK
8982
8983 Come here at the very end of processing. We want to go into a
8984 loop where we allow the user to enter commands and interact with the
8985 debugger, but we don't want anything else to execute.
8986
8987 First we set the C<$finished> variable, so that some commands that
8988 shouldn't be run after the end of program quit working.
8989
8990 We then figure out whether we're truly done (as in the user entered a C<q>
8991 command, or we finished execution while running nonstop). If we aren't,
8992 we set C<$single> to 1 (causing the debugger to get control again).
8993
8994 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
8995 message and returns control to the debugger. Repeat.
8996
8997 When the user finally enters a C<q> command, C<$fall_off_end> is set to
8998 1 and the C<END> block simply exits with C<$single> set to 0 (don't
8999 break, run to completion.).
9000
9001 =cut
9002
9003 END {
9004     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9005     $fall_off_end = 1 unless $inhibit_exit;
9006
9007     # Do not stop in at_exit() and destructors on exit:
9008     $DB::single = !$fall_off_end && !$runnonstop;
9009     DB::fake::at_exit() unless $fall_off_end or $runnonstop;
9010 } ## end END
9011
9012 =head1 PRE-5.8 COMMANDS
9013
9014 Some of the commands changed function quite a bit in the 5.8 command
9015 realignment, so much so that the old code had to be replaced completely.
9016 Because we wanted to retain the option of being able to go back to the
9017 former command set, we moved the old code off to this section.
9018
9019 There's an awful lot of duplicated code here. We've duplicated the
9020 comments to keep things clear.
9021
9022 =head2 Null command
9023
9024 Does nothing. Used to I<turn off> commands.
9025
9026 =cut
9027
9028 sub cmd_pre580_null {
9029
9030     # do nothing...
9031 }
9032
9033 =head2 Old C<a> command.
9034
9035 This version added actions if you supplied them, and deleted them
9036 if you didn't.
9037
9038 =cut
9039
9040 sub cmd_pre580_a {
9041     my $xcmd = shift;
9042     my $cmd  = shift;
9043
9044     # Argument supplied. Add the action.
9045     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9046
9047         # If the line isn't there, use the current line.
9048         $i = $1 || $line;
9049         $j = $2;
9050
9051         # If there is an action ...
9052         if ( length $j ) {
9053
9054             # ... but the line isn't breakable, skip it.
9055             if ( $dbline[$i] == 0 ) {
9056                 print $OUT "Line $i may not have an action.\n";
9057             }
9058             else {
9059
9060                 # ... and the line is breakable:
9061                 # Mark that there's an action in this file.
9062                 $had_breakpoints{$filename} |= 2;
9063
9064                 # Delete any current action.
9065                 $dbline{$i} =~ s/\0[^\0]*//;
9066
9067                 # Add the new action, continuing the line as needed.
9068                 $dbline{$i} .= "\0" . action($j);
9069             }
9070         } ## end if (length $j)
9071
9072         # No action supplied.
9073         else {
9074
9075             # Delete the action.
9076             $dbline{$i} =~ s/\0[^\0]*//;
9077
9078             # Mark as having no break or action if nothing's left.
9079             delete $dbline{$i} if $dbline{$i} eq '';
9080         }
9081     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9082 } ## end sub cmd_pre580_a
9083
9084 =head2 Old C<b> command
9085
9086 Add breakpoints.
9087
9088 =cut
9089
9090 sub cmd_pre580_b {
9091     my $xcmd   = shift;
9092     my $cmd    = shift;
9093     my $dbline = shift;
9094
9095     # Break on load.
9096     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9097         my $file = $1;
9098         $file =~ s/\s+$//;
9099         &cmd_b_load($file);
9100     }
9101
9102     # b compile|postpone <some sub> [<condition>]
9103     # The interpreter actually traps this one for us; we just put the
9104     # necessary condition in the %postponed hash.
9105     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9106
9107         # Capture the condition if there is one. Make it true if none.
9108         my $cond = length $3 ? $3 : '1';
9109
9110         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9111         # if it was 'compile'.
9112         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9113
9114         # De-Perl4-ify the name - ' separators to ::.
9115         $subname =~ s/\'/::/g;
9116
9117         # Qualify it into the current package unless it's already qualified.
9118         $subname = "${'package'}::" . $subname
9119           unless $subname =~ /::/;
9120
9121         # Add main if it starts with ::.
9122         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9123
9124         # Save the break type for this sub.
9125         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9126     } ## end elsif ($cmd =~ ...
9127
9128     # b <sub name> [<condition>]
9129     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9130         my $subname = $1;
9131         my $cond = length $2 ? $2 : '1';
9132         &cmd_b_sub( $subname, $cond );
9133     }
9134
9135     # b <line> [<condition>].
9136     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9137         my $i = $1 || $dbline;
9138         my $cond = length $2 ? $2 : '1';
9139         &cmd_b_line( $i, $cond );
9140     }
9141 } ## end sub cmd_pre580_b
9142
9143 =head2 Old C<D> command.
9144
9145 Delete all breakpoints unconditionally.
9146
9147 =cut
9148
9149 sub cmd_pre580_D {
9150     my $xcmd = shift;
9151     my $cmd  = shift;
9152     if ( $cmd =~ /^\s*$/ ) {
9153         print $OUT "Deleting all breakpoints...\n";
9154
9155         # %had_breakpoints lists every file that had at least one
9156         # breakpoint in it.
9157         my $file;
9158         for $file ( keys %had_breakpoints ) {
9159
9160             # Switch to the desired file temporarily.
9161             local *dbline = $main::{ '_<' . $file };
9162
9163             my $max = $#dbline;
9164             my $was;
9165
9166             # For all lines in this file ...
9167             for ( $i = 1 ; $i <= $max ; $i++ ) {
9168
9169                 # If there's a breakpoint or action on this line ...
9170                 if ( defined $dbline{$i} ) {
9171
9172                     # ... remove the breakpoint.
9173                     $dbline{$i} =~ s/^[^\0]+//;
9174                     if ( $dbline{$i} =~ s/^\0?$// ) {
9175
9176                         # Remove the entry altogether if no action is there.
9177                         delete $dbline{$i};
9178                     }
9179                 } ## end if (defined $dbline{$i...
9180             } ## end for ($i = 1 ; $i <= $max...
9181
9182             # If, after we turn off the "there were breakpoints in this file"
9183             # bit, the entry in %had_breakpoints for this file is zero,
9184             # we should remove this file from the hash.
9185             if ( not $had_breakpoints{$file} &= ~1 ) {
9186                 delete $had_breakpoints{$file};
9187             }
9188         } ## end for $file (keys %had_breakpoints)
9189
9190         # Kill off all the other breakpoints that are waiting for files that
9191         # haven't been loaded yet.
9192         undef %postponed;
9193         undef %postponed_file;
9194         undef %break_on_load;
9195     } ## end if ($cmd =~ /^\s*$/)
9196 } ## end sub cmd_pre580_D
9197
9198 =head2 Old C<h> command
9199
9200 Print help. Defaults to printing the long-form help; the 5.8 version
9201 prints the summary by default.
9202
9203 =cut
9204
9205 sub cmd_pre580_h {
9206     my $xcmd = shift;
9207     my $cmd  = shift;
9208
9209     # Print the *right* help, long format.
9210     if ( $cmd =~ /^\s*$/ ) {
9211         print_help($pre580_help);
9212     }
9213
9214     # 'h h' - explicitly-requested summary.
9215     elsif ( $cmd =~ /^h\s*/ ) {
9216         print_help($pre580_summary);
9217     }
9218
9219     # Find and print a command's help.
9220     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9221         my $asked  = $1;                   # for proper errmsg
9222         my $qasked = quotemeta($asked);    # for searching
9223                                            # XXX: finds CR but not <CR>
9224         if (
9225             $pre580_help =~ /^
9226                               <?           # Optional '<'
9227                               (?:[IB]<)    # Optional markup
9228                               $qasked      # The command name
9229                             /mx
9230           )
9231         {
9232
9233             while (
9234                 $pre580_help =~ /^
9235                                   (             # The command help:
9236                                    <?           # Optional '<'
9237                                    (?:[IB]<)    # Optional markup
9238                                    $qasked      # The command name
9239                                    ([\s\S]*?)   # Lines starting with tabs
9240                                    \n           # Final newline
9241                                   )
9242                                   (?!\s)/mgx
9243               )    # Line not starting with space
9244                    # (Next command's help)
9245             {
9246                 print_help($1);
9247             }
9248         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9249
9250         # Help not found.
9251         else {
9252             print_help("B<$asked> is not a debugger command.\n");
9253         }
9254     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9255 } ## end sub cmd_pre580_h
9256
9257 =head2 Old C<W> command
9258
9259 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9260
9261 =cut
9262
9263 sub cmd_pre580_W {
9264     my $xcmd = shift;
9265     my $cmd  = shift;
9266
9267     # Delete all watch expressions.
9268     if ( $cmd =~ /^$/ ) {
9269
9270         # No watching is going on.
9271         $trace &= ~2;
9272
9273         # Kill all the watch expressions and values.
9274         @to_watch = @old_watch = ();
9275     }
9276
9277     # Add a watch expression.
9278     elsif ( $cmd =~ /^(.*)/s ) {
9279
9280         # add it to the list to be watched.
9281         push @to_watch, $1;
9282
9283         # Get the current value of the expression.
9284         # Doesn't handle expressions returning list values!
9285         $evalarg = $1;
9286         my ($val) = &eval;
9287         $val = ( defined $val ) ? "'$val'" : 'undef';
9288
9289         # Save it.
9290         push @old_watch, $val;
9291
9292         # We're watching stuff.
9293         $trace |= 2;
9294
9295     } ## end elsif ($cmd =~ /^(.*)/s)
9296 } ## end sub cmd_pre580_W
9297
9298 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9299
9300 The debugger used to have a bunch of nearly-identical code to handle
9301 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9302 C<cmd_prepost> unify all this into one set of code to handle the
9303 appropriate actions.
9304
9305 =head2 C<cmd_pre590_prepost>
9306
9307 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9308 do something destructive. In pre 5.8 debuggers, the default action was to
9309 delete all the actions.
9310
9311 =cut
9312
9313 sub cmd_pre590_prepost {
9314     my $cmd    = shift;
9315     my $line   = shift || '*';
9316     my $dbline = shift;
9317
9318     return &cmd_prepost( $cmd, $line, $dbline );
9319 } ## end sub cmd_pre590_prepost
9320
9321 =head2 C<cmd_prepost>
9322
9323 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9324 Since the lists of actions are all held in arrays that are pointed to by
9325 references anyway, all we have to do is pick the right array reference and
9326 then use generic code to all, delete, or list actions.
9327
9328 =cut
9329
9330 sub cmd_prepost {
9331     my $cmd = shift;
9332
9333     # No action supplied defaults to 'list'.
9334     my $line = shift || '?';
9335
9336     # Figure out what to put in the prompt.
9337     my $which = '';
9338
9339     # Make sure we have some array or another to address later.
9340     # This means that if ssome reason the tests fail, we won't be
9341     # trying to stash actions or delete them from the wrong place.
9342     my $aref = [];
9343
9344     # < - Perl code to run before prompt.
9345     if ( $cmd =~ /^\</o ) {
9346         $which = 'pre-perl';
9347         $aref  = $pre;
9348     }
9349
9350     # > - Perl code to run after prompt.
9351     elsif ( $cmd =~ /^\>/o ) {
9352         $which = 'post-perl';
9353         $aref  = $post;
9354     }
9355
9356     # { - first check for properly-balanced braces.
9357     elsif ( $cmd =~ /^\{/o ) {
9358         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9359             print $OUT
9360 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9361         }
9362
9363         # Properly balanced. Pre-prompt debugger actions.
9364         else {
9365             $which = 'pre-debugger';
9366             $aref  = $pretype;
9367         }
9368     } ## end elsif ( $cmd =~ /^\{/o )
9369
9370     # Did we find something that makes sense?
9371     unless ($which) {
9372         print $OUT "Confused by command: $cmd\n";
9373     }
9374
9375     # Yes.
9376     else {
9377
9378         # List actions.
9379         if ( $line =~ /^\s*\?\s*$/o ) {
9380             unless (@$aref) {
9381
9382                 # Nothing there. Complain.
9383                 print $OUT "No $which actions.\n";
9384             }
9385             else {
9386
9387                 # List the actions in the selected list.
9388                 print $OUT "$which commands:\n";
9389                 foreach my $action (@$aref) {
9390                     print $OUT "\t$cmd -- $action\n";
9391                 }
9392             } ## end else
9393         } ## end if ( $line =~ /^\s*\?\s*$/o)
9394
9395         # Might be a delete.
9396         else {
9397             if ( length($cmd) == 1 ) {
9398                 if ( $line =~ /^\s*\*\s*$/o ) {
9399
9400                     # It's a delete. Get rid of the old actions in the
9401                     # selected list..
9402                     @$aref = ();
9403                     print $OUT "All $cmd actions cleared.\n";
9404                 }
9405                 else {
9406
9407                     # Replace all the actions. (This is a <, >, or {).
9408                     @$aref = action($line);
9409                 }
9410             } ## end if ( length($cmd) == 1)
9411             elsif ( length($cmd) == 2 ) {
9412
9413                 # Add the action to the line. (This is a <<, >>, or {{).
9414                 push @$aref, action($line);
9415             }
9416             else {
9417
9418                 # <<<, >>>>, {{{{{{ ... something not a command.
9419                 print $OUT
9420                   "Confused by strange length of $which command($cmd)...\n";
9421             }
9422         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9423     } ## end else
9424 } ## end sub cmd_prepost
9425
9426 =head1 C<DB::fake>
9427
9428 Contains the C<at_exit> routine that the debugger uses to issue the
9429 C<Debugged program terminated ...> message after the program completes. See
9430 the C<END> block documentation for more details.
9431
9432 =cut
9433
9434 package DB::fake;
9435
9436 sub at_exit {
9437     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9438 }
9439
9440 package DB;    # Do not trace this 1; below!
9441
9442 1;
9443
9444