lib/overload.pm

   1 package overload;
   2
   3 our $VERSION = '1.00';
   4
   5 $overload::hint_bits = 0x20000;
   6
   7 sub nil {}
   8
   9 sub OVERLOAD {
  10   $package = shift;
  11   my %arg = @_;
  12   my ($sub, $fb);
  13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
  14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
  15   for (keys %arg) {
  16     if ($_ eq 'fallback') {
  17       $fb = $arg{$_};
  18     } else {
  19       $sub = $arg{$_};
  20       if (not ref $sub and $sub !~ /::/) {
  21         $ {$package . "::(" . $_} = $sub;
  22         $sub = \&nil;
  23       }
  24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
  25       *{$package . "::(" . $_} = \&{ $sub };
  26     }
  27   }
  28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
  29 }
  30
  31 sub import {
  32   $package = (caller())[0];
  33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
  34   shift;
  35   $package->overload::OVERLOAD(@_);
  36 }
  37
  38 sub unimport {
  39   $package = (caller())[0];
  40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
  41   shift;
  42   for (@_) {
  43     if ($_ eq 'fallback') {
  44       undef $ {$package . "::()"};
  45     } else {
  46       delete $ {$package . "::"}{"(" . $_};
  47     }
  48   }
  49 }
  50
  51 sub Overloaded {
  52   my $package = shift;
  53   $package = ref $package if ref $package;
  54   $package->can('()');
  55 }
  56
  57 sub ov_method {
  58   my $globref = shift;
  59   return undef unless $globref;
  60   my $sub = \&{*$globref};
  61   return $sub if $sub ne \&nil;
  62   return shift->can($ {*$globref});
  63 }
  64
  65 sub OverloadedStringify {
  66   my $package = shift;
  67   $package = ref $package if ref $package;
  68   #$package->can('(""')
  69   ov_method mycan($package, '(""'), $package
  70     or ov_method mycan($package, '(0+'), $package
  71     or ov_method mycan($package, '(bool'), $package
  72     or ov_method mycan($package, '(nomethod'), $package;
  73 }
  74
  75 sub Method {
  76   my $package = shift;
  77   $package = ref $package if ref $package;
  78   #my $meth = $package->can('(' . shift);
  79   ov_method mycan($package, '(' . shift), $package;
  80   #return $meth if $meth ne \&nil;
  81   #return $ {*{$meth}};
  82 }
  83
  84 sub AddrRef {
  85   my $package = ref $_[0];
  86   return "$_[0]" unless $package;
  87   bless $_[0], overload::Fake;  # Non-overloaded package
  88   my $str = "$_[0]";
  89   bless $_[0], $package;        # Back
  90   $package . substr $str, index $str, '=';
  91 }
  92
  93 sub StrVal {
  94   (OverloadedStringify($_[0]) or ref($_[0]) eq 'Regexp') ?
  95     (AddrRef(shift)) :
  96     "$_[0]";
  97 }
  98
  99 sub mycan {                             # Real can would leave stubs.
 100   my ($package, $meth) = @_;
 101   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
 102   my $p;
 103   foreach $p (@{$package . "::ISA"}) {
 104     my $out = mycan($p, $meth);
 105     return $out if $out;
 106   }
 107   return undef;
 108 }
 109
 110 %constants = (
 111               'integer'   =>  0x1000,
 112               'float'     =>  0x2000,
 113               'binary'    =>  0x4000,
 114               'q'         =>  0x8000,
 115               'qr'        => 0x10000,
 116              );
 117
 118 %ops = ( with_assign      => "+ - * / % ** << >> x .",
 119          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
 120          num_comparison   => "< <= >  >= == !=",
 121          '3way_comparison'=> "<=> cmp",
 122          str_comparison   => "lt le gt ge eq ne",
 123          binary           => "& | ^",
 124          unary            => "neg ! ~",
 125          mutators         => '++ --',
 126          func             => "atan2 cos sin exp abs log sqrt",
 127          conversion       => 'bool "" 0+',
 128          iterators        => '<>',
 129          dereferencing    => '${} @{} %{} &{} *{}',
 130          special          => 'nomethod fallback =');
 131
 132 use warnings::register;
 133 sub constant {
 134   # Arguments: what, sub
 135   while (@_) {
 136     if (@_ == 1) {
 137         warnings::warnif ("Odd number of arguments for overload::constant");
 138         last;
 139     }
 140     elsif (!exists $constants {$_ [0]}) {
 141         warnings::warnif ("`$_[0]' is not an overloadable type");
 142     }
 143     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
 144         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
 145         # blessed, and C<ref> would return the package the ref is blessed into.
 146         if (warnings::enabled) {
 147             $_ [1] = "undef" unless defined $_ [1];
 148             warnings::warn ("`$_[1]' is not a code reference");
 149         }
 150     }
 151     else {
 152         $^H{$_[0]} = $_[1];
 153         $^H |= $constants{$_[0]} | $overload::hint_bits;
 154     }
 155     shift, shift;
 156   }
 157 }
 158
 159 sub remove_constant {
 160   # Arguments: what, sub
 161   while (@_) {
 162     delete $^H{$_[0]};
 163     $^H &= ~ $constants{$_[0]};
 164     shift, shift;
 165   }
 166 }
 167
 168 1;
 169
 170 __END__
 171
 172 =head1 NAME
 173
 174 overload - Package for overloading perl operations
 175
 176 =head1 SYNOPSIS
 177
 178     package SomeThing;
 179
 180     use overload
 181         '+' => \&myadd,
 182         '-' => \&mysub;
 183         # etc
 184     ...
 185
 186     package main;
 187     $a = new SomeThing 57;
 188     $b=5+$a;
 189     ...
 190     if (overload::Overloaded $b) {...}
 191     ...
 192     $strval = overload::StrVal $b;
 193
 194 =head1 DESCRIPTION
 195
 196 =head2 Declaration of overloaded functions
 197
 198 The compilation directive
 199
 200     package Number;
 201     use overload
 202         "+" => \&add,
 203         "*=" => "muas";
 204
 205 declares function Number::add() for addition, and method muas() in
 206 the "class" C<Number> (or one of its base classes)
 207 for the assignment form C<*=> of multiplication.
 208
 209 Arguments of this directive come in (key, value) pairs.  Legal values
 210 are values legal inside a C<&{ ... }> call, so the name of a
 211 subroutine, a reference to a subroutine, or an anonymous subroutine
 212 will all work.  Note that values specified as strings are
 213 interpreted as methods, not subroutines.  Legal keys are listed below.
 214
 215 The subroutine C<add> will be called to execute C<$a+$b> if $a
 216 is a reference to an object blessed into the package C<Number>, or if $a is
 217 not an object from a package with defined mathemagic addition, but $b is a
 218 reference to a C<Number>.  It can also be called in other situations, like
 219 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
 220 methods refer to methods triggered by an overloaded mathematical
 221 operator.)
 222
 223 Since overloading respects inheritance via the @ISA hierarchy, the
 224 above declaration would also trigger overloading of C<+> and C<*=> in
 225 all the packages which inherit from C<Number>.
 226
 227 =head2 Calling Conventions for Binary Operations
 228
 229 The functions specified in the C<use overload ...> directive are called
 230 with three (in one particular case with four, see L<Last Resort>)
 231 arguments.  If the corresponding operation is binary, then the first
 232 two arguments are the two arguments of the operation.  However, due to
 233 general object calling conventions, the first argument should always be
 234 an object in the package, so in the situation of C<7+$a>, the
 235 order of the arguments is interchanged.  It probably does not matter
 236 when implementing the addition method, but whether the arguments
 237 are reversed is vital to the subtraction method.  The method can
 238 query this information by examining the third argument, which can take
 239 three different values:
 240
 241 =over 7
 242
 243 =item FALSE
 244
 245 the order of arguments is as in the current operation.
 246
 247 =item TRUE
 248
 249 the arguments are reversed.
 250
 251 =item C<undef>
 252
 253 the current operation is an assignment variant (as in
 254 C<$a+=7>), but the usual function is called instead.  This additional
 255 information can be used to generate some optimizations.  Compare
 256 L<Calling Conventions for Mutators>.
 257
 258 =back
 259
 260 =head2 Calling Conventions for Unary Operations
 261
 262 Unary operation are considered binary operations with the second
 263 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
 264 is called with arguments C<($a,undef,'')> when $a++ is executed.
 265
 266 =head2 Calling Conventions for Mutators
 267
 268 Two types of mutators have different calling conventions:
 269
 270 =over
 271
 272 =item C<++> and C<-->
 273
 274 The routines which implement these operators are expected to actually
 275 I<mutate> their arguments.  So, assuming that $obj is a reference to a
 276 number,
 277
 278   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
 279
 280 is an appropriate implementation of overloaded C<++>.  Note that
 281
 282   sub incr { ++$ {$_[0]} ; shift }
 283
 284 is OK if used with preincrement and with postincrement. (In the case
 285 of postincrement a copying will be performed, see L<Copy Constructor>.)
 286
 287 =item C<x=> and other assignment versions
 288
 289 There is nothing special about these methods.  They may change the
 290 value of their arguments, and may leave it as is.  The result is going
 291 to be assigned to the value in the left-hand-side if different from
 292 this value.
 293
 294 This allows for the same method to be used as overloaded C<+=> and
 295 C<+>.  Note that this is I<allowed>, but not recommended, since by the
 296 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
 297 if C<+=> is not overloaded.
 298
 299 =back
 300
 301 B<Warning.>  Due to the presense of assignment versions of operations,
 302 routines which may be called in assignment context may create
 303 self-referential structures.  Currently Perl will not free self-referential
 304 structures until cycles are C<explicitly> broken.  You may get problems
 305 when traversing your structures too.
 306
 307 Say,
 308
 309   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
 310
 311 is asking for trouble, since for code C<$obj += $foo> the subroutine
 312 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
 313 \$foo]>.  If using such a subroutine is an important optimization, one
 314 can overload C<+=> explicitly by a non-"optimized" version, or switch
 315 to non-optimized version if C<not defined $_[2]> (see
 316 L<Calling Conventions for Binary Operations>).
 317
 318 Even if no I<explicit> assignment-variants of operators are present in
 319 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
 320 C<',' . $obj . ','> may be both optimized to
 321
 322   my $tmp = ',' . $obj;    $tmp .= ',';
 323
 324 =head2 Overloadable Operations
 325
 326 The following symbols can be specified in C<use overload> directive:
 327
 328 =over 5
 329
 330 =item * I<Arithmetic operations>
 331
 332     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
 333     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
 334
 335 For these operations a substituted non-assignment variant can be called if
 336 the assignment variant is not available.  Methods for operations "C<+>",
 337 "C<->", "C<+=>", and "C<-=>" can be called to automatically generate
 338 increment and decrement methods.  The operation "C<->" can be used to
 339 autogenerate missing methods for unary minus or C<abs>.
 340
 341 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
 342 L<"Calling Conventions for Binary Operations">) for details of these
 343 substitutions.
 344
 345 =item * I<Comparison operations>
 346
 347     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
 348     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
 349
 350 If the corresponding "spaceship" variant is available, it can be
 351 used to substitute for the missing operation.  During C<sort>ing
 352 arrays, C<cmp> is used to compare values subject to C<use overload>.
 353
 354 =item * I<Bit operations>
 355
 356     "&", "^", "|", "neg", "!", "~",
 357
 358 "C<neg>" stands for unary minus.  If the method for C<neg> is not
 359 specified, it can be autogenerated using the method for
 360 subtraction. If the method for "C<!>" is not specified, it can be
 361 autogenerated using the methods for "C<bool>", or "C<\"\">", or "C<0+>".
 362
 363 =item * I<Increment and decrement>
 364
 365     "++", "--",
 366
 367 If undefined, addition and subtraction methods can be
 368 used instead.  These operations are called both in prefix and
 369 postfix form.
 370
 371 =item * I<Transcendental functions>
 372
 373     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt",
 374
 375 If C<abs> is unavailable, it can be autogenerated using methods
 376 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
 377
 378 =item * I<Boolean, string and numeric conversion>
 379
 380     "bool", "\"\"", "0+",
 381
 382 If one or two of these operations are not overloaded, the remaining ones can
 383 be used instead.  C<bool> is used in the flow control operators
 384 (like C<while>) and for the ternary "C<?:>" operation.  These functions can
 385 return any arbitrary Perl value.  If the corresponding operation for this value
 386 is overloaded too, that operation will be called again with this value.
 387
 388 As a special case if the overload returns the object itself then it will
 389 be used directly. An overloaded conversion returning the object is
 390 probably a bug, because you're likely to get something that looks like
 391 C<YourPackage=HASH(0x8172b34)>.
 392
 393 =item * I<Iteration>
 394
 395     "<>"
 396
 397 If not overloaded, the argument will be converted to a filehandle or
 398 glob (which may require a stringification).  The same overloading
 399 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
 400 I<globbing> syntax C<E<lt>${var}E<gt>>.
 401
 402 =item * I<Dereferencing>
 403
 404     '${}', '@{}', '%{}', '&{}', '*{}'.
 405
 406 If not overloaded, the argument will be dereferenced I<as is>, thus
 407 should be of correct type.  These functions should return a reference
 408 of correct type, or another object with overloaded dereferencing.
 409
 410 As a special case if the overload returns the object itself then it
 411 will be used directly (provided it is the correct type).
 412
 413 The dereference operators must be specified explicitly they will not be passed to
 414 "nomethod".
 415
 416 =item * I<Special>
 417
 418     "nomethod", "fallback", "=",
 419
 420 see L<SPECIAL SYMBOLS FOR C<use overload>>.
 421
 422 =back
 423
 424 See L<"Fallback"> for an explanation of when a missing method can be
 425 autogenerated.
 426
 427 A computer-readable form of the above table is available in the hash
 428 %overload::ops, with values being space-separated lists of names:
 429
 430  with_assign      => '+ - * / % ** << >> x .',
 431  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
 432  num_comparison   => '< <= > >= == !=',
 433  '3way_comparison'=> '<=> cmp',
 434  str_comparison   => 'lt le gt ge eq ne',
 435  binary           => '& | ^',
 436  unary            => 'neg ! ~',
 437  mutators         => '++ --',
 438  func             => 'atan2 cos sin exp abs log sqrt',
 439  conversion       => 'bool "" 0+',
 440  iterators        => '<>',
 441  dereferencing    => '${} @{} %{} &{} *{}',
 442  special          => 'nomethod fallback ='
 443
 444 =head2 Inheritance and overloading
 445
 446 Inheritance interacts with overloading in two ways.
 447
 448 =over
 449
 450 =item Strings as values of C<use overload> directive
 451
 452 If C<value> in
 453
 454   use overload key => value;
 455
 456 is a string, it is interpreted as a method name.
 457
 458 =item Overloading of an operation is inherited by derived classes
 459
 460 Any class derived from an overloaded class is also overloaded.  The
 461 set of overloaded methods is the union of overloaded methods of all
 462 the ancestors. If some method is overloaded in several ancestor, then
 463 which description will be used is decided by the usual inheritance
 464 rules:
 465
 466 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
 467 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
 468 then the subroutine C<D::plus_sub> will be called to implement
 469 operation C<+> for an object in package C<A>.
 470
 471 =back
 472
 473 Note that since the value of the C<fallback> key is not a subroutine,
 474 its inheritance is not governed by the above rules.  In the current
 475 implementation, the value of C<fallback> in the first overloaded
 476 ancestor is used, but this is accidental and subject to change.
 477
 478 =head1 SPECIAL SYMBOLS FOR C<use overload>
 479
 480 Three keys are recognized by Perl that are not covered by the above
 481 description.
 482
 483 =head2 Last Resort
 484
 485 C<"nomethod"> should be followed by a reference to a function of four
 486 parameters.  If defined, it is called when the overloading mechanism
 487 cannot find a method for some operation.  The first three arguments of
 488 this function coincide with the arguments for the corresponding method if
 489 it were found, the fourth argument is the symbol
 490 corresponding to the missing method.  If several methods are tried,
 491 the last one is used.  Say, C<1-$a> can be equivalent to
 492
 493         &nomethodMethod($a,1,1,"-")
 494
 495 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
 496 C<use overload> directive.
 497
 498 The C<"nomethod"> mechanism is I<not> used for the dereference operators
 499 ( ${} @{} %{} &{} *{} ).
 500
 501
 502 If some operation cannot be resolved, and there is no function
 503 assigned to C<"nomethod">, then an exception will be raised via die()--
 504 unless C<"fallback"> was specified as a key in C<use overload> directive.
 505
 506
 507 =head2 Fallback
 508
 509 The key C<"fallback"> governs what to do if a method for a particular
 510 operation is not found.  Three different cases are possible depending on
 511 the value of C<"fallback">:
 512
 513 =over 16
 514
 515 =item * C<undef>
 516
 517 Perl tries to use a
 518 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
 519 then tries to calls C<"nomethod"> value; if missing, an exception
 520 will be raised.
 521
 522 =item * TRUE
 523
 524 The same as for the C<undef> value, but no exception is raised.  Instead,
 525 it silently reverts to what it would have done were there no C<use overload>
 526 present.
 527
 528 =item * defined, but FALSE
 529
 530 No autogeneration is tried.  Perl tries to call
 531 C<"nomethod"> value, and if this is missing, raises an exception.
 532
 533 =back
 534
 535 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
 536 yet, see L<"Inheritance and overloading">.
 537
 538 =head2 Copy Constructor
 539
 540 The value for C<"="> is a reference to a function with three
 541 arguments, i.e., it looks like the other values in C<use
 542 overload>. However, it does not overload the Perl assignment
 543 operator. This would go against Camel hair.
 544
 545 This operation is called in the situations when a mutator is applied
 546 to a reference that shares its object with some other reference, such
 547 as
 548
 549         $a=$b;
 550         ++$a;
 551
 552 To make this change $a and not change $b, a copy of C<$$a> is made,
 553 and $a is assigned a reference to this new object.  This operation is
 554 done during execution of the C<++$a>, and not during the assignment,
 555 (so before the increment C<$$a> coincides with C<$$b>).  This is only
 556 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
 557 C<nomethod>).  Note that if this operation is expressed via C<'+'>
 558 a nonmutator, i.e., as in
 559
 560         $a=$b;
 561         $a=$a+1;
 562
 563 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
 564 appear as lvalue when the above code is executed.
 565
 566 If the copy constructor is required during the execution of some mutator,
 567 but a method for C<'='> was not specified, it can be autogenerated as a
 568 string copy if the object is a plain scalar.
 569
 570 =over 5
 571
 572 =item B<Example>
 573
 574 The actually executed code for
 575
 576         $a=$b;
 577         Something else which does not modify $a or $b....
 578         ++$a;
 579
 580 may be
 581
 582         $a=$b;
 583         Something else which does not modify $a or $b....
 584         $a = $a->clone(undef,"");
 585         $a->incr(undef,"");
 586
 587 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
 588 C<'='> was overloaded with C<\&clone>.
 589
 590 =back
 591
 592 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
 593 C<$b = $a; ++$a>.
 594
 595 =head1 MAGIC AUTOGENERATION
 596
 597 If a method for an operation is not found, and the value for  C<"fallback"> is
 598 TRUE or undefined, Perl tries to autogenerate a substitute method for
 599 the missing operation based on the defined operations.  Autogenerated method
 600 substitutions are possible for the following operations:
 601
 602 =over 16
 603
 604 =item I<Assignment forms of arithmetic operations>
 605
 606 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
 607 is not defined.
 608
 609 =item I<Conversion operations>
 610
 611 String, numeric, and boolean conversion are calculated in terms of one
 612 another if not all of them are defined.
 613
 614 =item I<Increment and decrement>
 615
 616 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
 617 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
 618
 619 =item C<abs($a)>
 620
 621 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
 622
 623 =item I<Unary minus>
 624
 625 can be expressed in terms of subtraction.
 626
 627 =item I<Negation>
 628
 629 C<!> and C<not> can be expressed in terms of boolean conversion, or
 630 string or numerical conversion.
 631
 632 =item I<Concatenation>
 633
 634 can be expressed in terms of string conversion.
 635
 636 =item I<Comparison operations>
 637
 638 can be expressed in terms of its "spaceship" counterpart: either
 639 C<E<lt>=E<gt>> or C<cmp>:
 640
 641     <, >, <=, >=, ==, !=        in terms of <=>
 642     lt, gt, le, ge, eq, ne      in terms of cmp
 643
 644 =item I<Iterator>
 645
 646     <>                          in terms of builtin operations
 647
 648 =item I<Dereferencing>
 649
 650     ${} @{} %{} &{} *{}         in terms of builtin operations
 651
 652 =item I<Copy operator>
 653
 654 can be expressed in terms of an assignment to the dereferenced value, if this
 655 value is a scalar and not a reference.
 656
 657 =back
 658
 659 =head1 Losing overloading
 660
 661 The restriction for the comparison operation is that even if, for example,
 662 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
 663 function will produce only a standard logical value based on the
 664 numerical value of the result of `C<cmp>'.  In particular, a working
 665 numeric conversion is needed in this case (possibly expressed in terms of
 666 other conversions).
 667
 668 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
 669 if the string conversion substitution is applied.
 670
 671 When you chop() a mathemagical object it is promoted to a string and its
 672 mathemagical properties are lost.  The same can happen with other
 673 operations as well.
 674
 675 =head1 Run-time Overloading
 676
 677 Since all C<use> directives are executed at compile-time, the only way to
 678 change overloading during run-time is to
 679
 680     eval 'use overload "+" => \&addmethod';
 681
 682 You can also use
 683
 684     eval 'no overload "+", "--", "<="';
 685
 686 though the use of these constructs during run-time is questionable.
 687
 688 =head1 Public functions
 689
 690 Package C<overload.pm> provides the following public functions:
 691
 692 =over 5
 693
 694 =item overload::StrVal(arg)
 695
 696 Gives string value of C<arg> as in absence of stringify overloading.
 697
 698 =item overload::Overloaded(arg)
 699
 700 Returns true if C<arg> is subject to overloading of some operations.
 701
 702 =item overload::Method(obj,op)
 703
 704 Returns C<undef> or a reference to the method that implements C<op>.
 705
 706 =back
 707
 708 =head1 Overloading constants
 709
 710 For some application Perl parser mangles constants too much.  It is possible
 711 to hook into this process via overload::constant() and overload::remove_constant()
 712 functions.
 713
 714 These functions take a hash as an argument.  The recognized keys of this hash
 715 are
 716
 717 =over 8
 718
 719 =item integer
 720
 721 to overload integer constants,
 722
 723 =item float
 724
 725 to overload floating point constants,
 726
 727 =item binary
 728
 729 to overload octal and hexadecimal constants,
 730
 731 =item q
 732
 733 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
 734 strings and here-documents,
 735
 736 =item qr
 737
 738 to overload constant pieces of regular expressions.
 739
 740 =back
 741
 742 The corresponding values are references to functions which take three arguments:
 743 the first one is the I<initial> string form of the constant, the second one
 744 is how Perl interprets this constant, the third one is how the constant is used.
 745 Note that the initial string form does not
 746 contain string delimiters, and has backslashes in backslash-delimiter
 747 combinations stripped (thus the value of delimiter is not relevant for
 748 processing of this string).  The return value of this function is how this
 749 constant is going to be interpreted by Perl.  The third argument is undefined
 750 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
 751 context (comes from strings, regular expressions, and single-quote HERE
 752 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
 753 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
 754
 755 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
 756 it is expected that overloaded constant strings are equipped with reasonable
 757 overloaded catenation operator, otherwise absurd results will result.
 758 Similarly, negative numbers are considered as negations of positive constants.
 759
 760 Note that it is probably meaningless to call the functions overload::constant()
 761 and overload::remove_constant() from anywhere but import() and unimport() methods.
 762 From these methods they may be called as
 763
 764         sub import {
 765           shift;
 766           return unless @_;
 767           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
 768           overload::constant integer => sub {Math::BigInt->new(shift)};
 769         }
 770
 771 B<BUGS> Currently overloaded-ness of constants does not propagate
 772 into C<eval '...'>.
 773
 774 =head1 IMPLEMENTATION
 775
 776 What follows is subject to change RSN.
 777
 778 The table of methods for all operations is cached in magic for the
 779 symbol table hash for the package.  The cache is invalidated during
 780 processing of C<use overload>, C<no overload>, new function
 781 definitions, and changes in @ISA. However, this invalidation remains
 782 unprocessed until the next C<bless>ing into the package. Hence if you
 783 want to change overloading structure dynamically, you'll need an
 784 additional (fake) C<bless>ing to update the table.
 785
 786 (Every SVish thing has a magic queue, and magic is an entry in that
 787 queue.  This is how a single variable may participate in multiple
 788 forms of magic simultaneously.  For instance, environment variables
 789 regularly have two forms at once: their %ENV magic and their taint
 790 magic. However, the magic which implements overloading is applied to
 791 the stashes, which are rarely used directly, thus should not slow down
 792 Perl.)
 793
 794 If an object belongs to a package using overload, it carries a special
 795 flag.  Thus the only speed penalty during arithmetic operations without
 796 overloading is the checking of this flag.
 797
 798 In fact, if C<use overload> is not present, there is almost no overhead
 799 for overloadable operations, so most programs should not suffer
 800 measurable performance penalties.  A considerable effort was made to
 801 minimize the overhead when overload is used in some package, but the
 802 arguments in question do not belong to packages using overload.  When
 803 in doubt, test your speed with C<use overload> and without it.  So far
 804 there have been no reports of substantial speed degradation if Perl is
 805 compiled with optimization turned on.
 806
 807 There is no size penalty for data if overload is not used. The only
 808 size penalty if overload is used in some package is that I<all> the
 809 packages acquire a magic during the next C<bless>ing into the
 810 package. This magic is three-words-long for packages without
 811 overloading, and carries the cache table if the package is overloaded.
 812
 813 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
 814 carried out before any operation that can imply an assignment to the
 815 object $a (or $b) refers to, like C<$a++>.  You can override this
 816 behavior by defining your own copy constructor (see L<"Copy Constructor">).
 817
 818 It is expected that arguments to methods that are not explicitly supposed
 819 to be changed are constant (but this is not enforced).
 820
 821 =head1 Metaphor clash
 822
 823 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
 824 If it I<looks> counter intuitive to you, you are subject to a metaphor
 825 clash.
 826
 827 Here is a Perl object metaphor:
 828
 829 I<  object is a reference to blessed data>
 830
 831 and an arithmetic metaphor:
 832
 833 I<  object is a thing by itself>.
 834
 835 The I<main> problem of overloading C<=> is the fact that these metaphors
 836 imply different actions on the assignment C<$a = $b> if $a and $b are
 837 objects.  Perl-think implies that $a becomes a reference to whatever
 838 $b was referencing.  Arithmetic-think implies that the value of "object"
 839 $a is changed to become the value of the object $b, preserving the fact
 840 that $a and $b are separate entities.
 841
 842 The difference is not relevant in the absence of mutators.  After
 843 a Perl-way assignment an operation which mutates the data referenced by $a
 844 would change the data referenced by $b too.  Effectively, after
 845 C<$a = $b> values of $a and $b become I<indistinguishable>.
 846
 847 On the other hand, anyone who has used algebraic notation knows the
 848 expressive power of the arithmetic metaphor.  Overloading works hard
 849 to enable this metaphor while preserving the Perlian way as far as
 850 possible.  Since it is not not possible to freely mix two contradicting
 851 metaphors, overloading allows the arithmetic way to write things I<as
 852 far as all the mutators are called via overloaded access only>.  The
 853 way it is done is described in L<Copy Constructor>.
 854
 855 If some mutator methods are directly applied to the overloaded values,
 856 one may need to I<explicitly unlink> other values which references the
 857 same value:
 858
 859     $a = new Data 23;
 860     ...
 861     $b = $a;            # $b is "linked" to $a
 862     ...
 863     $a = $a->clone;     # Unlink $b from $a
 864     $a->increment_by(4);
 865
 866 Note that overloaded access makes this transparent:
 867
 868     $a = new Data 23;
 869     $b = $a;            # $b is "linked" to $a
 870     $a += 4;            # would unlink $b automagically
 871
 872 However, it would not make
 873
 874     $a = new Data 23;
 875     $a = 4;             # Now $a is a plain 4, not 'Data'
 876
 877 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
 878 to an object do whatever you want.  It is just not the overload, but
 879 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
 880 which returns the object itself, and STORE() method which changes the
 881 value of the object, one can reproduce the arithmetic metaphor in its
 882 completeness, at least for variables which were tie()d from the start.
 883
 884 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
 885
 886 =head1 Cookbook
 887
 888 Please add examples to what follows!
 889
 890 =head2 Two-face scalars
 891
 892 Put this in F<two_face.pm> in your Perl library directory:
 893
 894   package two_face;             # Scalars with separate string and
 895                                 # numeric values.
 896   sub new { my $p = shift; bless [@_], $p }
 897   use overload '""' => \&str, '0+' => \&num, fallback => 1;
 898   sub num {shift->[1]}
 899   sub str {shift->[0]}
 900
 901 Use it as follows:
 902
 903   require two_face;
 904   my $seven = new two_face ("vii", 7);
 905   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
 906   print "seven contains `i'\n" if $seven =~ /i/;
 907
 908 (The second line creates a scalar which has both a string value, and a
 909 numeric value.)  This prints:
 910
 911   seven=vii, seven=7, eight=8
 912   seven contains `i'
 913
 914 =head2 Two-face references
 915
 916 Suppose you want to create an object which is accessible as both an
 917 array reference and a hash reference, similar to the
 918 L<pseudo-hash|perlref/"Pseudo-hashes: Using an array as a hash">
 919 builtin Perl type.  Let's make it better than a pseudo-hash by
 920 allowing index 0 to be treated as a normal element.
 921
 922   package two_refs;
 923   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
 924   sub new {
 925     my $p = shift;
 926     bless \ [@_], $p;
 927   }
 928   sub gethash {
 929     my %h;
 930     my $self = shift;
 931     tie %h, ref $self, $self;
 932     \%h;
 933   }
 934
 935   sub TIEHASH { my $p = shift; bless \ shift, $p }
 936   my %fields;
 937   my $i = 0;
 938   $fields{$_} = $i++ foreach qw{zero one two three};
 939   sub STORE {
 940     my $self = ${shift()};
 941     my $key = $fields{shift()};
 942     defined $key or die "Out of band access";
 943     $$self->[$key] = shift;
 944   }
 945   sub FETCH {
 946     my $self = ${shift()};
 947     my $key = $fields{shift()};
 948     defined $key or die "Out of band access";
 949     $$self->[$key];
 950   }
 951
 952 Now one can access an object using both the array and hash syntax:
 953
 954   my $bar = new two_refs 3,4,5,6;
 955   $bar->[2] = 11;
 956   $bar->{two} == 11 or die 'bad hash fetch';
 957
 958 Note several important features of this example.  First of all, the
 959 I<actual> type of $bar is a scalar reference, and we do not overload
 960 the scalar dereference.  Thus we can get the I<actual> non-overloaded
 961 contents of $bar by just using C<$$bar> (what we do in functions which
 962 overload dereference).  Similarly, the object returned by the
 963 TIEHASH() method is a scalar reference.
 964
 965 Second, we create a new tied hash each time the hash syntax is used.
 966 This allows us not to worry about a possibility of a reference loop,
 967 would would lead to a memory leak.
 968
 969 Both these problems can be cured.  Say, if we want to overload hash
 970 dereference on a reference to an object which is I<implemented> as a
 971 hash itself, the only problem one has to circumvent is how to access
 972 this I<actual> hash (as opposed to the I<virtual> exhibited by
 973 overloaded dereference operator).  Here is one possible fetching routine:
 974
 975   sub access_hash {
 976     my ($self, $key) = (shift, shift);
 977     my $class = ref $self;
 978     bless $self, 'overload::dummy'; # Disable overloading of %{}
 979     my $out = $self->{$key};
 980     bless $self, $class;        # Restore overloading
 981     $out;
 982   }
 983
 984 To move creation of the tied hash on each access, one may an extra
 985 level of indirection which allows a non-circular structure of references:
 986
 987   package two_refs1;
 988   use overload '%{}' => sub { ${shift()}->[1] },
 989                '@{}' => sub { ${shift()}->[0] };
 990   sub new {
 991     my $p = shift;
 992     my $a = [@_];
 993     my %h;
 994     tie %h, $p, $a;
 995     bless \ [$a, \%h], $p;
 996   }
 997   sub gethash {
 998     my %h;
 999     my $self = shift;
1000     tie %h, ref $self, $self;
1001     \%h;
1002   }
1003
1004   sub TIEHASH { my $p = shift; bless \ shift, $p }
1005   my %fields;
1006   my $i = 0;
1007   $fields{$_} = $i++ foreach qw{zero one two three};
1008   sub STORE {
1009     my $a = ${shift()};
1010     my $key = $fields{shift()};
1011     defined $key or die "Out of band access";
1012     $a->[$key] = shift;
1013   }
1014   sub FETCH {
1015     my $a = ${shift()};
1016     my $key = $fields{shift()};
1017     defined $key or die "Out of band access";
1018     $a->[$key];
1019   }
1020
1021 Now if $baz is overloaded like this, then C<$bar> is a reference to a
1022 reference to the intermediate array, which keeps a reference to an
1023 actual array, and the access hash.  The tie()ing object for the access
1024 hash is also a reference to a reference to the actual array, so
1025
1026 =over
1027
1028 =item *
1029
1030 There are no loops of references.
1031
1032 =item *
1033
1034 Both "objects" which are blessed into the class C<two_refs1> are
1035 references to a reference to an array, thus references to a I<scalar>.
1036 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1037 overloaded operations.
1038
1039 =back
1040
1041 =head2 Symbolic calculator
1042
1043 Put this in F<symbolic.pm> in your Perl library directory:
1044
1045   package symbolic;             # Primitive symbolic calculator
1046   use overload nomethod => \&wrap;
1047
1048   sub new { shift; bless ['n', @_] }
1049   sub wrap {
1050     my ($obj, $other, $inv, $meth) = @_;
1051     ($obj, $other) = ($other, $obj) if $inv;
1052     bless [$meth, $obj, $other];
1053   }
1054
1055 This module is very unusual as overloaded modules go: it does not
1056 provide any usual overloaded operators, instead it provides the L<Last
1057 Resort> operator C<nomethod>.  In this example the corresponding
1058 subroutine returns an object which encapsulates operations done over
1059 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1060 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1061
1062 Here is an example of the script which "calculates" the side of
1063 circumscribed octagon using the above package:
1064
1065   require symbolic;
1066   my $iter = 1;                 # 2**($iter+2) = 8
1067   my $side = new symbolic 1;
1068   my $cnt = $iter;
1069
1070   while ($cnt--) {
1071     $side = (sqrt(1 + $side**2) - 1)/$side;
1072   }
1073   print "OK\n";
1074
1075 The value of $side is
1076
1077   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1078                        undef], 1], ['n', 1]]
1079
1080 Note that while we obtained this value using a nice little script,
1081 there is no simple way to I<use> this value.  In fact this value may
1082 be inspected in debugger (see L<perldebug>), but ony if
1083 C<bareStringify> B<O>ption is set, and not via C<p> command.
1084
1085 If one attempts to print this value, then the overloaded operator
1086 C<""> will be called, which will call C<nomethod> operator.  The
1087 result of this operator will be stringified again, but this result is
1088 again of type C<symbolic>, which will lead to an infinite loop.
1089
1090 Add a pretty-printer method to the module F<symbolic.pm>:
1091
1092   sub pretty {
1093     my ($meth, $a, $b) = @{+shift};
1094     $a = 'u' unless defined $a;
1095     $b = 'u' unless defined $b;
1096     $a = $a->pretty if ref $a;
1097     $b = $b->pretty if ref $b;
1098     "[$meth $a $b]";
1099   }
1100
1101 Now one can finish the script by
1102
1103   print "side = ", $side->pretty, "\n";
1104
1105 The method C<pretty> is doing object-to-string conversion, so it
1106 is natural to overload the operator C<""> using this method.  However,
1107 inside such a method it is not necessary to pretty-print the
1108 I<components> $a and $b of an object.  In the above subroutine
1109 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1110 and $b.  If these components use overloading, the catenation operator
1111 will look for an overloaded operator C<.>, if not present, it will
1112 look for an overloaded operator C<"">.  Thus it is enough to use
1113
1114   use overload nomethod => \&wrap, '""' => \&str;
1115   sub str {
1116     my ($meth, $a, $b) = @{+shift};
1117     $a = 'u' unless defined $a;
1118     $b = 'u' unless defined $b;
1119     "[$meth $a $b]";
1120   }
1121
1122 Now one can change the last line of the script to
1123
1124   print "side = $side\n";
1125
1126 which outputs
1127
1128   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1129
1130 and one can inspect the value in debugger using all the possible
1131 methods.
1132
1133 Something is is still amiss: consider the loop variable $cnt of the
1134 script.  It was a number, not an object.  We cannot make this value of
1135 type C<symbolic>, since then the loop will not terminate.
1136
1137 Indeed, to terminate the cycle, the $cnt should become false.
1138 However, the operator C<bool> for checking falsity is overloaded (this
1139 time via overloaded C<"">), and returns a long string, thus any object
1140 of type C<symbolic> is true.  To overcome this, we need a way to
1141 compare an object to 0.  In fact, it is easier to write a numeric
1142 conversion routine.
1143
1144 Here is the text of F<symbolic.pm> with such a routine added (and
1145 slightly modified str()):
1146
1147   package symbolic;             # Primitive symbolic calculator
1148   use overload
1149     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1150
1151   sub new { shift; bless ['n', @_] }
1152   sub wrap {
1153     my ($obj, $other, $inv, $meth) = @_;
1154     ($obj, $other) = ($other, $obj) if $inv;
1155     bless [$meth, $obj, $other];
1156   }
1157   sub str {
1158     my ($meth, $a, $b) = @{+shift};
1159     $a = 'u' unless defined $a;
1160     if (defined $b) {
1161       "[$meth $a $b]";
1162     } else {
1163       "[$meth $a]";
1164     }
1165   }
1166   my %subr = ( n => sub {$_[0]},
1167                sqrt => sub {sqrt $_[0]},
1168                '-' => sub {shift() - shift()},
1169                '+' => sub {shift() + shift()},
1170                '/' => sub {shift() / shift()},
1171                '*' => sub {shift() * shift()},
1172                '**' => sub {shift() ** shift()},
1173              );
1174   sub num {
1175     my ($meth, $a, $b) = @{+shift};
1176     my $subr = $subr{$meth}
1177       or die "Do not know how to ($meth) in symbolic";
1178     $a = $a->num if ref $a eq __PACKAGE__;
1179     $b = $b->num if ref $b eq __PACKAGE__;
1180     $subr->($a,$b);
1181   }
1182
1183 All the work of numeric conversion is done in %subr and num().  Of
1184 course, %subr is not complete, it contains only operators used in the
1185 example below.  Here is the extra-credit question: why do we need an
1186 explicit recursion in num()?  (Answer is at the end of this section.)
1187
1188 Use this module like this:
1189
1190   require symbolic;
1191   my $iter = new symbolic 2;    # 16-gon
1192   my $side = new symbolic 1;
1193   my $cnt = $iter;
1194
1195   while ($cnt) {
1196     $cnt = $cnt - 1;            # Mutator `--' not implemented
1197     $side = (sqrt(1 + $side**2) - 1)/$side;
1198   }
1199   printf "%s=%f\n", $side, $side;
1200   printf "pi=%f\n", $side*(2**($iter+2));
1201
1202 It prints (without so many line breaks)
1203
1204   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1205                           [n 1]] 2]]] 1]
1206      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1207   pi=3.182598
1208
1209 The above module is very primitive.  It does not implement
1210 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1211 (not required without mutators!), and implements only those arithmetic
1212 operations which are used in the example.
1213
1214 To implement most arithmetic operations is easy, one should just use
1215 the tables of operations, and change the code which fills %subr to
1216
1217   my %subr = ( 'n' => sub {$_[0]} );
1218   foreach my $op (split " ", $overload::ops{with_assign}) {
1219     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1220   }
1221   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1222   foreach my $op (split " ", "@overload::ops{ @bins }") {
1223     $subr{$op} = eval "sub {shift() $op shift()}";
1224   }
1225   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1226     print "defining `$op'\n";
1227     $subr{$op} = eval "sub {$op shift()}";
1228   }
1229
1230 Due to L<Calling Conventions for Mutators>, we do not need anything
1231 special to make C<+=> and friends work, except filling C<+=> entry of
1232 %subr, and defining a copy constructor (needed since Perl has no
1233 way to know that the implementation of C<'+='> does not mutate
1234 the argument, compare L<Copy Constructor>).
1235
1236 To implement a copy constructor, add C<'=' => \&cpy> to C<use overload>
1237 line, and code (this code assumes that mutators change things one level
1238 deep only, so recursive copying is not needed):
1239
1240   sub cpy {
1241     my $self = shift;
1242     bless [@$self], ref $self;
1243   }
1244
1245 To make C<++> and C<--> work, we need to implement actual mutators,
1246 either directly, or in C<nomethod>.  We continue to do things inside
1247 C<nomethod>, thus add
1248
1249     if ($meth eq '++' or $meth eq '--') {
1250       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1251       return $obj;
1252     }
1253
1254 after the first line of wrap().  This is not a most effective
1255 implementation, one may consider
1256
1257   sub inc { $_[0] = bless ['++', shift, 1]; }
1258
1259 instead.
1260
1261 As a final remark, note that one can fill %subr by
1262
1263   my %subr = ( 'n' => sub {$_[0]} );
1264   foreach my $op (split " ", $overload::ops{with_assign}) {
1265     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1266   }
1267   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1268   foreach my $op (split " ", "@overload::ops{ @bins }") {
1269     $subr{$op} = eval "sub {shift() $op shift()}";
1270   }
1271   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1272     $subr{$op} = eval "sub {$op shift()}";
1273   }
1274   $subr{'++'} = $subr{'+'};
1275   $subr{'--'} = $subr{'-'};
1276
1277 This finishes implementation of a primitive symbolic calculator in
1278 50 lines of Perl code.  Since the numeric values of subexpressions
1279 are not cached, the calculator is very slow.
1280
1281 Here is the answer for the exercise: In the case of str(), we need no
1282 explicit recursion since the overloaded C<.>-operator will fall back
1283 to an existing overloaded operator C<"">.  Overloaded arithmetic
1284 operators I<do not> fall back to numeric conversion if C<fallback> is
1285 not explicitly requested.  Thus without an explicit recursion num()
1286 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1287 the argument of num().
1288
1289 If you wonder why defaults for conversion are different for str() and
1290 num(), note how easy it was to write the symbolic calculator.  This
1291 simplicity is due to an appropriate choice of defaults.  One extra
1292 note: due to the explicit recursion num() is more fragile than sym():
1293 we need to explicitly check for the type of $a and $b.  If components
1294 $a and $b happen to be of some related type, this may lead to problems.
1295
1296 =head2 I<Really> symbolic calculator
1297
1298 One may wonder why we call the above calculator symbolic.  The reason
1299 is that the actual calculation of the value of expression is postponed
1300 until the value is I<used>.
1301
1302 To see it in action, add a method
1303
1304   sub STORE {
1305     my $obj = shift;
1306     $#$obj = 1;
1307     @$obj->[0,1] = ('=', shift);
1308   }
1309
1310 to the package C<symbolic>.  After this change one can do
1311
1312   my $a = new symbolic 3;
1313   my $b = new symbolic 4;
1314   my $c = sqrt($a**2 + $b**2);
1315
1316 and the numeric value of $c becomes 5.  However, after calling
1317
1318   $a->STORE(12);  $b->STORE(5);
1319
1320 the numeric value of $c becomes 13.  There is no doubt now that the module
1321 symbolic provides a I<symbolic> calculator indeed.
1322
1323 To hide the rough edges under the hood, provide a tie()d interface to the
1324 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1325
1326   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1327   sub FETCH { shift }
1328   sub nop {  }          # Around a bug
1329
1330 (the bug is described in L<"BUGS">).  One can use this new interface as
1331
1332   tie $a, 'symbolic', 3;
1333   tie $b, 'symbolic', 4;
1334   $a->nop;  $b->nop;    # Around a bug
1335
1336   my $c = sqrt($a**2 + $b**2);
1337
1338 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1339 of $c becomes 13.  To insulate the user of the module add a method
1340
1341   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1342
1343 Now
1344
1345   my ($a, $b);
1346   symbolic->vars($a, $b);
1347   my $c = sqrt($a**2 + $b**2);
1348
1349   $a = 3; $b = 4;
1350   printf "c5  %s=%f\n", $c, $c;
1351
1352   $a = 12; $b = 5;
1353   printf "c13  %s=%f\n", $c, $c;
1354
1355 shows that the numeric value of $c follows changes to the values of $a
1356 and $b.
1357
1358 =head1 AUTHOR
1359
1360 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1361
1362 =head1 DIAGNOSTICS
1363
1364 When Perl is run with the B<-Do> switch or its equivalent, overloading
1365 induces diagnostic messages.
1366
1367 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1368 deduce which operations are overloaded (and which ancestor triggers
1369 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1370 is shown by debugger. The method C<()> corresponds to the C<fallback>
1371 key (in fact a presence of this method shows that this package has
1372 overloading enabled, and it is what is used by the C<Overloaded>
1373 function of module C<overload>).
1374
1375 The module might issue the following warnings:
1376
1377 =over 4
1378
1379 =item Odd number of arguments for overload::constant
1380
1381 (W) The call to overload::constant contained an odd number of arguments.
1382 The arguments should come in pairs.
1383
1384 =item `%s' is not an overloadable type
1385
1386 (W) You tried to overload a constant type the overload package is unaware of.
1387
1388 =item `%s' is not a code reference
1389
1390 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1391 to be a code reference. Either an anonymous subroutine, or a reference
1392 to a subroutine.
1393
1394 =back
1395
1396 =head1 BUGS
1397
1398 Because it is used for overloading, the per-package hash %OVERLOAD now
1399 has a special meaning in Perl. The symbol table is filled with names
1400 looking like line-noise.
1401
1402 For the purpose of inheritance every overloaded package behaves as if
1403 C<fallback> is present (possibly undefined). This may create
1404 interesting effects if some package is not overloaded, but inherits
1405 from two overloaded packages.
1406
1407 Relation between overloading and tie()ing is broken.  Overloading is
1408 triggered or not basing on the I<previous> class of tie()d value.
1409
1410 This happens because the presence of overloading is checked too early,
1411 before any tie()d access is attempted.  If the FETCH()ed class of the
1412 tie()d value does not change, a simple workaround is to access the value
1413 immediately after tie()ing, so that after this call the I<previous> class
1414 coincides with the current one.
1415
1416 B<Needed:> a way to fix this without a speed penalty.
1417
1418 Barewords are not covered by overloaded string constants.
1419
1420 This document is confusing.  There are grammos and misleading language
1421 used in places.  It would seem a total rewrite is needed.
1422
1423 =cut
1424