lib/open.pm

   1 package open;
   2 use Carp;
   3 $open::hint_bits = 0x20000;
   4
   5 our $VERSION = '1.01';
   6
   7 my $locale_encoding;
   8
   9 sub in_locale { $^H & $locale::hint_bits }
  10
  11 sub _get_locale_encoding {
  12     unless (defined $locale_encoding) {
  13         eval { use I18N::Langinfo qw(langinfo CODESET) };
  14         unless ($@) {
  15             $locale_encoding = langinfo(CODESET);
  16         }
  17         my $country_language;
  18         if (not $locale_encoding && in_locale()) {
  19             if ($ENV{LC_ALL} =~ /^([^.]+)\.([^.]+)$/) {
  20                 ($country_language, $locale_encoding) = ($1, $2);
  21             } elsif ($ENV{LANG} =~ /^([^.]+)\.([^.]+)$/) {
  22                 ($country_language, $locale_encoding) = ($1, $2);
  23             }
  24         } else {
  25             # Could do heuristics based on the country and language
  26             # parts of LC_ALL and LANG (the parts before the dot (if any)),
  27             # since we have Locale::Country and Locale::Language available.
  28             # TODO: get a database of Language -> Encoding mappings
  29             # (the Estonian database would be excellent!)
  30             # --jhi
  31         }
  32         if (defined $locale_encoding &&
  33             $locale_encoding eq 'euc' &&
  34             defined $country_language) {
  35             if ($country_language =~ /^ja_JP|japan(?:ese)?$/i) {
  36                 $locale_encoding = 'eucjp';
  37             } elsif ($country_language =~ /^ko_KR|korean?$/i) {
  38                 $locale_encoding = 'euckr';
  39             } elsif ($country_language =~ /^zh_TW|taiwan(?:ese)?$/i) {
  40                 $locale_encoding = 'euctw';
  41             }
  42             croak "Locale encoding 'euc' too ambiguous"
  43                 if $locale_encoding eq 'euc';
  44         }
  45     }
  46 }
  47
  48 sub import {
  49     my ($class,@args) = @_;
  50     croak("`use open' needs explicit list of disciplines") unless @args;
  51     $^H |= $open::hint_bits;
  52     my ($in,$out) = split(/\0/,(${^OPEN} || '\0'));
  53     my @in  = split(/\s+/,$in);
  54     my @out = split(/\s+/,$out);
  55     while (@args) {
  56         my $type = shift(@args);
  57         my $discp = shift(@args);
  58         my @val;
  59         foreach my $layer (split(/\s+/,$discp)) {
  60             $layer =~ s/^://;
  61             if ($layer eq 'locale') {
  62                 use Encode;
  63                 _get_locale_encoding()
  64                     unless defined $locale_encoding;
  65                 croak "Cannot figure out an encoding to use"
  66                     unless defined $locale_encoding;
  67                 if ($locale_encoding =~ /^utf-?8$/i) {
  68                     $layer = "utf8";
  69                 } else {
  70                     $layer = "encoding";
  71                 }
  72             }
  73             unless(PerlIO::Layer::->find($layer)) {
  74                 carp("Unknown discipline layer '$layer'");
  75             }
  76             if (defined $locale_encoding) {
  77                 $layer = "$layer($locale_encoding)";
  78             }
  79             push(@val,":$layer");
  80             if ($layer =~ /^(crlf|raw)$/) {
  81                 $^H{"open_$type"} = $layer;
  82             }
  83         }
  84         if ($type eq 'IN') {
  85             $in  = join(' ',@val);
  86         }
  87         elsif ($type eq 'OUT') {
  88             $out = join(' ',@val);
  89         }
  90         elsif ($type eq 'INOUT') {
  91             $in = $out = join(' ',@val);
  92         }
  93         else {
  94             croak "Unknown discipline class '$type'";
  95         }
  96     }
  97     ${^OPEN} = join('\0',$in,$out);
  98 }
  99
 100 1;
 101 __END__
 102
 103 =head1 NAME
 104
 105 open - perl pragma to set default disciplines for input and output
 106
 107 =head1 SYNOPSIS
 108
 109     use open IN => ":crlf", OUT => ":raw";
 110     use open INOUT => ":utf8";
 111
 112 =head1 DESCRIPTION
 113
 114 Full-fledged support for I/O disciplines is now implemented provided
 115 Perl is configured to use PerlIO as its IO system (which is now the
 116 default).
 117
 118 The C<open> pragma serves as one of the interfaces to declare default
 119 "layers" (aka disciplines) for all I/O.
 120
 121 The C<open> pragma is used to declare one or more default layers for
 122 I/O operations.  Any open(), readpipe() (aka qx//) and similar
 123 operators found within the lexical scope of this pragma will use the
 124 declared defaults.
 125
 126 When open() is given an explicit list of layers they are appended to
 127 the list declared using this pragma.
 128
 129 Directory handles may also support disciplines in future.
 130
 131 =head1 NONPERLIO FUNCTIONALITY
 132
 133 If Perl is not built to use PerlIO as its IO system then only the two
 134 pseudo-disciplines ":raw" and ":crlf" are available.
 135
 136 The ":raw" discipline corresponds to "binary mode" and the ":crlf"
 137 discipline corresponds to "text mode" on platforms that distinguish
 138 between the two modes when opening files (which is many DOS-like
 139 platforms, including Windows).  These two disciplines are no-ops on
 140 platforms where binmode() is a no-op, but perform their functions
 141 everywhere if PerlIO is enabled.
 142
 143 =head1 IMPLEMENTATION DETAILS
 144
 145 There is a class method in C<PerlIO::Layer> C<find> which is
 146 implemented as XS code.  It is called by C<import> to validate the
 147 layers:
 148
 149    PerlIO::Layer::->find("perlio")
 150
 151 The return value (if defined) is a Perl object, of class
 152 C<PerlIO::Layer> which is created by the C code in F<perlio.c>.  As
 153 yet there is nothing useful you can do with the object at the perl
 154 level.
 155
 156 =head1 SEE ALSO
 157
 158 L<perlfunc/"binmode">, L<perlfunc/"open">, L<perlunicode>, L<PerlIO>
 159
 160 =cut