lib/lib_pm.PL

   1 use Config;
   2 use File::Basename qw(&basename &dirname);
   3 use File::Spec;
   4 use Cwd;
   5
   6 my $origdir = cwd;
   7 chdir dirname($0);
   8 my $file = basename($0, '.PL');
   9 $file =~ s!_(pm)$!.$1!i;
  10
  11 my $useConfig;
  12 my $Config_archname;
  13 my $Config_version;
  14 my $Config_inc_version_list;
  15
  16 # Expand the variables only if explicitly requested because
  17 # otherwise relocating Perl becomes much harder.
  18
  19 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
  20     $useConfig = '';
  21     $Config_archname = qq('$Config{archname}');
  22     $Config_version  = qq('$Config{version}');
  23     my @Config_inc_version_list =
  24         reverse split / /, $Config{inc_version_list};
  25     $Config_inc_version_list =
  26         @Config_inc_version_list ?
  27             qq(@Config_inc_version_list) : q(());
  28 } else {
  29     $useConfig = 'use Config;';
  30     $Config_archname = q($Config{archname});
  31     $Config_version  = q($Config{version});
  32     $Config_inc_version_list =
  33               q(reverse split / /, $Config{inc_version_list});
  34 }
  35
  36 open OUT,">$file" or die "Can't create $file: $!";
  37
  38 print "Extracting $file (with variable substitutions)\n";
  39
  40 # In this section, perl variables will be expanded during extraction.
  41 # You can use $Config{...} to use Configure variables.
  42
  43 print OUT <<"!GROK!THIS!";
  44 package lib;
  45
  46 # THIS FILE IS AUTOMATICALLY GENERATED FROM lib_pm.PL.
  47 # ANY CHANGES TO THIS FILE WILL BE OVERWRITTEN BY THE NEXT PERL BUILD.
  48
  49 $useConfig
  50
  51 my \$archname         = $Config_archname;
  52 my \$version          = $Config_version;
  53 my \@inc_version_list = $Config_inc_version_list;
  54
  55 !GROK!THIS!
  56 print OUT <<'!NO!SUBS!';
  57
  58 our @ORIG_INC = @INC;   # take a handy copy of 'original' value
  59 our $VERSION = '0.5564';
  60 my $Is_MacOS = $^O eq 'MacOS';
  61 my $Mac_FS;
  62 if ($Is_MacOS) {
  63         require File::Spec;
  64         $Mac_FS = eval { require Mac::FileSpec::Unixish };
  65 }
  66
  67 sub import {
  68     shift;
  69
  70     my %names;
  71     foreach (reverse @_) {
  72         if ($_ eq '') {
  73             require Carp;
  74             Carp::carp("Empty compile time value given to use lib");
  75         }
  76
  77         local $_ = _nativize($_);
  78
  79         if (-e && ! -d _) {
  80             require Carp;
  81             Carp::carp("Parameter to use lib must be directory, not file");
  82         }
  83         unshift(@INC, $_);
  84         # Add any previous version directories we found at configure time
  85         foreach my $invcer (@inc_version_list)
  86         {
  87             my $dir = $Is_MacOS
  88                 ? File::Spec->catdir( $_, $incver )
  89                 : "$_/$incver";
  90             unshift(@INC, $dir) if -d $dir;
  91         }
  92         # Put a corresponding archlib directory infront of $_ if it
  93         # looks like $_ has an archlib directory below it.
  94         my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
  95             = _get_dirs($_);
  96         unshift(@INC, $arch_dir)         if -d $arch_auto_dir;
  97         unshift(@INC, $version_dir)      if -d $version_dir;
  98         unshift(@INC, $version_arch_dir) if -d $version_arch_dir;
  99     }
 100
 101     # remove trailing duplicates
 102     @INC = grep { ++$names{$_} == 1 } @INC;
 103     return;
 104 }
 105
 106
 107 sub unimport {
 108     shift;
 109
 110     my %names;
 111     foreach (@_) {
 112         local $_ = _nativize($_);
 113
 114         my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
 115             = _get_dirs($_);
 116         ++$names{$_};
 117         ++$names{$arch_dir}         if -d $arch_auto_dir;
 118         ++$names{$version_dir}      if -d $version_dir;
 119         ++$names{$version_arch_dir} if -d $version_arch_dir;
 120     }
 121
 122     # Remove ALL instances of each named directory.
 123     @INC = grep { !exists $names{$_} } @INC;
 124     return;
 125 }
 126
 127 sub _get_dirs {
 128     my($dir) = @_;
 129     my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);
 130
 131     # we could use this for all platforms in the future, but leave it
 132     # Mac-only for now, until there is more time for testing it.
 133     if ($Is_MacOS) {
 134         $arch_auto_dir    = File::Spec->catdir( $_, $archname, 'auto' );
 135         $arch_dir         = File::Spec->catdir( $_, $archname, );
 136         $version_dir      = File::Spec->catdir( $_, $version );
 137         $version_arch_dir = File::Spec->catdir( $_, $version, $archname );
 138     } else {
 139         $arch_auto_dir    = "$_/$archname/auto";
 140         $arch_dir         = "$_/$archname";
 141         $version_dir      = "$_/$version";
 142         $version_arch_dir = "$_/$version/$archname";
 143     }
 144     return($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);
 145 }
 146
 147 sub _nativize {
 148     my($dir) = @_;
 149
 150     if ($Is_MacOS && $Mac_FS) {
 151         $dir = Mac::FileSpec::Unixish::nativize($dir);
 152         $dir .= ":" unless $dir =~ /:$/;
 153     }
 154
 155     return $dir;
 156 }
 157
 158 1;
 159 __END__
 160
 161 =head1 NAME
 162
 163 lib - manipulate @INC at compile time
 164
 165 =head1 SYNOPSIS
 166
 167     use lib LIST;
 168
 169     no lib LIST;
 170
 171 =head1 DESCRIPTION
 172
 173 This is a small simple module which simplifies the manipulation of @INC
 174 at compile time.
 175
 176 It is typically used to add extra directories to perl's search path so
 177 that later C<use> or C<require> statements will find modules which are
 178 not located on perl's default search path.
 179
 180 =head2 Adding directories to @INC
 181
 182 The parameters to C<use lib> are added to the start of the perl search
 183 path. Saying
 184
 185     use lib LIST;
 186
 187 is I<almost> the same as saying
 188
 189     BEGIN { unshift(@INC, LIST) }
 190
 191 For each directory in LIST (called $dir here) the lib module also
 192 checks to see if a directory called $dir/$archname/auto exists.
 193 If so the $dir/$archname directory is assumed to be a corresponding
 194 architecture specific directory and is added to @INC in front of $dir.
 195
 196 To avoid memory leaks, all trailing duplicate entries in @INC are
 197 removed.
 198
 199 =head2 Deleting directories from @INC
 200
 201 You should normally only add directories to @INC.  If you need to
 202 delete directories from @INC take care to only delete those which you
 203 added yourself or which you are certain are not needed by other modules
 204 in your script.  Other modules may have added directories which they
 205 need for correct operation.
 206
 207 The C<no lib> statement deletes all instances of each named directory
 208 from @INC.
 209
 210 For each directory in LIST (called $dir here) the lib module also
 211 checks to see if a directory called $dir/$archname/auto exists.
 212 If so the $dir/$archname directory is assumed to be a corresponding
 213 architecture specific directory and is also deleted from @INC.
 214
 215 =head2 Restoring original @INC
 216
 217 When the lib module is first loaded it records the current value of @INC
 218 in an array C<@lib::ORIG_INC>. To restore @INC to that value you
 219 can say
 220
 221     @INC = @lib::ORIG_INC;
 222
 223 =head1 CAVEATS
 224
 225 In order to keep lib.pm small and simple, it only works with Unix
 226 filepaths.  This doesn't mean it only works on Unix, but non-Unix
 227 users must first translate their file paths to Unix conventions.
 228
 229     # VMS users wanting to put [.stuff.moo] into
 230     # their @INC would write
 231     use lib 'stuff/moo';
 232
 233 =head1 NOTES
 234
 235 In the future, this module will likely use File::Spec for determining
 236 paths, as it does now for Mac OS (where Unix-style or Mac-style paths
 237 work, and Unix-style paths are converted properly to Mac-style paths
 238 before being added to @INC).
 239
 240 =head1 SEE ALSO
 241
 242 FindBin - optional module which deals with paths relative to the source file.
 243
 244 =head1 AUTHOR
 245
 246 Tim Bunce, 2nd June 1995.
 247
 248 =cut
 249 !NO!SUBS!
 250
 251 close OUT or die "Can't close $file: $!";
 252 chdir $origdir;