lib/lib.pm

   1 package lib;
   2
   3 use Config;
   4
   5 my $archname = $Config{'archname'};
   6
   7 @ORIG_INC = ();         # (avoid typo warning)
   8 @ORIG_INC = @INC;       # take a handy copy of 'original' value
   9
  10
  11 sub import {
  12     shift;
  13     foreach (reverse @_) {
  14         unless (defined $_ and $_ ne '') {
  15             require Carp;
  16             Carp::carp("Empty or undefined compile time value given"); # at foo.pl line ...
  17         }
  18         unshift(@INC, $_);
  19         # Put a corresponding archlib directory infront of $_ if it
  20         # looks like $_ has an archlib directory below it.
  21         unshift(@INC, "$_/$archname/$]") if -d "$_/$archname/$]/auto";
  22         unshift(@INC, "$_/$archname")    if -d "$_/$archname/auto";
  23     }
  24 }
  25
  26
  27 sub unimport {
  28     shift;
  29     my $mode = shift if $_[0] =~ m/^:[A-Z]+/;
  30
  31     my %names;
  32     foreach(@_) {
  33         ++$names{$_};
  34         ++$names{"$_/$archname"} if -d "$_/$archname/auto";
  35     }
  36
  37     if ($mode and $mode eq ':ALL') {
  38         # Remove ALL instances of each named directory.
  39         @INC = grep { !exists $names{$_} } @INC;
  40     } else {
  41         # Remove INITIAL instance(s) of each named directory.
  42         @INC = grep { --$names{$_} < 0   } @INC;
  43     }
  44 }
  45
  46 1;
  47 __END__
  48
  49 =head1 NAME
  50
  51 lib - manipulate @INC at compile time
  52
  53 =head1 SYNOPSIS
  54
  55     use lib LIST;
  56
  57     no lib LIST;
  58
  59 =head1 DESCRIPTION
  60
  61 This is a small simple module which simplifies the manipulation of @INC
  62 at compile time.
  63
  64 It is typically used to add extra directories to perl's search path so
  65 that later C<use> or C<require> statements will find modules which are
  66 not located on perl's default search path.
  67
  68
  69 =head2 ADDING DIRECTORIES TO @INC
  70
  71 The parameters to C<use lib> are added to the start of the perl search
  72 path. Saying
  73
  74     use lib LIST;
  75
  76 is I<almost> the same as saying
  77
  78     BEGIN { unshift(@INC, LIST) }
  79
  80 For each directory in LIST (called $dir here) the lib module also
  81 checks to see if a directory called $dir/$archname/auto exists.
  82 If so the $dir/$archname directory is assumed to be a corresponding
  83 architecture specific directory and is added to @INC in front of $dir.
  84
  85 If LIST includes both $dir and $dir/$archname then $dir/$archname will
  86 be added to @INC twice (if $dir/$archname/auto exists).
  87
  88
  89 =head2 DELETING DIRECTORIES FROM @INC
  90
  91 You should normally only add directories to @INC.  If you need to
  92 delete directories from @INC take care to only delete those which you
  93 added yourself or which you are certain are not needed by other modules
  94 in your script.  Other modules may have added directories which they
  95 need for correct operation.
  96
  97 By default the C<no lib> statement deletes the I<first> instance of
  98 each named directory from @INC.  To delete multiple instances of the
  99 same name from @INC you can specify the name multiple times.
 100
 101 To delete I<all> instances of I<all> the specified names from @INC you can
 102 specify ':ALL' as the first parameter of C<no lib>. For example:
 103
 104     no lib qw(:ALL .);
 105
 106 For each directory in LIST (called $dir here) the lib module also
 107 checks to see if a directory called $dir/$archname/auto exists.
 108 If so the $dir/$archname directory is assumed to be a corresponding
 109 architecture specific directory and is also deleted from @INC.
 110
 111 If LIST includes both $dir and $dir/$archname then $dir/$archname will
 112 be deleted from @INC twice (if $dir/$archname/auto exists).
 113
 114
 115 =head2 RESTORING ORIGINAL @INC
 116
 117 When the lib module is first loaded it records the current value of @INC
 118 in an array C<@lib::ORIG_INC>. To restore @INC to that value you
 119 can say
 120
 121     @INC = @lib::ORIG_INC;
 122
 123
 124 =head1 SEE ALSO
 125
 126 FindBin - optional module which deals with paths relative to the source file.
 127
 128 =head1 AUTHOR
 129
 130 Tim Bunce, 2nd June 1995.
 131
 132 =cut
 133