lib/fields.t

   1 #!./perl -w
   2
   3 my $w;
   4
   5 BEGIN {
   6    chdir 't' if -d 't';
   7    @INC = '../lib';
   8    $SIG{__WARN__} = sub {
   9        if ($_[0] =~ /^Hides field 'b1' in base class/) {
  10            $w++;
  11            return;
  12        }
  13        print STDERR $_[0];
  14    };
  15 }
  16
  17 use strict;
  18 use warnings;
  19 use vars qw($DEBUG);
  20
  21 use Test::More;
  22
  23
  24 package B1;
  25 use fields qw(b1 b2 b3);
  26
  27 package B2;
  28 use fields '_b1';
  29 use fields qw(b1 _b2 b2);
  30
  31 sub new { fields::new(shift); }
  32
  33 package D1;
  34 use base 'B1';
  35 use fields qw(d1 d2 d3);
  36
  37 package D2;
  38 use base 'B1';
  39 use fields qw(_d1 _d2);
  40 use fields qw(d1 d2);
  41
  42 package D3;
  43 use base 'B2';
  44 use fields qw(b1 d1 _b1 _d1);  # hide b1
  45
  46 package D4;
  47 use base 'D3';
  48 use fields qw(_d3 d3);
  49
  50 package M;
  51 sub m {}
  52
  53 package D5;
  54 use base qw(M B2);
  55
  56 package Foo::Bar;
  57 use base 'B1';
  58
  59 package Foo::Bar::Baz;
  60 use base 'Foo::Bar';
  61 use fields qw(foo bar baz);
  62
  63 # Test repeatability for when modules get reloaded.
  64 package B1;
  65 use fields qw(b1 b2 b3);
  66
  67 package D3;
  68 use base 'B2';
  69 use fields qw(b1 d1 _b1 _d1);  # hide b1
  70
  71 package main;
  72
  73 sub fstr {
  74    my $h = shift;
  75    my @tmp;
  76    for my $k (sort {$h->{$a} <=> $h->{$b}} keys %$h) {
  77         my $v = $h->{$k};
  78         push(@tmp, "$k:$v");
  79    }
  80    my $str = join(",", @tmp);
  81    print "$h => $str\n" if $DEBUG;
  82    $str;
  83 }
  84
  85 my %expect = (
  86     B1 => "b1:1,b2:2,b3:3",
  87     B2 => "_b1:1,b1:2,_b2:3,b2:4",
  88     D1 => "b1:1,b2:2,b3:3,d1:4,d2:5,d3:6",
  89     D2 => "b1:1,b2:2,b3:3,_d1:4,_d2:5,d1:6,d2:7",
  90     D3 => "b2:4,b1:5,d1:6,_b1:7,_d1:8",
  91     D4 => "b2:4,b1:5,d1:6,_d3:9,d3:10",
  92     D5 => "b1:2,b2:4",
  93     'Foo::Bar::Baz' => 'b1:1,b2:2,b3:3,foo:4,bar:5,baz:6',
  94 );
  95
  96 plan tests => keys(%expect) + 21;
  97
  98 my $testno = 0;
  99
 100 while (my($class, $exp) = each %expect) {
 101    no strict 'refs';
 102    my $fstr = fstr(\%{$class."::FIELDS"});
 103    is( $fstr, $exp, "\%FIELDS check for $class" );
 104 }
 105
 106 # Did we get the appropriate amount of warnings?
 107 is( $w, 1 );
 108
 109 # A simple object creation and AVHV attribute access test
 110 my B2 $obj1 = D3->new;
 111 $obj1->{b1} = "B2";
 112 my D3 $obj2 = $obj1;
 113 $obj2->{b1} = "D3";
 114
 115 # We should get compile time failures field name typos
 116 eval q(my D3 $obj3 = $obj2; $obj3->{notthere} = "");
 117 like $@, qr/^Attempt to access disallowed key 'notthere' in a restricted hash/;
 118
 119 # Slices
 120 @$obj1{"_b1", "b1"} = (17, 29);
 121 is_deeply($obj1, { b1 => 29, _b1 => 17 });
 122
 123 @$obj1{'_b1', 'b1'} = (44,28);
 124 is_deeply($obj1, { b1 => 28, _b1 => 44 });
 125
 126 eval { fields::phash };
 127 like $@, qr/^Pseudo-hashes have been removed from Perl/;
 128
 129 #fields::_dump();
 130
 131 # check if fields autovivify
 132 {
 133     package Foo;
 134     use fields qw(foo bar);
 135     sub new { fields::new($_[0]) }
 136
 137     package main;
 138     my Foo $a = Foo->new();
 139     $a->{foo} = ['a', 'ok', 'c'];
 140     $a->{bar} = { A => 'ok' };
 141     is( $a->{foo}[1],    'ok' );
 142     is( $a->{bar}->{A},, 'ok' );
 143 }
 144
 145 # check if fields autovivify
 146 {
 147     package Bar;
 148     use fields qw(foo bar);
 149     sub new { return fields::new($_[0]) }
 150
 151     package main;
 152     my Bar $a = Bar::->new();
 153     $a->{foo} = ['a', 'ok', 'c'];
 154     $a->{bar} = { A => 'ok' };
 155     is( $a->{foo}[1], 'ok' );
 156     is( $a->{bar}->{A}, 'ok' );
 157 }
 158
 159
 160 # Test $VERSION bug
 161 package No::Version;
 162
 163 use vars qw($Foo);
 164 sub VERSION { 42 }
 165
 166 package Test::Version;
 167
 168 use base qw(No::Version);
 169 ::like( $No::Version::VERSION, qr/set by base.pm/ );
 170
 171 # Test Inverse of $VERSION bug base.pm should not clobber existing $VERSION
 172 package Has::Version;
 173
 174 BEGIN { $Has::Version::VERSION = '42' };
 175
 176 package Test::Version2;
 177
 178 use base qw(Has::Version);
 179 ::is( $Has::Version::VERSION, 42 );
 180
 181 package main;
 182
 183 our $eval1 = q{
 184   {
 185     package Eval1;
 186     {
 187       package Eval2;
 188       use base 'Eval1';
 189       $Eval2::VERSION = "1.02";
 190     }
 191     $Eval1::VERSION = "1.01";
 192   }
 193 };
 194
 195 eval $eval1;
 196 is( $@, '' );
 197
 198 is( $Eval1::VERSION, 1.01 );
 199
 200 is( $Eval2::VERSION, 1.02 );
 201
 202
 203 eval q{use base 'reallyReAlLyNotexists'};
 204 like( $@, qr/^Base class package "reallyReAlLyNotexists" is empty./,
 205                                           'base with empty package');
 206
 207 eval q{use base 'reallyReAlLyNotexists'};
 208 like( $@, qr/^Base class package "reallyReAlLyNotexists" is empty./,
 209                                           '  still empty on 2nd load');
 210
 211 BEGIN { $Has::Version_0::VERSION = 0 }
 212
 213 package Test::Version3;
 214
 215 use base qw(Has::Version_0);
 216 ::is( $Has::Version_0::VERSION, 0, '$VERSION==0 preserved' );
 217
 218 package Test::FooBar;
 219
 220 use fields qw(a b c);
 221
 222 sub new {
 223     my $self = fields::new(shift);
 224     %$self = @_ if @_;
 225     $self;
 226 }
 227
 228 package main;
 229
 230 {
 231     my $x = Test::FooBar->new( a => 1, b => 2);
 232
 233     is(ref $x, 'Test::FooBar', 'x is a Test::FooBar');
 234     ok(exists $x->{a}, 'x has a');
 235     ok(exists $x->{b}, 'x has b');
 236     is(scalar keys %$x, 2, 'x has two fields');
 237 }
 238
 239