lib/fields.pm

   1 package fields;
   2
   3 =head1 NAME
   4
   5 fields - compile-time class fields
   6
   7 =head1 SYNOPSIS
   8
   9     {
  10         package Foo;
  11         use fields qw(foo bar _private);
  12     }
  13     ...
  14     my Foo $var = new Foo;
  15     $var->{foo} = 42;
  16
  17     # This will generate a compile-time error.
  18     $var->{zap} = 42;
  19
  20     {
  21         package Bar;
  22         use base 'Foo';
  23         use fields 'bar';             # hides Foo->{bar}
  24         use fields qw(baz _private);  # not shared with Foo
  25     }
  26
  27 =head1 DESCRIPTION
  28
  29 The C<fields> pragma enables compile-time verified class fields.  It
  30 does so by updating the %FIELDS hash in the calling package.
  31
  32 If a typed lexical variable holding a reference is used to access a
  33 hash element and the %FIELDS hash of the given type exists, then the
  34 operation is turned into an array access at compile time.  The %FIELDS
  35 hash maps from hash element names to the array indices.  If the hash
  36 element is not present in the %FIELDS hash, then a compile-time error
  37 is signaled.
  38
  39 Since the %FIELDS hash is used at compile-time, it must be set up at
  40 compile-time too.  This is made easier with the help of the 'fields'
  41 and the 'base' pragma modules.  The 'base' pragma will copy fields
  42 from base classes and the 'fields' pragma adds new fields.  Field
  43 names that start with an underscore character are made private to a
  44 class and are not visible to subclasses.  Inherited fields can be
  45 overridden but will generate a warning if used together with the C<-w>
  46 switch.
  47
  48 The effect of all this is that you can have objects with named fields
  49 which are as compact and as fast arrays to access.  This only works
  50 as long as the objects are accessed through properly typed variables.
  51 For untyped access to work you have to make sure that a reference to
  52 the proper %FIELDS hash is assigned to the 0'th element of the array
  53 object (so that the objects can be treated like an pseudo-hash).  A
  54 constructor like this does the job:
  55
  56   sub new
  57   {
  58       my $class = shift;
  59       no strict 'refs';
  60       my $self = bless [\%{"$class\::FIELDS"}], $class;
  61       $self;
  62   }
  63
  64
  65 =head1 SEE ALSO
  66
  67 L<base>,
  68 L<perlref/Pseudo-hashes: Using an array as a hash>
  69
  70 =cut
  71
  72 use 5.005_64;
  73 use strict;
  74 no strict 'refs';
  75 our(%attr, $VERSION);
  76
  77 $VERSION = "1.01";
  78
  79 # some constants
  80 sub _PUBLIC    () { 1 }
  81 sub _PRIVATE   () { 2 }
  82
  83 # The %attr hash holds the attributes of the currently assigned fields
  84 # per class.  The hash is indexed by class names and the hash value is
  85 # an array reference.  The first element in the array is the lowest field
  86 # number not belonging to a base class.  The remaining elements' indices
  87 # are the field numbers.  The values are integer bit masks, or undef
  88 # in the case of base class private fields (which occupy a slot but are
  89 # otherwise irrelevant to the class).
  90
  91 sub import {
  92     my $class = shift;
  93     return unless @_;
  94     my $package = caller(0);
  95     my $fields = \%{"$package\::FIELDS"};
  96     my $fattr = ($attr{$package} ||= [1]);
  97     my $next = @$fattr;
  98
  99     if ($next > $fattr->[0]
 100         and ($fields->{$_[0]} || 0) >= $fattr->[0])
 101     {
 102         # There are already fields not belonging to base classes.
 103         # Looks like a possible module reload...
 104         $next = $fattr->[0];
 105     }
 106     foreach my $f (@_) {
 107         my $fno = $fields->{$f};
 108
 109         # Allow the module to be reloaded so long as field positions
 110         # have not changed.
 111         if ($fno and $fno != $next) {
 112             require Carp;
 113             if ($fno < $fattr->[0]) {
 114                 Carp::carp("Hides field '$f' in base class") if $^W;
 115             } else {
 116                 Carp::croak("Field name '$f' already in use");
 117             }
 118         }
 119         $fields->{$f} = $next;
 120         $fattr->[$next] = ($f =~ /^_/) ? _PRIVATE : _PUBLIC;
 121         $next += 1;
 122     }
 123     if (@$fattr > $next) {
 124         # Well, we gave them the benefit of the doubt by guessing the
 125         # module was reloaded, but they appear to be declaring fields
 126         # in more than one place.  We can't be sure (without some extra
 127         # bookkeeping) that the rest of the fields will be declared or
 128         # have the same positions, so punt.
 129         require Carp;
 130         Carp::croak ("Reloaded module must declare all fields at once");
 131     }
 132 }
 133
 134 sub inherit  # called by base.pm when $base_fields is nonempty
 135 {
 136     my($derived, $base) = @_;
 137     my $base_attr = $attr{$base};
 138     my $derived_attr = $attr{$derived} ||= [];
 139     my $base_fields    = \%{"$base\::FIELDS"};
 140     my $derived_fields = \%{"$derived\::FIELDS"};
 141
 142     $derived_attr->[0] = $base_attr ? scalar(@$base_attr) : 1;
 143     while (my($k,$v) = each %$base_fields) {
 144         my($fno);
 145         if ($fno = $derived_fields->{$k} and $fno != $v) {
 146             require Carp;
 147             Carp::croak ("Inherited %FIELDS can't override existing %FIELDS");
 148         }
 149         if ($base_attr->[$v] & _PRIVATE) {
 150             $derived_attr->[$v] = undef;
 151         } else {
 152             $derived_attr->[$v] = $base_attr->[$v];
 153             $derived_fields->{$k} = $v;
 154         }
 155      }
 156 }
 157
 158 sub _dump  # sometimes useful for debugging
 159 {
 160    for my $pkg (sort keys %attr) {
 161       print "\n$pkg";
 162       if (@{"$pkg\::ISA"}) {
 163          print " (", join(", ", @{"$pkg\::ISA"}), ")";
 164       }
 165       print "\n";
 166       my $fields = \%{"$pkg\::FIELDS"};
 167       for my $f (sort {$fields->{$a} <=> $fields->{$b}} keys %$fields) {
 168          my $no = $fields->{$f};
 169          print "   $no: $f";
 170          my $fattr = $attr{$pkg}[$no];
 171          if (defined $fattr) {
 172             my @a;
 173             push(@a, "public")    if $fattr & _PUBLIC;
 174             push(@a, "private")   if $fattr & _PRIVATE;
 175             push(@a, "inherited") if $no < $attr{$pkg}[0];
 176             print "\t(", join(", ", @a), ")";
 177          }
 178          print "\n";
 179       }
 180    }
 181 }
 182
 183 1;