lib/feature.pm

   1 package feature;
   2
   3 our $VERSION = '1.10';
   4
   5 # (feature name) => (internal name, used in %^H)
   6 my %feature = (
   7     switch => 'feature_switch',
   8     say    => "feature_say",
   9     err    => "feature_err",
  10     state  => "feature_state",
  11 );
  12
  13 my %feature_bundle = (
  14     "5.10.0" => [qw(switch say err state)],
  15 );
  16 # latest version here
  17 # keep it harcoded until we actually bump the version number to 5.10
  18 $feature_bundle{"5.10"} = $feature_bundle{"5.10.0"};
  19 #$feature_bundle{"5.10"} = $feature_bundle{sprintf("%vd",$^V)};
  20
  21 $feature_bundle{"5.9.5"} = $feature_bundle{"5.10.0"};
  22
  23 # TODO:
  24 # - think about versioned features (use feature switch => 2)
  25
  26 =head1 NAME
  27
  28 feature - Perl pragma to enable new syntactic features
  29
  30 =head1 SYNOPSIS
  31
  32     use feature qw(switch say);
  33     given ($foo) {
  34         when (1)          { say "\$foo == 1" }
  35         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  36         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  37         when ($_ > 100)   { say "\$foo > 100" }
  38         default           { say "None of the above" }
  39     }
  40
  41     use feature ':5.10'; # loads all features available in perl 5.10
  42
  43 =head1 DESCRIPTION
  44
  45 It is usually impossible to add new syntax to Perl without breaking
  46 some existing programs. This pragma provides a way to minimize that
  47 risk. New syntactic constructs can be enabled by C<use feature 'foo'>,
  48 and will be parsed only when the appropriate feature pragma is in
  49 scope.
  50
  51 =head2 Lexical effect
  52
  53 Like other pragmas (C<use strict>, for example), features have a lexical
  54 effect. C<use feature qw(foo)> will only make the feature "foo" available
  55 from that point to the end of the enclosing block.
  56
  57     {
  58         use feature 'say';
  59         say "say is available here";
  60     }
  61     print "But not here.\n";
  62
  63 =head2 C<no feature>
  64
  65 Features can also be turned off by using C<no feature "foo">. This too
  66 has lexical effect.
  67
  68     use feature 'say';
  69     say "say is available here";
  70     {
  71         no feature 'say';
  72         print "But not here.\n";
  73     }
  74     say "Yet it is here.";
  75
  76 C<no feature> with no features specified will turn off all features.
  77
  78 =head2 The 'switch' feature
  79
  80 C<use feature 'switch'> tells the compiler to enable the Perl 6
  81 given/when construct.
  82
  83 See L<perlsyn/"Switch statements"> for details.
  84
  85 =head2 The 'say' feature
  86
  87 C<use feature 'say'> tells the compiler to enable the Perl 6
  88 C<say> function.
  89
  90 See L<perlfunc/say> for details.
  91
  92 =head2 the 'err' feature
  93
  94 C<use feature 'err'> tells the compiler to enable the C<err>
  95 operator.
  96
  97 C<err> is a low-precedence variant of the C<//> operator:
  98 see C<perlop> for details.
  99
 100 =head2 the 'state' feature
 101
 102 C<use feature 'state'> tells the compiler to enable C<state>
 103 variables.
 104
 105 See L<perlsub/"Persistent Private Variables"> for details.
 106
 107 =head1 FEATURE BUNDLES
 108
 109 It's possible to load a whole slew of features in one go, using
 110 a I<feature bundle>. The name of a feature bundle is prefixed with
 111 a colon, to distinguish it from an actual feature. At present, the
 112 only feature bundles are C<use feature ":5.10"> and C<use feature ":5.10.0">,
 113 which both are equivalent to C<use feature qw(switch say err state)>.
 114
 115 In the forthcoming 5.10.X perl releases, C<use feature ":5.10"> will be
 116 equivalent to the latest C<use feature ":5.10.X">.
 117
 118 =head1 IMPLICIT LOADING
 119
 120 There are two ways to load the C<feature> pragma implicitly :
 121
 122 =over 4
 123
 124 =item *
 125
 126 By using the C<-E> switch on the command-line instead of C<-e>. It enables
 127 all available features in the main compilation unit (that is, the one-liner.)
 128
 129 =item *
 130
 131 By requiring explicitly a minimal Perl version number for your program, with
 132 the C<use VERSION> construct, and when the version is higher than or equal to
 133 5.9.5. That is,
 134
 135     use 5.9.5;
 136
 137 will do an implicit
 138
 139     use feature ':5.9.5';
 140
 141 and so on.
 142
 143 =back
 144
 145 =cut
 146
 147 sub import {
 148     my $class = shift;
 149     if (@_ == 0) {
 150         croak("No features specified");
 151     }
 152     while (@_) {
 153         my $name = shift(@_);
 154         if (substr($name, 0, 1) eq ":") {
 155             my $v = substr($name, 1);
 156             if (!exists $feature_bundle{$v}) {
 157                 unknown_feature_bundle($v);
 158             }
 159             unshift @_, @{$feature_bundle{$v}};
 160             next;
 161         }
 162         if (!exists $feature{$name}) {
 163             unknown_feature($name);
 164         }
 165         $^H{$feature{$name}} = 1;
 166     }
 167 }
 168
 169 sub unimport {
 170     my $class = shift;
 171
 172     # A bare C<no feature> should disable *all* features
 173     if (!@_) {
 174         delete @^H{ values(%feature) };
 175         return;
 176     }
 177
 178     while (@_) {
 179         my $name = shift;
 180         if (substr($name, 0, 1) eq ":") {
 181             my $v = substr($name, 1);
 182             if (!exists $feature_bundle{$v}) {
 183                 unknown_feature_bundle($v);
 184             }
 185             unshift @_, @{$feature_bundle{$v}};
 186             next;
 187         }
 188         if (!exists($feature{$name})) {
 189             unknown_feature($name);
 190         }
 191         else {
 192             delete $^H{$feature{$name}};
 193         }
 194     }
 195 }
 196
 197 sub unknown_feature {
 198     my $feature = shift;
 199     croak(sprintf('Feature "%s" is not supported by Perl %vd',
 200             $feature, $^V));
 201 }
 202
 203 sub unknown_feature_bundle {
 204     my $feature = shift;
 205     croak(sprintf('Feature bundle "%s" is not supported by Perl %vd',
 206             $feature, $^V));
 207 }
 208
 209 sub croak {
 210     require Carp;
 211     Carp::croak(@_);
 212 }
 213
 214 1;