lib/feature.pm

   1 package feature;
   2
   3 our $VERSION = '1.12';
   4
   5 # (feature name) => (internal name, used in %^H)
   6 my %feature = (
   7     switch => 'feature_switch',
   8     say    => "feature_say",
   9     state  => "feature_state",
  10 );
  11
  12 # NB. the latest bundle must be loaded by the -E switch (see toke.c)
  13
  14 my %feature_bundle = (
  15     "5.10.0" => [qw(switch say state)],
  16     "5.11.0" => [qw(switch say state)],
  17 );
  18
  19 # latest version here
  20 $feature_bundle{"5.11"} = $feature_bundle{sprintf("%vd",$^V)};
  21
  22 $feature_bundle{"5.10"} = $feature_bundle{"5.10.0"};
  23 $feature_bundle{"5.9.5"} = $feature_bundle{"5.10.0"};
  24
  25 # TODO:
  26 # - think about versioned features (use feature switch => 2)
  27
  28 =head1 NAME
  29
  30 feature - Perl pragma to enable new syntactic features
  31
  32 =head1 SYNOPSIS
  33
  34     use feature qw(switch say);
  35     given ($foo) {
  36         when (1)          { say "\$foo == 1" }
  37         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  38         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  39         when ($_ > 100)   { say "\$foo > 100" }
  40         default           { say "None of the above" }
  41     }
  42
  43     use feature ':5.10'; # loads all features available in perl 5.10
  44
  45 =head1 DESCRIPTION
  46
  47 It is usually impossible to add new syntax to Perl without breaking
  48 some existing programs. This pragma provides a way to minimize that
  49 risk. New syntactic constructs can be enabled by C<use feature 'foo'>,
  50 and will be parsed only when the appropriate feature pragma is in
  51 scope.
  52
  53 =head2 Lexical effect
  54
  55 Like other pragmas (C<use strict>, for example), features have a lexical
  56 effect. C<use feature qw(foo)> will only make the feature "foo" available
  57 from that point to the end of the enclosing block.
  58
  59     {
  60         use feature 'say';
  61         say "say is available here";
  62     }
  63     print "But not here.\n";
  64
  65 =head2 C<no feature>
  66
  67 Features can also be turned off by using C<no feature "foo">. This too
  68 has lexical effect.
  69
  70     use feature 'say';
  71     say "say is available here";
  72     {
  73         no feature 'say';
  74         print "But not here.\n";
  75     }
  76     say "Yet it is here.";
  77
  78 C<no feature> with no features specified will turn off all features.
  79
  80 =head2 The 'switch' feature
  81
  82 C<use feature 'switch'> tells the compiler to enable the Perl 6
  83 given/when construct.
  84
  85 See L<perlsyn/"Switch statements"> for details.
  86
  87 =head2 The 'say' feature
  88
  89 C<use feature 'say'> tells the compiler to enable the Perl 6
  90 C<say> function.
  91
  92 See L<perlfunc/say> for details.
  93
  94 =head2 the 'state' feature
  95
  96 C<use feature 'state'> tells the compiler to enable C<state>
  97 variables.
  98
  99 See L<perlsub/"Persistent Private Variables"> for details.
 100
 101 =head1 FEATURE BUNDLES
 102
 103 It's possible to load a whole slew of features in one go, using
 104 a I<feature bundle>. The name of a feature bundle is prefixed with
 105 a colon, to distinguish it from an actual feature. At present, the
 106 only feature bundles are C<use feature ":5.10"> and C<use feature ":5.10.0">,
 107 which both are equivalent to C<use feature qw(switch say state)>.
 108
 109 In the forthcoming 5.10.X perl releases, C<use feature ":5.10"> will be
 110 equivalent to the latest C<use feature ":5.10.X">.
 111
 112 =head1 IMPLICIT LOADING
 113
 114 There are two ways to load the C<feature> pragma implicitly :
 115
 116 =over 4
 117
 118 =item *
 119
 120 By using the C<-E> switch on the command-line instead of C<-e>. It enables
 121 all available features in the main compilation unit (that is, the one-liner.)
 122
 123 =item *
 124
 125 By requiring explicitly a minimal Perl version number for your program, with
 126 the C<use VERSION> construct, and when the version is higher than or equal to
 127 5.10.0. That is,
 128
 129     use 5.10.0;
 130
 131 will do an implicit
 132
 133     use feature ':5.10.0';
 134
 135 and so on.
 136
 137 But to avoid portability warnings (see L<perlfunc/use>), you may prefer:
 138
 139     use 5.010;
 140
 141 with the same effect.
 142
 143 =back
 144
 145 =cut
 146
 147 sub import {
 148     my $class = shift;
 149     if (@_ == 0) {
 150         croak("No features specified");
 151     }
 152     while (@_) {
 153         my $name = shift(@_);
 154         if (substr($name, 0, 1) eq ":") {
 155             my $v = substr($name, 1);
 156             if (!exists $feature_bundle{$v}) {
 157                 unknown_feature_bundle($v);
 158             }
 159             unshift @_, @{$feature_bundle{$v}};
 160             next;
 161         }
 162         if (!exists $feature{$name}) {
 163             unknown_feature($name);
 164         }
 165         $^H{$feature{$name}} = 1;
 166     }
 167 }
 168
 169 sub unimport {
 170     my $class = shift;
 171
 172     # A bare C<no feature> should disable *all* features
 173     if (!@_) {
 174         delete @^H{ values(%feature) };
 175         return;
 176     }
 177
 178     while (@_) {
 179         my $name = shift;
 180         if (substr($name, 0, 1) eq ":") {
 181             my $v = substr($name, 1);
 182             if (!exists $feature_bundle{$v}) {
 183                 unknown_feature_bundle($v);
 184             }
 185             unshift @_, @{$feature_bundle{$v}};
 186             next;
 187         }
 188         if (!exists($feature{$name})) {
 189             unknown_feature($name);
 190         }
 191         else {
 192             delete $^H{$feature{$name}};
 193         }
 194     }
 195 }
 196
 197 sub unknown_feature {
 198     my $feature = shift;
 199     croak(sprintf('Feature "%s" is not supported by Perl %vd',
 200             $feature, $^V));
 201 }
 202
 203 sub unknown_feature_bundle {
 204     my $feature = shift;
 205     croak(sprintf('Feature bundle "%s" is not supported by Perl %vd',
 206             $feature, $^V));
 207 }
 208
 209 sub croak {
 210     require Carp;
 211     Carp::croak(@_);
 212 }
 213
 214 1;