lib/feature.pm

   1 package feature;
   2
   3 our $VERSION = '1.01';
   4
   5 # (feature name) => (internal name, used in %^H)
   6 my %feature = (
   7     switch => 'feature_switch',
   8     "~~"   => "feature_~~",
   9     say    => "feature_say",
  10     err    => "feature_err",
  11     state  => "feature_state",
  12 );
  13
  14 my %feature_bundle = (
  15     "5.10" => [qw(switch ~~ say err state)],
  16 );
  17
  18
  19 # Here are some notes that probably shouldn't be in the public
  20 # documentation, but which it's useful to have somewhere.
  21 #
  22 # One side-effect of the change is that C<prototype("CORE::continue")>
  23 # no longer throws the error C<Can't find an opnumber for "continue">.
  24 # One of the tests in t/op/cproto.t had to be changed to accommodate
  25 # this, but it really shouldn't affect real-world code.
  26 #
  27 # TODO:
  28 # - sort out the smartmatch semantics
  29 # - think about versioned features (use switch => 2)
  30 #
  31 # -- Robin 2005-12
  32
  33 =head1 NAME
  34
  35 feature - Perl pragma to enable new syntactic features
  36
  37 =head1 SYNOPSIS
  38
  39     use feature qw(switch say);
  40     given ($foo) {
  41         when (1)          { say "\$foo == 1" }
  42         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  43         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  44         when ($_ > 100)   { say "\$foo > 100" }
  45         default           { say "None of the above" }
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 It is usually impossible to add new syntax to Perl without breaking
  51 some existing programs. This pragma provides a way to minimize that
  52 risk. New syntactic constructs can be enabled by C<use feature 'foo'>,
  53 and will be parsed only when the appropriate feature pragma is in
  54 scope.
  55
  56 =head2 The 'switch' feature
  57
  58 C<use feature 'switch'> tells the compiler to enable the Perl 6
  59 given/when construct from here to the end of the enclosing BLOCK.
  60
  61 See L<perlsyn/"Switch statements"> for details.
  62
  63 =head2 The '~~' feature
  64
  65 C<use feature '~~'> tells the compiler to enable the Perl 6
  66 smart match C<~~> operator from here to the end of the enclosing BLOCK.
  67
  68 See L<perlsyn/"Smart Matching in Detail"> for details.
  69
  70 =head2 The 'say' feature
  71
  72 C<use feature 'say'> tells the compiler to enable the Perl 6
  73 C<say> function from here to the end of the enclosing BLOCK.
  74
  75 See L<perlfunc/say> for details.
  76
  77 =head2 the 'err' feature
  78
  79 C<use feature 'err'> tells the compiler to enable the C<err>
  80 operator from here to the end of the enclosing BLOCK.
  81
  82 C<err> is a low-precedence variant of the C<//> operator:
  83 see C<perlop> for details.
  84
  85 =head2 the 'state' feature
  86
  87 C<use feature 'state'> tells the compiler to enable C<state>
  88 variables from here to the end of the enclosing BLOCK.
  89
  90 =head1 FEATURE BUNDLES
  91
  92 It's possible to load a whole slew of features in one go, using
  93 a I<feature bundle>. The name of a feature bundle is prefixed with
  94 a colon, to distinguish it from an actual feature. At present, the
  95 only feature bundle is C<use feature ":5.10">, which is equivalent
  96 to C<use feature qw(switch ~~ say err state)>.
  97
  98 =cut
  99
 100 sub import {
 101     my $class = shift;
 102     if (@_ == 0) {
 103         require Carp;
 104         Carp->import("croak");
 105         croak("No features specified");
 106     }
 107     while (@_) {
 108         my $name = shift(@_);
 109         if ($name =~ /^:(.*)/) {
 110             if (!exists $feature_bundle{$1}) {
 111                 require Carp;
 112                 Carp->import("croak");
 113                 croak(sprintf('Feature bundle "%s" is not supported by Perl %vd',
 114                     $1, $^V));
 115             }
 116             unshift @_, @{$feature_bundle{$1}};
 117             next;
 118         }
 119         if (!exists $feature{$name}) {
 120             require Carp;
 121             Carp->import("croak");
 122             croak(sprintf('Feature "%s" is not supported by Perl %vd',
 123                 $name, $^V));
 124         }
 125         $^H{$feature{$name}} = 1;
 126     }
 127 }
 128
 129 sub unimport {
 130     my $class = shift;
 131
 132     # A bare C<no feature> should disable *all* features
 133     if (!@_) {
 134         delete @^H{ values(%feature) };
 135         return;
 136     }
 137
 138     while (@_) {
 139         my $name = shift;
 140         if ($name =~ /^:(.*)/) {
 141             if (!exists $feature_bundle{$1}) {
 142                 require Carp;
 143                 Carp->import("croak");
 144                 croak(sprintf('Feature bundle "%s" is not supported by Perl %vd',
 145                     $1, $^V));
 146             }
 147             unshift @_, @{$feature_bundle{$1}};
 148             next;
 149         }
 150         if (!exists($feature{$name})) {
 151             require Carp;
 152             Carp->import("croak");
 153             croak(sprintf('Feature "%s" is not supported by Perl %vd',
 154                 $name, $^V));
 155         }
 156         else {
 157             delete $^H{$feature{$name}};
 158         }
 159     }
 160 }
 161
 162 1;