lib/charnames.pm

   1 package charnames;
   2
   3 my $fname = 'unicode/UnicodeData-Latest.txt';
   4 my $txt;
   5
   6 # This is not optimized in any way yet
   7 sub charnames {
   8   $name = shift;
   9   $txt = do "unicode/Name.pl" unless $txt;
  10   my @off;
  11   if ($^H{charnames_full} and $txt =~ /\t\t$name$/m) {
  12     @off = ($-[0], $+[0]);
  13   }
  14   unless (@off) {
  15     if ($^H{charnames_short} and $name =~ /^(.*?):(.*)/s) {
  16       my ($script, $cname) = ($1,$2);
  17       my $case = ( $cname =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
  18       if ($txt =~ m/\t\t\U$script\E (?:$case )?LETTER \U$cname$/m) {
  19         @off = ($-[0], $+[0]);
  20       }
  21     }
  22   }
  23   unless (@off) {
  24     my $case = ( $name =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
  25     for ( @{$^H{charnames_scripts}} ) {
  26       (@off = ($-[0], $+[0])), last
  27         if $txt =~ m/\t\t$_ (?:$case )?LETTER \U$name$/m;
  28     }
  29   }
  30   die "Unknown charname '$name'" unless @off;
  31
  32   my $ord = hex substr $txt, $off[0] - 4, 4;
  33   if ($^H & 0x8) {      # "use bytes" in effect?
  34     use bytes;
  35     return chr $ord if $ord <= 255;
  36     my $hex = sprintf '%X=0%o', $ord, $ord;
  37     my $fname = substr $txt, $off[0] + 2, $off[1] - $off[0] - 2;
  38     die "Character 0x$hex with name '$fname' is above 0xFF";
  39   }
  40   return chr $ord;
  41 }
  42
  43 sub import {
  44   shift;
  45   die "No scripts for `use charnames'" unless @_;
  46   $^H |= 0x20000;
  47   $^H{charnames} = \&charnames ;
  48   my %h;
  49   @h{@_} = (1) x @_;
  50   $^H{charnames_full} = delete $h{':full'};
  51   $^H{charnames_short} = delete $h{':short'};
  52   $^H{charnames_scripts} = [map uc, keys %h];
  53 }
  54
  55
  56 1;
  57 __END__
  58
  59 =head1 NAME
  60
  61 charnames - define character names for C<\N{named}> string literal escape.
  62
  63 =head1 SYNOPSIS
  64
  65   use charnames ':full';
  66   print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
  67
  68   use charnames ':short';
  69   print "\N{greek:Sigma} is an upper-case sigma.\n";
  70
  71   use charnames qw(cyrillic greek);
  72   print "\N{sigma} is Greek sigma, and \N{be} is Cyrillic b.\n";
  73
  74 =head1 DESCRIPTION
  75
  76 Pragma C<use charnames> supports arguments C<:full>, C<:short> and
  77 script names.  If C<:full> is present, for expansion of
  78 C<\N{CHARNAME}}> string C<CHARNAME> is first looked in the list of
  79 standard Unicode names of chars.  If C<:short> is present, and
  80 C<CHARNAME> has the form C<SCRIPT:CNAME>, then C<CNAME> is looked up
  81 as a letter in script C<SCRIPT>.  If pragma C<use charnames> is used
  82 with script name arguments, then for C<\N{CHARNAME}}> the name
  83 C<CHARNAME> is looked up as a letter in the given scripts (in the
  84 specified order).
  85
  86 For lookup of C<CHARNAME> inside a given script C<SCRIPTNAME>
  87 F<charcodes.pm> looks for the names
  88
  89   SCRIPTNAME CAPITAL LETTER CHARNAME
  90   SCRIPTNAME SMALL LETTER CHARNAME
  91   SCRIPTNAME LETTER CHARNAME
  92
  93 in the table of standard Unicode names.  If C<CHARNAME> is lowercase,
  94 then the C<CAPITAL> variant is ignored, otherwise C<SMALL> variant is
  95 ignored.
  96
  97 =head1 CUSTOM TRANSLATORS
  98
  99 The mechanism of translation is C<\N{...}> escapes is general and not
 100 hardwired into F<charnames.pm>.  A module can install custom
 101 translations (inside the scope which C<use>s the module) by the
 102 following magic incantation:
 103
 104   sub import {
 105     shift;
 106     $^H |= 0x20000;
 107     $^H{charnames} = \&translator;
 108   }
 109
 110 Here translator() is a subroutine which takes C<CHARNAME> as an
 111 argument, and returns text to insert into the string instead of the
 112 C<\N{CHARNAME}> escape.  Since the text to insert should be different
 113 in C<utf8> mode and out of it, the function should check the current
 114 state of C<utf8>-flag as in
 115
 116   sub translator {
 117     if ($^H & 0x8) {
 118       return utf_translator(@_);
 119     } else {
 120       return no_utf_translator(@_);
 121     }
 122   }
 123
 124 =head1 BUGS
 125
 126 Since evaluation of the translation function happens in a middle of
 127 compilation (of a string literal), the translation function should not
 128 do any C<eval>s or C<require>s.  This restriction should be lifted in
 129 a future version of Perl.
 130
 131 =cut
 132