lib/base.pm

   1 =head1 NAME
   2
   3 base - Establish IS-A relationship with base class at compile time
   4
   5 =head1 SYNOPSIS
   6
   7     package Baz;
   8     use base qw(Foo Bar);
   9
  10 =head1 DESCRIPTION
  11
  12 Roughly similar in effect to
  13
  14     BEGIN {
  15         require Foo;
  16         require Bar;
  17         push @ISA, qw(Foo Bar);
  18     }
  19
  20 Will also initialize the %FIELDS hash if one of the base classes has
  21 it.  Multiple inheritance of %FIELDS is not supported.  The 'base'
  22 pragma will croak if multiple base classes have a %FIELDS hash.  See
  23 L<fields> for a description of this feature.
  24
  25 When strict 'vars' is in scope I<base> also let you assign to @ISA
  26 without having to declare @ISA with the 'vars' pragma first.
  27
  28 If any of the base classes are not loaded yet, I<base> silently
  29 C<require>s them.  Whether to C<require> a base class package is
  30 determined by the absence of a global $VERSION in the base package.
  31 If $VERSION is not detected even after loading it, <base> will
  32 define $VERSION in the base package, setting it to the string
  33 C<-1, defined by base.pm>.
  34
  35 =head1 HISTORY
  36
  37 This module was introduced with Perl 5.004_04.
  38
  39 =head1 SEE ALSO
  40
  41 L<fields>
  42
  43 =cut
  44
  45 package base;
  46 use vars qw($VERSION);
  47 $VERSION = "1.01";
  48
  49 sub import {
  50     my $class = shift;
  51     my $fields_base;
  52     my $pkg = caller(0);
  53
  54     foreach my $base (@_) {
  55         next if $pkg->isa($base);
  56         push @{"$pkg\::ISA"}, $base;
  57         unless (exists ${"$base\::"}{VERSION}) {
  58             eval "require $base";
  59             # Only ignore "Can't locate" errors from our eval require.
  60             # Other fatal errors (syntax etc) must be reported.
  61             die if $@ && $@ !~ /^Can't locate .*? at \(eval /;
  62             unless (%{"$base\::"}) {
  63                 require Carp;
  64                 Carp::croak("Base class package \"$base\" is empty.\n",
  65                             "\t(Perhaps you need to 'use' the module ",
  66                             "which defines that package first.)");
  67             }
  68             ${"$base\::VERSION"} = "-1, set by base.pm"
  69                 unless exists ${"$base\::"}{VERSION};
  70         }
  71
  72         # A simple test like (defined %{"$base\::FIELDS"}) will
  73         # sometimes produce typo warnings because it would create
  74         # the hash if it was not present before.
  75         my $fglob;
  76         if ($fglob = ${"$base\::"}{"FIELDS"} and *$fglob{HASH}) {
  77             if ($fields_base) {
  78                 require Carp;
  79                 Carp::croak("Can't multiply inherit %FIELDS");
  80             } else {
  81                 $fields_base = $base;
  82             }
  83         }
  84     }
  85     if ($fields_base) {
  86         require fields;
  87         fields::inherit($pkg, $fields_base);
  88     }
  89 }
  90
  91 1;