lib/attributes.pm

   1 package attributes;
   2
   3 $VERSION = 0.03;
   4
   5 @EXPORT_OK = qw(get reftype);
   6 @EXPORT = ();
   7 %EXPORT_TAGS = (ALL => [@EXPORT, @EXPORT_OK]);
   8
   9 use strict;
  10
  11 sub croak {
  12     require Carp;
  13     goto &Carp::croak;
  14 }
  15
  16 sub carp {
  17     require Carp;
  18     goto &Carp::carp;
  19 }
  20
  21 ## forward declaration(s) rather than wrapping the bootstrap call in BEGIN{}
  22 #sub reftype ($) ;
  23 #sub _fetch_attrs ($) ;
  24 #sub _guess_stash ($) ;
  25 #sub _modify_attrs ;
  26 #sub _warn_reserved () ;
  27 #
  28 # The extra trips through newATTRSUB in the interpreter wipe out any savings
  29 # from avoiding the BEGIN block.  Just do the bootstrap now.
  30 BEGIN { bootstrap }
  31
  32 sub import {
  33     @_ > 2 && ref $_[2] or do {
  34         require Exporter;
  35         goto &Exporter::import;
  36     };
  37     my (undef,$home_stash,$svref,@attrs) = @_;
  38
  39     my $svtype = uc reftype($svref);
  40     my $pkgmeth;
  41     $pkgmeth = UNIVERSAL::can($home_stash, "MODIFY_${svtype}_ATTRIBUTES")
  42         if defined $home_stash && $home_stash ne '';
  43     my @badattrs;
  44     if ($pkgmeth) {
  45         my @pkgattrs = _modify_attrs($svref, @attrs);
  46         @badattrs = $pkgmeth->($home_stash, $svref, @attrs);
  47         if (!@badattrs && @pkgattrs) {
  48             return unless _warn_reserved;
  49             @pkgattrs = grep { m/\A[[:lower:]]+(?:\z|\()/ } @pkgattrs;
  50             if (@pkgattrs) {
  51                 for my $attr (@pkgattrs) {
  52                     $attr =~ s/\(.+\z//s;
  53                 }
  54                 my $s = ((@pkgattrs == 1) ? '' : 's');
  55                 carp "$svtype package attribute$s " .
  56                     "may clash with future reserved word$s: " .
  57                     join(' : ' , @pkgattrs);
  58             }
  59         }
  60     }
  61     else {
  62         @badattrs = _modify_attrs($svref, @attrs);
  63     }
  64     if (@badattrs) {
  65         croak "Invalid $svtype attribute" .
  66             (( @badattrs == 1 ) ? '' : 's') .
  67             ": " .
  68             join(' : ', @badattrs);
  69     }
  70 }
  71
  72 sub get ($) {
  73     @_ == 1  && ref $_[0] or
  74         croak 'Usage: '.__PACKAGE__.'::get $ref';
  75     my $svref = shift;
  76     my $svtype = uc reftype $svref;
  77     my $stash = _guess_stash $svref;
  78     $stash = caller unless defined $stash;
  79     my $pkgmeth;
  80     $pkgmeth = UNIVERSAL::can($stash, "FETCH_${svtype}_ATTRIBUTES")
  81         if defined $stash && $stash ne '';
  82     return $pkgmeth ?
  83                 (_fetch_attrs($svref), $pkgmeth->($stash, $svref)) :
  84                 (_fetch_attrs($svref))
  85         ;
  86 }
  87
  88 sub require_version { goto &UNIVERSAL::VERSION }
  89
  90 1;
  91 __END__
  92 #The POD goes here
  93
  94 =head1 NAME
  95
  96 attributes - get/set subroutine or variable attributes
  97
  98 =head1 SYNOPSIS
  99
 100   sub foo : method ;
 101   my ($x,@y,%z) : Bent ;
 102   my $s = sub : method { ... };
 103
 104   use attributes ();    # optional, to get subroutine declarations
 105   my @attrlist = attributes::get(\&foo);
 106
 107   use attributes 'get'; # import the attributes::get subroutine
 108   my @attrlist = get \&foo;
 109
 110 =head1 DESCRIPTION
 111
 112 Subroutine declarations and definitions may optionally have attribute lists
 113 associated with them.  (Variable C<my> declarations also may, but see the
 114 warning below.)  Perl handles these declarations by passing some information
 115 about the call site and the thing being declared along with the attribute
 116 list to this module.  In particular, the first example above is equivalent to
 117 the following:
 118
 119     use attributes __PACKAGE__, \&foo, 'method';
 120
 121 The second example in the synopsis does something equivalent to this:
 122
 123     use attributes __PACKAGE__, \$x, 'Bent';
 124     use attributes __PACKAGE__, \@y, 'Bent';
 125     use attributes __PACKAGE__, \%z, 'Bent';
 126
 127 Yes, that's three invocations.
 128
 129 B<WARNING>: attribute declarations for variables are an I<experimental>
 130 feature.  The semantics of such declarations could change or be removed
 131 in future versions.  They are present for purposes of experimentation
 132 with what the semantics ought to be.  Do not rely on the current
 133 implementation of this feature.
 134
 135 There are only a few attributes currently handled by Perl itself (or
 136 directly by this module, depending on how you look at it.)  However,
 137 package-specific attributes are allowed by an extension mechanism.
 138 (See L<"Package-specific Attribute Handling"> below.)
 139
 140 The setting of attributes happens at compile time.  An attempt to set
 141 an unrecognized attribute is a fatal error.  (The error is trappable, but
 142 it still stops the compilation within that C<eval>.)  Setting an attribute
 143 with a name that's all lowercase letters that's not a built-in attribute
 144 (such as "foo")
 145 will result in a warning with B<-w> or C<use warnings 'reserved'>.
 146
 147 =head2 Built-in Attributes
 148
 149 The following are the built-in attributes for subroutines:
 150
 151 =over 4
 152
 153 =item locked
 154
 155 Setting this attribute is only meaningful when the subroutine or
 156 method is to be called by multiple threads.  When set on a method
 157 subroutine (i.e., one marked with the B<method> attribute below),
 158 Perl ensures that any invocation of it implicitly locks its first
 159 argument before execution.  When set on a non-method subroutine,
 160 Perl ensures that a lock is taken on the subroutine itself before
 161 execution.  The semantics of the lock are exactly those of one
 162 explicitly taken with the C<lock> operator immediately after the
 163 subroutine is entered.
 164
 165 =item method
 166
 167 Indicates that the referenced subroutine is a method.
 168 This has a meaning when taken together with the B<locked> attribute,
 169 as described there.  It also means that a subroutine so marked
 170 will not trigger the "Ambiguous call resolved as CORE::%s" warning.
 171
 172 =back
 173
 174 There are no built-in attributes for anything other than subroutines.
 175
 176 =head2 Available Subroutines
 177
 178 The following subroutines are available for general use once this module
 179 has been loaded:
 180
 181 =over 4
 182
 183 =item get
 184
 185 This routine expects a single parameter--a reference to a
 186 subroutine or variable.  It returns a list of attributes, which may be
 187 empty.  If passed invalid arguments, it uses die() (via L<Carp::croak|Carp>)
 188 to raise a fatal exception.  If it can find an appropriate package name
 189 for a class method lookup, it will include the results from a
 190 C<FETCH_I<type>_ATTRIBUTES> call in its return list, as described in
 191 L<"Package-specific Attribute Handling"> below.
 192 Otherwise, only L<built-in attributes|"Built-in Attributes"> will be returned.
 193
 194 =item reftype
 195
 196 This routine expects a single parameter--a reference to a subroutine or
 197 variable.  It returns the built-in type of the referenced variable,
 198 ignoring any package into which it might have been blessed.
 199 This can be useful for determining the I<type> value which forms part of
 200 the method names described in L<"Package-specific Attribute Handling"> below.
 201
 202 =back
 203
 204 Note that these routines are I<not> exported by default.
 205
 206 =head2 Package-specific Attribute Handling
 207
 208 B<WARNING>: the mechanisms described here are still experimental.  Do not
 209 rely on the current implementation.  In particular, there is no provision
 210 for applying package attributes to 'cloned' copies of subroutines used as
 211 closures.  (See L<perlref/"Making References"> for information on closures.)
 212 Package-specific attribute handling may change incompatibly in a future
 213 release.
 214
 215 When an attribute list is present in a declaration, a check is made to see
 216 whether an attribute 'modify' handler is present in the appropriate package
 217 (or its @ISA inheritance tree).  Similarly, when C<attributes::get> is
 218 called on a valid reference, a check is made for an appropriate attribute
 219 'fetch' handler.  See L<"EXAMPLES"> to see how the "appropriate package"
 220 determination works.
 221
 222 The handler names are based on the underlying type of the variable being
 223 declared or of the reference passed.  Because these attributes are
 224 associated with subroutine or variable declarations, this deliberately
 225 ignores any possibility of being blessed into some package.  Thus, a
 226 subroutine declaration uses "CODE" as its I<type>, and even a blessed
 227 hash reference uses "HASH" as its I<type>.
 228
 229 The class methods invoked for modifying and fetching are these:
 230
 231 =over 4
 232
 233 =item FETCH_I<type>_ATTRIBUTES
 234
 235 This method receives a single argument, which is a reference to the
 236 variable or subroutine for which package-defined attributes are desired.
 237 The expected return value is a list of associated attributes.
 238 This list may be empty.
 239
 240 =item MODIFY_I<type>_ATTRIBUTES
 241
 242 This method is called with two fixed arguments, followed by the list of
 243 attributes from the relevant declaration.  The two fixed arguments are
 244 the relevant package name and a reference to the declared subroutine or
 245 variable.  The expected return value as a list of attributes which were
 246 not recognized by this handler.  Note that this allows for a derived class
 247 to delegate a call to its base class, and then only examine the attributes
 248 which the base class didn't already handle for it.
 249
 250 The call to this method is currently made I<during> the processing of the
 251 declaration.  In particular, this means that a subroutine reference will
 252 probably be for an undefined subroutine, even if this declaration is
 253 actually part of the definition.
 254
 255 =back
 256
 257 Calling C<attributes::get()> from within the scope of a null package
 258 declaration C<package ;> for an unblessed variable reference will
 259 not provide any starting package name for the 'fetch' method lookup.
 260 Thus, this circumstance will not result in a method call for package-defined
 261 attributes.  A named subroutine knows to which symbol table entry it belongs
 262 (or originally belonged), and it will use the corresponding package.
 263 An anonymous subroutine knows the package name into which it was compiled
 264 (unless it was also compiled with a null package declaration), and so it
 265 will use that package name.
 266
 267 =head2 Syntax of Attribute Lists
 268
 269 An attribute list is a sequence of attribute specifications, separated by
 270 whitespace or a colon (with optional whitespace).
 271 Each attribute specification is a simple
 272 name, optionally followed by a parenthesised parameter list.
 273 If such a parameter list is present, it is scanned past as for the rules
 274 for the C<q()> operator.  (See L<perlop/"Quote and Quote-like Operators">.)
 275 The parameter list is passed as it was found, however, and not as per C<q()>.
 276
 277 Some examples of syntactically valid attribute lists:
 278
 279     switch(10,foo(7,3))  :  expensive
 280     Ugly('\(") :Bad
 281     _5x5
 282     locked method
 283
 284 Some examples of syntactically invalid attribute lists (with annotation):
 285
 286     switch(10,foo()             # ()-string not balanced
 287     Ugly('(')                   # ()-string not balanced
 288     5x5                         # "5x5" not a valid identifier
 289     Y2::north                   # "Y2::north" not a simple identifier
 290     foo + bar                   # "+" neither a colon nor whitespace
 291
 292 =head1 EXPORTS
 293
 294 =head2 Default exports
 295
 296 None.
 297
 298 =head2 Available exports
 299
 300 The routines C<get> and C<reftype> are exportable.
 301
 302 =head2 Export tags defined
 303
 304 The C<:ALL> tag will get all of the above exports.
 305
 306 =head1 EXAMPLES
 307
 308 Here are some samples of syntactically valid declarations, with annotation
 309 as to how they resolve internally into C<use attributes> invocations by
 310 perl.  These examples are primarily useful to see how the "appropriate
 311 package" is found for the possible method lookups for package-defined
 312 attributes.
 313
 314 =over 4
 315
 316 =item 1.
 317
 318 Code:
 319
 320     package Canine;
 321     package Dog;
 322     my Canine $spot : Watchful ;
 323
 324 Effect:
 325
 326     use attributes Canine => \$spot, "Watchful";
 327
 328 =item 2.
 329
 330 Code:
 331
 332     package Felis;
 333     my $cat : Nervous;
 334
 335 Effect:
 336
 337     use attributes Felis => \$cat, "Nervous";
 338
 339 =item 3.
 340
 341 Code:
 342
 343     package X;
 344     sub foo : locked ;
 345
 346 Effect:
 347
 348     use attributes X => \&foo, "locked";
 349
 350 =item 4.
 351
 352 Code:
 353
 354     package X;
 355     sub Y::x : locked { 1 }
 356
 357 Effect:
 358
 359     use attributes Y => \&Y::x, "locked";
 360
 361 =item 5.
 362
 363 Code:
 364
 365     package X;
 366     sub foo { 1 }
 367
 368     package Y;
 369     BEGIN { *bar = \&X::foo; }
 370
 371     package Z;
 372     sub Y::bar : locked ;
 373
 374 Effect:
 375
 376     use attributes X => \&X::foo, "locked";
 377
 378 =back
 379
 380 This last example is purely for purposes of completeness.  You should not
 381 be trying to mess with the attributes of something in a package that's
 382 not your own.
 383
 384 =head1 SEE ALSO
 385
 386 L<perlsub/"Private Variables via my()"> and
 387 L<perlsub/"Subroutine Attributes"> for details on the basic declarations;
 388 L<attrs> for the obsolescent form of subroutine attribute specification
 389 which this module replaces;
 390 L<perlfunc/use> for details on the normal invocation mechanism.
 391
 392 =cut
 393